configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 LIBUDEV_REQUIRED=151
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.2.0
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94 LIBSENSORS_REQUIRED=4.0.0
  95
  96 dnl Check for progs
  97 AC_PROG_CPP
  98 AC_PROG_CC
  99 AC_PROG_CXX
 100 AM_PROG_CC_C_O
 101 AM_PROG_AS
 102 AX_CHECK_GNU_MAKE
 103 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 104 AC_PROG_SED
 105 AC_PROG_MKDIR_P
 106
 107 AC_SYS_LARGEFILE
 108
 109 LT_PREREQ([2.2])
 110 LT_INIT([disable-static])
 111
 112 AC_CHECK_PROG(RM, rm, [rm -f])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.
 827 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 828
 829 dnl pthread-stubs is mandatory on targets where it exists
 830 case "$host_os" in
 831 cygwin* )
 832     pthread_stubs_possible="no"
 833     ;;
 834 * )
 835     pthread_stubs_possible="yes"
 836     ;;
 837 esac
 838
 839 if test "x$pthread_stubs_possible" = xyes; then
 840     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 841     AC_SUBST(PTHREADSTUBS_CFLAGS)
 842     AC_SUBST(PTHREADSTUBS_LIBS)
 843 fi
 844
 845 dnl SELinux awareness.
 846 AC_ARG_ENABLE([selinux],
 847     [AS_HELP_STRING([--enable-selinux],
 848         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 849     [MESA_SELINUX="$enableval"],
 850     [MESA_SELINUX=no])
 851 if test "x$enable_selinux" = "xyes"; then
 852     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 853         [AC_CHECK_HEADER([selinux/selinux.h],[],
 854                          [AC_MSG_ERROR([SELinux headers not found])])
 855          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 856                       [AC_MSG_ERROR([SELinux library not found])])
 857          SELINUX_LIBS="-lselinux"])
 858     DEFINES="$DEFINES -DMESA_SELINUX"
 859 fi
 860 AC_SUBST([SELINUX_CFLAGS])
 861 AC_SUBST([SELINUX_LIBS])
 862
 863 dnl Options for APIs
 864 AC_ARG_ENABLE([opengl],
 865     [AS_HELP_STRING([--disable-opengl],
 866         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 867     [enable_opengl="$enableval"],
 868     [enable_opengl=yes])
 869 AC_ARG_ENABLE([gles1],
 870     [AS_HELP_STRING([--disable-gles1],
 871         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 872     [enable_gles1="$enableval"],
 873     [enable_gles1=yes])
 874 AC_ARG_ENABLE([gles2],
 875     [AS_HELP_STRING([--disable-gles2],
 876         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 877     [enable_gles2="$enableval"],
 878     [enable_gles2=yes])
 879
 880 AC_ARG_ENABLE([dri],
 881     [AS_HELP_STRING([--enable-dri],
 882         [enable DRI modules @<:@default=enabled@:>@])],
 883     [enable_dri="$enableval"],
 884     [enable_dri=yes])
 885
 886 AC_ARG_ENABLE([gallium-extra-hud],
 887     [AS_HELP_STRING([--enable-gallium-extra-hud],
 888         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 889     [enable_gallium_extra_hud="$enableval"],
 890     [enable_gallium_extra_hud=no])
 891 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 892 if test "x$enable_gallium_extra_hud" = xyes ; then
 893     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 894 fi
 895
 896 #TODO: no pkgconfig .pc available for libsensors.
 897 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 898 AC_ARG_ENABLE([lmsensors],
 899     [AS_HELP_STRING([--enable-lmsensors],
 900         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 901     [enable_lmsensors="$enableval"],
 902     [enable_lmsensors=no])
 903 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 904 if test "x$enable_lmsensors" = xyes ; then
 905     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 906     LIBSENSORS_LDFLAGS="-lsensors"
 907 else
 908     LIBSENSORS_LDFLAGS=""
 909 fi
 910 AC_SUBST(LIBSENSORS_LDFLAGS)
 911
 912 case "$host_os" in
 913 linux*)
 914     dri3_default=yes
 915     ;;
 916 *)
 917     dri3_default=no
 918     ;;
 919 esac
 920
 921 if test "x$enable_dri" = xno; then
 922     dri3_default=no
 923 fi
 924
 925 AC_ARG_ENABLE([dri3],
 926     [AS_HELP_STRING([--enable-dri3],
 927         [enable DRI3 @<:@default=auto@:>@])],
 928     [enable_dri3="$enableval"],
 929     [enable_dri3="$dri3_default"])
 930 AC_ARG_ENABLE([glx],
 931     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 932         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 933     [enable_glx="$enableval"],
 934     [enable_glx=yes])
 935 AC_ARG_ENABLE([osmesa],
 936     [AS_HELP_STRING([--enable-osmesa],
 937         [enable OSMesa library @<:@default=disabled@:>@])],
 938     [enable_osmesa="$enableval"],
 939     [enable_osmesa=no])
 940 AC_ARG_ENABLE([gallium-osmesa],
 941     [AS_HELP_STRING([--enable-gallium-osmesa],
 942         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 943     [enable_gallium_osmesa="$enableval"],
 944     [enable_gallium_osmesa=no])
 945 AC_ARG_ENABLE([egl],
 946     [AS_HELP_STRING([--disable-egl],
 947         [disable EGL library @<:@default=enabled@:>@])],
 948     [enable_egl="$enableval"],
 949     [enable_egl=yes])
 950
 951 AC_ARG_ENABLE([xa],
 952     [AS_HELP_STRING([--enable-xa],
 953         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 954     [enable_xa="$enableval"],
 955     [enable_xa=no])
 956 AC_ARG_ENABLE([gbm],
 957    [AS_HELP_STRING([--enable-gbm],
 958          [enable gbm library @<:@default=auto@:>@])],
 959    [enable_gbm="$enableval"],
 960    [enable_gbm=auto])
 961 AC_ARG_ENABLE([nine],
 962     [AS_HELP_STRING([--enable-nine],
 963         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 964     [enable_nine="$enableval"],
 965     [enable_nine=no])
 966
 967 AC_ARG_ENABLE([xvmc],
 968    [AS_HELP_STRING([--enable-xvmc],
 969          [enable xvmc library @<:@default=auto@:>@])],
 970    [enable_xvmc="$enableval"],
 971    [enable_xvmc=auto])
 972 AC_ARG_ENABLE([vdpau],
 973    [AS_HELP_STRING([--enable-vdpau],
 974          [enable vdpau library @<:@default=auto@:>@])],
 975    [enable_vdpau="$enableval"],
 976    [enable_vdpau=auto])
 977 AC_ARG_ENABLE([omx],
 978    [AS_HELP_STRING([--enable-omx],
 979          [enable OpenMAX library @<:@default=disabled@:>@])],
 980    [enable_omx="$enableval"],
 981    [enable_omx=no])
 982 AC_ARG_ENABLE([va],
 983    [AS_HELP_STRING([--enable-va],
 984          [enable va library @<:@default=auto@:>@])],
 985    [enable_va="$enableval"],
 986    [enable_va=auto])
 987 AC_ARG_ENABLE([opencl],
 988    [AS_HELP_STRING([--enable-opencl],
 989          [enable OpenCL library @<:@default=disabled@:>@])],
 990    [enable_opencl="$enableval"],
 991    [enable_opencl=no])
 992 AC_ARG_ENABLE([opencl_icd],
 993    [AS_HELP_STRING([--enable-opencl-icd],
 994           [Build an OpenCL ICD library to be loaded by an ICD implementation
 995            @<:@default=disabled@:>@])],
 996     [enable_opencl_icd="$enableval"],
 997     [enable_opencl_icd=no])
 998
 999 AC_ARG_ENABLE([gallium-tests],
1000     [AS_HELP_STRING([--enable-gallium-tests],
1001         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1002     [enable_gallium_tests="$enableval"],
1003     [enable_gallium_tests=no])
1004
1005 # Option for Gallium drivers
1006
1007 # Keep this in sync with the --with-gallium-drivers help string default value
1008 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1009
1010 AC_ARG_WITH([gallium-drivers],
1011     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1012         [comma delimited Gallium drivers list, e.g.
1013         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1014         @<:@default=r300,r600,svga,swrast@:>@])],
1015     [with_gallium_drivers="$withval"],
1016     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1017
1018 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1019 # here so that the script doesn't choke on an unknown driver name later.
1020 case "$with_gallium_drivers" in
1021     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1022     no) with_gallium_drivers='' ;;
1023 esac
1024
1025 if test "x$enable_opengl" = xno -a \
1026         "x$enable_gles1" = xno -a \
1027         "x$enable_gles2" = xno -a \
1028         "x$enable_nine" = xno -a \
1029         "x$enable_xa" = xno -a \
1030         "x$enable_xvmc" = xno -a \
1031         "x$enable_vdpau" = xno -a \
1032         "x$enable_omx" = xno -a \
1033         "x$enable_va" = xno -a \
1034         "x$enable_opencl" = xno; then
1035     AC_MSG_ERROR([at least one API should be enabled])
1036 fi
1037
1038 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1039 if test "x$enable_opengl" = xno -a \
1040         "x$enable_gles1" = xyes; then
1041     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1042 fi
1043
1044 if test "x$enable_opengl" = xno -a \
1045         "x$enable_gles2" = xyes; then
1046     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1047 fi
1048
1049 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1050 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1051 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1052 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1053                                         "x$enable_gles1" = xyes -o \
1054                                         "x$enable_gles2" = xyes)
1055
1056 # Validate GLX options
1057 if test "x$enable_glx" = xyes; then
1058     if test "x$enable_dri" = xyes; then
1059         enable_glx=dri
1060     elif test -n "$with_gallium_drivers"; then
1061         enable_glx=gallium-xlib
1062     else
1063         enable_glx=xlib
1064     fi
1065 fi
1066 case "x$enable_glx" in
1067 xdri | xxlib | xgallium-xlib)
1068     # GLX requires OpenGL
1069     if test "x$enable_opengl" = xno; then
1070         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1071     fi
1072
1073     # Check individual dependencies
1074     case "x$enable_glx" in
1075     xdri)
1076         if test "x$enable_dri" = xno; then
1077             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1078         fi
1079         ;;
1080     xxlib)
1081         if test "x$enable_dri" = xyes; then
1082             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1083         fi
1084         ;;
1085     xgallium-xlib )
1086         if test "x$enable_dri" = xyes; then
1087             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1088         fi
1089         if test -z "$with_gallium_drivers"; then
1090             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1091         fi
1092         ;;
1093     esac
1094     ;;
1095 xno)
1096     ;;
1097 *)
1098     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1099     ;;
1100 esac
1101
1102 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1103 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1104 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1105 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1106
1107 dnl
1108 dnl Libglvnd configuration
1109 dnl
1110 AC_ARG_ENABLE([libglvnd],
1111     [AS_HELP_STRING([--enable-libglvnd],
1112         [Build for libglvnd @<:@default=disabled@:>@])],
1113     [enable_libglvnd="$enableval"],
1114     [enable_libglvnd=no])
1115 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1116 if test "x$enable_libglvnd" = xyes ; then
1117     dnl XXX: update once we can handle more than libGL/glx.
1118     dnl Namely: we should error out if neither of the glvnd enabled libraries
1119     dnl are built
1120     case "x$enable_glx" in
1121     xno)
1122         AC_MSG_ERROR([cannot build libglvnd without GLX])
1123         ;;
1124     xxlib | xgallium-xlib )
1125         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1126         ;;
1127     xdri)
1128         ;;
1129     esac
1130
1131     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1132     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1133     DEFAULT_GL_LIB_NAME=GLX_mesa
1134 fi
1135
1136 # Check for libdrm
1137 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1138                   [have_libdrm=yes], [have_libdrm=no])
1139 if test "x$have_libdrm" = xyes; then
1140         DEFINES="$DEFINES -DHAVE_LIBDRM"
1141 fi
1142
1143 # Select which platform-dependent DRI code gets built
1144 case "$host_os" in
1145 darwin*)
1146     dri_platform='apple' ;;
1147 cygwin*)
1148     dri_platform='windows' ;;
1149 gnu*)
1150     dri_platform='none' ;;
1151 *)
1152     dri_platform='drm' ;;
1153 esac
1154
1155 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1156     have_drisw_kms='yes'
1157 fi
1158
1159 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1160 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1161 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1162 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1163 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1164 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1165 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1166 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1167 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1168
1169 AC_ARG_ENABLE([shared-glapi],
1170     [AS_HELP_STRING([--enable-shared-glapi],
1171         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1172     [enable_shared_glapi="$enableval"],
1173     [enable_shared_glapi=yes])
1174
1175 case "x$enable_opengl$enable_gles1$enable_gles2" in
1176 x*yes*yes*)
1177     if test "x$enable_shared_glapi" = xno; then
1178         AC_MSG_ERROR([shared GLAPI required when building two or more of
1179                       the following APIs - opengl, gles1 gles2])
1180     fi
1181     ;;
1182 esac
1183
1184 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1185
1186 # Build the pipe-drivers as separate libraries/modules.
1187 # Do not touch this unless you know what you are doing.
1188 # XXX: Expose via configure option ?
1189 enable_shared_pipe_drivers=no
1190
1191 dnl
1192 dnl Driver specific build directories
1193 dnl
1194
1195 if test "x$enable_gallium_osmesa" = xyes; then
1196     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1197         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1198     fi
1199     if test "x$enable_osmesa" = xyes; then
1200         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1201     fi
1202 fi
1203
1204 AC_SUBST([MESA_LLVM])
1205
1206 # SHA1 hashing
1207 AC_ARG_WITH([sha1],
1208         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1209         [choose SHA1 implementation])])
1210 case "x$with_sha1" in
1211 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1212   ;;
1213 *)
1214         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1215 esac
1216
1217 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1218 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1219         with_sha1=libc
1220 fi
1221 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1222         AC_MSG_ERROR([sha1 in libc requested but not found])
1223 fi
1224 if test "x$with_sha1" = xlibc; then
1225         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1226                 [Use libc SHA1 functions])
1227         SHA1_LIBS=""
1228 fi
1229 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1230 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1231         with_sha1=CommonCrypto
1232 fi
1233 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1234         AC_MSG_ERROR([CommonCrypto requested but not found])
1235 fi
1236 if test "x$with_sha1" = xCommonCrypto; then
1237         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1238                 [Use CommonCrypto SHA1 functions])
1239         SHA1_LIBS=""
1240 fi
1241 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1242 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1243 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1244         with_sha1=CryptoAPI
1245 fi
1246 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1247         AC_MSG_ERROR([CryptoAPI requested but not found])
1248 fi
1249 if test "x$with_sha1" = xCryptoAPI; then
1250         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1251                 [Use CryptoAPI SHA1 functions])
1252         SHA1_LIBS=""
1253 fi
1254 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1255 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1256         with_sha1=libmd
1257 fi
1258 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1259         AC_MSG_ERROR([libmd requested but not found])
1260 fi
1261 if test "x$with_sha1" = xlibmd; then
1262         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1263                   [Use libmd SHA1 functions])
1264         SHA1_LIBS=-lmd
1265 fi
1266 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1267 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1268    with_sha1=libsha1
1269 fi
1270 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1271         AC_MSG_ERROR([libsha1 requested but not found])
1272 fi
1273 if test "x$with_sha1" = xlibsha1; then
1274         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1275                   [Use libsha1 for SHA1])
1276         SHA1_LIBS=-lsha1
1277 fi
1278 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1279 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1280         with_sha1=libnettle
1281 fi
1282 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1283         AC_MSG_ERROR([libnettle requested but not found])
1284 fi
1285 if test "x$with_sha1" = xlibnettle; then
1286         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1287                   [Use libnettle SHA1 functions])
1288         SHA1_LIBS=-lnettle
1289 fi
1290 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1291 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1292         with_sha1=libgcrypt
1293 fi
1294 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1295         AC_MSG_ERROR([libgcrypt requested but not found])
1296 fi
1297 if test "x$with_sha1" = xlibgcrypt; then
1298         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1299                   [Use libgcrypt SHA1 functions])
1300         SHA1_LIBS=-lgcrypt
1301 fi
1302 # We don't need all of the OpenSSL libraries, just libcrypto
1303 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1304 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1305                   [HAVE_OPENSSL_PKC=no])
1306 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1307         if test "x$with_sha1" = x; then
1308                 with_sha1=libcrypto
1309         fi
1310 else
1311         if test "x$with_sha1" = xlibcrypto; then
1312                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1313         fi
1314 fi
1315 if test "x$with_sha1" = xlibcrypto; then
1316         if test "x$HAVE_LIBCRYPTO" = xyes; then
1317                 SHA1_LIBS=-lcrypto
1318         else
1319                 SHA1_LIBS="$OPENSSL_LIBS"
1320                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1321         fi
1322 fi
1323 AC_MSG_CHECKING([for SHA1 implementation])
1324 AC_MSG_RESULT([$with_sha1])
1325 AC_SUBST(SHA1_LIBS)
1326 AC_SUBST(SHA1_CFLAGS)
1327
1328 # Enable a define for SHA1
1329 if test "x$with_sha1" != "x"; then
1330         DEFINES="$DEFINES -DHAVE_SHA1"
1331 fi
1332
1333 # Allow user to configure out the shader-cache feature
1334 AC_ARG_ENABLE([shader-cache],
1335     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1336     [enable_shader_cache="$enableval"],
1337     [if test "x$with_sha1" != "x"; then
1338         enable_shader_cache=yes
1339      else
1340         enable_shader_cache=no
1341      fi])
1342 if test "x$with_sha1" = "x"; then
1343     if test "x$enable_shader_cache" = "xyes"; then
1344         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1345     fi
1346 fi
1347 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1348 if test "x$enable_shader_cache" = "xyes"; then
1349    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1350 fi
1351
1352 case "$host_os" in
1353 linux*)
1354     need_pci_id=yes ;;
1355 *)
1356     need_pci_id=no ;;
1357 esac
1358
1359 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1360                   have_libudev=yes, have_libudev=no)
1361
1362 AC_ARG_ENABLE([sysfs],
1363     [AS_HELP_STRING([--enable-sysfs],
1364         [enable /sys PCI identification @<:@default=disabled@:>@])],
1365     [have_sysfs="$enableval"],
1366     [have_sysfs=no]
1367 )
1368
1369 if test "x$enable_dri" = xyes; then
1370     if test "$enable_static" = yes; then
1371         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1372     fi
1373
1374     # not a hard requirement as swrast does not depend on it
1375     if test "x$have_libdrm" = xyes; then
1376         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1377     fi
1378 fi
1379
1380 AC_ARG_ENABLE([driglx-direct],
1381     [AS_HELP_STRING([--disable-driglx-direct],
1382         [disable direct rendering in GLX and EGL for DRI \
1383             @<:@default=auto@:>@])],
1384     [driglx_direct="$enableval"],
1385     [driglx_direct="yes"])
1386
1387 dnl
1388 dnl libGL configuration per driver
1389 dnl
1390 case "x$enable_glx" in
1391 xxlib | xgallium-xlib)
1392     # Xlib-based GLX
1393     dri_modules="x11 xext xcb"
1394     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1395     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1396     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1397     GL_LIB_DEPS="$XLIBGL_LIBS"
1398     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1399     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1400     ;;
1401 xdri)
1402     # DRI-based GLX
1403     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1404
1405     # find the DRI deps for libGL
1406     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1407
1408     if test x"$driglx_direct" = xyes; then
1409         if test x"$dri_platform" = xdrm ; then
1410             DEFINES="$DEFINES -DGLX_USE_DRM"
1411             if test "x$have_libdrm" != xyes; then
1412                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1413             fi
1414
1415             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1416             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1417             if test x"$enable_dri3" = xyes; then
1418                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1419                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1420             fi
1421
1422             if test x"$enable_dri" = xyes; then
1423                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1424             fi
1425
1426             if test x"$enable_dri3" = xyes; then
1427                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1428                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1429                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1430             fi
1431         fi
1432         if test x"$dri_platform" = xapple ; then
1433             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1434         fi
1435         if test x"$dri_platform" = xwindows ; then
1436             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1437         fi
1438     fi
1439
1440     # add xf86vidmode if available
1441     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1442     if test "$HAVE_XF86VIDMODE" = yes ; then
1443         dri_modules="$dri_modules xxf86vm"
1444     fi
1445
1446     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1447     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1448     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1449     GL_LIB_DEPS="$DRIGL_LIBS"
1450
1451     # need DRM libs, $PTHREAD_LIBS, etc.
1452     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1453     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1454     ;;
1455 esac
1456
1457 have_pci_id=no
1458 if test "$have_libudev" = yes; then
1459     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1460     have_pci_id=yes
1461 fi
1462
1463 if test "$have_sysfs" = yes; then
1464     DEFINES="$DEFINES -DHAVE_SYSFS"
1465     have_pci_id=yes
1466 fi
1467
1468 # This is outside the case (above) so that it is invoked even for non-GLX
1469 # builds.
1470 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1471
1472 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1473 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1474 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1475 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1476
1477 AC_SUBST([X11_INCLUDES])
1478 AC_SUBST([GL_LIB_DEPS])
1479 AC_SUBST([GL_PC_REQ_PRIV])
1480 AC_SUBST([GL_PC_LIB_PRIV])
1481 AC_SUBST([GL_PC_CFLAGS])
1482 AC_SUBST([DRI_PC_REQ_PRIV])
1483 AC_SUBST([GLESv1_CM_LIB_DEPS])
1484 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1485 AC_SUBST([GLESv2_LIB_DEPS])
1486 AC_SUBST([GLESv2_PC_LIB_PRIV])
1487
1488 AC_SUBST([HAVE_XF86VIDMODE])
1489
1490 dnl
1491 dnl More GLX setup
1492 dnl
1493 case "x$enable_glx" in
1494 xxlib | xgallium-xlib)
1495     DEFINES="$DEFINES -DUSE_XSHM"
1496     ;;
1497 xdri)
1498     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1499     if test "x$driglx_direct" = xyes; then
1500         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1501     fi
1502     ;;
1503 esac
1504
1505 dnl
1506 dnl TLS detection
1507 dnl
1508
1509 AC_ARG_ENABLE([glx-tls],
1510     [AS_HELP_STRING([--enable-glx-tls],
1511         [enable TLS support in GLX @<:@default=disabled@:>@])],
1512     [GLX_USE_TLS="$enableval"],
1513     [GLX_USE_TLS=no])
1514 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1515
1516 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1517       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1518
1519 dnl Read-only text section on x86 hardened platforms
1520 AC_ARG_ENABLE([glx-read-only-text],
1521     [AS_HELP_STRING([--enable-glx-read-only-text],
1522         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1523     [enable_glx_read_only_text="$enableval"],
1524     [enable_glx_read_only_text=no])
1525 if test "x$enable_glx_read_only_text" = xyes; then
1526     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1527 fi
1528
1529 dnl
1530 dnl More DRI setup
1531 dnl
1532 dnl Directory for DRI drivers
1533 AC_ARG_WITH([dri-driverdir],
1534     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1535         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1536     [DRI_DRIVER_INSTALL_DIR="$withval"],
1537     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1538 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1539 dnl Extra search path for DRI drivers
1540 AC_ARG_WITH([dri-searchpath],
1541     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1542         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1543     [DRI_DRIVER_SEARCH_DIR="$withval"],
1544     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1545 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1546 dnl Which drivers to build - default is chosen by platform
1547 AC_ARG_WITH([dri-drivers],
1548     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1549         [comma delimited classic DRI drivers list, e.g.
1550         "swrast,i965,radeon" @<:@default=auto@:>@])],
1551     [with_dri_drivers="$withval"],
1552     [with_dri_drivers=auto])
1553
1554 if test "x$with_dri_drivers" = xauto; then
1555     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1556         with_dri_drivers="yes"
1557     else
1558         with_dri_drivers="no"
1559     fi
1560 fi
1561 if test "x$with_dri_drivers" = xno; then
1562     with_dri_drivers=''
1563 fi
1564
1565 dnl If $with_dri_drivers is yes, drivers will be added through
1566 dnl platform checks. Set DEFINES and LIB_DEPS
1567 if test "x$enable_dri" = xyes; then
1568     # Platform specific settings and drivers to build
1569     case "$host_os" in
1570     linux*)
1571         DEFINES="$DEFINES -DHAVE_ALIAS"
1572         if test "x$enable_dri3" = xyes; then
1573             DEFINES="$DEFINES -DHAVE_DRI3"
1574         fi
1575
1576         if test "x$have_pci_id" != xyes; then
1577             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1578         fi
1579
1580         case "$host_cpu" in
1581         powerpc* | sparc*)
1582             # Build only the drivers for cards that exist on PowerPC/sparc
1583             if test "x$with_dri_drivers" = "xyes"; then
1584                 with_dri_drivers="r200 radeon swrast"
1585             fi
1586             ;;
1587         esac
1588         ;;
1589     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1590         DEFINES="$DEFINES -DHAVE_ALIAS"
1591         ;;
1592     gnu*)
1593         DEFINES="$DEFINES -DHAVE_ALIAS"
1594         ;;
1595     cygwin*)
1596         if test "x$with_dri_drivers" = "xyes"; then
1597             with_dri_drivers="swrast"
1598         fi
1599         ;;
1600     darwin*)
1601         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1602         if test "x$with_dri_drivers" = "xyes"; then
1603             with_dri_drivers="swrast"
1604         fi
1605         ;;
1606     esac
1607
1608     # default drivers
1609     if test "x$with_dri_drivers" = "xyes"; then
1610         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1611     fi
1612
1613     # Check for expat
1614     PKG_CHECK_MODULES([EXPAT], [expat], [],
1615         # expat version 2.0 and earlier do not provide expat.pc
1616         [AC_CHECK_HEADER([expat.h],[],
1617                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1618          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1619                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1620          EXPAT_LIBS="-lexpat"])
1621
1622     # put all the necessary libs together
1623     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1624 fi
1625
1626 AC_SUBST([DRI_LIB_DEPS])
1627
1628 DRI_DIRS=''
1629 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1630 if test -n "$with_dri_drivers"; then
1631     if test "x$enable_opengl" != xyes; then
1632         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1633     fi
1634
1635     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1636     for driver in $dri_drivers; do
1637         DRI_DIRS="$DRI_DIRS $driver"
1638         case "x$driver" in
1639         xi915)
1640             HAVE_I915_DRI=yes;
1641             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1642             ;;
1643         xi965)
1644             HAVE_I965_DRI=yes;
1645             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1646             ;;
1647         xnouveau)
1648             HAVE_NOUVEAU_DRI=yes;
1649             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1650             ;;
1651         xradeon)
1652             HAVE_RADEON_DRI=yes;
1653             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1654             ;;
1655         xr200)
1656             HAVE_R200_DRI=yes;
1657             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1658             ;;
1659         xswrast)
1660             HAVE_SWRAST_DRI=yes;
1661             ;;
1662         *)
1663             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1664             ;;
1665         esac
1666     done
1667     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1668 fi
1669
1670
1671 #
1672 # Vulkan driver configuration
1673 #
1674
1675 AC_ARG_WITH([vulkan-drivers],
1676     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1677         [comma delimited Vulkan drivers list, e.g.
1678         "intel"
1679         @<:@default=no@:>@])],
1680     [with_vulkan_drivers="$withval"],
1681     [with_vulkan_drivers="no"])
1682
1683 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1684 # here so that the script doesn't choke on an unknown driver name later.
1685 case "x$with_vulkan_drivers" in
1686     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1687     xno) with_vulkan_drivers='' ;;
1688 esac
1689
1690 AC_ARG_WITH([vulkan-icddir],
1691     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1692         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1693     [VULKAN_ICD_INSTALL_DIR="$withval"],
1694     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1695 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1696
1697 AC_ARG_ENABLE([vulkan-icd-full-driver-path],
1698    [AS_HELP_STRING([--disable-vulkan-icd-full-driver-path],
1699                    [create Vulkan ICD files with just a .so name and no path])],
1700    [vulkan_icd_driver_path="$enableval"],
1701    [vulkan_icd_driver_path="yes"])
1702 AM_CONDITIONAL(VULKAN_ICD_DRIVER_PATH, test "x$vulkan_icd_driver_path" = xyes)
1703
1704 if test -n "$with_vulkan_drivers"; then
1705     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1706     for driver in $VULKAN_DRIVERS; do
1707         case "x$driver" in
1708         xintel)
1709             if test "x$HAVE_I965_DRI" != xyes; then
1710                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1711             fi
1712             if test "x$with_sha1" == "x"; then
1713                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1714             fi
1715             HAVE_INTEL_VULKAN=yes;
1716
1717             ;;
1718         xradeon)
1719             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1720             HAVE_RADEON_VULKAN=yes;
1721             ;;
1722         *)
1723             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1724             ;;
1725         esac
1726     done
1727     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1728 fi
1729
1730
1731 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1732 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1733                                   "x$enable_osmesa" = xyes -o \
1734                                   -n "$DRI_DIRS")
1735
1736 dnl
1737 dnl OSMesa configuration
1738 dnl
1739
1740 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1741 AC_ARG_WITH([osmesa-bits],
1742     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1743         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1744     [osmesa_bits="$withval"],
1745     [osmesa_bits=8])
1746 if test "x$osmesa_bits" != x8; then
1747     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1748         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1749         osmesa_bits=8
1750     fi
1751 fi
1752 case "x$osmesa_bits" in
1753 x8)
1754     OSMESA_LIB="${OSMESA_LIB}"
1755     ;;
1756 x16|x32)
1757     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1758     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1759     ;;
1760 *)
1761     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1762     ;;
1763 esac
1764
1765 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1766     # only link libraries with osmesa if shared
1767     if test "$enable_static" = no; then
1768         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1769     else
1770         OSMESA_LIB_DEPS=""
1771     fi
1772     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1773 fi
1774
1775 AC_SUBST([OSMESA_LIB_DEPS])
1776 AC_SUBST([OSMESA_PC_REQ])
1777 AC_SUBST([OSMESA_PC_LIB_PRIV])
1778
1779 dnl
1780 dnl gbm configuration
1781 dnl
1782 if test "x$enable_gbm" = xauto; then
1783     case "$with_egl_platforms" in
1784         *drm*)
1785             enable_gbm=yes ;;
1786          *)
1787             enable_gbm=no ;;
1788     esac
1789 fi
1790 if test "x$enable_gbm" = xyes; then
1791     if test "x$need_pci_id$have_pci_id" = xyesno; then
1792         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1793     fi
1794
1795     if test "x$enable_dri" = xyes; then
1796         if test "x$enable_shared_glapi" = xno; then
1797             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1798         fi
1799     else
1800         # Strictly speaking libgbm does not require --enable-dri, although
1801         # both of its backends do. Thus one can build libgbm without any
1802         # backends if --disable-dri is set.
1803         # To avoid unnecessary complexity of checking if at least one backend
1804         # is available when building, just mandate --enable-dri.
1805         AC_MSG_ERROR([gbm requires --enable-dri])
1806     fi
1807 fi
1808 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1809 if test "x$need_pci_id$have_libudev" = xyesyes; then
1810     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1811 else
1812     GBM_PC_REQ_PRIV=""
1813 fi
1814 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1815 AC_SUBST([GBM_PC_REQ_PRIV])
1816 AC_SUBST([GBM_PC_LIB_PRIV])
1817
1818 dnl
1819 dnl EGL configuration
1820 dnl
1821 EGL_CLIENT_APIS=""
1822
1823 if test "x$enable_egl" = xyes; then
1824     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1825
1826     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1827
1828     if test "$enable_static" != yes; then
1829         if test "x$enable_dri" = xyes; then
1830             HAVE_EGL_DRIVER_DRI2=1
1831             if test "x$enable_shared_glapi" = xno; then
1832                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1833             fi
1834             if test "x$enable_dri3" = xyes; then
1835                 HAVE_EGL_DRIVER_DRI3=1
1836                 if test "x$enable_shared_glapi" = xno; then
1837                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1838                 fi
1839             fi
1840         else
1841             # Avoid building an "empty" libEGL. Drop/update this
1842             # when other backends (haiku?) come along.
1843             AC_MSG_ERROR([egl requires --enable-dri])
1844         fi
1845
1846     fi
1847 fi
1848 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1849 AC_SUBST([EGL_LIB_DEPS])
1850
1851 gallium_st="mesa"
1852
1853 dnl
1854 dnl XA configuration
1855 dnl
1856 if test "x$enable_xa" = xyes; then
1857     if test "x$with_gallium_drivers" = xswrast; then
1858        AC_MSG_ERROR([
1859           Building xa requires at least one non swrast gallium driver.
1860           If you are looking to use libxatracker.so with the VMware driver,
1861           make sure to include svga in the gallium drivers list, apart from
1862           enabling XA.
1863           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1864     fi
1865     gallium_st="$gallium_st xa"
1866 fi
1867 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1868
1869 dnl
1870 dnl Gallium G3DVL configuration
1871 dnl
1872 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1873     if test "x$enable_xvmc" = xauto; then
1874         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1875     fi
1876
1877     if test "x$enable_vdpau" = xauto; then
1878         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1879     fi
1880
1881     if test "x$enable_omx" = xauto; then
1882         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1883     fi
1884
1885     if test "x$enable_va" = xauto; then
1886         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1887     fi
1888 fi
1889
1890 if test "x$enable_dri" = xyes -o \
1891         "x$enable_xvmc" = xyes -o \
1892         "x$enable_vdpau" = xyes -o \
1893         "x$enable_omx" = xyes -o \
1894         "x$enable_va" = xyes; then
1895     need_gallium_vl=yes
1896 fi
1897 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1898
1899 if test "x$enable_xvmc" = xyes -o \
1900         "x$enable_vdpau" = xyes -o \
1901         "x$enable_omx" = xyes -o \
1902         "x$enable_va" = xyes; then
1903     if test x"$enable_dri3" = xyes; then
1904         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1905                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1906     else
1907         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1908     fi
1909     need_gallium_vl_winsys=yes
1910 fi
1911 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1912
1913 if test "x$enable_xvmc" = xyes; then
1914     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1915     gallium_st="$gallium_st xvmc"
1916 fi
1917 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1918
1919 if test "x$enable_vdpau" = xyes; then
1920     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1921     gallium_st="$gallium_st vdpau"
1922     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1923 fi
1924 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1925
1926 if test "x$enable_omx" = xyes; then
1927     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1928     gallium_st="$gallium_st omx"
1929 fi
1930 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1931
1932 if test "x$enable_va" = xyes; then
1933     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1934     gallium_st="$gallium_st va"
1935 fi
1936 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1937
1938 dnl
1939 dnl Nine Direct3D9 configuration
1940 dnl
1941 if test "x$enable_nine" = xyes; then
1942     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1943         AC_MSG_ERROR([nine requires the gallium swrast driver])
1944     fi
1945     if test "x$with_gallium_drivers" = xswrast; then
1946         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1947     fi
1948     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1949         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1950     fi
1951
1952     if test "x$enable_dri3" = xno; then
1953         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1954     fi
1955
1956     gallium_st="$gallium_st nine"
1957 fi
1958 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1959
1960 dnl
1961 dnl OpenCL configuration
1962 dnl
1963
1964 AC_ARG_WITH([clang-libdir],
1965    [AS_HELP_STRING([--with-clang-libdir],
1966          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1967    [CLANG_LIBDIR="$withval"],
1968    [CLANG_LIBDIR=''])
1969
1970 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1971 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1972
1973 if test "x$have_libelf" = xno; then
1974    LIBELF_LIBS=''
1975    LIBELF_CFLAGS=''
1976    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1977    AC_SUBST([LIBELF_LIBS])
1978    AC_SUBST([LIBELF_CFLAGS])
1979 fi
1980
1981 if test "x$enable_opencl" = xyes; then
1982     if test -z "$with_gallium_drivers"; then
1983         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1984     fi
1985
1986     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1987         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1988     fi
1989
1990     if test "x$have_libclc" = xno; then
1991         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1992                     Make sure the directory containing libclc.pc is specified in your
1993                     PKG_CONFIG_PATH environment variable.
1994                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1995     else
1996         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1997         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1998         AC_SUBST([LIBCLC_INCLUDEDIR])
1999         AC_SUBST([LIBCLC_LIBEXECDIR])
2000     fi
2001
2002     gallium_st="$gallium_st clover"
2003
2004     if test "x$enable_opencl_icd" = xyes; then
2005         OPENCL_LIBNAME="MesaOpenCL"
2006     else
2007         OPENCL_LIBNAME="OpenCL"
2008     fi
2009
2010     if test "x$have_libelf" != xyes; then
2011        AC_MSG_ERROR([Clover requires libelf])
2012     fi
2013 fi
2014 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2015 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2016 AC_SUBST([OPENCL_LIBNAME])
2017
2018 dnl
2019 dnl Gallium configuration
2020 dnl
2021 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2022
2023 AC_SUBST([LLVM_BINDIR])
2024 AC_SUBST([LLVM_CFLAGS])
2025 AC_SUBST([LLVM_CPPFLAGS])
2026 AC_SUBST([LLVM_CXXFLAGS])
2027 AC_SUBST([LLVM_LIBDIR])
2028 AC_SUBST([LLVM_LIBS])
2029 AC_SUBST([LLVM_LDFLAGS])
2030 AC_SUBST([LLVM_INCLUDEDIR])
2031 AC_SUBST([LLVM_VERSION])
2032 AC_SUBST([CLANG_RESOURCE_DIR])
2033
2034 case "x$enable_opengl$enable_gles1$enable_gles2" in
2035 x*yes*)
2036     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2037     ;;
2038 esac
2039
2040 AC_SUBST([VG_LIB_DEPS])
2041 AC_SUBST([EGL_CLIENT_APIS])
2042
2043 dnl
2044 dnl EGL Platforms configuration
2045 dnl
2046 AC_ARG_WITH([egl-platforms],
2047     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2048         [comma delimited native platforms libEGL supports, e.g.
2049         "x11,drm" @<:@default=auto@:>@])],
2050     [with_egl_platforms="$withval"],
2051     [if test "x$enable_egl" = xyes; then
2052         with_egl_platforms="x11"
2053     else
2054         with_egl_platforms=""
2055     fi])
2056
2057 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2058     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2059 fi
2060
2061 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2062         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2063         WAYLAND_SCANNER='')
2064 if test "x$WAYLAND_SCANNER" = x; then
2065     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2066 fi
2067
2068 # Do per-EGL platform setups and checks
2069 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2070 for plat in $egl_platforms; do
2071         case "$plat" in
2072         wayland)
2073                 test "x$have_libdrm" != xyes &&
2074                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
2075
2076                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2077
2078                 if test "x$WAYLAND_SCANNER" = x; then
2079                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2080                 fi
2081                 ;;
2082
2083         x11)
2084                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2085                 ;;
2086
2087         drm)
2088                 test "x$enable_gbm" = "xno" &&
2089                         AC_MSG_ERROR([EGL platform drm needs gbm])
2090                 test "x$have_libdrm" != xyes &&
2091                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
2092                 ;;
2093
2094         surfaceless)
2095                 test "x$have_libdrm" != xyes &&
2096                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
2097                 ;;
2098
2099         android)
2100                 ;;
2101
2102         *)
2103                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2104                 ;;
2105         esac
2106
2107         case "$plat$need_pci_id$have_pci_id" in
2108                 waylandyesno|drmyesno)
2109                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
2110         esac
2111 done
2112
2113 # libEGL wants to default to the first platform specified in
2114 # ./configure.  parse that here.
2115 if test "x$egl_platforms" != "x"; then
2116     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2117     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2118 else
2119     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2120 fi
2121
2122 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2123 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2124 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2125 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2126 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2127
2128 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2129
2130 AC_SUBST([EGL_NATIVE_PLATFORM])
2131 AC_SUBST([EGL_CFLAGS])
2132
2133 # If we don't have the X11 platform, set this define so we don't try to include
2134 # the X11 headers.
2135 if ! echo "$egl_platforms" | grep -q 'x11'; then
2136     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2137     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2138 fi
2139
2140 dnl
2141 dnl Gallium LLVM
2142 dnl
2143 AC_ARG_ENABLE([gallium-llvm],
2144     [AS_HELP_STRING([--enable-gallium-llvm],
2145         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2146     [enable_gallium_llvm="$enableval"],
2147     [enable_gallium_llvm=auto])
2148
2149 AC_ARG_ENABLE([llvm-shared-libs],
2150     [AS_HELP_STRING([--enable-llvm-shared-libs],
2151         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2152     [enable_llvm_shared_libs="$enableval"],
2153     [enable_llvm_shared_libs=yes])
2154
2155 AC_ARG_WITH([llvm-prefix],
2156     [AS_HELP_STRING([--with-llvm-prefix],
2157         [Prefix for LLVM installations in non-standard locations])],
2158     [llvm_prefix="$withval"],
2159     [llvm_prefix=''])
2160
2161
2162 # Call this inside ` ` to get the return value.
2163 # $1 is the llvm-config command with arguments.
2164 strip_unwanted_llvm_flags() {
2165     # Use \> (marks the end of the word)
2166     echo `$1` | sed \
2167         -e 's/-march=\S*//g' \
2168         -e 's/-mtune=\S*//g' \
2169         -e 's/-mcpu=\S*//g' \
2170         -e 's/-DNDEBUG\>//g' \
2171         -e 's/-D_GNU_SOURCE\>//g' \
2172         -e 's/-pedantic\>//g' \
2173         -e 's/-Wcovered-switch-default\>//g' \
2174         -e 's/-O.\>//g' \
2175         -e 's/-g\>//g' \
2176         -e 's/-Wall\>//g' \
2177         -e 's/-Wcast-qual\>//g' \
2178         -e 's/-Woverloaded-virtual\>//g' \
2179         -e 's/-fcolor-diagnostics\>//g' \
2180         -e 's/-fdata-sections\>//g' \
2181         -e 's/-ffunction-sections\>//g' \
2182         -e 's/-fno-exceptions\>//g' \
2183         -e 's/-fomit-frame-pointer\>//g' \
2184         -e 's/-fvisibility-inlines-hidden\>//g' \
2185         -e 's/-fPIC\>//g' \
2186         -e 's/-fstack-protector-strong\>//g'
2187 }
2188
2189 llvm_check_version_for() {
2190     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2191         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2192     fi
2193 }
2194
2195
2196
2197 if test -z "$with_gallium_drivers"; then
2198     enable_gallium_llvm=no
2199 fi
2200 if test "x$enable_gallium_llvm" = xauto; then
2201     case "$host_cpu" in
2202     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2203     esac
2204 fi
2205 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2206     if test -n "$llvm_prefix"; then
2207         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2208     else
2209         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2210     fi
2211
2212     if test "x$LLVM_CONFIG" != xno; then
2213         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2214         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2215         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2216         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2217         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2218         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2219         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2220         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2221
2222         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2223             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2224         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2225             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2226
2227         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2228         if test -z "$LLVM_VERSION_PATCH"; then
2229             LLVM_VERSION_PATCH=0
2230         fi
2231
2232         if test -n "${LLVM_VERSION_MAJOR}"; then
2233             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2234         else
2235             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2236         fi
2237
2238         LLVM_REQUIRED_VERSION_MAJOR="3"
2239         LLVM_REQUIRED_VERSION_MINOR="3"
2240         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2241             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2242         fi
2243
2244         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2245
2246         if $LLVM_CONFIG --components | grep -q inteljitevents ; then
2247             LLVM_COMPONENTS="${LLVM_COMPONENTS} inteljitevents"
2248         fi
2249
2250         if test "x$enable_opencl" = xyes; then
2251             llvm_check_version_for "3" "6" "0" "opencl"
2252
2253             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2254             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2255         fi
2256         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2257         MESA_LLVM=1
2258
2259         dnl Check for Clang internal headers
2260         if test "x$enable_opencl" = xyes; then
2261             if test -z "$CLANG_LIBDIR"; then
2262                 CLANG_LIBDIR=${LLVM_LIBDIR}
2263             fi
2264             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2265             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2266                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2267         fi
2268     else
2269         MESA_LLVM=0
2270         LLVM_VERSION_INT=0
2271     fi
2272 else
2273     MESA_LLVM=0
2274     LLVM_VERSION_INT=0
2275
2276     if test "x$enable_opencl" = xyes; then
2277         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2278     fi
2279 fi
2280
2281 dnl Directory for XVMC libs
2282 AC_ARG_WITH([xvmc-libdir],
2283     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2284         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2285     [XVMC_LIB_INSTALL_DIR="$withval"],
2286     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2287 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2288
2289 dnl
2290 dnl Gallium Tests
2291 dnl
2292 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2293
2294 dnl Directory for VDPAU libs
2295 AC_ARG_WITH([vdpau-libdir],
2296     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2297         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2298     [VDPAU_LIB_INSTALL_DIR="$withval"],
2299     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2300 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2301
2302 dnl Directory for OMX libs
2303
2304 AC_ARG_WITH([omx-libdir],
2305     [AS_HELP_STRING([--with-omx-libdir=DIR],
2306         [directory for the OMX libraries])],
2307     [OMX_LIB_INSTALL_DIR="$withval"],
2308     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2309 AC_SUBST([OMX_LIB_INSTALL_DIR])
2310
2311 dnl Directory for VA libs
2312
2313 AC_ARG_WITH([va-libdir],
2314     [AS_HELP_STRING([--with-va-libdir=DIR],
2315         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2316     [VA_LIB_INSTALL_DIR="$withval"],
2317     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2318 AC_SUBST([VA_LIB_INSTALL_DIR])
2319
2320 AC_ARG_WITH([d3d-libdir],
2321     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2322         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2323     [D3D_DRIVER_INSTALL_DIR="$withval"],
2324     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2325 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2326
2327 dnl
2328 dnl Gallium helper functions
2329 dnl
2330 gallium_require_drm() {
2331     if test "x$have_libdrm" != xyes; then
2332        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2333     fi
2334 }
2335
2336 gallium_require_llvm() {
2337     if test "x$MESA_LLVM" = x0; then
2338         case "$host" in *gnux32) return;; esac
2339         case "$host_cpu" in
2340         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2341         esac
2342     fi
2343 }
2344
2345 gallium_require_drm_loader() {
2346     if test "x$need_pci_id$have_pci_id" = xyesno; then
2347         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2348     fi
2349 }
2350
2351 dnl This is for Glamor. Skip this if OpenGL is disabled.
2352 require_egl_drm() {
2353     if test "x$enable_opengl" = xno; then
2354         return 0
2355     fi
2356
2357     case "$with_egl_platforms" in
2358         *drm*)
2359             ;;
2360          *)
2361             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2362             ;;
2363     esac
2364     if test "x$enable_gbm" != xyes; then
2365             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2366     fi
2367 }
2368
2369 radeon_llvm_check() {
2370     if test ${LLVM_VERSION_INT} -lt 307; then
2371         amdgpu_llvm_target_name='r600'
2372     else
2373         amdgpu_llvm_target_name='amdgpu'
2374     fi
2375     llvm_check_version_for $2 $3 $4 $1
2376     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2377         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2378     fi
2379     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2380     NEED_RADEON_LLVM=yes
2381     if test "x$have_libelf" != xyes; then
2382        AC_MSG_ERROR([$1 requires libelf when using llvm])
2383     fi
2384 }
2385
2386 radeon_gallium_llvm_check() {
2387     if test "x$enable_gallium_llvm" != "xyes"; then
2388         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2389     fi
2390     radeon_llvm_check $*
2391 }
2392
2393 swr_llvm_check() {
2394     gallium_require_llvm $1
2395     if test ${LLVM_VERSION_INT} -lt 306; then
2396         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2397     fi
2398     if test "x$enable_gallium_llvm" != "xyes"; then
2399         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2400     fi
2401 }
2402
2403 swr_require_cxx_feature_flags() {
2404     feature_name="$1"
2405     preprocessor_test="$2"
2406     option_list="$3"
2407     output_var="$4"
2408
2409     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2410     AC_LANG_PUSH([C++])
2411     save_CXXFLAGS="$CXXFLAGS"
2412     save_IFS="$IFS"
2413     IFS=","
2414     found=0
2415     for opts in $option_list
2416     do
2417         unset IFS
2418         CXXFLAGS="$opts $save_CXXFLAGS"
2419         AC_COMPILE_IFELSE(
2420             [AC_LANG_PROGRAM(
2421                 [   #if !($preprocessor_test)
2422                     #error
2423                     #endif
2424                 ])],
2425             [found=1; break],
2426             [])
2427         IFS=","
2428     done
2429     IFS="$save_IFS"
2430     CXXFLAGS="$save_CXXFLAGS"
2431     AC_LANG_POP([C++])
2432     if test $found -eq 1; then
2433         AC_MSG_RESULT([$opts])
2434         eval "$output_var=\$opts"
2435         return 0
2436     fi
2437     AC_MSG_RESULT([no])
2438     AC_MSG_ERROR([swr requires $feature_name support])
2439     return 1
2440 }
2441
2442 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2443 if test -n "$with_gallium_drivers"; then
2444     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2445     for driver in $gallium_drivers; do
2446         case "x$driver" in
2447         xsvga)
2448             HAVE_GALLIUM_SVGA=yes
2449             gallium_require_drm "svga"
2450             gallium_require_drm_loader
2451             ;;
2452         xi915)
2453             HAVE_GALLIUM_I915=yes
2454             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2455             gallium_require_drm "Gallium i915"
2456             gallium_require_drm_loader
2457             ;;
2458         xilo)
2459             HAVE_GALLIUM_ILO=yes
2460             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2461             gallium_require_drm "Gallium i965/ilo"
2462             gallium_require_drm_loader
2463             ;;
2464         xr300)
2465             HAVE_GALLIUM_R300=yes
2466             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2467             gallium_require_drm "Gallium R300"
2468             gallium_require_drm_loader
2469             gallium_require_llvm "Gallium R300"
2470             ;;
2471         xr600)
2472             HAVE_GALLIUM_R600=yes
2473             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2474             gallium_require_drm "Gallium R600"
2475             gallium_require_drm_loader
2476             if test "x$enable_opencl" = xyes; then
2477                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2478                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2479             fi
2480             ;;
2481         xradeonsi)
2482             HAVE_GALLIUM_RADEONSI=yes
2483             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2484             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2485             gallium_require_drm "radeonsi"
2486             gallium_require_drm_loader
2487             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2488             require_egl_drm "radeonsi"
2489             ;;
2490         xnouveau)
2491             HAVE_GALLIUM_NOUVEAU=yes
2492             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2493             gallium_require_drm "nouveau"
2494             gallium_require_drm_loader
2495             ;;
2496         xfreedreno)
2497             HAVE_GALLIUM_FREEDRENO=yes
2498             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2499             gallium_require_drm "freedreno"
2500             gallium_require_drm_loader
2501             ;;
2502         xswrast)
2503             HAVE_GALLIUM_SOFTPIPE=yes
2504             if test "x$MESA_LLVM" = x1; then
2505                 HAVE_GALLIUM_LLVMPIPE=yes
2506             fi
2507             ;;
2508         xswr)
2509             swr_llvm_check "swr"
2510
2511             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2512                 ",-std=c++11" \
2513                 SWR_CXX11_CXXFLAGS
2514             AC_SUBST([SWR_CXX11_CXXFLAGS])
2515
2516             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2517                 ",-mavx,-march=core-avx" \
2518                 SWR_AVX_CXXFLAGS
2519             AC_SUBST([SWR_AVX_CXXFLAGS])
2520
2521             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2522                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2523                 SWR_AVX2_CXXFLAGS
2524             AC_SUBST([SWR_AVX2_CXXFLAGS])
2525
2526             HAVE_GALLIUM_SWR=yes
2527             ;;
2528         xvc4)
2529             HAVE_GALLIUM_VC4=yes
2530             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2531             gallium_require_drm "vc4"
2532             gallium_require_drm_loader
2533
2534             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2535                               [USE_VC4_SIMULATOR=yes;
2536                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2537                               [USE_VC4_SIMULATOR=no])
2538             ;;
2539         xvirgl)
2540             HAVE_GALLIUM_VIRGL=yes
2541             gallium_require_drm "virgl"
2542             gallium_require_drm_loader
2543             require_egl_drm "virgl"
2544             ;;
2545         *)
2546             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2547             ;;
2548         esac
2549     done
2550 fi
2551
2552 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2553     radeon_llvm_check "radv" "3" "9" "0"
2554 fi
2555
2556 dnl Set LLVM_LIBS - This is done after the driver configuration so
2557 dnl that drivers can add additional components to LLVM_COMPONENTS.
2558 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2559 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2560 dnl this was causing the same libraries to be appear multiple times
2561 dnl in LLVM_LIBS.
2562
2563 if test "x$MESA_LLVM" != x0; then
2564
2565     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2566        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2567     fi
2568     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2569
2570     dnl llvm-config may not give the right answer when llvm is a built as a
2571     dnl single shared library, so we must work the library name out for
2572     dnl ourselves.
2573     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2574     if test "x$enable_llvm_shared_libs" = xyes; then
2575         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2576         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2577         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2578
2579         if test "x$llvm_have_one_so" = xyes; then
2580             dnl LLVM was built using auto*, so there is only one shared object.
2581             LLVM_LIBS="-l$LLVM_SO_NAME"
2582         else
2583             dnl If LLVM was built with CMake, there will be one shared object per
2584             dnl component.
2585             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2586                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2587         Please make sure you have built llvm with the --enable-shared option
2588         and that your llvm libraries are installed in $LLVM_LIBDIR
2589         If you have installed your llvm libraries to a different directory you
2590         can use the --with-llvm-prefix= configure flag to specify this directory.
2591         NOTE: Mesa is attempting to use llvm shared libraries by default.
2592         If you do not want to build with llvm shared libraries and instead want to
2593         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2594         invocation and rebuild.])])
2595
2596            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2597            dnl install uses a shared object for each component and we have
2598            dnl already added all of these objects to LLVM_LIBS.
2599         fi
2600     else
2601         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2602         dnl We need to link to llvm system libs when using static libs
2603         dnl However, only llvm 3.5+ provides --system-libs
2604         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2605             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2606         fi
2607     fi
2608 fi
2609
2610 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2611 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2612 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2613 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2614 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2615 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2616 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2617                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2618 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2619 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2620 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2621 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2622 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2623 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2624                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2625                                          "x$HAVE_GALLIUM_SWR" = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2628
2629 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2630
2631 if test "x$enable_dri" = xyes; then
2632     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2633 fi
2634
2635 if test "x$have_drisw_kms" = xyes; then
2636     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2637 fi
2638 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2639
2640 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2641 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2642 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2643 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2644 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2645 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2646
2647 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2648 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2649
2650 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2651                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2652                                       "x$HAVE_RADEON_VULKAN" = xyes)
2653
2654 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2655                                         "x$HAVE_I965_DRI" = xyes)
2656
2657 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2658                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2659                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2660 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2661 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2662 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2663 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2664 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2665 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2666     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2667 fi
2668
2669 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2670 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2671 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2672 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2673                                         "x$enable_gallium_osmesa" = xyes)
2674
2675 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2676 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2677 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2678
2679 AC_SUBST([NINE_MAJOR], 1)
2680 AC_SUBST([NINE_MINOR], 0)
2681 AC_SUBST([NINE_TINY], 0)
2682 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2683
2684 AC_SUBST([VDPAU_MAJOR], 1)
2685 AC_SUBST([VDPAU_MINOR], 0)
2686
2687 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2688 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2689 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2690 AC_SUBST([VA_MINOR], $VA_MINOR)
2691
2692 AC_SUBST([XVMC_MAJOR], 1)
2693 AC_SUBST([XVMC_MINOR], 0)
2694
2695 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2696 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2697 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2698 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2699
2700 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2701 AC_SUBST([XA_MINOR], $XA_MINOR)
2702 AC_SUBST([XA_TINY], $XA_TINY)
2703 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2704
2705 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2706
2707 AC_ARG_ENABLE(valgrind,
2708               [AS_HELP_STRING([--enable-valgrind],
2709                              [Build mesa with valgrind support (default: auto)])],
2710                              [VALGRIND=$enableval], [VALGRIND=auto])
2711 if test "x$VALGRIND" != xno; then
2712         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2713 fi
2714 AC_MSG_CHECKING([whether to enable Valgrind support])
2715 if test "x$VALGRIND" = xauto; then
2716         VALGRIND="$have_valgrind"
2717 fi
2718
2719 if test "x$VALGRIND" = "xyes"; then
2720         if ! test "x$have_valgrind" = xyes; then
2721                 AC_MSG_ERROR([Valgrind support required but not present])
2722         fi
2723         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2724 fi
2725
2726 AC_MSG_RESULT([$VALGRIND])
2727
2728 dnl Restore LDFLAGS and CPPFLAGS
2729 LDFLAGS="$_SAVE_LDFLAGS"
2730 CPPFLAGS="$_SAVE_CPPFLAGS"
2731
2732 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2733 if test "x$acv_mesa_CLANG" = xyes; then
2734     CFLAGS="$CFLAGS -Qunused-arguments"
2735     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2736 fi
2737
2738 dnl Add user CFLAGS and CXXFLAGS
2739 CFLAGS="$CFLAGS $USER_CFLAGS"
2740 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2741
2742 dnl Substitute the config
2743 AC_CONFIG_FILES([Makefile
2744                 src/Makefile
2745                 src/amd/Makefile
2746                 src/amd/common/Makefile
2747                 src/amd/vulkan/Makefile
2748                 src/compiler/Makefile
2749                 src/egl/Makefile
2750                 src/egl/main/egl.pc
2751                 src/egl/wayland/wayland-drm/Makefile
2752                 src/egl/wayland/wayland-egl/Makefile
2753                 src/egl/wayland/wayland-egl/wayland-egl.pc
2754                 src/gallium/Makefile
2755                 src/gallium/auxiliary/Makefile
2756                 src/gallium/auxiliary/pipe-loader/Makefile
2757                 src/gallium/drivers/freedreno/Makefile
2758                 src/gallium/drivers/ddebug/Makefile
2759                 src/gallium/drivers/i915/Makefile
2760                 src/gallium/drivers/ilo/Makefile
2761                 src/gallium/drivers/llvmpipe/Makefile
2762                 src/gallium/drivers/noop/Makefile
2763                 src/gallium/drivers/nouveau/Makefile
2764                 src/gallium/drivers/r300/Makefile
2765                 src/gallium/drivers/r600/Makefile
2766                 src/gallium/drivers/radeon/Makefile
2767                 src/gallium/drivers/radeonsi/Makefile
2768                 src/gallium/drivers/rbug/Makefile
2769                 src/gallium/drivers/softpipe/Makefile
2770                 src/gallium/drivers/svga/Makefile
2771                 src/gallium/drivers/swr/Makefile
2772                 src/gallium/drivers/trace/Makefile
2773                 src/gallium/drivers/vc4/Makefile
2774                 src/gallium/drivers/virgl/Makefile
2775                 src/gallium/state_trackers/clover/Makefile
2776                 src/gallium/state_trackers/dri/Makefile
2777                 src/gallium/state_trackers/glx/xlib/Makefile
2778                 src/gallium/state_trackers/nine/Makefile
2779                 src/gallium/state_trackers/omx/Makefile
2780                 src/gallium/state_trackers/osmesa/Makefile
2781                 src/gallium/state_trackers/va/Makefile
2782                 src/gallium/state_trackers/vdpau/Makefile
2783                 src/gallium/state_trackers/xa/Makefile
2784                 src/gallium/state_trackers/xvmc/Makefile
2785                 src/gallium/targets/d3dadapter9/Makefile
2786                 src/gallium/targets/d3dadapter9/d3d.pc
2787                 src/gallium/targets/dri/Makefile
2788                 src/gallium/targets/libgl-xlib/Makefile
2789                 src/gallium/targets/omx/Makefile
2790                 src/gallium/targets/opencl/Makefile
2791                 src/gallium/targets/opencl/mesa.icd
2792                 src/gallium/targets/osmesa/Makefile
2793                 src/gallium/targets/osmesa/osmesa.pc
2794                 src/gallium/targets/pipe-loader/Makefile
2795                 src/gallium/targets/va/Makefile
2796                 src/gallium/targets/vdpau/Makefile
2797                 src/gallium/targets/xa/Makefile
2798                 src/gallium/targets/xa/xatracker.pc
2799                 src/gallium/targets/xvmc/Makefile
2800                 src/gallium/tests/trivial/Makefile
2801                 src/gallium/tests/unit/Makefile
2802                 src/gallium/winsys/freedreno/drm/Makefile
2803                 src/gallium/winsys/i915/drm/Makefile
2804                 src/gallium/winsys/intel/drm/Makefile
2805                 src/gallium/winsys/nouveau/drm/Makefile
2806                 src/gallium/winsys/radeon/drm/Makefile
2807                 src/gallium/winsys/amdgpu/drm/Makefile
2808                 src/gallium/winsys/svga/drm/Makefile
2809                 src/gallium/winsys/sw/dri/Makefile
2810                 src/gallium/winsys/sw/kms-dri/Makefile
2811                 src/gallium/winsys/sw/null/Makefile
2812                 src/gallium/winsys/sw/wrapper/Makefile
2813                 src/gallium/winsys/sw/xlib/Makefile
2814                 src/gallium/winsys/vc4/drm/Makefile
2815                 src/gallium/winsys/virgl/drm/Makefile
2816                 src/gallium/winsys/virgl/vtest/Makefile
2817                 src/gbm/Makefile
2818                 src/gbm/main/gbm.pc
2819                 src/glx/Makefile
2820                 src/glx/apple/Makefile
2821                 src/glx/tests/Makefile
2822                 src/glx/windows/Makefile
2823                 src/glx/windows/windowsdriproto.pc
2824                 src/gtest/Makefile
2825                 src/intel/Makefile
2826                 src/intel/tools/Makefile
2827                 src/intel/vulkan/Makefile
2828                 src/loader/Makefile
2829                 src/mapi/Makefile
2830                 src/mapi/es1api/glesv1_cm.pc
2831                 src/mapi/es2api/glesv2.pc
2832                 src/mapi/glapi/gen/Makefile
2833                 src/mesa/Makefile
2834                 src/mesa/gl.pc
2835                 src/mesa/drivers/dri/dri.pc
2836                 src/mesa/drivers/dri/common/Makefile
2837                 src/mesa/drivers/dri/common/xmlpool/Makefile
2838                 src/mesa/drivers/dri/i915/Makefile
2839                 src/mesa/drivers/dri/i965/Makefile
2840                 src/mesa/drivers/dri/Makefile
2841                 src/mesa/drivers/dri/nouveau/Makefile
2842                 src/mesa/drivers/dri/r200/Makefile
2843                 src/mesa/drivers/dri/radeon/Makefile
2844                 src/mesa/drivers/dri/swrast/Makefile
2845                 src/mesa/drivers/osmesa/Makefile
2846                 src/mesa/drivers/osmesa/osmesa.pc
2847                 src/mesa/drivers/x11/Makefile
2848                 src/mesa/main/tests/Makefile
2849                 src/util/Makefile
2850                 src/util/tests/hash_table/Makefile])
2851
2852 AC_OUTPUT
2853
2854 # Fix up dependencies in *.Plo files, where we changed the extension of a
2855 # source file
2856 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2857
2858
2859 dnl
2860 dnl Output some configuration info for the user
2861 dnl
2862 echo ""
2863 echo "        prefix:          $prefix"
2864 echo "        exec_prefix:     $exec_prefix"
2865 echo "        libdir:          $libdir"
2866 echo "        includedir:      $includedir"
2867
2868 dnl API info
2869 echo ""
2870 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2871
2872 dnl Driver info
2873 echo ""
2874 case "x$enable_osmesa$enable_gallium_osmesa" in
2875 xnoyes)
2876         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2877         ;;
2878 xyesno)
2879         echo "        OSMesa:          lib$OSMESA_LIB"
2880         ;;
2881 xnono)
2882         echo "        OSMesa:          no"
2883         ;;
2884 esac
2885
2886 echo ""
2887 if test "x$enable_dri" != xno; then
2888         echo "        DRI platform:    $dri_platform"
2889         if test -z "$DRI_DIRS"; then
2890             echo "        DRI drivers:     no"
2891         else
2892             echo "        DRI drivers:     $DRI_DIRS"
2893         fi
2894         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2895 fi
2896
2897 case "x$enable_glx" in
2898 xdri)
2899     echo "        GLX:             DRI-based"
2900     ;;
2901 xxlib)
2902     echo "        GLX:             Xlib-based"
2903     ;;
2904 xgallium-xlib)
2905     echo "        GLX:             Xlib-based (Gallium)"
2906     ;;
2907 *)
2908     echo "        GLX:             $enable_glx"
2909     ;;
2910 esac
2911
2912 dnl EGL
2913 echo ""
2914 echo "        EGL:             $enable_egl"
2915 if test "$enable_egl" = yes; then
2916     echo "        EGL platforms:   $egl_platforms"
2917
2918     egl_drivers=""
2919     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2920         egl_drivers="$egl_drivers builtin:egl_dri2"
2921     fi
2922     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2923         egl_drivers="$egl_drivers builtin:egl_dri3"
2924     fi
2925
2926     echo "        EGL drivers:    $egl_drivers"
2927 fi
2928
2929 # Vulkan
2930 echo ""
2931 if test "x$VULKAN_DRIVERS" != x; then
2932     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2933     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2934 else
2935     echo "        Vulkan drivers:  no"
2936 fi
2937
2938 echo ""
2939 if test "x$MESA_LLVM" = x1; then
2940     echo "        llvm:            yes"
2941     echo "        llvm-config:     $LLVM_CONFIG"
2942     echo "        llvm-version:    $LLVM_VERSION"
2943 else
2944     echo "        llvm:            no"
2945 fi
2946
2947 echo ""
2948 if test -n "$with_gallium_drivers"; then
2949     echo "        Gallium drivers: $gallium_drivers"
2950     echo "        Gallium st:      $gallium_st"
2951 else
2952     echo "        Gallium:         no"
2953 fi
2954
2955 echo ""
2956 if test "x$enable_gallium_extra_hud" != xyes; then
2957     echo "        HUD extra stats: no"
2958 else
2959     echo "        HUD extra stats: yes"
2960 fi
2961
2962 if test "x$enable_lmsensors" != xyes; then
2963     echo "        HUD lmsensors:   no"
2964 else
2965     echo "        HUD lmsensors:   yes"
2966 fi
2967
2968 dnl Shader cache
2969 echo ""
2970 echo "        Shader cache:    $enable_shader_cache"
2971 if test "x$enable_shader_cache" = "xyes"; then
2972     echo "        With SHA1 from:  $with_sha1"
2973 fi
2974
2975 dnl Libraries
2976 echo ""
2977 echo "        Shared libs:     $enable_shared"
2978 echo "        Static libs:     $enable_static"
2979 echo "        Shared-glapi:    $enable_shared_glapi"
2980
2981 dnl Compiler options
2982 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2983 cflags=`echo $CFLAGS | \
2984     $SED 's/^ *//;s/  */ /;s/ *$//'`
2985 cxxflags=`echo $CXXFLAGS | \
2986     $SED 's/^ *//;s/  */ /;s/ *$//'`
2987 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2988 echo ""
2989 echo "        CFLAGS:          $cflags"
2990 echo "        CXXFLAGS:        $cxxflags"
2991 echo "        Macros:          $defines"
2992 echo ""
2993 if test "x$MESA_LLVM" = x1; then
2994     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2995     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2996     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2997     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2998     echo ""
2999 fi
3000 echo "        PYTHON2:         $PYTHON2"
3001
3002 echo ""
3003 echo "        Run '${MAKE-make}' to build Mesa"
3004 echo ""