configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67
  68 dnl Versions for external dependencies
  69 LIBDRM_REQUIRED=2.4.38
  70 LIBDRM_RADEON_REQUIRED=2.4.56
  71 LIBDRM_INTEL_REQUIRED=2.4.60
  72 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  73 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  74 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  75 DRI2PROTO_REQUIRED=2.6
  76 DRI3PROTO_REQUIRED=1.0
  77 PRESENTPROTO_REQUIRED=1.0
  78 LIBUDEV_REQUIRED=151
  79 GLPROTO_REQUIRED=1.4.14
  80 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  81 LIBVA_REQUIRED=0.35.0
  82 VDPAU_REQUIRED=0.4.1
  83 WAYLAND_REQUIRED=1.2.0
  84 XCB_REQUIRED=1.9.3
  85 XCBDRI2_REQUIRED=1.8
  86 XCBGLX_REQUIRED=1.8.1
  87 XSHMFENCE_REQUIRED=1.1
  88 XVMC_REQUIRED=1.0.6
  89 PYTHON_MAKO_REQUIRED=0.3.4
  90
  91 dnl Check for progs
  92 AC_PROG_CPP
  93 AC_PROG_CC
  94 AC_PROG_CXX
  95 AM_PROG_CC_C_O
  96 AM_PROG_AS
  97 AX_CHECK_GNU_MAKE
  98 AC_CHECK_PROGS([PYTHON2], [python2 python])
  99 AC_PROG_SED
 100 AC_PROG_MKDIR_P
 101
 102 AC_SYS_LARGEFILE
 103
 104 LT_PREREQ([2.2])
 105 LT_INIT([disable-static])
 106
 107 AX_PROG_BISON([],
 108               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 109                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 110 AX_PROG_FLEX([],
 111              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 112                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 113
 114 AC_CHECK_PROG(INDENT, indent, indent, cat)
 115 if test "x$INDENT" != "xcat"; then
 116     # Only GNU indent is supported
 117     INDENT_VERSION=`indent --version | grep GNU`
 118     if test $? -eq 0; then
 119        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 120     else
 121        INDENT="cat"
 122     fi
 123 fi
 124
 125 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 126
 127 if test -z "$PYTHON2"; then
 128     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 129         AC_MSG_ERROR([Python not found - unable to generate sources])
 130     fi
 131 else
 132     if test "x$acv_mako_found" = xno; then
 133         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 134             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 135         fi
 136     fi
 137 fi
 138
 139 AC_PROG_INSTALL
 140
 141 dnl We need a POSIX shell for parts of the build. Assume we have one
 142 dnl in most cases.
 143 case "$host_os" in
 144 solaris*)
 145     # Solaris /bin/sh is too old/non-POSIX compliant
 146     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 147     SHELL="$POSIX_SHELL"
 148     ;;
 149 esac
 150
 151 dnl clang is mostly GCC-compatible, but its version is much lower,
 152 dnl so we have to check for it.
 153 AC_MSG_CHECKING([if compiling with clang])
 154
 155 AC_COMPILE_IFELSE(
 156 [AC_LANG_PROGRAM([], [[
 157 #ifndef __clang__
 158        not clang
 159 #endif
 160 ]])],
 161 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 162
 163 AC_MSG_RESULT([$acv_mesa_CLANG])
 164
 165 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 166 dnl versions are explictly not supported.
 167 GEN_ASM_OFFSETS=no
 168 USE_GNU99=no
 169 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 170     AC_MSG_CHECKING([whether gcc version is sufficient])
 171     major=0
 172     minor=0
 173
 174     GCC_VERSION=`$CC -dumpversion`
 175     if test $? -eq 0; then
 176         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 177         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 178     fi
 179
 180     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 181         AC_MSG_RESULT([no])
 182         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 183     else
 184         AC_MSG_RESULT([yes])
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 188         USE_GNU99=yes
 189     fi
 190     if test "x$cross_compiling" = xyes; then
 191         GEN_ASM_OFFSETS=yes
 192     fi
 193 fi
 194
 195 dnl Check for compiler builtins
 196 AX_GCC_BUILTIN([__builtin_bswap32])
 197 AX_GCC_BUILTIN([__builtin_bswap64])
 198 AX_GCC_BUILTIN([__builtin_clz])
 199 AX_GCC_BUILTIN([__builtin_clzll])
 200 AX_GCC_BUILTIN([__builtin_ctz])
 201 AX_GCC_BUILTIN([__builtin_expect])
 202 AX_GCC_BUILTIN([__builtin_ffs])
 203 AX_GCC_BUILTIN([__builtin_ffsll])
 204 AX_GCC_BUILTIN([__builtin_popcount])
 205 AX_GCC_BUILTIN([__builtin_popcountll])
 206 AX_GCC_BUILTIN([__builtin_unreachable])
 207
 208 AX_GCC_FUNC_ATTRIBUTE([flatten])
 209 AX_GCC_FUNC_ATTRIBUTE([format])
 210 AX_GCC_FUNC_ATTRIBUTE([malloc])
 211 AX_GCC_FUNC_ATTRIBUTE([packed])
 212 AX_GCC_FUNC_ATTRIBUTE([unused])
 213
 214 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 215
 216 dnl Make sure the pkg-config macros are defined
 217 m4_ifndef([PKG_PROG_PKG_CONFIG],
 218     [m4_fatal([Could not locate the pkg-config autoconf macros.
 219   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 220   are in a different location, try setting the environment variable
 221   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 222 PKG_PROG_PKG_CONFIG()
 223
 224 dnl LIB_DIR - library basename
 225 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 226 AC_SUBST([LIB_DIR])
 227
 228 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 229 _SAVE_LDFLAGS="$LDFLAGS"
 230 _SAVE_CPPFLAGS="$CPPFLAGS"
 231
 232 dnl Compiler macros
 233 DEFINES=""
 234 AC_SUBST([DEFINES])
 235 case "$host_os" in
 236 linux*|*-gnu*|gnu*)
 237     DEFINES="$DEFINES -D_GNU_SOURCE"
 238     ;;
 239 solaris*)
 240     DEFINES="$DEFINES -DSVR4"
 241     ;;
 242 cygwin*)
 243     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 244     ;;
 245 esac
 246
 247 dnl Add flags for gcc and g++
 248 if test "x$GCC" = xyes; then
 249     CFLAGS="$CFLAGS -Wall"
 250
 251     if test "x$USE_GNU99" = xyes; then
 252         CFLAGS="$CFLAGS -std=gnu99"
 253     else
 254         CFLAGS="$CFLAGS -std=c99"
 255     fi
 256
 257     # Enable -Werror=implicit-function-declaration and
 258     # -Werror=missing-prototypes, if available, or otherwise, just
 259     # -Wmissing-prototypes.  This is particularly useful to avoid
 260     # generating a loadable driver module that has undefined symbols.
 261     save_CFLAGS="$CFLAGS"
 262     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 263     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 264     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 265     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 266                    AC_MSG_RESULT([yes]),
 267                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 268                     AC_MSG_RESULT([no])]);
 269
 270     # Enable -fvisibility=hidden if using a gcc that supports it
 271     save_CFLAGS="$CFLAGS"
 272     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 273     VISIBILITY_CFLAGS="-fvisibility=hidden"
 274     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 275     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 276                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 277
 278     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 279     CFLAGS=$save_CFLAGS
 280
 281     # Work around aliasing bugs - developers should comment this out
 282     CFLAGS="$CFLAGS -fno-strict-aliasing"
 283
 284     # gcc's builtin memcmp is slower than glibc's
 285     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 286     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 287
 288     # Flags to help ensure that certain portions of the code -- and only those
 289     # portions -- can be built with MSVC:
 290     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 291     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 292     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 293     #   supports most of C99)
 294     # - the rest has no compiler compiler restrictions
 295     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 296     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 297
 298     # Enable -Werror=vla if compiler supports it
 299     save_CFLAGS="$CFLAGS"
 300     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 301     CFLAGS="$CFLAGS -Werror=vla"
 302     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 303                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 304                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 305                     AC_MSG_RESULT([yes])],
 306                     AC_MSG_RESULT([no]));
 307     CFLAGS="$save_CFLAGS"
 308
 309     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 310     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 311 fi
 312 if test "x$GXX" = xyes; then
 313     CXXFLAGS="$CXXFLAGS -Wall"
 314
 315     # Enable -fvisibility=hidden if using a gcc that supports it
 316     save_CXXFLAGS="$CXXFLAGS"
 317     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 318     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 319     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 320     AC_LANG_PUSH([C++])
 321     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 322                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 323     AC_LANG_POP([C++])
 324
 325     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 326     CXXFLAGS=$save_CXXFLAGS
 327
 328     # Work around aliasing bugs - developers should comment this out
 329     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 330
 331     # gcc's builtin memcmp is slower than glibc's
 332     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 333     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 334 fi
 335
 336 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 337 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 338 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 339 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 340
 341 dnl even if the compiler appears to support it, using visibility attributes isn't
 342 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 343 case "$host_os" in
 344 cygwin*)
 345     VISIBILITY_CFLAGS=""
 346     VISIBILITY_CXXFLAGS=""
 347     ;;
 348 esac
 349
 350 AC_SUBST([VISIBILITY_CFLAGS])
 351 AC_SUBST([VISIBILITY_CXXFLAGS])
 352
 353 dnl
 354 dnl Optional flags, check for compiler support
 355 dnl
 356 SSE41_CFLAGS="-msse4.1"
 357 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 358 dnl stack, but on x86-32 such alignment is not guaranteed.
 359 case "$target_cpu" in
 360 i?86)
 361     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 362     ;;
 363 esac
 364 save_CFLAGS="$CFLAGS"
 365 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 366 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 367 #include <smmintrin.h>
 368 int main () {
 369     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 370     c = _mm_max_epu32(a, b);
 371     return 0;
 372 }]])], SSE41_SUPPORTED=1)
 373 CFLAGS="$save_CFLAGS"
 374 if test "x$SSE41_SUPPORTED" = x1; then
 375     DEFINES="$DEFINES -DUSE_SSE41"
 376 fi
 377 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 378 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 379
 380 dnl Can't have static and shared libraries, default to static if user
 381 dnl explicitly requested. If both disabled, set to static since shared
 382 dnl was explicitly requested.
 383 case "x$enable_static$enable_shared" in
 384 xyesyes)
 385     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 386     enable_shared=no
 387     ;;
 388 xnono)
 389     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 390     enable_shared=yes
 391     ;;
 392 esac
 393
 394 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 395
 396 dnl
 397 dnl other compiler options
 398 dnl
 399 AC_ARG_ENABLE([debug],
 400     [AS_HELP_STRING([--enable-debug],
 401         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 402     [enable_debug="$enableval"],
 403     [enable_debug=no]
 404 )
 405 if test "x$enable_debug" = xyes; then
 406     DEFINES="$DEFINES -DDEBUG"
 407     if test "x$GCC" = xyes; then
 408         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 409             CFLAGS="$CFLAGS -g"
 410         fi
 411         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 412             CFLAGS="$CFLAGS -O0"
 413         fi
 414     fi
 415     if test "x$GXX" = xyes; then
 416         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 417             CXXFLAGS="$CXXFLAGS -g"
 418         fi
 419         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 420             CXXFLAGS="$CXXFLAGS -O0"
 421         fi
 422     fi
 423 else
 424    DEFINES="$DEFINES -DNDEBUG"
 425 fi
 426
 427 dnl
 428 dnl Check if linker supports -Bsymbolic
 429 dnl
 430 save_LDFLAGS=$LDFLAGS
 431 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 432 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 433 AC_LINK_IFELSE(
 434     [AC_LANG_SOURCE([int main() { return 0;}])],
 435     [AC_MSG_RESULT([yes])
 436         BSYMBOLIC="-Wl,-Bsymbolic";],
 437     [AC_MSG_RESULT([no])
 438         BSYMBOLIC="";])
 439 LDFLAGS=$save_LDFLAGS
 440
 441 AC_SUBST([BSYMBOLIC])
 442
 443 dnl
 444 dnl Check if linker supports garbage collection
 445 dnl
 446 save_LDFLAGS=$LDFLAGS
 447 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 448 AC_MSG_CHECKING([whether ld supports --gc-sections])
 449 AC_LINK_IFELSE(
 450     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 451     [AC_MSG_RESULT([yes])
 452         GC_SECTIONS="-Wl,--gc-sections";],
 453     [AC_MSG_RESULT([no])
 454         GC_SECTIONS="";])
 455 LDFLAGS=$save_LDFLAGS
 456
 457 AC_SUBST([GC_SECTIONS])
 458
 459 dnl
 460 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 461 dnl so when these flags are passed to ld via libtool the checks will fail
 462 dnl
 463 case "$host_os" in
 464 openbsd* | darwin* )
 465     LD_NO_UNDEFINED="" ;;
 466 *)
 467     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 468 esac
 469
 470 AC_SUBST([LD_NO_UNDEFINED])
 471
 472 dnl
 473 dnl Check if linker supports version scripts
 474 dnl
 475 AC_MSG_CHECKING([if the linker supports version-scripts])
 476 save_LDFLAGS=$LDFLAGS
 477 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 478 cat > conftest.map <<EOF
 479 VERSION_1 {
 480      global:
 481          main;
 482
 483      local:
 484          *;
 485 };
 486 EOF
 487 AC_LINK_IFELSE(
 488     [AC_LANG_SOURCE([int main() { return 0;}])],
 489     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 490     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 491 LDFLAGS=$save_LDFLAGS
 492 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 493
 494 dnl
 495 dnl Check if linker supports dynamic list files
 496 dnl
 497 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 498 save_LDFLAGS=$LDFLAGS
 499 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 500 cat > conftest.dyn <<EOF
 501 {
 502         radeon_drm_winsys_create;
 503 };
 504 EOF
 505 AC_LINK_IFELSE(
 506     [AC_LANG_SOURCE([int main() { return 0;}])],
 507     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 508     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 509 LDFLAGS=$save_LDFLAGS
 510 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 511
 512 dnl
 513 dnl compatibility symlinks
 514 dnl
 515 case "$host_os" in
 516 linux* )
 517     HAVE_COMPAT_SYMLINKS=yes ;;
 518 * )
 519     HAVE_COMPAT_SYMLINKS=no ;;
 520 esac
 521
 522 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 523
 524 dnl
 525 dnl library names
 526 dnl
 527 case "$host_os" in
 528 darwin* )
 529     LIB_EXT='dylib' ;;
 530 cygwin* )
 531     LIB_EXT='dll' ;;
 532 aix* )
 533     LIB_EXT='a' ;;
 534 * )
 535     LIB_EXT='so' ;;
 536 esac
 537
 538 AC_SUBST([LIB_EXT])
 539
 540 AC_ARG_WITH([gl-lib-name],
 541   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 542     [specify GL library name @<:@default=GL@:>@])],
 543   [GL_LIB=$withval],
 544   [GL_LIB=GL])
 545 AC_ARG_WITH([osmesa-lib-name],
 546   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 547     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 548   [OSMESA_LIB=$withval],
 549   [OSMESA_LIB=OSMesa])
 550 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 551 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 552
 553 dnl
 554 dnl Mangled Mesa support
 555 dnl
 556 AC_ARG_ENABLE([mangling],
 557   [AS_HELP_STRING([--enable-mangling],
 558     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 559   [enable_mangling="${enableval}"],
 560   [enable_mangling=no]
 561 )
 562 if test "x${enable_mangling}" = "xyes" ; then
 563   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 564   GL_LIB="Mangled${GL_LIB}"
 565   OSMESA_LIB="Mangled${OSMESA_LIB}"
 566 fi
 567 AC_SUBST([GL_LIB])
 568 AC_SUBST([OSMESA_LIB])
 569
 570 dnl
 571 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 572 dnl
 573 AC_ARG_ENABLE([texture-float],
 574     [AS_HELP_STRING([--enable-texture-float],
 575         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 576     [enable_texture_float="$enableval"],
 577     [enable_texture_float=no]
 578 )
 579 if test "x$enable_texture_float" = xyes; then
 580     AC_MSG_WARN([Floating-point textures enabled.])
 581     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 582     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 583 fi
 584
 585 dnl
 586 dnl Arch/platform-specific settings
 587 dnl
 588 AC_ARG_ENABLE([asm],
 589     [AS_HELP_STRING([--disable-asm],
 590         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 591     [enable_asm="$enableval"],
 592     [enable_asm=yes]
 593 )
 594 asm_arch=""
 595 AC_MSG_CHECKING([whether to enable assembly])
 596 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 597 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 598 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 599     case "$host_cpu" in
 600     i?86 | x86_64 | amd64)
 601         enable_asm=no
 602         AC_MSG_RESULT([no, cross compiling])
 603         ;;
 604     esac
 605 fi
 606 # check for supported arches
 607 if test "x$enable_asm" = xyes; then
 608     case "$host_cpu" in
 609     i?86)
 610         case "$host_os" in
 611         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 612             asm_arch=x86
 613             ;;
 614         esac
 615         ;;
 616     x86_64|amd64)
 617         case "$host_os" in
 618         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 619             asm_arch=x86_64
 620             ;;
 621         esac
 622         ;;
 623     sparc*)
 624         case "$host_os" in
 625         linux*)
 626             asm_arch=sparc
 627             ;;
 628         esac
 629         ;;
 630     esac
 631
 632     case "$asm_arch" in
 633     x86)
 634         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 635         AC_MSG_RESULT([yes, x86])
 636         ;;
 637     x86_64|amd64)
 638         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 639         AC_MSG_RESULT([yes, x86_64])
 640         ;;
 641     sparc)
 642         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 643         AC_MSG_RESULT([yes, sparc])
 644         ;;
 645     *)
 646         AC_MSG_RESULT([no, platform not supported])
 647         ;;
 648     esac
 649 fi
 650
 651 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 652 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 653
 654 dnl Check to see if dlopen is in default libraries (like Solaris, which
 655 dnl has it in libc), or if libdl is needed to get it.
 656 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 657     [AC_CHECK_LIB([dl], [dlopen],
 658        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 659 AC_SUBST([DLOPEN_LIBS])
 660
 661 dnl Check if that library also has dladdr
 662 save_LIBS="$LIBS"
 663 LIBS="$LIBS $DLOPEN_LIBS"
 664 AC_CHECK_FUNCS([dladdr])
 665 LIBS="$save_LIBS"
 666
 667 case "$host_os" in
 668 darwin*)
 669     ;;
 670 *)
 671     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 672                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 673                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 674     AC_SUBST([CLOCK_LIB])
 675     ;;
 676 esac
 677
 678 dnl See if posix_memalign is available
 679 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 680
 681 dnl Check for pthreads
 682 AX_PTHREAD
 683 if test "x$ax_pthread_ok" = xno; then
 684     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 685 fi
 686 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 687 dnl to -pthread, which causes problems if we need -lpthread to appear in
 688 dnl pkgconfig files.
 689 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 690
 691 dnl SELinux awareness.
 692 AC_ARG_ENABLE([selinux],
 693     [AS_HELP_STRING([--enable-selinux],
 694         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 695     [MESA_SELINUX="$enableval"],
 696     [MESA_SELINUX=no])
 697 if test "x$enable_selinux" = "xyes"; then
 698     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 699         [AC_CHECK_HEADER([selinux/selinux.h],[],
 700                          [AC_MSG_ERROR([SELinux headers not found])])
 701          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 702                       [AC_MSG_ERROR([SELinux library not found])])
 703          SELINUX_LIBS="-lselinux"])
 704     DEFINES="$DEFINES -DMESA_SELINUX"
 705 fi
 706 AC_SUBST([SELINUX_CFLAGS])
 707 AC_SUBST([SELINUX_LIBS])
 708
 709 dnl Options for APIs
 710 AC_ARG_ENABLE([opengl],
 711     [AS_HELP_STRING([--disable-opengl],
 712         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 713     [enable_opengl="$enableval"],
 714     [enable_opengl=yes])
 715 AC_ARG_ENABLE([gles1],
 716     [AS_HELP_STRING([--enable-gles1],
 717         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 718     [enable_gles1="$enableval"],
 719     [enable_gles1=no])
 720 AC_ARG_ENABLE([gles2],
 721     [AS_HELP_STRING([--enable-gles2],
 722         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 723     [enable_gles2="$enableval"],
 724     [enable_gles2=no])
 725
 726 AC_ARG_ENABLE([dri],
 727     [AS_HELP_STRING([--enable-dri],
 728         [enable DRI modules @<:@default=enabled@:>@])],
 729     [enable_dri="$enableval"],
 730     [enable_dri=yes])
 731
 732 case "$host_os" in
 733 linux*)
 734     dri3_default=yes
 735     ;;
 736 *)
 737     dri3_default=no
 738     ;;
 739 esac
 740 AC_ARG_ENABLE([dri3],
 741     [AS_HELP_STRING([--enable-dri3],
 742         [enable DRI3 @<:@default=auto@:>@])],
 743     [enable_dri3="$enableval"],
 744     [enable_dri3="$dri3_default"])
 745 AC_ARG_ENABLE([glx],
 746     [AS_HELP_STRING([--enable-glx],
 747         [enable GLX library @<:@default=enabled@:>@])],
 748     [enable_glx="$enableval"],
 749     [enable_glx=yes])
 750 AC_ARG_ENABLE([osmesa],
 751     [AS_HELP_STRING([--enable-osmesa],
 752         [enable OSMesa library @<:@default=disabled@:>@])],
 753     [enable_osmesa="$enableval"],
 754     [enable_osmesa=no])
 755 AC_ARG_ENABLE([gallium-osmesa],
 756     [AS_HELP_STRING([--enable-gallium-osmesa],
 757         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 758     [enable_gallium_osmesa="$enableval"],
 759     [enable_gallium_osmesa=no])
 760 AC_ARG_ENABLE([egl],
 761     [AS_HELP_STRING([--disable-egl],
 762         [disable EGL library @<:@default=enabled@:>@])],
 763     [enable_egl="$enableval"],
 764     [enable_egl=yes])
 765
 766 AC_ARG_ENABLE([xa],
 767     [AS_HELP_STRING([--enable-xa],
 768         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 769     [enable_xa="$enableval"],
 770     [enable_xa=no])
 771 AC_ARG_ENABLE([gbm],
 772    [AS_HELP_STRING([--enable-gbm],
 773          [enable gbm library @<:@default=auto@:>@])],
 774    [enable_gbm="$enableval"],
 775    [enable_gbm=auto])
 776 AC_ARG_ENABLE([nine],
 777     [AS_HELP_STRING([--enable-nine],
 778         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 779     [enable_nine="$enableval"],
 780     [enable_nine=no])
 781
 782 AC_ARG_ENABLE([xvmc],
 783    [AS_HELP_STRING([--enable-xvmc],
 784          [enable xvmc library @<:@default=auto@:>@])],
 785    [enable_xvmc="$enableval"],
 786    [enable_xvmc=auto])
 787 AC_ARG_ENABLE([vdpau],
 788    [AS_HELP_STRING([--enable-vdpau],
 789          [enable vdpau library @<:@default=auto@:>@])],
 790    [enable_vdpau="$enableval"],
 791    [enable_vdpau=auto])
 792 AC_ARG_ENABLE([omx],
 793    [AS_HELP_STRING([--enable-omx],
 794          [enable OpenMAX library @<:@default=disabled@:>@])],
 795    [enable_omx="$enableval"],
 796    [enable_omx=no])
 797 AC_ARG_ENABLE([va],
 798    [AS_HELP_STRING([--enable-va],
 799          [enable va library @<:@default=auto@:>@])],
 800    [enable_va="$enableval"],
 801    [enable_va=auto])
 802 AC_ARG_ENABLE([opencl],
 803    [AS_HELP_STRING([--enable-opencl],
 804          [enable OpenCL library @<:@default=disabled@:>@])],
 805    [enable_opencl="$enableval"],
 806    [enable_opencl=no])
 807 AC_ARG_ENABLE([opencl_icd],
 808    [AS_HELP_STRING([--enable-opencl-icd],
 809           [Build an OpenCL ICD library to be loaded by an ICD implementation
 810            @<:@default=disabled@:>@])],
 811     [enable_opencl_icd="$enableval"],
 812     [enable_opencl_icd=no])
 813 AC_ARG_ENABLE([xlib-glx],
 814     [AS_HELP_STRING([--enable-xlib-glx],
 815         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 816     [enable_xlib_glx="$enableval"],
 817     [enable_xlib_glx=no])
 818
 819 AC_ARG_ENABLE([r600-llvm-compiler],
 820     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 821         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 822     [enable_r600_llvm="$enableval"],
 823     [enable_r600_llvm=no])
 824
 825 AC_ARG_ENABLE([gallium-tests],
 826     [AS_HELP_STRING([--enable-gallium-tests],
 827         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 828     [enable_gallium_tests="$enableval"],
 829     [enable_gallium_tests=no])
 830
 831 # Option for Gallium drivers
 832
 833 # Keep this in sync with the --with-gallium-drivers help string default value
 834 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 835
 836 AC_ARG_WITH([gallium-drivers],
 837     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 838         [comma delimited Gallium drivers list, e.g.
 839         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 840         @<:@default=r300,r600,svga,swrast@:>@])],
 841     [with_gallium_drivers="$withval"],
 842     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 843
 844 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 845 # here so that the script doesn't choke on an unknown driver name later.
 846 case "$with_gallium_drivers" in
 847     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 848     no) with_gallium_drivers='' ;;
 849 esac
 850
 851 if test "x$enable_opengl" = xno -a \
 852         "x$enable_gles1" = xno -a \
 853         "x$enable_gles2" = xno -a \
 854         "x$enable_nine" = xno -a \
 855         "x$enable_xa" = xno -a \
 856         "x$enable_xvmc" = xno -a \
 857         "x$enable_vdpau" = xno -a \
 858         "x$enable_omx" = xno -a \
 859         "x$enable_va" = xno -a \
 860         "x$enable_opencl" = xno; then
 861     AC_MSG_ERROR([at least one API should be enabled])
 862 fi
 863
 864 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 865 if test "x$enable_opengl" = xno -a \
 866         "x$enable_gles1" = xyes; then
 867     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 868 fi
 869
 870 if test "x$enable_opengl" = xno -a \
 871         "x$enable_gles2" = xyes; then
 872     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 873 fi
 874
 875 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 876 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 877 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 878 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 879                                         "x$enable_gles1" = xyes -o \
 880                                         "x$enable_gles2" = xyes)
 881
 882 if test "x$enable_glx" = xno; then
 883     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 884     enable_xlib_glx=no
 885 fi
 886
 887 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 888     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 889 fi
 890
 891 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 892     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 893 fi
 894
 895 # Disable GLX if OpenGL is not enabled
 896 if test "x$enable_glx$enable_opengl" = xyesno; then
 897     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 898     enable_glx=no
 899 fi
 900
 901 # Disable GLX if DRI and Xlib-GLX are not enabled
 902 if test "x$enable_glx" = xyes -a \
 903         "x$enable_dri" = xno -a \
 904         "x$enable_xlib_glx" = xno; then
 905     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 906     enable_glx=no
 907 fi
 908
 909 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 910                                   "x$enable_dri" = xyes)
 911
 912 # Select which platform-dependent DRI code gets built
 913 case "$host_os" in
 914 darwin*)
 915     dri_platform='apple' ;;
 916 gnu*|cygwin*)
 917     dri_platform='none' ;;
 918 *)
 919     dri_platform='drm' ;;
 920 esac
 921
 922 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 923 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 924 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 925 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 926 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 927
 928 AC_ARG_ENABLE([shared-glapi],
 929     [AS_HELP_STRING([--enable-shared-glapi],
 930         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 931     [enable_shared_glapi="$enableval"],
 932     [enable_shared_glapi=yes])
 933
 934 case "x$enable_opengl$enable_gles1$enable_gles2" in
 935 x*yes*yes*)
 936     if test "x$enable_shared_glapi" = xno; then
 937         AC_MSG_ERROR([shared GLAPI required when building two or more of
 938                       the following APIs - opengl, gles1 gles2])
 939     fi
 940     ;;
 941 esac
 942
 943 # Building Xlib-GLX requires shared glapi to be disabled.
 944 if test "x$enable_xlib_glx" = xyes; then
 945     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 946     enable_shared_glapi=no
 947 fi
 948
 949 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 950
 951 # Build the pipe-drivers as separate libraries/modules.
 952 # Do not touch this unless you know what you are doing.
 953 # XXX: Expose via configure option ?
 954 enable_shared_pipe_drivers=no
 955
 956 dnl
 957 dnl Driver specific build directories
 958 dnl
 959
 960 case "x$enable_glx$enable_xlib_glx" in
 961 xyesyes)
 962     NEED_WINSYS_XLIB="yes"
 963     ;;
 964 esac
 965
 966 if test "x$enable_dri" = xyes; then
 967     enable_gallium_loader="$enable_shared_pipe_drivers"
 968 fi
 969
 970 if test "x$enable_gallium_osmesa" = xyes; then
 971     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 972         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 973     fi
 974     if test "x$enable_osmesa" = xyes; then
 975         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 976     fi
 977 fi
 978
 979 AC_SUBST([MESA_LLVM])
 980
 981 # SHA1 hashing
 982 AC_ARG_WITH([sha1],
 983         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 984         [choose SHA1 implementation])])
 985 case "x$with_sha1" in
 986 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 987   ;;
 988 *)
 989         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 990 esac
 991
 992 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 993 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 994         with_sha1=libc
 995 fi
 996 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 997         AC_MSG_ERROR([sha1 in libc requested but not found])
 998 fi
 999 if test "x$with_sha1" = xlibc; then
1000         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1001                 [Use libc SHA1 functions])
1002         SHA1_LIBS=""
1003 fi
1004 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1005 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1006         with_sha1=CommonCrypto
1007 fi
1008 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1009         AC_MSG_ERROR([CommonCrypto requested but not found])
1010 fi
1011 if test "x$with_sha1" = xCommonCrypto; then
1012         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1013                 [Use CommonCrypto SHA1 functions])
1014         SHA1_LIBS=""
1015 fi
1016 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1017 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1018 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1019         with_sha1=CryptoAPI
1020 fi
1021 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1022         AC_MSG_ERROR([CryptoAPI requested but not found])
1023 fi
1024 if test "x$with_sha1" = xCryptoAPI; then
1025         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1026                 [Use CryptoAPI SHA1 functions])
1027         SHA1_LIBS=""
1028 fi
1029 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1030 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1031         with_sha1=libmd
1032 fi
1033 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1034         AC_MSG_ERROR([libmd requested but not found])
1035 fi
1036 if test "x$with_sha1" = xlibmd; then
1037         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1038                   [Use libmd SHA1 functions])
1039         SHA1_LIBS=-lmd
1040 fi
1041 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1042 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1043    with_sha1=libsha1
1044 fi
1045 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1046         AC_MSG_ERROR([libsha1 requested but not found])
1047 fi
1048 if test "x$with_sha1" = xlibsha1; then
1049         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1050                   [Use libsha1 for SHA1])
1051         SHA1_LIBS=-lsha1
1052 fi
1053 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1054 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1055         with_sha1=libnettle
1056 fi
1057 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1058         AC_MSG_ERROR([libnettle requested but not found])
1059 fi
1060 if test "x$with_sha1" = xlibnettle; then
1061         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1062                   [Use libnettle SHA1 functions])
1063         SHA1_LIBS=-lnettle
1064 fi
1065 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1066 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1067         with_sha1=libgcrypt
1068 fi
1069 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1070         AC_MSG_ERROR([libgcrypt requested but not found])
1071 fi
1072 if test "x$with_sha1" = xlibgcrypt; then
1073         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1074                   [Use libgcrypt SHA1 functions])
1075         SHA1_LIBS=-lgcrypt
1076 fi
1077 # We don't need all of the OpenSSL libraries, just libcrypto
1078 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1079 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1080                   [HAVE_OPENSSL_PKC=no])
1081 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1082         if test "x$with_sha1" = x; then
1083                 with_sha1=libcrypto
1084         fi
1085 else
1086         if test "x$with_sha1" = xlibcrypto; then
1087                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1088         fi
1089 fi
1090 if test "x$with_sha1" = xlibcrypto; then
1091         if test "x$HAVE_LIBCRYPTO" = xyes; then
1092                 SHA1_LIBS=-lcrypto
1093         else
1094                 SHA1_LIBS="$OPENSSL_LIBS"
1095                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1096         fi
1097 fi
1098 AC_MSG_CHECKING([for SHA1 implementation])
1099 AC_MSG_RESULT([$with_sha1])
1100 AC_SUBST(SHA1_LIBS)
1101 AC_SUBST(SHA1_CFLAGS)
1102
1103 # Allow user to configure out the shader-cache feature
1104 AC_ARG_ENABLE([shader-cache],
1105     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1106     [enable_shader_cache="$enableval"],
1107     [if test "x$with_sha1" != "x"; then
1108         enable_shader_cache=yes
1109      else
1110         enable_shader_cache=no
1111      fi])
1112 if test "x$with_sha1" = "x"; then
1113     if test "x$enable_shader_cache" = "xyes"; then
1114         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1115     fi
1116 fi
1117 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1118
1119 # Check for libdrm
1120 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1121                   [have_libdrm=yes], [have_libdrm=no])
1122 if test "x$have_libdrm" = xyes; then
1123         DEFINES="$DEFINES -DHAVE_LIBDRM"
1124 fi
1125
1126 case "$host_os" in
1127 linux*)
1128     need_pci_id=yes ;;
1129 *)
1130     need_pci_id=no ;;
1131 esac
1132
1133 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1134                   have_libudev=yes, have_libudev=no)
1135
1136 AC_ARG_ENABLE([sysfs],
1137     [AS_HELP_STRING([--enable-sysfs],
1138         [enable /sys PCI identification @<:@default=disabled@:>@])],
1139     [have_sysfs="$enableval"],
1140     [have_sysfs=no]
1141 )
1142
1143 if test "x$enable_dri" = xyes; then
1144     if test "$enable_static" = yes; then
1145         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1146     fi
1147
1148     # not a hard requirement as swrast does not depend on it
1149     if test "x$have_libdrm" = xyes; then
1150         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1151     fi
1152 fi
1153
1154 AC_ARG_ENABLE([driglx-direct],
1155     [AS_HELP_STRING([--disable-driglx-direct],
1156         [disable direct rendering in GLX and EGL for DRI \
1157             @<:@default=auto@:>@])],
1158     [driglx_direct="$enableval"],
1159     [driglx_direct="yes"])
1160
1161 # Check for libcaca
1162 PKG_CHECK_EXISTS([caca], [have_libcaca=yes], [have_libcaca=no])
1163 AM_CONDITIONAL([HAVE_LIBCACA], [test x$have_libcaca = xyes])
1164
1165 dnl
1166 dnl libGL configuration per driver
1167 dnl
1168 case "x$enable_glx$enable_xlib_glx" in
1169 xyesyes)
1170     # Xlib-based GLX
1171     dri_modules="x11 xext xcb"
1172     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1173     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1174     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1175     GL_LIB_DEPS="$XLIBGL_LIBS"
1176     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1177     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1178     ;;
1179 xyesno)
1180     # DRI-based GLX
1181     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1182
1183     # find the DRI deps for libGL
1184     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1185
1186     if test x"$driglx_direct" = xyes; then
1187         if test x"$dri_platform" = xdrm ; then
1188             DEFINES="$DEFINES -DGLX_USE_DRM"
1189             if test "x$have_libdrm" != xyes; then
1190                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1191             fi
1192
1193             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1194             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1195             if test x"$enable_dri3" = xyes; then
1196                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1197                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1198             fi
1199
1200             if test x"$enable_dri" = xyes; then
1201                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1202             fi
1203
1204             if test x"$enable_dri3" = xyes; then
1205                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1206                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1207             fi
1208         fi
1209         if test x"$dri_platform" = xapple ; then
1210             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1211         fi
1212     fi
1213
1214     # add xf86vidmode if available
1215     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1216     if test "$HAVE_XF86VIDMODE" = yes ; then
1217         dri_modules="$dri_modules xxf86vm"
1218     fi
1219
1220     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1221     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1222     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1223     GL_LIB_DEPS="$DRIGL_LIBS"
1224
1225     # need DRM libs, $PTHREAD_LIBS, etc.
1226     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1227     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1228     ;;
1229 esac
1230
1231 have_pci_id=no
1232 if test "$have_libudev" = yes; then
1233     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1234     have_pci_id=yes
1235 fi
1236
1237 if test "$have_sysfs" = yes; then
1238     DEFINES="$DEFINES -DHAVE_SYSFS"
1239     have_pci_id=yes
1240 fi
1241
1242 # This is outside the case (above) so that it is invoked even for non-GLX
1243 # builds.
1244 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1245
1246 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1247 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1248 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1249 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1250
1251 AC_SUBST([X11_INCLUDES])
1252 AC_SUBST([GL_LIB_DEPS])
1253 AC_SUBST([GL_PC_REQ_PRIV])
1254 AC_SUBST([GL_PC_LIB_PRIV])
1255 AC_SUBST([GL_PC_CFLAGS])
1256 AC_SUBST([DRI_PC_REQ_PRIV])
1257 AC_SUBST([GLESv1_CM_LIB_DEPS])
1258 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1259 AC_SUBST([GLESv2_LIB_DEPS])
1260 AC_SUBST([GLESv2_PC_LIB_PRIV])
1261
1262 AC_SUBST([HAVE_XF86VIDMODE])
1263
1264 dnl
1265 dnl More GLX setup
1266 dnl
1267 case "x$enable_glx$enable_xlib_glx" in
1268 xyesyes)
1269     DEFINES="$DEFINES -DUSE_XSHM"
1270     ;;
1271 xyesno)
1272     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1273     if test "x$driglx_direct" = xyes; then
1274         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1275     fi
1276     ;;
1277 esac
1278
1279 dnl
1280 dnl TLS detection
1281 dnl
1282
1283 AC_ARG_ENABLE([glx-tls],
1284     [AS_HELP_STRING([--enable-glx-tls],
1285         [enable TLS support in GLX @<:@default=disabled@:>@])],
1286     [GLX_USE_TLS="$enableval"],
1287     [GLX_USE_TLS=no])
1288 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1289
1290 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1291       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1292
1293 dnl
1294 dnl More DRI setup
1295 dnl
1296 dnl Directory for DRI drivers
1297 AC_ARG_WITH([dri-driverdir],
1298     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1299         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1300     [DRI_DRIVER_INSTALL_DIR="$withval"],
1301     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1302 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1303 dnl Extra search path for DRI drivers
1304 AC_ARG_WITH([dri-searchpath],
1305     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1306         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1307     [DRI_DRIVER_SEARCH_DIR="$withval"],
1308     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1309 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1310 dnl Which drivers to build - default is chosen by platform
1311 AC_ARG_WITH([dri-drivers],
1312     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1313         [comma delimited classic DRI drivers list, e.g.
1314         "swrast,i965,radeon" @<:@default=auto@:>@])],
1315     [with_dri_drivers="$withval"],
1316     [with_dri_drivers=auto])
1317
1318 if test "x$with_dri_drivers" = xauto; then
1319     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1320         with_dri_drivers="yes"
1321     else
1322         with_dri_drivers="no"
1323     fi
1324 fi
1325 if test "x$with_dri_drivers" = xno; then
1326     with_dri_drivers=''
1327 fi
1328
1329 dnl If $with_dri_drivers is yes, drivers will be added through
1330 dnl platform checks. Set DEFINES and LIB_DEPS
1331 if test "x$enable_dri" = xyes; then
1332     # Platform specific settings and drivers to build
1333     case "$host_os" in
1334     linux*)
1335         DEFINES="$DEFINES -DHAVE_ALIAS"
1336         if test "x$enable_dri3" = xyes; then
1337             DEFINES="$DEFINES -DHAVE_DRI3"
1338         fi
1339
1340         if test "x$have_pci_id" != xyes; then
1341             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1342         fi
1343
1344         case "$host_cpu" in
1345         powerpc* | sparc*)
1346             # Build only the drivers for cards that exist on PowerPC/sparc
1347             if test "x$with_dri_drivers" = "xyes"; then
1348                 with_dri_drivers="r200 radeon swrast"
1349             fi
1350             ;;
1351         esac
1352         ;;
1353     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1354         DEFINES="$DEFINES -DHAVE_ALIAS"
1355         ;;
1356     gnu*)
1357         DEFINES="$DEFINES -DHAVE_ALIAS"
1358         ;;
1359     cygwin*)
1360         if test "x$with_dri_drivers" = "xyes"; then
1361             with_dri_drivers="swrast"
1362         fi
1363         ;;
1364     darwin*)
1365         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1366         if test "x$with_dri_drivers" = "xyes"; then
1367             with_dri_drivers="swrast"
1368         fi
1369         ;;
1370     esac
1371
1372     # default drivers
1373     if test "x$with_dri_drivers" = "xyes"; then
1374         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1375     fi
1376
1377     # Check for expat
1378     PKG_CHECK_MODULES([EXPAT], [expat], [],
1379         # expat version 2.0 and earlier do not provide expat.pc
1380         [AC_CHECK_HEADER([expat.h],[],
1381                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1382          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1383                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1384          EXPAT_LIBS="-lexpat"])
1385
1386     DRICOMMON_NEED_LIBDRM=no
1387     # If we are building any DRI driver other than swrast.
1388     if test -n "$with_dri_drivers"; then
1389         if test "x$with_dri_drivers" != xswrast; then
1390             # ... libdrm is required
1391             if test "x$have_libdrm" != xyes; then
1392                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1393             fi
1394             DRICOMMON_NEED_LIBDRM=yes
1395         fi
1396     fi
1397
1398     # If we're building any gallium DRI driver other than swrast
1399     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1400         if test "x$with_gallium_drivers" != xswrast; then
1401             # ... build a libdrm aware dricommon
1402             DRICOMMON_NEED_LIBDRM=yes
1403         fi
1404     fi
1405
1406     # put all the necessary libs together
1407     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1408 fi
1409
1410 AC_SUBST([DRI_LIB_DEPS])
1411
1412 DRI_DIRS=''
1413 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1414 if test -n "$with_dri_drivers"; then
1415     if test "x$enable_opengl" != xyes; then
1416         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1417     fi
1418
1419     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1420     for driver in $dri_drivers; do
1421         DRI_DIRS="$DRI_DIRS $driver"
1422         case "x$driver" in
1423         xi915)
1424             HAVE_I915_DRI=yes;
1425             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1426             ;;
1427         xi965)
1428             HAVE_I965_DRI=yes;
1429             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1430             ;;
1431         xnouveau)
1432             HAVE_NOUVEAU_DRI=yes;
1433             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1434             ;;
1435         xradeon)
1436             HAVE_RADEON_DRI=yes;
1437             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1438             ;;
1439         xr200)
1440             HAVE_R200_DRI=yes;
1441             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1442             ;;
1443         xswrast)
1444             HAVE_SWRAST_DRI=yes;
1445             ;;
1446         *)
1447             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1448             ;;
1449         esac
1450     done
1451     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1452 fi
1453
1454 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1455 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1456                                   "x$enable_osmesa" = xyes -o \
1457                                   -n "$DRI_DIRS")
1458
1459 dnl
1460 dnl OSMesa configuration
1461 dnl
1462
1463 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1464 AC_ARG_WITH([osmesa-bits],
1465     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1466         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1467     [osmesa_bits="$withval"],
1468     [osmesa_bits=8])
1469 if test "x$osmesa_bits" != x8; then
1470     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1471         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1472         osmesa_bits=8
1473     fi
1474 fi
1475 case "x$osmesa_bits" in
1476 x8)
1477     OSMESA_LIB="${OSMESA_LIB}"
1478     ;;
1479 x16|x32)
1480     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1481     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1482     ;;
1483 *)
1484     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1485     ;;
1486 esac
1487
1488 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1489     # only link libraries with osmesa if shared
1490     if test "$enable_static" = no; then
1491         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1492     else
1493         OSMESA_LIB_DEPS=""
1494     fi
1495     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1496 fi
1497
1498 AC_SUBST([OSMESA_LIB_DEPS])
1499 AC_SUBST([OSMESA_PC_REQ])
1500 AC_SUBST([OSMESA_PC_LIB_PRIV])
1501
1502 dnl
1503 dnl gbm configuration
1504 dnl
1505 if test "x$enable_gbm" = xauto; then
1506     case "$with_egl_platforms" in
1507         *drm*)
1508             enable_gbm=yes ;;
1509          *)
1510             enable_gbm=no ;;
1511     esac
1512 fi
1513 if test "x$enable_gbm" = xyes; then
1514     if test "x$need_pci_id$have_pci_id" = xyesno; then
1515         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1516     fi
1517
1518     if test "x$enable_dri" = xyes; then
1519         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1520         if test "x$enable_shared_glapi" = xno; then
1521             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1522         fi
1523     else
1524         # Strictly speaking libgbm does not require --enable-dri, although
1525         # both of its backends do. Thus one can build libgbm without any
1526         # backends if --disable-dri is set.
1527         # To avoid unnecessary complexity of checking if at least one backend
1528         # is available when building, just mandate --enable-dri.
1529         AC_MSG_ERROR([gbm requires --enable-dri])
1530     fi
1531 fi
1532 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1533 if test "x$need_pci_id$have_libudev" = xyesyes; then
1534     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1535 else
1536     GBM_PC_REQ_PRIV=""
1537 fi
1538 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1539 AC_SUBST([GBM_PC_REQ_PRIV])
1540 AC_SUBST([GBM_PC_LIB_PRIV])
1541
1542 AM_CONDITIONAL(HAVE_VULKAN, true)
1543
1544 dnl
1545 dnl EGL configuration
1546 dnl
1547 EGL_CLIENT_APIS=""
1548
1549 if test "x$enable_egl" = xyes; then
1550     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1551
1552     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1553
1554     if test "$enable_static" != yes; then
1555         if test "x$enable_dri" = xyes; then
1556             HAVE_EGL_DRIVER_DRI2=1
1557         fi
1558
1559     fi
1560 fi
1561 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1562 AC_SUBST([EGL_LIB_DEPS])
1563
1564 dnl
1565 dnl XA configuration
1566 dnl
1567 if test "x$enable_xa" = xyes; then
1568     if test "x$with_gallium_drivers" = xswrast; then
1569        AC_MSG_ERROR([
1570           Building xa requires at least one non swrast gallium driver.
1571           If you are looking to use libxatracker.so with the VMware driver,
1572           make sure to include svga in the gallium drivers list, apart from
1573           enabling XA.
1574           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1575     fi
1576     enable_gallium_loader=$enable_shared_pipe_drivers
1577 fi
1578 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1579
1580 dnl
1581 dnl Gallium G3DVL configuration
1582 dnl
1583 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1584     if test "x$enable_xvmc" = xauto; then
1585         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1586     fi
1587
1588     if test "x$enable_vdpau" = xauto; then
1589         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1590     fi
1591
1592     if test "x$enable_omx" = xauto; then
1593         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1594     fi
1595
1596     if test "x$enable_va" = xauto; then
1597         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1598     fi
1599 fi
1600
1601 if test "x$enable_dri" = xyes -o \
1602         "x$enable_xvmc" = xyes -o \
1603         "x$enable_vdpau" = xyes -o \
1604         "x$enable_omx" = xyes -o \
1605         "x$enable_va" = xyes; then
1606     need_gallium_vl=yes
1607 fi
1608 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1609
1610 if test "x$enable_xvmc" = xyes -o \
1611         "x$enable_vdpau" = xyes -o \
1612         "x$enable_omx" = xyes -o \
1613         "x$enable_va" = xyes; then
1614     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1615     need_gallium_vl_winsys=yes
1616 fi
1617 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1618
1619 if test "x$enable_xvmc" = xyes; then
1620     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1621     enable_gallium_loader=$enable_shared_pipe_drivers
1622 fi
1623 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1624
1625 if test "x$enable_vdpau" = xyes; then
1626     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1627     enable_gallium_loader=$enable_shared_pipe_drivers
1628 fi
1629 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1630
1631 if test "x$enable_omx" = xyes; then
1632     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1633     enable_gallium_loader=$enable_shared_pipe_drivers
1634 fi
1635 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1636
1637 if test "x$enable_va" = xyes; then
1638     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1639     enable_gallium_loader=$enable_shared_pipe_drivers
1640 fi
1641 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1642
1643 dnl
1644 dnl Nine Direct3D9 configuration
1645 dnl
1646 if test "x$enable_nine" = xyes; then
1647     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1648         AC_MSG_ERROR([nine requires the gallium swrast driver])
1649     fi
1650     if test "x$with_gallium_drivers" = xswrast; then
1651         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1652     fi
1653     if test "x$enable_dri3" = xno; then
1654         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1655     fi
1656
1657     enable_gallium_loader=$enable_shared_pipe_drivers
1658 fi
1659 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1660
1661 dnl
1662 dnl OpenCL configuration
1663 dnl
1664
1665 AC_ARG_WITH([clang-libdir],
1666    [AS_HELP_STRING([--with-clang-libdir],
1667          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1668    [CLANG_LIBDIR="$withval"],
1669    [CLANG_LIBDIR=''])
1670
1671 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1672 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1673
1674 if test "x$enable_opencl" = xyes; then
1675     if test -z "$with_gallium_drivers"; then
1676         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1677     fi
1678
1679     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1680         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1681     fi
1682
1683     if test "x$have_libclc" = xno; then
1684         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1685                     Make sure the directory containing libclc.pc is specified in your
1686                     PKG_CONFIG_PATH environment variable.
1687                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1688     else
1689         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1690         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1691         AC_SUBST([LIBCLC_INCLUDEDIR])
1692         AC_SUBST([LIBCLC_LIBEXECDIR])
1693     fi
1694
1695     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1696     enable_gallium_loader=yes
1697
1698     if test "x$enable_opencl_icd" = xyes; then
1699         OPENCL_LIBNAME="MesaOpenCL"
1700     else
1701         OPENCL_LIBNAME="OpenCL"
1702     fi
1703
1704     if test "x$have_libelf" != xyes; then
1705        AC_MSG_ERROR([Clover requires libelf])
1706     fi
1707 fi
1708 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1709 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1710 AC_SUBST([OPENCL_LIBNAME])
1711
1712 dnl
1713 dnl Gallium configuration
1714 dnl
1715 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1716
1717 AC_SUBST([LLVM_BINDIR])
1718 AC_SUBST([LLVM_CFLAGS])
1719 AC_SUBST([LLVM_CPPFLAGS])
1720 AC_SUBST([LLVM_CXXFLAGS])
1721 AC_SUBST([LLVM_LIBDIR])
1722 AC_SUBST([LLVM_LIBS])
1723 AC_SUBST([LLVM_LDFLAGS])
1724 AC_SUBST([LLVM_INCLUDEDIR])
1725 AC_SUBST([LLVM_VERSION])
1726 AC_SUBST([CLANG_RESOURCE_DIR])
1727
1728 case "x$enable_opengl$enable_gles1$enable_gles2" in
1729 x*yes*)
1730     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1731     ;;
1732 esac
1733
1734 AC_SUBST([VG_LIB_DEPS])
1735 AC_SUBST([EGL_CLIENT_APIS])
1736
1737 dnl
1738 dnl EGL Platforms configuration
1739 dnl
1740 AC_ARG_WITH([egl-platforms],
1741     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1742         [comma delimited native platforms libEGL supports, e.g.
1743         "x11,drm" @<:@default=auto@:>@])],
1744     [with_egl_platforms="$withval"],
1745     [if test "x$enable_egl" = xyes; then
1746         with_egl_platforms="x11"
1747     else
1748         with_egl_platforms=""
1749     fi])
1750
1751 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1752     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1753 fi
1754
1755 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1756         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1757         WAYLAND_SCANNER='')
1758 if test "x$WAYLAND_SCANNER" = x; then
1759     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1760 fi
1761
1762 # Do per-EGL platform setups and checks
1763 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1764 for plat in $egl_platforms; do
1765         case "$plat" in
1766         wayland)
1767                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1768
1769                 if test "x$WAYLAND_SCANNER" = x; then
1770                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1771                 fi
1772                 ;;
1773
1774         x11)
1775                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1776                 ;;
1777
1778         drm)
1779                 test "x$enable_gbm" = "xno" &&
1780                         AC_MSG_ERROR([EGL platform drm needs gbm])
1781                 test "x$have_libdrm" != xyes &&
1782                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1783                 ;;
1784
1785         android|gdi|null)
1786                 ;;
1787
1788         *)
1789                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1790                 ;;
1791         esac
1792
1793         case "$plat$need_pci_id$have_pci_id" in
1794                 waylandyesno|drmyesno)
1795                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1796         esac
1797 done
1798
1799 # libEGL wants to default to the first platform specified in
1800 # ./configure.  parse that here.
1801 if test "x$egl_platforms" != "x"; then
1802     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1803     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1804 else
1805     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1806 fi
1807
1808 if echo "$egl_platforms" | grep -q 'x11'; then
1809     NEED_WINSYS_XLIB=yes
1810 fi
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1812 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1813 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1814 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1815
1816 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1817
1818 AC_SUBST([EGL_NATIVE_PLATFORM])
1819 AC_SUBST([EGL_CFLAGS])
1820
1821 # If we don't have the X11 platform, set this define so we don't try to include
1822 # the X11 headers.
1823 if ! echo "$egl_platforms" | grep -q 'x11'; then
1824     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1825     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1826 fi
1827
1828 dnl
1829 dnl Gallium LLVM
1830 dnl
1831 AC_ARG_ENABLE([gallium-llvm],
1832     [AS_HELP_STRING([--enable-gallium-llvm],
1833         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1834     [enable_gallium_llvm="$enableval"],
1835     [enable_gallium_llvm=auto])
1836
1837 AC_ARG_ENABLE([llvm-shared-libs],
1838     [AS_HELP_STRING([--enable-llvm-shared-libs],
1839         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1840     [enable_llvm_shared_libs="$enableval"],
1841     [enable_llvm_shared_libs=yes])
1842
1843 AC_ARG_WITH([llvm-prefix],
1844     [AS_HELP_STRING([--with-llvm-prefix],
1845         [Prefix for LLVM installations in non-standard locations])],
1846     [llvm_prefix="$withval"],
1847     [llvm_prefix=''])
1848
1849
1850 # Call this inside ` ` to get the return value.
1851 # $1 is the llvm-config command with arguments.
1852 strip_unwanted_llvm_flags() {
1853     # Use \> (marks the end of the word)
1854     echo `$1` | sed \
1855         -e 's/-DNDEBUG\>//g' \
1856         -e 's/-D_GNU_SOURCE\>//g' \
1857         -e 's/-pedantic\>//g' \
1858         -e 's/-Wcovered-switch-default\>//g' \
1859         -e 's/-O.\>//g' \
1860         -e 's/-g\>//g' \
1861         -e 's/-Wall\>//g' \
1862         -e 's/-Wcast-qual\>//g' \
1863         -e 's/-Woverloaded-virtual\>//g' \
1864         -e 's/-fcolor-diagnostics\>//g' \
1865         -e 's/-fdata-sections\>//g' \
1866         -e 's/-ffunction-sections\>//g' \
1867         -e 's/-fno-exceptions\>//g' \
1868         -e 's/-fomit-frame-pointer\>//g' \
1869         -e 's/-fvisibility-inlines-hidden\>//g' \
1870         -e 's/-fPIC\>//g' \
1871         -e 's/-fstack-protector-strong\>//g'
1872 }
1873
1874 llvm_check_version_for() {
1875     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1876         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1877     fi
1878 }
1879
1880
1881
1882 if test -z "$with_gallium_drivers"; then
1883     enable_gallium_llvm=no
1884 fi
1885 if test "x$enable_gallium_llvm" = xauto; then
1886     case "$host_cpu" in
1887     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1888     esac
1889 fi
1890 if test "x$enable_gallium_llvm" = xyes; then
1891     if test -n "$llvm_prefix"; then
1892         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1893     else
1894         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1895     fi
1896
1897     if test "x$LLVM_CONFIG" != xno; then
1898         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1899         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1900         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1901         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1902         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1903         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1904         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1905         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1906
1907         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1908             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1909         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1910             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1911
1912         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1913         if test -z "$LLVM_VERSION_PATCH"; then
1914             LLVM_VERSION_PATCH=0
1915         fi
1916
1917         if test -n "${LLVM_VERSION_MAJOR}"; then
1918             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1919         else
1920             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1921         fi
1922
1923         LLVM_REQUIRED_VERSION_MAJOR="3"
1924         LLVM_REQUIRED_VERSION_MINOR="3"
1925         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1926             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1927         fi
1928
1929         LLVM_COMPONENTS="engine bitwriter"
1930         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1931             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1932         fi
1933
1934         if test "x$enable_opencl" = xyes; then
1935             llvm_check_version_for "3" "5" "0" "opencl"
1936
1937             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1938             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1939         fi
1940         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1941         MESA_LLVM=1
1942
1943         dnl Check for Clang internal headers
1944         if test "x$enable_opencl" = xyes; then
1945             if test -z "$CLANG_LIBDIR"; then
1946                 CLANG_LIBDIR=${LLVM_LIBDIR}
1947             fi
1948             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1949             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1950                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1951         fi
1952     else
1953         MESA_LLVM=0
1954         LLVM_VERSION_INT=0
1955     fi
1956 else
1957     MESA_LLVM=0
1958     LLVM_VERSION_INT=0
1959
1960     if test "x$enable_opencl" = xyes; then
1961         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1962     fi
1963 fi
1964
1965 dnl Directory for XVMC libs
1966 AC_ARG_WITH([xvmc-libdir],
1967     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1968         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1969     [XVMC_LIB_INSTALL_DIR="$withval"],
1970     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1971 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1972
1973 dnl
1974 dnl Gallium Tests
1975 dnl
1976 if test "x$enable_gallium_tests" = xyes; then
1977     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1978     enable_gallium_loader=yes
1979 fi
1980 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1981
1982 dnl Directory for VDPAU libs
1983 AC_ARG_WITH([vdpau-libdir],
1984     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1985         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1986     [VDPAU_LIB_INSTALL_DIR="$withval"],
1987     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1988 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1989
1990 dnl Directory for OMX libs
1991
1992 AC_ARG_WITH([omx-libdir],
1993     [AS_HELP_STRING([--with-omx-libdir=DIR],
1994         [directory for the OMX libraries])],
1995     [OMX_LIB_INSTALL_DIR="$withval"],
1996     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1997 AC_SUBST([OMX_LIB_INSTALL_DIR])
1998
1999 dnl Directory for VA libs
2000
2001 AC_ARG_WITH([va-libdir],
2002     [AS_HELP_STRING([--with-va-libdir=DIR],
2003         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2004     [VA_LIB_INSTALL_DIR="$withval"],
2005     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2006 AC_SUBST([VA_LIB_INSTALL_DIR])
2007
2008 AC_ARG_WITH([d3d-libdir],
2009     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2010         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2011     [D3D_DRIVER_INSTALL_DIR="$withval"],
2012     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2013 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2014
2015 dnl
2016 dnl Gallium helper functions
2017 dnl
2018 gallium_require_drm() {
2019     if test "x$have_libdrm" != xyes; then
2020        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2021     fi
2022 }
2023
2024 gallium_require_llvm() {
2025     if test "x$MESA_LLVM" = x0; then
2026         case "$host" in *gnux32) return;; esac
2027         case "$host_cpu" in
2028         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2029         esac
2030     fi
2031 }
2032
2033 gallium_require_drm_loader() {
2034     if test "x$enable_gallium_loader" = xyes; then
2035         if test "x$need_pci_id$have_pci_id" = xyesno; then
2036             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2037         fi
2038         enable_gallium_drm_loader=yes
2039     fi
2040     if test "x$enable_va" = xyes && test "x$7" != x; then
2041          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2042     fi
2043 }
2044
2045 require_egl_drm() {
2046     case "$with_egl_platforms" in
2047         *drm*)
2048             ;;
2049          *)
2050             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2051             ;;
2052     esac
2053     if test "x$enable_gbm" != xyes; then
2054             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2055     fi
2056 }
2057
2058 radeon_llvm_check() {
2059     if test "x$enable_gallium_llvm" != "xyes"; then
2060         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2061     fi
2062     llvm_check_version_for "3" "4" "2" $1
2063     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2064         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2065                       sources with the --enable-experimental-targets=R600
2066                       configure flag])
2067     fi
2068     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2069     NEED_RADEON_LLVM=yes
2070     if test "x$have_libelf" != xyes; then
2071        AC_MSG_ERROR([$1 requires libelf when using llvm])
2072     fi
2073 }
2074
2075 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2076 if test -n "$with_gallium_drivers"; then
2077     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2078     for driver in $gallium_drivers; do
2079         case "x$driver" in
2080         xsvga)
2081             HAVE_GALLIUM_SVGA=yes
2082             gallium_require_drm "svga"
2083             gallium_require_drm_loader
2084             ;;
2085         xi915)
2086             HAVE_GALLIUM_I915=yes
2087             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2088             gallium_require_drm "Gallium i915"
2089             gallium_require_drm_loader
2090             ;;
2091         xilo)
2092             HAVE_GALLIUM_ILO=yes
2093             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2094             gallium_require_drm "Gallium i965/ilo"
2095             gallium_require_drm_loader
2096             ;;
2097         xr300)
2098             HAVE_GALLIUM_R300=yes
2099             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2100             gallium_require_drm "Gallium R300"
2101             gallium_require_drm_loader
2102             gallium_require_llvm "Gallium R300"
2103             ;;
2104         xr600)
2105             HAVE_GALLIUM_R600=yes
2106             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2107             gallium_require_drm "Gallium R600"
2108             gallium_require_drm_loader
2109             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2110                 radeon_llvm_check "r600g"
2111                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2112             fi
2113             if test "x$enable_r600_llvm" = xyes; then
2114                 USE_R600_LLVM_COMPILER=yes;
2115             fi
2116             if test "x$enable_opencl" = xyes; then
2117                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2118             fi
2119             ;;
2120         xradeonsi)
2121             HAVE_GALLIUM_RADEONSI=yes
2122             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2123             gallium_require_drm "radeonsi"
2124             gallium_require_drm_loader
2125             radeon_llvm_check "radeonsi"
2126             require_egl_drm "radeonsi"
2127             ;;
2128         xnouveau)
2129             HAVE_GALLIUM_NOUVEAU=yes
2130             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2131             gallium_require_drm "nouveau"
2132             gallium_require_drm_loader
2133             ;;
2134         xfreedreno)
2135             HAVE_GALLIUM_FREEDRENO=yes
2136             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2137             gallium_require_drm "freedreno"
2138             gallium_require_drm_loader
2139             ;;
2140         xswrast)
2141             HAVE_GALLIUM_SOFTPIPE=yes
2142             if test "x$MESA_LLVM" = x1; then
2143                 HAVE_GALLIUM_LLVMPIPE=yes
2144             fi
2145             ;;
2146         xvc4)
2147             HAVE_GALLIUM_VC4=yes
2148             gallium_require_drm "vc4"
2149             gallium_require_drm_loader
2150
2151             case "$host_cpu" in
2152                 i?86 | x86_64 | amd64)
2153                 USE_VC4_SIMULATOR=yes
2154                 ;;
2155             esac
2156             ;;
2157         *)
2158             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2159             ;;
2160         esac
2161     done
2162 fi
2163
2164 dnl Set LLVM_LIBS - This is done after the driver configuration so
2165 dnl that drivers can add additional components to LLVM_COMPONENTS.
2166 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2167 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2168 dnl this was causing the same libraries to be appear multiple times
2169 dnl in LLVM_LIBS.
2170
2171 if test "x$MESA_LLVM" != x0; then
2172
2173     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2174
2175     if test "x$enable_llvm_shared_libs" = xyes; then
2176         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2177         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2178         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2179
2180         if test "x$llvm_have_one_so" = xyes; then
2181             dnl LLVM was built using auto*, so there is only one shared object.
2182             LLVM_LIBS="-l$LLVM_SO_NAME"
2183         else
2184             dnl If LLVM was built with CMake, there will be one shared object per
2185             dnl component.
2186             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2187                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2188         Please make sure you have built llvm with the --enable-shared option
2189         and that your llvm libraries are installed in $LLVM_LIBDIR
2190         If you have installed your llvm libraries to a different directory you
2191         can use the --with-llvm-prefix= configure flag to specify this directory.
2192         NOTE: Mesa is attempting to use llvm shared libraries by default.
2193         If you do not want to build with llvm shared libraries and instead want to
2194         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2195         invocation and rebuild.])])
2196
2197            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2198            dnl install uses a shared object for each component and we have
2199            dnl already added all of these objects to LLVM_LIBS.
2200         fi
2201     else
2202         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2203         dnl We need to link to llvm system libs when using static libs
2204         dnl However, only llvm 3.5+ provides --system-libs
2205         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2206             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2207         fi
2208     fi
2209 fi
2210
2211 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2212 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2213 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2214 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2215 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2216 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2217 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2218                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2219 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2220 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2222 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2223 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2224
2225 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2226
2227 # NOTE: anything using xcb or other client side libs ends up in separate
2228 #       _CLIENT variables.  The pipe loader is built in two variants,
2229 #       one that is standalone and does not link any x client libs (for
2230 #       use by XA tracker in particular, but could be used in any case
2231 #       where communication with xserver is not desired).
2232 if test "x$enable_gallium_loader" = xyes; then
2233     if test "x$NEED_WINSYS_XLIB" = xyes; then
2234         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2235     fi
2236
2237     if test "x$enable_dri" = xyes; then
2238         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2239     fi
2240
2241     if test "x$enable_gallium_drm_loader" = xyes; then
2242         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2243         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2244                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2245         if test "x$pipe_loader_have_xcb" = xyes; then
2246             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2247             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2248         fi
2249     fi
2250
2251     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2252     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2253
2254     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2255     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2256     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2257     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2258 fi
2259
2260 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2261 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2262 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2263 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2264 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2265 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2266
2267 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2268                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2269                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2270 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2271 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2272 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2273 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2274 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2275 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2276 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2277 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2278 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2279     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2280 fi
2281
2282 AC_SUBST([ELF_LIB])
2283
2284 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2285 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2286 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2287 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2288 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2289
2290 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2291 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2292 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2293
2294 AC_SUBST([NINE_MAJOR], 1)
2295 AC_SUBST([NINE_MINOR], 0)
2296 AC_SUBST([NINE_TINY], 0)
2297 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2298
2299 AC_SUBST([VDPAU_MAJOR], 1)
2300 AC_SUBST([VDPAU_MINOR], 0)
2301
2302 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2303 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2304 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2305 AC_SUBST([VA_MINOR], $VA_MINOR)
2306
2307 AC_SUBST([XVMC_MAJOR], 1)
2308 AC_SUBST([XVMC_MINOR], 0)
2309
2310 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2311 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2312 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2313 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2314
2315 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2316 AC_SUBST([XA_MINOR], $XA_MINOR)
2317 AC_SUBST([XA_TINY], $XA_TINY)
2318 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2319
2320 PKG_CHECK_MODULES(VALGRIND, [valgrind],
2321                   [have_valgrind=yes], [have_valgrind=no])
2322 if test "x$have_valgrind" = "xyes"; then
2323     AC_DEFINE([HAVE_VALGRIND], 1,
2324               [Use valgrind intrinsics to suppress false warnings])
2325 fi
2326
2327 dnl Restore LDFLAGS and CPPFLAGS
2328 LDFLAGS="$_SAVE_LDFLAGS"
2329 CPPFLAGS="$_SAVE_CPPFLAGS"
2330
2331 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2332 if test "x$acv_mesa_CLANG" = xyes; then
2333     CFLAGS="$CFLAGS -Qunused-arguments"
2334     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2335 fi
2336
2337 dnl Add user CFLAGS and CXXFLAGS
2338 CFLAGS="$CFLAGS $USER_CFLAGS"
2339 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2340
2341 dnl Substitute the config
2342 AC_CONFIG_FILES([Makefile
2343                 src/Makefile
2344                 src/egl/drivers/dri2/Makefile
2345                 src/egl/main/Makefile
2346                 src/egl/main/egl.pc
2347                 src/egl/wayland/wayland-drm/Makefile
2348                 src/egl/wayland/wayland-egl/Makefile
2349                 src/egl/wayland/wayland-egl/wayland-egl.pc
2350                 src/gallium/Makefile
2351                 src/gallium/auxiliary/Makefile
2352                 src/gallium/auxiliary/pipe-loader/Makefile
2353                 src/gallium/drivers/freedreno/Makefile
2354                 src/gallium/drivers/i915/Makefile
2355                 src/gallium/drivers/ilo/Makefile
2356                 src/gallium/drivers/llvmpipe/Makefile
2357                 src/gallium/drivers/noop/Makefile
2358                 src/gallium/drivers/nouveau/Makefile
2359                 src/gallium/drivers/r300/Makefile
2360                 src/gallium/drivers/r600/Makefile
2361                 src/gallium/drivers/radeon/Makefile
2362                 src/gallium/drivers/radeonsi/Makefile
2363                 src/gallium/drivers/rbug/Makefile
2364                 src/gallium/drivers/softpipe/Makefile
2365                 src/gallium/drivers/svga/Makefile
2366                 src/gallium/drivers/trace/Makefile
2367                 src/gallium/drivers/vc4/Makefile
2368                 src/gallium/drivers/vc4/kernel/Makefile
2369                 src/gallium/state_trackers/clover/Makefile
2370                 src/gallium/state_trackers/dri/Makefile
2371                 src/gallium/state_trackers/glx/xlib/Makefile
2372                 src/gallium/state_trackers/nine/Makefile
2373                 src/gallium/state_trackers/omx/Makefile
2374                 src/gallium/state_trackers/osmesa/Makefile
2375                 src/gallium/state_trackers/va/Makefile
2376                 src/gallium/state_trackers/vdpau/Makefile
2377                 src/gallium/state_trackers/xa/Makefile
2378                 src/gallium/state_trackers/xvmc/Makefile
2379                 src/gallium/targets/d3dadapter9/Makefile
2380                 src/gallium/targets/d3dadapter9/d3d.pc
2381                 src/gallium/targets/dri/Makefile
2382                 src/gallium/targets/libgl-xlib/Makefile
2383                 src/gallium/targets/omx/Makefile
2384                 src/gallium/targets/opencl/Makefile
2385                 src/gallium/targets/osmesa/Makefile
2386                 src/gallium/targets/osmesa/osmesa.pc
2387                 src/gallium/targets/pipe-loader/Makefile
2388                 src/gallium/targets/va/Makefile
2389                 src/gallium/targets/vdpau/Makefile
2390                 src/gallium/targets/xa/Makefile
2391                 src/gallium/targets/xa/xatracker.pc
2392                 src/gallium/targets/xvmc/Makefile
2393                 src/gallium/tests/trivial/Makefile
2394                 src/gallium/tests/unit/Makefile
2395                 src/gallium/winsys/freedreno/drm/Makefile
2396                 src/gallium/winsys/i915/drm/Makefile
2397                 src/gallium/winsys/intel/drm/Makefile
2398                 src/gallium/winsys/nouveau/drm/Makefile
2399                 src/gallium/winsys/radeon/drm/Makefile
2400                 src/gallium/winsys/svga/drm/Makefile
2401                 src/gallium/winsys/sw/dri/Makefile
2402                 src/gallium/winsys/sw/kms-dri/Makefile
2403                 src/gallium/winsys/sw/null/Makefile
2404                 src/gallium/winsys/sw/wrapper/Makefile
2405                 src/gallium/winsys/sw/xlib/Makefile
2406                 src/gallium/winsys/vc4/drm/Makefile
2407                 src/gbm/Makefile
2408                 src/gbm/main/gbm.pc
2409                 src/glsl/Makefile
2410                 src/glx/Makefile
2411                 src/glx/apple/Makefile
2412                 src/glx/tests/Makefile
2413                 src/gtest/Makefile
2414                 src/loader/Makefile
2415                 src/mapi/Makefile
2416                 src/mapi/es1api/glesv1_cm.pc
2417                 src/mapi/es2api/glesv2.pc
2418                 src/mapi/glapi/gen/Makefile
2419                 src/mesa/Makefile
2420                 src/mesa/gl.pc
2421                 src/mesa/drivers/dri/dri.pc
2422                 src/mesa/drivers/dri/common/Makefile
2423                 src/mesa/drivers/dri/common/xmlpool/Makefile
2424                 src/mesa/drivers/dri/i915/Makefile
2425                 src/mesa/drivers/dri/i965/Makefile
2426                 src/mesa/drivers/dri/Makefile
2427                 src/mesa/drivers/dri/nouveau/Makefile
2428                 src/mesa/drivers/dri/r200/Makefile
2429                 src/mesa/drivers/dri/radeon/Makefile
2430                 src/mesa/drivers/dri/swrast/Makefile
2431                 src/mesa/drivers/osmesa/Makefile
2432                 src/mesa/drivers/osmesa/osmesa.pc
2433                 src/mesa/drivers/x11/Makefile
2434                 src/mesa/main/tests/Makefile
2435                 src/vulkan/Makefile
2436                 src/util/Makefile
2437                 src/util/tests/hash_table/Makefile])
2438
2439 AC_OUTPUT
2440
2441 dnl
2442 dnl Output some configuration info for the user
2443 dnl
2444 echo ""
2445 echo "        prefix:          $prefix"
2446 echo "        exec_prefix:     $exec_prefix"
2447 echo "        libdir:          $libdir"
2448 echo "        includedir:      $includedir"
2449
2450 dnl API info
2451 echo ""
2452 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2453
2454 dnl Driver info
2455 echo ""
2456 case "x$enable_osmesa$enable_gallium_osmesa" in
2457 xnoyes)
2458         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2459         ;;
2460 xyesno)
2461         echo "        OSMesa:          lib$OSMESA_LIB"
2462         ;;
2463 xnono)
2464         echo "        OSMesa:          no"
2465         ;;
2466 esac
2467
2468 echo ""
2469 if test "x$enable_dri" != xno; then
2470         echo "        DRI platform:    $dri_platform"
2471         if test -z "$DRI_DIRS"; then
2472             echo "        DRI drivers:     no"
2473         else
2474             echo "        DRI drivers:     $DRI_DIRS"
2475         fi
2476         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2477 fi
2478
2479 case "x$enable_glx$enable_xlib_glx" in
2480 xyesyes)
2481     echo "        GLX:             Xlib-based"
2482     ;;
2483 xyesno)
2484     echo "        GLX:             DRI-based"
2485     ;;
2486 *)
2487     echo "        GLX:             $enable_glx"
2488     ;;
2489 esac
2490
2491 dnl EGL
2492 echo ""
2493 echo "        EGL:             $enable_egl"
2494 if test "$enable_egl" = yes; then
2495     echo "        EGL platforms:   $egl_platforms"
2496
2497     egl_drivers=""
2498     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2499         egl_drivers="$egl_drivers builtin:egl_dri2"
2500     fi
2501
2502     echo "        EGL drivers:    $egl_drivers"
2503 fi
2504
2505 echo ""
2506 if test "x$MESA_LLVM" = x1; then
2507     echo "        llvm:            yes"
2508     echo "        llvm-config:     $LLVM_CONFIG"
2509     echo "        llvm-version:    $LLVM_VERSION"
2510 else
2511     echo "        llvm:            no"
2512 fi
2513
2514 echo ""
2515 if test -n "$with_gallium_drivers"; then
2516     echo "        Gallium:         yes"
2517 else
2518     echo "        Gallium:         no"
2519 fi
2520
2521 dnl Shader cache
2522 echo ""
2523 echo "        Shader cache:    $enable_shader_cache"
2524 if test "x$enable_shader_cache" = "xyes"; then
2525     echo "        With SHA1 from:  $with_sha1"
2526 fi
2527
2528 dnl Libraries
2529 echo ""
2530 echo "        Shared libs:     $enable_shared"
2531 echo "        Static libs:     $enable_static"
2532 echo "        Shared-glapi:    $enable_shared_glapi"
2533
2534 dnl Compiler options
2535 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2536 cflags=`echo $CFLAGS | \
2537     $SED 's/^ *//;s/  */ /;s/ *$//'`
2538 cxxflags=`echo $CXXFLAGS | \
2539     $SED 's/^ *//;s/  */ /;s/ *$//'`
2540 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2541 echo ""
2542 echo "        CFLAGS:          $cflags"
2543 echo "        CXXFLAGS:        $cxxflags"
2544 echo "        Macros:          $defines"
2545 echo ""
2546 if test "x$MESA_LLVM" = x1; then
2547     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2548     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2549     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2550     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2551     echo ""
2552 fi
2553 echo "        PYTHON2:         $PYTHON2"
2554
2555 echo ""
2556 echo "        Run '${MAKE-make}' to build Mesa"
2557 echo ""