configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl Check for compiler builtins
 201 AX_GCC_BUILTIN([__builtin_bswap32])
 202 AX_GCC_BUILTIN([__builtin_bswap64])
 203 AX_GCC_BUILTIN([__builtin_clz])
 204 AX_GCC_BUILTIN([__builtin_clzll])
 205 AX_GCC_BUILTIN([__builtin_ctz])
 206 AX_GCC_BUILTIN([__builtin_expect])
 207 AX_GCC_BUILTIN([__builtin_ffs])
 208 AX_GCC_BUILTIN([__builtin_ffsll])
 209 AX_GCC_BUILTIN([__builtin_popcount])
 210 AX_GCC_BUILTIN([__builtin_popcountll])
 211 AX_GCC_BUILTIN([__builtin_unreachable])
 212
 213 AX_GCC_FUNC_ATTRIBUTE([const])
 214 AX_GCC_FUNC_ATTRIBUTE([flatten])
 215 AX_GCC_FUNC_ATTRIBUTE([format])
 216 AX_GCC_FUNC_ATTRIBUTE([malloc])
 217 AX_GCC_FUNC_ATTRIBUTE([packed])
 218 AX_GCC_FUNC_ATTRIBUTE([pure])
 219 AX_GCC_FUNC_ATTRIBUTE([unused])
 220 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 221
 222 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 223
 224 dnl Make sure the pkg-config macros are defined
 225 m4_ifndef([PKG_PROG_PKG_CONFIG],
 226     [m4_fatal([Could not locate the pkg-config autoconf macros.
 227   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 228   are in a different location, try setting the environment variable
 229   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 230 PKG_PROG_PKG_CONFIG()
 231
 232 dnl LIB_DIR - library basename
 233 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 234 AC_SUBST([LIB_DIR])
 235
 236 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 237 _SAVE_LDFLAGS="$LDFLAGS"
 238 _SAVE_CPPFLAGS="$CPPFLAGS"
 239
 240 dnl Compiler macros
 241 DEFINES="-D__STDC_LIMIT_MACROS"
 242 AC_SUBST([DEFINES])
 243 case "$host_os" in
 244 linux*|*-gnu*|gnu*)
 245     DEFINES="$DEFINES -D_GNU_SOURCE"
 246     ;;
 247 solaris*)
 248     DEFINES="$DEFINES -DSVR4"
 249     ;;
 250 cygwin*)
 251     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 252     ;;
 253 esac
 254
 255 dnl Add flags for gcc and g++
 256 if test "x$GCC" = xyes; then
 257     CFLAGS="$CFLAGS -Wall"
 258
 259     if test "x$USE_GNU99" = xyes; then
 260         CFLAGS="$CFLAGS -std=gnu99"
 261     else
 262         CFLAGS="$CFLAGS -std=c99"
 263     fi
 264
 265     # Enable -Werror=implicit-function-declaration and
 266     # -Werror=missing-prototypes, if available, or otherwise, just
 267     # -Wmissing-prototypes.  This is particularly useful to avoid
 268     # generating a loadable driver module that has undefined symbols.
 269     save_CFLAGS="$CFLAGS"
 270     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 271     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 272     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 273     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 274                    AC_MSG_RESULT([yes]),
 275                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 276                     AC_MSG_RESULT([no])]);
 277
 278     # Enable -fvisibility=hidden if using a gcc that supports it
 279     save_CFLAGS="$CFLAGS"
 280     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 281     VISIBILITY_CFLAGS="-fvisibility=hidden"
 282     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 283     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 284                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 285
 286     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 287     CFLAGS=$save_CFLAGS
 288
 289     # Work around aliasing bugs - developers should comment this out
 290     CFLAGS="$CFLAGS -fno-strict-aliasing"
 291
 292     # We don't want floating-point math functions to set errno or trap
 293     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 294
 295     # gcc's builtin memcmp is slower than glibc's
 296     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 297     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 298
 299     # Flags to help ensure that certain portions of the code -- and only those
 300     # portions -- can be built with MSVC:
 301     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 302     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 303     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 304     #   supports most of C99)
 305     # - the rest has no compiler compiler restrictions
 306     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 307     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 308
 309     # Enable -Werror=vla if compiler supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 312     CFLAGS="$CFLAGS -Werror=vla"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 314                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 315                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 316                     AC_MSG_RESULT([yes])],
 317                     AC_MSG_RESULT([no]));
 318     CFLAGS="$save_CFLAGS"
 319
 320     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 321     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 322 fi
 323 if test "x$GXX" = xyes; then
 324     CXXFLAGS="$CXXFLAGS -Wall"
 325
 326     # Enable -fvisibility=hidden if using a gcc that supports it
 327     save_CXXFLAGS="$CXXFLAGS"
 328     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 329     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 330     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 331     AC_LANG_PUSH([C++])
 332     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 333                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 334     AC_LANG_POP([C++])
 335
 336     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 337     CXXFLAGS=$save_CXXFLAGS
 338
 339     # Work around aliasing bugs - developers should comment this out
 340     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 341
 342     # gcc's builtin memcmp is slower than glibc's
 343     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 344     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 350 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 351
 352 dnl even if the compiler appears to support it, using visibility attributes isn't
 353 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 354 case "$host_os" in
 355 cygwin*)
 356     VISIBILITY_CFLAGS=""
 357     VISIBILITY_CXXFLAGS=""
 358     ;;
 359 esac
 360
 361 AC_SUBST([VISIBILITY_CFLAGS])
 362 AC_SUBST([VISIBILITY_CXXFLAGS])
 363
 364 dnl
 365 dnl Optional flags, check for compiler support
 366 dnl
 367 SSE41_CFLAGS="-msse4.1"
 368 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 369 dnl stack, but on x86-32 such alignment is not guaranteed.
 370 case "$target_cpu" in
 371 i?86)
 372     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 373     ;;
 374 esac
 375 save_CFLAGS="$CFLAGS"
 376 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 377 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 378 #include <smmintrin.h>
 379 int main () {
 380     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 381     c = _mm_max_epu32(a, b);
 382     return 0;
 383 }]])], SSE41_SUPPORTED=1)
 384 CFLAGS="$save_CFLAGS"
 385 if test "x$SSE41_SUPPORTED" = x1; then
 386     DEFINES="$DEFINES -DUSE_SSE41"
 387 fi
 388 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 389 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 390
 391 dnl Can't have static and shared libraries, default to static if user
 392 dnl explicitly requested. If both disabled, set to static since shared
 393 dnl was explicitly requested.
 394 case "x$enable_static$enable_shared" in
 395 xyesyes)
 396     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 397     enable_shared=no
 398     ;;
 399 xnono)
 400     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 401     enable_shared=yes
 402     ;;
 403 esac
 404
 405 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 406
 407 dnl
 408 dnl other compiler options
 409 dnl
 410 AC_ARG_ENABLE([debug],
 411     [AS_HELP_STRING([--enable-debug],
 412         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 413     [enable_debug="$enableval"],
 414     [enable_debug=no]
 415 )
 416 if test "x$enable_debug" = xyes; then
 417     DEFINES="$DEFINES -DDEBUG"
 418     if test "x$GCC" = xyes; then
 419         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 420             CFLAGS="$CFLAGS -g"
 421         fi
 422         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 423             CFLAGS="$CFLAGS -O0"
 424         fi
 425     fi
 426     if test "x$GXX" = xyes; then
 427         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 428             CXXFLAGS="$CXXFLAGS -g"
 429         fi
 430         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 431             CXXFLAGS="$CXXFLAGS -O0"
 432         fi
 433     fi
 434 else
 435    DEFINES="$DEFINES -DNDEBUG"
 436 fi
 437
 438 dnl
 439 dnl Check if linker supports -Bsymbolic
 440 dnl
 441 save_LDFLAGS=$LDFLAGS
 442 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 443 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 444 AC_LINK_IFELSE(
 445     [AC_LANG_SOURCE([int main() { return 0;}])],
 446     [AC_MSG_RESULT([yes])
 447         BSYMBOLIC="-Wl,-Bsymbolic";],
 448     [AC_MSG_RESULT([no])
 449         BSYMBOLIC="";])
 450 LDFLAGS=$save_LDFLAGS
 451
 452 AC_SUBST([BSYMBOLIC])
 453
 454 dnl
 455 dnl Check if linker supports garbage collection
 456 dnl
 457 save_LDFLAGS=$LDFLAGS
 458 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 459 AC_MSG_CHECKING([whether ld supports --gc-sections])
 460 AC_LINK_IFELSE(
 461     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 462     [AC_MSG_RESULT([yes])
 463         GC_SECTIONS="-Wl,--gc-sections";],
 464     [AC_MSG_RESULT([no])
 465         GC_SECTIONS="";])
 466 LDFLAGS=$save_LDFLAGS
 467
 468 AC_SUBST([GC_SECTIONS])
 469
 470 dnl
 471 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 472 dnl so when these flags are passed to ld via libtool the checks will fail
 473 dnl
 474 case "$host_os" in
 475 openbsd* | darwin* )
 476     LD_NO_UNDEFINED="" ;;
 477 *)
 478     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 479 esac
 480
 481 AC_SUBST([LD_NO_UNDEFINED])
 482
 483 dnl
 484 dnl Check if linker supports version scripts
 485 dnl
 486 AC_MSG_CHECKING([if the linker supports version-scripts])
 487 save_LDFLAGS=$LDFLAGS
 488 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 489 cat > conftest.map <<EOF
 490 VERSION_1 {
 491      global:
 492          main;
 493
 494      local:
 495          *;
 496 };
 497 EOF
 498 AC_LINK_IFELSE(
 499     [AC_LANG_SOURCE([int main() { return 0;}])],
 500     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 501     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 502 LDFLAGS=$save_LDFLAGS
 503 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 504
 505 dnl
 506 dnl Check if linker supports dynamic list files
 507 dnl
 508 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 509 save_LDFLAGS=$LDFLAGS
 510 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 511 cat > conftest.dyn <<EOF
 512 {
 513         radeon_drm_winsys_create;
 514 };
 515 EOF
 516 AC_LINK_IFELSE(
 517     [AC_LANG_SOURCE([int main() { return 0;}])],
 518     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 519     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 520 LDFLAGS=$save_LDFLAGS
 521 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 522
 523 dnl
 524 dnl compatibility symlinks
 525 dnl
 526 case "$host_os" in
 527 linux* )
 528     HAVE_COMPAT_SYMLINKS=yes ;;
 529 * )
 530     HAVE_COMPAT_SYMLINKS=no ;;
 531 esac
 532
 533 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 534
 535 dnl
 536 dnl library names
 537 dnl
 538 dnl Unfortunately we need to do a few things that libtool can't help us with,
 539 dnl so we need some knowledge of shared library filenames:
 540 dnl
 541 dnl LIB_EXT is the extension used when creating symlinks for alternate
 542 dnl filenames for a shared library which will be dynamically loaded
 543 dnl
 544 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 545 dnl the file for a shared library we wish to link with
 546 dnl
 547 case "$host_os" in
 548 darwin* )
 549     LIB_EXT='dylib'
 550     IMP_LIB_EXT=$LIB_EXT
 551     ;;
 552 cygwin* )
 553     LIB_EXT='dll'
 554     IMP_LIB_EXT='dll.a'
 555     ;;
 556 aix* )
 557     LIB_EXT='a'
 558     IMP_LIB_EXT=$LIB_EXT
 559     ;;
 560 * )
 561     LIB_EXT='so'
 562     IMP_LIB_EXT=$LIB_EXT
 563     ;;
 564 esac
 565
 566 AC_SUBST([LIB_EXT])
 567
 568 AC_ARG_WITH([gl-lib-name],
 569   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 570     [specify GL library name @<:@default=GL@:>@])],
 571   [GL_LIB=$withval],
 572   [GL_LIB=GL])
 573 AC_ARG_WITH([osmesa-lib-name],
 574   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 575     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 576   [OSMESA_LIB=$withval],
 577   [OSMESA_LIB=OSMesa])
 578 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 579 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 580
 581 dnl
 582 dnl Mangled Mesa support
 583 dnl
 584 AC_ARG_ENABLE([mangling],
 585   [AS_HELP_STRING([--enable-mangling],
 586     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 587   [enable_mangling="${enableval}"],
 588   [enable_mangling=no]
 589 )
 590 if test "x${enable_mangling}" = "xyes" ; then
 591   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 592   GL_LIB="Mangled${GL_LIB}"
 593   OSMESA_LIB="Mangled${OSMESA_LIB}"
 594 fi
 595 AC_SUBST([GL_LIB])
 596 AC_SUBST([OSMESA_LIB])
 597
 598 dnl
 599 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 600 dnl
 601 AC_ARG_ENABLE([texture-float],
 602     [AS_HELP_STRING([--enable-texture-float],
 603         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 604     [enable_texture_float="$enableval"],
 605     [enable_texture_float=no]
 606 )
 607 if test "x$enable_texture_float" = xyes; then
 608     AC_MSG_WARN([Floating-point textures enabled.])
 609     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 610     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 611 fi
 612
 613 dnl
 614 dnl Arch/platform-specific settings
 615 dnl
 616 AC_ARG_ENABLE([asm],
 617     [AS_HELP_STRING([--disable-asm],
 618         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 619     [enable_asm="$enableval"],
 620     [enable_asm=yes]
 621 )
 622 asm_arch=""
 623 AC_MSG_CHECKING([whether to enable assembly])
 624 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 625 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 626 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 627     case "$host_cpu" in
 628     i?86 | x86_64 | amd64)
 629         enable_asm=no
 630         AC_MSG_RESULT([no, cross compiling])
 631         ;;
 632     esac
 633 fi
 634 # check for supported arches
 635 if test "x$enable_asm" = xyes; then
 636     case "$host_cpu" in
 637     i?86)
 638         case "$host_os" in
 639         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 640             asm_arch=x86
 641             ;;
 642         esac
 643         ;;
 644     x86_64|amd64)
 645         case "$host_os" in
 646         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 647             asm_arch=x86_64
 648             ;;
 649         esac
 650         ;;
 651     sparc*)
 652         case "$host_os" in
 653         linux*)
 654             asm_arch=sparc
 655             ;;
 656         esac
 657         ;;
 658     esac
 659
 660     case "$asm_arch" in
 661     x86)
 662         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 663         AC_MSG_RESULT([yes, x86])
 664         ;;
 665     x86_64|amd64)
 666         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 667         AC_MSG_RESULT([yes, x86_64])
 668         ;;
 669     sparc)
 670         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 671         AC_MSG_RESULT([yes, sparc])
 672         ;;
 673     *)
 674         AC_MSG_RESULT([no, platform not supported])
 675         ;;
 676     esac
 677 fi
 678
 679 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 680 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 681 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 682 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 683
 684 dnl Check to see if dlopen is in default libraries (like Solaris, which
 685 dnl has it in libc), or if libdl is needed to get it.
 686 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 687     [AC_CHECK_LIB([dl], [dlopen],
 688        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 689 AC_SUBST([DLOPEN_LIBS])
 690
 691 dnl Check if that library also has dladdr
 692 save_LIBS="$LIBS"
 693 LIBS="$LIBS $DLOPEN_LIBS"
 694 AC_CHECK_FUNCS([dladdr])
 695 LIBS="$save_LIBS"
 696
 697 case "$host_os" in
 698 darwin*)
 699     ;;
 700 *)
 701     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 702                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 703                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 704     AC_SUBST([CLOCK_LIB])
 705     ;;
 706 esac
 707
 708 dnl See if posix_memalign is available
 709 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 710
 711 dnl Check for pthreads
 712 AX_PTHREAD
 713 if test "x$ax_pthread_ok" = xno; then
 714     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 715 fi
 716 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 717 dnl to -pthread, which causes problems if we need -lpthread to appear in
 718 dnl pkgconfig files.
 719 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 720
 721 dnl SELinux awareness.
 722 AC_ARG_ENABLE([selinux],
 723     [AS_HELP_STRING([--enable-selinux],
 724         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 725     [MESA_SELINUX="$enableval"],
 726     [MESA_SELINUX=no])
 727 if test "x$enable_selinux" = "xyes"; then
 728     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 729         [AC_CHECK_HEADER([selinux/selinux.h],[],
 730                          [AC_MSG_ERROR([SELinux headers not found])])
 731          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 732                       [AC_MSG_ERROR([SELinux library not found])])
 733          SELINUX_LIBS="-lselinux"])
 734     DEFINES="$DEFINES -DMESA_SELINUX"
 735 fi
 736 AC_SUBST([SELINUX_CFLAGS])
 737 AC_SUBST([SELINUX_LIBS])
 738
 739 dnl Options for APIs
 740 AC_ARG_ENABLE([opengl],
 741     [AS_HELP_STRING([--disable-opengl],
 742         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 743     [enable_opengl="$enableval"],
 744     [enable_opengl=yes])
 745 AC_ARG_ENABLE([gles1],
 746     [AS_HELP_STRING([--disable-gles1],
 747         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 748     [enable_gles1="$enableval"],
 749     [enable_gles1=yes])
 750 AC_ARG_ENABLE([gles2],
 751     [AS_HELP_STRING([--disable-gles2],
 752         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 753     [enable_gles2="$enableval"],
 754     [enable_gles2=yes])
 755
 756 AC_ARG_ENABLE([dri],
 757     [AS_HELP_STRING([--enable-dri],
 758         [enable DRI modules @<:@default=enabled@:>@])],
 759     [enable_dri="$enableval"],
 760     [enable_dri=yes])
 761
 762 case "$host_os" in
 763 linux*)
 764     dri3_default=yes
 765     ;;
 766 *)
 767     dri3_default=no
 768     ;;
 769 esac
 770
 771 if test "x$enable_dri" = xno; then
 772     dri3_default=no
 773 fi
 774
 775 AC_ARG_ENABLE([dri3],
 776     [AS_HELP_STRING([--enable-dri3],
 777         [enable DRI3 @<:@default=auto@:>@])],
 778     [enable_dri3="$enableval"],
 779     [enable_dri3="$dri3_default"])
 780 AC_ARG_ENABLE([glx],
 781     [AS_HELP_STRING([--enable-glx],
 782         [enable GLX library @<:@default=enabled@:>@])],
 783     [enable_glx="$enableval"],
 784     [enable_glx=yes])
 785 AC_ARG_ENABLE([osmesa],
 786     [AS_HELP_STRING([--enable-osmesa],
 787         [enable OSMesa library @<:@default=disabled@:>@])],
 788     [enable_osmesa="$enableval"],
 789     [enable_osmesa=no])
 790 AC_ARG_ENABLE([gallium-osmesa],
 791     [AS_HELP_STRING([--enable-gallium-osmesa],
 792         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 793     [enable_gallium_osmesa="$enableval"],
 794     [enable_gallium_osmesa=no])
 795 AC_ARG_ENABLE([egl],
 796     [AS_HELP_STRING([--disable-egl],
 797         [disable EGL library @<:@default=enabled@:>@])],
 798     [enable_egl="$enableval"],
 799     [enable_egl=yes])
 800
 801 AC_ARG_ENABLE([xa],
 802     [AS_HELP_STRING([--enable-xa],
 803         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 804     [enable_xa="$enableval"],
 805     [enable_xa=no])
 806 AC_ARG_ENABLE([gbm],
 807    [AS_HELP_STRING([--enable-gbm],
 808          [enable gbm library @<:@default=auto@:>@])],
 809    [enable_gbm="$enableval"],
 810    [enable_gbm=auto])
 811 AC_ARG_ENABLE([nine],
 812     [AS_HELP_STRING([--enable-nine],
 813         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 814     [enable_nine="$enableval"],
 815     [enable_nine=no])
 816
 817 AC_ARG_ENABLE([xvmc],
 818    [AS_HELP_STRING([--enable-xvmc],
 819          [enable xvmc library @<:@default=auto@:>@])],
 820    [enable_xvmc="$enableval"],
 821    [enable_xvmc=auto])
 822 AC_ARG_ENABLE([vdpau],
 823    [AS_HELP_STRING([--enable-vdpau],
 824          [enable vdpau library @<:@default=auto@:>@])],
 825    [enable_vdpau="$enableval"],
 826    [enable_vdpau=auto])
 827 AC_ARG_ENABLE([omx],
 828    [AS_HELP_STRING([--enable-omx],
 829          [enable OpenMAX library @<:@default=disabled@:>@])],
 830    [enable_omx="$enableval"],
 831    [enable_omx=no])
 832 AC_ARG_ENABLE([va],
 833    [AS_HELP_STRING([--enable-va],
 834          [enable va library @<:@default=auto@:>@])],
 835    [enable_va="$enableval"],
 836    [enable_va=auto])
 837 AC_ARG_ENABLE([opencl],
 838    [AS_HELP_STRING([--enable-opencl],
 839          [enable OpenCL library @<:@default=disabled@:>@])],
 840    [enable_opencl="$enableval"],
 841    [enable_opencl=no])
 842 AC_ARG_ENABLE([opencl_icd],
 843    [AS_HELP_STRING([--enable-opencl-icd],
 844           [Build an OpenCL ICD library to be loaded by an ICD implementation
 845            @<:@default=disabled@:>@])],
 846     [enable_opencl_icd="$enableval"],
 847     [enable_opencl_icd=no])
 848 AC_ARG_ENABLE([xlib-glx],
 849     [AS_HELP_STRING([--enable-xlib-glx],
 850         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 851     [enable_xlib_glx="$enableval"],
 852     [enable_xlib_glx=no])
 853
 854 AC_ARG_ENABLE([r600-llvm-compiler],
 855     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 856         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 857     [enable_r600_llvm="$enableval"],
 858     [enable_r600_llvm=no])
 859
 860 AC_ARG_ENABLE([gallium-tests],
 861     [AS_HELP_STRING([--enable-gallium-tests],
 862         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 863     [enable_gallium_tests="$enableval"],
 864     [enable_gallium_tests=no])
 865
 866 # Option for Gallium drivers
 867
 868 # Keep this in sync with the --with-gallium-drivers help string default value
 869 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 870
 871 AC_ARG_WITH([gallium-drivers],
 872     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 873         [comma delimited Gallium drivers list, e.g.
 874         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 875         @<:@default=r300,r600,svga,swrast@:>@])],
 876     [with_gallium_drivers="$withval"],
 877     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 878
 879 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 880 # here so that the script doesn't choke on an unknown driver name later.
 881 case "$with_gallium_drivers" in
 882     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 883     no) with_gallium_drivers='' ;;
 884 esac
 885
 886 if test "x$enable_opengl" = xno -a \
 887         "x$enable_gles1" = xno -a \
 888         "x$enable_gles2" = xno -a \
 889         "x$enable_nine" = xno -a \
 890         "x$enable_xa" = xno -a \
 891         "x$enable_xvmc" = xno -a \
 892         "x$enable_vdpau" = xno -a \
 893         "x$enable_omx" = xno -a \
 894         "x$enable_va" = xno -a \
 895         "x$enable_opencl" = xno; then
 896     AC_MSG_ERROR([at least one API should be enabled])
 897 fi
 898
 899 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 900 if test "x$enable_opengl" = xno -a \
 901         "x$enable_gles1" = xyes; then
 902     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 903 fi
 904
 905 if test "x$enable_opengl" = xno -a \
 906         "x$enable_gles2" = xyes; then
 907     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 908 fi
 909
 910 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 911 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 912 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 913 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 914                                         "x$enable_gles1" = xyes -o \
 915                                         "x$enable_gles2" = xyes)
 916
 917 if test "x$enable_glx" = xno; then
 918     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 919     enable_xlib_glx=no
 920 fi
 921
 922 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 923     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 924 fi
 925
 926 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 927     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 928 fi
 929
 930 # Disable GLX if OpenGL is not enabled
 931 if test "x$enable_glx$enable_opengl" = xyesno; then
 932     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 933     enable_glx=no
 934 fi
 935
 936 # Disable GLX if DRI and Xlib-GLX are not enabled
 937 if test "x$enable_glx" = xyes -a \
 938         "x$enable_dri" = xno -a \
 939         "x$enable_xlib_glx" = xno; then
 940     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 941     enable_glx=no
 942 fi
 943
 944 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 945                                   "x$enable_dri" = xyes)
 946
 947 # Check for libdrm
 948 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 949                   [have_libdrm=yes], [have_libdrm=no])
 950 if test "x$have_libdrm" = xyes; then
 951         DEFINES="$DEFINES -DHAVE_LIBDRM"
 952 fi
 953
 954 # Select which platform-dependent DRI code gets built
 955 case "$host_os" in
 956 darwin*)
 957     dri_platform='apple' ;;
 958 gnu*|cygwin*)
 959     dri_platform='none' ;;
 960 *)
 961     dri_platform='drm' ;;
 962 esac
 963
 964 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
 965     have_drisw_kms='yes'
 966 fi
 967
 968 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 969 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 970 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
 971 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 972 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 973 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 974
 975 AC_ARG_ENABLE([shared-glapi],
 976     [AS_HELP_STRING([--enable-shared-glapi],
 977         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 978     [enable_shared_glapi="$enableval"],
 979     [enable_shared_glapi=yes])
 980
 981 case "x$enable_opengl$enable_gles1$enable_gles2" in
 982 x*yes*yes*)
 983     if test "x$enable_shared_glapi" = xno; then
 984         AC_MSG_ERROR([shared GLAPI required when building two or more of
 985                       the following APIs - opengl, gles1 gles2])
 986     fi
 987     ;;
 988 esac
 989
 990 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 991
 992 # Build the pipe-drivers as separate libraries/modules.
 993 # Do not touch this unless you know what you are doing.
 994 # XXX: Expose via configure option ?
 995 enable_shared_pipe_drivers=no
 996
 997 dnl
 998 dnl Driver specific build directories
 999 dnl
1000
1001 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
1002     NEED_WINSYS_XLIB="yes"
1003 fi
1004
1005 if test "x$enable_gallium_osmesa" = xyes; then
1006     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1007         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1008     fi
1009     if test "x$enable_osmesa" = xyes; then
1010         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1011     fi
1012 fi
1013
1014 AC_SUBST([MESA_LLVM])
1015
1016 # SHA1 hashing
1017 AC_ARG_WITH([sha1],
1018         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1019         [choose SHA1 implementation])])
1020 case "x$with_sha1" in
1021 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1022   ;;
1023 *)
1024         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1025 esac
1026
1027 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1028 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1029         with_sha1=libc
1030 fi
1031 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1032         AC_MSG_ERROR([sha1 in libc requested but not found])
1033 fi
1034 if test "x$with_sha1" = xlibc; then
1035         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1036                 [Use libc SHA1 functions])
1037         SHA1_LIBS=""
1038 fi
1039 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1040 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1041         with_sha1=CommonCrypto
1042 fi
1043 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1044         AC_MSG_ERROR([CommonCrypto requested but not found])
1045 fi
1046 if test "x$with_sha1" = xCommonCrypto; then
1047         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1048                 [Use CommonCrypto SHA1 functions])
1049         SHA1_LIBS=""
1050 fi
1051 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1052 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1053 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1054         with_sha1=CryptoAPI
1055 fi
1056 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1057         AC_MSG_ERROR([CryptoAPI requested but not found])
1058 fi
1059 if test "x$with_sha1" = xCryptoAPI; then
1060         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1061                 [Use CryptoAPI SHA1 functions])
1062         SHA1_LIBS=""
1063 fi
1064 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1065 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1066         with_sha1=libmd
1067 fi
1068 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1069         AC_MSG_ERROR([libmd requested but not found])
1070 fi
1071 if test "x$with_sha1" = xlibmd; then
1072         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1073                   [Use libmd SHA1 functions])
1074         SHA1_LIBS=-lmd
1075 fi
1076 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1077 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1078    with_sha1=libsha1
1079 fi
1080 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1081         AC_MSG_ERROR([libsha1 requested but not found])
1082 fi
1083 if test "x$with_sha1" = xlibsha1; then
1084         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1085                   [Use libsha1 for SHA1])
1086         SHA1_LIBS=-lsha1
1087 fi
1088 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1089 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1090         with_sha1=libnettle
1091 fi
1092 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1093         AC_MSG_ERROR([libnettle requested but not found])
1094 fi
1095 if test "x$with_sha1" = xlibnettle; then
1096         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1097                   [Use libnettle SHA1 functions])
1098         SHA1_LIBS=-lnettle
1099 fi
1100 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1101 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1102         with_sha1=libgcrypt
1103 fi
1104 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1105         AC_MSG_ERROR([libgcrypt requested but not found])
1106 fi
1107 if test "x$with_sha1" = xlibgcrypt; then
1108         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1109                   [Use libgcrypt SHA1 functions])
1110         SHA1_LIBS=-lgcrypt
1111 fi
1112 # We don't need all of the OpenSSL libraries, just libcrypto
1113 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1114 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1115                   [HAVE_OPENSSL_PKC=no])
1116 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1117         if test "x$with_sha1" = x; then
1118                 with_sha1=libcrypto
1119         fi
1120 else
1121         if test "x$with_sha1" = xlibcrypto; then
1122                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1123         fi
1124 fi
1125 if test "x$with_sha1" = xlibcrypto; then
1126         if test "x$HAVE_LIBCRYPTO" = xyes; then
1127                 SHA1_LIBS=-lcrypto
1128         else
1129                 SHA1_LIBS="$OPENSSL_LIBS"
1130                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1131         fi
1132 fi
1133 AC_MSG_CHECKING([for SHA1 implementation])
1134 AC_MSG_RESULT([$with_sha1])
1135 AC_SUBST(SHA1_LIBS)
1136 AC_SUBST(SHA1_CFLAGS)
1137
1138 # Enable a define for SHA1
1139 if test "x$with_sha1" != "x"; then
1140         DEFINES="$DEFINES -DHAVE_SHA1"
1141 fi
1142
1143 # Allow user to configure out the shader-cache feature
1144 AC_ARG_ENABLE([shader-cache],
1145     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1146     [enable_shader_cache="$enableval"],
1147     [if test "x$with_sha1" != "x"; then
1148         enable_shader_cache=yes
1149      else
1150         enable_shader_cache=no
1151      fi])
1152 if test "x$with_sha1" = "x"; then
1153     if test "x$enable_shader_cache" = "xyes"; then
1154         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1155     fi
1156 fi
1157 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1158
1159 case "$host_os" in
1160 linux*)
1161     need_pci_id=yes ;;
1162 *)
1163     need_pci_id=no ;;
1164 esac
1165
1166 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1167                   have_libudev=yes, have_libudev=no)
1168
1169 AC_ARG_ENABLE([sysfs],
1170     [AS_HELP_STRING([--enable-sysfs],
1171         [enable /sys PCI identification @<:@default=disabled@:>@])],
1172     [have_sysfs="$enableval"],
1173     [have_sysfs=no]
1174 )
1175
1176 if test "x$enable_dri" = xyes; then
1177     if test "$enable_static" = yes; then
1178         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1179     fi
1180
1181     # not a hard requirement as swrast does not depend on it
1182     if test "x$have_libdrm" = xyes; then
1183         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1184     fi
1185 fi
1186
1187 AC_ARG_ENABLE([driglx-direct],
1188     [AS_HELP_STRING([--disable-driglx-direct],
1189         [disable direct rendering in GLX and EGL for DRI \
1190             @<:@default=auto@:>@])],
1191     [driglx_direct="$enableval"],
1192     [driglx_direct="yes"])
1193
1194 dnl
1195 dnl libGL configuration per driver
1196 dnl
1197 case "x$enable_glx$enable_xlib_glx" in
1198 xyesyes)
1199     # Xlib-based GLX
1200     dri_modules="x11 xext xcb"
1201     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1202     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1203     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1204     GL_LIB_DEPS="$XLIBGL_LIBS"
1205     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1206     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1207     ;;
1208 xyesno)
1209     # DRI-based GLX
1210     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1211
1212     # find the DRI deps for libGL
1213     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1214
1215     if test x"$driglx_direct" = xyes; then
1216         if test x"$dri_platform" = xdrm ; then
1217             DEFINES="$DEFINES -DGLX_USE_DRM"
1218             if test "x$have_libdrm" != xyes; then
1219                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1220             fi
1221
1222             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1223             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1224             if test x"$enable_dri3" = xyes; then
1225                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1226                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1227             fi
1228
1229             if test x"$enable_dri" = xyes; then
1230                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1231             fi
1232
1233             if test x"$enable_dri3" = xyes; then
1234                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1235                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1236                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1237             fi
1238         fi
1239         if test x"$dri_platform" = xapple ; then
1240             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1241         fi
1242     fi
1243
1244     # add xf86vidmode if available
1245     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1246     if test "$HAVE_XF86VIDMODE" = yes ; then
1247         dri_modules="$dri_modules xxf86vm"
1248     fi
1249
1250     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1251     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1252     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1253     GL_LIB_DEPS="$DRIGL_LIBS"
1254
1255     # need DRM libs, $PTHREAD_LIBS, etc.
1256     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1257     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1258     ;;
1259 esac
1260
1261 have_pci_id=no
1262 if test "$have_libudev" = yes; then
1263     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1264     have_pci_id=yes
1265 fi
1266
1267 if test "$have_sysfs" = yes; then
1268     DEFINES="$DEFINES -DHAVE_SYSFS"
1269     have_pci_id=yes
1270 fi
1271
1272 # This is outside the case (above) so that it is invoked even for non-GLX
1273 # builds.
1274 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1275
1276 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1277 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1278 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1279 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1280
1281 AC_SUBST([X11_INCLUDES])
1282 AC_SUBST([GL_LIB_DEPS])
1283 AC_SUBST([GL_PC_REQ_PRIV])
1284 AC_SUBST([GL_PC_LIB_PRIV])
1285 AC_SUBST([GL_PC_CFLAGS])
1286 AC_SUBST([DRI_PC_REQ_PRIV])
1287 AC_SUBST([GLESv1_CM_LIB_DEPS])
1288 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1289 AC_SUBST([GLESv2_LIB_DEPS])
1290 AC_SUBST([GLESv2_PC_LIB_PRIV])
1291
1292 AC_SUBST([HAVE_XF86VIDMODE])
1293
1294 dnl
1295 dnl More GLX setup
1296 dnl
1297 case "x$enable_glx$enable_xlib_glx" in
1298 xyesyes)
1299     DEFINES="$DEFINES -DUSE_XSHM"
1300     ;;
1301 xyesno)
1302     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1303     if test "x$driglx_direct" = xyes; then
1304         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1305     fi
1306     ;;
1307 esac
1308
1309 dnl
1310 dnl TLS detection
1311 dnl
1312
1313 AC_ARG_ENABLE([glx-tls],
1314     [AS_HELP_STRING([--enable-glx-tls],
1315         [enable TLS support in GLX @<:@default=disabled@:>@])],
1316     [GLX_USE_TLS="$enableval"],
1317     [GLX_USE_TLS=no])
1318 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1319
1320 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1321       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1322
1323 dnl Read-only text section on x86 hardened platforms
1324 AC_ARG_ENABLE([glx-read-only-text],
1325     [AS_HELP_STRING([--enable-glx-read-only-text],
1326         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1327     [enable_glx_read_only_text="$enableval"],
1328     [enable_glx_read_only_text=no])
1329 if test "x$enable_glx_read_only_text" = xyes; then
1330     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1331 fi
1332
1333 dnl
1334 dnl More DRI setup
1335 dnl
1336 dnl Directory for DRI drivers
1337 AC_ARG_WITH([dri-driverdir],
1338     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1339         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1340     [DRI_DRIVER_INSTALL_DIR="$withval"],
1341     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1342 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1343 dnl Extra search path for DRI drivers
1344 AC_ARG_WITH([dri-searchpath],
1345     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1346         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1347     [DRI_DRIVER_SEARCH_DIR="$withval"],
1348     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1349 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1350 dnl Which drivers to build - default is chosen by platform
1351 AC_ARG_WITH([dri-drivers],
1352     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1353         [comma delimited classic DRI drivers list, e.g.
1354         "swrast,i965,radeon" @<:@default=auto@:>@])],
1355     [with_dri_drivers="$withval"],
1356     [with_dri_drivers=auto])
1357
1358 if test "x$with_dri_drivers" = xauto; then
1359     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1360         with_dri_drivers="yes"
1361     else
1362         with_dri_drivers="no"
1363     fi
1364 fi
1365 if test "x$with_dri_drivers" = xno; then
1366     with_dri_drivers=''
1367 fi
1368
1369 dnl If $with_dri_drivers is yes, drivers will be added through
1370 dnl platform checks. Set DEFINES and LIB_DEPS
1371 if test "x$enable_dri" = xyes; then
1372     # Platform specific settings and drivers to build
1373     case "$host_os" in
1374     linux*)
1375         DEFINES="$DEFINES -DHAVE_ALIAS"
1376         if test "x$enable_dri3" = xyes; then
1377             DEFINES="$DEFINES -DHAVE_DRI3"
1378         fi
1379
1380         if test "x$have_pci_id" != xyes; then
1381             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1382         fi
1383
1384         case "$host_cpu" in
1385         powerpc* | sparc*)
1386             # Build only the drivers for cards that exist on PowerPC/sparc
1387             if test "x$with_dri_drivers" = "xyes"; then
1388                 with_dri_drivers="r200 radeon swrast"
1389             fi
1390             ;;
1391         esac
1392         ;;
1393     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1394         DEFINES="$DEFINES -DHAVE_ALIAS"
1395         ;;
1396     gnu*)
1397         DEFINES="$DEFINES -DHAVE_ALIAS"
1398         ;;
1399     cygwin*)
1400         if test "x$with_dri_drivers" = "xyes"; then
1401             with_dri_drivers="swrast"
1402         fi
1403         ;;
1404     darwin*)
1405         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1406         if test "x$with_dri_drivers" = "xyes"; then
1407             with_dri_drivers="swrast"
1408         fi
1409         ;;
1410     esac
1411
1412     # default drivers
1413     if test "x$with_dri_drivers" = "xyes"; then
1414         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1415     fi
1416
1417     # Check for expat
1418     PKG_CHECK_MODULES([EXPAT], [expat], [],
1419         # expat version 2.0 and earlier do not provide expat.pc
1420         [AC_CHECK_HEADER([expat.h],[],
1421                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1422          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1423                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1424          EXPAT_LIBS="-lexpat"])
1425
1426     # put all the necessary libs together
1427     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1428 fi
1429
1430 AC_SUBST([DRI_LIB_DEPS])
1431
1432 DRI_DIRS=''
1433 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1434 if test -n "$with_dri_drivers"; then
1435     if test "x$enable_opengl" != xyes; then
1436         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1437     fi
1438
1439     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1440     for driver in $dri_drivers; do
1441         DRI_DIRS="$DRI_DIRS $driver"
1442         case "x$driver" in
1443         xi915)
1444             HAVE_I915_DRI=yes;
1445             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1446             ;;
1447         xi965)
1448             HAVE_I965_DRI=yes;
1449             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1450             ;;
1451         xnouveau)
1452             HAVE_NOUVEAU_DRI=yes;
1453             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1454             ;;
1455         xradeon)
1456             HAVE_RADEON_DRI=yes;
1457             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1458             ;;
1459         xr200)
1460             HAVE_R200_DRI=yes;
1461             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1462             ;;
1463         xswrast)
1464             HAVE_SWRAST_DRI=yes;
1465             ;;
1466         *)
1467             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1468             ;;
1469         esac
1470     done
1471     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1472 fi
1473
1474 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1475 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1476                                   "x$enable_osmesa" = xyes -o \
1477                                   -n "$DRI_DIRS")
1478
1479 dnl
1480 dnl OSMesa configuration
1481 dnl
1482
1483 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1484 AC_ARG_WITH([osmesa-bits],
1485     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1486         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1487     [osmesa_bits="$withval"],
1488     [osmesa_bits=8])
1489 if test "x$osmesa_bits" != x8; then
1490     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1491         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1492         osmesa_bits=8
1493     fi
1494 fi
1495 case "x$osmesa_bits" in
1496 x8)
1497     OSMESA_LIB="${OSMESA_LIB}"
1498     ;;
1499 x16|x32)
1500     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1501     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1502     ;;
1503 *)
1504     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1505     ;;
1506 esac
1507
1508 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1509     # only link libraries with osmesa if shared
1510     if test "$enable_static" = no; then
1511         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1512     else
1513         OSMESA_LIB_DEPS=""
1514     fi
1515     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1516 fi
1517
1518 AC_SUBST([OSMESA_LIB_DEPS])
1519 AC_SUBST([OSMESA_PC_REQ])
1520 AC_SUBST([OSMESA_PC_LIB_PRIV])
1521
1522 dnl
1523 dnl gbm configuration
1524 dnl
1525 if test "x$enable_gbm" = xauto; then
1526     case "$with_egl_platforms" in
1527         *drm*)
1528             enable_gbm=yes ;;
1529          *)
1530             enable_gbm=no ;;
1531     esac
1532 fi
1533 if test "x$enable_gbm" = xyes; then
1534     if test "x$need_pci_id$have_pci_id" = xyesno; then
1535         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1536     fi
1537
1538     if test "x$enable_dri" = xyes; then
1539         if test "x$enable_shared_glapi" = xno; then
1540             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1541         fi
1542     else
1543         # Strictly speaking libgbm does not require --enable-dri, although
1544         # both of its backends do. Thus one can build libgbm without any
1545         # backends if --disable-dri is set.
1546         # To avoid unnecessary complexity of checking if at least one backend
1547         # is available when building, just mandate --enable-dri.
1548         AC_MSG_ERROR([gbm requires --enable-dri])
1549     fi
1550 fi
1551 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1552 if test "x$need_pci_id$have_libudev" = xyesyes; then
1553     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1554 else
1555     GBM_PC_REQ_PRIV=""
1556 fi
1557 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1558 AC_SUBST([GBM_PC_REQ_PRIV])
1559 AC_SUBST([GBM_PC_LIB_PRIV])
1560
1561 dnl
1562 dnl EGL configuration
1563 dnl
1564 EGL_CLIENT_APIS=""
1565
1566 if test "x$enable_egl" = xyes; then
1567     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1568
1569     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1570
1571     if test "$enable_static" != yes; then
1572         if test "x$enable_dri" = xyes; then
1573             HAVE_EGL_DRIVER_DRI2=1
1574             if test "x$enable_shared_glapi" = xno; then
1575                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1576             fi
1577             if test "x$enable_dri3" = xyes; then
1578                 HAVE_EGL_DRIVER_DRI3=1
1579                 if test "x$enable_shared_glapi" = xno; then
1580                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1581                 fi
1582             fi
1583         else
1584             # Avoid building an "empty" libEGL. Drop/update this
1585             # when other backends (haiku?) come along.
1586             AC_MSG_ERROR([egl requires --enable-dri])
1587         fi
1588
1589     fi
1590 fi
1591 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1592 AC_SUBST([EGL_LIB_DEPS])
1593
1594 gallium_st="mesa"
1595
1596 dnl
1597 dnl XA configuration
1598 dnl
1599 if test "x$enable_xa" = xyes; then
1600     if test "x$with_gallium_drivers" = xswrast; then
1601        AC_MSG_ERROR([
1602           Building xa requires at least one non swrast gallium driver.
1603           If you are looking to use libxatracker.so with the VMware driver,
1604           make sure to include svga in the gallium drivers list, apart from
1605           enabling XA.
1606           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1607     fi
1608     gallium_st="$gallium_st xa"
1609 fi
1610 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1611
1612 dnl
1613 dnl Gallium G3DVL configuration
1614 dnl
1615 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1616     if test "x$enable_xvmc" = xauto; then
1617         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1618     fi
1619
1620     if test "x$enable_vdpau" = xauto; then
1621         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1622     fi
1623
1624     if test "x$enable_omx" = xauto; then
1625         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1626     fi
1627
1628     if test "x$enable_va" = xauto; then
1629         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1630     fi
1631 fi
1632
1633 if test "x$enable_dri" = xyes -o \
1634         "x$enable_xvmc" = xyes -o \
1635         "x$enable_vdpau" = xyes -o \
1636         "x$enable_omx" = xyes -o \
1637         "x$enable_va" = xyes; then
1638     need_gallium_vl=yes
1639 fi
1640 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1641
1642 if test "x$enable_xvmc" = xyes -o \
1643         "x$enable_vdpau" = xyes -o \
1644         "x$enable_omx" = xyes -o \
1645         "x$enable_va" = xyes; then
1646     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1647     need_gallium_vl_winsys=yes
1648 fi
1649 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1650
1651 if test "x$enable_xvmc" = xyes; then
1652     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1653     gallium_st="$gallium_st xvmc"
1654 fi
1655 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1656
1657 if test "x$enable_vdpau" = xyes; then
1658     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1659     gallium_st="$gallium_st vdpau"
1660 fi
1661 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1662
1663 if test "x$enable_omx" = xyes; then
1664     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1665     gallium_st="$gallium_st omx"
1666 fi
1667 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1668
1669 if test "x$enable_va" = xyes; then
1670     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1671     gallium_st="$gallium_st va"
1672 fi
1673 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1674
1675 dnl
1676 dnl Nine Direct3D9 configuration
1677 dnl
1678 if test "x$enable_nine" = xyes; then
1679     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1680         AC_MSG_ERROR([nine requires the gallium swrast driver])
1681     fi
1682     if test "x$with_gallium_drivers" = xswrast; then
1683         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1684     fi
1685     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1686         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1687     fi
1688
1689     if test "x$enable_dri3" = xno; then
1690         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1691     fi
1692
1693     gallium_st="$gallium_st nine"
1694 fi
1695 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1696
1697 dnl
1698 dnl OpenCL configuration
1699 dnl
1700
1701 AC_ARG_WITH([clang-libdir],
1702    [AS_HELP_STRING([--with-clang-libdir],
1703          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1704    [CLANG_LIBDIR="$withval"],
1705    [CLANG_LIBDIR=''])
1706
1707 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1708 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1709
1710 if test "x$enable_opencl" = xyes; then
1711     if test -z "$with_gallium_drivers"; then
1712         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1713     fi
1714
1715     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1716         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1717     fi
1718
1719     if test "x$have_libclc" = xno; then
1720         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1721                     Make sure the directory containing libclc.pc is specified in your
1722                     PKG_CONFIG_PATH environment variable.
1723                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1724     else
1725         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1726         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1727         AC_SUBST([LIBCLC_INCLUDEDIR])
1728         AC_SUBST([LIBCLC_LIBEXECDIR])
1729     fi
1730
1731     gallium_st="$gallium_st clover"
1732
1733     if test "x$enable_opencl_icd" = xyes; then
1734         OPENCL_LIBNAME="MesaOpenCL"
1735     else
1736         OPENCL_LIBNAME="OpenCL"
1737     fi
1738
1739     if test "x$have_libelf" != xyes; then
1740        AC_MSG_ERROR([Clover requires libelf])
1741     fi
1742 fi
1743 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1744 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1745 AC_SUBST([OPENCL_LIBNAME])
1746
1747 dnl
1748 dnl Gallium configuration
1749 dnl
1750 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1751
1752 AC_SUBST([LLVM_BINDIR])
1753 AC_SUBST([LLVM_CFLAGS])
1754 AC_SUBST([LLVM_CPPFLAGS])
1755 AC_SUBST([LLVM_CXXFLAGS])
1756 AC_SUBST([LLVM_LIBDIR])
1757 AC_SUBST([LLVM_LIBS])
1758 AC_SUBST([LLVM_LDFLAGS])
1759 AC_SUBST([LLVM_INCLUDEDIR])
1760 AC_SUBST([LLVM_VERSION])
1761 AC_SUBST([CLANG_RESOURCE_DIR])
1762
1763 case "x$enable_opengl$enable_gles1$enable_gles2" in
1764 x*yes*)
1765     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1766     ;;
1767 esac
1768
1769 AC_SUBST([VG_LIB_DEPS])
1770 AC_SUBST([EGL_CLIENT_APIS])
1771
1772 dnl
1773 dnl EGL Platforms configuration
1774 dnl
1775 AC_ARG_WITH([egl-platforms],
1776     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1777         [comma delimited native platforms libEGL supports, e.g.
1778         "x11,drm" @<:@default=auto@:>@])],
1779     [with_egl_platforms="$withval"],
1780     [if test "x$enable_egl" = xyes; then
1781         with_egl_platforms="x11"
1782     else
1783         with_egl_platforms=""
1784     fi])
1785
1786 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1787     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1788 fi
1789
1790 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1791         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1792         WAYLAND_SCANNER='')
1793 if test "x$WAYLAND_SCANNER" = x; then
1794     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1795 fi
1796
1797 # Do per-EGL platform setups and checks
1798 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1799 for plat in $egl_platforms; do
1800         case "$plat" in
1801         wayland)
1802                 test "x$have_libdrm" != xyes &&
1803                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1804
1805                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1806
1807                 if test "x$WAYLAND_SCANNER" = x; then
1808                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1809                 fi
1810                 ;;
1811
1812         x11)
1813                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1814                 ;;
1815
1816         drm)
1817                 test "x$enable_gbm" = "xno" &&
1818                         AC_MSG_ERROR([EGL platform drm needs gbm])
1819                 test "x$have_libdrm" != xyes &&
1820                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1821                 ;;
1822
1823         surfaceless)
1824                 test "x$have_libdrm" != xyes &&
1825                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1826                 ;;
1827
1828         *)
1829                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1830                 ;;
1831         esac
1832
1833         case "$plat$need_pci_id$have_pci_id" in
1834                 waylandyesno|drmyesno)
1835                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1836         esac
1837 done
1838
1839 # libEGL wants to default to the first platform specified in
1840 # ./configure.  parse that here.
1841 if test "x$egl_platforms" != "x"; then
1842     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1843     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1844 else
1845     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1846 fi
1847
1848 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1849 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1850 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1851 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1852 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1853
1854 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1855
1856 AC_SUBST([EGL_NATIVE_PLATFORM])
1857 AC_SUBST([EGL_CFLAGS])
1858
1859 # If we don't have the X11 platform, set this define so we don't try to include
1860 # the X11 headers.
1861 if ! echo "$egl_platforms" | grep -q 'x11'; then
1862     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1863     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1864 fi
1865
1866 dnl
1867 dnl Gallium LLVM
1868 dnl
1869 AC_ARG_ENABLE([gallium-llvm],
1870     [AS_HELP_STRING([--enable-gallium-llvm],
1871         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1872     [enable_gallium_llvm="$enableval"],
1873     [enable_gallium_llvm=auto])
1874
1875 AC_ARG_ENABLE([llvm-shared-libs],
1876     [AS_HELP_STRING([--enable-llvm-shared-libs],
1877         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1878     [enable_llvm_shared_libs="$enableval"],
1879     [enable_llvm_shared_libs=yes])
1880
1881 AC_ARG_WITH([llvm-prefix],
1882     [AS_HELP_STRING([--with-llvm-prefix],
1883         [Prefix for LLVM installations in non-standard locations])],
1884     [llvm_prefix="$withval"],
1885     [llvm_prefix=''])
1886
1887
1888 # Call this inside ` ` to get the return value.
1889 # $1 is the llvm-config command with arguments.
1890 strip_unwanted_llvm_flags() {
1891     # Use \> (marks the end of the word)
1892     echo `$1` | sed \
1893         -e 's/-DNDEBUG\>//g' \
1894         -e 's/-D_GNU_SOURCE\>//g' \
1895         -e 's/-pedantic\>//g' \
1896         -e 's/-Wcovered-switch-default\>//g' \
1897         -e 's/-O.\>//g' \
1898         -e 's/-g\>//g' \
1899         -e 's/-Wall\>//g' \
1900         -e 's/-Wcast-qual\>//g' \
1901         -e 's/-Woverloaded-virtual\>//g' \
1902         -e 's/-fcolor-diagnostics\>//g' \
1903         -e 's/-fdata-sections\>//g' \
1904         -e 's/-ffunction-sections\>//g' \
1905         -e 's/-fno-exceptions\>//g' \
1906         -e 's/-fomit-frame-pointer\>//g' \
1907         -e 's/-fvisibility-inlines-hidden\>//g' \
1908         -e 's/-fPIC\>//g' \
1909         -e 's/-fstack-protector-strong\>//g'
1910 }
1911
1912 llvm_check_version_for() {
1913     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1914         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1915     fi
1916 }
1917
1918
1919
1920 if test -z "$with_gallium_drivers"; then
1921     enable_gallium_llvm=no
1922 fi
1923 if test "x$enable_gallium_llvm" = xauto; then
1924     case "$host_cpu" in
1925     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1926     esac
1927 fi
1928 if test "x$enable_gallium_llvm" = xyes; then
1929     if test -n "$llvm_prefix"; then
1930         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1931     else
1932         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1933     fi
1934
1935     if test "x$LLVM_CONFIG" != xno; then
1936         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1937         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1938         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1939         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1940         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1941         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1942         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1943         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1944
1945         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1946             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1947         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1948             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1949
1950         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1951         if test -z "$LLVM_VERSION_PATCH"; then
1952             LLVM_VERSION_PATCH=0
1953         fi
1954
1955         if test -n "${LLVM_VERSION_MAJOR}"; then
1956             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1957         else
1958             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1959         fi
1960
1961         LLVM_REQUIRED_VERSION_MAJOR="3"
1962         LLVM_REQUIRED_VERSION_MINOR="3"
1963         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1964             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1965         fi
1966
1967         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1968
1969         if test "x$enable_opencl" = xyes; then
1970             llvm_check_version_for "3" "5" "0" "opencl"
1971
1972             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1973             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1974         fi
1975         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1976         MESA_LLVM=1
1977
1978         dnl Check for Clang internal headers
1979         if test "x$enable_opencl" = xyes; then
1980             if test -z "$CLANG_LIBDIR"; then
1981                 CLANG_LIBDIR=${LLVM_LIBDIR}
1982             fi
1983             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1984             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1985                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1986         fi
1987     else
1988         MESA_LLVM=0
1989         LLVM_VERSION_INT=0
1990     fi
1991 else
1992     MESA_LLVM=0
1993     LLVM_VERSION_INT=0
1994
1995     if test "x$enable_opencl" = xyes; then
1996         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1997     fi
1998 fi
1999
2000 dnl Directory for XVMC libs
2001 AC_ARG_WITH([xvmc-libdir],
2002     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2003         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2004     [XVMC_LIB_INSTALL_DIR="$withval"],
2005     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2006 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2007
2008 dnl
2009 dnl Gallium Tests
2010 dnl
2011 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2012
2013 dnl Directory for VDPAU libs
2014 AC_ARG_WITH([vdpau-libdir],
2015     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2016         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2017     [VDPAU_LIB_INSTALL_DIR="$withval"],
2018     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2019 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2020
2021 dnl Directory for OMX libs
2022
2023 AC_ARG_WITH([omx-libdir],
2024     [AS_HELP_STRING([--with-omx-libdir=DIR],
2025         [directory for the OMX libraries])],
2026     [OMX_LIB_INSTALL_DIR="$withval"],
2027     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2028 AC_SUBST([OMX_LIB_INSTALL_DIR])
2029
2030 dnl Directory for VA libs
2031
2032 AC_ARG_WITH([va-libdir],
2033     [AS_HELP_STRING([--with-va-libdir=DIR],
2034         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2035     [VA_LIB_INSTALL_DIR="$withval"],
2036     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2037 AC_SUBST([VA_LIB_INSTALL_DIR])
2038
2039 AC_ARG_WITH([d3d-libdir],
2040     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2041         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2042     [D3D_DRIVER_INSTALL_DIR="$withval"],
2043     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2044 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2045
2046 dnl
2047 dnl Gallium helper functions
2048 dnl
2049 gallium_require_drm() {
2050     if test "x$have_libdrm" != xyes; then
2051        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2052     fi
2053 }
2054
2055 gallium_require_llvm() {
2056     if test "x$MESA_LLVM" = x0; then
2057         case "$host" in *gnux32) return;; esac
2058         case "$host_cpu" in
2059         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2060         esac
2061     fi
2062 }
2063
2064 gallium_require_drm_loader() {
2065     if test "x$need_pci_id$have_pci_id" = xyesno; then
2066         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2067     fi
2068 }
2069
2070 require_egl_drm() {
2071     case "$with_egl_platforms" in
2072         *drm*)
2073             ;;
2074          *)
2075             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2076             ;;
2077     esac
2078     if test "x$enable_gbm" != xyes; then
2079             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2080     fi
2081 }
2082
2083 radeon_llvm_check() {
2084     if test ${LLVM_VERSION_INT} -lt 307; then
2085         amdgpu_llvm_target_name='r600'
2086     else
2087         amdgpu_llvm_target_name='amdgpu'
2088     fi
2089     if test "x$enable_gallium_llvm" != "xyes"; then
2090         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2091     fi
2092     llvm_check_version_for "3" "5" "0" $1
2093     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2094         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2095     fi
2096     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2097     NEED_RADEON_LLVM=yes
2098     if test "x$have_libelf" != xyes; then
2099        AC_MSG_ERROR([$1 requires libelf when using llvm])
2100     fi
2101 }
2102
2103 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2104 if test -n "$with_gallium_drivers"; then
2105     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2106     for driver in $gallium_drivers; do
2107         case "x$driver" in
2108         xsvga)
2109             HAVE_GALLIUM_SVGA=yes
2110             gallium_require_drm "svga"
2111             gallium_require_drm_loader
2112             ;;
2113         xi915)
2114             HAVE_GALLIUM_I915=yes
2115             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2116             gallium_require_drm "Gallium i915"
2117             gallium_require_drm_loader
2118             ;;
2119         xilo)
2120             HAVE_GALLIUM_ILO=yes
2121             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2122             gallium_require_drm "Gallium i965/ilo"
2123             gallium_require_drm_loader
2124             ;;
2125         xr300)
2126             HAVE_GALLIUM_R300=yes
2127             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2128             gallium_require_drm "Gallium R300"
2129             gallium_require_drm_loader
2130             gallium_require_llvm "Gallium R300"
2131             ;;
2132         xr600)
2133             HAVE_GALLIUM_R600=yes
2134             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2135             gallium_require_drm "Gallium R600"
2136             gallium_require_drm_loader
2137             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2138                 radeon_llvm_check "r600g"
2139                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2140             fi
2141             if test "x$enable_r600_llvm" = xyes; then
2142                 USE_R600_LLVM_COMPILER=yes;
2143             fi
2144             if test "x$enable_opencl" = xyes; then
2145                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2146             fi
2147             ;;
2148         xradeonsi)
2149             HAVE_GALLIUM_RADEONSI=yes
2150             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2151             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2152             gallium_require_drm "radeonsi"
2153             gallium_require_drm_loader
2154             radeon_llvm_check "radeonsi"
2155             require_egl_drm "radeonsi"
2156             ;;
2157         xnouveau)
2158             HAVE_GALLIUM_NOUVEAU=yes
2159             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2160             gallium_require_drm "nouveau"
2161             gallium_require_drm_loader
2162             ;;
2163         xfreedreno)
2164             HAVE_GALLIUM_FREEDRENO=yes
2165             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2166             gallium_require_drm "freedreno"
2167             gallium_require_drm_loader
2168             ;;
2169         xswrast)
2170             HAVE_GALLIUM_SOFTPIPE=yes
2171             if test "x$MESA_LLVM" = x1; then
2172                 HAVE_GALLIUM_LLVMPIPE=yes
2173             fi
2174             ;;
2175         xvc4)
2176             HAVE_GALLIUM_VC4=yes
2177             gallium_require_drm "vc4"
2178             gallium_require_drm_loader
2179
2180             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2181                               [USE_VC4_SIMULATOR=yes;
2182                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2183                               [USE_VC4_SIMULATOR=no])
2184             ;;
2185         xvirgl)
2186             HAVE_GALLIUM_VIRGL=yes
2187             gallium_require_drm "virgl"
2188             gallium_require_drm_loader
2189             require_egl_drm "virgl"
2190             ;;
2191         *)
2192             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2193             ;;
2194         esac
2195     done
2196 fi
2197
2198 dnl Set LLVM_LIBS - This is done after the driver configuration so
2199 dnl that drivers can add additional components to LLVM_COMPONENTS.
2200 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2201 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2202 dnl this was causing the same libraries to be appear multiple times
2203 dnl in LLVM_LIBS.
2204
2205 if test "x$MESA_LLVM" != x0; then
2206
2207     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2208
2209     dnl llvm-config may not give the right answer when llvm is a built as a
2210     dnl single shared library, so we must work the library name out for
2211     dnl ourselves.
2212     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2213     if test "x$enable_llvm_shared_libs" = xyes; then
2214         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2215         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2216         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2217
2218         if test "x$llvm_have_one_so" = xyes; then
2219             dnl LLVM was built using auto*, so there is only one shared object.
2220             LLVM_LIBS="-l$LLVM_SO_NAME"
2221         else
2222             dnl If LLVM was built with CMake, there will be one shared object per
2223             dnl component.
2224             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2225                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2226         Please make sure you have built llvm with the --enable-shared option
2227         and that your llvm libraries are installed in $LLVM_LIBDIR
2228         If you have installed your llvm libraries to a different directory you
2229         can use the --with-llvm-prefix= configure flag to specify this directory.
2230         NOTE: Mesa is attempting to use llvm shared libraries by default.
2231         If you do not want to build with llvm shared libraries and instead want to
2232         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2233         invocation and rebuild.])])
2234
2235            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2236            dnl install uses a shared object for each component and we have
2237            dnl already added all of these objects to LLVM_LIBS.
2238         fi
2239     else
2240         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2241         dnl We need to link to llvm system libs when using static libs
2242         dnl However, only llvm 3.5+ provides --system-libs
2243         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2244             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2245         fi
2246     fi
2247 fi
2248
2249 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2250 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2251 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2252 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2253 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2254 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2255 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2256                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2257 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2258 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2259 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2260 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2261 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2262 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2263
2264 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2265
2266 if test "x$enable_dri" = xyes; then
2267     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2268 fi
2269
2270 if test "x$have_drisw_kms" = xyes; then
2271     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2272 fi
2273 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2274
2275 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2276 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2277 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2278 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2279 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2280 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2281
2282 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2283                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2284                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2285 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2286 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2287 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2288 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2289 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2290 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2291 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2292     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2293 fi
2294
2295 AC_SUBST([ELF_LIB])
2296
2297 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2298 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2299 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2300 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2301
2302 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2303 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2304 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2305
2306 AC_SUBST([NINE_MAJOR], 1)
2307 AC_SUBST([NINE_MINOR], 0)
2308 AC_SUBST([NINE_TINY], 0)
2309 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2310
2311 AC_SUBST([VDPAU_MAJOR], 1)
2312 AC_SUBST([VDPAU_MINOR], 0)
2313
2314 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2315 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2316 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2317 AC_SUBST([VA_MINOR], $VA_MINOR)
2318
2319 AC_SUBST([XVMC_MAJOR], 1)
2320 AC_SUBST([XVMC_MINOR], 0)
2321
2322 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2323 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2324 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2325 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2326
2327 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2328 AC_SUBST([XA_MINOR], $XA_MINOR)
2329 AC_SUBST([XA_TINY], $XA_TINY)
2330 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2331
2332 dnl Restore LDFLAGS and CPPFLAGS
2333 LDFLAGS="$_SAVE_LDFLAGS"
2334 CPPFLAGS="$_SAVE_CPPFLAGS"
2335
2336 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2337 if test "x$acv_mesa_CLANG" = xyes; then
2338     CFLAGS="$CFLAGS -Qunused-arguments"
2339     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2340 fi
2341
2342 dnl Add user CFLAGS and CXXFLAGS
2343 CFLAGS="$CFLAGS $USER_CFLAGS"
2344 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2345
2346 dnl Substitute the config
2347 AC_CONFIG_FILES([Makefile
2348                 src/Makefile
2349                 src/egl/Makefile
2350                 src/egl/main/egl.pc
2351                 src/egl/wayland/wayland-drm/Makefile
2352                 src/egl/wayland/wayland-egl/Makefile
2353                 src/egl/wayland/wayland-egl/wayland-egl.pc
2354                 src/gallium/Makefile
2355                 src/gallium/auxiliary/Makefile
2356                 src/gallium/auxiliary/pipe-loader/Makefile
2357                 src/gallium/drivers/freedreno/Makefile
2358                 src/gallium/drivers/ddebug/Makefile
2359                 src/gallium/drivers/i915/Makefile
2360                 src/gallium/drivers/ilo/Makefile
2361                 src/gallium/drivers/llvmpipe/Makefile
2362                 src/gallium/drivers/noop/Makefile
2363                 src/gallium/drivers/nouveau/Makefile
2364                 src/gallium/drivers/r300/Makefile
2365                 src/gallium/drivers/r600/Makefile
2366                 src/gallium/drivers/radeon/Makefile
2367                 src/gallium/drivers/radeonsi/Makefile
2368                 src/gallium/drivers/rbug/Makefile
2369                 src/gallium/drivers/softpipe/Makefile
2370                 src/gallium/drivers/svga/Makefile
2371                 src/gallium/drivers/trace/Makefile
2372                 src/gallium/drivers/vc4/Makefile
2373                 src/gallium/drivers/virgl/Makefile
2374                 src/gallium/state_trackers/clover/Makefile
2375                 src/gallium/state_trackers/dri/Makefile
2376                 src/gallium/state_trackers/glx/xlib/Makefile
2377                 src/gallium/state_trackers/nine/Makefile
2378                 src/gallium/state_trackers/omx/Makefile
2379                 src/gallium/state_trackers/osmesa/Makefile
2380                 src/gallium/state_trackers/va/Makefile
2381                 src/gallium/state_trackers/vdpau/Makefile
2382                 src/gallium/state_trackers/xa/Makefile
2383                 src/gallium/state_trackers/xvmc/Makefile
2384                 src/gallium/targets/d3dadapter9/Makefile
2385                 src/gallium/targets/d3dadapter9/d3d.pc
2386                 src/gallium/targets/dri/Makefile
2387                 src/gallium/targets/libgl-xlib/Makefile
2388                 src/gallium/targets/omx/Makefile
2389                 src/gallium/targets/opencl/Makefile
2390                 src/gallium/targets/opencl/mesa.icd
2391                 src/gallium/targets/osmesa/Makefile
2392                 src/gallium/targets/osmesa/osmesa.pc
2393                 src/gallium/targets/pipe-loader/Makefile
2394                 src/gallium/targets/va/Makefile
2395                 src/gallium/targets/vdpau/Makefile
2396                 src/gallium/targets/xa/Makefile
2397                 src/gallium/targets/xa/xatracker.pc
2398                 src/gallium/targets/xvmc/Makefile
2399                 src/gallium/tests/trivial/Makefile
2400                 src/gallium/tests/unit/Makefile
2401                 src/gallium/winsys/freedreno/drm/Makefile
2402                 src/gallium/winsys/i915/drm/Makefile
2403                 src/gallium/winsys/intel/drm/Makefile
2404                 src/gallium/winsys/nouveau/drm/Makefile
2405                 src/gallium/winsys/radeon/drm/Makefile
2406                 src/gallium/winsys/amdgpu/drm/Makefile
2407                 src/gallium/winsys/svga/drm/Makefile
2408                 src/gallium/winsys/sw/dri/Makefile
2409                 src/gallium/winsys/sw/kms-dri/Makefile
2410                 src/gallium/winsys/sw/null/Makefile
2411                 src/gallium/winsys/sw/wrapper/Makefile
2412                 src/gallium/winsys/sw/xlib/Makefile
2413                 src/gallium/winsys/vc4/drm/Makefile
2414                 src/gallium/winsys/virgl/drm/Makefile
2415                 src/gallium/winsys/virgl/vtest/Makefile
2416                 src/gbm/Makefile
2417                 src/gbm/main/gbm.pc
2418                 src/glsl/Makefile
2419                 src/glx/Makefile
2420                 src/glx/apple/Makefile
2421                 src/glx/tests/Makefile
2422                 src/gtest/Makefile
2423                 src/loader/Makefile
2424                 src/mapi/Makefile
2425                 src/mapi/es1api/glesv1_cm.pc
2426                 src/mapi/es2api/glesv2.pc
2427                 src/mapi/glapi/gen/Makefile
2428                 src/mesa/Makefile
2429                 src/mesa/gl.pc
2430                 src/mesa/drivers/dri/dri.pc
2431                 src/mesa/drivers/dri/common/Makefile
2432                 src/mesa/drivers/dri/common/xmlpool/Makefile
2433                 src/mesa/drivers/dri/i915/Makefile
2434                 src/mesa/drivers/dri/i965/Makefile
2435                 src/mesa/drivers/dri/Makefile
2436                 src/mesa/drivers/dri/nouveau/Makefile
2437                 src/mesa/drivers/dri/r200/Makefile
2438                 src/mesa/drivers/dri/radeon/Makefile
2439                 src/mesa/drivers/dri/swrast/Makefile
2440                 src/mesa/drivers/osmesa/Makefile
2441                 src/mesa/drivers/osmesa/osmesa.pc
2442                 src/mesa/drivers/x11/Makefile
2443                 src/mesa/main/tests/Makefile
2444                 src/util/Makefile
2445                 src/util/tests/hash_table/Makefile])
2446
2447 AC_OUTPUT
2448
2449 dnl
2450 dnl Output some configuration info for the user
2451 dnl
2452 echo ""
2453 echo "        prefix:          $prefix"
2454 echo "        exec_prefix:     $exec_prefix"
2455 echo "        libdir:          $libdir"
2456 echo "        includedir:      $includedir"
2457
2458 dnl API info
2459 echo ""
2460 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2461
2462 dnl Driver info
2463 echo ""
2464 case "x$enable_osmesa$enable_gallium_osmesa" in
2465 xnoyes)
2466         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2467         ;;
2468 xyesno)
2469         echo "        OSMesa:          lib$OSMESA_LIB"
2470         ;;
2471 xnono)
2472         echo "        OSMesa:          no"
2473         ;;
2474 esac
2475
2476 echo ""
2477 if test "x$enable_dri" != xno; then
2478         echo "        DRI platform:    $dri_platform"
2479         if test -z "$DRI_DIRS"; then
2480             echo "        DRI drivers:     no"
2481         else
2482             echo "        DRI drivers:     $DRI_DIRS"
2483         fi
2484         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2485 fi
2486
2487 case "x$enable_glx$enable_xlib_glx" in
2488 xyesyes)
2489     echo "        GLX:             Xlib-based"
2490     ;;
2491 xyesno)
2492     echo "        GLX:             DRI-based"
2493     ;;
2494 *)
2495     echo "        GLX:             $enable_glx"
2496     ;;
2497 esac
2498
2499 dnl EGL
2500 echo ""
2501 echo "        EGL:             $enable_egl"
2502 if test "$enable_egl" = yes; then
2503     echo "        EGL platforms:   $egl_platforms"
2504
2505     egl_drivers=""
2506     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2507         egl_drivers="$egl_drivers builtin:egl_dri2"
2508     fi
2509     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2510         egl_drivers="$egl_drivers builtin:egl_dri3"
2511     fi
2512
2513     echo "        EGL drivers:    $egl_drivers"
2514 fi
2515
2516 echo ""
2517 if test "x$MESA_LLVM" = x1; then
2518     echo "        llvm:            yes"
2519     echo "        llvm-config:     $LLVM_CONFIG"
2520     echo "        llvm-version:    $LLVM_VERSION"
2521 else
2522     echo "        llvm:            no"
2523 fi
2524
2525 echo ""
2526 if test -n "$with_gallium_drivers"; then
2527     echo "        Gallium drivers: $gallium_drivers"
2528     echo "        Gallium st:      $gallium_st"
2529 else
2530     echo "        Gallium:         no"
2531 fi
2532
2533 dnl Shader cache
2534 echo ""
2535 echo "        Shader cache:    $enable_shader_cache"
2536 if test "x$enable_shader_cache" = "xyes"; then
2537     echo "        With SHA1 from:  $with_sha1"
2538 fi
2539
2540 dnl Libraries
2541 echo ""
2542 echo "        Shared libs:     $enable_shared"
2543 echo "        Static libs:     $enable_static"
2544 echo "        Shared-glapi:    $enable_shared_glapi"
2545
2546 dnl Compiler options
2547 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2548 cflags=`echo $CFLAGS | \
2549     $SED 's/^ *//;s/  */ /;s/ *$//'`
2550 cxxflags=`echo $CXXFLAGS | \
2551     $SED 's/^ *//;s/  */ /;s/ *$//'`
2552 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2553 echo ""
2554 echo "        CFLAGS:          $cflags"
2555 echo "        CXXFLAGS:        $cxxflags"
2556 echo "        Macros:          $defines"
2557 echo ""
2558 if test "x$MESA_LLVM" = x1; then
2559     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2560     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2561     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2562     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2563     echo ""
2564 fi
2565 echo "        PYTHON2:         $PYTHON2"
2566
2567 echo ""
2568 echo "        Run '${MAKE-make}' to build Mesa"
2569 echo ""