configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 827 dnl is not valid for that platform.
 828 if test "x$android" = xno; then
 829     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 830 fi
 831
 832 dnl pthread-stubs is mandatory on targets where it exists
 833 case "$host_os" in
 834 cygwin* )
 835     pthread_stubs_possible="no"
 836     ;;
 837 * )
 838     pthread_stubs_possible="yes"
 839     ;;
 840 esac
 841
 842 if test "x$pthread_stubs_possible" = xyes; then
 843     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 844     AC_SUBST(PTHREADSTUBS_CFLAGS)
 845     AC_SUBST(PTHREADSTUBS_LIBS)
 846 fi
 847
 848 dnl SELinux awareness.
 849 AC_ARG_ENABLE([selinux],
 850     [AS_HELP_STRING([--enable-selinux],
 851         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 852     [MESA_SELINUX="$enableval"],
 853     [MESA_SELINUX=no])
 854 if test "x$enable_selinux" = "xyes"; then
 855     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 856         [AC_CHECK_HEADER([selinux/selinux.h],[],
 857                          [AC_MSG_ERROR([SELinux headers not found])])
 858          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 859                       [AC_MSG_ERROR([SELinux library not found])])
 860          SELINUX_LIBS="-lselinux"])
 861     DEFINES="$DEFINES -DMESA_SELINUX"
 862 fi
 863 AC_SUBST([SELINUX_CFLAGS])
 864 AC_SUBST([SELINUX_LIBS])
 865
 866 dnl
 867 dnl LLVM
 868 dnl
 869 AC_ARG_ENABLE([llvm-shared-libs],
 870     [AS_HELP_STRING([--enable-llvm-shared-libs],
 871         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 872     [enable_llvm_shared_libs="$enableval"],
 873     [enable_llvm_shared_libs=yes])
 874
 875 AC_ARG_WITH([llvm-prefix],
 876     [AS_HELP_STRING([--with-llvm-prefix],
 877         [Prefix for LLVM installations in non-standard locations])],
 878     [llvm_prefix="$withval"],
 879     [llvm_prefix=''])
 880
 881 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 882 if test "x$have_libelf" = xno; then
 883    LIBELF_LIBS=''
 884    LIBELF_CFLAGS=''
 885    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 886    AC_SUBST([LIBELF_LIBS])
 887    AC_SUBST([LIBELF_CFLAGS])
 888 fi
 889
 890 if test -z "$LLVM_CONFIG"; then
 891     if test -n "$llvm_prefix"; then
 892         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 893     else
 894         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 895     fi
 896 fi
 897
 898 llvm_add_component() {
 899     new_llvm_component=$1
 900     driver_name=$2
 901
 902     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 903         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 904     else
 905         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 906     fi
 907 }
 908
 909 llvm_add_default_components() {
 910     driver_name=$1
 911
 912     # Required default components
 913     llvm_add_component "bitwriter" $driver_name
 914     llvm_add_component "engine" $driver_name
 915     llvm_add_component "mcdisassembler" $driver_name
 916     llvm_add_component "mcjit" $driver_name
 917
 918     # Optional default components
 919     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 920         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 921     fi
 922 }
 923
 924 llvm_add_target() {
 925     new_llvm_target=$1
 926     driver_name=$2
 927
 928     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 929         llvm_add_component $new_llvm_target $driver_name
 930     else
 931         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 932     fi
 933 }
 934
 935 # Call this inside ` ` to get the return value.
 936 # $1 is the llvm-config command with arguments.
 937 strip_unwanted_llvm_flags() {
 938     # Use \> (marks the end of the word)
 939     echo `$1` | sed \
 940         -e 's/-march=\S*//g' \
 941         -e 's/-mtune=\S*//g' \
 942         -e 's/-mcpu=\S*//g' \
 943         -e 's/-DNDEBUG\>//g' \
 944         -e 's/-D_GNU_SOURCE\>//g' \
 945         -e 's/-pedantic\>//g' \
 946         -e 's/-Wcovered-switch-default\>//g' \
 947         -e 's/-O.\>//g' \
 948         -e 's/-g\>//g' \
 949         -e 's/-Wall\>//g' \
 950         -e 's/-Wcast-qual\>//g' \
 951         -e 's/-Woverloaded-virtual\>//g' \
 952         -e 's/-fcolor-diagnostics\>//g' \
 953         -e 's/-fdata-sections\>//g' \
 954         -e 's/-ffunction-sections\>//g' \
 955         -e 's/-fno-exceptions\>//g' \
 956         -e 's/-fomit-frame-pointer\>//g' \
 957         -e 's/-fvisibility-inlines-hidden\>//g' \
 958         -e 's/-fPIC\>//g' \
 959         -e 's/-fstack-protector-strong\>//g'
 960 }
 961
 962 llvm_set_environment_variables() {
 963     if test "x$LLVM_CONFIG" != xno; then
 964         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 965         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 966         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 967         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 968         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 969         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 970         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 971         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 972
 973         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 974             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 975         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 976             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 977
 978         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 979         if test -z "$LLVM_VERSION_PATCH"; then
 980             LLVM_VERSION_PATCH=0
 981         fi
 982
 983         if test -n "${LLVM_VERSION_MAJOR}"; then
 984             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 985         else
 986             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
 987         fi
 988
 989         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
 990         MESA_LLVM=1
 991     else
 992         MESA_LLVM=0
 993         LLVM_VERSION_INT=0
 994     fi
 995 }
 996
 997 llvm_check_version_for() {
 998     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
 999         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1000     fi
1001 }
1002
1003 radeon_llvm_check() {
1004     if test ${LLVM_VERSION_INT} -lt 307; then
1005         amdgpu_llvm_target_name='r600'
1006     else
1007         amdgpu_llvm_target_name='amdgpu'
1008     fi
1009
1010     llvm_check_version_for $*
1011
1012     llvm_add_target $amdgpu_llvm_target_name $4
1013
1014     llvm_add_default_components $4
1015     llvm_add_component "bitreader" $4
1016     llvm_add_component "ipo" $4
1017
1018     NEED_RADEON_LLVM=yes
1019     if test "x$have_libelf" != xyes; then
1020        AC_MSG_ERROR([$1 requires libelf when using llvm])
1021     fi
1022 }
1023
1024 llvm_set_environment_variables
1025
1026 AC_SUBST([MESA_LLVM])
1027 AC_SUBST([LLVM_BINDIR])
1028 AC_SUBST([LLVM_CFLAGS])
1029 AC_SUBST([LLVM_CPPFLAGS])
1030 AC_SUBST([LLVM_CXXFLAGS])
1031 AC_SUBST([LLVM_LIBDIR])
1032 AC_SUBST([LLVM_LIBS])
1033 AC_SUBST([LLVM_LDFLAGS])
1034 AC_SUBST([LLVM_INCLUDEDIR])
1035 AC_SUBST([LLVM_VERSION])
1036
1037 dnl Options for APIs
1038 AC_ARG_ENABLE([opengl],
1039     [AS_HELP_STRING([--disable-opengl],
1040         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1041     [enable_opengl="$enableval"],
1042     [enable_opengl=yes])
1043 AC_ARG_ENABLE([gles1],
1044     [AS_HELP_STRING([--disable-gles1],
1045         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1046     [enable_gles1="$enableval"],
1047     [enable_gles1=yes])
1048 AC_ARG_ENABLE([gles2],
1049     [AS_HELP_STRING([--disable-gles2],
1050         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1051     [enable_gles2="$enableval"],
1052     [enable_gles2=yes])
1053
1054 AC_ARG_ENABLE([dri],
1055     [AS_HELP_STRING([--enable-dri],
1056         [enable DRI modules @<:@default=enabled@:>@])],
1057     [enable_dri="$enableval"],
1058     [enable_dri=yes])
1059
1060 AC_ARG_ENABLE([gallium-extra-hud],
1061     [AS_HELP_STRING([--enable-gallium-extra-hud],
1062         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1063     [enable_gallium_extra_hud="$enableval"],
1064     [enable_gallium_extra_hud=no])
1065 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1066 if test "x$enable_gallium_extra_hud" = xyes ; then
1067     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1068 fi
1069
1070 #TODO: no pkgconfig .pc available for libsensors.
1071 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1072 AC_ARG_ENABLE([lmsensors],
1073     [AS_HELP_STRING([--enable-lmsensors],
1074         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1075     [enable_lmsensors="$enableval"],
1076     [enable_lmsensors=no])
1077 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1078 if test "x$enable_lmsensors" = xyes ; then
1079     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1080     LIBSENSORS_LDFLAGS="-lsensors"
1081 else
1082     LIBSENSORS_LDFLAGS=""
1083 fi
1084 AC_SUBST(LIBSENSORS_LDFLAGS)
1085
1086 case "$host_os" in
1087 linux*)
1088     dri3_default=yes
1089     ;;
1090 *)
1091     dri3_default=no
1092     ;;
1093 esac
1094
1095 if test "x$enable_dri" = xno; then
1096     dri3_default=no
1097 fi
1098
1099 AC_ARG_ENABLE([dri3],
1100     [AS_HELP_STRING([--enable-dri3],
1101         [enable DRI3 @<:@default=auto@:>@])],
1102     [enable_dri3="$enableval"],
1103     [enable_dri3="$dri3_default"])
1104 AC_ARG_ENABLE([glx],
1105     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1106         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1107     [enable_glx="$enableval"],
1108     [enable_glx=yes])
1109 AC_ARG_ENABLE([osmesa],
1110     [AS_HELP_STRING([--enable-osmesa],
1111         [enable OSMesa library @<:@default=disabled@:>@])],
1112     [enable_osmesa="$enableval"],
1113     [enable_osmesa=no])
1114 AC_ARG_ENABLE([gallium-osmesa],
1115     [AS_HELP_STRING([--enable-gallium-osmesa],
1116         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1117     [enable_gallium_osmesa="$enableval"],
1118     [enable_gallium_osmesa=no])
1119 AC_ARG_ENABLE([egl],
1120     [AS_HELP_STRING([--disable-egl],
1121         [disable EGL library @<:@default=enabled@:>@])],
1122     [enable_egl="$enableval"],
1123     [enable_egl=yes])
1124
1125 AC_ARG_ENABLE([xa],
1126     [AS_HELP_STRING([--enable-xa],
1127         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1128     [enable_xa="$enableval"],
1129     [enable_xa=no])
1130 AC_ARG_ENABLE([gbm],
1131    [AS_HELP_STRING([--enable-gbm],
1132          [enable gbm library @<:@default=yes except cygwin@:>@])],
1133    [enable_gbm="$enableval"],
1134    [case "$host_os" in
1135        cygwin*)
1136           enable_gbm=no
1137           ;;
1138        *)
1139           enable_gbm=yes
1140           ;;
1141     esac])
1142 AC_ARG_ENABLE([nine],
1143     [AS_HELP_STRING([--enable-nine],
1144         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1145     [enable_nine="$enableval"],
1146     [enable_nine=no])
1147
1148 AC_ARG_ENABLE([xvmc],
1149    [AS_HELP_STRING([--enable-xvmc],
1150          [enable xvmc library @<:@default=auto@:>@])],
1151    [enable_xvmc="$enableval"],
1152    [enable_xvmc=auto])
1153 AC_ARG_ENABLE([vdpau],
1154    [AS_HELP_STRING([--enable-vdpau],
1155          [enable vdpau library @<:@default=auto@:>@])],
1156    [enable_vdpau="$enableval"],
1157    [enable_vdpau=auto])
1158 AC_ARG_ENABLE([omx],
1159    [AS_HELP_STRING([--enable-omx],
1160          [enable OpenMAX library @<:@default=disabled@:>@])],
1161    [enable_omx="$enableval"],
1162    [enable_omx=no])
1163 AC_ARG_ENABLE([va],
1164    [AS_HELP_STRING([--enable-va],
1165          [enable va library @<:@default=auto@:>@])],
1166    [enable_va="$enableval"],
1167    [enable_va=auto])
1168 AC_ARG_ENABLE([opencl],
1169    [AS_HELP_STRING([--enable-opencl],
1170          [enable OpenCL library @<:@default=disabled@:>@])],
1171    [enable_opencl="$enableval"],
1172    [enable_opencl=no])
1173 AC_ARG_ENABLE([opencl_icd],
1174    [AS_HELP_STRING([--enable-opencl-icd],
1175           [Build an OpenCL ICD library to be loaded by an ICD implementation
1176            @<:@default=disabled@:>@])],
1177     [enable_opencl_icd="$enableval"],
1178     [enable_opencl_icd=no])
1179
1180 AC_ARG_ENABLE([gallium-tests],
1181     [AS_HELP_STRING([--enable-gallium-tests],
1182         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1183     [enable_gallium_tests="$enableval"],
1184     [enable_gallium_tests=no])
1185
1186 # Option for Gallium drivers
1187
1188 # Keep this in sync with the --with-gallium-drivers help string default value
1189 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1190
1191 AC_ARG_WITH([gallium-drivers],
1192     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1193         [comma delimited Gallium drivers list, e.g.
1194         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1195         @<:@default=r300,r600,svga,swrast@:>@])],
1196     [with_gallium_drivers="$withval"],
1197     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1198
1199 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1200 # here so that the script doesn't choke on an unknown driver name later.
1201 case "$with_gallium_drivers" in
1202     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1203     no) with_gallium_drivers='' ;;
1204 esac
1205
1206 if test "x$enable_opengl" = xno -a \
1207         "x$enable_gles1" = xno -a \
1208         "x$enable_gles2" = xno -a \
1209         "x$enable_nine" = xno -a \
1210         "x$enable_xa" = xno -a \
1211         "x$enable_xvmc" = xno -a \
1212         "x$enable_vdpau" = xno -a \
1213         "x$enable_omx" = xno -a \
1214         "x$enable_va" = xno -a \
1215         "x$enable_opencl" = xno; then
1216     AC_MSG_ERROR([at least one API should be enabled])
1217 fi
1218
1219 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1220 if test "x$enable_opengl" = xno -a \
1221         "x$enable_gles1" = xyes; then
1222     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1223 fi
1224
1225 if test "x$enable_opengl" = xno -a \
1226         "x$enable_gles2" = xyes; then
1227     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1228 fi
1229
1230 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1231 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1232 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1233 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1234                                         "x$enable_gles1" = xyes -o \
1235                                         "x$enable_gles2" = xyes)
1236
1237 # Validate GLX options
1238 if test "x$enable_glx" = xyes; then
1239     if test "x$enable_dri" = xyes; then
1240         enable_glx=dri
1241     elif test -n "$with_gallium_drivers"; then
1242         enable_glx=gallium-xlib
1243     else
1244         enable_glx=xlib
1245     fi
1246 fi
1247 case "x$enable_glx" in
1248 xdri | xxlib | xgallium-xlib)
1249     # GLX requires OpenGL
1250     if test "x$enable_opengl" = xno; then
1251         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1252     fi
1253
1254     # Check individual dependencies
1255     case "x$enable_glx" in
1256     xdri)
1257         if test "x$enable_dri" = xno; then
1258             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1259         fi
1260         ;;
1261     xxlib)
1262         if test "x$enable_dri" = xyes; then
1263             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1264         fi
1265         ;;
1266     xgallium-xlib )
1267         if test "x$enable_dri" = xyes; then
1268             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1269         fi
1270         if test -z "$with_gallium_drivers"; then
1271             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1272         fi
1273         ;;
1274     esac
1275     ;;
1276 xno)
1277     ;;
1278 *)
1279     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1280     ;;
1281 esac
1282
1283 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1284 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1285 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1286 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1287
1288 dnl
1289 dnl Libglvnd configuration
1290 dnl
1291 AC_ARG_ENABLE([libglvnd],
1292     [AS_HELP_STRING([--enable-libglvnd],
1293         [Build for libglvnd @<:@default=disabled@:>@])],
1294     [enable_libglvnd="$enableval"],
1295     [enable_libglvnd=no])
1296 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1297 if test "x$enable_libglvnd" = xyes ; then
1298     dnl XXX: update once we can handle more than libGL/glx.
1299     dnl Namely: we should error out if neither of the glvnd enabled libraries
1300     dnl are built
1301     case "x$enable_glx" in
1302     xno)
1303         AC_MSG_ERROR([cannot build libglvnd without GLX])
1304         ;;
1305     xxlib | xgallium-xlib )
1306         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1307         ;;
1308     xdri)
1309         ;;
1310     esac
1311
1312     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1313     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1314     DEFAULT_GL_LIB_NAME=GLX_mesa
1315 fi
1316
1317 # Check for libdrm
1318 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1319                   [have_libdrm=yes], [have_libdrm=no])
1320 if test "x$have_libdrm" = xyes; then
1321         DEFINES="$DEFINES -DHAVE_LIBDRM"
1322 fi
1323
1324 require_libdrm() {
1325     if test "x$have_libdrm" != xyes; then
1326        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1327     fi
1328 }
1329
1330
1331 # Select which platform-dependent DRI code gets built
1332 case "$host_os" in
1333 darwin*)
1334     dri_platform='apple' ;;
1335 cygwin*)
1336     dri_platform='windows' ;;
1337 gnu*)
1338     dri_platform='none' ;;
1339 *)
1340     dri_platform='drm' ;;
1341 esac
1342
1343 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1344     have_drisw_kms='yes'
1345 fi
1346
1347 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1348 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1349 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1350 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1351 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1352 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1353 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1354 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1355 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1356
1357 AC_ARG_ENABLE([shared-glapi],
1358     [AS_HELP_STRING([--enable-shared-glapi],
1359         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1360     [enable_shared_glapi="$enableval"],
1361     [enable_shared_glapi=yes])
1362
1363 case "x$enable_opengl$enable_gles1$enable_gles2" in
1364 x*yes*yes*)
1365     if test "x$enable_shared_glapi" = xno; then
1366         AC_MSG_ERROR([shared GLAPI required when building two or more of
1367                       the following APIs - opengl, gles1 gles2])
1368     fi
1369     ;;
1370 esac
1371
1372 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1373
1374 # Build the pipe-drivers as separate libraries/modules.
1375 # Do not touch this unless you know what you are doing.
1376 # XXX: Expose via configure option ?
1377 enable_shared_pipe_drivers=no
1378
1379 dnl
1380 dnl Driver specific build directories
1381 dnl
1382
1383 if test "x$enable_gallium_osmesa" = xyes; then
1384     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1385         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1386     fi
1387     if test "x$enable_osmesa" = xyes; then
1388         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1389     fi
1390 fi
1391
1392 # SHA1 hashing
1393 AC_ARG_WITH([sha1],
1394         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1395         [choose SHA1 implementation])])
1396 case "x$with_sha1" in
1397 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1398   ;;
1399 *)
1400         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1401 esac
1402
1403 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1404 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1405         with_sha1=libc
1406 fi
1407 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1408         AC_MSG_ERROR([sha1 in libc requested but not found])
1409 fi
1410 if test "x$with_sha1" = xlibc; then
1411         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1412                 [Use libc SHA1 functions])
1413         SHA1_LIBS=""
1414 fi
1415 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1416 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1417         with_sha1=CommonCrypto
1418 fi
1419 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1420         AC_MSG_ERROR([CommonCrypto requested but not found])
1421 fi
1422 if test "x$with_sha1" = xCommonCrypto; then
1423         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1424                 [Use CommonCrypto SHA1 functions])
1425         SHA1_LIBS=""
1426 fi
1427 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1428 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1429 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1430         with_sha1=CryptoAPI
1431 fi
1432 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1433         AC_MSG_ERROR([CryptoAPI requested but not found])
1434 fi
1435 if test "x$with_sha1" = xCryptoAPI; then
1436         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1437                 [Use CryptoAPI SHA1 functions])
1438         SHA1_LIBS=""
1439 fi
1440 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1441 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1442         with_sha1=libmd
1443 fi
1444 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1445         AC_MSG_ERROR([libmd requested but not found])
1446 fi
1447 if test "x$with_sha1" = xlibmd; then
1448         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1449                   [Use libmd SHA1 functions])
1450         SHA1_LIBS=-lmd
1451 fi
1452 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1453 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1454    with_sha1=libsha1
1455 fi
1456 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1457         AC_MSG_ERROR([libsha1 requested but not found])
1458 fi
1459 if test "x$with_sha1" = xlibsha1; then
1460         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1461                   [Use libsha1 for SHA1])
1462         SHA1_LIBS=-lsha1
1463 fi
1464 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1465 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1466         with_sha1=libnettle
1467 fi
1468 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1469         AC_MSG_ERROR([libnettle requested but not found])
1470 fi
1471 if test "x$with_sha1" = xlibnettle; then
1472         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1473                   [Use libnettle SHA1 functions])
1474         SHA1_LIBS=-lnettle
1475 fi
1476 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1477 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1478         with_sha1=libgcrypt
1479 fi
1480 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1481         AC_MSG_ERROR([libgcrypt requested but not found])
1482 fi
1483 if test "x$with_sha1" = xlibgcrypt; then
1484         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1485                   [Use libgcrypt SHA1 functions])
1486         SHA1_LIBS=-lgcrypt
1487 fi
1488 # We don't need all of the OpenSSL libraries, just libcrypto
1489 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1490 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1491                   [HAVE_OPENSSL_PKC=no])
1492 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1493         if test "x$with_sha1" = x; then
1494                 with_sha1=libcrypto
1495         fi
1496 else
1497         if test "x$with_sha1" = xlibcrypto; then
1498                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1499         fi
1500 fi
1501 if test "x$with_sha1" = xlibcrypto; then
1502         if test "x$HAVE_LIBCRYPTO" = xyes; then
1503                 SHA1_LIBS=-lcrypto
1504         else
1505                 SHA1_LIBS="$OPENSSL_LIBS"
1506                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1507         fi
1508 fi
1509 AC_MSG_CHECKING([for SHA1 implementation])
1510 AC_MSG_RESULT([$with_sha1])
1511 AC_SUBST(SHA1_LIBS)
1512 AC_SUBST(SHA1_CFLAGS)
1513
1514 # Enable a define for SHA1
1515 if test "x$with_sha1" != "x"; then
1516         DEFINES="$DEFINES -DHAVE_SHA1"
1517 fi
1518
1519 # Allow user to configure out the shader-cache feature
1520 AC_ARG_ENABLE([shader-cache],
1521     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1522     [enable_shader_cache="$enableval"],
1523     [if test "x$with_sha1" != "x"; then
1524         enable_shader_cache=yes
1525      else
1526         enable_shader_cache=no
1527      fi])
1528 if test "x$with_sha1" = "x"; then
1529     if test "x$enable_shader_cache" = "xyes"; then
1530         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1531     fi
1532 fi
1533 if test "x$enable_shader_cache" = "xyes"; then
1534    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1535 fi
1536
1537 if test "x$enable_dri" = xyes; then
1538     if test "$enable_static" = yes; then
1539         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1540     fi
1541
1542     # not a hard requirement as swrast does not depend on it
1543     if test "x$have_libdrm" = xyes; then
1544         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1545     fi
1546 fi
1547
1548 AC_ARG_ENABLE([driglx-direct],
1549     [AS_HELP_STRING([--disable-driglx-direct],
1550         [disable direct rendering in GLX and EGL for DRI \
1551             @<:@default=auto@:>@])],
1552     [driglx_direct="$enableval"],
1553     [driglx_direct="yes"])
1554
1555 dnl
1556 dnl libGL configuration per driver
1557 dnl
1558 case "x$enable_glx" in
1559 xxlib | xgallium-xlib)
1560     # Xlib-based GLX
1561     dri_modules="x11 xext xcb"
1562     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1563     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1564     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1565     GL_LIB_DEPS="$XLIBGL_LIBS"
1566     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1567     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1568     ;;
1569 xdri)
1570     # DRI-based GLX
1571     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1572
1573     # find the DRI deps for libGL
1574     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1575
1576     if test x"$driglx_direct" = xyes; then
1577         if test x"$dri_platform" = xdrm ; then
1578             DEFINES="$DEFINES -DGLX_USE_DRM"
1579             require_libdrm "Direct rendering"
1580
1581             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1582             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1583             if test x"$enable_dri3" = xyes; then
1584                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1585                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1586             fi
1587
1588             if test x"$enable_dri" = xyes; then
1589                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1590             fi
1591
1592             if test x"$enable_dri3" = xyes; then
1593                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1594                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1595                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1596             fi
1597         fi
1598         if test x"$dri_platform" = xapple ; then
1599             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1600         fi
1601         if test x"$dri_platform" = xwindows ; then
1602             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1603         fi
1604     fi
1605
1606     # add xf86vidmode if available
1607     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1608     if test "$HAVE_XF86VIDMODE" = yes ; then
1609         dri_modules="$dri_modules xxf86vm"
1610     fi
1611
1612     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1613     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1614     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1615     GL_LIB_DEPS="$DRIGL_LIBS"
1616
1617     # need DRM libs, $PTHREAD_LIBS, etc.
1618     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1619     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1620     ;;
1621 esac
1622
1623 # This is outside the case (above) so that it is invoked even for non-GLX
1624 # builds.
1625 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1626
1627 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1628 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1629 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1630 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1631
1632 AC_SUBST([X11_INCLUDES])
1633 AC_SUBST([GL_LIB_DEPS])
1634 AC_SUBST([GL_PC_REQ_PRIV])
1635 AC_SUBST([GL_PC_LIB_PRIV])
1636 AC_SUBST([GL_PC_CFLAGS])
1637 AC_SUBST([DRI_PC_REQ_PRIV])
1638 AC_SUBST([GLESv1_CM_LIB_DEPS])
1639 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1640 AC_SUBST([GLESv2_LIB_DEPS])
1641 AC_SUBST([GLESv2_PC_LIB_PRIV])
1642
1643 AC_SUBST([HAVE_XF86VIDMODE])
1644
1645 dnl
1646 dnl More GLX setup
1647 dnl
1648 case "x$enable_glx" in
1649 xxlib | xgallium-xlib)
1650     DEFINES="$DEFINES -DUSE_XSHM"
1651     ;;
1652 xdri)
1653     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1654     if test "x$driglx_direct" = xyes; then
1655         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1656     fi
1657     ;;
1658 esac
1659
1660 dnl
1661 dnl TLS detection
1662 dnl
1663
1664 AC_ARG_ENABLE([glx-tls],
1665     [AS_HELP_STRING([--enable-glx-tls],
1666         [enable TLS support in GLX @<:@default=disabled@:>@])],
1667     [GLX_USE_TLS="$enableval"],
1668     [GLX_USE_TLS=no])
1669 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1670
1671 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1672       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1673
1674 dnl Read-only text section on x86 hardened platforms
1675 AC_ARG_ENABLE([glx-read-only-text],
1676     [AS_HELP_STRING([--enable-glx-read-only-text],
1677         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1678     [enable_glx_read_only_text="$enableval"],
1679     [enable_glx_read_only_text=no])
1680 if test "x$enable_glx_read_only_text" = xyes; then
1681     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1682 fi
1683
1684 dnl
1685 dnl More DRI setup
1686 dnl
1687 dnl Directory for DRI drivers
1688 AC_ARG_WITH([dri-driverdir],
1689     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1690         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1691     [DRI_DRIVER_INSTALL_DIR="$withval"],
1692     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1693 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1694 dnl Extra search path for DRI drivers
1695 AC_ARG_WITH([dri-searchpath],
1696     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1697         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1698     [DRI_DRIVER_SEARCH_DIR="$withval"],
1699     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1700 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1701 dnl Which drivers to build - default is chosen by platform
1702 AC_ARG_WITH([dri-drivers],
1703     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1704         [comma delimited classic DRI drivers list, e.g.
1705         "swrast,i965,radeon" @<:@default=auto@:>@])],
1706     [with_dri_drivers="$withval"],
1707     [with_dri_drivers=auto])
1708
1709 if test "x$with_dri_drivers" = xauto; then
1710     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1711         with_dri_drivers="yes"
1712     else
1713         with_dri_drivers="no"
1714     fi
1715 fi
1716 if test "x$with_dri_drivers" = xno; then
1717     with_dri_drivers=''
1718 fi
1719
1720 dnl If $with_dri_drivers is yes, drivers will be added through
1721 dnl platform checks. Set DEFINES and LIB_DEPS
1722 if test "x$enable_dri" = xyes; then
1723     # Platform specific settings and drivers to build
1724     case "$host_os" in
1725     linux*)
1726         DEFINES="$DEFINES -DHAVE_ALIAS"
1727         if test "x$enable_dri3" = xyes; then
1728             DEFINES="$DEFINES -DHAVE_DRI3"
1729         fi
1730
1731         case "$host_cpu" in
1732         powerpc* | sparc*)
1733             # Build only the drivers for cards that exist on PowerPC/sparc
1734             if test "x$with_dri_drivers" = "xyes"; then
1735                 with_dri_drivers="r200 radeon swrast"
1736             fi
1737             ;;
1738         esac
1739         ;;
1740     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1741         DEFINES="$DEFINES -DHAVE_ALIAS"
1742         ;;
1743     gnu*)
1744         DEFINES="$DEFINES -DHAVE_ALIAS"
1745         ;;
1746     cygwin*)
1747         if test "x$with_dri_drivers" = "xyes"; then
1748             with_dri_drivers="swrast"
1749         fi
1750         ;;
1751     darwin*)
1752         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1753         if test "x$with_dri_drivers" = "xyes"; then
1754             with_dri_drivers="swrast"
1755         fi
1756         ;;
1757     esac
1758
1759     # default drivers
1760     if test "x$with_dri_drivers" = "xyes"; then
1761         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1762     fi
1763
1764     # Check for expat
1765     PKG_CHECK_MODULES([EXPAT], [expat], [],
1766         # expat version 2.0 and earlier do not provide expat.pc
1767         [AC_CHECK_HEADER([expat.h],[],
1768                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1769          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1770                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1771          EXPAT_LIBS="-lexpat"])
1772
1773     # put all the necessary libs together
1774     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1775 fi
1776
1777 AC_SUBST([DRI_LIB_DEPS])
1778
1779 DRI_DIRS=''
1780 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1781 if test -n "$with_dri_drivers"; then
1782     if test "x$enable_opengl" != xyes; then
1783         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1784     fi
1785
1786     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1787     for driver in $dri_drivers; do
1788         DRI_DIRS="$DRI_DIRS $driver"
1789         case "x$driver" in
1790         xi915)
1791             HAVE_I915_DRI=yes;
1792             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1793             ;;
1794         xi965)
1795             HAVE_I965_DRI=yes;
1796             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1797             ;;
1798         xnouveau)
1799             HAVE_NOUVEAU_DRI=yes;
1800             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1801             ;;
1802         xradeon)
1803             HAVE_RADEON_DRI=yes;
1804             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1805             ;;
1806         xr200)
1807             HAVE_R200_DRI=yes;
1808             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1809             ;;
1810         xswrast)
1811             HAVE_SWRAST_DRI=yes;
1812             ;;
1813         *)
1814             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1815             ;;
1816         esac
1817     done
1818     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1819 fi
1820
1821
1822 #
1823 # Vulkan driver configuration
1824 #
1825
1826 AC_ARG_WITH([vulkan-drivers],
1827     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1828         [comma delimited Vulkan drivers list, e.g.
1829         "intel"
1830         @<:@default=no@:>@])],
1831     [with_vulkan_drivers="$withval"],
1832     [with_vulkan_drivers="no"])
1833
1834 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1835 # here so that the script doesn't choke on an unknown driver name later.
1836 case "x$with_vulkan_drivers" in
1837     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1838     xno) with_vulkan_drivers='' ;;
1839 esac
1840
1841 AC_ARG_WITH([vulkan-icddir],
1842     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1843         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1844     [VULKAN_ICD_INSTALL_DIR="$withval"],
1845     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1846 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1847
1848 if test -n "$with_vulkan_drivers"; then
1849     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1850     for driver in $VULKAN_DRIVERS; do
1851         case "x$driver" in
1852         xintel)
1853             if test "x$HAVE_I965_DRI" != xyes; then
1854                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1855             fi
1856             if test "x$with_sha1" == "x"; then
1857                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1858             fi
1859             HAVE_INTEL_VULKAN=yes;
1860
1861             ;;
1862         xradeon)
1863             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1864             radeon_llvm_check "3" "9" "0" "radv"
1865             HAVE_RADEON_VULKAN=yes;
1866             if test "x$with_sha1" == "x"; then
1867                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1868             fi
1869             ;;
1870         *)
1871             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1872             ;;
1873         esac
1874     done
1875     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1876 fi
1877
1878
1879 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1880 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1881                                   "x$enable_osmesa" = xyes -o \
1882                                   -n "$DRI_DIRS")
1883
1884 dnl
1885 dnl OSMesa configuration
1886 dnl
1887
1888 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1889 AC_ARG_WITH([osmesa-bits],
1890     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1891         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1892     [osmesa_bits="$withval"],
1893     [osmesa_bits=8])
1894 if test "x$osmesa_bits" != x8; then
1895     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1896         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1897         osmesa_bits=8
1898     fi
1899 fi
1900 case "x$osmesa_bits" in
1901 x8)
1902     OSMESA_LIB="${OSMESA_LIB}"
1903     ;;
1904 x16|x32)
1905     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1906     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1907     ;;
1908 *)
1909     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1910     ;;
1911 esac
1912
1913 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1914     # only link libraries with osmesa if shared
1915     if test "$enable_static" = no; then
1916         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1917     else
1918         OSMESA_LIB_DEPS=""
1919     fi
1920     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1921 fi
1922
1923 AC_SUBST([OSMESA_LIB_DEPS])
1924 AC_SUBST([OSMESA_PC_REQ])
1925 AC_SUBST([OSMESA_PC_LIB_PRIV])
1926
1927 dnl
1928 dnl gbm configuration
1929 dnl
1930 if test "x$enable_gbm" = xyes; then
1931     if test "x$enable_dri" = xyes; then
1932         if test "x$enable_shared_glapi" = xno; then
1933             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1934         fi
1935     else
1936         # Strictly speaking libgbm does not require --enable-dri, although
1937         # both of its backends do. Thus one can build libgbm without any
1938         # backends if --disable-dri is set.
1939         # To avoid unnecessary complexity of checking if at least one backend
1940         # is available when building, just mandate --enable-dri.
1941         AC_MSG_ERROR([gbm requires --enable-dri])
1942     fi
1943 fi
1944 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1945 # FINISHME: GBM has a number of dependencies which we should add below
1946 GBM_PC_REQ_PRIV=""
1947 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1948 AC_SUBST([GBM_PC_REQ_PRIV])
1949 AC_SUBST([GBM_PC_LIB_PRIV])
1950
1951 dnl
1952 dnl EGL configuration
1953 dnl
1954 EGL_CLIENT_APIS=""
1955
1956 if test "x$enable_egl" = xyes; then
1957     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1958
1959     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1960
1961     if test "$enable_static" != yes; then
1962         if test "x$enable_dri" = xyes; then
1963             HAVE_EGL_DRIVER_DRI2=1
1964             if test "x$enable_shared_glapi" = xno; then
1965                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1966             fi
1967             if test "x$enable_dri3" = xyes; then
1968                 HAVE_EGL_DRIVER_DRI3=1
1969                 if test "x$enable_shared_glapi" = xno; then
1970                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1971                 fi
1972             fi
1973         else
1974             # Avoid building an "empty" libEGL. Drop/update this
1975             # when other backends (haiku?) come along.
1976             AC_MSG_ERROR([egl requires --enable-dri])
1977         fi
1978
1979     fi
1980 fi
1981 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1982 AC_SUBST([EGL_LIB_DEPS])
1983
1984 gallium_st="mesa"
1985
1986 dnl
1987 dnl XA configuration
1988 dnl
1989 if test "x$enable_xa" = xyes; then
1990     if test "x$with_gallium_drivers" = xswrast; then
1991        AC_MSG_ERROR([
1992           Building xa requires at least one non swrast gallium driver.
1993           If you are looking to use libxatracker.so with the VMware driver,
1994           make sure to include svga in the gallium drivers list, apart from
1995           enabling XA.
1996           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1997     fi
1998     gallium_st="$gallium_st xa"
1999 fi
2000 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2001
2002 dnl
2003 dnl Gallium G3DVL configuration
2004 dnl
2005 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2006     if test "x$enable_xvmc" = xauto; then
2007         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2008     fi
2009
2010     if test "x$enable_vdpau" = xauto; then
2011         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2012     fi
2013
2014     if test "x$enable_omx" = xauto; then
2015         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2016     fi
2017
2018     if test "x$enable_va" = xauto; then
2019         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2020     fi
2021 fi
2022
2023 if test "x$enable_dri" = xyes -o \
2024         "x$enable_xvmc" = xyes -o \
2025         "x$enable_vdpau" = xyes -o \
2026         "x$enable_omx" = xyes -o \
2027         "x$enable_va" = xyes; then
2028     need_gallium_vl=yes
2029 fi
2030 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2031
2032 if test "x$enable_xvmc" = xyes -o \
2033         "x$enable_vdpau" = xyes -o \
2034         "x$enable_omx" = xyes -o \
2035         "x$enable_va" = xyes; then
2036     if test x"$enable_dri3" = xyes; then
2037         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2038                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2039     else
2040         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2041     fi
2042     need_gallium_vl_winsys=yes
2043 fi
2044 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2045
2046 if test "x$enable_xvmc" = xyes; then
2047     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2048     gallium_st="$gallium_st xvmc"
2049 fi
2050 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2051
2052 if test "x$enable_vdpau" = xyes; then
2053     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2054     gallium_st="$gallium_st vdpau"
2055     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2056 fi
2057 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2058
2059 if test "x$enable_omx" = xyes; then
2060     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2061     gallium_st="$gallium_st omx"
2062 fi
2063 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2064
2065 if test "x$enable_va" = xyes; then
2066     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2067     gallium_st="$gallium_st va"
2068 fi
2069 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2070
2071 dnl
2072 dnl Nine Direct3D9 configuration
2073 dnl
2074 if test "x$enable_nine" = xyes; then
2075     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2076         AC_MSG_ERROR([nine requires the gallium swrast driver])
2077     fi
2078     if test "x$with_gallium_drivers" = xswrast; then
2079         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2080     fi
2081     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2082         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2083     fi
2084
2085     if test "x$enable_dri3" = xno; then
2086         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2087     fi
2088
2089     gallium_st="$gallium_st nine"
2090 fi
2091 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2092
2093 dnl
2094 dnl OpenCL configuration
2095 dnl
2096
2097 AC_ARG_WITH([clang-libdir],
2098    [AS_HELP_STRING([--with-clang-libdir],
2099          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2100    [CLANG_LIBDIR="$withval"],
2101    [CLANG_LIBDIR=''])
2102
2103 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2104
2105 if test "x$enable_opencl" = xyes; then
2106     if test -z "$with_gallium_drivers"; then
2107         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2108     fi
2109
2110     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2111         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2112     fi
2113
2114     if test "x$have_libclc" = xno; then
2115         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2116                     Make sure the directory containing libclc.pc is specified in your
2117                     PKG_CONFIG_PATH environment variable.
2118                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2119     else
2120         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2121         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2122         AC_SUBST([LIBCLC_INCLUDEDIR])
2123         AC_SUBST([LIBCLC_LIBEXECDIR])
2124     fi
2125
2126     gallium_st="$gallium_st clover"
2127
2128     if test "x$enable_opencl_icd" = xyes; then
2129         OPENCL_LIBNAME="MesaOpenCL"
2130     else
2131         OPENCL_LIBNAME="OpenCL"
2132     fi
2133
2134     if test "x$have_libelf" != xyes; then
2135        AC_MSG_ERROR([Clover requires libelf])
2136     fi
2137
2138     llvm_check_version_for "3" "6" "0" "opencl"
2139
2140     llvm_add_default_components "opencl"
2141     llvm_add_component "all-targets" "opencl"
2142     llvm_add_component "linker" "opencl"
2143     llvm_add_component "instrumentation" "opencl"
2144     llvm_add_component "ipo" "opencl"
2145     llvm_add_component "irreader" "opencl"
2146     llvm_add_component "option" "opencl"
2147     llvm_add_component "objcarcopts" "opencl"
2148     llvm_add_component "profiledata" "opencl"
2149
2150     dnl Check for Clang internal headers
2151     if test -z "$CLANG_LIBDIR"; then
2152         CLANG_LIBDIR=${LLVM_LIBDIR}
2153     fi
2154     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2155     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2156         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2157 fi
2158 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2159 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2160 AC_SUBST([OPENCL_LIBNAME])
2161 AC_SUBST([CLANG_RESOURCE_DIR])
2162
2163 dnl
2164 dnl Gallium configuration
2165 dnl
2166 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2167
2168 case "x$enable_opengl$enable_gles1$enable_gles2" in
2169 x*yes*)
2170     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2171     ;;
2172 esac
2173
2174 AC_SUBST([VG_LIB_DEPS])
2175 AC_SUBST([EGL_CLIENT_APIS])
2176
2177 dnl
2178 dnl EGL Platforms configuration
2179 dnl
2180 AC_ARG_WITH([egl-platforms],
2181     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2182         [comma delimited native platforms libEGL supports, e.g.
2183         "x11,drm" @<:@default=auto@:>@])],
2184     [with_egl_platforms="$withval"],
2185     [if test "x$enable_egl" = xyes; then
2186         if test "x$enable_gbm" = xyes; then
2187            with_egl_platforms="x11,drm"
2188         else
2189            with_egl_platforms="x11"
2190         fi
2191     else
2192         with_egl_platforms=""
2193     fi])
2194
2195 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2196     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2197 fi
2198
2199 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2200         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2201         WAYLAND_SCANNER='')
2202 if test "x$WAYLAND_SCANNER" = x; then
2203     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2204 fi
2205
2206 # Do per-EGL platform setups and checks
2207 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2208 for plat in $egl_platforms; do
2209         case "$plat" in
2210         wayland)
2211
2212                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2213
2214                 if test "x$WAYLAND_SCANNER" = x; then
2215                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2216                 fi
2217                 ;;
2218
2219         x11)
2220                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2221                 ;;
2222
2223         drm)
2224                 test "x$enable_gbm" = "xno" &&
2225                         AC_MSG_ERROR([EGL platform drm needs gbm])
2226                 ;;
2227
2228         surfaceless)
2229                 ;;
2230
2231         android)
2232                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2233                 ;;
2234
2235         *)
2236                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2237                 ;;
2238         esac
2239
2240         case "$plat" in
2241         wayland|drm|surfaceless)
2242                 require_libdrm "Platform $plat"
2243                 ;;
2244         esac
2245 done
2246
2247 # libEGL wants to default to the first platform specified in
2248 # ./configure.  parse that here.
2249 if test "x$egl_platforms" != "x"; then
2250     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2251     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2252 else
2253     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2254 fi
2255
2256 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2257 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2258 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2259 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2260 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2261
2262 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2263
2264 AC_SUBST([EGL_NATIVE_PLATFORM])
2265 AC_SUBST([EGL_CFLAGS])
2266
2267 # If we don't have the X11 platform, set this define so we don't try to include
2268 # the X11 headers.
2269 if ! echo "$egl_platforms" | grep -q 'x11'; then
2270     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2271     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2272 fi
2273
2274 dnl
2275 dnl Gallium LLVM
2276 dnl
2277 AC_ARG_ENABLE([gallium-llvm],
2278     [AS_HELP_STRING([--enable-gallium-llvm],
2279         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2280     [enable_gallium_llvm="$enableval"],
2281     [enable_gallium_llvm=auto])
2282
2283 if test -z "$with_gallium_drivers"; then
2284     enable_gallium_llvm=no
2285 fi
2286 if test "x$enable_gallium_llvm" = xauto; then
2287     case "$host_cpu" in
2288     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2289     esac
2290 fi
2291
2292 dnl Directory for XVMC libs
2293 AC_ARG_WITH([xvmc-libdir],
2294     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2295         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2296     [XVMC_LIB_INSTALL_DIR="$withval"],
2297     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2298 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2299
2300 dnl
2301 dnl Gallium Tests
2302 dnl
2303 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2304
2305 dnl Directory for VDPAU libs
2306 AC_ARG_WITH([vdpau-libdir],
2307     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2308         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2309     [VDPAU_LIB_INSTALL_DIR="$withval"],
2310     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2311 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2312
2313 dnl Directory for OMX libs
2314
2315 AC_ARG_WITH([omx-libdir],
2316     [AS_HELP_STRING([--with-omx-libdir=DIR],
2317         [directory for the OMX libraries])],
2318     [OMX_LIB_INSTALL_DIR="$withval"],
2319     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2320 AC_SUBST([OMX_LIB_INSTALL_DIR])
2321
2322 dnl Directory for VA libs
2323
2324 AC_ARG_WITH([va-libdir],
2325     [AS_HELP_STRING([--with-va-libdir=DIR],
2326         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2327     [VA_LIB_INSTALL_DIR="$withval"],
2328     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2329 AC_SUBST([VA_LIB_INSTALL_DIR])
2330
2331 AC_ARG_WITH([d3d-libdir],
2332     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2333         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2334     [D3D_DRIVER_INSTALL_DIR="$withval"],
2335     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2336 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2337
2338 dnl
2339 dnl Gallium helper functions
2340 dnl
2341 gallium_require_llvm() {
2342     if test "x$enable_gallium_llvm" == "xyes"; then
2343         llvm_check_version_for "3" "3" "0" "gallium"
2344     else
2345         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2346     fi
2347 }
2348
2349 dnl
2350 dnl DRM is needed by X, Wayland, and offscreen rendering.
2351 dnl Surfaceless is an alternative for the last one.
2352 dnl
2353 require_basic_egl() {
2354     case "$with_egl_platforms" in
2355         *drm*|*surfaceless*)
2356             ;;
2357         *)
2358             AC_MSG_ERROR([$1 requires one of these:
2359                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2360                   2) --with-egl-platforms=surfaceless (offscreen only)
2361                   Recommended options: drm,x11])
2362             ;;
2363     esac
2364 }
2365
2366 radeon_gallium_llvm_check() {
2367     if test "x$enable_gallium_llvm" != "xyes"; then
2368         AC_MSG_ERROR([--enable-gallium-llvm is required when building $4])
2369     fi
2370     radeon_llvm_check $*
2371 }
2372
2373 swr_require_cxx_feature_flags() {
2374     feature_name="$1"
2375     preprocessor_test="$2"
2376     option_list="$3"
2377     output_var="$4"
2378
2379     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2380     AC_LANG_PUSH([C++])
2381     save_CXXFLAGS="$CXXFLAGS"
2382     save_IFS="$IFS"
2383     IFS=","
2384     found=0
2385     for opts in $option_list
2386     do
2387         unset IFS
2388         CXXFLAGS="$opts $save_CXXFLAGS"
2389         AC_COMPILE_IFELSE(
2390             [AC_LANG_PROGRAM(
2391                 [   #if !($preprocessor_test)
2392                     #error
2393                     #endif
2394                 ])],
2395             [found=1; break],
2396             [])
2397         IFS=","
2398     done
2399     IFS="$save_IFS"
2400     CXXFLAGS="$save_CXXFLAGS"
2401     AC_LANG_POP([C++])
2402     if test $found -eq 1; then
2403         AC_MSG_RESULT([$opts])
2404         eval "$output_var=\$opts"
2405         return 0
2406     fi
2407     AC_MSG_RESULT([no])
2408     AC_MSG_ERROR([swr requires $feature_name support])
2409     return 1
2410 }
2411
2412 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2413 if test -n "$with_gallium_drivers"; then
2414     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2415     for driver in $gallium_drivers; do
2416         case "x$driver" in
2417         xsvga)
2418             HAVE_GALLIUM_SVGA=yes
2419             require_libdrm "svga"
2420             ;;
2421         xi915)
2422             HAVE_GALLIUM_I915=yes
2423             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2424             require_libdrm "Gallium i915"
2425             ;;
2426         xilo)
2427             HAVE_GALLIUM_ILO=yes
2428             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2429             require_libdrm "Gallium i965/ilo"
2430             ;;
2431         xr300)
2432             HAVE_GALLIUM_R300=yes
2433             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2434             require_libdrm "r300"
2435             gallium_require_llvm "r300"
2436             ;;
2437         xr600)
2438             HAVE_GALLIUM_R600=yes
2439             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2440             require_libdrm "r600"
2441             if test "x$enable_opencl" = xyes; then
2442                 radeon_gallium_llvm_check "3" "6" "0" "r600"
2443
2444                 llvm_add_component "asmparser" "r600"
2445                 llvm_add_component "bitreader" "r600"
2446             fi
2447             ;;
2448         xradeonsi)
2449             HAVE_GALLIUM_RADEONSI=yes
2450             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2451             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2452             require_libdrm "radeonsi"
2453             radeon_gallium_llvm_check "3" "6" "0" "radeonsi"
2454             require_basic_egl "radeonsi"
2455             ;;
2456         xnouveau)
2457             HAVE_GALLIUM_NOUVEAU=yes
2458             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2459             require_libdrm "nouveau"
2460             ;;
2461         xfreedreno)
2462             HAVE_GALLIUM_FREEDRENO=yes
2463             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2464             require_libdrm "freedreno"
2465             ;;
2466         xswrast)
2467             HAVE_GALLIUM_SOFTPIPE=yes
2468             if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes";  then
2469                 HAVE_GALLIUM_LLVMPIPE=yes
2470             fi
2471             ;;
2472         xswr)
2473             llvm_check_version_for "3" "6" "0" "swr"
2474             gallium_require_llvm "swr"
2475
2476             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2477                 ",-std=c++11" \
2478                 SWR_CXX11_CXXFLAGS
2479             AC_SUBST([SWR_CXX11_CXXFLAGS])
2480
2481             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2482                 ",-mavx,-march=core-avx" \
2483                 SWR_AVX_CXXFLAGS
2484             AC_SUBST([SWR_AVX_CXXFLAGS])
2485
2486             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2487                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2488                 SWR_AVX2_CXXFLAGS
2489             AC_SUBST([SWR_AVX2_CXXFLAGS])
2490
2491             HAVE_GALLIUM_SWR=yes
2492             ;;
2493         xvc4)
2494             HAVE_GALLIUM_VC4=yes
2495             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2496             require_libdrm "vc4"
2497
2498             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2499                               [USE_VC4_SIMULATOR=yes;
2500                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2501                               [USE_VC4_SIMULATOR=no])
2502             ;;
2503         xvirgl)
2504             HAVE_GALLIUM_VIRGL=yes
2505             require_libdrm "virgl"
2506             require_basic_egl "virgl"
2507             ;;
2508         *)
2509             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2510             ;;
2511         esac
2512     done
2513 fi
2514
2515 if test "x$enable_gallium_llvm" == "xyes"; then
2516     llvm_check_version_for "3" "3" "0" "gallium"
2517     llvm_add_default_components "gallium"
2518 fi
2519
2520 dnl Set LLVM_LIBS - This is done after the driver configuration so
2521 dnl that drivers can add additional components to LLVM_COMPONENTS.
2522 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2523 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2524 dnl this was causing the same libraries to be appear multiple times
2525 dnl in LLVM_LIBS.
2526
2527 if test "x$MESA_LLVM" != x0; then
2528
2529     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2530        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2531     fi
2532     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2533
2534     dnl llvm-config may not give the right answer when llvm is a built as a
2535     dnl single shared library, so we must work the library name out for
2536     dnl ourselves.
2537     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2538     if test "x$enable_llvm_shared_libs" = xyes; then
2539         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2540         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2541         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2542
2543         if test "x$llvm_have_one_so" = xyes; then
2544             dnl LLVM was built using auto*, so there is only one shared object.
2545             LLVM_LIBS="-l$LLVM_SO_NAME"
2546         else
2547             dnl If LLVM was built with CMake, there will be one shared object per
2548             dnl component.
2549             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2550                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2551         Please make sure you have built llvm with the --enable-shared option
2552         and that your llvm libraries are installed in $LLVM_LIBDIR
2553         If you have installed your llvm libraries to a different directory you
2554         can use the --with-llvm-prefix= configure flag to specify this directory.
2555         NOTE: Mesa is attempting to use llvm shared libraries by default.
2556         If you do not want to build with llvm shared libraries and instead want to
2557         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2558         invocation and rebuild.])])
2559
2560            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2561            dnl install uses a shared object for each component and we have
2562            dnl already added all of these objects to LLVM_LIBS.
2563         fi
2564     else
2565         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2566         dnl We need to link to llvm system libs when using static libs
2567         dnl However, only llvm 3.5+ provides --system-libs
2568         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2569             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2570         fi
2571     fi
2572 fi
2573
2574 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2575 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2576 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2577 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2578 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2579 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2580 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2581                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2582 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2583 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2584 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2585 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2586 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2587 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2588                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2589                                          "x$HAVE_GALLIUM_SWR" = xyes)
2590 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2591 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2592
2593 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2594
2595 if test "x$enable_dri" = xyes; then
2596     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2597 fi
2598
2599 if test "x$have_drisw_kms" = xyes; then
2600     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2601 fi
2602 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2603
2604 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2605 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2606 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2607 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2608 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2609 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2610
2611 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2612 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2613
2614 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2615                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2616                                       "x$HAVE_RADEON_VULKAN" = xyes)
2617
2618 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2619                                         "x$HAVE_I965_DRI" = xyes)
2620
2621 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2622                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2623                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2624 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2625 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2626 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2627 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$MESA_LLVM" = x1 -a \
2628                                        "x$enable_gallium_llvm" = xyes)
2629 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2630 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2631     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2632 fi
2633
2634 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2635 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2636 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2637 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2638                                         "x$enable_gallium_osmesa" = xyes)
2639
2640 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2641 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2642 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2643
2644 AC_SUBST([NINE_MAJOR], 1)
2645 AC_SUBST([NINE_MINOR], 0)
2646 AC_SUBST([NINE_TINY], 0)
2647 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2648
2649 AC_SUBST([VDPAU_MAJOR], 1)
2650 AC_SUBST([VDPAU_MINOR], 0)
2651
2652 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2653 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2654 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2655 AC_SUBST([VA_MINOR], $VA_MINOR)
2656
2657 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2658
2659 AC_SUBST([XVMC_MAJOR], 1)
2660 AC_SUBST([XVMC_MINOR], 0)
2661
2662 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2663 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2664 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2665 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2666
2667 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2668 AC_SUBST([XA_MINOR], $XA_MINOR)
2669 AC_SUBST([XA_TINY], $XA_TINY)
2670 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2671
2672 AC_ARG_ENABLE(valgrind,
2673               [AS_HELP_STRING([--enable-valgrind],
2674                              [Build mesa with valgrind support (default: auto)])],
2675                              [VALGRIND=$enableval], [VALGRIND=auto])
2676 if test "x$VALGRIND" != xno; then
2677         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2678 fi
2679 AC_MSG_CHECKING([whether to enable Valgrind support])
2680 if test "x$VALGRIND" = xauto; then
2681         VALGRIND="$have_valgrind"
2682 fi
2683
2684 if test "x$VALGRIND" = "xyes"; then
2685         if ! test "x$have_valgrind" = xyes; then
2686                 AC_MSG_ERROR([Valgrind support required but not present])
2687         fi
2688         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2689 fi
2690
2691 AC_MSG_RESULT([$VALGRIND])
2692
2693 dnl Restore LDFLAGS and CPPFLAGS
2694 LDFLAGS="$_SAVE_LDFLAGS"
2695 CPPFLAGS="$_SAVE_CPPFLAGS"
2696
2697 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2698 if test "x$acv_mesa_CLANG" = xyes; then
2699     CFLAGS="$CFLAGS -Qunused-arguments"
2700     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2701 fi
2702
2703 dnl Add user CFLAGS and CXXFLAGS
2704 CFLAGS="$CFLAGS $USER_CFLAGS"
2705 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2706
2707 dnl Substitute the config
2708 AC_CONFIG_FILES([Makefile
2709                 src/Makefile
2710                 src/amd/Makefile
2711                 src/amd/vulkan/Makefile
2712                 src/compiler/Makefile
2713                 src/egl/Makefile
2714                 src/egl/main/egl.pc
2715                 src/egl/wayland/wayland-drm/Makefile
2716                 src/egl/wayland/wayland-egl/Makefile
2717                 src/egl/wayland/wayland-egl/wayland-egl.pc
2718                 src/gallium/Makefile
2719                 src/gallium/auxiliary/Makefile
2720                 src/gallium/auxiliary/pipe-loader/Makefile
2721                 src/gallium/drivers/freedreno/Makefile
2722                 src/gallium/drivers/ddebug/Makefile
2723                 src/gallium/drivers/i915/Makefile
2724                 src/gallium/drivers/ilo/Makefile
2725                 src/gallium/drivers/llvmpipe/Makefile
2726                 src/gallium/drivers/noop/Makefile
2727                 src/gallium/drivers/nouveau/Makefile
2728                 src/gallium/drivers/r300/Makefile
2729                 src/gallium/drivers/r600/Makefile
2730                 src/gallium/drivers/radeon/Makefile
2731                 src/gallium/drivers/radeonsi/Makefile
2732                 src/gallium/drivers/rbug/Makefile
2733                 src/gallium/drivers/softpipe/Makefile
2734                 src/gallium/drivers/svga/Makefile
2735                 src/gallium/drivers/swr/Makefile
2736                 src/gallium/drivers/trace/Makefile
2737                 src/gallium/drivers/vc4/Makefile
2738                 src/gallium/drivers/virgl/Makefile
2739                 src/gallium/state_trackers/clover/Makefile
2740                 src/gallium/state_trackers/dri/Makefile
2741                 src/gallium/state_trackers/glx/xlib/Makefile
2742                 src/gallium/state_trackers/nine/Makefile
2743                 src/gallium/state_trackers/omx/Makefile
2744                 src/gallium/state_trackers/osmesa/Makefile
2745                 src/gallium/state_trackers/va/Makefile
2746                 src/gallium/state_trackers/vdpau/Makefile
2747                 src/gallium/state_trackers/xa/Makefile
2748                 src/gallium/state_trackers/xvmc/Makefile
2749                 src/gallium/targets/d3dadapter9/Makefile
2750                 src/gallium/targets/d3dadapter9/d3d.pc
2751                 src/gallium/targets/dri/Makefile
2752                 src/gallium/targets/libgl-xlib/Makefile
2753                 src/gallium/targets/omx/Makefile
2754                 src/gallium/targets/opencl/Makefile
2755                 src/gallium/targets/opencl/mesa.icd
2756                 src/gallium/targets/osmesa/Makefile
2757                 src/gallium/targets/osmesa/osmesa.pc
2758                 src/gallium/targets/pipe-loader/Makefile
2759                 src/gallium/targets/va/Makefile
2760                 src/gallium/targets/vdpau/Makefile
2761                 src/gallium/targets/xa/Makefile
2762                 src/gallium/targets/xa/xatracker.pc
2763                 src/gallium/targets/xvmc/Makefile
2764                 src/gallium/tests/trivial/Makefile
2765                 src/gallium/tests/unit/Makefile
2766                 src/gallium/winsys/freedreno/drm/Makefile
2767                 src/gallium/winsys/i915/drm/Makefile
2768                 src/gallium/winsys/intel/drm/Makefile
2769                 src/gallium/winsys/nouveau/drm/Makefile
2770                 src/gallium/winsys/radeon/drm/Makefile
2771                 src/gallium/winsys/amdgpu/drm/Makefile
2772                 src/gallium/winsys/svga/drm/Makefile
2773                 src/gallium/winsys/sw/dri/Makefile
2774                 src/gallium/winsys/sw/kms-dri/Makefile
2775                 src/gallium/winsys/sw/null/Makefile
2776                 src/gallium/winsys/sw/wrapper/Makefile
2777                 src/gallium/winsys/sw/xlib/Makefile
2778                 src/gallium/winsys/vc4/drm/Makefile
2779                 src/gallium/winsys/virgl/drm/Makefile
2780                 src/gallium/winsys/virgl/vtest/Makefile
2781                 src/gbm/Makefile
2782                 src/gbm/main/gbm.pc
2783                 src/glx/Makefile
2784                 src/glx/apple/Makefile
2785                 src/glx/tests/Makefile
2786                 src/glx/windows/Makefile
2787                 src/glx/windows/windowsdriproto.pc
2788                 src/gtest/Makefile
2789                 src/intel/Makefile
2790                 src/intel/tools/Makefile
2791                 src/intel/vulkan/Makefile
2792                 src/loader/Makefile
2793                 src/mapi/Makefile
2794                 src/mapi/es1api/glesv1_cm.pc
2795                 src/mapi/es2api/glesv2.pc
2796                 src/mapi/glapi/gen/Makefile
2797                 src/mesa/Makefile
2798                 src/mesa/gl.pc
2799                 src/mesa/drivers/dri/dri.pc
2800                 src/mesa/drivers/dri/common/Makefile
2801                 src/mesa/drivers/dri/common/xmlpool/Makefile
2802                 src/mesa/drivers/dri/i915/Makefile
2803                 src/mesa/drivers/dri/i965/Makefile
2804                 src/mesa/drivers/dri/Makefile
2805                 src/mesa/drivers/dri/nouveau/Makefile
2806                 src/mesa/drivers/dri/r200/Makefile
2807                 src/mesa/drivers/dri/radeon/Makefile
2808                 src/mesa/drivers/dri/swrast/Makefile
2809                 src/mesa/drivers/osmesa/Makefile
2810                 src/mesa/drivers/osmesa/osmesa.pc
2811                 src/mesa/drivers/x11/Makefile
2812                 src/mesa/main/tests/Makefile
2813                 src/util/Makefile
2814                 src/util/tests/hash_table/Makefile
2815                 src/vulkan/wsi/Makefile])
2816
2817 AC_OUTPUT
2818
2819 # Fix up dependencies in *.Plo files, where we changed the extension of a
2820 # source file
2821 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2822
2823
2824 dnl
2825 dnl Output some configuration info for the user
2826 dnl
2827 echo ""
2828 echo "        prefix:          $prefix"
2829 echo "        exec_prefix:     $exec_prefix"
2830 echo "        libdir:          $libdir"
2831 echo "        includedir:      $includedir"
2832
2833 dnl API info
2834 echo ""
2835 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2836
2837 dnl Driver info
2838 echo ""
2839 case "x$enable_osmesa$enable_gallium_osmesa" in
2840 xnoyes)
2841         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2842         ;;
2843 xyesno)
2844         echo "        OSMesa:          lib$OSMESA_LIB"
2845         ;;
2846 xnono)
2847         echo "        OSMesa:          no"
2848         ;;
2849 esac
2850
2851 echo ""
2852 if test "x$enable_dri" != xno; then
2853         echo "        DRI platform:    $dri_platform"
2854         if test -z "$DRI_DIRS"; then
2855             echo "        DRI drivers:     no"
2856         else
2857             echo "        DRI drivers:     $DRI_DIRS"
2858         fi
2859         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2860 fi
2861
2862 case "x$enable_glx" in
2863 xdri)
2864     echo "        GLX:             DRI-based"
2865     ;;
2866 xxlib)
2867     echo "        GLX:             Xlib-based"
2868     ;;
2869 xgallium-xlib)
2870     echo "        GLX:             Xlib-based (Gallium)"
2871     ;;
2872 *)
2873     echo "        GLX:             $enable_glx"
2874     ;;
2875 esac
2876
2877 dnl EGL
2878 echo ""
2879 echo "        EGL:             $enable_egl"
2880 if test "$enable_egl" = yes; then
2881     echo "        EGL platforms:   $egl_platforms"
2882
2883     egl_drivers=""
2884     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2885         egl_drivers="$egl_drivers builtin:egl_dri2"
2886     fi
2887     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2888         egl_drivers="$egl_drivers builtin:egl_dri3"
2889     fi
2890
2891     echo "        EGL drivers:    $egl_drivers"
2892 fi
2893 if test "x$enable_gbm" = xyes; then
2894     echo "        GBM:             yes"
2895 else
2896     echo "        GBM:             no"
2897 fi
2898
2899 # Vulkan
2900 echo ""
2901 if test "x$VULKAN_DRIVERS" != x; then
2902     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2903     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2904 else
2905     echo "        Vulkan drivers:  no"
2906 fi
2907
2908 echo ""
2909 if test "x$MESA_LLVM" = x1; then
2910     echo "        llvm:            yes"
2911     echo "        llvm-config:     $LLVM_CONFIG"
2912     echo "        llvm-version:    $LLVM_VERSION"
2913 else
2914     echo "        llvm:            no"
2915 fi
2916
2917 echo ""
2918 if test -n "$with_gallium_drivers"; then
2919     echo "        Gallium drivers: $gallium_drivers"
2920     echo "        Gallium st:      $gallium_st"
2921 else
2922     echo "        Gallium:         no"
2923 fi
2924
2925 echo ""
2926 if test "x$enable_gallium_extra_hud" != xyes; then
2927     echo "        HUD extra stats: no"
2928 else
2929     echo "        HUD extra stats: yes"
2930 fi
2931
2932 if test "x$enable_lmsensors" != xyes; then
2933     echo "        HUD lmsensors:   no"
2934 else
2935     echo "        HUD lmsensors:   yes"
2936 fi
2937
2938 dnl Shader cache
2939 echo ""
2940 echo "        Shader cache:    $enable_shader_cache"
2941 if test "x$enable_shader_cache" = "xyes"; then
2942     echo "        With SHA1 from:  $with_sha1"
2943 fi
2944
2945 dnl Libraries
2946 echo ""
2947 echo "        Shared libs:     $enable_shared"
2948 echo "        Static libs:     $enable_static"
2949 echo "        Shared-glapi:    $enable_shared_glapi"
2950
2951 dnl Compiler options
2952 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2953 cflags=`echo $CFLAGS | \
2954     $SED 's/^ *//;s/  */ /;s/ *$//'`
2955 cxxflags=`echo $CXXFLAGS | \
2956     $SED 's/^ *//;s/  */ /;s/ *$//'`
2957 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2958 echo ""
2959 echo "        CFLAGS:          $cflags"
2960 echo "        CXXFLAGS:        $cxxflags"
2961 echo "        Macros:          $defines"
2962 echo ""
2963 if test "x$MESA_LLVM" = x1; then
2964     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2965     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2966     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2967     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2968     echo ""
2969 fi
2970 echo "        PYTHON2:         $PYTHON2"
2971
2972 echo ""
2973 echo "        Run '${MAKE-make}' to build Mesa"
2974 echo ""