CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.2)
   2
   3 #-----------------------------------------------------------------------------#
   4 # Project configuration
   5
   6 project(cvc4)
   7
   8 set(CVC4_MAJOR   1) # Major component of the version of CVC4.
   9 set(CVC4_MINOR   8) # Minor component of the version of CVC4.
  10 set(CVC4_RELEASE 0) # Release component of the version of CVC4.
  11
  12 # Extraversion component of the version of CVC4.
  13 set(CVC4_EXTRAVERSION "-prerelease")
  14
  15 # Shared library versioning. Increment SOVERSION for every new CVC4 release.
  16 set(CVC4_SOVERSION 6)
  17
  18 # Full release string for CVC4.
  19 if(CVC4_RELEASE)
  20   set(CVC4_RELEASE_STRING
  21       "${CVC4_MAJOR}.${CVC4_MINOR}.${CVC4_RELEASE}${CVC4_EXTRAVERSION}")
  22 else()
  23   set(CVC4_RELEASE_STRING "${CVC4_MAJOR}.${CVC4_MINOR}${CVC4_EXTRAVERSION}")
  24 endif()
  25
  26 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  27 set(CMAKE_C_STANDARD 99)
  28 set(CMAKE_CXX_STANDARD 11)
  29 set(CMAKE_CXX_EXTENSIONS OFF)
  30
  31 # Generate compile_commands.json, which can be used for various code completion
  32 # plugins.
  33 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  34
  35 #-----------------------------------------------------------------------------#
  36 # Policies
  37
  38 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  39 if(POLICY CMP0075)
  40   cmake_policy(SET CMP0075 NEW)
  41 endif()
  42
  43 #-----------------------------------------------------------------------------#
  44 # Tell CMake where to find our dependencies
  45
  46 if(ABC_DIR)
  47   list(APPEND CMAKE_PREFIX_PATH "${ABC_DIR}")
  48 endif()
  49 if(ANTLR_DIR)
  50   list(APPEND CMAKE_PREFIX_PATH "${ANTLR_DIR}")
  51 endif()
  52 if(CADICAL_DIR)
  53   list(APPEND CMAKE_PREFIX_PATH "${CADICAL_DIR}")
  54 endif()
  55 if(CRYPTOMINISAT_DIR)
  56   list(APPEND CMAKE_PREFIX_PATH "${CRYPTOMINISAT_DIR}")
  57 endif()
  58 if(CXXTEST_DIR)
  59   list(APPEND CMAKE_PREFIX_PATH "${CXXTEST_DIR}")
  60 endif()
  61 if(DRAT2ER_DIR)
  62   list(APPEND CMAKE_PREFIX_PATH "${DRAT2ER_DIR}")
  63 endif()
  64 if(GLPK_DIR)
  65   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  66 endif()
  67 if(GMP_DIR)
  68   list(APPEND CMAKE_PREFIX_PATH "${GMP_DIR}")
  69 endif()
  70 if(LFSC_DIR)
  71   list(APPEND CMAKE_PREFIX_PATH "${LFSC_DIR}")
  72 endif()
  73 if(SYMFPU_DIR)
  74   list(APPEND CMAKE_PREFIX_PATH "${SYMFPU_DIR}")
  75 endif()
  76
  77 # By default the contrib/get-* scripts install dependencies to deps/install.
  78 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  79
  80 #-----------------------------------------------------------------------------#
  81
  82 set(INCLUDE_INSTALL_DIR include)
  83 set(LIBRARY_INSTALL_DIR lib)
  84 set(RUNTIME_INSTALL_DIR bin)
  85
  86 #-----------------------------------------------------------------------------#
  87
  88 # Embed the installation prefix as an RPATH in the executable such that the
  89 # linker can find our libraries (such as libcvc4parser) when executing the cvc4
  90 # binary. This is for example useful when installing CVC4 with a custom prefix
  91 # on macOS (e.g. when using homebrew in a non-standard directory). If we do not
  92 # set this option, then the linker will not be able to find the required
  93 # libraries when trying to run CVC4.
  94 #
  95 # More information on RPATH in CMake:
  96 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
  97 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${LIBRARY_INSTALL_DIR}")
  98
  99 #-----------------------------------------------------------------------------#
 100
 101 include(Helpers)
 102
 103 #-----------------------------------------------------------------------------#
 104 # User options
 105
 106 # License
 107 option(ENABLE_GPL "Enable GPL dependencies")
 108
 109 # General build options
 110 #
 111 # >> 3-valued: IGNORE ON OFF
 112 #    > allows to detect if set by user (default: IGNORE)
 113 #    > only necessary for options set for build types
 114 cvc4_option(ENABLE_ASAN           "Enable ASAN build")
 115 cvc4_option(ENABLE_UBSAN          "Enable UBSan build")
 116 cvc4_option(ENABLE_TSAN           "Enable TSan build")
 117 cvc4_option(ENABLE_ASSERTIONS     "Enable assertions")
 118 cvc4_option(ENABLE_COMP_INC_TRACK
 119             "Enable optimizations for incremental SMT-COMP tracks")
 120 cvc4_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
 121 cvc4_option(ENABLE_DUMPING        "Enable dumping")
 122 cvc4_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
 123 cvc4_option(ENABLE_PROOFS         "Enable proof support")
 124 cvc4_option(ENABLE_REPLAY         "Enable the replay feature")
 125 cvc4_option(ENABLE_STATISTICS     "Enable statistics")
 126 cvc4_option(ENABLE_TRACING        "Enable tracing")
 127 cvc4_option(ENABLE_UNIT_TESTING   "Enable unit testing")
 128 cvc4_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
 129 cvc4_option(ENABLE_SHARED         "Build as shared library")
 130 cvc4_option(ENABLE_STATIC_BINARY
 131             "Build static binaries with statically linked system libraries")
 132 # >> 2-valued: ON OFF
 133 #    > for options where we don't need to detect if set by user (default: OFF)
 134 option(ENABLE_BEST             "Enable dependencies known to give best performance")
 135 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
 136 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
 137 option(ENABLE_PROFILING        "Enable support for gprof profiling")
 138
 139 # Optional dependencies
 140 #
 141 # >> 3-valued: IGNORE ON OFF
 142 #    > allows to detect if set by user (default: IGNORE)
 143 #    > only necessary for options set for ENABLE_BEST
 144 cvc4_option(USE_ABC           "Use ABC for AIG bit-blasting")
 145 cvc4_option(USE_CADICAL       "Use CaDiCaL SAT solver")
 146 cvc4_option(USE_CLN           "Use CLN instead of GMP")
 147 cvc4_option(USE_GLPK          "Use GLPK simplex solver")
 148 cvc4_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 149 cvc4_option(USE_READLINE      "Use readline for better interactive support")
 150 # >> 2-valued: ON OFF
 151 #    > for options where we don't need to detect if set by user (default: OFF)
 152 option(USE_DRAT2ER            "Include drat2er for making eager BV proofs")
 153 option(USE_LFSC               "Use LFSC proof checker")
 154 option(USE_SYMFPU             "Use SymFPU for floating point support")
 155 option(USE_PYTHON2            "Prefer using Python 2 (for Python bindings)")
 156 option(USE_PYTHON3            "Prefer using Python 3 (for Python bindings)")
 157
 158 # Custom install directories for dependencies
 159 # If no directory is provided by the user, we first check if the dependency was
 160 # installed via the corresponding contrib/get-* script and if not found, we
 161 # check the intalled system version. If the user provides a directory we
 162 # immediately fail if the dependency was not found at the specified location.
 163 set(ABC_DIR           "" CACHE STRING "Set ABC install directory")
 164 set(ANTLR_DIR         "" CACHE STRING "Set ANTLR3 install directory")
 165 set(CADICAL_DIR       "" CACHE STRING "Set CaDiCaL install directory")
 166 set(CRYPTOMINISAT_DIR "" CACHE STRING "Set CryptoMiniSat install directory")
 167 set(CXXTEST_DIR       "" CACHE STRING "Set CxxTest install directory")
 168 set(DRAT2ER_DIR       "" CACHE STRING "Set drat2er install directory")
 169 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 170 set(GMP_DIR           "" CACHE STRING "Set GMP install directory")
 171 set(LFSC_DIR          "" CACHE STRING "Set LFSC install directory")
 172 set(SYMFPU_DIR        "" CACHE STRING "Set SymFPU install directory")
 173
 174 # Prepend binaries with prefix on make install
 175 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 176
 177 # Supported SWIG language bindings
 178 option(BUILD_SWIG_BINDINGS_JAVA   "Build Java bindings with SWIG")
 179 option(BUILD_SWIG_BINDINGS_PYTHON "Build Python bindings with SWIG")
 180
 181 # Supprted language bindings based on new C++ API
 182 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 183
 184 #-----------------------------------------------------------------------------#
 185 # Internal cmake variables
 186
 187 set(OPTIMIZATION_LEVEL 3)
 188 set(GPL_LIBS "")
 189
 190 #-----------------------------------------------------------------------------#
 191 # Determine number of threads available, used to configure (default) parallel
 192 # execution of custom test targets (can be overriden with ARGS=-jN).
 193
 194 include(ProcessorCount)
 195 ProcessorCount(CTEST_NTHREADS)
 196 if(CTEST_NTHREADS EQUAL 0)
 197   set(CTEST_NTHREADS 1)
 198 endif()
 199
 200 #-----------------------------------------------------------------------------#
 201 # Build types
 202
 203 # Note: Module CodeCoverage requires the name of the debug build to conform
 204 #       to cmake standards (first letter uppercase).
 205 set(BUILD_TYPES Production Debug Testing Competition)
 206
 207 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 208   set(CMAKE_BUILD_TYPE Debug)
 209 endif()
 210
 211 # Set the default build type to Production
 212 if(NOT CMAKE_BUILD_TYPE)
 213   set(CMAKE_BUILD_TYPE
 214       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 215   # Provide drop down menu options in cmake-gui
 216   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 217 endif()
 218
 219 # Check if specified build type is valid.
 220 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 221 if(${FOUND_BUILD_TYPE} EQUAL -1)
 222   message(FATAL_ERROR
 223     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 224     "Available builds are: ${BUILD_TYPES}")
 225 endif()
 226
 227 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 228 include(Config${CMAKE_BUILD_TYPE})
 229
 230 #-----------------------------------------------------------------------------#
 231 # Compiler flags
 232
 233 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 234 add_check_c_cxx_flag("-Wall")
 235 add_check_c_flag("-fexceptions")
 236 add_check_c_cxx_flag("-Wno-deprecated")
 237 add_check_cxx_flag("-Wsuggest-override")
 238 add_check_cxx_flag("-Wnon-virtual-dtor")
 239 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 240 add_check_c_cxx_flag("-Wshadow")
 241
 242 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 243 # cdlist.h warnings. Remove when fixed.
 244 add_check_cxx_flag("-Wno-class-memaccess")
 245
 246 #-----------------------------------------------------------------------------#
 247 # Use ld.gold if available
 248
 249 execute_process(COMMAND ${CMAKE_C_COMPILER}
 250                 -fuse-ld=gold
 251                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 252 if ("${LD_VERSION}" MATCHES "GNU gold")
 253   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 254   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 255   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 256   message(STATUS "Using GNU gold linker.")
 257 endif ()
 258
 259 #-----------------------------------------------------------------------------#
 260 # Option defaults (three-valued options (cvc4_option(...)))
 261 #
 262 # These options are only set if their value is IGNORE. Otherwise, the user
 263 # already set the option, which we don't want to overwrite.
 264
 265 if(ENABLE_STATIC_BINARY)
 266   cvc4_set_option(ENABLE_SHARED OFF)
 267 else()
 268   cvc4_set_option(ENABLE_SHARED ON)
 269 endif()
 270
 271 #-----------------------------------------------------------------------------#
 272 # Set options for best configuration
 273
 274 if(ENABLE_BEST)
 275   cvc4_set_option(USE_ABC ON)
 276   cvc4_set_option(USE_CADICAL ON)
 277   cvc4_set_option(USE_CLN ON)
 278   cvc4_set_option(USE_CRYPTOMINISAT ON)
 279   cvc4_set_option(USE_GLPK ON)
 280   cvc4_set_option(USE_READLINE ON)
 281 endif()
 282
 283 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 284 # that expect AssertionException to be thrown will fail.
 285 if(NOT ENABLE_ASSERTIONS)
 286   set(ENABLE_UNIT_TESTING OFF)
 287 endif()
 288
 289 #-----------------------------------------------------------------------------#
 290 # Shared/static libraries
 291 #
 292 # This needs to be set before any find_package(...) command since we want to
 293 # search for static libraries with suffix .a.
 294
 295 if(ENABLE_SHARED)
 296   set(BUILD_SHARED_LIBS ON)
 297   if(ENABLE_STATIC_BINARY)
 298     set(ENABLE_STATIC_BINARY OFF)
 299     message(WARNING "Disabling static binary since shared build is enabled.")
 300   endif()
 301 else()
 302   set(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 303   set(BUILD_SHARED_LIBS OFF)
 304   cvc4_set_option(ENABLE_STATIC_BINARY ON)
 305
 306   # Never build unit tests as static binaries, otherwise we'll end up with
 307   # ~300MB per unit test.
 308   if(ENABLE_UNIT_TESTING)
 309     message(WARNING "Disabling unit tests since static build is enabled.")
 310     set(ENABLE_UNIT_TESTING OFF)
 311   endif()
 312 endif()
 313
 314 #-----------------------------------------------------------------------------#
 315 # Enable the ctest testing framework
 316
 317 # This needs to be enabled here rather than in subdirectory test in order to
 318 # allow calling ctest from the root build directory.
 319 enable_testing()
 320
 321 #-----------------------------------------------------------------------------#
 322 # Check GCC version.
 323 #
 324 # GCC version 4.5.1 builds MiniSat incorrectly with -O2, which results in
 325 # incorrect answers.
 326
 327 if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
 328   execute_process(
 329     COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
 330     OUTPUT_VARIABLE GCC_VERSION
 331     OUTPUT_STRIP_TRAILING_WHITESPACE)
 332   if(GCC_VERSION VERSION_EQUAL "4.5.1")
 333     message(FATAL_ERROR
 334       "GCC 4.5.1's optimizer is known to build MiniSat incorrectly "
 335       "(and by extension CVC4).")
 336   endif()
 337 endif()
 338
 339 #-----------------------------------------------------------------------------#
 340 # Check options, find packages and configure build.
 341
 342 if(USE_PYTHON2)
 343   find_package(PythonInterp 2.7 REQUIRED)
 344 elseif(USE_PYTHON3)
 345   find_package(PythonInterp 3 REQUIRED)
 346 else()
 347   find_package(PythonInterp REQUIRED)
 348 endif()
 349
 350 find_package(GMP REQUIRED)
 351
 352 if(ENABLE_ASAN)
 353   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 354   # otherwise the -fsanitize=address check will fail while linking.
 355   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 356   add_required_c_cxx_flag("-fsanitize=address")
 357   unset(CMAKE_REQUIRED_FLAGS)
 358   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 359   add_check_c_cxx_flag("-fsanitize-recover=address")
 360 endif()
 361
 362 if(ENABLE_UBSAN)
 363   add_required_c_cxx_flag("-fsanitize=undefined")
 364   add_definitions(-DCVC4_USE_UBSAN)
 365 endif()
 366
 367 if(ENABLE_TSAN)
 368   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 369   # otherwise the -fsanitize=thread check will fail while linking.
 370   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 371   add_required_c_cxx_flag("-fsanitize=thread")
 372   unset(CMAKE_REQUIRED_FLAGS)
 373 endif()
 374
 375 if(ENABLE_ASSERTIONS)
 376   add_definitions(-DCVC4_ASSERTIONS)
 377 else()
 378   add_definitions(-DNDEBUG)
 379 endif()
 380
 381 if(ENABLE_COVERAGE)
 382   include(CodeCoverage)
 383   APPEND_COVERAGE_COMPILER_FLAGS()
 384   add_definitions(-DCVC4_COVERAGE)
 385   # Note: The ctest command returns a non-zero exit code if tests fail or run
 386   # into a timeout. As a consequence, the coverage report is not generated. To
 387   # prevent this we always return with exit code 0 after the ctest command has
 388   # finished.
 389   setup_target_for_coverage_gcovr_html(
 390     NAME coverage
 391     EXECUTABLE
 392       ctest -j${CTEST_NTHREADS} -LE "example"
 393         --output-on-failure $$ARGS || exit 0
 394     DEPENDS
 395       build-tests)
 396 endif()
 397
 398 if(ENABLE_DEBUG_CONTEXT_MM)
 399   add_definitions(-DCVC4_DEBUG_CONTEXT_MEMORY_MANAGER)
 400 endif()
 401
 402 if(ENABLE_DEBUG_SYMBOLS)
 403   add_check_c_cxx_flag("-ggdb3")
 404 endif()
 405
 406 if(ENABLE_COMP_INC_TRACK)
 407   add_definitions(-DCVC4_SMTCOMP_APPLICATION_TRACK)
 408 endif()
 409
 410 if(ENABLE_MUZZLE)
 411   add_definitions(-DCVC4_MUZZLE)
 412 endif()
 413
 414 if(ENABLE_DUMPING)
 415   add_definitions(-DCVC4_DUMPING)
 416 endif()
 417
 418 if(ENABLE_PROFILING)
 419   add_definitions(-DCVC4_PROFILING)
 420   add_check_c_cxx_flag("-pg")
 421 endif()
 422
 423 if(ENABLE_PROOFS)
 424   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --enable-proof)
 425   add_definitions(-DCVC4_PROOF)
 426 endif()
 427
 428 if(ENABLE_REPLAY)
 429   add_definitions(-DCVC4_REPLAY)
 430 endif()
 431
 432 if(ENABLE_TRACING)
 433   add_definitions(-DCVC4_TRACING)
 434 endif()
 435
 436 if(ENABLE_STATISTICS)
 437   add_definitions(-DCVC4_STATISTICS_ON)
 438 endif()
 439
 440 if(ENABLE_VALGRIND)
 441   find_package(Valgrind REQUIRED)
 442   add_definitions(-DCVC4_VALGRIND)
 443 endif()
 444
 445 if(USE_ABC)
 446   find_package(ABC REQUIRED)
 447   add_definitions(-DCVC4_USE_ABC ${ABC_ARCH_FLAGS})
 448 endif()
 449
 450 if(USE_CADICAL)
 451   find_package(CaDiCaL REQUIRED)
 452   add_definitions(-DCVC4_USE_CADICAL)
 453 endif()
 454
 455 if(USE_CLN)
 456   set(GPL_LIBS "${GPL_LIBS} cln")
 457   find_package(CLN 1.2.2 REQUIRED)
 458   set(CVC4_USE_CLN_IMP 1)
 459   set(CVC4_USE_GMP_IMP 0)
 460 else()
 461   set(CVC4_USE_CLN_IMP 0)
 462   set(CVC4_USE_GMP_IMP 1)
 463 endif()
 464
 465 if(USE_CRYPTOMINISAT)
 466   # CryptoMiniSat requires pthreads support
 467   set(THREADS_PREFER_PTHREAD_FLAG ON)
 468   find_package(Threads REQUIRED)
 469   if(THREADS_HAVE_PTHREAD_ARG)
 470     add_c_cxx_flag(-pthread)
 471   endif()
 472   find_package(CryptoMiniSat REQUIRED)
 473   add_definitions(-DCVC4_USE_CRYPTOMINISAT)
 474 endif()
 475
 476 if(USE_DRAT2ER)
 477   find_package(Drat2Er REQUIRED)
 478   add_definitions(-DCVC4_USE_DRAT2ER)
 479 endif()
 480
 481 if(USE_GLPK)
 482   set(GPL_LIBS "${GPL_LIBS} glpk")
 483   find_package(GLPK REQUIRED)
 484   add_definitions(-DCVC4_USE_GLPK)
 485 endif()
 486
 487 if(USE_LFSC)
 488   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --with-lfsc)
 489   find_package(LFSC REQUIRED)
 490   add_definitions(-DCVC4_USE_LFSC)
 491 endif()
 492
 493 if(USE_READLINE)
 494   set(GPL_LIBS "${GPL_LIBS} readline")
 495   find_package(Readline REQUIRED)
 496   set(HAVE_LIBREADLINE 1)
 497   if(Readline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 498     set(READLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 499   endif()
 500 endif()
 501
 502 if(USE_SYMFPU)
 503   find_package(SymFPU REQUIRED)
 504   add_definitions(-DCVC4_USE_SYMFPU)
 505   set(CVC4_USE_SYMFPU 1)
 506 else()
 507   set(CVC4_USE_SYMFPU 0)
 508 endif()
 509
 510 if(GPL_LIBS)
 511   if(NOT ENABLE_GPL)
 512     message(FATAL_ERROR
 513       "Bad configuration detected: BSD-licensed code only, but also requested "
 514       "GPLed libraries: ${GPL_LIBS}")
 515   endif()
 516   set(CVC4_GPL_DEPS 1)
 517 endif()
 518
 519 #-----------------------------------------------------------------------------#
 520 # Generate CVC4's cvc4autoconfig.h header
 521
 522 include(ConfigureCVC4)
 523 configure_file(cvc4autoconfig.h.in cvc4autoconfig.h)
 524 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 525
 526 #-----------------------------------------------------------------------------#
 527 # Add subdirectories
 528
 529 # signatures needs to come before src since it adds source files to libcvc4.
 530 if(ENABLE_PROOFS)
 531   add_subdirectory(proofs/signatures)
 532 endif()
 533
 534 add_subdirectory(doc)
 535 add_subdirectory(src)
 536 add_subdirectory(test)
 537
 538 if(BUILD_SWIG_BINDINGS_JAVA OR BUILD_SWIG_BINDINGS_PYTHON)
 539   add_subdirectory(src/bindings)
 540 endif()
 541
 542 if(BUILD_BINDINGS_PYTHON)
 543   add_subdirectory(src/api/python)
 544 endif()
 545
 546 #-----------------------------------------------------------------------------#
 547 # Package configuration
 548 #
 549 # Export CVC4 targets to support find_package(CVC4) in other cmake projects.
 550
 551 include(CMakePackageConfigHelpers)
 552
 553 install(EXPORT cvc4-targets
 554   FILE CVC4Targets.cmake
 555   NAMESPACE CVC4::
 556   DESTINATION ${LIBRARY_INSTALL_DIR}/cmake/CVC4)
 557
 558 configure_package_config_file(
 559   ${CMAKE_SOURCE_DIR}/cmake/CVC4Config.cmake.in
 560   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 561   INSTALL_DESTINATION ${LIBRARY_INSTALL_DIR}/cmake/CVC4
 562   PATH_VARS LIBRARY_INSTALL_DIR
 563 )
 564
 565 write_basic_package_version_file(
 566   ${CMAKE_CURRENT_BINARY_DIR}/CVC4ConfigVersion.cmake
 567   VERSION ${CVC4_RELEASE_STRING}
 568   COMPATIBILITY ExactVersion
 569 )
 570
 571 install(FILES
 572   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 573   ${CMAKE_BINARY_DIR}/CVC4ConfigVersion.cmake
 574   DESTINATION ${LIBRARY_INSTALL_DIR}/cmake/CVC4
 575 )
 576
 577
 578 #-----------------------------------------------------------------------------#
 579 # Print build configuration
 580
 581 # Convert build type to lower case.
 582 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC4_BUILD_PROFILE_STRING)
 583
 584 # Get all definitions added via add_definitions.
 585 get_directory_property(CVC4_DEFINITIONS COMPILE_DEFINITIONS)
 586 string(REPLACE ";" " " CVC4_DEFINITIONS "${CVC4_DEFINITIONS}")
 587
 588 message("CVC4 ${CVC4_RELEASE_STRING}")
 589 message("")
 590 if(ENABLE_COMP_INC_TRACK)
 591   message("Build profile        : ${CVC4_BUILD_PROFILE_STRING} (incremental)")
 592 else()
 593   message("Build profile        : ${CVC4_BUILD_PROFILE_STRING}")
 594 endif()
 595 message("")
 596 print_config("GPL                       :" ENABLE_GPL)
 597 print_config("Best configuration        :" ENABLE_BEST)
 598 print_config("Optimization level        :" OPTIMIZATION_LEVEL)
 599 message("")
 600 print_config("Assertions                :" ENABLE_ASSERTIONS)
 601 print_config("Debug symbols             :" ENABLE_DEBUG_SYMBOLS)
 602 print_config("Debug context mem mgr     :" ENABLE_DEBUG_CONTEXT_MM)
 603 message("")
 604 print_config("Dumping                   :" ENABLE_DUMPING)
 605 print_config("Muzzle                    :" ENABLE_MUZZLE)
 606 print_config("Proofs                    :" ENABLE_PROOFS)
 607 print_config("Replay                    :" ENABLE_REPLAY)
 608 print_config("Statistics                :" ENABLE_STATISTICS)
 609 print_config("Tracing                   :" ENABLE_TRACING)
 610 message("")
 611 print_config("ASan                      :" ENABLE_ASAN)
 612 print_config("UBSan                     :" ENABLE_UBSAN)
 613 print_config("TSan                      :" ENABLE_TSAN)
 614 print_config("Coverage (gcov)           :" ENABLE_COVERAGE)
 615 print_config("Profiling (gprof)         :" ENABLE_PROFILING)
 616 print_config("Unit tests                :" ENABLE_UNIT_TESTING)
 617 print_config("Valgrind                  :" ENABLE_VALGRIND)
 618 message("")
 619 print_config("Shared libs               :" ENABLE_SHARED)
 620 print_config("Static binary             :" ENABLE_STATIC_BINARY)
 621 print_config("Java SWIG bindings        :" BUILD_SWIG_BINDINGS_JAVA)
 622 print_config("Python SWIG bindings      :" BUILD_SWIG_BINDINGS_PYTHON)
 623 print_config("Python bindings           :" BUILD_BINDINGS_PYTHON)
 624 print_config("Python2                   :" USE_PYTHON2)
 625 print_config("Python3                   :" USE_PYTHON3)
 626 message("")
 627 print_config("ABC                       :" USE_ABC)
 628 print_config("CaDiCaL                   :" USE_CADICAL)
 629 print_config("CryptoMiniSat             :" USE_CRYPTOMINISAT)
 630 print_config("drat2er                   :" USE_DRAT2ER)
 631 print_config("GLPK                      :" USE_GLPK)
 632 print_config("LFSC                      :" USE_LFSC)
 633
 634 if(CVC4_USE_CLN_IMP)
 635   message("MP library                   : cln")
 636 else()
 637   message("MP library                   : gmp")
 638 endif()
 639 print_config("Readline                  :" ${USE_READLINE})
 640 print_config("SymFPU                    :" ${USE_SYMFPU})
 641 message("")
 642 if(ABC_DIR)
 643   message("ABC dir                      : ${ABC_DIR}")
 644 endif()
 645 if(ANTLR_DIR)
 646   message("ANTLR dir                    : ${ANTLR_DIR}")
 647 endif()
 648 if(CADICAL_DIR)
 649   message("CADICAL dir                  : ${CADICAL_DIR}")
 650 endif()
 651 if(CRYPTOMINISAT_DIR)
 652   message("CRYPTOMINISAT dir            : ${CRYPTOMINISAT_DIR}")
 653 endif()
 654 if(DRAT2ER_DIR)
 655   message("DRAT2ER dir                  : ${DRAT2ER_DIR}")
 656 endif()
 657 if(GLPK_DIR)
 658   message("GLPK dir                     : ${GLPK_DIR}")
 659 endif()
 660 if(GMP_DIR)
 661   message("GMP dir                      : ${GMP_DIR}")
 662 endif()
 663 if(LFSC_DIR)
 664   message("LFSC dir                     : ${LFSC_DIR}")
 665 endif()
 666 if(SYMFPU_DIR)
 667   message("SYMFPU dir                   : ${SYMFPU_DIR}")
 668 endif()
 669 message("")
 670 message("CPPLAGS (-D...)                : ${CVC4_DEFINITIONS}")
 671 message("CXXFLAGS                       : ${CMAKE_CXX_FLAGS}")
 672 message("CFLAGS                         : ${CMAKE_C_FLAGS}")
 673 message("")
 674 message("Install prefix                 : ${CMAKE_INSTALL_PREFIX}")
 675 message("")
 676
 677 if(GPL_LIBS)
 678   message(
 679   "CVC4 license                         : GPLv3 (due to optional libraries; see below)"
 680   "\n"
 681   "\n"
 682   "Please note that CVC4 will be built against the following GPLed libraries:"
 683   "\n"
 684   "${GPL_LIBS}"
 685   "\n"
 686   "As these libraries are covered under the GPLv3, so is this build of CVC4."
 687   "\n"
 688   "CVC4 is also available to you under the terms of the (modified) BSD license."
 689   "\n"
 690   "If you prefer to license CVC4 under those terms, please configure CVC4 to"
 691   "\n"
 692   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 693   )
 694 else()
 695   message(
 696   "CVC4 license                         : modified BSD"
 697   "\n"
 698   "\n"
 699   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 700   "\n"
 701   "it is covered by the (modified) BSD license.  This is, however, not the best"
 702   "\n"
 703   "performing configuration of CVC4.  To build against GPL'ed libraries which"
 704   "\n"
 705   "improve CVC4's performance, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 706   )
 707 endif()
 708
 709 message("")
 710 message("Now just type make, followed by make check or make install.")
 711 message("")