binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ar.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  13
  14 AC_PROG_CC
  15 AC_GNU_SOURCE
  16 AC_USE_SYSTEM_EXTENSIONS
  17 AC_PROG_LIBTOOL
  18
  19 AC_ARG_ENABLE(targets,
  20 [  --enable-targets        alternative target configurations],
  21 [case "${enableval}" in
  22   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  23             ;;
  24   no)       enable_targets= ;;
  25   *)        enable_targets=$enableval ;;
  26 esac])dnl
  27 AC_ARG_ENABLE(commonbfdlib,
  28 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  29 [case "${enableval}" in
  30   yes) commonbfdlib=true ;;
  31   no)  commonbfdlib=false ;;
  32   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  33 esac])dnl
  34
  35 AM_BINUTILS_WARNINGS
  36
  37 AM_CONFIG_HEADER(config.h:config.in)
  38
  39 if test -z "$target" ; then
  40     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  41 fi
  42 if test -z "$host" ; then
  43     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  44 fi
  45
  46 AC_PROG_YACC
  47 AM_PROG_LEX
  48
  49 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW fi vi uk sk"
  50 ZW_GNU_GETTEXT_SISTER_DIR
  51 AM_PO_SUBDIRS
  52
  53 AM_MAINTAINER_MODE
  54 AM_CONDITIONAL(GENINSRC_NEVER, false)
  55 AC_EXEEXT
  56 if test -n "$EXEEXT"; then
  57   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  58             [Does the platform use an executable suffix?])
  59 fi
  60 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  61                    [Suffix used for executables, if any.])
  62
  63 # host-specific stuff:
  64
  65 HDEFINES=
  66
  67 . ${srcdir}/../bfd/configure.host
  68
  69 AC_SUBST(HDEFINES)
  70 AR=${AR-ar}
  71 AC_SUBST(AR)
  72 AC_PROG_RANLIB
  73 AC_PROG_INSTALL
  74
  75 BFD_CC_FOR_BUILD
  76
  77 DEMANGLER_NAME=c++filt
  78 case "${host}" in
  79   *-*-go32* | *-*-msdos*)
  80     DEMANGLER_NAME=cxxfilt
  81 esac
  82 AC_SUBST(DEMANGLER_NAME)
  83
  84 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  85 AC_HEADER_SYS_WAIT
  86 AC_FUNC_ALLOCA
  87 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  88 AC_CHECK_FUNC([mkstemp],
  89               AC_DEFINE([HAVE_MKSTEMP], 1,
  90               [Define to 1 if you have the `mkstemp' function.]))
  91 AC_CHECK_FUNC([mkdtemp],
  92               AC_DEFINE([HAVE_MKDTEMP], 1,
  93               [Define to 1 if you have the `mkdtemp' function.]))
  94
  95 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  96 # needs to be defined for it
  97 AC_MSG_CHECKING([for fopen64])
  98 AC_CACHE_VAL(bu_cv_have_fopen64,
  99 [AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 100 bu_cv_have_fopen64=yes,
 101 [saved_CPPFLAGS=$CPPFLAGS
 102  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 103  AC_TRY_LINK([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");],
 104 bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 105 bu_cv_have_fopen64=no)
 106  CPPFLAGS=$saved_CPPFLAGS])])
 107 AC_MSG_RESULT($bu_cv_have_fopen64)
 108 if test "$bu_cv_have_fopen64" != no; then
 109   AC_DEFINE([HAVE_FOPEN64], 1,
 110             [Is fopen64 available?])
 111 fi
 112 AC_MSG_CHECKING([for stat64])
 113 AC_CACHE_VAL(bu_cv_have_stat64,
 114 [AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 115 bu_cv_have_stat64=yes,
 116 [saved_CPPFLAGS=$CPPFLAGS
 117  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 118  AC_TRY_LINK([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);],
 119 bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 120 bu_cv_have_stat64=no)
 121  CPPFLAGS=$saved_CPPFLAGS])])
 122 AC_MSG_RESULT($bu_cv_have_stat64)
 123 if test "$bu_cv_have_stat64" != no; then
 124   AC_DEFINE([HAVE_STAT64], 1,
 125             [Is stat64 available?])
 126 fi
 127 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 128    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 129   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 130             [Enable LFS])
 131   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 132 fi
 133
 134 # Some systems have frexp only in -lm, not in -lc.
 135 AC_SEARCH_LIBS(frexp, m)
 136
 137 AC_MSG_CHECKING(for time_t in time.h)
 138 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 139 [AC_TRY_COMPILE([#include <time.h>], [time_t i;],
 140 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 141 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 142 if test $bu_cv_decl_time_t_time_h = yes; then
 143   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 144             [Is the type time_t defined in <time.h>?])
 145 fi
 146
 147 AC_MSG_CHECKING(for time_t in sys/types.h)
 148 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 149 [AC_TRY_COMPILE([#include <sys/types.h>], [time_t i;],
 150 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 151 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 152 if test $bu_cv_decl_time_t_types_h = yes; then
 153   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 154             [Is the type time_t defined in <sys/types.h>?])
 155 fi
 156
 157 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 158 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 159 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 160 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 161 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 162 if test $bu_cv_decl_getopt_unistd_h = yes; then
 163   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 164             [Is the prototype for getopt in <unistd.h> in the expected format?])
 165 fi
 166
 167 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 168 # by default.
 169 AC_MSG_CHECKING([for utime.h])
 170 AC_CACHE_VAL(bu_cv_header_utime_h,
 171 [AC_TRY_COMPILE([#include <sys/types.h>
 172 #ifdef HAVE_TIME_H
 173 #include <time.h>
 174 #endif
 175 #include <utime.h>],
 176 [struct utimbuf s;],
 177 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 178 AC_MSG_RESULT($bu_cv_header_utime_h)
 179 if test $bu_cv_header_utime_h = yes; then
 180   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 181 fi
 182
 183 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 184                 snprintf, vsnprintf])
 185
 186 # Link in zlib if we can.  This allows us to read compressed debug
 187 # sections.  This is used only by readelf.c (objdump uses bfd for
 188 # reading compressed sections).
 189 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 190
 191 BFD_BINARY_FOPEN
 192
 193 # target-specific stuff:
 194
 195 # Canonicalize the secondary target names.
 196 if test -n "$enable_targets"; then
 197     for targ in `echo $enable_targets | sed 's/,/ /g'`
 198     do
 199         result=`$ac_config_sub $targ 2>/dev/null`
 200         if test -n "$result"; then
 201             canon_targets="$canon_targets $result"
 202         else
 203             # Allow targets that config.sub doesn't recognize, like "all".
 204             canon_targets="$canon_targets $targ"
 205         fi
 206     done
 207 fi
 208
 209 AC_CHECK_HEADER(iconv.h)
 210 AM_ICONV
 211
 212 all_targets=false
 213 BUILD_NLMCONV=
 214 NLMCONV_DEFS=
 215 BUILD_SRCONV=
 216 BUILD_DLLTOOL=
 217 DLLTOOL_DEFS=
 218 DLLTOOL_DEFAULT=
 219 BUILD_WINDRES=
 220 BUILD_WINDMC=
 221 BUILD_DLLWRAP=
 222 BUILD_MISC=
 223 BUILD_INSTALL_MISC=
 224 OBJDUMP_DEFS=
 225
 226 for targ in $target $canon_targets
 227 do
 228     if test "x$targ" = "xall"; then
 229         all_targets=true
 230         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 231         BUILD_SRCONV='$(SRCONV_PROG)'
 232         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 233         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 234         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 235         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 236         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 237         if test -z "$DLLTOOL_DEFAULT"; then
 238           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 239         fi
 240         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 241         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 242     else
 243         case $targ in
 244 changequote(,)dnl
 245         i[3-7]86*-*-netware*)
 246 changequote([,])dnl
 247           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 248           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 249           ;;
 250         alpha*-*-netware*)
 251           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 252           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 253           ;;
 254         powerpc*-*-netware*)
 255           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 256           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 257           ;;
 258         sparc*-*-netware*)
 259           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 260           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 261           ;;
 262         esac
 263         case $targ in
 264         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 265         esac
 266         case $targ in
 267         arm-epoc-pe*)
 268           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 269           if test -z "$DLLTOOL_DEFAULT"; then
 270             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 271           fi
 272           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 273           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 274           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 275           ;;
 276         arm-wince-pe* | arm-*-wince)
 277           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 278           if test -z "$DLLTOOL_DEFAULT"; then
 279             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 280           fi
 281           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 282           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 283           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 284           ;;
 285         arm-*-pe*)
 286           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 287           if test -z "$DLLTOOL_DEFAULT"; then
 288             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 289           fi
 290           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 291           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 292           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 293           ;;
 294         thumb-*-pe*)
 295           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 296           if test -z "$DLLTOOL_DEFAULT"; then
 297             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 298           fi
 299           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 300           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 301           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 302           ;;
 303         x86_64-*-mingw*)
 304           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 305           if test -z "$DLLTOOL_DEFAULT"; then
 306             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 307           fi
 308           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 309           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 310           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 311           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 312           ;;
 313 changequote(,)dnl
 314         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 315 changequote([,])dnl
 316           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 317           if test -z "$DLLTOOL_DEFAULT"; then
 318             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 319           fi
 320           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 321           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 322           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 323           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 324           ;;
 325 changequote(,)dnl
 326         i[3-7]86-*-interix)
 327 changequote([,])dnl
 328           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 329           if test -z "$DLLTOOL_DEFAULT"; then
 330             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 331           fi
 332           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 333           ;;
 334 changequote(,)dnl
 335         powerpc*-aix5.[01])
 336 changequote([,])dnl
 337           ;;
 338         powerpc*-aix5.*)
 339           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 340           ;;
 341         powerpc*-*-pe* | powerpc*-*-cygwin*)
 342           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 343           if test -z "$DLLTOOL_DEFAULT"; then
 344             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 345           fi
 346           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 347           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 348           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 349           ;;
 350         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 351           BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 352           ;;
 353         sh*-*-pe)
 354           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 355           if test -z "$DLLTOOL_DEFAULT"; then
 356             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 357           fi
 358           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 359           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 360           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 361           ;;
 362         spu-*-*)
 363           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 364           ;;
 365         mips*-*-pe)
 366           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 367           if test -z "$DLLTOOL_DEFAULT"; then
 368             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 369           fi
 370           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 371           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 372           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 373           ;;
 374         mcore-*-pe)
 375           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 376           if test -z "$DLLTOOL_DEFAULT"; then
 377             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 378           fi
 379           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 380           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 381           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 382           ;;
 383         mcore-*-elf)
 384           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 385           if test -z "$DLLTOOL_DEFAULT"; then
 386             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 387           fi
 388           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 389           ;;
 390         mep-*)
 391           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 392           ;;
 393         esac
 394     fi
 395 done
 396
 397 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 398
 399 if test "${with_windres+set}" = set; then
 400           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 401 fi
 402
 403 if test "${with_windmc+set}" = set; then
 404           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 405 fi
 406
 407 AC_SUBST(NLMCONV_DEFS)
 408 AC_SUBST(BUILD_NLMCONV)
 409 AC_SUBST(BUILD_SRCONV)
 410 AC_SUBST(BUILD_DLLTOOL)
 411 AC_SUBST(DLLTOOL_DEFS)
 412 AC_SUBST(BUILD_WINDRES)
 413 AC_SUBST(BUILD_WINDMC)
 414 AC_SUBST(BUILD_DLLWRAP)
 415 AC_SUBST(BUILD_MISC)
 416 AC_SUBST(BUILD_INSTALL_MISC)
 417 AC_SUBST(OBJDUMP_DEFS)
 418
 419 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 420
 421 targ=$target
 422 . $srcdir/../bfd/config.bfd
 423 if test "x$targ_underscore" = "xyes"; then
 424     UNDERSCORE=1
 425 else
 426     UNDERSCORE=0
 427 fi
 428 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 429  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 430
 431 # Emulation
 432 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 433 do
 434   # Canonicalize the secondary target names.
 435  result=`$ac_config_sub $targ_alias 2>/dev/null`
 436  if test -n "$result"; then
 437    targ=$result
 438  else
 439    targ=$targ_alias
 440  fi
 441
 442  . ${srcdir}/configure.tgt
 443
 444   EMULATION=$targ_emul
 445   EMULATION_VECTOR=$targ_emul_vector
 446 done
 447
 448 AC_SUBST(EMULATION)
 449 AC_SUBST(EMULATION_VECTOR)
 450
 451 # Required for html and install-html
 452 AC_SUBST(datarootdir)
 453 AC_SUBST(docdir)
 454 AC_SUBST(htmldir)
 455
 456 AC_OUTPUT(Makefile doc/Makefile po/Makefile.in:po/Make-in)