CMakeLists.txt

   1 ###############################################################################
   2 # Top contributors (to current version):
   3 #   Aina Niemetz, Mathias Preiner, Gereon Kremer
   4 #
   5 # This file is part of the cvc5 project.
   6 #
   7 # Copyright (c) 2009-2021 by the authors listed in the file AUTHORS
   8 # in the top-level source directory and their institutional affiliations.
   9 # All rights reserved.  See the file COPYING in the top-level source
  10 # directory for licensing information.
  11 # #############################################################################
  12 #
  13 # The build system configuration.
  14 ##
  15
  16 cmake_minimum_required(VERSION 3.9)
  17
  18 #-----------------------------------------------------------------------------#
  19 # Project configuration
  20
  21 project(cvc5)
  22
  23 include(CheckIPOSupported)
  24 include(GNUInstallDirs)
  25 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  26
  27 include(version)
  28
  29 set(CMAKE_C_STANDARD 99)
  30 set(CMAKE_CXX_STANDARD 17)
  31 set(CMAKE_CXX_EXTENSIONS OFF)
  32 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  33 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  34 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  35
  36 # Generate compile_commands.json, which can be used for various code completion
  37 # plugins.
  38 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  39
  40 #-----------------------------------------------------------------------------#
  41 # Policies
  42
  43 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  44 if(POLICY CMP0075)
  45   cmake_policy(SET CMP0075 NEW)
  46 endif()
  47
  48 #-----------------------------------------------------------------------------#
  49 # Tell CMake where to find our dependencies
  50
  51 if(GLPK_DIR)
  52   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  53 endif()
  54
  55 # By default the contrib/get-* scripts install dependencies to deps/install.
  56 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  57
  58 #-----------------------------------------------------------------------------#
  59
  60 include(Helpers)
  61
  62 #-----------------------------------------------------------------------------#
  63 # User options
  64
  65 # License
  66 option(ENABLE_GPL "Enable GPL dependencies")
  67
  68 # General build options
  69 #
  70 # >> 3-valued: IGNORE ON OFF
  71 #    > allows to detect if set by user (default: IGNORE)
  72 #    > only necessary for options set for build types
  73 option(BUILD_SHARED_LIBS          "Build shared libraries and binary")
  74 cvc5_option(ENABLE_ASAN           "Enable ASAN build")
  75 cvc5_option(ENABLE_UBSAN          "Enable UBSan build")
  76 cvc5_option(ENABLE_TSAN           "Enable TSan build")
  77 cvc5_option(ENABLE_ASSERTIONS     "Enable assertions")
  78 cvc5_option(ENABLE_COMP_INC_TRACK
  79             "Enable optimizations for incremental SMT-COMP tracks")
  80 cvc5_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
  81 cvc5_option(ENABLE_DUMPING        "Enable dumping")
  82 cvc5_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
  83 cvc5_option(ENABLE_STATISTICS     "Enable statistics")
  84 cvc5_option(ENABLE_TRACING        "Enable tracing")
  85 cvc5_option(ENABLE_UNIT_TESTING   "Enable unit testing")
  86 cvc5_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
  87 cvc5_option(ENABLE_AUTO_DOWNLOAD  "Enable automatic download of dependencies")
  88 cvc5_option(ENABLE_IPO            "Enable interprocedural optimization")
  89 # >> 2-valued: ON OFF
  90 #    > for options where we don't need to detect if set by user (default: OFF)
  91 option(ENABLE_BEST             "Enable dependencies known to give best performance")
  92 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
  93 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
  94 option(ENABLE_PROFILING        "Enable support for gprof profiling")
  95
  96 # Optional dependencies
  97 #
  98 # >> 3-valued: IGNORE ON OFF
  99 #    > allows to detect if set by user (default: IGNORE)
 100 #    > only necessary for options set for ENABLE_BEST
 101 cvc5_option(USE_CLN           "Use CLN instead of GMP")
 102 cvc5_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 103 cvc5_option(USE_GLPK          "Use GLPK simplex solver")
 104 cvc5_option(USE_KISSAT        "Use Kissat SAT solver")
 105 cvc5_option(USE_EDITLINE      "Use Editline for better interactive support")
 106 # >> 2-valued: ON OFF
 107 #    > for options where we don't need to detect if set by user (default: OFF)
 108 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 109 option(USE_COCOA              "Use CoCoALib for further polynomial operations")
 110 option(USE_PYTHON2            "Force Python 2 (deprecated)")
 111
 112 # Custom install directories for dependencies
 113 # If no directory is provided by the user, we first check if the dependency was
 114 # installed via the corresponding contrib/get-* script and if not found, we
 115 # check the intalled system version. If the user provides a directory we
 116 # immediately fail if the dependency was not found at the specified location.
 117 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 118
 119 # Prepend binaries with prefix on make install
 120 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 121
 122 # Supported language bindings based on new C++ API
 123 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 124 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 125
 126 # Api documentation
 127 option(BUILD_DOCS "Build Api documentation")
 128
 129 #-----------------------------------------------------------------------------#
 130 # Internal cmake variables
 131
 132 set(OPTIMIZATION_LEVEL 3)
 133 set(GPL_LIBS "")
 134
 135 #-----------------------------------------------------------------------------#
 136 # Determine number of threads available, used to configure (default) parallel
 137 # execution of custom test targets (can be overriden with ARGS=-jN).
 138
 139 include(ProcessorCount)
 140 ProcessorCount(CTEST_NTHREADS)
 141 if(CTEST_NTHREADS EQUAL 0)
 142   set(CTEST_NTHREADS 1)
 143 endif()
 144
 145 #-----------------------------------------------------------------------------#
 146 # Build types
 147
 148 # Note: Module CodeCoverage requires the name of the debug build to conform
 149 #       to cmake standards (first letter uppercase).
 150 set(BUILD_TYPES Production Debug Testing Competition)
 151
 152 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 153   set(CMAKE_BUILD_TYPE Debug)
 154 endif()
 155
 156 # Set the default build type to Production
 157 if(NOT CMAKE_BUILD_TYPE)
 158   set(CMAKE_BUILD_TYPE
 159       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 160   # Provide drop down menu options in cmake-gui
 161   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 162 endif()
 163
 164 # Check if specified build type is valid.
 165 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 166 if(${FOUND_BUILD_TYPE} EQUAL -1)
 167   message(FATAL_ERROR
 168     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 169     "Available builds are: ${BUILD_TYPES}")
 170 endif()
 171
 172 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 173 include(Config${CMAKE_BUILD_TYPE})
 174
 175 #-----------------------------------------------------------------------------#
 176 # Compiler flags
 177
 178 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 179 add_check_c_cxx_flag("-Wall")
 180 add_check_c_cxx_supression_flag("-Wno-unused-private-field")
 181 add_check_c_flag("-fexceptions")
 182 add_check_cxx_flag("-Wsuggest-override")
 183 add_check_cxx_flag("-Wnon-virtual-dtor")
 184 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 185 add_check_c_cxx_flag("-Wshadow")
 186
 187 # Assume no dynamic initialization of thread-local variables in non-defining
 188 # translation units. This option should result in better performance and works
 189 # around crashing issues with our Windows build.
 190 add_check_cxx_flag("-fno-extern-tls-init")
 191
 192 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 193 # cdlist.h warnings. Remove when fixed.
 194 add_check_cxx_supression_flag("-Wno-class-memaccess")
 195
 196 if (WIN32)
 197   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 198 endif ()
 199
 200 #-----------------------------------------------------------------------------#
 201 # Use ld.gold if available
 202
 203 execute_process(COMMAND ${CMAKE_C_COMPILER}
 204                 -fuse-ld=gold
 205                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 206 if ("${LD_VERSION}" MATCHES "GNU gold")
 207   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 208   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 209   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 210   message(STATUS "Using GNU gold linker.")
 211 endif ()
 212
 213 #-----------------------------------------------------------------------------#
 214 # Use interprocedural optimization if requested
 215
 216 if(ENABLE_IPO)
 217   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 218 endif()
 219
 220 #-----------------------------------------------------------------------------#
 221
 222 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 223 # that expect AssertionException to be thrown will fail.
 224 if(NOT ENABLE_ASSERTIONS)
 225   message(STATUS "Disabling unit tests since assertions are disabled.")
 226   set(ENABLE_UNIT_TESTING OFF)
 227 endif()
 228
 229 #-----------------------------------------------------------------------------#
 230 # Shared/static libraries
 231
 232 # Embed the installation prefix as an RPATH in the executable such that the
 233 # linker can find our libraries (such as libcvc5parser) when executing the
 234 # cvc5 binary. This is for example useful when installing cvc5 with a custom
 235 # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 236 # we do not set this option, then the linker will not be able to find the
 237 # required libraries when trying to run cvc5.
 238 #
 239 # Also embed the installation prefix of the installed contrib libraries as an
 240 # RPATH. This allows to install a dynamically linked binary that depends on
 241 # dynamically linked libraries. This is dangerous, as the installed binary
 242 # breaks if the contrib library is removed or changes in other ways, we thus
 243 # print a big warning and only allow if installing to a custom installation
 244 # prefix.
 245 #
 246 # More information on RPATH in CMake:
 247 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 248 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 249
 250 # Set visibility to default if unit tests are enabled
 251 if(ENABLE_UNIT_TESTING)
 252   set(CMAKE_CXX_VISIBILITY_PRESET default)
 253   set(CMAKE_VISIBILITY_INLINES_HIDDEN 0)
 254 endif()
 255
 256 #-----------------------------------------------------------------------------#
 257 # Enable the ctest testing framework
 258
 259 # This needs to be enabled here rather than in subdirectory test in order to
 260 # allow calling ctest from the root build directory.
 261 enable_testing()
 262
 263 #-----------------------------------------------------------------------------#
 264 # Check options, find packages and configure build.
 265
 266 if(BUILD_SHARED_LIBS)
 267   if (WIN32)
 268     set(CMAKE_FIND_LIBRARY_SUFFIXES .dll .lib .a)
 269   else()
 270     set(CMAKE_FIND_LIBRARY_SUFFIXES .so .dylib .a)
 271   endif()
 272 else()
 273   if (WIN32)
 274     set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a .dll)
 275   else()
 276     set(CMAKE_FIND_LIBRARY_SUFFIXES .a .so .dylib)
 277   endif()
 278 endif()
 279
 280 if(USE_PYTHON2)
 281   find_package(PythonInterp 2.7 REQUIRED)
 282 else()
 283   find_package(PythonInterp 3 REQUIRED)
 284 endif()
 285
 286 find_package(GMP 6.1 REQUIRED)
 287
 288 if(ENABLE_ASAN)
 289   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 290   # otherwise the -fsanitize=address check will fail while linking.
 291   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 292   add_required_c_cxx_flag("-fsanitize=address")
 293   unset(CMAKE_REQUIRED_FLAGS)
 294   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 295   add_check_c_cxx_flag("-fsanitize-recover=address")
 296 endif()
 297
 298 if(ENABLE_UBSAN)
 299   add_required_c_cxx_flag("-fsanitize=undefined")
 300   add_definitions(-DCVC5_USE_UBSAN)
 301 endif()
 302
 303 if(ENABLE_TSAN)
 304   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 305   # otherwise the -fsanitize=thread check will fail while linking.
 306   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 307   add_required_c_cxx_flag("-fsanitize=thread")
 308   unset(CMAKE_REQUIRED_FLAGS)
 309 endif()
 310
 311 if(ENABLE_ASSERTIONS)
 312   add_definitions(-DCVC5_ASSERTIONS)
 313 else()
 314   add_definitions(-DNDEBUG)
 315 endif()
 316
 317 if(ENABLE_COVERAGE)
 318   include(CodeCoverage)
 319   APPEND_COVERAGE_COMPILER_FLAGS()
 320   add_definitions(-DCVC5_COVERAGE)
 321   # Note: The ctest command returns a non-zero exit code if tests fail or run
 322   # into a timeout. As a consequence, the coverage report is not generated. To
 323   # prevent this we always return with exit code 0 after the ctest command has
 324   # finished.
 325   setup_target_for_coverage_gcovr_html(
 326     NAME coverage-test
 327     EXECUTABLE
 328       ctest -j${CTEST_NTHREADS} -LE "example"
 329         --output-on-failure $$ARGS || exit 0
 330     DEPENDS
 331       build-tests)
 332
 333   # Adds targets `coverage` and `coverage-reset` for manually generating
 334   # coverage reports for specific executions.
 335   #
 336   # Target coverage-reset resets all the coverage counters to zero, while
 337   # target coverage will generate a coverage report for all executions since
 338   # the last coverage-reset.
 339   setup_target_for_coverage_lcov_no_executable(
 340     NAME coverage
 341     DEPENDENCIES cvc5-bin)
 342 endif()
 343
 344 if(ENABLE_DEBUG_CONTEXT_MM)
 345   add_definitions(-DCVC5_DEBUG_CONTEXT_MEMORY_MANAGER)
 346 endif()
 347
 348 if(ENABLE_DEBUG_SYMBOLS)
 349   add_check_c_cxx_flag("-ggdb3")
 350 endif()
 351
 352 if(ENABLE_COMP_INC_TRACK)
 353   add_definitions(-DCVC5_SMTCOMP_APPLICATION_TRACK)
 354 endif()
 355
 356 if(ENABLE_MUZZLE)
 357   add_definitions(-DCVC5_MUZZLE)
 358 endif()
 359
 360 if(ENABLE_DUMPING)
 361   add_definitions(-DCVC5_DUMPING)
 362 endif()
 363
 364 if(ENABLE_PROFILING)
 365   add_definitions(-DCVC5_PROFILING)
 366   add_check_c_cxx_flag("-pg")
 367 endif()
 368
 369 if(ENABLE_TRACING)
 370   add_definitions(-DCVC5_TRACING)
 371 endif()
 372
 373 if(ENABLE_STATISTICS)
 374   add_definitions(-DCVC5_STATISTICS_ON)
 375 endif()
 376
 377 if(ENABLE_VALGRIND)
 378   find_package(Valgrind REQUIRED)
 379   add_definitions(-DCVC5_VALGRIND)
 380 endif()
 381
 382 find_package(CaDiCaL REQUIRED)
 383
 384 if(USE_CLN)
 385   set(GPL_LIBS "${GPL_LIBS} cln")
 386   find_package(CLN 1.2.2 REQUIRED)
 387   set(CVC5_USE_CLN_IMP 1)
 388   set(CVC5_USE_GMP_IMP 0)
 389 else()
 390   set(CVC5_USE_CLN_IMP 0)
 391   set(CVC5_USE_GMP_IMP 1)
 392 endif()
 393
 394 if(USE_CRYPTOMINISAT)
 395   # CryptoMiniSat requires pthreads support
 396   set(THREADS_PREFER_PTHREAD_FLAG ON)
 397   find_package(Threads REQUIRED)
 398   if(THREADS_HAVE_PTHREAD_ARG)
 399     add_c_cxx_flag(-pthread)
 400   endif()
 401   find_package(CryptoMiniSat 5.8 REQUIRED)
 402   add_definitions(-DCVC5_USE_CRYPTOMINISAT)
 403 endif()
 404
 405 if(USE_GLPK)
 406   set(GPL_LIBS "${GPL_LIBS} glpk")
 407   find_package(GLPK REQUIRED)
 408   add_definitions(-DCVC5_USE_GLPK)
 409 endif()
 410
 411 if(USE_KISSAT)
 412   find_package(Kissat REQUIRED)
 413   add_definitions(-DCVC5_USE_KISSAT)
 414 endif()
 415
 416 if(USE_POLY)
 417   find_package(Poly REQUIRED)
 418   add_definitions(-DCVC5_USE_POLY)
 419   set(CVC5_USE_POLY_IMP 1)
 420 else()
 421   set(CVC5_USE_POLY_IMP 0)
 422 endif()
 423
 424 if(USE_COCOA)
 425   find_package(CoCoA REQUIRED 0.99711)
 426   add_definitions(-DCVC5_USE_COCOA)
 427 endif()
 428
 429 if(USE_EDITLINE)
 430   find_package(Editline REQUIRED)
 431   set(HAVE_LIBEDITLINE 1)
 432   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 433     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 434   endif()
 435 endif()
 436
 437 find_package(SymFPU REQUIRED)
 438
 439 if(GPL_LIBS)
 440   if(NOT ENABLE_GPL)
 441     message(FATAL_ERROR
 442       "Bad configuration detected: BSD-licensed code only, but also requested "
 443       "GPLed libraries: ${GPL_LIBS}")
 444   endif()
 445   set(CVC5_GPL_DEPS 1)
 446 endif()
 447
 448 #-----------------------------------------------------------------------------#
 449 # Provide targets to inspect iwyu suggestions
 450
 451 include(IWYU)
 452 include(fuzzing-murxla)
 453
 454 #-----------------------------------------------------------------------------#
 455
 456 include(ConfigureCvc5)
 457 if(BUILD_SHARED_LIBS)
 458   set(CVC5_STATIC_BUILD OFF)
 459 else()
 460   set(CVC5_STATIC_BUILD ON)
 461 endif()
 462
 463 #-----------------------------------------------------------------------------#
 464 # Add subdirectories
 465
 466 add_subdirectory(src)
 467
 468 if(BUILD_BINDINGS_PYTHON AND NOT BUILD_SHARED_LIBS)
 469   message(STATUS "Python bindings can only be built in a shared build.")
 470   set(BUILD_BINDINGS_PYTHON OFF)
 471 endif()
 472 if(BUILD_BINDINGS_PYTHON)
 473   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 474   add_subdirectory(src/api/python)
 475 endif()
 476
 477 if(BUILD_BINDINGS_JAVA)
 478   add_subdirectory(src/api/java)
 479   message(WARNING "Java API is currently under development.")
 480 endif()
 481
 482 if(BUILD_DOCS)
 483   add_subdirectory(docs)
 484 endif()
 485
 486 add_subdirectory(test)
 487
 488 include(target-graphs)
 489
 490 #-----------------------------------------------------------------------------#
 491 # Package configuration
 492 #
 493 # Export cvc5 targets to support find_package(cvc5) in other cmake projects.
 494
 495 include(CMakePackageConfigHelpers)
 496
 497 # If we install a dynamically linked binary that also uses dynamically used
 498 # libraries from deps/install/lib, we need to be cautious. Changing these
 499 # shared libraries from deps/install/lib most probably breaks the binary.
 500 # We only allow such an installation for custom installation prefixes
 501 # (in the assumption that only reasonably experienced users use this and
 502 # also that custom installation prefixes are not used for longer periods of
 503 # time anyway). Also, we print a big warning with further instructions.
 504 if(BUILD_SHARED_LIBS)
 505   # Get the libraries that cvc5 links against
 506   get_target_property(libs cvc5 INTERFACE_LINK_LIBRARIES)
 507   set(LIBS_SHARED_FROM_DEPS "")
 508   foreach(lib ${libs})
 509     # Filter out those that are linked dynamically and come from deps/install
 510     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 511       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 512     endif()
 513   endforeach()
 514   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 515   # Check if we actually use such "dangerous" libraries
 516   if(list_len GREATER 0)
 517     # Print a generic warning
 518     install(CODE "message(WARNING \"You are installing a dynamically linked \
 519     binary of cvc5 which may be a problem if you are using any dynamically \
 520     linked third-party library that you obtained through one of the \
 521     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 522     locally, hence executing such a contrib script removing the \
 523     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 524     Consider installing the dynamically linked dependencies on your system \
 525     manually or link cvc5 statically.\")")
 526     # Print the libraries in question
 527     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 528       install(CODE "message(WARNING \"The following library is used by the cvc5 binary: ${lib}\")")
 529     endforeach()
 530     # Check if we use a custom installation prefix
 531     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 532       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 533       soon-to-be-broken binary, system-wide installation is disabled if the \
 534       binary depends on locally-built shared libraries.\")")
 535     else()
 536       install(CODE "message(WARNING \"You have selected a custom install \
 537       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 538       previous warning and know what you are doing.\")")
 539     endif()
 540   endif()
 541 endif()
 542
 543 install(EXPORT cvc5-targets
 544   FILE cvc5Targets.cmake
 545   NAMESPACE cvc5::
 546   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5)
 547
 548 configure_package_config_file(
 549   ${CMAKE_SOURCE_DIR}/cmake/cvc5Config.cmake.in
 550   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 551   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 552   PATH_VARS CMAKE_INSTALL_LIBDIR
 553 )
 554
 555 write_basic_package_version_file(
 556   ${CMAKE_CURRENT_BINARY_DIR}/cvc5ConfigVersion.cmake
 557   VERSION ${CVC5_VERSION}
 558   COMPATIBILITY ExactVersion
 559 )
 560
 561 install(FILES
 562   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 563   ${CMAKE_BINARY_DIR}/cvc5ConfigVersion.cmake
 564   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 565 )
 566
 567
 568 #-----------------------------------------------------------------------------#
 569 # Print build configuration
 570
 571 # Set colors.
 572 if(NOT WIN32)
 573   string(ASCII 27 Esc)
 574   set(Green "${Esc}[32m")
 575   set(Blue "${Esc}[1;34m")
 576   set(ResetColor "${Esc}[m")
 577 endif()
 578
 579 # Convert build type to lower case.
 580 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC5_BUILD_PROFILE_STRING)
 581
 582 # Get all definitions added via add_definitions.
 583 get_directory_property(CVC5_DEFINITIONS COMPILE_DEFINITIONS)
 584 string(REPLACE ";" " " CVC5_DEFINITIONS "${CVC5_DEFINITIONS}")
 585
 586 message("")
 587 print_info("cvc5 ${CVC5_VERSION}")
 588 message("")
 589 if(ENABLE_COMP_INC_TRACK)
 590   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING} (incremental)")
 591 else()
 592   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING}")
 593 endif()
 594 message("")
 595 print_config("GPL                       " ${ENABLE_GPL})
 596 print_config("Best configuration        " ${ENABLE_BEST})
 597 message("")
 598 print_config("Assertions                " ${ENABLE_ASSERTIONS})
 599 print_config("Debug symbols             " ${ENABLE_DEBUG_SYMBOLS})
 600 print_config("Debug context mem mgr     " ${ENABLE_DEBUG_CONTEXT_MM})
 601 message("")
 602 print_config("Dumping                   " ${ENABLE_DUMPING})
 603 print_config("Muzzle                    " ${ENABLE_MUZZLE})
 604 print_config("Statistics                " ${ENABLE_STATISTICS})
 605 print_config("Tracing                   " ${ENABLE_TRACING})
 606 message("")
 607 print_config("ASan                      " ${ENABLE_ASAN})
 608 print_config("UBSan                     " ${ENABLE_UBSAN})
 609 print_config("TSan                      " ${ENABLE_TSAN})
 610 print_config("Coverage (gcov)           " ${ENABLE_COVERAGE})
 611 print_config("Profiling (gprof)         " ${ENABLE_PROFILING})
 612 print_config("Unit tests                " ${ENABLE_UNIT_TESTING})
 613 print_config("Valgrind                  " ${ENABLE_VALGRIND})
 614 message("")
 615 print_config("Shared build              " ${BUILD_SHARED_LIBS})
 616 print_config("Python bindings           " ${BUILD_BINDINGS_PYTHON})
 617 print_config("Java bindings             " ${BUILD_BINDINGS_JAVA})
 618 print_config("Python2                   " ${USE_PYTHON2})
 619 print_config("Interprocedural opt.      " ${ENABLE_IPO})
 620 message("")
 621 print_config("CryptoMiniSat             " ${USE_CRYPTOMINISAT} FOUND_SYSTEM ${CryptoMiniSat_FOUND_SYSTEM})
 622 print_config("GLPK                      " ${USE_GLPK})
 623 print_config("Kissat                    " ${USE_KISSAT} FOUND_SYSTEM ${Kissat_FOUND_SYSTEM})
 624 print_config("LibPoly                   " ${USE_POLY} FOUND_SYSTEM ${Poly_FOUND_SYSTEM})
 625 print_config("CoCoALib                  " ${USE_COCOA} FOUND_SYSTEM ${CoCoA_FOUND_SYSTEM})
 626
 627 if(CVC5_USE_CLN_IMP)
 628   print_config("MP library                " "cln" FOUND_SYSTEM ${CLN_FOUND_SYSTEM})
 629 else()
 630   print_config("MP library                " "gmp" FOUND_SYSTEM ${GMP_FOUND_SYSTEM})
 631 endif()
 632 print_config("Editline                  " ${USE_EDITLINE})
 633 message("")
 634 print_config("Api docs                  " ${BUILD_DOCS})
 635 message("")
 636 if(GLPK_DIR)
 637   print_config("GLPK dir                  " ${GLPK_DIR})
 638 endif()
 639 message("")
 640 print_config("CPPLAGS (-D...)" "${CVC5_DEFINITIONS}")
 641 print_config("CXXFLAGS       " "${CMAKE_CXX_FLAGS}")
 642 print_config("CFLAGS         " "${CMAKE_C_FLAGS}")
 643 print_config("Linker flags   " "${CMAKE_EXE_LINKER_FLAGS}")
 644 message("")
 645 print_config("Install prefix " "${CMAKE_INSTALL_PREFIX}")
 646 message("")
 647
 648 if(GPL_LIBS)
 649   message(
 650   "${Blue}cvc5 license: "
 651   "${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 652   "\n"
 653   "\n"
 654   "Please note that cvc5 will be built against the following GPLed libraries:"
 655   "\n"
 656   "${GPL_LIBS}"
 657   "\n"
 658   "As these libraries are covered under the GPLv3, so is this build of cvc5."
 659   "\n"
 660   "cvc5 is also available to you under the terms of the (modified) BSD license."
 661   "\n"
 662   "If you prefer to license cvc5 under those terms, please configure cvc5 to"
 663   "\n"
 664   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 665   )
 666 else()
 667   message(
 668   "${Blue}cvc5 license:${ResetColor} modified BSD"
 669   "\n"
 670   "\n"
 671   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 672   "\n"
 673   "it is covered by the (modified) BSD license.  To build against GPL'ed"
 674   "\n"
 675   "libraries which can improve cvc5's performance on arithmetic and bitvector"
 676   "\n"
 677   "logics, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 678   )
 679 endif()
 680
 681 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 682   set(BUILD_COMMAND_NAME "ninja")
 683 else()
 684   set(BUILD_COMMAND_NAME "make")
 685 endif()
 686
 687 message("")
 688 message("Now just type '${BUILD_COMMAND_NAME}', "
 689         "followed by '${BUILD_COMMAND_NAME} check' "
 690         "or '${BUILD_COMMAND_NAME} install'.")
 691 message("")