CMakeLists.txt

   1 ###############################################################################
   2 # Top contributors (to current version):
   3 #   Aina Niemetz, Mathias Preiner, Gereon Kremer
   4 #
   5 # This file is part of the cvc5 project.
   6 #
   7 # Copyright (c) 2009-2021 by the authors listed in the file AUTHORS
   8 # in the top-level source directory and their institutional affiliations.
   9 # All rights reserved.  See the file COPYING in the top-level source
  10 # directory for licensing information.
  11 # #############################################################################
  12 #
  13 # The build system configuration.
  14 ##
  15
  16 cmake_minimum_required(VERSION 3.9)
  17
  18 #-----------------------------------------------------------------------------#
  19 # Project configuration
  20
  21 project(cvc5)
  22
  23 include(CheckIPOSupported)
  24 include(GNUInstallDirs)
  25 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  26
  27 include(version)
  28
  29 set(CMAKE_C_STANDARD 99)
  30 set(CMAKE_CXX_STANDARD 17)
  31 set(CMAKE_CXX_EXTENSIONS OFF)
  32 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  33 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  34 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  35
  36 # Generate compile_commands.json, which can be used for various code completion
  37 # plugins.
  38 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  39
  40 #-----------------------------------------------------------------------------#
  41 # Policies
  42
  43 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  44 if(POLICY CMP0075)
  45   cmake_policy(SET CMP0075 NEW)
  46 endif()
  47
  48 #-----------------------------------------------------------------------------#
  49 # Tell CMake where to find our dependencies
  50
  51 if(ABC_DIR)
  52   list(APPEND CMAKE_PREFIX_PATH "${ABC_DIR}")
  53 endif()
  54 if(GLPK_DIR)
  55   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  56 endif()
  57
  58 # By default the contrib/get-* scripts install dependencies to deps/install.
  59 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  60
  61 #-----------------------------------------------------------------------------#
  62
  63 include(Helpers)
  64
  65 #-----------------------------------------------------------------------------#
  66 # User options
  67
  68 # License
  69 option(ENABLE_GPL "Enable GPL dependencies")
  70
  71 # General build options
  72 #
  73 # >> 3-valued: IGNORE ON OFF
  74 #    > allows to detect if set by user (default: IGNORE)
  75 #    > only necessary for options set for build types
  76 cvc5_option(ENABLE_ASAN           "Enable ASAN build")
  77 cvc5_option(ENABLE_UBSAN          "Enable UBSan build")
  78 cvc5_option(ENABLE_TSAN           "Enable TSan build")
  79 cvc5_option(ENABLE_ASSERTIONS     "Enable assertions")
  80 cvc5_option(ENABLE_COMP_INC_TRACK
  81             "Enable optimizations for incremental SMT-COMP tracks")
  82 cvc5_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
  83 cvc5_option(ENABLE_DUMPING        "Enable dumping")
  84 cvc5_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
  85 cvc5_option(ENABLE_STATISTICS     "Enable statistics")
  86 cvc5_option(ENABLE_TRACING        "Enable tracing")
  87 cvc5_option(ENABLE_UNIT_TESTING   "Enable unit testing")
  88 cvc5_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
  89 cvc5_option(ENABLE_STATIC_LIBRARY "Enable building static library")
  90 cvc5_option(ENABLE_STATIC_BINARY
  91             "Build static binaries with statically linked system libraries")
  92 cvc5_option(ENABLE_AUTO_DOWNLOAD  "Enable automatic download of dependencies")
  93 cvc5_option(ENABLE_IPO            "Enable interprocedural optimization")
  94 # >> 2-valued: ON OFF
  95 #    > for options where we don't need to detect if set by user (default: OFF)
  96 option(ENABLE_BEST             "Enable dependencies known to give best performance")
  97 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
  98 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
  99 option(ENABLE_PROFILING        "Enable support for gprof profiling")
 100
 101 # Optional dependencies
 102 #
 103 # >> 3-valued: IGNORE ON OFF
 104 #    > allows to detect if set by user (default: IGNORE)
 105 #    > only necessary for options set for ENABLE_BEST
 106 cvc5_option(USE_ABC           "Use ABC for AIG bit-blasting")
 107 cvc5_option(USE_CLN           "Use CLN instead of GMP")
 108 cvc5_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 109 cvc5_option(USE_GLPK          "Use GLPK simplex solver")
 110 cvc5_option(USE_KISSAT        "Use Kissat SAT solver")
 111 cvc5_option(USE_EDITLINE      "Use Editline for better interactive support")
 112 # >> 2-valued: ON OFF
 113 #    > for options where we don't need to detect if set by user (default: OFF)
 114 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 115 option(USE_COCOA              "Use CoCoALib for further polynomial operations")
 116 option(USE_PYTHON2            "Force Python 2 (deprecated)")
 117
 118 # Custom install directories for dependencies
 119 # If no directory is provided by the user, we first check if the dependency was
 120 # installed via the corresponding contrib/get-* script and if not found, we
 121 # check the intalled system version. If the user provides a directory we
 122 # immediately fail if the dependency was not found at the specified location.
 123 set(ABC_DIR           "" CACHE STRING "Set ABC install directory")
 124 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 125
 126 # Prepend binaries with prefix on make install
 127 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 128
 129 # Supported language bindings based on new C++ API
 130 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 131 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 132
 133 # Api documentation
 134 cvc5_option(BUILD_DOCS "Build Api documentation")
 135
 136 #-----------------------------------------------------------------------------#
 137 # Internal cmake variables
 138
 139 set(OPTIMIZATION_LEVEL 3)
 140 set(GPL_LIBS "")
 141
 142 #-----------------------------------------------------------------------------#
 143 # Determine number of threads available, used to configure (default) parallel
 144 # execution of custom test targets (can be overriden with ARGS=-jN).
 145
 146 include(ProcessorCount)
 147 ProcessorCount(CTEST_NTHREADS)
 148 if(CTEST_NTHREADS EQUAL 0)
 149   set(CTEST_NTHREADS 1)
 150 endif()
 151
 152 #-----------------------------------------------------------------------------#
 153 # Build types
 154
 155 # Note: Module CodeCoverage requires the name of the debug build to conform
 156 #       to cmake standards (first letter uppercase).
 157 set(BUILD_TYPES Production Debug Testing Competition)
 158
 159 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 160   set(CMAKE_BUILD_TYPE Debug)
 161 endif()
 162
 163 # Set the default build type to Production
 164 if(NOT CMAKE_BUILD_TYPE)
 165   set(CMAKE_BUILD_TYPE
 166       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 167   # Provide drop down menu options in cmake-gui
 168   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 169 endif()
 170
 171 # Check if specified build type is valid.
 172 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 173 if(${FOUND_BUILD_TYPE} EQUAL -1)
 174   message(FATAL_ERROR
 175     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 176     "Available builds are: ${BUILD_TYPES}")
 177 endif()
 178
 179 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 180 include(Config${CMAKE_BUILD_TYPE})
 181
 182 #-----------------------------------------------------------------------------#
 183 # Compiler flags
 184
 185 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 186 add_check_c_cxx_flag("-Wall")
 187 add_check_c_cxx_flag("-Wno-unused-private-field")
 188 add_check_c_flag("-fexceptions")
 189 add_check_cxx_flag("-Wsuggest-override")
 190 add_check_cxx_flag("-Wnon-virtual-dtor")
 191 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 192 add_check_c_cxx_flag("-Wshadow")
 193
 194 # Assume no dynamic initialization of thread-local variables in non-defining
 195 # translation units. This option should result in better performance and works
 196 # around crashing issues with our Windows build.
 197 add_check_cxx_flag("-fno-extern-tls-init")
 198
 199 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 200 # cdlist.h warnings. Remove when fixed.
 201 add_check_cxx_flag("-Wno-class-memaccess")
 202
 203 if (WIN32)
 204   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 205 endif ()
 206
 207 #-----------------------------------------------------------------------------#
 208 # Use ld.gold if available
 209
 210 execute_process(COMMAND ${CMAKE_C_COMPILER}
 211                 -fuse-ld=gold
 212                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 213 if ("${LD_VERSION}" MATCHES "GNU gold")
 214   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 215   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 216   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 217   message(STATUS "Using GNU gold linker.")
 218 endif ()
 219
 220 #-----------------------------------------------------------------------------#
 221 # Use interprocedural optimization if requested
 222
 223 if(ENABLE_IPO)
 224   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 225 endif()
 226
 227
 228 #-----------------------------------------------------------------------------#
 229 # Option defaults (three-valued options (cvc5_option(...)))
 230 #
 231 # These options are only set if their value is IGNORE. Otherwise, the user
 232 # already set the option, which we don't want to overwrite.
 233
 234 if(ENABLE_STATIC_BINARY)
 235   message(STATUS "Enable static library for static binary build.")
 236   cvc5_set_option(ENABLE_STATIC_LIBRARY ON)
 237 endif()
 238
 239 #-----------------------------------------------------------------------------#
 240
 241 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 242 # that expect AssertionException to be thrown will fail.
 243 if(NOT ENABLE_ASSERTIONS)
 244   message(STATUS "Disabling unit tests since assertions are disabled.")
 245   set(ENABLE_UNIT_TESTING OFF)
 246 endif()
 247
 248 #-----------------------------------------------------------------------------#
 249 # Shared/static libraries
 250 #
 251 # This needs to be set before any find_package(...) command since we want to
 252 # search for static libraries with suffix .a.
 253
 254 # Embed the installation prefix as an RPATH in the executable such that the
 255 # linker can find our libraries (such as libcvc5parser) when executing the
 256 # cvc5 binary. This is for example useful when installing cvc5 with a custom
 257 # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 258 # we do not set this option, then the linker will not be able to find the
 259 # required libraries when trying to run cvc5.
 260 #
 261 # Also embed the installation prefix of the installed contrib libraries as an
 262 # RPATH. This allows to install a dynamically linked binary that depends on
 263 # dynamically linked libraries. This is dangerous, as the installed binary
 264 # breaks if the contrib library is removed or changes in other ways, we thus
 265 # print a big warning and only allow if installing to a custom installation
 266 # prefix.
 267 #
 268 # More information on RPATH in CMake:
 269 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 270 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 271
 272 # Set visibility to default if unit tests are enabled
 273 if(ENABLE_UNIT_TESTING)
 274   set(CMAKE_CXX_VISIBILITY_PRESET default)
 275   set(CMAKE_VISIBILITY_INLINES_HIDDEN 0)
 276 endif()
 277
 278 #-----------------------------------------------------------------------------#
 279 # Enable the ctest testing framework
 280
 281 # This needs to be enabled here rather than in subdirectory test in order to
 282 # allow calling ctest from the root build directory.
 283 enable_testing()
 284
 285 #-----------------------------------------------------------------------------#
 286 # Check options, find packages and configure build.
 287
 288 if(USE_PYTHON2)
 289   find_package(PythonInterp 2.7 REQUIRED)
 290 else()
 291   find_package(PythonInterp 3 REQUIRED)
 292 endif()
 293
 294 find_package(GMP 6.1 REQUIRED)
 295
 296 if(ENABLE_ASAN)
 297   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 298   # otherwise the -fsanitize=address check will fail while linking.
 299   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 300   add_required_c_cxx_flag("-fsanitize=address")
 301   unset(CMAKE_REQUIRED_FLAGS)
 302   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 303   add_check_c_cxx_flag("-fsanitize-recover=address")
 304 endif()
 305
 306 if(ENABLE_UBSAN)
 307   add_required_c_cxx_flag("-fsanitize=undefined")
 308   add_definitions(-DCVC5_USE_UBSAN)
 309 endif()
 310
 311 if(ENABLE_TSAN)
 312   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 313   # otherwise the -fsanitize=thread check will fail while linking.
 314   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 315   add_required_c_cxx_flag("-fsanitize=thread")
 316   unset(CMAKE_REQUIRED_FLAGS)
 317 endif()
 318
 319 if(ENABLE_ASSERTIONS)
 320   add_definitions(-DCVC5_ASSERTIONS)
 321 else()
 322   add_definitions(-DNDEBUG)
 323 endif()
 324
 325 if(ENABLE_COVERAGE)
 326   include(CodeCoverage)
 327   APPEND_COVERAGE_COMPILER_FLAGS()
 328   add_definitions(-DCVC5_COVERAGE)
 329   # Note: The ctest command returns a non-zero exit code if tests fail or run
 330   # into a timeout. As a consequence, the coverage report is not generated. To
 331   # prevent this we always return with exit code 0 after the ctest command has
 332   # finished.
 333   setup_target_for_coverage_gcovr_html(
 334     NAME coverage-test
 335     EXECUTABLE
 336       ctest -j${CTEST_NTHREADS} -LE "example"
 337         --output-on-failure $$ARGS || exit 0
 338     DEPENDS
 339       build-tests)
 340
 341   # Adds targets `coverage` and `coverage-reset` for manually generating
 342   # coverage reports for specific executions.
 343   #
 344   # Target coverage-reset resets all the coverage counters to zero, while
 345   # target coverage will generate a coverage report for all executions since
 346   # the last coverage-reset.
 347   setup_target_for_coverage_lcov_no_executable(
 348     NAME coverage
 349     DEPENDENCIES cvc5-bin)
 350 endif()
 351
 352 if(ENABLE_DEBUG_CONTEXT_MM)
 353   add_definitions(-DCVC5_DEBUG_CONTEXT_MEMORY_MANAGER)
 354 endif()
 355
 356 if(ENABLE_DEBUG_SYMBOLS)
 357   add_check_c_cxx_flag("-ggdb3")
 358 endif()
 359
 360 if(ENABLE_COMP_INC_TRACK)
 361   add_definitions(-DCVC5_SMTCOMP_APPLICATION_TRACK)
 362 endif()
 363
 364 if(ENABLE_MUZZLE)
 365   add_definitions(-DCVC5_MUZZLE)
 366 endif()
 367
 368 if(ENABLE_DUMPING)
 369   add_definitions(-DCVC5_DUMPING)
 370 endif()
 371
 372 if(ENABLE_PROFILING)
 373   add_definitions(-DCVC5_PROFILING)
 374   add_check_c_cxx_flag("-pg")
 375 endif()
 376
 377 if(ENABLE_TRACING)
 378   add_definitions(-DCVC5_TRACING)
 379 endif()
 380
 381 if(ENABLE_STATISTICS)
 382   add_definitions(-DCVC5_STATISTICS_ON)
 383 endif()
 384
 385 if(ENABLE_VALGRIND)
 386   find_package(Valgrind REQUIRED)
 387   add_definitions(-DCVC5_VALGRIND)
 388 endif()
 389
 390 if(USE_ABC)
 391   find_package(ABC REQUIRED)
 392   add_definitions(-DCVC5_USE_ABC ${ABC_ARCH_FLAGS})
 393 endif()
 394
 395 find_package(CaDiCaL REQUIRED)
 396
 397 if(USE_CLN)
 398   set(GPL_LIBS "${GPL_LIBS} cln")
 399   find_package(CLN 1.2.2 REQUIRED)
 400   set(CVC5_USE_CLN_IMP 1)
 401   set(CVC5_USE_GMP_IMP 0)
 402 else()
 403   set(CVC5_USE_CLN_IMP 0)
 404   set(CVC5_USE_GMP_IMP 1)
 405 endif()
 406
 407 if(USE_CRYPTOMINISAT)
 408   # CryptoMiniSat requires pthreads support
 409   set(THREADS_PREFER_PTHREAD_FLAG ON)
 410   find_package(Threads REQUIRED)
 411   if(THREADS_HAVE_PTHREAD_ARG)
 412     add_c_cxx_flag(-pthread)
 413   endif()
 414   find_package(CryptoMiniSat 5.8 REQUIRED)
 415   add_definitions(-DCVC5_USE_CRYPTOMINISAT)
 416 endif()
 417
 418 if(USE_GLPK)
 419   set(GPL_LIBS "${GPL_LIBS} glpk")
 420   find_package(GLPK REQUIRED)
 421   add_definitions(-DCVC5_USE_GLPK)
 422 endif()
 423
 424 if(USE_KISSAT)
 425   find_package(Kissat REQUIRED)
 426   add_definitions(-DCVC5_USE_KISSAT)
 427 endif()
 428
 429 if(USE_POLY)
 430   find_package(Poly REQUIRED)
 431   add_definitions(-DCVC5_USE_POLY)
 432   set(CVC5_USE_POLY_IMP 1)
 433 else()
 434   set(CVC5_USE_POLY_IMP 0)
 435 endif()
 436
 437 if(USE_COCOA)
 438   find_package(CoCoA REQUIRED 0.99711)
 439   add_definitions(-DCVC5_USE_COCOA)
 440 endif()
 441
 442 if(USE_EDITLINE)
 443   find_package(Editline REQUIRED)
 444   set(HAVE_LIBEDITLINE 1)
 445   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 446     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 447   endif()
 448 endif()
 449
 450 find_package(SymFPU REQUIRED)
 451
 452 if(GPL_LIBS)
 453   if(NOT ENABLE_GPL)
 454     message(FATAL_ERROR
 455       "Bad configuration detected: BSD-licensed code only, but also requested "
 456       "GPLed libraries: ${GPL_LIBS}")
 457   endif()
 458   set(CVC5_GPL_DEPS 1)
 459 endif()
 460
 461 #-----------------------------------------------------------------------------#
 462 # Provide targets to inspect iwyu suggestions
 463
 464 include(IWYU)
 465
 466 #-----------------------------------------------------------------------------#
 467
 468 include(ConfigureCvc5)
 469 if(ENABLE_STATIC_BINARY)
 470   set(CVC5_STATIC_BUILD ON)
 471 endif()
 472
 473 #-----------------------------------------------------------------------------#
 474 # Add subdirectories
 475
 476 add_subdirectory(src)
 477
 478 if(BUILD_BINDINGS_PYTHON)
 479   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 480   add_subdirectory(src/api/python)
 481 endif()
 482
 483 if(BUILD_BINDINGS_JAVA)
 484   add_subdirectory(src/api/java)
 485   message(WARNING "Java API is currently under development.")
 486 endif()
 487
 488 if(BUILD_DOCS)
 489   add_subdirectory(docs)
 490 endif()
 491
 492 add_subdirectory(test)
 493
 494 #-----------------------------------------------------------------------------#
 495 # Package configuration
 496 #
 497 # Export cvc5 targets to support find_package(cvc5) in other cmake projects.
 498
 499 include(CMakePackageConfigHelpers)
 500
 501 # If we install a dynamically linked binary that also uses dynamically used
 502 # libraries from deps/install/lib, we need to be cautious. Changing these
 503 # shared libraries from deps/install/lib most probably breaks the binary.
 504 # We only allow such an installation for custom installation prefixes
 505 # (in the assumption that only reasonably experienced users use this and
 506 # also that custom installation prefixes are not used for longer periods of
 507 # time anyway). Also, we print a big warning with further instructions.
 508 if(NOT ENABLE_STATIC_BINARY)
 509   # Get the libraries that cvc5 links against
 510   get_target_property(libs cvc5-shared INTERFACE_LINK_LIBRARIES)
 511   set(LIBS_SHARED_FROM_DEPS "")
 512   foreach(lib ${libs})
 513     # Filter out those that are linked dynamically and come from deps/install
 514     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 515       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 516     endif()
 517   endforeach()
 518   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 519   # Check if we actually use such "dangerous" libraries
 520   if(list_len GREATER 0)
 521     # Print a generic warning
 522     install(CODE "message(WARNING \"You are installing a dynamically linked \
 523     binary of cvc5 which may be a problem if you are using any dynamically \
 524     linked third-party library that you obtained through one of the \
 525     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 526     locally, hence executing such a contrib script removing the \
 527     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 528     Consider installing the dynamically linked dependencies on your system \
 529     manually or link cvc5 statically.\")")
 530     # Print the libraries in question
 531     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 532       install(CODE "message(WARNING \"The following library is used by the cvc5 binary: ${lib}\")")
 533     endforeach()
 534     # Check if we use a custom installation prefix
 535     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 536       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 537       soon-to-be-broken binary, system-wide installation is disabled if the \
 538       binary depends on locally-built shared libraries.\")")
 539     else()
 540       install(CODE "message(WARNING \"You have selected a custom install \
 541       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 542       previous warning and know what you are doing.\")")
 543     endif()
 544   endif()
 545 endif()
 546
 547 install(EXPORT cvc5-targets
 548   FILE cvc5Targets.cmake
 549   NAMESPACE cvc5::
 550   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5)
 551
 552 configure_package_config_file(
 553   ${CMAKE_SOURCE_DIR}/cmake/cvc5Config.cmake.in
 554   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 555   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 556   PATH_VARS CMAKE_INSTALL_LIBDIR
 557 )
 558
 559 write_basic_package_version_file(
 560   ${CMAKE_CURRENT_BINARY_DIR}/cvc5ConfigVersion.cmake
 561   VERSION ${CVC5_VERSION}
 562   COMPATIBILITY ExactVersion
 563 )
 564
 565 install(FILES
 566   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 567   ${CMAKE_BINARY_DIR}/cvc5ConfigVersion.cmake
 568   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 569 )
 570
 571
 572 #-----------------------------------------------------------------------------#
 573 # Print build configuration
 574
 575 # Set colors.
 576 if(NOT WIN32)
 577   string(ASCII 27 Esc)
 578   set(Green "${Esc}[32m")
 579   set(Blue "${Esc}[1;34m")
 580   set(ResetColor "${Esc}[m")
 581 endif()
 582
 583 # Convert build type to lower case.
 584 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC5_BUILD_PROFILE_STRING)
 585
 586 # Get all definitions added via add_definitions.
 587 get_directory_property(CVC5_DEFINITIONS COMPILE_DEFINITIONS)
 588 string(REPLACE ";" " " CVC5_DEFINITIONS "${CVC5_DEFINITIONS}")
 589
 590 message("")
 591 print_info("cvc5 ${CVC5_VERSION}")
 592 message("")
 593 if(ENABLE_COMP_INC_TRACK)
 594   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING} (incremental)")
 595 else()
 596   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING}")
 597 endif()
 598 message("")
 599 print_config("GPL                       " ${ENABLE_GPL})
 600 print_config("Best configuration        " ${ENABLE_BEST})
 601 message("")
 602 print_config("Assertions                " ${ENABLE_ASSERTIONS})
 603 print_config("Debug symbols             " ${ENABLE_DEBUG_SYMBOLS})
 604 print_config("Debug context mem mgr     " ${ENABLE_DEBUG_CONTEXT_MM})
 605 message("")
 606 print_config("Dumping                   " ${ENABLE_DUMPING})
 607 print_config("Muzzle                    " ${ENABLE_MUZZLE})
 608 print_config("Statistics                " ${ENABLE_STATISTICS})
 609 print_config("Tracing                   " ${ENABLE_TRACING})
 610 message("")
 611 print_config("ASan                      " ${ENABLE_ASAN})
 612 print_config("UBSan                     " ${ENABLE_UBSAN})
 613 print_config("TSan                      " ${ENABLE_TSAN})
 614 print_config("Coverage (gcov)           " ${ENABLE_COVERAGE})
 615 print_config("Profiling (gprof)         " ${ENABLE_PROFILING})
 616 print_config("Unit tests                " ${ENABLE_UNIT_TESTING})
 617 print_config("Valgrind                  " ${ENABLE_VALGRIND})
 618 message("")
 619 print_config("Static library            " ${ENABLE_STATIC_LIBRARY})
 620 print_config("Static binary             " ${ENABLE_STATIC_BINARY})
 621 print_config("Python bindings           " ${BUILD_BINDINGS_PYTHON})
 622 print_config("Java bindings             " ${BUILD_BINDINGS_JAVA})
 623 print_config("Python2                   " ${USE_PYTHON2})
 624 print_config("Interprocedural opt.      " ${ENABLE_IPO})
 625 message("")
 626 print_config("ABC                       " ${USE_ABC})
 627 print_config("CryptoMiniSat             " ${USE_CRYPTOMINISAT} FOUND_SYSTEM ${CryptoMiniSat_FOUND_SYSTEM})
 628 print_config("GLPK                      " ${USE_GLPK})
 629 print_config("Kissat                    " ${USE_KISSAT} FOUND_SYSTEM ${Kissat_FOUND_SYSTEM})
 630 print_config("LibPoly                   " ${USE_POLY} FOUND_SYSTEM ${Poly_FOUND_SYSTEM})
 631 print_config("CoCoALib                  " ${USE_COCOA} FOUND_SYSTEM ${CoCoA_FOUND_SYSTEM})
 632
 633 if(CVC5_USE_CLN_IMP)
 634   print_config("MP library                " "cln" FOUND_SYSTEM ${CLN_FOUND_SYSTEM})
 635 else()
 636   print_config("MP library                " "gmp" FOUND_SYSTEM ${GMP_FOUND_SYSTEM})
 637 endif()
 638 print_config("Editline                  " ${USE_EDITLINE})
 639 message("")
 640 print_config("Api docs                  " ${BUILD_DOCS})
 641 message("")
 642 if(ABC_DIR)
 643   print_config("ABC dir                   " ${ABC_DIR})
 644 endif()
 645 if(GLPK_DIR)
 646   print_config("GLPK dir                  " ${GLPK_DIR})
 647 endif()
 648 message("")
 649 print_config("CPPLAGS (-D...)" "${CVC5_DEFINITIONS}")
 650 print_config("CXXFLAGS       " "${CMAKE_CXX_FLAGS}")
 651 print_config("CFLAGS         " "${CMAKE_C_FLAGS}")
 652 print_config("Linker flags   " "${CMAKE_EXE_LINKER_FLAGS}")
 653 message("")
 654 print_config("Install prefix " "${CMAKE_INSTALL_PREFIX}")
 655 message("")
 656
 657 if(GPL_LIBS)
 658   message(
 659   "${Blue}cvc5 license: "
 660   "${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 661   "\n"
 662   "\n"
 663   "Please note that cvc5 will be built against the following GPLed libraries:"
 664   "\n"
 665   "${GPL_LIBS}"
 666   "\n"
 667   "As these libraries are covered under the GPLv3, so is this build of cvc5."
 668   "\n"
 669   "cvc5 is also available to you under the terms of the (modified) BSD license."
 670   "\n"
 671   "If you prefer to license cvc5 under those terms, please configure cvc5 to"
 672   "\n"
 673   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 674   )
 675 else()
 676   message(
 677   "${Blue}cvc5 license:${ResetColor} modified BSD"
 678   "\n"
 679   "\n"
 680   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 681   "\n"
 682   "it is covered by the (modified) BSD license.  To build against GPL'ed"
 683   "\n"
 684   "libraries which can improve cvc5's performance on arithmetic and bitvector"
 685   "\n"
 686   "logics, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 687   )
 688 endif()
 689
 690 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 691   set(BUILD_COMMAND_NAME "ninja")
 692 else()
 693   set(BUILD_COMMAND_NAME "make")
 694 endif()
 695
 696 message("")
 697 message("Now just type '${BUILD_COMMAND_NAME}', "
 698         "followed by '${BUILD_COMMAND_NAME} check' "
 699         "or '${BUILD_COMMAND_NAME} install'.")
 700 message("")