configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.42
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AX_PROG_CC_FOR_BUILD
  48 AC_PROG_CXX
  49 AX_PROG_CXX_FOR_BUILD
  50 AM_PROG_CC_C_O
  51 AM_PROG_AS
  52 AC_CHECK_PROGS([MAKE], [gmake make])
  53 AC_CHECK_PROGS([PYTHON2], [python2 python])
  54 AX_PYTHON_MODULE([libxml2], [needed])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([disable-static])
  60
  61 AX_PROG_BISON([],
  62               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  63                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  64 AX_PROG_FLEX([],
  65              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  66                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  67
  68 AC_PATH_PROG([PERL], [perl])
  69
  70 AC_CHECK_PROG(INDENT, indent, indent, cat)
  71 if test "x$INDENT" != "xcat"; then
  72     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  73 fi
  74
  75 AC_PROG_INSTALL
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122 dnl Make sure the pkg-config macros are defined
 123 m4_ifndef([PKG_PROG_PKG_CONFIG],
 124     [m4_fatal([Could not locate the pkg-config autoconf macros.
 125   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 126   are in a different location, try setting the environment variable
 127   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 128 PKG_PROG_PKG_CONFIG()
 129
 130 dnl LIB_DIR - library basename
 131 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 132 AC_SUBST([LIB_DIR])
 133
 134 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 135 _SAVE_LDFLAGS="$LDFLAGS"
 136 _SAVE_CPPFLAGS="$CPPFLAGS"
 137
 138 dnl build host compiler macros
 139 DEFINES_FOR_BUILD=""
 140 AC_SUBST([DEFINES_FOR_BUILD])
 141 case "$build_os" in
 142 linux*|*-gnu*|gnu*)
 143     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 144     ;;
 145 solaris*)
 146     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 147     ;;
 148 cygwin*)
 149     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 150     ;;
 151 esac
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DHAVE_PTHREAD"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     case "$host_os" in
 171     cygwin*)
 172         CFLAGS="$CFLAGS -Wall -std=gnu99"
 173         ;;
 174     *)
 175         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 176         CFLAGS="$CFLAGS -Wall -std=c99"
 177         ;;
 178     esac
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 206     CFLAGS="$CFLAGS -fno-strict-aliasing"
 207
 208     # gcc's builtin memcmp is slower than glibc's
 209     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 210     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 215     CXXFLAGS="$CXXFLAGS -Wall"
 216
 217     # Enable -fvisibility=hidden if using a gcc that supports it
 218     save_CXXFLAGS="$CXXFLAGS"
 219     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 220     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 221     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 222     AC_LANG_PUSH([C++])
 223     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 224                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 225     AC_LANG_POP([C++])
 226
 227     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 228     CXXFLAGS=$save_CXXFLAGS
 229
 230     # Work around aliasing bugs - developers should comment this out
 231     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 232     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 233
 234     # gcc's builtin memcmp is slower than glibc's
 235     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 236     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Hacks to enable 32 or 64 bit build
 254 dnl
 255 AC_ARG_ENABLE([32-bit],
 256     [AS_HELP_STRING([--enable-32-bit],
 257         [build 32-bit libraries @<:@default=auto@:>@])],
 258     [enable_32bit="$enableval"],
 259     [enable_32bit=auto]
 260 )
 261 if test "x$enable_32bit" = xyes; then
 262     if test "x$GCC" = xyes; then
 263         CFLAGS="$CFLAGS -m32"
 264         CCASFLAGS="$CCASFLAGS -m32"
 265     fi
 266     if test "x$GXX" = xyes; then
 267         CXXFLAGS="$CXXFLAGS -m32"
 268     fi
 269 fi
 270 AC_ARG_ENABLE([64-bit],
 271     [AS_HELP_STRING([--enable-64-bit],
 272         [build 64-bit libraries @<:@default=auto@:>@])],
 273     [enable_64bit="$enableval"],
 274     [enable_64bit=auto]
 275 )
 276 if test "x$enable_64bit" = xyes; then
 277     if test "x$GCC" = xyes; then
 278         CFLAGS="$CFLAGS -m64"
 279     fi
 280     if test "x$GXX" = xyes; then
 281         CXXFLAGS="$CXXFLAGS -m64"
 282     fi
 283 fi
 284
 285 dnl Can't have static and shared libraries, default to static if user
 286 dnl explicitly requested. If both disabled, set to static since shared
 287 dnl was explicitly requested.
 288 case "x$enable_static$enable_shared" in
 289 xyesyes )
 290     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 291     enable_shared=no
 292     ;;
 293 xnono )
 294     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 295     enable_static=yes
 296     ;;
 297 esac
 298
 299 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 300
 301 dnl
 302 dnl other compiler options
 303 dnl
 304 AC_ARG_ENABLE([debug],
 305     [AS_HELP_STRING([--enable-debug],
 306         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 307     [enable_debug="$enableval"],
 308     [enable_debug=no]
 309 )
 310 if test "x$enable_debug" = xyes; then
 311     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 312     if test "x$GCC_FOR_BUILD" = xyes; then
 313         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 314     fi
 315     if test "x$GXX_FOR_BUILD" = xyes; then
 316         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 317     fi
 318
 319     DEFINES="$DEFINES -DDEBUG"
 320     if test "x$GCC" = xyes; then
 321         CFLAGS="$CFLAGS -g -O0"
 322     fi
 323     if test "x$GXX" = xyes; then
 324         CXXFLAGS="$CXXFLAGS -g -O0"
 325     fi
 326 fi
 327
 328 dnl
 329 dnl library names
 330 dnl
 331 LIB_PREFIX_GLOB='lib'
 332 LIB_VERSION_SEPARATOR='.'
 333 if test "$enable_static" = yes; then
 334     LIB_EXTENSION='a'
 335 else
 336     case "$host_os" in
 337     darwin* )
 338         LIB_EXTENSION='dylib' ;;
 339     cygwin* )
 340         dnl prefix can be 'cyg' or 'lib'
 341         LIB_PREFIX_GLOB='???'
 342         LIB_VERSION_SEPARATOR='-'
 343         LIB_EXTENSION='dll' ;;
 344     aix* )
 345         LIB_EXTENSION='a' ;;
 346     * )
 347         LIB_EXTENSION='so' ;;
 348     esac
 349 fi
 350 AC_ARG_WITH([gl-lib-name],
 351   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 352     [specify GL library name @<:@default=GL@:>@])],
 353   [GL_LIB=$withval],
 354   [GL_LIB=GL])
 355 AC_ARG_WITH([osmesa-lib-name],
 356   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 357     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 358   [OSMESA_LIB=$withval],
 359   [OSMESA_LIB=OSMesa])
 360 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 361 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 362
 363 dnl
 364 dnl Mangled Mesa support
 365 dnl
 366 AC_ARG_ENABLE([mangling],
 367   [AS_HELP_STRING([--enable-mangling],
 368     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 369   [enable_mangling="${enableval}"],
 370   [enable_mangling=no]
 371 )
 372 if test "x${enable_mangling}" = "xyes" ; then
 373   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 374   GL_LIB="Mangled${GL_LIB}"
 375   OSMESA_LIB="Mangled${OSMESA_LIB}"
 376 fi
 377 AC_SUBST([GL_LIB])
 378 AC_SUBST([OSMESA_LIB])
 379
 380 dnl
 381 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 382 dnl
 383 AC_ARG_ENABLE([texture-float],
 384     [AS_HELP_STRING([--enable-texture-float],
 385         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 386     [enable_texture_float="$enableval"],
 387     [enable_texture_float=no]
 388 )
 389 if test "x$enable_texture_float" = xyes; then
 390     AC_MSG_WARN([Floating-point textures enabled.])
 391     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 392     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 393 fi
 394
 395 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 396 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 397 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 398 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 399 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 400 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 401 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 402
 403 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410
 411 AC_SUBST([GL_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([EGL_LIB_GLOB])
 421 AC_SUBST([GLESv1_CM_LIB_GLOB])
 422 AC_SUBST([GLESv2_LIB_GLOB])
 423 AC_SUBST([VG_LIB_GLOB])
 424 AC_SUBST([GLAPI_LIB_GLOB])
 425
 426 dnl
 427 dnl Arch/platform-specific settings
 428 dnl
 429 AC_ARG_ENABLE([asm],
 430     [AS_HELP_STRING([--disable-asm],
 431         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 432     [enable_asm="$enableval"],
 433     [enable_asm=yes]
 434 )
 435 asm_arch=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         gnu*)
 456             asm_arch=x86
 457             ;;
 458         esac
 459         ;;
 460     x86_64)
 461         case "$host_os" in
 462         linux* | *freebsd* | dragonfly* | *netbsd*)
 463             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 464             ;;
 465         esac
 466         ;;
 467     sparc*)
 468         case "$host_os" in
 469         linux*)
 470             asm_arch=sparc
 471             ;;
 472         esac
 473         ;;
 474     esac
 475
 476     case "$asm_arch" in
 477     x86)
 478         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 479         AC_MSG_RESULT([yes, x86])
 480         ;;
 481     x86_64)
 482         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 483         AC_MSG_RESULT([yes, x86_64])
 484         ;;
 485     sparc)
 486         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494
 495 dnl Check to see if dlopen is in default libraries (like Solaris, which
 496 dnl has it in libc), or if libdl is needed to get it.
 497 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 498     [AC_CHECK_LIB([dl], [dlopen],
 499        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 500 AC_SUBST([DLOPEN_LIBS])
 501
 502 case "$host_os" in
 503 darwin*|mingw*)
 504     ;;
 505 *)
 506     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 507                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 508                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 509     AC_SUBST([CLOCK_LIB])
 510     ;;
 511 esac
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl Check for pthreads
 517 AX_PTHREAD
 518 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 519 dnl to -pthread, which causes problems if we need -lpthread to appear in
 520 dnl pkgconfig files.
 521 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 522
 523 dnl SELinux awareness.
 524 AC_ARG_ENABLE([selinux],
 525     [AS_HELP_STRING([--enable-selinux],
 526         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 527     [MESA_SELINUX="$enableval"],
 528     [MESA_SELINUX=no])
 529 if test "x$enable_selinux" = "xyes"; then
 530     AC_CHECK_HEADER([selinux/selinux.h],[],
 531                     [AC_MSG_ERROR([SELinux headers not found])])
 532     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 533                  [AC_MSG_ERROR([SELinux library not found])])
 534     SELINUX_LIBS="-lselinux"
 535     DEFINES="$DEFINES -DMESA_SELINUX"
 536 fi
 537 AC_SUBST([SELINUX_LIBS])
 538
 539 dnl Options for APIs
 540 AC_ARG_ENABLE([opengl],
 541     [AS_HELP_STRING([--disable-opengl],
 542         [disable support for standard OpenGL API @<:@default=no@:>@])],
 543     [enable_opengl="$enableval"],
 544     [enable_opengl=yes])
 545 AC_ARG_ENABLE([gles1],
 546     [AS_HELP_STRING([--enable-gles1],
 547         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 548     [enable_gles1="$enableval"],
 549     [enable_gles1=no])
 550 AC_ARG_ENABLE([gles2],
 551     [AS_HELP_STRING([--enable-gles2],
 552         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 553     [enable_gles2="$enableval"],
 554     [enable_gles2=no])
 555 AC_ARG_ENABLE([openvg],
 556     [AS_HELP_STRING([--enable-openvg],
 557         [enable support for OpenVG API @<:@default=no@:>@])],
 558     [enable_openvg="$enableval"],
 559     [enable_openvg=no])
 560
 561 AC_ARG_ENABLE([dri],
 562     [AS_HELP_STRING([--enable-dri],
 563         [enable DRI modules @<:@default=enabled@:>@])],
 564     [enable_dri="$enableval"],
 565     [enable_dri=yes])
 566 AC_ARG_ENABLE([glx],
 567     [AS_HELP_STRING([--enable-glx],
 568         [enable GLX library @<:@default=enabled@:>@])],
 569     [enable_glx="$enableval"],
 570     [enable_glx=yes])
 571 AC_ARG_ENABLE([osmesa],
 572     [AS_HELP_STRING([--enable-osmesa],
 573         [enable OSMesa library @<:@default=disabled@:>@])],
 574     [enable_osmesa="$enableval"],
 575     [enable_osmesa=no])
 576 AC_ARG_ENABLE([egl],
 577     [AS_HELP_STRING([--disable-egl],
 578         [disable EGL library @<:@default=enabled@:>@])],
 579     [enable_egl="$enableval"],
 580     [enable_egl=yes])
 581
 582 AC_ARG_ENABLE([xorg],
 583     [AS_HELP_STRING([--enable-xorg],
 584         [enable support for X.Org DDX API @<:@default=no@:>@])],
 585     [enable_xorg="$enableval"],
 586     [enable_xorg=no])
 587 AC_ARG_ENABLE([xa],
 588     [AS_HELP_STRING([--enable-xa],
 589         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 590     [enable_xa="$enableval"],
 591     [enable_xa=no])
 592 AC_ARG_ENABLE([gbm],
 593    [AS_HELP_STRING([--enable-gbm],
 594          [enable gbm library @<:@default=auto@:>@])],
 595    [enable_gbm="$enableval"],
 596    [enable_gbm=auto])
 597
 598 AC_ARG_ENABLE([xvmc],
 599    [AS_HELP_STRING([--enable-xvmc],
 600          [enable xvmc library @<:@default=auto@:>@])],
 601    [enable_xvmc="$enableval"],
 602    [enable_xvmc=auto])
 603 AC_ARG_ENABLE([vdpau],
 604    [AS_HELP_STRING([--enable-vdpau],
 605          [enable vdpau library @<:@default=auto@:>@])],
 606    [enable_vdpau="$enableval"],
 607    [enable_vdpau=auto])
 608 AC_ARG_ENABLE([opencl],
 609    [AS_HELP_STRING([--enable-opencl],
 610          [enable OpenCL library NOTE: Enabling this option will also enable
 611           --with-llvm-shared-libs
 612           @<:@default=no@:>@])],
 613    [],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=no])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648
 649 # Keep this in sync with the --with-gallium-drivers help string default value
 650 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 651
 652 AC_ARG_WITH([gallium-drivers],
 653     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 654         [comma delimited Gallium drivers list, e.g.
 655         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 656         @<:@default=r300,r600,svga,swrast@:>@])],
 657     [with_gallium_drivers="$withval"],
 658     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 659
 660 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 661 # here so that the script doesn't choke on an unknown driver name later.
 662 case "$with_gallium_drivers" in
 663     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 664     no) with_gallium_drivers='' ;;
 665 esac
 666
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xno -a \
 669         "x$enable_gles2" = xno -a \
 670         "x$enable_openvg" = xno -a \
 671         "x$enable_xorg" = xno -a \
 672         "x$enable_xa" = xno -a \
 673         "x$enable_xvmc" = xno -a \
 674         "x$enable_vdpau" = xno -a \
 675         "x$enable_opencl" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 API_DEFINES=""
 680 if test "x$enable_opengl" = xno; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 682 else
 683     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 684 fi
 685 if test "x$enable_gles1" = xyes; then
 686     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 687 fi
 688 if test "x$enable_gles2" = xyes; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 690 fi
 691 AC_SUBST([API_DEFINES])
 692
 693 if test "x$enable_glx" = xno; then
 694     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 695     enable_xlib_glx=no
 696 fi
 697
 698 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 699     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 700 fi
 701
 702 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 703     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 704 fi
 705
 706 # Disable GLX if OpenGL is not enabled
 707 if test "x$enable_glx$enable_opengl" = xyesno; then
 708     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 709     enable_glx=no
 710 fi
 711
 712 # Disable GLX if DRI and Xlib-GLX are not enabled
 713 if test "x$enable_glx" = xyes -a \
 714         "x$enable_dri" = xno -a \
 715         "x$enable_xlib_glx" = xno; then
 716     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 717     enable_glx=no
 718 fi
 719
 720 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 721 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 722                                   "x$enable_osmesa" = xyes)
 723
 724 AC_ARG_ENABLE([shared-glapi],
 725     [AS_HELP_STRING([--enable-shared-glapi],
 726         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 727     [enable_shared_glapi="$enableval"],
 728     [enable_shared_glapi="$enable_dri"])
 729
 730 # Shared GLAPI is only useful for DRI
 731 if test "x$enable_dri" = xno; then
 732     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 733     enable_shared_glapi=no
 734 fi
 735
 736 if test "x$enable_shared_glapi" = xyes; then
 737     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 738     # the remap table)
 739     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 740     CORE_DIRS="mapi/shared-glapi"
 741 fi
 742 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 743
 744 dnl
 745 dnl Driver specific build directories
 746 dnl
 747 GALLIUM_DIRS="auxiliary drivers state_trackers"
 748 GALLIUM_TARGET_DIRS=""
 749 GALLIUM_WINSYS_DIRS="sw"
 750 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 751 GALLIUM_STATE_TRACKERS_DIRS=""
 752
 753 # build glapi if OpenGL is enabled
 754 if test "x$enable_opengl" = xyes; then
 755     CORE_DIRS="$CORE_DIRS mapi/glapi"
 756 fi
 757
 758 # build es1api if OpenGL ES 1.x is enabled
 759 if test "x$enable_gles1" = xyes; then
 760     CORE_DIRS="$CORE_DIRS mapi/es1api"
 761 fi
 762
 763 # build es2api if OpenGL ES 2.x is enabled
 764 if test "x$enable_gles2" = xyes; then
 765     CORE_DIRS="$CORE_DIRS mapi/es2api"
 766 fi
 767
 768 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 769 case "x$enable_opengl$enable_gles1$enable_gles2" in
 770 x*yes*)
 771     CORE_DIRS="mapi/glapi/gen $CORE_DIRS gtest glsl mesa"
 772     ;;
 773 esac
 774
 775 case "x$enable_glx$enable_xlib_glx" in
 776 xyesyes)
 777     DRIVER_DIRS="$DRIVER_DIRS x11"
 778     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 779     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 780     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 781     HAVE_WINSYS_XLIB="yes"
 782     ;;
 783 xyesno)
 784     # DRI-based GLX
 785     SRC_DIRS="$SRC_DIRS glx"
 786     ;;
 787 esac
 788
 789 if test "x$enable_dri" = xyes; then
 790     DRIVER_DIRS="$DRIVER_DIRS dri"
 791
 792     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 793     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 794     HAVE_ST_DRI="yes"
 795 fi
 796
 797 if test "x$enable_osmesa" = xyes; then
 798     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 799     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 800     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 801 fi
 802
 803 AC_SUBST([SRC_DIRS])
 804 AC_SUBST([DRIVER_DIRS])
 805 AC_SUBST([GALLIUM_DIRS])
 806 AC_SUBST([GALLIUM_TARGET_DIRS])
 807 AC_SUBST([GALLIUM_WINSYS_DIRS])
 808 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 809 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 810 AC_SUBST([MESA_LLVM])
 811
 812 # Check for libdrm
 813 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 814                   [have_libdrm=yes], [have_libdrm=no])
 815
 816 if test "x$enable_dri" = xyes; then
 817     # DRI must be shared, I think
 818     if test "$enable_static" = yes; then
 819         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 820     fi
 821
 822     # not a hard requirement as swrast does not depend on it
 823     if test "x$have_libdrm" = xyes; then
 824         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 825     fi
 826 fi
 827
 828 dnl Direct rendering or just indirect rendering
 829 case "$host_os" in
 830 gnu*)
 831     dnl Disable by default on GNU/Hurd
 832     driglx_direct_default="no"
 833     ;;
 834 cygwin*)
 835     dnl Disable by default on cygwin
 836     driglx_direct_default="no"
 837     ;;
 838 *)
 839     driglx_direct_default="yes"
 840     ;;
 841 esac
 842 AC_ARG_ENABLE([driglx-direct],
 843     [AS_HELP_STRING([--disable-driglx-direct],
 844         [disable direct rendering in GLX and EGL for DRI \
 845             @<:@default=auto@:>@])],
 846     [driglx_direct="$enableval"],
 847     [driglx_direct="$driglx_direct_default"])
 848
 849 dnl
 850 dnl libGL configuration per driver
 851 dnl
 852 case "x$enable_glx$enable_xlib_glx" in
 853 xyesyes)
 854     # Xlib-based GLX
 855     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 856     GL_PC_REQ_PRIV="x11 xext"
 857     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 858     GL_LIB_DEPS="$XLIBGL_LIBS"
 859     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 860     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 861     ;;
 862 xyesno)
 863     # DRI-based GLX
 864     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 865     if test x"$driglx_direct" = xyes; then
 866         if test "x$have_libdrm" != xyes; then
 867             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 868         fi
 869         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 870         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 871     fi
 872
 873     # find the DRI deps for libGL
 874     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 875
 876     # add xf86vidmode if available
 877     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 878     if test "$HAVE_XF86VIDMODE" = yes ; then
 879         dri_modules="$dri_modules xxf86vm"
 880     fi
 881
 882     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 883     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 884     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 885     GL_LIB_DEPS="$DRIGL_LIBS"
 886
 887     # need DRM libs, $PTHREAD_LIBS, etc.
 888     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 889     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 890     ;;
 891 esac
 892
 893 # This is outside the case (above) so that it is invoked even for non-GLX
 894 # builds.
 895 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 896
 897 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 898 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 899 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 900 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 901
 902 AC_SUBST([X11_INCLUDES])
 903 AC_SUBST([GL_LIB_DEPS])
 904 AC_SUBST([GL_PC_REQ_PRIV])
 905 AC_SUBST([GL_PC_LIB_PRIV])
 906 AC_SUBST([GL_PC_CFLAGS])
 907 AC_SUBST([DRI_PC_REQ_PRIV])
 908 AC_SUBST([GLESv1_CM_LIB_DEPS])
 909 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 910 AC_SUBST([GLESv2_LIB_DEPS])
 911 AC_SUBST([GLESv2_PC_LIB_PRIV])
 912
 913 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 914
 915 AC_SUBST([HAVE_XF86VIDMODE])
 916
 917 dnl
 918 dnl More GLX setup
 919 dnl
 920 case "x$enable_glx$enable_xlib_glx" in
 921 xyesyes)
 922     DEFINES="$DEFINES -DUSE_XSHM"
 923     ;;
 924 xyesno)
 925     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 926     if test "x$driglx_direct" = xyes; then
 927         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 928     fi
 929     ;;
 930 esac
 931
 932 dnl
 933 dnl TLS detection
 934 dnl
 935
 936 AC_ARG_ENABLE([glx-tls],
 937     [AS_HELP_STRING([--enable-glx-tls],
 938         [enable TLS support in GLX @<:@default=disabled@:>@])],
 939     [GLX_USE_TLS="$enableval"],
 940     [GLX_USE_TLS=no])
 941 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 942
 943 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 944       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 945
 946 dnl
 947 dnl More DRI setup
 948 dnl
 949 dnl Directory for DRI drivers
 950 AC_ARG_WITH([dri-driverdir],
 951     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 952         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 953     [DRI_DRIVER_INSTALL_DIR="$withval"],
 954     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 955 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 956 dnl Extra search path for DRI drivers
 957 AC_ARG_WITH([dri-searchpath],
 958     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 959         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 960     [DRI_DRIVER_SEARCH_DIR="$withval"],
 961     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 962 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 963 dnl Which drivers to build - default is chosen by platform
 964 AC_ARG_WITH([dri-drivers],
 965     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 966         [comma delimited DRI drivers list, e.g.
 967         "swrast,i965,radeon" @<:@default=auto@:>@])],
 968     [with_dri_drivers="$withval"],
 969     [with_dri_drivers=yes])
 970 if test "x$with_dri_drivers" = x; then
 971     with_dri_drivers=no
 972 fi
 973
 974 dnl If $with_dri_drivers is yes, directories will be added through
 975 dnl platform checks
 976 DRI_DIRS=""
 977 case "$with_dri_drivers" in
 978 no) ;;
 979 yes)
 980     # classic DRI drivers require FEATURE_GL to build
 981     if test "x$enable_opengl" = xyes; then
 982         DRI_DIRS="yes"
 983     fi
 984     ;;
 985 *)
 986     # verify the requested driver directories exist
 987     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 988     for driver in $dri_drivers; do
 989         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 990             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 991     done
 992     DRI_DIRS="$dri_drivers"
 993     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 994         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 995     fi
 996     ;;
 997 esac
 998
 999 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1000 if test "x$enable_dri" = xyes; then
1001     # Platform specific settings and drivers to build
1002     case "$host_os" in
1003     linux*)
1004         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1005         DEFINES="$DEFINES -DHAVE_ALIAS"
1006
1007         case "$host_cpu" in
1008         x86_64)
1009             if test "x$DRI_DIRS" = "xyes"; then
1010                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1011             fi
1012             ;;
1013         powerpc*)
1014             # Build only the drivers for cards that exist on PowerPC.
1015             if test "x$DRI_DIRS" = "xyes"; then
1016                 DRI_DIRS="r200 radeon swrast"
1017             fi
1018             ;;
1019         sparc*)
1020             # Build only the drivers for cards that exist on sparc
1021             if test "x$DRI_DIRS" = "xyes"; then
1022                 DRI_DIRS="r200 radeon swrast"
1023             fi
1024             ;;
1025         esac
1026         ;;
1027     freebsd* | dragonfly* | *netbsd*)
1028         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1029         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1030
1031         if test "x$DRI_DIRS" = "xyes"; then
1032             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1033         fi
1034         ;;
1035     gnu*)
1036         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1037         DEFINES="$DEFINES -DHAVE_ALIAS"
1038         ;;
1039     solaris*)
1040         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1041         ;;
1042     cygwin*)
1043         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1044         if test "x$DRI_DIRS" = "xyes"; then
1045             DRI_DIRS="swrast"
1046         fi
1047         ;;
1048     esac
1049
1050     # default drivers
1051     if test "x$DRI_DIRS" = "xyes"; then
1052         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1053     fi
1054
1055     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1056
1057     # Check for expat
1058     EXPAT_INCLUDES=""
1059     EXPAT_LIB=-lexpat
1060     AC_ARG_WITH([expat],
1061         [AS_HELP_STRING([--with-expat=DIR],
1062             [expat install directory])],[
1063         EXPAT_INCLUDES="-I$withval/include"
1064         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1065         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1066         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1067         ])
1068     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1069     save_LIBS="$LIBS"
1070     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1071         [AC_MSG_ERROR([Expat required for DRI.])])
1072     LIBS="$save_LIBS"
1073
1074     # If we are building any DRI driver other than swrast.
1075     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1076         # ... libdrm is required
1077         if test "x$have_libdrm" != xyes; then
1078             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1079         fi
1080         # ... and build dricommon
1081         HAVE_COMMON_DRI=yes
1082     fi
1083
1084     # put all the necessary libs together
1085     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1086     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1087 fi
1088 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1089 AC_SUBST([DRI_DIRS])
1090 AC_SUBST([EXPAT_INCLUDES])
1091 AC_SUBST([DRI_LIB_DEPS])
1092 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1093
1094 case $DRI_DIRS in
1095 *i915*|*i965*)
1096     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1097
1098     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1099         case $d in
1100         i915)
1101             HAVE_I915_DRI=yes;
1102             ;;
1103         i965)
1104             HAVE_I965_DRI=yes;
1105             ;;
1106         esac
1107     done
1108
1109     ;;
1110 esac
1111
1112 case $DRI_DIRS in
1113 *nouveau*)
1114     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1115     HAVE_NOUVEAU_DRI=yes;
1116     ;;
1117 esac
1118
1119 case $DRI_DIRS in
1120 *radeon*|*r200*)
1121     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1122
1123     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1124         case $d in
1125         radeon)
1126             HAVE_RADEON_DRI=yes;
1127             ;;
1128         r200)
1129             HAVE_R200_DRI=yes;
1130             ;;
1131         esac
1132     done
1133
1134     ;;
1135 esac
1136
1137 case $DRI_DIRS in
1138 *swrast*)
1139     HAVE_SWRAST_DRI=yes;
1140     ;;
1141 esac
1142
1143 dnl
1144 dnl OSMesa configuration
1145 dnl
1146
1147 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1148 AC_ARG_WITH([osmesa-bits],
1149     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1150         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1151     [osmesa_bits="$withval"],
1152     [osmesa_bits=8])
1153 if test "x$osmesa_bits" != x8; then
1154     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1155         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1156         osmesa_bits=8
1157     fi
1158 fi
1159 case "x$osmesa_bits" in
1160 x8)
1161     OSMESA_LIB="${OSMESA_LIB}"
1162     ;;
1163 x16|x32)
1164     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1165     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1166     ;;
1167 *)
1168     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1169     ;;
1170 esac
1171
1172 if test "x$enable_osmesa" = xyes; then
1173     # only link libraries with osmesa if shared
1174     if test "$enable_static" = no; then
1175         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1176     else
1177         OSMESA_LIB_DEPS=""
1178     fi
1179     OSMESA_MESA_DEPS=""
1180     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1181 fi
1182
1183 AC_SUBST([OSMESA_LIB_DEPS])
1184 AC_SUBST([OSMESA_MESA_DEPS])
1185 AC_SUBST([OSMESA_PC_REQ])
1186 AC_SUBST([OSMESA_PC_LIB_PRIV])
1187
1188 dnl
1189 dnl gbm configuration
1190 dnl
1191 if test "x$enable_gbm" = xauto; then
1192     case "$with_egl_platforms" in
1193         *drm*)
1194             enable_gbm=yes ;;
1195          *)
1196             enable_gbm=no ;;
1197     esac
1198 fi
1199 if test "x$enable_gbm" = xyes; then
1200     SRC_DIRS="$SRC_DIRS gbm"
1201
1202     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1203                       AC_MSG_ERROR([gbm needs udev]))
1204
1205     if test "x$enable_dri" = xyes; then
1206         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1207         if test "x$enable_shared_glapi" = xno; then
1208             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1209         fi
1210     fi
1211 fi
1212 GBM_PC_REQ_PRIV="libudev"
1213 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1214 AC_SUBST([GBM_PC_REQ_PRIV])
1215 AC_SUBST([GBM_PC_LIB_PRIV])
1216
1217 dnl
1218 dnl EGL configuration
1219 dnl
1220 EGL_CLIENT_APIS=""
1221
1222 if test "x$enable_egl" = xyes; then
1223     SRC_DIRS="$SRC_DIRS egl"
1224     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1225
1226     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1227
1228     if test "$enable_static" != yes; then
1229         # build egl_glx when libGL is built
1230         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1231                           [have_libudev=yes],[have_libudev=no])
1232         if test "$have_libudev" = yes; then
1233             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1234         fi
1235
1236         if test "x$enable_dri" = xyes; then
1237             HAVE_EGL_DRIVER_DRI2=1
1238         fi
1239
1240     fi
1241 fi
1242 AC_SUBST([EGL_LIB_DEPS])
1243
1244 dnl
1245 dnl EGL Gallium configuration
1246 dnl
1247 if test "x$enable_gallium_egl" = xyes; then
1248     if test "x$with_gallium_drivers" = x; then
1249         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1250     fi
1251     if test "x$enable_egl" = xno; then
1252         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1253     fi
1254     if test "x$have_libdrm" != xyes; then
1255         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1256     fi
1257
1258     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1259     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1260     HAVE_ST_EGL="yes"
1261 fi
1262
1263 dnl
1264 dnl gbm Gallium configuration
1265 dnl
1266 if test "x$enable_gallium_gbm" = xauto; then
1267     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1268         yesyesyes*drm*)
1269             enable_gallium_gbm=yes ;;
1270          *)
1271             enable_gallium_gbm=no ;;
1272     esac
1273 fi
1274 if test "x$enable_gallium_gbm" = xyes; then
1275     if test "x$with_gallium_drivers" = x; then
1276         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1277     fi
1278     if test "x$enable_gbm" = xno; then
1279         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1280     fi
1281     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1282     if test "x$enable_dri" = xno; then
1283         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1284     fi
1285
1286     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1287     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1288     HAVE_ST_GBM="yes"
1289     enable_gallium_loader=yes
1290 fi
1291
1292 dnl
1293 dnl X.Org DDX configuration
1294 dnl
1295 if test "x$enable_xorg" = xyes; then
1296     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1297     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1298     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1299     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1300         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1301         HAVE_XEXTPROTO_71="no")
1302     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1303     HAVE_ST_XORG=yes
1304 fi
1305
1306 dnl
1307 dnl XA configuration
1308 dnl
1309 if test "x$enable_xa" = xyes; then
1310 AC_PROG_AWK
1311 AC_PROG_GREP
1312 AC_CHECK_PROG(NM, nm, "nm")
1313 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1314 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1315 enable_xa=no
1316 fi
1317 fi
1318 if test "x$enable_xa" = xyes; then
1319     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1320     HAVE_ST_XA=yes
1321     AC_SUBST(AWK)
1322     AC_SUBST(GREP)
1323     AC_SUBST(NM)
1324 fi
1325
1326 dnl
1327 dnl OpenVG configuration
1328 dnl
1329 VG_LIB_DEPS=""
1330
1331 if test "x$enable_openvg" = xyes; then
1332     if test "x$enable_egl" = xno; then
1333         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1334     fi
1335     if test "x$with_gallium_drivers" = x; then
1336         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1337     fi
1338     if test "x$enable_gallium_egl" = xno; then
1339         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1340     fi
1341
1342     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1343     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1344     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1345     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1346     HAVE_ST_VEGA=yes
1347     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1348     AC_SUBST([VG_PC_LIB_PRIV])
1349 fi
1350 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1351
1352 dnl
1353 dnl Gallium G3DVL configuration
1354 dnl
1355 AC_ARG_ENABLE([gallium-g3dvl],
1356     [AS_HELP_STRING([--enable-gallium-g3dvl],
1357         [build gallium g3dvl @<:@default=disabled@:>@])],
1358     [enable_gallium_g3dvl="$enableval"],
1359     [enable_gallium_g3dvl=no])
1360 if test "x$enable_gallium_g3dvl" = xyes; then
1361     if test "x$with_gallium_drivers" = x; then
1362         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1363     fi
1364
1365     if test "x$enable_xvmc" = xauto; then
1366         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1367     fi
1368
1369     if test "x$enable_vdpau" = xauto; then
1370         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1371     fi
1372 fi
1373
1374 if test "x$enable_xvmc" = xyes; then
1375     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1376     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1377     HAVE_ST_XVMC="yes"
1378 fi
1379
1380 if test "x$enable_vdpau" = xyes; then
1381     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1382     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1383     HAVE_ST_VDPAU="yes"
1384 fi
1385
1386 dnl
1387 dnl OpenCL configuration
1388 dnl
1389
1390 AC_ARG_WITH([libclc-path],
1391    [AS_HELP_STRING([--with-libclc-path],
1392          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1393    [LIBCLC_PATH="$withval"],
1394    [LIBCLC_PATH=""])
1395
1396 if test "x$LIBCLC_PATH" != x; then
1397    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1398                   Please review the updated build instructions for clover:
1399                   http://dri.freedesktop.org/wiki/GalliumCompute])
1400 fi
1401
1402
1403 AC_ARG_WITH([clang-libdir],
1404    [AS_HELP_STRING([--with-clang-libdir],
1405          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1406    [CLANG_LIBDIR="$withval"],
1407    [CLANG_LIBDIR=""])
1408
1409 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1410 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1411 AC_SUBST([LIBCLC_INCLUDEDIR])
1412 AC_SUBST([LIBCLC_LIBEXECDIR])
1413
1414 if test "x$enable_opencl" = xyes; then
1415     if test "x$with_gallium_drivers" = x; then
1416         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1417     fi
1418
1419     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1420         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1421     fi
1422
1423     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1424         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1425     fi
1426
1427     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1428     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1429     enable_gallium_loader=yes
1430 fi
1431
1432 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1433     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1434 fi
1435
1436 dnl
1437 dnl Gallium configuration
1438 dnl
1439 if test "x$with_gallium_drivers" != x; then
1440     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1441 fi
1442 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1443
1444 AC_SUBST([LLVM_BINDIR])
1445 AC_SUBST([LLVM_CFLAGS])
1446 AC_SUBST([LLVM_CPPFLAGS])
1447 AC_SUBST([LLVM_CXXFLAGS])
1448 AC_SUBST([LLVM_LIBDIR])
1449 AC_SUBST([LLVM_LIBS])
1450 AC_SUBST([LLVM_LDFLAGS])
1451 AC_SUBST([LLVM_INCLUDEDIR])
1452 AC_SUBST([LLVM_VERSION])
1453 AC_SUBST([CLANG_RESOURCE_DIR])
1454
1455 case "x$enable_opengl$enable_gles1$enable_gles2" in
1456 x*yes*)
1457     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1458     HAVE_OPENGL=yes
1459     ;;
1460 esac
1461 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1462
1463 AC_SUBST([VG_LIB_DEPS])
1464 AC_SUBST([EGL_CLIENT_APIS])
1465
1466 dnl
1467 dnl EGL Platforms configuration
1468 dnl
1469 AC_ARG_WITH([egl-platforms],
1470     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1471         [comma delimited native platforms libEGL supports, e.g.
1472         "x11,drm" @<:@default=auto@:>@])],
1473     [with_egl_platforms="$withval"],
1474     [if test "x$enable_egl" = xyes; then
1475         with_egl_platforms="x11"
1476     else
1477         with_egl_platforms=""
1478     fi])
1479
1480 EGL_PLATFORMS=""
1481
1482 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1483     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1484 fi
1485
1486 # Do per-EGL platform setups and checks
1487 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1488 for plat in $egl_platforms; do
1489         case "$plat" in
1490         fbdev|null)
1491                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1492                 ;;
1493
1494         wayland)
1495                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1496                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1497
1498                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1499                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1500                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1501                 ;;
1502
1503         x11)
1504                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1505
1506                 if test "x$enable_glx" = xyes; then
1507                         HAVE_EGL_DRIVER_GLX=1
1508                 fi
1509                 ;;
1510
1511         drm)
1512                 test "x$enable_gbm" = "xno" &&
1513                         AC_MSG_ERROR([EGL platform drm needs gbm])
1514                 ;;
1515
1516         android|gdi)
1517                 ;;
1518
1519         *)
1520                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1521                 ;;
1522         esac
1523
1524         case "$plat$have_libudev" in
1525                 waylandno|drmno)
1526                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1527         esac
1528 done
1529
1530 # libEGL wants to default to the first platform specified in
1531 # ./configure.  parse that here.
1532 if test "x$egl_platforms" != "x"; then
1533     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1534     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1535 else
1536     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1537 fi
1538
1539 EGL_PLATFORMS="$egl_platforms"
1540
1541 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1542 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1543 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1544 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1545 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1546
1547 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1548 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1549
1550 AC_SUBST([EGL_NATIVE_PLATFORM])
1551 AC_SUBST([EGL_PLATFORMS])
1552 AC_SUBST([EGL_CFLAGS])
1553
1554 AC_ARG_WITH([egl-driver-dir],
1555     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1556                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1557     [EGL_DRIVER_INSTALL_DIR="$withval"],
1558     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1559 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1560
1561 AC_ARG_WITH([xorg-driver-dir],
1562     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1563                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1564     [XORG_DRIVER_INSTALL_DIR="$withval"],
1565     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1566 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1567
1568 AC_ARG_WITH([max-width],
1569     [AS_HELP_STRING([--with-max-width=N],
1570                     [Maximum framebuffer width (4096)])],
1571     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1572      AS_IF([test "${withval}" -gt "4096"],
1573            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1574 )
1575 AC_ARG_WITH([max-height],
1576     [AS_HELP_STRING([--with-max-height=N],
1577                     [Maximum framebuffer height (4096)])],
1578     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1579      AS_IF([test "${withval}" -gt "4096"],
1580            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1581 )
1582
1583 dnl
1584 dnl Gallium LLVM
1585 dnl
1586 AC_ARG_ENABLE([gallium-llvm],
1587     [AS_HELP_STRING([--enable-gallium-llvm],
1588         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1589     [enable_gallium_llvm="$enableval"],
1590     [enable_gallium_llvm=auto])
1591
1592 AC_ARG_WITH([llvm-shared-libs],
1593     [AS_HELP_STRING([--with-llvm-shared-libs],
1594         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1595     [],
1596     [with_llvm_shared_libs=no])
1597 AS_IF([test x$enable_opencl = xyes],
1598     [
1599         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1600         with_llvm_shared_libs=yes
1601     ])
1602
1603 AC_ARG_WITH([llvm-prefix],
1604     [AS_HELP_STRING([--with-llvm-prefix],
1605         [Prefix for LLVM installations in non-standard locations])],
1606     [llvm_prefix="$withval"],
1607     [llvm_prefix=""])
1608
1609
1610 # Call this inside ` ` to get the return value.
1611 # $1 is the llvm-config command with arguments.
1612 strip_unwanted_llvm_flags() {
1613     # Use \> (marks the end of the word)
1614     echo `$1` | sed \
1615         -e 's/-DNDEBUG\>//g' \
1616         -e 's/-pedantic\>//g' \
1617         -e 's/-Wcovered-switch-default\>//g' \
1618         -e 's/-O.\>//g' \
1619         -e 's/-g\>//g' \
1620         -e 's/-Wall\>//g' \
1621         -e 's/-fomit-frame-pointer\>//g'
1622 }
1623
1624
1625 if test "x$with_gallium_drivers" = x; then
1626     enable_gallium_llvm=no
1627 fi
1628 if test "x$enable_gallium_llvm" = xauto; then
1629     case "$host_cpu" in
1630     i*86|x86_64) enable_gallium_llvm=yes;;
1631     esac
1632 fi
1633 if test "x$enable_gallium_llvm" = xyes; then
1634     if test "x$llvm_prefix" != x; then
1635         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1636     else
1637         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1638     fi
1639
1640     if test "x$LLVM_CONFIG" != xno; then
1641         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1642         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1643         LLVM_COMPONENTS="engine bitwriter"
1644         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1645             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1646         fi
1647         if $LLVM_CONFIG --components | grep -q '\<oprofilejit\>'; then
1648             LLVM_COMPONENTS="${LLVM_COMPONENTS} oprofilejit"
1649         fi
1650
1651         if test "x$enable_opencl" = xyes; then
1652             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1653         fi
1654         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1655         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1656         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1657         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1658         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1659         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1660         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1661         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1662         MESA_LLVM=1
1663
1664         dnl Check for Clang interanl headers
1665         if test "x$enable_opencl" = xyes; then
1666             if test "x$CLANG_LIBDIR" = x; then
1667                 CLANG_LIBDIR=${LLVM_LIBDIR}
1668             fi
1669             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1670             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1671                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1672         fi
1673     else
1674         MESA_LLVM=0
1675         LLVM_VERSION_INT=0
1676     fi
1677 else
1678     MESA_LLVM=0
1679     LLVM_VERSION_INT=0
1680 fi
1681
1682 dnl Directory for XVMC libs
1683 AC_ARG_WITH([xvmc-libdir],
1684     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1685         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1686     [XVMC_LIB_INSTALL_DIR="$withval"],
1687     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1688 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1689
1690 dnl
1691 dnl Gallium Tests
1692 dnl
1693 if test "x$enable_gallium_tests" = xyes; then
1694     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1695     enable_gallium_loader=yes
1696 fi
1697
1698 dnl Directory for VDPAU libs
1699 AC_ARG_WITH([vdpau-libdir],
1700     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1701         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1702     [VDPAU_LIB_INSTALL_DIR="$withval"],
1703     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1704 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1705
1706 dnl Directory for OpenCL libs
1707 AC_ARG_WITH([opencl-libdir],
1708     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1709         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1710     [OPENCL_LIB_INSTALL_DIR="$withval"],
1711     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1712 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1713
1714 dnl
1715 dnl Gallium helper functions
1716 dnl
1717 gallium_check_st() {
1718     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1719          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1720          test "x$HAVE_ST_VDPAU" = xyes; then
1721          if test "x$have_libdrm" != xyes; then
1722             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1723          fi
1724          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1725     fi
1726     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1727          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1728          HAVE_COMMON_DRI=yes
1729     fi
1730     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1731          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1732     fi
1733     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1734          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1735     fi
1736     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1737          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1738     fi
1739     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1740          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1741     fi
1742 }
1743
1744 gallium_require_llvm() {
1745     if test "x$MESA_LLVM" = x0; then
1746         case "$host_cpu" in
1747         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1748         esac
1749     fi
1750 }
1751
1752 gallium_require_drm_loader() {
1753     if test "x$enable_gallium_loader" = xyes; then
1754         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1755                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1756         if test "x$have_libdrm" != xyes; then
1757             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1758         fi
1759         enable_gallium_drm_loader=yes
1760     fi
1761 }
1762
1763 radeon_llvm_check() {
1764     LLVM_REQUIRED_VERSION_MAJOR="3"
1765     LLVM_REQUIRED_VERSION_MINOR="2"
1766     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1767         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1768                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1769                      git://people.freedesktop.org/~tstellar/llvm master
1770                      and build with --enable-experimental-targets=R600])
1771     fi
1772     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1773         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1774                       sources with the --enable-experimental-targets=R600
1775                       configure flag])
1776     fi
1777     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1778     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader"
1779 }
1780
1781 dnl Gallium drivers
1782 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1783 if test "x$with_gallium_drivers" != x; then
1784     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1785     for driver in $gallium_drivers; do
1786         case "x$driver" in
1787         xsvga)
1788             HAVE_GALLIUM_SVGA=yes
1789             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1790             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1791             ;;
1792         xi915)
1793             HAVE_GALLIUM_I915=yes
1794             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1795             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1796             if test "x$MESA_LLVM" = x1; then
1797                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1798             fi
1799             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1800             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1801             ;;
1802         xr300)
1803             HAVE_GALLIUM_R300=yes
1804             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1805             gallium_require_llvm "Gallium R300"
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1807             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1808             ;;
1809         xr600)
1810             HAVE_GALLIUM_R600=yes
1811             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1812             gallium_require_drm_loader
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1814             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1815                 radeon_llvm_check
1816                 NEED_RADEON_GALLIUM=yes;
1817                 R600_NEED_RADEON_GALLIUM=yes;
1818                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1819             fi
1820             if test "x$enable_r600_llvm" = xyes; then
1821                 USE_R600_LLVM_COMPILER=yes;
1822             fi
1823             if test "x$enable_opencl" = xyes; then
1824                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1825             fi
1826             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1827             ;;
1828         xradeonsi)
1829             HAVE_GALLIUM_RADEONSI=yes
1830             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1831             gallium_require_drm_loader
1832             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1833             radeon_llvm_check
1834             NEED_RADEON_GALLIUM=yes;
1835             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1836             ;;
1837         xnouveau)
1838             HAVE_GALLIUM_NOUVEAU=yes
1839             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1840             gallium_require_drm_loader
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1842             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1843             ;;
1844         xfreedreno)
1845             HAVE_GALLIUM_FREEDRENO=yes
1846             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1847             gallium_require_drm_loader
1848             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1849             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1850             ;;
1851         xswrast)
1852             HAVE_GALLIUM_SOFTPIPE=yes
1853             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1854             if test "x$MESA_LLVM" = x1; then
1855                 HAVE_GALLIUM_LLVMPIPE=yes
1856                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1857             fi
1858
1859             if test "x$HAVE_ST_DRI" = xyes; then
1860                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1861             fi
1862             if test "x$HAVE_ST_VDPAU" = xyes; then
1863                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1864             fi
1865             if test "x$HAVE_ST_XVMC" = xyes; then
1866                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1867             fi
1868             if test "x$HAVE_ST_VDPAU" = xyes ||
1869                test "x$HAVE_ST_XVMC" = xyes; then
1870                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1871                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1872                fi
1873             fi
1874             ;;
1875         *)
1876             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1877             ;;
1878         esac
1879     done
1880 fi
1881
1882 dnl Set LLVM_LIBS - This is done after the driver configuration so
1883 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1884 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1885 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1886 dnl this was causing the same libraries to be appear multiple times
1887 dnl in LLVM_LIBS.
1888
1889 if test "x$MESA_LLVM" != x0; then
1890
1891     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1892
1893     if test "x$with_llvm_shared_libs" = xyes; then
1894         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1895         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1896         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1897
1898         if test "x$llvm_have_one_so" = xyes; then
1899             dnl LLVM was built using auto*, so there is only one shared object.
1900             LLVM_LIBS="-l$LLVM_SO_NAME"
1901         else
1902             dnl If LLVM was built with CMake, there will be one shared object per
1903             dnl component.
1904             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1905                     AC_MSG_ERROR([Could not find llvm shared libraries:
1906         Please make sure you have built llvm with the --enable-shared option
1907         and that your llvm libraries are installed in $LLVM_LIBDIR
1908         If you have installed your llvm libraries to a different directory you
1909         can use the --with-llvm-prefix= configure flag to specify this directory.
1910         NOTE: Mesa is attempting to use llvm shared libraries because you have
1911         passed one of the following options to configure:
1912                 --with-llvm-shared-libs
1913                 --enable-opencl
1914         If you do not want to build with llvm shared libraries and instead want to
1915         use llvm static libraries then remove these options from your configure
1916         invocation and reconfigure.]))
1917
1918            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1919            dnl install uses a shared object for each compoenent and we have
1920            dnl already added all of these objects to LLVM_LIBS.
1921         fi
1922     fi
1923 fi
1924
1925 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1926 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1927 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1928 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1929 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1930 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1931 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1932 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1933 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1934
1935 if test "x$enable_gallium_loader" = xyes; then
1936     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1937     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1938     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1939     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1940
1941     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1942         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1943         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1944     fi
1945
1946     if test "x$enable_gallium_drm_loader" = xyes; then
1947         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1948         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1949                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1950         if test "x$pipe_loader_have_xcb" = xyes; then
1951             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1952             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1953         fi
1954     fi
1955
1956     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1957     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1958 fi
1959
1960 dnl Tell Automake which drivers to build
1961 for driver in $GALLIUM_DRIVERS_DIRS; do
1962     case "x$driver" in
1963         xgalahad)
1964             HAVE_GALAHAD_GALLIUM=yes;
1965             ;;
1966         xidentity)
1967             HAVE_IDENTITY_GALLIUM=yes;
1968             ;;
1969         xnoop)
1970             HAVE_NOOP_GALLIUM=yes;
1971             ;;
1972         *)
1973             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1974             ;;
1975     esac
1976 done
1977
1978 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1979 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1980 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1981 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1982 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1983 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1984 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1985
1986 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1987 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1988 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1989 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1990 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
1991 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1992 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1993 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1994 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1995 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1996 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1997
1998 AC_SUBST([GALLIUM_MAKE_DIRS])
1999
2000 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
2001                                      "x$enable_xlib_glx" = xyes -o \
2002                                      "x$enable_osmesa" = xyes)
2003 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2004
2005 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2006 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2007 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2008
2009 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
2010
2011 AC_SUBST([VDPAU_MAJOR], 1)
2012 AC_SUBST([VDPAU_MINOR], 0)
2013
2014 AC_SUBST([XVMC_MAJOR], 1)
2015 AC_SUBST([XVMC_MINOR], 0)
2016
2017 AC_SUBST([XA_MAJOR], 1)
2018 AC_SUBST([XA_MINOR], 0)
2019 AC_SUBST([XA_TINY], 0)
2020 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2021
2022 dnl prepend CORE_DIRS to SRC_DIRS
2023 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2024
2025 dnl Restore LDFLAGS and CPPFLAGS
2026 LDFLAGS="$_SAVE_LDFLAGS"
2027 CPPFLAGS="$_SAVE_CPPFLAGS"
2028
2029 dnl Add user CFLAGS and CXXFLAGS
2030 CFLAGS="$CFLAGS $USER_CFLAGS"
2031 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2032
2033 dnl Substitute the config
2034 AC_CONFIG_FILES([Makefile
2035                 src/Makefile
2036                 src/egl/Makefile
2037                 src/egl/drivers/Makefile
2038                 src/egl/drivers/dri2/Makefile
2039                 src/egl/drivers/glx/Makefile
2040                 src/egl/main/Makefile
2041                 src/egl/main/egl.pc
2042                 src/egl/wayland/Makefile
2043                 src/egl/wayland/wayland-drm/Makefile
2044                 src/egl/wayland/wayland-egl/Makefile
2045                 src/egl/wayland/wayland-egl/wayland-egl.pc
2046                 src/gallium/Makefile
2047                 src/gallium/auxiliary/Makefile
2048                 src/gallium/auxiliary/pipe-loader/Makefile
2049                 src/gallium/drivers/Makefile
2050                 src/gallium/drivers/freedreno/Makefile
2051                 src/gallium/drivers/i915/Makefile
2052                 src/gallium/drivers/llvmpipe/Makefile
2053                 src/gallium/drivers/nouveau/Makefile
2054                 src/gallium/drivers/nv30/Makefile
2055                 src/gallium/drivers/nv50/Makefile
2056                 src/gallium/drivers/nvc0/Makefile
2057                 src/gallium/drivers/r300/Makefile
2058                 src/gallium/drivers/r600/Makefile
2059                 src/gallium/drivers/radeon/Makefile
2060                 src/gallium/drivers/radeonsi/Makefile
2061                 src/gallium/drivers/rbug/Makefile
2062                 src/gallium/drivers/softpipe/Makefile
2063                 src/gallium/drivers/svga/Makefile
2064                 src/gallium/drivers/trace/Makefile
2065                 src/gallium/state_trackers/Makefile
2066                 src/gallium/state_trackers/clover/Makefile
2067                 src/gallium/state_trackers/dri/Makefile
2068                 src/gallium/state_trackers/dri/drm/Makefile
2069                 src/gallium/state_trackers/dri/sw/Makefile
2070                 src/gallium/state_trackers/egl/Makefile
2071                 src/gallium/state_trackers/gbm/Makefile
2072                 src/gallium/state_trackers/glx/Makefile
2073                 src/gallium/state_trackers/osmesa/Makefile
2074                 src/gallium/state_trackers/vdpau/Makefile
2075                 src/gallium/state_trackers/vega/Makefile
2076                 src/gallium/state_trackers/xa/Makefile
2077                 src/gallium/state_trackers/xorg/Makefile
2078                 src/gallium/state_trackers/xvmc/Makefile
2079                 src/gallium/targets/Makefile
2080                 src/gallium/targets/dri-freedreno/Makefile
2081                 src/gallium/targets/dri-i915/Makefile
2082                 src/gallium/targets/dri-nouveau/Makefile
2083                 src/gallium/targets/dri-r300/Makefile
2084                 src/gallium/targets/dri-r600/Makefile
2085                 src/gallium/targets/dri-radeonsi/Makefile
2086                 src/gallium/targets/dri-swrast/Makefile
2087                 src/gallium/targets/dri-vmwgfx/Makefile
2088                 src/gallium/targets/egl-static/Makefile
2089                 src/gallium/targets/gbm/Makefile
2090                 src/gallium/targets/opencl/Makefile
2091                 src/gallium/targets/osmesa/Makefile
2092                 src/gallium/targets/pipe-loader/Makefile
2093                 src/gallium/targets/libgl-xlib/Makefile
2094                 src/gallium/targets/vdpau-nouveau/Makefile
2095                 src/gallium/targets/vdpau-r300/Makefile
2096                 src/gallium/targets/vdpau-r600/Makefile
2097                 src/gallium/targets/vdpau-radeonsi/Makefile
2098                 src/gallium/targets/vdpau-softpipe/Makefile
2099                 src/gallium/targets/xa-vmwgfx/Makefile
2100                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2101                 src/gallium/targets/xorg-i915/Makefile
2102                 src/gallium/targets/xorg-nouveau/Makefile
2103                 src/gallium/targets/xorg-r600/Makefile
2104                 src/gallium/targets/xorg-radeonsi/Makefile
2105                 src/gallium/targets/xvmc-nouveau/Makefile
2106                 src/gallium/targets/xvmc-r300/Makefile
2107                 src/gallium/targets/xvmc-r600/Makefile
2108                 src/gallium/targets/xvmc-softpipe/Makefile
2109                 src/gallium/tests/trivial/Makefile
2110                 src/gallium/tests/unit/Makefile
2111                 src/gallium/winsys/Makefile
2112                 src/gallium/winsys/freedreno/drm/Makefile
2113                 src/gallium/winsys/i915/drm/Makefile
2114                 src/gallium/winsys/i915/sw/Makefile
2115                 src/gallium/winsys/nouveau/drm/Makefile
2116                 src/gallium/winsys/radeon/drm/Makefile
2117                 src/gallium/winsys/svga/drm/Makefile
2118                 src/gallium/winsys/sw/Makefile
2119                 src/gallium/winsys/sw/dri/Makefile
2120                 src/gallium/winsys/sw/fbdev/Makefile
2121                 src/gallium/winsys/sw/null/Makefile
2122                 src/gallium/winsys/sw/wayland/Makefile
2123                 src/gallium/winsys/sw/wrapper/Makefile
2124                 src/gallium/winsys/sw/xlib/Makefile
2125                 src/gbm/Makefile
2126                 src/gbm/main/gbm.pc
2127                 src/glsl/Makefile
2128                 src/glsl/builtin_compiler/Makefile
2129                 src/glx/Makefile
2130                 src/glx/tests/Makefile
2131                 src/gtest/Makefile
2132                 src/mapi/es1api/Makefile
2133                 src/mapi/es1api/glesv1_cm.pc
2134                 src/mapi/es2api/Makefile
2135                 src/mapi/es2api/glesv2.pc
2136                 src/mapi/glapi/Makefile
2137                 src/mapi/glapi/gen/Makefile
2138                 src/mapi/glapi/tests/Makefile
2139                 src/mapi/shared-glapi/Makefile
2140                 src/mapi/shared-glapi/tests/Makefile
2141                 src/mapi/vgapi/Makefile
2142                 src/mapi/vgapi/vg.pc
2143                 src/mesa/Makefile
2144                 src/mesa/gl.pc
2145                 src/mesa/drivers/Makefile
2146                 src/mesa/drivers/dri/dri.pc
2147                 src/mesa/drivers/dri/common/Makefile
2148                 src/mesa/drivers/dri/common/xmlpool/Makefile
2149                 src/mesa/drivers/dri/i915/Makefile
2150                 src/mesa/drivers/dri/i965/Makefile
2151                 src/mesa/drivers/dri/Makefile
2152                 src/mesa/drivers/dri/nouveau/Makefile
2153                 src/mesa/drivers/dri/r200/Makefile
2154                 src/mesa/drivers/dri/radeon/Makefile
2155                 src/mesa/drivers/dri/swrast/Makefile
2156                 src/mesa/drivers/osmesa/Makefile
2157                 src/mesa/drivers/osmesa/osmesa.pc
2158                 src/mesa/drivers/x11/Makefile
2159                 src/mesa/libdricore/Makefile
2160                 src/mesa/main/tests/Makefile
2161                 src/mesa/main/tests/hash_table/Makefile
2162                 src/mesa/program/Makefile
2163                 src/mesa/x86-64/Makefile
2164                 src/mesa/x86/Makefile])
2165
2166 dnl Sort the dirs alphabetically
2167 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2168 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2169 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2170 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2171 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2172
2173 AC_OUTPUT
2174
2175 dnl
2176 dnl Output some configuration info for the user
2177 dnl
2178 echo ""
2179 echo "        prefix:          $prefix"
2180 echo "        exec_prefix:     $exec_prefix"
2181 echo "        libdir:          $libdir"
2182 echo "        includedir:      $includedir"
2183
2184 dnl API info
2185 echo ""
2186 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2187 echo "        OpenVG:          $enable_openvg"
2188
2189 dnl Driver info
2190 echo ""
2191 if test "x$enable_osmesa" != xno; then
2192         echo "        OSMesa:          lib$OSMESA_LIB"
2193 else
2194         echo "        OSMesa:          no"
2195 fi
2196
2197 if test "x$enable_dri" != xno; then
2198         # cleanup the drivers var
2199         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2200         if test "x$DRI_DIRS" = x; then
2201             echo "        DRI drivers:     no"
2202         else
2203             echo "        DRI drivers:     $dri_dirs"
2204         fi
2205         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2206 fi
2207
2208 case "x$enable_glx$enable_xlib_glx" in
2209 xyesyes)
2210     echo "        GLX:             Xlib-based"
2211     ;;
2212 xyesno)
2213     echo "        GLX:             DRI-based"
2214     ;;
2215 *)
2216     echo "        GLX:             $enable_glx"
2217     ;;
2218 esac
2219
2220 dnl EGL
2221 echo ""
2222 echo "        EGL:             $enable_egl"
2223 if test "$enable_egl" = yes; then
2224     echo "        EGL platforms:   $EGL_PLATFORMS"
2225
2226     egl_drivers=""
2227     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2228         egl_drivers="$egl_drivers builtin:egl_glx"
2229     fi
2230     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2231         egl_drivers="$egl_drivers builtin:egl_dri2"
2232     fi
2233
2234     if test "x$HAVE_ST_EGL" = xyes; then
2235         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2236         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2237     else
2238         echo "        EGL drivers:    $egl_drivers"
2239     fi
2240 fi
2241
2242 echo ""
2243 if test "x$MESA_LLVM" = x1; then
2244     echo "        llvm:            yes"
2245     echo "        llvm-config:     $LLVM_CONFIG"
2246     echo "        llvm-version:    $LLVM_VERSION"
2247 else
2248     echo "        llvm:            no"
2249 fi
2250
2251 echo ""
2252 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2253     echo "        Gallium:         yes"
2254     echo "        Gallium dirs:    $GALLIUM_DIRS"
2255     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2256     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2257     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2258     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2259 else
2260     echo "        Gallium:         no"
2261 fi
2262
2263
2264 dnl Libraries
2265 echo ""
2266 echo "        Shared libs:     $enable_shared"
2267 echo "        Static libs:     $enable_static"
2268 echo "        Shared-glapi:    $enable_shared_glapi"
2269
2270 dnl Compiler options
2271 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2272 cflags=`echo $CFLAGS | \
2273     $SED 's/^ *//;s/  */ /;s/ *$//'`
2274 cxxflags=`echo $CXXFLAGS | \
2275     $SED 's/^ *//;s/  */ /;s/ *$//'`
2276 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2277 echo ""
2278 echo "        CFLAGS:          $cflags"
2279 echo "        CXXFLAGS:        $cxxflags"
2280 echo "        Macros:          $defines"
2281 echo ""
2282 if test "x$MESA_LLVM" = x1; then
2283     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2284     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2285     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2286     echo ""
2287 fi
2288 echo "        PYTHON2:         $PYTHON2"
2289
2290 echo ""
2291 echo "        Run '${MAKE-make}' to build Mesa"
2292 echo ""