configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz])
  48
  49 # Support silent build rules, requires at least automake-1.11. Disable
  50 # by either passing --disable-silent-rules to configure or passing V=1
  51 # to make
  52 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  53     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  54
  55 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  56
  57 dnl Set internal versions
  58 OSMESA_VERSION=8
  59 AC_SUBST([OSMESA_VERSION])
  60
  61 dnl Versions for external dependencies
  62 LIBDRM_REQUIRED=2.4.38
  63 LIBDRM_RADEON_REQUIRED=2.4.56
  64 LIBDRM_INTEL_REQUIRED=2.4.52
  65 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  66 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  67 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  68 DRI2PROTO_REQUIRED=2.6
  69 DRI3PROTO_REQUIRED=1.0
  70 PRESENTPROTO_REQUIRED=1.0
  71 LIBUDEV_REQUIRED=151
  72 GLPROTO_REQUIRED=1.4.14
  73 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  74 LIBVA_REQUIRED=0.35.0
  75 VDPAU_REQUIRED=0.4.1
  76 WAYLAND_REQUIRED=1.2.0
  77 XCB_REQUIRED=1.9.3
  78 XCBDRI2_REQUIRED=1.8
  79 XCBGLX_REQUIRED=1.8.1
  80 XSHMFENCE_REQUIRED=1.1
  81 XVMC_REQUIRED=1.0.6
  82 PYTHON_MAKO_REQUIRED=0.3.4
  83
  84 dnl Check for progs
  85 AC_PROG_CPP
  86 AC_PROG_CC
  87 AC_PROG_CXX
  88 AM_PROG_CC_C_O
  89 AM_PROG_AS
  90 AX_CHECK_GNU_MAKE
  91 AC_CHECK_PROGS([PYTHON2], [python2 python])
  92 AC_PROG_SED
  93 AC_PROG_MKDIR_P
  94
  95 AC_SYS_LARGEFILE
  96
  97 LT_PREREQ([2.2])
  98 LT_INIT([disable-static])
  99
 100 AX_PROG_BISON([],
 101               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 102                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 103 AX_PROG_FLEX([],
 104              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 105                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 106
 107 AC_CHECK_PROG(INDENT, indent, indent, cat)
 108 if test "x$INDENT" != "xcat"; then
 109     # Only GNU indent is supported
 110     INDENT_VERSION=`indent --version | grep GNU`
 111     if test $? -eq 0; then
 112        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 113     else
 114        INDENT="cat"
 115     fi
 116 fi
 117
 118 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 119 if test -n "$PYTHON2" -a "x$acv_mako_found" = "xyes"; then
 120     AC_MSG_RESULT(yes)
 121 else
 122     AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 123 fi
 124
 125 AC_PROG_INSTALL
 126
 127 dnl We need a POSIX shell for parts of the build. Assume we have one
 128 dnl in most cases.
 129 case "$host_os" in
 130 solaris*)
 131     # Solaris /bin/sh is too old/non-POSIX compliant
 132     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 133     SHELL="$POSIX_SHELL"
 134     ;;
 135 esac
 136
 137 dnl clang is mostly GCC-compatible, but its version is much lower,
 138 dnl so we have to check for it.
 139 AC_MSG_CHECKING([if compiling with clang])
 140
 141 AC_COMPILE_IFELSE(
 142 [AC_LANG_PROGRAM([], [[
 143 #ifndef __clang__
 144        not clang
 145 #endif
 146 ]])],
 147 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 148
 149 AC_MSG_RESULT([$acv_mesa_CLANG])
 150
 151 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 152 dnl versions are explictly not supported.
 153 GEN_ASM_OFFSETS=no
 154 USE_GNU99=no
 155 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 156     AC_MSG_CHECKING([whether gcc version is sufficient])
 157     major=0
 158     minor=0
 159
 160     GCC_VERSION=`$CC -dumpversion`
 161     if test $? -eq 0; then
 162         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 163         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 164     fi
 165
 166     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 167         AC_MSG_RESULT([no])
 168         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 169     else
 170         AC_MSG_RESULT([yes])
 171     fi
 172
 173     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 174         USE_GNU99=yes
 175     fi
 176     if test "x$cross_compiling" = xyes; then
 177         GEN_ASM_OFFSETS=yes
 178     fi
 179 fi
 180
 181 dnl Check for compiler builtins
 182 AX_GCC_BUILTIN([__builtin_bswap32])
 183 AX_GCC_BUILTIN([__builtin_bswap64])
 184 AX_GCC_BUILTIN([__builtin_clz])
 185 AX_GCC_BUILTIN([__builtin_clzll])
 186 AX_GCC_BUILTIN([__builtin_ctz])
 187 AX_GCC_BUILTIN([__builtin_expect])
 188 AX_GCC_BUILTIN([__builtin_ffs])
 189 AX_GCC_BUILTIN([__builtin_ffsll])
 190 AX_GCC_BUILTIN([__builtin_popcount])
 191 AX_GCC_BUILTIN([__builtin_popcountll])
 192 AX_GCC_BUILTIN([__builtin_unreachable])
 193
 194 AX_GCC_FUNC_ATTRIBUTE([flatten])
 195 AX_GCC_FUNC_ATTRIBUTE([format])
 196 AX_GCC_FUNC_ATTRIBUTE([malloc])
 197 AX_GCC_FUNC_ATTRIBUTE([packed])
 198
 199 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 200
 201 dnl Make sure the pkg-config macros are defined
 202 m4_ifndef([PKG_PROG_PKG_CONFIG],
 203     [m4_fatal([Could not locate the pkg-config autoconf macros.
 204   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 205   are in a different location, try setting the environment variable
 206   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 207 PKG_PROG_PKG_CONFIG()
 208
 209 dnl LIB_DIR - library basename
 210 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 211 AC_SUBST([LIB_DIR])
 212
 213 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 214 _SAVE_LDFLAGS="$LDFLAGS"
 215 _SAVE_CPPFLAGS="$CPPFLAGS"
 216
 217 dnl Compiler macros
 218 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 219 AC_SUBST([DEFINES])
 220 case "$host_os" in
 221 linux*|*-gnu*|gnu*)
 222     DEFINES="$DEFINES -D_GNU_SOURCE"
 223     ;;
 224 solaris*)
 225     DEFINES="$DEFINES -DSVR4"
 226     ;;
 227 cygwin*)
 228     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 229     ;;
 230 esac
 231
 232 dnl Add flags for gcc and g++
 233 if test "x$GCC" = xyes; then
 234     CFLAGS="$CFLAGS -Wall"
 235
 236     if test "x$USE_GNU99" = xyes; then
 237         CFLAGS="$CFLAGS -std=gnu99"
 238     else
 239         CFLAGS="$CFLAGS -std=c99"
 240     fi
 241
 242     # Enable -Werror=implicit-function-declaration and
 243     # -Werror=missing-prototypes, if available, or otherwise, just
 244     # -Wmissing-prototypes.  This is particularly useful to avoid
 245     # generating a loadable driver module that has undefined symbols.
 246     save_CFLAGS="$CFLAGS"
 247     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 248     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 249     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 250     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 251                    AC_MSG_RESULT([yes]),
 252                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 253                     AC_MSG_RESULT([no])]);
 254
 255     # Enable -fvisibility=hidden if using a gcc that supports it
 256     save_CFLAGS="$CFLAGS"
 257     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 258     VISIBILITY_CFLAGS="-fvisibility=hidden"
 259     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 260     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 261                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 262
 263     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 264     CFLAGS=$save_CFLAGS
 265
 266     # Work around aliasing bugs - developers should comment this out
 267     CFLAGS="$CFLAGS -fno-strict-aliasing"
 268
 269     # gcc's builtin memcmp is slower than glibc's
 270     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 271     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 272
 273     # Flags to help ensure that certain portions of the code -- and only those
 274     # portions -- can be built with MSVC:
 275     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 276     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 277     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 278     #   supports most of C99)
 279     # - the rest has no compiler compiler restrictions
 280     MSVC2013_COMPAT_CFLAGS="-Werror=vla -Werror=pointer-arith"
 281     MSVC2013_COMPAT_CXXFLAGS="-Werror=vla -Werror=pointer-arith"
 282     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 283     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 284 fi
 285 if test "x$GXX" = xyes; then
 286     CXXFLAGS="$CXXFLAGS -Wall"
 287
 288     # Enable -fvisibility=hidden if using a gcc that supports it
 289     save_CXXFLAGS="$CXXFLAGS"
 290     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 291     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 292     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 293     AC_LANG_PUSH([C++])
 294     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 295                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 296     AC_LANG_POP([C++])
 297
 298     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 299     CXXFLAGS=$save_CXXFLAGS
 300
 301     # Work around aliasing bugs - developers should comment this out
 302     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 303
 304     # gcc's builtin memcmp is slower than glibc's
 305     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 306     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 307 fi
 308
 309 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 310 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 311 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 312 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 313
 314 dnl even if the compiler appears to support it, using visibility attributes isn't
 315 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 316 case "$host_os" in
 317 cygwin*)
 318     VISIBILITY_CFLAGS=""
 319     VISIBILITY_CXXFLAGS=""
 320     ;;
 321 esac
 322
 323 AC_SUBST([VISIBILITY_CFLAGS])
 324 AC_SUBST([VISIBILITY_CXXFLAGS])
 325
 326 dnl
 327 dnl Optional flags, check for compiler support
 328 dnl
 329 SSE41_CFLAGS="-msse4.1"
 330 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 331 dnl stack, but on x86-32 such alignment is not guaranteed.
 332 case "$target_cpu" in
 333 i?86)
 334     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 335     ;;
 336 esac
 337 save_CFLAGS="$CFLAGS"
 338 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 339 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 340 #include <smmintrin.h>
 341 int main () {
 342     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 343     c = _mm_max_epu32(a, b);
 344     return 0;
 345 }]])], SSE41_SUPPORTED=1)
 346 CFLAGS="$save_CFLAGS"
 347 if test "x$SSE41_SUPPORTED" = x1; then
 348     DEFINES="$DEFINES -DUSE_SSE41"
 349 fi
 350 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 351 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 352
 353 dnl Can't have static and shared libraries, default to static if user
 354 dnl explicitly requested. If both disabled, set to static since shared
 355 dnl was explicitly requested.
 356 case "x$enable_static$enable_shared" in
 357 xyesyes)
 358     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 359     enable_shared=no
 360     ;;
 361 xnono)
 362     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 363     enable_shared=yes
 364     ;;
 365 esac
 366
 367 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 368
 369 dnl
 370 dnl other compiler options
 371 dnl
 372 AC_ARG_ENABLE([debug],
 373     [AS_HELP_STRING([--enable-debug],
 374         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 375     [enable_debug="$enableval"],
 376     [enable_debug=no]
 377 )
 378 if test "x$enable_debug" = xyes; then
 379     DEFINES="$DEFINES -DDEBUG"
 380     if test "x$GCC" = xyes; then
 381         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 382             CFLAGS="$CFLAGS -g"
 383         fi
 384         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 385             CFLAGS="$CFLAGS -O0"
 386         fi
 387     fi
 388     if test "x$GXX" = xyes; then
 389         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 390             CXXFLAGS="$CXXFLAGS -g"
 391         fi
 392         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 393             CXXFLAGS="$CXXFLAGS -O0"
 394         fi
 395     fi
 396 else
 397    DEFINES="$DEFINES -DNDEBUG"
 398 fi
 399
 400 dnl
 401 dnl Check if linker supports -Bsymbolic
 402 dnl
 403 save_LDFLAGS=$LDFLAGS
 404 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 405 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 406 AC_LINK_IFELSE(
 407     [AC_LANG_SOURCE([int main() { return 0;}])],
 408     [AC_MSG_RESULT([yes])
 409         BSYMBOLIC="-Wl,-Bsymbolic";],
 410     [AC_MSG_RESULT([no])
 411         BSYMBOLIC="";])
 412 LDFLAGS=$save_LDFLAGS
 413
 414 AC_SUBST([BSYMBOLIC])
 415
 416 dnl
 417 dnl Check if linker supports garbage collection
 418 dnl
 419 save_LDFLAGS=$LDFLAGS
 420 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 421 AC_MSG_CHECKING([whether ld supports --gc-sections])
 422 AC_LINK_IFELSE(
 423     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 424     [AC_MSG_RESULT([yes])
 425         GC_SECTIONS="-Wl,--gc-sections";],
 426     [AC_MSG_RESULT([no])
 427         GC_SECTIONS="";])
 428 LDFLAGS=$save_LDFLAGS
 429
 430 AC_SUBST([GC_SECTIONS])
 431
 432 dnl
 433 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 434 dnl so when these flags are passed to ld via libtool the checks will fail
 435 dnl
 436 case "$host_os" in
 437 openbsd* | darwin* )
 438     LD_NO_UNDEFINED="" ;;
 439 *)
 440     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 441 esac
 442
 443 AC_SUBST([LD_NO_UNDEFINED])
 444
 445 dnl
 446 dnl Check if linker supports version scripts
 447 dnl
 448 AC_MSG_CHECKING([if the linker supports version-scripts])
 449 save_LDFLAGS=$LDFLAGS
 450 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 451 cat > conftest.map <<EOF
 452 VERSION_1 {
 453      global:
 454          main;
 455
 456      local:
 457          *;
 458 };
 459 EOF
 460 AC_LINK_IFELSE(
 461     [AC_LANG_SOURCE([int main() { return 0;}])],
 462     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 463     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 464 LDFLAGS=$save_LDFLAGS
 465 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 466
 467 dnl
 468 dnl Check if linker supports dynamic list files
 469 dnl
 470 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 471 save_LDFLAGS=$LDFLAGS
 472 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 473 cat > conftest.dyn <<EOF
 474 {
 475         radeon_drm_winsys_create;
 476 };
 477 EOF
 478 AC_LINK_IFELSE(
 479     [AC_LANG_SOURCE([int main() { return 0;}])],
 480     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 481     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 482 LDFLAGS=$save_LDFLAGS
 483 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 484
 485 dnl
 486 dnl compatibility symlinks
 487 dnl
 488 case "$host_os" in
 489 linux* )
 490     HAVE_COMPAT_SYMLINKS=yes ;;
 491 * )
 492     HAVE_COMPAT_SYMLINKS=no ;;
 493 esac
 494
 495 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 496
 497 dnl
 498 dnl library names
 499 dnl
 500 case "$host_os" in
 501 darwin* )
 502     LIB_EXT='dylib' ;;
 503 cygwin* )
 504     LIB_EXT='dll' ;;
 505 aix* )
 506     LIB_EXT='a' ;;
 507 * )
 508     LIB_EXT='so' ;;
 509 esac
 510
 511 AC_SUBST([LIB_EXT])
 512
 513 AC_ARG_WITH([gl-lib-name],
 514   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 515     [specify GL library name @<:@default=GL@:>@])],
 516   [GL_LIB=$withval],
 517   [GL_LIB=GL])
 518 AC_ARG_WITH([osmesa-lib-name],
 519   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 520     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 521   [OSMESA_LIB=$withval],
 522   [OSMESA_LIB=OSMesa])
 523 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 524 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 525
 526 dnl
 527 dnl Mangled Mesa support
 528 dnl
 529 AC_ARG_ENABLE([mangling],
 530   [AS_HELP_STRING([--enable-mangling],
 531     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 532   [enable_mangling="${enableval}"],
 533   [enable_mangling=no]
 534 )
 535 if test "x${enable_mangling}" = "xyes" ; then
 536   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 537   GL_LIB="Mangled${GL_LIB}"
 538   OSMESA_LIB="Mangled${OSMESA_LIB}"
 539 fi
 540 AC_SUBST([GL_LIB])
 541 AC_SUBST([OSMESA_LIB])
 542
 543 dnl
 544 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 545 dnl
 546 AC_ARG_ENABLE([texture-float],
 547     [AS_HELP_STRING([--enable-texture-float],
 548         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 549     [enable_texture_float="$enableval"],
 550     [enable_texture_float=no]
 551 )
 552 if test "x$enable_texture_float" = xyes; then
 553     AC_MSG_WARN([Floating-point textures enabled.])
 554     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 555     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 556 fi
 557
 558 dnl
 559 dnl Arch/platform-specific settings
 560 dnl
 561 AC_ARG_ENABLE([asm],
 562     [AS_HELP_STRING([--disable-asm],
 563         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 564     [enable_asm="$enableval"],
 565     [enable_asm=yes]
 566 )
 567 asm_arch=""
 568 AC_MSG_CHECKING([whether to enable assembly])
 569 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 570 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 571 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 572     case "$host_cpu" in
 573     i?86 | x86_64 | amd64)
 574         enable_asm=no
 575         AC_MSG_RESULT([no, cross compiling])
 576         ;;
 577     esac
 578 fi
 579 # check for supported arches
 580 if test "x$enable_asm" = xyes; then
 581     case "$host_cpu" in
 582     i?86)
 583         case "$host_os" in
 584         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 585             asm_arch=x86
 586             ;;
 587         esac
 588         ;;
 589     x86_64|amd64)
 590         case "$host_os" in
 591         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 592             asm_arch=x86_64
 593             ;;
 594         esac
 595         ;;
 596     sparc*)
 597         case "$host_os" in
 598         linux*)
 599             asm_arch=sparc
 600             ;;
 601         esac
 602         ;;
 603     esac
 604
 605     case "$asm_arch" in
 606     x86)
 607         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 608         AC_MSG_RESULT([yes, x86])
 609         ;;
 610     x86_64|amd64)
 611         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 612         AC_MSG_RESULT([yes, x86_64])
 613         ;;
 614     sparc)
 615         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 616         AC_MSG_RESULT([yes, sparc])
 617         ;;
 618     *)
 619         AC_MSG_RESULT([no, platform not supported])
 620         ;;
 621     esac
 622 fi
 623
 624 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 625 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 626
 627 dnl Check to see if dlopen is in default libraries (like Solaris, which
 628 dnl has it in libc), or if libdl is needed to get it.
 629 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 630     [AC_CHECK_LIB([dl], [dlopen],
 631        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 632 AC_SUBST([DLOPEN_LIBS])
 633
 634 dnl Check if that library also has dladdr
 635 save_LIBS="$LIBS"
 636 LIBS="$LIBS $DLOPEN_LIBS"
 637 AC_CHECK_FUNCS([dladdr])
 638 LIBS="$save_LIBS"
 639
 640 case "$host_os" in
 641 darwin*|mingw*)
 642     ;;
 643 *)
 644     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 645                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 646                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 647     AC_SUBST([CLOCK_LIB])
 648     ;;
 649 esac
 650
 651 dnl See if posix_memalign is available
 652 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 653
 654 dnl Check for pthreads
 655 case "$host_os" in
 656 mingw*)
 657     ;;
 658 *)
 659     AX_PTHREAD
 660     if test "x$ax_pthread_ok" = xno; then
 661         AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 662     fi
 663     ;;
 664 esac
 665 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 666 dnl to -pthread, which causes problems if we need -lpthread to appear in
 667 dnl pkgconfig files.
 668 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 669
 670 dnl SELinux awareness.
 671 AC_ARG_ENABLE([selinux],
 672     [AS_HELP_STRING([--enable-selinux],
 673         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 674     [MESA_SELINUX="$enableval"],
 675     [MESA_SELINUX=no])
 676 if test "x$enable_selinux" = "xyes"; then
 677     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 678         [AC_CHECK_HEADER([selinux/selinux.h],[],
 679                          [AC_MSG_ERROR([SELinux headers not found])])
 680          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 681                       [AC_MSG_ERROR([SELinux library not found])])
 682          SELINUX_LIBS="-lselinux"])
 683     DEFINES="$DEFINES -DMESA_SELINUX"
 684 fi
 685 AC_SUBST([SELINUX_CFLAGS])
 686 AC_SUBST([SELINUX_LIBS])
 687
 688 dnl Options for APIs
 689 AC_ARG_ENABLE([opengl],
 690     [AS_HELP_STRING([--disable-opengl],
 691         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 692     [enable_opengl="$enableval"],
 693     [enable_opengl=yes])
 694 AC_ARG_ENABLE([gles1],
 695     [AS_HELP_STRING([--enable-gles1],
 696         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 697     [enable_gles1="$enableval"],
 698     [enable_gles1=no])
 699 AC_ARG_ENABLE([gles2],
 700     [AS_HELP_STRING([--enable-gles2],
 701         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 702     [enable_gles2="$enableval"],
 703     [enable_gles2=no])
 704
 705 AC_ARG_ENABLE([dri],
 706     [AS_HELP_STRING([--enable-dri],
 707         [enable DRI modules @<:@default=enabled@:>@])],
 708     [enable_dri="$enableval"],
 709     [enable_dri=yes])
 710
 711 case "$host_os" in
 712 linux*)
 713     dri3_default=yes
 714     ;;
 715 *)
 716     dri3_default=no
 717     ;;
 718 esac
 719 AC_ARG_ENABLE([dri3],
 720     [AS_HELP_STRING([--enable-dri3],
 721         [enable DRI3 @<:@default=auto@:>@])],
 722     [enable_dri3="$enableval"],
 723     [enable_dri3="$dri3_default"])
 724 AC_ARG_ENABLE([glx],
 725     [AS_HELP_STRING([--enable-glx],
 726         [enable GLX library @<:@default=enabled@:>@])],
 727     [enable_glx="$enableval"],
 728     [enable_glx=yes])
 729 AC_ARG_ENABLE([osmesa],
 730     [AS_HELP_STRING([--enable-osmesa],
 731         [enable OSMesa library @<:@default=disabled@:>@])],
 732     [enable_osmesa="$enableval"],
 733     [enable_osmesa=no])
 734 AC_ARG_ENABLE([gallium-osmesa],
 735     [AS_HELP_STRING([--enable-gallium-osmesa],
 736         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 737     [enable_gallium_osmesa="$enableval"],
 738     [enable_gallium_osmesa=no])
 739 AC_ARG_ENABLE([egl],
 740     [AS_HELP_STRING([--disable-egl],
 741         [disable EGL library @<:@default=enabled@:>@])],
 742     [enable_egl="$enableval"],
 743     [enable_egl=yes])
 744
 745 AC_ARG_ENABLE([xa],
 746     [AS_HELP_STRING([--enable-xa],
 747         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 748     [enable_xa="$enableval"],
 749     [enable_xa=no])
 750 AC_ARG_ENABLE([gbm],
 751    [AS_HELP_STRING([--enable-gbm],
 752          [enable gbm library @<:@default=auto@:>@])],
 753    [enable_gbm="$enableval"],
 754    [enable_gbm=auto])
 755 AC_ARG_ENABLE([nine],
 756     [AS_HELP_STRING([--enable-nine],
 757         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 758     [enable_nine="$enableval"],
 759     [enable_nine=no])
 760
 761 AC_ARG_ENABLE([xvmc],
 762    [AS_HELP_STRING([--enable-xvmc],
 763          [enable xvmc library @<:@default=auto@:>@])],
 764    [enable_xvmc="$enableval"],
 765    [enable_xvmc=auto])
 766 AC_ARG_ENABLE([vdpau],
 767    [AS_HELP_STRING([--enable-vdpau],
 768          [enable vdpau library @<:@default=auto@:>@])],
 769    [enable_vdpau="$enableval"],
 770    [enable_vdpau=auto])
 771 AC_ARG_ENABLE([omx],
 772    [AS_HELP_STRING([--enable-omx],
 773          [enable OpenMAX library @<:@default=disabled@:>@])],
 774    [enable_omx="$enableval"],
 775    [enable_omx=no])
 776 AC_ARG_ENABLE([va],
 777    [AS_HELP_STRING([--enable-va],
 778          [enable va library @<:@default=auto@:>@])],
 779    [enable_va="$enableval"],
 780    [enable_va=auto])
 781 AC_ARG_ENABLE([opencl],
 782    [AS_HELP_STRING([--enable-opencl],
 783          [enable OpenCL library @<:@default=disabled@:>@])],
 784    [enable_opencl="$enableval"],
 785    [enable_opencl=no])
 786 AC_ARG_ENABLE([opencl_icd],
 787    [AS_HELP_STRING([--enable-opencl-icd],
 788           [Build an OpenCL ICD library to be loaded by an ICD implementation
 789            @<:@default=disabled@:>@])],
 790     [enable_opencl_icd="$enableval"],
 791     [enable_opencl_icd=no])
 792 AC_ARG_ENABLE([xlib-glx],
 793     [AS_HELP_STRING([--enable-xlib-glx],
 794         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 795     [enable_xlib_glx="$enableval"],
 796     [enable_xlib_glx=no])
 797
 798 AC_ARG_ENABLE([r600-llvm-compiler],
 799     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 800         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 801     [enable_r600_llvm="$enableval"],
 802     [enable_r600_llvm=no])
 803
 804 AC_ARG_ENABLE([gallium-tests],
 805     [AS_HELP_STRING([--enable-gallium-tests],
 806         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 807     [enable_gallium_tests="$enableval"],
 808     [enable_gallium_tests=no])
 809
 810 # Option for Gallium drivers
 811
 812 # Keep this in sync with the --with-gallium-drivers help string default value
 813 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 814
 815 AC_ARG_WITH([gallium-drivers],
 816     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 817         [comma delimited Gallium drivers list, e.g.
 818         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 819         @<:@default=r300,r600,svga,swrast@:>@])],
 820     [with_gallium_drivers="$withval"],
 821     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 822
 823 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 824 # here so that the script doesn't choke on an unknown driver name later.
 825 case "$with_gallium_drivers" in
 826     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 827     no) with_gallium_drivers='' ;;
 828 esac
 829
 830 if test "x$enable_opengl" = xno -a \
 831         "x$enable_gles1" = xno -a \
 832         "x$enable_gles2" = xno -a \
 833         "x$enable_nine" = xno -a \
 834         "x$enable_xa" = xno -a \
 835         "x$enable_xvmc" = xno -a \
 836         "x$enable_vdpau" = xno -a \
 837         "x$enable_omx" = xno -a \
 838         "x$enable_va" = xno -a \
 839         "x$enable_opencl" = xno; then
 840     AC_MSG_ERROR([at least one API should be enabled])
 841 fi
 842
 843 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 844 if test "x$enable_opengl" = xno -a \
 845         "x$enable_gles1" = xyes; then
 846     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 847 fi
 848
 849 if test "x$enable_opengl" = xno -a \
 850         "x$enable_gles2" = xyes; then
 851     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 852 fi
 853
 854 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 855 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 856 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 857 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 858                                         "x$enable_gles1" = xyes -o \
 859                                         "x$enable_gles2" = xyes)
 860
 861 if test "x$enable_glx" = xno; then
 862     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 863     enable_xlib_glx=no
 864 fi
 865
 866 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 867     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 868 fi
 869
 870 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 871     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 872 fi
 873
 874 # Disable GLX if OpenGL is not enabled
 875 if test "x$enable_glx$enable_opengl" = xyesno; then
 876     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 877     enable_glx=no
 878 fi
 879
 880 # Disable GLX if DRI and Xlib-GLX are not enabled
 881 if test "x$enable_glx" = xyes -a \
 882         "x$enable_dri" = xno -a \
 883         "x$enable_xlib_glx" = xno; then
 884     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 885     enable_glx=no
 886 fi
 887
 888 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 889                                   "x$enable_dri" = xyes)
 890
 891 # Select which platform-dependent DRI code gets built
 892 case "$host_os" in
 893 darwin*)
 894     dri_platform='apple' ;;
 895 gnu*|mingw*|cygwin*)
 896     dri_platform='none' ;;
 897 *)
 898     dri_platform='drm' ;;
 899 esac
 900
 901 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 902 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 903 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 904 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 905 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 906
 907 AC_ARG_ENABLE([shared-glapi],
 908     [AS_HELP_STRING([--enable-shared-glapi],
 909         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 910     [enable_shared_glapi="$enableval"],
 911     [enable_shared_glapi=yes])
 912
 913 case "x$enable_opengl$enable_gles1$enable_gles2" in
 914 x*yes*yes*)
 915     if test "x$enable_shared_glapi" = xno; then
 916         AC_MSG_ERROR([shared GLAPI required when building two or more of
 917                       the following APIs - opengl, gles1 gles2])
 918     fi
 919     ;;
 920 esac
 921
 922 # Building Xlib-GLX requires shared glapi to be disabled.
 923 if test "x$enable_xlib_glx" = xyes; then
 924     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 925     enable_shared_glapi=no
 926 fi
 927
 928 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 929
 930 # Build the pipe-drivers as separate libraries/modules.
 931 # Do not touch this unless you know what you are doing.
 932 # XXX: Expose via configure option ?
 933 enable_shared_pipe_drivers=no
 934
 935 dnl
 936 dnl Driver specific build directories
 937 dnl
 938
 939 case "x$enable_glx$enable_xlib_glx" in
 940 xyesyes)
 941     NEED_WINSYS_XLIB="yes"
 942     ;;
 943 esac
 944
 945 if test "x$enable_dri" = xyes; then
 946     enable_gallium_loader="$enable_shared_pipe_drivers"
 947 fi
 948
 949 if test "x$enable_gallium_osmesa" = xyes; then
 950     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 951         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 952     fi
 953     if test "x$enable_osmesa" = xyes; then
 954         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 955     fi
 956 fi
 957
 958 AC_SUBST([MESA_LLVM])
 959
 960 # SHA1 hashing
 961 AC_ARG_WITH([sha1],
 962         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
 963         [choose SHA1 implementation])])
 964 case "x$with_sha1" in
 965 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
 966   ;;
 967 *)
 968         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
 969 esac
 970
 971 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
 972 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
 973         with_sha1=libc
 974 fi
 975 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
 976         AC_MSG_ERROR([sha1 in libc requested but not found])
 977 fi
 978 if test "x$with_sha1" = xlibc; then
 979         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
 980                 [Use libc SHA1 functions])
 981         SHA1_LIBS=""
 982 fi
 983 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
 984 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
 985         with_sha1=CommonCrypto
 986 fi
 987 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
 988         AC_MSG_ERROR([CommonCrypto requested but not found])
 989 fi
 990 if test "x$with_sha1" = xCommonCrypto; then
 991         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
 992                 [Use CommonCrypto SHA1 functions])
 993         SHA1_LIBS=""
 994 fi
 995 dnl stdcall functions cannot be tested with AC_CHECK_LIB
 996 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
 997 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
 998         with_sha1=CryptoAPI
 999 fi
1000 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1001         AC_MSG_ERROR([CryptoAPI requested but not found])
1002 fi
1003 if test "x$with_sha1" = xCryptoAPI; then
1004         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1005                 [Use CryptoAPI SHA1 functions])
1006         SHA1_LIBS=""
1007 fi
1008 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1009 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1010         with_sha1=libmd
1011 fi
1012 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1013         AC_MSG_ERROR([libmd requested but not found])
1014 fi
1015 if test "x$with_sha1" = xlibmd; then
1016         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1017                   [Use libmd SHA1 functions])
1018         SHA1_LIBS=-lmd
1019 fi
1020 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1021 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1022    with_sha1=libsha1
1023 fi
1024 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1025         AC_MSG_ERROR([libsha1 requested but not found])
1026 fi
1027 if test "x$with_sha1" = xlibsha1; then
1028         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1029                   [Use libsha1 for SHA1])
1030         SHA1_LIBS=-lsha1
1031 fi
1032 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1033 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1034         with_sha1=libnettle
1035 fi
1036 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1037         AC_MSG_ERROR([libnettle requested but not found])
1038 fi
1039 if test "x$with_sha1" = xlibnettle; then
1040         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1041                   [Use libnettle SHA1 functions])
1042         SHA1_LIBS=-lnettle
1043 fi
1044 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1045 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1046         with_sha1=libgcrypt
1047 fi
1048 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1049         AC_MSG_ERROR([libgcrypt requested but not found])
1050 fi
1051 if test "x$with_sha1" = xlibgcrypt; then
1052         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1053                   [Use libgcrypt SHA1 functions])
1054         SHA1_LIBS=-lgcrypt
1055 fi
1056 # We don't need all of the OpenSSL libraries, just libcrypto
1057 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1058 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1059                   [HAVE_OPENSSL_PKC=no])
1060 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1061         if test "x$with_sha1" = x; then
1062                 with_sha1=libcrypto
1063         fi
1064 else
1065         if test "x$with_sha1" = xlibcrypto; then
1066                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1067         fi
1068 fi
1069 if test "x$with_sha1" = xlibcrypto; then
1070         if test "x$HAVE_LIBCRYPTO" = xyes; then
1071                 SHA1_LIBS=-lcrypto
1072         else
1073                 SHA1_LIBS="$OPENSSL_LIBS"
1074                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1075         fi
1076 fi
1077 AC_MSG_CHECKING([for SHA1 implementation])
1078 AC_MSG_RESULT([$with_sha1])
1079 AC_SUBST(SHA1_LIBS)
1080 AC_SUBST(SHA1_CFLAGS)
1081
1082 # Allow user to configure out the shader-cache feature
1083 AC_ARG_ENABLE([shader-cache],
1084     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1085     [enable_shader_cache="$enableval"],
1086     [if test "x$with_sha1" != "x"; then
1087         enable_shader_cache=yes
1088      else
1089         enable_shader_cache=no
1090      fi])
1091 if test "x$with_sha1" = "x"; then
1092     if test "x$enable_shader_cache" = "xyes"; then
1093         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1094     fi
1095 fi
1096 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1097
1098 # Check for libdrm
1099 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1100                   [have_libdrm=yes], [have_libdrm=no])
1101 if test "x$have_libdrm" = xyes; then
1102         DEFINES="$DEFINES -DHAVE_LIBDRM"
1103 fi
1104
1105 case "$host_os" in
1106 linux*)
1107     need_pci_id=yes ;;
1108 *)
1109     need_pci_id=no ;;
1110 esac
1111
1112 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1113                   have_libudev=yes, have_libudev=no)
1114
1115 AC_ARG_ENABLE([sysfs],
1116     [AS_HELP_STRING([--enable-sysfs],
1117         [enable /sys PCI identification @<:@default=disabled@:>@])],
1118     [have_sysfs="$enableval"],
1119     [have_sysfs=no]
1120 )
1121
1122 if test "x$enable_dri" = xyes; then
1123     if test "$enable_static" = yes; then
1124         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1125     fi
1126
1127     # not a hard requirement as swrast does not depend on it
1128     if test "x$have_libdrm" = xyes; then
1129         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1130     fi
1131 fi
1132
1133 AC_ARG_ENABLE([driglx-direct],
1134     [AS_HELP_STRING([--disable-driglx-direct],
1135         [disable direct rendering in GLX and EGL for DRI \
1136             @<:@default=auto@:>@])],
1137     [driglx_direct="$enableval"],
1138     [driglx_direct="yes"])
1139
1140 dnl
1141 dnl libGL configuration per driver
1142 dnl
1143 case "x$enable_glx$enable_xlib_glx" in
1144 xyesyes)
1145     # Xlib-based GLX
1146     dri_modules="x11 xext xcb"
1147     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1148     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1149     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1150     GL_LIB_DEPS="$XLIBGL_LIBS"
1151     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1152     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1153     ;;
1154 xyesno)
1155     # DRI-based GLX
1156     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1157
1158     # find the DRI deps for libGL
1159     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1160
1161     if test x"$driglx_direct" = xyes; then
1162         if test x"$dri_platform" = xdrm ; then
1163             DEFINES="$DEFINES -DGLX_USE_DRM"
1164             if test "x$have_libdrm" != xyes; then
1165                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1166             fi
1167
1168             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1169             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1170             if test x"$enable_dri3" = xyes; then
1171                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1172                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1173             fi
1174
1175             if test x"$enable_dri" = xyes; then
1176                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1177             fi
1178
1179             if test x"$enable_dri3" = xyes; then
1180                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1181                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1182             fi
1183         fi
1184         if test x"$dri_platform" = xapple ; then
1185             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1186         fi
1187     fi
1188
1189     # add xf86vidmode if available
1190     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1191     if test "$HAVE_XF86VIDMODE" = yes ; then
1192         dri_modules="$dri_modules xxf86vm"
1193     fi
1194
1195     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1196     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1197     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1198     GL_LIB_DEPS="$DRIGL_LIBS"
1199
1200     # need DRM libs, $PTHREAD_LIBS, etc.
1201     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1202     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1203     ;;
1204 esac
1205
1206 have_pci_id=no
1207 if test "$have_libudev" = yes; then
1208     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1209     have_pci_id=yes
1210 fi
1211
1212 if test "$have_sysfs" = yes; then
1213     DEFINES="$DEFINES -DHAVE_SYSFS"
1214     have_pci_id=yes
1215 fi
1216
1217 # This is outside the case (above) so that it is invoked even for non-GLX
1218 # builds.
1219 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1220
1221 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1222 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1223 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1224 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1225
1226 AC_SUBST([X11_INCLUDES])
1227 AC_SUBST([GL_LIB_DEPS])
1228 AC_SUBST([GL_PC_REQ_PRIV])
1229 AC_SUBST([GL_PC_LIB_PRIV])
1230 AC_SUBST([GL_PC_CFLAGS])
1231 AC_SUBST([DRI_PC_REQ_PRIV])
1232 AC_SUBST([GLESv1_CM_LIB_DEPS])
1233 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1234 AC_SUBST([GLESv2_LIB_DEPS])
1235 AC_SUBST([GLESv2_PC_LIB_PRIV])
1236
1237 AC_SUBST([HAVE_XF86VIDMODE])
1238
1239 dnl
1240 dnl More GLX setup
1241 dnl
1242 case "x$enable_glx$enable_xlib_glx" in
1243 xyesyes)
1244     DEFINES="$DEFINES -DUSE_XSHM"
1245     ;;
1246 xyesno)
1247     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1248     if test "x$driglx_direct" = xyes; then
1249         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1250     fi
1251     ;;
1252 esac
1253
1254 dnl
1255 dnl TLS detection
1256 dnl
1257
1258 AC_ARG_ENABLE([glx-tls],
1259     [AS_HELP_STRING([--enable-glx-tls],
1260         [enable TLS support in GLX @<:@default=disabled@:>@])],
1261     [GLX_USE_TLS="$enableval"],
1262     [GLX_USE_TLS=no])
1263 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1264
1265 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1266       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1267
1268 dnl
1269 dnl More DRI setup
1270 dnl
1271 dnl Directory for DRI drivers
1272 AC_ARG_WITH([dri-driverdir],
1273     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1274         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1275     [DRI_DRIVER_INSTALL_DIR="$withval"],
1276     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1277 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1278 dnl Extra search path for DRI drivers
1279 AC_ARG_WITH([dri-searchpath],
1280     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1281         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1282     [DRI_DRIVER_SEARCH_DIR="$withval"],
1283     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1284 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1285 dnl Which drivers to build - default is chosen by platform
1286 AC_ARG_WITH([dri-drivers],
1287     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1288         [comma delimited classic DRI drivers list, e.g.
1289         "swrast,i965,radeon" @<:@default=auto@:>@])],
1290     [with_dri_drivers="$withval"],
1291     [with_dri_drivers=auto])
1292
1293 if test "x$with_dri_drivers" = xauto; then
1294     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1295         with_dri_drivers="yes"
1296     else
1297         with_dri_drivers="no"
1298     fi
1299 fi
1300 if test "x$with_dri_drivers" = xno; then
1301     with_dri_drivers=''
1302 fi
1303
1304 dnl If $with_dri_drivers is yes, drivers will be added through
1305 dnl platform checks. Set DEFINES and LIB_DEPS
1306 if test "x$enable_dri" = xyes; then
1307     # Platform specific settings and drivers to build
1308     case "$host_os" in
1309     linux*)
1310         DEFINES="$DEFINES -DHAVE_ALIAS"
1311         if test "x$enable_dri3" = xyes; then
1312             DEFINES="$DEFINES -DHAVE_DRI3"
1313         fi
1314
1315         if test "x$have_pci_id" != xyes; then
1316             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1317         fi
1318
1319         case "$host_cpu" in
1320         powerpc* | sparc*)
1321             # Build only the drivers for cards that exist on PowerPC/sparc
1322             if test "x$with_dri_drivers" = "xyes"; then
1323                 with_dri_drivers="r200 radeon swrast"
1324             fi
1325             ;;
1326         esac
1327         ;;
1328     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1329         DEFINES="$DEFINES -DHAVE_ALIAS"
1330         ;;
1331     gnu*)
1332         DEFINES="$DEFINES -DHAVE_ALIAS"
1333         ;;
1334     cygwin*)
1335         if test "x$with_dri_drivers" = "xyes"; then
1336             with_dri_drivers="swrast"
1337         fi
1338         ;;
1339     darwin*)
1340         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1341         if test "x$with_dri_drivers" = "xyes"; then
1342             with_dri_drivers="swrast"
1343         fi
1344         ;;
1345     esac
1346
1347     # default drivers
1348     if test "x$with_dri_drivers" = "xyes"; then
1349         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1350     fi
1351
1352     # Check for expat
1353     PKG_CHECK_MODULES([EXPAT], [expat], [],
1354         # expat version 2.0 and earlier do not provide expat.pc
1355         [AC_CHECK_HEADER([expat.h],[],
1356                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1357          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1358                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1359          EXPAT_LIBS="-lexpat"])
1360
1361     DRICOMMON_NEED_LIBDRM=no
1362     # If we are building any DRI driver other than swrast.
1363     if test -n "$with_dri_drivers"; then
1364         if test "x$with_dri_drivers" != xswrast; then
1365             # ... libdrm is required
1366             if test "x$have_libdrm" != xyes; then
1367                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1368             fi
1369             DRICOMMON_NEED_LIBDRM=yes
1370         fi
1371     fi
1372
1373     # If we're building any gallium DRI driver other than swrast
1374     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1375         if test "x$with_gallium_drivers" != xswrast; then
1376             # ... build a libdrm aware dricommon
1377             DRICOMMON_NEED_LIBDRM=yes
1378         fi
1379     fi
1380
1381     # put all the necessary libs together
1382     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1383 fi
1384
1385 AC_SUBST([DRI_LIB_DEPS])
1386
1387 DRI_DIRS=''
1388 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1389 if test -n "$with_dri_drivers"; then
1390     if test "x$enable_opengl" != xyes; then
1391         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1392     fi
1393
1394     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1395     for driver in $dri_drivers; do
1396         DRI_DIRS="$DRI_DIRS $driver"
1397         case "x$driver" in
1398         xi915)
1399             HAVE_I915_DRI=yes;
1400             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1401             ;;
1402         xi965)
1403             HAVE_I965_DRI=yes;
1404             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1405             ;;
1406         xnouveau)
1407             HAVE_NOUVEAU_DRI=yes;
1408             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1409             ;;
1410         xradeon)
1411             HAVE_RADEON_DRI=yes;
1412             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1413             ;;
1414         xr200)
1415             HAVE_R200_DRI=yes;
1416             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1417             ;;
1418         xswrast)
1419             HAVE_SWRAST_DRI=yes;
1420             ;;
1421         *)
1422             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1423             ;;
1424         esac
1425     done
1426     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1427 fi
1428
1429 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1430 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1431                                   "x$enable_osmesa" = xyes -o \
1432                                   -n "$DRI_DIRS")
1433
1434 dnl
1435 dnl OSMesa configuration
1436 dnl
1437
1438 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1439 AC_ARG_WITH([osmesa-bits],
1440     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1441         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1442     [osmesa_bits="$withval"],
1443     [osmesa_bits=8])
1444 if test "x$osmesa_bits" != x8; then
1445     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1446         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1447         osmesa_bits=8
1448     fi
1449 fi
1450 case "x$osmesa_bits" in
1451 x8)
1452     OSMESA_LIB="${OSMESA_LIB}"
1453     ;;
1454 x16|x32)
1455     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1456     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1457     ;;
1458 *)
1459     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1460     ;;
1461 esac
1462
1463 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1464     # only link libraries with osmesa if shared
1465     if test "$enable_static" = no; then
1466         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1467     else
1468         OSMESA_LIB_DEPS=""
1469     fi
1470     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1471 fi
1472
1473 AC_SUBST([OSMESA_LIB_DEPS])
1474 AC_SUBST([OSMESA_PC_REQ])
1475 AC_SUBST([OSMESA_PC_LIB_PRIV])
1476
1477 dnl
1478 dnl gbm configuration
1479 dnl
1480 if test "x$enable_gbm" = xauto; then
1481     case "$with_egl_platforms" in
1482         *drm*)
1483             enable_gbm=yes ;;
1484          *)
1485             enable_gbm=no ;;
1486     esac
1487 fi
1488 if test "x$enable_gbm" = xyes; then
1489     if test "x$need_pci_id$have_pci_id" = xyesno; then
1490         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1491     fi
1492
1493     if test "x$enable_dri" = xyes; then
1494         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1495         if test "x$enable_shared_glapi" = xno; then
1496             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1497         fi
1498     else
1499         # Strictly speaking libgbm does not require --enable-dri, although
1500         # both of its backends do. Thus one can build libgbm without any
1501         # backends if --disable-dri is set.
1502         # To avoid unnecessary complexity of checking if at least one backend
1503         # is available when building, just mandate --enable-dri.
1504         AC_MSG_ERROR([gbm requires --enable-dri])
1505     fi
1506 fi
1507 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1508 if test "x$need_pci_id$have_libudev" = xyesyes; then
1509     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1510 else
1511     GBM_PC_REQ_PRIV=""
1512 fi
1513 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1514 AC_SUBST([GBM_PC_REQ_PRIV])
1515 AC_SUBST([GBM_PC_LIB_PRIV])
1516
1517 dnl
1518 dnl EGL configuration
1519 dnl
1520 EGL_CLIENT_APIS=""
1521
1522 if test "x$enable_egl" = xyes; then
1523     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1524
1525     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1526
1527     if test "$enable_static" != yes; then
1528         if test "x$enable_dri" = xyes; then
1529             HAVE_EGL_DRIVER_DRI2=1
1530         fi
1531
1532     fi
1533 fi
1534 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1535 AC_SUBST([EGL_LIB_DEPS])
1536
1537 dnl
1538 dnl XA configuration
1539 dnl
1540 if test "x$enable_xa" = xyes; then
1541     if test "x$with_gallium_drivers" = xswrast; then
1542        AC_MSG_ERROR([
1543           Building xa requires at least one non swrast gallium driver.
1544           If you are looking to use libxatracker.so with the VMware driver,
1545           make sure to include svga in the gallium drivers list, apart from
1546           enabling XA.
1547           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1548     fi
1549     enable_gallium_loader=$enable_shared_pipe_drivers
1550 fi
1551 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1552
1553 dnl
1554 dnl Gallium G3DVL configuration
1555 dnl
1556 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1557     if test "x$enable_xvmc" = xauto; then
1558         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1559     fi
1560
1561     if test "x$enable_vdpau" = xauto; then
1562         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1563     fi
1564
1565     if test "x$enable_omx" = xauto; then
1566         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1567     fi
1568
1569     if test "x$enable_va" = xauto; then
1570         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1571     fi
1572 fi
1573
1574 if test "x$enable_dri" = xyes -o \
1575         "x$enable_xvmc" = xyes -o \
1576         "x$enable_vdpau" = xyes -o \
1577         "x$enable_omx" = xyes -o \
1578         "x$enable_va" = xyes; then
1579     need_gallium_vl=yes
1580 fi
1581 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1582
1583 if test "x$enable_xvmc" = xyes -o \
1584         "x$enable_vdpau" = xyes -o \
1585         "x$enable_omx" = xyes -o \
1586         "x$enable_va" = xyes; then
1587     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1588     need_gallium_vl_winsys=yes
1589 fi
1590 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1591
1592 if test "x$enable_xvmc" = xyes; then
1593     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1594     enable_gallium_loader=$enable_shared_pipe_drivers
1595 fi
1596 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1597
1598 if test "x$enable_vdpau" = xyes; then
1599     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1600     enable_gallium_loader=$enable_shared_pipe_drivers
1601 fi
1602 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1603
1604 if test "x$enable_omx" = xyes; then
1605     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1606     enable_gallium_loader=$enable_shared_pipe_drivers
1607 fi
1608 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1609
1610 if test "x$enable_va" = xyes; then
1611     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1612     enable_gallium_loader=$enable_shared_pipe_drivers
1613 fi
1614 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1615
1616 dnl
1617 dnl Nine Direct3D9 configuration
1618 dnl
1619 if test "x$enable_nine" = xyes; then
1620     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1621         AC_MSG_ERROR([nine requires the gallium swrast driver])
1622     fi
1623     if test "x$with_gallium_drivers" == xswrast; then
1624         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1625     fi
1626     if test "x$enable_dri3" = xno; then
1627         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1628     fi
1629
1630     enable_gallium_loader=$enable_shared_pipe_drivers
1631 fi
1632 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1633
1634 dnl
1635 dnl OpenCL configuration
1636 dnl
1637
1638 AC_ARG_WITH([libclc-path],
1639    [AS_HELP_STRING([--with-libclc-path],
1640          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1641    [LIBCLC_PATH="$withval"],
1642    [LIBCLC_PATH=''])
1643
1644 if test -n "$LIBCLC_PATH"; then
1645    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1646                   Please review the updated build instructions for clover:
1647                   http://dri.freedesktop.org/wiki/GalliumCompute])
1648 fi
1649
1650
1651 AC_ARG_WITH([clang-libdir],
1652    [AS_HELP_STRING([--with-clang-libdir],
1653          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1654    [CLANG_LIBDIR="$withval"],
1655    [CLANG_LIBDIR=''])
1656
1657 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1658 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1659
1660 if test "x$enable_opencl" = xyes; then
1661     if test -z "$with_gallium_drivers"; then
1662         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1663     fi
1664
1665     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1666         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1667     fi
1668
1669     if test "x$have_libclc" = xno; then
1670         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1671                     Make sure the directory containing libclc.pc is specified in your
1672                     PKG_CONFIG_PATH environment variable.
1673                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1674     else
1675         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1676         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1677         AC_SUBST([LIBCLC_INCLUDEDIR])
1678         AC_SUBST([LIBCLC_LIBEXECDIR])
1679     fi
1680
1681     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1682     enable_gallium_loader=yes
1683
1684     if test "x$enable_opencl_icd" = xyes; then
1685         OPENCL_LIBNAME="MesaOpenCL"
1686     else
1687         OPENCL_LIBNAME="OpenCL"
1688     fi
1689
1690     if test "x$have_libelf" != xyes; then
1691        AC_MSG_ERROR([Clover requires libelf])
1692     fi
1693 fi
1694 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1695 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1696 AC_SUBST([OPENCL_LIBNAME])
1697
1698 dnl
1699 dnl Gallium configuration
1700 dnl
1701 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1702
1703 AC_SUBST([LLVM_BINDIR])
1704 AC_SUBST([LLVM_CFLAGS])
1705 AC_SUBST([LLVM_CPPFLAGS])
1706 AC_SUBST([LLVM_CXXFLAGS])
1707 AC_SUBST([LLVM_LIBDIR])
1708 AC_SUBST([LLVM_LIBS])
1709 AC_SUBST([LLVM_LDFLAGS])
1710 AC_SUBST([LLVM_INCLUDEDIR])
1711 AC_SUBST([LLVM_VERSION])
1712 AC_SUBST([CLANG_RESOURCE_DIR])
1713
1714 case "x$enable_opengl$enable_gles1$enable_gles2" in
1715 x*yes*)
1716     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1717     ;;
1718 esac
1719
1720 AC_SUBST([VG_LIB_DEPS])
1721 AC_SUBST([EGL_CLIENT_APIS])
1722
1723 dnl
1724 dnl EGL Platforms configuration
1725 dnl
1726 AC_ARG_WITH([egl-platforms],
1727     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1728         [comma delimited native platforms libEGL supports, e.g.
1729         "x11,drm" @<:@default=auto@:>@])],
1730     [with_egl_platforms="$withval"],
1731     [if test "x$enable_egl" = xyes; then
1732         with_egl_platforms="x11"
1733     else
1734         with_egl_platforms=""
1735     fi])
1736
1737 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1738     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1739 fi
1740
1741 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1742         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1743         WAYLAND_SCANNER='')
1744 if test "x$WAYLAND_SCANNER" = x; then
1745     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1746 fi
1747
1748 # Do per-EGL platform setups and checks
1749 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1750 for plat in $egl_platforms; do
1751         case "$plat" in
1752         wayland)
1753                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1754
1755                 if test "x$WAYLAND_SCANNER" = x; then
1756                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1757                 fi
1758                 ;;
1759
1760         x11)
1761                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1762                 ;;
1763
1764         drm)
1765                 test "x$enable_gbm" = "xno" &&
1766                         AC_MSG_ERROR([EGL platform drm needs gbm])
1767                 test "x$have_libdrm" != xyes &&
1768                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1769                 ;;
1770
1771         android|fbdev|gdi|null)
1772                 ;;
1773
1774         *)
1775                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1776                 ;;
1777         esac
1778
1779         case "$plat$need_pci_id$have_pci_id" in
1780                 waylandyesno|drmyesno)
1781                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1782         esac
1783 done
1784
1785 # libEGL wants to default to the first platform specified in
1786 # ./configure.  parse that here.
1787 if test "x$egl_platforms" != "x"; then
1788     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1789     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1790 else
1791     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1792 fi
1793
1794 if echo "$egl_platforms" | grep -q 'x11'; then
1795     NEED_WINSYS_XLIB=yes
1796 fi
1797 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1798 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1799 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1800 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1801 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1802
1803 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1804
1805 AC_SUBST([EGL_NATIVE_PLATFORM])
1806 AC_SUBST([EGL_CFLAGS])
1807
1808 # If we don't have the X11 platform, set this define so we don't try to include
1809 # the X11 headers.
1810 if ! echo "$egl_platforms" | grep -q 'x11'; then
1811     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1812     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1813 fi
1814
1815 AC_ARG_WITH([max-width],
1816     [AS_HELP_STRING([--with-max-width=N],
1817                     [Maximum framebuffer width (4096)])],
1818     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1819      AS_IF([test "${withval}" -gt "4096"],
1820            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1821 )
1822 AC_ARG_WITH([max-height],
1823     [AS_HELP_STRING([--with-max-height=N],
1824                     [Maximum framebuffer height (4096)])],
1825     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1826      AS_IF([test "${withval}" -gt "4096"],
1827            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1828 )
1829
1830 dnl
1831 dnl Gallium LLVM
1832 dnl
1833 AC_ARG_ENABLE([gallium-llvm],
1834     [AS_HELP_STRING([--enable-gallium-llvm],
1835         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1836     [enable_gallium_llvm="$enableval"],
1837     [enable_gallium_llvm=auto])
1838
1839 AC_ARG_ENABLE([llvm-shared-libs],
1840     [AS_HELP_STRING([--enable-llvm-shared-libs],
1841         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1842     [enable_llvm_shared_libs="$enableval"],
1843     [enable_llvm_shared_libs=yes])
1844
1845 AC_ARG_WITH([llvm-prefix],
1846     [AS_HELP_STRING([--with-llvm-prefix],
1847         [Prefix for LLVM installations in non-standard locations])],
1848     [llvm_prefix="$withval"],
1849     [llvm_prefix=''])
1850
1851
1852 # Call this inside ` ` to get the return value.
1853 # $1 is the llvm-config command with arguments.
1854 strip_unwanted_llvm_flags() {
1855     # Use \> (marks the end of the word)
1856     echo `$1` | sed \
1857         -e 's/-DNDEBUG\>//g' \
1858         -e 's/-D_GNU_SOURCE\>//g' \
1859         -e 's/-pedantic\>//g' \
1860         -e 's/-Wcovered-switch-default\>//g' \
1861         -e 's/-O.\>//g' \
1862         -e 's/-g\>//g' \
1863         -e 's/-Wall\>//g' \
1864         -e 's/-Wcast-qual\>//g' \
1865         -e 's/-Woverloaded-virtual\>//g' \
1866         -e 's/-fcolor-diagnostics\>//g' \
1867         -e 's/-fdata-sections\>//g' \
1868         -e 's/-ffunction-sections\>//g' \
1869         -e 's/-fno-exceptions\>//g' \
1870         -e 's/-fomit-frame-pointer\>//g' \
1871         -e 's/-fvisibility-inlines-hidden\>//g' \
1872         -e 's/-fPIC\>//g' \
1873         -e 's/-fstack-protector-strong\>//g'
1874 }
1875
1876
1877 if test -z "$with_gallium_drivers"; then
1878     enable_gallium_llvm=no
1879 fi
1880 if test "x$enable_gallium_llvm" = xauto; then
1881     case "$host_cpu" in
1882     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1883     esac
1884 fi
1885 if test "x$enable_gallium_llvm" = xyes; then
1886     if test -n "$llvm_prefix"; then
1887         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1888     else
1889         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1890     fi
1891
1892     if test "x$LLVM_CONFIG" != xno; then
1893         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1894         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1895         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1896         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1897         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1898         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1899         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1900         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1901
1902         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1903             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1904         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1905             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1906
1907         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1908         if test -z "$LLVM_VERSION_PATCH"; then
1909             LLVM_VERSION_PATCH=0
1910         fi
1911
1912         if test -n "${LLVM_VERSION_MAJOR}"; then
1913             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1914         else
1915             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1916         fi
1917
1918         LLVM_REQUIRED_VERSION_MAJOR="3"
1919         LLVM_REQUIRED_VERSION_MINOR="3"
1920         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1921             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1922         fi
1923
1924         LLVM_COMPONENTS="engine bitwriter"
1925         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1926             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1927         fi
1928
1929         if test "x$enable_opencl" = xyes; then
1930             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1931             # LLVM 3.3 >= 177971 requires IRReader
1932             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1933                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1934             fi
1935             # LLVM 3.4 requires Option
1936             if $LLVM_CONFIG --components | grep -qw 'option'; then
1937                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1938             fi
1939             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1940             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1941                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1942             fi
1943             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1944                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1945             fi
1946         fi
1947         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1948         MESA_LLVM=1
1949
1950         dnl Check for Clang internal headers
1951         if test "x$enable_opencl" = xyes; then
1952             if test -z "$CLANG_LIBDIR"; then
1953                 CLANG_LIBDIR=${LLVM_LIBDIR}
1954             fi
1955             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1956             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1957                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1958         fi
1959     else
1960         MESA_LLVM=0
1961         LLVM_VERSION_INT=0
1962     fi
1963 else
1964     MESA_LLVM=0
1965     LLVM_VERSION_INT=0
1966
1967     if test "x$enable_opencl" = xyes; then
1968         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1969     fi
1970 fi
1971
1972 dnl Directory for XVMC libs
1973 AC_ARG_WITH([xvmc-libdir],
1974     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1975         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1976     [XVMC_LIB_INSTALL_DIR="$withval"],
1977     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1978 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1979
1980 dnl
1981 dnl Gallium Tests
1982 dnl
1983 if test "x$enable_gallium_tests" = xyes; then
1984     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1985     enable_gallium_loader=yes
1986 fi
1987 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1988
1989 dnl Directory for VDPAU libs
1990 AC_ARG_WITH([vdpau-libdir],
1991     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1992         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1993     [VDPAU_LIB_INSTALL_DIR="$withval"],
1994     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1995 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1996
1997 dnl Directory for OMX libs
1998
1999 AC_ARG_WITH([omx-libdir],
2000     [AS_HELP_STRING([--with-omx-libdir=DIR],
2001         [directory for the OMX libraries])],
2002     [OMX_LIB_INSTALL_DIR="$withval"],
2003     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2004 AC_SUBST([OMX_LIB_INSTALL_DIR])
2005
2006 dnl Directory for VA libs
2007
2008 AC_ARG_WITH([va-libdir],
2009     [AS_HELP_STRING([--with-va-libdir=DIR],
2010         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2011     [VA_LIB_INSTALL_DIR="$withval"],
2012     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2013 AC_SUBST([VA_LIB_INSTALL_DIR])
2014
2015 AC_ARG_WITH([d3d-libdir],
2016     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2017         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2018     [D3D_DRIVER_INSTALL_DIR="$withval"],
2019     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2020 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2021
2022 dnl
2023 dnl Gallium helper functions
2024 dnl
2025 gallium_require_drm() {
2026     if test "x$have_libdrm" != xyes; then
2027        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2028     fi
2029 }
2030
2031 gallium_require_llvm() {
2032     if test "x$MESA_LLVM" = x0; then
2033         case "$host" in *gnux32) return;; esac
2034         case "$host_cpu" in
2035         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2036         esac
2037     fi
2038 }
2039
2040 gallium_require_drm_loader() {
2041     if test "x$enable_gallium_loader" = xyes; then
2042         if test "x$need_pci_id$have_pci_id" = xyesno; then
2043             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2044         fi
2045         enable_gallium_drm_loader=yes
2046     fi
2047     if test "x$enable_va" = xyes && test "x$7" != x; then
2048          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2049     fi
2050 }
2051
2052 require_egl_drm() {
2053     case "$with_egl_platforms" in
2054         *drm*)
2055             ;;
2056          *)
2057             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2058             ;;
2059     esac
2060     if test "x$enable_gbm" != xyes; then
2061             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2062     fi
2063 }
2064
2065 radeon_llvm_check() {
2066     if test "x$enable_gallium_llvm" != "xyes"; then
2067         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2068     fi
2069     LLVM_REQUIRED_VERSION_MAJOR="3"
2070     LLVM_REQUIRED_VERSION_MINOR="4"
2071     LLVM_REQUIRED_VERSION_PATCH="2"
2072     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
2073         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
2074     fi
2075     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
2076         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
2077                       sources with the --enable-experimental-targets=R600
2078                       configure flag])
2079     fi
2080     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
2081     NEED_RADEON_LLVM=yes
2082     if test "x$have_libelf" != xyes; then
2083        AC_MSG_ERROR([$1 requires libelf when using llvm])
2084     fi
2085 }
2086
2087 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2088 if test -n "$with_gallium_drivers"; then
2089     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2090     for driver in $gallium_drivers; do
2091         case "x$driver" in
2092         xsvga)
2093             HAVE_GALLIUM_SVGA=yes
2094             gallium_require_drm "svga"
2095             gallium_require_drm_loader
2096             ;;
2097         xi915)
2098             HAVE_GALLIUM_I915=yes
2099             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2100             gallium_require_drm "Gallium i915"
2101             gallium_require_drm_loader
2102             ;;
2103         xilo)
2104             HAVE_GALLIUM_ILO=yes
2105             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2106             gallium_require_drm "Gallium i965/ilo"
2107             gallium_require_drm_loader
2108             ;;
2109         xr300)
2110             HAVE_GALLIUM_R300=yes
2111             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2112             gallium_require_drm "Gallium R300"
2113             gallium_require_drm_loader
2114             gallium_require_llvm "Gallium R300"
2115             ;;
2116         xr600)
2117             HAVE_GALLIUM_R600=yes
2118             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2119             gallium_require_drm "Gallium R600"
2120             gallium_require_drm_loader
2121             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2122                 radeon_llvm_check "r600g"
2123                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2124             fi
2125             if test "x$enable_r600_llvm" = xyes; then
2126                 USE_R600_LLVM_COMPILER=yes;
2127             fi
2128             if test "x$enable_opencl" = xyes; then
2129                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2130             fi
2131             ;;
2132         xradeonsi)
2133             HAVE_GALLIUM_RADEONSI=yes
2134             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2135             gallium_require_drm "radeonsi"
2136             gallium_require_drm_loader
2137             radeon_llvm_check "radeonsi"
2138             require_egl_drm "radeonsi"
2139             ;;
2140         xnouveau)
2141             HAVE_GALLIUM_NOUVEAU=yes
2142             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2143             gallium_require_drm "nouveau"
2144             gallium_require_drm_loader
2145             ;;
2146         xfreedreno)
2147             HAVE_GALLIUM_FREEDRENO=yes
2148             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2149             gallium_require_drm "freedreno"
2150             gallium_require_drm_loader
2151             ;;
2152         xswrast)
2153             HAVE_GALLIUM_SOFTPIPE=yes
2154             if test "x$MESA_LLVM" = x1; then
2155                 HAVE_GALLIUM_LLVMPIPE=yes
2156             fi
2157             ;;
2158         xvc4)
2159             HAVE_GALLIUM_VC4=yes
2160             gallium_require_drm "vc4"
2161             gallium_require_drm_loader
2162
2163             case "$host_cpu" in
2164                 i?86 | x86_64 | amd64)
2165                 USE_VC4_SIMULATOR=yes
2166                 ;;
2167             esac
2168             ;;
2169         *)
2170             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2171             ;;
2172         esac
2173     done
2174 fi
2175
2176 dnl Set LLVM_LIBS - This is done after the driver configuration so
2177 dnl that drivers can add additional components to LLVM_COMPONENTS.
2178 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2179 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2180 dnl this was causing the same libraries to be appear multiple times
2181 dnl in LLVM_LIBS.
2182
2183 if test "x$MESA_LLVM" != x0; then
2184
2185     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2186
2187     if test "x$enable_llvm_shared_libs" = xyes; then
2188         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2189         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2190         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2191
2192         if test "x$llvm_have_one_so" = xyes; then
2193             dnl LLVM was built using auto*, so there is only one shared object.
2194             LLVM_LIBS="-l$LLVM_SO_NAME"
2195         else
2196             dnl If LLVM was built with CMake, there will be one shared object per
2197             dnl component.
2198             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2199                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2200         Please make sure you have built llvm with the --enable-shared option
2201         and that your llvm libraries are installed in $LLVM_LIBDIR
2202         If you have installed your llvm libraries to a different directory you
2203         can use the --with-llvm-prefix= configure flag to specify this directory.
2204         NOTE: Mesa is attempting to use llvm shared libraries by default.
2205         If you do not want to build with llvm shared libraries and instead want to
2206         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2207         invocation and rebuild.])])
2208
2209            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2210            dnl install uses a shared object for each component and we have
2211            dnl already added all of these objects to LLVM_LIBS.
2212         fi
2213     else
2214         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2215         dnl We need to link to llvm system libs when using static libs
2216         dnl However, only llvm 3.5+ provides --system-libs
2217         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2218             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2219         fi
2220     fi
2221 fi
2222
2223 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2224 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2225 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2226 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2227 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2228 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2229 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2230                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2231 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2232 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2233 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2234 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2235 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2236
2237 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2238
2239 # NOTE: anything using xcb or other client side libs ends up in separate
2240 #       _CLIENT variables.  The pipe loader is built in two variants,
2241 #       one that is standalone and does not link any x client libs (for
2242 #       use by XA tracker in particular, but could be used in any case
2243 #       where communication with xserver is not desired).
2244 if test "x$enable_gallium_loader" = xyes; then
2245     if test "x$NEED_WINSYS_XLIB" = xyes; then
2246         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2247     fi
2248
2249     if test "x$enable_dri" = xyes; then
2250         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2251     fi
2252
2253     if test "x$enable_gallium_drm_loader" = xyes; then
2254         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2255         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2256                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2257         if test "x$pipe_loader_have_xcb" = xyes; then
2258             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2259             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2260         fi
2261     fi
2262
2263     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2264     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2265
2266     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2267     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2268     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2269     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2270 fi
2271
2272 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2273 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2274 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2275 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2276 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2277 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2278
2279 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2280                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2281                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2282 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2283 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2284 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2285 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2286 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2287 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2288 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2289 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2290 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2291     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2292 fi
2293
2294 AC_SUBST([ELF_LIB])
2295
2296 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2297 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2298 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2299 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2300 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2301
2302 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2303 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2304 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2305
2306 AC_SUBST([NINE_MAJOR], 1)
2307 AC_SUBST([NINE_MINOR], 0)
2308 AC_SUBST([NINE_TINY], 0)
2309 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2310
2311 AC_SUBST([VDPAU_MAJOR], 1)
2312 AC_SUBST([VDPAU_MINOR], 0)
2313
2314 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2315 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2316 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2317 AC_SUBST([VA_MINOR], $VA_MINOR)
2318
2319 AC_SUBST([XVMC_MAJOR], 1)
2320 AC_SUBST([XVMC_MINOR], 0)
2321
2322 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2323 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2324 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2325 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2326
2327 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2328 AC_SUBST([XA_MINOR], $XA_MINOR)
2329 AC_SUBST([XA_TINY], $XA_TINY)
2330 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2331
2332 dnl Restore LDFLAGS and CPPFLAGS
2333 LDFLAGS="$_SAVE_LDFLAGS"
2334 CPPFLAGS="$_SAVE_CPPFLAGS"
2335
2336 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2337 if test "x$acv_mesa_CLANG" = xyes; then
2338     CFLAGS="$CFLAGS -Qunused-arguments"
2339     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2340 fi
2341
2342 dnl Add user CFLAGS and CXXFLAGS
2343 CFLAGS="$CFLAGS $USER_CFLAGS"
2344 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2345
2346 dnl Substitute the config
2347 AC_CONFIG_FILES([Makefile
2348                 src/Makefile
2349                 src/egl/drivers/dri2/Makefile
2350                 src/egl/main/Makefile
2351                 src/egl/main/egl.pc
2352                 src/egl/wayland/wayland-drm/Makefile
2353                 src/egl/wayland/wayland-egl/Makefile
2354                 src/egl/wayland/wayland-egl/wayland-egl.pc
2355                 src/gallium/Makefile
2356                 src/gallium/auxiliary/Makefile
2357                 src/gallium/auxiliary/pipe-loader/Makefile
2358                 src/gallium/drivers/freedreno/Makefile
2359                 src/gallium/drivers/galahad/Makefile
2360                 src/gallium/drivers/i915/Makefile
2361                 src/gallium/drivers/ilo/Makefile
2362                 src/gallium/drivers/llvmpipe/Makefile
2363                 src/gallium/drivers/noop/Makefile
2364                 src/gallium/drivers/nouveau/Makefile
2365                 src/gallium/drivers/r300/Makefile
2366                 src/gallium/drivers/r600/Makefile
2367                 src/gallium/drivers/radeon/Makefile
2368                 src/gallium/drivers/radeonsi/Makefile
2369                 src/gallium/drivers/rbug/Makefile
2370                 src/gallium/drivers/softpipe/Makefile
2371                 src/gallium/drivers/svga/Makefile
2372                 src/gallium/drivers/trace/Makefile
2373                 src/gallium/drivers/vc4/Makefile
2374                 src/gallium/drivers/vc4/kernel/Makefile
2375                 src/gallium/state_trackers/clover/Makefile
2376                 src/gallium/state_trackers/dri/Makefile
2377                 src/gallium/state_trackers/glx/xlib/Makefile
2378                 src/gallium/state_trackers/nine/Makefile
2379                 src/gallium/state_trackers/omx/Makefile
2380                 src/gallium/state_trackers/osmesa/Makefile
2381                 src/gallium/state_trackers/va/Makefile
2382                 src/gallium/state_trackers/vdpau/Makefile
2383                 src/gallium/state_trackers/xa/Makefile
2384                 src/gallium/state_trackers/xvmc/Makefile
2385                 src/gallium/targets/d3dadapter9/Makefile
2386                 src/gallium/targets/d3dadapter9/d3d.pc
2387                 src/gallium/targets/dri/Makefile
2388                 src/gallium/targets/libgl-xlib/Makefile
2389                 src/gallium/targets/omx/Makefile
2390                 src/gallium/targets/opencl/Makefile
2391                 src/gallium/targets/osmesa/Makefile
2392                 src/gallium/targets/osmesa/osmesa.pc
2393                 src/gallium/targets/pipe-loader/Makefile
2394                 src/gallium/targets/va/Makefile
2395                 src/gallium/targets/vdpau/Makefile
2396                 src/gallium/targets/xa/Makefile
2397                 src/gallium/targets/xa/xatracker.pc
2398                 src/gallium/targets/xvmc/Makefile
2399                 src/gallium/tests/trivial/Makefile
2400                 src/gallium/tests/unit/Makefile
2401                 src/gallium/winsys/freedreno/drm/Makefile
2402                 src/gallium/winsys/i915/drm/Makefile
2403                 src/gallium/winsys/intel/drm/Makefile
2404                 src/gallium/winsys/nouveau/drm/Makefile
2405                 src/gallium/winsys/radeon/drm/Makefile
2406                 src/gallium/winsys/svga/drm/Makefile
2407                 src/gallium/winsys/sw/dri/Makefile
2408                 src/gallium/winsys/sw/fbdev/Makefile
2409                 src/gallium/winsys/sw/kms-dri/Makefile
2410                 src/gallium/winsys/sw/null/Makefile
2411                 src/gallium/winsys/sw/wayland/Makefile
2412                 src/gallium/winsys/sw/wrapper/Makefile
2413                 src/gallium/winsys/sw/xlib/Makefile
2414                 src/gallium/winsys/vc4/drm/Makefile
2415                 src/gbm/Makefile
2416                 src/gbm/main/gbm.pc
2417                 src/glsl/Makefile
2418                 src/glx/Makefile
2419                 src/glx/apple/Makefile
2420                 src/glx/tests/Makefile
2421                 src/gtest/Makefile
2422                 src/loader/Makefile
2423                 src/mapi/Makefile
2424                 src/mapi/es1api/glesv1_cm.pc
2425                 src/mapi/es2api/glesv2.pc
2426                 src/mapi/glapi/gen/Makefile
2427                 src/mesa/Makefile
2428                 src/mesa/gl.pc
2429                 src/mesa/drivers/dri/dri.pc
2430                 src/mesa/drivers/dri/common/Makefile
2431                 src/mesa/drivers/dri/common/xmlpool/Makefile
2432                 src/mesa/drivers/dri/i915/Makefile
2433                 src/mesa/drivers/dri/i965/Makefile
2434                 src/mesa/drivers/dri/Makefile
2435                 src/mesa/drivers/dri/nouveau/Makefile
2436                 src/mesa/drivers/dri/r200/Makefile
2437                 src/mesa/drivers/dri/radeon/Makefile
2438                 src/mesa/drivers/dri/swrast/Makefile
2439                 src/mesa/drivers/osmesa/Makefile
2440                 src/mesa/drivers/osmesa/osmesa.pc
2441                 src/mesa/drivers/x11/Makefile
2442                 src/mesa/main/tests/Makefile
2443                 src/util/Makefile
2444                 src/util/tests/hash_table/Makefile])
2445
2446 AC_OUTPUT
2447
2448 dnl
2449 dnl Output some configuration info for the user
2450 dnl
2451 echo ""
2452 echo "        prefix:          $prefix"
2453 echo "        exec_prefix:     $exec_prefix"
2454 echo "        libdir:          $libdir"
2455 echo "        includedir:      $includedir"
2456
2457 dnl API info
2458 echo ""
2459 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2460
2461 dnl Driver info
2462 echo ""
2463 case "x$enable_osmesa$enable_gallium_osmesa" in
2464 xnoyes)
2465         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2466         ;;
2467 xyesno)
2468         echo "        OSMesa:          lib$OSMESA_LIB"
2469         ;;
2470 xnono)
2471         echo "        OSMesa:          no"
2472         ;;
2473 esac
2474
2475 echo ""
2476 if test "x$enable_dri" != xno; then
2477         echo "        DRI platform:    $dri_platform"
2478         if test -z "$DRI_DIRS"; then
2479             echo "        DRI drivers:     no"
2480         else
2481             echo "        DRI drivers:     $DRI_DIRS"
2482         fi
2483         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2484 fi
2485
2486 case "x$enable_glx$enable_xlib_glx" in
2487 xyesyes)
2488     echo "        GLX:             Xlib-based"
2489     ;;
2490 xyesno)
2491     echo "        GLX:             DRI-based"
2492     ;;
2493 *)
2494     echo "        GLX:             $enable_glx"
2495     ;;
2496 esac
2497
2498 dnl EGL
2499 echo ""
2500 echo "        EGL:             $enable_egl"
2501 if test "$enable_egl" = yes; then
2502     echo "        EGL platforms:   $egl_platforms"
2503
2504     egl_drivers=""
2505     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2506         egl_drivers="$egl_drivers builtin:egl_dri2"
2507     fi
2508
2509     echo "        EGL drivers:    $egl_drivers"
2510 fi
2511
2512 echo ""
2513 if test "x$MESA_LLVM" = x1; then
2514     echo "        llvm:            yes"
2515     echo "        llvm-config:     $LLVM_CONFIG"
2516     echo "        llvm-version:    $LLVM_VERSION"
2517 else
2518     echo "        llvm:            no"
2519 fi
2520
2521 echo ""
2522 if test -n "$with_gallium_drivers"; then
2523     echo "        Gallium:         yes"
2524 else
2525     echo "        Gallium:         no"
2526 fi
2527
2528 dnl Shader cache
2529 echo ""
2530 echo "        Shader cache:    $enable_shader_cache"
2531 if test "x$enable_shader_cache" = "xyes"; then
2532     echo "        With SHA1 from:  $with_sha1"
2533 fi
2534
2535 dnl Libraries
2536 echo ""
2537 echo "        Shared libs:     $enable_shared"
2538 echo "        Static libs:     $enable_static"
2539 echo "        Shared-glapi:    $enable_shared_glapi"
2540
2541 dnl Compiler options
2542 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2543 cflags=`echo $CFLAGS | \
2544     $SED 's/^ *//;s/  */ /;s/ *$//'`
2545 cxxflags=`echo $CXXFLAGS | \
2546     $SED 's/^ *//;s/  */ /;s/ *$//'`
2547 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2548 echo ""
2549 echo "        CFLAGS:          $cflags"
2550 echo "        CXXFLAGS:        $cxxflags"
2551 echo "        Macros:          $defines"
2552 echo ""
2553 if test "x$MESA_LLVM" = x1; then
2554     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2555     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2556     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2557     echo ""
2558 fi
2559 echo "        PYTHON2:         $PYTHON2"
2560
2561 echo ""
2562 echo "        Run '${MAKE-make}' to build Mesa"
2563 echo ""