config/boost.m4

   1 # boost.m4: Locate Boost headers and libraries for autoconf-based projects.
   2 # Copyright (C) 2007, 2008, 2009, 2010, 2011  Benoit Sigoure <tsuna@lrde.epita.fr>
   3 #
   4 # This program is free software: you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation, either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # Additional permission under section 7 of the GNU General Public
  10 # License, version 3 ("GPLv3"):
  11 #
  12 # If you convey this file as part of a work that contains a
  13 # configuration script generated by Autoconf, you may do so under
  14 # terms of your choice.
  15 #
  16 # This program is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 m4_define([_BOOST_SERIAL], [m4_translit([
  25 # serial 16
  26 ], [#
  27 ], [])])
  28
  29 # Original sources can be found at http://github.com/tsuna/boost.m4
  30 # You can fetch the latest version of the script by doing:
  31 #   wget http://github.com/tsuna/boost.m4/raw/master/build-aux/boost.m4
  32
  33 # ------ #
  34 # README #
  35 # ------ #
  36
  37 # This file provides several macros to use the various Boost libraries.
  38 # The first macro is BOOST_REQUIRE.  It will simply check if it's possible to
  39 # find the Boost headers of a given (optional) minimum version and it will
  40 # define BOOST_CPPFLAGS accordingly.  It will add an option --with-boost to
  41 # your configure so that users can specify non standard locations.
  42 # If the user's environment contains BOOST_ROOT and --with-boost was not
  43 # specified, --with-boost=$BOOST_ROOT is implicitly used.
  44 # For more README and documentation, go to http://github.com/tsuna/boost.m4
  45 # Note: THESE MACROS ASSUME THAT YOU USE LIBTOOL.  If you don't, don't worry,
  46 # simply read the README, it will show you what to do step by step.
  47
  48 m4_pattern_forbid([^_?(BOOST|Boost)_])
  49
  50
  51 # _BOOST_SED_CPP(SED-PROGRAM, PROGRAM,
  52 #                [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
  53 # --------------------------------------------------------
  54 # Same as AC_EGREP_CPP, but leave the result in conftest.i.
  55 #
  56 # SED-PROGRAM is *not* overquoted, as in AC_EGREP_CPP.  It is expanded
  57 # in double-quotes, so escape your double quotes.
  58 #
  59 # It could be useful to turn this into a macro which extracts the
  60 # value of any macro.
  61 m4_define([_BOOST_SED_CPP],
  62 [AC_LANG_PREPROC_REQUIRE()dnl
  63 AC_REQUIRE([AC_PROG_SED])dnl
  64 AC_LANG_CONFTEST([AC_LANG_SOURCE([[$2]])])
  65 AS_IF([dnl eval is necessary to expand ac_cpp.
  66 dnl Ultrix and Pyramid sh refuse to redirect output of eval, so use subshell.
  67 dnl Beware of Windows end-of-lines, for instance if we are running
  68 dnl some Windows programs under Wine.  In that case, boost/version.hpp
  69 dnl is certainly using "\r\n", but the regular Unix shell will only
  70 dnl strip `\n' with backquotes, not the `\r'.  This results in
  71 dnl boost_cv_lib_version='1_37\r' for instance, which breaks
  72 dnl everything else.
  73 dnl Cannot use 'dnl' after [$4] because a trailing dnl may break AC_CACHE_CHECK
  74 (eval "$ac_cpp conftest.$ac_ext") 2>&AS_MESSAGE_LOG_FD |
  75   tr -d '\r' |
  76   $SED -n -e "$1" >conftest.i 2>&1],
  77   [$3],
  78   [$4])
  79 rm -rf conftest*
  80 ])# AC_EGREP_CPP
  81
  82
  83
  84 # BOOST_REQUIRE([VERSION], [ACTION-IF-NOT-FOUND])
  85 # -----------------------------------------------
  86 # Look for Boost.  If version is given, it must either be a literal of the form
  87 # "X.Y.Z" where X, Y and Z are integers (the ".Z" part being optional) or a
  88 # variable "$var".
  89 # Defines the value BOOST_CPPFLAGS.  This macro only checks for headers with
  90 # the required version, it does not check for any of the Boost libraries.
  91 # On # success, defines HAVE_BOOST.  On failure, calls the optional
  92 # ACTION-IF-NOT-FOUND action if one was supplied.
  93 # Otherwise aborts with an error message.
  94 AC_DEFUN([BOOST_REQUIRE],
  95 [AC_REQUIRE([AC_PROG_CXX])dnl
  96 AC_REQUIRE([AC_PROG_GREP])dnl
  97 echo "$as_me: this is boost.m4[]_BOOST_SERIAL" >&AS_MESSAGE_LOG_FD
  98 boost_save_IFS=$IFS
  99 boost_version_req=$1
 100 IFS=.
 101 set x $boost_version_req 0 0 0
 102 IFS=$boost_save_IFS
 103 shift
 104 boost_version_req=`expr "$[1]" '*' 100000 + "$[2]" '*' 100 + "$[3]"`
 105 boost_version_req_string=$[1].$[2].$[3]
 106 AC_ARG_WITH([boost],
 107    [AS_HELP_STRING([--with-boost=DIR],
 108                    [prefix of Boost $1 @<:@guess@:>@])])dnl
 109 AC_ARG_VAR([BOOST_ROOT],[Location of Boost installation])dnl
 110 # If BOOST_ROOT is set and the user has not provided a value to
 111 # --with-boost, then treat BOOST_ROOT as if it the user supplied it.
 112 if test x"$BOOST_ROOT" != x; then
 113   if test x"$with_boost" = x; then
 114     AC_MSG_NOTICE([Detected BOOST_ROOT; continuing with --with-boost=$BOOST_ROOT])
 115     with_boost=$BOOST_ROOT
 116   else
 117     AC_MSG_NOTICE([Detected BOOST_ROOT=$BOOST_ROOT, but overridden by --with-boost=$with_boost])
 118   fi
 119 fi
 120 AC_SUBST([DISTCHECK_CONFIGURE_FLAGS],
 121          ["$DISTCHECK_CONFIGURE_FLAGS '--with-boost=$with_boost'"])dnl
 122 boost_save_CPPFLAGS=$CPPFLAGS
 123   AC_CACHE_CHECK([for Boost headers version >= $boost_version_req_string],
 124     [boost_cv_inc_path],
 125     [boost_cv_inc_path=no
 126 AC_LANG_PUSH([C++])dnl
 127 m4_pattern_allow([^BOOST_VERSION$])dnl
 128     AC_LANG_CONFTEST([AC_LANG_PROGRAM([[#include <boost/version.hpp>
 129 #if !defined BOOST_VERSION
 130 # error BOOST_VERSION is not defined
 131 #elif BOOST_VERSION < $boost_version_req
 132 # error Boost headers version < $boost_version_req
 133 #endif
 134 ]])])
 135     # If the user provided a value to --with-boost, use it and only it.
 136     case $with_boost in #(
 137       ''|yes) set x '' /opt/local/include /usr/local/include /opt/include \
 138                  /usr/include C:/Boost/include;; #(
 139       *)      set x "$with_boost/include" "$with_boost";;
 140     esac
 141     shift
 142     for boost_dir
 143     do
 144     # Without --layout=system, Boost (or at least some versions) installs
 145     # itself in <prefix>/include/boost-<version>.  This inner loop helps to
 146     # find headers in such directories.
 147     #
 148     # Any ${boost_dir}/boost-x_xx directories are searched in reverse version
 149     # order followed by ${boost_dir}.  The final '.' is a sentinel for
 150     # searching $boost_dir" itself.  Entries are whitespace separated.
 151     #
 152     # I didn't indent this loop on purpose (to avoid over-indented code)
 153     boost_layout_system_search_list=`cd "$boost_dir" 2>/dev/null \
 154         && ls -1 | "${GREP}" '^boost-' | sort -rn -t- -k2 \
 155         && echo .`
 156     for boost_inc in $boost_layout_system_search_list
 157     do
 158       if test x"$boost_inc" != x.; then
 159         boost_inc="$boost_dir/$boost_inc"
 160       else
 161         boost_inc="$boost_dir" # Uses sentinel in boost_layout_system_search_list
 162       fi
 163       if test x"$boost_inc" != x; then
 164         # We are going to check whether the version of Boost installed
 165         # in $boost_inc is usable by running a compilation that
 166         # #includes it.  But if we pass a -I/some/path in which Boost
 167         # is not installed, the compiler will just skip this -I and
 168         # use other locations (either from CPPFLAGS, or from its list
 169         # of system include directories).  As a result we would use
 170         # header installed on the machine instead of the /some/path
 171         # specified by the user.  So in that precise case (trying
 172         # $boost_inc), make sure the version.hpp exists.
 173         #
 174         # Use test -e as there can be symlinks.
 175         test -e "$boost_inc/boost/version.hpp" || continue
 176         CPPFLAGS="$CPPFLAGS -I$boost_inc"
 177       fi
 178       AC_COMPILE_IFELSE([], [boost_cv_inc_path=yes], [boost_cv_version=no])
 179       if test x"$boost_cv_inc_path" = xyes; then
 180         if test x"$boost_inc" != x; then
 181           boost_cv_inc_path=$boost_inc
 182         fi
 183         break 2
 184       fi
 185     done
 186     done
 187 AC_LANG_POP([C++])dnl
 188     ])
 189     case $boost_cv_inc_path in #(
 190       no)
 191         boost_errmsg="cannot find Boost headers version >= $boost_version_req_string"
 192         m4_if([$2], [],  [AC_MSG_ERROR([$boost_errmsg])],
 193                         [AC_MSG_NOTICE([$boost_errmsg])])
 194         $2
 195         ;;#(
 196       yes)
 197         BOOST_CPPFLAGS=
 198         ;;#(
 199       *)
 200         AC_SUBST([BOOST_CPPFLAGS], ["-I$boost_cv_inc_path"])dnl
 201         ;;
 202     esac
 203   if test x"$boost_cv_inc_path" != xno; then
 204   AC_DEFINE([HAVE_BOOST], [1],
 205             [Defined if the requested minimum BOOST version is satisfied])
 206   AC_CACHE_CHECK([for Boost's header version],
 207     [boost_cv_lib_version],
 208     [m4_pattern_allow([^BOOST_LIB_VERSION$])dnl
 209      _BOOST_SED_CPP([/^boost-lib-version = /{s///;s/\"//g;p;q;}],
 210                     [#include <boost/version.hpp>
 211 boost-lib-version = BOOST_LIB_VERSION],
 212     [boost_cv_lib_version=`cat conftest.i`])])
 213     # e.g. "134" for 1_34_1 or "135" for 1_35
 214     boost_major_version=`echo "$boost_cv_lib_version" | sed 's/_//;s/_.*//'`
 215     case $boost_major_version in #(
 216       '' | *[[!0-9]]*)
 217         AC_MSG_ERROR([invalid value: boost_major_version=$boost_major_version])
 218         ;;
 219     esac
 220 fi
 221 CPPFLAGS=$boost_save_CPPFLAGS
 222 ])# BOOST_REQUIRE
 223
 224 # BOOST_STATIC()
 225 # --------------
 226 # Add the "--enable-static-boost" configure argument. If this argument is given
 227 # on the command line, static versions of the libraries will be looked up.
 228 AC_DEFUN([BOOST_STATIC],
 229   [AC_ARG_ENABLE([static-boost],
 230      [AC_HELP_STRING([--enable-static-boost],
 231                [Prefer the static boost libraries over the shared ones [no]])],
 232      [enable_static_boost=yes],
 233      [enable_static_boost=no])])# BOOST_STATIC
 234
 235 # BOOST_FIND_HEADER([HEADER-NAME], [ACTION-IF-NOT-FOUND], [ACTION-IF-FOUND])
 236 # --------------------------------------------------------------------------
 237 # Wrapper around AC_CHECK_HEADER for Boost headers.  Useful to check for
 238 # some parts of the Boost library which are only made of headers and don't
 239 # require linking (such as Boost.Foreach).
 240 #
 241 # Default ACTION-IF-NOT-FOUND: Fail with a fatal error unless Boost couldn't be
 242 # found in the first place, in which case by default a notice is issued to the
 243 # user.  Presumably if we haven't died already it's because it's OK to not have
 244 # Boost, which is why only a notice is issued instead of a hard error.
 245 #
 246 # Default ACTION-IF-FOUND: define the preprocessor symbol HAVE_<HEADER-NAME> in
 247 # case of success # (where HEADER-NAME is written LIKE_THIS, e.g.,
 248 # HAVE_BOOST_FOREACH_HPP).
 249 AC_DEFUN([BOOST_FIND_HEADER],
 250 [AC_REQUIRE([BOOST_REQUIRE])dnl
 251 if test x"$boost_cv_inc_path" = xno; then
 252   m4_default([$2], [AC_MSG_NOTICE([Boost not available, not searching for $1])])
 253 else
 254 AC_LANG_PUSH([C++])dnl
 255 boost_save_CPPFLAGS=$CPPFLAGS
 256 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 257 AC_CHECK_HEADER([$1],
 258   [m4_default([$3], [AC_DEFINE(AS_TR_CPP([HAVE_$1]), [1],
 259                                [Define to 1 if you have <$1>])])],
 260   [m4_default([$2], [AC_MSG_ERROR([cannot find $1])])])
 261 CPPFLAGS=$boost_save_CPPFLAGS
 262 AC_LANG_POP([C++])dnl
 263 fi
 264 ])# BOOST_FIND_HEADER
 265
 266
 267 # BOOST_FIND_LIB([LIB-NAME], [PREFERRED-RT-OPT], [HEADER-NAME], [CXX-TEST],
 268 #                [CXX-PROLOGUE], [ACTION-IF-NOT-FOUND])
 269 # -------------------------------------------------------------------------
 270 # Look for the Boost library LIB-NAME (e.g., LIB-NAME = `thread', for
 271 # libboost_thread).  Check that HEADER-NAME works and check that
 272 # libboost_LIB-NAME can link with the code CXX-TEST.  The optional argument
 273 # CXX-PROLOGUE can be used to include some C++ code before the `main'
 274 # function.  If ACTION-IF-NOT-FOUND is given, errors are nonfatal (otherwise
 275 # they are fatal).
 276 #
 277 # Invokes BOOST_FIND_HEADER([HEADER-NAME]) (see above).
 278 #
 279 # Boost libraries typically come compiled with several flavors (with different
 280 # runtime options) so PREFERRED-RT-OPT is the preferred suffix.  A suffix is one
 281 # or more of the following letters: sgdpn (in that order).  s = static
 282 # runtime, d = debug build, g = debug/diagnostic runtime, p = STLPort build,
 283 # n = (unsure) STLPort build without iostreams from STLPort (it looks like `n'
 284 # must always be used along with `p').  Additionally, PREFERRED-RT-OPT can
 285 # start with `mt-' to indicate that there is a preference for multi-thread
 286 # builds.  Some sample values for PREFERRED-RT-OPT: (nothing), mt, d, mt-d, gdp
 287 # ...  If you want to make sure you have a specific version of Boost
 288 # (eg, >= 1.33) you *must* invoke BOOST_REQUIRE before this macro.
 289 AC_DEFUN([BOOST_FIND_LIB],
 290 [AC_REQUIRE([BOOST_REQUIRE])dnl
 291 AC_REQUIRE([_BOOST_FIND_COMPILER_TAG])dnl
 292 AC_REQUIRE([BOOST_STATIC])dnl
 293 AC_REQUIRE([_BOOST_GUESS_WHETHER_TO_USE_MT])dnl
 294 if test x"$boost_cv_inc_path" = xno; then
 295   AC_MSG_NOTICE([Boost not available, not searching for the Boost $1 library])
 296 else
 297 dnl The else branch is huge and wasn't intended on purpose.
 298 AC_LANG_PUSH([C++])dnl
 299 AS_VAR_PUSHDEF([Boost_lib], [boost_cv_lib_$1])dnl
 300 AS_VAR_PUSHDEF([Boost_lib_LDFLAGS], [boost_cv_lib_$1_LDFLAGS])dnl
 301 AS_VAR_PUSHDEF([Boost_lib_LDPATH], [boost_cv_lib_$1_LDPATH])dnl
 302 AS_VAR_PUSHDEF([Boost_lib_LIBS], [boost_cv_lib_$1_LIBS])dnl
 303 BOOST_FIND_HEADER([$3], [$6])
 304 boost_save_CPPFLAGS=$CPPFLAGS
 305 CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
 306 # Now let's try to find the library.  The algorithm is as follows: first look
 307 # for a given library name according to the user's PREFERRED-RT-OPT.  For each
 308 # library name, we prefer to use the ones that carry the tag (toolset name).
 309 # Each library is searched through the various standard paths were Boost is
 310 # usually installed.  If we can't find the standard variants, we try to
 311 # enforce -mt (for instance on MacOSX, libboost_threads.dylib doesn't exist
 312 # but there's -obviously- libboost_threads-mt.dylib).
 313 AC_CACHE_CHECK([for the Boost $1 library], [Boost_lib],
 314   [Boost_lib=no
 315   case "$2" in #(
 316     mt | mt-) boost_mt=-mt; boost_rtopt=;; #(
 317     mt* | mt-*) boost_mt=-mt; boost_rtopt=`expr "X$2" : 'Xmt-*\(.*\)'`;; #(
 318     *) boost_mt=; boost_rtopt=$2;;
 319   esac
 320   if test $enable_static_boost = yes; then
 321     boost_rtopt="s$boost_rtopt"
 322   fi
 323   # Find the proper debug variant depending on what we've been asked to find.
 324   case $boost_rtopt in #(
 325     *d*) boost_rt_d=$boost_rtopt;; #(
 326     *[[sgpn]]*) # Insert the `d' at the right place (in between `sg' and `pn')
 327       boost_rt_d=`echo "$boost_rtopt" | sed 's/\(s*g*\)\(p*n*\)/\1\2/'`;; #(
 328     *) boost_rt_d='-d';;
 329   esac
 330   # If the PREFERRED-RT-OPT are not empty, prepend a `-'.
 331   test -n "$boost_rtopt" && boost_rtopt="-$boost_rtopt"
 332   $boost_guess_use_mt && boost_mt=-mt
 333   # Look for the abs path the static archive.
 334   # $libext is computed by Libtool but let's make sure it's non empty.
 335   test -z "$libext" &&
 336     AC_MSG_ERROR([the libext variable is empty, did you invoke Libtool?])
 337   boost_save_ac_objext=$ac_objext
 338   # Generate the test file.
 339   AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <$3>
 340 $5], [$4])])
 341 dnl Optimization hacks: compiling C++ is slow, especially with Boost.  What
 342 dnl we're trying to do here is guess the right combination of link flags
 343 dnl (LIBS / LDFLAGS) to use a given library.  This can take several
 344 dnl iterations before it succeeds and is thus *very* slow.  So what we do
 345 dnl instead is that we compile the code first (and thus get an object file,
 346 dnl typically conftest.o).  Then we try various combinations of link flags
 347 dnl until we succeed to link conftest.o in an executable.  The problem is
 348 dnl that the various TRY_LINK / COMPILE_IFELSE macros of Autoconf always
 349 dnl remove all the temporary files including conftest.o.  So the trick here
 350 dnl is to temporarily change the value of ac_objext so that conftest.o is
 351 dnl preserved accross tests.  This is obviously fragile and I will burn in
 352 dnl hell for not respecting Autoconf's documented interfaces, but in the
 353 dnl mean time, it optimizes the macro by a factor of 5 to 30.
 354 dnl Another small optimization: the first argument of AC_COMPILE_IFELSE left
 355 dnl empty because the test file is generated only once above (before we
 356 dnl start the for loops).
 357   AC_COMPILE_IFELSE([],
 358     [ac_objext=do_not_rm_me_plz],
 359     [m4_if([$6], [],  [AC_MSG_ERROR([cannot compile a test that uses Boost $1])],
 360                       [AC_MSG_NOTICE([cannot compile a test that uses Boost $1])])
 361      $6])
 362   ac_objext=$boost_save_ac_objext
 363   boost_failed_libs=
 364 # Don't bother to ident the 6 nested for loops, only the 2 innermost ones
 365 # matter.
 366 for boost_tag_ in -$boost_cv_lib_tag ''; do
 367 for boost_ver_ in -$boost_cv_lib_version ''; do
 368 for boost_mt_ in $boost_mt -mt ''; do
 369 for boost_rtopt_ in $boost_rtopt '' -d; do
 370   for boost_lib in \
 371     boost_$1$boost_tag_$boost_mt_$boost_rtopt_$boost_ver_ \
 372     boost_$1$boost_tag_$boost_rtopt_$boost_ver_ \
 373     boost_$1$boost_tag_$boost_mt_$boost_ver_ \
 374     boost_$1$boost_tag_$boost_ver_
 375   do
 376     # Avoid testing twice the same lib
 377     case $boost_failed_libs in #(
 378       *@$boost_lib@*) continue;;
 379     esac
 380     # If with_boost is empty, we'll search in /lib first, which is not quite
 381     # right so instead we'll try to a location based on where the headers are.
 382     boost_tmp_lib=$with_boost
 383     test x"$with_boost" = x && boost_tmp_lib=${boost_cv_inc_path%/include}
 384     for boost_ldpath in "$boost_tmp_lib/lib" '' \
 385              /opt/local/lib* /usr/local/lib* /opt/lib* /usr/lib* \
 386              "$with_boost" C:/Boost/lib /lib*
 387     do
 388       test -e "$boost_ldpath" || continue
 389       boost_save_LDFLAGS=$LDFLAGS
 390       # Are we looking for a static library?
 391       case $boost_ldpath:$boost_rtopt_ in #(
 392         *?*:*s*) # Yes (Non empty boost_ldpath + s in rt opt)
 393           Boost_lib_LIBS="$boost_ldpath/lib$boost_lib.$libext"
 394           test -e "$Boost_lib_LIBS" || continue;; #(
 395         *) # No: use -lboost_foo to find the shared library.
 396           Boost_lib_LIBS="-l$boost_lib";;
 397       esac
 398       boost_save_LIBS=$LIBS
 399       LIBS="$Boost_lib_LIBS $LIBS"
 400       test x"$boost_ldpath" != x && LDFLAGS="$LDFLAGS -L$boost_ldpath"
 401 dnl First argument of AC_LINK_IFELSE left empty because the test file is
 402 dnl generated only once above (before we start the for loops).
 403       _BOOST_AC_LINK_IFELSE([],
 404                             [Boost_lib=yes], [Boost_lib=no])
 405       ac_objext=$boost_save_ac_objext
 406       LDFLAGS=$boost_save_LDFLAGS
 407       LIBS=$boost_save_LIBS
 408       if test x"$Boost_lib" = xyes; then
 409         Boost_lib_LDFLAGS="-L$boost_ldpath -Wl,-rpath -Wl,$boost_ldpath"
 410         Boost_lib_LDPATH="$boost_ldpath"
 411         break 6
 412       else
 413         boost_failed_libs="$boost_failed_libs@$boost_lib@"
 414       fi
 415     done
 416   done
 417 done
 418 done
 419 done
 420 done
 421 rm -f conftest.$ac_objext
 422 ])
 423 case $Boost_lib in #((
 424   no) _AC_MSG_LOG_CONFTEST
 425     m4_if([$6], [], [AC_MSG_ERROR([cannot find the flags to link with Boost $1])],
 426                     [AC_MSG_NOTICE([cannot find the flags to link with Boost $1])])
 427     $6
 428     ;;
 429   *)
 430     AC_SUBST(AS_TR_CPP([BOOST_$1_LDFLAGS]), [$Boost_lib_LDFLAGS])dnl
 431     AC_SUBST(AS_TR_CPP([BOOST_$1_LDPATH]), [$Boost_lib_LDPATH])dnl
 432     AC_SUBST([BOOST_LDPATH], [$Boost_lib_LDPATH])dnl
 433     AC_SUBST(AS_TR_CPP([BOOST_$1_LIBS]), [$Boost_lib_LIBS])dnl
 434     ;;
 435 esac
 436 CPPFLAGS=$boost_save_CPPFLAGS
 437 AS_VAR_POPDEF([Boost_lib])dnl
 438 AS_VAR_POPDEF([Boost_lib_LDFLAGS])dnl
 439 AS_VAR_POPDEF([Boost_lib_LDPATH])dnl
 440 AS_VAR_POPDEF([Boost_lib_LIBS])dnl
 441 AC_LANG_POP([C++])dnl
 442 fi
 443 ])# BOOST_FIND_LIB
 444
 445
 446 # --------------------------------------- #
 447 # Checks for the various Boost libraries. #
 448 # --------------------------------------- #
 449
 450 # List of boost libraries: http://www.boost.org/libs/libraries.htm
 451 # The page http://beta.boost.org/doc/libs is useful: it gives the first release
 452 # version of each library (among other things).
 453
 454 # BOOST_DEFUN(LIBRARY, CODE)
 455 # --------------------------
 456 # Define BOOST_<LIBRARY-UPPERCASE> as a macro that runs CODE.
 457 #
 458 # Use indir to avoid the warning on underquoted macro name given to AC_DEFUN.
 459 m4_define([BOOST_DEFUN],
 460 [m4_indir([AC_DEFUN],
 461           m4_toupper([BOOST_$1]),
 462 [m4_pushdef([BOOST_Library], [$1])dnl
 463 $2
 464 m4_popdef([BOOST_Library])dnl
 465 ])
 466 ])
 467
 468 # BOOST_ARRAY()
 469 # -------------
 470 # Look for Boost.Array
 471 BOOST_DEFUN([Array],
 472 [BOOST_FIND_HEADER([boost/array.hpp])])
 473
 474
 475 # BOOST_ASIO()
 476 # ------------
 477 # Look for Boost.Asio (new in Boost 1.35).
 478 BOOST_DEFUN([Asio],
 479 [AC_REQUIRE([BOOST_SYSTEM])dnl
 480 BOOST_FIND_HEADER([boost/asio.hpp])])
 481
 482
 483 # BOOST_BIND()
 484 # ------------
 485 # Look for Boost.Bind
 486 BOOST_DEFUN([Bind],
 487 [BOOST_FIND_HEADER([boost/bind.hpp])])
 488
 489
 490 # BOOST_CHRONO()
 491 # ------------------
 492 # Look for Boost.Chrono
 493 BOOST_DEFUN([Chrono],
 494 [# Do we have to check for Boost.System?  This link-time dependency was
 495 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
 496 # find Boost.System as it didn't exist by then.
 497 if test $boost_major_version -ge 135; then
 498 BOOST_SYSTEM([$1])
 499 fi # end of the Boost.System check.
 500 boost_filesystem_save_LIBS=$LIBS
 501 boost_filesystem_save_LDFLAGS=$LDFLAGS
 502 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 503 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
 504 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 505 BOOST_FIND_LIB([chrono], [$1],
 506                 [boost/chrono.hpp],
 507                 [boost::chrono::thread_clock d;])
 508 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
 509     AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
 510 fi
 511 LIBS=$boost_filesystem_save_LIBS
 512 LDFLAGS=$boost_filesystem_save_LDFLAGS
 513
 514 ])# BOOST_CHRONO
 515
 516
 517 # BOOST_CONVERSION()
 518 # ------------------
 519 # Look for Boost.Conversion (cast / lexical_cast)
 520 BOOST_DEFUN([Conversion],
 521 [BOOST_FIND_HEADER([boost/cast.hpp])
 522 BOOST_FIND_HEADER([boost/lexical_cast.hpp])
 523 ])# BOOST_CONVERSION
 524
 525
 526 # BOOST_DATE_TIME([PREFERRED-RT-OPT])
 527 # -----------------------------------
 528 # Look for Boost.Date_Time.  For the documentation of PREFERRED-RT-OPT, see the
 529 # documentation of BOOST_FIND_LIB above.
 530 BOOST_DEFUN([Date_Time],
 531 [BOOST_FIND_LIB([date_time], [$1],
 532                 [boost/date_time/posix_time/posix_time.hpp],
 533                 [boost::posix_time::ptime t;])
 534 ])# BOOST_DATE_TIME
 535
 536
 537 # BOOST_FILESYSTEM([PREFERRED-RT-OPT])
 538 # ------------------------------------
 539 # Look for Boost.Filesystem.  For the documentation of PREFERRED-RT-OPT, see
 540 # the documentation of BOOST_FIND_LIB above.
 541 # Do not check for boost/filesystem.hpp because this file was introduced in
 542 # 1.34.
 543 BOOST_DEFUN([Filesystem],
 544 [# Do we have to check for Boost.System?  This link-time dependency was
 545 # added as of 1.35.0.  If we have a version <1.35, we must not attempt to
 546 # find Boost.System as it didn't exist by then.
 547 if test $boost_major_version -ge 135; then
 548 BOOST_SYSTEM([$1])
 549 fi # end of the Boost.System check.
 550 boost_filesystem_save_LIBS=$LIBS
 551 boost_filesystem_save_LDFLAGS=$LDFLAGS
 552 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 553 LIBS="$LIBS $BOOST_SYSTEM_LIBS"
 554 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 555 BOOST_FIND_LIB([filesystem], [$1],
 556                 [boost/filesystem/path.hpp], [boost::filesystem::path p;])
 557 if test $enable_static_boost = yes && test $boost_major_version -ge 135; then
 558     AC_SUBST([BOOST_FILESYSTEM_LIBS], ["$BOOST_FILESYSTEM_LIBS $BOOST_SYSTEM_LIBS"])
 559 fi
 560 LIBS=$boost_filesystem_save_LIBS
 561 LDFLAGS=$boost_filesystem_save_LDFLAGS
 562 ])# BOOST_FILESYSTEM
 563
 564
 565 # BOOST_FOREACH()
 566 # ---------------
 567 # Look for Boost.Foreach
 568 BOOST_DEFUN([Foreach],
 569 [BOOST_FIND_HEADER([boost/foreach.hpp])])
 570
 571
 572 # BOOST_FORMAT()
 573 # --------------
 574 # Look for Boost.Format
 575 # Note: we can't check for boost/format/format_fwd.hpp because the header isn't
 576 # standalone.  It can't be compiled because it triggers the following error:
 577 # boost/format/detail/config_macros.hpp:88: error: 'locale' in namespace 'std'
 578 #                                                  does not name a type
 579 BOOST_DEFUN([Format],
 580 [BOOST_FIND_HEADER([boost/format.hpp])])
 581
 582
 583 # BOOST_FUNCTION()
 584 # ----------------
 585 # Look for Boost.Function
 586 BOOST_DEFUN([Function],
 587 [BOOST_FIND_HEADER([boost/function.hpp])])
 588
 589
 590 # BOOST_GRAPH([PREFERRED-RT-OPT])
 591 # -------------------------------
 592 # Look for Boost.Graphs.  For the documentation of PREFERRED-RT-OPT, see the
 593 # documentation of BOOST_FIND_LIB above.
 594 BOOST_DEFUN([Graph],
 595 [BOOST_FIND_LIB([graph], [$1],
 596                 [boost/graph/adjacency_list.hpp], [boost::adjacency_list<> g;])
 597 ])# BOOST_GRAPH
 598
 599
 600 # BOOST_IOSTREAMS([PREFERRED-RT-OPT])
 601 # -----------------------------------
 602 # Look for Boost.IOStreams.  For the documentation of PREFERRED-RT-OPT, see the
 603 # documentation of BOOST_FIND_LIB above.
 604 BOOST_DEFUN([IOStreams],
 605 [BOOST_FIND_LIB([iostreams], [$1],
 606                 [boost/iostreams/device/file_descriptor.hpp],
 607                 [boost::iostreams::file_descriptor fd; fd.close();])
 608 ])# BOOST_IOSTREAMS
 609
 610
 611 # BOOST_HASH()
 612 # ------------
 613 # Look for Boost.Functional/Hash
 614 BOOST_DEFUN([Hash],
 615 [BOOST_FIND_HEADER([boost/functional/hash.hpp])])
 616
 617
 618 # BOOST_LAMBDA()
 619 # --------------
 620 # Look for Boost.Lambda
 621 BOOST_DEFUN([Lambda],
 622 [BOOST_FIND_HEADER([boost/lambda/lambda.hpp])])
 623
 624
 625 # BOOST_LOG([PREFERRED-RT-OPT])
 626 # -----------------------------
 627 # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
 628 # documentation of BOOST_FIND_LIB above.
 629 BOOST_DEFUN([Log],
 630 [BOOST_FIND_LIB([log], [$1],
 631     [boost/log/core/core.hpp],
 632     [boost::log::attribute a; a.get_value();])
 633 ])# BOOST_LOG
 634
 635
 636 # BOOST_LOG_SETUP([PREFERRED-RT-OPT])
 637 # -----------------------------------
 638 # Look for Boost.Log For the documentation of PREFERRED-RT-OPT, see the
 639 # documentation of BOOST_FIND_LIB above.
 640 BOOST_DEFUN([Log_Setup],
 641 [AC_REQUIRE([BOOST_LOG])dnl
 642 BOOST_FIND_LIB([log_setup], [$1],
 643     [boost/log/utility/init/from_settings.hpp],
 644     [boost::log::basic_settings<char> bs; bs.empty();])
 645 ])# BOOST_LOG_SETUP
 646
 647
 648 # BOOST_MATH()
 649 # ------------
 650 # Look for Boost.Math
 651 # TODO: This library isn't header-only but it comes in multiple different
 652 # flavors that don't play well with BOOST_FIND_LIB (e.g, libboost_math_c99,
 653 # libboost_math_c99f, libboost_math_c99l, libboost_math_tr1,
 654 # libboost_math_tr1f, libboost_math_tr1l).  This macro must be fixed to do the
 655 # right thing anyway.
 656 BOOST_DEFUN([Math],
 657 [BOOST_FIND_HEADER([boost/math/special_functions.hpp])])
 658
 659
 660 # BOOST_MULTIARRAY()
 661 # ------------------
 662 # Look for Boost.MultiArray
 663 BOOST_DEFUN([MultiArray],
 664 [BOOST_FIND_HEADER([boost/multi_array.hpp])])
 665
 666
 667 # BOOST_NUMERIC_CONVERSION()
 668 # --------------------------
 669 # Look for Boost.NumericConversion (policy-based numeric conversion)
 670 BOOST_DEFUN([Numeric_Conversion],
 671 [BOOST_FIND_HEADER([boost/numeric/conversion/converter.hpp])
 672 ])# BOOST_NUMERIC_CONVERSION
 673
 674
 675 # BOOST_OPTIONAL()
 676 # ----------------
 677 # Look for Boost.Optional
 678 BOOST_DEFUN([Optional],
 679 [BOOST_FIND_HEADER([boost/optional.hpp])])
 680
 681
 682 # BOOST_PREPROCESSOR()
 683 # --------------------
 684 # Look for Boost.Preprocessor
 685 BOOST_DEFUN([Preprocessor],
 686 [BOOST_FIND_HEADER([boost/preprocessor/repeat.hpp])])
 687
 688
 689 # BOOST_UNORDERED()
 690 # -----------------
 691 # Look for Boost.Unordered
 692 BOOST_DEFUN([Unordered],
 693 [BOOST_FIND_HEADER([boost/unordered_map.hpp])])
 694
 695
 696 # BOOST_UUID()
 697 # ------------
 698 # Look for Boost.Uuid
 699 BOOST_DEFUN([Uuid],
 700 [BOOST_FIND_HEADER([boost/uuid/uuid.hpp])])
 701
 702
 703 # BOOST_PROGRAM_OPTIONS([PREFERRED-RT-OPT])
 704 # -----------------------------------------
 705 # Look for Boost.Program_options.  For the documentation of PREFERRED-RT-OPT,
 706 # see the documentation of BOOST_FIND_LIB above.
 707 BOOST_DEFUN([Program_Options],
 708 [BOOST_FIND_LIB([program_options], [$1],
 709                 [boost/program_options.hpp],
 710                 [boost::program_options::options_description d("test");])
 711 ])# BOOST_PROGRAM_OPTIONS
 712
 713
 714
 715 # _BOOST_PYTHON_CONFIG(VARIABLE, FLAG)
 716 # ------------------------------------
 717 # Save VARIABLE, and define it via `python-config --FLAG`.
 718 # Substitute BOOST_PYTHON_VARIABLE.
 719 m4_define([_BOOST_PYTHON_CONFIG],
 720 [AC_SUBST([BOOST_PYTHON_$1],
 721           [`python-config --$2 2>/dev/null`])dnl
 722 boost_python_save_$1=$$1
 723 $1="$$1 $BOOST_PYTHON_$1"])
 724
 725
 726 # BOOST_PYTHON([PREFERRED-RT-OPT])
 727 # --------------------------------
 728 # Look for Boost.Python.  For the documentation of PREFERRED-RT-OPT,
 729 # see the documentation of BOOST_FIND_LIB above.
 730 BOOST_DEFUN([Python],
 731 [_BOOST_PYTHON_CONFIG([CPPFLAGS], [includes])
 732 _BOOST_PYTHON_CONFIG([LDFLAGS],   [ldflags])
 733 _BOOST_PYTHON_CONFIG([LIBS],      [libs])
 734 m4_pattern_allow([^BOOST_PYTHON_MODULE$])dnl
 735 BOOST_FIND_LIB([python], [$1],
 736                [boost/python.hpp],
 737                [], [BOOST_PYTHON_MODULE(empty) {}])
 738 CPPFLAGS=$boost_python_save_CPPFLAGS
 739 LDFLAGS=$boost_python_save_LDFLAGS
 740 LIBS=$boost_python_save_LIBS
 741 ])# BOOST_PYTHON
 742
 743
 744 # BOOST_REF()
 745 # -----------
 746 # Look for Boost.Ref
 747 BOOST_DEFUN([Ref],
 748 [BOOST_FIND_HEADER([boost/ref.hpp])])
 749
 750
 751 # BOOST_REGEX([PREFERRED-RT-OPT])
 752 # -------------------------------
 753 # Look for Boost.Regex.  For the documentation of PREFERRED-RT-OPT, see the
 754 # documentation of BOOST_FIND_LIB above.
 755 BOOST_DEFUN([Regex],
 756 [BOOST_FIND_LIB([regex], [$1],
 757                 [boost/regex.hpp],
 758                 [boost::regex exp("*"); boost::regex_match("foo", exp);])
 759 ])# BOOST_REGEX
 760
 761
 762 # BOOST_SERIALIZATION([PREFERRED-RT-OPT])
 763 # ---------------------------------------
 764 # Look for Boost.Serialization.  For the documentation of PREFERRED-RT-OPT, see
 765 # the documentation of BOOST_FIND_LIB above.
 766 BOOST_DEFUN([Serialization],
 767 [BOOST_FIND_LIB([serialization], [$1],
 768                 [boost/archive/text_oarchive.hpp],
 769                 [std::ostream* o = 0; // Cheap way to get an ostream...
 770                 boost::archive::text_oarchive t(*o);])
 771 ])# BOOST_SERIALIZATION
 772
 773
 774 # BOOST_SIGNALS([PREFERRED-RT-OPT])
 775 # ---------------------------------
 776 # Look for Boost.Signals.  For the documentation of PREFERRED-RT-OPT, see the
 777 # documentation of BOOST_FIND_LIB above.
 778 BOOST_DEFUN([Signals],
 779 [BOOST_FIND_LIB([signals], [$1],
 780                 [boost/signal.hpp],
 781                 [boost::signal<void ()> s;])
 782 ])# BOOST_SIGNALS
 783
 784
 785 # BOOST_SMART_PTR()
 786 # -----------------
 787 # Look for Boost.SmartPtr
 788 BOOST_DEFUN([Smart_Ptr],
 789 [BOOST_FIND_HEADER([boost/scoped_ptr.hpp])
 790 BOOST_FIND_HEADER([boost/shared_ptr.hpp])
 791 ])
 792
 793
 794 # BOOST_STATICASSERT()
 795 # --------------------
 796 # Look for Boost.StaticAssert
 797 BOOST_DEFUN([StaticAssert],
 798 [BOOST_FIND_HEADER([boost/static_assert.hpp])])
 799
 800
 801 # BOOST_STRING_ALGO()
 802 # -------------------
 803 # Look for Boost.StringAlgo
 804 BOOST_DEFUN([String_Algo],
 805 [BOOST_FIND_HEADER([boost/algorithm/string.hpp])
 806 ])
 807
 808
 809 # BOOST_SYSTEM([PREFERRED-RT-OPT], [ACTION-IF-NOT-FOUND])
 810 # -------------------------------------------------------
 811 # Look for Boost.System.  For the documentation of PREFERRED-RT-OPT, see the
 812 # documentation of BOOST_FIND_LIB above.  This library was introduced in Boost
 813 # 1.35.0.
 814 BOOST_DEFUN([System],
 815 [BOOST_FIND_LIB([system], [$1],
 816                 [boost/system/error_code.hpp],
 817                 [boost::system::error_code e; e.clear();],
 818                 [], [$2])
 819 ])# BOOST_SYSTEM
 820
 821
 822 # BOOST_TEST([PREFERRED-RT-OPT])
 823 # ------------------------------
 824 # Look for Boost.Test.  For the documentation of PREFERRED-RT-OPT, see the
 825 # documentation of BOOST_FIND_LIB above.
 826 BOOST_DEFUN([Test],
 827 [m4_pattern_allow([^BOOST_CHECK$])dnl
 828 BOOST_FIND_LIB([unit_test_framework], [$1],
 829                [boost/test/unit_test.hpp], [BOOST_CHECK(2 == 2);],
 830                [using boost::unit_test::test_suite;
 831                test_suite* init_unit_test_suite(int argc, char ** argv)
 832                { return NULL; }])
 833 ])# BOOST_TEST
 834
 835
 836 # BOOST_THREADS([PREFERRED-RT-OPT], [ACTION-IF-NOT-FOUND])
 837 # --------------------------------------------------------
 838 # Look for Boost.Thread.  For the documentation of PREFERRED-RT-OPT, see the
 839 # documentation of BOOST_FIND_LIB above.  If ACTION-IF-NOT-FOUND is given,
 840 # errors are non-fatal; if it's absent, errors are fatal.
 841 # FIXME: Provide an alias "BOOST_THREAD".
 842 BOOST_DEFUN([Threads],
 843 [dnl Having the pthread flag is required at least on GCC3 where
 844 dnl boost/thread.hpp would complain if we try to compile without
 845 dnl -pthread on GNU/Linux.
 846 AC_REQUIRE([_BOOST_PTHREAD_FLAG])dnl
 847 boost_threads_save_LIBS=$LIBS
 848 boost_threads_save_LDFLAGS=$LDFLAGS
 849 boost_threads_save_CPPFLAGS=$CPPFLAGS
 850 # Link-time dependency from thread to system was added as of 1.49.0.
 851 if test $boost_major_version -ge 149; then
 852 BOOST_SYSTEM([$1], [AC_MSG_WARN([[Boost system library (libboost-system) not installed or unusable; this may lead to problems with using threads.  It is recommended that you install your distribution's libboost-system development package (probably named libboost-system###-dev, or boost-system-devel, or something like that).]])])
 853 fi # end of the Boost.System check.
 854 m4_pattern_allow([^BOOST_SYSTEM_(LIBS|LDFLAGS)$])dnl
 855 LIBS="$LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
 856 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS"
 857 # Yes, we *need* to put the -pthread thing in CPPFLAGS because with GCC3,
 858 # boost/thread.hpp will trigger a #error if -pthread isn't used:
 859 #   boost/config/requires_threads.hpp:47:5: #error "Compiler threading support
 860 #   is not turned on. Please set the correct command line options for
 861 #   threading: -pthread (Linux), -pthreads (Solaris) or -mthreads (Mingw32)"
 862 CPPFLAGS="$CPPFLAGS $boost_cv_pthread_flag"
 863
 864 # When compiling for the Windows platform, the threads library is named
 865 # differently.
 866 case $host_os in
 867   (*mingw*)
 868     BOOST_FIND_LIB([thread_win32], [$1],
 869                    [boost/thread.hpp], [boost::thread t; boost::mutex m;], [], [$2])
 870     BOOST_THREAD_LDFLAGS=$BOOST_THREAD_WIN32_LDFLAGS
 871     BOOST_THREAD_LDPATH=$BOOST_THREAD_WIN32_LDPATH
 872     BOOST_THREAD_LIBS=$BOOST_THREAD_WIN32_LIBS
 873   ;;
 874   (*)
 875     BOOST_FIND_LIB([thread], [$1],
 876                    [boost/thread.hpp], [boost::thread t; boost::mutex m;], [], [$2])
 877   ;;
 878 esac
 879
 880 BOOST_THREAD_LIBS="$BOOST_THREAD_LIBS $BOOST_SYSTEM_LIBS $boost_cv_pthread_flag"
 881 BOOST_THREAD_LDFLAGS="$BOOST_SYSTEM_LDFLAGS"
 882 BOOST_CPPFLAGS="$BOOST_CPPFLAGS $boost_cv_pthread_flag"
 883 LIBS=$boost_threads_save_LIBS
 884 LDFLAGS=$boost_threads_save_LDFLAGS
 885 CPPFLAGS=$boost_threads_save_CPPFLAGS
 886 ])# BOOST_THREADS
 887
 888
 889 # BOOST_TOKENIZER()
 890 # -----------------
 891 # Look for Boost.Tokenizer
 892 BOOST_DEFUN([Tokenizer],
 893 [BOOST_FIND_HEADER([boost/tokenizer.hpp])])
 894
 895
 896 # BOOST_TRIBOOL()
 897 # ---------------
 898 # Look for Boost.Tribool
 899 BOOST_DEFUN([Tribool],
 900 [BOOST_FIND_HEADER([boost/logic/tribool_fwd.hpp])
 901 BOOST_FIND_HEADER([boost/logic/tribool.hpp])
 902 ])
 903
 904
 905 # BOOST_TUPLE()
 906 # -------------
 907 # Look for Boost.Tuple
 908 BOOST_DEFUN([Tuple],
 909 [BOOST_FIND_HEADER([boost/tuple/tuple.hpp])])
 910
 911
 912 # BOOST_TYPETRAITS()
 913 # --------------------
 914 # Look for Boost.TypeTraits
 915 BOOST_DEFUN([TypeTraits],
 916 [BOOST_FIND_HEADER([boost/type_traits.hpp])])
 917
 918
 919 # BOOST_UTILITY()
 920 # ---------------
 921 # Look for Boost.Utility (noncopyable, result_of, base-from-member idiom,
 922 # etc.)
 923 BOOST_DEFUN([Utility],
 924 [BOOST_FIND_HEADER([boost/utility.hpp])])
 925
 926
 927 # BOOST_VARIANT()
 928 # ---------------
 929 # Look for Boost.Variant.
 930 BOOST_DEFUN([Variant],
 931 [BOOST_FIND_HEADER([boost/variant/variant_fwd.hpp])
 932 BOOST_FIND_HEADER([boost/variant.hpp])])
 933
 934
 935 # BOOST_WAVE([PREFERRED-RT-OPT])
 936 # ------------------------------
 937 # NOTE: If you intend to use Wave/Spirit with thread support, make sure you
 938 # call BOOST_THREADS first.
 939 # Look for Boost.Wave.  For the documentation of PREFERRED-RT-OPT, see the
 940 # documentation of BOOST_FIND_LIB above.
 941 BOOST_DEFUN([Wave],
 942 [AC_REQUIRE([BOOST_FILESYSTEM])dnl
 943 AC_REQUIRE([BOOST_DATE_TIME])dnl
 944 boost_wave_save_LIBS=$LIBS
 945 boost_wave_save_LDFLAGS=$LDFLAGS
 946 m4_pattern_allow([^BOOST_((FILE)?SYSTEM|DATE_TIME|THREAD)_(LIBS|LDFLAGS)$])dnl
 947 LIBS="$LIBS $BOOST_SYSTEM_LIBS $BOOST_FILESYSTEM_LIBS $BOOST_DATE_TIME_LIBS \
 948 $BOOST_THREAD_LIBS"
 949 LDFLAGS="$LDFLAGS $BOOST_SYSTEM_LDFLAGS $BOOST_FILESYSTEM_LDFLAGS \
 950 $BOOST_DATE_TIME_LDFLAGS $BOOST_THREAD_LDFLAGS"
 951 BOOST_FIND_LIB([wave], [$1],
 952                 [boost/wave.hpp],
 953                 [boost::wave::token_id id; get_token_name(id);])
 954 LIBS=$boost_wave_save_LIBS
 955 LDFLAGS=$boost_wave_save_LDFLAGS
 956 ])# BOOST_WAVE
 957
 958
 959 # BOOST_XPRESSIVE()
 960 # -----------------
 961 # Look for Boost.Xpressive (new since 1.36.0).
 962 BOOST_DEFUN([Xpressive],
 963 [BOOST_FIND_HEADER([boost/xpressive/xpressive.hpp])])
 964
 965
 966 # ----------------- #
 967 # Internal helpers. #
 968 # ----------------- #
 969
 970
 971 # _BOOST_PTHREAD_FLAG()
 972 # ---------------------
 973 # Internal helper for BOOST_THREADS.  Based on ACX_PTHREAD:
 974 # http://autoconf-archive.cryp.to/acx_pthread.html
 975 AC_DEFUN([_BOOST_PTHREAD_FLAG],
 976 [AC_REQUIRE([AC_PROG_CXX])dnl
 977 AC_REQUIRE([AC_CANONICAL_HOST])dnl
 978 AC_LANG_PUSH([C++])dnl
 979 AC_CACHE_CHECK([for the flags needed to use pthreads], [boost_cv_pthread_flag],
 980 [ boost_cv_pthread_flag=
 981   # The ordering *is* (sometimes) important.  Some notes on the
 982   # individual items follow:
 983   # (none): in case threads are in libc; should be tried before -Kthread and
 984   #       other compiler flags to prevent continual compiler warnings
 985   # -lpthreads: AIX (must check this before -lpthread)
 986   # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 987   # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 988   # -llthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 989   # -pthread: GNU Linux/GCC (kernel threads), BSD/GCC (userland threads)
 990   # -pthreads: Solaris/GCC
 991   # -mthreads: MinGW32/GCC, Lynx/GCC
 992   # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 993   #      doesn't hurt to check since this sometimes defines pthreads too;
 994   #      also defines -D_REENTRANT)
 995   #      ... -mt is also the pthreads flag for HP/aCC
 996   # -lpthread: GNU Linux, etc.
 997   # --thread-safe: KAI C++
 998   case $host_os in #(
 999     *solaris*)
1000       # On Solaris (at least, for some versions), libc contains stubbed
1001       # (non-functional) versions of the pthreads routines, so link-based
1002       # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
1003       # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
1004       # a function called by this macro, so we could check for that, but
1005       # who knows whether they'll stub that too in a future libc.)  So,
1006       # we'll just look for -pthreads and -lpthread first:
1007       boost_pthread_flags="-pthreads -lpthread -mt -pthread";; #(
1008     *)
1009       boost_pthread_flags="-lpthreads -Kthread -kthread -llthread -pthread \
1010                            -pthreads -mthreads -lpthread --thread-safe -mt";;
1011   esac
1012   # Generate the test file.
1013   AC_LANG_CONFTEST([AC_LANG_PROGRAM([#include <pthread.h>],
1014     [pthread_t th; pthread_join(th, 0);
1015     pthread_attr_init(0); pthread_cleanup_push(0, 0);
1016     pthread_create(0,0,0,0); pthread_cleanup_pop(0);])])
1017   for boost_pthread_flag in '' $boost_pthread_flags; do
1018     boost_pthread_ok=false
1019 dnl Re-use the test file already generated.
1020     boost_pthreads__save_LIBS=$LIBS
1021     LIBS="$LIBS $boost_pthread_flag"
1022     AC_LINK_IFELSE([],
1023       [if grep ".*$boost_pthread_flag" conftest.err; then
1024          echo "This flag seems to have triggered warnings" >&AS_MESSAGE_LOG_FD
1025        else
1026          boost_pthread_ok=:; boost_cv_pthread_flag=$boost_pthread_flag
1027        fi])
1028     LIBS=$boost_pthreads__save_LIBS
1029     $boost_pthread_ok && break
1030   done
1031 ])
1032 AC_LANG_POP([C++])dnl
1033 ])# _BOOST_PTHREAD_FLAG
1034
1035
1036 # _BOOST_gcc_test(MAJOR, MINOR)
1037 # -----------------------------
1038 # Internal helper for _BOOST_FIND_COMPILER_TAG.
1039 m4_define([_BOOST_gcc_test],
1040 ["defined __GNUC__ && __GNUC__ == $1 && __GNUC_MINOR__ == $2 && !defined __ICC @ gcc$1$2"])dnl
1041
1042
1043 # _BOOST_FIND_COMPILER_TAG()
1044 # --------------------------
1045 # Internal.  When Boost is installed without --layout=system, each library
1046 # filename will hold a suffix that encodes the compiler used during the
1047 # build.  The Boost build system seems to call this a `tag'.
1048 AC_DEFUN([_BOOST_FIND_COMPILER_TAG],
1049 [AC_REQUIRE([AC_PROG_CXX])dnl
1050 AC_REQUIRE([AC_CANONICAL_HOST])dnl
1051 AC_CACHE_CHECK([for the toolset name used by Boost for $CXX], [boost_cv_lib_tag],
1052 [boost_cv_lib_tag=unknown
1053 if test x$boost_cv_inc_path != xno; then
1054   AC_LANG_PUSH([C++])dnl
1055   # The following tests are mostly inspired by boost/config/auto_link.hpp
1056   # The list is sorted to most recent/common to oldest compiler (in order
1057   # to increase the likelihood of finding the right compiler with the
1058   # least number of compilation attempt).
1059   # Beware that some tests are sensible to the order (for instance, we must
1060   # look for MinGW before looking for GCC3).
1061   # I used one compilation test per compiler with a #error to recognize
1062   # each compiler so that it works even when cross-compiling (let me know
1063   # if you know a better approach).
1064   # Known missing tags (known from Boost's tools/build/v2/tools/common.jam):
1065   #   como, edg, kcc, bck, mp, sw, tru, xlc
1066   # I'm not sure about my test for `il' (be careful: Intel's ICC pre-defines
1067   # the same defines as GCC's).
1068   for i in \
1069     _BOOST_gcc_test(4, 8) \
1070     _BOOST_gcc_test(4, 7) \
1071     _BOOST_gcc_test(4, 6) \
1072     _BOOST_gcc_test(4, 5) \
1073     _BOOST_gcc_test(4, 4) \
1074     _BOOST_gcc_test(4, 3) \
1075     _BOOST_gcc_test(4, 2) \
1076     _BOOST_gcc_test(4, 1) \
1077     _BOOST_gcc_test(4, 0) \
1078     "defined __GNUC__ && __GNUC__ == 3 && !defined __ICC \
1079      && (defined WIN32 || defined WINNT || defined _WIN32 || defined __WIN32 \
1080          || defined __WIN32__ || defined __WINNT || defined __WINNT__) @ mgw" \
1081     _BOOST_gcc_test(3, 4) \
1082     _BOOST_gcc_test(3, 3) \
1083     "defined _MSC_VER && _MSC_VER >= 1500 @ vc90" \
1084     "defined _MSC_VER && _MSC_VER == 1400 @ vc80" \
1085     _BOOST_gcc_test(3, 2) \
1086     "defined _MSC_VER && _MSC_VER == 1310 @ vc71" \
1087     _BOOST_gcc_test(3, 1) \
1088     _BOOST_gcc_test(3, 0) \
1089     "defined __BORLANDC__ @ bcb" \
1090     "defined __ICC && (defined __unix || defined __unix__) @ il" \
1091     "defined __ICL @ iw" \
1092     "defined _MSC_VER && _MSC_VER == 1300 @ vc7" \
1093     _BOOST_gcc_test(2, 95) \
1094     "defined __MWERKS__ && __MWERKS__ <= 0x32FF @ cw9" \
1095     "defined _MSC_VER && _MSC_VER < 1300 && !defined UNDER_CE @ vc6" \
1096     "defined _MSC_VER && _MSC_VER < 1300 && defined UNDER_CE @ evc4" \
1097     "defined __MWERKS__ && __MWERKS__ <= 0x31FF @ cw8"
1098   do
1099     boost_tag_test=`expr "X$i" : 'X\([[^@]]*\) @ '`
1100     boost_tag=`expr "X$i" : 'X[[^@]]* @ \(.*\)'`
1101     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1102 #if $boost_tag_test
1103 /* OK */
1104 #else
1105 # error $boost_tag_test
1106 #endif
1107 ]])], [boost_cv_lib_tag=$boost_tag; break], [])
1108   done
1109 AC_LANG_POP([C++])dnl
1110   case $boost_cv_lib_tag in #(
1111     # Some newer (>= 1.35?) versions of Boost seem to only use "gcc" as opposed
1112     # to "gcc41" for instance.
1113     *-gcc | *'-gcc ') :;; #(  Don't re-add -gcc: it's already in there.
1114     gcc*)
1115       boost_tag_x=
1116       case $host_os in #(
1117         darwin*)
1118           if test $boost_major_version -ge 136; then
1119             # The `x' added in r46793 of Boost.
1120             boost_tag_x=x
1121           fi;;
1122       esac
1123       # We can specify multiple tags in this variable because it's used by
1124       # BOOST_FIND_LIB that does a `for tag in -$boost_cv_lib_tag' ...
1125       boost_cv_lib_tag="$boost_tag_x$boost_cv_lib_tag -${boost_tag_x}gcc"
1126       ;; #(
1127     unknown)
1128       AC_MSG_WARN([[could not figure out which toolset name to use for $CXX]])
1129       boost_cv_lib_tag=
1130       ;;
1131   esac
1132 fi])dnl end of AC_CACHE_CHECK
1133 ])# _BOOST_FIND_COMPILER_TAG
1134
1135
1136 # _BOOST_GUESS_WHETHER_TO_USE_MT()
1137 # --------------------------------
1138 # Compile a small test to try to guess whether we should favor MT (Multi
1139 # Thread) flavors of Boost.  Sets boost_guess_use_mt accordingly.
1140 AC_DEFUN([_BOOST_GUESS_WHETHER_TO_USE_MT],
1141 [# Check whether we do better use `mt' even though we weren't ask to.
1142 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1143 #if defined _REENTRANT || defined _MT || defined __MT__
1144 /* use -mt */
1145 #else
1146 # error MT not needed
1147 #endif
1148 ]])], [boost_guess_use_mt=:], [boost_guess_use_mt=false])
1149 ])
1150
1151 # _BOOST_AC_LINK_IFELSE(PROGRAM, [ACTION-IF-TRUE], [ACTION-IF-FALSE])
1152 # -------------------------------------------------------------------
1153 # Fork of _AC_LINK_IFELSE that preserves conftest.o across calls.  Fragile,
1154 # will break when Autoconf changes its internals.  Requires that you manually
1155 # rm -f conftest.$ac_objext in between to really different tests, otherwise
1156 # you will try to link a conftest.o left behind by a previous test.
1157 # Used to aggressively optimize BOOST_FIND_LIB (see the big comment in this
1158 # macro).
1159 #
1160 # Don't use "break" in the actions, as it would short-circuit some code
1161 # this macro runs after the actions.
1162 m4_define([_BOOST_AC_LINK_IFELSE],
1163 [m4_ifvaln([$1], [AC_LANG_CONFTEST([$1])])dnl
1164 rm -f conftest$ac_exeext
1165 boost_save_ac_ext=$ac_ext
1166 boost_use_source=:
1167 # If we already have a .o, re-use it.  We change $ac_ext so that $ac_link
1168 # tries to link the existing object file instead of compiling from source.
1169 test -f conftest.$ac_objext && ac_ext=$ac_objext && boost_use_source=false &&
1170   _AS_ECHO_LOG([re-using the existing conftest.$ac_objext])
1171 AS_IF([_AC_DO_STDERR($ac_link) && {
1172          test -z "$ac_[]_AC_LANG_ABBREV[]_werror_flag" ||
1173          test ! -s conftest.err
1174        } && test -s conftest$ac_exeext && {
1175          test "$cross_compiling" = yes ||
1176          $as_executable_p conftest$ac_exeext
1177 dnl FIXME: use AS_TEST_X instead when 2.61 is widespread enough.
1178        }],
1179       [$2],
1180       [if $boost_use_source; then
1181          _AC_MSG_LOG_CONFTEST
1182        fi
1183        $3])
1184 ac_objext=$boost_save_ac_objext
1185 ac_ext=$boost_save_ac_ext
1186 dnl Delete also the IPA/IPO (Inter Procedural Analysis/Optimization)
1187 dnl information created by the PGI compiler (conftest_ipa8_conftest.oo),
1188 dnl as it would interfere with the next link command.
1189 rm -f core conftest.err conftest_ipa8_conftest.oo \
1190       conftest$ac_exeext m4_ifval([$1], [conftest.$ac_ext])[]dnl
1191 ])# _BOOST_AC_LINK_IFELSE
1192
1193 # Local Variables:
1194 # mode: autoconf
1195 # End: