configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284
 285 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 286 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 287 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 288 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 289 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 290 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 291 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 293
 294 AC_SUBST([GL_LIB_NAME])
 295 AC_SUBST([GLU_LIB_NAME])
 296 AC_SUBST([GLUT_LIB_NAME])
 297 AC_SUBST([GLW_LIB_NAME])
 298 AC_SUBST([OSMESA_LIB_NAME])
 299 AC_SUBST([EGL_LIB_NAME])
 300 AC_SUBST([GLESv1_CM_LIB_NAME])
 301 AC_SUBST([GLESv2_LIB_NAME])
 302
 303 AC_SUBST([GL_LIB_GLOB])
 304 AC_SUBST([GLU_LIB_GLOB])
 305 AC_SUBST([GLUT_LIB_GLOB])
 306 AC_SUBST([GLW_LIB_GLOB])
 307 AC_SUBST([OSMESA_LIB_GLOB])
 308 AC_SUBST([EGL_LIB_GLOB])
 309 AC_SUBST([GLESv1_CM_LIB_GLOB])
 310 AC_SUBST([GLESv2_LIB_GLOB])
 311
 312 dnl
 313 dnl Arch/platform-specific settings
 314 dnl
 315 AC_ARG_ENABLE([asm],
 316     [AS_HELP_STRING([--disable-asm],
 317         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 318     [enable_asm="$enableval"],
 319     [enable_asm=yes]
 320 )
 321 asm_arch=""
 322 ASM_FLAGS=""
 323 MESA_ASM_SOURCES=""
 324 GLAPI_ASM_SOURCES=""
 325 AC_MSG_CHECKING([whether to enable assembly])
 326 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 327 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 328 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 329     case "$host_cpu" in
 330     i?86 | x86_64)
 331         enable_asm=no
 332         AC_MSG_RESULT([no, cross compiling])
 333         ;;
 334     esac
 335 fi
 336 # check for supported arches
 337 if test "x$enable_asm" = xyes; then
 338     case "$host_cpu" in
 339     i?86)
 340         case "$host_os" in
 341         linux* | *freebsd* | dragonfly*)
 342             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 343             ;;
 344         esac
 345         ;;
 346     x86_64)
 347         case "$host_os" in
 348         linux* | *freebsd* | dragonfly*)
 349             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 350             ;;
 351         esac
 352         ;;
 353     powerpc)
 354         case "$host_os" in
 355         linux*)
 356             asm_arch=ppc
 357             ;;
 358         esac
 359         ;;
 360     sparc*)
 361         case "$host_os" in
 362         linux*)
 363             asm_arch=sparc
 364             ;;
 365         esac
 366         ;;
 367     esac
 368
 369     case "$asm_arch" in
 370     x86)
 371         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 372         MESA_ASM_SOURCES='$(X86_SOURCES)'
 373         GLAPI_ASM_SOURCES='$(X86_API)'
 374         AC_MSG_RESULT([yes, x86])
 375         ;;
 376     x86_64)
 377         ASM_FLAGS="-DUSE_X86_64_ASM"
 378         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 379         GLAPI_ASM_SOURCES='$(X86-64_API)'
 380         AC_MSG_RESULT([yes, x86_64])
 381         ;;
 382     ppc)
 383         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 384         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 385         AC_MSG_RESULT([yes, ppc])
 386         ;;
 387     sparc)
 388         ASM_FLAGS="-DUSE_SPARC_ASM"
 389         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 390         GLAPI_ASM_SOURCES='$(SPARC_API)'
 391         AC_MSG_RESULT([yes, sparc])
 392         ;;
 393     *)
 394         AC_MSG_RESULT([no, platform not supported])
 395         ;;
 396     esac
 397 fi
 398 AC_SUBST([ASM_FLAGS])
 399 AC_SUBST([MESA_ASM_SOURCES])
 400 AC_SUBST([GLAPI_ASM_SOURCES])
 401
 402 dnl PIC code macro
 403 MESA_PIC_FLAGS
 404
 405 dnl Check to see if dlopen is in default libraries (like Solaris, which
 406 dnl has it in libc), or if libdl is needed to get it.
 407 AC_CHECK_FUNC([dlopen], [],
 408     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 409
 410 dnl See if posix_memalign is available
 411 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 412
 413 dnl SELinux awareness.
 414 AC_ARG_ENABLE([selinux],
 415     [AS_HELP_STRING([--enable-selinux],
 416         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 417     [MESA_SELINUX="$enableval"],
 418     [MESA_SELINUX=no])
 419 if test "x$enable_selinux" = "xyes"; then
 420     AC_CHECK_HEADER([selinux/selinux.h],[],
 421                     [AC_MSG_ERROR([SELinux headers not found])])
 422     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 423                  [AC_MSG_ERROR([SELinux library not found])])
 424     SELINUX_LIBS="-lselinux"
 425     DEFINES="$DEFINES -DMESA_SELINUX"
 426 fi
 427
 428 dnl
 429 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 430 dnl More later: fbdev, ...
 431 dnl
 432 default_driver="xlib"
 433
 434 case "$host_os" in
 435 linux*)
 436     case "$host_cpu" in
 437     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 438     esac
 439     ;;
 440 *freebsd* | dragonfly*)
 441     case "$host_cpu" in
 442     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 443     esac
 444     ;;
 445 esac
 446
 447 AC_ARG_WITH([driver],
 448     [AS_HELP_STRING([--with-driver=DRIVER],
 449         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 450     [mesa_driver="$withval"],
 451     [mesa_driver="$default_driver"])
 452 dnl Check for valid option
 453 case "x$mesa_driver" in
 454 xxlib|xdri|xosmesa)
 455     ;;
 456 *)
 457     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 458     ;;
 459 esac
 460
 461 dnl
 462 dnl Driver specific build directories
 463 dnl
 464
 465 dnl this variable will be prepended to SRC_DIRS and is not exported
 466 CORE_DIRS="glsl mesa"
 467
 468 SRC_DIRS="glew"
 469 GLU_DIRS="sgi"
 470 GALLIUM_DIRS="auxiliary drivers state_trackers"
 471 GALLIUM_TARGET_DIRS=""
 472 GALLIUM_WINSYS_DIRS="sw"
 473 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 474 GALLIUM_STATE_TRACKERS_DIRS=""
 475
 476 case "$mesa_driver" in
 477 xlib)
 478     DRIVER_DIRS="x11"
 479     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 480     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 481     ;;
 482 dri)
 483     SRC_DIRS="$SRC_DIRS glx"
 484     DRIVER_DIRS="dri"
 485     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 486     ;;
 487 osmesa)
 488     DRIVER_DIRS="osmesa"
 489     ;;
 490 esac
 491 AC_SUBST([SRC_DIRS])
 492 AC_SUBST([GLU_DIRS])
 493 AC_SUBST([DRIVER_DIRS])
 494 AC_SUBST([GALLIUM_DIRS])
 495 AC_SUBST([GALLIUM_TARGET_DIRS])
 496 AC_SUBST([GALLIUM_WINSYS_DIRS])
 497 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 498 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 499 AC_SUBST([MESA_LLVM])
 500
 501 dnl
 502 dnl User supplied program configuration
 503 dnl
 504 if test -d "$srcdir/progs/demos"; then
 505     default_demos=yes
 506 else
 507     default_demos=no
 508 fi
 509 AC_ARG_WITH([demos],
 510     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 511         [optional comma delimited demo directories to build
 512         @<:@default=auto if source available@:>@])],
 513     [with_demos="$withval"],
 514     [with_demos="$default_demos"])
 515 if test "x$with_demos" = x; then
 516     with_demos=no
 517 fi
 518
 519 dnl If $with_demos is yes, directories will be added as libs available
 520 PROGRAM_DIRS=""
 521 case "$with_demos" in
 522 no) ;;
 523 yes)
 524     # If the driver isn't osmesa, we have libGL and can build xdemos
 525     if test "$mesa_driver" != osmesa; then
 526         PROGRAM_DIRS="xdemos"
 527     fi
 528     ;;
 529 *)
 530     # verify the requested demos directories exist
 531     demos=`IFS=,; echo $with_demos`
 532     for demo in $demos; do
 533         test -d "$srcdir/progs/$demo" || \
 534             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 535     done
 536     PROGRAM_DIRS="$demos"
 537     ;;
 538 esac
 539
 540 dnl
 541 dnl Find out if X is available. The variable have_x is set if libX11 is
 542 dnl found to mimic AC_PATH_XTRA.
 543 dnl
 544 if test -n "$PKG_CONFIG"; then
 545     AC_MSG_CHECKING([pkg-config files for X11 are available])
 546     PKG_CHECK_EXISTS([x11],[
 547         x11_pkgconfig=yes
 548         have_x=yes
 549         ],[
 550         x11_pkgconfig=no
 551     ])
 552     AC_MSG_RESULT([$x11_pkgconfig])
 553 else
 554     x11_pkgconfig=no
 555 fi
 556 dnl Use the autoconf macro if no pkg-config files
 557 if test "$x11_pkgconfig" = yes; then
 558     PKG_CHECK_MODULES([X11], [x11])
 559 else
 560     AC_PATH_XTRA
 561     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 562     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 563     AC_SUBST([X11_CFLAGS])
 564     AC_SUBST([X11_LIBS])
 565 fi
 566
 567 dnl Try to tell the user that the --x-* options are only used when
 568 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 569 m4_divert_once([HELP_BEGIN],
 570 [These options are only used when the X libraries cannot be found by the
 571 pkg-config utility.])
 572
 573 dnl We need X for xlib and dri, so bomb now if it's not found
 574 case "$mesa_driver" in
 575 xlib|dri)
 576     if test "$no_x" = yes; then
 577         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 578     fi
 579     ;;
 580 esac
 581
 582 dnl XCB - this is only used for GLX right now
 583 AC_ARG_ENABLE([xcb],
 584     [AS_HELP_STRING([--enable-xcb],
 585         [use XCB for GLX @<:@default=disabled@:>@])],
 586     [enable_xcb="$enableval"],
 587     [enable_xcb=no])
 588 if test "x$enable_xcb" = xyes; then
 589     DEFINES="$DEFINES -DUSE_XCB"
 590 else
 591     enable_xcb=no
 592 fi
 593
 594 dnl
 595 dnl libGL configuration per driver
 596 dnl
 597 case "$mesa_driver" in
 598 xlib)
 599     if test "$x11_pkgconfig" = yes; then
 600         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 601         GL_PC_REQ_PRIV="x11 xext"
 602         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 603         GL_LIB_DEPS="$XLIBGL_LIBS"
 604     else
 605         # should check these...
 606         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 607         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 608         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 609         GL_PC_CFLAGS="$X11_INCLUDES"
 610     fi
 611     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 612     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 613
 614     # if static, move the external libraries to the programs
 615     # and empty the libraries for libGL
 616     if test "$enable_static" = yes; then
 617         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 618         GL_LIB_DEPS=""
 619     fi
 620     ;;
 621 dri)
 622     # DRI must be shared, I think
 623     if test "$enable_static" = yes; then
 624         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 625     fi
 626
 627     # Check for libdrm
 628     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 629     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 630     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 631     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 632     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 633
 634     # find the DRI deps for libGL
 635     if test "$x11_pkgconfig" = yes; then
 636         # add xcb modules if necessary
 637         dri_modules="x11 xext xxf86vm xdamage xfixes"
 638         if test "$enable_xcb" = yes; then
 639             dri_modules="$dri_modules x11-xcb xcb-glx"
 640         fi
 641
 642         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 643         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 644         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 645         GL_LIB_DEPS="$DRIGL_LIBS"
 646     else
 647         # should check these...
 648         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 649         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 650         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 651         GL_PC_CFLAGS="$X11_INCLUDES"
 652
 653         # XCB can only be used from pkg-config
 654         if test "$enable_xcb" = yes; then
 655             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 656             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 657             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 658             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 659         fi
 660     fi
 661
 662     # need DRM libs, -lpthread, etc.
 663     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 664     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 665     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 666     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 667     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 668     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 669     ;;
 670 osmesa)
 671     # No libGL for osmesa
 672     GL_LIB_DEPS=""
 673     ;;
 674 esac
 675 AC_SUBST([GL_LIB_DEPS])
 676 AC_SUBST([GL_PC_REQ_PRIV])
 677 AC_SUBST([GL_PC_LIB_PRIV])
 678 AC_SUBST([GL_PC_CFLAGS])
 679 AC_SUBST([DRI_PC_REQ_PRIV])
 680 AC_SUBST([GLESv1_LIB_DEPS])
 681 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 682 AC_SUBST([GLESv2_LIB_DEPS])
 683 AC_SUBST([GLESv2_PC_LIB_PRIV])
 684
 685
 686 dnl
 687 dnl More X11 setup
 688 dnl
 689 if test "$mesa_driver" = xlib; then
 690     DEFINES="$DEFINES -DUSE_XSHM"
 691 fi
 692
 693 dnl
 694 dnl More DRI setup
 695 dnl
 696 AC_ARG_ENABLE([glx-tls],
 697     [AS_HELP_STRING([--enable-glx-tls],
 698         [enable TLS support in GLX @<:@default=disabled@:>@])],
 699     [GLX_USE_TLS="$enableval"],
 700     [GLX_USE_TLS=no])
 701 dnl Directory for DRI drivers
 702 AC_ARG_WITH([dri-driverdir],
 703     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 704         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 705     [DRI_DRIVER_INSTALL_DIR="$withval"],
 706     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 707 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 708 dnl Extra search path for DRI drivers
 709 AC_ARG_WITH([dri-searchpath],
 710     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 711         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 712     [DRI_DRIVER_SEARCH_DIR="$withval"],
 713     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 714 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 715 dnl Direct rendering or just indirect rendering
 716 AC_ARG_ENABLE([driglx-direct],
 717     [AS_HELP_STRING([--disable-driglx-direct],
 718         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 719     [driglx_direct="$enableval"],
 720     [driglx_direct="yes"])
 721 dnl Which drivers to build - default is chosen by platform
 722 AC_ARG_WITH([dri-drivers],
 723     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 724         [comma delimited DRI drivers list, e.g.
 725         "swrast,i965,radeon" @<:@default=auto@:>@])],
 726     [with_dri_drivers="$withval"],
 727     [with_dri_drivers=yes])
 728 if test "x$with_dri_drivers" = x; then
 729     with_dri_drivers=no
 730 fi
 731
 732 dnl Determine which APIs to support
 733 AC_ARG_ENABLE([opengl],
 734     [AS_HELP_STRING([--disable-opengl],
 735         [disable support for standard OpenGL API @<:@default=no@:>@])],
 736     [enable_opengl="$enableval"],
 737     [enable_opengl=yes])
 738 AC_ARG_ENABLE([gles1],
 739     [AS_HELP_STRING([--enable-gles1],
 740         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 741     [enable_gles1="$enableval"],
 742     [enable_gles1=no])
 743 AC_ARG_ENABLE([gles2],
 744     [AS_HELP_STRING([--enable-gles2],
 745         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 746     [enable_gles2="$enableval"],
 747     [enable_gles2=no])
 748
 749 API_DEFINES=""
 750 APIS=""
 751 ES1_SOURCES=""
 752 ES2_SOURCES=""
 753 if test "x$enable_opengl" = xno; then
 754     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 755 else
 756     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 757     APIS="$APIS gl"
 758 fi
 759 if test "x$enable_gles1" = xyes; then
 760     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 761     APIS="$APIS es1"
 762     ES1_SOURCES='$(ES1_SOURCES)'
 763 fi
 764 if test "x$enable_gles2" = xyes; then
 765     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 766     APIS="$APIS es2"
 767     ES2_SOURCES='$(ES2_SOURCES)'
 768 fi
 769 if test "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 770     SRC_DIRS="$SRC_DIRS gles"
 771 fi
 772 AC_SUBST([API_DEFINES])
 773 AC_SUBST([APIS])
 774 AC_SUBST([ES1_SOURCES])
 775 AC_SUBST([ES2_SOURCES])
 776
 777 dnl If $with_dri_drivers is yes, directories will be added through
 778 dnl platform checks
 779 DRI_DIRS=""
 780 case "$with_dri_drivers" in
 781 no) ;;
 782 yes)
 783     DRI_DIRS="yes"
 784     ;;
 785 *)
 786     # verify the requested driver directories exist
 787     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 788     for driver in $dri_drivers; do
 789         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 790             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 791     done
 792     DRI_DIRS="$dri_drivers"
 793     ;;
 794 esac
 795
 796 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 797 if test "$mesa_driver" = dri; then
 798     # Use TLS in GLX?
 799     if test "x$GLX_USE_TLS" = xyes; then
 800         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 801     fi
 802
 803     # Platform specific settings and drivers to build
 804     case "$host_os" in
 805     linux*)
 806         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 807         if test "x$driglx_direct" = xyes; then
 808             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 809         fi
 810         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 811
 812         case "$host_cpu" in
 813         x86_64)
 814             # sis is missing because they have not be converted to use
 815             # the new interface.  i810 are missing because there is no
 816             # x86-64 system where they could *ever* be used.
 817             if test "x$DRI_DIRS" = "xyes"; then
 818                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 819                     savage tdfx unichrome swrast"
 820             fi
 821             ;;
 822         powerpc*)
 823             # Build only the drivers for cards that exist on PowerPC.
 824             # At some point MGA will be added, but not yet.
 825             if test "x$DRI_DIRS" = "xyes"; then
 826                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 827             fi
 828             ;;
 829         sparc*)
 830             # Build only the drivers for cards that exist on sparc`
 831             if test "x$DRI_DIRS" = "xyes"; then
 832                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 833             fi
 834             ;;
 835         esac
 836         ;;
 837     freebsd* | dragonfly*)
 838         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 839         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 840         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 841         if test "x$driglx_direct" = xyes; then
 842             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 843         fi
 844         if test "x$GXX" = xyes; then
 845             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 846         fi
 847
 848         if test "x$DRI_DIRS" = "xyes"; then
 849             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 850                 unichrome savage sis swrast"
 851         fi
 852         ;;
 853     gnu*)
 854         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 855         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 856         ;;
 857     solaris*)
 858         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 859         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 860         if test "x$driglx_direct" = xyes; then
 861             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 862         fi
 863         ;;
 864     esac
 865
 866     # default drivers
 867     if test "x$DRI_DIRS" = "xyes"; then
 868         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 869             savage sis tdfx unichrome swrast"
 870     fi
 871
 872     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 873
 874     # Check for expat
 875     EXPAT_INCLUDES=""
 876     EXPAT_LIB=-lexpat
 877     AC_ARG_WITH([expat],
 878         [AS_HELP_STRING([--with-expat=DIR],
 879             [expat install directory])],[
 880         EXPAT_INCLUDES="-I$withval/include"
 881         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 882         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 883         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 884         ])
 885     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 886     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 887         [AC_MSG_ERROR([Expat required for DRI.])])
 888
 889     # put all the necessary libs together
 890     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 891 fi
 892 AC_SUBST([DRI_DIRS])
 893 AC_SUBST([EXPAT_INCLUDES])
 894 AC_SUBST([DRI_LIB_DEPS])
 895
 896 case $DRI_DIRS in
 897 *i915*|*i965*)
 898     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 899     ;;
 900 esac
 901
 902 case $DRI_DIRS in
 903 *radeon*|*r200*|*r300*|*r600*)
 904     PKG_CHECK_MODULES([LIBDRM_RADEON],
 905                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 906                       HAVE_LIBDRM_RADEON=yes,
 907                       HAVE_LIBDRM_RADEON=no)
 908
 909     if test "$HAVE_LIBDRM_RADEON" = yes; then
 910         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 911         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 912     fi
 913     ;;
 914 esac
 915 AC_SUBST([RADEON_CFLAGS])
 916 AC_SUBST([RADEON_LDFLAGS])
 917
 918
 919 dnl
 920 dnl OSMesa configuration
 921 dnl
 922 if test "$mesa_driver" = xlib; then
 923     default_gl_osmesa=yes
 924 else
 925     default_gl_osmesa=no
 926 fi
 927 AC_ARG_ENABLE([gl-osmesa],
 928     [AS_HELP_STRING([--enable-gl-osmesa],
 929         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 930     [gl_osmesa="$enableval"],
 931     [gl_osmesa="$default_gl_osmesa"])
 932 if test "x$gl_osmesa" = xyes; then
 933     if test "$mesa_driver" = osmesa; then
 934         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 935     else
 936         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 937     fi
 938 fi
 939
 940 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 941 AC_ARG_WITH([osmesa-bits],
 942     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 943         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 944     [osmesa_bits="$withval"],
 945     [osmesa_bits=8])
 946 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 947     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 948     osmesa_bits=8
 949 fi
 950 case "x$osmesa_bits" in
 951 x8)
 952     OSMESA_LIB=OSMesa
 953     ;;
 954 x16|x32)
 955     OSMESA_LIB="OSMesa$osmesa_bits"
 956     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 957     ;;
 958 *)
 959     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 960     ;;
 961 esac
 962 AC_SUBST([OSMESA_LIB])
 963
 964 case "$mesa_driver" in
 965 osmesa)
 966     # only link libraries with osmesa if shared
 967     if test "$enable_static" = no; then
 968         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 969     else
 970         OSMESA_LIB_DEPS=""
 971     fi
 972     OSMESA_MESA_DEPS=""
 973     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 974     ;;
 975 *)
 976     # Link OSMesa to libGL otherwise
 977     OSMESA_LIB_DEPS=""
 978     # only link libraries with osmesa if shared
 979     if test "$enable_static" = no; then
 980         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 981     else
 982         OSMESA_MESA_DEPS=""
 983     fi
 984     OSMESA_PC_REQ="gl"
 985     ;;
 986 esac
 987 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 988 AC_SUBST([OSMESA_LIB_DEPS])
 989 AC_SUBST([OSMESA_MESA_DEPS])
 990 AC_SUBST([OSMESA_PC_REQ])
 991 AC_SUBST([OSMESA_PC_LIB_PRIV])
 992
 993 dnl
 994 dnl EGL configuration
 995 dnl
 996 AC_ARG_ENABLE([egl],
 997     [AS_HELP_STRING([--disable-egl],
 998         [disable EGL library @<:@default=enabled@:>@])],
 999     [enable_egl="$enableval"],
1000     [enable_egl=yes])
1001 if test "x$enable_egl" = xyes; then
1002     SRC_DIRS="$SRC_DIRS egl"
1003     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1004     EGL_DRIVERS_DIRS=""
1005     if test "$enable_static" != yes; then
1006         # build egl_glx when libGL is built
1007         if test "$mesa_driver" != osmesa; then
1008             EGL_DRIVERS_DIRS="glx"
1009         fi
1010
1011         # build egl_dri2 when xcb-dri2 is available
1012         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
1013                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1014         if test "$have_xcb_dri2" = yes; then
1015             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
1016         fi
1017     fi
1018
1019     if test "$with_demos" = yes; then
1020         PROGRAM_DIRS="$PROGRAM_DIRS egl/eglut egl/opengl"
1021     fi
1022 fi
1023 AC_SUBST([EGL_LIB_DEPS])
1024 AC_SUBST([EGL_DRIVERS_DIRS])
1025
1026 dnl
1027 dnl GLU configuration
1028 dnl
1029 AC_ARG_ENABLE([glu],
1030     [AS_HELP_STRING([--disable-glu],
1031         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1032     [enable_glu="$enableval"],
1033     [enable_glu=yes])
1034 if test "x$enable_glu" = xyes; then
1035     SRC_DIRS="$SRC_DIRS glu"
1036
1037     case "$mesa_driver" in
1038     osmesa)
1039         # If GLU is available and we have libOSMesa (not 16 or 32),
1040         # we can build the osdemos
1041         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
1042             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
1043         fi
1044
1045         # Link libGLU to libOSMesa instead of libGL
1046         GLU_LIB_DEPS=""
1047         GLU_PC_REQ="osmesa"
1048         if test "$enable_static" = no; then
1049             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1050         else
1051             GLU_MESA_DEPS=""
1052         fi
1053         ;;
1054     *)
1055         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1056         GLU_PC_REQ="gl"
1057         GLU_PC_LIB_PRIV="-lm"
1058         if test "$enable_static" = no; then
1059             GLU_LIB_DEPS="-lm"
1060             GLU_MESA_DEPS='-l$(GL_LIB)'
1061         else
1062             GLU_LIB_DEPS=""
1063             GLU_MESA_DEPS=""
1064             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1065         fi
1066         ;;
1067     esac
1068 fi
1069 if test "$enable_static" = no; then
1070     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1071 fi
1072 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1073 AC_SUBST([GLU_LIB_DEPS])
1074 AC_SUBST([GLU_MESA_DEPS])
1075 AC_SUBST([GLU_PC_REQ])
1076 AC_SUBST([GLU_PC_REQ_PRIV])
1077 AC_SUBST([GLU_PC_LIB_PRIV])
1078 AC_SUBST([GLU_PC_CFLAGS])
1079
1080 dnl
1081 dnl GLw configuration
1082 dnl
1083 AC_ARG_ENABLE([glw],
1084     [AS_HELP_STRING([--disable-glw],
1085         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1086     [enable_glw="$enableval"],
1087     [enable_glw=yes])
1088 dnl Don't build GLw on osmesa
1089 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1090     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1091     enable_glw=no
1092 fi
1093 AC_ARG_ENABLE([motif],
1094     [AS_HELP_STRING([--enable-motif],
1095         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1096     [enable_motif="$enableval"],
1097     [enable_motif=no])
1098
1099 if test "x$enable_glw" = xyes; then
1100     SRC_DIRS="$SRC_DIRS glw"
1101     if test "$x11_pkgconfig" = yes; then
1102         PKG_CHECK_MODULES([GLW],[x11 xt])
1103         GLW_PC_REQ_PRIV="x11 xt"
1104         GLW_LIB_DEPS="$GLW_LIBS"
1105     else
1106         # should check these...
1107         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1108         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1109         GLW_PC_CFLAGS="$X11_INCLUDES"
1110     fi
1111
1112     GLW_SOURCES="GLwDrawA.c"
1113     MOTIF_CFLAGS=
1114     if test "x$enable_motif" = xyes; then
1115         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1116         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1117         if test "x$MOTIF_CONFIG" != xno; then
1118             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1119             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1120         else
1121             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1122                 [AC_MSG_ERROR([Can't locate Motif headers])])
1123             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1124                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1125         fi
1126         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1127         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1128         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1129         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1130     fi
1131
1132     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1133     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1134     if test "$enable_static" = no; then
1135         GLW_MESA_DEPS='-l$(GL_LIB)'
1136         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1137     else
1138         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1139         GLW_LIB_DEPS=""
1140         GLW_MESA_DEPS=""
1141     fi
1142 fi
1143 AC_SUBST([GLW_LIB_DEPS])
1144 AC_SUBST([GLW_MESA_DEPS])
1145 AC_SUBST([GLW_SOURCES])
1146 AC_SUBST([MOTIF_CFLAGS])
1147 AC_SUBST([GLW_PC_REQ_PRIV])
1148 AC_SUBST([GLW_PC_LIB_PRIV])
1149 AC_SUBST([GLW_PC_CFLAGS])
1150
1151 dnl
1152 dnl GLUT configuration
1153 dnl
1154 if test -f "$srcdir/include/GL/glut.h"; then
1155     default_glut=yes
1156 else
1157     default_glut=no
1158 fi
1159 AC_ARG_ENABLE([glut],
1160     [AS_HELP_STRING([--disable-glut],
1161         [enable GLUT library @<:@default=enabled if source available@:>@])],
1162     [enable_glut="$enableval"],
1163     [enable_glut="$default_glut"])
1164
1165 dnl Can't build glut if GLU not available
1166 if test "x$enable_glu$enable_glut" = xnoyes; then
1167     AC_MSG_WARN([Disabling glut since GLU is disabled])
1168     enable_glut=no
1169 fi
1170 dnl Don't build glut on osmesa
1171 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1172     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1173     enable_glut=no
1174 fi
1175
1176 if test "x$enable_glut" = xyes; then
1177     SRC_DIRS="$SRC_DIRS glut/glx"
1178     GLUT_CFLAGS=""
1179     if test "x$GCC" = xyes; then
1180         GLUT_CFLAGS="-fexceptions"
1181     fi
1182     if test "$x11_pkgconfig" = yes; then
1183         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1184         GLUT_PC_REQ_PRIV="x11 xmu xi"
1185         GLUT_LIB_DEPS="$GLUT_LIBS"
1186     else
1187         # should check these...
1188         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1189         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1190         GLUT_PC_CFLAGS="$X11_INCLUDES"
1191     fi
1192     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1193     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1194
1195     # If glut is available, we can build most programs
1196     if test "$with_demos" = yes; then
1197         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1198     fi
1199
1200     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1201     if test "$enable_static" = no; then
1202         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1203     else
1204         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1205         GLUT_LIB_DEPS=""
1206         GLUT_MESA_DEPS=""
1207     fi
1208 fi
1209 AC_SUBST([GLUT_LIB_DEPS])
1210 AC_SUBST([GLUT_MESA_DEPS])
1211 AC_SUBST([GLUT_CFLAGS])
1212 AC_SUBST([GLUT_PC_REQ_PRIV])
1213 AC_SUBST([GLUT_PC_LIB_PRIV])
1214 AC_SUBST([GLUT_PC_CFLAGS])
1215
1216 dnl
1217 dnl Program library dependencies
1218 dnl    Only libm is added here if necessary as the libraries should
1219 dnl    be pulled in by the linker
1220 dnl
1221 if test "x$APP_LIB_DEPS" = x; then
1222     case "$host_os" in
1223     solaris*)
1224         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1225         ;;
1226     cygwin*)
1227         APP_LIB_DEPS="-lX11"
1228         ;;
1229     *)
1230         APP_LIB_DEPS="-lm"
1231         ;;
1232     esac
1233 fi
1234 AC_SUBST([APP_LIB_DEPS])
1235 AC_SUBST([PROGRAM_DIRS])
1236
1237 dnl
1238 dnl Gallium configuration
1239 dnl
1240 AC_ARG_ENABLE([gallium],
1241     [AS_HELP_STRING([--disable-gallium],
1242         [build gallium @<:@default=enabled@:>@])],
1243     [enable_gallium="$enableval"],
1244     [enable_gallium=yes])
1245 if test "x$enable_gallium" = xyes; then
1246     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1247     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1248                 [HAS_UDIS86="no"])
1249     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1250 fi
1251
1252 AC_SUBST([LLVM_CFLAGS])
1253 AC_SUBST([LLVM_LIBS])
1254 AC_SUBST([LLVM_LDFLAGS])
1255 AC_SUBST([LLVM_VERSION])
1256
1257 dnl
1258 dnl Gallium state trackers configuration
1259 dnl
1260 AC_ARG_WITH([state-trackers],
1261     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1262         [comma delimited state_trackers list, e.g.
1263         "egl,glx" @<:@default=auto@:>@])],
1264     [with_state_trackers="$withval"],
1265     [with_state_trackers=yes])
1266
1267 case "$with_state_trackers" in
1268 no)
1269     GALLIUM_STATE_TRACKERS_DIRS=""
1270     ;;
1271 yes)
1272     # look at what else is built
1273     case "$mesa_driver" in
1274     xlib)
1275         GALLIUM_STATE_TRACKERS_DIRS=glx
1276         ;;
1277     dri)
1278         GALLIUM_STATE_TRACKERS_DIRS="dri"
1279         HAVE_ST_DRI="yes"
1280         if test "x$enable_egl" = xyes; then
1281             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1282             HAVE_ST_EGL="yes"
1283         fi
1284         # Have only tested st/xorg on 1.6.0 servers
1285         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1286             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1287             HAVE_ST_XORG="no")
1288         ;;
1289     esac
1290     ;;
1291 *)
1292     # verify the requested state tracker exist
1293     state_trackers=`IFS=', '; echo $with_state_trackers`
1294     for tracker in $state_trackers; do
1295         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1296             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1297
1298         case "$tracker" in
1299         dri)
1300             if test "x$mesa_driver" != xdri; then
1301                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1302             fi
1303             HAVE_ST_DRI="yes"
1304             ;;
1305         egl)
1306             if test "x$enable_egl" != xyes; then
1307                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1308             fi
1309             HAVE_ST_EGL="yes"
1310             ;;
1311         xorg)
1312             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1313             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1314             HAVE_ST_XORG="yes"
1315             ;;
1316         es)
1317             # mesa/es is required to build es state tracker
1318             CORE_DIRS="$CORE_DIRS mesa/es"
1319             ;;
1320         esac
1321     done
1322     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1323     ;;
1324 esac
1325
1326 if test "x$HAVE_ST_XORG" = xyes; then
1327     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1328         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1329         HAVE_XEXTPROTO_71="no")
1330 fi
1331
1332 AC_ARG_WITH([egl-displays],
1333     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1334         [comma delimited native displays libEGL supports, e.g.
1335         "x11,kms" @<:@default=auto@:>@])],
1336     [with_egl_displays="$withval"],
1337     [with_egl_displays=yes])
1338
1339 EGL_DISPLAYS=""
1340 case "$with_egl_displays" in
1341 yes)
1342     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1343         EGL_DISPLAYS="x11"
1344     fi
1345     ;;
1346 *)
1347     if test "x$enable_egl" != xyes; then
1348         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1349     fi
1350     # verify the requested driver directories exist
1351     egl_displays=`IFS=', '; echo $with_egl_displays`
1352     for dpy in $egl_displays; do
1353         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1354             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1355     done
1356     EGL_DISPLAYS="$egl_displays"
1357     ;;
1358 esac
1359 AC_SUBST([EGL_DISPLAYS])
1360
1361 AC_ARG_WITH([egl-driver-dir],
1362     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1363                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1364     [EGL_DRIVER_INSTALL_DIR="$withval"],
1365     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1366 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1367
1368 AC_ARG_WITH([xorg-driver-dir],
1369     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1370                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1371     [XORG_DRIVER_INSTALL_DIR="$withval"],
1372     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1373 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1374
1375 AC_ARG_WITH([max-width],
1376     [AS_HELP_STRING([--with-max-width=N],
1377                     [Maximum framebuffer width (4096)])],
1378     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1379      AS_IF([test "${withval}" -gt "4096"],
1380            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1381 )
1382 AC_ARG_WITH([max-height],
1383     [AS_HELP_STRING([--with-max-height=N],
1384                     [Maximum framebuffer height (4096)])],
1385     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1386      AS_IF([test "${withval}" -gt "4096"],
1387            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1388 )
1389
1390 dnl
1391 dnl Gallium LLVM
1392 dnl
1393 AC_ARG_ENABLE([gallium-llvm],
1394     [AS_HELP_STRING([--enable-gallium-llvm],
1395         [build gallium LLVM support @<:@default=disabled@:>@])],
1396     [enable_gallium_llvm="$enableval"],
1397     [enable_gallium_llvm=auto])
1398 if test "x$enable_gallium_llvm" = xyes; then
1399     if test "x$LLVM_CONFIG" != xno; then
1400         LLVM_VERSION=`$LLVM_CONFIG --version`
1401         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1402         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1403
1404         if test "x$HAS_UDIS86" != xno; then
1405             LLVM_LIBS="$LLVM_LIBS -ludis86"
1406             DEFINES="$DEFINES -DHAVE_UDIS86"
1407         fi
1408         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1409         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1410         DEFINES="$DEFINES -DMESA_LLVM -D__STDC_CONSTANT_MACROS"
1411         MESA_LLVM=1
1412     else
1413         MESA_LLVM=0
1414     fi
1415 else
1416     MESA_LLVM=0
1417 fi
1418
1419 dnl
1420 dnl Gallium helper functions
1421 dnl
1422 gallium_check_st() {
1423     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1424          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1425     fi
1426     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1427          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1428     fi
1429     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1430          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1431     fi
1432     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1433          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1434     fi
1435 }
1436
1437
1438 dnl
1439 dnl Gallium SVGA configuration
1440 dnl
1441 AC_ARG_ENABLE([gallium-svga],
1442     [AS_HELP_STRING([--enable-gallium-svga],
1443         [build gallium SVGA @<:@default=disabled@:>@])],
1444     [enable_gallium_svga="$enableval"],
1445     [enable_gallium_svga=auto])
1446 if test "x$enable_gallium_svga" = xyes; then
1447     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1448     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1449 elif test "x$enable_gallium_svga" = xauto; then
1450     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1451 fi
1452
1453 dnl
1454 dnl Gallium Intel configuration
1455 dnl
1456 AC_ARG_ENABLE([gallium-intel],
1457     [AS_HELP_STRING([--enable-gallium-intel],
1458         [build gallium intel @<:@default=disabled@:>@])],
1459     [enable_gallium_intel="$enableval"],
1460     [enable_gallium_intel=auto])
1461 if test "x$enable_gallium_intel" = xyes; then
1462     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1463     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1464     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1465 elif test "x$enable_gallium_intel" = xauto; then
1466     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1467     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1468 fi
1469
1470 dnl
1471 dnl Gallium Radeon configuration
1472 dnl
1473 AC_ARG_ENABLE([gallium-radeon],
1474     [AS_HELP_STRING([--enable-gallium-radeon],
1475         [build gallium radeon @<:@default=disabled@:>@])],
1476     [enable_gallium_radeon="$enableval"],
1477     [enable_gallium_radeon=auto])
1478 if test "x$enable_gallium_radeon" = xyes; then
1479     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1480     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1481 elif test "x$enable_gallium_radeon" = xauto; then
1482     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1483 fi
1484
1485 dnl
1486 dnl Gallium Nouveau configuration
1487 dnl
1488 AC_ARG_ENABLE([gallium-nouveau],
1489     [AS_HELP_STRING([--enable-gallium-nouveau],
1490         [build gallium nouveau @<:@default=disabled@:>@])],
1491     [enable_gallium_nouveau="$enableval"],
1492     [enable_gallium_nouveau=no])
1493 if test "x$enable_gallium_nouveau" = xyes; then
1494     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1495     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1496 fi
1497
1498 dnl
1499 dnl Gallium swrast configuration
1500 dnl
1501 AC_ARG_ENABLE([gallium-swrast],
1502     [AS_HELP_STRING([--enable-gallium-swrast],
1503         [build gallium swrast @<:@default=auto@:>@])],
1504     [enable_gallium_swrast="$enableval"],
1505     [enable_gallium_swrast=auto])
1506 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1507     if test "x$HAVE_ST_DRI" = xyes; then
1508         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1509     fi
1510     if test "x$HAVE_ST_EGL" = xyes; then
1511         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1512     fi
1513 fi
1514
1515 dnl prepend CORE_DIRS to SRC_DIRS
1516 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1517
1518 dnl Restore LDFLAGS and CPPFLAGS
1519 LDFLAGS="$_SAVE_LDFLAGS"
1520 CPPFLAGS="$_SAVE_CPPFLAGS"
1521
1522 dnl Substitute the config
1523 AC_CONFIG_FILES([configs/autoconf])
1524
1525 dnl Replace the configs/current symlink
1526 AC_CONFIG_COMMANDS([configs],[
1527 if test -f configs/current || test -L configs/current; then
1528     rm -f configs/current
1529 fi
1530 ln -s autoconf configs/current
1531 ])
1532
1533 AC_OUTPUT
1534
1535 dnl
1536 dnl Output some configuration info for the user
1537 dnl
1538 echo ""
1539 echo "        prefix:          $prefix"
1540 echo "        exec_prefix:     $exec_prefix"
1541 echo "        libdir:          $libdir"
1542 echo "        includedir:      $includedir"
1543
1544 dnl Driver info
1545 echo ""
1546 echo "        Driver:          $mesa_driver"
1547 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1548     echo "        OSMesa:          lib$OSMESA_LIB"
1549 else
1550     echo "        OSMesa:          no"
1551 fi
1552 if test "$mesa_driver" = dri; then
1553     # cleanup the drivers var
1554     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1555 if test "x$DRI_DIRS" = x; then
1556     echo "        DRI drivers:     no"
1557 else
1558     echo "        DRI drivers:     $dri_dirs"
1559 fi
1560     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1561 fi
1562 echo "        Use XCB:         $enable_xcb"
1563
1564 echo ""
1565 if test "x$MESA_LLVM" == x1; then
1566     echo "        llvm:            yes"
1567     echo "        llvm-config:     $LLVM_CONFIG"
1568     echo "        llvm-version:    $LLVM_VERSION"
1569 else
1570     echo "        llvm:            no"
1571 fi
1572
1573 echo ""
1574 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1575     echo "        Gallium:         yes"
1576     echo "        Gallium dirs:    $GALLIUM_DIRS"
1577     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1578     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1579     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1580     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1581 else
1582     echo "        Gallium:         no"
1583 fi
1584
1585 dnl Libraries
1586 echo ""
1587 echo "        Shared libs:     $enable_shared"
1588 echo "        Static libs:     $enable_static"
1589 if test "$enable_egl" = yes; then
1590     echo "        EGL:             $EGL_DRIVERS_DIRS"
1591 else
1592     echo "        EGL:             no"
1593 fi
1594 echo "        GLU:             $enable_glu"
1595 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1596 echo "        glut:            $enable_glut"
1597
1598 dnl Programs
1599 # cleanup the programs var for display
1600 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1601 if test "x$program_dirs" = x; then
1602     echo "        Demos:           no"
1603 else
1604     echo "        Demos:           $program_dirs"
1605 fi
1606
1607 dnl Compiler options
1608 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1609 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1610     $SED 's/^ *//;s/  */ /;s/ *$//'`
1611 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1612     $SED 's/^ *//;s/  */ /;s/ *$//'`
1613 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1614 echo ""
1615 echo "        CFLAGS:          $cflags"
1616 echo "        CXXFLAGS:        $cxxflags"
1617 echo "        Macros:          $defines"
1618
1619 echo ""
1620 echo "        Run '${MAKE-make}' to build Mesa"
1621 echo ""