configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.55
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AC_CHECK_PROGS([MAKE], [gmake make])
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133 AX_GCC_BUILTIN([__builtin_clz])
 134 AX_GCC_BUILTIN([__builtin_clzll])
 135 AX_GCC_BUILTIN([__builtin_ctz])
 136 AX_GCC_BUILTIN([__builtin_expect])
 137 AX_GCC_BUILTIN([__builtin_ffs])
 138 AX_GCC_BUILTIN([__builtin_ffsll])
 139 AX_GCC_BUILTIN([__builtin_popcount])
 140 AX_GCC_BUILTIN([__builtin_popcountll])
 141 AX_GCC_BUILTIN([__builtin_unreachable])
 142
 143 AX_GCC_FUNC_ATTRIBUTE([flatten])
 144 AX_GCC_FUNC_ATTRIBUTE([format])
 145 AX_GCC_FUNC_ATTRIBUTE([malloc])
 146 AX_GCC_FUNC_ATTRIBUTE([packed])
 147
 148 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 149
 150 dnl Make sure the pkg-config macros are defined
 151 m4_ifndef([PKG_PROG_PKG_CONFIG],
 152     [m4_fatal([Could not locate the pkg-config autoconf macros.
 153   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 154   are in a different location, try setting the environment variable
 155   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 156 PKG_PROG_PKG_CONFIG()
 157
 158 dnl LIB_DIR - library basename
 159 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 160 AC_SUBST([LIB_DIR])
 161
 162 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 163 _SAVE_LDFLAGS="$LDFLAGS"
 164 _SAVE_CPPFLAGS="$CPPFLAGS"
 165
 166 dnl Compiler macros
 167 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 168 AC_SUBST([DEFINES])
 169 case "$host_os" in
 170 linux*|*-gnu*|gnu*)
 171     DEFINES="$DEFINES -D_GNU_SOURCE"
 172     ;;
 173 solaris*)
 174     DEFINES="$DEFINES -DSVR4"
 175     ;;
 176 cygwin*)
 177     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 178     ;;
 179 esac
 180
 181 dnl Add flags for gcc and g++
 182 if test "x$GCC" = xyes; then
 183     CFLAGS="$CFLAGS -Wall -std=c99"
 184
 185     # Enable -Werror=implicit-function-declaration and
 186     # -Werror=missing-prototypes, if available, or otherwise, just
 187     # -Wmissing-prototypes.  This is particularly useful to avoid
 188     # generating a loadable driver module that has undefined symbols.
 189     save_CFLAGS="$CFLAGS"
 190     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 191     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 192     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 194                    AC_MSG_RESULT([yes]),
 195                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 196                     AC_MSG_RESULT([no])]);
 197
 198     # Enable -fvisibility=hidden if using a gcc that supports it
 199     save_CFLAGS="$CFLAGS"
 200     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 201     VISIBILITY_CFLAGS="-fvisibility=hidden"
 202     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 204                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 205
 206     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 207     CFLAGS=$save_CFLAGS
 208
 209     # Work around aliasing bugs - developers should comment this out
 210     CFLAGS="$CFLAGS -fno-strict-aliasing"
 211
 212     # gcc's builtin memcmp is slower than glibc's
 213     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 214     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 215 fi
 216 if test "x$GXX" = xyes; then
 217     CXXFLAGS="$CXXFLAGS -Wall"
 218
 219     # Enable -fvisibility=hidden if using a gcc that supports it
 220     save_CXXFLAGS="$CXXFLAGS"
 221     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 222     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 223     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 224     AC_LANG_PUSH([C++])
 225     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 226                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 227     AC_LANG_POP([C++])
 228
 229     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 230     CXXFLAGS=$save_CXXFLAGS
 231
 232     # Work around aliasing bugs - developers should comment this out
 233     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 234
 235     # gcc's builtin memcmp is slower than glibc's
 236     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Optional flags, check for compiler support
 254 dnl
 255 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 256 if test "x$SSE41_SUPPORTED" = x1; then
 257     DEFINES="$DEFINES -DUSE_SSE41"
 258 fi
 259 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 260
 261 dnl Can't have static and shared libraries, default to static if user
 262 dnl explicitly requested. If both disabled, set to static since shared
 263 dnl was explicitly requested.
 264 case "x$enable_static$enable_shared" in
 265 xyesyes)
 266     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 267     enable_shared=no
 268     ;;
 269 xnono)
 270     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 271     enable_shared=yes
 272     ;;
 273 esac
 274
 275 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 276
 277 dnl
 278 dnl other compiler options
 279 dnl
 280 AC_ARG_ENABLE([debug],
 281     [AS_HELP_STRING([--enable-debug],
 282         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 283     [enable_debug="$enableval"],
 284     [enable_debug=no]
 285 )
 286 if test "x$enable_debug" = xyes; then
 287     DEFINES="$DEFINES -DDEBUG"
 288     if test "x$GCC" = xyes; then
 289         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 290             CFLAGS="$CFLAGS -g"
 291         fi
 292         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 293             CFLAGS="$CFLAGS -O0"
 294         fi
 295     fi
 296     if test "x$GXX" = xyes; then
 297         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 298             CXXFLAGS="$CXXFLAGS -g"
 299         fi
 300         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 301             CXXFLAGS="$CXXFLAGS -O0"
 302         fi
 303     fi
 304 fi
 305
 306 dnl
 307 dnl Check if linker supports -Bsymbolic
 308 dnl
 309 save_LDFLAGS=$LDFLAGS
 310 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 311 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 312 AC_LINK_IFELSE(
 313     [AC_LANG_SOURCE([int main() { return 0;}])],
 314     [AC_MSG_RESULT([yes])
 315         BSYMBOLIC="-Wl,-Bsymbolic";],
 316     [AC_MSG_RESULT([no])
 317         BSYMBOLIC="";])
 318 LDFLAGS=$save_LDFLAGS
 319
 320 AC_SUBST([BSYMBOLIC])
 321
 322 dnl
 323 dnl Check if linker supports garbage collection
 324 dnl
 325 save_LDFLAGS=$LDFLAGS
 326 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 327 AC_MSG_CHECKING([whether ld supports --gc-sections])
 328 AC_LINK_IFELSE(
 329     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 330     [AC_MSG_RESULT([yes])
 331         GC_SECTIONS="-Wl,--gc-sections";],
 332     [AC_MSG_RESULT([no])
 333         GC_SECTIONS="";])
 334 LDFLAGS=$save_LDFLAGS
 335
 336 AC_SUBST([GC_SECTIONS])
 337
 338 dnl
 339 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 340 dnl so when these flags are passed to ld via libtool the checks will fail
 341 dnl
 342 case "$host_os" in
 343 openbsd* | darwin* )
 344     LD_NO_UNDEFINED="" ;;
 345 *)
 346     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 347 esac
 348
 349 AC_SUBST([LD_NO_UNDEFINED])
 350
 351 dnl
 352 dnl Check if linker supports version scripts
 353 dnl
 354 AC_MSG_CHECKING([if the linker supports version-scripts])
 355 save_LDFLAGS=$LDFLAGS
 356 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 357 cat > conftest.map <<EOF
 358 VERSION_1 {
 359      global:
 360          main;
 361
 362      local:
 363          *;
 364 };
 365 EOF
 366 AC_LINK_IFELSE(
 367     [AC_LANG_SOURCE([int main() { return 0;}])],
 368     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 369     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 370 LDFLAGS=$save_LDFLAGS
 371 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 372
 373 dnl
 374 dnl Check if linker supports dynamic list files
 375 dnl
 376 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 377 save_LDFLAGS=$LDFLAGS
 378 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 379 cat > conftest.dyn <<EOF
 380 {
 381         radeon_drm_winsys_create;
 382 };
 383 EOF
 384 AC_LINK_IFELSE(
 385     [AC_LANG_SOURCE([int main() { return 0;}])],
 386     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 387     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 388 LDFLAGS=$save_LDFLAGS
 389 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 390
 391 dnl
 392 dnl compatibility symlinks
 393 dnl
 394 case "$host_os" in
 395 linux* )
 396     HAVE_COMPAT_SYMLINKS=yes ;;
 397 * )
 398     HAVE_COMPAT_SYMLINKS=no ;;
 399 esac
 400
 401 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 402
 403 dnl
 404 dnl library names
 405 dnl
 406 case "$host_os" in
 407 darwin* )
 408     LIB_EXT='dylib' ;;
 409 cygwin* )
 410     LIB_EXT='dll' ;;
 411 aix* )
 412     LIB_EXT='a' ;;
 413 * )
 414     LIB_EXT='so' ;;
 415 esac
 416
 417 AC_SUBST([LIB_EXT])
 418
 419 AC_ARG_WITH([gl-lib-name],
 420   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 421     [specify GL library name @<:@default=GL@:>@])],
 422   [GL_LIB=$withval],
 423   [GL_LIB=GL])
 424 AC_ARG_WITH([osmesa-lib-name],
 425   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 426     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 427   [OSMESA_LIB=$withval],
 428   [OSMESA_LIB=OSMesa])
 429 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 430 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 431
 432 dnl
 433 dnl Mangled Mesa support
 434 dnl
 435 AC_ARG_ENABLE([mangling],
 436   [AS_HELP_STRING([--enable-mangling],
 437     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 438   [enable_mangling="${enableval}"],
 439   [enable_mangling=no]
 440 )
 441 if test "x${enable_mangling}" = "xyes" ; then
 442   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 443   GL_LIB="Mangled${GL_LIB}"
 444   OSMESA_LIB="Mangled${OSMESA_LIB}"
 445 fi
 446 AC_SUBST([GL_LIB])
 447 AC_SUBST([OSMESA_LIB])
 448
 449 dnl
 450 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 451 dnl
 452 AC_ARG_ENABLE([texture-float],
 453     [AS_HELP_STRING([--enable-texture-float],
 454         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 455     [enable_texture_float="$enableval"],
 456     [enable_texture_float=no]
 457 )
 458 if test "x$enable_texture_float" = xyes; then
 459     AC_MSG_WARN([Floating-point textures enabled.])
 460     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 461     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 462 fi
 463
 464 dnl
 465 dnl Arch/platform-specific settings
 466 dnl
 467 AC_ARG_ENABLE([asm],
 468     [AS_HELP_STRING([--disable-asm],
 469         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 470     [enable_asm="$enableval"],
 471     [enable_asm=yes]
 472 )
 473 asm_arch=""
 474 AC_MSG_CHECKING([whether to enable assembly])
 475 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 476 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 477 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 478     case "$host_cpu" in
 479     i?86 | x86_64 | amd64)
 480         enable_asm=no
 481         AC_MSG_RESULT([no, cross compiling])
 482         ;;
 483     esac
 484 fi
 485 # check for supported arches
 486 if test "x$enable_asm" = xyes; then
 487     case "$host_cpu" in
 488     i?86)
 489         case "$host_os" in
 490         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 dnl Check to see if dlopen is in default libraries (like Solaris, which
 531 dnl has it in libc), or if libdl is needed to get it.
 532 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 533     [AC_CHECK_LIB([dl], [dlopen],
 534        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 535 AC_SUBST([DLOPEN_LIBS])
 536
 537 dnl Check if that library also has dladdr
 538 save_LIBS="$LIBS"
 539 LIBS="$LIBS $DLOPEN_LIBS"
 540 AC_CHECK_FUNCS([dladdr])
 541 LIBS="$save_LIBS"
 542
 543 case "$host_os" in
 544 darwin*|mingw*)
 545     ;;
 546 *)
 547     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 548                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 549                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 550     AC_SUBST([CLOCK_LIB])
 551     ;;
 552 esac
 553
 554 dnl See if posix_memalign is available
 555 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 556
 557 dnl Check for pthreads
 558 case "$host_os" in
 559 mingw*)
 560     ;;
 561 *)
 562     AX_PTHREAD
 563     ;;
 564 esac
 565 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 566 dnl to -pthread, which causes problems if we need -lpthread to appear in
 567 dnl pkgconfig files.
 568 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 569
 570 dnl SELinux awareness.
 571 AC_ARG_ENABLE([selinux],
 572     [AS_HELP_STRING([--enable-selinux],
 573         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 574     [MESA_SELINUX="$enableval"],
 575     [MESA_SELINUX=no])
 576 if test "x$enable_selinux" = "xyes"; then
 577     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 578         [AC_CHECK_HEADER([selinux/selinux.h],[],
 579                          [AC_MSG_ERROR([SELinux headers not found])])
 580          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 581                       [AC_MSG_ERROR([SELinux library not found])])
 582          SELINUX_LIBS="-lselinux"])
 583     DEFINES="$DEFINES -DMESA_SELINUX"
 584 fi
 585 AC_SUBST([SELINUX_CFLAGS])
 586 AC_SUBST([SELINUX_LIBS])
 587
 588 dnl Options for APIs
 589 AC_ARG_ENABLE([opengl],
 590     [AS_HELP_STRING([--disable-opengl],
 591         [disable support for standard OpenGL API @<:@default=no@:>@])],
 592     [enable_opengl="$enableval"],
 593     [enable_opengl=yes])
 594 AC_ARG_ENABLE([gles1],
 595     [AS_HELP_STRING([--enable-gles1],
 596         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 597     [enable_gles1="$enableval"],
 598     [enable_gles1=no])
 599 AC_ARG_ENABLE([gles2],
 600     [AS_HELP_STRING([--enable-gles2],
 601         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 602     [enable_gles2="$enableval"],
 603     [enable_gles2=no])
 604 AC_ARG_ENABLE([openvg],
 605     [AS_HELP_STRING([--enable-openvg],
 606         [enable support for OpenVG API @<:@default=no@:>@])],
 607     [enable_openvg="$enableval"],
 608     [enable_openvg=no])
 609
 610 AC_ARG_ENABLE([dri],
 611     [AS_HELP_STRING([--enable-dri],
 612         [enable DRI modules @<:@default=enabled@:>@])],
 613     [enable_dri="$enableval"],
 614     [enable_dri=yes])
 615
 616 case "$host_os" in
 617 linux*)
 618     dri3_default=yes
 619     ;;
 620 *)
 621     dri3_default=no
 622     ;;
 623 esac
 624 AC_ARG_ENABLE([dri3],
 625     [AS_HELP_STRING([--enable-dri3],
 626         [enable DRI3 @<:@default=auto@:>@])],
 627     [enable_dri3="$enableval"],
 628     [enable_dri3="$dri3_default"])
 629 AC_ARG_ENABLE([glx],
 630     [AS_HELP_STRING([--enable-glx],
 631         [enable GLX library @<:@default=enabled@:>@])],
 632     [enable_glx="$enableval"],
 633     [enable_glx=yes])
 634 AC_ARG_ENABLE([osmesa],
 635     [AS_HELP_STRING([--enable-osmesa],
 636         [enable OSMesa library @<:@default=disabled@:>@])],
 637     [enable_osmesa="$enableval"],
 638     [enable_osmesa=no])
 639 AC_ARG_ENABLE([gallium-osmesa],
 640     [AS_HELP_STRING([--enable-gallium-osmesa],
 641         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 642     [enable_gallium_osmesa="$enableval"],
 643     [enable_gallium_osmesa=no])
 644 AC_ARG_ENABLE([egl],
 645     [AS_HELP_STRING([--disable-egl],
 646         [disable EGL library @<:@default=enabled@:>@])],
 647     [enable_egl="$enableval"],
 648     [enable_egl=yes])
 649
 650 AC_ARG_ENABLE([xa],
 651     [AS_HELP_STRING([--enable-xa],
 652         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 653     [enable_xa="$enableval"],
 654     [enable_xa=no])
 655 AC_ARG_ENABLE([gbm],
 656    [AS_HELP_STRING([--enable-gbm],
 657          [enable gbm library @<:@default=auto@:>@])],
 658    [enable_gbm="$enableval"],
 659    [enable_gbm=auto])
 660
 661 AC_ARG_ENABLE([xvmc],
 662    [AS_HELP_STRING([--enable-xvmc],
 663          [enable xvmc library @<:@default=auto@:>@])],
 664    [enable_xvmc="$enableval"],
 665    [enable_xvmc=auto])
 666 AC_ARG_ENABLE([vdpau],
 667    [AS_HELP_STRING([--enable-vdpau],
 668          [enable vdpau library @<:@default=auto@:>@])],
 669    [enable_vdpau="$enableval"],
 670    [enable_vdpau=auto])
 671 AC_ARG_ENABLE([omx],
 672    [AS_HELP_STRING([--enable-omx],
 673          [enable OpenMAX library @<:@default=no@:>@])],
 674    [enable_omx="$enableval"],
 675    [enable_omx=no])
 676 AC_ARG_ENABLE([opencl],
 677    [AS_HELP_STRING([--enable-opencl],
 678          [enable OpenCL library @<:@default=no@:>@])],
 679    [enable_opencl="$enableval"],
 680    [enable_opencl=no])
 681 AC_ARG_ENABLE([opencl_icd],
 682    [AS_HELP_STRING([--enable-opencl-icd],
 683           [Build an OpenCL ICD library to be loaded by an ICD implementation
 684            @<:@default=no@:>@])],
 685     [enable_opencl_icd="$enableval"],
 686     [enable_opencl_icd=no])
 687 AC_ARG_ENABLE([xlib-glx],
 688     [AS_HELP_STRING([--enable-xlib-glx],
 689         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 690     [enable_xlib_glx="$enableval"],
 691     [enable_xlib_glx=no])
 692 AC_ARG_ENABLE([gallium-egl],
 693     [AS_HELP_STRING([--enable-gallium-egl],
 694         [enable optional EGL state tracker (not required
 695          for EGL support in Gallium with OpenGL and OpenGL ES)
 696          @<:@default=disable@:>@])],
 697     [enable_gallium_egl="$enableval"],
 698     [enable_gallium_egl=no])
 699 AC_ARG_ENABLE([gallium-gbm],
 700     [AS_HELP_STRING([--enable-gallium-gbm],
 701         [enable optional gbm state tracker (not required for
 702          gbm support in Gallium)
 703          @<:@default=auto@:>@])],
 704     [enable_gallium_gbm="$enableval"],
 705     [enable_gallium_gbm=auto])
 706
 707 AC_ARG_ENABLE([r600-llvm-compiler],
 708     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 709         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 710     [enable_r600_llvm="$enableval"],
 711     [enable_r600_llvm=no])
 712
 713 AC_ARG_ENABLE([gallium-tests],
 714     [AS_HELP_STRING([--enable-gallium-tests],
 715         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 716     [enable_gallium_tests="$enableval"],
 717     [enable_gallium_tests=no])
 718
 719 # Option for Gallium drivers
 720
 721 # Keep this in sync with the --with-gallium-drivers help string default value
 722 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 723
 724 AC_ARG_WITH([gallium-drivers],
 725     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 726         [comma delimited Gallium drivers list, e.g.
 727         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 728         @<:@default=r300,r600,svga,swrast@:>@])],
 729     [with_gallium_drivers="$withval"],
 730     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 731
 732 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 733 # here so that the script doesn't choke on an unknown driver name later.
 734 case "$with_gallium_drivers" in
 735     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 736     no) with_gallium_drivers='' ;;
 737 esac
 738
 739 if test "x$enable_opengl" = xno -a \
 740         "x$enable_gles1" = xno -a \
 741         "x$enable_gles2" = xno -a \
 742         "x$enable_openvg" = xno -a \
 743         "x$enable_xa" = xno -a \
 744         "x$enable_xvmc" = xno -a \
 745         "x$enable_vdpau" = xno -a \
 746         "x$enable_omx" = xno -a \
 747         "x$enable_opencl" = xno; then
 748     AC_MSG_ERROR([at least one API should be enabled])
 749 fi
 750
 751 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 752 if test "x$enable_opengl" = xno -a \
 753         "x$enable_gles1" = xyes; then
 754     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 755 fi
 756
 757 if test "x$enable_opengl" = xno -a \
 758         "x$enable_gles2" = xyes; then
 759     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 760 fi
 761
 762 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 763 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 764 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 765 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 766                                         "x$enable_gles1" = xyes -o \
 767                                         "x$enable_gles2" = xyes)
 768
 769 if test "x$enable_glx" = xno; then
 770     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 771     enable_xlib_glx=no
 772 fi
 773
 774 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 775     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 776 fi
 777
 778 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 779     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 780 fi
 781
 782 # Disable GLX if OpenGL is not enabled
 783 if test "x$enable_glx$enable_opengl" = xyesno; then
 784     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 785     enable_glx=no
 786 fi
 787
 788 # Disable GLX if DRI and Xlib-GLX are not enabled
 789 if test "x$enable_glx" = xyes -a \
 790         "x$enable_dri" = xno -a \
 791         "x$enable_xlib_glx" = xno; then
 792     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 793     enable_glx=no
 794 fi
 795
 796 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 797                                   "x$enable_dri" = xyes)
 798
 799 # Select which platform-dependent DRI code gets built
 800 case "$host_os" in
 801 darwin*)
 802     dri_platform='apple' ;;
 803 gnu*|mingw*|cygwin*)
 804     dri_platform='none' ;;
 805 *)
 806     dri_platform='drm' ;;
 807 esac
 808
 809 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 810 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 811 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 812 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 813 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 814
 815 AC_ARG_ENABLE([shared-glapi],
 816     [AS_HELP_STRING([--enable-shared-glapi],
 817         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 818     [enable_shared_glapi="$enableval"],
 819     [enable_shared_glapi=yes])
 820
 821 case "x$enable_opengl$enable_gles1$enable_gles2" in
 822 x*yes*yes*)
 823     if test "x$enable_shared_glapi" = xno; then
 824         AC_MSG_ERROR([shared GLAPI required when building two or more of
 825                       the following APIs - opengl, gles1 gles2])
 826     fi
 827     ;;
 828 esac
 829
 830 # Building Xlib-GLX requires shared glapi to be disabled.
 831 if test "x$enable_xlib_glx" = xyes; then
 832     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 833     enable_shared_glapi=no
 834 fi
 835
 836 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 837
 838 # Build the pipe-drivers as separate libraries/modules.
 839 # Do not touch this unless you know what you are doing.
 840 # XXX: Expose via configure option ?
 841 enable_shared_pipe_drivers=no
 842
 843 dnl
 844 dnl Driver specific build directories
 845 dnl
 846 GALLIUM_TARGET_DIRS=""
 847 GALLIUM_WINSYS_DIRS="sw"
 848 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 849 GALLIUM_STATE_TRACKERS_DIRS=""
 850
 851 case "x$enable_glx$enable_xlib_glx" in
 852 xyesyes)
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 854     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 855     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 856     NEED_WINSYS_XLIB="yes"
 857     ;;
 858 esac
 859
 860 if test "x$enable_dri" = xyes; then
 861     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 862     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 863     enable_gallium_loader="$enable_shared_pipe_drivers"
 864 fi
 865
 866 if test "x$enable_gallium_osmesa" = xyes; then
 867     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 868         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 869     fi
 870     if test "x$enable_osmesa" = xyes; then
 871         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 872     fi
 873     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 874     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 875 fi
 876
 877 AC_SUBST([MESA_LLVM])
 878
 879 # Check for libdrm
 880 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 881                   [have_libdrm=yes], [have_libdrm=no])
 882 if test "x$have_libdrm" = xyes; then
 883         DEFINES="$DEFINES -DHAVE_LIBDRM"
 884 fi
 885
 886 case "$host_os" in
 887 linux*)
 888     need_pci_id=yes ;;
 889 *)
 890     need_pci_id=no ;;
 891 esac
 892
 893 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 894                   have_libudev=yes, have_libudev=no)
 895
 896 AC_ARG_ENABLE([sysfs],
 897     [AS_HELP_STRING([--enable-sysfs],
 898         [enable /sys PCI identification @<:@default=disabled@:>@])],
 899     [have_sysfs="$enableval"],
 900     [have_sysfs=no]
 901 )
 902
 903 if test "x$enable_dri" = xyes; then
 904     if test "$enable_static" = yes; then
 905         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 906     fi
 907
 908     # not a hard requirement as swrast does not depend on it
 909     if test "x$have_libdrm" = xyes; then
 910         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 911     fi
 912 fi
 913
 914 AC_ARG_ENABLE([driglx-direct],
 915     [AS_HELP_STRING([--disable-driglx-direct],
 916         [disable direct rendering in GLX and EGL for DRI \
 917             @<:@default=auto@:>@])],
 918     [driglx_direct="$enableval"],
 919     [driglx_direct="yes"])
 920
 921 dnl
 922 dnl libGL configuration per driver
 923 dnl
 924 case "x$enable_glx$enable_xlib_glx" in
 925 xyesyes)
 926     # Xlib-based GLX
 927     dri_modules="x11 xext xcb"
 928     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 929     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 930     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 931     GL_LIB_DEPS="$XLIBGL_LIBS"
 932     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 933     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 934     ;;
 935 xyesno)
 936     # DRI-based GLX
 937     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 938
 939     # find the DRI deps for libGL
 940     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 941
 942     if test x"$driglx_direct" = xyes; then
 943         if test x"$dri_platform" = xdrm ; then
 944             DEFINES="$DEFINES -DGLX_USE_DRM"
 945             if test "x$have_libdrm" != xyes; then
 946                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 947             fi
 948
 949             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 950             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 951             if test x"$enable_dri3" = xyes; then
 952                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 953                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 954             fi
 955
 956             if test x"$enable_dri" = xyes; then
 957                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 958             fi
 959
 960             if test x"$enable_dri3" = xyes; then
 961                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 962                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 963             fi
 964         fi
 965         if test x"$dri_platform" = xapple ; then
 966             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 967         fi
 968     fi
 969
 970     # add xf86vidmode if available
 971     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 972     if test "$HAVE_XF86VIDMODE" = yes ; then
 973         dri_modules="$dri_modules xxf86vm"
 974     fi
 975
 976     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 977     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 978     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 979     GL_LIB_DEPS="$DRIGL_LIBS"
 980
 981     # need DRM libs, $PTHREAD_LIBS, etc.
 982     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 983     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 984     ;;
 985 esac
 986
 987 have_pci_id=no
 988 if test "$have_libudev" = yes; then
 989     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 990     have_pci_id=yes
 991 fi
 992
 993 if test "$have_sysfs" = yes; then
 994     DEFINES="$DEFINES -DHAVE_SYSFS"
 995     have_pci_id=yes
 996 fi
 997
 998 # This is outside the case (above) so that it is invoked even for non-GLX
 999 # builds.
1000 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1001
1002 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1003 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1004 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1005 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1006
1007 AC_SUBST([X11_INCLUDES])
1008 AC_SUBST([GL_LIB_DEPS])
1009 AC_SUBST([GL_PC_REQ_PRIV])
1010 AC_SUBST([GL_PC_LIB_PRIV])
1011 AC_SUBST([GL_PC_CFLAGS])
1012 AC_SUBST([DRI_PC_REQ_PRIV])
1013 AC_SUBST([GLESv1_CM_LIB_DEPS])
1014 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1015 AC_SUBST([GLESv2_LIB_DEPS])
1016 AC_SUBST([GLESv2_PC_LIB_PRIV])
1017
1018 AC_SUBST([HAVE_XF86VIDMODE])
1019
1020 dnl
1021 dnl More GLX setup
1022 dnl
1023 case "x$enable_glx$enable_xlib_glx" in
1024 xyesyes)
1025     DEFINES="$DEFINES -DUSE_XSHM"
1026     ;;
1027 xyesno)
1028     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1029     if test "x$driglx_direct" = xyes; then
1030         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1031     fi
1032     ;;
1033 esac
1034
1035 dnl
1036 dnl TLS detection
1037 dnl
1038
1039 AC_ARG_ENABLE([glx-tls],
1040     [AS_HELP_STRING([--enable-glx-tls],
1041         [enable TLS support in GLX @<:@default=disabled@:>@])],
1042     [GLX_USE_TLS="$enableval"],
1043     [GLX_USE_TLS=no])
1044 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1045
1046 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1047       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1048
1049 dnl
1050 dnl More DRI setup
1051 dnl
1052 dnl Directory for DRI drivers
1053 AC_ARG_WITH([dri-driverdir],
1054     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1055         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1056     [DRI_DRIVER_INSTALL_DIR="$withval"],
1057     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1058 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1059 dnl Extra search path for DRI drivers
1060 AC_ARG_WITH([dri-searchpath],
1061     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1062         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1063     [DRI_DRIVER_SEARCH_DIR="$withval"],
1064     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1065 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1066 dnl Which drivers to build - default is chosen by platform
1067 AC_ARG_WITH([dri-drivers],
1068     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1069         [comma delimited classic DRI drivers list, e.g.
1070         "swrast,i965,radeon" @<:@default=auto@:>@])],
1071     [with_dri_drivers="$withval"],
1072     [with_dri_drivers=auto])
1073
1074 if test "x$with_dri_drivers" = xauto; then
1075     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1076         with_dri_drivers="yes"
1077     else
1078         with_dri_drivers="no"
1079     fi
1080 fi
1081 if test "x$with_dri_drivers" = xno; then
1082     with_dri_drivers=''
1083 fi
1084
1085 dnl If $with_dri_drivers is yes, drivers will be added through
1086 dnl platform checks. Set DEFINES and LIB_DEPS
1087 if test "x$enable_dri" = xyes; then
1088     # Platform specific settings and drivers to build
1089     case "$host_os" in
1090     linux*)
1091         DEFINES="$DEFINES -DHAVE_ALIAS"
1092         if test "x$enable_dri3" = xyes; then
1093             DEFINES="$DEFINES -DHAVE_DRI3"
1094         fi
1095
1096         if test "x$have_pci_id" != xyes; then
1097             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1098         fi
1099
1100         case "$host_cpu" in
1101         powerpc* | sparc*)
1102             # Build only the drivers for cards that exist on PowerPC/sparc
1103             if test "x$with_dri_drivers" = "xyes"; then
1104                 with_dri_drivers="r200 radeon swrast"
1105             fi
1106             ;;
1107         esac
1108         ;;
1109     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1110         DEFINES="$DEFINES -DHAVE_ALIAS"
1111         ;;
1112     gnu*)
1113         DEFINES="$DEFINES -DHAVE_ALIAS"
1114         ;;
1115     cygwin*)
1116         if test "x$with_dri_drivers" = "xyes"; then
1117             with_dri_drivers="swrast"
1118         fi
1119         ;;
1120     darwin*)
1121         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1122         if test "x$with_dri_drivers" = "xyes"; then
1123             with_dri_drivers="swrast"
1124         fi
1125         ;;
1126     esac
1127
1128     # default drivers
1129     if test "x$with_dri_drivers" = "xyes"; then
1130         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1131     fi
1132
1133     # Check for expat
1134     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1135     if test "x$have_expat" = "xyes"; then
1136        PKG_CHECK_MODULES([EXPAT], [expat], [],
1137                          AC_MSG_ERROR([Expat required for DRI.]))
1138     else
1139        # expat version 2.0 and earlier do not provide expat.pc
1140        EXPAT_LIBS=-lexpat
1141     fi
1142
1143     DRICOMMON_NEED_LIBDRM=no
1144     # If we are building any DRI driver other than swrast.
1145     if test -n "$with_dri_drivers"; then
1146         if test "x$with_dri_drivers" != xswrast; then
1147             # ... libdrm is required
1148             if test "x$have_libdrm" != xyes; then
1149                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1150             fi
1151             DRICOMMON_NEED_LIBDRM=yes
1152         fi
1153     fi
1154
1155     # If we're building any gallium DRI driver other than swrast
1156     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1157         if test "x$with_gallium_drivers" != xswrast; then
1158             # ... build a libdrm aware dricommon
1159             DRICOMMON_NEED_LIBDRM=yes
1160         fi
1161     fi
1162
1163     # put all the necessary libs together
1164     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1165 fi
1166
1167 AC_SUBST([DRI_LIB_DEPS])
1168
1169 DRI_DIRS=''
1170 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1171 if test -n "$with_dri_drivers"; then
1172     if test "x$enable_opengl" != xyes; then
1173         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1174     fi
1175
1176     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1177     for driver in $dri_drivers; do
1178         DRI_DIRS="$DRI_DIRS $driver"
1179         case "x$driver" in
1180         xi915)
1181             HAVE_I915_DRI=yes;
1182             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1183             ;;
1184         xi965)
1185             HAVE_I965_DRI=yes;
1186             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1187             ;;
1188         xnouveau)
1189             HAVE_NOUVEAU_DRI=yes;
1190             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1191             ;;
1192         xradeon)
1193             HAVE_RADEON_DRI=yes;
1194             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1195             ;;
1196         xr200)
1197             HAVE_R200_DRI=yes;
1198             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1199             ;;
1200         xswrast)
1201             HAVE_SWRAST_DRI=yes;
1202             ;;
1203         *)
1204             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1205             ;;
1206         esac
1207     done
1208     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1209 fi
1210
1211 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1212 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1213                                   "x$enable_osmesa" = xyes -o \
1214                                   -n "$DRI_DIRS")
1215
1216 dnl
1217 dnl OSMesa configuration
1218 dnl
1219
1220 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1221 AC_ARG_WITH([osmesa-bits],
1222     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1223         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1224     [osmesa_bits="$withval"],
1225     [osmesa_bits=8])
1226 if test "x$osmesa_bits" != x8; then
1227     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1228         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1229         osmesa_bits=8
1230     fi
1231 fi
1232 case "x$osmesa_bits" in
1233 x8)
1234     OSMESA_LIB="${OSMESA_LIB}"
1235     ;;
1236 x16|x32)
1237     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1238     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1239     ;;
1240 *)
1241     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1242     ;;
1243 esac
1244
1245 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1246     # only link libraries with osmesa if shared
1247     if test "$enable_static" = no; then
1248         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1249     else
1250         OSMESA_LIB_DEPS=""
1251     fi
1252     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1253 fi
1254
1255 AC_SUBST([OSMESA_LIB_DEPS])
1256 AC_SUBST([OSMESA_PC_REQ])
1257 AC_SUBST([OSMESA_PC_LIB_PRIV])
1258
1259 dnl
1260 dnl gbm configuration
1261 dnl
1262 if test "x$enable_gbm" = xauto; then
1263     case "$with_egl_platforms" in
1264         *drm*)
1265             enable_gbm=yes ;;
1266          *)
1267             enable_gbm=no ;;
1268     esac
1269 fi
1270 if test "x$enable_gbm" = xyes; then
1271     if test "x$need_pci_id$have_pci_id" = xyesno; then
1272         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1273     fi
1274
1275     if test "x$enable_dri" = xyes; then
1276         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1277         if test "x$enable_shared_glapi" = xno; then
1278             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1279         fi
1280     else
1281         # Strictly speaking libgbm does not require --enable-dri, although
1282         # both of its backends do. Thus one can build libgbm without any
1283         # backends if --disable-dri is set.
1284         # To avoid unnecessary complexity of checking if at least one backend
1285         # is available when building, just mandate --enable-dri.
1286         AC_MSG_ERROR([gbm requires --enable-dri])
1287     fi
1288 fi
1289 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1290 if test "x$need_pci_id$have_libudev" = xyesyes; then
1291     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1292 else
1293     GBM_PC_REQ_PRIV=""
1294 fi
1295 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1296 AC_SUBST([GBM_PC_REQ_PRIV])
1297 AC_SUBST([GBM_PC_LIB_PRIV])
1298
1299 dnl
1300 dnl EGL configuration
1301 dnl
1302 EGL_CLIENT_APIS=""
1303
1304 if test "x$enable_egl" = xyes; then
1305     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1306
1307     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1308
1309     if test "$enable_static" != yes; then
1310         if test "x$enable_dri" = xyes; then
1311             HAVE_EGL_DRIVER_DRI2=1
1312         fi
1313
1314     fi
1315 fi
1316 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1317 AC_SUBST([EGL_LIB_DEPS])
1318
1319 dnl
1320 dnl EGL Gallium configuration
1321 dnl
1322 if test "x$enable_gallium_egl" = xyes; then
1323     if test -z "$with_gallium_drivers"; then
1324         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1325     fi
1326     if test "x$enable_egl" = xno; then
1327         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1328     fi
1329     if test "x$have_libdrm" != xyes; then
1330         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1331     fi
1332
1333     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1334     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1335 # XXX: Uncomment once converted to use static/shared pipe-drivers
1336 #    enable_gallium_loader=$enable_shared_pipe_drivers
1337 fi
1338 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1339
1340 dnl
1341 dnl gbm Gallium configuration
1342 dnl
1343 if test "x$enable_gallium_gbm" = xauto; then
1344     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1345         yesyesyes*drm*)
1346             enable_gallium_gbm=yes ;;
1347          *)
1348             enable_gallium_gbm=no ;;
1349     esac
1350 fi
1351 if test "x$enable_gallium_gbm" = xyes; then
1352     if test -z "$with_gallium_drivers"; then
1353         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1354     fi
1355     if test "x$enable_gbm" = xno; then
1356         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1357     fi
1358
1359     if test "x$enable_gallium_egl" != xyes; then
1360         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1361     fi
1362
1363     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1364     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1365     enable_gallium_loader=$enable_shared_pipe_drivers
1366 fi
1367 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1368
1369 dnl
1370 dnl XA configuration
1371 dnl
1372 if test "x$enable_xa" = xyes; then
1373     if test "x$with_gallium_drivers" = xswrast; then
1374        AC_MSG_ERROR([
1375           Building xa requires at least one non swrast gallium driver.
1376           If you are looking to use libxatracker.so with the VMware driver,
1377           make sure to include svga in the gallium drivers list, apart from
1378           enabling XA.
1379           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1380     fi
1381     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1382     enable_gallium_loader=$enable_shared_pipe_drivers
1383 fi
1384 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1385
1386 dnl
1387 dnl OpenVG configuration
1388 dnl
1389 VG_LIB_DEPS=""
1390
1391 if test "x$enable_openvg" = xyes; then
1392     if test "x$enable_egl" = xno; then
1393         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1394     fi
1395     if test -z "$with_gallium_drivers"; then
1396         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1397     fi
1398     if test "x$enable_gallium_egl" = xno; then
1399         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1400     fi
1401
1402     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1403     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1404     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1405     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1406     AC_SUBST([VG_PC_LIB_PRIV])
1407 fi
1408 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1409
1410 dnl
1411 dnl Gallium G3DVL configuration
1412 dnl
1413 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1414     if test "x$enable_xvmc" = xauto; then
1415         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1416     fi
1417
1418     if test "x$enable_vdpau" = xauto; then
1419         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1420     fi
1421
1422     if test "x$enable_omx" = xauto; then
1423         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1424     fi
1425 fi
1426
1427 if test "x$enable_xvmc" = xyes; then
1428     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1429     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1430     enable_gallium_loader=$enable_shared_pipe_drivers
1431 fi
1432 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1433
1434 if test "x$enable_vdpau" = xyes; then
1435     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1436                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1437     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1438     enable_gallium_loader=$enable_shared_pipe_drivers
1439 fi
1440 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1441
1442 if test "x$enable_omx" = xyes; then
1443     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1444     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1445     enable_gallium_loader=$enable_shared_pipe_drivers
1446 fi
1447 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1448
1449 dnl
1450 dnl OpenCL configuration
1451 dnl
1452
1453 AC_ARG_WITH([libclc-path],
1454    [AS_HELP_STRING([--with-libclc-path],
1455          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1456    [LIBCLC_PATH="$withval"],
1457    [LIBCLC_PATH=''])
1458
1459 if test -n "$LIBCLC_PATH"; then
1460    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1461                   Please review the updated build instructions for clover:
1462                   http://dri.freedesktop.org/wiki/GalliumCompute])
1463 fi
1464
1465
1466 AC_ARG_WITH([clang-libdir],
1467    [AS_HELP_STRING([--with-clang-libdir],
1468          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1469    [CLANG_LIBDIR="$withval"],
1470    [CLANG_LIBDIR=''])
1471
1472 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1473
1474 if test "x$enable_opencl" = xyes; then
1475     if test -z "$with_gallium_drivers"; then
1476         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1477     fi
1478
1479     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1480         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1481     fi
1482
1483     if test "x$have_libclc" = xno; then
1484         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1485                     Make sure the directory containing libclc.pc is specified in your
1486                     PKG_CONFIG_PATH environment variable.
1487                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1488     else
1489         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1490         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1491         AC_SUBST([LIBCLC_INCLUDEDIR])
1492         AC_SUBST([LIBCLC_LIBEXECDIR])
1493     fi
1494
1495     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1496     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1497     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1498     enable_gallium_loader=yes
1499
1500     if test "x$enable_opencl_icd" = xyes; then
1501         OPENCL_LIBNAME="MesaOpenCL"
1502     else
1503         OPENCL_LIBNAME="OpenCL"
1504     fi
1505 fi
1506 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1507 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1508 AC_SUBST([OPENCL_LIBNAME])
1509
1510 dnl
1511 dnl Gallium configuration
1512 dnl
1513 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1514
1515 AC_SUBST([LLVM_BINDIR])
1516 AC_SUBST([LLVM_CFLAGS])
1517 AC_SUBST([LLVM_CPPFLAGS])
1518 AC_SUBST([LLVM_CXXFLAGS])
1519 AC_SUBST([LLVM_LIBDIR])
1520 AC_SUBST([LLVM_LIBS])
1521 AC_SUBST([LLVM_LDFLAGS])
1522 AC_SUBST([LLVM_INCLUDEDIR])
1523 AC_SUBST([LLVM_VERSION])
1524 AC_SUBST([CLANG_RESOURCE_DIR])
1525
1526 case "x$enable_opengl$enable_gles1$enable_gles2" in
1527 x*yes*)
1528     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1529     ;;
1530 esac
1531
1532 AC_SUBST([VG_LIB_DEPS])
1533 AC_SUBST([EGL_CLIENT_APIS])
1534
1535 dnl
1536 dnl EGL Platforms configuration
1537 dnl
1538 AC_ARG_WITH([egl-platforms],
1539     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1540         [comma delimited native platforms libEGL supports, e.g.
1541         "x11,drm" @<:@default=auto@:>@])],
1542     [with_egl_platforms="$withval"],
1543     [if test "x$enable_egl" = xyes; then
1544         with_egl_platforms="x11"
1545     else
1546         with_egl_platforms=""
1547     fi])
1548
1549 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1550     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1551 fi
1552
1553 # Do per-EGL platform setups and checks
1554 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1555 for plat in $egl_platforms; do
1556         case "$plat" in
1557         wayland)
1558                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1559                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1560
1561                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1562                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1563                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1564                 ;;
1565
1566         x11)
1567                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1568                 ;;
1569
1570         drm)
1571                 test "x$enable_gbm" = "xno" &&
1572                         AC_MSG_ERROR([EGL platform drm needs gbm])
1573                 test "x$have_libdrm" != xyes &&
1574                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1575                 ;;
1576
1577         android|fbdev|gdi|null)
1578                 ;;
1579
1580         *)
1581                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1582                 ;;
1583         esac
1584
1585         case "$plat$need_pci_id$have_pci_id" in
1586                 waylandyesno|drmyesno)
1587                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1588         esac
1589 done
1590
1591 # libEGL wants to default to the first platform specified in
1592 # ./configure.  parse that here.
1593 if test "x$egl_platforms" != "x"; then
1594     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1595     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1596 else
1597     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1598 fi
1599
1600 if echo "$egl_platforms" | grep -q 'x11'; then
1601     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1602     NEED_WINSYS_XLIB=yes
1603 fi
1604 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1605 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1608 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1609
1610 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1611
1612 AC_SUBST([EGL_NATIVE_PLATFORM])
1613 AC_SUBST([EGL_CFLAGS])
1614
1615 # If we don't have the X11 platform, set this define so we don't try to include
1616 # the X11 headers.
1617 if ! echo "$egl_platforms" | grep -q 'x11'; then
1618     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1619     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1620 fi
1621
1622 AC_ARG_WITH([egl-driver-dir],
1623     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1624                     [directory for EGL drivers @<:@default=${libdir}/egl@:>@])],
1625     [EGL_DRIVER_INSTALL_DIR="$withval"],
1626     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1627 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1628
1629 AC_ARG_WITH([max-width],
1630     [AS_HELP_STRING([--with-max-width=N],
1631                     [Maximum framebuffer width (4096)])],
1632     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1633      AS_IF([test "${withval}" -gt "4096"],
1634            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1635 )
1636 AC_ARG_WITH([max-height],
1637     [AS_HELP_STRING([--with-max-height=N],
1638                     [Maximum framebuffer height (4096)])],
1639     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1640      AS_IF([test "${withval}" -gt "4096"],
1641            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1642 )
1643
1644 dnl
1645 dnl Gallium LLVM
1646 dnl
1647 AC_ARG_ENABLE([gallium-llvm],
1648     [AS_HELP_STRING([--enable-gallium-llvm],
1649         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1650     [enable_gallium_llvm="$enableval"],
1651     [enable_gallium_llvm=auto])
1652
1653 AC_ARG_ENABLE([llvm-shared-libs],
1654     [AS_HELP_STRING([--enable-llvm-shared-libs],
1655         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1656     [enable_llvm_shared_libs="$enableval"],
1657     [enable_llvm_shared_libs=yes])
1658
1659 AC_ARG_WITH([llvm-prefix],
1660     [AS_HELP_STRING([--with-llvm-prefix],
1661         [Prefix for LLVM installations in non-standard locations])],
1662     [llvm_prefix="$withval"],
1663     [llvm_prefix=''])
1664
1665
1666 # Call this inside ` ` to get the return value.
1667 # $1 is the llvm-config command with arguments.
1668 strip_unwanted_llvm_flags() {
1669     # Use \> (marks the end of the word)
1670     echo `$1` | sed \
1671         -e 's/-DNDEBUG\>//g' \
1672         -e 's/-D_GNU_SOURCE\>//g' \
1673         -e 's/-pedantic\>//g' \
1674         -e 's/-Wcovered-switch-default\>//g' \
1675         -e 's/-O.\>//g' \
1676         -e 's/-g\>//g' \
1677         -e 's/-Wall\>//g' \
1678         -e 's/-Wcast-qual\>//g' \
1679         -e 's/-Woverloaded-virtual\>//g' \
1680         -e 's/-fcolor-diagnostics\>//g' \
1681         -e 's/-fdata-sections\>//g' \
1682         -e 's/-ffunction-sections\>//g' \
1683         -e 's/-fno-exceptions\>//g' \
1684         -e 's/-fomit-frame-pointer\>//g' \
1685         -e 's/-fvisibility-inlines-hidden\>//g' \
1686         -e 's/-fPIC\>//g' \
1687         -e 's/-fstack-protector-strong\>//g'
1688 }
1689
1690
1691 if test -z "$with_gallium_drivers"; then
1692     enable_gallium_llvm=no
1693 fi
1694 if test "x$enable_gallium_llvm" = xauto; then
1695     case "$host_cpu" in
1696     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1697     esac
1698 fi
1699 if test "x$enable_gallium_llvm" = xyes; then
1700     if test -n "$llvm_prefix"; then
1701         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1702     else
1703         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1704     fi
1705
1706     if test "x$LLVM_CONFIG" != xno; then
1707         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1708         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1709         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1710         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1711         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1712         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1713         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1714         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1715
1716         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1717             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1718         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1719             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1720
1721         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1722         dnl llvm-config.h
1723         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1724             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1725             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1726
1727         if test -n "${LLVM_VERSION_MAJOR}"; then
1728             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1729         else
1730             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1731         fi
1732
1733         LLVM_REQUIRED_VERSION_MAJOR="3"
1734         LLVM_REQUIRED_VERSION_MINOR="1"
1735         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1736             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1737         fi
1738
1739         LLVM_COMPONENTS="engine bitwriter"
1740         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1741             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1742         fi
1743
1744         if test "x$enable_opencl" = xyes; then
1745             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1746             # LLVM 3.3 >= 177971 requires IRReader
1747             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1748                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1749             fi
1750             # LLVM 3.4 requires Option
1751             if $LLVM_CONFIG --components | grep -qw 'option'; then
1752                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1753             fi
1754             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1755             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1756                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1757             fi
1758             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1759                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1760             fi
1761         fi
1762         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1763         MESA_LLVM=1
1764
1765         dnl Check for Clang internal headers
1766         if test "x$enable_opencl" = xyes; then
1767             if test -z "$CLANG_LIBDIR"; then
1768                 CLANG_LIBDIR=${LLVM_LIBDIR}
1769             fi
1770             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1771             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1772                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1773         fi
1774     else
1775         MESA_LLVM=0
1776         LLVM_VERSION_INT=0
1777     fi
1778 else
1779     MESA_LLVM=0
1780     LLVM_VERSION_INT=0
1781
1782     if test "x$enable_opencl" = xyes; then
1783         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1784     fi
1785 fi
1786
1787 dnl Directory for XVMC libs
1788 AC_ARG_WITH([xvmc-libdir],
1789     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1790         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1791     [XVMC_LIB_INSTALL_DIR="$withval"],
1792     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1793 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1794
1795 dnl
1796 dnl Gallium Tests
1797 dnl
1798 if test "x$enable_gallium_tests" = xyes; then
1799     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1800     enable_gallium_loader=yes
1801 fi
1802 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1803
1804 if test "x$enable_gallium_loader" = xyes; then
1805     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1806 fi
1807
1808 dnl Directory for VDPAU libs
1809 AC_ARG_WITH([vdpau-libdir],
1810     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1811         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1812     [VDPAU_LIB_INSTALL_DIR="$withval"],
1813     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1814 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1815
1816 OMX_LIB_INSTALL_DIR_DEFAULT=''
1817 if test "x$enable_omx" = xyes; then
1818     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1819 fi
1820
1821 AC_ARG_WITH([omx-libdir],
1822     [AS_HELP_STRING([--with-omx-libdir=DIR],
1823         [directory for the OMX libraries])],
1824     [OMX_LIB_INSTALL_DIR="$withval"],
1825     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1826 AC_SUBST([OMX_LIB_INSTALL_DIR])
1827
1828 dnl Directory for OpenCL libs
1829 AC_ARG_WITH([opencl-libdir],
1830     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1831         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1832     [OPENCL_LIB_INSTALL_DIR="$withval"],
1833     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1834 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1835
1836 dnl
1837 dnl Gallium helper functions
1838 dnl
1839 gallium_check_st() {
1840     if test "x$have_libdrm" != xyes; then
1841        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1842     fi
1843     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $2"
1844
1845     if test "x$enable_dri" = xyes -a -n "$3"; then
1846          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1847     fi
1848     if test "x$enable_xa" = xyes -a -n "$4"; then
1849          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1850     fi
1851     if test "x$enable_xvmc" = xyes -a -n "$5"; then
1852          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1853     fi
1854     if test "x$enable_vdpau" = xyes -a -n "$6"; then
1855          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1856     fi
1857     if test "x$enable_omx" = xyes -a "x$7" != x; then
1858          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1859     fi
1860 }
1861
1862 gallium_require_llvm() {
1863     if test "x$MESA_LLVM" = x0; then
1864         case "$host" in *gnux32) return;; esac
1865         case "$host_cpu" in
1866         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1867         esac
1868     fi
1869 }
1870
1871 gallium_require_drm_loader() {
1872     if test "x$enable_gallium_loader" = xyes; then
1873         if test "x$need_pci_id$have_pci_id" = xyesno; then
1874             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1875         fi
1876         if test "x$have_libdrm" != xyes; then
1877             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1878         fi
1879         enable_gallium_drm_loader=yes
1880     fi
1881 }
1882
1883 require_egl_drm() {
1884     case "$with_egl_platforms" in
1885         *drm*)
1886             ;;
1887          *)
1888             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1889             ;;
1890     esac
1891     if test "x$enable_gbm" != xyes; then
1892             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1893     fi
1894 }
1895
1896 radeon_llvm_check() {
1897     if test "x$enable_gallium_llvm" != "xyes"; then
1898         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1899     fi
1900     LLVM_REQUIRED_VERSION_MAJOR="3"
1901     LLVM_REQUIRED_VERSION_MINOR="4"
1902     LLVM_REQUIRED_VERSION_PATCH="2"
1903     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1904         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1905     fi
1906     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1907         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1908                       sources with the --enable-experimental-targets=R600
1909                       configure flag])
1910     fi
1911     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1912     NEED_RADEON_LLVM=yes
1913     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1914                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1915 }
1916
1917 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1918 if test -n "$with_gallium_drivers"; then
1919     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1920     for driver in $gallium_drivers; do
1921         case "x$driver" in
1922         xsvga)
1923             HAVE_GALLIUM_SVGA=yes
1924             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1925             gallium_require_drm_loader
1926             gallium_check_st "svga" "svga/drm" "dri/vmwgfx" "xa/vmwgfx"
1927             ;;
1928         xi915)
1929             HAVE_GALLIUM_I915=yes
1930             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1931             gallium_require_drm_loader
1932             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1933             gallium_check_st "Gallium i915" "i915/drm" "dri/i915" "xa/i915"
1934             ;;
1935         xilo)
1936             HAVE_GALLIUM_ILO=yes
1937             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1938             gallium_require_drm_loader
1939             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1940             gallium_check_st "Gallium i965/ilo" "intel/drm" "dri/ilo" "xa/ilo"
1941             ;;
1942         xr300)
1943             HAVE_GALLIUM_R300=yes
1944             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1945             gallium_require_drm_loader
1946             gallium_require_llvm "Gallium R300"
1947             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1948             gallium_check_st "Gallium R300" "radeon/drm" "dri/r300"
1949             ;;
1950         xr600)
1951             HAVE_GALLIUM_R600=yes
1952             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1953             gallium_require_drm_loader
1954             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1955             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1956                 radeon_llvm_check "r600g"
1957                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1958             fi
1959             if test "x$enable_r600_llvm" = xyes; then
1960                 USE_R600_LLVM_COMPILER=yes;
1961             fi
1962             if test "x$enable_opencl" = xyes; then
1963                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1964             fi
1965             gallium_check_st "Gallium R600" "radeon/drm" "dri/r600" "" "xvmc/r600" "vdpau/r600" "omx/r600"
1966             ;;
1967         xradeonsi)
1968             HAVE_GALLIUM_RADEONSI=yes
1969             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1970             gallium_require_drm_loader
1971             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1972             radeon_llvm_check "radeonsi"
1973             require_egl_drm "radeonsi"
1974             gallium_check_st "radeonsi" "radeon/drm" "dri/radeonsi" "" "" "vdpau/radeonsi" "omx/radeonsi"
1975             ;;
1976         xnouveau)
1977             HAVE_GALLIUM_NOUVEAU=yes
1978             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1979             gallium_require_drm_loader
1980             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1981             gallium_check_st "nouveau" "nouveau/drm" "dri/nouveau" "xa/nouveau" "xvmc/nouveau" "vdpau/nouveau" "omx/nouveau"
1982             ;;
1983         xfreedreno)
1984             HAVE_GALLIUM_FREEDRENO=yes
1985             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1986             gallium_require_drm_loader
1987             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1988             gallium_check_st "freedreno" "freedreno/drm" "dri/freedreno" "xa/freedreno" "" ""
1989             ;;
1990         xswrast)
1991             HAVE_GALLIUM_SOFTPIPE=yes
1992             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1993             if test "x$MESA_LLVM" = x1; then
1994                 HAVE_GALLIUM_LLVMPIPE=yes
1995                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1996             fi
1997
1998             if test "x$enable_dri" = xyes; then
1999                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/swrast"
2000             fi
2001
2002             if test "x$have_libdrm" = xyes; then
2003                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/kms-dri"
2004                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri/kms-swrast"
2005             fi
2006             ;;
2007         xvc4)
2008             HAVE_GALLIUM_VC4=yes
2009             gallium_require_drm_loader
2010             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS vc4"
2011             gallium_check_st "vc4" "vc4/drm" "dri-vc4" "" "" ""
2012
2013             case "$host_cpu" in
2014                 i?86 | x86_64 | amd64)
2015                 USE_VC4_SIMULATOR=yes
2016                 ;;
2017             esac
2018             ;;
2019         *)
2020             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2021             ;;
2022         esac
2023     done
2024 fi
2025
2026 dnl Set LLVM_LIBS - This is done after the driver configuration so
2027 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2028 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2029 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2030 dnl this was causing the same libraries to be appear multiple times
2031 dnl in LLVM_LIBS.
2032
2033 if test "x$MESA_LLVM" != x0; then
2034
2035     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2036
2037     if test "x$enable_llvm_shared_libs" = xyes; then
2038         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2039         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2040         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2041
2042         if test "x$llvm_have_one_so" = xyes; then
2043             dnl LLVM was built using auto*, so there is only one shared object.
2044             LLVM_LIBS="-l$LLVM_SO_NAME"
2045         else
2046             dnl If LLVM was built with CMake, there will be one shared object per
2047             dnl component.
2048             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2049                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2050         Please make sure you have built llvm with the --enable-shared option
2051         and that your llvm libraries are installed in $LLVM_LIBDIR
2052         If you have installed your llvm libraries to a different directory you
2053         can use the --with-llvm-prefix= configure flag to specify this directory.
2054         NOTE: Mesa is attempting to use llvm shared libraries by default.
2055         If you do not want to build with llvm shared libraries and instead want to
2056         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2057         invocation and rebuild.])])
2058
2059            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2060            dnl install uses a shared object for each compoenent and we have
2061            dnl already added all of these objects to LLVM_LIBS.
2062         fi
2063     else
2064         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2065     fi
2066 fi
2067
2068 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2069 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2070 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2071 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2072 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2073 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2075                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2076 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2077 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2078 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2079 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2080 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2081
2082 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2083
2084 # NOTE: anything using xcb or other client side libs ends up in separate
2085 #       _CLIENT variables.  The pipe loader is built in two variants,
2086 #       one that is standalone and does not link any x client libs (for
2087 #       use by XA tracker in particular, but could be used in any case
2088 #       where communication with xserver is not desired).
2089 if test "x$enable_gallium_loader" = xyes; then
2090     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2091
2092     if test "x$NEED_WINSYS_XLIB" = xyes; then
2093         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2094     fi
2095
2096     if test "x$enable_dri" = xyes; then
2097         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2098     fi
2099
2100     if test "x$enable_gallium_drm_loader" = xyes; then
2101         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2102         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2103                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2104         if test "x$pipe_loader_have_xcb" = xyes; then
2105             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2106             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2107         fi
2108     fi
2109
2110     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2111     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2112
2113     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2114     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2115     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2116     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2117 fi
2118
2119 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2120 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2121 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2122 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2123 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2124 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2125
2126 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2127                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2128                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2129 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2130 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2131 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2132 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2133 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2134 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2135 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2136 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2137 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2138     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2139 fi
2140
2141 AC_SUBST([ELF_LIB])
2142
2143 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2144 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2145 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2146 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2147 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2148
2149 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2150 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2151 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2152
2153 AC_SUBST([VDPAU_MAJOR], 1)
2154 AC_SUBST([VDPAU_MINOR], 0)
2155
2156 AC_SUBST([XVMC_MAJOR], 1)
2157 AC_SUBST([XVMC_MINOR], 0)
2158
2159 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2160 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2161 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2162 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2163
2164 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2165 AC_SUBST([XA_MINOR], $XA_MINOR)
2166 AC_SUBST([XA_TINY], $XA_TINY)
2167 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2168
2169 dnl Restore LDFLAGS and CPPFLAGS
2170 LDFLAGS="$_SAVE_LDFLAGS"
2171 CPPFLAGS="$_SAVE_CPPFLAGS"
2172
2173 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2174 if test "x$acv_mesa_CLANG" = xyes; then
2175     CFLAGS="$CFLAGS -Qunused-arguments"
2176     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2177 fi
2178
2179 dnl Add user CFLAGS and CXXFLAGS
2180 CFLAGS="$CFLAGS $USER_CFLAGS"
2181 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2182
2183 dnl Substitute the config
2184 AC_CONFIG_FILES([Makefile
2185                 src/Makefile
2186                 src/egl/drivers/dri2/Makefile
2187                 src/egl/main/Makefile
2188                 src/egl/main/egl.pc
2189                 src/egl/wayland/Makefile
2190                 src/egl/wayland/wayland-drm/Makefile
2191                 src/egl/wayland/wayland-egl/Makefile
2192                 src/egl/wayland/wayland-egl/wayland-egl.pc
2193                 src/gallium/Makefile
2194                 src/gallium/auxiliary/Makefile
2195                 src/gallium/auxiliary/pipe-loader/Makefile
2196                 src/gallium/drivers/freedreno/Makefile
2197                 src/gallium/drivers/galahad/Makefile
2198                 src/gallium/drivers/i915/Makefile
2199                 src/gallium/drivers/identity/Makefile
2200                 src/gallium/drivers/ilo/Makefile
2201                 src/gallium/drivers/llvmpipe/Makefile
2202                 src/gallium/drivers/noop/Makefile
2203                 src/gallium/drivers/nouveau/Makefile
2204                 src/gallium/drivers/r300/Makefile
2205                 src/gallium/drivers/r600/Makefile
2206                 src/gallium/drivers/radeon/Makefile
2207                 src/gallium/drivers/radeonsi/Makefile
2208                 src/gallium/drivers/rbug/Makefile
2209                 src/gallium/drivers/softpipe/Makefile
2210                 src/gallium/drivers/svga/Makefile
2211                 src/gallium/drivers/trace/Makefile
2212                 src/gallium/drivers/vc4/Makefile
2213                 src/gallium/state_trackers/clover/Makefile
2214                 src/gallium/state_trackers/dri/Makefile
2215                 src/gallium/state_trackers/egl/Makefile
2216                 src/gallium/state_trackers/gbm/Makefile
2217                 src/gallium/state_trackers/glx/xlib/Makefile
2218                 src/gallium/state_trackers/omx/Makefile
2219                 src/gallium/state_trackers/osmesa/Makefile
2220                 src/gallium/state_trackers/vdpau/Makefile
2221                 src/gallium/state_trackers/vega/Makefile
2222                 src/gallium/state_trackers/xa/Makefile
2223                 src/gallium/state_trackers/xvmc/Makefile
2224                 src/gallium/targets/dri/Makefile
2225                 src/gallium/targets/egl-static/Makefile
2226                 src/gallium/targets/gbm/Makefile
2227                 src/gallium/targets/libgl-xlib/Makefile
2228                 src/gallium/targets/omx/Makefile
2229                 src/gallium/targets/opencl/Makefile
2230                 src/gallium/targets/osmesa/Makefile
2231                 src/gallium/targets/osmesa/osmesa.pc
2232                 src/gallium/targets/pipe-loader/Makefile
2233                 src/gallium/targets/vdpau/Makefile
2234                 src/gallium/targets/xa/Makefile
2235                 src/gallium/targets/xa/xatracker.pc
2236                 src/gallium/targets/xvmc/Makefile
2237                 src/gallium/tests/trivial/Makefile
2238                 src/gallium/tests/unit/Makefile
2239                 src/gallium/winsys/freedreno/drm/Makefile
2240                 src/gallium/winsys/i915/drm/Makefile
2241                 src/gallium/winsys/intel/drm/Makefile
2242                 src/gallium/winsys/nouveau/drm/Makefile
2243                 src/gallium/winsys/radeon/drm/Makefile
2244                 src/gallium/winsys/svga/drm/Makefile
2245                 src/gallium/winsys/sw/dri/Makefile
2246                 src/gallium/winsys/sw/fbdev/Makefile
2247                 src/gallium/winsys/sw/kms-dri/Makefile
2248                 src/gallium/winsys/sw/null/Makefile
2249                 src/gallium/winsys/sw/wayland/Makefile
2250                 src/gallium/winsys/sw/wrapper/Makefile
2251                 src/gallium/winsys/sw/xlib/Makefile
2252                 src/gallium/winsys/vc4/drm/Makefile
2253                 src/gbm/Makefile
2254                 src/gbm/main/gbm.pc
2255                 src/glsl/Makefile
2256                 src/glx/Makefile
2257                 src/glx/apple/Makefile
2258                 src/glx/tests/Makefile
2259                 src/gtest/Makefile
2260                 src/loader/Makefile
2261                 src/mapi/Makefile
2262                 src/mapi/es1api/glesv1_cm.pc
2263                 src/mapi/es2api/glesv2.pc
2264                 src/mapi/glapi/gen/Makefile
2265                 src/mapi/vgapi/Makefile
2266                 src/mapi/vgapi/vg.pc
2267                 src/mesa/Makefile
2268                 src/mesa/gl.pc
2269                 src/mesa/drivers/dri/dri.pc
2270                 src/mesa/drivers/dri/common/Makefile
2271                 src/mesa/drivers/dri/common/xmlpool/Makefile
2272                 src/mesa/drivers/dri/i915/Makefile
2273                 src/mesa/drivers/dri/i965/Makefile
2274                 src/mesa/drivers/dri/Makefile
2275                 src/mesa/drivers/dri/nouveau/Makefile
2276                 src/mesa/drivers/dri/r200/Makefile
2277                 src/mesa/drivers/dri/radeon/Makefile
2278                 src/mesa/drivers/dri/swrast/Makefile
2279                 src/mesa/drivers/osmesa/Makefile
2280                 src/mesa/drivers/osmesa/osmesa.pc
2281                 src/mesa/drivers/x11/Makefile
2282                 src/mesa/main/tests/Makefile
2283                 src/util/Makefile
2284                 src/util/tests/hash_table/Makefile])
2285
2286 dnl Sort the dirs alphabetically
2287 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2288 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2289 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2290 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2291
2292 AC_OUTPUT
2293
2294 dnl
2295 dnl Output some configuration info for the user
2296 dnl
2297 echo ""
2298 echo "        prefix:          $prefix"
2299 echo "        exec_prefix:     $exec_prefix"
2300 echo "        libdir:          $libdir"
2301 echo "        includedir:      $includedir"
2302
2303 dnl API info
2304 echo ""
2305 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2306 echo "        OpenVG:          $enable_openvg"
2307
2308 dnl Driver info
2309 echo ""
2310 case "x$enable_osmesa$enable_gallium_osmesa" in
2311 xnoyes)
2312         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2313         ;;
2314 xyesno)
2315         echo "        OSMesa:          lib$OSMESA_LIB"
2316         ;;
2317 xnono)
2318         echo "        OSMesa:          no"
2319         ;;
2320 esac
2321
2322 echo ""
2323 if test "x$enable_dri" != xno; then
2324         echo "        DRI platform:    $dri_platform"
2325         if test -z "$DRI_DIRS"; then
2326             echo "        DRI drivers:     no"
2327         else
2328             echo "        DRI drivers:     $DRI_DIRS"
2329         fi
2330         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2331 fi
2332
2333 case "x$enable_glx$enable_xlib_glx" in
2334 xyesyes)
2335     echo "        GLX:             Xlib-based"
2336     ;;
2337 xyesno)
2338     echo "        GLX:             DRI-based"
2339     ;;
2340 *)
2341     echo "        GLX:             $enable_glx"
2342     ;;
2343 esac
2344
2345 dnl EGL
2346 echo ""
2347 echo "        EGL:             $enable_egl"
2348 if test "$enable_egl" = yes; then
2349     echo "        EGL platforms:   $egl_platforms"
2350
2351     egl_drivers=""
2352     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2353         egl_drivers="$egl_drivers builtin:egl_dri2"
2354     fi
2355
2356     if test "x$enable_gallium_egl" = xyes; then
2357         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2358         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2359     else
2360         echo "        EGL drivers:    $egl_drivers"
2361     fi
2362 fi
2363
2364 echo ""
2365 if test "x$MESA_LLVM" = x1; then
2366     echo "        llvm:            yes"
2367     echo "        llvm-config:     $LLVM_CONFIG"
2368     echo "        llvm-version:    $LLVM_VERSION"
2369 else
2370     echo "        llvm:            no"
2371 fi
2372
2373 echo ""
2374 if test -n "$with_gallium_drivers"; then
2375     echo "        Gallium:         yes"
2376     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2377     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2378     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2379     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2380 else
2381     echo "        Gallium:         no"
2382 fi
2383
2384
2385 dnl Libraries
2386 echo ""
2387 echo "        Shared libs:     $enable_shared"
2388 echo "        Static libs:     $enable_static"
2389 echo "        Shared-glapi:    $enable_shared_glapi"
2390
2391 dnl Compiler options
2392 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2393 cflags=`echo $CFLAGS | \
2394     $SED 's/^ *//;s/  */ /;s/ *$//'`
2395 cxxflags=`echo $CXXFLAGS | \
2396     $SED 's/^ *//;s/  */ /;s/ *$//'`
2397 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2398 echo ""
2399 echo "        CFLAGS:          $cflags"
2400 echo "        CXXFLAGS:        $cxxflags"
2401 echo "        Macros:          $defines"
2402 echo ""
2403 if test "x$MESA_LLVM" = x1; then
2404     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2405     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2406     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2407     echo ""
2408 fi
2409 echo "        PYTHON2:         $PYTHON2"
2410
2411 echo ""
2412 echo "        Run '${MAKE-make}' to build Mesa"
2413 echo ""