configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.35.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_CHECK_PROGS([PYTHON3], [python3])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AX_PROG_BISON([],
 112               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 113                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 114 AX_PROG_FLEX([],
 115              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 116                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 117
 118 AC_CHECK_PROG(INDENT, indent, indent, cat)
 119 if test "x$INDENT" != "xcat"; then
 120     # Only GNU indent is supported
 121     INDENT_VERSION=`indent --version | grep GNU`
 122     if test $? -eq 0; then
 123        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 124     else
 125        INDENT="cat"
 126     fi
 127 fi
 128
 129 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 130
 131 if test -z "$PYTHON2"; then
 132     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 133         AC_MSG_ERROR([Python not found - unable to generate sources])
 134     fi
 135 else
 136     if test "x$acv_mako_found" = xno; then
 137         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 138             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 139         fi
 140     fi
 141 fi
 142
 143 AC_PROG_INSTALL
 144
 145 dnl We need a POSIX shell for parts of the build. Assume we have one
 146 dnl in most cases.
 147 case "$host_os" in
 148 solaris*)
 149     # Solaris /bin/sh is too old/non-POSIX compliant
 150     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 151     SHELL="$POSIX_SHELL"
 152     ;;
 153 esac
 154
 155 dnl clang is mostly GCC-compatible, but its version is much lower,
 156 dnl so we have to check for it.
 157 AC_MSG_CHECKING([if compiling with clang])
 158
 159 AC_COMPILE_IFELSE(
 160 [AC_LANG_PROGRAM([], [[
 161 #ifndef __clang__
 162        not clang
 163 #endif
 164 ]])],
 165 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 166
 167 AC_MSG_RESULT([$acv_mesa_CLANG])
 168
 169 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 170 dnl versions are explictly not supported.
 171 GEN_ASM_OFFSETS=no
 172 USE_GNU99=no
 173 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 174     AC_MSG_CHECKING([whether gcc version is sufficient])
 175     major=0
 176     minor=0
 177
 178     GCC_VERSION=`$CC -dumpversion`
 179     if test $? -eq 0; then
 180         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 181         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 182     fi
 183
 184     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 185         AC_MSG_RESULT([no])
 186         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 187     else
 188         AC_MSG_RESULT([yes])
 189     fi
 190
 191     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 192         USE_GNU99=yes
 193     fi
 194     if test "x$cross_compiling" = xyes; then
 195         GEN_ASM_OFFSETS=yes
 196     fi
 197 fi
 198
 199 dnl Check for compiler builtins
 200 AX_GCC_BUILTIN([__builtin_bswap32])
 201 AX_GCC_BUILTIN([__builtin_bswap64])
 202 AX_GCC_BUILTIN([__builtin_clz])
 203 AX_GCC_BUILTIN([__builtin_clzll])
 204 AX_GCC_BUILTIN([__builtin_ctz])
 205 AX_GCC_BUILTIN([__builtin_expect])
 206 AX_GCC_BUILTIN([__builtin_ffs])
 207 AX_GCC_BUILTIN([__builtin_ffsll])
 208 AX_GCC_BUILTIN([__builtin_popcount])
 209 AX_GCC_BUILTIN([__builtin_popcountll])
 210 AX_GCC_BUILTIN([__builtin_unreachable])
 211
 212 AX_GCC_FUNC_ATTRIBUTE([const])
 213 AX_GCC_FUNC_ATTRIBUTE([flatten])
 214 AX_GCC_FUNC_ATTRIBUTE([format])
 215 AX_GCC_FUNC_ATTRIBUTE([malloc])
 216 AX_GCC_FUNC_ATTRIBUTE([packed])
 217 AX_GCC_FUNC_ATTRIBUTE([pure])
 218 AX_GCC_FUNC_ATTRIBUTE([unused])
 219 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 220
 221 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 222
 223 dnl Make sure the pkg-config macros are defined
 224 m4_ifndef([PKG_PROG_PKG_CONFIG],
 225     [m4_fatal([Could not locate the pkg-config autoconf macros.
 226   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 227   are in a different location, try setting the environment variable
 228   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 229 PKG_PROG_PKG_CONFIG()
 230
 231 dnl LIB_DIR - library basename
 232 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 233 AC_SUBST([LIB_DIR])
 234
 235 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 236 _SAVE_LDFLAGS="$LDFLAGS"
 237 _SAVE_CPPFLAGS="$CPPFLAGS"
 238
 239 dnl Compiler macros
 240 DEFINES="-D__STDC_LIMIT_MACROS"
 241 AC_SUBST([DEFINES])
 242 case "$host_os" in
 243 linux*|*-gnu*|gnu*)
 244     DEFINES="$DEFINES -D_GNU_SOURCE"
 245     ;;
 246 solaris*)
 247     DEFINES="$DEFINES -DSVR4"
 248     ;;
 249 cygwin*)
 250     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 251     ;;
 252 esac
 253
 254 dnl Add flags for gcc and g++
 255 if test "x$GCC" = xyes; then
 256     CFLAGS="$CFLAGS -Wall"
 257
 258     if test "x$USE_GNU99" = xyes; then
 259         CFLAGS="$CFLAGS -std=gnu99"
 260     else
 261         CFLAGS="$CFLAGS -std=c99"
 262     fi
 263
 264     # Enable -Werror=implicit-function-declaration and
 265     # -Werror=missing-prototypes, if available, or otherwise, just
 266     # -Wmissing-prototypes.  This is particularly useful to avoid
 267     # generating a loadable driver module that has undefined symbols.
 268     save_CFLAGS="$CFLAGS"
 269     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 270     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 271     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 272     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 273                    AC_MSG_RESULT([yes]),
 274                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 275                     AC_MSG_RESULT([no])]);
 276
 277     # Enable -fvisibility=hidden if using a gcc that supports it
 278     save_CFLAGS="$CFLAGS"
 279     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 280     VISIBILITY_CFLAGS="-fvisibility=hidden"
 281     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 282     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 283                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 284
 285     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 286     CFLAGS=$save_CFLAGS
 287
 288     # Work around aliasing bugs - developers should comment this out
 289     CFLAGS="$CFLAGS -fno-strict-aliasing"
 290
 291     # We don't want floating-point math functions to set errno or trap
 292     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 293
 294     # gcc's builtin memcmp is slower than glibc's
 295     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 296     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 297
 298     # Flags to help ensure that certain portions of the code -- and only those
 299     # portions -- can be built with MSVC:
 300     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 301     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 302     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 303     #   supports most of C99)
 304     # - the rest has no compiler compiler restrictions
 305     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 306     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 307
 308     # Enable -Werror=vla if compiler supports it
 309     save_CFLAGS="$CFLAGS"
 310     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 311     CFLAGS="$CFLAGS -Werror=vla"
 312     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 313                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 314                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 315                     AC_MSG_RESULT([yes])],
 316                     AC_MSG_RESULT([no]));
 317     CFLAGS="$save_CFLAGS"
 318
 319     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 320     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 321 fi
 322 if test "x$GXX" = xyes; then
 323     CXXFLAGS="$CXXFLAGS -Wall"
 324
 325     # Enable -fvisibility=hidden if using a gcc that supports it
 326     save_CXXFLAGS="$CXXFLAGS"
 327     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 328     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 329     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 330     AC_LANG_PUSH([C++])
 331     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 332                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 333     AC_LANG_POP([C++])
 334
 335     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 336     CXXFLAGS=$save_CXXFLAGS
 337
 338     # Work around aliasing bugs - developers should comment this out
 339     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 340
 341     # gcc's builtin memcmp is slower than glibc's
 342     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 343     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 344 fi
 345
 346 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 347 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 348 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 349 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 350
 351 dnl even if the compiler appears to support it, using visibility attributes isn't
 352 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 353 case "$host_os" in
 354 cygwin*)
 355     VISIBILITY_CFLAGS=""
 356     VISIBILITY_CXXFLAGS=""
 357     ;;
 358 esac
 359
 360 AC_SUBST([VISIBILITY_CFLAGS])
 361 AC_SUBST([VISIBILITY_CXXFLAGS])
 362
 363 dnl
 364 dnl Optional flags, check for compiler support
 365 dnl
 366 SSE41_CFLAGS="-msse4.1"
 367 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 368 dnl stack, but on x86-32 such alignment is not guaranteed.
 369 case "$target_cpu" in
 370 i?86)
 371     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 372     ;;
 373 esac
 374 save_CFLAGS="$CFLAGS"
 375 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 376 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 377 #include <smmintrin.h>
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 380     c = _mm_max_epu32(a, b);
 381     return 0;
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Can't have static and shared libraries, default to static if user
 391 dnl explicitly requested. If both disabled, set to static since shared
 392 dnl was explicitly requested.
 393 case "x$enable_static$enable_shared" in
 394 xyesyes)
 395     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 396     enable_shared=no
 397     ;;
 398 xnono)
 399     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 400     enable_shared=yes
 401     ;;
 402 esac
 403
 404 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 405
 406 dnl
 407 dnl other compiler options
 408 dnl
 409 AC_ARG_ENABLE([debug],
 410     [AS_HELP_STRING([--enable-debug],
 411         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 412     [enable_debug="$enableval"],
 413     [enable_debug=no]
 414 )
 415 if test "x$enable_debug" = xyes; then
 416     DEFINES="$DEFINES -DDEBUG"
 417     if test "x$GCC" = xyes; then
 418         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 419             CFLAGS="$CFLAGS -g"
 420         fi
 421         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 422             CFLAGS="$CFLAGS -O0"
 423         fi
 424     fi
 425     if test "x$GXX" = xyes; then
 426         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 427             CXXFLAGS="$CXXFLAGS -g"
 428         fi
 429         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 430             CXXFLAGS="$CXXFLAGS -O0"
 431         fi
 432     fi
 433 else
 434    DEFINES="$DEFINES -DNDEBUG"
 435 fi
 436
 437 dnl
 438 dnl Check if linker supports -Bsymbolic
 439 dnl
 440 save_LDFLAGS=$LDFLAGS
 441 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 442 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 443 AC_LINK_IFELSE(
 444     [AC_LANG_SOURCE([int main() { return 0;}])],
 445     [AC_MSG_RESULT([yes])
 446         BSYMBOLIC="-Wl,-Bsymbolic";],
 447     [AC_MSG_RESULT([no])
 448         BSYMBOLIC="";])
 449 LDFLAGS=$save_LDFLAGS
 450
 451 AC_SUBST([BSYMBOLIC])
 452
 453 dnl
 454 dnl Check if linker supports garbage collection
 455 dnl
 456 save_LDFLAGS=$LDFLAGS
 457 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 458 AC_MSG_CHECKING([whether ld supports --gc-sections])
 459 AC_LINK_IFELSE(
 460     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 461     [AC_MSG_RESULT([yes])
 462         GC_SECTIONS="-Wl,--gc-sections";],
 463     [AC_MSG_RESULT([no])
 464         GC_SECTIONS="";])
 465 LDFLAGS=$save_LDFLAGS
 466
 467 AC_SUBST([GC_SECTIONS])
 468
 469 dnl
 470 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 471 dnl so when these flags are passed to ld via libtool the checks will fail
 472 dnl
 473 case "$host_os" in
 474 openbsd* | darwin* )
 475     LD_NO_UNDEFINED="" ;;
 476 *)
 477     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 478 esac
 479
 480 AC_SUBST([LD_NO_UNDEFINED])
 481
 482 dnl
 483 dnl Check if linker supports version scripts
 484 dnl
 485 AC_MSG_CHECKING([if the linker supports version-scripts])
 486 save_LDFLAGS=$LDFLAGS
 487 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 488 cat > conftest.map <<EOF
 489 VERSION_1 {
 490      global:
 491          main;
 492
 493      local:
 494          *;
 495 };
 496 EOF
 497 AC_LINK_IFELSE(
 498     [AC_LANG_SOURCE([int main() { return 0;}])],
 499     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 500     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 501 LDFLAGS=$save_LDFLAGS
 502 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 503
 504 dnl
 505 dnl Check if linker supports dynamic list files
 506 dnl
 507 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 508 save_LDFLAGS=$LDFLAGS
 509 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 510 cat > conftest.dyn <<EOF
 511 {
 512         radeon_drm_winsys_create;
 513 };
 514 EOF
 515 AC_LINK_IFELSE(
 516     [AC_LANG_SOURCE([int main() { return 0;}])],
 517     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 518     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 519 LDFLAGS=$save_LDFLAGS
 520 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 521
 522 dnl
 523 dnl compatibility symlinks
 524 dnl
 525 case "$host_os" in
 526 linux* )
 527     HAVE_COMPAT_SYMLINKS=yes ;;
 528 * )
 529     HAVE_COMPAT_SYMLINKS=no ;;
 530 esac
 531
 532 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 533
 534 dnl
 535 dnl library names
 536 dnl
 537 dnl Unfortunately we need to do a few things that libtool can't help us with,
 538 dnl so we need some knowledge of shared library filenames:
 539 dnl
 540 dnl LIB_EXT is the extension used when creating symlinks for alternate
 541 dnl filenames for a shared library which will be dynamically loaded
 542 dnl
 543 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 544 dnl the file for a shared library we wish to link with
 545 dnl
 546 case "$host_os" in
 547 darwin* )
 548     LIB_EXT='dylib'
 549     IMP_LIB_EXT=$LIB_EXT
 550     ;;
 551 cygwin* )
 552     LIB_EXT='dll'
 553     IMP_LIB_EXT='dll.a'
 554     ;;
 555 aix* )
 556     LIB_EXT='a'
 557     IMP_LIB_EXT=$LIB_EXT
 558     ;;
 559 * )
 560     LIB_EXT='so'
 561     IMP_LIB_EXT=$LIB_EXT
 562     ;;
 563 esac
 564
 565 AC_SUBST([LIB_EXT])
 566
 567 AC_ARG_WITH([gl-lib-name],
 568   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 569     [specify GL library name @<:@default=GL@:>@])],
 570   [GL_LIB=$withval],
 571   [GL_LIB=GL])
 572 AC_ARG_WITH([osmesa-lib-name],
 573   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 574     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 575   [OSMESA_LIB=$withval],
 576   [OSMESA_LIB=OSMesa])
 577 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 578 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 579
 580 dnl
 581 dnl Mangled Mesa support
 582 dnl
 583 AC_ARG_ENABLE([mangling],
 584   [AS_HELP_STRING([--enable-mangling],
 585     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 586   [enable_mangling="${enableval}"],
 587   [enable_mangling=no]
 588 )
 589 if test "x${enable_mangling}" = "xyes" ; then
 590   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 591   GL_LIB="Mangled${GL_LIB}"
 592   OSMESA_LIB="Mangled${OSMESA_LIB}"
 593 fi
 594 AC_SUBST([GL_LIB])
 595 AC_SUBST([OSMESA_LIB])
 596
 597 dnl
 598 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 599 dnl
 600 AC_ARG_ENABLE([texture-float],
 601     [AS_HELP_STRING([--enable-texture-float],
 602         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 603     [enable_texture_float="$enableval"],
 604     [enable_texture_float=no]
 605 )
 606 if test "x$enable_texture_float" = xyes; then
 607     AC_MSG_WARN([Floating-point textures enabled.])
 608     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 609     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 610 fi
 611
 612 dnl
 613 dnl Arch/platform-specific settings
 614 dnl
 615 AC_ARG_ENABLE([asm],
 616     [AS_HELP_STRING([--disable-asm],
 617         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 618     [enable_asm="$enableval"],
 619     [enable_asm=yes]
 620 )
 621 asm_arch=""
 622 AC_MSG_CHECKING([whether to enable assembly])
 623 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 624 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 625 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 626     case "$host_cpu" in
 627     i?86 | x86_64 | amd64)
 628         enable_asm=no
 629         AC_MSG_RESULT([no, cross compiling])
 630         ;;
 631     esac
 632 fi
 633 # check for supported arches
 634 if test "x$enable_asm" = xyes; then
 635     case "$host_cpu" in
 636     i?86)
 637         case "$host_os" in
 638         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 639             asm_arch=x86
 640             ;;
 641         esac
 642         ;;
 643     x86_64|amd64)
 644         case "$host_os" in
 645         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 646             asm_arch=x86_64
 647             ;;
 648         esac
 649         ;;
 650     sparc*)
 651         case "$host_os" in
 652         linux*)
 653             asm_arch=sparc
 654             ;;
 655         esac
 656         ;;
 657     esac
 658
 659     case "$asm_arch" in
 660     x86)
 661         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 662         AC_MSG_RESULT([yes, x86])
 663         ;;
 664     x86_64|amd64)
 665         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 666         AC_MSG_RESULT([yes, x86_64])
 667         ;;
 668     sparc)
 669         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 670         AC_MSG_RESULT([yes, sparc])
 671         ;;
 672     *)
 673         AC_MSG_RESULT([no, platform not supported])
 674         ;;
 675     esac
 676 fi
 677
 678 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 679 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 680 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 681 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 682
 683 dnl Check to see if dlopen is in default libraries (like Solaris, which
 684 dnl has it in libc), or if libdl is needed to get it.
 685 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 686     [AC_CHECK_LIB([dl], [dlopen],
 687        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 688 AC_SUBST([DLOPEN_LIBS])
 689
 690 dnl Check if that library also has dladdr
 691 save_LIBS="$LIBS"
 692 LIBS="$LIBS $DLOPEN_LIBS"
 693 AC_CHECK_FUNCS([dladdr])
 694 LIBS="$save_LIBS"
 695
 696 case "$host_os" in
 697 darwin*)
 698     ;;
 699 *)
 700     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 701                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 702                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 703     AC_SUBST([CLOCK_LIB])
 704     ;;
 705 esac
 706
 707 dnl See if posix_memalign is available
 708 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 709
 710 dnl Check for pthreads
 711 AX_PTHREAD
 712 if test "x$ax_pthread_ok" = xno; then
 713     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 714 fi
 715 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 716 dnl to -pthread, which causes problems if we need -lpthread to appear in
 717 dnl pkgconfig files.
 718 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 719
 720 dnl SELinux awareness.
 721 AC_ARG_ENABLE([selinux],
 722     [AS_HELP_STRING([--enable-selinux],
 723         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 724     [MESA_SELINUX="$enableval"],
 725     [MESA_SELINUX=no])
 726 if test "x$enable_selinux" = "xyes"; then
 727     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 728         [AC_CHECK_HEADER([selinux/selinux.h],[],
 729                          [AC_MSG_ERROR([SELinux headers not found])])
 730          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 731                       [AC_MSG_ERROR([SELinux library not found])])
 732          SELINUX_LIBS="-lselinux"])
 733     DEFINES="$DEFINES -DMESA_SELINUX"
 734 fi
 735 AC_SUBST([SELINUX_CFLAGS])
 736 AC_SUBST([SELINUX_LIBS])
 737
 738 dnl Options for APIs
 739 AC_ARG_ENABLE([opengl],
 740     [AS_HELP_STRING([--disable-opengl],
 741         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 742     [enable_opengl="$enableval"],
 743     [enable_opengl=yes])
 744 AC_ARG_ENABLE([gles1],
 745     [AS_HELP_STRING([--disable-gles1],
 746         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 747     [enable_gles1="$enableval"],
 748     [enable_gles1=yes])
 749 AC_ARG_ENABLE([gles2],
 750     [AS_HELP_STRING([--disable-gles2],
 751         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 752     [enable_gles2="$enableval"],
 753     [enable_gles2=yes])
 754
 755 AC_ARG_ENABLE([dri],
 756     [AS_HELP_STRING([--enable-dri],
 757         [enable DRI modules @<:@default=enabled@:>@])],
 758     [enable_dri="$enableval"],
 759     [enable_dri=yes])
 760
 761 case "$host_os" in
 762 linux*)
 763     dri3_default=yes
 764     ;;
 765 *)
 766     dri3_default=no
 767     ;;
 768 esac
 769 AC_ARG_ENABLE([dri3],
 770     [AS_HELP_STRING([--enable-dri3],
 771         [enable DRI3 @<:@default=auto@:>@])],
 772     [enable_dri3="$enableval"],
 773     [enable_dri3="$dri3_default"])
 774 AC_ARG_ENABLE([glx],
 775     [AS_HELP_STRING([--enable-glx],
 776         [enable GLX library @<:@default=enabled@:>@])],
 777     [enable_glx="$enableval"],
 778     [enable_glx=yes])
 779 AC_ARG_ENABLE([osmesa],
 780     [AS_HELP_STRING([--enable-osmesa],
 781         [enable OSMesa library @<:@default=disabled@:>@])],
 782     [enable_osmesa="$enableval"],
 783     [enable_osmesa=no])
 784 AC_ARG_ENABLE([gallium-osmesa],
 785     [AS_HELP_STRING([--enable-gallium-osmesa],
 786         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 787     [enable_gallium_osmesa="$enableval"],
 788     [enable_gallium_osmesa=no])
 789 AC_ARG_ENABLE([egl],
 790     [AS_HELP_STRING([--disable-egl],
 791         [disable EGL library @<:@default=enabled@:>@])],
 792     [enable_egl="$enableval"],
 793     [enable_egl=yes])
 794
 795 AC_ARG_ENABLE([xa],
 796     [AS_HELP_STRING([--enable-xa],
 797         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 798     [enable_xa="$enableval"],
 799     [enable_xa=no])
 800 AC_ARG_ENABLE([gbm],
 801    [AS_HELP_STRING([--enable-gbm],
 802          [enable gbm library @<:@default=auto@:>@])],
 803    [enable_gbm="$enableval"],
 804    [enable_gbm=auto])
 805 AC_ARG_ENABLE([nine],
 806     [AS_HELP_STRING([--enable-nine],
 807         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 808     [enable_nine="$enableval"],
 809     [enable_nine=no])
 810
 811 AC_ARG_ENABLE([xvmc],
 812    [AS_HELP_STRING([--enable-xvmc],
 813          [enable xvmc library @<:@default=auto@:>@])],
 814    [enable_xvmc="$enableval"],
 815    [enable_xvmc=auto])
 816 AC_ARG_ENABLE([vdpau],
 817    [AS_HELP_STRING([--enable-vdpau],
 818          [enable vdpau library @<:@default=auto@:>@])],
 819    [enable_vdpau="$enableval"],
 820    [enable_vdpau=auto])
 821 AC_ARG_ENABLE([omx],
 822    [AS_HELP_STRING([--enable-omx],
 823          [enable OpenMAX library @<:@default=disabled@:>@])],
 824    [enable_omx="$enableval"],
 825    [enable_omx=no])
 826 AC_ARG_ENABLE([va],
 827    [AS_HELP_STRING([--enable-va],
 828          [enable va library @<:@default=auto@:>@])],
 829    [enable_va="$enableval"],
 830    [enable_va=auto])
 831 AC_ARG_ENABLE([opencl],
 832    [AS_HELP_STRING([--enable-opencl],
 833          [enable OpenCL library @<:@default=disabled@:>@])],
 834    [enable_opencl="$enableval"],
 835    [enable_opencl=no])
 836 AC_ARG_ENABLE([opencl_icd],
 837    [AS_HELP_STRING([--enable-opencl-icd],
 838           [Build an OpenCL ICD library to be loaded by an ICD implementation
 839            @<:@default=disabled@:>@])],
 840     [enable_opencl_icd="$enableval"],
 841     [enable_opencl_icd=no])
 842 AC_ARG_ENABLE([xlib-glx],
 843     [AS_HELP_STRING([--enable-xlib-glx],
 844         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 845     [enable_xlib_glx="$enableval"],
 846     [enable_xlib_glx=no])
 847
 848 AC_ARG_ENABLE([r600-llvm-compiler],
 849     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 850         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 851     [enable_r600_llvm="$enableval"],
 852     [enable_r600_llvm=no])
 853
 854 AC_ARG_ENABLE([gallium-tests],
 855     [AS_HELP_STRING([--enable-gallium-tests],
 856         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 857     [enable_gallium_tests="$enableval"],
 858     [enable_gallium_tests=no])
 859
 860 # Option for Gallium drivers
 861
 862 # Keep this in sync with the --with-gallium-drivers help string default value
 863 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 864
 865 AC_ARG_WITH([gallium-drivers],
 866     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 867         [comma delimited Gallium drivers list, e.g.
 868         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 869         @<:@default=r300,r600,svga,swrast@:>@])],
 870     [with_gallium_drivers="$withval"],
 871     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 872
 873 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 874 # here so that the script doesn't choke on an unknown driver name later.
 875 case "$with_gallium_drivers" in
 876     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 877     no) with_gallium_drivers='' ;;
 878 esac
 879
 880 if test "x$enable_opengl" = xno -a \
 881         "x$enable_gles1" = xno -a \
 882         "x$enable_gles2" = xno -a \
 883         "x$enable_nine" = xno -a \
 884         "x$enable_xa" = xno -a \
 885         "x$enable_xvmc" = xno -a \
 886         "x$enable_vdpau" = xno -a \
 887         "x$enable_omx" = xno -a \
 888         "x$enable_va" = xno -a \
 889         "x$enable_opencl" = xno; then
 890     AC_MSG_ERROR([at least one API should be enabled])
 891 fi
 892
 893 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 894 if test "x$enable_opengl" = xno -a \
 895         "x$enable_gles1" = xyes; then
 896     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 897 fi
 898
 899 if test "x$enable_opengl" = xno -a \
 900         "x$enable_gles2" = xyes; then
 901     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 902 fi
 903
 904 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 905 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 906 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 907 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 908                                         "x$enable_gles1" = xyes -o \
 909                                         "x$enable_gles2" = xyes)
 910
 911 if test "x$enable_glx" = xno; then
 912     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 913     enable_xlib_glx=no
 914 fi
 915
 916 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 917     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 918 fi
 919
 920 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 921     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 922 fi
 923
 924 # Disable GLX if OpenGL is not enabled
 925 if test "x$enable_glx$enable_opengl" = xyesno; then
 926     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 927     enable_glx=no
 928 fi
 929
 930 # Disable GLX if DRI and Xlib-GLX are not enabled
 931 if test "x$enable_glx" = xyes -a \
 932         "x$enable_dri" = xno -a \
 933         "x$enable_xlib_glx" = xno; then
 934     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 935     enable_glx=no
 936 fi
 937
 938 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 939                                   "x$enable_dri" = xyes)
 940
 941 # Check for libdrm
 942 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 943                   [have_libdrm=yes], [have_libdrm=no])
 944 if test "x$have_libdrm" = xyes; then
 945         DEFINES="$DEFINES -DHAVE_LIBDRM"
 946 fi
 947
 948 # Select which platform-dependent DRI code gets built
 949 case "$host_os" in
 950 darwin*)
 951     dri_platform='apple' ;;
 952 gnu*|cygwin*)
 953     dri_platform='none' ;;
 954 *)
 955     dri_platform='drm' ;;
 956 esac
 957
 958 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 959 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 960 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 961 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 962 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 963
 964 AC_ARG_ENABLE([shared-glapi],
 965     [AS_HELP_STRING([--enable-shared-glapi],
 966         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 967     [enable_shared_glapi="$enableval"],
 968     [enable_shared_glapi=yes])
 969
 970 case "x$enable_opengl$enable_gles1$enable_gles2" in
 971 x*yes*yes*)
 972     if test "x$enable_shared_glapi" = xno; then
 973         AC_MSG_ERROR([shared GLAPI required when building two or more of
 974                       the following APIs - opengl, gles1 gles2])
 975     fi
 976     ;;
 977 esac
 978
 979 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 980
 981 # Build the pipe-drivers as separate libraries/modules.
 982 # Do not touch this unless you know what you are doing.
 983 # XXX: Expose via configure option ?
 984 enable_shared_pipe_drivers=no
 985
 986 dnl
 987 dnl Driver specific build directories
 988 dnl
 989
 990 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 991     NEED_WINSYS_XLIB="yes"
 992 fi
 993
 994 if test "x$enable_dri" = xyes; then
 995     enable_gallium_loader="$enable_shared_pipe_drivers"
 996 fi
 997
 998 if test "x$enable_gallium_osmesa" = xyes; then
 999     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1000         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1001     fi
1002     if test "x$enable_osmesa" = xyes; then
1003         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1004     fi
1005 fi
1006
1007 AC_SUBST([MESA_LLVM])
1008
1009 # SHA1 hashing
1010 AC_ARG_WITH([sha1],
1011         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1012         [choose SHA1 implementation])])
1013 case "x$with_sha1" in
1014 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1015   ;;
1016 *)
1017         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1018 esac
1019
1020 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1021 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1022         with_sha1=libc
1023 fi
1024 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1025         AC_MSG_ERROR([sha1 in libc requested but not found])
1026 fi
1027 if test "x$with_sha1" = xlibc; then
1028         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1029                 [Use libc SHA1 functions])
1030         SHA1_LIBS=""
1031 fi
1032 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1033 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1034         with_sha1=CommonCrypto
1035 fi
1036 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1037         AC_MSG_ERROR([CommonCrypto requested but not found])
1038 fi
1039 if test "x$with_sha1" = xCommonCrypto; then
1040         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1041                 [Use CommonCrypto SHA1 functions])
1042         SHA1_LIBS=""
1043 fi
1044 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1045 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1046 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1047         with_sha1=CryptoAPI
1048 fi
1049 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1050         AC_MSG_ERROR([CryptoAPI requested but not found])
1051 fi
1052 if test "x$with_sha1" = xCryptoAPI; then
1053         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1054                 [Use CryptoAPI SHA1 functions])
1055         SHA1_LIBS=""
1056 fi
1057 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1058 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1059         with_sha1=libmd
1060 fi
1061 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1062         AC_MSG_ERROR([libmd requested but not found])
1063 fi
1064 if test "x$with_sha1" = xlibmd; then
1065         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1066                   [Use libmd SHA1 functions])
1067         SHA1_LIBS=-lmd
1068 fi
1069 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1070 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1071    with_sha1=libsha1
1072 fi
1073 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1074         AC_MSG_ERROR([libsha1 requested but not found])
1075 fi
1076 if test "x$with_sha1" = xlibsha1; then
1077         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1078                   [Use libsha1 for SHA1])
1079         SHA1_LIBS=-lsha1
1080 fi
1081 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1082 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1083         with_sha1=libnettle
1084 fi
1085 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1086         AC_MSG_ERROR([libnettle requested but not found])
1087 fi
1088 if test "x$with_sha1" = xlibnettle; then
1089         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1090                   [Use libnettle SHA1 functions])
1091         SHA1_LIBS=-lnettle
1092 fi
1093 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1094 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1095         with_sha1=libgcrypt
1096 fi
1097 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1098         AC_MSG_ERROR([libgcrypt requested but not found])
1099 fi
1100 if test "x$with_sha1" = xlibgcrypt; then
1101         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1102                   [Use libgcrypt SHA1 functions])
1103         SHA1_LIBS=-lgcrypt
1104 fi
1105 # We don't need all of the OpenSSL libraries, just libcrypto
1106 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1107 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1108                   [HAVE_OPENSSL_PKC=no])
1109 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1110         if test "x$with_sha1" = x; then
1111                 with_sha1=libcrypto
1112         fi
1113 else
1114         if test "x$with_sha1" = xlibcrypto; then
1115                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1116         fi
1117 fi
1118 if test "x$with_sha1" = xlibcrypto; then
1119         if test "x$HAVE_LIBCRYPTO" = xyes; then
1120                 SHA1_LIBS=-lcrypto
1121         else
1122                 SHA1_LIBS="$OPENSSL_LIBS"
1123                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1124         fi
1125 fi
1126 AC_MSG_CHECKING([for SHA1 implementation])
1127 AC_MSG_RESULT([$with_sha1])
1128 AC_SUBST(SHA1_LIBS)
1129 AC_SUBST(SHA1_CFLAGS)
1130
1131 # Enable a define for SHA1
1132 if test "x$with_sha1" != "x"; then
1133         DEFINES="$DEFINES -DHAVE_SHA1"
1134 fi
1135
1136 # Allow user to configure out the shader-cache feature
1137 AC_ARG_ENABLE([shader-cache],
1138     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1139     [enable_shader_cache="$enableval"],
1140     [if test "x$with_sha1" != "x"; then
1141         enable_shader_cache=yes
1142      else
1143         enable_shader_cache=no
1144      fi])
1145 if test "x$with_sha1" = "x"; then
1146     if test "x$enable_shader_cache" = "xyes"; then
1147         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1148     fi
1149 fi
1150 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1151
1152 case "$host_os" in
1153 linux*)
1154     need_pci_id=yes ;;
1155 *)
1156     need_pci_id=no ;;
1157 esac
1158
1159 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1160                   have_libudev=yes, have_libudev=no)
1161
1162 AC_ARG_ENABLE([sysfs],
1163     [AS_HELP_STRING([--enable-sysfs],
1164         [enable /sys PCI identification @<:@default=disabled@:>@])],
1165     [have_sysfs="$enableval"],
1166     [have_sysfs=no]
1167 )
1168
1169 if test "x$enable_dri" = xyes; then
1170     if test "$enable_static" = yes; then
1171         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1172     fi
1173
1174     # not a hard requirement as swrast does not depend on it
1175     if test "x$have_libdrm" = xyes; then
1176         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1177     fi
1178 fi
1179
1180 AC_ARG_ENABLE([driglx-direct],
1181     [AS_HELP_STRING([--disable-driglx-direct],
1182         [disable direct rendering in GLX and EGL for DRI \
1183             @<:@default=auto@:>@])],
1184     [driglx_direct="$enableval"],
1185     [driglx_direct="yes"])
1186
1187 dnl
1188 dnl libGL configuration per driver
1189 dnl
1190 case "x$enable_glx$enable_xlib_glx" in
1191 xyesyes)
1192     # Xlib-based GLX
1193     dri_modules="x11 xext xcb"
1194     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1195     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1196     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1197     GL_LIB_DEPS="$XLIBGL_LIBS"
1198     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1199     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1200     ;;
1201 xyesno)
1202     # DRI-based GLX
1203     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1204
1205     # find the DRI deps for libGL
1206     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1207
1208     if test x"$driglx_direct" = xyes; then
1209         if test x"$dri_platform" = xdrm ; then
1210             DEFINES="$DEFINES -DGLX_USE_DRM"
1211             if test "x$have_libdrm" != xyes; then
1212                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1213             fi
1214
1215             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1216             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1217             if test x"$enable_dri3" = xyes; then
1218                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1219                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1220             fi
1221
1222             if test x"$enable_dri" = xyes; then
1223                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1224             fi
1225
1226             if test x"$enable_dri3" = xyes; then
1227                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1228                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1229             fi
1230         fi
1231         if test x"$dri_platform" = xapple ; then
1232             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1233         fi
1234     fi
1235
1236     # add xf86vidmode if available
1237     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1238     if test "$HAVE_XF86VIDMODE" = yes ; then
1239         dri_modules="$dri_modules xxf86vm"
1240     fi
1241
1242     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1243     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1244     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1245     GL_LIB_DEPS="$DRIGL_LIBS"
1246
1247     # need DRM libs, $PTHREAD_LIBS, etc.
1248     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1249     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1250     ;;
1251 esac
1252
1253 have_pci_id=no
1254 if test "$have_libudev" = yes; then
1255     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1256     have_pci_id=yes
1257 fi
1258
1259 if test "$have_sysfs" = yes; then
1260     DEFINES="$DEFINES -DHAVE_SYSFS"
1261     have_pci_id=yes
1262 fi
1263
1264 # This is outside the case (above) so that it is invoked even for non-GLX
1265 # builds.
1266 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1267
1268 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1269 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1270 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1271 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1272
1273 AC_SUBST([X11_INCLUDES])
1274 AC_SUBST([GL_LIB_DEPS])
1275 AC_SUBST([GL_PC_REQ_PRIV])
1276 AC_SUBST([GL_PC_LIB_PRIV])
1277 AC_SUBST([GL_PC_CFLAGS])
1278 AC_SUBST([DRI_PC_REQ_PRIV])
1279 AC_SUBST([GLESv1_CM_LIB_DEPS])
1280 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1281 AC_SUBST([GLESv2_LIB_DEPS])
1282 AC_SUBST([GLESv2_PC_LIB_PRIV])
1283
1284 AC_SUBST([HAVE_XF86VIDMODE])
1285
1286 dnl
1287 dnl More GLX setup
1288 dnl
1289 case "x$enable_glx$enable_xlib_glx" in
1290 xyesyes)
1291     DEFINES="$DEFINES -DUSE_XSHM"
1292     ;;
1293 xyesno)
1294     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1295     if test "x$driglx_direct" = xyes; then
1296         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1297     fi
1298     ;;
1299 esac
1300
1301 dnl
1302 dnl TLS detection
1303 dnl
1304
1305 AC_ARG_ENABLE([glx-tls],
1306     [AS_HELP_STRING([--enable-glx-tls],
1307         [enable TLS support in GLX @<:@default=disabled@:>@])],
1308     [GLX_USE_TLS="$enableval"],
1309     [GLX_USE_TLS=no])
1310 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1311
1312 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1313       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1314
1315 dnl Read-only text section on x86 hardened platforms
1316 AC_ARG_ENABLE([glx-read-only-text],
1317     [AS_HELP_STRING([--enable-glx-read-only-text],
1318         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1319     [enable_glx_read_only_text="$enableval"],
1320     [enable_glx_read_only_text=no])
1321 if test "x$enable_glx_read_only_text" = xyes; then
1322     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1323 fi
1324
1325 dnl
1326 dnl More DRI setup
1327 dnl
1328 dnl Directory for DRI drivers
1329 AC_ARG_WITH([dri-driverdir],
1330     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1331         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1332     [DRI_DRIVER_INSTALL_DIR="$withval"],
1333     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1334 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1335 dnl Extra search path for DRI drivers
1336 AC_ARG_WITH([dri-searchpath],
1337     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1338         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1339     [DRI_DRIVER_SEARCH_DIR="$withval"],
1340     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1341 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1342 dnl Which drivers to build - default is chosen by platform
1343 AC_ARG_WITH([dri-drivers],
1344     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1345         [comma delimited classic DRI drivers list, e.g.
1346         "swrast,i965,radeon" @<:@default=auto@:>@])],
1347     [with_dri_drivers="$withval"],
1348     [with_dri_drivers=auto])
1349
1350 if test "x$with_dri_drivers" = xauto; then
1351     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1352         with_dri_drivers="yes"
1353     else
1354         with_dri_drivers="no"
1355     fi
1356 fi
1357 if test "x$with_dri_drivers" = xno; then
1358     with_dri_drivers=''
1359 fi
1360
1361 dnl If $with_dri_drivers is yes, drivers will be added through
1362 dnl platform checks. Set DEFINES and LIB_DEPS
1363 if test "x$enable_dri" = xyes; then
1364     # Platform specific settings and drivers to build
1365     case "$host_os" in
1366     linux*)
1367         DEFINES="$DEFINES -DHAVE_ALIAS"
1368         if test "x$enable_dri3" = xyes; then
1369             DEFINES="$DEFINES -DHAVE_DRI3"
1370         fi
1371
1372         if test "x$have_pci_id" != xyes; then
1373             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1374         fi
1375
1376         case "$host_cpu" in
1377         powerpc* | sparc*)
1378             # Build only the drivers for cards that exist on PowerPC/sparc
1379             if test "x$with_dri_drivers" = "xyes"; then
1380                 with_dri_drivers="r200 radeon swrast"
1381             fi
1382             ;;
1383         esac
1384         ;;
1385     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1386         DEFINES="$DEFINES -DHAVE_ALIAS"
1387         ;;
1388     gnu*)
1389         DEFINES="$DEFINES -DHAVE_ALIAS"
1390         ;;
1391     cygwin*)
1392         if test "x$with_dri_drivers" = "xyes"; then
1393             with_dri_drivers="swrast"
1394         fi
1395         ;;
1396     darwin*)
1397         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1398         if test "x$with_dri_drivers" = "xyes"; then
1399             with_dri_drivers="swrast"
1400         fi
1401         ;;
1402     esac
1403
1404     # default drivers
1405     if test "x$with_dri_drivers" = "xyes"; then
1406         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1407     fi
1408
1409     # Check for expat
1410     PKG_CHECK_MODULES([EXPAT], [expat], [],
1411         # expat version 2.0 and earlier do not provide expat.pc
1412         [AC_CHECK_HEADER([expat.h],[],
1413                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1414          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1415                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1416          EXPAT_LIBS="-lexpat"])
1417
1418     # put all the necessary libs together
1419     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1420 fi
1421
1422 AC_SUBST([DRI_LIB_DEPS])
1423
1424 DRI_DIRS=''
1425 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1426 if test -n "$with_dri_drivers"; then
1427     if test "x$enable_opengl" != xyes; then
1428         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1429     fi
1430
1431     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1432     for driver in $dri_drivers; do
1433         DRI_DIRS="$DRI_DIRS $driver"
1434         case "x$driver" in
1435         xi915)
1436             HAVE_I915_DRI=yes;
1437             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1438             ;;
1439         xi965)
1440             HAVE_I965_DRI=yes;
1441             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1442             ;;
1443         xnouveau)
1444             HAVE_NOUVEAU_DRI=yes;
1445             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1446             ;;
1447         xradeon)
1448             HAVE_RADEON_DRI=yes;
1449             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1450             ;;
1451         xr200)
1452             HAVE_R200_DRI=yes;
1453             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1454             ;;
1455         xswrast)
1456             HAVE_SWRAST_DRI=yes;
1457             ;;
1458         *)
1459             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1460             ;;
1461         esac
1462     done
1463     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1464 fi
1465
1466 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1467 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1468                                   "x$enable_osmesa" = xyes -o \
1469                                   -n "$DRI_DIRS")
1470
1471 dnl
1472 dnl OSMesa configuration
1473 dnl
1474
1475 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1476 AC_ARG_WITH([osmesa-bits],
1477     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1478         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1479     [osmesa_bits="$withval"],
1480     [osmesa_bits=8])
1481 if test "x$osmesa_bits" != x8; then
1482     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1483         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1484         osmesa_bits=8
1485     fi
1486 fi
1487 case "x$osmesa_bits" in
1488 x8)
1489     OSMESA_LIB="${OSMESA_LIB}"
1490     ;;
1491 x16|x32)
1492     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1493     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1494     ;;
1495 *)
1496     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1497     ;;
1498 esac
1499
1500 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1501     # only link libraries with osmesa if shared
1502     if test "$enable_static" = no; then
1503         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1504     else
1505         OSMESA_LIB_DEPS=""
1506     fi
1507     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1508 fi
1509
1510 AC_SUBST([OSMESA_LIB_DEPS])
1511 AC_SUBST([OSMESA_PC_REQ])
1512 AC_SUBST([OSMESA_PC_LIB_PRIV])
1513
1514 dnl
1515 dnl gbm configuration
1516 dnl
1517 if test "x$enable_gbm" = xauto; then
1518     case "$with_egl_platforms" in
1519         *drm*)
1520             enable_gbm=yes ;;
1521          *)
1522             enable_gbm=no ;;
1523     esac
1524 fi
1525 if test "x$enable_gbm" = xyes; then
1526     if test "x$need_pci_id$have_pci_id" = xyesno; then
1527         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1528     fi
1529
1530     if test "x$enable_dri" = xyes; then
1531         if test "x$enable_shared_glapi" = xno; then
1532             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1533         fi
1534     else
1535         # Strictly speaking libgbm does not require --enable-dri, although
1536         # both of its backends do. Thus one can build libgbm without any
1537         # backends if --disable-dri is set.
1538         # To avoid unnecessary complexity of checking if at least one backend
1539         # is available when building, just mandate --enable-dri.
1540         AC_MSG_ERROR([gbm requires --enable-dri])
1541     fi
1542 fi
1543 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1544 if test "x$need_pci_id$have_libudev" = xyesyes; then
1545     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1546 else
1547     GBM_PC_REQ_PRIV=""
1548 fi
1549 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1550 AC_SUBST([GBM_PC_REQ_PRIV])
1551 AC_SUBST([GBM_PC_LIB_PRIV])
1552
1553 AM_CONDITIONAL(HAVE_VULKAN, true)
1554
1555 dnl
1556 dnl EGL configuration
1557 dnl
1558 EGL_CLIENT_APIS=""
1559
1560 if test "x$enable_egl" = xyes; then
1561     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1562
1563     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1564
1565     if test "$enable_static" != yes; then
1566         if test "x$enable_dri" = xyes; then
1567             HAVE_EGL_DRIVER_DRI2=1
1568             if test "x$enable_shared_glapi" = xno; then
1569                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1570             fi
1571         else
1572             # Avoid building an "empty" libEGL. Drop/update this
1573             # when other backends (haiku?) come along.
1574             AC_MSG_ERROR([egl requires --enable-dri])
1575         fi
1576
1577     fi
1578 fi
1579 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1580 AC_SUBST([EGL_LIB_DEPS])
1581
1582 dnl
1583 dnl XA configuration
1584 dnl
1585 if test "x$enable_xa" = xyes; then
1586     if test "x$with_gallium_drivers" = xswrast; then
1587        AC_MSG_ERROR([
1588           Building xa requires at least one non swrast gallium driver.
1589           If you are looking to use libxatracker.so with the VMware driver,
1590           make sure to include svga in the gallium drivers list, apart from
1591           enabling XA.
1592           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1593     fi
1594     enable_gallium_loader=$enable_shared_pipe_drivers
1595 fi
1596 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1597
1598 dnl
1599 dnl Gallium G3DVL configuration
1600 dnl
1601 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1602     if test "x$enable_xvmc" = xauto; then
1603         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1604     fi
1605
1606     if test "x$enable_vdpau" = xauto; then
1607         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1608     fi
1609
1610     if test "x$enable_omx" = xauto; then
1611         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1612     fi
1613
1614     if test "x$enable_va" = xauto; then
1615         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1616     fi
1617 fi
1618
1619 if test "x$enable_dri" = xyes -o \
1620         "x$enable_xvmc" = xyes -o \
1621         "x$enable_vdpau" = xyes -o \
1622         "x$enable_omx" = xyes -o \
1623         "x$enable_va" = xyes; then
1624     need_gallium_vl=yes
1625 fi
1626 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1627
1628 if test "x$enable_xvmc" = xyes -o \
1629         "x$enable_vdpau" = xyes -o \
1630         "x$enable_omx" = xyes -o \
1631         "x$enable_va" = xyes; then
1632     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1633     need_gallium_vl_winsys=yes
1634 fi
1635 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1636
1637 if test "x$enable_xvmc" = xyes; then
1638     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1639     enable_gallium_loader=$enable_shared_pipe_drivers
1640 fi
1641 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1642
1643 if test "x$enable_vdpau" = xyes; then
1644     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1645     enable_gallium_loader=$enable_shared_pipe_drivers
1646 fi
1647 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1648
1649 if test "x$enable_omx" = xyes; then
1650     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1651     enable_gallium_loader=$enable_shared_pipe_drivers
1652 fi
1653 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1654
1655 if test "x$enable_va" = xyes; then
1656     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1657     enable_gallium_loader=$enable_shared_pipe_drivers
1658 fi
1659 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1660
1661 dnl
1662 dnl Nine Direct3D9 configuration
1663 dnl
1664 if test "x$enable_nine" = xyes; then
1665     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1666         AC_MSG_ERROR([nine requires the gallium swrast driver])
1667     fi
1668     if test "x$with_gallium_drivers" = xswrast; then
1669         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1670     fi
1671     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1672         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1673     fi
1674
1675     if test "x$enable_dri3" = xno; then
1676         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1677     fi
1678
1679     enable_gallium_loader=$enable_shared_pipe_drivers
1680 fi
1681 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1682
1683 dnl
1684 dnl OpenCL configuration
1685 dnl
1686
1687 AC_ARG_WITH([clang-libdir],
1688    [AS_HELP_STRING([--with-clang-libdir],
1689          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1690    [CLANG_LIBDIR="$withval"],
1691    [CLANG_LIBDIR=''])
1692
1693 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1694 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1695
1696 if test "x$enable_opencl" = xyes; then
1697     if test -z "$with_gallium_drivers"; then
1698         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1699     fi
1700
1701     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1702         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1703     fi
1704
1705     if test "x$have_libclc" = xno; then
1706         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1707                     Make sure the directory containing libclc.pc is specified in your
1708                     PKG_CONFIG_PATH environment variable.
1709                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1710     else
1711         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1712         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1713         AC_SUBST([LIBCLC_INCLUDEDIR])
1714         AC_SUBST([LIBCLC_LIBEXECDIR])
1715     fi
1716
1717     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1718     enable_gallium_loader=yes
1719
1720     if test "x$enable_opencl_icd" = xyes; then
1721         OPENCL_LIBNAME="MesaOpenCL"
1722     else
1723         OPENCL_LIBNAME="OpenCL"
1724     fi
1725
1726     if test "x$have_libelf" != xyes; then
1727        AC_MSG_ERROR([Clover requires libelf])
1728     fi
1729 fi
1730 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1731 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1732 AC_SUBST([OPENCL_LIBNAME])
1733
1734 dnl
1735 dnl Gallium configuration
1736 dnl
1737 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1738
1739 AC_SUBST([LLVM_BINDIR])
1740 AC_SUBST([LLVM_CFLAGS])
1741 AC_SUBST([LLVM_CPPFLAGS])
1742 AC_SUBST([LLVM_CXXFLAGS])
1743 AC_SUBST([LLVM_LIBDIR])
1744 AC_SUBST([LLVM_LIBS])
1745 AC_SUBST([LLVM_LDFLAGS])
1746 AC_SUBST([LLVM_INCLUDEDIR])
1747 AC_SUBST([LLVM_VERSION])
1748 AC_SUBST([CLANG_RESOURCE_DIR])
1749
1750 case "x$enable_opengl$enable_gles1$enable_gles2" in
1751 x*yes*)
1752     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1753     ;;
1754 esac
1755
1756 AC_SUBST([VG_LIB_DEPS])
1757 AC_SUBST([EGL_CLIENT_APIS])
1758
1759 dnl
1760 dnl EGL Platforms configuration
1761 dnl
1762 AC_ARG_WITH([egl-platforms],
1763     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1764         [comma delimited native platforms libEGL supports, e.g.
1765         "x11,drm" @<:@default=auto@:>@])],
1766     [with_egl_platforms="$withval"],
1767     [if test "x$enable_egl" = xyes; then
1768         with_egl_platforms="x11"
1769     else
1770         with_egl_platforms=""
1771     fi])
1772
1773 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1774     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1775 fi
1776
1777 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1778         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1779         WAYLAND_SCANNER='')
1780 if test "x$WAYLAND_SCANNER" = x; then
1781     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1782 fi
1783
1784 # Do per-EGL platform setups and checks
1785 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1786 for plat in $egl_platforms; do
1787         case "$plat" in
1788         wayland)
1789                 test "x$have_libdrm" != xyes &&
1790                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1791
1792                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1793
1794                 if test "x$WAYLAND_SCANNER" = x; then
1795                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1796                 fi
1797                 ;;
1798
1799         x11)
1800                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1801                 ;;
1802
1803         drm)
1804                 test "x$enable_gbm" = "xno" &&
1805                         AC_MSG_ERROR([EGL platform drm needs gbm])
1806                 test "x$have_libdrm" != xyes &&
1807                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1808                 ;;
1809
1810         surfaceless)
1811                 test "x$have_libdrm" != xyes &&
1812                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1813                 ;;
1814
1815         *)
1816                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1817                 ;;
1818         esac
1819
1820         case "$plat$need_pci_id$have_pci_id" in
1821                 waylandyesno|drmyesno)
1822                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1823         esac
1824 done
1825
1826 # libEGL wants to default to the first platform specified in
1827 # ./configure.  parse that here.
1828 if test "x$egl_platforms" != "x"; then
1829     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1830     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1831 else
1832     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1833 fi
1834
1835 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1836 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1837 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1838 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1839 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1840
1841 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1842
1843 AC_SUBST([EGL_NATIVE_PLATFORM])
1844 AC_SUBST([EGL_CFLAGS])
1845
1846 # If we don't have the X11 platform, set this define so we don't try to include
1847 # the X11 headers.
1848 if ! echo "$egl_platforms" | grep -q 'x11'; then
1849     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1850     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1851 fi
1852
1853 dnl
1854 dnl Gallium LLVM
1855 dnl
1856 AC_ARG_ENABLE([gallium-llvm],
1857     [AS_HELP_STRING([--enable-gallium-llvm],
1858         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1859     [enable_gallium_llvm="$enableval"],
1860     [enable_gallium_llvm=auto])
1861
1862 AC_ARG_ENABLE([llvm-shared-libs],
1863     [AS_HELP_STRING([--enable-llvm-shared-libs],
1864         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1865     [enable_llvm_shared_libs="$enableval"],
1866     [enable_llvm_shared_libs=yes])
1867
1868 AC_ARG_WITH([llvm-prefix],
1869     [AS_HELP_STRING([--with-llvm-prefix],
1870         [Prefix for LLVM installations in non-standard locations])],
1871     [llvm_prefix="$withval"],
1872     [llvm_prefix=''])
1873
1874
1875 # Call this inside ` ` to get the return value.
1876 # $1 is the llvm-config command with arguments.
1877 strip_unwanted_llvm_flags() {
1878     # Use \> (marks the end of the word)
1879     echo `$1` | sed \
1880         -e 's/-DNDEBUG\>//g' \
1881         -e 's/-D_GNU_SOURCE\>//g' \
1882         -e 's/-pedantic\>//g' \
1883         -e 's/-Wcovered-switch-default\>//g' \
1884         -e 's/-O.\>//g' \
1885         -e 's/-g\>//g' \
1886         -e 's/-Wall\>//g' \
1887         -e 's/-Wcast-qual\>//g' \
1888         -e 's/-Woverloaded-virtual\>//g' \
1889         -e 's/-fcolor-diagnostics\>//g' \
1890         -e 's/-fdata-sections\>//g' \
1891         -e 's/-ffunction-sections\>//g' \
1892         -e 's/-fno-exceptions\>//g' \
1893         -e 's/-fomit-frame-pointer\>//g' \
1894         -e 's/-fvisibility-inlines-hidden\>//g' \
1895         -e 's/-fPIC\>//g' \
1896         -e 's/-fstack-protector-strong\>//g'
1897 }
1898
1899 llvm_check_version_for() {
1900     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1901         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1902     fi
1903 }
1904
1905
1906
1907 if test -z "$with_gallium_drivers"; then
1908     enable_gallium_llvm=no
1909 fi
1910 if test "x$enable_gallium_llvm" = xauto; then
1911     case "$host_cpu" in
1912     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1913     esac
1914 fi
1915 if test "x$enable_gallium_llvm" = xyes; then
1916     if test -n "$llvm_prefix"; then
1917         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1918     else
1919         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1920     fi
1921
1922     if test "x$LLVM_CONFIG" != xno; then
1923         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1924         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1925         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1926         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1927         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1928         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1929         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1930         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1931
1932         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1933             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1934         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1935             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1936
1937         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1938         if test -z "$LLVM_VERSION_PATCH"; then
1939             LLVM_VERSION_PATCH=0
1940         fi
1941
1942         if test -n "${LLVM_VERSION_MAJOR}"; then
1943             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1944         else
1945             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1946         fi
1947
1948         LLVM_REQUIRED_VERSION_MAJOR="3"
1949         LLVM_REQUIRED_VERSION_MINOR="3"
1950         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1951             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1952         fi
1953
1954         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1955
1956         if test "x$enable_opencl" = xyes; then
1957             llvm_check_version_for "3" "5" "0" "opencl"
1958
1959             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1960             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1961         fi
1962         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1963         MESA_LLVM=1
1964
1965         dnl Check for Clang internal headers
1966         if test "x$enable_opencl" = xyes; then
1967             if test -z "$CLANG_LIBDIR"; then
1968                 CLANG_LIBDIR=${LLVM_LIBDIR}
1969             fi
1970             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1971             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1972                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1973         fi
1974     else
1975         MESA_LLVM=0
1976         LLVM_VERSION_INT=0
1977     fi
1978 else
1979     MESA_LLVM=0
1980     LLVM_VERSION_INT=0
1981
1982     if test "x$enable_opencl" = xyes; then
1983         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1984     fi
1985 fi
1986
1987 dnl Directory for XVMC libs
1988 AC_ARG_WITH([xvmc-libdir],
1989     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1990         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1991     [XVMC_LIB_INSTALL_DIR="$withval"],
1992     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1993 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1994
1995 dnl
1996 dnl Gallium Tests
1997 dnl
1998 if test "x$enable_gallium_tests" = xyes; then
1999     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
2000     enable_gallium_loader=yes
2001 fi
2002 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2003
2004 dnl Directory for VDPAU libs
2005 AC_ARG_WITH([vdpau-libdir],
2006     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2007         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2008     [VDPAU_LIB_INSTALL_DIR="$withval"],
2009     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2010 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2011
2012 dnl Directory for OMX libs
2013
2014 AC_ARG_WITH([omx-libdir],
2015     [AS_HELP_STRING([--with-omx-libdir=DIR],
2016         [directory for the OMX libraries])],
2017     [OMX_LIB_INSTALL_DIR="$withval"],
2018     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2019 AC_SUBST([OMX_LIB_INSTALL_DIR])
2020
2021 dnl Directory for VA libs
2022
2023 AC_ARG_WITH([va-libdir],
2024     [AS_HELP_STRING([--with-va-libdir=DIR],
2025         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2026     [VA_LIB_INSTALL_DIR="$withval"],
2027     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2028 AC_SUBST([VA_LIB_INSTALL_DIR])
2029
2030 AC_ARG_WITH([d3d-libdir],
2031     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2032         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2033     [D3D_DRIVER_INSTALL_DIR="$withval"],
2034     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2035 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2036
2037 dnl
2038 dnl Gallium helper functions
2039 dnl
2040 gallium_require_drm() {
2041     if test "x$have_libdrm" != xyes; then
2042        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2043     fi
2044 }
2045
2046 gallium_require_llvm() {
2047     if test "x$MESA_LLVM" = x0; then
2048         case "$host" in *gnux32) return;; esac
2049         case "$host_cpu" in
2050         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2051         esac
2052     fi
2053 }
2054
2055 gallium_require_drm_loader() {
2056     if test "x$enable_gallium_loader" = xyes; then
2057         if test "x$need_pci_id$have_pci_id" = xyesno; then
2058             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2059         fi
2060         enable_gallium_drm_loader=yes
2061     fi
2062     if test "x$enable_va" = xyes && test "x$7" != x; then
2063          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
2064     fi
2065 }
2066
2067 require_egl_drm() {
2068     case "$with_egl_platforms" in
2069         *drm*)
2070             ;;
2071          *)
2072             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2073             ;;
2074     esac
2075     if test "x$enable_gbm" != xyes; then
2076             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2077     fi
2078 }
2079
2080 radeon_llvm_check() {
2081     if test ${LLVM_VERSION_INT} -lt 307; then
2082         amdgpu_llvm_target_name='r600'
2083     else
2084         amdgpu_llvm_target_name='amdgpu'
2085     fi
2086     if test "x$enable_gallium_llvm" != "xyes"; then
2087         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2088     fi
2089     llvm_check_version_for "3" "5" "0" $1
2090     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2091         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2092     fi
2093     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2094     NEED_RADEON_LLVM=yes
2095     if test "x$have_libelf" != xyes; then
2096        AC_MSG_ERROR([$1 requires libelf when using llvm])
2097     fi
2098 }
2099
2100 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2101 if test -n "$with_gallium_drivers"; then
2102     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2103     for driver in $gallium_drivers; do
2104         case "x$driver" in
2105         xsvga)
2106             HAVE_GALLIUM_SVGA=yes
2107             gallium_require_drm "svga"
2108             gallium_require_drm_loader
2109             ;;
2110         xi915)
2111             HAVE_GALLIUM_I915=yes
2112             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2113             gallium_require_drm "Gallium i915"
2114             gallium_require_drm_loader
2115             ;;
2116         xilo)
2117             HAVE_GALLIUM_ILO=yes
2118             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2119             gallium_require_drm "Gallium i965/ilo"
2120             gallium_require_drm_loader
2121             ;;
2122         xr300)
2123             HAVE_GALLIUM_R300=yes
2124             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2125             gallium_require_drm "Gallium R300"
2126             gallium_require_drm_loader
2127             gallium_require_llvm "Gallium R300"
2128             ;;
2129         xr600)
2130             HAVE_GALLIUM_R600=yes
2131             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2132             gallium_require_drm "Gallium R600"
2133             gallium_require_drm_loader
2134             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2135                 radeon_llvm_check "r600g"
2136                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2137             fi
2138             if test "x$enable_r600_llvm" = xyes; then
2139                 USE_R600_LLVM_COMPILER=yes;
2140             fi
2141             if test "x$enable_opencl" = xyes; then
2142                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2143             fi
2144             ;;
2145         xradeonsi)
2146             HAVE_GALLIUM_RADEONSI=yes
2147             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2148             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2149             gallium_require_drm "radeonsi"
2150             gallium_require_drm_loader
2151             radeon_llvm_check "radeonsi"
2152             require_egl_drm "radeonsi"
2153             ;;
2154         xnouveau)
2155             HAVE_GALLIUM_NOUVEAU=yes
2156             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2157             gallium_require_drm "nouveau"
2158             gallium_require_drm_loader
2159             ;;
2160         xfreedreno)
2161             HAVE_GALLIUM_FREEDRENO=yes
2162             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2163             gallium_require_drm "freedreno"
2164             gallium_require_drm_loader
2165             ;;
2166         xswrast)
2167             HAVE_GALLIUM_SOFTPIPE=yes
2168             if test "x$MESA_LLVM" = x1; then
2169                 HAVE_GALLIUM_LLVMPIPE=yes
2170             fi
2171             ;;
2172         xvc4)
2173             HAVE_GALLIUM_VC4=yes
2174             gallium_require_drm "vc4"
2175             gallium_require_drm_loader
2176
2177             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2178                               [USE_VC4_SIMULATOR=yes], [USE_VC4_SIMULATOR=no])
2179             ;;
2180         *)
2181             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2182             ;;
2183         esac
2184     done
2185 fi
2186
2187 dnl Set LLVM_LIBS - This is done after the driver configuration so
2188 dnl that drivers can add additional components to LLVM_COMPONENTS.
2189 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2190 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2191 dnl this was causing the same libraries to be appear multiple times
2192 dnl in LLVM_LIBS.
2193
2194 if test "x$MESA_LLVM" != x0; then
2195
2196     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2197
2198     dnl llvm-config may not give the right answer when llvm is a built as a
2199     dnl single shared library, so we must work the library name out for
2200     dnl ourselves.
2201     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2202     if test "x$enable_llvm_shared_libs" = xyes; then
2203         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2204         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2205         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2206
2207         if test "x$llvm_have_one_so" = xyes; then
2208             dnl LLVM was built using auto*, so there is only one shared object.
2209             LLVM_LIBS="-l$LLVM_SO_NAME"
2210         else
2211             dnl If LLVM was built with CMake, there will be one shared object per
2212             dnl component.
2213             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2214                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2215         Please make sure you have built llvm with the --enable-shared option
2216         and that your llvm libraries are installed in $LLVM_LIBDIR
2217         If you have installed your llvm libraries to a different directory you
2218         can use the --with-llvm-prefix= configure flag to specify this directory.
2219         NOTE: Mesa is attempting to use llvm shared libraries by default.
2220         If you do not want to build with llvm shared libraries and instead want to
2221         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2222         invocation and rebuild.])])
2223
2224            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2225            dnl install uses a shared object for each component and we have
2226            dnl already added all of these objects to LLVM_LIBS.
2227         fi
2228     else
2229         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2230         dnl We need to link to llvm system libs when using static libs
2231         dnl However, only llvm 3.5+ provides --system-libs
2232         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2233             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2234         fi
2235     fi
2236 fi
2237
2238 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2239 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2240 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2241 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2242 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2243 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2244 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2245                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2248 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2249 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2250 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2251
2252 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2253
2254 # NOTE: anything using xcb or other client side libs ends up in separate
2255 #       _CLIENT variables.  The pipe loader is built in two variants,
2256 #       one that is standalone and does not link any x client libs (for
2257 #       use by XA tracker in particular, but could be used in any case
2258 #       where communication with xserver is not desired).
2259 if test "x$enable_gallium_loader" = xyes; then
2260     if test "x$enable_dri" = xyes; then
2261         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2262     fi
2263
2264     if test "x$enable_gallium_drm_loader" = xyes; then
2265         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2266     fi
2267
2268     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2269 fi
2270
2271 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2272 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2273 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2274 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2275 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2276 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2277
2278 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2279                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2280                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2281 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2282 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2283 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2284 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2285 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2286 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2287 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2288 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2289 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2290     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2291 fi
2292
2293 AC_SUBST([ELF_LIB])
2294
2295 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2296 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2297 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2298 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2299
2300 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2301 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2302 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2303
2304 AC_SUBST([NINE_MAJOR], 1)
2305 AC_SUBST([NINE_MINOR], 0)
2306 AC_SUBST([NINE_TINY], 0)
2307 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2308
2309 AC_SUBST([VDPAU_MAJOR], 1)
2310 AC_SUBST([VDPAU_MINOR], 0)
2311
2312 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2313 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2314 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2315 AC_SUBST([VA_MINOR], $VA_MINOR)
2316
2317 AC_SUBST([XVMC_MAJOR], 1)
2318 AC_SUBST([XVMC_MINOR], 0)
2319
2320 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2321 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2322 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2323 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2324
2325 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2326 AC_SUBST([XA_MINOR], $XA_MINOR)
2327 AC_SUBST([XA_TINY], $XA_TINY)
2328 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2329
2330 PKG_CHECK_MODULES(VALGRIND, [valgrind],
2331                   [have_valgrind=yes], [have_valgrind=no])
2332 if test "x$have_valgrind" = "xyes"; then
2333     AC_DEFINE([HAVE_VALGRIND], 1,
2334               [Use valgrind intrinsics to suppress false warnings])
2335 fi
2336
2337 dnl Restore LDFLAGS and CPPFLAGS
2338 LDFLAGS="$_SAVE_LDFLAGS"
2339 CPPFLAGS="$_SAVE_CPPFLAGS"
2340
2341 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2342 if test "x$acv_mesa_CLANG" = xyes; then
2343     CFLAGS="$CFLAGS -Qunused-arguments"
2344     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2345 fi
2346
2347 dnl Add user CFLAGS and CXXFLAGS
2348 CFLAGS="$CFLAGS $USER_CFLAGS"
2349 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2350
2351 dnl Substitute the config
2352 AC_CONFIG_FILES([Makefile
2353                 src/Makefile
2354                 src/egl/Makefile
2355                 src/egl/main/egl.pc
2356                 src/egl/wayland/wayland-drm/Makefile
2357                 src/egl/wayland/wayland-egl/Makefile
2358                 src/egl/wayland/wayland-egl/wayland-egl.pc
2359                 src/gallium/Makefile
2360                 src/gallium/auxiliary/Makefile
2361                 src/gallium/auxiliary/pipe-loader/Makefile
2362                 src/gallium/drivers/freedreno/Makefile
2363                 src/gallium/drivers/ddebug/Makefile
2364                 src/gallium/drivers/i915/Makefile
2365                 src/gallium/drivers/ilo/Makefile
2366                 src/gallium/drivers/llvmpipe/Makefile
2367                 src/gallium/drivers/noop/Makefile
2368                 src/gallium/drivers/nouveau/Makefile
2369                 src/gallium/drivers/r300/Makefile
2370                 src/gallium/drivers/r600/Makefile
2371                 src/gallium/drivers/radeon/Makefile
2372                 src/gallium/drivers/radeonsi/Makefile
2373                 src/gallium/drivers/rbug/Makefile
2374                 src/gallium/drivers/softpipe/Makefile
2375                 src/gallium/drivers/svga/Makefile
2376                 src/gallium/drivers/trace/Makefile
2377                 src/gallium/drivers/vc4/Makefile
2378                 src/gallium/state_trackers/clover/Makefile
2379                 src/gallium/state_trackers/dri/Makefile
2380                 src/gallium/state_trackers/glx/xlib/Makefile
2381                 src/gallium/state_trackers/nine/Makefile
2382                 src/gallium/state_trackers/omx/Makefile
2383                 src/gallium/state_trackers/osmesa/Makefile
2384                 src/gallium/state_trackers/va/Makefile
2385                 src/gallium/state_trackers/vdpau/Makefile
2386                 src/gallium/state_trackers/xa/Makefile
2387                 src/gallium/state_trackers/xvmc/Makefile
2388                 src/gallium/targets/d3dadapter9/Makefile
2389                 src/gallium/targets/d3dadapter9/d3d.pc
2390                 src/gallium/targets/dri/Makefile
2391                 src/gallium/targets/libgl-xlib/Makefile
2392                 src/gallium/targets/omx/Makefile
2393                 src/gallium/targets/opencl/Makefile
2394                 src/gallium/targets/opencl/mesa.icd
2395                 src/gallium/targets/osmesa/Makefile
2396                 src/gallium/targets/osmesa/osmesa.pc
2397                 src/gallium/targets/pipe-loader/Makefile
2398                 src/gallium/targets/va/Makefile
2399                 src/gallium/targets/vdpau/Makefile
2400                 src/gallium/targets/xa/Makefile
2401                 src/gallium/targets/xa/xatracker.pc
2402                 src/gallium/targets/xvmc/Makefile
2403                 src/gallium/tests/trivial/Makefile
2404                 src/gallium/tests/unit/Makefile
2405                 src/gallium/winsys/freedreno/drm/Makefile
2406                 src/gallium/winsys/i915/drm/Makefile
2407                 src/gallium/winsys/intel/drm/Makefile
2408                 src/gallium/winsys/nouveau/drm/Makefile
2409                 src/gallium/winsys/radeon/drm/Makefile
2410                 src/gallium/winsys/amdgpu/drm/Makefile
2411                 src/gallium/winsys/svga/drm/Makefile
2412                 src/gallium/winsys/sw/dri/Makefile
2413                 src/gallium/winsys/sw/kms-dri/Makefile
2414                 src/gallium/winsys/sw/null/Makefile
2415                 src/gallium/winsys/sw/wrapper/Makefile
2416                 src/gallium/winsys/sw/xlib/Makefile
2417                 src/gallium/winsys/vc4/drm/Makefile
2418                 src/gbm/Makefile
2419                 src/gbm/main/gbm.pc
2420                 src/glsl/Makefile
2421                 src/glx/Makefile
2422                 src/glx/apple/Makefile
2423                 src/glx/tests/Makefile
2424                 src/gtest/Makefile
2425                 src/loader/Makefile
2426                 src/mapi/Makefile
2427                 src/mapi/es1api/glesv1_cm.pc
2428                 src/mapi/es2api/glesv2.pc
2429                 src/mapi/glapi/gen/Makefile
2430                 src/mesa/Makefile
2431                 src/mesa/gl.pc
2432                 src/mesa/drivers/dri/dri.pc
2433                 src/mesa/drivers/dri/common/Makefile
2434                 src/mesa/drivers/dri/common/xmlpool/Makefile
2435                 src/mesa/drivers/dri/i915/Makefile
2436                 src/mesa/drivers/dri/i965/Makefile
2437                 src/mesa/drivers/dri/Makefile
2438                 src/mesa/drivers/dri/nouveau/Makefile
2439                 src/mesa/drivers/dri/r200/Makefile
2440                 src/mesa/drivers/dri/radeon/Makefile
2441                 src/mesa/drivers/dri/swrast/Makefile
2442                 src/mesa/drivers/osmesa/Makefile
2443                 src/mesa/drivers/osmesa/osmesa.pc
2444                 src/mesa/drivers/x11/Makefile
2445                 src/mesa/main/tests/Makefile
2446                 src/vulkan/Makefile
2447                 src/vulkan/anv_icd.json
2448                 src/vulkan/tests/Makefile
2449                 src/util/Makefile
2450                 src/util/tests/hash_table/Makefile])
2451
2452 AC_OUTPUT
2453
2454 dnl
2455 dnl Output some configuration info for the user
2456 dnl
2457 echo ""
2458 echo "        prefix:          $prefix"
2459 echo "        exec_prefix:     $exec_prefix"
2460 echo "        libdir:          $libdir"
2461 echo "        includedir:      $includedir"
2462
2463 dnl API info
2464 echo ""
2465 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2466
2467 dnl Driver info
2468 echo ""
2469 case "x$enable_osmesa$enable_gallium_osmesa" in
2470 xnoyes)
2471         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2472         ;;
2473 xyesno)
2474         echo "        OSMesa:          lib$OSMESA_LIB"
2475         ;;
2476 xnono)
2477         echo "        OSMesa:          no"
2478         ;;
2479 esac
2480
2481 echo ""
2482 if test "x$enable_dri" != xno; then
2483         echo "        DRI platform:    $dri_platform"
2484         if test -z "$DRI_DIRS"; then
2485             echo "        DRI drivers:     no"
2486         else
2487             echo "        DRI drivers:     $DRI_DIRS"
2488         fi
2489         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2490 fi
2491
2492 case "x$enable_glx$enable_xlib_glx" in
2493 xyesyes)
2494     echo "        GLX:             Xlib-based"
2495     ;;
2496 xyesno)
2497     echo "        GLX:             DRI-based"
2498     ;;
2499 *)
2500     echo "        GLX:             $enable_glx"
2501     ;;
2502 esac
2503
2504 dnl EGL
2505 echo ""
2506 echo "        EGL:             $enable_egl"
2507 if test "$enable_egl" = yes; then
2508     echo "        EGL platforms:   $egl_platforms"
2509
2510     egl_drivers=""
2511     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2512         egl_drivers="$egl_drivers builtin:egl_dri2"
2513     fi
2514
2515     echo "        EGL drivers:    $egl_drivers"
2516 fi
2517
2518 echo ""
2519 if test "x$MESA_LLVM" = x1; then
2520     echo "        llvm:            yes"
2521     echo "        llvm-config:     $LLVM_CONFIG"
2522     echo "        llvm-version:    $LLVM_VERSION"
2523 else
2524     echo "        llvm:            no"
2525 fi
2526
2527 echo ""
2528 if test -n "$with_gallium_drivers"; then
2529     echo "        Gallium:         yes"
2530 else
2531     echo "        Gallium:         no"
2532 fi
2533
2534 dnl Shader cache
2535 echo ""
2536 echo "        Shader cache:    $enable_shader_cache"
2537 if test "x$enable_shader_cache" = "xyes"; then
2538     echo "        With SHA1 from:  $with_sha1"
2539 fi
2540
2541 dnl Libraries
2542 echo ""
2543 echo "        Shared libs:     $enable_shared"
2544 echo "        Static libs:     $enable_static"
2545 echo "        Shared-glapi:    $enable_shared_glapi"
2546
2547 dnl Compiler options
2548 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2549 cflags=`echo $CFLAGS | \
2550     $SED 's/^ *//;s/  */ /;s/ *$//'`
2551 cxxflags=`echo $CXXFLAGS | \
2552     $SED 's/^ *//;s/  */ /;s/ *$//'`
2553 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2554 echo ""
2555 echo "        CFLAGS:          $cflags"
2556 echo "        CXXFLAGS:        $cxxflags"
2557 echo "        Macros:          $defines"
2558 echo ""
2559 if test "x$MESA_LLVM" = x1; then
2560     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2561     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2562     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2563     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2564     echo ""
2565 fi
2566 echo "        PYTHON2:         $PYTHON2"
2567 echo "        PYTHON3:         $PYTHON3"
2568
2569 echo ""
2570 echo "        Run '${MAKE-make}' to build Mesa"
2571 echo ""