binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_ENABLE(targets,
  17 [  --enable-targets        alternative target configurations],
  18 [case "${enableval}" in
  19   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  20             ;;
  21   no)       enable_targets= ;;
  22   *)        enable_targets=$enableval ;;
  23 esac])dnl
  24 AC_ARG_ENABLE(commonbfdlib,
  25 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  26 [case "${enableval}" in
  27   yes) commonbfdlib=true ;;
  28   no)  commonbfdlib=false ;;
  29   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  30 esac])dnl
  31
  32 AM_BINUTILS_WARNINGS
  33
  34 AM_CONFIG_HEADER(config.h:config.in)
  35
  36 if test -z "$target" ; then
  37     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  38 fi
  39 if test -z "$host" ; then
  40     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  41 fi
  42
  43 AC_PROG_CC
  44
  45 AC_PROG_YACC
  46 AM_PROG_LEX
  47
  48 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW"
  49 CY_GNU_GETTEXT
  50
  51 AM_MAINTAINER_MODE
  52 AC_EXEEXT
  53 if test -n "$EXEEXT"; then
  54   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  55             [Does the platform use an executable suffix?])
  56 fi
  57 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  58                    [Suffix used for executables, if any.])
  59
  60 # host-specific stuff:
  61
  62 HDEFINES=
  63
  64 . ${srcdir}/../bfd/configure.host
  65
  66 AC_SUBST(HDEFINES)
  67 AR=${AR-ar}
  68 AC_SUBST(AR)
  69 AC_PROG_RANLIB
  70 AC_PROG_INSTALL
  71
  72 BFD_CC_FOR_BUILD
  73
  74 DEMANGLER_NAME=c++filt
  75 case "${host}" in
  76   *-*-go32* | *-*-msdos*)
  77     DEMANGLER_NAME=cxxfilt
  78 esac
  79 AC_SUBST(DEMANGLER_NAME)
  80
  81 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h)
  82 AC_HEADER_SYS_WAIT
  83 AC_FUNC_ALLOCA
  84 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  85
  86 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  87 # needs to be defined for it
  88 AC_MSG_CHECKING([for fopen64])
  89 AC_CACHE_VAL(bu_cv_have_fopen64,
  90 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  91 bu_cv_have_fopen64=yes,
  92 [saved_CPPFLAGS=$CPPFLAGS
  93  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
  94  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
  95 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
  96 bu_cv_have_fopen64=no)
  97  CPPFLAGS=$saved_CPPFLAGS])])
  98 AC_MSG_RESULT($bu_cv_have_fopen64)
  99 if test "$bu_cv_have_fopen64" != no; then
 100   AC_DEFINE([HAVE_FOPEN64], 1,
 101             [Is fopen64 available?])
 102 fi
 103 AC_MSG_CHECKING([for stat64])
 104 AC_CACHE_VAL(bu_cv_have_stat64,
 105 [AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 106 bu_cv_have_stat64=yes,
 107 [saved_CPPFLAGS=$CPPFLAGS
 108  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 109  AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 110 bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 111 bu_cv_have_stat64=no)
 112  CPPFLAGS=$saved_CPPFLAGS])])
 113 AC_MSG_RESULT($bu_cv_have_stat64)
 114 if test "$bu_cv_have_stat64" != no; then
 115   AC_DEFINE([HAVE_STAT64], 1,
 116             [Is stat64 available?])
 117 fi
 118 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 119    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 120   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 121             [Enable LFS])
 122   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 123 fi
 124
 125 # Some systems have frexp only in -lm, not in -lc.
 126 AC_SEARCH_LIBS(frexp, m)
 127
 128 AC_MSG_CHECKING(for time_t in time.h)
 129 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 130 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 131 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 132 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 133 if test $bu_cv_decl_time_t_time_h = yes; then
 134   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 135             [Is the type time_t defined in <time.h>?])
 136 fi
 137
 138 AC_MSG_CHECKING(for time_t in sys/types.h)
 139 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 140 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 141 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 142 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 143 if test $bu_cv_decl_time_t_types_h = yes; then
 144   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 145             [Is the type time_t defined in <sys/types.h>?])
 146 fi
 147
 148 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 149 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 150 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 151 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 152 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 153 if test $bu_cv_decl_getopt_unistd_h = yes; then
 154   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 155             [Is the prototype for getopt in <unistd.h> in the expected format?])
 156 fi
 157
 158 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 159 # by default.
 160 AC_MSG_CHECKING([for utime.h])
 161 AC_CACHE_VAL(bu_cv_header_utime_h,
 162 [AC_TRY_COMPILE([#include <sys/types.h>
 163 #ifdef HAVE_TIME_H
 164 #include <time.h>
 165 #endif
 166 #include <utime.h>],
 167 [struct utimbuf s;],
 168 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 169 AC_MSG_RESULT($bu_cv_header_utime_h)
 170 if test $bu_cv_header_utime_h = yes; then
 171   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 172 fi
 173
 174 AC_CHECK_DECLS([fprintf, strstr, sbrk, getenv, environ, getc_unlocked])
 175
 176 BFD_BINARY_FOPEN
 177
 178 # target-specific stuff:
 179
 180 # Canonicalize the secondary target names.
 181 if test -n "$enable_targets"; then
 182     for targ in `echo $enable_targets | sed 's/,/ /g'`
 183     do
 184         result=`$ac_config_sub $targ 2>/dev/null`
 185         if test -n "$result"; then
 186             canon_targets="$canon_targets $result"
 187         else
 188             # Allow targets that config.sub doesn't recognize, like "all".
 189             canon_targets="$canon_targets $targ"
 190         fi
 191     done
 192 fi
 193
 194 all_targets=false
 195 BUILD_NLMCONV=
 196 NLMCONV_DEFS=
 197 BUILD_SRCONV=
 198 BUILD_DLLTOOL=
 199 DLLTOOL_DEFS=
 200 BUILD_WINDRES=
 201 BUILD_DLLWRAP=
 202 BUILD_MISC=
 203 OBJDUMP_DEFS=
 204
 205 for targ in $target $canon_targets
 206 do
 207     if test "x$targ" = "xall"; then
 208         all_targets=true
 209         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 210         BUILD_SRCONV='$(SRCONV_PROG)'
 211         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 212     else
 213         case $targ in
 214 changequote(,)dnl
 215         i[3-7]86*-*-netware*)
 216 changequote([,])dnl
 217           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 218           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 219           ;;
 220         alpha*-*-netware*)
 221           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 222           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 223           ;;
 224         powerpc*-*-netware*)
 225           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 226           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 227           ;;
 228         sparc*-*-netware*)
 229           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 230           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 231           ;;
 232         esac
 233         case $targ in
 234         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 235         esac
 236         case $targ in
 237         arm-epoc-pe*)
 238           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 239           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 240           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 241           ;;
 242         arm-*-pe* | arm-*-wince)
 243           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 244           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 245           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 246           ;;
 247         thumb-*-pe*)
 248           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 249           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 250           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 251           ;;
 252         arm*-* | xscale-* | strongarm-* | d10v-*)
 253           OBJDUMP_DEFS="-DDISASSEMBLER_NEEDS_RELOCS"
 254           ;;
 255 changequote(,)dnl
 256         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 257 changequote([,])dnl
 258           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 259           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 260           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 261           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 262           ;;
 263 changequote(,)dnl
 264         i[3-7]86-*-interix)
 265 changequote([,])dnl
 266           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 267           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 268           ;;
 269 changequote(,)dnl
 270         powerpc*-aix5.[01])
 271 changequote([,])dnl
 272           ;;
 273         powerpc*-aix5.*)
 274           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 275           ;;
 276         powerpc*-*-pe* | powerpc*-*-cygwin*)
 277           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 278           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 279           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 280           ;;
 281         sh*-*-pe)
 282           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 283           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 284           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 285           ;;
 286         mips*-*-pe)
 287           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 288           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 289           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 290           ;;
 291         mcore-*-pe)
 292           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 293           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 294           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 295           ;;
 296         mcore-*-elf)
 297           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 298           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 299           ;;
 300         esac
 301     fi
 302 done
 303
 304 if test "${with_windres+set}" = set; then
 305           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 306 fi
 307
 308 AC_SUBST(NLMCONV_DEFS)
 309 AC_SUBST(BUILD_NLMCONV)
 310 AC_SUBST(BUILD_SRCONV)
 311 AC_SUBST(BUILD_DLLTOOL)
 312 AC_SUBST(DLLTOOL_DEFS)
 313 AC_SUBST(BUILD_WINDRES)
 314 AC_SUBST(BUILD_DLLWRAP)
 315 AC_SUBST(BUILD_MISC)
 316 AC_SUBST(OBJDUMP_DEFS)
 317
 318 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 319
 320 targ=$target
 321 . $srcdir/../bfd/config.bfd
 322 if test "x$targ_underscore" = "xyes"; then
 323     UNDERSCORE=1
 324 else
 325     UNDERSCORE=0
 326 fi
 327 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 328  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 329
 330 # Emulation
 331 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 332 do
 333   # Canonicalize the secondary target names.
 334  result=`$ac_config_sub $targ_alias 2>/dev/null`
 335  if test -n "$result"; then
 336    targ=$result
 337  else
 338    targ=$targ_alias
 339  fi
 340
 341  . ${srcdir}/configure.tgt
 342
 343   EMULATION=$targ_emul
 344   EMULATION_VECTOR=$targ_emul_vector
 345 done
 346
 347 AC_SUBST(EMULATION)
 348 AC_SUBST(EMULATION_VECTOR)
 349
 350 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in,
 351 [
 352 case "x$CONFIG_FILES" in
 353 *) sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile ;;
 354 esac
 355 ])