configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.66
  76 LIBDRM_RADEON_REQUIRED=2.4.56
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.6
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XSHMFENCE_REQUIRED=1.1
  98 XVMC_REQUIRED=1.0.6
  99 PYTHON_MAKO_REQUIRED=0.8.0
 100 LIBSENSORS_REQUIRED=4.0.0
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.6.0
 106 LLVM_REQUIRED_RADEONSI=3.6.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.6.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127 AC_CHECK_PROG(XXD, xxd, [xxd])
 128
 129 AX_PROG_BISON([],
 130               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 131                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 132 AX_PROG_FLEX([],
 133              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 134                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 135
 136 AC_CHECK_PROG(INDENT, indent, indent, cat)
 137 if test "x$INDENT" != "xcat"; then
 138     # Only GNU indent is supported
 139     INDENT_VERSION=`indent --version | grep GNU`
 140     if test $? -eq 0; then
 141        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 142     else
 143        INDENT="cat"
 144     fi
 145 fi
 146
 147 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 148
 149 if test -z "$PYTHON2"; then
 150     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 151         AC_MSG_ERROR([Python not found - unable to generate sources])
 152     fi
 153 else
 154     if test "x$acv_mako_found" = xno; then
 155         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 156             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 157         fi
 158     fi
 159 fi
 160
 161 AC_PROG_INSTALL
 162
 163 dnl We need a POSIX shell for parts of the build. Assume we have one
 164 dnl in most cases.
 165 case "$host_os" in
 166 solaris*)
 167     # Solaris /bin/sh is too old/non-POSIX compliant
 168     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 169     SHELL="$POSIX_SHELL"
 170     ;;
 171 esac
 172
 173 dnl clang is mostly GCC-compatible, but its version is much lower,
 174 dnl so we have to check for it.
 175 AC_MSG_CHECKING([if compiling with clang])
 176
 177 AC_COMPILE_IFELSE(
 178 [AC_LANG_PROGRAM([], [[
 179 #ifndef __clang__
 180        not clang
 181 #endif
 182 ]])],
 183 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 184
 185 AC_MSG_RESULT([$acv_mesa_CLANG])
 186
 187 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 188 dnl versions are explictly not supported.
 189 GEN_ASM_OFFSETS=no
 190 USE_GNU99=no
 191 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 192     AC_MSG_CHECKING([whether gcc version is sufficient])
 193     major=0
 194     minor=0
 195
 196     GCC_VERSION=`$CC -dumpversion`
 197     if test $? -eq 0; then
 198         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 199         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 200     fi
 201
 202     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 203         AC_MSG_RESULT([no])
 204         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 205     else
 206         AC_MSG_RESULT([yes])
 207     fi
 208
 209     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 210         USE_GNU99=yes
 211     fi
 212     if test "x$cross_compiling" = xyes; then
 213         GEN_ASM_OFFSETS=yes
 214     fi
 215 fi
 216
 217 dnl We don't support building Mesa with Sun C compiler
 218 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 219 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 220 if test "x$SUNCC" = xyes; then
 221     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 222 fi
 223
 224 dnl Check for compiler builtins
 225 AX_GCC_BUILTIN([__builtin_bswap32])
 226 AX_GCC_BUILTIN([__builtin_bswap64])
 227 AX_GCC_BUILTIN([__builtin_clz])
 228 AX_GCC_BUILTIN([__builtin_clzll])
 229 AX_GCC_BUILTIN([__builtin_ctz])
 230 AX_GCC_BUILTIN([__builtin_expect])
 231 AX_GCC_BUILTIN([__builtin_ffs])
 232 AX_GCC_BUILTIN([__builtin_ffsll])
 233 AX_GCC_BUILTIN([__builtin_popcount])
 234 AX_GCC_BUILTIN([__builtin_popcountll])
 235 AX_GCC_BUILTIN([__builtin_unreachable])
 236
 237 AX_GCC_FUNC_ATTRIBUTE([const])
 238 AX_GCC_FUNC_ATTRIBUTE([flatten])
 239 AX_GCC_FUNC_ATTRIBUTE([format])
 240 AX_GCC_FUNC_ATTRIBUTE([malloc])
 241 AX_GCC_FUNC_ATTRIBUTE([packed])
 242 AX_GCC_FUNC_ATTRIBUTE([pure])
 243 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 244 AX_GCC_FUNC_ATTRIBUTE([unused])
 245 AX_GCC_FUNC_ATTRIBUTE([visibility])
 246 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 247 AX_GCC_FUNC_ATTRIBUTE([weak])
 248 AX_GCC_FUNC_ATTRIBUTE([alias])
 249
 250 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 251
 252 dnl Make sure the pkg-config macros are defined
 253 m4_ifndef([PKG_PROG_PKG_CONFIG],
 254     [m4_fatal([Could not locate the pkg-config autoconf macros.
 255   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 256   are in a different location, try setting the environment variable
 257   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 258 PKG_PROG_PKG_CONFIG()
 259
 260 dnl LIB_DIR - library basename
 261 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 262 AC_SUBST([LIB_DIR])
 263
 264 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 265 _SAVE_LDFLAGS="$LDFLAGS"
 266 _SAVE_CPPFLAGS="$CPPFLAGS"
 267
 268 dnl Compiler macros
 269 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 270 AC_SUBST([DEFINES])
 271 android=no
 272 case "$host_os" in
 273 *-android)
 274     android=yes
 275     ;;
 276 linux*|*-gnu*|gnu*|cygwin*)
 277     DEFINES="$DEFINES -D_GNU_SOURCE"
 278     ;;
 279 solaris*)
 280     DEFINES="$DEFINES -DSVR4"
 281     ;;
 282 esac
 283
 284 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 285
 286 dnl Add flags for gcc and g++
 287 if test "x$GCC" = xyes; then
 288     CFLAGS="$CFLAGS -Wall"
 289
 290     if test "x$USE_GNU99" = xyes; then
 291         CFLAGS="$CFLAGS -std=gnu99"
 292     else
 293         CFLAGS="$CFLAGS -std=c99"
 294     fi
 295
 296     # Enable -Werror=implicit-function-declaration and
 297     # -Werror=missing-prototypes, if available, or otherwise, just
 298     # -Wmissing-prototypes.  This is particularly useful to avoid
 299     # generating a loadable driver module that has undefined symbols.
 300     save_CFLAGS="$CFLAGS"
 301     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 302     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 303     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 304     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 305                    AC_MSG_RESULT([yes]),
 306                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 307                     AC_MSG_RESULT([no])]);
 308
 309     # Enable -fvisibility=hidden if using a gcc that supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 312     VISIBILITY_CFLAGS="-fvisibility=hidden"
 313     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 315                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 316
 317     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 318     CFLAGS=$save_CFLAGS
 319
 320     # We don't want floating-point math functions to set errno or trap
 321     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 322
 323     # Flags to help ensure that certain portions of the code -- and only those
 324     # portions -- can be built with MSVC:
 325     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 326     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 327     #   supports most of C99)
 328     # - the rest has no compiler compiler restrictions
 329     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 330     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 331
 332     # Enable -Werror=vla if compiler supports it
 333     save_CFLAGS="$CFLAGS"
 334     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 335     CFLAGS="$CFLAGS -Werror=vla"
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 337                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 338                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 339                     AC_MSG_RESULT([yes])],
 340                     AC_MSG_RESULT([no]));
 341     CFLAGS="$save_CFLAGS"
 342 fi
 343 if test "x$GXX" = xyes; then
 344     CXXFLAGS="$CXXFLAGS -Wall"
 345
 346     # Enable -fvisibility=hidden if using a gcc that supports it
 347     save_CXXFLAGS="$CXXFLAGS"
 348     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 349     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 350     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 351     AC_LANG_PUSH([C++])
 352     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 353                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 354     AC_LANG_POP([C++])
 355
 356     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 357     CXXFLAGS=$save_CXXFLAGS
 358
 359     # We don't want floating-point math functions to set errno or trap
 360     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 361 fi
 362
 363 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 364 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 365
 366 dnl even if the compiler appears to support it, using visibility attributes isn't
 367 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 368 case "$host_os" in
 369 cygwin*)
 370     VISIBILITY_CFLAGS=""
 371     VISIBILITY_CXXFLAGS=""
 372     ;;
 373 esac
 374
 375 AC_SUBST([VISIBILITY_CFLAGS])
 376 AC_SUBST([VISIBILITY_CXXFLAGS])
 377
 378 dnl
 379 dnl Optional flags, check for compiler support
 380 dnl
 381 SSE41_CFLAGS="-msse4.1"
 382 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 383 dnl stack, but on x86-32 such alignment is not guaranteed.
 384 case "$target_cpu" in
 385 i?86)
 386     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 387     ;;
 388 esac
 389 save_CFLAGS="$CFLAGS"
 390 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 #include <smmintrin.h>
 393 int param;
 394 int main () {
 395     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 396     c = _mm_max_epu32(a, b);
 397     return _mm_cvtsi128_si32(c);
 398 }]])], SSE41_SUPPORTED=1)
 399 CFLAGS="$save_CFLAGS"
 400 if test "x$SSE41_SUPPORTED" = x1; then
 401     DEFINES="$DEFINES -DUSE_SSE41"
 402 fi
 403 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 404 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 405
 406 dnl Check for new-style atomic builtins
 407 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 408 int main() {
 409     int n;
 410     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 411 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 412 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 413     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 414 fi
 415 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 416
 417 dnl Check for Endianness
 418 AC_C_BIGENDIAN(
 419    little_endian=no,
 420    little_endian=yes,
 421    little_endian=no,
 422    little_endian=no
 423 )
 424
 425 dnl Check for POWER8 Architecture
 426 PWR8_CFLAGS="-mpower8-vector"
 427 have_pwr8_intrinsics=no
 428 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 429 save_CFLAGS=$CFLAGS
 430 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 431 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 432 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 433 #error "Need GCC >= 4.8 for sane POWER8 support"
 434 #endif
 435 #include <altivec.h>
 436 int main () {
 437     vector unsigned char r;
 438     vector unsigned int v = vec_splat_u32 (1);
 439     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 440     return 0;
 441 }]])], have_pwr8_intrinsics=yes)
 442 CFLAGS=$save_CFLAGS
 443
 444 AC_ARG_ENABLE(pwr8,
 445    [AC_HELP_STRING([--disable-pwr8-inst],
 446                    [disable POWER8-specific instructions])],
 447    [enable_pwr8=$enableval], [enable_pwr8=auto])
 448
 449 if test "x$enable_pwr8" = xno ; then
 450    have_pwr8_intrinsics=disabled
 451 fi
 452
 453 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 454    DEFINES="$DEFINES -D_ARCH_PWR8"
 455    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 456    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 457 else
 458    PWR8_CFLAGS=
 459 fi
 460
 461 AC_MSG_RESULT($have_pwr8_intrinsics)
 462 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 463    AC_MSG_ERROR([POWER8 compiler support not detected])
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 467    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 468 fi
 469
 470 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 471
 472 dnl Can't have static and shared libraries, default to static if user
 473 dnl explicitly requested. If both disabled, set to static since shared
 474 dnl was explicitly requested.
 475 case "x$enable_static$enable_shared" in
 476 xyesyes)
 477     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 478     ;;
 479 xnono)
 480     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 481     ;;
 482 esac
 483
 484 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 485
 486 dnl
 487 dnl other compiler options
 488 dnl
 489 AC_ARG_ENABLE([debug],
 490     [AS_HELP_STRING([--enable-debug],
 491         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 492     [enable_debug="$enableval"],
 493     [enable_debug=no]
 494 )
 495
 496 AC_ARG_ENABLE([profile],
 497     [AS_HELP_STRING([--enable-profile],
 498         [enable profiling of code @<:@default=disabled@:>@])],
 499     [enable_profile="$enableval"],
 500     [enable_profile=no]
 501 )
 502
 503 if test "x$enable_profile" = xyes; then
 504     DEFINES="$DEFINES -DPROFILE"
 505     if test "x$GCC" = xyes; then
 506         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 507     fi
 508     if test "x$GXX" = xyes; then
 509         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 510     fi
 511 fi
 512
 513 if test "x$enable_debug" = xyes; then
 514     DEFINES="$DEFINES -DDEBUG"
 515     if test "x$enable_profile" = xyes; then
 516         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 517     fi
 518     if test "x$GCC" = xyes; then
 519         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 520             CFLAGS="$CFLAGS -g"
 521         fi
 522         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 523             CFLAGS="$CFLAGS -O0"
 524         fi
 525     fi
 526     if test "x$GXX" = xyes; then
 527         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 528             CXXFLAGS="$CXXFLAGS -g"
 529         fi
 530         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 531             CXXFLAGS="$CXXFLAGS -O0"
 532         fi
 533     fi
 534 else
 535    DEFINES="$DEFINES -DNDEBUG"
 536 fi
 537
 538 dnl
 539 dnl Check if linker supports -Bsymbolic
 540 dnl
 541 save_LDFLAGS=$LDFLAGS
 542 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 543 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 544 AC_LINK_IFELSE(
 545     [AC_LANG_SOURCE([int main() { return 0;}])],
 546     [AC_MSG_RESULT([yes])
 547         BSYMBOLIC="-Wl,-Bsymbolic";],
 548     [AC_MSG_RESULT([no])
 549         BSYMBOLIC="";])
 550 LDFLAGS=$save_LDFLAGS
 551
 552 AC_SUBST([BSYMBOLIC])
 553
 554 dnl
 555 dnl Check if linker supports garbage collection
 556 dnl
 557 save_LDFLAGS=$LDFLAGS
 558 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 559 AC_MSG_CHECKING([whether ld supports --gc-sections])
 560 AC_LINK_IFELSE(
 561     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 562     [AC_MSG_RESULT([yes])
 563         GC_SECTIONS="-Wl,--gc-sections";],
 564     [AC_MSG_RESULT([no])
 565         GC_SECTIONS="";])
 566 LDFLAGS=$save_LDFLAGS
 567
 568 AC_SUBST([GC_SECTIONS])
 569
 570 dnl
 571 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 572 dnl so when these flags are passed to ld via libtool the checks will fail
 573 dnl
 574 case "$host_os" in
 575 openbsd* | darwin* )
 576     LD_NO_UNDEFINED="" ;;
 577 *)
 578     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 579 esac
 580
 581 AC_SUBST([LD_NO_UNDEFINED])
 582
 583 dnl
 584 dnl Check if linker supports version scripts
 585 dnl
 586 AC_MSG_CHECKING([if the linker supports version-scripts])
 587 save_LDFLAGS=$LDFLAGS
 588 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 589 cat > conftest.map <<EOF
 590 VERSION_1 {
 591      global:
 592          main;
 593
 594      local:
 595          *;
 596 };
 597 EOF
 598 AC_LINK_IFELSE(
 599     [AC_LANG_SOURCE([int main() { return 0;}])],
 600     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 601     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 602 LDFLAGS=$save_LDFLAGS
 603 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 604
 605 dnl
 606 dnl Check if linker supports dynamic list files
 607 dnl
 608 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 609 save_LDFLAGS=$LDFLAGS
 610 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 611 cat > conftest.dyn <<EOF
 612 {
 613         radeon_drm_winsys_create;
 614 };
 615 EOF
 616 AC_LINK_IFELSE(
 617     [AC_LANG_SOURCE([int main() { return 0;}])],
 618     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 619     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 620 LDFLAGS=$save_LDFLAGS
 621 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 622
 623 dnl
 624 dnl compatibility symlinks
 625 dnl
 626 case "$host_os" in
 627 linux* )
 628     HAVE_COMPAT_SYMLINKS=yes ;;
 629 * )
 630     HAVE_COMPAT_SYMLINKS=no ;;
 631 esac
 632
 633 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 634
 635 dnl
 636 dnl library names
 637 dnl
 638 dnl Unfortunately we need to do a few things that libtool can't help us with,
 639 dnl so we need some knowledge of shared library filenames:
 640 dnl
 641 dnl LIB_EXT is the extension used when creating symlinks for alternate
 642 dnl filenames for a shared library which will be dynamically loaded
 643 dnl
 644 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 645 dnl the file for a shared library we wish to link with
 646 dnl
 647 case "$host_os" in
 648 darwin* )
 649     LIB_EXT='dylib'
 650     IMP_LIB_EXT=$LIB_EXT
 651     ;;
 652 cygwin* )
 653     LIB_EXT='dll'
 654     IMP_LIB_EXT='dll.a'
 655     ;;
 656 aix* )
 657     LIB_EXT='a'
 658     IMP_LIB_EXT=$LIB_EXT
 659     ;;
 660 * )
 661     LIB_EXT='so'
 662     IMP_LIB_EXT=$LIB_EXT
 663     ;;
 664 esac
 665
 666 AC_SUBST([LIB_EXT])
 667
 668 dnl
 669 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 670 dnl
 671 AC_ARG_ENABLE([texture-float],
 672     [AS_HELP_STRING([--enable-texture-float],
 673         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 674     [enable_texture_float="$enableval"],
 675     [enable_texture_float=no]
 676 )
 677 if test "x$enable_texture_float" = xyes; then
 678     AC_MSG_WARN([Floating-point textures enabled.])
 679     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 680     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 681 fi
 682
 683 dnl
 684 dnl Arch/platform-specific settings
 685 dnl
 686 AC_ARG_ENABLE([asm],
 687     [AS_HELP_STRING([--disable-asm],
 688         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 689     [enable_asm="$enableval"],
 690     [enable_asm=yes]
 691 )
 692 asm_arch=""
 693 AC_MSG_CHECKING([whether to enable assembly])
 694 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 695 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 696 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 697     case "$host_cpu" in
 698     i?86 | x86_64 | amd64)
 699         if test "x$host_cpu" != "x$target_cpu"; then
 700             enable_asm=no
 701             AC_MSG_RESULT([no, cross compiling])
 702         fi
 703         ;;
 704     esac
 705 fi
 706 # check for supported arches
 707 if test "x$enable_asm" = xyes; then
 708     case "$host_cpu" in
 709     i?86)
 710         case "$host_os" in
 711         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 712             asm_arch=x86
 713             ;;
 714         esac
 715         ;;
 716     x86_64|amd64)
 717         case "$host_os" in
 718         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 719             asm_arch=x86_64
 720             ;;
 721         esac
 722         ;;
 723     sparc*)
 724         case "$host_os" in
 725         linux*)
 726             asm_arch=sparc
 727             ;;
 728         esac
 729         ;;
 730     esac
 731
 732     case "$asm_arch" in
 733     x86)
 734         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 735         AC_MSG_RESULT([yes, x86])
 736         ;;
 737     x86_64|amd64)
 738         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 739         AC_MSG_RESULT([yes, x86_64])
 740         ;;
 741     sparc)
 742         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 743         AC_MSG_RESULT([yes, sparc])
 744         ;;
 745     *)
 746         AC_MSG_RESULT([no, platform not supported])
 747         ;;
 748     esac
 749 fi
 750
 751 AC_HEADER_MAJOR
 752 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 753 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 754 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 755 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 756
 757 dnl Check to see if dlopen is in default libraries (like Solaris, which
 758 dnl has it in libc), or if libdl is needed to get it.
 759 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 760     [AC_CHECK_LIB([dl], [dlopen],
 761        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 762 AC_SUBST([DLOPEN_LIBS])
 763
 764 dnl Check if that library also has dladdr
 765 save_LIBS="$LIBS"
 766 LIBS="$LIBS $DLOPEN_LIBS"
 767 AC_CHECK_FUNCS([dladdr])
 768 LIBS="$save_LIBS"
 769
 770 case "$host_os" in
 771 darwin*)
 772     ;;
 773 *)
 774     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 775                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 776                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 777     AC_SUBST([CLOCK_LIB])
 778     ;;
 779 esac
 780
 781 dnl See if posix_memalign is available
 782 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 783
 784 dnl Check for pthreads
 785 AX_PTHREAD
 786 if test "x$ax_pthread_ok" = xno; then
 787     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 788 fi
 789 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 790 dnl to -pthread, which causes problems if we need -lpthread to appear in
 791 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 792 dnl is not valid for that platform.
 793 if test "x$android" = xno; then
 794     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 795 fi
 796
 797 dnl pthread-stubs is mandatory on targets where it exists
 798 case "$host_os" in
 799 cygwin* )
 800     pthread_stubs_possible="no"
 801     ;;
 802 * )
 803     pthread_stubs_possible="yes"
 804     ;;
 805 esac
 806
 807 if test "x$pthread_stubs_possible" = xyes; then
 808     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 809     AC_SUBST(PTHREADSTUBS_CFLAGS)
 810     AC_SUBST(PTHREADSTUBS_LIBS)
 811 fi
 812
 813 dnl SELinux awareness.
 814 AC_ARG_ENABLE([selinux],
 815     [AS_HELP_STRING([--enable-selinux],
 816         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 817     [MESA_SELINUX="$enableval"],
 818     [MESA_SELINUX=no])
 819 if test "x$enable_selinux" = "xyes"; then
 820     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 821         [AC_CHECK_HEADER([selinux/selinux.h],[],
 822                          [AC_MSG_ERROR([SELinux headers not found])])
 823          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 824                       [AC_MSG_ERROR([SELinux library not found])])
 825          SELINUX_LIBS="-lselinux"])
 826     DEFINES="$DEFINES -DMESA_SELINUX"
 827 fi
 828 AC_SUBST([SELINUX_CFLAGS])
 829 AC_SUBST([SELINUX_LIBS])
 830
 831 dnl
 832 dnl LLVM
 833 dnl
 834 AC_ARG_ENABLE([llvm-shared-libs],
 835     [AS_HELP_STRING([--enable-llvm-shared-libs],
 836         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 837     [enable_llvm_shared_libs="$enableval"],
 838     [enable_llvm_shared_libs=yes])
 839
 840 AC_ARG_WITH([llvm-prefix],
 841     [AS_HELP_STRING([--with-llvm-prefix],
 842         [Prefix for LLVM installations in non-standard locations])],
 843     [llvm_prefix="$withval"],
 844     [llvm_prefix=''])
 845
 846 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 847 if test "x$have_libelf" = xno; then
 848    LIBELF_LIBS=''
 849    LIBELF_CFLAGS=''
 850    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 851    AC_SUBST([LIBELF_LIBS])
 852    AC_SUBST([LIBELF_CFLAGS])
 853 fi
 854
 855 if test -z "$LLVM_CONFIG"; then
 856     if test -n "$llvm_prefix"; then
 857         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 858     else
 859         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 860     fi
 861 fi
 862
 863 llvm_add_component() {
 864     new_llvm_component=$1
 865     driver_name=$2
 866
 867     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 868         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 869     else
 870         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 871     fi
 872 }
 873
 874 llvm_add_default_components() {
 875     driver_name=$1
 876
 877     # Required default components
 878     llvm_add_component "bitwriter" $driver_name
 879     llvm_add_component "engine" $driver_name
 880     llvm_add_component "mcdisassembler" $driver_name
 881     llvm_add_component "mcjit" $driver_name
 882
 883     # Optional default components
 884     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 885         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 886     fi
 887 }
 888
 889 llvm_add_target() {
 890     new_llvm_target=$1
 891     driver_name=$2
 892
 893     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 894         llvm_add_component $new_llvm_target $driver_name
 895     else
 896         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 897     fi
 898 }
 899
 900 # Call this inside ` ` to get the return value.
 901 # $1 is the llvm-config command with arguments.
 902 strip_unwanted_llvm_flags() {
 903     # Use \> (marks the end of the word)
 904     echo `$1` | sed \
 905         -e 's/-march=\S*//g' \
 906         -e 's/-mtune=\S*//g' \
 907         -e 's/-mcpu=\S*//g' \
 908         -e 's/-DNDEBUG\>//g' \
 909         -e 's/-D_GNU_SOURCE\>//g' \
 910         -e 's/-pedantic\>//g' \
 911         -e 's/-Wcovered-switch-default\>//g' \
 912         -e 's/-O.\>//g' \
 913         -e 's/-g\>//g' \
 914         -e 's/-Wall\>//g' \
 915         -e 's/-Wcast-qual\>//g' \
 916         -e 's/-Woverloaded-virtual\>//g' \
 917         -e 's/-fcolor-diagnostics\>//g' \
 918         -e 's/-fdata-sections\>//g' \
 919         -e 's/-ffunction-sections\>//g' \
 920         -e 's/-fno-exceptions\>//g' \
 921         -e 's/-fomit-frame-pointer\>//g' \
 922         -e 's/-fvisibility-inlines-hidden\>//g' \
 923         -e 's/-fPIC\>//g' \
 924         -e 's/-fstack-protector-strong\>//g'
 925 }
 926
 927 llvm_set_environment_variables() {
 928     if test "x$LLVM_CONFIG" != xno; then
 929         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 930         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 931         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 932         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 933
 934         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 935         save_CFLAGS="$CFLAGS"
 936         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 937
 938         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 939             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 940         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 941             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 942         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 943             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 944
 945         CFLAGS="$save_CFLAGS"
 946
 947         # Only needed for LLVM < 3.6.0
 948         if test -z "$LLVM_VERSION_PATCH"; then
 949             LLVM_VERSION_PATCH=0
 950         fi
 951
 952         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 953
 954         FOUND_LLVM=yes
 955     else
 956         FOUND_LLVM=no
 957         LLVM_VERSION_INT=0
 958     fi
 959 }
 960
 961 require_llvm() {
 962     if test "x$enable_llvm" != "xyes"; then
 963         AC_MSG_ERROR([--enable-llvm is required when building $1])
 964     fi
 965 }
 966
 967 llvm_require_version() {
 968     require_llvm $2
 969
 970     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 971     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 972     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 973
 974     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 975         # major > required major
 976         #  --> OK
 977         return
 978     fi
 979
 980     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 981         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 982             # major = required major and
 983             # minor > required minor
 984             #  --> OK
 985             return
 986         else
 987             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 988                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 989                     # major = required major and
 990                     # minor = required minor and
 991                     # patch >= required patch
 992                     #  --> OK
 993                     return
 994                 fi
 995             fi
 996         fi
 997     fi
 998
 999     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1000 }
1001
1002 radeon_llvm_check() {
1003     if test ${LLVM_VERSION_INT} -lt 307; then
1004         amdgpu_llvm_target_name='r600'
1005     else
1006         amdgpu_llvm_target_name='amdgpu'
1007     fi
1008
1009     llvm_require_version $*
1010
1011     llvm_add_target $amdgpu_llvm_target_name $2
1012
1013     llvm_add_default_components $2
1014     llvm_add_component "bitreader" $2
1015     llvm_add_component "ipo" $2
1016
1017     NEED_RADEON_LLVM=yes
1018     if test "x$have_libelf" != xyes; then
1019        AC_MSG_ERROR([$1 requires libelf when using llvm])
1020     fi
1021 }
1022
1023 llvm_set_environment_variables
1024
1025 AC_SUBST([LLVM_CFLAGS])
1026 AC_SUBST([LLVM_CXXFLAGS])
1027 AC_SUBST([LLVM_LIBS])
1028 AC_SUBST([LLVM_LDFLAGS])
1029 AC_SUBST([LLVM_INCLUDEDIR])
1030
1031 dnl Options for APIs
1032 AC_ARG_ENABLE([opengl],
1033     [AS_HELP_STRING([--disable-opengl],
1034         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1035     [enable_opengl="$enableval"],
1036     [enable_opengl=yes])
1037 AC_ARG_ENABLE([gles1],
1038     [AS_HELP_STRING([--disable-gles1],
1039         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1040     [enable_gles1="$enableval"],
1041     [enable_gles1=yes])
1042 AC_ARG_ENABLE([gles2],
1043     [AS_HELP_STRING([--disable-gles2],
1044         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1045     [enable_gles2="$enableval"],
1046     [enable_gles2=yes])
1047
1048 AC_ARG_ENABLE([dri],
1049     [AS_HELP_STRING([--enable-dri],
1050         [enable DRI modules @<:@default=enabled@:>@])],
1051     [enable_dri="$enableval"],
1052     [enable_dri=yes])
1053
1054 AC_ARG_ENABLE([gallium-extra-hud],
1055     [AS_HELP_STRING([--enable-gallium-extra-hud],
1056         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1057     [enable_gallium_extra_hud="$enableval"],
1058     [enable_gallium_extra_hud=no])
1059 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1060 if test "x$enable_gallium_extra_hud" = xyes ; then
1061     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1062 fi
1063
1064 #TODO: no pkgconfig .pc available for libsensors.
1065 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1066 AC_ARG_ENABLE([lmsensors],
1067     [AS_HELP_STRING([--enable-lmsensors],
1068         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1069     [enable_lmsensors="$enableval"],
1070     [enable_lmsensors=no])
1071 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1072 if test "x$enable_lmsensors" = xyes ; then
1073     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1074     LIBSENSORS_LIBS="-lsensors"
1075 else
1076     LIBSENSORS_LIBS=""
1077 fi
1078 AC_SUBST(LIBSENSORS_LIBS)
1079
1080 case "$host_os" in
1081 linux*)
1082     dri3_default=yes
1083     ;;
1084 *)
1085     dri3_default=no
1086     ;;
1087 esac
1088
1089 if test "x$enable_dri" = xno; then
1090     dri3_default=no
1091 fi
1092
1093 AC_ARG_ENABLE([dri3],
1094     [AS_HELP_STRING([--enable-dri3],
1095         [enable DRI3 @<:@default=auto@:>@])],
1096     [enable_dri3="$enableval"],
1097     [enable_dri3="$dri3_default"])
1098 AC_ARG_ENABLE([glx],
1099     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1100         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1101     [enable_glx="$enableval"],
1102     [enable_glx=yes])
1103 AC_ARG_ENABLE([osmesa],
1104     [AS_HELP_STRING([--enable-osmesa],
1105         [enable OSMesa library @<:@default=disabled@:>@])],
1106     [enable_osmesa="$enableval"],
1107     [enable_osmesa=no])
1108 AC_ARG_ENABLE([gallium-osmesa],
1109     [AS_HELP_STRING([--enable-gallium-osmesa],
1110         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1111     [enable_gallium_osmesa="$enableval"],
1112     [enable_gallium_osmesa=no])
1113 AC_ARG_ENABLE([egl],
1114     [AS_HELP_STRING([--disable-egl],
1115         [disable EGL library @<:@default=enabled@:>@])],
1116     [enable_egl="$enableval"],
1117     [enable_egl=yes])
1118
1119 AC_ARG_ENABLE([xa],
1120     [AS_HELP_STRING([--enable-xa],
1121         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1122     [enable_xa="$enableval"],
1123     [enable_xa=no])
1124 AC_ARG_ENABLE([gbm],
1125    [AS_HELP_STRING([--enable-gbm],
1126          [enable gbm library @<:@default=yes except cygwin@:>@])],
1127    [enable_gbm="$enableval"],
1128    [case "$host_os" in
1129        cygwin*)
1130           enable_gbm=no
1131           ;;
1132        *)
1133           enable_gbm=yes
1134           ;;
1135     esac])
1136 AC_ARG_ENABLE([nine],
1137     [AS_HELP_STRING([--enable-nine],
1138         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1139     [enable_nine="$enableval"],
1140     [enable_nine=no])
1141
1142 AC_ARG_ENABLE([xvmc],
1143    [AS_HELP_STRING([--enable-xvmc],
1144          [enable xvmc library @<:@default=auto@:>@])],
1145    [enable_xvmc="$enableval"],
1146    [enable_xvmc=auto])
1147 AC_ARG_ENABLE([vdpau],
1148    [AS_HELP_STRING([--enable-vdpau],
1149          [enable vdpau library @<:@default=auto@:>@])],
1150    [enable_vdpau="$enableval"],
1151    [enable_vdpau=auto])
1152 AC_ARG_ENABLE([omx],
1153    [AS_HELP_STRING([--enable-omx],
1154          [enable OpenMAX library @<:@default=disabled@:>@])],
1155    [enable_omx="$enableval"],
1156    [enable_omx=no])
1157 AC_ARG_ENABLE([va],
1158    [AS_HELP_STRING([--enable-va],
1159          [enable va library @<:@default=auto@:>@])],
1160    [enable_va="$enableval"],
1161    [enable_va=auto])
1162 AC_ARG_ENABLE([opencl],
1163    [AS_HELP_STRING([--enable-opencl],
1164          [enable OpenCL library @<:@default=disabled@:>@])],
1165    [enable_opencl="$enableval"],
1166    [enable_opencl=no])
1167 AC_ARG_ENABLE([opencl_icd],
1168    [AS_HELP_STRING([--enable-opencl-icd],
1169           [Build an OpenCL ICD library to be loaded by an ICD implementation
1170            @<:@default=disabled@:>@])],
1171     [enable_opencl_icd="$enableval"],
1172     [enable_opencl_icd=no])
1173
1174 AC_ARG_ENABLE([gallium-tests],
1175     [AS_HELP_STRING([--enable-gallium-tests],
1176         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1177     [enable_gallium_tests="$enableval"],
1178     [enable_gallium_tests=no])
1179
1180 # Option for Gallium drivers
1181
1182 # Keep this in sync with the --with-gallium-drivers help string default value
1183 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1184
1185 AC_ARG_WITH([gallium-drivers],
1186     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1187         [comma delimited Gallium drivers list, e.g.
1188         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1189         @<:@default=r300,r600,svga,swrast@:>@])],
1190     [with_gallium_drivers="$withval"],
1191     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1192
1193 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1194 # here so that the script doesn't choke on an unknown driver name later.
1195 case "$with_gallium_drivers" in
1196     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1197     no) with_gallium_drivers='' ;;
1198 esac
1199
1200 if test "x$enable_opengl" = xno -a \
1201         "x$enable_gles1" = xno -a \
1202         "x$enable_gles2" = xno -a \
1203         "x$enable_nine" = xno -a \
1204         "x$enable_xa" = xno -a \
1205         "x$enable_xvmc" = xno -a \
1206         "x$enable_vdpau" = xno -a \
1207         "x$enable_omx" = xno -a \
1208         "x$enable_va" = xno -a \
1209         "x$enable_opencl" = xno; then
1210     AC_MSG_ERROR([at least one API should be enabled])
1211 fi
1212
1213 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1214 if test "x$enable_opengl" = xno -a \
1215         "x$enable_gles1" = xyes; then
1216     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1217 fi
1218
1219 if test "x$enable_opengl" = xno -a \
1220         "x$enable_gles2" = xyes; then
1221     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1222 fi
1223
1224 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1225 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1226 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1227 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1228                                         "x$enable_gles1" = xyes -o \
1229                                         "x$enable_gles2" = xyes)
1230
1231 # Validate GLX options
1232 if test "x$enable_glx" = xyes; then
1233     if test "x$enable_dri" = xyes; then
1234         enable_glx=dri
1235     elif test -n "$with_gallium_drivers"; then
1236         enable_glx=gallium-xlib
1237     else
1238         enable_glx=xlib
1239     fi
1240 fi
1241 case "x$enable_glx" in
1242 xdri | xxlib | xgallium-xlib)
1243     # GLX requires OpenGL
1244     if test "x$enable_opengl" = xno; then
1245         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1246     fi
1247
1248     # Check individual dependencies
1249     case "x$enable_glx" in
1250     xdri)
1251         if test "x$enable_dri" = xno; then
1252             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1253         fi
1254         ;;
1255     xxlib)
1256         if test "x$enable_dri" = xyes; then
1257             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1258         fi
1259         ;;
1260     xgallium-xlib )
1261         if test "x$enable_dri" = xyes; then
1262             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1263         fi
1264         if test -z "$with_gallium_drivers"; then
1265             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1266         fi
1267         ;;
1268     esac
1269     ;;
1270 xno)
1271     ;;
1272 *)
1273     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1274     ;;
1275 esac
1276
1277 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1278 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1279 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1280 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1281
1282 DEFAULT_GL_LIB_NAME=GL
1283
1284 dnl
1285 dnl Libglvnd configuration
1286 dnl
1287 AC_ARG_ENABLE([libglvnd],
1288     [AS_HELP_STRING([--enable-libglvnd],
1289         [Build for libglvnd @<:@default=disabled@:>@])],
1290     [enable_libglvnd="$enableval"],
1291     [enable_libglvnd=no])
1292 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1293 if test "x$enable_libglvnd" = xyes ; then
1294     dnl XXX: update once we can handle more than libGL/glx.
1295     dnl Namely: we should error out if neither of the glvnd enabled libraries
1296     dnl are built
1297     case "x$enable_glx" in
1298     xno)
1299         AC_MSG_ERROR([cannot build libglvnd without GLX])
1300         ;;
1301     xxlib | xgallium-xlib )
1302         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1303         ;;
1304     xdri)
1305         ;;
1306     esac
1307
1308     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1309     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1310     DEFAULT_GL_LIB_NAME=GLX_mesa
1311 fi
1312
1313 AC_ARG_WITH([gl-lib-name],
1314   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1315     [specify GL library name @<:@default=GL@:>@])],
1316   [GL_LIB=$withval],
1317   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1318 AC_ARG_WITH([osmesa-lib-name],
1319   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1320     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1321   [OSMESA_LIB=$withval],
1322   [OSMESA_LIB=OSMesa])
1323 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1324 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1325
1326 dnl
1327 dnl Mangled Mesa support
1328 dnl
1329 AC_ARG_ENABLE([mangling],
1330   [AS_HELP_STRING([--enable-mangling],
1331     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1332   [enable_mangling="${enableval}"],
1333   [enable_mangling=no]
1334 )
1335 if test "x${enable_mangling}" = "xyes" ; then
1336   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1337   GL_LIB="Mangled${GL_LIB}"
1338   OSMESA_LIB="Mangled${OSMESA_LIB}"
1339 fi
1340 AC_SUBST([GL_LIB])
1341 AC_SUBST([OSMESA_LIB])
1342
1343 # Check for libdrm
1344 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1345                   [have_libdrm=yes], [have_libdrm=no])
1346 if test "x$have_libdrm" = xyes; then
1347         DEFINES="$DEFINES -DHAVE_LIBDRM"
1348 fi
1349
1350 require_libdrm() {
1351     if test "x$have_libdrm" != xyes; then
1352        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1353     fi
1354 }
1355
1356
1357 # Select which platform-dependent DRI code gets built
1358 case "$host_os" in
1359 darwin*)
1360     dri_platform='apple' ;;
1361 cygwin*)
1362     dri_platform='windows' ;;
1363 gnu*)
1364     dri_platform='none' ;;
1365 *)
1366     dri_platform='drm' ;;
1367 esac
1368
1369 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1370     have_drisw_kms='yes'
1371 fi
1372
1373 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1374 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1375 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1376 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1377 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1378 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1379 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1380 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1381 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1382
1383 AC_ARG_ENABLE([shared-glapi],
1384     [AS_HELP_STRING([--enable-shared-glapi],
1385         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1386     [enable_shared_glapi="$enableval"],
1387     [enable_shared_glapi=yes])
1388
1389 case "x$enable_opengl$enable_gles1$enable_gles2" in
1390 x*yes*yes*)
1391     if test "x$enable_shared_glapi" = xno; then
1392         AC_MSG_ERROR([shared GLAPI required when building two or more of
1393                       the following APIs - opengl, gles1 gles2])
1394     fi
1395     ;;
1396 esac
1397
1398 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1399
1400 # Build the pipe-drivers as separate libraries/modules.
1401 # Do not touch this unless you know what you are doing.
1402 # XXX: Expose via configure option ?
1403 enable_shared_pipe_drivers=no
1404
1405 dnl
1406 dnl Driver specific build directories
1407 dnl
1408
1409 if test "x$enable_gallium_osmesa" = xyes; then
1410     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1411         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1412     fi
1413     if test "x$enable_osmesa" = xyes; then
1414         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1415     fi
1416 fi
1417
1418 require_dri_shared_libs_and_glapi() {
1419     if test "x$enable_static" = xyes; then
1420         AC_MSG_ERROR([$1 cannot be build as static library])
1421     fi
1422
1423     if test "x$enable_dri" != xyes; then
1424         # There is only a single backend which won't be build/used otherwise.
1425         # XXX: Revisit this as the egl/haiku is a thing.
1426         AC_MSG_ERROR([$1 requires --enable-dri])
1427     fi
1428
1429     if test "x$enable_shared_glapi" != xyes; then
1430         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1431     fi
1432 }
1433
1434 if test "x$enable_dri" = xyes; then
1435     require_dri_shared_libs_and_glapi "DRI"
1436
1437     # not a hard requirement as swrast does not depend on it
1438     if test "x$have_libdrm" = xyes; then
1439         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1440     fi
1441 fi
1442
1443 AC_ARG_ENABLE([driglx-direct],
1444     [AS_HELP_STRING([--disable-driglx-direct],
1445         [disable direct rendering in GLX and EGL for DRI \
1446             @<:@default=auto@:>@])],
1447     [driglx_direct="$enableval"],
1448     [driglx_direct="yes"])
1449
1450 dnl
1451 dnl libGL configuration per driver
1452 dnl
1453 if test "x$enable_glx" != xno; then
1454     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1455 fi
1456 case "x$enable_glx" in
1457 xxlib | xgallium-xlib)
1458     # Xlib-based GLX
1459     dri_modules="x11 xext xcb"
1460     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1461     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1462     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1463     GL_LIB_DEPS="$XLIBGL_LIBS"
1464     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1465     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1466     ;;
1467 xdri)
1468     # DRI-based GLX
1469
1470     # find the DRI deps for libGL
1471     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1472
1473     if test x"$driglx_direct" = xyes; then
1474         if test x"$dri_platform" = xdrm ; then
1475             DEFINES="$DEFINES -DGLX_USE_DRM"
1476             require_libdrm "Direct rendering"
1477
1478             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1479             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1480             if test x"$enable_dri3" = xyes; then
1481                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1482                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1483             fi
1484
1485             if test x"$enable_dri" = xyes; then
1486                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1487             fi
1488
1489             if test x"$enable_dri3" = xyes; then
1490                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1491                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1492                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1493             fi
1494         fi
1495         if test x"$dri_platform" = xapple ; then
1496             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1497         fi
1498         if test x"$dri_platform" = xwindows ; then
1499             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1500         fi
1501     fi
1502
1503     # add xf86vidmode if available
1504     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1505     if test "$HAVE_XF86VIDMODE" = yes ; then
1506         dri_modules="$dri_modules xxf86vm"
1507     fi
1508
1509     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1510     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1511     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1512     GL_LIB_DEPS="$DRIGL_LIBS"
1513
1514     # need DRM libs, $PTHREAD_LIBS, etc.
1515     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1516     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1517     ;;
1518 esac
1519
1520 # This is outside the case (above) so that it is invoked even for non-GLX
1521 # builds.
1522 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1523
1524 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1525 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1526 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1527 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1528
1529 AC_SUBST([X11_INCLUDES])
1530 AC_SUBST([GL_LIB_DEPS])
1531 AC_SUBST([GL_PC_REQ_PRIV])
1532 AC_SUBST([GL_PC_LIB_PRIV])
1533 AC_SUBST([GL_PC_CFLAGS])
1534 AC_SUBST([DRI_PC_REQ_PRIV])
1535 AC_SUBST([GLESv1_CM_LIB_DEPS])
1536 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1537 AC_SUBST([GLESv2_LIB_DEPS])
1538 AC_SUBST([GLESv2_PC_LIB_PRIV])
1539
1540 AC_SUBST([HAVE_XF86VIDMODE])
1541
1542 dnl
1543 dnl More GLX setup
1544 dnl
1545 case "x$enable_glx" in
1546 xxlib | xgallium-xlib)
1547     DEFINES="$DEFINES -DUSE_XSHM"
1548     ;;
1549 xdri)
1550     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1551     if test "x$driglx_direct" = xyes; then
1552         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1553     fi
1554     ;;
1555 esac
1556
1557 dnl
1558 dnl TLS detection
1559 dnl
1560
1561 AC_ARG_ENABLE([glx-tls],
1562     [AS_HELP_STRING([--enable-glx-tls],
1563         [enable TLS support in GLX @<:@default=enabled@:>@])],
1564     [GLX_USE_TLS="$enableval"],
1565     [GLX_USE_TLS=yes])
1566 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1567
1568 if test "x$GLX_USE_TLS" = xyes; then
1569     DEFINES="$DEFINES -DGLX_USE_TLS"
1570 fi
1571
1572 dnl Read-only text section on x86 hardened platforms
1573 AC_ARG_ENABLE([glx-read-only-text],
1574     [AS_HELP_STRING([--enable-glx-read-only-text],
1575         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1576     [enable_glx_read_only_text="$enableval"],
1577     [enable_glx_read_only_text=no])
1578 if test "x$enable_glx_read_only_text" = xyes; then
1579     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1580 fi
1581
1582 dnl
1583 dnl More DRI setup
1584 dnl
1585 dnl Directory for DRI drivers
1586 AC_ARG_WITH([dri-driverdir],
1587     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1588         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1589     [DRI_DRIVER_INSTALL_DIR="$withval"],
1590     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1591 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1592 dnl Extra search path for DRI drivers
1593 AC_ARG_WITH([dri-searchpath],
1594     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1595         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1596     [DRI_DRIVER_SEARCH_DIR="$withval"],
1597     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1598 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1599 dnl Which drivers to build - default is chosen by platform
1600 AC_ARG_WITH([dri-drivers],
1601     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1602         [comma delimited classic DRI drivers list, e.g.
1603         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1604     [with_dri_drivers="$withval"],
1605     [with_dri_drivers=auto])
1606
1607 if test "x$with_dri_drivers" = xauto; then
1608     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1609         with_dri_drivers="yes"
1610     else
1611         with_dri_drivers="no"
1612     fi
1613 fi
1614 if test "x$with_dri_drivers" = xno; then
1615     with_dri_drivers=''
1616 fi
1617
1618 dnl If $with_dri_drivers is yes, drivers will be added through
1619 dnl platform checks. Set DEFINES and LIB_DEPS
1620 if test "x$enable_dri" = xyes; then
1621     # Platform specific settings and drivers to build
1622     case "$host_os" in
1623     linux*)
1624         if test "x$enable_dri3" = xyes; then
1625             DEFINES="$DEFINES -DHAVE_DRI3"
1626         fi
1627
1628         case "$host_cpu" in
1629         powerpc* | sparc*)
1630             # Build only the drivers for cards that exist on PowerPC/sparc
1631             if test "x$with_dri_drivers" = "xyes"; then
1632                 with_dri_drivers="r200 radeon swrast"
1633             fi
1634             ;;
1635         esac
1636         ;;
1637     cygwin*)
1638         if test "x$with_dri_drivers" = "xyes"; then
1639             with_dri_drivers="swrast"
1640         fi
1641         ;;
1642     darwin*)
1643         DEFINES="$DEFINES -DBUILDING_MESA"
1644         if test "x$with_dri_drivers" = "xyes"; then
1645             with_dri_drivers="swrast"
1646         fi
1647         ;;
1648     esac
1649
1650     # default drivers
1651     if test "x$with_dri_drivers" = "xyes"; then
1652         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1653     fi
1654
1655     # Check for expat
1656     PKG_CHECK_MODULES([EXPAT], [expat], [],
1657         # expat version 2.0 and earlier do not provide expat.pc
1658         [AC_CHECK_HEADER([expat.h],[],
1659                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1660          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1661                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1662          EXPAT_LIBS="-lexpat"])
1663
1664     # put all the necessary libs together
1665     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1666 fi
1667
1668 AC_SUBST([DRI_LIB_DEPS])
1669
1670 DRI_DIRS=''
1671 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1672 if test -n "$with_dri_drivers"; then
1673     if test "x$enable_opengl" != xyes; then
1674         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1675     fi
1676
1677     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1678     for driver in $dri_drivers; do
1679         DRI_DIRS="$DRI_DIRS $driver"
1680         case "x$driver" in
1681         xi915)
1682             require_libdrm "i915"
1683             HAVE_I915_DRI=yes;
1684             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1685             ;;
1686         xi965)
1687             require_libdrm "i965"
1688             HAVE_I965_DRI=yes;
1689             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1690             ;;
1691         xnouveau)
1692             require_libdrm "nouveau"
1693             HAVE_NOUVEAU_DRI=yes;
1694             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1695             ;;
1696         xradeon)
1697             require_libdrm "radeon"
1698             HAVE_RADEON_DRI=yes;
1699             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1700             ;;
1701         xr200)
1702             require_libdrm "r200"
1703             HAVE_R200_DRI=yes;
1704             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1705             ;;
1706         xswrast)
1707             HAVE_SWRAST_DRI=yes;
1708             ;;
1709         *)
1710             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1711             ;;
1712         esac
1713     done
1714     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1715 fi
1716
1717
1718 dnl
1719 dnl Gallium LLVM
1720 dnl Deprecated: kept for backwards compatibility
1721 dnl
1722 AC_ARG_ENABLE([gallium-llvm],
1723     [AS_HELP_STRING([--enable-gallium-llvm],
1724         [DEPRECATED: use --enable-llvm instead])],
1725     [enable_gallium_llvm="$enableval"],
1726     [enable_gallium_llvm=auto])
1727
1728 if test "x$enable_gallium_llvm" != xauto; then
1729    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1730    enable_llvm=$enable_gallium_llvm
1731 fi
1732
1733 dnl
1734 dnl LLVM
1735 dnl
1736 AC_ARG_ENABLE([llvm],
1737     [AS_HELP_STRING([--enable-llvm],
1738         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1739     [enable_llvm="$enableval"],
1740     [enable_llvm=auto])
1741
1742 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1743     if test "x$FOUND_LLVM" = xyes; then
1744         case "$host_cpu" in
1745         i*86|x86_64|amd64) enable_llvm=yes;;
1746         *) enable_llvm=no;;
1747         esac
1748     else
1749         enable_llvm=no
1750     fi
1751 fi
1752
1753 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1754     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1755 fi
1756
1757 #
1758 # Vulkan driver configuration
1759 #
1760
1761 AC_ARG_WITH([vulkan-drivers],
1762     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1763         [comma delimited Vulkan drivers list, e.g.
1764         "intel,radeon"
1765         @<:@default=no@:>@])],
1766     [with_vulkan_drivers="$withval"],
1767     [with_vulkan_drivers="no"])
1768
1769 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1770 # here so that the script doesn't choke on an unknown driver name later.
1771 case "x$with_vulkan_drivers" in
1772     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1773     xno) with_vulkan_drivers='' ;;
1774 esac
1775
1776 AC_ARG_WITH([vulkan-icddir],
1777     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1778         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1779     [VULKAN_ICD_INSTALL_DIR="$withval"],
1780     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1781 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1782
1783 if test -n "$with_vulkan_drivers"; then
1784     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1785     for driver in $VULKAN_DRIVERS; do
1786         case "x$driver" in
1787         xintel)
1788             if test "x$HAVE_I965_DRI" != xyes; then
1789                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1790             fi
1791             HAVE_INTEL_VULKAN=yes;
1792
1793             ;;
1794         xradeon)
1795             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1796             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1797             HAVE_RADEON_VULKAN=yes;
1798             ;;
1799         *)
1800             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1801             ;;
1802         esac
1803     done
1804     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1805 fi
1806
1807
1808 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1809 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1810 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1811                                   "x$enable_osmesa" = xyes -o \
1812                                   -n "$DRI_DIRS")
1813
1814 dnl
1815 dnl OSMesa configuration
1816 dnl
1817
1818 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1819 AC_ARG_WITH([osmesa-bits],
1820     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1821         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1822     [osmesa_bits="$withval"],
1823     [osmesa_bits=8])
1824 if test "x$osmesa_bits" != x8; then
1825     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1826         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1827         osmesa_bits=8
1828     fi
1829 fi
1830 case "x$osmesa_bits" in
1831 x8)
1832     OSMESA_LIB="${OSMESA_LIB}"
1833     ;;
1834 x16|x32)
1835     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1836     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1837     ;;
1838 *)
1839     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1840     ;;
1841 esac
1842
1843 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1844     # only link libraries with osmesa if shared
1845     if test "$enable_static" = no; then
1846         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1847     else
1848         OSMESA_LIB_DEPS=""
1849     fi
1850     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1851 fi
1852
1853 AC_SUBST([OSMESA_LIB_DEPS])
1854 AC_SUBST([OSMESA_PC_REQ])
1855 AC_SUBST([OSMESA_PC_LIB_PRIV])
1856
1857 dnl
1858 dnl gbm configuration
1859 dnl
1860 if test "x$enable_gbm" = xyes; then
1861     require_dri_shared_libs_and_glapi "gbm"
1862 fi
1863 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1864 # FINISHME: GBM has a number of dependencies which we should add below
1865 GBM_PC_REQ_PRIV=""
1866 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1867 AC_SUBST([GBM_PC_REQ_PRIV])
1868 AC_SUBST([GBM_PC_LIB_PRIV])
1869
1870 dnl
1871 dnl EGL configuration
1872 dnl
1873
1874 if test "x$enable_egl" = xyes; then
1875     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1876
1877     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1878
1879     require_dri_shared_libs_and_glapi "egl"
1880 fi
1881 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1882 AC_SUBST([EGL_LIB_DEPS])
1883
1884 gallium_st="mesa"
1885
1886 dnl
1887 dnl XA configuration
1888 dnl
1889 if test "x$enable_xa" = xyes; then
1890     if test "x$with_gallium_drivers" = xswrast; then
1891        AC_MSG_ERROR([
1892           Building xa requires at least one non swrast gallium driver.
1893           If you are looking to use libxatracker.so with the VMware driver,
1894           make sure to include svga in the gallium drivers list, apart from
1895           enabling XA.
1896           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1897     fi
1898     gallium_st="$gallium_st xa"
1899 fi
1900 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1901
1902 dnl
1903 dnl Gallium G3DVL configuration
1904 dnl
1905 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1906     if test "x$enable_xvmc" = xauto; then
1907         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1908     fi
1909
1910     if test "x$enable_vdpau" = xauto; then
1911         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1912     fi
1913
1914     if test "x$enable_omx" = xauto; then
1915         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1916     fi
1917
1918     if test "x$enable_va" = xauto; then
1919         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1920     fi
1921 fi
1922
1923 if test "x$enable_dri" = xyes -o \
1924         "x$enable_xvmc" = xyes -o \
1925         "x$enable_vdpau" = xyes -o \
1926         "x$enable_omx" = xyes -o \
1927         "x$enable_va" = xyes; then
1928     need_gallium_vl=yes
1929 fi
1930 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1931
1932 if test "x$enable_xvmc" = xyes -o \
1933         "x$enable_vdpau" = xyes -o \
1934         "x$enable_omx" = xyes -o \
1935         "x$enable_va" = xyes; then
1936     if test x"$enable_dri3" = xyes; then
1937         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1938                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1939     else
1940         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1941     fi
1942     need_gallium_vl_winsys=yes
1943 fi
1944 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1945
1946 if test "x$enable_xvmc" = xyes; then
1947     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1948     gallium_st="$gallium_st xvmc"
1949 fi
1950 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1951
1952 if test "x$enable_vdpau" = xyes; then
1953     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1954     gallium_st="$gallium_st vdpau"
1955     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1956 fi
1957 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1958
1959 if test "x$enable_omx" = xyes; then
1960     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1961     gallium_st="$gallium_st omx"
1962 fi
1963 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1964
1965 if test "x$enable_va" = xyes; then
1966     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1967     gallium_st="$gallium_st va"
1968 fi
1969 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1970
1971 dnl
1972 dnl Nine Direct3D9 configuration
1973 dnl
1974 if test "x$enable_nine" = xyes; then
1975     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1976         AC_MSG_ERROR([nine requires the gallium swrast driver])
1977     fi
1978     if test "x$with_gallium_drivers" = xswrast; then
1979         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1980     fi
1981     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1982         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1983     fi
1984
1985     if test "x$enable_dri3" = xno; then
1986         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1987     fi
1988
1989     gallium_st="$gallium_st nine"
1990 fi
1991 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1992
1993 dnl
1994 dnl OpenCL configuration
1995 dnl
1996
1997 AC_ARG_WITH([clang-libdir],
1998    [AS_HELP_STRING([--with-clang-libdir],
1999          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2000    [CLANG_LIBDIR="$withval"],
2001    [CLANG_LIBDIR=''])
2002
2003 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2004
2005 if test "x$enable_opencl" = xyes; then
2006     if test -z "$with_gallium_drivers"; then
2007         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2008     fi
2009
2010     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2011         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2012     fi
2013
2014     if test "x$have_libclc" = xno; then
2015         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2016                     Make sure the directory containing libclc.pc is specified in your
2017                     PKG_CONFIG_PATH environment variable.
2018                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2019     else
2020         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2021         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2022         AC_SUBST([LIBCLC_INCLUDEDIR])
2023         AC_SUBST([LIBCLC_LIBEXECDIR])
2024     fi
2025
2026     gallium_st="$gallium_st clover"
2027
2028     if test "x$enable_opencl_icd" = xyes; then
2029         OPENCL_LIBNAME="MesaOpenCL"
2030     else
2031         OPENCL_LIBNAME="OpenCL"
2032     fi
2033
2034     if test "x$have_libelf" != xyes; then
2035        AC_MSG_ERROR([Clover requires libelf])
2036     fi
2037
2038     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2039
2040     llvm_add_default_components "opencl"
2041     llvm_add_component "all-targets" "opencl"
2042     llvm_add_component "linker" "opencl"
2043     llvm_add_component "instrumentation" "opencl"
2044     llvm_add_component "ipo" "opencl"
2045     llvm_add_component "irreader" "opencl"
2046     llvm_add_component "option" "opencl"
2047     llvm_add_component "objcarcopts" "opencl"
2048     llvm_add_component "profiledata" "opencl"
2049
2050     dnl Check for Clang internal headers
2051     if test -z "$CLANG_LIBDIR"; then
2052         CLANG_LIBDIR=${LLVM_LIBDIR}
2053     fi
2054     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2055     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2056         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2057 fi
2058 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2059 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2060 AC_SUBST([OPENCL_LIBNAME])
2061 AC_SUBST([CLANG_RESOURCE_DIR])
2062
2063 dnl
2064 dnl Gallium configuration
2065 dnl
2066 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2067
2068 dnl
2069 dnl EGL Platforms configuration
2070 dnl
2071 AC_ARG_WITH([egl-platforms],
2072     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2073         [comma delimited native platforms libEGL supports, e.g.
2074         "x11,drm" @<:@default=auto@:>@])],
2075     [with_egl_platforms="$withval"],
2076     [if test "x$enable_egl" = xyes; then
2077         if test "x$enable_gbm" = xyes; then
2078            with_egl_platforms="x11,drm"
2079         else
2080            with_egl_platforms="x11"
2081         fi
2082     else
2083         with_egl_platforms=""
2084     fi])
2085
2086 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2087     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2088 fi
2089
2090 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2091         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2092         WAYLAND_SCANNER='')
2093 if test "x$WAYLAND_SCANNER" = x; then
2094     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2095 fi
2096
2097 # Do per-EGL platform setups and checks
2098 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2099 for plat in $egl_platforms; do
2100         case "$plat" in
2101         wayland)
2102
2103                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2104
2105                 if test "x$WAYLAND_SCANNER" = x; then
2106                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2107                 fi
2108                 ;;
2109
2110         x11)
2111                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2112                 ;;
2113
2114         drm)
2115                 test "x$enable_gbm" = "xno" &&
2116                         AC_MSG_ERROR([EGL platform drm needs gbm])
2117                 ;;
2118
2119         surfaceless)
2120                 ;;
2121
2122         android)
2123                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2124                 ;;
2125
2126         *)
2127                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2128                 ;;
2129         esac
2130
2131         case "$plat" in
2132         wayland|drm|surfaceless)
2133                 require_libdrm "Platform $plat"
2134                 ;;
2135         esac
2136 done
2137
2138 # libEGL wants to default to the first platform specified in
2139 # ./configure.  parse that here.
2140 if test "x$egl_platforms" != "x"; then
2141     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2142     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2143 else
2144     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2145 fi
2146
2147 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2148 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2149 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2150 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2151 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2152
2153 AC_SUBST([EGL_NATIVE_PLATFORM])
2154 AC_SUBST([EGL_CFLAGS])
2155
2156 # If we don't have the X11 platform, set this define so we don't try to include
2157 # the X11 headers.
2158 if ! echo "$egl_platforms" | grep -q 'x11'; then
2159     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2160     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2161 fi
2162
2163 dnl Directory for XVMC libs
2164 AC_ARG_WITH([xvmc-libdir],
2165     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2166         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2167     [XVMC_LIB_INSTALL_DIR="$withval"],
2168     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2169 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2170
2171 dnl
2172 dnl Gallium Tests
2173 dnl
2174 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2175
2176 dnl Directory for VDPAU libs
2177 AC_ARG_WITH([vdpau-libdir],
2178     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2179         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2180     [VDPAU_LIB_INSTALL_DIR="$withval"],
2181     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2182 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2183
2184 dnl Directory for OMX libs
2185
2186 AC_ARG_WITH([omx-libdir],
2187     [AS_HELP_STRING([--with-omx-libdir=DIR],
2188         [directory for the OMX libraries])],
2189     [OMX_LIB_INSTALL_DIR="$withval"],
2190     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2191 AC_SUBST([OMX_LIB_INSTALL_DIR])
2192
2193 dnl Directory for VA libs
2194
2195 AC_ARG_WITH([va-libdir],
2196     [AS_HELP_STRING([--with-va-libdir=DIR],
2197         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2198     [VA_LIB_INSTALL_DIR="$withval"],
2199     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2200 AC_SUBST([VA_LIB_INSTALL_DIR])
2201
2202 AC_ARG_WITH([d3d-libdir],
2203     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2204         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2205     [D3D_DRIVER_INSTALL_DIR="$withval"],
2206     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2207 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2208
2209 dnl
2210 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2211 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2212 dnl architectures.
2213 dnl
2214 r300_require_llvm() {
2215     case "$host" in *gnux32) return;; esac
2216     case "$host_cpu" in
2217     i*86|x86_64|amd64) require_llvm $1
2218         ;;
2219     esac
2220 }
2221
2222 dnl
2223 dnl DRM is needed by X, Wayland, and offscreen rendering.
2224 dnl Surfaceless is an alternative for the last one.
2225 dnl
2226 require_basic_egl() {
2227     case "$with_egl_platforms" in
2228         *drm*|*surfaceless*)
2229             ;;
2230         *)
2231             AC_MSG_ERROR([$1 requires one of these:
2232                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2233                   2) --with-egl-platforms=surfaceless (offscreen only)
2234                   Recommended options: drm,x11])
2235             ;;
2236     esac
2237 }
2238
2239 swr_require_cxx_feature_flags() {
2240     feature_name="$1"
2241     preprocessor_test="$2"
2242     option_list="$3"
2243     output_var="$4"
2244
2245     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2246     AC_LANG_PUSH([C++])
2247     save_CXXFLAGS="$CXXFLAGS"
2248     save_IFS="$IFS"
2249     IFS=","
2250     found=0
2251     for opts in $option_list
2252     do
2253         unset IFS
2254         CXXFLAGS="$opts $save_CXXFLAGS"
2255         AC_COMPILE_IFELSE(
2256             [AC_LANG_PROGRAM(
2257                 [   #if !($preprocessor_test)
2258                     #error
2259                     #endif
2260                 ])],
2261             [found=1; break],
2262             [])
2263         IFS=","
2264     done
2265     IFS="$save_IFS"
2266     CXXFLAGS="$save_CXXFLAGS"
2267     AC_LANG_POP([C++])
2268     if test $found -eq 1; then
2269         AC_MSG_RESULT([$opts])
2270         eval "$output_var=\$opts"
2271         return 0
2272     fi
2273     AC_MSG_RESULT([no])
2274     AC_MSG_ERROR([swr requires $feature_name support])
2275     return 1
2276 }
2277
2278 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2279 if test -n "$with_gallium_drivers"; then
2280     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2281     for driver in $gallium_drivers; do
2282         case "x$driver" in
2283         xsvga)
2284             HAVE_GALLIUM_SVGA=yes
2285             require_libdrm "svga"
2286             ;;
2287         xi915)
2288             HAVE_GALLIUM_I915=yes
2289             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2290             require_libdrm "Gallium i915"
2291             ;;
2292         xr300)
2293             HAVE_GALLIUM_R300=yes
2294             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2295             require_libdrm "r300"
2296             r300_require_llvm "r300"
2297             ;;
2298         xr600)
2299             HAVE_GALLIUM_R600=yes
2300             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2301             require_libdrm "r600"
2302             if test "x$enable_opencl" = xyes; then
2303                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2304
2305                 llvm_add_component "asmparser" "r600"
2306                 llvm_add_component "bitreader" "r600"
2307             fi
2308             ;;
2309         xradeonsi)
2310             HAVE_GALLIUM_RADEONSI=yes
2311             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2312             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2313             require_libdrm "radeonsi"
2314             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2315             require_basic_egl "radeonsi"
2316             ;;
2317         xnouveau)
2318             HAVE_GALLIUM_NOUVEAU=yes
2319             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2320             require_libdrm "nouveau"
2321             ;;
2322         xfreedreno)
2323             HAVE_GALLIUM_FREEDRENO=yes
2324             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2325             require_libdrm "freedreno"
2326             ;;
2327         xetnaviv)
2328             HAVE_GALLIUM_ETNAVIV=yes
2329             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2330             require_libdrm "etnaviv"
2331             ;;
2332        ximx)
2333             HAVE_GALLIUM_IMX=yes
2334             ;;
2335         xswrast)
2336             HAVE_GALLIUM_SOFTPIPE=yes
2337             if test "x$enable_llvm" = xyes; then
2338                 HAVE_GALLIUM_LLVMPIPE=yes
2339             fi
2340             ;;
2341         xswr)
2342             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2343
2344             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2345                 ",-std=c++11" \
2346                 SWR_CXX11_CXXFLAGS
2347             AC_SUBST([SWR_CXX11_CXXFLAGS])
2348
2349             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2350                 ",-mavx,-march=core-avx" \
2351                 SWR_AVX_CXXFLAGS
2352             AC_SUBST([SWR_AVX_CXXFLAGS])
2353
2354             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2355                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2356                 SWR_AVX2_CXXFLAGS
2357             AC_SUBST([SWR_AVX2_CXXFLAGS])
2358
2359             HAVE_GALLIUM_SWR=yes
2360             ;;
2361         xvc4)
2362             HAVE_GALLIUM_VC4=yes
2363             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2364             require_libdrm "vc4"
2365
2366             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2367                               [USE_VC4_SIMULATOR=yes;
2368                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2369                               [USE_VC4_SIMULATOR=no])
2370             ;;
2371         xvirgl)
2372             HAVE_GALLIUM_VIRGL=yes
2373             require_libdrm "virgl"
2374             require_basic_egl "virgl"
2375             ;;
2376         *)
2377             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2378             ;;
2379         esac
2380     done
2381 fi
2382
2383 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2384     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2385     llvm_add_default_components "gallium"
2386 fi
2387
2388 dnl We need to validate some needed dependencies for renderonly drivers.
2389
2390 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2391     AC_ERROR([Building with imx requires etnaviv])
2392 fi
2393
2394 dnl
2395 dnl Set defines and buildtime variables only when using LLVM.
2396 dnl
2397 if test "x$enable_llvm" = xyes; then
2398     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2399
2400     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2401     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2402     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2403
2404     dnl Set LLVM_LIBS - This is done after the driver configuration so
2405     dnl that drivers can add additional components to LLVM_COMPONENTS.
2406     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2407     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2408     dnl this was causing the same libraries to be appear multiple times
2409     dnl in LLVM_LIBS.
2410
2411     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2412        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2413     fi
2414     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2415
2416     dnl llvm-config may not give the right answer when llvm is a built as a
2417     dnl single shared library, so we must work the library name out for
2418     dnl ourselves.
2419     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2420     if test "x$enable_llvm_shared_libs" = xyes; then
2421         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2422         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2423         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2424
2425         if test "x$llvm_have_one_so" = xyes; then
2426             dnl LLVM was built using auto*, so there is only one shared object.
2427             LLVM_LIBS="-l$LLVM_SO_NAME"
2428         else
2429             dnl If LLVM was built with CMake, there will be one shared object per
2430             dnl component.
2431             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2432                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2433         Please make sure you have built llvm with the --enable-shared option
2434         and that your llvm libraries are installed in $LLVM_LIBDIR
2435         If you have installed your llvm libraries to a different directory you
2436         can use the --with-llvm-prefix= configure flag to specify this directory.
2437         NOTE: Mesa is attempting to use llvm shared libraries by default.
2438         If you do not want to build with llvm shared libraries and instead want to
2439         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2440         invocation and rebuild.])])
2441
2442            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2443            dnl install uses a shared object for each component and we have
2444            dnl already added all of these objects to LLVM_LIBS.
2445         fi
2446     else
2447         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2448         dnl We need to link to llvm system libs when using static libs
2449         dnl However, only llvm 3.5+ provides --system-libs
2450         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2451             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2452         fi
2453     fi
2454 fi
2455
2456 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2457 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2458 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2460 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2461 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2462                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2463 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2464 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2465 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2467 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2468 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2469 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2470 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2471                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2472                                          "x$HAVE_GALLIUM_SWR" = xyes)
2473 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2474 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2475
2476 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2477
2478 if test "x$enable_dri" = xyes; then
2479     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2480 fi
2481
2482 if test "x$have_drisw_kms" = xyes; then
2483     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2484 fi
2485 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2486
2487 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2488 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2489 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2490 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2491 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2492 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2493
2494 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2495 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2496
2497 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2498                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2499                                       "x$HAVE_RADEON_VULKAN" = xyes)
2500
2501 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2502                                         "x$HAVE_I965_DRI" = xyes)
2503
2504 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2505                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2506                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2507 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2508 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2509 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2510 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2511 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2512
2513 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2514 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2515 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2516 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2517                                         "x$enable_gallium_osmesa" = xyes)
2518
2519 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2520 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2521 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2522
2523 AC_SUBST([NINE_MAJOR], 1)
2524 AC_SUBST([NINE_MINOR], 0)
2525 AC_SUBST([NINE_TINY], 0)
2526 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2527
2528 AC_SUBST([VDPAU_MAJOR], 1)
2529 AC_SUBST([VDPAU_MINOR], 0)
2530
2531 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2532 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2533 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2534 AC_SUBST([VA_MINOR], $VA_MINOR)
2535
2536 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2537
2538 AC_SUBST([XVMC_MAJOR], 1)
2539 AC_SUBST([XVMC_MINOR], 0)
2540
2541 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2542 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2543 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2544 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2545
2546 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2547 AC_SUBST([XA_MINOR], $XA_MINOR)
2548 AC_SUBST([XA_TINY], $XA_TINY)
2549 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2550
2551 AC_ARG_ENABLE(valgrind,
2552               [AS_HELP_STRING([--enable-valgrind],
2553                              [Build mesa with valgrind support (default: auto)])],
2554                              [VALGRIND=$enableval], [VALGRIND=auto])
2555 if test "x$VALGRIND" != xno; then
2556         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2557 fi
2558 AC_MSG_CHECKING([whether to enable Valgrind support])
2559 if test "x$VALGRIND" = xauto; then
2560         VALGRIND="$have_valgrind"
2561 fi
2562
2563 if test "x$VALGRIND" = "xyes"; then
2564         if ! test "x$have_valgrind" = xyes; then
2565                 AC_MSG_ERROR([Valgrind support required but not present])
2566         fi
2567         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2568 fi
2569
2570 AC_MSG_RESULT([$VALGRIND])
2571
2572 dnl Restore LDFLAGS and CPPFLAGS
2573 LDFLAGS="$_SAVE_LDFLAGS"
2574 CPPFLAGS="$_SAVE_CPPFLAGS"
2575
2576 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2577 if test "x$acv_mesa_CLANG" = xyes; then
2578     CFLAGS="$CFLAGS -Qunused-arguments"
2579     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2580 fi
2581
2582 dnl Add user CFLAGS and CXXFLAGS
2583 CFLAGS="$CFLAGS $USER_CFLAGS"
2584 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2585
2586 dnl Substitute the config
2587 AC_CONFIG_FILES([Makefile
2588                 src/Makefile
2589                 src/amd/Makefile
2590                 src/amd/vulkan/Makefile
2591                 src/compiler/Makefile
2592                 src/egl/Makefile
2593                 src/egl/main/egl.pc
2594                 src/egl/wayland/wayland-drm/Makefile
2595                 src/egl/wayland/wayland-egl/Makefile
2596                 src/egl/wayland/wayland-egl/wayland-egl.pc
2597                 src/gallium/Makefile
2598                 src/gallium/auxiliary/Makefile
2599                 src/gallium/auxiliary/pipe-loader/Makefile
2600                 src/gallium/drivers/freedreno/Makefile
2601                 src/gallium/drivers/ddebug/Makefile
2602                 src/gallium/drivers/i915/Makefile
2603                 src/gallium/drivers/llvmpipe/Makefile
2604                 src/gallium/drivers/noop/Makefile
2605                 src/gallium/drivers/nouveau/Makefile
2606                 src/gallium/drivers/r300/Makefile
2607                 src/gallium/drivers/r600/Makefile
2608                 src/gallium/drivers/radeon/Makefile
2609                 src/gallium/drivers/radeonsi/Makefile
2610                 src/gallium/drivers/rbug/Makefile
2611                 src/gallium/drivers/softpipe/Makefile
2612                 src/gallium/drivers/svga/Makefile
2613                 src/gallium/drivers/swr/Makefile
2614                 src/gallium/drivers/trace/Makefile
2615                 src/gallium/drivers/etnaviv/Makefile
2616                 src/gallium/drivers/imx/Makefile
2617                 src/gallium/drivers/vc4/Makefile
2618                 src/gallium/drivers/virgl/Makefile
2619                 src/gallium/state_trackers/clover/Makefile
2620                 src/gallium/state_trackers/dri/Makefile
2621                 src/gallium/state_trackers/glx/xlib/Makefile
2622                 src/gallium/state_trackers/nine/Makefile
2623                 src/gallium/state_trackers/omx/Makefile
2624                 src/gallium/state_trackers/osmesa/Makefile
2625                 src/gallium/state_trackers/va/Makefile
2626                 src/gallium/state_trackers/vdpau/Makefile
2627                 src/gallium/state_trackers/xa/Makefile
2628                 src/gallium/state_trackers/xvmc/Makefile
2629                 src/gallium/targets/d3dadapter9/Makefile
2630                 src/gallium/targets/d3dadapter9/d3d.pc
2631                 src/gallium/targets/dri/Makefile
2632                 src/gallium/targets/libgl-xlib/Makefile
2633                 src/gallium/targets/omx/Makefile
2634                 src/gallium/targets/opencl/Makefile
2635                 src/gallium/targets/opencl/mesa.icd
2636                 src/gallium/targets/osmesa/Makefile
2637                 src/gallium/targets/osmesa/osmesa.pc
2638                 src/gallium/targets/pipe-loader/Makefile
2639                 src/gallium/targets/va/Makefile
2640                 src/gallium/targets/vdpau/Makefile
2641                 src/gallium/targets/xa/Makefile
2642                 src/gallium/targets/xa/xatracker.pc
2643                 src/gallium/targets/xvmc/Makefile
2644                 src/gallium/tests/trivial/Makefile
2645                 src/gallium/tests/unit/Makefile
2646                 src/gallium/winsys/etnaviv/drm/Makefile
2647                 src/gallium/winsys/imx/drm/Makefile
2648                 src/gallium/winsys/freedreno/drm/Makefile
2649                 src/gallium/winsys/i915/drm/Makefile
2650                 src/gallium/winsys/nouveau/drm/Makefile
2651                 src/gallium/winsys/radeon/drm/Makefile
2652                 src/gallium/winsys/amdgpu/drm/Makefile
2653                 src/gallium/winsys/svga/drm/Makefile
2654                 src/gallium/winsys/sw/dri/Makefile
2655                 src/gallium/winsys/sw/kms-dri/Makefile
2656                 src/gallium/winsys/sw/null/Makefile
2657                 src/gallium/winsys/sw/wrapper/Makefile
2658                 src/gallium/winsys/sw/xlib/Makefile
2659                 src/gallium/winsys/vc4/drm/Makefile
2660                 src/gallium/winsys/virgl/drm/Makefile
2661                 src/gallium/winsys/virgl/vtest/Makefile
2662                 src/gbm/Makefile
2663                 src/gbm/main/gbm.pc
2664                 src/glx/Makefile
2665                 src/glx/apple/Makefile
2666                 src/glx/tests/Makefile
2667                 src/glx/windows/Makefile
2668                 src/glx/windows/windowsdriproto.pc
2669                 src/gtest/Makefile
2670                 src/intel/Makefile
2671                 src/intel/tools/Makefile
2672                 src/intel/vulkan/Makefile
2673                 src/loader/Makefile
2674                 src/mapi/Makefile
2675                 src/mapi/es1api/glesv1_cm.pc
2676                 src/mapi/es2api/glesv2.pc
2677                 src/mapi/glapi/gen/Makefile
2678                 src/mesa/Makefile
2679                 src/mesa/gl.pc
2680                 src/mesa/drivers/dri/dri.pc
2681                 src/mesa/drivers/dri/common/Makefile
2682                 src/mesa/drivers/dri/common/xmlpool/Makefile
2683                 src/mesa/drivers/dri/i915/Makefile
2684                 src/mesa/drivers/dri/i965/Makefile
2685                 src/mesa/drivers/dri/Makefile
2686                 src/mesa/drivers/dri/nouveau/Makefile
2687                 src/mesa/drivers/dri/r200/Makefile
2688                 src/mesa/drivers/dri/radeon/Makefile
2689                 src/mesa/drivers/dri/swrast/Makefile
2690                 src/mesa/drivers/osmesa/Makefile
2691                 src/mesa/drivers/osmesa/osmesa.pc
2692                 src/mesa/drivers/x11/Makefile
2693                 src/mesa/main/tests/Makefile
2694                 src/util/Makefile
2695                 src/util/tests/hash_table/Makefile
2696                 src/vulkan/wsi/Makefile])
2697
2698 AC_OUTPUT
2699
2700 # Fix up dependencies in *.Plo files, where we changed the extension of a
2701 # source file
2702 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2703
2704
2705 dnl
2706 dnl Output some configuration info for the user
2707 dnl
2708 echo ""
2709 echo "        prefix:          $prefix"
2710 echo "        exec_prefix:     $exec_prefix"
2711 echo "        libdir:          $libdir"
2712 echo "        includedir:      $includedir"
2713
2714 dnl API info
2715 echo ""
2716 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2717
2718 dnl Driver info
2719 echo ""
2720 case "x$enable_osmesa$enable_gallium_osmesa" in
2721 xnoyes)
2722         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2723         ;;
2724 xyesno)
2725         echo "        OSMesa:          lib$OSMESA_LIB"
2726         ;;
2727 xnono)
2728         echo "        OSMesa:          no"
2729         ;;
2730 esac
2731
2732 echo ""
2733 if test "x$enable_dri" != xno; then
2734         echo "        DRI platform:    $dri_platform"
2735         if test -z "$DRI_DIRS"; then
2736             echo "        DRI drivers:     no"
2737         else
2738             echo "        DRI drivers:     $DRI_DIRS"
2739         fi
2740         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2741 fi
2742
2743 case "x$enable_glx" in
2744 xdri)
2745     echo "        GLX:             DRI-based"
2746     ;;
2747 xxlib)
2748     echo "        GLX:             Xlib-based"
2749     ;;
2750 xgallium-xlib)
2751     echo "        GLX:             Xlib-based (Gallium)"
2752     ;;
2753 *)
2754     echo "        GLX:             $enable_glx"
2755     ;;
2756 esac
2757
2758 dnl EGL
2759 echo ""
2760 echo "        EGL:             $enable_egl"
2761 if test "$enable_egl" = yes; then
2762     echo "        EGL platforms:   $egl_platforms"
2763
2764     egl_drivers=""
2765     if test "x$enable_dri" != "xno"; then
2766         egl_drivers="$egl_drivers builtin:egl_dri2"
2767     fi
2768     if test "x$enable_dri3" != "xno"; then
2769         egl_drivers="$egl_drivers builtin:egl_dri3"
2770     fi
2771
2772     echo "        EGL drivers:    $egl_drivers"
2773 fi
2774 if test "x$enable_gbm" = xyes; then
2775     echo "        GBM:             yes"
2776 else
2777     echo "        GBM:             no"
2778 fi
2779
2780 # Vulkan
2781 echo ""
2782 if test "x$VULKAN_DRIVERS" != x; then
2783     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2784     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2785 else
2786     echo "        Vulkan drivers:  no"
2787 fi
2788
2789 echo ""
2790 if test "x$enable_llvm" = xyes; then
2791     echo "        llvm:            yes"
2792     echo "        llvm-config:     $LLVM_CONFIG"
2793     echo "        llvm-version:    $LLVM_VERSION"
2794 else
2795     echo "        llvm:            no"
2796 fi
2797
2798 echo ""
2799 if test -n "$with_gallium_drivers"; then
2800     echo "        Gallium drivers: $gallium_drivers"
2801     echo "        Gallium st:      $gallium_st"
2802 else
2803     echo "        Gallium:         no"
2804 fi
2805
2806 echo ""
2807 if test "x$enable_gallium_extra_hud" != xyes; then
2808     echo "        HUD extra stats: no"
2809 else
2810     echo "        HUD extra stats: yes"
2811 fi
2812
2813 if test "x$enable_lmsensors" != xyes; then
2814     echo "        HUD lmsensors:   no"
2815 else
2816     echo "        HUD lmsensors:   yes"
2817 fi
2818
2819 dnl Libraries
2820 echo ""
2821 echo "        Shared libs:     $enable_shared"
2822 echo "        Static libs:     $enable_static"
2823 echo "        Shared-glapi:    $enable_shared_glapi"
2824
2825 dnl Compiler options
2826 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2827 cflags=`echo $CFLAGS | \
2828     $SED 's/^ *//;s/  */ /;s/ *$//'`
2829 cxxflags=`echo $CXXFLAGS | \
2830     $SED 's/^ *//;s/  */ /;s/ *$//'`
2831 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2832 echo ""
2833 echo "        CFLAGS:          $cflags"
2834 echo "        CXXFLAGS:        $cxxflags"
2835 echo "        Macros:          $defines"
2836 echo ""
2837 if test "x$enable_llvm" = xyes; then
2838     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2839     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2840     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2841     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2842     echo ""
2843 fi
2844 echo "        PYTHON2:         $PYTHON2"
2845
2846 echo ""
2847 echo "        Run '${MAKE-make}' to build Mesa"
2848 echo ""