binutils/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 AC_PREREQ(2.59)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR(ar.c)
   6
   7 AC_CANONICAL_TARGET
   8 AC_ISC_POSIX
   9
  10 changequote(,)dnl
  11 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  12 changequote([,])dnl
  13 AM_INIT_AUTOMAKE(binutils, ${BFD_VERSION})
  14
  15 AC_PROG_CC
  16 AC_GNU_SOURCE
  17 AC_USE_SYSTEM_EXTENSIONS
  18
  19 ACX_LARGEFILE
  20 LT_INIT
  21
  22 AC_ARG_ENABLE(targets,
  23 [  --enable-targets        alternative target configurations],
  24 [case "${enableval}" in
  25   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  26             ;;
  27   no)       enable_targets= ;;
  28   *)        enable_targets=$enableval ;;
  29 esac])dnl
  30
  31 AC_ARG_ENABLE(deterministic-archives,
  32 [AS_HELP_STRING([--enable-deterministic-archives],
  33                 [ar and ranlib default to -D behavior])], [
  34 if test "${enableval}" = no; then
  35   default_ar_deterministic=0
  36 else
  37   default_ar_deterministic=1
  38 fi], [default_ar_deterministic=0])
  39
  40 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  41                    [Should ar and ranlib use -D behavior by default?])
  42
  43 AM_BINUTILS_WARNINGS
  44
  45 AC_CONFIG_HEADERS(config.h:config.in)
  46
  47 if test -z "$target" ; then
  48     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  49 fi
  50 if test -z "$host" ; then
  51     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  52 fi
  53
  54 AC_PROG_YACC
  55 AM_PROG_LEX
  56
  57 ALL_LINGUAS="bg da es fi fr id it ja ro ru rw sk sv tr uk vi zh_CN zh_TW"
  58 ZW_GNU_GETTEXT_SISTER_DIR
  59 AM_PO_SUBDIRS
  60
  61 AM_MAINTAINER_MODE
  62 AM_CONDITIONAL(GENINSRC_NEVER, false)
  63 AC_EXEEXT
  64 if test -n "$EXEEXT"; then
  65   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
  66             [Does the platform use an executable suffix?])
  67 fi
  68 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
  69                    [Suffix used for executables, if any.])
  70
  71 # host-specific stuff:
  72
  73 HDEFINES=
  74
  75 . ${srcdir}/../bfd/configure.host
  76
  77 AC_SUBST(HDEFINES)
  78 AR=${AR-ar}
  79 AC_SUBST(AR)
  80 AC_PROG_RANLIB
  81 AC_PROG_INSTALL
  82
  83 BFD_CC_FOR_BUILD
  84
  85 DEMANGLER_NAME=c++filt
  86 case "${host}" in
  87   *-*-go32* | *-*-msdos*)
  88     DEMANGLER_NAME=cxxfilt
  89 esac
  90 AC_SUBST(DEMANGLER_NAME)
  91
  92 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h fcntl.h sys/file.h limits.h locale.h sys/param.h)
  93 AC_HEADER_SYS_WAIT
  94 ACX_HEADER_STRING
  95 AC_FUNC_ALLOCA
  96 AC_CHECK_FUNCS(sbrk utimes setmode getc_unlocked strcoll setlocale)
  97 AC_CHECK_FUNC([mkstemp],
  98               AC_DEFINE([HAVE_MKSTEMP], 1,
  99               [Define to 1 if you have the `mkstemp' function.]))
 100 AC_CHECK_FUNC([mkdtemp],
 101               AC_DEFINE([HAVE_MKDTEMP], 1,
 102               [Define to 1 if you have the `mkdtemp' function.]))
 103
 104 # Some systems have frexp only in -lm, not in -lc.
 105 AC_SEARCH_LIBS(frexp, m)
 106
 107 AM_LC_MESSAGES
 108
 109 AC_MSG_CHECKING(for time_t in time.h)
 110 AC_CACHE_VAL(bu_cv_decl_time_t_time_h,
 111 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [time_t i;])],
 112 bu_cv_decl_time_t_time_h=yes, bu_cv_decl_time_t_time_h=no)])
 113 AC_MSG_RESULT($bu_cv_decl_time_t_time_h)
 114 if test $bu_cv_decl_time_t_time_h = yes; then
 115   AC_DEFINE([HAVE_TIME_T_IN_TIME_H], 1,
 116             [Is the type time_t defined in <time.h>?])
 117 fi
 118
 119 AC_MSG_CHECKING(for time_t in sys/types.h)
 120 AC_CACHE_VAL(bu_cv_decl_time_t_types_h,
 121 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>], [time_t i;])],
 122 bu_cv_decl_time_t_types_h=yes, bu_cv_decl_time_t_types_h=no)])
 123 AC_MSG_RESULT($bu_cv_decl_time_t_types_h)
 124 if test $bu_cv_decl_time_t_types_h = yes; then
 125   AC_DEFINE([HAVE_TIME_T_IN_TYPES_H], 1,
 126             [Is the type time_t defined in <sys/types.h>?])
 127 fi
 128
 129 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 130 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 131 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 132 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 133 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 134 if test $bu_cv_decl_getopt_unistd_h = yes; then
 135   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 136             [Is the prototype for getopt in <unistd.h> in the expected format?])
 137 fi
 138
 139 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 140 # by default.
 141 AC_MSG_CHECKING([for utime.h])
 142 AC_CACHE_VAL(bu_cv_header_utime_h,
 143 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 144 #ifdef HAVE_TIME_H
 145 #include <time.h>
 146 #endif
 147 #include <utime.h>],
 148 [struct utimbuf s;])],
 149 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 150 AC_MSG_RESULT($bu_cv_header_utime_h)
 151 if test $bu_cv_header_utime_h = yes; then
 152   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 153 fi
 154
 155 AC_CHECK_DECLS([fprintf, stpcpy, strstr, sbrk, getenv, environ, getc_unlocked,
 156                 snprintf, vsnprintf])
 157
 158 # Link in zlib if we can.  This allows us to read compressed debug
 159 # sections.  This is used only by readelf.c (objdump uses bfd for
 160 # reading compressed sections).
 161 AM_ZLIB
 162
 163 BFD_BINARY_FOPEN
 164
 165 # target-specific stuff:
 166
 167 # Canonicalize the secondary target names.
 168 if test -n "$enable_targets"; then
 169     for targ in `echo $enable_targets | sed 's/,/ /g'`
 170     do
 171         result=`$ac_config_sub $targ 2>/dev/null`
 172         if test -n "$result"; then
 173             canon_targets="$canon_targets $result"
 174         else
 175             # Allow targets that config.sub doesn't recognize, like "all".
 176             canon_targets="$canon_targets $targ"
 177         fi
 178     done
 179 fi
 180
 181 AC_CHECK_HEADER(iconv.h)
 182 AM_ICONV
 183
 184 all_targets=false
 185 BUILD_NLMCONV=
 186 NLMCONV_DEFS=
 187 BUILD_SRCONV=
 188 BUILD_DLLTOOL=
 189 DLLTOOL_DEFS=
 190 DLLTOOL_DEFAULT=
 191 BUILD_WINDRES=
 192 BUILD_WINDMC=
 193 BUILD_DLLWRAP=
 194 BUILD_MISC=
 195 BUILD_INSTALL_MISC=
 196 OBJDUMP_DEFS=
 197 OBJDUMP_PRIVATE_VECTORS=
 198 OBJDUMP_PRIVATE_OFILES=
 199 od_vectors=
 200
 201 for targ in $target $canon_targets
 202 do
 203     if test "x$targ" = "xall"; then
 204         all_targets=true
 205         BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 206         BUILD_SRCONV='$(SRCONV_PROG)'
 207         NLMCONV_DEFS="-DNLMCONV_I386 -DNLMCONV_ALPHA -DNLMCONV_POWERPC -DNLMCONV_SPARC"
 208         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 209         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 210         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 211         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 212         if test -z "$DLLTOOL_DEFAULT"; then
 213           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 214         fi
 215         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 216         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 217         od_vectors="$od_vectors objdump_private_desc_xcoff"
 218     else
 219         case $targ in
 220 changequote(,)dnl
 221         i[3-7]86*-*-netware*)
 222 changequote([,])dnl
 223           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 224           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_I386"
 225           ;;
 226         alpha*-*-netware*)
 227           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 228           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_ALPHA"
 229           ;;
 230         powerpc*-*-netware*)
 231           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 232           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_POWERPC"
 233           ;;
 234         sparc*-*-netware*)
 235           BUILD_NLMCONV='$(NLMCONV_PROG)$(EXEEXT)'
 236           NLMCONV_DEFS="$NLMCONV_DEFS -DNLMCONV_SPARC"
 237           ;;
 238         esac
 239
 240         case $targ in
 241         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 242         esac
 243
 244         case $targ in
 245         arm-epoc-pe*)
 246           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 247           if test -z "$DLLTOOL_DEFAULT"; then
 248             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_EPOC"
 249           fi
 250           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_EPOC -DDLLTOOL_ARM"
 251           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 252           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 253           ;;
 254         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 255           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 256           if test -z "$DLLTOOL_DEFAULT"; then
 257             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 258           fi
 259           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 260           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 261           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 262           ;;
 263         arm-*-pe*)
 264           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 265           if test -z "$DLLTOOL_DEFAULT"; then
 266             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 267           fi
 268           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 269           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 270           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 271           ;;
 272         x86_64-*-mingw*)
 273           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 274           if test -z "$DLLTOOL_DEFAULT"; then
 275             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 276           fi
 277           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 278           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 279           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 280           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 281           ;;
 282 changequote(,)dnl
 283         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32** | i[3-7]86-*-netbsdpe*)
 284 changequote([,])dnl
 285           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 286           if test -z "$DLLTOOL_DEFAULT"; then
 287             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 288           fi
 289           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 290           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 291           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 292           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 293           ;;
 294 changequote(,)dnl
 295         i[3-7]86-*-interix)
 296 changequote([,])dnl
 297           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 298           if test -z "$DLLTOOL_DEFAULT"; then
 299             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 300           fi
 301           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 302           ;;
 303 changequote(,)dnl
 304         powerpc*-aix5.[01])
 305 changequote([,])dnl
 306           ;;
 307 changequote(,)dnl
 308         powerpc*-aix[5-9].*)
 309 changequote([,])dnl
 310           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 311           ;;
 312         powerpc*-*-pe* | powerpc*-*-cygwin*)
 313           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 314           if test -z "$DLLTOOL_DEFAULT"; then
 315             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_PPC"
 316           fi
 317           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_PPC"
 318           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 319           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 320           ;;
 321         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 322           case "$BUILD_INSTALL_MISC" in
 323             *embedspu*) ;;
 324             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 325           esac
 326           ;;
 327         sh*-*-pe)
 328           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 329           if test -z "$DLLTOOL_DEFAULT"; then
 330             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 331           fi
 332           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 333           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 334           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 335           ;;
 336         spu-*-*)
 337           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 338           ;;
 339         mips*-*-pe)
 340           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 341           if test -z "$DLLTOOL_DEFAULT"; then
 342             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 343           fi
 344           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 345           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 346           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 347           ;;
 348         mcore-*-pe)
 349           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 350           if test -z "$DLLTOOL_DEFAULT"; then
 351             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 352           fi
 353           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 354           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 355           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 356           ;;
 357         mcore-*-elf)
 358           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 359           if test -z "$DLLTOOL_DEFAULT"; then
 360             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 361           fi
 362           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 363           ;;
 364         mep-*)
 365           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 366           ;;
 367         esac
 368
 369         # Add objdump private vectors.
 370         case $targ in
 371         powerpc-*-aix*)
 372           od_vectors="$od_vectors objdump_private_desc_xcoff"
 373           ;;
 374         *-*-darwin*)
 375           od_vectors="$od_vectors objdump_private_desc_mach_o"
 376           ;;
 377         esac
 378     fi
 379 done
 380
 381 # Uniq objdump private vector, build objdump target ofiles.
 382 od_files=
 383 f=""
 384 for i in $od_vectors ; do
 385     case " $f " in
 386     *" $i "*) ;;
 387     *)
 388         f="$f $i"
 389         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 390         case $i in
 391         objdump_private_desc_xcoff)
 392             od_files="$od_files od-xcoff" ;;
 393         objdump_private_desc_mach_o)
 394             od_files="$od_files od-macho" ;;
 395         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 396         esac
 397         ;;
 398     esac
 399 done
 400
 401 # Uniq objdump target ofiles
 402 f=""
 403 for i in $od_files ; do
 404     case " $f " in
 405     *" $i "*) ;;
 406     *)
 407         f="$f $i"
 408         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 409         ;;
 410     esac
 411 done
 412
 413 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 414
 415 if test "${with_windres+set}" = set; then
 416           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 417 fi
 418
 419 if test "${with_windmc+set}" = set; then
 420           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 421 fi
 422
 423 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 424
 425 AC_SUBST(NLMCONV_DEFS)
 426 AC_SUBST(BUILD_NLMCONV)
 427 AC_SUBST(BUILD_SRCONV)
 428 AC_SUBST(BUILD_DLLTOOL)
 429 AC_SUBST(DLLTOOL_DEFS)
 430 AC_SUBST(BUILD_WINDRES)
 431 AC_SUBST(BUILD_WINDMC)
 432 AC_SUBST(BUILD_DLLWRAP)
 433 AC_SUBST(BUILD_MISC)
 434 AC_SUBST(BUILD_INSTALL_MISC)
 435 AC_SUBST(OBJDUMP_DEFS)
 436 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 437
 438 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 439
 440 targ=$target
 441 . $srcdir/../bfd/config.bfd
 442 if test "x$targ_underscore" = "xyes"; then
 443     UNDERSCORE=1
 444 else
 445     UNDERSCORE=0
 446 fi
 447 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 448  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 449
 450 # Emulation
 451 targ=$target
 452 . ${srcdir}/configure.tgt
 453 EMULATION=$targ_emul
 454 EMULATION_VECTOR=$targ_emul_vector
 455
 456 AC_SUBST(EMULATION)
 457 AC_SUBST(EMULATION_VECTOR)
 458
 459 # Required for html and install-html
 460 AC_SUBST(datarootdir)
 461 AC_SUBST(docdir)
 462 AC_SUBST(htmldir)
 463 AC_SUBST(pdfdir)
 464
 465 AC_CONFIG_FILES(Makefile doc/Makefile po/Makefile.in:po/Make-in)
 466 AC_OUTPUT