configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.64
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.35.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_CHECK_PROGS([PYTHON3], [python3])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AX_PROG_BISON([],
 112               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 113                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 114 AX_PROG_FLEX([],
 115              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 116                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 117
 118 AC_CHECK_PROG(INDENT, indent, indent, cat)
 119 if test "x$INDENT" != "xcat"; then
 120     # Only GNU indent is supported
 121     INDENT_VERSION=`indent --version | grep GNU`
 122     if test $? -eq 0; then
 123        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 124     else
 125        INDENT="cat"
 126     fi
 127 fi
 128
 129 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 130
 131 if test -z "$PYTHON2"; then
 132     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 133         AC_MSG_ERROR([Python not found - unable to generate sources])
 134     fi
 135 else
 136     if test "x$acv_mako_found" = xno; then
 137         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 138             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 139         fi
 140     fi
 141 fi
 142
 143 AC_PROG_INSTALL
 144
 145 dnl We need a POSIX shell for parts of the build. Assume we have one
 146 dnl in most cases.
 147 case "$host_os" in
 148 solaris*)
 149     # Solaris /bin/sh is too old/non-POSIX compliant
 150     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 151     SHELL="$POSIX_SHELL"
 152     ;;
 153 esac
 154
 155 dnl clang is mostly GCC-compatible, but its version is much lower,
 156 dnl so we have to check for it.
 157 AC_MSG_CHECKING([if compiling with clang])
 158
 159 AC_COMPILE_IFELSE(
 160 [AC_LANG_PROGRAM([], [[
 161 #ifndef __clang__
 162        not clang
 163 #endif
 164 ]])],
 165 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 166
 167 AC_MSG_RESULT([$acv_mesa_CLANG])
 168
 169 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 170 dnl versions are explictly not supported.
 171 GEN_ASM_OFFSETS=no
 172 USE_GNU99=no
 173 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 174     AC_MSG_CHECKING([whether gcc version is sufficient])
 175     major=0
 176     minor=0
 177
 178     GCC_VERSION=`$CC -dumpversion`
 179     if test $? -eq 0; then
 180         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 181         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 182     fi
 183
 184     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 185         AC_MSG_RESULT([no])
 186         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 187     else
 188         AC_MSG_RESULT([yes])
 189     fi
 190
 191     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 192         USE_GNU99=yes
 193     fi
 194     if test "x$cross_compiling" = xyes; then
 195         GEN_ASM_OFFSETS=yes
 196     fi
 197 fi
 198
 199 dnl Check for compiler builtins
 200 AX_GCC_BUILTIN([__builtin_bswap32])
 201 AX_GCC_BUILTIN([__builtin_bswap64])
 202 AX_GCC_BUILTIN([__builtin_clz])
 203 AX_GCC_BUILTIN([__builtin_clzll])
 204 AX_GCC_BUILTIN([__builtin_ctz])
 205 AX_GCC_BUILTIN([__builtin_expect])
 206 AX_GCC_BUILTIN([__builtin_ffs])
 207 AX_GCC_BUILTIN([__builtin_ffsll])
 208 AX_GCC_BUILTIN([__builtin_popcount])
 209 AX_GCC_BUILTIN([__builtin_popcountll])
 210 AX_GCC_BUILTIN([__builtin_unreachable])
 211
 212 AX_GCC_FUNC_ATTRIBUTE([const])
 213 AX_GCC_FUNC_ATTRIBUTE([flatten])
 214 AX_GCC_FUNC_ATTRIBUTE([format])
 215 AX_GCC_FUNC_ATTRIBUTE([malloc])
 216 AX_GCC_FUNC_ATTRIBUTE([packed])
 217 AX_GCC_FUNC_ATTRIBUTE([pure])
 218 AX_GCC_FUNC_ATTRIBUTE([unused])
 219 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 220
 221 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 222
 223 dnl Make sure the pkg-config macros are defined
 224 m4_ifndef([PKG_PROG_PKG_CONFIG],
 225     [m4_fatal([Could not locate the pkg-config autoconf macros.
 226   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 227   are in a different location, try setting the environment variable
 228   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 229 PKG_PROG_PKG_CONFIG()
 230
 231 dnl LIB_DIR - library basename
 232 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 233 AC_SUBST([LIB_DIR])
 234
 235 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 236 _SAVE_LDFLAGS="$LDFLAGS"
 237 _SAVE_CPPFLAGS="$CPPFLAGS"
 238
 239 dnl Compiler macros
 240 DEFINES="-D__STDC_LIMIT_MACROS"
 241 AC_SUBST([DEFINES])
 242 case "$host_os" in
 243 linux*|*-gnu*|gnu*)
 244     DEFINES="$DEFINES -D_GNU_SOURCE"
 245     ;;
 246 solaris*)
 247     DEFINES="$DEFINES -DSVR4"
 248     ;;
 249 cygwin*)
 250     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 251     ;;
 252 esac
 253
 254 dnl Add flags for gcc and g++
 255 if test "x$GCC" = xyes; then
 256     CFLAGS="$CFLAGS -Wall"
 257
 258     if test "x$USE_GNU99" = xyes; then
 259         CFLAGS="$CFLAGS -std=gnu99"
 260     else
 261         CFLAGS="$CFLAGS -std=c99"
 262     fi
 263
 264     # Enable -Werror=implicit-function-declaration and
 265     # -Werror=missing-prototypes, if available, or otherwise, just
 266     # -Wmissing-prototypes.  This is particularly useful to avoid
 267     # generating a loadable driver module that has undefined symbols.
 268     save_CFLAGS="$CFLAGS"
 269     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 270     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 271     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 272     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 273                    AC_MSG_RESULT([yes]),
 274                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 275                     AC_MSG_RESULT([no])]);
 276
 277     # Enable -fvisibility=hidden if using a gcc that supports it
 278     save_CFLAGS="$CFLAGS"
 279     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 280     VISIBILITY_CFLAGS="-fvisibility=hidden"
 281     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 282     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 283                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 284
 285     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 286     CFLAGS=$save_CFLAGS
 287
 288     # Work around aliasing bugs - developers should comment this out
 289     CFLAGS="$CFLAGS -fno-strict-aliasing"
 290
 291     # We don't want floating-point math functions to set errno or trap
 292     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 293
 294     # gcc's builtin memcmp is slower than glibc's
 295     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 296     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 297
 298     # Flags to help ensure that certain portions of the code -- and only those
 299     # portions -- can be built with MSVC:
 300     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 301     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 302     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 303     #   supports most of C99)
 304     # - the rest has no compiler compiler restrictions
 305     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 306     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 307
 308     # Enable -Werror=vla if compiler supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 311     CFLAGS="$CFLAGS -Werror=vla"
 312     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 313                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 314                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 315                     AC_MSG_RESULT([yes])],
 316                     AC_MSG_RESULT([no]));
 317     CFLAGS="$save_CFLAGS"
 318
 319     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 320     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 321 fi
 322 if test "x$GXX" = xyes; then
 323     CXXFLAGS="$CXXFLAGS -Wall"
 324
 325     # Enable -fvisibility=hidden if using a gcc that supports it
 326     save_CXXFLAGS="$CXXFLAGS"
 327     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 328     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 329     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 330     AC_LANG_PUSH([C++])
 331     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 332                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 333     AC_LANG_POP([C++])
 334
 335     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 336     CXXFLAGS=$save_CXXFLAGS
 337
 338     # Work around aliasing bugs - developers should comment this out
 339     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 340
 341     # gcc's builtin memcmp is slower than glibc's
 342     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 343     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 344 fi
 345
 346 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 347 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 348 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 349 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 350
 351 dnl even if the compiler appears to support it, using visibility attributes isn't
 352 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 353 case "$host_os" in
 354 cygwin*)
 355     VISIBILITY_CFLAGS=""
 356     VISIBILITY_CXXFLAGS=""
 357     ;;
 358 esac
 359
 360 AC_SUBST([VISIBILITY_CFLAGS])
 361 AC_SUBST([VISIBILITY_CXXFLAGS])
 362
 363 dnl
 364 dnl Optional flags, check for compiler support
 365 dnl
 366 SSE41_CFLAGS="-msse4.1"
 367 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 368 dnl stack, but on x86-32 such alignment is not guaranteed.
 369 case "$target_cpu" in
 370 i?86)
 371     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 372     ;;
 373 esac
 374 save_CFLAGS="$CFLAGS"
 375 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 376 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 377 #include <smmintrin.h>
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 380     c = _mm_max_epu32(a, b);
 381     return 0;
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Can't have static and shared libraries, default to static if user
 391 dnl explicitly requested. If both disabled, set to static since shared
 392 dnl was explicitly requested.
 393 case "x$enable_static$enable_shared" in
 394 xyesyes)
 395     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 396     enable_shared=no
 397     ;;
 398 xnono)
 399     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 400     enable_shared=yes
 401     ;;
 402 esac
 403
 404 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 405
 406 dnl
 407 dnl other compiler options
 408 dnl
 409 AC_ARG_ENABLE([debug],
 410     [AS_HELP_STRING([--enable-debug],
 411         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 412     [enable_debug="$enableval"],
 413     [enable_debug=no]
 414 )
 415 if test "x$enable_debug" = xyes; then
 416     DEFINES="$DEFINES -DDEBUG"
 417     if test "x$GCC" = xyes; then
 418         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 419             CFLAGS="$CFLAGS -g"
 420         fi
 421         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 422             CFLAGS="$CFLAGS -O0"
 423         fi
 424     fi
 425     if test "x$GXX" = xyes; then
 426         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 427             CXXFLAGS="$CXXFLAGS -g"
 428         fi
 429         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 430             CXXFLAGS="$CXXFLAGS -O0"
 431         fi
 432     fi
 433 else
 434    DEFINES="$DEFINES -DNDEBUG"
 435 fi
 436
 437 dnl
 438 dnl Check if linker supports -Bsymbolic
 439 dnl
 440 save_LDFLAGS=$LDFLAGS
 441 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 442 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 443 AC_LINK_IFELSE(
 444     [AC_LANG_SOURCE([int main() { return 0;}])],
 445     [AC_MSG_RESULT([yes])
 446         BSYMBOLIC="-Wl,-Bsymbolic";],
 447     [AC_MSG_RESULT([no])
 448         BSYMBOLIC="";])
 449 LDFLAGS=$save_LDFLAGS
 450
 451 AC_SUBST([BSYMBOLIC])
 452
 453 dnl
 454 dnl Check if linker supports garbage collection
 455 dnl
 456 save_LDFLAGS=$LDFLAGS
 457 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 458 AC_MSG_CHECKING([whether ld supports --gc-sections])
 459 AC_LINK_IFELSE(
 460     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 461     [AC_MSG_RESULT([yes])
 462         GC_SECTIONS="-Wl,--gc-sections";],
 463     [AC_MSG_RESULT([no])
 464         GC_SECTIONS="";])
 465 LDFLAGS=$save_LDFLAGS
 466
 467 AC_SUBST([GC_SECTIONS])
 468
 469 dnl
 470 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 471 dnl so when these flags are passed to ld via libtool the checks will fail
 472 dnl
 473 case "$host_os" in
 474 openbsd* | darwin* )
 475     LD_NO_UNDEFINED="" ;;
 476 *)
 477     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 478 esac
 479
 480 AC_SUBST([LD_NO_UNDEFINED])
 481
 482 dnl
 483 dnl Check if linker supports version scripts
 484 dnl
 485 AC_MSG_CHECKING([if the linker supports version-scripts])
 486 save_LDFLAGS=$LDFLAGS
 487 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 488 cat > conftest.map <<EOF
 489 VERSION_1 {
 490      global:
 491          main;
 492
 493      local:
 494          *;
 495 };
 496 EOF
 497 AC_LINK_IFELSE(
 498     [AC_LANG_SOURCE([int main() { return 0;}])],
 499     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 500     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 501 LDFLAGS=$save_LDFLAGS
 502 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 503
 504 dnl
 505 dnl Check if linker supports dynamic list files
 506 dnl
 507 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 508 save_LDFLAGS=$LDFLAGS
 509 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 510 cat > conftest.dyn <<EOF
 511 {
 512         radeon_drm_winsys_create;
 513 };
 514 EOF
 515 AC_LINK_IFELSE(
 516     [AC_LANG_SOURCE([int main() { return 0;}])],
 517     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 518     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 519 LDFLAGS=$save_LDFLAGS
 520 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 521
 522 dnl
 523 dnl compatibility symlinks
 524 dnl
 525 case "$host_os" in
 526 linux* )
 527     HAVE_COMPAT_SYMLINKS=yes ;;
 528 * )
 529     HAVE_COMPAT_SYMLINKS=no ;;
 530 esac
 531
 532 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 533
 534 dnl
 535 dnl library names
 536 dnl
 537 case "$host_os" in
 538 darwin* )
 539     LIB_EXT='dylib' ;;
 540 cygwin* )
 541     LIB_EXT='dll' ;;
 542 aix* )
 543     LIB_EXT='a' ;;
 544 * )
 545     LIB_EXT='so' ;;
 546 esac
 547
 548 AC_SUBST([LIB_EXT])
 549
 550 AC_ARG_WITH([gl-lib-name],
 551   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 552     [specify GL library name @<:@default=GL@:>@])],
 553   [GL_LIB=$withval],
 554   [GL_LIB=GL])
 555 AC_ARG_WITH([osmesa-lib-name],
 556   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 557     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 558   [OSMESA_LIB=$withval],
 559   [OSMESA_LIB=OSMesa])
 560 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 561 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 562
 563 dnl
 564 dnl Mangled Mesa support
 565 dnl
 566 AC_ARG_ENABLE([mangling],
 567   [AS_HELP_STRING([--enable-mangling],
 568     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 569   [enable_mangling="${enableval}"],
 570   [enable_mangling=no]
 571 )
 572 if test "x${enable_mangling}" = "xyes" ; then
 573   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 574   GL_LIB="Mangled${GL_LIB}"
 575   OSMESA_LIB="Mangled${OSMESA_LIB}"
 576 fi
 577 AC_SUBST([GL_LIB])
 578 AC_SUBST([OSMESA_LIB])
 579
 580 dnl
 581 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 582 dnl
 583 AC_ARG_ENABLE([texture-float],
 584     [AS_HELP_STRING([--enable-texture-float],
 585         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 586     [enable_texture_float="$enableval"],
 587     [enable_texture_float=no]
 588 )
 589 if test "x$enable_texture_float" = xyes; then
 590     AC_MSG_WARN([Floating-point textures enabled.])
 591     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 592     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 593 fi
 594
 595 dnl
 596 dnl Arch/platform-specific settings
 597 dnl
 598 AC_ARG_ENABLE([asm],
 599     [AS_HELP_STRING([--disable-asm],
 600         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 601     [enable_asm="$enableval"],
 602     [enable_asm=yes]
 603 )
 604 asm_arch=""
 605 AC_MSG_CHECKING([whether to enable assembly])
 606 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 607 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 608 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 609     case "$host_cpu" in
 610     i?86 | x86_64 | amd64)
 611         enable_asm=no
 612         AC_MSG_RESULT([no, cross compiling])
 613         ;;
 614     esac
 615 fi
 616 # check for supported arches
 617 if test "x$enable_asm" = xyes; then
 618     case "$host_cpu" in
 619     i?86)
 620         case "$host_os" in
 621         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 622             asm_arch=x86
 623             ;;
 624         esac
 625         ;;
 626     x86_64|amd64)
 627         case "$host_os" in
 628         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 629             asm_arch=x86_64
 630             ;;
 631         esac
 632         ;;
 633     sparc*)
 634         case "$host_os" in
 635         linux*)
 636             asm_arch=sparc
 637             ;;
 638         esac
 639         ;;
 640     esac
 641
 642     case "$asm_arch" in
 643     x86)
 644         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 645         AC_MSG_RESULT([yes, x86])
 646         ;;
 647     x86_64|amd64)
 648         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 649         AC_MSG_RESULT([yes, x86_64])
 650         ;;
 651     sparc)
 652         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 653         AC_MSG_RESULT([yes, sparc])
 654         ;;
 655     *)
 656         AC_MSG_RESULT([no, platform not supported])
 657         ;;
 658     esac
 659 fi
 660
 661 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 662 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 663 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 664 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 665
 666 dnl Check to see if dlopen is in default libraries (like Solaris, which
 667 dnl has it in libc), or if libdl is needed to get it.
 668 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 669     [AC_CHECK_LIB([dl], [dlopen],
 670        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 671 AC_SUBST([DLOPEN_LIBS])
 672
 673 dnl Check if that library also has dladdr
 674 save_LIBS="$LIBS"
 675 LIBS="$LIBS $DLOPEN_LIBS"
 676 AC_CHECK_FUNCS([dladdr])
 677 LIBS="$save_LIBS"
 678
 679 case "$host_os" in
 680 darwin*)
 681     ;;
 682 *)
 683     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 684                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 685                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 686     AC_SUBST([CLOCK_LIB])
 687     ;;
 688 esac
 689
 690 dnl See if posix_memalign is available
 691 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 692
 693 dnl Check for pthreads
 694 AX_PTHREAD
 695 if test "x$ax_pthread_ok" = xno; then
 696     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 697 fi
 698 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 699 dnl to -pthread, which causes problems if we need -lpthread to appear in
 700 dnl pkgconfig files.
 701 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 702
 703 dnl SELinux awareness.
 704 AC_ARG_ENABLE([selinux],
 705     [AS_HELP_STRING([--enable-selinux],
 706         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 707     [MESA_SELINUX="$enableval"],
 708     [MESA_SELINUX=no])
 709 if test "x$enable_selinux" = "xyes"; then
 710     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 711         [AC_CHECK_HEADER([selinux/selinux.h],[],
 712                          [AC_MSG_ERROR([SELinux headers not found])])
 713          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 714                       [AC_MSG_ERROR([SELinux library not found])])
 715          SELINUX_LIBS="-lselinux"])
 716     DEFINES="$DEFINES -DMESA_SELINUX"
 717 fi
 718 AC_SUBST([SELINUX_CFLAGS])
 719 AC_SUBST([SELINUX_LIBS])
 720
 721 dnl Options for APIs
 722 AC_ARG_ENABLE([opengl],
 723     [AS_HELP_STRING([--disable-opengl],
 724         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 725     [enable_opengl="$enableval"],
 726     [enable_opengl=yes])
 727 AC_ARG_ENABLE([gles1],
 728     [AS_HELP_STRING([--disable-gles1],
 729         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 730     [enable_gles1="$enableval"],
 731     [enable_gles1=yes])
 732 AC_ARG_ENABLE([gles2],
 733     [AS_HELP_STRING([--disable-gles2],
 734         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 735     [enable_gles2="$enableval"],
 736     [enable_gles2=yes])
 737
 738 AC_ARG_ENABLE([dri],
 739     [AS_HELP_STRING([--enable-dri],
 740         [enable DRI modules @<:@default=enabled@:>@])],
 741     [enable_dri="$enableval"],
 742     [enable_dri=yes])
 743
 744 case "$host_os" in
 745 linux*)
 746     dri3_default=yes
 747     ;;
 748 *)
 749     dri3_default=no
 750     ;;
 751 esac
 752 AC_ARG_ENABLE([dri3],
 753     [AS_HELP_STRING([--enable-dri3],
 754         [enable DRI3 @<:@default=auto@:>@])],
 755     [enable_dri3="$enableval"],
 756     [enable_dri3="$dri3_default"])
 757 AC_ARG_ENABLE([glx],
 758     [AS_HELP_STRING([--enable-glx],
 759         [enable GLX library @<:@default=enabled@:>@])],
 760     [enable_glx="$enableval"],
 761     [enable_glx=yes])
 762 AC_ARG_ENABLE([osmesa],
 763     [AS_HELP_STRING([--enable-osmesa],
 764         [enable OSMesa library @<:@default=disabled@:>@])],
 765     [enable_osmesa="$enableval"],
 766     [enable_osmesa=no])
 767 AC_ARG_ENABLE([gallium-osmesa],
 768     [AS_HELP_STRING([--enable-gallium-osmesa],
 769         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 770     [enable_gallium_osmesa="$enableval"],
 771     [enable_gallium_osmesa=no])
 772 AC_ARG_ENABLE([egl],
 773     [AS_HELP_STRING([--disable-egl],
 774         [disable EGL library @<:@default=enabled@:>@])],
 775     [enable_egl="$enableval"],
 776     [enable_egl=yes])
 777
 778 AC_ARG_ENABLE([xa],
 779     [AS_HELP_STRING([--enable-xa],
 780         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 781     [enable_xa="$enableval"],
 782     [enable_xa=no])
 783 AC_ARG_ENABLE([gbm],
 784    [AS_HELP_STRING([--enable-gbm],
 785          [enable gbm library @<:@default=auto@:>@])],
 786    [enable_gbm="$enableval"],
 787    [enable_gbm=auto])
 788 AC_ARG_ENABLE([nine],
 789     [AS_HELP_STRING([--enable-nine],
 790         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 791     [enable_nine="$enableval"],
 792     [enable_nine=no])
 793
 794 AC_ARG_ENABLE([xvmc],
 795    [AS_HELP_STRING([--enable-xvmc],
 796          [enable xvmc library @<:@default=auto@:>@])],
 797    [enable_xvmc="$enableval"],
 798    [enable_xvmc=auto])
 799 AC_ARG_ENABLE([vdpau],
 800    [AS_HELP_STRING([--enable-vdpau],
 801          [enable vdpau library @<:@default=auto@:>@])],
 802    [enable_vdpau="$enableval"],
 803    [enable_vdpau=auto])
 804 AC_ARG_ENABLE([omx],
 805    [AS_HELP_STRING([--enable-omx],
 806          [enable OpenMAX library @<:@default=disabled@:>@])],
 807    [enable_omx="$enableval"],
 808    [enable_omx=no])
 809 AC_ARG_ENABLE([va],
 810    [AS_HELP_STRING([--enable-va],
 811          [enable va library @<:@default=auto@:>@])],
 812    [enable_va="$enableval"],
 813    [enable_va=auto])
 814 AC_ARG_ENABLE([opencl],
 815    [AS_HELP_STRING([--enable-opencl],
 816          [enable OpenCL library @<:@default=disabled@:>@])],
 817    [enable_opencl="$enableval"],
 818    [enable_opencl=no])
 819 AC_ARG_ENABLE([opencl_icd],
 820    [AS_HELP_STRING([--enable-opencl-icd],
 821           [Build an OpenCL ICD library to be loaded by an ICD implementation
 822            @<:@default=disabled@:>@])],
 823     [enable_opencl_icd="$enableval"],
 824     [enable_opencl_icd=no])
 825 AC_ARG_ENABLE([xlib-glx],
 826     [AS_HELP_STRING([--enable-xlib-glx],
 827         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 828     [enable_xlib_glx="$enableval"],
 829     [enable_xlib_glx=no])
 830
 831 AC_ARG_ENABLE([r600-llvm-compiler],
 832     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 833         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 834     [enable_r600_llvm="$enableval"],
 835     [enable_r600_llvm=no])
 836
 837 AC_ARG_ENABLE([gallium-tests],
 838     [AS_HELP_STRING([--enable-gallium-tests],
 839         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 840     [enable_gallium_tests="$enableval"],
 841     [enable_gallium_tests=no])
 842
 843 # Option for Gallium drivers
 844
 845 # Keep this in sync with the --with-gallium-drivers help string default value
 846 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 847
 848 AC_ARG_WITH([gallium-drivers],
 849     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 850         [comma delimited Gallium drivers list, e.g.
 851         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 852         @<:@default=r300,r600,svga,swrast@:>@])],
 853     [with_gallium_drivers="$withval"],
 854     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 855
 856 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 857 # here so that the script doesn't choke on an unknown driver name later.
 858 case "$with_gallium_drivers" in
 859     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 860     no) with_gallium_drivers='' ;;
 861 esac
 862
 863 if test "x$enable_opengl" = xno -a \
 864         "x$enable_gles1" = xno -a \
 865         "x$enable_gles2" = xno -a \
 866         "x$enable_nine" = xno -a \
 867         "x$enable_xa" = xno -a \
 868         "x$enable_xvmc" = xno -a \
 869         "x$enable_vdpau" = xno -a \
 870         "x$enable_omx" = xno -a \
 871         "x$enable_va" = xno -a \
 872         "x$enable_opencl" = xno; then
 873     AC_MSG_ERROR([at least one API should be enabled])
 874 fi
 875
 876 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 877 if test "x$enable_opengl" = xno -a \
 878         "x$enable_gles1" = xyes; then
 879     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 880 fi
 881
 882 if test "x$enable_opengl" = xno -a \
 883         "x$enable_gles2" = xyes; then
 884     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 885 fi
 886
 887 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 888 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 889 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 890 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 891                                         "x$enable_gles1" = xyes -o \
 892                                         "x$enable_gles2" = xyes)
 893
 894 if test "x$enable_glx" = xno; then
 895     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 896     enable_xlib_glx=no
 897 fi
 898
 899 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 900     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 901 fi
 902
 903 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 904     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 905 fi
 906
 907 # Disable GLX if OpenGL is not enabled
 908 if test "x$enable_glx$enable_opengl" = xyesno; then
 909     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 910     enable_glx=no
 911 fi
 912
 913 # Disable GLX if DRI and Xlib-GLX are not enabled
 914 if test "x$enable_glx" = xyes -a \
 915         "x$enable_dri" = xno -a \
 916         "x$enable_xlib_glx" = xno; then
 917     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 918     enable_glx=no
 919 fi
 920
 921 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 922                                   "x$enable_dri" = xyes)
 923
 924 # Check for libdrm
 925 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 926                   [have_libdrm=yes], [have_libdrm=no])
 927 if test "x$have_libdrm" = xyes; then
 928         DEFINES="$DEFINES -DHAVE_LIBDRM"
 929 fi
 930
 931 # Select which platform-dependent DRI code gets built
 932 case "$host_os" in
 933 darwin*)
 934     dri_platform='apple' ;;
 935 gnu*|cygwin*)
 936     dri_platform='none' ;;
 937 *)
 938     dri_platform='drm' ;;
 939 esac
 940
 941 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 942 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 943 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 944 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 945 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 946
 947 AC_ARG_ENABLE([shared-glapi],
 948     [AS_HELP_STRING([--enable-shared-glapi],
 949         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 950     [enable_shared_glapi="$enableval"],
 951     [enable_shared_glapi=yes])
 952
 953 case "x$enable_opengl$enable_gles1$enable_gles2" in
 954 x*yes*yes*)
 955     if test "x$enable_shared_glapi" = xno; then
 956         AC_MSG_ERROR([shared GLAPI required when building two or more of
 957                       the following APIs - opengl, gles1 gles2])
 958     fi
 959     ;;
 960 esac
 961
 962 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 963
 964 # Build the pipe-drivers as separate libraries/modules.
 965 # Do not touch this unless you know what you are doing.
 966 # XXX: Expose via configure option ?
 967 enable_shared_pipe_drivers=no
 968
 969 dnl
 970 dnl Driver specific build directories
 971 dnl
 972
 973 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 974     NEED_WINSYS_XLIB="yes"
 975 fi
 976
 977 if test "x$enable_dri" = xyes; then
 978     enable_gallium_loader="$enable_shared_pipe_drivers"
 979 fi
 980
 981 if test "x$enable_gallium_osmesa" = xyes; then
 982     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 983         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 984     fi
 985     if test "x$enable_osmesa" = xyes; then
 986         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 987     fi
 988 fi
 989
 990 AC_SUBST([MESA_LLVM])
 991
 992 # SHA1 hashing
 993 AC_ARG_WITH([sha1],
 994         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 995         [choose SHA1 implementation])])
 996 case "x$with_sha1" in
 997 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 998   ;;
 999 *)
1000         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1001 esac
1002
1003 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1004 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1005         with_sha1=libc
1006 fi
1007 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1008         AC_MSG_ERROR([sha1 in libc requested but not found])
1009 fi
1010 if test "x$with_sha1" = xlibc; then
1011         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1012                 [Use libc SHA1 functions])
1013         SHA1_LIBS=""
1014 fi
1015 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1016 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1017         with_sha1=CommonCrypto
1018 fi
1019 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1020         AC_MSG_ERROR([CommonCrypto requested but not found])
1021 fi
1022 if test "x$with_sha1" = xCommonCrypto; then
1023         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1024                 [Use CommonCrypto SHA1 functions])
1025         SHA1_LIBS=""
1026 fi
1027 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1028 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1029 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1030         with_sha1=CryptoAPI
1031 fi
1032 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1033         AC_MSG_ERROR([CryptoAPI requested but not found])
1034 fi
1035 if test "x$with_sha1" = xCryptoAPI; then
1036         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1037                 [Use CryptoAPI SHA1 functions])
1038         SHA1_LIBS=""
1039 fi
1040 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1041 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1042         with_sha1=libmd
1043 fi
1044 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1045         AC_MSG_ERROR([libmd requested but not found])
1046 fi
1047 if test "x$with_sha1" = xlibmd; then
1048         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1049                   [Use libmd SHA1 functions])
1050         SHA1_LIBS=-lmd
1051 fi
1052 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1053 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1054    with_sha1=libsha1
1055 fi
1056 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1057         AC_MSG_ERROR([libsha1 requested but not found])
1058 fi
1059 if test "x$with_sha1" = xlibsha1; then
1060         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1061                   [Use libsha1 for SHA1])
1062         SHA1_LIBS=-lsha1
1063 fi
1064 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1065 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1066         with_sha1=libnettle
1067 fi
1068 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1069         AC_MSG_ERROR([libnettle requested but not found])
1070 fi
1071 if test "x$with_sha1" = xlibnettle; then
1072         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1073                   [Use libnettle SHA1 functions])
1074         SHA1_LIBS=-lnettle
1075 fi
1076 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1077 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1078         with_sha1=libgcrypt
1079 fi
1080 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1081         AC_MSG_ERROR([libgcrypt requested but not found])
1082 fi
1083 if test "x$with_sha1" = xlibgcrypt; then
1084         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1085                   [Use libgcrypt SHA1 functions])
1086         SHA1_LIBS=-lgcrypt
1087 fi
1088 # We don't need all of the OpenSSL libraries, just libcrypto
1089 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1090 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1091                   [HAVE_OPENSSL_PKC=no])
1092 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1093         if test "x$with_sha1" = x; then
1094                 with_sha1=libcrypto
1095         fi
1096 else
1097         if test "x$with_sha1" = xlibcrypto; then
1098                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1099         fi
1100 fi
1101 if test "x$with_sha1" = xlibcrypto; then
1102         if test "x$HAVE_LIBCRYPTO" = xyes; then
1103                 SHA1_LIBS=-lcrypto
1104         else
1105                 SHA1_LIBS="$OPENSSL_LIBS"
1106                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1107         fi
1108 fi
1109 AC_MSG_CHECKING([for SHA1 implementation])
1110 AC_MSG_RESULT([$with_sha1])
1111 AC_SUBST(SHA1_LIBS)
1112 AC_SUBST(SHA1_CFLAGS)
1113
1114 # Allow user to configure out the shader-cache feature
1115 AC_ARG_ENABLE([shader-cache],
1116     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1117     [enable_shader_cache="$enableval"],
1118     [if test "x$with_sha1" != "x"; then
1119         enable_shader_cache=yes
1120      else
1121         enable_shader_cache=no
1122      fi])
1123 if test "x$with_sha1" = "x"; then
1124     if test "x$enable_shader_cache" = "xyes"; then
1125         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1126     fi
1127 fi
1128 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1129
1130 case "$host_os" in
1131 linux*)
1132     need_pci_id=yes ;;
1133 *)
1134     need_pci_id=no ;;
1135 esac
1136
1137 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1138                   have_libudev=yes, have_libudev=no)
1139
1140 AC_ARG_ENABLE([sysfs],
1141     [AS_HELP_STRING([--enable-sysfs],
1142         [enable /sys PCI identification @<:@default=disabled@:>@])],
1143     [have_sysfs="$enableval"],
1144     [have_sysfs=no]
1145 )
1146
1147 if test "x$enable_dri" = xyes; then
1148     if test "$enable_static" = yes; then
1149         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1150     fi
1151
1152     # not a hard requirement as swrast does not depend on it
1153     if test "x$have_libdrm" = xyes; then
1154         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1155     fi
1156 fi
1157
1158 AC_ARG_ENABLE([driglx-direct],
1159     [AS_HELP_STRING([--disable-driglx-direct],
1160         [disable direct rendering in GLX and EGL for DRI \
1161             @<:@default=auto@:>@])],
1162     [driglx_direct="$enableval"],
1163     [driglx_direct="yes"])
1164
1165 dnl
1166 dnl libGL configuration per driver
1167 dnl
1168 case "x$enable_glx$enable_xlib_glx" in
1169 xyesyes)
1170     # Xlib-based GLX
1171     dri_modules="x11 xext xcb"
1172     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1173     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1174     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1175     GL_LIB_DEPS="$XLIBGL_LIBS"
1176     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1177     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1178     ;;
1179 xyesno)
1180     # DRI-based GLX
1181     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1182
1183     # find the DRI deps for libGL
1184     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1185
1186     if test x"$driglx_direct" = xyes; then
1187         if test x"$dri_platform" = xdrm ; then
1188             DEFINES="$DEFINES -DGLX_USE_DRM"
1189             if test "x$have_libdrm" != xyes; then
1190                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1191             fi
1192
1193             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1194             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1195             if test x"$enable_dri3" = xyes; then
1196                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1197                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1198             fi
1199
1200             if test x"$enable_dri" = xyes; then
1201                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1202             fi
1203
1204             if test x"$enable_dri3" = xyes; then
1205                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1206                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1207             fi
1208         fi
1209         if test x"$dri_platform" = xapple ; then
1210             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1211         fi
1212     fi
1213
1214     # add xf86vidmode if available
1215     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1216     if test "$HAVE_XF86VIDMODE" = yes ; then
1217         dri_modules="$dri_modules xxf86vm"
1218     fi
1219
1220     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1221     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1222     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1223     GL_LIB_DEPS="$DRIGL_LIBS"
1224
1225     # need DRM libs, $PTHREAD_LIBS, etc.
1226     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1227     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1228     ;;
1229 esac
1230
1231 have_pci_id=no
1232 if test "$have_libudev" = yes; then
1233     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1234     have_pci_id=yes
1235 fi
1236
1237 if test "$have_sysfs" = yes; then
1238     DEFINES="$DEFINES -DHAVE_SYSFS"
1239     have_pci_id=yes
1240 fi
1241
1242 # This is outside the case (above) so that it is invoked even for non-GLX
1243 # builds.
1244 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1245
1246 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1247 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1248 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1249 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1250
1251 AC_SUBST([X11_INCLUDES])
1252 AC_SUBST([GL_LIB_DEPS])
1253 AC_SUBST([GL_PC_REQ_PRIV])
1254 AC_SUBST([GL_PC_LIB_PRIV])
1255 AC_SUBST([GL_PC_CFLAGS])
1256 AC_SUBST([DRI_PC_REQ_PRIV])
1257 AC_SUBST([GLESv1_CM_LIB_DEPS])
1258 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1259 AC_SUBST([GLESv2_LIB_DEPS])
1260 AC_SUBST([GLESv2_PC_LIB_PRIV])
1261
1262 AC_SUBST([HAVE_XF86VIDMODE])
1263
1264 dnl
1265 dnl More GLX setup
1266 dnl
1267 case "x$enable_glx$enable_xlib_glx" in
1268 xyesyes)
1269     DEFINES="$DEFINES -DUSE_XSHM"
1270     ;;
1271 xyesno)
1272     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1273     if test "x$driglx_direct" = xyes; then
1274         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1275     fi
1276     ;;
1277 esac
1278
1279 dnl
1280 dnl TLS detection
1281 dnl
1282
1283 AC_ARG_ENABLE([glx-tls],
1284     [AS_HELP_STRING([--enable-glx-tls],
1285         [enable TLS support in GLX @<:@default=disabled@:>@])],
1286     [GLX_USE_TLS="$enableval"],
1287     [GLX_USE_TLS=no])
1288 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1289
1290 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1291       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1292
1293 dnl
1294 dnl More DRI setup
1295 dnl
1296 dnl Directory for DRI drivers
1297 AC_ARG_WITH([dri-driverdir],
1298     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1299         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1300     [DRI_DRIVER_INSTALL_DIR="$withval"],
1301     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1302 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1303 dnl Extra search path for DRI drivers
1304 AC_ARG_WITH([dri-searchpath],
1305     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1306         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1307     [DRI_DRIVER_SEARCH_DIR="$withval"],
1308     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1309 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1310 dnl Which drivers to build - default is chosen by platform
1311 AC_ARG_WITH([dri-drivers],
1312     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1313         [comma delimited classic DRI drivers list, e.g.
1314         "swrast,i965,radeon" @<:@default=auto@:>@])],
1315     [with_dri_drivers="$withval"],
1316     [with_dri_drivers=auto])
1317
1318 if test "x$with_dri_drivers" = xauto; then
1319     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1320         with_dri_drivers="yes"
1321     else
1322         with_dri_drivers="no"
1323     fi
1324 fi
1325 if test "x$with_dri_drivers" = xno; then
1326     with_dri_drivers=''
1327 fi
1328
1329 dnl If $with_dri_drivers is yes, drivers will be added through
1330 dnl platform checks. Set DEFINES and LIB_DEPS
1331 if test "x$enable_dri" = xyes; then
1332     # Platform specific settings and drivers to build
1333     case "$host_os" in
1334     linux*)
1335         DEFINES="$DEFINES -DHAVE_ALIAS"
1336         if test "x$enable_dri3" = xyes; then
1337             DEFINES="$DEFINES -DHAVE_DRI3"
1338         fi
1339
1340         if test "x$have_pci_id" != xyes; then
1341             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1342         fi
1343
1344         case "$host_cpu" in
1345         powerpc* | sparc*)
1346             # Build only the drivers for cards that exist on PowerPC/sparc
1347             if test "x$with_dri_drivers" = "xyes"; then
1348                 with_dri_drivers="r200 radeon swrast"
1349             fi
1350             ;;
1351         esac
1352         ;;
1353     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1354         DEFINES="$DEFINES -DHAVE_ALIAS"
1355         ;;
1356     gnu*)
1357         DEFINES="$DEFINES -DHAVE_ALIAS"
1358         ;;
1359     cygwin*)
1360         if test "x$with_dri_drivers" = "xyes"; then
1361             with_dri_drivers="swrast"
1362         fi
1363         ;;
1364     darwin*)
1365         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1366         if test "x$with_dri_drivers" = "xyes"; then
1367             with_dri_drivers="swrast"
1368         fi
1369         ;;
1370     esac
1371
1372     # default drivers
1373     if test "x$with_dri_drivers" = "xyes"; then
1374         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1375     fi
1376
1377     # Check for expat
1378     PKG_CHECK_MODULES([EXPAT], [expat], [],
1379         # expat version 2.0 and earlier do not provide expat.pc
1380         [AC_CHECK_HEADER([expat.h],[],
1381                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1382          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1383                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1384          EXPAT_LIBS="-lexpat"])
1385
1386     # put all the necessary libs together
1387     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1388 fi
1389
1390 AC_SUBST([DRI_LIB_DEPS])
1391
1392 DRI_DIRS=''
1393 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1394 if test -n "$with_dri_drivers"; then
1395     if test "x$enable_opengl" != xyes; then
1396         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1397     fi
1398
1399     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1400     for driver in $dri_drivers; do
1401         DRI_DIRS="$DRI_DIRS $driver"
1402         case "x$driver" in
1403         xi915)
1404             HAVE_I915_DRI=yes;
1405             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1406             ;;
1407         xi965)
1408             HAVE_I965_DRI=yes;
1409             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1410             ;;
1411         xnouveau)
1412             HAVE_NOUVEAU_DRI=yes;
1413             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1414             ;;
1415         xradeon)
1416             HAVE_RADEON_DRI=yes;
1417             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1418             ;;
1419         xr200)
1420             HAVE_R200_DRI=yes;
1421             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1422             ;;
1423         xswrast)
1424             HAVE_SWRAST_DRI=yes;
1425             ;;
1426         *)
1427             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1428             ;;
1429         esac
1430     done
1431     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1432 fi
1433
1434 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1435 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1436                                   "x$enable_osmesa" = xyes -o \
1437                                   -n "$DRI_DIRS")
1438
1439 dnl
1440 dnl OSMesa configuration
1441 dnl
1442
1443 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1444 AC_ARG_WITH([osmesa-bits],
1445     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1446         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1447     [osmesa_bits="$withval"],
1448     [osmesa_bits=8])
1449 if test "x$osmesa_bits" != x8; then
1450     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1451         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1452         osmesa_bits=8
1453     fi
1454 fi
1455 case "x$osmesa_bits" in
1456 x8)
1457     OSMESA_LIB="${OSMESA_LIB}"
1458     ;;
1459 x16|x32)
1460     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1461     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1462     ;;
1463 *)
1464     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1465     ;;
1466 esac
1467
1468 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1469     # only link libraries with osmesa if shared
1470     if test "$enable_static" = no; then
1471         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1472     else
1473         OSMESA_LIB_DEPS=""
1474     fi
1475     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1476 fi
1477
1478 AC_SUBST([OSMESA_LIB_DEPS])
1479 AC_SUBST([OSMESA_PC_REQ])
1480 AC_SUBST([OSMESA_PC_LIB_PRIV])
1481
1482 dnl
1483 dnl gbm configuration
1484 dnl
1485 if test "x$enable_gbm" = xauto; then
1486     case "$with_egl_platforms" in
1487         *drm*)
1488             enable_gbm=yes ;;
1489          *)
1490             enable_gbm=no ;;
1491     esac
1492 fi
1493 if test "x$enable_gbm" = xyes; then
1494     if test "x$need_pci_id$have_pci_id" = xyesno; then
1495         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1496     fi
1497
1498     if test "x$enable_dri" = xyes; then
1499         if test "x$enable_shared_glapi" = xno; then
1500             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1501         fi
1502     else
1503         # Strictly speaking libgbm does not require --enable-dri, although
1504         # both of its backends do. Thus one can build libgbm without any
1505         # backends if --disable-dri is set.
1506         # To avoid unnecessary complexity of checking if at least one backend
1507         # is available when building, just mandate --enable-dri.
1508         AC_MSG_ERROR([gbm requires --enable-dri])
1509     fi
1510 fi
1511 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1512 if test "x$need_pci_id$have_libudev" = xyesyes; then
1513     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1514 else
1515     GBM_PC_REQ_PRIV=""
1516 fi
1517 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1518 AC_SUBST([GBM_PC_REQ_PRIV])
1519 AC_SUBST([GBM_PC_LIB_PRIV])
1520
1521 AM_CONDITIONAL(HAVE_VULKAN, true)
1522
1523 AC_ARG_VAR([GLSLC], [Path to the glslc executable])
1524 AC_CHECK_PROGS([GLSLC], [glslc])
1525 AC_SUBST([GLSLC])
1526
1527 dnl
1528 dnl EGL configuration
1529 dnl
1530 EGL_CLIENT_APIS=""
1531
1532 if test "x$enable_egl" = xyes; then
1533     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1534
1535     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1536
1537     if test "$enable_static" != yes; then
1538         if test "x$enable_dri" = xyes; then
1539             HAVE_EGL_DRIVER_DRI2=1
1540             if test "x$enable_shared_glapi" = xno; then
1541                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1542             fi
1543         else
1544             # Avoid building an "empty" libEGL. Drop/update this
1545             # when other backends (haiku?) come along.
1546             AC_MSG_ERROR([egl requires --enable-dri])
1547         fi
1548
1549     fi
1550 fi
1551 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1552 AC_SUBST([EGL_LIB_DEPS])
1553
1554 dnl
1555 dnl XA configuration
1556 dnl
1557 if test "x$enable_xa" = xyes; then
1558     if test "x$with_gallium_drivers" = xswrast; then
1559        AC_MSG_ERROR([
1560           Building xa requires at least one non swrast gallium driver.
1561           If you are looking to use libxatracker.so with the VMware driver,
1562           make sure to include svga in the gallium drivers list, apart from
1563           enabling XA.
1564           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1565     fi
1566     enable_gallium_loader=$enable_shared_pipe_drivers
1567 fi
1568 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1569
1570 dnl
1571 dnl Gallium G3DVL configuration
1572 dnl
1573 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1574     if test "x$enable_xvmc" = xauto; then
1575         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1576     fi
1577
1578     if test "x$enable_vdpau" = xauto; then
1579         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1580     fi
1581
1582     if test "x$enable_omx" = xauto; then
1583         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1584     fi
1585
1586     if test "x$enable_va" = xauto; then
1587         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1588     fi
1589 fi
1590
1591 if test "x$enable_dri" = xyes -o \
1592         "x$enable_xvmc" = xyes -o \
1593         "x$enable_vdpau" = xyes -o \
1594         "x$enable_omx" = xyes -o \
1595         "x$enable_va" = xyes; then
1596     need_gallium_vl=yes
1597 fi
1598 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1599
1600 if test "x$enable_xvmc" = xyes -o \
1601         "x$enable_vdpau" = xyes -o \
1602         "x$enable_omx" = xyes -o \
1603         "x$enable_va" = xyes; then
1604     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1605     need_gallium_vl_winsys=yes
1606 fi
1607 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1608
1609 if test "x$enable_xvmc" = xyes; then
1610     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1611     enable_gallium_loader=$enable_shared_pipe_drivers
1612 fi
1613 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1614
1615 if test "x$enable_vdpau" = xyes; then
1616     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1617     enable_gallium_loader=$enable_shared_pipe_drivers
1618 fi
1619 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1620
1621 if test "x$enable_omx" = xyes; then
1622     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1623     enable_gallium_loader=$enable_shared_pipe_drivers
1624 fi
1625 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1626
1627 if test "x$enable_va" = xyes; then
1628     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1629     enable_gallium_loader=$enable_shared_pipe_drivers
1630 fi
1631 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1632
1633 dnl
1634 dnl Nine Direct3D9 configuration
1635 dnl
1636 if test "x$enable_nine" = xyes; then
1637     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1638         AC_MSG_ERROR([nine requires the gallium swrast driver])
1639     fi
1640     if test "x$with_gallium_drivers" = xswrast; then
1641         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1642     fi
1643     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1644         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1645     fi
1646
1647     if test "x$enable_dri3" = xno; then
1648         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1649     fi
1650
1651     enable_gallium_loader=$enable_shared_pipe_drivers
1652 fi
1653 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1654
1655 dnl
1656 dnl OpenCL configuration
1657 dnl
1658
1659 AC_ARG_WITH([clang-libdir],
1660    [AS_HELP_STRING([--with-clang-libdir],
1661          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1662    [CLANG_LIBDIR="$withval"],
1663    [CLANG_LIBDIR=''])
1664
1665 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1666 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1667
1668 if test "x$enable_opencl" = xyes; then
1669     if test -z "$with_gallium_drivers"; then
1670         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1671     fi
1672
1673     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1674         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1675     fi
1676
1677     if test "x$have_libclc" = xno; then
1678         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1679                     Make sure the directory containing libclc.pc is specified in your
1680                     PKG_CONFIG_PATH environment variable.
1681                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1682     else
1683         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1684         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1685         AC_SUBST([LIBCLC_INCLUDEDIR])
1686         AC_SUBST([LIBCLC_LIBEXECDIR])
1687     fi
1688
1689     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1690     enable_gallium_loader=yes
1691
1692     if test "x$enable_opencl_icd" = xyes; then
1693         OPENCL_LIBNAME="MesaOpenCL"
1694     else
1695         OPENCL_LIBNAME="OpenCL"
1696     fi
1697
1698     if test "x$have_libelf" != xyes; then
1699        AC_MSG_ERROR([Clover requires libelf])
1700     fi
1701 fi
1702 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1703 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1704 AC_SUBST([OPENCL_LIBNAME])
1705
1706 dnl
1707 dnl Gallium configuration
1708 dnl
1709 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1710
1711 AC_SUBST([LLVM_BINDIR])
1712 AC_SUBST([LLVM_CFLAGS])
1713 AC_SUBST([LLVM_CPPFLAGS])
1714 AC_SUBST([LLVM_CXXFLAGS])
1715 AC_SUBST([LLVM_LIBDIR])
1716 AC_SUBST([LLVM_LIBS])
1717 AC_SUBST([LLVM_LDFLAGS])
1718 AC_SUBST([LLVM_INCLUDEDIR])
1719 AC_SUBST([LLVM_VERSION])
1720 AC_SUBST([CLANG_RESOURCE_DIR])
1721
1722 case "x$enable_opengl$enable_gles1$enable_gles2" in
1723 x*yes*)
1724     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1725     ;;
1726 esac
1727
1728 AC_SUBST([VG_LIB_DEPS])
1729 AC_SUBST([EGL_CLIENT_APIS])
1730
1731 dnl
1732 dnl EGL Platforms configuration
1733 dnl
1734 AC_ARG_WITH([egl-platforms],
1735     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1736         [comma delimited native platforms libEGL supports, e.g.
1737         "x11,drm" @<:@default=auto@:>@])],
1738     [with_egl_platforms="$withval"],
1739     [if test "x$enable_egl" = xyes; then
1740         with_egl_platforms="x11"
1741     else
1742         with_egl_platforms=""
1743     fi])
1744
1745 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1746     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1747 fi
1748
1749 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1750         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1751         WAYLAND_SCANNER='')
1752 if test "x$WAYLAND_SCANNER" = x; then
1753     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1754 fi
1755
1756 # Do per-EGL platform setups and checks
1757 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1758 for plat in $egl_platforms; do
1759         case "$plat" in
1760         wayland)
1761                 test "x$have_libdrm" != xyes &&
1762                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1763
1764                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1765
1766                 if test "x$WAYLAND_SCANNER" = x; then
1767                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1768                 fi
1769                 ;;
1770
1771         x11)
1772                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1773                 ;;
1774
1775         drm)
1776                 test "x$enable_gbm" = "xno" &&
1777                         AC_MSG_ERROR([EGL platform drm needs gbm])
1778                 test "x$have_libdrm" != xyes &&
1779                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1780                 ;;
1781
1782         surfaceless)
1783                 test "x$have_libdrm" != xyes &&
1784                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1785                 ;;
1786
1787         *)
1788                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1789                 ;;
1790         esac
1791
1792         case "$plat$need_pci_id$have_pci_id" in
1793                 waylandyesno|drmyesno)
1794                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1795         esac
1796 done
1797
1798 # libEGL wants to default to the first platform specified in
1799 # ./configure.  parse that here.
1800 if test "x$egl_platforms" != "x"; then
1801     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1802     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1803 else
1804     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1805 fi
1806
1807 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1808 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1809 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1810 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1811 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1812
1813 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1814
1815 AC_SUBST([EGL_NATIVE_PLATFORM])
1816 AC_SUBST([EGL_CFLAGS])
1817
1818 # If we don't have the X11 platform, set this define so we don't try to include
1819 # the X11 headers.
1820 if ! echo "$egl_platforms" | grep -q 'x11'; then
1821     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1822     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1823 fi
1824
1825 dnl
1826 dnl Gallium LLVM
1827 dnl
1828 AC_ARG_ENABLE([gallium-llvm],
1829     [AS_HELP_STRING([--enable-gallium-llvm],
1830         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1831     [enable_gallium_llvm="$enableval"],
1832     [enable_gallium_llvm=auto])
1833
1834 AC_ARG_ENABLE([llvm-shared-libs],
1835     [AS_HELP_STRING([--enable-llvm-shared-libs],
1836         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1837     [enable_llvm_shared_libs="$enableval"],
1838     [enable_llvm_shared_libs=yes])
1839
1840 AC_ARG_WITH([llvm-prefix],
1841     [AS_HELP_STRING([--with-llvm-prefix],
1842         [Prefix for LLVM installations in non-standard locations])],
1843     [llvm_prefix="$withval"],
1844     [llvm_prefix=''])
1845
1846
1847 # Call this inside ` ` to get the return value.
1848 # $1 is the llvm-config command with arguments.
1849 strip_unwanted_llvm_flags() {
1850     # Use \> (marks the end of the word)
1851     echo `$1` | sed \
1852         -e 's/-DNDEBUG\>//g' \
1853         -e 's/-D_GNU_SOURCE\>//g' \
1854         -e 's/-pedantic\>//g' \
1855         -e 's/-Wcovered-switch-default\>//g' \
1856         -e 's/-O.\>//g' \
1857         -e 's/-g\>//g' \
1858         -e 's/-Wall\>//g' \
1859         -e 's/-Wcast-qual\>//g' \
1860         -e 's/-Woverloaded-virtual\>//g' \
1861         -e 's/-fcolor-diagnostics\>//g' \
1862         -e 's/-fdata-sections\>//g' \
1863         -e 's/-ffunction-sections\>//g' \
1864         -e 's/-fno-exceptions\>//g' \
1865         -e 's/-fomit-frame-pointer\>//g' \
1866         -e 's/-fvisibility-inlines-hidden\>//g' \
1867         -e 's/-fPIC\>//g' \
1868         -e 's/-fstack-protector-strong\>//g'
1869 }
1870
1871 llvm_check_version_for() {
1872     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1873         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1874     fi
1875 }
1876
1877
1878
1879 if test -z "$with_gallium_drivers"; then
1880     enable_gallium_llvm=no
1881 fi
1882 if test "x$enable_gallium_llvm" = xauto; then
1883     case "$host_cpu" in
1884     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1885     esac
1886 fi
1887 if test "x$enable_gallium_llvm" = xyes; then
1888     if test -n "$llvm_prefix"; then
1889         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1890     else
1891         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1892     fi
1893
1894     if test "x$LLVM_CONFIG" != xno; then
1895         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1896         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1897         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1898         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1899         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1900         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1901         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1902         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1903
1904         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1905             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1906         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1907             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1908
1909         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1910         if test -z "$LLVM_VERSION_PATCH"; then
1911             LLVM_VERSION_PATCH=0
1912         fi
1913
1914         if test -n "${LLVM_VERSION_MAJOR}"; then
1915             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1916         else
1917             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1918         fi
1919
1920         LLVM_REQUIRED_VERSION_MAJOR="3"
1921         LLVM_REQUIRED_VERSION_MINOR="3"
1922         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1923             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1924         fi
1925
1926         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1927
1928         if test "x$enable_opencl" = xyes; then
1929             llvm_check_version_for "3" "5" "0" "opencl"
1930
1931             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1932             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1933         fi
1934         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1935         MESA_LLVM=1
1936
1937         dnl Check for Clang internal headers
1938         if test "x$enable_opencl" = xyes; then
1939             if test -z "$CLANG_LIBDIR"; then
1940                 CLANG_LIBDIR=${LLVM_LIBDIR}
1941             fi
1942             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1943             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1944                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1945         fi
1946     else
1947         MESA_LLVM=0
1948         LLVM_VERSION_INT=0
1949     fi
1950 else
1951     MESA_LLVM=0
1952     LLVM_VERSION_INT=0
1953
1954     if test "x$enable_opencl" = xyes; then
1955         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1956     fi
1957 fi
1958
1959 dnl Directory for XVMC libs
1960 AC_ARG_WITH([xvmc-libdir],
1961     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1962         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1963     [XVMC_LIB_INSTALL_DIR="$withval"],
1964     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1965 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1966
1967 dnl
1968 dnl Gallium Tests
1969 dnl
1970 if test "x$enable_gallium_tests" = xyes; then
1971     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1972     enable_gallium_loader=yes
1973 fi
1974 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1975
1976 dnl Directory for VDPAU libs
1977 AC_ARG_WITH([vdpau-libdir],
1978     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1979         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1980     [VDPAU_LIB_INSTALL_DIR="$withval"],
1981     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1982 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1983
1984 dnl Directory for OMX libs
1985
1986 AC_ARG_WITH([omx-libdir],
1987     [AS_HELP_STRING([--with-omx-libdir=DIR],
1988         [directory for the OMX libraries])],
1989     [OMX_LIB_INSTALL_DIR="$withval"],
1990     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1991 AC_SUBST([OMX_LIB_INSTALL_DIR])
1992
1993 dnl Directory for VA libs
1994
1995 AC_ARG_WITH([va-libdir],
1996     [AS_HELP_STRING([--with-va-libdir=DIR],
1997         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
1998     [VA_LIB_INSTALL_DIR="$withval"],
1999     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2000 AC_SUBST([VA_LIB_INSTALL_DIR])
2001
2002 AC_ARG_WITH([d3d-libdir],
2003     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2004         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2005     [D3D_DRIVER_INSTALL_DIR="$withval"],
2006     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2007 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2008
2009 dnl
2010 dnl Gallium helper functions
2011 dnl
2012 gallium_require_drm() {
2013     if test "x$have_libdrm" != xyes; then
2014        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2015     fi
2016 }
2017
2018 gallium_require_llvm() {
2019     if test "x$MESA_LLVM" = x0; then
2020         case "$host" in *gnux32) return;; esac
2021         case "$host_cpu" in
2022         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2023         esac
2024     fi
2025 }
2026
2027 gallium_require_drm_loader() {
2028     if test "x$enable_gallium_loader" = xyes; then
2029         if test "x$need_pci_id$have_pci_id" = xyesno; then
2030             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2031         fi
2032         enable_gallium_drm_loader=yes
2033     fi
2034     if test "x$enable_va" = xyes && test "x$7" != x; then
2035          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2036     fi
2037 }
2038
2039 require_egl_drm() {
2040     case "$with_egl_platforms" in
2041         *drm*)
2042             ;;
2043          *)
2044             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2045             ;;
2046     esac
2047     if test "x$enable_gbm" != xyes; then
2048             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2049     fi
2050 }
2051
2052 radeon_llvm_check() {
2053     if test ${LLVM_VERSION_INT} -lt 307; then
2054         amdgpu_llvm_target_name='r600'
2055     else
2056         amdgpu_llvm_target_name='amdgpu'
2057     fi
2058     if test "x$enable_gallium_llvm" != "xyes"; then
2059         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2060     fi
2061     llvm_check_version_for "3" "4" "2" $1
2062     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2063         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2064     fi
2065     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2066     NEED_RADEON_LLVM=yes
2067     if test "x$have_libelf" != xyes; then
2068        AC_MSG_ERROR([$1 requires libelf when using llvm])
2069     fi
2070 }
2071
2072 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2073 if test -n "$with_gallium_drivers"; then
2074     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2075     for driver in $gallium_drivers; do
2076         case "x$driver" in
2077         xsvga)
2078             HAVE_GALLIUM_SVGA=yes
2079             gallium_require_drm "svga"
2080             gallium_require_drm_loader
2081             ;;
2082         xi915)
2083             HAVE_GALLIUM_I915=yes
2084             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2085             gallium_require_drm "Gallium i915"
2086             gallium_require_drm_loader
2087             ;;
2088         xilo)
2089             HAVE_GALLIUM_ILO=yes
2090             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2091             gallium_require_drm "Gallium i965/ilo"
2092             gallium_require_drm_loader
2093             ;;
2094         xr300)
2095             HAVE_GALLIUM_R300=yes
2096             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2097             gallium_require_drm "Gallium R300"
2098             gallium_require_drm_loader
2099             gallium_require_llvm "Gallium R300"
2100             ;;
2101         xr600)
2102             HAVE_GALLIUM_R600=yes
2103             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2104             gallium_require_drm "Gallium R600"
2105             gallium_require_drm_loader
2106             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2107                 radeon_llvm_check "r600g"
2108                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2109             fi
2110             if test "x$enable_r600_llvm" = xyes; then
2111                 USE_R600_LLVM_COMPILER=yes;
2112             fi
2113             if test "x$enable_opencl" = xyes; then
2114                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2115             fi
2116             ;;
2117         xradeonsi)
2118             HAVE_GALLIUM_RADEONSI=yes
2119             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2120             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2121             gallium_require_drm "radeonsi"
2122             gallium_require_drm_loader
2123             radeon_llvm_check "radeonsi"
2124             require_egl_drm "radeonsi"
2125             ;;
2126         xnouveau)
2127             HAVE_GALLIUM_NOUVEAU=yes
2128             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2129             gallium_require_drm "nouveau"
2130             gallium_require_drm_loader
2131             ;;
2132         xfreedreno)
2133             HAVE_GALLIUM_FREEDRENO=yes
2134             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2135             gallium_require_drm "freedreno"
2136             gallium_require_drm_loader
2137             ;;
2138         xswrast)
2139             HAVE_GALLIUM_SOFTPIPE=yes
2140             if test "x$MESA_LLVM" = x1; then
2141                 HAVE_GALLIUM_LLVMPIPE=yes
2142             fi
2143             ;;
2144         xvc4)
2145             HAVE_GALLIUM_VC4=yes
2146             gallium_require_drm "vc4"
2147             gallium_require_drm_loader
2148
2149             case "$host_cpu" in
2150                 i?86 | x86_64 | amd64)
2151                 USE_VC4_SIMULATOR=yes
2152                 ;;
2153             esac
2154             ;;
2155         *)
2156             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2157             ;;
2158         esac
2159     done
2160 fi
2161
2162 dnl Set LLVM_LIBS - This is done after the driver configuration so
2163 dnl that drivers can add additional components to LLVM_COMPONENTS.
2164 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2165 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2166 dnl this was causing the same libraries to be appear multiple times
2167 dnl in LLVM_LIBS.
2168
2169 if test "x$MESA_LLVM" != x0; then
2170
2171     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2172
2173     if test "x$enable_llvm_shared_libs" = xyes; then
2174         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2175         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2176         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2177
2178         if test "x$llvm_have_one_so" = xyes; then
2179             dnl LLVM was built using auto*, so there is only one shared object.
2180             LLVM_LIBS="-l$LLVM_SO_NAME"
2181         else
2182             dnl If LLVM was built with CMake, there will be one shared object per
2183             dnl component.
2184             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2185                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2186         Please make sure you have built llvm with the --enable-shared option
2187         and that your llvm libraries are installed in $LLVM_LIBDIR
2188         If you have installed your llvm libraries to a different directory you
2189         can use the --with-llvm-prefix= configure flag to specify this directory.
2190         NOTE: Mesa is attempting to use llvm shared libraries by default.
2191         If you do not want to build with llvm shared libraries and instead want to
2192         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2193         invocation and rebuild.])])
2194
2195            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2196            dnl install uses a shared object for each component and we have
2197            dnl already added all of these objects to LLVM_LIBS.
2198         fi
2199     else
2200         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2201         dnl We need to link to llvm system libs when using static libs
2202         dnl However, only llvm 3.5+ provides --system-libs
2203         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2204             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2205         fi
2206     fi
2207 fi
2208
2209 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2210 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2211 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2212 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2213 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2214 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2215 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2216                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2217 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2218 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2219 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2220 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2221 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2222
2223 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2224
2225 # NOTE: anything using xcb or other client side libs ends up in separate
2226 #       _CLIENT variables.  The pipe loader is built in two variants,
2227 #       one that is standalone and does not link any x client libs (for
2228 #       use by XA tracker in particular, but could be used in any case
2229 #       where communication with xserver is not desired).
2230 if test "x$enable_gallium_loader" = xyes; then
2231     if test "x$enable_dri" = xyes; then
2232         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2233     fi
2234
2235     if test "x$enable_gallium_drm_loader" = xyes; then
2236         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2237     fi
2238
2239     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2240 fi
2241
2242 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2243 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2244 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2245 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2246 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2247 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2248
2249 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2250                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2251                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2252 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2253 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2254 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2255 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2256 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2257 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2258 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2259 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2260 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2261     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2262 fi
2263
2264 AC_SUBST([ELF_LIB])
2265
2266 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2267 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2268 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2269 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2270
2271 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2272 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2273 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2274
2275 AC_SUBST([NINE_MAJOR], 1)
2276 AC_SUBST([NINE_MINOR], 0)
2277 AC_SUBST([NINE_TINY], 0)
2278 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2279
2280 AC_SUBST([VDPAU_MAJOR], 1)
2281 AC_SUBST([VDPAU_MINOR], 0)
2282
2283 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2284 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2285 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2286 AC_SUBST([VA_MINOR], $VA_MINOR)
2287
2288 AC_SUBST([XVMC_MAJOR], 1)
2289 AC_SUBST([XVMC_MINOR], 0)
2290
2291 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2292 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2293 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2294 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2295
2296 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2297 AC_SUBST([XA_MINOR], $XA_MINOR)
2298 AC_SUBST([XA_TINY], $XA_TINY)
2299 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2300
2301 PKG_CHECK_MODULES(VALGRIND, [valgrind],
2302                   [have_valgrind=yes], [have_valgrind=no])
2303 if test "x$have_valgrind" = "xyes"; then
2304     AC_DEFINE([HAVE_VALGRIND], 1,
2305               [Use valgrind intrinsics to suppress false warnings])
2306 fi
2307
2308 dnl Restore LDFLAGS and CPPFLAGS
2309 LDFLAGS="$_SAVE_LDFLAGS"
2310 CPPFLAGS="$_SAVE_CPPFLAGS"
2311
2312 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2313 if test "x$acv_mesa_CLANG" = xyes; then
2314     CFLAGS="$CFLAGS -Qunused-arguments"
2315     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2316 fi
2317
2318 dnl Add user CFLAGS and CXXFLAGS
2319 CFLAGS="$CFLAGS $USER_CFLAGS"
2320 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2321
2322 dnl Substitute the config
2323 AC_CONFIG_FILES([Makefile
2324                 src/Makefile
2325                 src/egl/Makefile
2326                 src/egl/main/egl.pc
2327                 src/egl/wayland/wayland-drm/Makefile
2328                 src/egl/wayland/wayland-egl/Makefile
2329                 src/egl/wayland/wayland-egl/wayland-egl.pc
2330                 src/gallium/Makefile
2331                 src/gallium/auxiliary/Makefile
2332                 src/gallium/auxiliary/pipe-loader/Makefile
2333                 src/gallium/drivers/freedreno/Makefile
2334                 src/gallium/drivers/ddebug/Makefile
2335                 src/gallium/drivers/i915/Makefile
2336                 src/gallium/drivers/ilo/Makefile
2337                 src/gallium/drivers/llvmpipe/Makefile
2338                 src/gallium/drivers/noop/Makefile
2339                 src/gallium/drivers/nouveau/Makefile
2340                 src/gallium/drivers/r300/Makefile
2341                 src/gallium/drivers/r600/Makefile
2342                 src/gallium/drivers/radeon/Makefile
2343                 src/gallium/drivers/radeonsi/Makefile
2344                 src/gallium/drivers/rbug/Makefile
2345                 src/gallium/drivers/softpipe/Makefile
2346                 src/gallium/drivers/svga/Makefile
2347                 src/gallium/drivers/trace/Makefile
2348                 src/gallium/drivers/vc4/Makefile
2349                 src/gallium/state_trackers/clover/Makefile
2350                 src/gallium/state_trackers/dri/Makefile
2351                 src/gallium/state_trackers/glx/xlib/Makefile
2352                 src/gallium/state_trackers/nine/Makefile
2353                 src/gallium/state_trackers/omx/Makefile
2354                 src/gallium/state_trackers/osmesa/Makefile
2355                 src/gallium/state_trackers/va/Makefile
2356                 src/gallium/state_trackers/vdpau/Makefile
2357                 src/gallium/state_trackers/xa/Makefile
2358                 src/gallium/state_trackers/xvmc/Makefile
2359                 src/gallium/targets/d3dadapter9/Makefile
2360                 src/gallium/targets/d3dadapter9/d3d.pc
2361                 src/gallium/targets/dri/Makefile
2362                 src/gallium/targets/libgl-xlib/Makefile
2363                 src/gallium/targets/omx/Makefile
2364                 src/gallium/targets/opencl/Makefile
2365                 src/gallium/targets/opencl/mesa.icd
2366                 src/gallium/targets/osmesa/Makefile
2367                 src/gallium/targets/osmesa/osmesa.pc
2368                 src/gallium/targets/pipe-loader/Makefile
2369                 src/gallium/targets/va/Makefile
2370                 src/gallium/targets/vdpau/Makefile
2371                 src/gallium/targets/xa/Makefile
2372                 src/gallium/targets/xa/xatracker.pc
2373                 src/gallium/targets/xvmc/Makefile
2374                 src/gallium/tests/trivial/Makefile
2375                 src/gallium/tests/unit/Makefile
2376                 src/gallium/winsys/freedreno/drm/Makefile
2377                 src/gallium/winsys/i915/drm/Makefile
2378                 src/gallium/winsys/intel/drm/Makefile
2379                 src/gallium/winsys/nouveau/drm/Makefile
2380                 src/gallium/winsys/radeon/drm/Makefile
2381                 src/gallium/winsys/amdgpu/drm/Makefile
2382                 src/gallium/winsys/svga/drm/Makefile
2383                 src/gallium/winsys/sw/dri/Makefile
2384                 src/gallium/winsys/sw/kms-dri/Makefile
2385                 src/gallium/winsys/sw/null/Makefile
2386                 src/gallium/winsys/sw/wrapper/Makefile
2387                 src/gallium/winsys/sw/xlib/Makefile
2388                 src/gallium/winsys/vc4/drm/Makefile
2389                 src/gbm/Makefile
2390                 src/gbm/main/gbm.pc
2391                 src/glsl/Makefile
2392                 src/glx/Makefile
2393                 src/glx/apple/Makefile
2394                 src/glx/tests/Makefile
2395                 src/gtest/Makefile
2396                 src/loader/Makefile
2397                 src/mapi/Makefile
2398                 src/mapi/es1api/glesv1_cm.pc
2399                 src/mapi/es2api/glesv2.pc
2400                 src/mapi/glapi/gen/Makefile
2401                 src/mesa/Makefile
2402                 src/mesa/gl.pc
2403                 src/mesa/drivers/dri/dri.pc
2404                 src/mesa/drivers/dri/common/Makefile
2405                 src/mesa/drivers/dri/common/xmlpool/Makefile
2406                 src/mesa/drivers/dri/i915/Makefile
2407                 src/mesa/drivers/dri/i965/Makefile
2408                 src/mesa/drivers/dri/Makefile
2409                 src/mesa/drivers/dri/nouveau/Makefile
2410                 src/mesa/drivers/dri/r200/Makefile
2411                 src/mesa/drivers/dri/radeon/Makefile
2412                 src/mesa/drivers/dri/swrast/Makefile
2413                 src/mesa/drivers/osmesa/Makefile
2414                 src/mesa/drivers/osmesa/osmesa.pc
2415                 src/mesa/drivers/x11/Makefile
2416                 src/mesa/main/tests/Makefile
2417                 src/vulkan/Makefile
2418                 src/vulkan/anv_icd.json
2419                 src/vulkan/tests/Makefile
2420                 src/util/Makefile
2421                 src/util/tests/hash_table/Makefile])
2422
2423 AC_OUTPUT
2424
2425 dnl
2426 dnl Output some configuration info for the user
2427 dnl
2428 echo ""
2429 echo "        prefix:          $prefix"
2430 echo "        exec_prefix:     $exec_prefix"
2431 echo "        libdir:          $libdir"
2432 echo "        includedir:      $includedir"
2433
2434 dnl API info
2435 echo ""
2436 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2437
2438 dnl Driver info
2439 echo ""
2440 case "x$enable_osmesa$enable_gallium_osmesa" in
2441 xnoyes)
2442         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2443         ;;
2444 xyesno)
2445         echo "        OSMesa:          lib$OSMESA_LIB"
2446         ;;
2447 xnono)
2448         echo "        OSMesa:          no"
2449         ;;
2450 esac
2451
2452 echo ""
2453 if test "x$enable_dri" != xno; then
2454         echo "        DRI platform:    $dri_platform"
2455         if test -z "$DRI_DIRS"; then
2456             echo "        DRI drivers:     no"
2457         else
2458             echo "        DRI drivers:     $DRI_DIRS"
2459         fi
2460         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2461 fi
2462
2463 case "x$enable_glx$enable_xlib_glx" in
2464 xyesyes)
2465     echo "        GLX:             Xlib-based"
2466     ;;
2467 xyesno)
2468     echo "        GLX:             DRI-based"
2469     ;;
2470 *)
2471     echo "        GLX:             $enable_glx"
2472     ;;
2473 esac
2474
2475 dnl EGL
2476 echo ""
2477 echo "        EGL:             $enable_egl"
2478 if test "$enable_egl" = yes; then
2479     echo "        EGL platforms:   $egl_platforms"
2480
2481     egl_drivers=""
2482     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2483         egl_drivers="$egl_drivers builtin:egl_dri2"
2484     fi
2485
2486     echo "        EGL drivers:    $egl_drivers"
2487 fi
2488
2489 echo ""
2490 if test "x$MESA_LLVM" = x1; then
2491     echo "        llvm:            yes"
2492     echo "        llvm-config:     $LLVM_CONFIG"
2493     echo "        llvm-version:    $LLVM_VERSION"
2494 else
2495     echo "        llvm:            no"
2496 fi
2497
2498 echo ""
2499 if test -n "$with_gallium_drivers"; then
2500     echo "        Gallium:         yes"
2501 else
2502     echo "        Gallium:         no"
2503 fi
2504
2505 dnl Shader cache
2506 echo ""
2507 echo "        Shader cache:    $enable_shader_cache"
2508 if test "x$enable_shader_cache" = "xyes"; then
2509     echo "        With SHA1 from:  $with_sha1"
2510 fi
2511
2512 dnl Libraries
2513 echo ""
2514 echo "        Shared libs:     $enable_shared"
2515 echo "        Static libs:     $enable_static"
2516 echo "        Shared-glapi:    $enable_shared_glapi"
2517
2518 dnl Compiler options
2519 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2520 cflags=`echo $CFLAGS | \
2521     $SED 's/^ *//;s/  */ /;s/ *$//'`
2522 cxxflags=`echo $CXXFLAGS | \
2523     $SED 's/^ *//;s/  */ /;s/ *$//'`
2524 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2525 echo ""
2526 echo "        CFLAGS:          $cflags"
2527 echo "        CXXFLAGS:        $cxxflags"
2528 echo "        Macros:          $defines"
2529 echo ""
2530 if test "x$MESA_LLVM" = x1; then
2531     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2532     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2533     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2534     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2535     echo ""
2536 fi
2537 echo "        PYTHON2:         $PYTHON2"
2538 echo "        PYTHON3:         $PYTHON3"
2539
2540 echo ""
2541 echo "        Run '${MAKE-make}' to build Mesa"
2542 echo ""