config/cvc4.m4

   1 # CVC4_AC_INIT
   2 # ------------
   3 # Do early initialization/diversion of autoconf things for CVC4 build process.
   4 AC_DEFUN([CVC4_AC_INIT],
   5 dnl _AS_ME_PREPARE
   6 [CVC4_REWRITE_ARGS_FOR_BUILD_PROFILE
   7 ])# CVC4_AC_INIT
   8
   9
  10 # CVC4_REWRITE_ARGS_FOR_BUILD_PROFILE
  11 # -----------------------------------
  12 # Rewrite (e.g.) "./configure debug" to "./configure --with-build=debug"
  13 AC_DEFUN([CVC4_REWRITE_ARGS_FOR_BUILD_PROFILE],
  14 [m4_divert_push([PARSE_ARGS])dnl
  15
  16 unset ac_cvc4_rewritten_args
  17 for ac_option
  18 do
  19   case $ac_option in
  20     -*|*=*) ;;
  21     production|production-*|debug|debug-*|default|default-*|competition|competition-*)
  22       ac_option_build=`expr "$ac_option" : '\([[^-]]*\)-\?'`
  23       ac_cvc4_build_profile_set=yes
  24       AC_MSG_NOTICE([CVC4: building profile $ac_option_build])
  25       for x in optimized assertions tracing muzzle coverage profiling; do
  26         if expr "$ac_option" : '.*-no'$x'-\|.*-no'$x'$' >/dev/null; then
  27           eval 'ac_cvc4_rewritten_args="${ac_cvc4_rewritten_args+$ac_cvc4_rewritten_args }\"--disable-$x\""'
  28         fi
  29         if expr "$ac_option" : '.*-'$x'-\|.*-'$x'$' >/dev/null; then
  30           eval 'ac_cvc4_rewritten_args="${ac_cvc4_rewritten_args+$ac_cvc4_rewritten_args }\"--enable-$x\""'
  31         fi
  32       done
  33       if expr "$ac_option" : '.*-nodebugsymbols-\|.*-nodebugsymbols$' >/dev/null; then
  34         eval 'ac_cvc4_rewritten_args="${ac_cvc4_rewritten_args+$ac_cvc4_rewritten_args }\"--disable-debug-symbols\""'
  35       fi
  36       if expr "$ac_option" : '.*-debugsymbols-\|.*-debugsymbols$' >/dev/null; then
  37         eval 'ac_cvc4_rewritten_args="${ac_cvc4_rewritten_args+$ac_cvc4_rewritten_args }\"--enable-debug-symbols\""'
  38       fi
  39       ac_option="--with-build=$ac_option_build"
  40   esac
  41   eval 'ac_cvc4_rewritten_args="${ac_cvc4_rewritten_args+$ac_cvc4_rewritten_args }\"$ac_option\""'
  42 done
  43 eval set x $ac_cvc4_rewritten_args
  44 shift
  45 dnl echo "args are now:" "${@}"
  46 m4_divert_pop([PARSE_ARGS])dnl
  47 ])# CVC4_REWRITE_ARGS_FOR_BUILD_PROFILE