configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 285
 286 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 287 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 288 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 289 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 290 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 291 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 293 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 294 VG_LIB_GLOB='lib$(VG_LIB).*'${LIB_EXTENSION}'*'
 295
 296 AC_SUBST([GL_LIB_NAME])
 297 AC_SUBST([GLU_LIB_NAME])
 298 AC_SUBST([GLUT_LIB_NAME])
 299 AC_SUBST([GLW_LIB_NAME])
 300 AC_SUBST([OSMESA_LIB_NAME])
 301 AC_SUBST([EGL_LIB_NAME])
 302 AC_SUBST([GLESv1_CM_LIB_NAME])
 303 AC_SUBST([GLESv2_LIB_NAME])
 304 AC_SUBST([VG_LIB_NAME])
 305
 306 AC_SUBST([GL_LIB_GLOB])
 307 AC_SUBST([GLU_LIB_GLOB])
 308 AC_SUBST([GLUT_LIB_GLOB])
 309 AC_SUBST([GLW_LIB_GLOB])
 310 AC_SUBST([OSMESA_LIB_GLOB])
 311 AC_SUBST([EGL_LIB_GLOB])
 312 AC_SUBST([GLESv1_CM_LIB_GLOB])
 313 AC_SUBST([GLESv2_LIB_GLOB])
 314 AC_SUBST([VG_LIB_GLOB])
 315
 316 dnl
 317 dnl Arch/platform-specific settings
 318 dnl
 319 AC_ARG_ENABLE([asm],
 320     [AS_HELP_STRING([--disable-asm],
 321         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 322     [enable_asm="$enableval"],
 323     [enable_asm=yes]
 324 )
 325 asm_arch=""
 326 ASM_FLAGS=""
 327 MESA_ASM_SOURCES=""
 328 GLAPI_ASM_SOURCES=""
 329 AC_MSG_CHECKING([whether to enable assembly])
 330 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 331 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 332 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 333     case "$host_cpu" in
 334     i?86 | x86_64)
 335         enable_asm=no
 336         AC_MSG_RESULT([no, cross compiling])
 337         ;;
 338     esac
 339 fi
 340 # check for supported arches
 341 if test "x$enable_asm" = xyes; then
 342     case "$host_cpu" in
 343     i?86)
 344         case "$host_os" in
 345         linux* | *freebsd* | dragonfly*)
 346             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 347             ;;
 348         esac
 349         ;;
 350     x86_64)
 351         case "$host_os" in
 352         linux* | *freebsd* | dragonfly*)
 353             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 354             ;;
 355         esac
 356         ;;
 357     powerpc)
 358         case "$host_os" in
 359         linux*)
 360             asm_arch=ppc
 361             ;;
 362         esac
 363         ;;
 364     sparc*)
 365         case "$host_os" in
 366         linux*)
 367             asm_arch=sparc
 368             ;;
 369         esac
 370         ;;
 371     esac
 372
 373     case "$asm_arch" in
 374     x86)
 375         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 376         MESA_ASM_SOURCES='$(X86_SOURCES)'
 377         GLAPI_ASM_SOURCES='$(X86_API)'
 378         AC_MSG_RESULT([yes, x86])
 379         ;;
 380     x86_64)
 381         ASM_FLAGS="-DUSE_X86_64_ASM"
 382         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 383         GLAPI_ASM_SOURCES='$(X86-64_API)'
 384         AC_MSG_RESULT([yes, x86_64])
 385         ;;
 386     ppc)
 387         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 388         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 389         AC_MSG_RESULT([yes, ppc])
 390         ;;
 391     sparc)
 392         ASM_FLAGS="-DUSE_SPARC_ASM"
 393         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 394         GLAPI_ASM_SOURCES='$(SPARC_API)'
 395         AC_MSG_RESULT([yes, sparc])
 396         ;;
 397     *)
 398         AC_MSG_RESULT([no, platform not supported])
 399         ;;
 400     esac
 401 fi
 402 AC_SUBST([ASM_FLAGS])
 403 AC_SUBST([MESA_ASM_SOURCES])
 404 AC_SUBST([GLAPI_ASM_SOURCES])
 405
 406 dnl PIC code macro
 407 MESA_PIC_FLAGS
 408
 409 dnl Check to see if dlopen is in default libraries (like Solaris, which
 410 dnl has it in libc), or if libdl is needed to get it.
 411 AC_CHECK_FUNC([dlopen], [],
 412     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 413
 414 dnl See if posix_memalign is available
 415 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 416
 417 dnl SELinux awareness.
 418 AC_ARG_ENABLE([selinux],
 419     [AS_HELP_STRING([--enable-selinux],
 420         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 421     [MESA_SELINUX="$enableval"],
 422     [MESA_SELINUX=no])
 423 if test "x$enable_selinux" = "xyes"; then
 424     AC_CHECK_HEADER([selinux/selinux.h],[],
 425                     [AC_MSG_ERROR([SELinux headers not found])])
 426     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 427                  [AC_MSG_ERROR([SELinux library not found])])
 428     SELINUX_LIBS="-lselinux"
 429     DEFINES="$DEFINES -DMESA_SELINUX"
 430 fi
 431
 432 dnl
 433 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 434 dnl More later: fbdev, ...
 435 dnl
 436 default_driver="xlib"
 437
 438 case "$host_os" in
 439 linux*)
 440     case "$host_cpu" in
 441     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 442     esac
 443     ;;
 444 *freebsd* | dragonfly*)
 445     case "$host_cpu" in
 446     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 447     esac
 448     ;;
 449 esac
 450
 451 AC_ARG_WITH([driver],
 452     [AS_HELP_STRING([--with-driver=DRIVER],
 453         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 454     [mesa_driver="$withval"],
 455     [mesa_driver="$default_driver"])
 456 dnl Check for valid option
 457 case "x$mesa_driver" in
 458 xxlib|xdri|xosmesa)
 459     ;;
 460 *)
 461     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 462     ;;
 463 esac
 464
 465 dnl
 466 dnl Driver specific build directories
 467 dnl
 468
 469 dnl this variable will be prepended to SRC_DIRS and is not exported
 470 CORE_DIRS="mapi/glapi glsl mesa"
 471
 472 SRC_DIRS="glew"
 473 GLU_DIRS="sgi"
 474 GALLIUM_DIRS="auxiliary drivers state_trackers"
 475 GALLIUM_TARGET_DIRS=""
 476 GALLIUM_WINSYS_DIRS="sw"
 477 GALLIUM_DRIVERS_DIRS="softpipe failover trace identity"
 478 GALLIUM_STATE_TRACKERS_DIRS=""
 479
 480 case "$mesa_driver" in
 481 xlib)
 482     DRIVER_DIRS="x11"
 483     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 484     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 485     ;;
 486 dri)
 487     SRC_DIRS="$SRC_DIRS glx"
 488     DRIVER_DIRS="dri"
 489     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 490     ;;
 491 osmesa)
 492     DRIVER_DIRS="osmesa"
 493     ;;
 494 esac
 495 AC_SUBST([SRC_DIRS])
 496 AC_SUBST([GLU_DIRS])
 497 AC_SUBST([DRIVER_DIRS])
 498 AC_SUBST([GALLIUM_DIRS])
 499 AC_SUBST([GALLIUM_TARGET_DIRS])
 500 AC_SUBST([GALLIUM_WINSYS_DIRS])
 501 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 502 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 503 AC_SUBST([MESA_LLVM])
 504
 505 dnl
 506 dnl User supplied program configuration
 507 dnl
 508 if test -d "$srcdir/progs/demos"; then
 509     default_demos=yes
 510 else
 511     default_demos=no
 512 fi
 513 AC_ARG_WITH([demos],
 514     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 515         [optional comma delimited demo directories to build
 516         @<:@default=auto if source available@:>@])],
 517     [with_demos="$withval"],
 518     [with_demos="$default_demos"])
 519 if test "x$with_demos" = x; then
 520     with_demos=no
 521 fi
 522
 523 dnl If $with_demos is yes, directories will be added as libs available
 524 PROGRAM_DIRS=""
 525 case "$with_demos" in
 526 no) ;;
 527 yes)
 528     # If the driver isn't osmesa, we have libGL and can build xdemos
 529     if test "$mesa_driver" != osmesa; then
 530         PROGRAM_DIRS="xdemos"
 531     fi
 532     ;;
 533 *)
 534     # verify the requested demos directories exist
 535     demos=`IFS=,; echo $with_demos`
 536     for demo in $demos; do
 537         test -d "$srcdir/progs/$demo" || \
 538             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 539     done
 540     PROGRAM_DIRS="$demos"
 541     ;;
 542 esac
 543
 544 dnl
 545 dnl Find out if X is available. The variable have_x is set if libX11 is
 546 dnl found to mimic AC_PATH_XTRA.
 547 dnl
 548 if test -n "$PKG_CONFIG"; then
 549     AC_MSG_CHECKING([pkg-config files for X11 are available])
 550     PKG_CHECK_EXISTS([x11],[
 551         x11_pkgconfig=yes
 552         have_x=yes
 553         ],[
 554         x11_pkgconfig=no
 555     ])
 556     AC_MSG_RESULT([$x11_pkgconfig])
 557 else
 558     x11_pkgconfig=no
 559 fi
 560 dnl Use the autoconf macro if no pkg-config files
 561 if test "$x11_pkgconfig" = yes; then
 562     PKG_CHECK_MODULES([X11], [x11])
 563 else
 564     AC_PATH_XTRA
 565     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 566     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 567     AC_SUBST([X11_CFLAGS])
 568     AC_SUBST([X11_LIBS])
 569 fi
 570
 571 dnl Try to tell the user that the --x-* options are only used when
 572 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 573 m4_divert_once([HELP_BEGIN],
 574 [These options are only used when the X libraries cannot be found by the
 575 pkg-config utility.])
 576
 577 dnl We need X for xlib and dri, so bomb now if it's not found
 578 case "$mesa_driver" in
 579 xlib|dri)
 580     if test "$no_x" = yes; then
 581         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 582     fi
 583     ;;
 584 esac
 585
 586 dnl XCB - this is only used for GLX right now
 587 AC_ARG_ENABLE([xcb],
 588     [AS_HELP_STRING([--enable-xcb],
 589         [use XCB for GLX @<:@default=disabled@:>@])],
 590     [enable_xcb="$enableval"],
 591     [enable_xcb=no])
 592 if test "x$enable_xcb" = xyes; then
 593     DEFINES="$DEFINES -DUSE_XCB"
 594 else
 595     enable_xcb=no
 596 fi
 597
 598 dnl
 599 dnl libGL configuration per driver
 600 dnl
 601 case "$mesa_driver" in
 602 xlib)
 603     if test "$x11_pkgconfig" = yes; then
 604         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 605         GL_PC_REQ_PRIV="x11 xext"
 606         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 607         GL_LIB_DEPS="$XLIBGL_LIBS"
 608     else
 609         # should check these...
 610         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 611         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 612         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 613         GL_PC_CFLAGS="$X11_INCLUDES"
 614     fi
 615     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 616     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 617
 618     # if static, move the external libraries to the programs
 619     # and empty the libraries for libGL
 620     if test "$enable_static" = yes; then
 621         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 622         GL_LIB_DEPS=""
 623     fi
 624     ;;
 625 dri)
 626     # DRI must be shared, I think
 627     if test "$enable_static" = yes; then
 628         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 629     fi
 630
 631     # Check for libdrm
 632     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 633     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 634     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 635     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 636     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 637
 638     # find the DRI deps for libGL
 639     if test "$x11_pkgconfig" = yes; then
 640         # add xcb modules if necessary
 641         dri_modules="x11 xext xxf86vm xdamage xfixes"
 642         if test "$enable_xcb" = yes; then
 643             dri_modules="$dri_modules x11-xcb xcb-glx"
 644         fi
 645
 646         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 647         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 648         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 649         GL_LIB_DEPS="$DRIGL_LIBS"
 650     else
 651         # should check these...
 652         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 653         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 654         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 655         GL_PC_CFLAGS="$X11_INCLUDES"
 656
 657         # XCB can only be used from pkg-config
 658         if test "$enable_xcb" = yes; then
 659             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 660             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 661             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 662             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 663         fi
 664     fi
 665
 666     # need DRM libs, -lpthread, etc.
 667     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 668     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 669     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 670     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 671     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 672     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 673     ;;
 674 osmesa)
 675     # No libGL for osmesa
 676     GL_LIB_DEPS=""
 677     ;;
 678 esac
 679 AC_SUBST([GL_LIB_DEPS])
 680 AC_SUBST([GL_PC_REQ_PRIV])
 681 AC_SUBST([GL_PC_LIB_PRIV])
 682 AC_SUBST([GL_PC_CFLAGS])
 683 AC_SUBST([DRI_PC_REQ_PRIV])
 684 AC_SUBST([GLESv1_LIB_DEPS])
 685 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 686 AC_SUBST([GLESv2_LIB_DEPS])
 687 AC_SUBST([GLESv2_PC_LIB_PRIV])
 688
 689
 690 dnl
 691 dnl More X11 setup
 692 dnl
 693 if test "$mesa_driver" = xlib; then
 694     DEFINES="$DEFINES -DUSE_XSHM"
 695 fi
 696
 697 dnl
 698 dnl More DRI setup
 699 dnl
 700 AC_ARG_ENABLE([glx-tls],
 701     [AS_HELP_STRING([--enable-glx-tls],
 702         [enable TLS support in GLX @<:@default=disabled@:>@])],
 703     [GLX_USE_TLS="$enableval"],
 704     [GLX_USE_TLS=no])
 705 dnl Directory for DRI drivers
 706 AC_ARG_WITH([dri-driverdir],
 707     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 708         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 709     [DRI_DRIVER_INSTALL_DIR="$withval"],
 710     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 711 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 712 dnl Extra search path for DRI drivers
 713 AC_ARG_WITH([dri-searchpath],
 714     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 715         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 716     [DRI_DRIVER_SEARCH_DIR="$withval"],
 717     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 718 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 719 dnl Direct rendering or just indirect rendering
 720 AC_ARG_ENABLE([driglx-direct],
 721     [AS_HELP_STRING([--disable-driglx-direct],
 722         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 723     [driglx_direct="$enableval"],
 724     [driglx_direct="yes"])
 725 dnl Which drivers to build - default is chosen by platform
 726 AC_ARG_WITH([dri-drivers],
 727     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 728         [comma delimited DRI drivers list, e.g.
 729         "swrast,i965,radeon" @<:@default=auto@:>@])],
 730     [with_dri_drivers="$withval"],
 731     [with_dri_drivers=yes])
 732 if test "x$with_dri_drivers" = x; then
 733     with_dri_drivers=no
 734 fi
 735
 736 dnl Determine which APIs to support
 737 AC_ARG_ENABLE([opengl],
 738     [AS_HELP_STRING([--disable-opengl],
 739         [disable support for standard OpenGL API @<:@default=no@:>@])],
 740     [enable_opengl="$enableval"],
 741     [enable_opengl=yes])
 742 AC_ARG_ENABLE([gles1],
 743     [AS_HELP_STRING([--enable-gles1],
 744         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 745     [enable_gles1="$enableval"],
 746     [enable_gles1=no])
 747 AC_ARG_ENABLE([gles2],
 748     [AS_HELP_STRING([--enable-gles2],
 749         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 750     [enable_gles2="$enableval"],
 751     [enable_gles2=no])
 752
 753 API_DEFINES=""
 754 APIS=""
 755 if test "x$enable_opengl" = xno; then
 756     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 757 else
 758     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 759     APIS="$APIS gl"
 760 fi
 761 if test "x$enable_gles1" = xyes; then
 762     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 763     APIS="$APIS es1"
 764 fi
 765 if test "x$enable_gles2" = xyes; then
 766     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 767     APIS="$APIS es2"
 768 fi
 769 if test "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 770     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 771     SRC_DIRS="$SRC_DIRS gles"
 772 fi
 773 AC_SUBST([API_DEFINES])
 774 AC_SUBST([APIS])
 775
 776 dnl If $with_dri_drivers is yes, directories will be added through
 777 dnl platform checks
 778 DRI_DIRS=""
 779 case "$with_dri_drivers" in
 780 no) ;;
 781 yes)
 782     DRI_DIRS="yes"
 783     ;;
 784 *)
 785     # verify the requested driver directories exist
 786     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 787     for driver in $dri_drivers; do
 788         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 789             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 790     done
 791     DRI_DIRS="$dri_drivers"
 792     ;;
 793 esac
 794
 795 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 796 if test "$mesa_driver" = dri; then
 797     # Use TLS in GLX?
 798     if test "x$GLX_USE_TLS" = xyes; then
 799         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 800     fi
 801
 802     # Platform specific settings and drivers to build
 803     case "$host_os" in
 804     linux*)
 805         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 806         if test "x$driglx_direct" = xyes; then
 807             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 808         fi
 809         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 810
 811         case "$host_cpu" in
 812         x86_64)
 813             # sis is missing because they have not be converted to use
 814             # the new interface.  i810 are missing because there is no
 815             # x86-64 system where they could *ever* be used.
 816             if test "x$DRI_DIRS" = "xyes"; then
 817                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 818                     savage tdfx unichrome swrast"
 819             fi
 820             ;;
 821         powerpc*)
 822             # Build only the drivers for cards that exist on PowerPC.
 823             # At some point MGA will be added, but not yet.
 824             if test "x$DRI_DIRS" = "xyes"; then
 825                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 826             fi
 827             ;;
 828         sparc*)
 829             # Build only the drivers for cards that exist on sparc`
 830             if test "x$DRI_DIRS" = "xyes"; then
 831                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 832             fi
 833             ;;
 834         esac
 835         ;;
 836     freebsd* | dragonfly*)
 837         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 838         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 839         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 840         if test "x$driglx_direct" = xyes; then
 841             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 842         fi
 843         if test "x$GXX" = xyes; then
 844             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 845         fi
 846
 847         if test "x$DRI_DIRS" = "xyes"; then
 848             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 849                 unichrome savage sis swrast"
 850         fi
 851         ;;
 852     gnu*)
 853         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 854         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 855         ;;
 856     solaris*)
 857         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 858         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 859         if test "x$driglx_direct" = xyes; then
 860             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 861         fi
 862         ;;
 863     esac
 864
 865     # default drivers
 866     if test "x$DRI_DIRS" = "xyes"; then
 867         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 868             savage sis tdfx unichrome swrast"
 869     fi
 870
 871     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 872
 873     # Check for expat
 874     EXPAT_INCLUDES=""
 875     EXPAT_LIB=-lexpat
 876     AC_ARG_WITH([expat],
 877         [AS_HELP_STRING([--with-expat=DIR],
 878             [expat install directory])],[
 879         EXPAT_INCLUDES="-I$withval/include"
 880         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 881         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 882         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 883         ])
 884     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 885     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 886         [AC_MSG_ERROR([Expat required for DRI.])])
 887
 888     # put all the necessary libs together
 889     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 890 fi
 891 AC_SUBST([DRI_DIRS])
 892 AC_SUBST([EXPAT_INCLUDES])
 893 AC_SUBST([DRI_LIB_DEPS])
 894
 895 case $DRI_DIRS in
 896 *i915*|*i965*)
 897     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 898     ;;
 899 esac
 900
 901 case $DRI_DIRS in
 902 *radeon*|*r200*|*r300*|*r600*)
 903     PKG_CHECK_MODULES([LIBDRM_RADEON],
 904                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 905                       HAVE_LIBDRM_RADEON=yes,
 906                       HAVE_LIBDRM_RADEON=no)
 907
 908     if test "$HAVE_LIBDRM_RADEON" = yes; then
 909         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 910         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 911     fi
 912     ;;
 913 esac
 914 AC_SUBST([RADEON_CFLAGS])
 915 AC_SUBST([RADEON_LDFLAGS])
 916
 917
 918 dnl
 919 dnl OSMesa configuration
 920 dnl
 921 if test "$mesa_driver" = xlib; then
 922     default_gl_osmesa=yes
 923 else
 924     default_gl_osmesa=no
 925 fi
 926 AC_ARG_ENABLE([gl-osmesa],
 927     [AS_HELP_STRING([--enable-gl-osmesa],
 928         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 929     [gl_osmesa="$enableval"],
 930     [gl_osmesa="$default_gl_osmesa"])
 931 if test "x$gl_osmesa" = xyes; then
 932     if test "$mesa_driver" = osmesa; then
 933         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 934     else
 935         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 936     fi
 937 fi
 938
 939 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 940 AC_ARG_WITH([osmesa-bits],
 941     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 942         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 943     [osmesa_bits="$withval"],
 944     [osmesa_bits=8])
 945 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 946     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 947     osmesa_bits=8
 948 fi
 949 case "x$osmesa_bits" in
 950 x8)
 951     OSMESA_LIB=OSMesa
 952     ;;
 953 x16|x32)
 954     OSMESA_LIB="OSMesa$osmesa_bits"
 955     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 956     ;;
 957 *)
 958     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 959     ;;
 960 esac
 961 AC_SUBST([OSMESA_LIB])
 962
 963 case "$mesa_driver" in
 964 osmesa)
 965     # only link libraries with osmesa if shared
 966     if test "$enable_static" = no; then
 967         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 968     else
 969         OSMESA_LIB_DEPS=""
 970     fi
 971     OSMESA_MESA_DEPS=""
 972     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 973     ;;
 974 *)
 975     # Link OSMesa to libGL otherwise
 976     OSMESA_LIB_DEPS=""
 977     # only link libraries with osmesa if shared
 978     if test "$enable_static" = no; then
 979         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 980     else
 981         OSMESA_MESA_DEPS=""
 982     fi
 983     OSMESA_PC_REQ="gl"
 984     ;;
 985 esac
 986 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 987 AC_SUBST([OSMESA_LIB_DEPS])
 988 AC_SUBST([OSMESA_MESA_DEPS])
 989 AC_SUBST([OSMESA_PC_REQ])
 990 AC_SUBST([OSMESA_PC_LIB_PRIV])
 991
 992 dnl
 993 dnl EGL configuration
 994 dnl
 995 AC_ARG_ENABLE([egl],
 996     [AS_HELP_STRING([--disable-egl],
 997         [disable EGL library @<:@default=enabled@:>@])],
 998     [enable_egl="$enableval"],
 999     [enable_egl=yes])
1000 if test "x$enable_egl" = xyes; then
1001     SRC_DIRS="$SRC_DIRS egl"
1002     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1003     EGL_DRIVERS_DIRS=""
1004     if test "$enable_static" != yes; then
1005         # build egl_glx when libGL is built
1006         if test "$mesa_driver" != osmesa; then
1007             EGL_DRIVERS_DIRS="glx"
1008         fi
1009
1010         # build egl_dri2 when xcb-dri2 is available
1011         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
1012                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1013         if test "$have_xcb_dri2" = yes; then
1014             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
1015         fi
1016     fi
1017
1018     if test "$with_demos" = yes; then
1019         PROGRAM_DIRS="$PROGRAM_DIRS egl/eglut egl/opengl"
1020     fi
1021 fi
1022 AC_SUBST([EGL_LIB_DEPS])
1023 AC_SUBST([EGL_DRIVERS_DIRS])
1024
1025 dnl
1026 dnl GLU configuration
1027 dnl
1028 AC_ARG_ENABLE([glu],
1029     [AS_HELP_STRING([--disable-glu],
1030         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1031     [enable_glu="$enableval"],
1032     [enable_glu=yes])
1033 if test "x$enable_glu" = xyes; then
1034     SRC_DIRS="$SRC_DIRS glu"
1035
1036     case "$mesa_driver" in
1037     osmesa)
1038         # If GLU is available and we have libOSMesa (not 16 or 32),
1039         # we can build the osdemos
1040         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
1041             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
1042         fi
1043
1044         # Link libGLU to libOSMesa instead of libGL
1045         GLU_LIB_DEPS=""
1046         GLU_PC_REQ="osmesa"
1047         if test "$enable_static" = no; then
1048             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1049         else
1050             GLU_MESA_DEPS=""
1051         fi
1052         ;;
1053     *)
1054         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1055         GLU_PC_REQ="gl"
1056         GLU_PC_LIB_PRIV="-lm"
1057         if test "$enable_static" = no; then
1058             GLU_LIB_DEPS="-lm"
1059             GLU_MESA_DEPS='-l$(GL_LIB)'
1060         else
1061             GLU_LIB_DEPS=""
1062             GLU_MESA_DEPS=""
1063             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1064         fi
1065         ;;
1066     esac
1067 fi
1068 if test "$enable_static" = no; then
1069     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1070 fi
1071 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1072 AC_SUBST([GLU_LIB_DEPS])
1073 AC_SUBST([GLU_MESA_DEPS])
1074 AC_SUBST([GLU_PC_REQ])
1075 AC_SUBST([GLU_PC_REQ_PRIV])
1076 AC_SUBST([GLU_PC_LIB_PRIV])
1077 AC_SUBST([GLU_PC_CFLAGS])
1078
1079 dnl
1080 dnl GLw configuration
1081 dnl
1082 AC_ARG_ENABLE([glw],
1083     [AS_HELP_STRING([--disable-glw],
1084         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1085     [enable_glw="$enableval"],
1086     [enable_glw=yes])
1087 dnl Don't build GLw on osmesa
1088 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1089     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1090     enable_glw=no
1091 fi
1092 AC_ARG_ENABLE([motif],
1093     [AS_HELP_STRING([--enable-motif],
1094         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1095     [enable_motif="$enableval"],
1096     [enable_motif=no])
1097
1098 if test "x$enable_glw" = xyes; then
1099     SRC_DIRS="$SRC_DIRS glw"
1100     if test "$x11_pkgconfig" = yes; then
1101         PKG_CHECK_MODULES([GLW],[x11 xt])
1102         GLW_PC_REQ_PRIV="x11 xt"
1103         GLW_LIB_DEPS="$GLW_LIBS"
1104     else
1105         # should check these...
1106         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1107         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1108         GLW_PC_CFLAGS="$X11_INCLUDES"
1109     fi
1110
1111     GLW_SOURCES="GLwDrawA.c"
1112     MOTIF_CFLAGS=
1113     if test "x$enable_motif" = xyes; then
1114         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1115         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1116         if test "x$MOTIF_CONFIG" != xno; then
1117             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1118             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1119         else
1120             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1121                 [AC_MSG_ERROR([Can't locate Motif headers])])
1122             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1123                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1124         fi
1125         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1126         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1127         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1128         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1129     fi
1130
1131     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1132     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1133     if test "$enable_static" = no; then
1134         GLW_MESA_DEPS='-l$(GL_LIB)'
1135         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1136     else
1137         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1138         GLW_LIB_DEPS=""
1139         GLW_MESA_DEPS=""
1140     fi
1141 fi
1142 AC_SUBST([GLW_LIB_DEPS])
1143 AC_SUBST([GLW_MESA_DEPS])
1144 AC_SUBST([GLW_SOURCES])
1145 AC_SUBST([MOTIF_CFLAGS])
1146 AC_SUBST([GLW_PC_REQ_PRIV])
1147 AC_SUBST([GLW_PC_LIB_PRIV])
1148 AC_SUBST([GLW_PC_CFLAGS])
1149
1150 dnl
1151 dnl GLUT configuration
1152 dnl
1153 if test -f "$srcdir/include/GL/glut.h"; then
1154     default_glut=yes
1155 else
1156     default_glut=no
1157 fi
1158 AC_ARG_ENABLE([glut],
1159     [AS_HELP_STRING([--disable-glut],
1160         [enable GLUT library @<:@default=enabled if source available@:>@])],
1161     [enable_glut="$enableval"],
1162     [enable_glut="$default_glut"])
1163
1164 dnl Can't build glut if GLU not available
1165 if test "x$enable_glu$enable_glut" = xnoyes; then
1166     AC_MSG_WARN([Disabling glut since GLU is disabled])
1167     enable_glut=no
1168 fi
1169 dnl Don't build glut on osmesa
1170 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1171     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1172     enable_glut=no
1173 fi
1174
1175 if test "x$enable_glut" = xyes; then
1176     SRC_DIRS="$SRC_DIRS glut/glx"
1177     GLUT_CFLAGS=""
1178     if test "x$GCC" = xyes; then
1179         GLUT_CFLAGS="-fexceptions"
1180     fi
1181     if test "$x11_pkgconfig" = yes; then
1182         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1183         GLUT_PC_REQ_PRIV="x11 xmu xi"
1184         GLUT_LIB_DEPS="$GLUT_LIBS"
1185     else
1186         # should check these...
1187         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1188         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1189         GLUT_PC_CFLAGS="$X11_INCLUDES"
1190     fi
1191     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1192     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1193
1194     # If glut is available, we can build most programs
1195     if test "$with_demos" = yes; then
1196         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1197     fi
1198
1199     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1200     if test "$enable_static" = no; then
1201         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1202     else
1203         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1204         GLUT_LIB_DEPS=""
1205         GLUT_MESA_DEPS=""
1206     fi
1207 fi
1208 AC_SUBST([GLUT_LIB_DEPS])
1209 AC_SUBST([GLUT_MESA_DEPS])
1210 AC_SUBST([GLUT_CFLAGS])
1211 AC_SUBST([GLUT_PC_REQ_PRIV])
1212 AC_SUBST([GLUT_PC_LIB_PRIV])
1213 AC_SUBST([GLUT_PC_CFLAGS])
1214
1215 dnl
1216 dnl Program library dependencies
1217 dnl    Only libm is added here if necessary as the libraries should
1218 dnl    be pulled in by the linker
1219 dnl
1220 if test "x$APP_LIB_DEPS" = x; then
1221     case "$host_os" in
1222     solaris*)
1223         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1224         ;;
1225     cygwin*)
1226         APP_LIB_DEPS="-lX11"
1227         ;;
1228     *)
1229         APP_LIB_DEPS="-lm"
1230         ;;
1231     esac
1232 fi
1233 AC_SUBST([APP_LIB_DEPS])
1234 AC_SUBST([PROGRAM_DIRS])
1235
1236 dnl
1237 dnl Gallium configuration
1238 dnl
1239 AC_ARG_ENABLE([gallium],
1240     [AS_HELP_STRING([--disable-gallium],
1241         [build gallium @<:@default=enabled@:>@])],
1242     [enable_gallium="$enableval"],
1243     [enable_gallium=yes])
1244 if test "x$enable_gallium" = xyes; then
1245     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1246     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1247                 [HAS_UDIS86="no"])
1248     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1249 fi
1250
1251 AC_SUBST([LLVM_CFLAGS])
1252 AC_SUBST([LLVM_LIBS])
1253 AC_SUBST([LLVM_LDFLAGS])
1254 AC_SUBST([LLVM_VERSION])
1255
1256 VG_LIB_DEPS=""
1257
1258 dnl
1259 dnl Gallium state trackers configuration
1260 dnl
1261 AC_ARG_WITH([state-trackers],
1262     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1263         [comma delimited state_trackers list, e.g.
1264         "egl,glx" @<:@default=auto@:>@])],
1265     [with_state_trackers="$withval"],
1266     [with_state_trackers=yes])
1267
1268 case "$with_state_trackers" in
1269 no)
1270     GALLIUM_STATE_TRACKERS_DIRS=""
1271     ;;
1272 yes)
1273     # look at what else is built
1274     case "$mesa_driver" in
1275     xlib)
1276         GALLIUM_STATE_TRACKERS_DIRS=glx
1277         ;;
1278     dri)
1279         GALLIUM_STATE_TRACKERS_DIRS="dri"
1280         HAVE_ST_DRI="yes"
1281         if test "x$enable_egl" = xyes; then
1282             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1283             HAVE_ST_EGL="yes"
1284         fi
1285         # Have only tested st/xorg on 1.6.0 servers
1286         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1287             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1288             HAVE_ST_XORG="no")
1289         ;;
1290     esac
1291     ;;
1292 *)
1293     # verify the requested state tracker exist
1294     state_trackers=`IFS=', '; echo $with_state_trackers`
1295     for tracker in $state_trackers; do
1296         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1297             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1298
1299         case "$tracker" in
1300         dri)
1301             if test "x$mesa_driver" != xdri; then
1302                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1303             fi
1304             HAVE_ST_DRI="yes"
1305             ;;
1306         egl)
1307             if test "x$enable_egl" != xyes; then
1308                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1309             fi
1310             HAVE_ST_EGL="yes"
1311             ;;
1312         xorg)
1313             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1314             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1315             HAVE_ST_XORG="yes"
1316             ;;
1317         es)
1318             if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1319                 CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1320             fi
1321             # mesa/es is required to build es state tracker
1322             CORE_DIRS="$CORE_DIRS mesa/es"
1323             ;;
1324         vega)
1325             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1326             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1327             ;;
1328         esac
1329     done
1330     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1331     ;;
1332 esac
1333
1334 AC_SUBST([VG_LIB_DEPS])
1335
1336 if test "x$HAVE_ST_XORG" = xyes; then
1337     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1338         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1339         HAVE_XEXTPROTO_71="no")
1340 fi
1341
1342 AC_ARG_WITH([egl-displays],
1343     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1344         [comma delimited native displays libEGL supports, e.g.
1345         "x11,kms" @<:@default=auto@:>@])],
1346     [with_egl_displays="$withval"],
1347     [with_egl_displays=yes])
1348
1349 EGL_DISPLAYS=""
1350 case "$with_egl_displays" in
1351 yes)
1352     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1353         EGL_DISPLAYS="x11"
1354     fi
1355     ;;
1356 *)
1357     if test "x$enable_egl" != xyes; then
1358         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1359     fi
1360     # verify the requested driver directories exist
1361     egl_displays=`IFS=', '; echo $with_egl_displays`
1362     for dpy in $egl_displays; do
1363         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1364             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1365     done
1366     EGL_DISPLAYS="$egl_displays"
1367     ;;
1368 esac
1369 AC_SUBST([EGL_DISPLAYS])
1370
1371 AC_ARG_WITH([egl-driver-dir],
1372     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1373                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1374     [EGL_DRIVER_INSTALL_DIR="$withval"],
1375     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1376 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1377
1378 AC_ARG_WITH([xorg-driver-dir],
1379     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1380                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1381     [XORG_DRIVER_INSTALL_DIR="$withval"],
1382     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1383 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1384
1385 AC_ARG_WITH([max-width],
1386     [AS_HELP_STRING([--with-max-width=N],
1387                     [Maximum framebuffer width (4096)])],
1388     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1389      AS_IF([test "${withval}" -gt "4096"],
1390            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1391 )
1392 AC_ARG_WITH([max-height],
1393     [AS_HELP_STRING([--with-max-height=N],
1394                     [Maximum framebuffer height (4096)])],
1395     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1396      AS_IF([test "${withval}" -gt "4096"],
1397            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1398 )
1399
1400 dnl
1401 dnl Gallium LLVM
1402 dnl
1403 AC_ARG_ENABLE([gallium-llvm],
1404     [AS_HELP_STRING([--enable-gallium-llvm],
1405         [build gallium LLVM support @<:@default=disabled@:>@])],
1406     [enable_gallium_llvm="$enableval"],
1407     [enable_gallium_llvm=auto])
1408 if test "x$enable_gallium_llvm" = xyes; then
1409     if test "x$LLVM_CONFIG" != xno; then
1410         LLVM_VERSION=`$LLVM_CONFIG --version`
1411         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1412         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1413
1414         if test "x$HAS_UDIS86" != xno; then
1415             LLVM_LIBS="$LLVM_LIBS -ludis86"
1416             DEFINES="$DEFINES -DHAVE_UDIS86"
1417         fi
1418         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1419         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1420         DEFINES="$DEFINES -DMESA_LLVM -D__STDC_CONSTANT_MACROS"
1421         MESA_LLVM=1
1422     else
1423         MESA_LLVM=0
1424     fi
1425 else
1426     MESA_LLVM=0
1427 fi
1428
1429 dnl
1430 dnl Gallium helper functions
1431 dnl
1432 gallium_check_st() {
1433     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1434          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1435     fi
1436     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1437          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1438     fi
1439     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1440          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1441     fi
1442     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1443          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1444     fi
1445 }
1446
1447
1448 dnl
1449 dnl Gallium SVGA configuration
1450 dnl
1451 AC_ARG_ENABLE([gallium-svga],
1452     [AS_HELP_STRING([--enable-gallium-svga],
1453         [build gallium SVGA @<:@default=disabled@:>@])],
1454     [enable_gallium_svga="$enableval"],
1455     [enable_gallium_svga=auto])
1456 if test "x$enable_gallium_svga" = xyes; then
1457     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1458     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1459 elif test "x$enable_gallium_svga" = xauto; then
1460     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1461 fi
1462
1463 dnl
1464 dnl Gallium Intel configuration
1465 dnl
1466 AC_ARG_ENABLE([gallium-intel],
1467     [AS_HELP_STRING([--enable-gallium-intel],
1468         [build gallium intel @<:@default=disabled@:>@])],
1469     [enable_gallium_intel="$enableval"],
1470     [enable_gallium_intel=auto])
1471 if test "x$enable_gallium_intel" = xyes; then
1472     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1473     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1474     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1475 elif test "x$enable_gallium_intel" = xauto; then
1476     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1477     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1478 fi
1479
1480 dnl
1481 dnl Gallium Radeon configuration
1482 dnl
1483 AC_ARG_ENABLE([gallium-radeon],
1484     [AS_HELP_STRING([--enable-gallium-radeon],
1485         [build gallium radeon @<:@default=disabled@:>@])],
1486     [enable_gallium_radeon="$enableval"],
1487     [enable_gallium_radeon=auto])
1488 if test "x$enable_gallium_radeon" = xyes; then
1489     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1490     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1491 elif test "x$enable_gallium_radeon" = xauto; then
1492     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1493 fi
1494
1495 dnl
1496 dnl Gallium Nouveau configuration
1497 dnl
1498 AC_ARG_ENABLE([gallium-nouveau],
1499     [AS_HELP_STRING([--enable-gallium-nouveau],
1500         [build gallium nouveau @<:@default=disabled@:>@])],
1501     [enable_gallium_nouveau="$enableval"],
1502     [enable_gallium_nouveau=no])
1503 if test "x$enable_gallium_nouveau" = xyes; then
1504     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1505     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1506 fi
1507
1508 dnl
1509 dnl Gallium swrast configuration
1510 dnl
1511 AC_ARG_ENABLE([gallium-swrast],
1512     [AS_HELP_STRING([--enable-gallium-swrast],
1513         [build gallium swrast @<:@default=auto@:>@])],
1514     [enable_gallium_swrast="$enableval"],
1515     [enable_gallium_swrast=auto])
1516 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1517     if test "x$HAVE_ST_DRI" = xyes; then
1518         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1519     fi
1520     if test "x$HAVE_ST_EGL" = xyes; then
1521         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1522     fi
1523 fi
1524
1525 dnl prepend CORE_DIRS to SRC_DIRS
1526 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1527
1528 dnl Restore LDFLAGS and CPPFLAGS
1529 LDFLAGS="$_SAVE_LDFLAGS"
1530 CPPFLAGS="$_SAVE_CPPFLAGS"
1531
1532 dnl Substitute the config
1533 AC_CONFIG_FILES([configs/autoconf])
1534
1535 dnl Replace the configs/current symlink
1536 AC_CONFIG_COMMANDS([configs],[
1537 if test -f configs/current || test -L configs/current; then
1538     rm -f configs/current
1539 fi
1540 ln -s autoconf configs/current
1541 ])
1542
1543 AC_OUTPUT
1544
1545 dnl
1546 dnl Output some configuration info for the user
1547 dnl
1548 echo ""
1549 echo "        prefix:          $prefix"
1550 echo "        exec_prefix:     $exec_prefix"
1551 echo "        libdir:          $libdir"
1552 echo "        includedir:      $includedir"
1553
1554 dnl Driver info
1555 echo ""
1556 echo "        Driver:          $mesa_driver"
1557 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1558     echo "        OSMesa:          lib$OSMESA_LIB"
1559 else
1560     echo "        OSMesa:          no"
1561 fi
1562 if test "$mesa_driver" = dri; then
1563     # cleanup the drivers var
1564     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1565 if test "x$DRI_DIRS" = x; then
1566     echo "        DRI drivers:     no"
1567 else
1568     echo "        DRI drivers:     $dri_dirs"
1569 fi
1570     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1571 fi
1572 echo "        Use XCB:         $enable_xcb"
1573
1574 echo ""
1575 if test "x$MESA_LLVM" == x1; then
1576     echo "        llvm:            yes"
1577     echo "        llvm-config:     $LLVM_CONFIG"
1578     echo "        llvm-version:    $LLVM_VERSION"
1579 else
1580     echo "        llvm:            no"
1581 fi
1582
1583 echo ""
1584 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1585     echo "        Gallium:         yes"
1586     echo "        Gallium dirs:    $GALLIUM_DIRS"
1587     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1588     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1589     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1590     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1591 else
1592     echo "        Gallium:         no"
1593 fi
1594
1595 dnl Libraries
1596 echo ""
1597 echo "        Shared libs:     $enable_shared"
1598 echo "        Static libs:     $enable_static"
1599 if test "$enable_egl" = yes; then
1600     echo "        EGL:             $EGL_DRIVERS_DIRS"
1601 else
1602     echo "        EGL:             no"
1603 fi
1604 echo "        GLU:             $enable_glu"
1605 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1606 echo "        glut:            $enable_glut"
1607
1608 dnl Programs
1609 # cleanup the programs var for display
1610 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1611 if test "x$program_dirs" = x; then
1612     echo "        Demos:           no"
1613 else
1614     echo "        Demos:           $program_dirs"
1615 fi
1616
1617 dnl Compiler options
1618 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1619 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1620     $SED 's/^ *//;s/  */ /;s/ *$//'`
1621 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1622     $SED 's/^ *//;s/  */ /;s/ *$//'`
1623 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1624 echo ""
1625 echo "        CFLAGS:          $cflags"
1626 echo "        CXXFLAGS:        $cxxflags"
1627 echo "        Macros:          $defines"
1628
1629 echo ""
1630 echo "        Run '${MAKE-make}' to build Mesa"
1631 echo ""