binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18 LT_INIT
  19
  20 AC_ARG_ENABLE(targets,
  21 [  --enable-targets        alternative target configurations],
  22 [case "${enableval}" in
  23   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  24             ;;
  25   no)       enable_targets= ;;
  26   *)        enable_targets=$enableval ;;
  27 esac])dnl
  28 AC_ARG_ENABLE(commonbfdlib,
  29 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  30 [case "${enableval}" in
  31   yes) commonbfdlib=true ;;
  32   no)  commonbfdlib=false ;;
  33   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  34 esac])dnl
  35
  36 AM_BINUTILS_WARNINGS
  37
  38 AC_CONFIG_HEADERS(config.h:config.in)
  39
  40 if test -z "$target" ; then
  41     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  42 fi
  43 if test -z "$host" ; then
  44     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  45 fi
  46
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49
  50 ALL_LINGUAS="fr tr ja es sv da zh_CN ru ro rw zh_TW fi vi uk sk"
  51 ZW_GNU_GETTEXT_SISTER_DIR
  52 AM_PO_SUBDIRS
  53
  54 AM_MAINTAINER_MODE
  55 AM_CONDITIONAL(GENINSRC_NEVER, false)
  56 AC_EXEEXT
  57 if test -n "$EXEEXT"; then
  58   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  59             [Does the platform use an executable suffix?])
  60 fi
  61 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  62                    [Suffix used for executables, if any.])
  63
  64 # host-specific stuff:
  65
  66 HDEFINES=
  67
  68 . ${srcdir}/../bfd/configure.host
  69
  70 AC_SUBST(HDEFINES)
  71 AR=${AR-ar}
  72 AC_SUBST(AR)
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75
  76 BFD_CC_FOR_BUILD
  77
  78 DEMANGLER_NAME=c++filt
  79 case "${host}" in
  80   *-*-go32* | *-*-msdos*)
  81     DEMANGLER_NAME=cxxfilt
  82 esac
  83 AC_SUBST(DEMANGLER_NAME)
  84
  85 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h sys/param.h)
  86 AC_HEADER_SYS_WAIT
  87 AC_FUNC_ALLOCA
  88 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll)
  89 AC_CHECK_FUNC([mkstemp],
  90               AC_DEFINE([HAVE_MKSTEMP], 1,
  91               [Define to 1 if you have the `mkstemp' function.]))
  92 AC_CHECK_FUNC([mkdtemp],
  93               AC_DEFINE([HAVE_MKDTEMP], 1,
  94               [Define to 1 if you have the `mkdtemp' function.]))
  95
  96 # Check whether fopen64 is available and whether _LARGEFILE64_SOURCE
  97 # needs to be defined for it
  98 AC_MSG_CHECKING([for fopen64])
  99 AC_CACHE_VAL(bu_cv_have_fopen64,
 100 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");])],
 101 bu_cv_have_fopen64=yes,
 102 [saved_CPPFLAGS=$CPPFLAGS
 103  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 104  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <stdio.h>], [FILE *f = fopen64 ("/tmp/foo","r");])],
 105  bu_cv_have_fopen64="need -D_LARGEFILE64_SOURCE",
 106  bu_cv_have_fopen64=no)
 107  CPPFLAGS=$saved_CPPFLAGS])])
 108 AC_MSG_RESULT($bu_cv_have_fopen64)
 109 if test "$bu_cv_have_fopen64" != no; then
 110   AC_DEFINE([HAVE_FOPEN64], 1,
 111             [Is fopen64 available?])
 112 fi
 113 AC_MSG_CHECKING([for stat64])
 114 AC_CACHE_VAL(bu_cv_have_stat64,
 115 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);])],
 116 bu_cv_have_stat64=yes,
 117 [saved_CPPFLAGS=$CPPFLAGS
 118  CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 119  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/stat.h>], [struct stat64 st; stat64 ("/tmp/foo", &st);])],
 120  bu_cv_have_stat64="need -D_LARGEFILE64_SOURCE",
 121  bu_cv_have_stat64=no)
 122  CPPFLAGS=$saved_CPPFLAGS])])
 123 AC_MSG_RESULT($bu_cv_have_stat64)
 124 if test "$bu_cv_have_stat64" != no; then
 125   AC_DEFINE([HAVE_STAT64], 1,
 126             [Is stat64 available?])
 127 fi
 128 if test "$bu_cv_have_fopen64" = "need -D_LARGEFILE64_SOURCE" \
 129    || test "$bu_cv_have_stat64" = "need -D_LARGEFILE64_SOURCE"; then
 130   AC_DEFINE([_LARGEFILE64_SOURCE], 1,
 131             [Enable LFS])
 132   CPPFLAGS="$CPPFLAGS -D_LARGEFILE64_SOURCE"
 133 fi
 134
 135 # Some systems have frexp only in -lm, not in -lc.
 136 AC_SEARCH_LIBS(frexp, m)
 137
 138 AC_MSG_CHECKING(for time_t in time.h)
 139 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 140 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 141 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 142 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 143 if test $bu_cv_decl_time_t_time_h = yes; then
 144   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 145             [Is the type time_t defined in <time.h>?])
 146 fi
 147
 148 AC_MSG_CHECKING(for time_t in sys/types.h)
 149 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 150 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 151 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 152 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 153 if test $bu_cv_decl_time_t_types_h = yes; then
 154   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 155             [Is the type time_t defined in <sys/types.h>?])
 156 fi
 157
 158 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 159 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 160 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 161 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 162 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 163 if test $bu_cv_decl_getopt_unistd_h = yes; then
 164   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 165             [Is the prototype for getopt in <unistd.h> in the expected format?])
 166 fi
 167
 168 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 169 # by default.
 170 AC_MSG_CHECKING([for utime.h])
 171 AC_CACHE_VAL(bu_cv_header_utime_h,
 172 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 173 #ifdef HAVE_TIME_H
 174 #include <time.h>
 175 #endif
 176 #include <utime.h>],
 177 [struct utimbuf s;])],
 178 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 179 AC_MSG_RESULT($bu_cv_header_utime_h)
 180 if test $bu_cv_header_utime_h = yes; then
 181   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 182 fi
 183
 184 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 185                 snprintf, vsnprintf])
 186
 187 # Link in zlib if we can.  This allows us to read compressed debug
 188 # sections.  This is used only by readelf.c (objdump uses bfd for
 189 # reading compressed sections).
 190 AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)])
 191
 192 BFD_BINARY_FOPEN
 193
 194 # target-specific stuff:
 195
 196 # Canonicalize the secondary target names.
 197 if test -n "$enable_targets"; then
 198     for targ in `echo $enable_targets | sed 's/,/ /g'`
 199     do
 200         result=`$ac_config_sub $targ 2>/dev/null`
 201         if test -n "$result"; then
 202             canon_targets="$canon_targets $result"
 203         else
 204             # Allow targets that config.sub doesn't recognize, like "all".
 205             canon_targets="$canon_targets $targ"
 206         fi
 207     done
 208 fi
 209
 210 AC_CHECK_HEADER(iconv.h)
 211 AM_ICONV
 212
 213 all_targets=false
 214 BUILD_NLMCONV=
 215 NLMCONV_DEFS=
 216 BUILD_SRCONV=
 217 BUILD_DLLTOOL=
 218 DLLTOOL_DEFS=
 219 DLLTOOL_DEFAULT=
 220 BUILD_WINDRES=
 221 BUILD_WINDMC=
 222 BUILD_DLLWRAP=
 223 BUILD_MISC=
 224 BUILD_INSTALL_MISC=
 225 OBJDUMP_DEFS=
 226
 227 for targ in $target $canon_targets
 228 do
 229     if test "x$targ" = "xall"; then
 230         all_targets=true
 231         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 232         BUILD_SRCONV='$(SRCONV_PROG)'
 233         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 234         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 235         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 236         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 237         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 238         if test -z "$DLLTOOL_DEFAULT"; then
 239           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 240         fi
 241         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 242         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 243     else
 244         case $targ in
 245 changequote(,)dnl
 246         i[3-7]86*-*-netware*)
 247 changequote([,])dnl
 248           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 249           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 250           ;;
 251         alpha*-*-netware*)
 252           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 253           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 254           ;;
 255         powerpc*-*-netware*)
 256           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 257           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 258           ;;
 259         sparc*-*-netware*)
 260           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 261           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 262           ;;
 263         esac
 264         case $targ in
 265         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 266         esac
 267         case $targ in
 268         arm-epoc-pe*)
 269           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 270           if test -z "$DLLTOOL_DEFAULT"; then
 271             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 272           fi
 273           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 274           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 275           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 276           ;;
 277         arm-wince-pe* | arm-*-wince)
 278           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 279           if test -z "$DLLTOOL_DEFAULT"; then
 280             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 281           fi
 282           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 283           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 284           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 285           ;;
 286         arm-*-pe*)
 287           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 288           if test -z "$DLLTOOL_DEFAULT"; then
 289             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 290           fi
 291           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 292           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 293           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 294           ;;
 295         thumb-*-pe*)
 296           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 297           if test -z "$DLLTOOL_DEFAULT"; then
 298             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 299           fi
 300           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 301           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 302           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 303           ;;
 304         x86_64-*-mingw*)
 305           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 306           if test -z "$DLLTOOL_DEFAULT"; then
 307             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 308           fi
 309           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 310           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 311           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 312           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 313           ;;
 314 changequote(,)dnl
 315         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 316 changequote([,])dnl
 317           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 318           if test -z "$DLLTOOL_DEFAULT"; then
 319             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 320           fi
 321           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 322           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 323           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 324           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 325           ;;
 326 changequote(,)dnl
 327         i[3-7]86-*-interix)
 328 changequote([,])dnl
 329           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 330           if test -z "$DLLTOOL_DEFAULT"; then
 331             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 332           fi
 333           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 334           ;;
 335 changequote(,)dnl
 336         powerpc*-aix5.[01])
 337 changequote([,])dnl
 338           ;;
 339         powerpc*-aix5.*)
 340           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 341           ;;
 342         powerpc*-*-pe* | powerpc*-*-cygwin*)
 343           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 344           if test -z "$DLLTOOL_DEFAULT"; then
 345             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 346           fi
 347           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 348           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 349           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 350           ;;
 351         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 352           BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 353           ;;
 354         sh*-*-pe)
 355           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 356           if test -z "$DLLTOOL_DEFAULT"; then
 357             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 358           fi
 359           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 360           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 361           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 362           ;;
 363         spu-*-*)
 364           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 365           ;;
 366         mips*-*-pe)
 367           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 368           if test -z "$DLLTOOL_DEFAULT"; then
 369             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 370           fi
 371           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 372           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 373           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 374           ;;
 375         mcore-*-pe)
 376           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 377           if test -z "$DLLTOOL_DEFAULT"; then
 378             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 379           fi
 380           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 381           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 382           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 383           ;;
 384         mcore-*-elf)
 385           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 386           if test -z "$DLLTOOL_DEFAULT"; then
 387             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 388           fi
 389           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 390           ;;
 391         mep-*)
 392           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 393           ;;
 394         esac
 395     fi
 396 done
 397
 398 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 399
 400 if test "${with_windres+set}" = set; then
 401           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 402 fi
 403
 404 if test "${with_windmc+set}" = set; then
 405           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 406 fi
 407
 408 AC_SUBST(NLMCONV_DEFS)
 409 AC_SUBST(BUILD_NLMCONV)
 410 AC_SUBST(BUILD_SRCONV)
 411 AC_SUBST(BUILD_DLLTOOL)
 412 AC_SUBST(DLLTOOL_DEFS)
 413 AC_SUBST(BUILD_WINDRES)
 414 AC_SUBST(BUILD_WINDMC)
 415 AC_SUBST(BUILD_DLLWRAP)
 416 AC_SUBST(BUILD_MISC)
 417 AC_SUBST(BUILD_INSTALL_MISC)
 418 AC_SUBST(OBJDUMP_DEFS)
 419
 420 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 421
 422 targ=$target
 423 . $srcdir/../bfd/config.bfd
 424 if test "x$targ_underscore" = "xyes"; then
 425     UNDERSCORE=1
 426 else
 427     UNDERSCORE=0
 428 fi
 429 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 430  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 431
 432 # Emulation
 433 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 434 do
 435   # Canonicalize the secondary target names.
 436  result=`$ac_config_sub $targ_alias 2>/dev/null`
 437  if test -n "$result"; then
 438    targ=$result
 439  else
 440    targ=$targ_alias
 441  fi
 442
 443  . ${srcdir}/configure.tgt
 444
 445   EMULATION=$targ_emul
 446   EMULATION_VECTOR=$targ_emul_vector
 447 done
 448
 449 AC_SUBST(EMULATION)
 450 AC_SUBST(EMULATION_VECTOR)
 451
 452 # Required for html and install-html
 453 AC_SUBST(datarootdir)
 454 AC_SUBST(docdir)
 455 AC_SUBST(htmldir)
 456
 457 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 458 AC_OUTPUT