configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 LT_PREREQ([2.2])
  28 LT_INIT([disable-static])
  29
  30 dnl Set internal versions
  31 OSMESA_VERSION=8
  32 AC_SUBST([OSMESA_VERSION])
  33
  34 dnl Versions for external dependencies
  35 LIBDRM_REQUIRED=2.4.24
  36 LIBDRM_RADEON_REQUIRED=2.4.39
  37 LIBDRM_INTEL_REQUIRED=2.4.38
  38 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  39 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  75 fi
  76
  77 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  78 dnl configuration in that case.
  79 AC_PROG_INSTALL
  80 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  81
  82 dnl We need a POSIX shell for parts of the build. Assume we have one
  83 dnl in most cases.
  84 case "$host_os" in
  85 solaris*)
  86     # Solaris /bin/sh is too old/non-POSIX compliant
  87     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  88     SHELL="$POSIX_SHELL"
  89     ;;
  90 esac
  91
  92 dnl clang is mostly GCC-compatible, but its version is much lower,
  93 dnl so we have to check for it.
  94 AC_MSG_CHECKING([if compiling with clang])
  95
  96 AC_COMPILE_IFELSE(
  97 [AC_LANG_PROGRAM([], [[
  98 #ifndef __clang__
  99        not clang
 100 #endif
 101 ]])],
 102 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 103
 104 AC_MSG_RESULT([$acv_mesa_CLANG])
 105
 106 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 107 dnl versions are explictly not supported.
 108 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 109     AC_MSG_CHECKING([whether gcc version is sufficient])
 110     major=0
 111     minor=0
 112
 113     GCC_VERSION=`$CC -dumpversion`
 114     if test $? -eq 0; then
 115         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 116         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 117     fi
 118
 119     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 122     else
 123         AC_MSG_RESULT([yes])
 124     fi
 125 fi
 126
 127
 128 MKDEP_OPTIONS=-fdepend
 129 dnl Ask gcc where it's keeping its secret headers
 130 if test "x$GCC" = xyes; then
 131     for dir in include include-fixed; do
 132         GCC_INCLUDES=`$CC -print-file-name=$dir`
 133         if test "x$GCC_INCLUDES" != x && \
 134            test "$GCC_INCLUDES" != "$dir" && \
 135            test -d "$GCC_INCLUDES"; then
 136             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 137         fi
 138     done
 139 fi
 140 AC_SUBST([MKDEP_OPTIONS])
 141
 142 dnl Make sure the pkg-config macros are defined
 143 m4_ifndef([PKG_PROG_PKG_CONFIG],
 144     [m4_fatal([Could not locate the pkg-config autoconf macros.
 145   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 146   are in a different location, try setting the environment variable
 147   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 148 PKG_PROG_PKG_CONFIG()
 149
 150 dnl LIB_DIR - library basename
 151 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 152 AC_SUBST([LIB_DIR])
 153
 154 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 155 _SAVE_LDFLAGS="$LDFLAGS"
 156 _SAVE_CPPFLAGS="$CPPFLAGS"
 157
 158 dnl Compiler macros
 159 DEFINES=""
 160 AC_SUBST([DEFINES])
 161 case "$host_os" in
 162 linux*|*-gnu*|gnu*)
 163     DEFINES="$DEFINES -D_GNU_SOURCE"
 164     ;;
 165 solaris*)
 166     DEFINES="$DEFINES -DSVR4"
 167     ;;
 168 cygwin*)
 169     DEFINES="$DEFINES"
 170     ;;
 171 esac
 172
 173 dnl Add flags for gcc and g++
 174 if test "x$GCC" = xyes; then
 175     CFLAGS="$CFLAGS -Wall -std=c99"
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl mklib options
 295 dnl
 296 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 297 if test "$enable_static" = yes; then
 298     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 299 fi
 300 AC_SUBST([MKLIB_OPTIONS])
 301
 302 dnl
 303 dnl other compiler options
 304 dnl
 305 AC_ARG_ENABLE([debug],
 306     [AS_HELP_STRING([--enable-debug],
 307         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 308     [enable_debug="$enableval"],
 309     [enable_debug=no]
 310 )
 311 if test "x$enable_debug" = xyes; then
 312     DEFINES="$DEFINES -DDEBUG"
 313     if test "x$GCC" = xyes; then
 314         CFLAGS="$CFLAGS -g"
 315     fi
 316     if test "x$GXX" = xyes; then
 317         CXXFLAGS="$CXXFLAGS -g"
 318     fi
 319 fi
 320
 321 dnl
 322 dnl library names
 323 dnl
 324 LIB_PREFIX_GLOB='lib'
 325 LIB_VERSION_SEPARATOR='.'
 326 if test "$enable_static" = yes; then
 327     LIB_EXTENSION='a'
 328 else
 329     case "$host_os" in
 330     darwin* )
 331         LIB_EXTENSION='dylib' ;;
 332     cygwin* )
 333         dnl prefix can be 'cyg' or 'lib'
 334         LIB_PREFIX_GLOB='???'
 335         LIB_VERSION_SEPARATOR='-'
 336         LIB_EXTENSION='dll' ;;
 337     aix* )
 338         LIB_EXTENSION='a' ;;
 339     * )
 340         LIB_EXTENSION='so' ;;
 341     esac
 342 fi
 343 AC_ARG_WITH([gl-lib-name],
 344   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 345     [specify GL library name @<:@default=GL@:>@])],
 346   [GL_LIB=$withval],
 347   [GL_LIB=GL])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 355
 356 dnl
 357 dnl Mangled Mesa support
 358 dnl
 359 AC_ARG_ENABLE([mangling],
 360   [AS_HELP_STRING([--enable-mangling],
 361     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 362   [enable_mangling="${enableval}"],
 363   [enable_mangling=no]
 364 )
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="Mangled${GL_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([OSMESA_LIB])
 372
 373 dnl
 374 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 375 dnl
 376 AC_ARG_ENABLE([texture-float],
 377     [AS_HELP_STRING([--enable-texture-float],
 378         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 379     [enable_texture_float="$enableval"],
 380     [enable_texture_float=no]
 381 )
 382 if test "x$enable_texture_float" = xyes; then
 383     AC_MSG_WARN([Floating-point textures enabled.])
 384     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 385     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 386 fi
 387
 388 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 389 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 390 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 391 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 392 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 393 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 394 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 395
 396 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403
 404 AC_SUBST([GL_LIB_NAME])
 405 AC_SUBST([OSMESA_LIB_NAME])
 406 AC_SUBST([EGL_LIB_NAME])
 407 AC_SUBST([GLESv1_CM_LIB_NAME])
 408 AC_SUBST([GLESv2_LIB_NAME])
 409 AC_SUBST([VG_LIB_NAME])
 410 AC_SUBST([GLAPI_LIB_NAME])
 411
 412 AC_SUBST([GL_LIB_GLOB])
 413 AC_SUBST([EGL_LIB_GLOB])
 414 AC_SUBST([GLESv1_CM_LIB_GLOB])
 415 AC_SUBST([GLESv2_LIB_GLOB])
 416 AC_SUBST([VG_LIB_GLOB])
 417 AC_SUBST([GLAPI_LIB_GLOB])
 418
 419 dnl
 420 dnl Arch/platform-specific settings
 421 dnl
 422 AC_ARG_ENABLE([asm],
 423     [AS_HELP_STRING([--disable-asm],
 424         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 425     [enable_asm="$enableval"],
 426     [enable_asm=yes]
 427 )
 428 asm_arch=""
 429 MESA_ASM_FILES=""
 430 AC_MSG_CHECKING([whether to enable assembly])
 431 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 432 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 433 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 434     case "$host_cpu" in
 435     i?86 | x86_64)
 436         enable_asm=no
 437         AC_MSG_RESULT([no, cross compiling])
 438         ;;
 439     esac
 440 fi
 441 # check for supported arches
 442 if test "x$enable_asm" = xyes; then
 443     case "$host_cpu" in
 444     i?86)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd*)
 447             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         MESA_ASM_FILES='$(X86_FILES)'
 471         AC_MSG_RESULT([yes, x86])
 472         ;;
 473     x86_64)
 474         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 475         MESA_ASM_FILES='$(X86_64_FILES)'
 476         AC_MSG_RESULT([yes, x86_64])
 477         ;;
 478     sparc)
 479         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 480         MESA_ASM_FILES='$(SPARC_FILES)'
 481         AC_MSG_RESULT([yes, sparc])
 482         ;;
 483     *)
 484         AC_MSG_RESULT([no, platform not supported])
 485         ;;
 486     esac
 487 fi
 488 AC_SUBST([MESA_ASM_FILES])
 489
 490 dnl PIC code macro
 491 MESA_PIC_FLAGS
 492
 493 dnl Check to see if dlopen is in default libraries (like Solaris, which
 494 dnl has it in libc), or if libdl is needed to get it.
 495 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 496     [AC_CHECK_LIB([dl], [dlopen],
 497        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 498 AC_SUBST([DLOPEN_LIBS])
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl signbit() is a macro in glibc's math.h, so AC_CHECK_FUNC fails. To handle
 504 dnl this, use AC_CHECK_DECLS and fallback to AC_CHECK_FUNC in case it fails.
 505 AC_CHECK_DECLS([signbit],[],
 506                AC_CHECK_FUNC([signbit],[],
 507                              AC_MSG_ERROR([could not find signbit()])),
 508                [#include <math.h>])
 509
 510 dnl Check for pthreads
 511 AX_PTHREAD
 512 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 513 dnl to -pthread, which causes problems if we need -lpthread to appear in
 514 dnl pkgconfig files.
 515 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 516
 517 dnl SELinux awareness.
 518 AC_ARG_ENABLE([selinux],
 519     [AS_HELP_STRING([--enable-selinux],
 520         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 521     [MESA_SELINUX="$enableval"],
 522     [MESA_SELINUX=no])
 523 if test "x$enable_selinux" = "xyes"; then
 524     AC_CHECK_HEADER([selinux/selinux.h],[],
 525                     [AC_MSG_ERROR([SELinux headers not found])])
 526     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 527                  [AC_MSG_ERROR([SELinux library not found])])
 528     SELINUX_LIBS="-lselinux"
 529     DEFINES="$DEFINES -DMESA_SELINUX"
 530 fi
 531 AC_SUBST([SELINUX_LIBS])
 532
 533 dnl Options for APIs
 534 AC_ARG_ENABLE([opengl],
 535     [AS_HELP_STRING([--disable-opengl],
 536         [disable support for standard OpenGL API @<:@default=no@:>@])],
 537     [enable_opengl="$enableval"],
 538     [enable_opengl=yes])
 539 AC_ARG_ENABLE([gles1],
 540     [AS_HELP_STRING([--enable-gles1],
 541         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 542     [enable_gles1="$enableval"],
 543     [enable_gles1=no])
 544 AC_ARG_ENABLE([gles2],
 545     [AS_HELP_STRING([--enable-gles2],
 546         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 547     [enable_gles2="$enableval"],
 548     [enable_gles2=no])
 549 AC_ARG_ENABLE([openvg],
 550     [AS_HELP_STRING([--enable-openvg],
 551         [enable support for OpenVG API @<:@default=no@:>@])],
 552     [enable_openvg="$enableval"],
 553     [enable_openvg=no])
 554
 555 AC_ARG_ENABLE([dri],
 556     [AS_HELP_STRING([--enable-dri],
 557         [enable DRI modules @<:@default=enabled@:>@])],
 558     [enable_dri="$enableval"],
 559     [enable_dri=yes])
 560 AC_ARG_ENABLE([glx],
 561     [AS_HELP_STRING([--enable-glx],
 562         [enable GLX library @<:@default=enabled@:>@])],
 563     [enable_glx="$enableval"],
 564     [enable_glx=yes])
 565 AC_ARG_ENABLE([osmesa],
 566     [AS_HELP_STRING([--enable-osmesa],
 567         [enable OSMesa library @<:@default=disabled@:>@])],
 568     [enable_osmesa="$enableval"],
 569     [enable_osmesa=no])
 570 AC_ARG_ENABLE([egl],
 571     [AS_HELP_STRING([--disable-egl],
 572         [disable EGL library @<:@default=enabled@:>@])],
 573     [enable_egl="$enableval"],
 574     [enable_egl=yes])
 575
 576 AC_ARG_ENABLE([xorg],
 577     [AS_HELP_STRING([--enable-xorg],
 578         [enable support for X.Org DDX API @<:@default=no@:>@])],
 579     [enable_xorg="$enableval"],
 580     [enable_xorg=no])
 581 AC_ARG_ENABLE([xa],
 582     [AS_HELP_STRING([--enable-xa],
 583         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 584     [enable_xa="$enableval"],
 585     [enable_xa=no])
 586 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 587 enable_d3d1x=no
 588 dnl AC_ARG_ENABLE([d3d1x],
 589 dnl     [AS_HELP_STRING([--enable-d3d1x],
 590 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 591 dnl     [enable_d3d1x="$enableval"],
 592 dnl     [enable_d3d1x=no])
 593 AC_ARG_ENABLE([gbm],
 594    [AS_HELP_STRING([--enable-gbm],
 595          [enable gbm library @<:@default=auto@:>@])],
 596    [enable_gbm="$enableval"],
 597    [enable_gbm=auto])
 598
 599 AC_ARG_ENABLE([xvmc],
 600    [AS_HELP_STRING([--enable-xvmc],
 601          [enable xvmc library @<:@default=auto@:>@])],
 602    [enable_xvmc="$enableval"],
 603    [enable_xvmc=auto])
 604 AC_ARG_ENABLE([vdpau],
 605    [AS_HELP_STRING([--enable-vdpau],
 606          [enable vdpau library @<:@default=auto@:>@])],
 607    [enable_vdpau="$enableval"],
 608    [enable_vdpau=auto])
 609 AC_ARG_ENABLE([va],
 610    [AS_HELP_STRING([--enable-va],
 611          [enable va library @<:@default=auto@:>@])],
 612    [enable_va="$enableval"],
 613    [enable_va=auto])
 614 AC_ARG_ENABLE([opencl],
 615    [AS_HELP_STRING([--enable-opencl],
 616          [enable OpenCL library @<:@default=no@:>@])],
 617    [enable_opencl="$enableval"],
 618    [enable_opencl=no])
 619 AC_ARG_ENABLE([xlib_glx],
 620     [AS_HELP_STRING([--enable-xlib-glx],
 621         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 622     [enable_xlib_glx="$enableval"],
 623     [enable_xlib_glx=no])
 624 AC_ARG_ENABLE([gallium_egl],
 625     [AS_HELP_STRING([--enable-gallium-egl],
 626         [enable optional EGL state tracker (not required
 627          for EGL support in Gallium with OpenGL and OpenGL ES)
 628          @<:@default=disable@:>@])],
 629     [enable_gallium_egl="$enableval"],
 630     [enable_gallium_egl=no])
 631 AC_ARG_ENABLE([gallium_gbm],
 632     [AS_HELP_STRING([--enable-gallium-gbm],
 633         [enable optional gbm state tracker (not required for
 634          gbm support in Gallium)
 635          @<:@default=auto@:>@])],
 636     [enable_gallium_gbm="$enableval"],
 637     [enable_gallium_gbm=auto])
 638
 639 AC_ARG_ENABLE([r600-llvm-compiler],
 640     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 641         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 642     [enable_r600_llvm="$enableval"],
 643     [enable_r600_llvm=no])
 644
 645 AC_ARG_ENABLE([gallium_tests],
 646     [AS_HELP_STRING([--enable-gallium-tests],
 647         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 648     [enable_gallium_tests="$enableval"],
 649     [enable_gallium_tests=no])
 650
 651 # Option for Gallium drivers
 652 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 653
 654 AC_ARG_WITH([gallium-drivers],
 655     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 656         [comma delimited Gallium drivers list, e.g.
 657         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 658         @<:@default=r300,r600,swrast@:>@])],
 659     [with_gallium_drivers="$withval"],
 660     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 661
 662 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 663 # here so that the script doesn't choke on an unknown driver name later.
 664 case "$with_gallium_drivers" in
 665     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 666     no) with_gallium_drivers='' ;;
 667 esac
 668
 669 if test "x$enable_opengl" = xno -a \
 670         "x$enable_gles1" = xno -a \
 671         "x$enable_gles2" = xno -a \
 672         "x$enable_openvg" = xno -a \
 673         "x$enable_xorg" = xno -a \
 674         "x$enable_xa" = xno -a \
 675         "x$enable_d3d1x" = xno -a \
 676         "x$enable_xvmc" = xno -a \
 677         "x$enable_vdpau" = xno -a \
 678         "x$enable_va" = xno -a \
 679         "x$enable_opencl" = xno; then
 680     AC_MSG_ERROR([at least one API should be enabled])
 681 fi
 682
 683 API_DEFINES=""
 684 if test "x$enable_opengl" = xno; then
 685     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 686 else
 687     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 688 fi
 689 if test "x$enable_gles1" = xyes; then
 690     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 691 fi
 692 if test "x$enable_gles2" = xyes; then
 693     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 694 fi
 695 AC_SUBST([API_DEFINES])
 696
 697 if test "x$enable_glx" = xno; then
 698     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 699     enable_xlib_glx=no
 700 fi
 701
 702 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 703     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 704 fi
 705
 706 # Disable GLX if DRI and Xlib-GLX are not enabled
 707 if test "x$enable_glx" = xyes -a \
 708         "x$enable_dri" = xno -a \
 709         "x$enable_xlib_glx" = xno; then
 710     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 711     enable_glx=no
 712 fi
 713
 714 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 715 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 716                                   "x$enable_osmesa" = xyes)
 717
 718 AC_ARG_ENABLE([shared-glapi],
 719     [AS_HELP_STRING([--enable-shared-glapi],
 720         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 721     [enable_shared_glapi="$enableval"],
 722     [enable_shared_glapi="$enable_dri"])
 723
 724 # Shared GLAPI is only useful for DRI
 725 if test "x$enable_dri" = xno; then
 726     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 727     enable_shared_glapi=no
 728 fi
 729
 730 # TODO: Get rid of SHARED_GLAPI variable
 731 SHARED_GLAPI="0"
 732 if test "x$enable_shared_glapi" = xyes; then
 733     SHARED_GLAPI="1"
 734     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 735     # the remap table)
 736     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 737     CORE_DIRS="mapi/shared-glapi"
 738 fi
 739 AC_SUBST([SHARED_GLAPI])
 740 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 741
 742 dnl
 743 dnl Driver specific build directories
 744 dnl
 745 SRC_DIRS="gtest"
 746 GALLIUM_DIRS="auxiliary drivers state_trackers"
 747 GALLIUM_TARGET_DIRS=""
 748 GALLIUM_WINSYS_DIRS="sw"
 749 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 750 GALLIUM_STATE_TRACKERS_DIRS=""
 751
 752 # build glapi if OpenGL is enabled
 753 if test "x$enable_opengl" = xyes; then
 754     CORE_DIRS="$CORE_DIRS mapi/glapi"
 755 fi
 756
 757 # build es1api if OpenGL ES 1.x is enabled
 758 if test "x$enable_gles1" = xyes; then
 759     CORE_DIRS="$CORE_DIRS mapi/es1api"
 760 fi
 761
 762 # build es2api if OpenGL ES 2.x is enabled
 763 if test "x$enable_gles2" = xyes; then
 764     CORE_DIRS="$CORE_DIRS mapi/es2api"
 765 fi
 766
 767 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 768 case "x$enable_opengl$enable_gles1$enable_gles2" in
 769 x*yes*)
 770     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 771     ;;
 772 esac
 773
 774 case "x$enable_glx$enable_xlib_glx" in
 775 xyesyes)
 776     DRIVER_DIRS="$DRIVER_DIRS x11"
 777     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 778     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 779     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 780     HAVE_WINSYS_XLIB="yes"
 781     ;;
 782 xyesno)
 783     # DRI-based GLX
 784     SRC_DIRS="$SRC_DIRS glx"
 785     ;;
 786 esac
 787
 788 if test "x$enable_dri" = xyes; then
 789     DRIVER_DIRS="$DRIVER_DIRS dri"
 790
 791     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 792     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 793     HAVE_ST_DRI="yes"
 794 fi
 795
 796 if test "x$enable_osmesa" = xyes; then
 797     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 798 fi
 799
 800 AC_SUBST([SRC_DIRS])
 801 AC_SUBST([DRIVER_DIRS])
 802 AC_SUBST([GALLIUM_DIRS])
 803 AC_SUBST([GALLIUM_TARGET_DIRS])
 804 AC_SUBST([GALLIUM_WINSYS_DIRS])
 805 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 806 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 807 AC_SUBST([MESA_LLVM])
 808
 809 # Check for libdrm
 810 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 811                   [have_libdrm=yes], [have_libdrm=no])
 812
 813 if test "x$enable_dri" = xyes; then
 814     # DRI must be shared, I think
 815     if test "$enable_static" = yes; then
 816         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 817     fi
 818
 819     # not a hard requirement as swrast does not depend on it
 820     if test "x$have_libdrm" = xyes; then
 821         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 822     fi
 823 fi
 824
 825 dnl Find out if X is available.
 826 PKG_CHECK_MODULES([X11], [x11])
 827
 828 dnl Try to tell the user that the --x-* options are only used when
 829 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 830 m4_divert_once([HELP_BEGIN],
 831 [These options are only used when the X libraries cannot be found by the
 832 pkg-config utility.])
 833
 834 dnl We need X for xlib and dri, so bomb now if it's not found
 835 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 836     AC_MSG_ERROR([X11 development libraries needed for GLX])
 837 fi
 838
 839 if test "x$enable_glx" = xyes; then
 840     DEFINES="$DEFINES -DUSE_XCB"
 841 fi
 842
 843 dnl Direct rendering or just indirect rendering
 844 case "$host_os" in
 845 gnu*)
 846     dnl Disable by default on GNU/Hurd
 847     driglx_direct_default="no"
 848     ;;
 849 cygwin*)
 850     dnl Disable by default on cygwin
 851     driglx_direct_default="no"
 852     ;;
 853 *)
 854     driglx_direct_default="yes"
 855     ;;
 856 esac
 857 AC_ARG_ENABLE([driglx-direct],
 858     [AS_HELP_STRING([--disable-driglx-direct],
 859         [enable direct rendering in GLX and EGL for DRI \
 860             @<:@default=auto@:>@])],
 861     [driglx_direct="$enableval"],
 862     [driglx_direct="$driglx_direct_default"])
 863
 864 dnl
 865 dnl libGL configuration per driver
 866 dnl
 867 case "x$enable_glx$enable_xlib_glx" in
 868 xyesyes)
 869     # Xlib-based GLX
 870     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 871     GL_PC_REQ_PRIV="x11 xext"
 872     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 873     GL_LIB_DEPS="$XLIBGL_LIBS"
 874     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 875     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 876     ;;
 877 xyesno)
 878     # DRI-based GLX
 879     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 880     if test x"$driglx_direct" = xyes; then
 881         if test "x$have_libdrm" != xyes; then
 882             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 883         fi
 884         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 885         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 886     fi
 887
 888     # find the DRI deps for libGL
 889     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 890
 891     # add xf86vidmode if available
 892     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 893     if test "$HAVE_XF86VIDMODE" = yes ; then
 894         dri_modules="$dri_modules xxf86vm"
 895     fi
 896
 897     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 898     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 899     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 900     GL_LIB_DEPS="$DRIGL_LIBS"
 901
 902     # need DRM libs, $PTHREAD_LIBS, etc.
 903     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 904     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905     ;;
 906 esac
 907
 908 # This is outside the case (above) so that it is invoked even for non-GLX
 909 # builds.
 910 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 911
 912 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 913 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 914 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 915 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 916
 917 AC_SUBST([X11_INCLUDES])
 918 AC_SUBST([GL_LIB_DEPS])
 919 AC_SUBST([GL_PC_REQ_PRIV])
 920 AC_SUBST([GL_PC_LIB_PRIV])
 921 AC_SUBST([GL_PC_CFLAGS])
 922 AC_SUBST([DRI_PC_REQ_PRIV])
 923 AC_SUBST([GLESv1_CM_LIB_DEPS])
 924 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 925 AC_SUBST([GLESv2_LIB_DEPS])
 926 AC_SUBST([GLESv2_PC_LIB_PRIV])
 927
 928 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 929
 930 AC_SUBST([HAVE_XF86VIDMODE])
 931
 932 dnl
 933 dnl More GLX setup
 934 dnl
 935 case "x$enable_glx$enable_xlib_glx" in
 936 xyesyes)
 937     DEFINES="$DEFINES -DUSE_XSHM"
 938     ;;
 939 xyesno)
 940     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 941     if test "x$driglx_direct" = xyes; then
 942         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 943     fi
 944     ;;
 945 esac
 946
 947 dnl
 948 dnl TLS detection
 949 dnl
 950
 951 AC_ARG_ENABLE([glx-tls],
 952     [AS_HELP_STRING([--enable-glx-tls],
 953         [enable TLS support in GLX @<:@default=disabled@:>@])],
 954     [GLX_USE_TLS="$enableval"],
 955     [GLX_USE_TLS=no])
 956 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 957
 958 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 959       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
 960
 961 dnl
 962 dnl More DRI setup
 963 dnl
 964 dnl Directory for DRI drivers
 965 AC_ARG_WITH([dri-driverdir],
 966     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 967         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 968     [DRI_DRIVER_INSTALL_DIR="$withval"],
 969     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 970 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 971 dnl Extra search path for DRI drivers
 972 AC_ARG_WITH([dri-searchpath],
 973     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 974         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 975     [DRI_DRIVER_SEARCH_DIR="$withval"],
 976     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 977 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 978 dnl Which drivers to build - default is chosen by platform
 979 AC_ARG_WITH([dri-drivers],
 980     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 981         [comma delimited DRI drivers list, e.g.
 982         "swrast,i965,radeon" @<:@default=auto@:>@])],
 983     [with_dri_drivers="$withval"],
 984     [with_dri_drivers=yes])
 985 if test "x$with_dri_drivers" = x; then
 986     with_dri_drivers=no
 987 fi
 988
 989 dnl If $with_dri_drivers is yes, directories will be added through
 990 dnl platform checks
 991 DRI_DIRS=""
 992 case "$with_dri_drivers" in
 993 no) ;;
 994 yes)
 995     # classic DRI drivers require FEATURE_GL to build
 996     if test "x$enable_opengl" = xyes; then
 997         DRI_DIRS="yes"
 998     fi
 999     ;;
1000 *)
1001     # verify the requested driver directories exist
1002     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1003     for driver in $dri_drivers; do
1004         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1005             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1006     done
1007     DRI_DIRS="$dri_drivers"
1008     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1009         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1010     fi
1011     ;;
1012 esac
1013
1014 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1015 if test "x$enable_dri" = xyes; then
1016     # Platform specific settings and drivers to build
1017     case "$host_os" in
1018     linux*)
1019         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1020         DEFINES="$DEFINES -DHAVE_ALIAS"
1021
1022         case "$host_cpu" in
1023         x86_64)
1024             if test "x$DRI_DIRS" = "xyes"; then
1025                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1026             fi
1027             ;;
1028         powerpc*)
1029             # Build only the drivers for cards that exist on PowerPC.
1030             if test "x$DRI_DIRS" = "xyes"; then
1031                 DRI_DIRS="r200 radeon swrast"
1032             fi
1033             ;;
1034         sparc*)
1035             # Build only the drivers for cards that exist on sparc
1036             if test "x$DRI_DIRS" = "xyes"; then
1037                 DRI_DIRS="r200 radeon swrast"
1038             fi
1039             ;;
1040         esac
1041         ;;
1042     freebsd* | dragonfly* | *netbsd*)
1043         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1044         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1045
1046         if test "x$DRI_DIRS" = "xyes"; then
1047             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1048         fi
1049         ;;
1050     gnu*)
1051         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1052         DEFINES="$DEFINES -DHAVE_ALIAS"
1053         ;;
1054     solaris*)
1055         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1056         ;;
1057     cygwin*)
1058         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1059         if test "x$DRI_DIRS" = "xyes"; then
1060             DRI_DIRS="swrast"
1061         fi
1062         ;;
1063     esac
1064
1065     # default drivers
1066     if test "x$DRI_DIRS" = "xyes"; then
1067         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1068     fi
1069
1070     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1071
1072     # Check for expat
1073     if test "x$enable_dri" = xyes; then
1074         EXPAT_INCLUDES=""
1075         EXPAT_LIB=-lexpat
1076         AC_ARG_WITH([expat],
1077             [AS_HELP_STRING([--with-expat=DIR],
1078                 [expat install directory])],[
1079             EXPAT_INCLUDES="-I$withval/include"
1080             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1081             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1082             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1083             ])
1084         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1085         save_LIBS="$LIBS"
1086         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1087             [AC_MSG_ERROR([Expat required for DRI.])])
1088         LIBS="$save_LIBS"
1089     fi
1090
1091     # if we are building any dri driver other than swrast ...
1092     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1093         # ... libdrm is required
1094         if test "x$have_libdrm" != xyes; then
1095             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1096         fi
1097         # ... and build dricommon
1098         HAVE_COMMON_DRI=yes
1099     fi
1100
1101     # put all the necessary libs together
1102     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1103     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1104 fi
1105 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1106 AC_SUBST([DRI_DIRS])
1107 AC_SUBST([EXPAT_INCLUDES])
1108 AC_SUBST([DRI_LIB_DEPS])
1109 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1110
1111 case $DRI_DIRS in
1112 *i915*|*i965*)
1113     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1114
1115     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1116         case $d in
1117         i915)
1118             HAVE_I915_DRI=yes;
1119             ;;
1120         i965)
1121             HAVE_I965_DRI=yes;
1122             ;;
1123         esac
1124     done
1125
1126     ;;
1127 esac
1128
1129 case $DRI_DIRS in
1130 *nouveau*)
1131     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1132     HAVE_NOUVEAU_DRI=yes;
1133     ;;
1134 esac
1135
1136 case $DRI_DIRS in
1137 *radeon*|*r200*)
1138     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1139
1140     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1141         case $d in
1142         radeon)
1143             HAVE_RADEON_DRI=yes;
1144             ;;
1145         r200)
1146             HAVE_R200_DRI=yes;
1147             ;;
1148         esac
1149     done
1150
1151     ;;
1152 esac
1153
1154 case $DRI_DIRS in
1155 *swrast*)
1156     HAVE_SWRAST_DRI=yes;
1157     ;;
1158 esac
1159
1160 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1161 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1162 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1163 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1164 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1165 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1166 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1167
1168 dnl
1169 dnl OSMesa configuration
1170 dnl
1171
1172 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1173 AC_ARG_WITH([osmesa-bits],
1174     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1175         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1176     [osmesa_bits="$withval"],
1177     [osmesa_bits=8])
1178 if test "x$osmesa_bits" != x8; then
1179     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1180         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1181         osmesa_bits=8
1182     fi
1183 fi
1184 case "x$osmesa_bits" in
1185 x8)
1186     OSMESA_LIB="${OSMESA_LIB}"
1187     ;;
1188 x16|x32)
1189     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1190     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1191     ;;
1192 *)
1193     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1194     ;;
1195 esac
1196
1197 if test "x$enable_osmesa" = xyes; then
1198     # only link libraries with osmesa if shared
1199     if test "$enable_static" = no; then
1200         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1201     else
1202         OSMESA_LIB_DEPS=""
1203     fi
1204     OSMESA_MESA_DEPS=""
1205     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1206 fi
1207
1208 AC_SUBST([OSMESA_LIB_DEPS])
1209 AC_SUBST([OSMESA_MESA_DEPS])
1210 AC_SUBST([OSMESA_PC_REQ])
1211 AC_SUBST([OSMESA_PC_LIB_PRIV])
1212
1213 dnl
1214 dnl gbm configuration
1215 dnl
1216 if test "x$enable_gbm" = xauto; then
1217     case "$with_egl_platforms" in
1218         *drm*)
1219             enable_gbm=yes ;;
1220          *)
1221             enable_gbm=no ;;
1222     esac
1223 fi
1224 if test "x$enable_gbm" = xyes; then
1225     SRC_DIRS="$SRC_DIRS gbm"
1226
1227     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1228                       AC_MSG_ERROR([gbm needs udev]))
1229
1230     if test "x$enable_dri" = xyes; then
1231         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1232         if test "x$enable_shared_glapi" = xno; then
1233             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1234         fi
1235         PKG_CHECK_MODULES([LIBKMS], [libkms], [],
1236                           AC_MSG_ERROR([gbm needs libkms]))
1237     fi
1238 fi
1239 GBM_PC_REQ_PRIV="libudev"
1240 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1241 AC_SUBST([GBM_PC_REQ_PRIV])
1242 AC_SUBST([GBM_PC_LIB_PRIV])
1243
1244 dnl
1245 dnl EGL configuration
1246 dnl
1247 EGL_CLIENT_APIS=""
1248
1249 if test "x$enable_egl" = xyes; then
1250     SRC_DIRS="$SRC_DIRS egl"
1251     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1252
1253     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1254
1255     if test "$enable_static" != yes; then
1256         # build egl_glx when libGL is built
1257         if test "x$enable_glx" = xyes; then
1258             HAVE_EGL_DRIVER_GLX=1
1259         fi
1260
1261         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1262                           [have_libudev=yes],[have_libudev=no])
1263         if test "$have_libudev" = yes; then
1264             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1265         fi
1266
1267         if test "x$enable_dri" = xyes; then
1268             HAVE_EGL_DRIVER_DRI2=1
1269         fi
1270
1271     fi
1272 fi
1273 AC_SUBST([EGL_LIB_DEPS])
1274
1275 dnl
1276 dnl EGL Gallium configuration
1277 dnl
1278 if test "x$enable_gallium_egl" = xyes; then
1279     if test "x$with_gallium_drivers" = x; then
1280         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1281     fi
1282     if test "x$enable_egl" = xno; then
1283         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1284     fi
1285     if test "x$have_libdrm" != xyes; then
1286         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1287     fi
1288
1289     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1290     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1291     HAVE_ST_EGL="yes"
1292 fi
1293
1294 dnl
1295 dnl gbm Gallium configuration
1296 dnl
1297 if test "x$enable_gallium_gbm" = xauto; then
1298     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1299         yesyesyes*drm*)
1300             enable_gallium_gbm=yes ;;
1301          *)
1302             enable_gallium_gbm=no ;;
1303     esac
1304 fi
1305 if test "x$enable_gallium_gbm" = xyes; then
1306     if test "x$with_gallium_drivers" = x; then
1307         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1308     fi
1309     if test "x$enable_gbm" = xno; then
1310         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1311     fi
1312     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1313     if test "x$enable_dri" = xno; then
1314         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1315     fi
1316
1317     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1318     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1319     HAVE_ST_GBM="yes"
1320     enable_gallium_loader=yes
1321 fi
1322
1323 dnl
1324 dnl X.Org DDX configuration
1325 dnl
1326 if test "x$enable_xorg" = xyes; then
1327     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1328     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1329     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1330     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1331         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1332         HAVE_XEXTPROTO_71="no")
1333     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1334     HAVE_ST_XORG=yes
1335 fi
1336
1337 dnl
1338 dnl XA configuration
1339 dnl
1340 if test "x$enable_xa" = xyes; then
1341 AC_PROG_AWK
1342 AC_PROG_GREP
1343 AC_CHECK_PROG(NM, nm, "nm")
1344 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1345 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1346 enable_xa=no
1347 fi
1348 fi
1349 if test "x$enable_xa" = xyes; then
1350     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1351     HAVE_ST_XA=yes
1352     AC_SUBST(AWK)
1353     AC_SUBST(GREP)
1354     AC_SUBST(NM)
1355 fi
1356
1357 dnl
1358 dnl OpenVG configuration
1359 dnl
1360 VG_LIB_DEPS=""
1361
1362 if test "x$enable_openvg" = xyes; then
1363     if test "x$enable_egl" = xno; then
1364         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1365     fi
1366     if test "x$with_gallium_drivers" = x; then
1367         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1368     fi
1369     if test "x$enable_gallium_egl" = xno; then
1370         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1371     fi
1372
1373     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1374     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1375     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1376     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1377     HAVE_ST_VEGA=yes
1378     VG_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1379     AC_SUBST([VG_PC_LIB_PRIV])
1380 fi
1381
1382 dnl
1383 dnl D3D1X configuration
1384 dnl
1385
1386 if test "x$enable_d3d1x" = xyes; then
1387     if test "x$with_gallium_drivers" = x; then
1388         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1389     fi
1390
1391     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1392     HAVE_ST_D3D1X=yes
1393 fi
1394
1395 dnl
1396 dnl Gallium G3DVL configuration
1397 dnl
1398 AC_ARG_ENABLE([gallium-g3dvl],
1399     [AS_HELP_STRING([--enable-gallium-g3dvl],
1400         [build gallium g3dvl @<:@default=disabled@:>@])],
1401     [enable_gallium_g3dvl="$enableval"],
1402     [enable_gallium_g3dvl=no])
1403 if test "x$enable_gallium_g3dvl" = xyes; then
1404     if test "x$with_gallium_drivers" = x; then
1405         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1406     fi
1407
1408     if test "x$enable_xvmc" = xauto; then
1409         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1410     fi
1411
1412     if test "x$enable_vdpau" = xauto; then
1413         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1414     fi
1415
1416     if test "x$enable_va" = xauto; then
1417         #don't enable vaapi state tracker even if package exists
1418         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1419         enable_va=no
1420     fi
1421 fi
1422
1423 if test "x$enable_xvmc" = xyes; then
1424     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1425     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1426     HAVE_ST_XVMC="yes"
1427 fi
1428
1429 if test "x$enable_vdpau" = xyes; then
1430     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1431     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1432     HAVE_ST_VDPAU="yes"
1433 fi
1434
1435 if test "x$enable_va" = xyes; then
1436     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1437     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1438     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1439     HAVE_ST_VA="yes"
1440 fi
1441
1442 dnl
1443 dnl OpenCL configuration
1444 dnl
1445
1446 AC_ARG_WITH([libclc-path],
1447    [AS_HELP_STRING([--with-libclc-path],
1448          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1449    [LIBCLC_PATH="$withval"],
1450    [LIBCLC_PATH=""])
1451
1452 AC_ARG_WITH([clang-libdir],
1453    [AS_HELP_STRING([--with-clang-libdir],
1454          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1455    [CLANG_LIBDIR="$withval"],
1456    [CLANG_LIBDIR=""])
1457
1458 AC_SUBST([LIBCLC_PATH])
1459
1460 if test "x$enable_opencl" = xyes; then
1461     if test "x$with_gallium_drivers" = x; then
1462         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1463     fi
1464
1465     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1466         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1467     fi
1468
1469     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1470     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1471     enable_gallium_loader=yes
1472 fi
1473
1474 dnl
1475 dnl Gallium configuration
1476 dnl
1477 if test "x$with_gallium_drivers" != x; then
1478     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1479 fi
1480 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1481
1482 AC_SUBST([LLVM_BINDIR])
1483 AC_SUBST([LLVM_CFLAGS])
1484 AC_SUBST([LLVM_CPPFLAGS])
1485 AC_SUBST([LLVM_CXXFLAGS])
1486 AC_SUBST([LLVM_LIBDIR])
1487 AC_SUBST([LLVM_LIBS])
1488 AC_SUBST([LLVM_LDFLAGS])
1489 AC_SUBST([LLVM_INCLUDEDIR])
1490 AC_SUBST([LLVM_VERSION])
1491 AC_SUBST([CLANG_RESOURCE_DIR])
1492
1493 case "x$enable_opengl$enable_gles1$enable_gles2" in
1494 x*yes*)
1495     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1496     ;;
1497 esac
1498
1499 AC_SUBST([VG_LIB_DEPS])
1500 AC_SUBST([EGL_CLIENT_APIS])
1501
1502 dnl
1503 dnl EGL Platforms configuration
1504 dnl
1505 AC_ARG_WITH([egl-platforms],
1506     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1507         [comma delimited native platforms libEGL supports, e.g.
1508         "x11,drm" @<:@default=auto@:>@])],
1509     [with_egl_platforms="$withval"],
1510     [if test "x$enable_egl" = xyes; then
1511         with_egl_platforms="x11"
1512     else
1513         with_egl_platforms=""
1514     fi])
1515
1516 EGL_PLATFORMS=""
1517
1518 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1519     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1520 fi
1521
1522 # Do per-EGL platform setups and checks
1523 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1524 for plat in $egl_platforms; do
1525         case "$plat" in
1526         fbdev|null)
1527                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1528                 ;;
1529
1530         wayland)
1531                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1532                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1533                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1534
1535                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1536                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1537                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1538                 ;;
1539
1540         x11)
1541                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1542                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1543                 save_LIBS="$LIBS"
1544                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1545                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1546                 LIBS="$save_LIBS"
1547                 ;;
1548
1549         drm)
1550                 test "x$enable_gbm" = "xno" &&
1551                         AC_MSG_ERROR([EGL platform drm needs gbm])
1552                 ;;
1553
1554         android|gdi)
1555                 ;;
1556
1557         *)
1558                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1559                 ;;
1560         esac
1561
1562         case "$plat$have_libudev" in
1563                 waylandno|drmno)
1564                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1565         esac
1566 done
1567
1568 # libEGL wants to default to the first platform specified in
1569 # ./configure.  parse that here.
1570 if test "x$egl_platforms" != "x"; then
1571     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1572     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1573 else
1574     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1575 fi
1576
1577 EGL_PLATFORMS="$egl_platforms"
1578
1579 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1580 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1581 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1582 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1583 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1584
1585 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1586 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1587
1588 AC_SUBST([EGL_NATIVE_PLATFORM])
1589 AC_SUBST([EGL_PLATFORMS])
1590 AC_SUBST([EGL_CFLAGS])
1591
1592 AC_ARG_WITH([egl-driver-dir],
1593     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1594                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1595     [EGL_DRIVER_INSTALL_DIR="$withval"],
1596     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1597 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1598
1599 AC_ARG_WITH([xorg-driver-dir],
1600     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1601                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1602     [XORG_DRIVER_INSTALL_DIR="$withval"],
1603     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1604 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1605
1606 AC_ARG_WITH([max-width],
1607     [AS_HELP_STRING([--with-max-width=N],
1608                     [Maximum framebuffer width (4096)])],
1609     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1610      AS_IF([test "${withval}" -gt "4096"],
1611            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1612 )
1613 AC_ARG_WITH([max-height],
1614     [AS_HELP_STRING([--with-max-height=N],
1615                     [Maximum framebuffer height (4096)])],
1616     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1617      AS_IF([test "${withval}" -gt "4096"],
1618            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1619 )
1620
1621 dnl
1622 dnl Gallium LLVM
1623 dnl
1624 AC_ARG_ENABLE([gallium-llvm],
1625     [AS_HELP_STRING([--enable-gallium-llvm],
1626         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1627     [enable_gallium_llvm="$enableval"],
1628     [enable_gallium_llvm=auto])
1629
1630 AC_ARG_WITH([llvm-shared-libs],
1631     [AS_HELP_STRING([--with-llvm-shared-libs],
1632         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1633     [with_llvm_shared_libs=yes],
1634     [with_llvm_shared_libs=no])
1635
1636 AC_ARG_WITH([llvm-prefix],
1637     [AS_HELP_STRING([--with-llvm-prefix],
1638         [Prefix for LLVM installations in non-standard locations])],
1639     [llvm_prefix="$withval"],
1640     [llvm_prefix=""])
1641
1642
1643 if test "x$with_gallium_drivers" = x; then
1644     enable_gallium_llvm=no
1645 fi
1646 if test "x$enable_gallium_llvm" = xauto; then
1647     case "$host_cpu" in
1648     i*86|x86_64) enable_gallium_llvm=yes;;
1649     esac
1650 fi
1651 if test "x$enable_gallium_llvm" = xyes; then
1652     if test "x$llvm_prefix" != x; then
1653         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1654     else
1655         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1656     fi
1657
1658     if test "x$LLVM_CONFIG" != xno; then
1659         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1660         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1661         if test "x$with_llvm_shared_libs" = xyes; then
1662             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1663             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1664         else
1665             LLVM_COMPONENTS="engine bitwriter"
1666             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1667                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1668             fi
1669
1670             if test "x$enable_opencl" = xyes; then
1671                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1672             fi
1673             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1674         fi
1675         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1676         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1677         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1678         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1679         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1680         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1681         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1682         MESA_LLVM=1
1683
1684         dnl Check for Clang interanl headers
1685         if test "x$enable_opencl" = xyes; then
1686             if test "x$CLANG_LIBDIR" = x; then
1687                 CLANG_LIBDIR=${LLVM_LIBDIR}
1688             fi
1689             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1690             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1691                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1692         fi
1693     else
1694         MESA_LLVM=0
1695     fi
1696 else
1697     MESA_LLVM=0
1698 fi
1699
1700 dnl Directory for XVMC libs
1701 AC_ARG_WITH([xvmc-libdir],
1702     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1703         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1704     [XVMC_LIB_INSTALL_DIR="$withval"],
1705     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1706 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1707
1708 dnl
1709 dnl Gallium Tests
1710 dnl
1711 if test "x$enable_gallium_tests" = xyes; then
1712     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1713     enable_gallium_loader=yes
1714 fi
1715
1716 dnl Directory for VDPAU libs
1717 AC_ARG_WITH([vdpau-libdir],
1718     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1719         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1720     [VDPAU_LIB_INSTALL_DIR="$withval"],
1721     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1722 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1723
1724 dnl Directory for VA libs
1725 AC_ARG_WITH([va-libdir],
1726     [AS_HELP_STRING([--with-va-libdir=DIR],
1727         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1728     [VA_LIB_INSTALL_DIR="$withval"],
1729     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1730 AC_SUBST([VA_LIB_INSTALL_DIR])
1731
1732 dnl Directory for OpenCL libs
1733 AC_ARG_WITH([opencl-libdir],
1734     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1735         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1736     [OPENCL_LIB_INSTALL_DIR="$withval"],
1737     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1738 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1739
1740 dnl
1741 dnl Gallium helper functions
1742 dnl
1743 gallium_check_st() {
1744     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1745          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1746          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1747          if test "x$have_libdrm" != xyes; then
1748             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1749          fi
1750          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1751     fi
1752     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1753          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1754     fi
1755     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1756          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1757     fi
1758     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1759          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1760     fi
1761     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1762          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1763     fi
1764     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1765          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1766     fi
1767     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1768          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1769     fi
1770 }
1771
1772 gallium_require_llvm() {
1773     if test "x$MESA_LLVM" = x0; then
1774         case "$host_cpu" in
1775         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1776         esac
1777     fi
1778 }
1779
1780 gallium_require_drm_loader() {
1781     if test "x$enable_gallium_loader" = xyes; then
1782         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1783                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1784         if test "x$have_libdrm" != xyes; then
1785             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1786         fi
1787         enable_gallium_drm_loader=yes
1788     fi
1789 }
1790
1791 radeon_llvm_check() {
1792     LLVM_VERSION_MAJOR=`echo $LLVM_VERSION | cut -d. -f1`
1793     if test "$LLVM_VERSION_MAJOR" -lt "3" -o "x$LLVM_VERSION" = "x3.0"; then
1794         AC_MSG_ERROR([LLVM 3.1 or newer is required for the r600/radeonsi llvm compiler.])
1795     fi
1796     if test "$LLVM_VERSION_MAJOR" -ge "3" -a "x$LLVM_VERSION" != "x3.1" && $LLVM_CONFIG --targets-built | grep -qv '\<AMDGPU\>' ; then
1797         AC_MSG_ERROR([To use the r600/radeonsi LLVM backend with LLVM 3.2 and newer, you need to fetch the LLVM source from:
1798                       git://people.freedesktop.org/~tstellar/llvm master
1799                       and build with --enable-experimental-targets==AMDGPU])
1800     fi
1801     if test "x$LLVM_VERSION" = "x3.2"; then
1802         LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --libs amdgpu`"
1803     fi
1804 }
1805
1806 dnl Gallium drivers
1807 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1808 if test "x$with_gallium_drivers" != x; then
1809     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1810     for driver in $gallium_drivers; do
1811         case "x$driver" in
1812         xsvga)
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1814             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1815             ;;
1816         xi915)
1817             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1818             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1819             if test "x$MESA_LLVM" = x1; then
1820                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1821             fi
1822             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1823             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1824             ;;
1825         xr300)
1826             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1827             gallium_require_llvm "Gallium R300"
1828             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1829             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1830             ;;
1831         xr600)
1832             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1833             gallium_require_drm_loader
1834             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1835             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1836                 radeon_llvm_check
1837                 NEED_RADEON_GALLIUM=yes;
1838             fi
1839             if test "x$enable_r600_llvm" = xyes; then
1840                 USE_R600_LLVM_COMPILER=yes;
1841             fi
1842             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1843                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1844             fi
1845             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1846             ;;
1847         xradeonsi)
1848             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1849             gallium_require_drm_loader
1850             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1851             radeon_llvm_check
1852             NEED_RADEON_GALLIUM=yes;
1853             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1854             ;;
1855         xnouveau)
1856             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1857             gallium_require_drm_loader
1858             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1859             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1860             ;;
1861         xswrast)
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1863             if test "x$MESA_LLVM" = x1; then
1864                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1865             fi
1866
1867             if test "x$HAVE_ST_DRI" = xyes; then
1868                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1869             fi
1870             if test "x$HAVE_ST_VDPAU" = xyes; then
1871                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1872             fi
1873             if test "x$HAVE_ST_XVMC" = xyes; then
1874                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1875             fi
1876             if test "x$HAVE_ST_VA" = xyes; then
1877                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1878             fi
1879             if test "x$HAVE_ST_VDPAU" = xyes ||
1880                test "x$HAVE_ST_XVMC" = xyes ||
1881                test "x$HAVE_ST_VA" = xyes; then
1882                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1883                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1884                fi
1885             fi
1886             ;;
1887         *)
1888             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1889             ;;
1890         esac
1891     done
1892 fi
1893
1894 if test "x$enable_gallium_loader" = xyes; then
1895     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1896     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1897     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1898     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1899
1900     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1901         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1902         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1903     fi
1904
1905     if test "x$enable_gallium_drm_loader" = xyes; then
1906         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1907         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1908                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1909         if test "x$pipe_loader_have_xcb" = xyes; then
1910             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1911             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1912         fi
1913     fi
1914
1915     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1916     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1917 fi
1918
1919 dnl Tell Automake which drivers to build
1920 for driver in $GALLIUM_DRIVERS_DIRS; do
1921     case "x$driver" in
1922         xgalahad)
1923             HAVE_GALAHAD_GALLIUM=yes;
1924             ;;
1925         xidentity)
1926             HAVE_IDENTITY_GALLIUM=yes;
1927             ;;
1928         xnoop)
1929             HAVE_NOOP_GALLIUM=yes;
1930             ;;
1931         *)
1932             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1933             ;;
1934     esac
1935 done
1936
1937 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1938 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1939 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1940 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1941 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1942 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1943 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1944 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1945 AC_SUBST([GALLIUM_MAKE_DIRS])
1946
1947 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1948
1949 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1950 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1951 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1952
1953 dnl prepend CORE_DIRS to SRC_DIRS
1954 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1955
1956 dnl Restore LDFLAGS and CPPFLAGS
1957 LDFLAGS="$_SAVE_LDFLAGS"
1958 CPPFLAGS="$_SAVE_CPPFLAGS"
1959
1960 dnl Add user CFLAGS and CXXFLAGS
1961 CFLAGS="$CFLAGS $USER_CFLAGS"
1962 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1963
1964 dnl Substitute the config
1965 AC_CONFIG_FILES([configs/current
1966                 Makefile
1967                 src/Makefile
1968                 src/egl/Makefile
1969                 src/egl/drivers/Makefile
1970                 src/egl/drivers/dri2/Makefile
1971                 src/egl/drivers/glx/Makefile
1972                 src/egl/main/Makefile
1973                 src/egl/main/egl.pc
1974                 src/egl/wayland/Makefile
1975                 src/egl/wayland/wayland-drm/Makefile
1976                 src/egl/wayland/wayland-egl/Makefile
1977                 src/egl/wayland/wayland-egl/wayland-egl.pc
1978                 src/gallium/Makefile
1979                 src/gallium/auxiliary/pipe-loader/Makefile
1980                 src/gallium/drivers/Makefile
1981                 src/gallium/drivers/r300/Makefile
1982                 src/gallium/drivers/r600/Makefile
1983                 src/gallium/state_trackers/clover/Makefile
1984                 src/gallium/targets/opencl/Makefile
1985                 src/gbm/Makefile
1986                 src/gbm/main/gbm.pc
1987                 src/glsl/Makefile
1988                 src/glsl/glcpp/Makefile
1989                 src/glsl/tests/Makefile
1990                 src/glx/Makefile
1991                 src/glx/tests/Makefile
1992                 src/gtest/Makefile
1993                 src/mapi/es1api/Makefile
1994                 src/mapi/es1api/glesv1_cm.pc
1995                 src/mapi/es2api/Makefile
1996                 src/mapi/es2api/glesv2.pc
1997                 src/mapi/glapi/Makefile
1998                 src/mapi/glapi/gen/Makefile
1999                 src/mapi/glapi/tests/Makefile
2000                 src/mapi/shared-glapi/Makefile
2001                 src/mapi/shared-glapi/tests/Makefile
2002                 src/mapi/vgapi/Makefile
2003                 src/mapi/vgapi/vg.pc
2004                 src/mesa/Makefile
2005                 src/mesa/gl.pc
2006                 src/mesa/drivers/Makefile
2007                 src/mesa/drivers/dri/dri.pc
2008                 src/mesa/drivers/dri/common/Makefile
2009                 src/mesa/drivers/dri/i915/Makefile
2010                 src/mesa/drivers/dri/i965/Makefile
2011                 src/mesa/drivers/dri/Makefile
2012                 src/mesa/drivers/dri/nouveau/Makefile
2013                 src/mesa/drivers/dri/r200/Makefile
2014                 src/mesa/drivers/dri/radeon/Makefile
2015                 src/mesa/drivers/dri/swrast/Makefile
2016                 src/mesa/drivers/osmesa/Makefile
2017                 src/mesa/drivers/osmesa/osmesa.pc
2018                 src/mesa/drivers/x11/Makefile
2019                 src/mesa/libdricore/Makefile
2020                 src/mesa/main/tests/Makefile
2021                 src/mesa/x86-64/Makefile
2022                 src/mesa/x86/Makefile])
2023
2024 dnl Sort the dirs alphabetically
2025 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2026 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2027 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2028 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2029 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2030
2031 AC_OUTPUT
2032
2033 dnl
2034 dnl Output some configuration info for the user
2035 dnl
2036 echo ""
2037 echo "        prefix:          $prefix"
2038 echo "        exec_prefix:     $exec_prefix"
2039 echo "        libdir:          $libdir"
2040 echo "        includedir:      $includedir"
2041
2042 dnl API info
2043 echo ""
2044 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2045 echo "        OpenVG:          $enable_openvg"
2046
2047 dnl Driver info
2048 echo ""
2049 if test "x$enable_osmesa" != xno; then
2050         echo "        OSMesa:          lib$OSMESA_LIB"
2051 else
2052         echo "        OSMesa:          no"
2053 fi
2054
2055 if test "x$enable_dri" != xno; then
2056         # cleanup the drivers var
2057         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2058         if test "x$DRI_DIRS" = x; then
2059             echo "        DRI drivers:     no"
2060         else
2061             echo "        DRI drivers:     $dri_dirs"
2062         fi
2063         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2064 fi
2065
2066 case "x$enable_glx$enable_xlib_glx" in
2067 xyesyes)
2068     echo "        GLX:             Xlib-based"
2069     ;;
2070 xyesno)
2071     echo "        GLX:             DRI-based"
2072     ;;
2073 *)
2074     echo "        GLX:             $enable_glx"
2075     ;;
2076 esac
2077
2078 dnl EGL
2079 echo ""
2080 echo "        EGL:             $enable_egl"
2081 if test "$enable_egl" = yes; then
2082     echo "        EGL platforms:   $EGL_PLATFORMS"
2083
2084     egl_drivers=""
2085     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2086         egl_drivers="$egl_drivers builtin:egl_glx"
2087     fi
2088     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2089         egl_drivers="$egl_drivers builtin:egl_dri2"
2090     fi
2091
2092     if test "x$HAVE_ST_EGL" = xyes; then
2093         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2094         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2095     else
2096         echo "        EGL drivers:    $egl_drivers"
2097     fi
2098 fi
2099
2100 echo ""
2101 if test "x$MESA_LLVM" = x1; then
2102     echo "        llvm:            yes"
2103     echo "        llvm-config:     $LLVM_CONFIG"
2104     echo "        llvm-version:    $LLVM_VERSION"
2105 else
2106     echo "        llvm:            no"
2107 fi
2108
2109 echo ""
2110 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2111     echo "        Gallium:         yes"
2112     echo "        Gallium dirs:    $GALLIUM_DIRS"
2113     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2114     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2115     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2116     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2117 else
2118     echo "        Gallium:         no"
2119 fi
2120
2121
2122 dnl Libraries
2123 echo ""
2124 echo "        Shared libs:     $enable_shared"
2125 echo "        Static libs:     $enable_static"
2126 echo "        Shared-glapi:    $enable_shared_glapi"
2127
2128 dnl Compiler options
2129 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2130 cflags=`echo $CFLAGS $PIC_FLAGS | \
2131     $SED 's/^ *//;s/  */ /;s/ *$//'`
2132 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2133     $SED 's/^ *//;s/  */ /;s/ *$//'`
2134 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2135 echo ""
2136 echo "        CFLAGS:          $cflags"
2137 echo "        CXXFLAGS:        $cxxflags"
2138 echo "        Macros:          $defines"
2139 echo ""
2140 echo "        PYTHON2:         $PYTHON2"
2141
2142 echo ""
2143 echo "        Run '${MAKE-make}' to build Mesa"
2144 echo ""