CMakeLists.txt

   1 #####################
   2 ## CMakeLists.txt
   3 ## Top contributors (to current version):
   4 ##   Mathias Preiner, Aina Niemetz, Gereon Kremer
   5 ## This file is part of the CVC4 project.
   6 ## Copyright (c) 2009-2020 by the authors listed in the file AUTHORS
   7 ## in the top-level source directory and their institutional affiliations.
   8 ## All rights reserved.  See the file COPYING in the top-level source
   9 ## directory for licensing information.
  10 ##
  11 cmake_minimum_required(VERSION 3.4)
  12
  13 #-----------------------------------------------------------------------------#
  14 # Project configuration
  15
  16 project(cvc4)
  17
  18 include(GNUInstallDirs)
  19
  20 set(CVC4_MAJOR   1) # Major component of the version of CVC4.
  21 set(CVC4_MINOR   9) # Minor component of the version of CVC4.
  22 set(CVC4_RELEASE 0) # Release component of the version of CVC4.
  23
  24 # Extraversion component of the version of CVC4.
  25 set(CVC4_EXTRAVERSION "-prerelease")
  26
  27 # Shared library versioning. Increment SOVERSION for every new CVC4 release.
  28 set(CVC4_SOVERSION 7)
  29
  30 # Full release string for CVC4.
  31 if(CVC4_RELEASE)
  32   set(CVC4_RELEASE_STRING
  33       "${CVC4_MAJOR}.${CVC4_MINOR}.${CVC4_RELEASE}${CVC4_EXTRAVERSION}")
  34 else()
  35   set(CVC4_RELEASE_STRING "${CVC4_MAJOR}.${CVC4_MINOR}${CVC4_EXTRAVERSION}")
  36 endif()
  37
  38 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  39 set(CMAKE_C_STANDARD 99)
  40 set(CMAKE_CXX_STANDARD 11)
  41 set(CMAKE_CXX_EXTENSIONS OFF)
  42
  43 # Generate compile_commands.json, which can be used for various code completion
  44 # plugins.
  45 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  46
  47 #-----------------------------------------------------------------------------#
  48 # Policies
  49
  50 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  51 if(POLICY CMP0075)
  52   cmake_policy(SET CMP0075 NEW)
  53 endif()
  54
  55 #-----------------------------------------------------------------------------#
  56 # Tell CMake where to find our dependencies
  57
  58 if(ABC_DIR)
  59   list(APPEND CMAKE_PREFIX_PATH "${ABC_DIR}")
  60 endif()
  61 if(ANTLR_DIR)
  62   list(APPEND CMAKE_PREFIX_PATH "${ANTLR_DIR}")
  63 endif()
  64 if(CADICAL_DIR)
  65   list(APPEND CMAKE_PREFIX_PATH "${CADICAL_DIR}")
  66 endif()
  67 if(CRYPTOMINISAT_DIR)
  68   list(APPEND CMAKE_PREFIX_PATH "${CRYPTOMINISAT_DIR}")
  69 endif()
  70 if(CXXTEST_DIR)
  71   list(APPEND CMAKE_PREFIX_PATH "${CXXTEST_DIR}")
  72 endif()
  73 if(DRAT2ER_DIR)
  74   list(APPEND CMAKE_PREFIX_PATH "${DRAT2ER_DIR}")
  75 endif()
  76 if(GLPK_DIR)
  77   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  78 endif()
  79 if(GMP_DIR)
  80   list(APPEND CMAKE_PREFIX_PATH "${GMP_DIR}")
  81 endif()
  82 if(KISSAT_DIR)
  83   list(APPEND CMAKE_PREFIX_PATH "${KISSAT_DIR}")
  84 endif()
  85 if(LFSC_DIR)
  86   list(APPEND CMAKE_PREFIX_PATH "${LFSC_DIR}")
  87 endif()
  88 if(POLY_DIR)
  89   list(APPEND CMAKE_PREFIX_PATH "${POLY_DIR}")
  90 endif()
  91 if(SYMFPU_DIR)
  92   list(APPEND CMAKE_PREFIX_PATH "${SYMFPU_DIR}")
  93 endif()
  94
  95 # By default the contrib/get-* scripts install dependencies to deps/install.
  96 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  97
  98 #-----------------------------------------------------------------------------#
  99
 100 include(Helpers)
 101
 102 #-----------------------------------------------------------------------------#
 103 # User options
 104
 105 # License
 106 option(ENABLE_GPL "Enable GPL dependencies")
 107
 108 # General build options
 109 #
 110 # >> 3-valued: IGNORE ON OFF
 111 #    > allows to detect if set by user (default: IGNORE)
 112 #    > only necessary for options set for build types
 113 cvc4_option(ENABLE_ASAN           "Enable ASAN build")
 114 cvc4_option(ENABLE_UBSAN          "Enable UBSan build")
 115 cvc4_option(ENABLE_TSAN           "Enable TSan build")
 116 cvc4_option(ENABLE_ASSERTIONS     "Enable assertions")
 117 cvc4_option(ENABLE_COMP_INC_TRACK
 118             "Enable optimizations for incremental SMT-COMP tracks")
 119 cvc4_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
 120 cvc4_option(ENABLE_DUMPING        "Enable dumping")
 121 cvc4_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
 122 cvc4_option(ENABLE_PROOFS         "Enable proof support")
 123 cvc4_option(ENABLE_STATISTICS     "Enable statistics")
 124 cvc4_option(ENABLE_TRACING        "Enable tracing")
 125 cvc4_option(ENABLE_UNIT_TESTING   "Enable unit testing")
 126 cvc4_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
 127 cvc4_option(ENABLE_SHARED         "Build as shared library")
 128 cvc4_option(ENABLE_STATIC_BINARY
 129             "Build static binaries with statically linked system libraries")
 130 # >> 2-valued: ON OFF
 131 #    > for options where we don't need to detect if set by user (default: OFF)
 132 option(ENABLE_BEST             "Enable dependencies known to give best performance")
 133 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
 134 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
 135 option(ENABLE_PROFILING        "Enable support for gprof profiling")
 136
 137 # Optional dependencies
 138 #
 139 # >> 3-valued: IGNORE ON OFF
 140 #    > allows to detect if set by user (default: IGNORE)
 141 #    > only necessary for options set for ENABLE_BEST
 142 cvc4_option(USE_ABC           "Use ABC for AIG bit-blasting")
 143 cvc4_option(USE_CADICAL       "Use CaDiCaL SAT solver")
 144 cvc4_option(USE_CLN           "Use CLN instead of GMP")
 145 cvc4_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 146 cvc4_option(USE_GLPK          "Use GLPK simplex solver")
 147 cvc4_option(USE_KISSAT        "Use Kissat SAT solver")
 148 cvc4_option(USE_EDITLINE      "Use Editline for better interactive support")
 149 # >> 2-valued: ON OFF
 150 #    > for options where we don't need to detect if set by user (default: OFF)
 151 option(USE_DRAT2ER            "Include drat2er for making eager BV proofs")
 152 option(USE_LFSC               "Use LFSC proof checker")
 153 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 154 option(USE_SYMFPU             "Use SymFPU for floating point support")
 155 option(USE_PYTHON2            "Prefer using Python 2 (for Python bindings)")
 156 option(USE_PYTHON3            "Prefer using Python 3 (for Python bindings)")
 157
 158 # Custom install directories for dependencies
 159 # If no directory is provided by the user, we first check if the dependency was
 160 # installed via the corresponding contrib/get-* script and if not found, we
 161 # check the intalled system version. If the user provides a directory we
 162 # immediately fail if the dependency was not found at the specified location.
 163 set(ABC_DIR           "" CACHE STRING "Set ABC install directory")
 164 set(ANTLR_DIR         "" CACHE STRING "Set ANTLR3 install directory")
 165 set(CADICAL_DIR       "" CACHE STRING "Set CaDiCaL install directory")
 166 set(CRYPTOMINISAT_DIR "" CACHE STRING "Set CryptoMiniSat install directory")
 167 set(CXXTEST_DIR       "" CACHE STRING "Set CxxTest install directory")
 168 set(DRAT2ER_DIR       "" CACHE STRING "Set drat2er install directory")
 169 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 170 set(GMP_DIR           "" CACHE STRING "Set GMP install directory")
 171 set(KISSAT_DIR        "" CACHE STRING "Set Kissat install directory")
 172 set(LFSC_DIR          "" CACHE STRING "Set LFSC install directory")
 173 set(POLY_DIR          "" CACHE STRING "Set LibPoly install directory")
 174 set(SYMFPU_DIR        "" CACHE STRING "Set SymFPU install directory")
 175
 176 # Prepend binaries with prefix on make install
 177 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 178
 179 # Supprted language bindings based on new C++ API
 180 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 181 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 182
 183 # Build limitations
 184 option(BUILD_LIB_ONLY         "Only build the library")
 185
 186 #-----------------------------------------------------------------------------#
 187 # Internal cmake variables
 188
 189 set(OPTIMIZATION_LEVEL 3)
 190 set(GPL_LIBS "")
 191
 192 #-----------------------------------------------------------------------------#
 193 # Determine number of threads available, used to configure (default) parallel
 194 # execution of custom test targets (can be overriden with ARGS=-jN).
 195
 196 include(ProcessorCount)
 197 ProcessorCount(CTEST_NTHREADS)
 198 if(CTEST_NTHREADS EQUAL 0)
 199   set(CTEST_NTHREADS 1)
 200 endif()
 201
 202 #-----------------------------------------------------------------------------#
 203 # Build types
 204
 205 # Note: Module CodeCoverage requires the name of the debug build to conform
 206 #       to cmake standards (first letter uppercase).
 207 set(BUILD_TYPES Production Debug Testing Competition)
 208
 209 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 210   set(CMAKE_BUILD_TYPE Debug)
 211 endif()
 212
 213 # Set the default build type to Production
 214 if(NOT CMAKE_BUILD_TYPE)
 215   set(CMAKE_BUILD_TYPE
 216       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 217   # Provide drop down menu options in cmake-gui
 218   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 219 endif()
 220
 221 # Check if specified build type is valid.
 222 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 223 if(${FOUND_BUILD_TYPE} EQUAL -1)
 224   message(FATAL_ERROR
 225     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 226     "Available builds are: ${BUILD_TYPES}")
 227 endif()
 228
 229 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 230 include(Config${CMAKE_BUILD_TYPE})
 231
 232 #-----------------------------------------------------------------------------#
 233 # Compiler flags
 234
 235 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 236 add_check_c_cxx_flag("-Wall")
 237 add_check_c_flag("-fexceptions")
 238 add_check_c_cxx_flag("-Wno-deprecated")
 239 add_check_cxx_flag("-Wsuggest-override")
 240 add_check_cxx_flag("-Wnon-virtual-dtor")
 241 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 242 add_check_c_cxx_flag("-Wshadow")
 243
 244 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 245 # cdlist.h warnings. Remove when fixed.
 246 add_check_cxx_flag("-Wno-class-memaccess")
 247
 248 if (WIN32)
 249   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 250 endif ()
 251
 252 #-----------------------------------------------------------------------------#
 253 # Use ld.gold if available
 254
 255 execute_process(COMMAND ${CMAKE_C_COMPILER}
 256                 -fuse-ld=gold
 257                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 258 if ("${LD_VERSION}" MATCHES "GNU gold")
 259   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 260   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 261   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 262   message(STATUS "Using GNU gold linker.")
 263 endif ()
 264
 265 #-----------------------------------------------------------------------------#
 266 # Option defaults (three-valued options (cvc4_option(...)))
 267 #
 268 # These options are only set if their value is IGNORE. Otherwise, the user
 269 # already set the option, which we don't want to overwrite.
 270
 271 if(ENABLE_STATIC_BINARY)
 272   cvc4_set_option(ENABLE_SHARED OFF)
 273 else()
 274   cvc4_set_option(ENABLE_SHARED ON)
 275 endif()
 276
 277 #-----------------------------------------------------------------------------#
 278 # Set options for best configuration
 279
 280 if(ENABLE_BEST)
 281   cvc4_set_option(USE_ABC ON)
 282   cvc4_set_option(USE_CADICAL ON)
 283   cvc4_set_option(USE_CLN ON)
 284   cvc4_set_option(USE_CRYPTOMINISAT ON)
 285   cvc4_set_option(USE_GLPK ON)
 286   cvc4_set_option(USE_EDITLINE ON)
 287 endif()
 288
 289 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 290 # that expect AssertionException to be thrown will fail.
 291 if(NOT ENABLE_ASSERTIONS)
 292   set(ENABLE_UNIT_TESTING OFF)
 293 endif()
 294
 295 #-----------------------------------------------------------------------------#
 296 # Shared/static libraries
 297 #
 298 # This needs to be set before any find_package(...) command since we want to
 299 # search for static libraries with suffix .a.
 300
 301 if(ENABLE_SHARED)
 302   set(BUILD_SHARED_LIBS ON)
 303   if(ENABLE_STATIC_BINARY)
 304     set(ENABLE_STATIC_BINARY OFF)
 305     message(WARNING "Disabling static binary since shared build is enabled.")
 306   endif()
 307
 308   # Embed the installation prefix as an RPATH in the executable such that the
 309   # linker can find our libraries (such as libcvc4parser) when executing the
 310   # cvc4 binary. This is for example useful when installing CVC4 with a custom
 311   # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 312   # we do not set this option, then the linker will not be able to find the
 313   # required libraries when trying to run CVC4.
 314   #
 315   # Also embed the installation prefix of the installed contrib libraries as an
 316   # RPATH. This allows to install a dynamically linked binary that depends on
 317   # dynamically linked libraries. This is dangerous, as the installed binary
 318   # breaks if the contrib library is removed or changes in other ways, we thus
 319   # print a big warning and only allow if installing to a custom installation
 320   # prefix.
 321   #
 322   # More information on RPATH in CMake:
 323   # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 324   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 325 else()
 326   # When building statically, we *only* want static archives/libraries
 327   if (WIN32)
 328       set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a)
 329   else()
 330       set(CMAKE_FIND_LIBRARY_SUFFIXES .a)
 331   endif()
 332   set(BUILD_SHARED_LIBS OFF)
 333   cvc4_set_option(ENABLE_STATIC_BINARY ON)
 334
 335   # Never build unit tests as static binaries, otherwise we'll end up with
 336   # ~300MB per unit test.
 337   if(ENABLE_UNIT_TESTING)
 338     message(WARNING "Disabling unit tests since static build is enabled.")
 339     set(ENABLE_UNIT_TESTING OFF)
 340   endif()
 341
 342   if (BUILD_BINDINGS_PYTHON)
 343     message(FATAL_ERROR "Building Python bindings is not possible "
 344                         "when building statically")
 345   endif()
 346 endif()
 347
 348 #-----------------------------------------------------------------------------#
 349 # Enable the ctest testing framework
 350
 351 # This needs to be enabled here rather than in subdirectory test in order to
 352 # allow calling ctest from the root build directory.
 353 enable_testing()
 354
 355 #-----------------------------------------------------------------------------#
 356 # Check GCC version.
 357 #
 358 # GCC version 4.5.1 builds MiniSat incorrectly with -O2, which results in
 359 # incorrect answers.
 360
 361 if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
 362   execute_process(
 363     COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
 364     OUTPUT_VARIABLE GCC_VERSION
 365     OUTPUT_STRIP_TRAILING_WHITESPACE)
 366   if(GCC_VERSION VERSION_EQUAL "4.5.1")
 367     message(FATAL_ERROR
 368       "GCC 4.5.1's optimizer is known to build MiniSat incorrectly "
 369       "(and by extension CVC4).")
 370   endif()
 371 endif()
 372
 373 #-----------------------------------------------------------------------------#
 374 # Check options, find packages and configure build.
 375
 376 if(USE_PYTHON2)
 377   find_package(PythonInterp 2.7 REQUIRED)
 378 elseif(USE_PYTHON3)
 379   find_package(PythonInterp 3 REQUIRED)
 380 else()
 381   find_package(PythonInterp REQUIRED)
 382 endif()
 383
 384 find_package(GMP REQUIRED)
 385
 386 if(ENABLE_ASAN)
 387   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 388   # otherwise the -fsanitize=address check will fail while linking.
 389   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 390   add_required_c_cxx_flag("-fsanitize=address")
 391   unset(CMAKE_REQUIRED_FLAGS)
 392   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 393   add_check_c_cxx_flag("-fsanitize-recover=address")
 394 endif()
 395
 396 if(ENABLE_UBSAN)
 397   add_required_c_cxx_flag("-fsanitize=undefined")
 398   add_definitions(-DCVC4_USE_UBSAN)
 399 endif()
 400
 401 if(ENABLE_TSAN)
 402   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 403   # otherwise the -fsanitize=thread check will fail while linking.
 404   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 405   add_required_c_cxx_flag("-fsanitize=thread")
 406   unset(CMAKE_REQUIRED_FLAGS)
 407 endif()
 408
 409 if(ENABLE_ASSERTIONS)
 410   add_definitions(-DCVC4_ASSERTIONS)
 411 else()
 412   add_definitions(-DNDEBUG)
 413 endif()
 414
 415 if(ENABLE_COVERAGE)
 416   include(CodeCoverage)
 417   APPEND_COVERAGE_COMPILER_FLAGS()
 418   add_definitions(-DCVC4_COVERAGE)
 419   # Note: The ctest command returns a non-zero exit code if tests fail or run
 420   # into a timeout. As a consequence, the coverage report is not generated. To
 421   # prevent this we always return with exit code 0 after the ctest command has
 422   # finished.
 423   setup_target_for_coverage_gcovr_html(
 424     NAME coverage
 425     EXECUTABLE
 426       ctest -j${CTEST_NTHREADS} -LE "example"
 427         --output-on-failure $$ARGS || exit 0
 428     DEPENDS
 429       build-tests)
 430 endif()
 431
 432 if(ENABLE_DEBUG_CONTEXT_MM)
 433   add_definitions(-DCVC4_DEBUG_CONTEXT_MEMORY_MANAGER)
 434 endif()
 435
 436 if(ENABLE_DEBUG_SYMBOLS)
 437   add_check_c_cxx_flag("-ggdb3")
 438 endif()
 439
 440 if(ENABLE_COMP_INC_TRACK)
 441   add_definitions(-DCVC4_SMTCOMP_APPLICATION_TRACK)
 442 endif()
 443
 444 if(ENABLE_MUZZLE)
 445   add_definitions(-DCVC4_MUZZLE)
 446 endif()
 447
 448 if(ENABLE_DUMPING)
 449   add_definitions(-DCVC4_DUMPING)
 450 endif()
 451
 452 if(ENABLE_PROFILING)
 453   add_definitions(-DCVC4_PROFILING)
 454   add_check_c_cxx_flag("-pg")
 455 endif()
 456
 457 if(ENABLE_PROOFS)
 458   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --enable-proof)
 459   add_definitions(-DCVC4_PROOF)
 460 endif()
 461
 462 if(ENABLE_TRACING)
 463   add_definitions(-DCVC4_TRACING)
 464 endif()
 465
 466 if(ENABLE_STATISTICS)
 467   add_definitions(-DCVC4_STATISTICS_ON)
 468 endif()
 469
 470 if(ENABLE_VALGRIND)
 471   find_package(Valgrind REQUIRED)
 472   add_definitions(-DCVC4_VALGRIND)
 473 endif()
 474
 475 if(USE_ABC)
 476   find_package(ABC REQUIRED)
 477   add_definitions(-DCVC4_USE_ABC ${ABC_ARCH_FLAGS})
 478 endif()
 479
 480 if(USE_CADICAL)
 481   find_package(CaDiCaL REQUIRED)
 482   add_definitions(-DCVC4_USE_CADICAL)
 483 endif()
 484
 485 if(USE_CLN)
 486   set(GPL_LIBS "${GPL_LIBS} cln")
 487   find_package(CLN 1.2.2 REQUIRED)
 488   set(CVC4_USE_CLN_IMP 1)
 489   set(CVC4_USE_GMP_IMP 0)
 490 else()
 491   set(CVC4_USE_CLN_IMP 0)
 492   set(CVC4_USE_GMP_IMP 1)
 493 endif()
 494
 495 if(USE_CRYPTOMINISAT)
 496   # CryptoMiniSat requires pthreads support
 497   set(THREADS_PREFER_PTHREAD_FLAG ON)
 498   find_package(Threads REQUIRED)
 499   if(THREADS_HAVE_PTHREAD_ARG)
 500     add_c_cxx_flag(-pthread)
 501   endif()
 502   find_package(CryptoMiniSat REQUIRED)
 503   add_definitions(-DCVC4_USE_CRYPTOMINISAT)
 504 endif()
 505
 506 if(USE_DRAT2ER)
 507   find_package(Drat2Er REQUIRED)
 508   add_definitions(-DCVC4_USE_DRAT2ER)
 509 endif()
 510
 511 if(USE_GLPK)
 512   set(GPL_LIBS "${GPL_LIBS} glpk")
 513   find_package(GLPK REQUIRED)
 514   add_definitions(-DCVC4_USE_GLPK)
 515 endif()
 516
 517 if(USE_KISSAT)
 518   find_package(Kissat REQUIRED)
 519   add_definitions(-DCVC4_USE_KISSAT)
 520 endif()
 521
 522 if(USE_LFSC)
 523   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --with-lfsc)
 524   find_package(LFSC REQUIRED)
 525   add_definitions(-DCVC4_USE_LFSC)
 526 endif()
 527
 528 if(USE_POLY)
 529   find_package(Poly REQUIRED)
 530   add_definitions(-DCVC4_USE_POLY)
 531   set(CVC4_USE_POLY_IMP 1)
 532 else()
 533   set(CVC4_USE_POLY_IMP 0)
 534 endif()
 535
 536 if(USE_EDITLINE)
 537   find_package(Editline REQUIRED)
 538   set(HAVE_LIBEDITLINE 1)
 539   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 540     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 541   endif()
 542 endif()
 543
 544 if(USE_SYMFPU)
 545   find_package(SymFPU REQUIRED)
 546   add_definitions(-DCVC4_USE_SYMFPU)
 547   set(CVC4_USE_SYMFPU 1)
 548 else()
 549   set(CVC4_USE_SYMFPU 0)
 550 endif()
 551
 552 if(GPL_LIBS)
 553   if(NOT ENABLE_GPL)
 554     message(FATAL_ERROR
 555       "Bad configuration detected: BSD-licensed code only, but also requested "
 556       "GPLed libraries: ${GPL_LIBS}")
 557   endif()
 558   set(CVC4_GPL_DEPS 1)
 559 endif()
 560
 561 #-----------------------------------------------------------------------------#
 562 # Generate CVC4's cvc4autoconfig.h header
 563
 564 include(ConfigureCVC4)
 565 if(NOT ENABLE_SHARED)
 566   set(CVC4_STATIC_BUILD ON)
 567 endif()
 568 configure_file(cvc4autoconfig.h.in cvc4autoconfig.h)
 569 unset(CVC4_STATIC_BUILD)
 570 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 571
 572 #-----------------------------------------------------------------------------#
 573 # Add subdirectories
 574
 575 # signatures needs to come before src since it adds source files to libcvc4.
 576 if(ENABLE_PROOFS)
 577   add_subdirectory(proofs/signatures)
 578 endif()
 579
 580 add_subdirectory(doc)
 581 add_subdirectory(src)
 582 add_subdirectory(test)
 583
 584 if(BUILD_BINDINGS_PYTHON)
 585   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 586   add_subdirectory(src/api/python)
 587 endif()
 588
 589 if(BUILD_BINDINGS_JAVA)
 590   message(FATAL_ERROR
 591     "Java bindings for the new API are not implemented yet.")
 592 endif()
 593
 594 #-----------------------------------------------------------------------------#
 595 # Package configuration
 596 #
 597 # Export CVC4 targets to support find_package(CVC4) in other cmake projects.
 598
 599 include(CMakePackageConfigHelpers)
 600
 601 # If we install a dynamically linked binary that also uses dynamically used
 602 # libraries from deps/install/lib, we need to be cautious. Changing these
 603 # shared libraries from deps/install/lib most probably breaks the binary.
 604 # We only allow such an installation for custom installation prefixes
 605 # (in the assumption that only reasonably experienced users use this and
 606 # also that custom installation prefixes are not used for longer periods of
 607 # time anyway). Also, we print a big warning with further instructions.
 608 if(NOT ENABLE_STATIC_BINARY)
 609   # Get the libraries that cvc4 links against
 610   get_target_property(libs cvc4 INTERFACE_LINK_LIBRARIES)
 611   set(LIBS_SHARED_FROM_DEPS "")
 612   foreach(lib ${libs})
 613     # Filter out those that are linked dynamically and come from deps/install
 614     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 615       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 616     endif()
 617   endforeach()
 618   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 619   # Check if we actually use such "dangerous" libraries
 620   if(list_len GREATER 0)
 621     # Print a generic warning
 622     install(CODE "message(WARNING \"You are installing a dynamically linked \
 623     binary of CVC4 which may be a problem if you are using any dynamically \
 624     linked third-party library that you obtained through one of the \
 625     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 626     locally, hence executing such a contrib script removing the \
 627     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 628     Consider installing the dynamically linked dependencies on your system \
 629     manually or link cvc4 statically.\")")
 630     # Print the libraries in question
 631     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 632       install(CODE "message(WARNING \"The following library is used by the cvc4 binary: ${lib}\")")
 633     endforeach()
 634     # Check if we use a custom installation prefix
 635     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 636       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 637       soon-to-be-broken binary, system-wide installation is disabled if the \
 638       binary depends on locally-built shared libraries.\")")
 639     else()
 640       install(CODE "message(WARNING \"You have selected a custom install \
 641       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 642       previous warning and know what you are doing.\")")
 643     endif()
 644   endif()
 645 endif()
 646
 647 install(EXPORT cvc4-targets
 648   FILE CVC4Targets.cmake
 649   NAMESPACE CVC4::
 650   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4)
 651
 652 configure_package_config_file(
 653   ${CMAKE_SOURCE_DIR}/cmake/CVC4Config.cmake.in
 654   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 655   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4
 656   PATH_VARS CMAKE_INSTALL_LIBDIR
 657 )
 658
 659 write_basic_package_version_file(
 660   ${CMAKE_CURRENT_BINARY_DIR}/CVC4ConfigVersion.cmake
 661   VERSION ${CVC4_RELEASE_STRING}
 662   COMPATIBILITY ExactVersion
 663 )
 664
 665 install(FILES
 666   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 667   ${CMAKE_BINARY_DIR}/CVC4ConfigVersion.cmake
 668   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4
 669 )
 670
 671
 672 #-----------------------------------------------------------------------------#
 673 # Print build configuration
 674
 675 # Convert build type to lower case.
 676 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC4_BUILD_PROFILE_STRING)
 677
 678 # Get all definitions added via add_definitions.
 679 get_directory_property(CVC4_DEFINITIONS COMPILE_DEFINITIONS)
 680 string(REPLACE ";" " " CVC4_DEFINITIONS "${CVC4_DEFINITIONS}")
 681
 682 message("CVC4 ${CVC4_RELEASE_STRING}")
 683 message("")
 684 if(ENABLE_COMP_INC_TRACK)
 685   message("Build profile             : ${CVC4_BUILD_PROFILE_STRING} (incremental)")
 686 else()
 687   message("Build profile             : ${CVC4_BUILD_PROFILE_STRING}")
 688 endif()
 689 message("")
 690 print_config("GPL                       :" ENABLE_GPL)
 691 print_config("Best configuration        :" ENABLE_BEST)
 692 print_config("Optimization level        :" OPTIMIZATION_LEVEL)
 693 message("")
 694 print_config("Assertions                :" ENABLE_ASSERTIONS)
 695 print_config("Debug symbols             :" ENABLE_DEBUG_SYMBOLS)
 696 print_config("Debug context mem mgr     :" ENABLE_DEBUG_CONTEXT_MM)
 697 message("")
 698 print_config("Dumping                   :" ENABLE_DUMPING)
 699 print_config("Muzzle                    :" ENABLE_MUZZLE)
 700 print_config("Proofs                    :" ENABLE_PROOFS)
 701 print_config("Statistics                :" ENABLE_STATISTICS)
 702 print_config("Tracing                   :" ENABLE_TRACING)
 703 message("")
 704 print_config("ASan                      :" ENABLE_ASAN)
 705 print_config("UBSan                     :" ENABLE_UBSAN)
 706 print_config("TSan                      :" ENABLE_TSAN)
 707 print_config("Coverage (gcov)           :" ENABLE_COVERAGE)
 708 print_config("Profiling (gprof)         :" ENABLE_PROFILING)
 709 print_config("Unit tests                :" ENABLE_UNIT_TESTING)
 710 print_config("Valgrind                  :" ENABLE_VALGRIND)
 711 message("")
 712 print_config("Shared libs               :" ENABLE_SHARED)
 713 print_config("Static binary             :" ENABLE_STATIC_BINARY)
 714 print_config("Python bindings           :" BUILD_BINDINGS_PYTHON)
 715 print_config("Java bindings             :" BUILD_BINDINGS_JAVA)
 716 print_config("Python2                   :" USE_PYTHON2)
 717 print_config("Python3                   :" USE_PYTHON3)
 718 message("")
 719 print_config("ABC                       :" USE_ABC)
 720 print_config("CaDiCaL                   :" USE_CADICAL)
 721 print_config("CryptoMiniSat             :" USE_CRYPTOMINISAT)
 722 print_config("drat2er                   :" USE_DRAT2ER)
 723 print_config("GLPK                      :" USE_GLPK)
 724 print_config("Kissat                    :" USE_KISSAT)
 725 print_config("LFSC                      :" USE_LFSC)
 726 print_config("LibPoly                   :" USE_POLY)
 727 message("")
 728 print_config("BUILD_LIB_ONLY            :" BUILD_LIB_ONLY)
 729
 730 if(CVC4_USE_CLN_IMP)
 731   message("MP library                : cln")
 732 else()
 733   message("MP library                : gmp")
 734 endif()
 735 print_config("Editline                  :" ${USE_EDITLINE})
 736 print_config("SymFPU                    :" ${USE_SYMFPU})
 737 message("")
 738 if(ABC_DIR)
 739   message("ABC dir                   : ${ABC_DIR}")
 740 endif()
 741 if(ANTLR_DIR)
 742   message("ANTLR dir                 : ${ANTLR_DIR}")
 743 endif()
 744 if(CADICAL_DIR)
 745   message("CADICAL dir               : ${CADICAL_DIR}")
 746 endif()
 747 if(CRYPTOMINISAT_DIR)
 748   message("CRYPTOMINISAT dir         : ${CRYPTOMINISAT_DIR}")
 749 endif()
 750 if(DRAT2ER_DIR)
 751   message("DRAT2ER dir               : ${DRAT2ER_DIR}")
 752 endif()
 753 if(GLPK_DIR)
 754   message("GLPK dir                  : ${GLPK_DIR}")
 755 endif()
 756 if(GMP_DIR)
 757   message("GMP dir                   : ${GMP_DIR}")
 758 endif()
 759 if(KISSAT_DIR)
 760   message("KISSAT dir                : ${KISSAT_DIR}")
 761 endif()
 762 if(LFSC_DIR)
 763   message("LFSC dir                  : ${LFSC_DIR}")
 764 endif()
 765 if(POLY_DIR)
 766   message("LibPoly dir               : ${POLY_DIR}")
 767 endif()
 768 if(SYMFPU_DIR)
 769   message("SYMFPU dir                : ${SYMFPU_DIR}")
 770 endif()
 771 message("")
 772 message("CPPLAGS (-D...)           : ${CVC4_DEFINITIONS}")
 773 message("CXXFLAGS                  : ${CMAKE_CXX_FLAGS}")
 774 message("CFLAGS                    : ${CMAKE_C_FLAGS}")
 775 message("Linker flags              : ${CMAKE_EXE_LINKER_FLAGS}")
 776 message("")
 777 message("Install prefix            : ${CMAKE_INSTALL_PREFIX}")
 778 message("")
 779
 780 if(GPL_LIBS)
 781   message(
 782   "CVC4 license             : ${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 783   "\n"
 784   "\n"
 785   "Please note that CVC4 will be built against the following GPLed libraries:"
 786   "\n"
 787   "${GPL_LIBS}"
 788   "\n"
 789   "As these libraries are covered under the GPLv3, so is this build of CVC4."
 790   "\n"
 791   "CVC4 is also available to you under the terms of the (modified) BSD license."
 792   "\n"
 793   "If you prefer to license CVC4 under those terms, please configure CVC4 to"
 794   "\n"
 795   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 796   )
 797 else()
 798   message(
 799   "CVC4 license              : modified BSD"
 800   "\n"
 801   "\n"
 802   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 803   "\n"
 804   "it is covered by the (modified) BSD license.  This is, however, not the best"
 805   "\n"
 806   "performing configuration of CVC4.  To build against GPL'ed libraries which"
 807   "\n"
 808   "improve CVC4's performance, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 809   )
 810 endif()
 811
 812 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 813   set(BUILD_COMMAND_NAME "ninja")
 814 else()
 815   set(BUILD_COMMAND_NAME "make")
 816 endif()
 817
 818 message("")
 819 message("Now just type '${BUILD_COMMAND_NAME}', "
 820         "followed by '${BUILD_COMMAND_NAME} check' "
 821         "or '${BUILD_COMMAND_NAME} install'.")
 822 message("")