configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.24
  36 LIBDRM_INTEL_REQUIRED=2.4.30
  37 LIBDRM_NOUVEAU_REQUIRED=0.6
  38 DRI2PROTO_REQUIRED=2.6
  39 GLPROTO_REQUIRED=1.4.14
  40 LIBDRM_XORG_REQUIRED=2.4.24
  41 LIBKMS_XORG_REQUIRED=1.0.0
  42
  43 dnl Check for progs
  44 AC_PROG_CPP
  45 AC_PROG_CC
  46 AC_PROG_CXX
  47 AC_CHECK_PROGS([MAKE], [gmake make])
  48 AC_CHECK_PROGS([PYTHON2], [python2 python])
  49 AC_PROG_SED
  50 AC_PROG_MKDIR_P
  51 AC_PATH_PROG([MKDEP], [makedepend])
  52
  53 if test "x$MKDEP" = "x"; then
  54     AC_MSG_ERROR([makedepend is required to build Mesa])
  55 fi
  56
  57 AC_PROG_YACC
  58 AC_PATH_PROG([YACC_INST], $YACC)
  59 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  60     if test -z "$YACC_INST"; then
  61         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  62     fi
  63 fi
  64 AC_PROG_LEX
  65
  66 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  67 dnl configuration in that case.
  68 AC_PROG_INSTALL
  69 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  70
  71 dnl We need a POSIX shell for parts of the build. Assume we have one
  72 dnl in most cases.
  73 case "$host_os" in
  74 solaris*)
  75     # Solaris /bin/sh is too old/non-POSIX compliant
  76     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  77     SHELL="$POSIX_SHELL"
  78     ;;
  79 esac
  80
  81 AC_PATH_PROG([GTESTCONFIG], [gtest-config])
  82 if test "x$GTESTCONFIG" != "x"; then
  83     GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
  84     GTEST_LIBS=`gtest-config --ldflags --libs`
  85     AC_SUBST([GTEST_CFLAGS])
  86     AC_SUBST([GTEST_LIBS])
  87     HAVE_GTEST=yes
  88 else
  89     HAVE_GTEST=no
  90 fi
  91 AM_CONDITIONAL(HAVE_GTEST, test x$HAVE_GTEST = xyes)
  92
  93 dnl clang is mostly GCC-compatible, but its version is much lower,
  94 dnl so we have to check for it.
  95 AC_MSG_CHECKING([if compiling with clang])
  96
  97 AC_COMPILE_IFELSE(
  98 [AC_LANG_PROGRAM([], [[
  99 #ifndef __clang__
 100        not clang
 101 #endif
 102 ]])],
 103 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 104
 105 AC_MSG_RESULT([$acv_mesa_CLANG])
 106
 107 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 108 dnl versions are explictly not supported.
 109 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 110     AC_MSG_CHECKING([whether gcc version is sufficient])
 111     major=0
 112     minor=0
 113
 114     GCC_VERSION=`$CC -dumpversion`
 115     if test $? -eq 0; then
 116         major=`echo $GCC_VERSION | cut -d. -f1`
 117         minor=`echo $GCC_VERSION | cut -d. -f2`
 118     fi
 119
 120     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 121         AC_MSG_RESULT([no])
 122         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 123     else
 124         AC_MSG_RESULT([yes])
 125     fi
 126 fi
 127
 128
 129 MKDEP_OPTIONS=-fdepend
 130 dnl Ask gcc where it's keeping its secret headers
 131 if test "x$GCC" = xyes; then
 132     for dir in include include-fixed; do
 133         GCC_INCLUDES=`$CC -print-file-name=$dir`
 134         if test "x$GCC_INCLUDES" != x && \
 135            test "$GCC_INCLUDES" != "$dir" && \
 136            test -d "$GCC_INCLUDES"; then
 137             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 138         fi
 139     done
 140 fi
 141 AC_SUBST([MKDEP_OPTIONS])
 142
 143 dnl Make sure the pkg-config macros are defined
 144 m4_ifndef([PKG_PROG_PKG_CONFIG],
 145     [m4_fatal([Could not locate the pkg-config autoconf macros.
 146   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 147   are in a different location, try setting the environment variable
 148   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 149 PKG_PROG_PKG_CONFIG()
 150
 151 dnl LIB_DIR - library basename
 152 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 153 AC_SUBST([LIB_DIR])
 154
 155 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 156 _SAVE_LDFLAGS="$LDFLAGS"
 157 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 158 AC_SUBST([EXTRA_LIB_PATH])
 159
 160 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 161 _SAVE_CPPFLAGS="$CPPFLAGS"
 162 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 163 AC_SUBST([X11_INCLUDES])
 164
 165 dnl Compiler macros
 166 DEFINES=""
 167 AC_SUBST([DEFINES])
 168 case "$host_os" in
 169 linux*|*-gnu*|gnu*)
 170     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 171     ;;
 172 solaris*)
 173     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 174     ;;
 175 cygwin*)
 176     DEFINES="$DEFINES -DPTHREADS"
 177     ;;
 178 esac
 179
 180 dnl Add flags for gcc and g++
 181 if test "x$GCC" = xyes; then
 182     CFLAGS="$CFLAGS -Wall -std=c99"
 183
 184     # Enable -Werror=implicit-function-declaration and
 185     # -Werror=missing-prototypes, if available, or otherwise, just
 186     # -Wmissing-prototypes.  This is particularly useful to avoid
 187     # generating a loadable driver module that has undefined symbols.
 188     save_CFLAGS="$CFLAGS"
 189     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 190     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 191     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 192     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 193                    AC_MSG_RESULT([yes]),
 194                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 195                     AC_MSG_RESULT([no])]);
 196
 197     # Enable -fvisibility=hidden if using a gcc that supports it
 198     save_CFLAGS="$CFLAGS"
 199     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 200     VISIBILITY_CFLAGS="-fvisibility=hidden"
 201     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 202     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 203                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 204
 205     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 206     CFLAGS=$save_CFLAGS
 207
 208     # Work around aliasing bugs - developers should comment this out
 209     CFLAGS="$CFLAGS -fno-strict-aliasing"
 210
 211     # gcc's builtin memcmp is slower than glibc's
 212     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 213     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 214 fi
 215 if test "x$GXX" = xyes; then
 216     CXXFLAGS="$CXXFLAGS -Wall"
 217
 218     # Enable -fvisibility=hidden if using a gcc that supports it
 219     save_CXXFLAGS="$CXXFLAGS"
 220     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 221     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 222     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 223     AC_LANG_PUSH([C++])
 224     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 225                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 226     AC_LANG_POP([C++])
 227
 228     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 229     CXXFLAGS=$save_CXXFLAGS
 230
 231     # Work around aliasing bugs - developers should comment this out
 232     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 233
 234     # gcc's builtin memcmp is slower than glibc's
 235     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 236     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 237 fi
 238
 239 dnl even if the compiler appears to support it, using visibility attributes isn't
 240 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 241 case "$host_os" in
 242 cygwin*)
 243     VISIBILITY_CFLAGS=""
 244     VISIBILITY_CXXFLAGS=""
 245     ;;
 246 esac
 247
 248 AC_SUBST([VISIBILITY_CFLAGS])
 249 AC_SUBST([VISIBILITY_CXXFLAGS])
 250
 251 dnl These should be unnecessary, but let the user set them if they want
 252 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 253     Default is to use CFLAGS.])
 254 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 255     compiler. Default is to use CFLAGS.])
 256 AC_SUBST([OPT_FLAGS])
 257 AC_SUBST([ARCH_FLAGS])
 258
 259 dnl
 260 dnl Hacks to enable 32 or 64 bit build
 261 dnl
 262 AC_ARG_ENABLE([32-bit],
 263     [AS_HELP_STRING([--enable-32-bit],
 264         [build 32-bit libraries @<:@default=auto@:>@])],
 265     [enable_32bit="$enableval"],
 266     [enable_32bit=auto]
 267 )
 268 if test "x$enable_32bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m32"
 271         ARCH_FLAGS="$ARCH_FLAGS -m32"
 272     fi
 273     if test "x$GXX" = xyes; then
 274         CXXFLAGS="$CXXFLAGS -m32"
 275     fi
 276 fi
 277 AC_ARG_ENABLE([64-bit],
 278     [AS_HELP_STRING([--enable-64-bit],
 279         [build 64-bit libraries @<:@default=auto@:>@])],
 280     [enable_64bit="$enableval"],
 281     [enable_64bit=auto]
 282 )
 283 if test "x$enable_64bit" = xyes; then
 284     if test "x$GCC" = xyes; then
 285         CFLAGS="$CFLAGS -m64"
 286     fi
 287     if test "x$GXX" = xyes; then
 288         CXXFLAGS="$CXXFLAGS -m64"
 289     fi
 290 fi
 291
 292 dnl Can't have static and shared libraries, default to static if user
 293 dnl explicitly requested. If both disabled, set to static since shared
 294 dnl was explicitly requested.
 295 case "x$enable_static$enable_shared" in
 296 xyesyes )
 297     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 298     enable_shared=no
 299     ;;
 300 xnono )
 301     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 302     enable_static=yes
 303     ;;
 304 esac
 305 AM_CONDITIONAL(BUILD_STATIC, test "x$enable_static" = xyes)
 306 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 307
 308 dnl
 309 dnl mklib options
 310 dnl
 311 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 312 if test "$enable_static" = yes; then
 313     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 314 fi
 315 AC_SUBST([MKLIB_OPTIONS])
 316
 317 dnl
 318 dnl other compiler options
 319 dnl
 320 AC_ARG_ENABLE([debug],
 321     [AS_HELP_STRING([--enable-debug],
 322         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 323     [enable_debug="$enableval"],
 324     [enable_debug=no]
 325 )
 326 if test "x$enable_debug" = xyes; then
 327     DEFINES="$DEFINES -DDEBUG"
 328     if test "x$GCC" = xyes; then
 329         CFLAGS="$CFLAGS -g"
 330     fi
 331     if test "x$GXX" = xyes; then
 332         CXXFLAGS="$CXXFLAGS -g"
 333     fi
 334 fi
 335
 336 dnl
 337 dnl library names
 338 dnl
 339 LIB_PREFIX_GLOB='lib'
 340 LIB_VERSION_SEPARATOR='.'
 341 if test "$enable_static" = yes; then
 342     LIB_EXTENSION='a'
 343 else
 344     case "$host_os" in
 345     darwin* )
 346         LIB_EXTENSION='dylib' ;;
 347     cygwin* )
 348         dnl prefix can be 'cyg' or 'lib'
 349         LIB_PREFIX_GLOB='???'
 350         LIB_VERSION_SEPARATOR='-'
 351         LIB_EXTENSION='dll' ;;
 352     aix* )
 353         LIB_EXTENSION='a' ;;
 354     * )
 355         LIB_EXTENSION='so' ;;
 356     esac
 357 fi
 358
 359 dnl
 360 dnl Mangled Mesa support
 361 dnl
 362 AC_ARG_ENABLE([mangling],
 363   [AS_HELP_STRING([--enable-mangling],
 364     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 365   [enable_mangling="${enableval}"],
 366   [enable_mangling=no]
 367 )
 368 GL_LIB="GL"
 369 GLU_LIB="GLU"
 370 OSMESA_LIB="OSMesa"
 371 if test "x${enable_mangling}" = "xyes" ; then
 372   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 373   GL_LIB="MangledGL"
 374   GLU_LIB="MangledGLU"
 375   OSMESA_LIB="MangledOSMesa"
 376 fi
 377 AC_SUBST([GL_LIB])
 378 AC_SUBST([GLU_LIB])
 379 AC_SUBST([OSMESA_LIB])
 380
 381 dnl
 382 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 383 dnl
 384 AC_ARG_ENABLE([texture-float],
 385     [AS_HELP_STRING([--enable-texture-float],
 386         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 387     [enable_texture_float="$enableval"],
 388     [enable_texture_float=no]
 389 )
 390 if test "x$enable_texture_float" = xyes; then
 391     AC_MSG_WARN([Floating-point textures enabled.])
 392     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 393     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 394 fi
 395
 396 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 397 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 398 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 399 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 400 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 401 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 402 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 403 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 404 GLSL_LIB_NAME='libglsl.'${LIB_EXTENSION}
 405
 406 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415
 416 AC_SUBST([GL_LIB_NAME])
 417 AC_SUBST([GLU_LIB_NAME])
 418 AC_SUBST([OSMESA_LIB_NAME])
 419 AC_SUBST([EGL_LIB_NAME])
 420 AC_SUBST([GLESv1_CM_LIB_NAME])
 421 AC_SUBST([GLESv2_LIB_NAME])
 422 AC_SUBST([VG_LIB_NAME])
 423 AC_SUBST([GLAPI_LIB_NAME])
 424 AC_SUBST([GLSL_LIB_NAME])
 425
 426 AC_SUBST([GL_LIB_GLOB])
 427 AC_SUBST([GLU_LIB_GLOB])
 428 AC_SUBST([OSMESA_LIB_GLOB])
 429 AC_SUBST([EGL_LIB_GLOB])
 430 AC_SUBST([GLESv1_CM_LIB_GLOB])
 431 AC_SUBST([GLESv2_LIB_GLOB])
 432 AC_SUBST([VG_LIB_GLOB])
 433 AC_SUBST([GLAPI_LIB_GLOB])
 434
 435 dnl
 436 dnl Arch/platform-specific settings
 437 dnl
 438 AC_ARG_ENABLE([asm],
 439     [AS_HELP_STRING([--disable-asm],
 440         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 441     [enable_asm="$enableval"],
 442     [enable_asm=yes]
 443 )
 444 asm_arch=""
 445 ASM_FLAGS=""
 446 MESA_ASM_SOURCES=""
 447 GLAPI_ASM_SOURCES=""
 448 AC_MSG_CHECKING([whether to enable assembly])
 449 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 450 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 451 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 452     case "$host_cpu" in
 453     i?86 | x86_64)
 454         enable_asm=no
 455         AC_MSG_RESULT([no, cross compiling])
 456         ;;
 457     esac
 458 fi
 459 # check for supported arches
 460 if test "x$enable_asm" = xyes; then
 461     case "$host_cpu" in
 462     i?86)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 466             ;;
 467         esac
 468         ;;
 469     x86_64)
 470         case "$host_os" in
 471         linux* | *freebsd* | dragonfly* | *netbsd*)
 472             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 473             ;;
 474         esac
 475         ;;
 476     powerpc)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=ppc
 480             ;;
 481         esac
 482         ;;
 483     sparc*)
 484         case "$host_os" in
 485         linux*)
 486             asm_arch=sparc
 487             ;;
 488         esac
 489         ;;
 490     esac
 491
 492     case "$asm_arch" in
 493     x86)
 494         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 495         MESA_ASM_SOURCES='$(X86_SOURCES)'
 496         GLAPI_ASM_SOURCES='$(X86_API)'
 497         AC_MSG_RESULT([yes, x86])
 498         ;;
 499     x86_64)
 500         ASM_FLAGS="-DUSE_X86_64_ASM"
 501         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 502         GLAPI_ASM_SOURCES='$(X86-64_API)'
 503         AC_MSG_RESULT([yes, x86_64])
 504         ;;
 505     sparc)
 506         ASM_FLAGS="-DUSE_SPARC_ASM"
 507         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 508         GLAPI_ASM_SOURCES='$(SPARC_API)'
 509         AC_MSG_RESULT([yes, sparc])
 510         ;;
 511     *)
 512         AC_MSG_RESULT([no, platform not supported])
 513         ;;
 514     esac
 515 fi
 516 AC_SUBST([ASM_FLAGS])
 517 AC_SUBST([MESA_ASM_SOURCES])
 518 AC_SUBST([GLAPI_ASM_SOURCES])
 519
 520 dnl PIC code macro
 521 MESA_PIC_FLAGS
 522
 523 dnl Check to see if dlopen is in default libraries (like Solaris, which
 524 dnl has it in libc), or if libdl is needed to get it.
 525 AC_CHECK_FUNC([dlopen], [],
 526     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 527 AC_SUBST([DLOPEN_LIBS])
 528
 529 dnl See if posix_memalign is available
 530 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 531
 532 dnl SELinux awareness.
 533 AC_ARG_ENABLE([selinux],
 534     [AS_HELP_STRING([--enable-selinux],
 535         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 536     [MESA_SELINUX="$enableval"],
 537     [MESA_SELINUX=no])
 538 if test "x$enable_selinux" = "xyes"; then
 539     AC_CHECK_HEADER([selinux/selinux.h],[],
 540                     [AC_MSG_ERROR([SELinux headers not found])])
 541     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 542                  [AC_MSG_ERROR([SELinux library not found])])
 543     SELINUX_LIBS="-lselinux"
 544     DEFINES="$DEFINES -DMESA_SELINUX"
 545 fi
 546
 547 dnl Options for APIs
 548 AC_ARG_ENABLE([opengl],
 549     [AS_HELP_STRING([--disable-opengl],
 550         [disable support for standard OpenGL API @<:@default=no@:>@])],
 551     [enable_opengl="$enableval"],
 552     [enable_opengl=yes])
 553 AC_ARG_ENABLE([gles1],
 554     [AS_HELP_STRING([--enable-gles1],
 555         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 556     [enable_gles1="$enableval"],
 557     [enable_gles1=no])
 558 AC_ARG_ENABLE([gles2],
 559     [AS_HELP_STRING([--enable-gles2],
 560         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 561     [enable_gles2="$enableval"],
 562     [enable_gles2=no])
 563 AC_ARG_ENABLE([openvg],
 564     [AS_HELP_STRING([--enable-openvg],
 565         [enable support for OpenVG API @<:@default=no@:>@])],
 566     [enable_openvg="$enableval"],
 567     [enable_openvg=no])
 568
 569 AC_ARG_ENABLE([dri],
 570     [AS_HELP_STRING([--enable-dri],
 571         [enable DRI modules @<:@default=auto@:>@])],
 572     [enable_dri="$enableval"],
 573     [enable_dri=auto])
 574 AC_ARG_ENABLE([glx],
 575     [AS_HELP_STRING([--enable-glx],
 576         [enable GLX library @<:@default=auto@:>@])],
 577     [enable_glx="$enableval"],
 578     [enable_glx=auto])
 579 AC_ARG_ENABLE([osmesa],
 580     [AS_HELP_STRING([--enable-osmesa],
 581         [enable OSMesa library @<:@default=auto@:>@])],
 582     [enable_osmesa="$enableval"],
 583     [enable_osmesa=auto])
 584 AC_ARG_ENABLE([egl],
 585     [AS_HELP_STRING([--disable-egl],
 586         [disable EGL library @<:@default=enabled@:>@])],
 587     [enable_egl="$enableval"],
 588     [enable_egl=yes])
 589
 590 AC_ARG_ENABLE([xorg],
 591     [AS_HELP_STRING([--enable-xorg],
 592         [enable support for X.Org DDX API @<:@default=no@:>@])],
 593     [enable_xorg="$enableval"],
 594     [enable_xorg=no])
 595 AC_ARG_ENABLE([xa],
 596     [AS_HELP_STRING([--enable-xa],
 597         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 598     [enable_xa="$enableval"],
 599     [enable_xa=no])
 600 AC_ARG_ENABLE([d3d1x],
 601     [AS_HELP_STRING([--enable-d3d1x],
 602         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 603     [enable_d3d1x="$enableval"],
 604     [enable_d3d1x=no])
 605 AC_ARG_ENABLE([gbm],
 606    [AS_HELP_STRING([--enable-gbm],
 607          [enable gbm library @<:@default=auto@:>@])],
 608    [enable_gbm="$enableval"],
 609    [enable_gbm=auto])
 610
 611 AC_ARG_ENABLE([xvmc],
 612    [AS_HELP_STRING([--enable-xvmc],
 613          [enable xvmc library @<:@default=auto@:>@])],
 614    [enable_xvmc="$enableval"],
 615    [enable_xvmc=auto])
 616 AC_ARG_ENABLE([vdpau],
 617    [AS_HELP_STRING([--enable-vdpau],
 618          [enable vdpau library @<:@default=auto@:>@])],
 619    [enable_vdpau="$enableval"],
 620    [enable_vdpau=auto])
 621 AC_ARG_ENABLE([va],
 622    [AS_HELP_STRING([--enable-va],
 623          [enable va library @<:@default=auto@:>@])],
 624    [enable_va="$enableval"],
 625    [enable_va=auto])
 626
 627 AC_ARG_ENABLE([xlib_glx],
 628     [AS_HELP_STRING([--enable-xlib-glx],
 629         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 630     [enable_xlib_glx="$enableval"],
 631     [enable_xlib_glx=auto])
 632 AC_ARG_ENABLE([gallium_egl],
 633     [AS_HELP_STRING([--enable-gallium-egl],
 634         [enable optional EGL state tracker (not required
 635          for EGL support in Gallium with OpenGL and OpenGL ES)
 636          @<:@default=disable@:>@])],
 637     [enable_gallium_egl="$enableval"],
 638     [enable_gallium_egl=no])
 639 AC_ARG_ENABLE([gallium_gbm],
 640     [AS_HELP_STRING([--enable-gallium-gbm],
 641         [enable optional gbm state tracker (not required for
 642          gbm support in Gallium)
 643          @<:@default=auto@:>@])],
 644     [enable_gallium_gbm="$enableval"],
 645     [enable_gallium_gbm=auto])
 646
 647 # Option for Gallium drivers
 648 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 649
 650 AC_ARG_WITH([gallium-drivers],
 651     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 652         [comma delimited Gallium drivers list, e.g.
 653         "i915,nouveau,r300,r600,svga,swrast"
 654         @<:@default=r300,r600,swrast@:>@])],
 655     [with_gallium_drivers="$withval"],
 656     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 657
 658 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 659 # here so that the script doesn't choke on an unknown driver name later.
 660 case "$with_gallium_drivers" in
 661     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 662     no) with_gallium_drivers='' ;;
 663 esac
 664
 665 if test "x$enable_opengl" = xno -a \
 666         "x$enable_gles1" = xno -a \
 667         "x$enable_gles2" = xno -a \
 668         "x$enable_openvg" = xno -a \
 669         "x$enable_xorg" = xno -a \
 670         "x$enable_xa" = xno -a \
 671         "x$enable_d3d1x" = xno -a \
 672         "x$enable_xvmc" = xno -a \
 673         "x$enable_vdpau" = xno -a \
 674         "x$enable_va" = xno; then
 675     AC_MSG_ERROR([at least one API should be enabled])
 676 fi
 677
 678 API_DEFINES=""
 679 if test "x$enable_opengl" = xno; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 681 else
 682     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 683 fi
 684 if test "x$enable_gles1" = xyes; then
 685     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 686 fi
 687 if test "x$enable_gles2" = xyes; then
 688     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 689 fi
 690 AC_SUBST([API_DEFINES])
 691
 692 AC_ARG_ENABLE([shared-glapi],
 693     [AS_HELP_STRING([--enable-shared-glapi],
 694         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 695     [enable_shared_glapi="$enableval"],
 696     [enable_shared_glapi=no])
 697
 698 SHARED_GLAPI="0"
 699 if test "x$enable_shared_glapi" = xyes; then
 700     SHARED_GLAPI="1"
 701 fi
 702 AC_SUBST([SHARED_GLAPI])
 703
 704 dnl
 705 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 706 dnl More later: fbdev, ...
 707 dnl
 708 default_driver="xlib"
 709
 710 case "$host_os" in
 711 linux*)
 712     case "$host_cpu" in
 713     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 714     esac
 715     ;;
 716 *freebsd* | dragonfly* | *netbsd*)
 717     case "$host_cpu" in
 718     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 719     esac
 720     ;;
 721 esac
 722
 723 if test "x$enable_opengl" = xno; then
 724     default_driver="no"
 725 fi
 726
 727 AC_ARG_WITH([driver],
 728     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 729     [mesa_driver="$withval"],
 730     [mesa_driver=auto])
 731 dnl Check for valid option
 732 case "x$mesa_driver" in
 733 xxlib|xdri|xosmesa|xno)
 734     if test "x$enable_dri" != xauto -o \
 735             "x$enable_glx" != xauto -o \
 736             "x$enable_osmesa" != xauto -o \
 737             "x$enable_xlib_glx" != xauto; then
 738         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 739     fi
 740     ;;
 741 xauto)
 742     mesa_driver="$default_driver"
 743     ;;
 744 *)
 745     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 746     ;;
 747 esac
 748
 749 # map $mesa_driver to APIs
 750 if test "x$enable_dri" = xauto; then
 751     case "x$mesa_driver" in
 752     xdri) enable_dri=yes ;;
 753     *)    enable_dri=no ;;
 754     esac
 755 fi
 756
 757 if test "x$enable_glx" = xauto; then
 758     case "x$mesa_driver" in
 759     xdri|xxlib) enable_glx=yes ;;
 760     *)          enable_glx=no ;;
 761     esac
 762 fi
 763
 764 if test "x$enable_osmesa" = xauto; then
 765     case "x$mesa_driver" in
 766     xxlib|xosmesa) enable_osmesa=yes ;;
 767     *)             enable_osmesa=no ;;
 768     esac
 769 fi
 770
 771 if test "x$enable_xlib_glx" = xauto; then
 772     case "x$mesa_driver" in
 773     xxlib) enable_xlib_glx=yes ;;
 774     *)     enable_xlib_glx=no ;;
 775     esac
 776 fi
 777
 778 if test "x$enable_glx" = xno; then
 779     enable_xlib_glx=no
 780 fi
 781
 782 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 783
 784 dnl
 785 dnl Driver specific build directories
 786 dnl
 787
 788 dnl this variable will be prepended to SRC_DIRS and is not exported
 789 CORE_DIRS=""
 790
 791 SRC_DIRS=""
 792 GLU_DIRS="sgi"
 793 GALLIUM_DIRS="auxiliary drivers state_trackers"
 794 GALLIUM_TARGET_DIRS=""
 795 GALLIUM_WINSYS_DIRS="sw"
 796 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 797 GALLIUM_STATE_TRACKERS_DIRS=""
 798
 799 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 800 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 801 x*yes*)
 802     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 803     ;;
 804 esac
 805
 806 # build glapi if OpenGL is enabled
 807 if test "x$enable_opengl" = xyes; then
 808     CORE_DIRS="$CORE_DIRS mapi/glapi"
 809 fi
 810
 811 # build es1api if OpenGL ES 1.x is enabled
 812 if test "x$enable_gles1" = xyes; then
 813     CORE_DIRS="$CORE_DIRS mapi/es1api"
 814 fi
 815
 816 # build es2api if OpenGL ES 2.x is enabled
 817 if test "x$enable_gles2" = xyes; then
 818     CORE_DIRS="$CORE_DIRS mapi/es2api"
 819 fi
 820
 821 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 822 case "x$enable_opengl$enable_gles1$enable_gles2" in
 823 x*yes*)
 824     CORE_DIRS="$CORE_DIRS glsl mesa"
 825     ;;
 826 esac
 827
 828 case "x$enable_glx$enable_xlib_glx" in
 829 xyesyes)
 830     DRIVER_DIRS="$DRIVER_DIRS x11"
 831     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 832     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 833     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 834     HAVE_WINSYS_XLIB="yes"
 835     ;;
 836 xyesno)
 837     # DRI-based GLX
 838     SRC_DIRS="$SRC_DIRS glx"
 839     ;;
 840 esac
 841
 842 if test "x$enable_dri" = xyes; then
 843     DRIVER_DIRS="$DRIVER_DIRS dri"
 844
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 846     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 847     HAVE_ST_DRI="yes"
 848 fi
 849
 850 if test "x$enable_osmesa" = xyes; then
 851     # the empty space matters for osmesa... (see src/mesa/Makefile)
 852     if test -n "$DRIVER_DIRS"; then
 853         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 854     else
 855         DRIVER_DIRS="osmesa"
 856     fi
 857 fi
 858
 859 AC_SUBST([SRC_DIRS])
 860 AC_SUBST([GLU_DIRS])
 861 AC_SUBST([DRIVER_DIRS])
 862 AC_SUBST([GALLIUM_DIRS])
 863 AC_SUBST([GALLIUM_TARGET_DIRS])
 864 AC_SUBST([GALLIUM_WINSYS_DIRS])
 865 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 866 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 867 AC_SUBST([MESA_LLVM])
 868
 869 # Check for libdrm
 870 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 871                   [have_libdrm=yes], [have_libdrm=no])
 872
 873 if test "x$enable_dri" = xyes; then
 874     # DRI must be shared, I think
 875     if test "$enable_static" = yes; then
 876         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 877     fi
 878
 879     # not a hard requirement as swrast does not depend on it
 880     if test "x$have_libdrm" = xyes; then
 881         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 882     fi
 883 fi
 884
 885 dnl
 886 dnl Find out if X is available. The variable have_x is set if libX11 is
 887 dnl found to mimic AC_PATH_XTRA.
 888 dnl
 889 if test -n "$PKG_CONFIG"; then
 890     AC_MSG_CHECKING([pkg-config files for X11 are available])
 891     PKG_CHECK_EXISTS([x11],[
 892         x11_pkgconfig=yes
 893         have_x=yes
 894         ],[
 895         x11_pkgconfig=no
 896     ])
 897     AC_MSG_RESULT([$x11_pkgconfig])
 898 else
 899     x11_pkgconfig=no
 900 fi
 901 dnl Use the autoconf macro if no pkg-config files
 902 if test "$x11_pkgconfig" = yes; then
 903     PKG_CHECK_MODULES([X11], [x11])
 904 else
 905     AC_PATH_XTRA
 906     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 907     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 908     AC_SUBST([X11_CFLAGS])
 909     AC_SUBST([X11_LIBS])
 910 fi
 911
 912 dnl Try to tell the user that the --x-* options are only used when
 913 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 914 m4_divert_once([HELP_BEGIN],
 915 [These options are only used when the X libraries cannot be found by the
 916 pkg-config utility.])
 917
 918 dnl We need X for xlib and dri, so bomb now if it's not found
 919 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 920     AC_MSG_ERROR([X11 development libraries needed for GLX])
 921 fi
 922
 923 if test "x$enable_glx" = xyes; then
 924     DEFINES="$DEFINES -DUSE_XCB"
 925 fi
 926
 927 dnl Direct rendering or just indirect rendering
 928 case "$host_os" in
 929 gnu*)
 930     dnl Disable by default on GNU/Hurd
 931     driglx_direct_default="no"
 932     ;;
 933 cygwin*)
 934     dnl Disable by default on cygwin
 935     driglx_direct_default="no"
 936     ;;
 937 *)
 938     driglx_direct_default="yes"
 939     ;;
 940 esac
 941 AC_ARG_ENABLE([driglx-direct],
 942     [AS_HELP_STRING([--disable-driglx-direct],
 943         [enable direct rendering in GLX and EGL for DRI \
 944             @<:@default=auto@:>@])],
 945     [driglx_direct="$enableval"],
 946     [driglx_direct="$driglx_direct_default"])
 947
 948 dnl
 949 dnl libGL configuration per driver
 950 dnl
 951 case "x$enable_glx$enable_xlib_glx" in
 952 xyesyes)
 953     # Xlib-based GLX
 954     if test "$x11_pkgconfig" = yes; then
 955         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 956         GL_PC_REQ_PRIV="x11 xext"
 957         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 958         GL_LIB_DEPS="$XLIBGL_LIBS"
 959     else
 960         # should check these...
 961         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 962         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 963         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 964         GL_PC_CFLAGS="$X11_INCLUDES"
 965     fi
 966     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 967     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 968     ;;
 969 xyesno)
 970     # DRI-based GLX
 971     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 972     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 973     if test x"$driglx_direct" = xyes; then
 974         if test "x$have_libdrm" != xyes; then
 975             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 976         fi
 977         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 978         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 979     fi
 980
 981     # find the DRI deps for libGL
 982     if test "$x11_pkgconfig" = yes; then
 983         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 984
 985         # add xf86vidmode if available
 986         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 987         if test "$HAVE_XF86VIDMODE" = yes ; then
 988             dri_modules="$dri_modules xxf86vm"
 989         fi
 990
 991         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 992         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 993         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 994         GL_LIB_DEPS="$DRIGL_LIBS"
 995     else
 996         # should check these...
 997         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 998         if test "x$HAVE_XF86VIDMODE" == xyes; then
 999            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1000         else
1001            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1002         fi
1003         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1004         GL_PC_CFLAGS="$X11_INCLUDES"
1005
1006         # XCB can only be used from pkg-config
1007         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1008         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1009         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1010         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1011     fi
1012
1013     # Check to see if the xcb-glx library is new enough to support
1014     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1015     # is released.
1016     save_CPPFLAGS="$CPPFLAGS"
1017     save_LDFLAGS="$LDFLAGS"
1018     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1019     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1020     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1021         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1022         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1023     CPPFLAGS="$save_CPPFLAGS"
1024     LDFLAGS="$save_LDFLAGS"
1025
1026     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1027         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1028     fi
1029
1030     # need DRM libs, -lpthread, etc.
1031     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1032     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1033     ;;
1034 esac
1035
1036 # This is outside the case (above) so that it is invoked even for non-GLX
1037 # builds.
1038 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1039     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1040
1041 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1042 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1043 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1044 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1045
1046 AC_SUBST([GL_LIB_DEPS])
1047 AC_SUBST([GL_PC_REQ_PRIV])
1048 AC_SUBST([GL_PC_LIB_PRIV])
1049 AC_SUBST([GL_PC_CFLAGS])
1050 AC_SUBST([DRI_PC_REQ_PRIV])
1051 AC_SUBST([GLESv1_CM_LIB_DEPS])
1052 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1053 AC_SUBST([GLESv2_LIB_DEPS])
1054 AC_SUBST([GLESv2_PC_LIB_PRIV])
1055
1056 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1057 AC_SUBST([GLAPI_LIB_DEPS])
1058
1059
1060 dnl Setup default DRI CFLAGS
1061 DRI_CFLAGS='$(CFLAGS)'
1062 DRI_CXXFLAGS='$(CXXFLAGS)'
1063 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1064 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1065
1066 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1067     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1068     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1069     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1070     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1071     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1072     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1073     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1074 fi
1075 AC_SUBST([DRICORE_LIBS])
1076 AC_SUBST([DRICORE_GLSL_LIBS])
1077 AC_SUBST([DRICORE_LIB_DEPS])
1078 AC_SUBST([DRI_CXXFLAGS])
1079 AC_SUBST([DRI_CFLAGS])
1080 AC_SUBST([MESA_MODULES])
1081
1082 AC_SUBST([HAVE_XF86VIDMODE])
1083
1084 dnl
1085 dnl More GLX setup
1086 dnl
1087 case "x$enable_glx$enable_xlib_glx" in
1088 xyesyes)
1089     DEFINES="$DEFINES -DUSE_XSHM"
1090     ;;
1091 xyesno)
1092     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1093     if test "x$driglx_direct" = xyes; then
1094         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1095     fi
1096     ;;
1097 esac
1098
1099 dnl
1100 dnl TLS detection
1101 dnl
1102
1103 AC_ARG_ENABLE([glx-tls],
1104     [AS_HELP_STRING([--enable-glx-tls],
1105         [enable TLS support in GLX @<:@default=disabled@:>@])],
1106     [GLX_USE_TLS="$enableval"],
1107     [GLX_USE_TLS=no])
1108 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1109
1110 AS_IF([test "x$GLX_USE_TLS" = xyes],
1111       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1112
1113 dnl
1114 dnl More DRI setup
1115 dnl
1116 dnl Directory for DRI drivers
1117 AC_ARG_WITH([dri-driverdir],
1118     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1119         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1120     [DRI_DRIVER_INSTALL_DIR="$withval"],
1121     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1122 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1123 dnl Extra search path for DRI drivers
1124 AC_ARG_WITH([dri-searchpath],
1125     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1126         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1127     [DRI_DRIVER_SEARCH_DIR="$withval"],
1128     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1129 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1130 dnl Which drivers to build - default is chosen by platform
1131 AC_ARG_WITH([dri-drivers],
1132     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1133         [comma delimited DRI drivers list, e.g.
1134         "swrast,i965,radeon" @<:@default=auto@:>@])],
1135     [with_dri_drivers="$withval"],
1136     [with_dri_drivers=yes])
1137 if test "x$with_dri_drivers" = x; then
1138     with_dri_drivers=no
1139 fi
1140
1141 dnl If $with_dri_drivers is yes, directories will be added through
1142 dnl platform checks
1143 DRI_DIRS=""
1144 case "$with_dri_drivers" in
1145 no) ;;
1146 yes)
1147     # classic DRI drivers require FEATURE_GL to build
1148     if test "x$enable_opengl" = xyes; then
1149         DRI_DIRS="yes"
1150     fi
1151     ;;
1152 *)
1153     # verify the requested driver directories exist
1154     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1155     for driver in $dri_drivers; do
1156         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1157             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1158     done
1159     DRI_DIRS="$dri_drivers"
1160     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1161         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1162     fi
1163     ;;
1164 esac
1165
1166 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1167 if test "x$enable_dri" = xyes; then
1168     # Platform specific settings and drivers to build
1169     case "$host_os" in
1170     linux*)
1171         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1172         DEFINES="$DEFINES -DHAVE_ALIAS"
1173
1174         case "$host_cpu" in
1175         x86_64)
1176             if test "x$DRI_DIRS" = "xyes"; then
1177                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1178             fi
1179             ;;
1180         powerpc*)
1181             # Build only the drivers for cards that exist on PowerPC.
1182             if test "x$DRI_DIRS" = "xyes"; then
1183                 DRI_DIRS="r200 radeon swrast"
1184             fi
1185             ;;
1186         sparc*)
1187             # Build only the drivers for cards that exist on sparc
1188             if test "x$DRI_DIRS" = "xyes"; then
1189                 DRI_DIRS="r200 radeon swrast"
1190             fi
1191             ;;
1192         esac
1193         ;;
1194     freebsd* | dragonfly* | *netbsd*)
1195         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1196         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1197
1198         if test "x$DRI_DIRS" = "xyes"; then
1199             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1200         fi
1201         ;;
1202     gnu*)
1203         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1204         DEFINES="$DEFINES -DHAVE_ALIAS"
1205         ;;
1206     solaris*)
1207         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1208         ;;
1209     cygwin*)
1210         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1211         if test "x$DRI_DIRS" = "xyes"; then
1212             DRI_DIRS="swrast"
1213         fi
1214         ;;
1215     esac
1216
1217     # default drivers
1218     if test "x$DRI_DIRS" = "xyes"; then
1219         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1220     fi
1221
1222     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1223
1224     # Check for expat
1225     if test "x$enable_dri" = xyes; then
1226         EXPAT_INCLUDES=""
1227         EXPAT_LIB=-lexpat
1228         AC_ARG_WITH([expat],
1229             [AS_HELP_STRING([--with-expat=DIR],
1230                 [expat install directory])],[
1231             EXPAT_INCLUDES="-I$withval/include"
1232             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1233             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1234             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1235             ])
1236         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1237         save_LIBS="$LIBS"
1238         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1239             [AC_MSG_ERROR([Expat required for DRI.])])
1240         LIBS="$save_LIBS"
1241     fi
1242
1243     # libdrm is required for all except swrast
1244     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1245         if test "x$have_libdrm" != xyes; then
1246             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1247         fi
1248     fi
1249
1250     # put all the necessary libs together
1251     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1252 fi
1253 AC_SUBST([DRI_DIRS])
1254 AC_SUBST([EXPAT_INCLUDES])
1255 AC_SUBST([DRI_LIB_DEPS])
1256
1257 case $DRI_DIRS in
1258 *i915*|*i965*)
1259     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1260
1261     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1262         case $d in
1263         i915)
1264             HAVE_I915_DRI=yes;
1265             ;;
1266         i965)
1267             HAVE_I965_DRI=yes;
1268             ;;
1269         esac
1270     done
1271
1272     ;;
1273 esac
1274
1275 case $DRI_DIRS in
1276 *nouveau*)
1277     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1278     HAVE_NOUVEAU_DRI=yes;
1279     ;;
1280 esac
1281
1282 case $DRI_DIRS in
1283 *radeon*|*r200*)
1284     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1285
1286     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1287         case $d in
1288         radeon)
1289             HAVE_RADEON_DRI=yes;
1290             ;;
1291         r200)
1292             HAVE_R200_DRI=yes;
1293             ;;
1294         esac
1295     done
1296
1297     ;;
1298 esac
1299
1300 case $DRI_DIRS in
1301 *swrast*)
1302     HAVE_SWRAST_DRI=yes;
1303     ;;
1304 esac
1305
1306 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1307 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1308 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1309 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1310 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1311 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1312
1313 dnl
1314 dnl OSMesa configuration
1315 dnl
1316
1317 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1318 AC_ARG_WITH([osmesa-bits],
1319     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1320         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1321     [osmesa_bits="$withval"],
1322     [osmesa_bits=8])
1323 if test "x$osmesa_bits" != x8; then
1324     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1325         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1326         osmesa_bits=8
1327     fi
1328 fi
1329 case "x$osmesa_bits" in
1330 x8)
1331     OSMESA_LIB="${OSMESA_LIB}"
1332     ;;
1333 x16|x32)
1334     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1335     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1336     ;;
1337 *)
1338     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1339     ;;
1340 esac
1341 AM_CONDITIONAL(HAVE_OSMESA8, test "x$osmesa_bits" = x8)
1342 AM_CONDITIONAL(HAVE_OSMESA16, test "x$osmesa_bits" = x16)
1343 AM_CONDITIONAL(HAVE_OSMESA32, test "x$osmesa_bits" = x32)
1344
1345 if test "x$enable_osmesa" = xyes; then
1346     # only link libraries with osmesa if shared
1347     if test "$enable_static" = no; then
1348         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1349     else
1350         OSMESA_LIB_DEPS=""
1351     fi
1352     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1353 fi
1354 AC_SUBST([OSMESA_LIB_DEPS])
1355 AC_SUBST([OSMESA_PC_LIB_PRIV])
1356
1357 dnl
1358 dnl gbm configuration
1359 dnl
1360 if test "x$enable_gbm" = xauto; then
1361     case "$with_egl_platforms" in
1362         *drm*)
1363             enable_gbm=yes ;;
1364          *)
1365             enable_gbm=no ;;
1366     esac
1367 fi
1368 if test "x$enable_gbm" = xyes; then
1369     SRC_DIRS="$SRC_DIRS gbm"
1370
1371     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1372                       AC_MSG_ERROR([gbm needs udev]))
1373
1374     if test "x$enable_dri" = xyes; then
1375         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1376         if test "$SHARED_GLAPI" -eq 0; then
1377             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1378         fi
1379     fi
1380 fi
1381 GBM_PC_REQ_PRIV="libudev"
1382 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1383 AC_SUBST([GBM_PC_REQ_PRIV])
1384 AC_SUBST([GBM_PC_LIB_PRIV])
1385
1386 dnl
1387 dnl EGL configuration
1388 dnl
1389 EGL_CLIENT_APIS=""
1390
1391 if test "x$enable_egl" = xyes; then
1392     SRC_DIRS="$SRC_DIRS egl"
1393     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1394     EGL_DRIVERS_DIRS=""
1395
1396     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1397
1398     if test "$enable_static" != yes; then
1399         # build egl_glx when libGL is built
1400         if test "x$enable_glx" = xyes; then
1401             EGL_DRIVERS_DIRS="glx"
1402         fi
1403
1404         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1405                           [have_libudev=yes],[have_libudev=no])
1406         if test "$have_libudev" = yes; then
1407             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1408         fi
1409         if test "x$enable_dri" = xyes; then
1410             # build egl_dri2 when xcb-dri2 is available
1411             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1412                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1413
1414             if test "$have_xcb_dri2" = yes; then
1415                 EGL_DRIVER_DRI2=dri2
1416                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1417                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1418                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1419                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1420             fi
1421         fi
1422
1423         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1424     fi
1425 fi
1426 AC_SUBST([EGL_LIB_DEPS])
1427 AC_SUBST([EGL_DRIVERS_DIRS])
1428
1429 dnl
1430 dnl EGL Gallium configuration
1431 dnl
1432 if test "x$enable_gallium_egl" = xyes; then
1433     if test "x$with_gallium_drivers" = x; then
1434         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1435     fi
1436     if test "x$enable_egl" = xno; then
1437         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1438     fi
1439     if test "x$have_libdrm" != xyes; then
1440         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1441     fi
1442
1443     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1444     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1445     HAVE_ST_EGL="yes"
1446 fi
1447
1448 dnl
1449 dnl gbm Gallium configuration
1450 dnl
1451 if test "x$enable_gallium_gbm" = xauto; then
1452     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1453         yesyesyes*drm*)
1454             enable_gallium_gbm=yes ;;
1455          *)
1456             enable_gallium_gbm=no ;;
1457     esac
1458 fi
1459 if test "x$enable_gallium_gbm" = xyes; then
1460     if test "x$with_gallium_drivers" = x; then
1461         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1462     fi
1463     if test "x$enable_gbm" = xno; then
1464         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1465     fi
1466     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1467     if test "x$enable_dri" = xno; then
1468         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1469     fi
1470
1471     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1472     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1473     HAVE_ST_GBM="yes"
1474 fi
1475
1476 dnl
1477 dnl X.Org DDX configuration
1478 dnl
1479 if test "x$enable_xorg" = xyes; then
1480     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1481     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1482     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1483     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1484         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1485         HAVE_XEXTPROTO_71="no")
1486     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1487     HAVE_ST_XORG=yes
1488 fi
1489
1490 dnl
1491 dnl XA configuration
1492 dnl
1493 if test "x$enable_xa" = xyes; then
1494 AC_PROG_AWK
1495 AC_PROG_GREP
1496 AC_CHECK_PROG(NM, nm, "nm")
1497 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1498 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1499 enable_xa=no
1500 fi
1501 fi
1502 if test "x$enable_xa" = xyes; then
1503     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1504     HAVE_ST_XA=yes
1505     AC_SUBST(AWK)
1506     AC_SUBST(GREP)
1507     AC_SUBST(NM)
1508 fi
1509
1510 dnl
1511 dnl OpenVG configuration
1512 dnl
1513 VG_LIB_DEPS=""
1514
1515 if test "x$enable_openvg" = xyes; then
1516     if test "x$enable_egl" = xno; then
1517         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1518     fi
1519     if test "x$with_gallium_drivers" = x; then
1520         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1521     fi
1522     if test "x$enable_gallium_egl" = xno; then
1523         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1524     fi
1525
1526     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1527     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1528     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1529     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1530     HAVE_ST_VEGA=yes
1531 fi
1532
1533 dnl
1534 dnl D3D1X configuration
1535 dnl
1536
1537 if test "x$enable_d3d1x" = xyes; then
1538     if test "x$with_gallium_drivers" = x; then
1539         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1540     fi
1541
1542     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1543     HAVE_ST_D3D1X=yes
1544 fi
1545
1546 dnl
1547 dnl Gallium G3DVL configuration
1548 dnl
1549 AC_ARG_ENABLE([gallium-g3dvl],
1550     [AS_HELP_STRING([--enable-gallium-g3dvl],
1551         [build gallium g3dvl @<:@default=disabled@:>@])],
1552     [enable_gallium_g3dvl="$enableval"],
1553     [enable_gallium_g3dvl=no])
1554 if test "x$enable_gallium_g3dvl" = xyes; then
1555     if test "x$with_gallium_drivers" = x; then
1556         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1557     fi
1558
1559     if test "x$enable_xvmc" = xauto; then
1560         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1561     fi
1562
1563     if test "x$enable_vdpau" = xauto; then
1564         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1565     fi
1566
1567     if test "x$enable_va" = xauto; then
1568         #don't enable vaapi state tracker even if package exists
1569         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1570         enable_va=no
1571     fi
1572 fi
1573
1574 if test "x$enable_xvmc" = xyes; then
1575     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6])
1576     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg/xvmc"
1577     HAVE_ST_XVMC="yes"
1578 fi
1579
1580 if test "x$enable_vdpau" = xyes; then
1581     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1])
1582     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1583     HAVE_ST_VDPAU="yes"
1584 fi
1585
1586 if test "x$enable_va" = xyes; then
1587     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1])
1588     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1589     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1590     HAVE_ST_VA="yes"
1591 fi
1592
1593 dnl
1594 dnl GLU configuration
1595 dnl
1596 AC_ARG_ENABLE([glu],
1597     [AS_HELP_STRING([--disable-glu],
1598         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1599     [enable_glu="$enableval"],
1600     [enable_glu=yes])
1601
1602 if test "x$enable_glu" = xyes; then
1603     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1604         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1605         enable_glu=no
1606     fi
1607 fi
1608
1609 if test "x$enable_glu" = xyes; then
1610     SRC_DIRS="$SRC_DIRS glu"
1611
1612     if test "x$enable_glx" = xno; then
1613         # Link libGLU to libOSMesa instead of libGL
1614         GLU_LIB_DEPS=""
1615         GLU_PC_REQ="osmesa"
1616         if test "$enable_static" = no; then
1617             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1618         else
1619             GLU_MESA_DEPS=""
1620         fi
1621     else
1622         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1623         GLU_PC_REQ="gl"
1624         GLU_PC_LIB_PRIV="-lm"
1625         if test "$enable_static" = no; then
1626             GLU_LIB_DEPS="-lm"
1627             GLU_MESA_DEPS='-l$(GL_LIB)'
1628         else
1629             GLU_LIB_DEPS=""
1630             GLU_MESA_DEPS=""
1631         fi
1632     fi
1633 fi
1634 if test "$enable_static" = no; then
1635     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1636 fi
1637 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1638 AC_SUBST([GLU_LIB_DEPS])
1639 AC_SUBST([GLU_MESA_DEPS])
1640 AC_SUBST([GLU_PC_REQ])
1641 AC_SUBST([GLU_PC_REQ_PRIV])
1642 AC_SUBST([GLU_PC_LIB_PRIV])
1643 AC_SUBST([GLU_PC_CFLAGS])
1644
1645 AC_SUBST([PROGRAM_DIRS])
1646
1647 dnl
1648 dnl Gallium configuration
1649 dnl
1650 if test "x$with_gallium_drivers" != x; then
1651     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1652 fi
1653
1654 AC_SUBST([LLVM_CFLAGS])
1655 AC_SUBST([LLVM_LIBS])
1656 AC_SUBST([LLVM_LDFLAGS])
1657 AC_SUBST([LLVM_VERSION])
1658
1659 case "x$enable_opengl$enable_gles1$enable_gles2" in
1660 x*yes*)
1661     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1662     ;;
1663 esac
1664
1665 AC_SUBST([VG_LIB_DEPS])
1666 AC_SUBST([EGL_CLIENT_APIS])
1667
1668 AC_ARG_WITH([egl-platforms],
1669     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1670         [comma delimited native platforms libEGL supports, e.g.
1671         "x11,drm" @<:@default=auto@:>@])],
1672     [with_egl_platforms="$withval"],
1673     [with_egl_platforms=yes])
1674
1675 EGL_PLATFORMS=""
1676
1677 case "$with_egl_platforms" in
1678 yes)
1679     if test "x$enable_egl" = xyes; then
1680         EGL_PLATFORMS="x11"
1681     fi
1682     ;;
1683 *)
1684     if test "x$enable_egl" != xyes; then
1685         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1686     fi
1687     # verify the requested driver directories exist
1688     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1689     for plat in $egl_platforms; do
1690         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1691             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1692         if test "$plat" = "fbdev"; then
1693                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1694         fi
1695         if test "$plat" = "null"; then
1696                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1697         fi
1698         if test "$plat" = "wayland"; then
1699                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1700                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1701                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1702
1703                 m4_ifdef([WAYLAND_SCANNER_RULES],
1704                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1705         fi
1706         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1707                 AC_MSG_ERROR([EGL platform drm needs gbm])
1708         fi
1709         case "$plat$have_libudev" in
1710                 waylandno|drmno)
1711                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1712         esac
1713     done
1714     EGL_PLATFORMS="$egl_platforms"
1715     ;;
1716 esac
1717 AC_SUBST([EGL_PLATFORMS])
1718
1719 AC_ARG_WITH([egl-driver-dir],
1720     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1721                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1722     [EGL_DRIVER_INSTALL_DIR="$withval"],
1723     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1724 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1725
1726 AC_ARG_WITH([xorg-driver-dir],
1727     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1728                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1729     [XORG_DRIVER_INSTALL_DIR="$withval"],
1730     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1731 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1732
1733 AC_ARG_WITH([max-width],
1734     [AS_HELP_STRING([--with-max-width=N],
1735                     [Maximum framebuffer width (4096)])],
1736     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1737      AS_IF([test "${withval}" -gt "4096"],
1738            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1739 )
1740 AC_ARG_WITH([max-height],
1741     [AS_HELP_STRING([--with-max-height=N],
1742                     [Maximum framebuffer height (4096)])],
1743     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1744      AS_IF([test "${withval}" -gt "4096"],
1745            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1746 )
1747
1748 dnl
1749 dnl Gallium LLVM
1750 dnl
1751 AC_ARG_ENABLE([gallium-llvm],
1752     [AS_HELP_STRING([--enable-gallium-llvm],
1753         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1754     [enable_gallium_llvm="$enableval"],
1755     [enable_gallium_llvm=auto])
1756 if test "x$with_gallium_drivers" = x; then
1757     enable_gallium_llvm=no
1758 fi
1759 if test "x$enable_gallium_llvm" = xauto; then
1760     case "$host_cpu" in
1761     i*86|x86_64) enable_gallium_llvm=yes;;
1762     esac
1763 fi
1764 if test "x$enable_gallium_llvm" = xyes; then
1765     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1766
1767     if test "x$LLVM_CONFIG" != xno; then
1768         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1769         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1770         LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1771
1772         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1773         DEFINES="$DEFINES -D__STDC_CONSTANT_MACROS"
1774         MESA_LLVM=1
1775     else
1776         MESA_LLVM=0
1777     fi
1778 else
1779     MESA_LLVM=0
1780 fi
1781
1782 dnl Directory for VDPAU libs
1783 AC_ARG_WITH([vdpau-libdir],
1784     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1785         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1786     [VDPAU_LIB_INSTALL_DIR="$withval"],
1787     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1788 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1789
1790 dnl Directory for VA libs
1791 AC_ARG_WITH([va-libdir],
1792     [AS_HELP_STRING([--with-va-libdir=DIR],
1793         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1794     [VA_LIB_INSTALL_DIR="$withval"],
1795     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1796 AC_SUBST([VA_LIB_INSTALL_DIR])
1797
1798 dnl
1799 dnl Gallium helper functions
1800 dnl
1801 gallium_check_st() {
1802     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1803          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1804          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1805          if test "x$have_libdrm" != xyes; then
1806             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1807          fi
1808          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1809     fi
1810     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1811          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1812     fi
1813     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1814          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1815     fi
1816     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1817          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1818     fi
1819     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1820          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1821          NEED_G3DVL_DRI="yes"
1822     fi
1823     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1824          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1825          NEED_G3DVL_DRI="yes"
1826     fi
1827     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1828          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1829          NEED_G3DVL_DRI="yes"
1830     fi
1831 }
1832
1833 gallium_require_llvm() {
1834     if test "x$MESA_LLVM" = x0; then
1835         case "$host_cpu" in
1836         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1837         esac
1838     fi
1839 }
1840
1841 dnl Gallium drivers
1842 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1843 if test "x$with_gallium_drivers" != x; then
1844     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1845     for driver in $gallium_drivers; do
1846         case "x$driver" in
1847         xsvga)
1848             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1849             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1850             ;;
1851         xi915)
1852             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1853             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1854             if test "x$MESA_LLVM" = x1; then
1855                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1856             fi
1857             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1858             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1859             ;;
1860         xr300)
1861             gallium_require_llvm "Gallium R300"
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1863             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1864             ;;
1865         xr600)
1866             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1867             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1868             ;;
1869         xnouveau)
1870             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1871             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1872             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1873             ;;
1874         xswrast)
1875             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1876             if test "x$MESA_LLVM" = x1; then
1877                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1878             fi
1879
1880             if test "x$HAVE_ST_DRI" = xyes; then
1881                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1882             fi
1883             if test "x$HAVE_ST_VDPAU" = xyes; then
1884                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1885             fi
1886             if test "x$HAVE_ST_XVMC" = xyes; then
1887                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1888             fi
1889             if test "x$HAVE_ST_VA" = xyes; then
1890                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1891             fi
1892             if test "x$HAVE_ST_VDPAU" = xyes ||
1893                test "x$HAVE_ST_XVMC" = xyes ||
1894                test "x$HAVE_ST_VA" = xyes; then
1895                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1896                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1897                fi
1898             fi
1899             ;;
1900         *)
1901             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1902             ;;
1903         esac
1904     done
1905 fi
1906
1907 if test "x$NEED_G3DVL_DRI" = xyes; then
1908     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS g3dvl/dri"
1909 fi
1910
1911 dnl prepend CORE_DIRS to SRC_DIRS
1912 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1913
1914 dnl Restore LDFLAGS and CPPFLAGS
1915 LDFLAGS="$_SAVE_LDFLAGS"
1916 CPPFLAGS="$_SAVE_CPPFLAGS"
1917
1918 dnl Add user CFLAGS and CXXFLAGS
1919 CFLAGS="$CFLAGS $USER_CFLAGS"
1920 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1921
1922 dnl Substitute the config
1923 AC_CONFIG_FILES([configs/autoconf
1924                 src/gbm/Makefile
1925                 src/gbm/main/gbm.pc
1926                 src/glsl/Makefile
1927                 src/glsl/glcpp/Makefile
1928                 src/egl/wayland/Makefile
1929                 src/egl/wayland/wayland-egl/Makefile
1930                 src/egl/wayland/wayland-egl/wayland-egl.pc
1931                 src/egl/wayland/wayland-drm/Makefile
1932                 src/mesa/drivers/dri/dri.pc
1933                 src/mesa/drivers/dri/Makefile
1934                 src/mesa/drivers/dri/common/Makefile
1935                 src/mesa/drivers/dri/i915/Makefile
1936                 src/mesa/drivers/dri/i965/Makefile
1937                 src/mesa/drivers/dri/nouveau/Makefile
1938                 src/mesa/drivers/dri/r200/Makefile
1939                 src/mesa/drivers/dri/radeon/Makefile
1940                 src/mesa/drivers/dri/swrast/Makefile
1941                 src/mesa/drivers/osmesa/osmesa.pc
1942                 src/mesa/drivers/osmesa/Makefile
1943                 tests/Makefile
1944                 tests/glx/Makefile])
1945
1946 dnl Replace the configs/current symlink
1947 AC_CONFIG_COMMANDS([configs],[
1948 if test -f configs/current || test -L configs/current; then
1949     rm -f configs/current
1950 fi
1951 ln -s autoconf configs/current
1952 ])
1953
1954 dnl Sort the dirs alphabetically
1955 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1956 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1957 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1958 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1959
1960 AC_OUTPUT
1961
1962 dnl
1963 dnl Output some configuration info for the user
1964 dnl
1965 echo ""
1966 echo "        prefix:          $prefix"
1967 echo "        exec_prefix:     $exec_prefix"
1968 echo "        libdir:          $libdir"
1969 echo "        includedir:      $includedir"
1970
1971 dnl API info
1972 echo ""
1973 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1974 echo "        OpenVG:          $enable_openvg"
1975
1976 dnl Driver info
1977 echo ""
1978 if test "x$enable_osmesa" != xno; then
1979         echo "        OSMesa:          lib$OSMESA_LIB"
1980 else
1981         echo "        OSMesa:          no"
1982 fi
1983
1984 if test "x$enable_dri" != xno; then
1985         # cleanup the drivers var
1986         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1987         if test "x$DRI_DIRS" = x; then
1988             echo "        DRI drivers:     no"
1989         else
1990             echo "        DRI drivers:     $dri_dirs"
1991         fi
1992         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1993 fi
1994
1995 case "x$enable_glx$enable_xlib_glx" in
1996 xyesyes)
1997     echo "        GLX:             Xlib-based"
1998     ;;
1999 xyesno)
2000     echo "        GLX:             DRI-based"
2001     ;;
2002 *)
2003     echo "        GLX:             $enable_glx"
2004     ;;
2005 esac
2006
2007 echo ""
2008 echo "        GLU:             $enable_glu"
2009
2010 dnl EGL
2011 echo ""
2012 echo "        EGL:             $enable_egl"
2013 if test "$enable_egl" = yes; then
2014     echo "        EGL platforms:   $EGL_PLATFORMS"
2015
2016     egl_drivers=""
2017     for d in $EGL_DRIVERS_DIRS; do
2018         egl_drivers="$egl_drivers builtin:egl_$d"
2019     done
2020
2021     if test "x$HAVE_ST_EGL" = xyes; then
2022         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2023         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2024     else
2025         echo "        EGL drivers:    $egl_drivers"
2026     fi
2027 fi
2028
2029 echo ""
2030 if test "x$MESA_LLVM" = x1; then
2031     echo "        llvm:            yes"
2032     echo "        llvm-config:     $LLVM_CONFIG"
2033     echo "        llvm-version:    $LLVM_VERSION"
2034 else
2035     echo "        llvm:            no"
2036 fi
2037
2038 echo ""
2039 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2040     echo "        Gallium:         yes"
2041     echo "        Gallium dirs:    $GALLIUM_DIRS"
2042     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2043     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2044     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2045     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2046 else
2047     echo "        Gallium:         no"
2048 fi
2049
2050
2051 dnl Libraries
2052 echo ""
2053 echo "        Shared libs:     $enable_shared"
2054 echo "        Static libs:     $enable_static"
2055
2056 dnl Compiler options
2057 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2058 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2059     $SED 's/^ *//;s/  */ /;s/ *$//'`
2060 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2061     $SED 's/^ *//;s/  */ /;s/ *$//'`
2062 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2063 echo ""
2064 echo "        CFLAGS:          $cflags"
2065 echo "        CXXFLAGS:        $cxxflags"
2066 echo "        Macros:          $defines"
2067 echo ""
2068 echo "        PYTHON2:         $PYTHON2"
2069
2070 echo ""
2071 echo "        Run '${MAKE-make}' to build Mesa"
2072 echo ""