configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.23
  22 LIBDRM_RADEON_REQUIRED=2.4.23
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.23
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 320
 321 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 331 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 332
 333 AC_SUBST([GL_LIB_NAME])
 334 AC_SUBST([GLU_LIB_NAME])
 335 AC_SUBST([GLUT_LIB_NAME])
 336 AC_SUBST([GLW_LIB_NAME])
 337 AC_SUBST([OSMESA_LIB_NAME])
 338 AC_SUBST([EGL_LIB_NAME])
 339 AC_SUBST([GLESv1_CM_LIB_NAME])
 340 AC_SUBST([GLESv2_LIB_NAME])
 341 AC_SUBST([VG_LIB_NAME])
 342 AC_SUBST([GLAPI_LIB_NAME])
 343
 344 AC_SUBST([GL_LIB_GLOB])
 345 AC_SUBST([GLU_LIB_GLOB])
 346 AC_SUBST([GLUT_LIB_GLOB])
 347 AC_SUBST([GLW_LIB_GLOB])
 348 AC_SUBST([OSMESA_LIB_GLOB])
 349 AC_SUBST([EGL_LIB_GLOB])
 350 AC_SUBST([GLESv1_CM_LIB_GLOB])
 351 AC_SUBST([GLESv2_LIB_GLOB])
 352 AC_SUBST([VG_LIB_GLOB])
 353 AC_SUBST([GLAPI_LIB_GLOB])
 354
 355 dnl
 356 dnl Arch/platform-specific settings
 357 dnl
 358 AC_ARG_ENABLE([asm],
 359     [AS_HELP_STRING([--disable-asm],
 360         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 361     [enable_asm="$enableval"],
 362     [enable_asm=yes]
 363 )
 364 asm_arch=""
 365 ASM_FLAGS=""
 366 MESA_ASM_SOURCES=""
 367 GLAPI_ASM_SOURCES=""
 368 AC_MSG_CHECKING([whether to enable assembly])
 369 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 370 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 371 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 372     case "$host_cpu" in
 373     i?86 | x86_64)
 374         enable_asm=no
 375         AC_MSG_RESULT([no, cross compiling])
 376         ;;
 377     esac
 378 fi
 379 # check for supported arches
 380 if test "x$enable_asm" = xyes; then
 381     case "$host_cpu" in
 382     i?86)
 383         case "$host_os" in
 384         linux* | *freebsd* | dragonfly* | *netbsd*)
 385             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 386             ;;
 387         esac
 388         ;;
 389     x86_64)
 390         case "$host_os" in
 391         linux* | *freebsd* | dragonfly* | *netbsd*)
 392             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 393             ;;
 394         esac
 395         ;;
 396     powerpc)
 397         case "$host_os" in
 398         linux*)
 399             asm_arch=ppc
 400             ;;
 401         esac
 402         ;;
 403     sparc*)
 404         case "$host_os" in
 405         linux*)
 406             asm_arch=sparc
 407             ;;
 408         esac
 409         ;;
 410     esac
 411
 412     case "$asm_arch" in
 413     x86)
 414         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 415         MESA_ASM_SOURCES='$(X86_SOURCES)'
 416         GLAPI_ASM_SOURCES='$(X86_API)'
 417         AC_MSG_RESULT([yes, x86])
 418         ;;
 419     x86_64)
 420         ASM_FLAGS="-DUSE_X86_64_ASM"
 421         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 422         GLAPI_ASM_SOURCES='$(X86-64_API)'
 423         AC_MSG_RESULT([yes, x86_64])
 424         ;;
 425     ppc)
 426         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 427         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 428         AC_MSG_RESULT([yes, ppc])
 429         ;;
 430     sparc)
 431         ASM_FLAGS="-DUSE_SPARC_ASM"
 432         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 433         GLAPI_ASM_SOURCES='$(SPARC_API)'
 434         AC_MSG_RESULT([yes, sparc])
 435         ;;
 436     *)
 437         AC_MSG_RESULT([no, platform not supported])
 438         ;;
 439     esac
 440 fi
 441 AC_SUBST([ASM_FLAGS])
 442 AC_SUBST([MESA_ASM_SOURCES])
 443 AC_SUBST([GLAPI_ASM_SOURCES])
 444
 445 dnl PIC code macro
 446 MESA_PIC_FLAGS
 447
 448 dnl Check to see if dlopen is in default libraries (like Solaris, which
 449 dnl has it in libc), or if libdl is needed to get it.
 450 AC_CHECK_FUNC([dlopen], [],
 451     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 452 AC_SUBST([DLOPEN_LIBS])
 453
 454 dnl See if posix_memalign is available
 455 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 456
 457 dnl SELinux awareness.
 458 AC_ARG_ENABLE([selinux],
 459     [AS_HELP_STRING([--enable-selinux],
 460         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 461     [MESA_SELINUX="$enableval"],
 462     [MESA_SELINUX=no])
 463 if test "x$enable_selinux" = "xyes"; then
 464     AC_CHECK_HEADER([selinux/selinux.h],[],
 465                     [AC_MSG_ERROR([SELinux headers not found])])
 466     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 467                  [AC_MSG_ERROR([SELinux library not found])])
 468     SELINUX_LIBS="-lselinux"
 469     DEFINES="$DEFINES -DMESA_SELINUX"
 470 fi
 471
 472 dnl Determine which APIs to support
 473 AC_ARG_ENABLE([opengl],
 474     [AS_HELP_STRING([--disable-opengl],
 475         [disable support for standard OpenGL API @<:@default=no@:>@])],
 476     [enable_opengl="$enableval"],
 477     [enable_opengl=yes])
 478 AC_ARG_ENABLE([gles1],
 479     [AS_HELP_STRING([--enable-gles1],
 480         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 481     [enable_gles1="$enableval"],
 482     [enable_gles1=no])
 483 AC_ARG_ENABLE([gles2],
 484     [AS_HELP_STRING([--enable-gles2],
 485         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 486     [enable_gles2="$enableval"],
 487     [enable_gles2=no])
 488 AC_ARG_ENABLE([gles-overlay],
 489     [AS_HELP_STRING([--enable-gles-overlay],
 490         [DEPRECATED.  Same as --enable-gles1 and --enable-gles2])],
 491     [enable_gles1="$enableval"; enable_gles2="$enableval"],
 492     [])
 493
 494 AC_ARG_ENABLE([openvg],
 495     [AS_HELP_STRING([--enable-openvg],
 496         [enable support for OpenVG API @<:@default=no@:>@])],
 497     [enable_openvg="$enableval"],
 498     [enable_openvg=no])
 499
 500 dnl smooth the transition; should be removed eventually
 501 if test "x$enable_openvg" = xno; then
 502     case "x$with_state_trackers" in
 503     x*vega*)
 504         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 505         enable_openvg=yes
 506         ;;
 507     esac
 508 fi
 509
 510 if test "x$enable_opengl" = xno -a \
 511         "x$enable_gles1" = xno -a \
 512         "x$enable_gles2" = xno -a \
 513         "x$enable_openvg" = xno; then
 514     AC_MSG_ERROR([at least one API should be enabled])
 515 fi
 516
 517 API_DEFINES=""
 518 if test "x$enable_opengl" = xno; then
 519     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 520 else
 521     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 522 fi
 523 if test "x$enable_gles1" = xyes; then
 524     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 525 fi
 526 if test "x$enable_gles2" = xyes; then
 527     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 528 fi
 529 AC_SUBST([API_DEFINES])
 530
 531 AC_ARG_ENABLE([shared-glapi],
 532     [AS_HELP_STRING([--enable-shared-glapi],
 533         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 534     [enable_shared_glapi="$enableval"],
 535     [enable_shared_glapi=no])
 536
 537 SHARED_GLAPI="0"
 538 if test "x$enable_shared_glapi" = xyes; then
 539     SHARED_GLAPI="1"
 540 fi
 541 AC_SUBST([SHARED_GLAPI])
 542
 543 dnl
 544 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 545 dnl More later: fbdev, ...
 546 dnl
 547 default_driver="xlib"
 548
 549 case "$host_os" in
 550 linux*)
 551     case "$host_cpu" in
 552     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 553     esac
 554     ;;
 555 *freebsd* | dragonfly* | *netbsd*)
 556     case "$host_cpu" in
 557     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 558     esac
 559     ;;
 560 esac
 561
 562 if test "x$enable_opengl" = xno; then
 563     default_driver="no"
 564 fi
 565
 566 AC_ARG_WITH([driver],
 567     [AS_HELP_STRING([--with-driver=DRIVER],
 568         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 569     [mesa_driver="$withval"],
 570     [mesa_driver="$default_driver"])
 571 dnl Check for valid option
 572 case "x$mesa_driver" in
 573 xxlib|xdri|xosmesa)
 574     if test "x$enable_opengl" = xno; then
 575         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 576     fi
 577     ;;
 578 xno)
 579     ;;
 580 *)
 581     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 582     ;;
 583 esac
 584
 585 PKG_CHECK_MODULES([TALLOC], [talloc])
 586 AC_SUBST([TALLOC_LIBS])
 587 AC_SUBST([TALLOC_CFLAGS])
 588
 589 dnl
 590 dnl Driver specific build directories
 591 dnl
 592
 593 dnl this variable will be prepended to SRC_DIRS and is not exported
 594 CORE_DIRS=""
 595
 596 SRC_DIRS=""
 597 GLU_DIRS="sgi"
 598 GALLIUM_DIRS="auxiliary drivers state_trackers"
 599 GALLIUM_TARGET_DIRS=""
 600 GALLIUM_WINSYS_DIRS="sw"
 601 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug noop identity"
 602 GALLIUM_STATE_TRACKERS_DIRS=""
 603
 604 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 605 case "x$enabled_shared_glapi$enable_gles1$enable_gles2" in
 606 x*yes*)
 607     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 608     ;;
 609 esac
 610
 611 # build glapi if OpenGL is enabled
 612 if test "x$enable_opengl" = xyes; then
 613     CORE_DIRS="$CORE_DIRS mapi/glapi"
 614 fi
 615
 616 # build es1api if OpenGL ES 1.x is enabled
 617 if test "x$enable_gles1" = xyes; then
 618     CORE_DIRS="$CORE_DIRS mapi/es1api"
 619 fi
 620
 621 # build es2api if OpenGL ES 2.x is enabled
 622 if test "x$enable_gles2" = xyes; then
 623     CORE_DIRS="$CORE_DIRS mapi/es2api"
 624 fi
 625
 626 # build vgapi if OpenVG is enabled
 627 if test "x$enable_openvg" = xyes; then
 628     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 629 fi
 630
 631 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 632 case "x$enable_opengl$enable_gles1$enable_gles2" in
 633 x*yes*)
 634     CORE_DIRS="$CORE_DIRS glsl mesa"
 635     ;;
 636 esac
 637
 638 case "$mesa_driver" in
 639 xlib)
 640     DRIVER_DIRS="x11"
 641     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 642     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 643     ;;
 644 dri)
 645     SRC_DIRS="$SRC_DIRS glx"
 646     DRIVER_DIRS="dri"
 647     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 648     ;;
 649 osmesa)
 650     DRIVER_DIRS="osmesa"
 651     ;;
 652 no)
 653     DRIVER_DRIS=""
 654     ;;
 655 esac
 656 AC_SUBST([SRC_DIRS])
 657 AC_SUBST([GLU_DIRS])
 658 AC_SUBST([DRIVER_DIRS])
 659 AC_SUBST([GALLIUM_DIRS])
 660 AC_SUBST([GALLIUM_TARGET_DIRS])
 661 AC_SUBST([GALLIUM_WINSYS_DIRS])
 662 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 663 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 664 AC_SUBST([MESA_LLVM])
 665
 666 dnl
 667 dnl Find out if X is available. The variable have_x is set if libX11 is
 668 dnl found to mimic AC_PATH_XTRA.
 669 dnl
 670 if test -n "$PKG_CONFIG"; then
 671     AC_MSG_CHECKING([pkg-config files for X11 are available])
 672     PKG_CHECK_EXISTS([x11],[
 673         x11_pkgconfig=yes
 674         have_x=yes
 675         ],[
 676         x11_pkgconfig=no
 677     ])
 678     AC_MSG_RESULT([$x11_pkgconfig])
 679 else
 680     x11_pkgconfig=no
 681 fi
 682 dnl Use the autoconf macro if no pkg-config files
 683 if test "$x11_pkgconfig" = yes; then
 684     PKG_CHECK_MODULES([X11], [x11])
 685 else
 686     AC_PATH_XTRA
 687     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 688     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 689     AC_SUBST([X11_CFLAGS])
 690     AC_SUBST([X11_LIBS])
 691 fi
 692
 693 dnl Try to tell the user that the --x-* options are only used when
 694 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 695 m4_divert_once([HELP_BEGIN],
 696 [These options are only used when the X libraries cannot be found by the
 697 pkg-config utility.])
 698
 699 dnl We need X for xlib and dri, so bomb now if it's not found
 700 case "$mesa_driver" in
 701 xlib|dri)
 702     if test "$no_x" = yes; then
 703         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 704     fi
 705     ;;
 706 esac
 707
 708 dnl XCB - this is only used for GLX right now
 709 AC_ARG_ENABLE([xcb],
 710     [AS_HELP_STRING([--enable-xcb],
 711         [use XCB for GLX @<:@default=disabled@:>@])],
 712     [enable_xcb="$enableval"],
 713     [enable_xcb=no])
 714 if test "x$enable_xcb" = xyes; then
 715     DEFINES="$DEFINES -DUSE_XCB"
 716 else
 717     enable_xcb=no
 718 fi
 719
 720 dnl
 721 dnl libGL configuration per driver
 722 dnl
 723 case "$mesa_driver" in
 724 xlib)
 725     if test "$x11_pkgconfig" = yes; then
 726         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 727         GL_PC_REQ_PRIV="x11 xext"
 728         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 729         GL_LIB_DEPS="$XLIBGL_LIBS"
 730     else
 731         # should check these...
 732         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 733         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 734         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 735         GL_PC_CFLAGS="$X11_INCLUDES"
 736     fi
 737     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 738     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 739
 740     # if static, move the external libraries to the programs
 741     # and empty the libraries for libGL
 742     if test "$enable_static" = yes; then
 743         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 744         GL_LIB_DEPS=""
 745     fi
 746     ;;
 747 dri|no) # these checks are still desired when there is no mesa_driver
 748     # DRI must be shared, I think
 749     if test "$enable_static" = yes; then
 750         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 751     fi
 752
 753     # Check for libdrm
 754     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 755     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 756     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 757     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 758     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 759
 760     # find the DRI deps for libGL
 761     if test "$x11_pkgconfig" = yes; then
 762         dri_modules="x11 xext xdamage xfixes"
 763
 764         # add xf86vidmode if available
 765         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 766         if test "$HAVE_XF86VIDMODE" = yes ; then
 767             dri_modules="$dri_modules xxf86vm"
 768         fi
 769
 770         # add xcb modules if necessary
 771         if test "$enable_xcb" = yes; then
 772             dri_modules="$dri_modules x11-xcb xcb-glx"
 773         fi
 774
 775         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 776         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 777         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 778         GL_LIB_DEPS="$DRIGL_LIBS"
 779     else
 780         # should check these...
 781         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 782         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 783         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 784         GL_PC_CFLAGS="$X11_INCLUDES"
 785
 786         # XCB can only be used from pkg-config
 787         if test "$enable_xcb" = yes; then
 788             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 789             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 790             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 791             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 792         fi
 793     fi
 794
 795     # need DRM libs, -lpthread, etc.
 796     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 797     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 798     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 799     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 800     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 801     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 802     ;;
 803 osmesa)
 804     # No libGL for osmesa
 805     GL_LIB_DEPS=""
 806     ;;
 807 esac
 808 AC_SUBST([GL_LIB_DEPS])
 809 AC_SUBST([GL_PC_REQ_PRIV])
 810 AC_SUBST([GL_PC_LIB_PRIV])
 811 AC_SUBST([GL_PC_CFLAGS])
 812 AC_SUBST([DRI_PC_REQ_PRIV])
 813 AC_SUBST([GLESv1_CM_LIB_DEPS])
 814 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 815 AC_SUBST([GLESv2_LIB_DEPS])
 816 AC_SUBST([GLESv2_PC_LIB_PRIV])
 817
 818 GLAPI_LIB_DEPS="-lpthread"
 819 AC_SUBST([GLAPI_LIB_DEPS])
 820
 821 AC_SUBST([HAVE_XF86VIDMODE])
 822
 823 PKG_CHECK_MODULES([LIBDRM_RADEON],
 824                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 825                   HAVE_LIBDRM_RADEON=yes,
 826                   HAVE_LIBDRM_RADEON=no)
 827
 828 dnl
 829 dnl More X11 setup
 830 dnl
 831 if test "$mesa_driver" = xlib; then
 832     DEFINES="$DEFINES -DUSE_XSHM"
 833 fi
 834
 835 dnl
 836 dnl TLS detection
 837 dnl
 838
 839 AC_ARG_ENABLE([glx-tls],
 840     [AS_HELP_STRING([--enable-glx-tls],
 841         [enable TLS support in GLX @<:@default=disabled@:>@])],
 842     [GLX_USE_TLS="$enableval"],
 843     [GLX_USE_TLS=no])
 844 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 845
 846 dnl
 847 dnl More DRI setup
 848 dnl
 849 dnl Directory for DRI drivers
 850 AC_ARG_WITH([dri-driverdir],
 851     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 852         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 853     [DRI_DRIVER_INSTALL_DIR="$withval"],
 854     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 855 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 856 dnl Extra search path for DRI drivers
 857 AC_ARG_WITH([dri-searchpath],
 858     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 859         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 860     [DRI_DRIVER_SEARCH_DIR="$withval"],
 861     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 862 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 863 dnl Direct rendering or just indirect rendering
 864 AC_ARG_ENABLE([driglx-direct],
 865     [AS_HELP_STRING([--disable-driglx-direct],
 866         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 867     [driglx_direct="$enableval"],
 868     [driglx_direct="yes"])
 869 dnl Which drivers to build - default is chosen by platform
 870 AC_ARG_WITH([dri-drivers],
 871     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 872         [comma delimited DRI drivers list, e.g.
 873         "swrast,i965,radeon" @<:@default=auto@:>@])],
 874     [with_dri_drivers="$withval"],
 875     [with_dri_drivers=yes])
 876 if test "x$with_dri_drivers" = x; then
 877     with_dri_drivers=no
 878 fi
 879
 880 dnl If $with_dri_drivers is yes, directories will be added through
 881 dnl platform checks
 882 DRI_DIRS=""
 883 case "$with_dri_drivers" in
 884 no) ;;
 885 yes)
 886     DRI_DIRS="yes"
 887     ;;
 888 *)
 889     # verify the requested driver directories exist
 890     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 891     for driver in $dri_drivers; do
 892         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 893             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 894     done
 895     DRI_DIRS="$dri_drivers"
 896     ;;
 897 esac
 898
 899 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 900 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 901     # Use TLS in GLX?
 902     if test "x$GLX_USE_TLS" = xyes; then
 903         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 904     fi
 905
 906     # Platform specific settings and drivers to build
 907     case "$host_os" in
 908     linux*)
 909         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 910         if test "x$driglx_direct" = xyes; then
 911             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 912         fi
 913         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 914
 915         case "$host_cpu" in
 916         x86_64)
 917             # sis is missing because they have not be converted to use
 918             # the new interface.  i810 are missing because there is no
 919             # x86-64 system where they could *ever* be used.
 920             if test "x$DRI_DIRS" = "xyes"; then
 921                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 922                     savage tdfx unichrome swrast"
 923             fi
 924             ;;
 925         powerpc*)
 926             # Build only the drivers for cards that exist on PowerPC.
 927             # At some point MGA will be added, but not yet.
 928             if test "x$DRI_DIRS" = "xyes"; then
 929                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 930             fi
 931             ;;
 932         sparc*)
 933             # Build only the drivers for cards that exist on sparc`
 934             if test "x$DRI_DIRS" = "xyes"; then
 935                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 936             fi
 937             ;;
 938         esac
 939         ;;
 940     freebsd* | dragonfly* | *netbsd*)
 941         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 942         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 943         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 944         if test "x$driglx_direct" = xyes; then
 945             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 946         fi
 947
 948         if test "x$DRI_DIRS" = "xyes"; then
 949             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 950                 unichrome savage sis swrast"
 951         fi
 952         ;;
 953     gnu*)
 954         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 955         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 956         ;;
 957     solaris*)
 958         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 959         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 960         if test "x$driglx_direct" = xyes; then
 961             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 962         fi
 963         ;;
 964     esac
 965
 966     # default drivers
 967     if test "x$DRI_DIRS" = "xyes"; then
 968         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 969             savage sis tdfx unichrome swrast"
 970     fi
 971
 972     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 973
 974     # Check for expat
 975     if test "$mesa_driver" = dri; then
 976         EXPAT_INCLUDES=""
 977         EXPAT_LIB=-lexpat
 978         AC_ARG_WITH([expat],
 979             [AS_HELP_STRING([--with-expat=DIR],
 980                 [expat install directory])],[
 981             EXPAT_INCLUDES="-I$withval/include"
 982             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 983             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 984             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 985             ])
 986         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 987         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 988             [AC_MSG_ERROR([Expat required for DRI.])])
 989     fi
 990
 991     # put all the necessary libs together
 992     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 993 fi
 994 AC_SUBST([DRI_DIRS])
 995 AC_SUBST([EXPAT_INCLUDES])
 996 AC_SUBST([DRI_LIB_DEPS])
 997
 998 case $DRI_DIRS in
 999 *i915*|*i965*)
1000     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.23])
1001     ;;
1002 esac
1003
1004 case $DRI_DIRS in
1005 *radeon*|*r200*|*r300*|*r600*)
1006     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1007         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
1008         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
1009     fi
1010     ;;
1011 esac
1012 AC_SUBST([RADEON_CFLAGS])
1013 AC_SUBST([RADEON_LDFLAGS])
1014
1015
1016 dnl
1017 dnl OSMesa configuration
1018 dnl
1019 if test "$mesa_driver" = xlib; then
1020     default_gl_osmesa=yes
1021 else
1022     default_gl_osmesa=no
1023 fi
1024 AC_ARG_ENABLE([gl-osmesa],
1025     [AS_HELP_STRING([--enable-gl-osmesa],
1026         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
1027     [gl_osmesa="$enableval"],
1028     [gl_osmesa="$default_gl_osmesa"])
1029 if test "x$gl_osmesa" = xyes; then
1030     if test "x$enable_opengl" = xno; then
1031         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1032     fi
1033     if test "$mesa_driver" = osmesa; then
1034         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1035     else
1036         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1037     fi
1038 fi
1039
1040 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1041 AC_ARG_WITH([osmesa-bits],
1042     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1043         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1044     [osmesa_bits="$withval"],
1045     [osmesa_bits=8])
1046 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1047     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1048     osmesa_bits=8
1049 fi
1050 case "x$osmesa_bits" in
1051 x8)
1052     OSMESA_LIB=OSMesa
1053     ;;
1054 x16|x32)
1055     OSMESA_LIB="OSMesa$osmesa_bits"
1056     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1057     ;;
1058 *)
1059     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1060     ;;
1061 esac
1062 AC_SUBST([OSMESA_LIB])
1063
1064 case "$DRIVER_DIRS" in
1065 *osmesa*)
1066     # only link libraries with osmesa if shared
1067     if test "$enable_static" = no; then
1068         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1069     else
1070         OSMESA_LIB_DEPS=""
1071     fi
1072     OSMESA_MESA_DEPS=""
1073     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1074     ;;
1075 esac
1076 AC_SUBST([OSMESA_LIB_DEPS])
1077 AC_SUBST([OSMESA_MESA_DEPS])
1078 AC_SUBST([OSMESA_PC_REQ])
1079 AC_SUBST([OSMESA_PC_LIB_PRIV])
1080
1081 dnl
1082 dnl EGL configuration
1083 dnl
1084 AC_ARG_ENABLE([egl],
1085     [AS_HELP_STRING([--disable-egl],
1086         [disable EGL library @<:@default=enabled@:>@])],
1087     [enable_egl="$enableval"],
1088     [enable_egl=yes])
1089 if test "x$enable_egl" = xno; then
1090     if test "x$mesa_driver" = xno; then
1091         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1092     fi
1093     if test "x$enable_openvg" = xyes; then
1094         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1095     fi
1096 fi
1097 if test "x$enable_egl" = xyes; then
1098     SRC_DIRS="$SRC_DIRS egl"
1099     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1100     EGL_DRIVERS_DIRS=""
1101     if test "$enable_static" != yes; then
1102         # build egl_glx when libGL is built
1103         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1104             EGL_DRIVERS_DIRS="glx"
1105         fi
1106
1107         if test "$mesa_driver" = dri; then
1108             # build egl_dri2 when xcb-dri2 is available
1109             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1110                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1111             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1112                           [have_libudev=yes],[have_libudev=no])
1113
1114             if test "$have_xcb_dri2" = yes; then
1115                 EGL_DRIVER_DRI2=dri2
1116                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1117                 if test "$have_libudev" = yes; then
1118                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1119                 fi
1120             fi
1121         fi
1122
1123         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1124     fi
1125 fi
1126 AC_SUBST([EGL_LIB_DEPS])
1127 AC_SUBST([EGL_DRIVERS_DIRS])
1128
1129 dnl
1130 dnl GLU configuration
1131 dnl
1132 AC_ARG_ENABLE([glu],
1133     [AS_HELP_STRING([--disable-glu],
1134         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1135     [enable_glu="$enableval"],
1136     [enable_glu=yes])
1137
1138 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1139     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1140     enable_glu=no
1141 fi
1142
1143 if test "x$enable_glu" = xyes; then
1144     SRC_DIRS="$SRC_DIRS glu"
1145
1146     case "$mesa_driver" in
1147     osmesa)
1148         # Link libGLU to libOSMesa instead of libGL
1149         GLU_LIB_DEPS=""
1150         GLU_PC_REQ="osmesa"
1151         if test "$enable_static" = no; then
1152             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1153         else
1154             GLU_MESA_DEPS=""
1155         fi
1156         ;;
1157     *)
1158         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1159         GLU_PC_REQ="gl"
1160         GLU_PC_LIB_PRIV="-lm"
1161         if test "$enable_static" = no; then
1162             GLU_LIB_DEPS="-lm"
1163             GLU_MESA_DEPS='-l$(GL_LIB)'
1164         else
1165             GLU_LIB_DEPS=""
1166             GLU_MESA_DEPS=""
1167             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1168         fi
1169         ;;
1170     esac
1171 fi
1172 if test "$enable_static" = no; then
1173     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1174 fi
1175 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1176 AC_SUBST([GLU_LIB_DEPS])
1177 AC_SUBST([GLU_MESA_DEPS])
1178 AC_SUBST([GLU_PC_REQ])
1179 AC_SUBST([GLU_PC_REQ_PRIV])
1180 AC_SUBST([GLU_PC_LIB_PRIV])
1181 AC_SUBST([GLU_PC_CFLAGS])
1182
1183 dnl
1184 dnl GLw configuration
1185 dnl
1186 AC_ARG_ENABLE([glw],
1187     [AS_HELP_STRING([--disable-glw],
1188         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1189     [enable_glw="$enableval"],
1190     [enable_glw=yes])
1191 dnl Don't build GLw on osmesa
1192 if test "x$enable_glw" = xyes; then
1193     case "$mesa_driver" in
1194     osmesa|no)
1195         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1196         enable_glw=no
1197         ;;
1198     esac
1199 fi
1200 AC_ARG_ENABLE([motif],
1201     [AS_HELP_STRING([--enable-motif],
1202         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1203     [enable_motif="$enableval"],
1204     [enable_motif=no])
1205
1206 if test "x$enable_glw" = xyes; then
1207     SRC_DIRS="$SRC_DIRS glw"
1208     if test "$x11_pkgconfig" = yes; then
1209         PKG_CHECK_MODULES([GLW],[x11 xt])
1210         GLW_PC_REQ_PRIV="x11 xt"
1211         GLW_LIB_DEPS="$GLW_LIBS"
1212     else
1213         # should check these...
1214         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1215         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1216         GLW_PC_CFLAGS="$X11_INCLUDES"
1217     fi
1218
1219     GLW_SOURCES="GLwDrawA.c"
1220     MOTIF_CFLAGS=
1221     if test "x$enable_motif" = xyes; then
1222         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1223         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1224         if test "x$MOTIF_CONFIG" != xno; then
1225             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1226             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1227         else
1228             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1229                 [AC_MSG_ERROR([Can't locate Motif headers])])
1230             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1231                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1232         fi
1233         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1234         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1235         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1236         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1237     fi
1238
1239     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1240     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1241     if test "$enable_static" = no; then
1242         GLW_MESA_DEPS='-l$(GL_LIB)'
1243         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1244     else
1245         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1246         GLW_LIB_DEPS=""
1247         GLW_MESA_DEPS=""
1248     fi
1249 fi
1250 AC_SUBST([GLW_LIB_DEPS])
1251 AC_SUBST([GLW_MESA_DEPS])
1252 AC_SUBST([GLW_SOURCES])
1253 AC_SUBST([MOTIF_CFLAGS])
1254 AC_SUBST([GLW_PC_REQ_PRIV])
1255 AC_SUBST([GLW_PC_LIB_PRIV])
1256 AC_SUBST([GLW_PC_CFLAGS])
1257
1258 dnl
1259 dnl GLUT configuration
1260 dnl
1261 if test -f "$srcdir/include/GL/glut.h"; then
1262     default_glut=yes
1263 else
1264     default_glut=no
1265 fi
1266 AC_ARG_ENABLE([glut],
1267     [AS_HELP_STRING([--disable-glut],
1268         [enable GLUT library @<:@default=enabled if source available@:>@])],
1269     [enable_glut="$enableval"],
1270     [enable_glut="$default_glut"])
1271
1272 dnl Don't build glut on osmesa
1273 if test "x$enable_glut" = xyes; then
1274     case "$mesa_driver" in
1275     osmesa|no)
1276         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1277         enable_glut=no
1278         ;;
1279     esac
1280 fi
1281 dnl Can't build glut if GLU not available
1282 if test "x$enable_glu$enable_glut" = xnoyes; then
1283     AC_MSG_WARN([Disabling glut since GLU is disabled])
1284     enable_glut=no
1285 fi
1286
1287 if test "x$enable_glut" = xyes; then
1288     SRC_DIRS="$SRC_DIRS glut/glx"
1289     if test "$x11_pkgconfig" = yes; then
1290         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1291         GLUT_PC_REQ_PRIV="x11 xmu xi"
1292         GLUT_LIB_DEPS="$GLUT_LIBS"
1293     else
1294         # should check these...
1295         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1296         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1297         GLUT_PC_CFLAGS="$X11_INCLUDES"
1298     fi
1299     if test "x$GCC" = xyes; then
1300         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1301     fi
1302     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1303     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1304
1305     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1306     if test "$enable_static" = no; then
1307         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1308     else
1309         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1310         GLUT_LIB_DEPS=""
1311         GLUT_MESA_DEPS=""
1312     fi
1313 fi
1314 AC_SUBST([GLUT_LIB_DEPS])
1315 AC_SUBST([GLUT_MESA_DEPS])
1316 AC_SUBST([GLUT_CFLAGS])
1317 AC_SUBST([GLUT_PC_REQ_PRIV])
1318 AC_SUBST([GLUT_PC_LIB_PRIV])
1319 AC_SUBST([GLUT_PC_CFLAGS])
1320
1321 dnl
1322 dnl Program library dependencies
1323 dnl    Only libm is added here if necessary as the libraries should
1324 dnl    be pulled in by the linker
1325 dnl
1326 if test "x$APP_LIB_DEPS" = x; then
1327     case "$host_os" in
1328     solaris*)
1329         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1330         ;;
1331     cygwin*)
1332         APP_LIB_DEPS="-lX11"
1333         ;;
1334     *)
1335         APP_LIB_DEPS="-lm"
1336         ;;
1337     esac
1338 fi
1339 AC_SUBST([APP_LIB_DEPS])
1340 AC_SUBST([PROGRAM_DIRS])
1341
1342 dnl
1343 dnl Gallium configuration
1344 dnl
1345 AC_ARG_ENABLE([gallium],
1346     [AS_HELP_STRING([--disable-gallium],
1347         [build gallium @<:@default=enabled@:>@])],
1348     [enable_gallium="$enableval"],
1349     [enable_gallium=yes])
1350 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1351     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1352 fi
1353 if test "x$enable_gallium" = xyes; then
1354     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1355     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1356                 [HAS_UDIS86="no"])
1357     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1358 fi
1359
1360 AC_SUBST([LLVM_CFLAGS])
1361 AC_SUBST([LLVM_LIBS])
1362 AC_SUBST([LLVM_LDFLAGS])
1363 AC_SUBST([LLVM_VERSION])
1364
1365 dnl
1366 dnl Gallium state trackers configuration
1367 dnl
1368
1369 AC_ARG_ENABLE([gallium-egl],
1370     [AS_HELP_STRING([--enable-gallium-egl],
1371         [enable gallium EGL state tracker @<:@default=auto@:>@])],
1372     [enable_gallium_egl="$enableval"],
1373     [enable_gallium_egl=auto])
1374 if test "x$enable_gallium_egl" = xauto; then
1375     case "$mesa_driver" in
1376     dri|no)
1377         enable_gallium_egl=$enable_egl
1378         ;;
1379     *)
1380         enable_gallium_egl=$enable_openvg
1381         ;;
1382     esac
1383 fi
1384 case "x$enable_egl$enable_gallium_egl" in
1385 xnoyes)
1386     AC_MSG_ERROR([cannot build Gallium EGL state tracker without EGL])
1387 esac
1388
1389 AC_ARG_WITH([state-trackers],
1390     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1391         [comma delimited state_trackers list, e.g.
1392         "egl,glx" @<:@default=auto@:>@])],
1393     [with_state_trackers="$withval"],
1394     [with_state_trackers=yes])
1395
1396 case "$with_state_trackers" in
1397 no)
1398     GALLIUM_STATE_TRACKERS_DIRS=""
1399     ;;
1400 yes)
1401     # look at what else is built
1402     case "$mesa_driver" in
1403     xlib)
1404         GALLIUM_STATE_TRACKERS_DIRS=glx
1405         ;;
1406     dri)
1407         GALLIUM_STATE_TRACKERS_DIRS="dri"
1408         HAVE_ST_DRI="yes"
1409         # Have only tested st/xorg on 1.6.0 servers
1410         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1411             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1412             HAVE_ST_XORG="no")
1413         ;;
1414     esac
1415
1416     if test "x$enable_egl" = xyes; then
1417         if test "$enable_openvg" = yes; then
1418             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1419             st_egl="yes"
1420         fi
1421
1422         if test "$enable_gallium_egl" = yes; then
1423             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1424             HAVE_ST_EGL="yes"
1425         fi
1426     fi
1427     ;;
1428 *)
1429     # verify the requested state tracker exist
1430     state_trackers=""
1431     _state_trackers=`IFS=', '; echo $with_state_trackers`
1432     for tracker in $_state_trackers; do
1433         case "$tracker" in
1434         dri)
1435             if test "x$mesa_driver" != xdri; then
1436                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1437             fi
1438             HAVE_ST_DRI="yes"
1439             ;;
1440         egl)
1441             if test "x$enable_egl" != xyes; then
1442                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1443             fi
1444             HAVE_ST_EGL="yes"
1445             ;;
1446         xorg)
1447             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1448             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1449             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1450             HAVE_ST_XORG="yes"
1451             ;;
1452         vega)
1453             if test "x$enable_openvg" != xyes; then
1454                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1455             fi
1456             have_st_vega="yes"
1457             ;;
1458         esac
1459
1460         if test -n "$tracker"; then
1461             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1462                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1463             if test -n "$state_trackers"; then
1464                 state_trackers="$state_trackers $tracker"
1465             else
1466                 state_trackers="$tracker"
1467             fi
1468         fi
1469     done
1470     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1471
1472     # append --enable-openvg/--enable-gallium-egl to --with-state-trackers
1473     if test "x$have_st_vega" != xyes -a "x$enable_openvg" = xyes; then
1474         AC_MSG_ERROR([--with-state-trackers specified but vega is missing])
1475     fi
1476     if test "x$HAVE_ST_EGL" != xyes -a "x$enable_gallium_egl" = xyes; then
1477         AC_MSG_ERROR([--with-state-trackers specified but egl is missing])
1478     fi
1479     ;;
1480 esac
1481
1482
1483 EGL_CLIENT_APIS=""
1484 VG_LIB_DEPS=""
1485
1486 case "x$enable_opengl$enable_gles1$enable_gles2" in
1487 x*yes*)
1488     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1489     ;;
1490 esac
1491 if test "x$enable_openvg" = xyes; then
1492     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1493     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1494 fi
1495
1496 AC_SUBST([VG_LIB_DEPS])
1497 AC_SUBST([EGL_CLIENT_APIS])
1498
1499 if test "x$HAVE_ST_EGL" = xyes; then
1500         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1501 fi
1502
1503 if test "x$HAVE_ST_XORG" = xyes; then
1504     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1505         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1506         HAVE_XEXTPROTO_71="no")
1507 fi
1508
1509 AC_ARG_WITH([egl-platforms],
1510     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1511         [comma delimited native platforms libEGL supports, e.g.
1512         "x11,drm" @<:@default=auto@:>@])],
1513     [with_egl_platforms="$withval"],
1514     [with_egl_platforms=yes])
1515 AC_ARG_WITH([egl-displays],
1516     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1517         [DEPRECATED.  Use --with-egl-platforms instead])],
1518     [with_egl_platforms="$withval"])
1519
1520 EGL_PLATFORMS=""
1521 case "$with_egl_platforms" in
1522 yes)
1523     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1524         EGL_PLATFORMS="x11"
1525         if test "$mesa_driver" = dri; then
1526             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1527         fi
1528     fi
1529     ;;
1530 *)
1531     if test "x$enable_egl" != xyes; then
1532         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1533     fi
1534     # verify the requested driver directories exist
1535     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1536     for plat in $egl_platforms; do
1537         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1538             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1539         if test "$plat" = "fbdev"; then
1540                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1541         fi
1542     done
1543     EGL_PLATFORMS="$egl_platforms"
1544     ;;
1545 esac
1546 AC_SUBST([EGL_PLATFORMS])
1547
1548 AC_ARG_WITH([egl-driver-dir],
1549     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1550                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1551     [EGL_DRIVER_INSTALL_DIR="$withval"],
1552     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1553 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1554
1555 AC_ARG_WITH([xorg-driver-dir],
1556     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1557                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1558     [XORG_DRIVER_INSTALL_DIR="$withval"],
1559     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1560 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1561
1562 AC_ARG_WITH([max-width],
1563     [AS_HELP_STRING([--with-max-width=N],
1564                     [Maximum framebuffer width (4096)])],
1565     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1566      AS_IF([test "${withval}" -gt "4096"],
1567            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1568 )
1569 AC_ARG_WITH([max-height],
1570     [AS_HELP_STRING([--with-max-height=N],
1571                     [Maximum framebuffer height (4096)])],
1572     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1573      AS_IF([test "${withval}" -gt "4096"],
1574            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1575 )
1576
1577 dnl
1578 dnl Gallium LLVM
1579 dnl
1580 AC_ARG_ENABLE([gallium-llvm],
1581     [AS_HELP_STRING([--enable-gallium-llvm],
1582         [build gallium LLVM support @<:@default=disabled@:>@])],
1583     [enable_gallium_llvm="$enableval"],
1584     [enable_gallium_llvm=auto])
1585 if test "x$enable_gallium_llvm" = xyes; then
1586     if test "x$LLVM_CONFIG" != xno; then
1587         LLVM_VERSION=`$LLVM_CONFIG --version`
1588         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags`
1589         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1590
1591         if test "x$HAS_UDIS86" != xno; then
1592             LLVM_LIBS="$LLVM_LIBS -ludis86"
1593             DEFINES="$DEFINES -DHAVE_UDIS86"
1594         fi
1595         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1596         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1597         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1598         MESA_LLVM=1
1599     else
1600         MESA_LLVM=0
1601     fi
1602 else
1603     MESA_LLVM=0
1604 fi
1605
1606 dnl
1607 dnl Gallium helper functions
1608 dnl
1609 gallium_check_st() {
1610     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1611          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1612     fi
1613     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1614          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1615     fi
1616     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1617          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1618     fi
1619 }
1620
1621
1622 dnl
1623 dnl Gallium SVGA configuration
1624 dnl
1625 AC_ARG_ENABLE([gallium-svga],
1626     [AS_HELP_STRING([--enable-gallium-svga],
1627         [build gallium SVGA @<:@default=disabled@:>@])],
1628     [enable_gallium_svga="$enableval"],
1629     [enable_gallium_svga=auto])
1630 if test "x$enable_gallium_svga" = xyes; then
1631     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1632     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1633 elif test "x$enable_gallium_svga" = xauto; then
1634     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1635 fi
1636
1637 dnl
1638 dnl Gallium i915 configuration
1639 dnl
1640 AC_ARG_ENABLE([gallium-i915],
1641     [AS_HELP_STRING([--enable-gallium-i915],
1642         [build gallium i915 @<:@default=disabled@:>@])],
1643     [enable_gallium_i915="$enableval"],
1644     [enable_gallium_i915=auto])
1645 if test "x$enable_gallium_i915" = xyes; then
1646     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1647     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1648     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1649 elif test "x$enable_gallium_i915" = xauto; then
1650     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1651     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1652 fi
1653
1654 dnl
1655 dnl Gallium i965 configuration
1656 dnl
1657 AC_ARG_ENABLE([gallium-i965],
1658     [AS_HELP_STRING([--enable-gallium-i965],
1659         [build gallium i965 @<:@default=disabled@:>@])],
1660     [enable_gallium_i965="$enableval"],
1661     [enable_gallium_i965=auto])
1662 if test "x$enable_gallium_i965" = xyes; then
1663     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1664     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1665 elif test "x$enable_gallium_i965" = xauto; then
1666     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1667 fi
1668
1669 dnl
1670 dnl Gallium Radeon r300g configuration
1671 dnl
1672 AC_ARG_ENABLE([gallium-radeon],
1673     [AS_HELP_STRING([--enable-gallium-radeon],
1674         [build gallium radeon @<:@default=disabled@:>@])],
1675     [enable_gallium_radeon="$enableval"],
1676     [enable_gallium_radeon=auto])
1677 if test "x$enable_gallium_radeon" = xauto; then
1678     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1679         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1680         gallium_check_st "radeon/drm" "dri-r300"
1681     else
1682         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1683     fi
1684 fi
1685 if test "x$enable_gallium_radeon" = xyes; then
1686     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1687         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1688         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1689     else
1690         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1691     fi
1692 fi
1693
1694 dnl
1695 dnl Gallium Radeon r600g configuration
1696 dnl
1697 AC_ARG_ENABLE([gallium-r600],
1698     [AS_HELP_STRING([--enable-gallium-r600],
1699         [build gallium radeon @<:@default=disabled@:>@])],
1700     [enable_gallium_r600="$enableval"],
1701     [enable_gallium_r600=auto])
1702 if test "x$enable_gallium_r600" = xyes; then
1703     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1704         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1705         gallium_check_st "r600/drm" "dri-r600"
1706     else
1707         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1708     fi
1709 fi
1710
1711 dnl
1712 dnl Gallium Nouveau configuration
1713 dnl
1714 AC_ARG_ENABLE([gallium-nouveau],
1715     [AS_HELP_STRING([--enable-gallium-nouveau],
1716         [build gallium nouveau @<:@default=disabled@:>@])],
1717     [enable_gallium_nouveau="$enableval"],
1718     [enable_gallium_nouveau=no])
1719 if test "x$enable_gallium_nouveau" = xyes; then
1720     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1721     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1722 fi
1723
1724 dnl
1725 dnl Gallium swrast configuration
1726 dnl
1727 AC_ARG_ENABLE([gallium-swrast],
1728     [AS_HELP_STRING([--enable-gallium-swrast],
1729         [build gallium swrast @<:@default=auto@:>@])],
1730     [enable_gallium_swrast="$enableval"],
1731     [enable_gallium_swrast=auto])
1732 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1733     if test "x$HAVE_ST_DRI" = xyes; then
1734         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1735     fi
1736 fi
1737
1738 dnl prepend CORE_DIRS to SRC_DIRS
1739 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1740
1741 dnl Restore LDFLAGS and CPPFLAGS
1742 LDFLAGS="$_SAVE_LDFLAGS"
1743 CPPFLAGS="$_SAVE_CPPFLAGS"
1744
1745 dnl Substitute the config
1746 AC_CONFIG_FILES([configs/autoconf])
1747
1748 dnl Replace the configs/current symlink
1749 AC_CONFIG_COMMANDS([configs],[
1750 if test -f configs/current || test -L configs/current; then
1751     rm -f configs/current
1752 fi
1753 ln -s autoconf configs/current
1754 ])
1755
1756 AC_OUTPUT
1757
1758 dnl
1759 dnl Output some configuration info for the user
1760 dnl
1761 echo ""
1762 echo "        prefix:          $prefix"
1763 echo "        exec_prefix:     $exec_prefix"
1764 echo "        libdir:          $libdir"
1765 echo "        includedir:      $includedir"
1766
1767 dnl API info
1768 echo ""
1769 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1770 echo "        OpenVG:          $enable_openvg"
1771
1772 dnl Driver info
1773 echo ""
1774 echo "        Driver:          $mesa_driver"
1775 if test "$mesa_driver" != no; then
1776     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1777         echo "        OSMesa:          lib$OSMESA_LIB"
1778     else
1779         echo "        OSMesa:          no"
1780     fi
1781     if test "$mesa_driver" = dri; then
1782         # cleanup the drivers var
1783         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1784         if test "x$DRI_DIRS" = x; then
1785             echo "        DRI drivers:     no"
1786         else
1787             echo "        DRI drivers:     $dri_dirs"
1788         fi
1789         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1790         echo "        Use XCB:         $enable_xcb"
1791     fi
1792 fi
1793 echo ""
1794 echo "        GLU:             $enable_glu"
1795 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1796 echo "        glut:            $enable_glut"
1797
1798 dnl EGL
1799 echo ""
1800 echo "        EGL:             $enable_egl"
1801 if test "$enable_egl" = yes; then
1802     echo "        EGL platforms:   $EGL_PLATFORMS"
1803
1804     egl_drivers=""
1805     for d in $EGL_DRIVERS_DIRS; do
1806         egl_drivers="$egl_drivers builtin:egl_$d"
1807     done
1808
1809     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1810         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
1811         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
1812     else
1813         echo "        EGL drivers:    $egl_drivers"
1814     fi
1815 fi
1816
1817 echo ""
1818 if test "x$MESA_LLVM" = x1; then
1819     echo "        llvm:            yes"
1820     echo "        llvm-config:     $LLVM_CONFIG"
1821     echo "        llvm-version:    $LLVM_VERSION"
1822 else
1823     echo "        llvm:            no"
1824 fi
1825
1826 echo ""
1827 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1828     echo "        Gallium:         yes"
1829     echo "        Gallium dirs:    $GALLIUM_DIRS"
1830     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1831     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1832     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1833     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1834 else
1835     echo "        Gallium:         no"
1836 fi
1837
1838 dnl Libraries
1839 echo ""
1840 echo "        Shared libs:     $enable_shared"
1841 echo "        Static libs:     $enable_static"
1842
1843 dnl Compiler options
1844 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1845 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1846     $SED 's/^ *//;s/  */ /;s/ *$//'`
1847 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1848     $SED 's/^ *//;s/  */ /;s/ *$//'`
1849 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1850 echo ""
1851 echo "        CFLAGS:          $cflags"
1852 echo "        CXXFLAGS:        $cxxflags"
1853 echo "        Macros:          $defines"
1854 echo ""
1855 echo "        PYTHON2:         $PYTHON2"
1856
1857 echo ""
1858 echo "        Run '${MAKE-make}' to build Mesa"
1859 echo ""