CMakeLists.txt

   1 ###############################################################################
   2 # Top contributors (to current version):
   3 #   Aina Niemetz, Mathias Preiner, Gereon Kremer
   4 #
   5 # This file is part of the cvc5 project.
   6 #
   7 # Copyright (c) 2009-2021 by the authors listed in the file AUTHORS
   8 # in the top-level source directory and their institutional affiliations.
   9 # All rights reserved.  See the file COPYING in the top-level source
  10 # directory for licensing information.
  11 # #############################################################################
  12 #
  13 # The build system configuration.
  14 ##
  15
  16 cmake_minimum_required(VERSION 3.9)
  17
  18 #-----------------------------------------------------------------------------#
  19 # Project configuration
  20
  21 project(cvc5)
  22
  23 include(CheckIPOSupported)
  24 include(GNUInstallDirs)
  25 set(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  26
  27 include(version)
  28
  29 set(CMAKE_C_STANDARD 99)
  30 set(CMAKE_CXX_STANDARD 17)
  31 set(CMAKE_CXX_EXTENSIONS OFF)
  32 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  33 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  34 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  35
  36 # Generate compile_commands.json, which can be used for various code completion
  37 # plugins.
  38 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  39
  40 #-----------------------------------------------------------------------------#
  41 # Policies
  42
  43 # Required for FindGLPK since it sets CMAKE_REQUIRED_LIBRARIES
  44 if(POLICY CMP0075)
  45   cmake_policy(SET CMP0075 NEW)
  46 endif()
  47
  48 #-----------------------------------------------------------------------------#
  49 # Tell CMake where to find our dependencies
  50
  51 if(ABC_DIR)
  52   list(APPEND CMAKE_PREFIX_PATH "${ABC_DIR}")
  53 endif()
  54 if(GLPK_DIR)
  55   list(APPEND CMAKE_PREFIX_PATH "${GLPK_DIR}")
  56 endif()
  57
  58 # By default the contrib/get-* scripts install dependencies to deps/install.
  59 list(APPEND CMAKE_PREFIX_PATH "${PROJECT_SOURCE_DIR}/deps/install")
  60
  61 #-----------------------------------------------------------------------------#
  62
  63 include(Helpers)
  64
  65 #-----------------------------------------------------------------------------#
  66 # User options
  67
  68 # License
  69 option(ENABLE_GPL "Enable GPL dependencies")
  70
  71 # General build options
  72 #
  73 # >> 3-valued: IGNORE ON OFF
  74 #    > allows to detect if set by user (default: IGNORE)
  75 #    > only necessary for options set for build types
  76 cvc5_option(ENABLE_ASAN           "Enable ASAN build")
  77 cvc5_option(ENABLE_UBSAN          "Enable UBSan build")
  78 cvc5_option(ENABLE_TSAN           "Enable TSan build")
  79 cvc5_option(ENABLE_ASSERTIONS     "Enable assertions")
  80 cvc5_option(ENABLE_COMP_INC_TRACK
  81             "Enable optimizations for incremental SMT-COMP tracks")
  82 cvc5_option(ENABLE_DEBUG_SYMBOLS  "Enable debug symbols")
  83 cvc5_option(ENABLE_DUMPING        "Enable dumping")
  84 cvc5_option(ENABLE_MUZZLE         "Suppress ALL non-result output")
  85 cvc5_option(ENABLE_STATISTICS     "Enable statistics")
  86 cvc5_option(ENABLE_TRACING        "Enable tracing")
  87 cvc5_option(ENABLE_UNIT_TESTING   "Enable unit testing")
  88 cvc5_option(ENABLE_VALGRIND       "Enable valgrind instrumentation")
  89 cvc5_option(ENABLE_STATIC_BUILD   "Enable building static libraries and binary")
  90 cvc5_option(ENABLE_AUTO_DOWNLOAD  "Enable automatic download of dependencies")
  91 cvc5_option(ENABLE_IPO            "Enable interprocedural optimization")
  92 # >> 2-valued: ON OFF
  93 #    > for options where we don't need to detect if set by user (default: OFF)
  94 option(ENABLE_BEST             "Enable dependencies known to give best performance")
  95 option(ENABLE_COVERAGE         "Enable support for gcov coverage testing")
  96 option(ENABLE_DEBUG_CONTEXT_MM "Enable the debug context memory manager")
  97 option(ENABLE_PROFILING        "Enable support for gprof profiling")
  98
  99 # Optional dependencies
 100 #
 101 # >> 3-valued: IGNORE ON OFF
 102 #    > allows to detect if set by user (default: IGNORE)
 103 #    > only necessary for options set for ENABLE_BEST
 104 cvc5_option(USE_ABC           "Use ABC for AIG bit-blasting")
 105 cvc5_option(USE_CLN           "Use CLN instead of GMP")
 106 cvc5_option(USE_CRYPTOMINISAT "Use CryptoMiniSat SAT solver")
 107 cvc5_option(USE_GLPK          "Use GLPK simplex solver")
 108 cvc5_option(USE_KISSAT        "Use Kissat SAT solver")
 109 cvc5_option(USE_EDITLINE      "Use Editline for better interactive support")
 110 # >> 2-valued: ON OFF
 111 #    > for options where we don't need to detect if set by user (default: OFF)
 112 option(USE_POLY               "Use LibPoly for polynomial arithmetic")
 113 option(USE_COCOA              "Use CoCoALib for further polynomial operations")
 114 option(USE_PYTHON2            "Force Python 2 (deprecated)")
 115
 116 # Custom install directories for dependencies
 117 # If no directory is provided by the user, we first check if the dependency was
 118 # installed via the corresponding contrib/get-* script and if not found, we
 119 # check the intalled system version. If the user provides a directory we
 120 # immediately fail if the dependency was not found at the specified location.
 121 set(ABC_DIR           "" CACHE STRING "Set ABC install directory")
 122 set(GLPK_DIR          "" CACHE STRING "Set GLPK install directory")
 123
 124 # Prepend binaries with prefix on make install
 125 set(PROGRAM_PREFIX    "" CACHE STRING "Program prefix on make install")
 126
 127 # Supported language bindings based on new C++ API
 128 option(BUILD_BINDINGS_PYTHON "Build Python bindings based on new C++ API ")
 129 option(BUILD_BINDINGS_JAVA "Build Java bindings based on new C++ API ")
 130
 131 # Api documentation
 132 option(BUILD_DOCS "Build Api documentation")
 133
 134 #-----------------------------------------------------------------------------#
 135 # Internal cmake variables
 136
 137 set(OPTIMIZATION_LEVEL 3)
 138 set(GPL_LIBS "")
 139
 140 #-----------------------------------------------------------------------------#
 141 # Determine number of threads available, used to configure (default) parallel
 142 # execution of custom test targets (can be overriden with ARGS=-jN).
 143
 144 include(ProcessorCount)
 145 ProcessorCount(CTEST_NTHREADS)
 146 if(CTEST_NTHREADS EQUAL 0)
 147   set(CTEST_NTHREADS 1)
 148 endif()
 149
 150 #-----------------------------------------------------------------------------#
 151 # Build types
 152
 153 # Note: Module CodeCoverage requires the name of the debug build to conform
 154 #       to cmake standards (first letter uppercase).
 155 set(BUILD_TYPES Production Debug Testing Competition)
 156
 157 if(ENABLE_ASAN OR ENABLE_UBSAN OR ENABLE_TSAN)
 158   set(CMAKE_BUILD_TYPE Debug)
 159 endif()
 160
 161 # Set the default build type to Production
 162 if(NOT CMAKE_BUILD_TYPE)
 163   set(CMAKE_BUILD_TYPE
 164       Production CACHE STRING "Options are: ${BUILD_TYPES}" FORCE)
 165   # Provide drop down menu options in cmake-gui
 166   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${BUILD_TYPES})
 167 endif()
 168
 169 # Check if specified build type is valid.
 170 list(FIND BUILD_TYPES ${CMAKE_BUILD_TYPE} FOUND_BUILD_TYPE)
 171 if(${FOUND_BUILD_TYPE} EQUAL -1)
 172   message(FATAL_ERROR
 173     "'${CMAKE_BUILD_TYPE}' is not a valid build type. "
 174     "Available builds are: ${BUILD_TYPES}")
 175 endif()
 176
 177 message(STATUS "Building ${CMAKE_BUILD_TYPE} build")
 178 include(Config${CMAKE_BUILD_TYPE})
 179
 180 #-----------------------------------------------------------------------------#
 181 # Compiler flags
 182
 183 add_check_c_cxx_flag("-O${OPTIMIZATION_LEVEL}")
 184 add_check_c_cxx_flag("-Wall")
 185 add_check_c_cxx_supression_flag("-Wno-unused-private-field")
 186 add_check_c_flag("-fexceptions")
 187 add_check_cxx_flag("-Wsuggest-override")
 188 add_check_cxx_flag("-Wnon-virtual-dtor")
 189 add_check_c_cxx_flag("-Wimplicit-fallthrough")
 190 add_check_c_cxx_flag("-Wshadow")
 191
 192 # Assume no dynamic initialization of thread-local variables in non-defining
 193 # translation units. This option should result in better performance and works
 194 # around crashing issues with our Windows build.
 195 add_check_cxx_flag("-fno-extern-tls-init")
 196
 197 # Temporarily disable -Wclass-memaccess to suppress 'no trivial copy-assignment'
 198 # cdlist.h warnings. Remove when fixed.
 199 add_check_cxx_supression_flag("-Wno-class-memaccess")
 200
 201 if (WIN32)
 202   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--stack,100000000")
 203 endif ()
 204
 205 #-----------------------------------------------------------------------------#
 206 # Use ld.gold if available
 207
 208 execute_process(COMMAND ${CMAKE_C_COMPILER}
 209                 -fuse-ld=gold
 210                 -Wl,--version ERROR_QUIET OUTPUT_VARIABLE LD_VERSION)
 211 if ("${LD_VERSION}" MATCHES "GNU gold")
 212   string(APPEND CMAKE_EXE_LINKER_FLAGS " -fuse-ld=gold")
 213   string(APPEND CMAKE_SHARED_LINKER_FLAGS " -fuse-ld=gold")
 214   string(APPEND CMAKE_MODULE_LINKER_FLAGS " -fuse-ld=gold")
 215   message(STATUS "Using GNU gold linker.")
 216 endif ()
 217
 218 #-----------------------------------------------------------------------------#
 219 # Use interprocedural optimization if requested
 220
 221 if(ENABLE_IPO)
 222   set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
 223 endif()
 224
 225 #-----------------------------------------------------------------------------#
 226
 227 # Only enable unit testing if assertions are enabled. Otherwise, unit tests
 228 # that expect AssertionException to be thrown will fail.
 229 if(NOT ENABLE_ASSERTIONS)
 230   message(STATUS "Disabling unit tests since assertions are disabled.")
 231   set(ENABLE_UNIT_TESTING OFF)
 232 endif()
 233
 234 #-----------------------------------------------------------------------------#
 235 # Shared/static libraries
 236
 237 # Embed the installation prefix as an RPATH in the executable such that the
 238 # linker can find our libraries (such as libcvc5parser) when executing the
 239 # cvc5 binary. This is for example useful when installing cvc5 with a custom
 240 # prefix on macOS (e.g. when using homebrew in a non-standard directory). If
 241 # we do not set this option, then the linker will not be able to find the
 242 # required libraries when trying to run cvc5.
 243 #
 244 # Also embed the installation prefix of the installed contrib libraries as an
 245 # RPATH. This allows to install a dynamically linked binary that depends on
 246 # dynamically linked libraries. This is dangerous, as the installed binary
 247 # breaks if the contrib library is removed or changes in other ways, we thus
 248 # print a big warning and only allow if installing to a custom installation
 249 # prefix.
 250 #
 251 # More information on RPATH in CMake:
 252 # https://gitlab.kitware.com/cmake/community/wikis/doc/cmake/RPATH-handling
 253 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR};${PROJECT_SOURCE_DIR}/deps/install/lib")
 254
 255 # Set visibility to default if unit tests are enabled
 256 if(ENABLE_UNIT_TESTING)
 257   set(CMAKE_CXX_VISIBILITY_PRESET default)
 258   set(CMAKE_VISIBILITY_INLINES_HIDDEN 0)
 259 endif()
 260
 261 #-----------------------------------------------------------------------------#
 262 # Enable the ctest testing framework
 263
 264 # This needs to be enabled here rather than in subdirectory test in order to
 265 # allow calling ctest from the root build directory.
 266 enable_testing()
 267
 268 #-----------------------------------------------------------------------------#
 269 # Check options, find packages and configure build.
 270
 271 if(USE_PYTHON2)
 272   find_package(PythonInterp 2.7 REQUIRED)
 273 else()
 274   find_package(PythonInterp 3 REQUIRED)
 275 endif()
 276
 277 find_package(GMP 6.1 REQUIRED)
 278
 279 if(ENABLE_ASAN)
 280   # -fsanitize=address requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 281   # otherwise the -fsanitize=address check will fail while linking.
 282   set(CMAKE_REQUIRED_FLAGS -fsanitize=address)
 283   add_required_c_cxx_flag("-fsanitize=address")
 284   unset(CMAKE_REQUIRED_FLAGS)
 285   add_required_c_cxx_flag("-fno-omit-frame-pointer")
 286   add_check_c_cxx_flag("-fsanitize-recover=address")
 287 endif()
 288
 289 if(ENABLE_UBSAN)
 290   add_required_c_cxx_flag("-fsanitize=undefined")
 291   add_definitions(-DCVC5_USE_UBSAN)
 292 endif()
 293
 294 if(ENABLE_TSAN)
 295   # -fsanitize=thread requires CMAKE_REQUIRED_FLAGS to be explicitely set,
 296   # otherwise the -fsanitize=thread check will fail while linking.
 297   set(CMAKE_REQUIRED_FLAGS -fsanitize=thread)
 298   add_required_c_cxx_flag("-fsanitize=thread")
 299   unset(CMAKE_REQUIRED_FLAGS)
 300 endif()
 301
 302 if(ENABLE_ASSERTIONS)
 303   add_definitions(-DCVC5_ASSERTIONS)
 304 else()
 305   add_definitions(-DNDEBUG)
 306 endif()
 307
 308 if(ENABLE_COVERAGE)
 309   include(CodeCoverage)
 310   APPEND_COVERAGE_COMPILER_FLAGS()
 311   add_definitions(-DCVC5_COVERAGE)
 312   # Note: The ctest command returns a non-zero exit code if tests fail or run
 313   # into a timeout. As a consequence, the coverage report is not generated. To
 314   # prevent this we always return with exit code 0 after the ctest command has
 315   # finished.
 316   setup_target_for_coverage_gcovr_html(
 317     NAME coverage-test
 318     EXECUTABLE
 319       ctest -j${CTEST_NTHREADS} -LE "example"
 320         --output-on-failure $$ARGS || exit 0
 321     DEPENDS
 322       build-tests)
 323
 324   # Adds targets `coverage` and `coverage-reset` for manually generating
 325   # coverage reports for specific executions.
 326   #
 327   # Target coverage-reset resets all the coverage counters to zero, while
 328   # target coverage will generate a coverage report for all executions since
 329   # the last coverage-reset.
 330   setup_target_for_coverage_lcov_no_executable(
 331     NAME coverage
 332     DEPENDENCIES cvc5-bin)
 333 endif()
 334
 335 if(ENABLE_DEBUG_CONTEXT_MM)
 336   add_definitions(-DCVC5_DEBUG_CONTEXT_MEMORY_MANAGER)
 337 endif()
 338
 339 if(ENABLE_DEBUG_SYMBOLS)
 340   add_check_c_cxx_flag("-ggdb3")
 341 endif()
 342
 343 if(ENABLE_COMP_INC_TRACK)
 344   add_definitions(-DCVC5_SMTCOMP_APPLICATION_TRACK)
 345 endif()
 346
 347 if(ENABLE_MUZZLE)
 348   add_definitions(-DCVC5_MUZZLE)
 349 endif()
 350
 351 if(ENABLE_DUMPING)
 352   add_definitions(-DCVC5_DUMPING)
 353 endif()
 354
 355 if(ENABLE_PROFILING)
 356   add_definitions(-DCVC5_PROFILING)
 357   add_check_c_cxx_flag("-pg")
 358 endif()
 359
 360 if(ENABLE_TRACING)
 361   add_definitions(-DCVC5_TRACING)
 362 endif()
 363
 364 if(ENABLE_STATISTICS)
 365   add_definitions(-DCVC5_STATISTICS_ON)
 366 endif()
 367
 368 if(ENABLE_VALGRIND)
 369   find_package(Valgrind REQUIRED)
 370   add_definitions(-DCVC5_VALGRIND)
 371 endif()
 372
 373 if(USE_ABC)
 374   find_package(ABC REQUIRED)
 375   add_definitions(-DCVC5_USE_ABC ${ABC_ARCH_FLAGS})
 376 endif()
 377
 378 find_package(CaDiCaL REQUIRED)
 379
 380 if(USE_CLN)
 381   set(GPL_LIBS "${GPL_LIBS} cln")
 382   find_package(CLN 1.2.2 REQUIRED)
 383   set(CVC5_USE_CLN_IMP 1)
 384   set(CVC5_USE_GMP_IMP 0)
 385 else()
 386   set(CVC5_USE_CLN_IMP 0)
 387   set(CVC5_USE_GMP_IMP 1)
 388 endif()
 389
 390 if(USE_CRYPTOMINISAT)
 391   # CryptoMiniSat requires pthreads support
 392   set(THREADS_PREFER_PTHREAD_FLAG ON)
 393   find_package(Threads REQUIRED)
 394   if(THREADS_HAVE_PTHREAD_ARG)
 395     add_c_cxx_flag(-pthread)
 396   endif()
 397   find_package(CryptoMiniSat 5.8 REQUIRED)
 398   add_definitions(-DCVC5_USE_CRYPTOMINISAT)
 399 endif()
 400
 401 if(USE_GLPK)
 402   set(GPL_LIBS "${GPL_LIBS} glpk")
 403   find_package(GLPK REQUIRED)
 404   add_definitions(-DCVC5_USE_GLPK)
 405 endif()
 406
 407 if(USE_KISSAT)
 408   find_package(Kissat REQUIRED)
 409   add_definitions(-DCVC5_USE_KISSAT)
 410 endif()
 411
 412 if(USE_POLY)
 413   find_package(Poly REQUIRED)
 414   add_definitions(-DCVC5_USE_POLY)
 415   set(CVC5_USE_POLY_IMP 1)
 416 else()
 417   set(CVC5_USE_POLY_IMP 0)
 418 endif()
 419
 420 if(USE_COCOA)
 421   find_package(CoCoA REQUIRED 0.99711)
 422   add_definitions(-DCVC5_USE_COCOA)
 423 endif()
 424
 425 if(USE_EDITLINE)
 426   find_package(Editline REQUIRED)
 427   set(HAVE_LIBEDITLINE 1)
 428   if(Editline_COMPENTRY_FUNC_RETURNS_CHARPTR)
 429     set(EDITLINE_COMPENTRY_FUNC_RETURNS_CHARP 1)
 430   endif()
 431 endif()
 432
 433 find_package(SymFPU REQUIRED)
 434
 435 if(GPL_LIBS)
 436   if(NOT ENABLE_GPL)
 437     message(FATAL_ERROR
 438       "Bad configuration detected: BSD-licensed code only, but also requested "
 439       "GPLed libraries: ${GPL_LIBS}")
 440   endif()
 441   set(CVC5_GPL_DEPS 1)
 442 endif()
 443
 444 #-----------------------------------------------------------------------------#
 445 # Provide targets to inspect iwyu suggestions
 446
 447 include(IWYU)
 448 include(fuzzing-murxla)
 449
 450 #-----------------------------------------------------------------------------#
 451
 452 include(ConfigureCvc5)
 453 if(ENABLE_STATIC_BUILD)
 454   set(CVC5_STATIC_BUILD ON)
 455 endif()
 456
 457 #-----------------------------------------------------------------------------#
 458 # Add subdirectories
 459
 460 add_subdirectory(src)
 461
 462 if(BUILD_BINDINGS_PYTHON)
 463   set(BUILD_BINDINGS_PYTHON_VERSION ${PYTHON_VERSION_MAJOR})
 464   add_subdirectory(src/api/python)
 465 endif()
 466
 467 if(BUILD_BINDINGS_JAVA)
 468   add_subdirectory(src/api/java)
 469   message(WARNING "Java API is currently under development.")
 470 endif()
 471
 472 if(BUILD_DOCS)
 473   add_subdirectory(docs)
 474 endif()
 475
 476 add_subdirectory(test)
 477
 478 include(target-graphs)
 479
 480 #-----------------------------------------------------------------------------#
 481 # Package configuration
 482 #
 483 # Export cvc5 targets to support find_package(cvc5) in other cmake projects.
 484
 485 include(CMakePackageConfigHelpers)
 486
 487 # If we install a dynamically linked binary that also uses dynamically used
 488 # libraries from deps/install/lib, we need to be cautious. Changing these
 489 # shared libraries from deps/install/lib most probably breaks the binary.
 490 # We only allow such an installation for custom installation prefixes
 491 # (in the assumption that only reasonably experienced users use this and
 492 # also that custom installation prefixes are not used for longer periods of
 493 # time anyway). Also, we print a big warning with further instructions.
 494 if(NOT ENABLE_STATIC_BUILD)
 495   # Get the libraries that cvc5 links against
 496   get_target_property(libs cvc5-shared INTERFACE_LINK_LIBRARIES)
 497   set(LIBS_SHARED_FROM_DEPS "")
 498   foreach(lib ${libs})
 499     # Filter out those that are linked dynamically and come from deps/install
 500     if(lib MATCHES ".*/deps/install/lib/.*\.so")
 501       list(APPEND LIBS_SHARED_FROM_DEPS ${lib})
 502     endif()
 503   endforeach()
 504   list(LENGTH LIBS_SHARED_FROM_DEPS list_len)
 505   # Check if we actually use such "dangerous" libraries
 506   if(list_len GREATER 0)
 507     # Print a generic warning
 508     install(CODE "message(WARNING \"You are installing a dynamically linked \
 509     binary of cvc5 which may be a problem if you are using any dynamically \
 510     linked third-party library that you obtained through one of the \
 511     contrib/get-xxx scripts. The binary uses the rpath mechanism to find these \
 512     locally, hence executing such a contrib script removing the \
 513     \\\"deps/install\\\" folder most probably breaks the installed binary! \
 514     Consider installing the dynamically linked dependencies on your system \
 515     manually or link cvc5 statically.\")")
 516     # Print the libraries in question
 517     foreach(lib ${LIBS_SHARED_FROM_DEPS})
 518       install(CODE "message(WARNING \"The following library is used by the cvc5 binary: ${lib}\")")
 519     endforeach()
 520     # Check if we use a custom installation prefix
 521     if(CMAKE_INSTALL_PREFIX STREQUAL "/usr/local")
 522       install(CODE "message(FATAL_ERROR \"To avoid installing a \
 523       soon-to-be-broken binary, system-wide installation is disabled if the \
 524       binary depends on locally-built shared libraries.\")")
 525     else()
 526       install(CODE "message(WARNING \"You have selected a custom install \
 527       directory ${CMAKE_INSTALL_PREFIX}, so we expect you understood the \
 528       previous warning and know what you are doing.\")")
 529     endif()
 530   endif()
 531 endif()
 532
 533 install(EXPORT cvc5-targets
 534   FILE cvc5Targets.cmake
 535   NAMESPACE cvc5::
 536   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5)
 537
 538 configure_package_config_file(
 539   ${CMAKE_SOURCE_DIR}/cmake/cvc5Config.cmake.in
 540   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 541   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 542   PATH_VARS CMAKE_INSTALL_LIBDIR
 543 )
 544
 545 write_basic_package_version_file(
 546   ${CMAKE_CURRENT_BINARY_DIR}/cvc5ConfigVersion.cmake
 547   VERSION ${CVC5_VERSION}
 548   COMPATIBILITY ExactVersion
 549 )
 550
 551 install(FILES
 552   ${CMAKE_BINARY_DIR}/cmake/cvc5Config.cmake
 553   ${CMAKE_BINARY_DIR}/cvc5ConfigVersion.cmake
 554   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/cvc5
 555 )
 556
 557
 558 #-----------------------------------------------------------------------------#
 559 # Print build configuration
 560
 561 # Set colors.
 562 if(NOT WIN32)
 563   string(ASCII 27 Esc)
 564   set(Green "${Esc}[32m")
 565   set(Blue "${Esc}[1;34m")
 566   set(ResetColor "${Esc}[m")
 567 endif()
 568
 569 # Convert build type to lower case.
 570 string(TOLOWER ${CMAKE_BUILD_TYPE} CVC5_BUILD_PROFILE_STRING)
 571
 572 # Get all definitions added via add_definitions.
 573 get_directory_property(CVC5_DEFINITIONS COMPILE_DEFINITIONS)
 574 string(REPLACE ";" " " CVC5_DEFINITIONS "${CVC5_DEFINITIONS}")
 575
 576 message("")
 577 print_info("cvc5 ${CVC5_VERSION}")
 578 message("")
 579 if(ENABLE_COMP_INC_TRACK)
 580   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING} (incremental)")
 581 else()
 582   print_config("Build profile             " "${CVC5_BUILD_PROFILE_STRING}")
 583 endif()
 584 message("")
 585 print_config("GPL                       " ${ENABLE_GPL})
 586 print_config("Best configuration        " ${ENABLE_BEST})
 587 message("")
 588 print_config("Assertions                " ${ENABLE_ASSERTIONS})
 589 print_config("Debug symbols             " ${ENABLE_DEBUG_SYMBOLS})
 590 print_config("Debug context mem mgr     " ${ENABLE_DEBUG_CONTEXT_MM})
 591 message("")
 592 print_config("Dumping                   " ${ENABLE_DUMPING})
 593 print_config("Muzzle                    " ${ENABLE_MUZZLE})
 594 print_config("Statistics                " ${ENABLE_STATISTICS})
 595 print_config("Tracing                   " ${ENABLE_TRACING})
 596 message("")
 597 print_config("ASan                      " ${ENABLE_ASAN})
 598 print_config("UBSan                     " ${ENABLE_UBSAN})
 599 print_config("TSan                      " ${ENABLE_TSAN})
 600 print_config("Coverage (gcov)           " ${ENABLE_COVERAGE})
 601 print_config("Profiling (gprof)         " ${ENABLE_PROFILING})
 602 print_config("Unit tests                " ${ENABLE_UNIT_TESTING})
 603 print_config("Valgrind                  " ${ENABLE_VALGRIND})
 604 message("")
 605 print_config("Static build              " ${ENABLE_STATIC_BUILD})
 606 print_config("Python bindings           " ${BUILD_BINDINGS_PYTHON})
 607 print_config("Java bindings             " ${BUILD_BINDINGS_JAVA})
 608 print_config("Python2                   " ${USE_PYTHON2})
 609 print_config("Interprocedural opt.      " ${ENABLE_IPO})
 610 message("")
 611 print_config("ABC                       " ${USE_ABC})
 612 print_config("CryptoMiniSat             " ${USE_CRYPTOMINISAT} FOUND_SYSTEM ${CryptoMiniSat_FOUND_SYSTEM})
 613 print_config("GLPK                      " ${USE_GLPK})
 614 print_config("Kissat                    " ${USE_KISSAT} FOUND_SYSTEM ${Kissat_FOUND_SYSTEM})
 615 print_config("LibPoly                   " ${USE_POLY} FOUND_SYSTEM ${Poly_FOUND_SYSTEM})
 616 print_config("CoCoALib                  " ${USE_COCOA} FOUND_SYSTEM ${CoCoA_FOUND_SYSTEM})
 617
 618 if(CVC5_USE_CLN_IMP)
 619   print_config("MP library                " "cln" FOUND_SYSTEM ${CLN_FOUND_SYSTEM})
 620 else()
 621   print_config("MP library                " "gmp" FOUND_SYSTEM ${GMP_FOUND_SYSTEM})
 622 endif()
 623 print_config("Editline                  " ${USE_EDITLINE})
 624 message("")
 625 print_config("Api docs                  " ${BUILD_DOCS})
 626 message("")
 627 if(ABC_DIR)
 628   print_config("ABC dir                   " ${ABC_DIR})
 629 endif()
 630 if(GLPK_DIR)
 631   print_config("GLPK dir                  " ${GLPK_DIR})
 632 endif()
 633 message("")
 634 print_config("CPPLAGS (-D...)" "${CVC5_DEFINITIONS}")
 635 print_config("CXXFLAGS       " "${CMAKE_CXX_FLAGS}")
 636 print_config("CFLAGS         " "${CMAKE_C_FLAGS}")
 637 print_config("Linker flags   " "${CMAKE_EXE_LINKER_FLAGS}")
 638 message("")
 639 print_config("Install prefix " "${CMAKE_INSTALL_PREFIX}")
 640 message("")
 641
 642 if(GPL_LIBS)
 643   message(
 644   "${Blue}cvc5 license: "
 645   "${Yellow}GPLv3 (due to optional libraries; see below)${ResetColor}"
 646   "\n"
 647   "\n"
 648   "Please note that cvc5 will be built against the following GPLed libraries:"
 649   "\n"
 650   "${GPL_LIBS}"
 651   "\n"
 652   "As these libraries are covered under the GPLv3, so is this build of cvc5."
 653   "\n"
 654   "cvc5 is also available to you under the terms of the (modified) BSD license."
 655   "\n"
 656   "If you prefer to license cvc5 under those terms, please configure cvc5 to"
 657   "\n"
 658   "disable all optional GPLed library dependencies (-DENABLE_BSD_ONLY=ON)."
 659   )
 660 else()
 661   message(
 662   "${Blue}cvc5 license:${ResetColor} modified BSD"
 663   "\n"
 664   "\n"
 665   "Note that this configuration is NOT built against any GPL'ed libraries, so"
 666   "\n"
 667   "it is covered by the (modified) BSD license.  To build against GPL'ed"
 668   "\n"
 669   "libraries which can improve cvc5's performance on arithmetic and bitvector"
 670   "\n"
 671   "logics, re-configure with '-DENABLE_GPL -DENABLE_BEST'."
 672   )
 673 endif()
 674
 675 if("${CMAKE_GENERATOR}" STREQUAL "Ninja")
 676   set(BUILD_COMMAND_NAME "ninja")
 677 else()
 678   set(BUILD_COMMAND_NAME "make")
 679 endif()
 680
 681 message("")
 682 message("Now just type '${BUILD_COMMAND_NAME}', "
 683         "followed by '${BUILD_COMMAND_NAME} check' "
 684         "or '${BUILD_COMMAND_NAME} install'.")
 685 message("")