configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 dnl Set internal versions
  28 OSMESA_VERSION=8
  29 AC_SUBST([OSMESA_VERSION])
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.42
  34 LIBDRM_INTEL_REQUIRED=2.4.38
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_CXX
  47 AX_PROG_CXX_FOR_BUILD
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AX_PYTHON_MODULE([libxml2], [needed])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([disable-static])
  58
  59 AX_PROG_BISON([],
  60               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  61                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  62 AX_PROG_FLEX([],
  63              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  64                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  65
  66 AC_PATH_PROG([PERL], [perl])
  67
  68 AC_CHECK_PROG(INDENT, indent, indent, cat)
  69 if test "x$INDENT" != "xcat"; then
  70     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  71 fi
  72
  73 AC_PROG_INSTALL
  74
  75 dnl We need a POSIX shell for parts of the build. Assume we have one
  76 dnl in most cases.
  77 case "$host_os" in
  78 solaris*)
  79     # Solaris /bin/sh is too old/non-POSIX compliant
  80     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  81     SHELL="$POSIX_SHELL"
  82     ;;
  83 esac
  84
  85 dnl clang is mostly GCC-compatible, but its version is much lower,
  86 dnl so we have to check for it.
  87 AC_MSG_CHECKING([if compiling with clang])
  88
  89 AC_COMPILE_IFELSE(
  90 [AC_LANG_PROGRAM([], [[
  91 #ifndef __clang__
  92        not clang
  93 #endif
  94 ]])],
  95 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  96
  97 AC_MSG_RESULT([$acv_mesa_CLANG])
  98
  99 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 100 dnl versions are explictly not supported.
 101 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 102     AC_MSG_CHECKING([whether gcc version is sufficient])
 103     major=0
 104     minor=0
 105
 106     GCC_VERSION=`$CC -dumpversion`
 107     if test $? -eq 0; then
 108         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 109         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 110     fi
 111
 112     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 113         AC_MSG_RESULT([no])
 114         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 115     else
 116         AC_MSG_RESULT([yes])
 117     fi
 118 fi
 119
 120 dnl Make sure the pkg-config macros are defined
 121 m4_ifndef([PKG_PROG_PKG_CONFIG],
 122     [m4_fatal([Could not locate the pkg-config autoconf macros.
 123   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 124   are in a different location, try setting the environment variable
 125   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 126 PKG_PROG_PKG_CONFIG()
 127
 128 dnl LIB_DIR - library basename
 129 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 130 AC_SUBST([LIB_DIR])
 131
 132 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 133 _SAVE_LDFLAGS="$LDFLAGS"
 134 _SAVE_CPPFLAGS="$CPPFLAGS"
 135
 136 dnl build host compiler macros
 137 DEFINES_FOR_BUILD=""
 138 AC_SUBST([DEFINES_FOR_BUILD])
 139 case "$build_os" in
 140 linux*|*-gnu*|gnu*)
 141     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 142     ;;
 143 solaris*)
 144     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 145     ;;
 146 cygwin*)
 147     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 148     ;;
 149 esac
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 174         CFLAGS="$CFLAGS -Wall -std=c99"
 175         ;;
 176     esac
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 204     CFLAGS="$CFLAGS -fno-strict-aliasing"
 205
 206     # gcc's builtin memcmp is slower than glibc's
 207     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 208     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 213     CXXFLAGS="$CXXFLAGS -Wall"
 214
 215     # Enable -fvisibility=hidden if using a gcc that supports it
 216     save_CXXFLAGS="$CXXFLAGS"
 217     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 218     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 219     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 220     AC_LANG_PUSH([C++])
 221     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 222                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 223     AC_LANG_POP([C++])
 224
 225     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 226     CXXFLAGS=$save_CXXFLAGS
 227
 228     # Work around aliasing bugs - developers should comment this out
 229     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 235     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 236 fi
 237
 238 dnl even if the compiler appears to support it, using visibility attributes isn't
 239 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 240 case "$host_os" in
 241 cygwin*)
 242     VISIBILITY_CFLAGS=""
 243     VISIBILITY_CXXFLAGS=""
 244     ;;
 245 esac
 246
 247 AC_SUBST([VISIBILITY_CFLAGS])
 248 AC_SUBST([VISIBILITY_CXXFLAGS])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes )
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono )
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 293     enable_static=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 310     if test "x$GCC_FOR_BUILD" = xyes; then
 311         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 312     fi
 313     if test "x$GXX_FOR_BUILD" = xyes; then
 314         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 315     fi
 316
 317     DEFINES="$DEFINES -DDEBUG"
 318     if test "x$GCC" = xyes; then
 319         CFLAGS="$CFLAGS -g -O0"
 320     fi
 321     if test "x$GXX" = xyes; then
 322         CXXFLAGS="$CXXFLAGS -g -O0"
 323     fi
 324 fi
 325
 326 dnl
 327 dnl library names
 328 dnl
 329 LIB_PREFIX_GLOB='lib'
 330 LIB_VERSION_SEPARATOR='.'
 331 if test "$enable_static" = yes; then
 332     LIB_EXTENSION='a'
 333 else
 334     case "$host_os" in
 335     darwin* )
 336         LIB_EXTENSION='dylib' ;;
 337     cygwin* )
 338         dnl prefix can be 'cyg' or 'lib'
 339         LIB_PREFIX_GLOB='???'
 340         LIB_VERSION_SEPARATOR='-'
 341         LIB_EXTENSION='dll' ;;
 342     aix* )
 343         LIB_EXTENSION='a' ;;
 344     * )
 345         LIB_EXTENSION='so' ;;
 346     esac
 347 fi
 348 AC_ARG_WITH([gl-lib-name],
 349   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 350     [specify GL library name @<:@default=GL@:>@])],
 351   [GL_LIB=$withval],
 352   [GL_LIB=GL])
 353 AC_ARG_WITH([osmesa-lib-name],
 354   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 355     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 356   [OSMESA_LIB=$withval],
 357   [OSMESA_LIB=OSMesa])
 358 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 359 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 360
 361 dnl
 362 dnl Mangled Mesa support
 363 dnl
 364 AC_ARG_ENABLE([mangling],
 365   [AS_HELP_STRING([--enable-mangling],
 366     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 367   [enable_mangling="${enableval}"],
 368   [enable_mangling=no]
 369 )
 370 if test "x${enable_mangling}" = "xyes" ; then
 371   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 372   GL_LIB="Mangled${GL_LIB}"
 373   OSMESA_LIB="Mangled${OSMESA_LIB}"
 374 fi
 375 AC_SUBST([GL_LIB])
 376 AC_SUBST([OSMESA_LIB])
 377
 378 dnl
 379 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 380 dnl
 381 AC_ARG_ENABLE([texture-float],
 382     [AS_HELP_STRING([--enable-texture-float],
 383         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 384     [enable_texture_float="$enableval"],
 385     [enable_texture_float=no]
 386 )
 387 if test "x$enable_texture_float" = xyes; then
 388     AC_MSG_WARN([Floating-point textures enabled.])
 389     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 390     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 391 fi
 392
 393 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 394 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 395 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 396 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 397 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 398 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 399 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 400
 401 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408
 409 AC_SUBST([GL_LIB_NAME])
 410 AC_SUBST([OSMESA_LIB_NAME])
 411 AC_SUBST([EGL_LIB_NAME])
 412 AC_SUBST([GLESv1_CM_LIB_NAME])
 413 AC_SUBST([GLESv2_LIB_NAME])
 414 AC_SUBST([VG_LIB_NAME])
 415 AC_SUBST([GLAPI_LIB_NAME])
 416
 417 AC_SUBST([GL_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl Check to see if dlopen is in default libraries (like Solaris, which
 496 dnl has it in libc), or if libdl is needed to get it.
 497 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 498     [AC_CHECK_LIB([dl], [dlopen],
 499        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 500 AC_SUBST([DLOPEN_LIBS])
 501
 502 case "$host_os" in
 503 darwin*|mingw*)
 504     ;;
 505 *)
 506     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 507                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 508                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 509     AC_SUBST([CLOCK_LIB])
 510     ;;
 511 esac
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl Check for pthreads
 517 AX_PTHREAD
 518 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 519 dnl to -pthread, which causes problems if we need -lpthread to appear in
 520 dnl pkgconfig files.
 521 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 522
 523 dnl SELinux awareness.
 524 AC_ARG_ENABLE([selinux],
 525     [AS_HELP_STRING([--enable-selinux],
 526         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 527     [MESA_SELINUX="$enableval"],
 528     [MESA_SELINUX=no])
 529 if test "x$enable_selinux" = "xyes"; then
 530     AC_CHECK_HEADER([selinux/selinux.h],[],
 531                     [AC_MSG_ERROR([SELinux headers not found])])
 532     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 533                  [AC_MSG_ERROR([SELinux library not found])])
 534     SELINUX_LIBS="-lselinux"
 535     DEFINES="$DEFINES -DMESA_SELINUX"
 536 fi
 537 AC_SUBST([SELINUX_LIBS])
 538
 539 dnl Options for APIs
 540 AC_ARG_ENABLE([opengl],
 541     [AS_HELP_STRING([--disable-opengl],
 542         [disable support for standard OpenGL API @<:@default=no@:>@])],
 543     [enable_opengl="$enableval"],
 544     [enable_opengl=yes])
 545 AC_ARG_ENABLE([gles1],
 546     [AS_HELP_STRING([--enable-gles1],
 547         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 548     [enable_gles1="$enableval"],
 549     [enable_gles1=no])
 550 AC_ARG_ENABLE([gles2],
 551     [AS_HELP_STRING([--enable-gles2],
 552         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 553     [enable_gles2="$enableval"],
 554     [enable_gles2=no])
 555 AC_ARG_ENABLE([openvg],
 556     [AS_HELP_STRING([--enable-openvg],
 557         [enable support for OpenVG API @<:@default=no@:>@])],
 558     [enable_openvg="$enableval"],
 559     [enable_openvg=no])
 560
 561 AC_ARG_ENABLE([dri],
 562     [AS_HELP_STRING([--enable-dri],
 563         [enable DRI modules @<:@default=enabled@:>@])],
 564     [enable_dri="$enableval"],
 565     [enable_dri=yes])
 566 AC_ARG_ENABLE([glx],
 567     [AS_HELP_STRING([--enable-glx],
 568         [enable GLX library @<:@default=enabled@:>@])],
 569     [enable_glx="$enableval"],
 570     [enable_glx=yes])
 571 AC_ARG_ENABLE([osmesa],
 572     [AS_HELP_STRING([--enable-osmesa],
 573         [enable OSMesa library @<:@default=disabled@:>@])],
 574     [enable_osmesa="$enableval"],
 575     [enable_osmesa=no])
 576 AC_ARG_ENABLE([egl],
 577     [AS_HELP_STRING([--disable-egl],
 578         [disable EGL library @<:@default=enabled@:>@])],
 579     [enable_egl="$enableval"],
 580     [enable_egl=yes])
 581
 582 AC_ARG_ENABLE([xorg],
 583     [AS_HELP_STRING([--enable-xorg],
 584         [enable support for X.Org DDX API @<:@default=no@:>@])],
 585     [enable_xorg="$enableval"],
 586     [enable_xorg=no])
 587 AC_ARG_ENABLE([xa],
 588     [AS_HELP_STRING([--enable-xa],
 589         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 590     [enable_xa="$enableval"],
 591     [enable_xa=no])
 592 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 593 enable_d3d1x=no
 594 dnl AC_ARG_ENABLE([d3d1x],
 595 dnl     [AS_HELP_STRING([--enable-d3d1x],
 596 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 597 dnl     [enable_d3d1x="$enableval"],
 598 dnl     [enable_d3d1x=no])
 599 AC_ARG_ENABLE([gbm],
 600    [AS_HELP_STRING([--enable-gbm],
 601          [enable gbm library @<:@default=auto@:>@])],
 602    [enable_gbm="$enableval"],
 603    [enable_gbm=auto])
 604
 605 AC_ARG_ENABLE([xvmc],
 606    [AS_HELP_STRING([--enable-xvmc],
 607          [enable xvmc library @<:@default=auto@:>@])],
 608    [enable_xvmc="$enableval"],
 609    [enable_xvmc=auto])
 610 AC_ARG_ENABLE([vdpau],
 611    [AS_HELP_STRING([--enable-vdpau],
 612          [enable vdpau library @<:@default=auto@:>@])],
 613    [enable_vdpau="$enableval"],
 614    [enable_vdpau=auto])
 615 AC_ARG_ENABLE([opencl],
 616    [AS_HELP_STRING([--enable-opencl],
 617          [enable OpenCL library NOTE: Enabling this option will also enable
 618           --with-llvm-shared-libs
 619           @<:@default=no@:>@])],
 620    [],
 621    [enable_opencl=no])
 622 AC_ARG_ENABLE([xlib_glx],
 623     [AS_HELP_STRING([--enable-xlib-glx],
 624         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 625     [enable_xlib_glx="$enableval"],
 626     [enable_xlib_glx=no])
 627 AC_ARG_ENABLE([gallium_egl],
 628     [AS_HELP_STRING([--enable-gallium-egl],
 629         [enable optional EGL state tracker (not required
 630          for EGL support in Gallium with OpenGL and OpenGL ES)
 631          @<:@default=disable@:>@])],
 632     [enable_gallium_egl="$enableval"],
 633     [enable_gallium_egl=no])
 634 AC_ARG_ENABLE([gallium_gbm],
 635     [AS_HELP_STRING([--enable-gallium-gbm],
 636         [enable optional gbm state tracker (not required for
 637          gbm support in Gallium)
 638          @<:@default=auto@:>@])],
 639     [enable_gallium_gbm="$enableval"],
 640     [enable_gallium_gbm=auto])
 641
 642 AC_ARG_ENABLE([r600-llvm-compiler],
 643     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 644         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 645     [enable_r600_llvm="$enableval"],
 646     [enable_r600_llvm=no])
 647
 648 AC_ARG_ENABLE([gallium_tests],
 649     [AS_HELP_STRING([--enable-gallium-tests],
 650         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 651     [enable_gallium_tests="$enableval"],
 652     [enable_gallium_tests=no])
 653
 654 # Option for Gallium drivers
 655
 656 # Keep this in sync with the --with-gallium-drivers help string default value
 657 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 658
 659 AC_ARG_WITH([gallium-drivers],
 660     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 661         [comma delimited Gallium drivers list, e.g.
 662         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 663         @<:@default=r300,r600,svga,swrast@:>@])],
 664     [with_gallium_drivers="$withval"],
 665     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 666
 667 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 668 # here so that the script doesn't choke on an unknown driver name later.
 669 case "$with_gallium_drivers" in
 670     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 671     no) with_gallium_drivers='' ;;
 672 esac
 673
 674 if test "x$enable_opengl" = xno -a \
 675         "x$enable_gles1" = xno -a \
 676         "x$enable_gles2" = xno -a \
 677         "x$enable_openvg" = xno -a \
 678         "x$enable_xorg" = xno -a \
 679         "x$enable_xa" = xno -a \
 680         "x$enable_d3d1x" = xno -a \
 681         "x$enable_xvmc" = xno -a \
 682         "x$enable_vdpau" = xno -a \
 683         "x$enable_opencl" = xno; then
 684     AC_MSG_ERROR([at least one API should be enabled])
 685 fi
 686
 687 API_DEFINES=""
 688 if test "x$enable_opengl" = xno; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 690 else
 691     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 692 fi
 693 if test "x$enable_gles1" = xyes; then
 694     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 695 fi
 696 if test "x$enable_gles2" = xyes; then
 697     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 698 fi
 699 AC_SUBST([API_DEFINES])
 700
 701 if test "x$enable_glx" = xno; then
 702     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 703     enable_xlib_glx=no
 704 fi
 705
 706 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 707     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 708 fi
 709
 710 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 711     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 712 fi
 713
 714 # Disable GLX if OpenGL is not enabled
 715 if test "x$enable_glx$enable_opengl" = xyesno; then
 716     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 717     enable_glx=no
 718 fi
 719
 720 # Disable GLX if DRI and Xlib-GLX are not enabled
 721 if test "x$enable_glx" = xyes -a \
 722         "x$enable_dri" = xno -a \
 723         "x$enable_xlib_glx" = xno; then
 724     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 725     enable_glx=no
 726 fi
 727
 728 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 729 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 730                                   "x$enable_osmesa" = xyes)
 731
 732 AC_ARG_ENABLE([shared-glapi],
 733     [AS_HELP_STRING([--enable-shared-glapi],
 734         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 735     [enable_shared_glapi="$enableval"],
 736     [enable_shared_glapi="$enable_dri"])
 737
 738 # Shared GLAPI is only useful for DRI
 739 if test "x$enable_dri" = xno; then
 740     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 741     enable_shared_glapi=no
 742 fi
 743
 744 if test "x$enable_shared_glapi" = xyes; then
 745     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 746     # the remap table)
 747     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 748     CORE_DIRS="mapi/shared-glapi"
 749 fi
 750 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 751
 752 dnl
 753 dnl Driver specific build directories
 754 dnl
 755 GALLIUM_DIRS="auxiliary drivers state_trackers"
 756 GALLIUM_TARGET_DIRS=""
 757 GALLIUM_WINSYS_DIRS="sw"
 758 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 759 GALLIUM_STATE_TRACKERS_DIRS=""
 760
 761 # build glapi if OpenGL is enabled
 762 if test "x$enable_opengl" = xyes; then
 763     CORE_DIRS="$CORE_DIRS mapi/glapi"
 764 fi
 765
 766 # build es1api if OpenGL ES 1.x is enabled
 767 if test "x$enable_gles1" = xyes; then
 768     CORE_DIRS="$CORE_DIRS mapi/es1api"
 769 fi
 770
 771 # build es2api if OpenGL ES 2.x is enabled
 772 if test "x$enable_gles2" = xyes; then
 773     CORE_DIRS="$CORE_DIRS mapi/es2api"
 774 fi
 775
 776 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 777 case "x$enable_opengl$enable_gles1$enable_gles2" in
 778 x*yes*)
 779     CORE_DIRS="mapi/glapi/gen $CORE_DIRS gtest glsl mesa"
 780     ;;
 781 esac
 782
 783 case "x$enable_glx$enable_xlib_glx" in
 784 xyesyes)
 785     DRIVER_DIRS="$DRIVER_DIRS x11"
 786     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 787     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 788     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 789     HAVE_WINSYS_XLIB="yes"
 790     ;;
 791 xyesno)
 792     # DRI-based GLX
 793     SRC_DIRS="$SRC_DIRS glx"
 794     ;;
 795 esac
 796
 797 if test "x$enable_dri" = xyes; then
 798     DRIVER_DIRS="$DRIVER_DIRS dri"
 799
 800     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 801     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 802     HAVE_ST_DRI="yes"
 803 fi
 804
 805 if test "x$enable_osmesa" = xyes; then
 806     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 807 fi
 808
 809 AC_SUBST([SRC_DIRS])
 810 AC_SUBST([DRIVER_DIRS])
 811 AC_SUBST([GALLIUM_DIRS])
 812 AC_SUBST([GALLIUM_TARGET_DIRS])
 813 AC_SUBST([GALLIUM_WINSYS_DIRS])
 814 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 815 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 816 AC_SUBST([MESA_LLVM])
 817
 818 # Check for libdrm
 819 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 820                   [have_libdrm=yes], [have_libdrm=no])
 821
 822 if test "x$enable_dri" = xyes; then
 823     # DRI must be shared, I think
 824     if test "$enable_static" = yes; then
 825         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 826     fi
 827
 828     # not a hard requirement as swrast does not depend on it
 829     if test "x$have_libdrm" = xyes; then
 830         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 831     fi
 832 fi
 833
 834 dnl Find out if X is available.
 835 PKG_CHECK_MODULES([X11], [x11], [no_x=no], [no_x=yes])
 836
 837 dnl Try to tell the user that the --x-* options are only used when
 838 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 839 m4_divert_once([HELP_BEGIN],
 840 [These options are only used when the X libraries cannot be found by the
 841 pkg-config utility.])
 842
 843 dnl We need X for xlib and dri, so bomb now if it's not found
 844 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 845     AC_MSG_ERROR([X11 development libraries needed for GLX])
 846 fi
 847
 848 dnl Direct rendering or just indirect rendering
 849 case "$host_os" in
 850 gnu*)
 851     dnl Disable by default on GNU/Hurd
 852     driglx_direct_default="no"
 853     ;;
 854 cygwin*)
 855     dnl Disable by default on cygwin
 856     driglx_direct_default="no"
 857     ;;
 858 *)
 859     driglx_direct_default="yes"
 860     ;;
 861 esac
 862 AC_ARG_ENABLE([driglx-direct],
 863     [AS_HELP_STRING([--disable-driglx-direct],
 864         [disable direct rendering in GLX and EGL for DRI \
 865             @<:@default=auto@:>@])],
 866     [driglx_direct="$enableval"],
 867     [driglx_direct="$driglx_direct_default"])
 868
 869 dnl
 870 dnl libGL configuration per driver
 871 dnl
 872 case "x$enable_glx$enable_xlib_glx" in
 873 xyesyes)
 874     # Xlib-based GLX
 875     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 876     GL_PC_REQ_PRIV="x11 xext"
 877     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 878     GL_LIB_DEPS="$XLIBGL_LIBS"
 879     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 881     ;;
 882 xyesno)
 883     # DRI-based GLX
 884     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 885     if test x"$driglx_direct" = xyes; then
 886         if test "x$have_libdrm" != xyes; then
 887             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 888         fi
 889         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 890         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 891     fi
 892
 893     # find the DRI deps for libGL
 894     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 895
 896     # add xf86vidmode if available
 897     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 898     if test "$HAVE_XF86VIDMODE" = yes ; then
 899         dri_modules="$dri_modules xxf86vm"
 900     fi
 901
 902     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 903     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 904     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 905     GL_LIB_DEPS="$DRIGL_LIBS"
 906
 907     # need DRM libs, $PTHREAD_LIBS, etc.
 908     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 909     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 910     ;;
 911 esac
 912
 913 # This is outside the case (above) so that it is invoked even for non-GLX
 914 # builds.
 915 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 916
 917 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 918 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 919 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 920 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 921
 922 AC_SUBST([X11_INCLUDES])
 923 AC_SUBST([GL_LIB_DEPS])
 924 AC_SUBST([GL_PC_REQ_PRIV])
 925 AC_SUBST([GL_PC_LIB_PRIV])
 926 AC_SUBST([GL_PC_CFLAGS])
 927 AC_SUBST([DRI_PC_REQ_PRIV])
 928 AC_SUBST([GLESv1_CM_LIB_DEPS])
 929 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 930 AC_SUBST([GLESv2_LIB_DEPS])
 931 AC_SUBST([GLESv2_PC_LIB_PRIV])
 932
 933 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 934
 935 AC_SUBST([HAVE_XF86VIDMODE])
 936
 937 dnl
 938 dnl More GLX setup
 939 dnl
 940 case "x$enable_glx$enable_xlib_glx" in
 941 xyesyes)
 942     DEFINES="$DEFINES -DUSE_XSHM"
 943     ;;
 944 xyesno)
 945     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 946     if test "x$driglx_direct" = xyes; then
 947         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 948     fi
 949     ;;
 950 esac
 951
 952 dnl
 953 dnl TLS detection
 954 dnl
 955
 956 AC_ARG_ENABLE([glx-tls],
 957     [AS_HELP_STRING([--enable-glx-tls],
 958         [enable TLS support in GLX @<:@default=disabled@:>@])],
 959     [GLX_USE_TLS="$enableval"],
 960     [GLX_USE_TLS=no])
 961 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 962
 963 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 964       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 965
 966 dnl
 967 dnl More DRI setup
 968 dnl
 969 dnl Directory for DRI drivers
 970 AC_ARG_WITH([dri-driverdir],
 971     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 972         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 973     [DRI_DRIVER_INSTALL_DIR="$withval"],
 974     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 975 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 976 dnl Extra search path for DRI drivers
 977 AC_ARG_WITH([dri-searchpath],
 978     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 979         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 980     [DRI_DRIVER_SEARCH_DIR="$withval"],
 981     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 982 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 983 dnl Which drivers to build - default is chosen by platform
 984 AC_ARG_WITH([dri-drivers],
 985     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 986         [comma delimited DRI drivers list, e.g.
 987         "swrast,i965,radeon" @<:@default=auto@:>@])],
 988     [with_dri_drivers="$withval"],
 989     [with_dri_drivers=yes])
 990 if test "x$with_dri_drivers" = x; then
 991     with_dri_drivers=no
 992 fi
 993
 994 dnl If $with_dri_drivers is yes, directories will be added through
 995 dnl platform checks
 996 DRI_DIRS=""
 997 case "$with_dri_drivers" in
 998 no) ;;
 999 yes)
1000     # classic DRI drivers require FEATURE_GL to build
1001     if test "x$enable_opengl" = xyes; then
1002         DRI_DIRS="yes"
1003     fi
1004     ;;
1005 *)
1006     # verify the requested driver directories exist
1007     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1008     for driver in $dri_drivers; do
1009         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1010             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1011     done
1012     DRI_DIRS="$dri_drivers"
1013     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1014         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1015     fi
1016     ;;
1017 esac
1018
1019 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1020 if test "x$enable_dri" = xyes; then
1021     # Platform specific settings and drivers to build
1022     case "$host_os" in
1023     linux*)
1024         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1025         DEFINES="$DEFINES -DHAVE_ALIAS"
1026
1027         case "$host_cpu" in
1028         x86_64)
1029             if test "x$DRI_DIRS" = "xyes"; then
1030                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1031             fi
1032             ;;
1033         powerpc*)
1034             # Build only the drivers for cards that exist on PowerPC.
1035             if test "x$DRI_DIRS" = "xyes"; then
1036                 DRI_DIRS="r200 radeon swrast"
1037             fi
1038             ;;
1039         sparc*)
1040             # Build only the drivers for cards that exist on sparc
1041             if test "x$DRI_DIRS" = "xyes"; then
1042                 DRI_DIRS="r200 radeon swrast"
1043             fi
1044             ;;
1045         esac
1046         ;;
1047     freebsd* | dragonfly* | *netbsd*)
1048         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1049         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1050
1051         if test "x$DRI_DIRS" = "xyes"; then
1052             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1053         fi
1054         ;;
1055     gnu*)
1056         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1057         DEFINES="$DEFINES -DHAVE_ALIAS"
1058         ;;
1059     solaris*)
1060         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1061         ;;
1062     cygwin*)
1063         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1064         if test "x$DRI_DIRS" = "xyes"; then
1065             DRI_DIRS="swrast"
1066         fi
1067         ;;
1068     esac
1069
1070     # default drivers
1071     if test "x$DRI_DIRS" = "xyes"; then
1072         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1073     fi
1074
1075     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1076
1077     # Check for expat
1078     if test "x$enable_dri" = xyes; then
1079         EXPAT_INCLUDES=""
1080         EXPAT_LIB=-lexpat
1081         AC_ARG_WITH([expat],
1082             [AS_HELP_STRING([--with-expat=DIR],
1083                 [expat install directory])],[
1084             EXPAT_INCLUDES="-I$withval/include"
1085             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1086             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1087             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1088             ])
1089         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1090         save_LIBS="$LIBS"
1091         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1092             [AC_MSG_ERROR([Expat required for DRI.])])
1093         LIBS="$save_LIBS"
1094     fi
1095
1096     # if we are building any dri driver other than swrast or using the dri state tracker ...
1097     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast || test "x$enable_dri" = xyes; then
1098         # ... libdrm is required
1099         if test "x$have_libdrm" != xyes; then
1100             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1101         fi
1102         # ... and build dricommon
1103         HAVE_COMMON_DRI=yes
1104     fi
1105
1106     # put all the necessary libs together
1107     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1108     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1109 fi
1110 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1111 AC_SUBST([DRI_DIRS])
1112 AC_SUBST([EXPAT_INCLUDES])
1113 AC_SUBST([DRI_LIB_DEPS])
1114 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1115
1116 case $DRI_DIRS in
1117 *i915*|*i965*)
1118     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1119
1120     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1121         case $d in
1122         i915)
1123             HAVE_I915_DRI=yes;
1124             ;;
1125         i965)
1126             HAVE_I965_DRI=yes;
1127             ;;
1128         esac
1129     done
1130
1131     ;;
1132 esac
1133
1134 case $DRI_DIRS in
1135 *nouveau*)
1136     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1137     HAVE_NOUVEAU_DRI=yes;
1138     ;;
1139 esac
1140
1141 case $DRI_DIRS in
1142 *radeon*|*r200*)
1143     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1144
1145     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1146         case $d in
1147         radeon)
1148             HAVE_RADEON_DRI=yes;
1149             ;;
1150         r200)
1151             HAVE_R200_DRI=yes;
1152             ;;
1153         esac
1154     done
1155
1156     ;;
1157 esac
1158
1159 case $DRI_DIRS in
1160 *swrast*)
1161     HAVE_SWRAST_DRI=yes;
1162     ;;
1163 esac
1164
1165 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1166 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1167 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1168 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1169 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1170 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1171 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1172
1173 dnl
1174 dnl OSMesa configuration
1175 dnl
1176
1177 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1178 AC_ARG_WITH([osmesa-bits],
1179     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1180         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1181     [osmesa_bits="$withval"],
1182     [osmesa_bits=8])
1183 if test "x$osmesa_bits" != x8; then
1184     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1185         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1186         osmesa_bits=8
1187     fi
1188 fi
1189 case "x$osmesa_bits" in
1190 x8)
1191     OSMESA_LIB="${OSMESA_LIB}"
1192     ;;
1193 x16|x32)
1194     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1195     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1196     ;;
1197 *)
1198     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1199     ;;
1200 esac
1201
1202 if test "x$enable_osmesa" = xyes; then
1203     # only link libraries with osmesa if shared
1204     if test "$enable_static" = no; then
1205         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1206     else
1207         OSMESA_LIB_DEPS=""
1208     fi
1209     OSMESA_MESA_DEPS=""
1210     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1211 fi
1212
1213 AC_SUBST([OSMESA_LIB_DEPS])
1214 AC_SUBST([OSMESA_MESA_DEPS])
1215 AC_SUBST([OSMESA_PC_REQ])
1216 AC_SUBST([OSMESA_PC_LIB_PRIV])
1217
1218 dnl
1219 dnl gbm configuration
1220 dnl
1221 if test "x$enable_gbm" = xauto; then
1222     case "$with_egl_platforms" in
1223         *drm*)
1224             enable_gbm=yes ;;
1225          *)
1226             enable_gbm=no ;;
1227     esac
1228 fi
1229 if test "x$enable_gbm" = xyes; then
1230     SRC_DIRS="$SRC_DIRS gbm"
1231
1232     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1233                       AC_MSG_ERROR([gbm needs udev]))
1234
1235     if test "x$enable_dri" = xyes; then
1236         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1237         if test "x$enable_shared_glapi" = xno; then
1238             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1239         fi
1240     fi
1241 fi
1242 GBM_PC_REQ_PRIV="libudev"
1243 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1244 AC_SUBST([GBM_PC_REQ_PRIV])
1245 AC_SUBST([GBM_PC_LIB_PRIV])
1246
1247 dnl
1248 dnl EGL configuration
1249 dnl
1250 EGL_CLIENT_APIS=""
1251
1252 if test "x$enable_egl" = xyes; then
1253     SRC_DIRS="$SRC_DIRS egl"
1254     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1255
1256     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1257
1258     if test "$enable_static" != yes; then
1259         # build egl_glx when libGL is built
1260         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1261                           [have_libudev=yes],[have_libudev=no])
1262         if test "$have_libudev" = yes; then
1263             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1264         fi
1265
1266         if test "x$enable_dri" = xyes; then
1267             HAVE_EGL_DRIVER_DRI2=1
1268         fi
1269
1270     fi
1271 fi
1272 AC_SUBST([EGL_LIB_DEPS])
1273
1274 dnl
1275 dnl EGL Gallium configuration
1276 dnl
1277 if test "x$enable_gallium_egl" = xyes; then
1278     if test "x$with_gallium_drivers" = x; then
1279         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1280     fi
1281     if test "x$enable_egl" = xno; then
1282         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1283     fi
1284     if test "x$have_libdrm" != xyes; then
1285         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1286     fi
1287
1288     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1289     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1290     HAVE_ST_EGL="yes"
1291 fi
1292
1293 dnl
1294 dnl gbm Gallium configuration
1295 dnl
1296 if test "x$enable_gallium_gbm" = xauto; then
1297     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1298         yesyesyes*drm*)
1299             enable_gallium_gbm=yes ;;
1300          *)
1301             enable_gallium_gbm=no ;;
1302     esac
1303 fi
1304 if test "x$enable_gallium_gbm" = xyes; then
1305     if test "x$with_gallium_drivers" = x; then
1306         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1307     fi
1308     if test "x$enable_gbm" = xno; then
1309         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1310     fi
1311     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1312     if test "x$enable_dri" = xno; then
1313         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1314     fi
1315
1316     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1317     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1318     HAVE_ST_GBM="yes"
1319     enable_gallium_loader=yes
1320 fi
1321
1322 dnl
1323 dnl X.Org DDX configuration
1324 dnl
1325 if test "x$enable_xorg" = xyes; then
1326     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1327     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1328     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1329     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1330         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1331         HAVE_XEXTPROTO_71="no")
1332     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1333     HAVE_ST_XORG=yes
1334 fi
1335
1336 dnl
1337 dnl XA configuration
1338 dnl
1339 if test "x$enable_xa" = xyes; then
1340 AC_PROG_AWK
1341 AC_PROG_GREP
1342 AC_CHECK_PROG(NM, nm, "nm")
1343 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1344 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1345 enable_xa=no
1346 fi
1347 fi
1348 if test "x$enable_xa" = xyes; then
1349     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1350     HAVE_ST_XA=yes
1351     AC_SUBST(AWK)
1352     AC_SUBST(GREP)
1353     AC_SUBST(NM)
1354 fi
1355
1356 dnl
1357 dnl OpenVG configuration
1358 dnl
1359 VG_LIB_DEPS=""
1360
1361 if test "x$enable_openvg" = xyes; then
1362     if test "x$enable_egl" = xno; then
1363         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1364     fi
1365     if test "x$with_gallium_drivers" = x; then
1366         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1367     fi
1368     if test "x$enable_gallium_egl" = xno; then
1369         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1370     fi
1371
1372     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1373     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1374     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1375     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1376     HAVE_ST_VEGA=yes
1377     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1378     AC_SUBST([VG_PC_LIB_PRIV])
1379 fi
1380 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1381
1382 dnl
1383 dnl D3D1X configuration
1384 dnl
1385
1386 if test "x$enable_d3d1x" = xyes; then
1387     if test "x$with_gallium_drivers" = x; then
1388         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1389     fi
1390
1391     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1392     HAVE_ST_D3D1X=yes
1393 fi
1394
1395 dnl
1396 dnl Gallium G3DVL configuration
1397 dnl
1398 AC_ARG_ENABLE([gallium-g3dvl],
1399     [AS_HELP_STRING([--enable-gallium-g3dvl],
1400         [build gallium g3dvl @<:@default=disabled@:>@])],
1401     [enable_gallium_g3dvl="$enableval"],
1402     [enable_gallium_g3dvl=no])
1403 if test "x$enable_gallium_g3dvl" = xyes; then
1404     if test "x$with_gallium_drivers" = x; then
1405         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1406     fi
1407
1408     if test "x$enable_xvmc" = xauto; then
1409         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1410     fi
1411
1412     if test "x$enable_vdpau" = xauto; then
1413         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1414     fi
1415 fi
1416
1417 if test "x$enable_xvmc" = xyes; then
1418     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1419     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1420     HAVE_ST_XVMC="yes"
1421 fi
1422
1423 if test "x$enable_vdpau" = xyes; then
1424     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1425     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1426     HAVE_ST_VDPAU="yes"
1427 fi
1428
1429 dnl
1430 dnl OpenCL configuration
1431 dnl
1432
1433 AC_ARG_WITH([libclc-path],
1434    [AS_HELP_STRING([--with-libclc-path],
1435          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1436    [LIBCLC_PATH="$withval"],
1437    [LIBCLC_PATH=""])
1438
1439 if test "x$LIBCLC_PATH" != x; then
1440    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1441                   Please review the updated build instructions for clover:
1442                   http://dri.freedesktop.org/wiki/GalliumCompute])
1443 fi
1444
1445
1446 AC_ARG_WITH([clang-libdir],
1447    [AS_HELP_STRING([--with-clang-libdir],
1448          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1449    [CLANG_LIBDIR="$withval"],
1450    [CLANG_LIBDIR=""])
1451
1452 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1453 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1454 AC_SUBST([LIBCLC_INCLUDEDIR])
1455 AC_SUBST([LIBCLC_LIBEXECDIR])
1456
1457 if test "x$enable_opencl" = xyes; then
1458     if test "x$with_gallium_drivers" = x; then
1459         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1460     fi
1461
1462     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1463         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1464     fi
1465
1466     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1467         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1468     fi
1469
1470     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1471     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1472     enable_gallium_loader=yes
1473 fi
1474
1475 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1476     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1477 fi
1478
1479 dnl
1480 dnl Gallium configuration
1481 dnl
1482 if test "x$with_gallium_drivers" != x; then
1483     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1484 fi
1485 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1486
1487 AC_SUBST([LLVM_BINDIR])
1488 AC_SUBST([LLVM_CFLAGS])
1489 AC_SUBST([LLVM_CPPFLAGS])
1490 AC_SUBST([LLVM_CXXFLAGS])
1491 AC_SUBST([LLVM_LIBDIR])
1492 AC_SUBST([LLVM_LIBS])
1493 AC_SUBST([LLVM_LDFLAGS])
1494 AC_SUBST([LLVM_INCLUDEDIR])
1495 AC_SUBST([LLVM_VERSION])
1496 AC_SUBST([CLANG_RESOURCE_DIR])
1497
1498 case "x$enable_opengl$enable_gles1$enable_gles2" in
1499 x*yes*)
1500     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1501     HAVE_OPENGL=yes
1502     ;;
1503 esac
1504 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1505
1506 AC_SUBST([VG_LIB_DEPS])
1507 AC_SUBST([EGL_CLIENT_APIS])
1508
1509 dnl
1510 dnl EGL Platforms configuration
1511 dnl
1512 AC_ARG_WITH([egl-platforms],
1513     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1514         [comma delimited native platforms libEGL supports, e.g.
1515         "x11,drm" @<:@default=auto@:>@])],
1516     [with_egl_platforms="$withval"],
1517     [if test "x$enable_egl" = xyes; then
1518         with_egl_platforms="x11"
1519     else
1520         with_egl_platforms=""
1521     fi])
1522
1523 EGL_PLATFORMS=""
1524
1525 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1526     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1527 fi
1528
1529 # Do per-EGL platform setups and checks
1530 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1531 for plat in $egl_platforms; do
1532         case "$plat" in
1533         fbdev|null)
1534                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1535                 ;;
1536
1537         wayland)
1538                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1539                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1540
1541                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1542                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1543                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1544                 ;;
1545
1546         x11)
1547                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1548
1549                 if test "x$enable_glx" = xyes; then
1550                         HAVE_EGL_DRIVER_GLX=1
1551                 fi
1552                 ;;
1553
1554         drm)
1555                 test "x$enable_gbm" = "xno" &&
1556                         AC_MSG_ERROR([EGL platform drm needs gbm])
1557                 ;;
1558
1559         android|gdi)
1560                 ;;
1561
1562         *)
1563                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1564                 ;;
1565         esac
1566
1567         case "$plat$have_libudev" in
1568                 waylandno|drmno)
1569                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1570         esac
1571 done
1572
1573 # libEGL wants to default to the first platform specified in
1574 # ./configure.  parse that here.
1575 if test "x$egl_platforms" != "x"; then
1576     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1577     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1578 else
1579     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1580 fi
1581
1582 EGL_PLATFORMS="$egl_platforms"
1583
1584 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1585 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1586 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1587 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1588 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1589
1590 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1591 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1592
1593 AC_SUBST([EGL_NATIVE_PLATFORM])
1594 AC_SUBST([EGL_PLATFORMS])
1595 AC_SUBST([EGL_CFLAGS])
1596
1597 AC_ARG_WITH([egl-driver-dir],
1598     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1599                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1600     [EGL_DRIVER_INSTALL_DIR="$withval"],
1601     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1602 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1603
1604 AC_ARG_WITH([xorg-driver-dir],
1605     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1606                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1607     [XORG_DRIVER_INSTALL_DIR="$withval"],
1608     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1609 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1610
1611 AC_ARG_WITH([max-width],
1612     [AS_HELP_STRING([--with-max-width=N],
1613                     [Maximum framebuffer width (4096)])],
1614     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1615      AS_IF([test "${withval}" -gt "4096"],
1616            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1617 )
1618 AC_ARG_WITH([max-height],
1619     [AS_HELP_STRING([--with-max-height=N],
1620                     [Maximum framebuffer height (4096)])],
1621     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1622      AS_IF([test "${withval}" -gt "4096"],
1623            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1624 )
1625
1626 dnl
1627 dnl Gallium LLVM
1628 dnl
1629 AC_ARG_ENABLE([gallium-llvm],
1630     [AS_HELP_STRING([--enable-gallium-llvm],
1631         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1632     [enable_gallium_llvm="$enableval"],
1633     [enable_gallium_llvm=auto])
1634
1635 AC_ARG_WITH([llvm-shared-libs],
1636     [AS_HELP_STRING([--with-llvm-shared-libs],
1637         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1638     [],
1639     [with_llvm_shared_libs=no])
1640 AS_IF([test x$enable_opencl = xyes],
1641     [
1642         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1643         with_llvm_shared_libs=yes
1644     ])
1645
1646 AC_ARG_WITH([llvm-prefix],
1647     [AS_HELP_STRING([--with-llvm-prefix],
1648         [Prefix for LLVM installations in non-standard locations])],
1649     [llvm_prefix="$withval"],
1650     [llvm_prefix=""])
1651
1652
1653 # Call this inside ` ` to get the return value.
1654 # $1 is the llvm-config command with arguments.
1655 strip_unwanted_llvm_flags() {
1656     # Use \> (marks the end of the word)
1657     echo `$1` | sed \
1658         -e 's/-DNDEBUG\>//g' \
1659         -e 's/-pedantic\>//g' \
1660         -e 's/-Wcovered-switch-default\>//g' \
1661         -e 's/-O.\>//g' \
1662         -e 's/-g\>//g' \
1663         -e 's/-Wall\>//g' \
1664         -e 's/-fomit-frame-pointer\>//g'
1665 }
1666
1667
1668 if test "x$with_gallium_drivers" = x; then
1669     enable_gallium_llvm=no
1670 fi
1671 if test "x$enable_gallium_llvm" = xauto; then
1672     case "$host_cpu" in
1673     i*86|x86_64) enable_gallium_llvm=yes;;
1674     esac
1675 fi
1676 if test "x$enable_gallium_llvm" = xyes; then
1677     if test "x$llvm_prefix" != x; then
1678         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1679     else
1680         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1681     fi
1682
1683     if test "x$LLVM_CONFIG" != xno; then
1684         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1685         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1686         LLVM_COMPONENTS="engine bitwriter"
1687         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1688             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1689         fi
1690
1691         if test "x$enable_opencl" = xyes; then
1692             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1693         fi
1694         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1695         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1696         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1697         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1698         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1699         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1700         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1701         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1702         MESA_LLVM=1
1703
1704         dnl Check for Clang interanl headers
1705         if test "x$enable_opencl" = xyes; then
1706             if test "x$CLANG_LIBDIR" = x; then
1707                 CLANG_LIBDIR=${LLVM_LIBDIR}
1708             fi
1709             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1710             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1711                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1712         fi
1713     else
1714         MESA_LLVM=0
1715         LLVM_VERSION_INT=0
1716     fi
1717 else
1718     MESA_LLVM=0
1719     LLVM_VERSION_INT=0
1720 fi
1721
1722 dnl Directory for XVMC libs
1723 AC_ARG_WITH([xvmc-libdir],
1724     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1725         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1726     [XVMC_LIB_INSTALL_DIR="$withval"],
1727     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1728 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1729
1730 dnl
1731 dnl Gallium Tests
1732 dnl
1733 if test "x$enable_gallium_tests" = xyes; then
1734     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1735     enable_gallium_loader=yes
1736 fi
1737
1738 dnl Directory for VDPAU libs
1739 AC_ARG_WITH([vdpau-libdir],
1740     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1741         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1742     [VDPAU_LIB_INSTALL_DIR="$withval"],
1743     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1744 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1745
1746 dnl Directory for OpenCL libs
1747 AC_ARG_WITH([opencl-libdir],
1748     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1749         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1750     [OPENCL_LIB_INSTALL_DIR="$withval"],
1751     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1752 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1753
1754 dnl
1755 dnl Gallium helper functions
1756 dnl
1757 gallium_check_st() {
1758     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1759          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1760          test "x$HAVE_ST_VDPAU" = xyes; then
1761          if test "x$have_libdrm" != xyes; then
1762             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1763          fi
1764          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1765     fi
1766     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1767          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1768     fi
1769     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1770          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1771     fi
1772     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1773          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1774     fi
1775     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1776          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1777     fi
1778     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1779          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1780     fi
1781 }
1782
1783 gallium_require_llvm() {
1784     if test "x$MESA_LLVM" = x0; then
1785         case "$host_cpu" in
1786         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1787         esac
1788     fi
1789 }
1790
1791 gallium_require_drm_loader() {
1792     if test "x$enable_gallium_loader" = xyes; then
1793         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1794                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1795         if test "x$have_libdrm" != xyes; then
1796             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1797         fi
1798         enable_gallium_drm_loader=yes
1799     fi
1800 }
1801
1802 radeon_llvm_check() {
1803     LLVM_REQUIRED_VERSION_MAJOR="3"
1804     LLVM_REQUIRED_VERSION_MINOR="2"
1805     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1806         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1807                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1808                      git://people.freedesktop.org/~tstellar/llvm master
1809                      and build with --enable-experimental-targets=R600])
1810     fi
1811     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1812         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1813                       sources with the --enable-experimental-targets=R600
1814                       configure flag])
1815     fi
1816     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1817     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600"
1818 }
1819
1820 dnl Gallium drivers
1821 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1822 if test "x$with_gallium_drivers" != x; then
1823     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1824     for driver in $gallium_drivers; do
1825         case "x$driver" in
1826         xsvga)
1827             HAVE_GALLIUM_SVGA=yes
1828             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1829             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1830             ;;
1831         xi915)
1832             HAVE_GALLIUM_I915=yes
1833             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1834             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1835             if test "x$MESA_LLVM" = x1; then
1836                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1837             fi
1838             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1839             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1840             ;;
1841         xr300)
1842             HAVE_GALLIUM_R300=yes
1843             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1844             gallium_require_llvm "Gallium R300"
1845             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1846             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1847             ;;
1848         xr600)
1849             HAVE_GALLIUM_R600=yes
1850             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1851             gallium_require_drm_loader
1852             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1853             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1854                 radeon_llvm_check
1855                 NEED_RADEON_GALLIUM=yes;
1856                 R600_NEED_RADEON_GALLIUM=yes;
1857                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1858             fi
1859             if test "x$enable_r600_llvm" = xyes; then
1860                 USE_R600_LLVM_COMPILER=yes;
1861             fi
1862             if test "x$enable_opencl" = xyes; then
1863                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1864             fi
1865             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1866             ;;
1867         xradeonsi)
1868             HAVE_GALLIUM_RADEONSI=yes
1869             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1870             gallium_require_drm_loader
1871             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1872             radeon_llvm_check
1873             NEED_RADEON_GALLIUM=yes;
1874             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1875             ;;
1876         xnouveau)
1877             HAVE_GALLIUM_NOUVEAU=yes
1878             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1879             gallium_require_drm_loader
1880             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1881             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1882             ;;
1883         xswrast)
1884             HAVE_GALLIUM_SOFTPIPE=yes
1885             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1886             if test "x$MESA_LLVM" = x1; then
1887                 HAVE_GALLIUM_LLVMPIPE=yes
1888                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1889             fi
1890
1891             if test "x$HAVE_ST_DRI" = xyes; then
1892                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1893             fi
1894             if test "x$HAVE_ST_VDPAU" = xyes; then
1895                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1896             fi
1897             if test "x$HAVE_ST_XVMC" = xyes; then
1898                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1899             fi
1900             if test "x$HAVE_ST_VDPAU" = xyes ||
1901                test "x$HAVE_ST_XVMC" = xyes; then
1902                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1903                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1904                fi
1905             fi
1906             ;;
1907         *)
1908             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1909             ;;
1910         esac
1911     done
1912 fi
1913
1914 dnl Set LLVM_LIBS - This is done after the driver configuration so
1915 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1916 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1917 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1918 dnl this was causing the same libraries to be appear multiple times
1919 dnl in LLVM_LIBS.
1920
1921 if test "x$MESA_LLVM" != x0; then
1922
1923     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1924
1925     if test "x$with_llvm_shared_libs" = xyes; then
1926         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1927         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1928         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1929
1930         if test "x$llvm_have_one_so" = xyes; then
1931             dnl LLVM was built using auto*, so there is only one shared object.
1932             LLVM_LIBS="-l$LLVM_SO_NAME"
1933         else
1934             dnl If LLVM was built with CMake, there will be one shared object per
1935             dnl component.
1936             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1937                     AC_MSG_ERROR([Could not find llvm shared libraries:
1938         Please make sure you have built llvm with the --enable-shared option
1939         and that your llvm libraries are installed in $LLVM_LIBDIR
1940         If you have installed your llvm libraries to a different directory you
1941         can use the --with-llvm-prefix= configure flag to specify this directory.
1942         NOTE: Mesa is attempting to use llvm shared libraries because you have
1943         passed one of the following options to configure:
1944                 --with-llvm-shared-libs
1945                 --enable-opencl
1946         If you do not want to build with llvm shared libraries and instead want to
1947         use llvm static libraries then remove these options from your configure
1948         invocation and reconfigure.]))
1949
1950            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1951            dnl install uses a shared object for each compoenent and we have
1952            dnl already added all of these objects to LLVM_LIBS.
1953         fi
1954     fi
1955 fi
1956
1957 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1958 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1959 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1960 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1961 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1962 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1963 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1964 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1965
1966 if test "x$enable_gallium_loader" = xyes; then
1967     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1968     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1969     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1970     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1971
1972     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1973         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1974         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1975     fi
1976
1977     if test "x$enable_gallium_drm_loader" = xyes; then
1978         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1979         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1980                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1981         if test "x$pipe_loader_have_xcb" = xyes; then
1982             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1983             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1984         fi
1985     fi
1986
1987     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1988     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1989 fi
1990
1991 dnl Tell Automake which drivers to build
1992 for driver in $GALLIUM_DRIVERS_DIRS; do
1993     case "x$driver" in
1994         xgalahad)
1995             HAVE_GALAHAD_GALLIUM=yes;
1996             ;;
1997         xidentity)
1998             HAVE_IDENTITY_GALLIUM=yes;
1999             ;;
2000         xnoop)
2001             HAVE_NOOP_GALLIUM=yes;
2002             ;;
2003         *)
2004             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2005             ;;
2006     esac
2007 done
2008
2009 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2010 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2011 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2012 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2013 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
2014 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2015 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2016 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2017 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2018 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2019 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
2020
2021 AC_SUBST([GALLIUM_MAKE_DIRS])
2022
2023 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
2024                                      "x$enable_xlib_glx" = xyes -o \
2025                                      "x$enable_osmesa" = xyes)
2026 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2027
2028 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2029 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2030 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2031
2032 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
2033
2034 AC_SUBST([VDPAU_MAJOR], 1)
2035 AC_SUBST([VDPAU_MINOR], 0)
2036
2037 AC_SUBST([XVMC_MAJOR], 1)
2038 AC_SUBST([XVMC_MINOR], 0)
2039
2040 AC_SUBST([XA_MAJOR], 1)
2041 AC_SUBST([XA_MINOR], 0)
2042 AC_SUBST([XA_TINY], 0)
2043 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2044
2045 dnl prepend CORE_DIRS to SRC_DIRS
2046 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2047
2048 dnl Restore LDFLAGS and CPPFLAGS
2049 LDFLAGS="$_SAVE_LDFLAGS"
2050 CPPFLAGS="$_SAVE_CPPFLAGS"
2051
2052 dnl Add user CFLAGS and CXXFLAGS
2053 CFLAGS="$CFLAGS $USER_CFLAGS"
2054 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2055
2056 dnl Substitute the config
2057 AC_CONFIG_FILES([Makefile
2058                 src/Makefile
2059                 src/egl/Makefile
2060                 src/egl/drivers/Makefile
2061                 src/egl/drivers/dri2/Makefile
2062                 src/egl/drivers/glx/Makefile
2063                 src/egl/main/Makefile
2064                 src/egl/main/egl.pc
2065                 src/egl/wayland/Makefile
2066                 src/egl/wayland/wayland-drm/Makefile
2067                 src/egl/wayland/wayland-egl/Makefile
2068                 src/egl/wayland/wayland-egl/wayland-egl.pc
2069                 src/gallium/Makefile
2070                 src/gallium/auxiliary/Makefile
2071                 src/gallium/auxiliary/pipe-loader/Makefile
2072                 src/gallium/drivers/Makefile
2073                 src/gallium/drivers/i915/Makefile
2074                 src/gallium/drivers/llvmpipe/Makefile
2075                 src/gallium/drivers/nouveau/Makefile
2076                 src/gallium/drivers/nv30/Makefile
2077                 src/gallium/drivers/nv50/Makefile
2078                 src/gallium/drivers/nvc0/Makefile
2079                 src/gallium/drivers/r300/Makefile
2080                 src/gallium/drivers/r600/Makefile
2081                 src/gallium/drivers/radeon/Makefile
2082                 src/gallium/drivers/radeonsi/Makefile
2083                 src/gallium/drivers/rbug/Makefile
2084                 src/gallium/drivers/softpipe/Makefile
2085                 src/gallium/drivers/svga/Makefile
2086                 src/gallium/drivers/trace/Makefile
2087                 src/gallium/state_trackers/Makefile
2088                 src/gallium/state_trackers/clover/Makefile
2089                 src/gallium/state_trackers/dri/Makefile
2090                 src/gallium/state_trackers/dri/drm/Makefile
2091                 src/gallium/state_trackers/dri/sw/Makefile
2092                 src/gallium/state_trackers/egl/Makefile
2093                 src/gallium/state_trackers/gbm/Makefile
2094                 src/gallium/state_trackers/glx/Makefile
2095                 src/gallium/state_trackers/vdpau/Makefile
2096                 src/gallium/state_trackers/vega/Makefile
2097                 src/gallium/state_trackers/xa/Makefile
2098                 src/gallium/state_trackers/xorg/Makefile
2099                 src/gallium/state_trackers/xvmc/Makefile
2100                 src/gallium/targets/Makefile
2101                 src/gallium/targets/dri-i915/Makefile
2102                 src/gallium/targets/dri-nouveau/Makefile
2103                 src/gallium/targets/dri-r300/Makefile
2104                 src/gallium/targets/dri-r600/Makefile
2105                 src/gallium/targets/dri-radeonsi/Makefile
2106                 src/gallium/targets/dri-swrast/Makefile
2107                 src/gallium/targets/dri-vmwgfx/Makefile
2108                 src/gallium/targets/egl-static/Makefile
2109                 src/gallium/targets/gbm/Makefile
2110                 src/gallium/targets/opencl/Makefile
2111                 src/gallium/targets/pipe-loader/Makefile
2112                 src/gallium/targets/libgl-xlib/Makefile
2113                 src/gallium/targets/vdpau-nouveau/Makefile
2114                 src/gallium/targets/vdpau-r300/Makefile
2115                 src/gallium/targets/vdpau-r600/Makefile
2116                 src/gallium/targets/vdpau-radeonsi/Makefile
2117                 src/gallium/targets/vdpau-softpipe/Makefile
2118                 src/gallium/targets/xa-vmwgfx/Makefile
2119                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2120                 src/gallium/targets/xorg-i915/Makefile
2121                 src/gallium/targets/xorg-nouveau/Makefile
2122                 src/gallium/targets/xorg-r600/Makefile
2123                 src/gallium/targets/xorg-radeonsi/Makefile
2124                 src/gallium/targets/xvmc-nouveau/Makefile
2125                 src/gallium/targets/xvmc-r300/Makefile
2126                 src/gallium/targets/xvmc-r600/Makefile
2127                 src/gallium/targets/xvmc-softpipe/Makefile
2128                 src/gallium/tests/trivial/Makefile
2129                 src/gallium/tests/unit/Makefile
2130                 src/gallium/winsys/Makefile
2131                 src/gallium/winsys/i915/drm/Makefile
2132                 src/gallium/winsys/i915/sw/Makefile
2133                 src/gallium/winsys/nouveau/drm/Makefile
2134                 src/gallium/winsys/radeon/drm/Makefile
2135                 src/gallium/winsys/svga/drm/Makefile
2136                 src/gallium/winsys/sw/Makefile
2137                 src/gallium/winsys/sw/dri/Makefile
2138                 src/gallium/winsys/sw/fbdev/Makefile
2139                 src/gallium/winsys/sw/null/Makefile
2140                 src/gallium/winsys/sw/wayland/Makefile
2141                 src/gallium/winsys/sw/wrapper/Makefile
2142                 src/gallium/winsys/sw/xlib/Makefile
2143                 src/gbm/Makefile
2144                 src/gbm/main/gbm.pc
2145                 src/glsl/Makefile
2146                 src/glsl/builtin_compiler/Makefile
2147                 src/glx/Makefile
2148                 src/glx/tests/Makefile
2149                 src/gtest/Makefile
2150                 src/mapi/es1api/Makefile
2151                 src/mapi/es1api/glesv1_cm.pc
2152                 src/mapi/es2api/Makefile
2153                 src/mapi/es2api/glesv2.pc
2154                 src/mapi/glapi/Makefile
2155                 src/mapi/glapi/gen/Makefile
2156                 src/mapi/glapi/tests/Makefile
2157                 src/mapi/shared-glapi/Makefile
2158                 src/mapi/shared-glapi/tests/Makefile
2159                 src/mapi/vgapi/Makefile
2160                 src/mapi/vgapi/vg.pc
2161                 src/mesa/Makefile
2162                 src/mesa/gl.pc
2163                 src/mesa/drivers/Makefile
2164                 src/mesa/drivers/dri/dri.pc
2165                 src/mesa/drivers/dri/common/Makefile
2166                 src/mesa/drivers/dri/common/xmlpool/Makefile
2167                 src/mesa/drivers/dri/i915/Makefile
2168                 src/mesa/drivers/dri/i965/Makefile
2169                 src/mesa/drivers/dri/Makefile
2170                 src/mesa/drivers/dri/nouveau/Makefile
2171                 src/mesa/drivers/dri/r200/Makefile
2172                 src/mesa/drivers/dri/radeon/Makefile
2173                 src/mesa/drivers/dri/swrast/Makefile
2174                 src/mesa/drivers/osmesa/Makefile
2175                 src/mesa/drivers/osmesa/osmesa.pc
2176                 src/mesa/drivers/x11/Makefile
2177                 src/mesa/libdricore/Makefile
2178                 src/mesa/main/tests/Makefile
2179                 src/mesa/main/tests/hash_table/Makefile
2180                 src/mesa/program/Makefile
2181                 src/mesa/x86-64/Makefile
2182                 src/mesa/x86/Makefile])
2183
2184 dnl Sort the dirs alphabetically
2185 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2186 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2187 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2188 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2189 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2190
2191 AC_OUTPUT
2192
2193 dnl
2194 dnl Output some configuration info for the user
2195 dnl
2196 echo ""
2197 echo "        prefix:          $prefix"
2198 echo "        exec_prefix:     $exec_prefix"
2199 echo "        libdir:          $libdir"
2200 echo "        includedir:      $includedir"
2201
2202 dnl API info
2203 echo ""
2204 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2205 echo "        OpenVG:          $enable_openvg"
2206
2207 dnl Driver info
2208 echo ""
2209 if test "x$enable_osmesa" != xno; then
2210         echo "        OSMesa:          lib$OSMESA_LIB"
2211 else
2212         echo "        OSMesa:          no"
2213 fi
2214
2215 if test "x$enable_dri" != xno; then
2216         # cleanup the drivers var
2217         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2218         if test "x$DRI_DIRS" = x; then
2219             echo "        DRI drivers:     no"
2220         else
2221             echo "        DRI drivers:     $dri_dirs"
2222         fi
2223         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2224 fi
2225
2226 case "x$enable_glx$enable_xlib_glx" in
2227 xyesyes)
2228     echo "        GLX:             Xlib-based"
2229     ;;
2230 xyesno)
2231     echo "        GLX:             DRI-based"
2232     ;;
2233 *)
2234     echo "        GLX:             $enable_glx"
2235     ;;
2236 esac
2237
2238 dnl EGL
2239 echo ""
2240 echo "        EGL:             $enable_egl"
2241 if test "$enable_egl" = yes; then
2242     echo "        EGL platforms:   $EGL_PLATFORMS"
2243
2244     egl_drivers=""
2245     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2246         egl_drivers="$egl_drivers builtin:egl_glx"
2247     fi
2248     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2249         egl_drivers="$egl_drivers builtin:egl_dri2"
2250     fi
2251
2252     if test "x$HAVE_ST_EGL" = xyes; then
2253         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2254         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2255     else
2256         echo "        EGL drivers:    $egl_drivers"
2257     fi
2258 fi
2259
2260 echo ""
2261 if test "x$MESA_LLVM" = x1; then
2262     echo "        llvm:            yes"
2263     echo "        llvm-config:     $LLVM_CONFIG"
2264     echo "        llvm-version:    $LLVM_VERSION"
2265 else
2266     echo "        llvm:            no"
2267 fi
2268
2269 echo ""
2270 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2271     echo "        Gallium:         yes"
2272     echo "        Gallium dirs:    $GALLIUM_DIRS"
2273     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2274     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2275     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2276     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2277 else
2278     echo "        Gallium:         no"
2279 fi
2280
2281
2282 dnl Libraries
2283 echo ""
2284 echo "        Shared libs:     $enable_shared"
2285 echo "        Static libs:     $enable_static"
2286 echo "        Shared-glapi:    $enable_shared_glapi"
2287
2288 dnl Compiler options
2289 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2290 cflags=`echo $CFLAGS | \
2291     $SED 's/^ *//;s/  */ /;s/ *$//'`
2292 cxxflags=`echo $CXXFLAGS | \
2293     $SED 's/^ *//;s/  */ /;s/ *$//'`
2294 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2295 echo ""
2296 echo "        CFLAGS:          $cflags"
2297 echo "        CXXFLAGS:        $cxxflags"
2298 echo "        Macros:          $defines"
2299 echo ""
2300 if test "x$MESA_LLVM" = x1; then
2301     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2302     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2303     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2304     echo ""
2305 fi
2306 echo "        PYTHON2:         $PYTHON2"
2307
2308 echo ""
2309 echo "        Run '${MAKE-make}' to build Mesa"
2310 echo ""