CMakeLists.txt

   1 #####################
   2 ## CMakeLists.txt
   3 ## Top contributors (to current version):
   4 ##   Mathias Preiner, Aina Niemetz, Gereon Kremer
   5 ## This file is part of the CVC4 project.
   6 ## Copyright (c) 2009-2020 by the authors listed in the file AUTHORS
   7 ## in the top-level source directory and their institutional affiliations.
   8 ## All rights reserved.  See the file COPYING in the top-level source
   9 ## directory for licensing information.
  10 ##
  11 cmake_minimum_required(VERSION 3.9)
  12
  13 #-----------------------------------------------------------------------------#
  14 # Project configuration
  15
  16 project(cvc4)
  17
  18 include(GNUInstallDirs)
  19
  20 set(CVC4_MAJOR   1) # Major component of the version of CVC4.
  21 set(CVC4_MINOR   9) # Minor component of the version of CVC4.
  22 set(CVC4_RELEASE 0) # Release component of the version of CVC4.
  23
  24 # Extraversion component of the version of CVC4.
  25 set(CVC4_EXTRAVERSION "-prerelease")
  26
  27 # Shared library versioning. Increment SOVERSION for every new CVC4 release.
  28 set(CVC4_SOVERSION 7)
  29
  30 # Full release string for CVC4.
  31 if(CVC4_RELEASE)
  32   set(CVC4_RELEASE_STRING
  33       "${CVC4_MAJOR}.${CVC4_MINOR}.${CVC4_RELEASE}${CVC4_EXTRAVERSION}")
  34 else()
  35   set(CVC4_RELEASE_STRING "${CVC4_MAJOR}.${CVC4_MINOR}${CVC4_EXTRAVERSION}")
  36 endif()
  37
  38 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  39 set(CMAKE_C_STANDARD 99)
  40 set(CMAKE_CXX_STANDARD 17)
  41 set(CMAKE_CXX_EXTENSIONS OFF)
  42 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  43
  44 # Generate compile_commands.json, which can be used for various code completion
  45 # plugins.
  46 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  47
  48 #-----------------------------------------------------------------------------#
  49 # Policies
  50
  51 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  52 if(POLICY CMP0075)
  53   cmake_policy(SET CMP0075 NEW)
  54 endif()
  55
  56 #-----------------------------------------------------------------------------#
  57 # Tell CMake where to find our dependencies
  58
  59 if(ABC_DIR)
  60   list(APPEND CMAKE_PREFIX_PATH "${ABC_DIR}")
  61 endif()
  62 if(ANTLR_DIR)
  63   list(APPEND CMAKE_PREFIX_PATH "${ANTLR_DIR}")
  64 endif()
  65 if(CADICAL_DIR)
  66   list(APPEND CMAKE_PREFIX_PATH "${CADICAL_DIR}")
  67 endif()
  68 if(CRYPTOMINISAT_DIR)
  69   list(APPEND CMAKE_PREFIX_PATH "${CRYPTOMINISAT_DIR}")
  70 endif()
  71 if(CXXTEST_DIR)
  72   list(APPEND CMAKE_PREFIX_PATH "${CXXTEST_DIR}")
  73 endif()
  74 if(DRAT2ER_DIR)
  75   list(APPEND CMAKE_PREFIX_PATH "${DRAT2ER_DIR}")
  76 endif()
  77 if(GLPK_DIR)
  78   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  79 endif()
  80 if(GMP_DIR)
  81   list(APPEND CMAKE_PREFIX_PATH "${GMP_DIR}")
  82 endif()
  83 if(KISSAT_DIR)
  84   list(APPEND CMAKE_PREFIX_PATH "${KISSAT_DIR}")
  85 endif()
  86 if(LFSC_DIR)
  87   list(APPEND CMAKE_PREFIX_PATH "${LFSC_DIR}")
  88 endif()
  89 if(POLY_DIR)
  90   list(APPEND CMAKE_PREFIX_PATH "${POLY_DIR}")
  91 endif()
  92 if(SYMFPU_DIR)
  93   list(APPEND CMAKE_PREFIX_PATH "${SYMFPU_DIR}")
  94 endif()
  95
  96 # By default the contrib/get-* scripts install dependencies to deps/install.
  97 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  98
  99 #-----------------------------------------------------------------------------#
 100
 101 include(Helpers)
 102
 103 #-----------------------------------------------------------------------------#
 104 # User options
 105
 106 # License
 107 option(ENABLE_GPL "Enable GPL dependencies")
 108
 109 # General build options
 110 #
 111 # >> 3-valued: IGNORE ON OFF
 112 #    > allows to detect if set by user (default: IGNORE)
 113 #    > only necessary for options set for build types
 114 cvc4_option(ENABLE_ASAN           "Enable ASAN build")
 115 cvc4_option(ENABLE_UBSAN          "Enable UBSan build")
 116 cvc4_option(ENABLE_TSAN           "Enable TSan build")
 117 cvc4_option(ENABLE_ASSERTIONS     "Enable assertions")
 118 cvc4_option(ENABLE_COMP_INC_TRACK
 119             "Enable optimizations for incremental SMT-COMP tracks")
 120 cvc4_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
 121 cvc4_option(ENABLE_DUMPING        "Enable dumping")
 122 cvc4_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
 123 cvc4_option(ENABLE_PROOFS         "Enable proof support")
 124 cvc4_option(ENABLE_STATISTICS     "Enable statistics")
 125 cvc4_option(ENABLE_TRACING        "Enable tracing")
 126 cvc4_option(ENABLE_UNIT_TESTING   "Enable unit testing")
 127 cvc4_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
 128 cvc4_option(ENABLE_SHARED         "Build as shared library")
 129 cvc4_option(ENABLE_STATIC_BINARY
 130             "Build static binaries with statically linked system libraries")
 131 # >> 2-valued: ON OFF
 132 #    > for options where we don't need to detect if set by user (default: OFF)
 133 option(ENABLE_BEST             "Enable dependencies known to give best performance")
 134 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
 135 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
 136 option(ENABLE_PROFILING        "Enable support for gprof profiling")
 137
 138 # Optional dependencies
 139 #
 140 # >> 3-valued: IGNORE ON OFF
 141 #    > allows to detect if set by user (default: IGNORE)
 142 #    > only necessary for options set for ENABLE_BEST
 143 cvc4_option(USE_ABC           "Use ABC for AIG bit-blasting")
 144 cvc4_option(USE_CADICAL       "Use CaDiCaL SAT solver")
 145 cvc4_option(USE_CLN           "Use CLN instead of GMP")
 146 cvc4_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 147 cvc4_option(USE_GLPK          "Use GLPK simplex solver")
 148 cvc4_option(USE_KISSAT        "Use Kissat SAT solver")
 149 cvc4_option(USE_EDITLINE      "Use Editline for better interactive support")
 150 # >> 2-valued: ON OFF
 151 #    > for options where we don't need to detect if set by user (default: OFF)
 152 option(USE_DRAT2ER            "Include drat2er for making eager BV proofs")
 153 option(USE_LFSC               "Use LFSC proof checker")
 154 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 155 option(USE_SYMFPU             "Use SymFPU for floating point support")
 156 option(USE_PYTHON2            "Force Python 2 (deprecated)")
 157
 158 # Custom install directories for dependencies
 159 # If no directory is provided by the user, we first check if the dependency was
 160 # installed via the corresponding contrib/get-* script and if not found, we
 161 # check the intalled system version. If the user provides a directory we
 162 # immediately fail if the dependency was not found at the specified location.
 163 set(ABC_DIR           "" CACHE STRING "Set ABC install directory")
 164 set(ANTLR_DIR         "" CACHE STRING "Set ANTLR3 install directory")
 165 set(CADICAL_DIR       "" CACHE STRING "Set CaDiCaL install directory")
 166 set(CRYPTOMINISAT_DIR "" CACHE STRING "Set CryptoMiniSat install directory")
 167 set(CXXTEST_DIR       "" CACHE STRING "Set CxxTest install directory")
 168 set(DRAT2ER_DIR       "" CACHE STRING "Set drat2er install directory")
 169 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 170 set(GMP_DIR           "" CACHE STRING "Set GMP install directory")
 171 set(KISSAT_DIR        "" CACHE STRING "Set Kissat install directory")
 172 set(LFSC_DIR          "" CACHE STRING "Set LFSC install directory")
 173 set(POLY_DIR          "" CACHE STRING "Set LibPoly install directory")
 174 set(SYMFPU_DIR        "" CACHE STRING "Set SymFPU install directory")
 175
 176 # Prepend binaries with prefix on make install
 177 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 178
 179 # Supprted language bindings based on new C++ API
 180 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 181 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 182
 183 # Build limitations
 184 option(BUILD_LIB_ONLY         "Only build the library")
 185
 186 #-----------------------------------------------------------------------------#
 187 # Internal cmake variables
 188
 189 set(OPTIMIZATION_LEVEL 3)
 190 set(GPL_LIBS "")
 191
 192 #-----------------------------------------------------------------------------#
 193 # Determine number of threads available, used to configure (default) parallel
 194 # execution of custom test targets (can be overriden with ARGS=-jN).
 195
 196 include(ProcessorCount)
 197 ProcessorCount(CTEST_NTHREADS)
 198 if(CTEST_NTHREADS EQUAL 0)
 199   set(CTEST_NTHREADS 1)
 200 endif()
 201
 202 #-----------------------------------------------------------------------------#
 203 # Build types
 204
 205 # Note: Module CodeCoverage requires the name of the debug build to conform
 206 #       to cmake standards (first letter uppercase).
 207 set(BUILD_TYPES Production Debug Testing Competition)
 208
 209 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 210   set(CMAKE_BUILD_TYPE Debug)
 211 endif()
 212
 213 # Set the default build type to Production
 214 if(NOT CMAKE_BUILD_TYPE)
 215   set(CMAKE_BUILD_TYPE
 216       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 217   # Provide drop down menu options in cmake-gui
 218   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 219 endif()
 220
 221 # Check if specified build type is valid.
 222 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 223 if(${FOUND_BUILD_TYPE} EQUAL -1)
 224   message(FATAL_ERROR
 225     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 226     "Available builds are: ${BUILD_TYPES}")
 227 endif()
 228
 229 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 230 include(Config${CMAKE_BUILD_TYPE})
 231
 232 #-----------------------------------------------------------------------------#
 233 # Compiler flags
 234
 235 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 236 add_check_c_cxx_flag("-Wall")
 237 add_check_c_cxx_flag("-Wno-unused-private-field")
 238 add_check_c_flag("-fexceptions")
 239 add_check_cxx_flag("-Wsuggest-override")
 240 add_check_cxx_flag("-Wnon-virtual-dtor")
 241 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 242 add_check_c_cxx_flag("-Wshadow")
 243
 244 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 245 # cdlist.h warnings. Remove when fixed.
 246 add_check_cxx_flag("-Wno-class-memaccess")
 247
 248 if (WIN32)
 249   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 250 endif ()
 251
 252 #-----------------------------------------------------------------------------#
 253 # Use ld.gold if available
 254
 255 execute_process(COMMAND ${CMAKE_C_COMPILER}
 256                 -fuse-ld=gold
 257                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 258 if ("${LD_VERSION}" MATCHES "GNU gold")
 259   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 260   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 261   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 262   message(STATUS "Using GNU gold linker.")
 263 endif ()
 264
 265 #-----------------------------------------------------------------------------#
 266 # Option defaults (three-valued options (cvc4_option(...)))
 267 #
 268 # These options are only set if their value is IGNORE. Otherwise, the user
 269 # already set the option, which we don't want to overwrite.
 270
 271 if(ENABLE_STATIC_BINARY)
 272   cvc4_set_option(ENABLE_SHARED OFF)
 273 else()
 274   cvc4_set_option(ENABLE_SHARED ON)
 275 endif()
 276
 277 #-----------------------------------------------------------------------------#
 278 # Set options for best configuration
 279
 280 if(ENABLE_BEST)
 281   cvc4_set_option(USE_ABC ON)
 282   cvc4_set_option(USE_CADICAL ON)
 283   cvc4_set_option(USE_CLN ON)
 284   cvc4_set_option(USE_CRYPTOMINISAT ON)
 285   cvc4_set_option(USE_GLPK ON)
 286   cvc4_set_option(USE_EDITLINE ON)
 287 endif()
 288
 289 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 290 # that expect AssertionException to be thrown will fail.
 291 if(NOT ENABLE_ASSERTIONS)
 292   message(WARNING "Disabling unit tests since assertions are disabled.")
 293   set(ENABLE_UNIT_TESTING OFF)
 294 endif()
 295
 296 #-----------------------------------------------------------------------------#
 297 # Shared/static libraries
 298 #
 299 # This needs to be set before any find_package(...) command since we want to
 300 # search for static libraries with suffix .a.
 301
 302 if(ENABLE_SHARED)
 303   set(BUILD_SHARED_LIBS ON)
 304   if(ENABLE_STATIC_BINARY)
 305     set(ENABLE_STATIC_BINARY OFF)
 306     message(WARNING "Disabling static binary since shared build is enabled.")
 307   endif()
 308
 309   # Embed the installation prefix as an RPATH in the executable such that the
 310   # linker can find our libraries (such as libcvc4parser) when executing the
 311   # cvc4 binary. This is for example useful when installing CVC4 with a custom
 312   # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 313   # we do not set this option, then the linker will not be able to find the
 314   # required libraries when trying to run CVC4.
 315   #
 316   # Also embed the installation prefix of the installed contrib libraries as an
 317   # RPATH. This allows to install a dynamically linked binary that depends on
 318   # dynamically linked libraries. This is dangerous, as the installed binary
 319   # breaks if the contrib library is removed or changes in other ways, we thus
 320   # print a big warning and only allow if installing to a custom installation
 321   # prefix.
 322   #
 323   # More information on RPATH in CMake:
 324   # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 325   set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 326 else()
 327   # When building statically, we *only* want static archives/libraries
 328   if (WIN32)
 329       set(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a)
 330   else()
 331       set(CMAKE_FIND_LIBRARY_SUFFIXES .a)
 332   endif()
 333   set(BUILD_SHARED_LIBS OFF)
 334   cvc4_set_option(ENABLE_STATIC_BINARY ON)
 335
 336   # Never build unit tests as static binaries, otherwise we'll end up with
 337   # ~300MB per unit test.
 338   if(ENABLE_UNIT_TESTING)
 339     message(WARNING "Disabling unit tests since static build is enabled.")
 340     set(ENABLE_UNIT_TESTING OFF)
 341   endif()
 342
 343   if (BUILD_BINDINGS_PYTHON)
 344     message(FATAL_ERROR "Building Python bindings is not possible "
 345                         "when building statically")
 346   endif()
 347 endif()
 348
 349 #-----------------------------------------------------------------------------#
 350 # Enable the ctest testing framework
 351
 352 # This needs to be enabled here rather than in subdirectory test in order to
 353 # allow calling ctest from the root build directory.
 354 enable_testing()
 355
 356 #-----------------------------------------------------------------------------#
 357 # Check GCC version.
 358 #
 359 # GCC version 4.5.1 builds MiniSat incorrectly with -O2, which results in
 360 # incorrect answers.
 361
 362 if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
 363   execute_process(
 364     COMMAND ${CMAKE_CXX_COMPILER} -dumpversion
 365     OUTPUT_VARIABLE GCC_VERSION
 366     OUTPUT_STRIP_TRAILING_WHITESPACE)
 367   if(GCC_VERSION VERSION_EQUAL "4.5.1")
 368     message(FATAL_ERROR
 369       "GCC 4.5.1's optimizer is known to build MiniSat incorrectly "
 370       "(and by extension CVC4).")
 371   endif()
 372 endif()
 373
 374 #-----------------------------------------------------------------------------#
 375 # Check options, find packages and configure build.
 376
 377 if(USE_PYTHON2)
 378   find_package(PythonInterp 2.7 REQUIRED)
 379 else()
 380   find_package(PythonInterp 3 REQUIRED)
 381 endif()
 382
 383 find_package(GMP REQUIRED)
 384
 385 if(ENABLE_ASAN)
 386   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 387   # otherwise the -fsanitize=address check will fail while linking.
 388   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 389   add_required_c_cxx_flag("-fsanitize=address")
 390   unset(CMAKE_REQUIRED_FLAGS)
 391   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 392   add_check_c_cxx_flag("-fsanitize-recover=address")
 393 endif()
 394
 395 if(ENABLE_UBSAN)
 396   add_required_c_cxx_flag("-fsanitize=undefined")
 397   add_definitions(-DCVC4_USE_UBSAN)
 398 endif()
 399
 400 if(ENABLE_TSAN)
 401   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 402   # otherwise the -fsanitize=thread check will fail while linking.
 403   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 404   add_required_c_cxx_flag("-fsanitize=thread")
 405   unset(CMAKE_REQUIRED_FLAGS)
 406 endif()
 407
 408 if(ENABLE_ASSERTIONS)
 409   add_definitions(-DCVC4_ASSERTIONS)
 410 else()
 411   add_definitions(-DNDEBUG)
 412 endif()
 413
 414 if(ENABLE_COVERAGE)
 415   include(CodeCoverage)
 416   APPEND_COVERAGE_COMPILER_FLAGS()
 417   add_definitions(-DCVC4_COVERAGE)
 418   # Note: The ctest command returns a non-zero exit code if tests fail or run
 419   # into a timeout. As a consequence, the coverage report is not generated. To
 420   # prevent this we always return with exit code 0 after the ctest command has
 421   # finished.
 422   setup_target_for_coverage_gcovr_html(
 423     NAME coverage
 424     EXECUTABLE
 425       ctest -j${CTEST_NTHREADS} -LE "example"
 426         --output-on-failure $$ARGS || exit 0
 427     DEPENDS
 428       build-tests)
 429 endif()
 430
 431 if(ENABLE_DEBUG_CONTEXT_MM)
 432   add_definitions(-DCVC4_DEBUG_CONTEXT_MEMORY_MANAGER)
 433 endif()
 434
 435 if(ENABLE_DEBUG_SYMBOLS)
 436   add_check_c_cxx_flag("-ggdb3")
 437 endif()
 438
 439 if(ENABLE_COMP_INC_TRACK)
 440   add_definitions(-DCVC4_SMTCOMP_APPLICATION_TRACK)
 441 endif()
 442
 443 if(ENABLE_MUZZLE)
 444   add_definitions(-DCVC4_MUZZLE)
 445 endif()
 446
 447 if(ENABLE_DUMPING)
 448   add_definitions(-DCVC4_DUMPING)
 449 endif()
 450
 451 if(ENABLE_PROFILING)
 452   add_definitions(-DCVC4_PROFILING)
 453   add_check_c_cxx_flag("-pg")
 454 endif()
 455
 456 if(ENABLE_PROOFS)
 457   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --enable-proof)
 458   add_definitions(-DCVC4_PROOF)
 459 endif()
 460
 461 if(ENABLE_TRACING)
 462   add_definitions(-DCVC4_TRACING)
 463 endif()
 464
 465 if(ENABLE_STATISTICS)
 466   add_definitions(-DCVC4_STATISTICS_ON)
 467 endif()
 468
 469 if(ENABLE_VALGRIND)
 470   find_package(Valgrind REQUIRED)
 471   add_definitions(-DCVC4_VALGRIND)
 472 endif()
 473
 474 if(USE_ABC)
 475   find_package(ABC REQUIRED)
 476   add_definitions(-DCVC4_USE_ABC ${ABC_ARCH_FLAGS})
 477 endif()
 478
 479 if(USE_CADICAL)
 480   find_package(CaDiCaL REQUIRED)
 481   add_definitions(-DCVC4_USE_CADICAL)
 482 endif()
 483
 484 if(USE_CLN)
 485   set(GPL_LIBS "${GPL_LIBS} cln")
 486   find_package(CLN 1.2.2 REQUIRED)
 487   set(CVC4_USE_CLN_IMP 1)
 488   set(CVC4_USE_GMP_IMP 0)
 489 else()
 490   set(CVC4_USE_CLN_IMP 0)
 491   set(CVC4_USE_GMP_IMP 1)
 492 endif()
 493
 494 if(USE_CRYPTOMINISAT)
 495   # CryptoMiniSat requires pthreads support
 496   set(THREADS_PREFER_PTHREAD_FLAG ON)
 497   find_package(Threads REQUIRED)
 498   if(THREADS_HAVE_PTHREAD_ARG)
 499     add_c_cxx_flag(-pthread)
 500   endif()
 501   find_package(CryptoMiniSat REQUIRED)
 502   add_definitions(-DCVC4_USE_CRYPTOMINISAT)
 503 endif()
 504
 505 if(USE_DRAT2ER)
 506   find_package(Drat2Er REQUIRED)
 507   add_definitions(-DCVC4_USE_DRAT2ER)
 508 endif()
 509
 510 if(USE_GLPK)
 511   set(GPL_LIBS "${GPL_LIBS} glpk")
 512   find_package(GLPK REQUIRED)
 513   add_definitions(-DCVC4_USE_GLPK)
 514 endif()
 515
 516 if(USE_KISSAT)
 517   find_package(Kissat REQUIRED)
 518   add_definitions(-DCVC4_USE_KISSAT)
 519 endif()
 520
 521 if(USE_LFSC)
 522   set(RUN_REGRESSION_ARGS ${RUN_REGRESSION_ARGS} --with-lfsc)
 523   find_package(LFSC REQUIRED)
 524   add_definitions(-DCVC4_USE_LFSC)
 525 endif()
 526
 527 if(USE_POLY)
 528   find_package(Poly REQUIRED)
 529   add_definitions(-DCVC4_USE_POLY)
 530   set(CVC4_USE_POLY_IMP 1)
 531 else()
 532   set(CVC4_USE_POLY_IMP 0)
 533 endif()
 534
 535 if(USE_EDITLINE)
 536   find_package(Editline REQUIRED)
 537   set(HAVE_LIBEDITLINE 1)
 538   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 539     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 540   endif()
 541 endif()
 542
 543 if(USE_SYMFPU)
 544   find_package(SymFPU REQUIRED)
 545   add_definitions(-DCVC4_USE_SYMFPU)
 546   set(CVC4_USE_SYMFPU 1)
 547 else()
 548   set(CVC4_USE_SYMFPU 0)
 549 endif()
 550
 551 if(GPL_LIBS)
 552   if(NOT ENABLE_GPL)
 553     message(FATAL_ERROR
 554       "Bad configuration detected: BSD-licensed code only, but also requested "
 555       "GPLed libraries: ${GPL_LIBS}")
 556   endif()
 557   set(CVC4_GPL_DEPS 1)
 558 endif()
 559
 560 #-----------------------------------------------------------------------------#
 561 # Generate CVC4's cvc4autoconfig.h header
 562
 563 include(ConfigureCVC4)
 564 if(NOT ENABLE_SHARED)
 565   set(CVC4_STATIC_BUILD ON)
 566 endif()
 567 configure_file(cvc4autoconfig.h.in cvc4autoconfig.h)
 568 unset(CVC4_STATIC_BUILD)
 569 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 570
 571 #-----------------------------------------------------------------------------#
 572 # Add subdirectories
 573
 574 # signatures needs to come before src since it adds source files to libcvc4.
 575 if(ENABLE_PROOFS)
 576   add_subdirectory(proofs/signatures)
 577 endif()
 578
 579 add_subdirectory(doc)
 580 add_subdirectory(src)
 581 add_subdirectory(test)
 582
 583 if(BUILD_BINDINGS_PYTHON)
 584   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 585   add_subdirectory(src/api/python)
 586 endif()
 587
 588 if(BUILD_BINDINGS_JAVA)
 589   message(FATAL_ERROR
 590     "Java bindings for the new API are not implemented yet.")
 591 endif()
 592
 593 #-----------------------------------------------------------------------------#
 594 # Package configuration
 595 #
 596 # Export CVC4 targets to support find_package(CVC4) in other cmake projects.
 597
 598 include(CMakePackageConfigHelpers)
 599
 600 # If we install a dynamically linked binary that also uses dynamically used
 601 # libraries from deps/install/lib, we need to be cautious. Changing these
 602 # shared libraries from deps/install/lib most probably breaks the binary.
 603 # We only allow such an installation for custom installation prefixes
 604 # (in the assumption that only reasonably experienced users use this and
 605 # also that custom installation prefixes are not used for longer periods of
 606 # time anyway). Also, we print a big warning with further instructions.
 607 if(NOT ENABLE_STATIC_BINARY)
 608   # Get the libraries that cvc4 links against
 609   get_target_property(libs cvc4 INTERFACE_LINK_LIBRARIES)
 610   set(LIBS_SHARED_FROM_DEPS "")
 611   foreach(lib ${libs})
 612     # Filter out those that are linked dynamically and come from deps/install
 613     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 614       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 615     endif()
 616   endforeach()
 617   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 618   # Check if we actually use such "dangerous" libraries
 619   if(list_len GREATER 0)
 620     # Print a generic warning
 621     install(CODE "message(WARNING \"You are installing a dynamically linked \
 622     binary of CVC4 which may be a problem if you are using any dynamically \
 623     linked third-party library that you obtained through one of the \
 624     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 625     locally, hence executing such a contrib script removing the \
 626     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 627     Consider installing the dynamically linked dependencies on your system \
 628     manually or link cvc4 statically.\")")
 629     # Print the libraries in question
 630     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 631       install(CODE "message(WARNING \"The following library is used by the cvc4 binary: ${lib}\")")
 632     endforeach()
 633     # Check if we use a custom installation prefix
 634     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 635       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 636       soon-to-be-broken binary, system-wide installation is disabled if the \
 637       binary depends on locally-built shared libraries.\")")
 638     else()
 639       install(CODE "message(WARNING \"You have selected a custom install \
 640       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 641       previous warning and know what you are doing.\")")
 642     endif()
 643   endif()
 644 endif()
 645
 646 install(EXPORT cvc4-targets
 647   FILE CVC4Targets.cmake
 648   NAMESPACE CVC4::
 649   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4)
 650
 651 configure_package_config_file(
 652   ${CMAKE_SOURCE_DIR}/cmake/CVC4Config.cmake.in
 653   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 654   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4
 655   PATH_VARS CMAKE_INSTALL_LIBDIR
 656 )
 657
 658 write_basic_package_version_file(
 659   ${CMAKE_CURRENT_BINARY_DIR}/CVC4ConfigVersion.cmake
 660   VERSION ${CVC4_RELEASE_STRING}
 661   COMPATIBILITY ExactVersion
 662 )
 663
 664 install(FILES
 665   ${CMAKE_BINARY_DIR}/cmake/CVC4Config.cmake
 666   ${CMAKE_BINARY_DIR}/CVC4ConfigVersion.cmake
 667   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/CVC4
 668 )
 669
 670
 671 #-----------------------------------------------------------------------------#
 672 # Print build configuration
 673
 674 # Convert build type to lower case.
 675 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC4_BUILD_PROFILE_STRING)
 676
 677 # Get all definitions added via add_definitions.
 678 get_directory_property(CVC4_DEFINITIONS COMPILE_DEFINITIONS)
 679 string(REPLACE ";" " " CVC4_DEFINITIONS "${CVC4_DEFINITIONS}")
 680
 681 message("CVC4 ${CVC4_RELEASE_STRING}")
 682 message("")
 683 if(ENABLE_COMP_INC_TRACK)
 684   message("Build profile             : ${CVC4_BUILD_PROFILE_STRING} (incremental)")
 685 else()
 686   message("Build profile             : ${CVC4_BUILD_PROFILE_STRING}")
 687 endif()
 688 message("")
 689 print_config("GPL                       :" ENABLE_GPL)
 690 print_config("Best configuration        :" ENABLE_BEST)
 691 print_config("Optimization level        :" OPTIMIZATION_LEVEL)
 692 message("")
 693 print_config("Assertions                :" ENABLE_ASSERTIONS)
 694 print_config("Debug symbols             :" ENABLE_DEBUG_SYMBOLS)
 695 print_config("Debug context mem mgr     :" ENABLE_DEBUG_CONTEXT_MM)
 696 message("")
 697 print_config("Dumping                   :" ENABLE_DUMPING)
 698 print_config("Muzzle                    :" ENABLE_MUZZLE)
 699 print_config("Proofs                    :" ENABLE_PROOFS)
 700 print_config("Statistics                :" ENABLE_STATISTICS)
 701 print_config("Tracing                   :" ENABLE_TRACING)
 702 message("")
 703 print_config("ASan                      :" ENABLE_ASAN)
 704 print_config("UBSan                     :" ENABLE_UBSAN)
 705 print_config("TSan                      :" ENABLE_TSAN)
 706 print_config("Coverage (gcov)           :" ENABLE_COVERAGE)
 707 print_config("Profiling (gprof)         :" ENABLE_PROFILING)
 708 print_config("Unit tests                :" ENABLE_UNIT_TESTING)
 709 print_config("Valgrind                  :" ENABLE_VALGRIND)
 710 message("")
 711 print_config("Shared libs               :" ENABLE_SHARED)
 712 print_config("Static binary             :" ENABLE_STATIC_BINARY)
 713 print_config("Python bindings           :" BUILD_BINDINGS_PYTHON)
 714 print_config("Java bindings             :" BUILD_BINDINGS_JAVA)
 715 print_config("Python2                   :" USE_PYTHON2)
 716 message("")
 717 print_config("ABC                       :" USE_ABC)
 718 print_config("CaDiCaL                   :" USE_CADICAL)
 719 print_config("CryptoMiniSat             :" USE_CRYPTOMINISAT)
 720 print_config("drat2er                   :" USE_DRAT2ER)
 721 print_config("GLPK                      :" USE_GLPK)
 722 print_config("Kissat                    :" USE_KISSAT)
 723 print_config("LFSC                      :" USE_LFSC)
 724 print_config("LibPoly                   :" USE_POLY)
 725 message("")
 726 print_config("BUILD_LIB_ONLY            :" BUILD_LIB_ONLY)
 727
 728 if(CVC4_USE_CLN_IMP)
 729   message("MP library                : cln")
 730 else()
 731   message("MP library                : gmp")
 732 endif()
 733 print_config("Editline                  :" ${USE_EDITLINE})
 734 print_config("SymFPU                    :" ${USE_SYMFPU})
 735 message("")
 736 if(ABC_DIR)
 737   message("ABC dir                   : ${ABC_DIR}")
 738 endif()
 739 if(ANTLR_DIR)
 740   message("ANTLR dir                 : ${ANTLR_DIR}")
 741 endif()
 742 if(CADICAL_DIR)
 743   message("CADICAL dir               : ${CADICAL_DIR}")
 744 endif()
 745 if(CRYPTOMINISAT_DIR)
 746   message("CRYPTOMINISAT dir         : ${CRYPTOMINISAT_DIR}")
 747 endif()
 748 if(DRAT2ER_DIR)
 749   message("DRAT2ER dir               : ${DRAT2ER_DIR}")
 750 endif()
 751 if(GLPK_DIR)
 752   message("GLPK dir                  : ${GLPK_DIR}")
 753 endif()
 754 if(GMP_DIR)
 755   message("GMP dir                   : ${GMP_DIR}")
 756 endif()
 757 if(KISSAT_DIR)
 758   message("KISSAT dir                : ${KISSAT_DIR}")
 759 endif()
 760 if(LFSC_DIR)
 761   message("LFSC dir                  : ${LFSC_DIR}")
 762 endif()
 763 if(POLY_DIR)
 764   message("LibPoly dir               : ${POLY_DIR}")
 765 endif()
 766 if(SYMFPU_DIR)
 767   message("SYMFPU dir                : ${SYMFPU_DIR}")
 768 endif()
 769 message("")
 770 message("CPPLAGS (-D...)           : ${CVC4_DEFINITIONS}")
 771 message("CXXFLAGS                  : ${CMAKE_CXX_FLAGS}")
 772 message("CFLAGS                    : ${CMAKE_C_FLAGS}")
 773 message("Linker flags              : ${CMAKE_EXE_LINKER_FLAGS}")
 774 message("")
 775 message("Install prefix            : ${CMAKE_INSTALL_PREFIX}")
 776 message("")
 777
 778 if(GPL_LIBS)
 779   message(
 780   "CVC4 license             : ${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 781   "\n"
 782   "\n"
 783   "Please note that CVC4 will be built against the following GPLed libraries:"
 784   "\n"
 785   "${GPL_LIBS}"
 786   "\n"
 787   "As these libraries are covered under the GPLv3, so is this build of CVC4."
 788   "\n"
 789   "CVC4 is also available to you under the terms of the (modified) BSD license."
 790   "\n"
 791   "If you prefer to license CVC4 under those terms, please configure CVC4 to"
 792   "\n"
 793   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 794   )
 795 else()
 796   message(
 797   "CVC4 license              : modified BSD"
 798   "\n"
 799   "\n"
 800   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 801   "\n"
 802   "it is covered by the (modified) BSD license.  This is, however, not the best"
 803   "\n"
 804   "performing configuration of CVC4.  To build against GPL'ed libraries which"
 805   "\n"
 806   "improve CVC4's performance, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 807   )
 808 endif()
 809
 810 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 811   set(BUILD_COMMAND_NAME "ninja")
 812 else()
 813   set(BUILD_COMMAND_NAME "make")
 814 endif()
 815
 816 message("")
 817 message("Now just type '${BUILD_COMMAND_NAME}', "
 818         "followed by '${BUILD_COMMAND_NAME} check' "
 819         "or '${BUILD_COMMAND_NAME} install'.")
 820 message("")