configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 827 dnl is not valid for that platform.
 828 if test "x$android" = xno; then
 829     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 830 fi
 831
 832 dnl pthread-stubs is mandatory on targets where it exists
 833 case "$host_os" in
 834 cygwin* )
 835     pthread_stubs_possible="no"
 836     ;;
 837 * )
 838     pthread_stubs_possible="yes"
 839     ;;
 840 esac
 841
 842 if test "x$pthread_stubs_possible" = xyes; then
 843     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 844     AC_SUBST(PTHREADSTUBS_CFLAGS)
 845     AC_SUBST(PTHREADSTUBS_LIBS)
 846 fi
 847
 848 dnl SELinux awareness.
 849 AC_ARG_ENABLE([selinux],
 850     [AS_HELP_STRING([--enable-selinux],
 851         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 852     [MESA_SELINUX="$enableval"],
 853     [MESA_SELINUX=no])
 854 if test "x$enable_selinux" = "xyes"; then
 855     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 856         [AC_CHECK_HEADER([selinux/selinux.h],[],
 857                          [AC_MSG_ERROR([SELinux headers not found])])
 858          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 859                       [AC_MSG_ERROR([SELinux library not found])])
 860          SELINUX_LIBS="-lselinux"])
 861     DEFINES="$DEFINES -DMESA_SELINUX"
 862 fi
 863 AC_SUBST([SELINUX_CFLAGS])
 864 AC_SUBST([SELINUX_LIBS])
 865
 866 dnl
 867 dnl LLVM
 868 dnl
 869 llvm_add_component() {
 870     new_llvm_component=$1
 871     driver_name=$2
 872
 873     LLVM_COMPONENTS="$LLVM_COMPONENTS $new_llvm_component"
 874 }
 875
 876 llvm_add_default_components() {
 877     driver_name=$1
 878
 879     # Required default components
 880     llvm_add_component "bitwriter" $driver_name
 881     llvm_add_component "engine" $driver_name
 882     llvm_add_component "mcdisassembler" $driver_name
 883     llvm_add_component "mcjit" $driver_name
 884
 885     # Optional default components
 886     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 887         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 888     fi
 889 }
 890
 891 llvm_add_target() {
 892     new_llvm_target=$1
 893     driver_name=$2
 894
 895     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 896         llvm_add_component $new_llvm_target $driver_name
 897     else
 898         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 899     fi
 900 }
 901
 902 dnl Options for APIs
 903 AC_ARG_ENABLE([opengl],
 904     [AS_HELP_STRING([--disable-opengl],
 905         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 906     [enable_opengl="$enableval"],
 907     [enable_opengl=yes])
 908 AC_ARG_ENABLE([gles1],
 909     [AS_HELP_STRING([--disable-gles1],
 910         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 911     [enable_gles1="$enableval"],
 912     [enable_gles1=yes])
 913 AC_ARG_ENABLE([gles2],
 914     [AS_HELP_STRING([--disable-gles2],
 915         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 916     [enable_gles2="$enableval"],
 917     [enable_gles2=yes])
 918
 919 AC_ARG_ENABLE([dri],
 920     [AS_HELP_STRING([--enable-dri],
 921         [enable DRI modules @<:@default=enabled@:>@])],
 922     [enable_dri="$enableval"],
 923     [enable_dri=yes])
 924
 925 AC_ARG_ENABLE([gallium-extra-hud],
 926     [AS_HELP_STRING([--enable-gallium-extra-hud],
 927         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 928     [enable_gallium_extra_hud="$enableval"],
 929     [enable_gallium_extra_hud=no])
 930 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 931 if test "x$enable_gallium_extra_hud" = xyes ; then
 932     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 933 fi
 934
 935 #TODO: no pkgconfig .pc available for libsensors.
 936 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 937 AC_ARG_ENABLE([lmsensors],
 938     [AS_HELP_STRING([--enable-lmsensors],
 939         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 940     [enable_lmsensors="$enableval"],
 941     [enable_lmsensors=no])
 942 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 943 if test "x$enable_lmsensors" = xyes ; then
 944     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 945     LIBSENSORS_LDFLAGS="-lsensors"
 946 else
 947     LIBSENSORS_LDFLAGS=""
 948 fi
 949 AC_SUBST(LIBSENSORS_LDFLAGS)
 950
 951 case "$host_os" in
 952 linux*)
 953     dri3_default=yes
 954     ;;
 955 *)
 956     dri3_default=no
 957     ;;
 958 esac
 959
 960 if test "x$enable_dri" = xno; then
 961     dri3_default=no
 962 fi
 963
 964 AC_ARG_ENABLE([dri3],
 965     [AS_HELP_STRING([--enable-dri3],
 966         [enable DRI3 @<:@default=auto@:>@])],
 967     [enable_dri3="$enableval"],
 968     [enable_dri3="$dri3_default"])
 969 AC_ARG_ENABLE([glx],
 970     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 971         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 972     [enable_glx="$enableval"],
 973     [enable_glx=yes])
 974 AC_ARG_ENABLE([osmesa],
 975     [AS_HELP_STRING([--enable-osmesa],
 976         [enable OSMesa library @<:@default=disabled@:>@])],
 977     [enable_osmesa="$enableval"],
 978     [enable_osmesa=no])
 979 AC_ARG_ENABLE([gallium-osmesa],
 980     [AS_HELP_STRING([--enable-gallium-osmesa],
 981         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 982     [enable_gallium_osmesa="$enableval"],
 983     [enable_gallium_osmesa=no])
 984 AC_ARG_ENABLE([egl],
 985     [AS_HELP_STRING([--disable-egl],
 986         [disable EGL library @<:@default=enabled@:>@])],
 987     [enable_egl="$enableval"],
 988     [enable_egl=yes])
 989
 990 AC_ARG_ENABLE([xa],
 991     [AS_HELP_STRING([--enable-xa],
 992         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 993     [enable_xa="$enableval"],
 994     [enable_xa=no])
 995 AC_ARG_ENABLE([gbm],
 996    [AS_HELP_STRING([--enable-gbm],
 997          [enable gbm library @<:@default=yes except cygwin@:>@])],
 998    [enable_gbm="$enableval"],
 999    [case "$host_os" in
1000        cygwin*)
1001           enable_gbm=no
1002           ;;
1003        *)
1004           enable_gbm=yes
1005           ;;
1006     esac])
1007 AC_ARG_ENABLE([nine],
1008     [AS_HELP_STRING([--enable-nine],
1009         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1010     [enable_nine="$enableval"],
1011     [enable_nine=no])
1012
1013 AC_ARG_ENABLE([xvmc],
1014    [AS_HELP_STRING([--enable-xvmc],
1015          [enable xvmc library @<:@default=auto@:>@])],
1016    [enable_xvmc="$enableval"],
1017    [enable_xvmc=auto])
1018 AC_ARG_ENABLE([vdpau],
1019    [AS_HELP_STRING([--enable-vdpau],
1020          [enable vdpau library @<:@default=auto@:>@])],
1021    [enable_vdpau="$enableval"],
1022    [enable_vdpau=auto])
1023 AC_ARG_ENABLE([omx],
1024    [AS_HELP_STRING([--enable-omx],
1025          [enable OpenMAX library @<:@default=disabled@:>@])],
1026    [enable_omx="$enableval"],
1027    [enable_omx=no])
1028 AC_ARG_ENABLE([va],
1029    [AS_HELP_STRING([--enable-va],
1030          [enable va library @<:@default=auto@:>@])],
1031    [enable_va="$enableval"],
1032    [enable_va=auto])
1033 AC_ARG_ENABLE([opencl],
1034    [AS_HELP_STRING([--enable-opencl],
1035          [enable OpenCL library @<:@default=disabled@:>@])],
1036    [enable_opencl="$enableval"],
1037    [enable_opencl=no])
1038 AC_ARG_ENABLE([opencl_icd],
1039    [AS_HELP_STRING([--enable-opencl-icd],
1040           [Build an OpenCL ICD library to be loaded by an ICD implementation
1041            @<:@default=disabled@:>@])],
1042     [enable_opencl_icd="$enableval"],
1043     [enable_opencl_icd=no])
1044
1045 AC_ARG_ENABLE([gallium-tests],
1046     [AS_HELP_STRING([--enable-gallium-tests],
1047         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1048     [enable_gallium_tests="$enableval"],
1049     [enable_gallium_tests=no])
1050
1051 # Option for Gallium drivers
1052
1053 # Keep this in sync with the --with-gallium-drivers help string default value
1054 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1055
1056 AC_ARG_WITH([gallium-drivers],
1057     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1058         [comma delimited Gallium drivers list, e.g.
1059         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1060         @<:@default=r300,r600,svga,swrast@:>@])],
1061     [with_gallium_drivers="$withval"],
1062     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1063
1064 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1065 # here so that the script doesn't choke on an unknown driver name later.
1066 case "$with_gallium_drivers" in
1067     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1068     no) with_gallium_drivers='' ;;
1069 esac
1070
1071 if test "x$enable_opengl" = xno -a \
1072         "x$enable_gles1" = xno -a \
1073         "x$enable_gles2" = xno -a \
1074         "x$enable_nine" = xno -a \
1075         "x$enable_xa" = xno -a \
1076         "x$enable_xvmc" = xno -a \
1077         "x$enable_vdpau" = xno -a \
1078         "x$enable_omx" = xno -a \
1079         "x$enable_va" = xno -a \
1080         "x$enable_opencl" = xno; then
1081     AC_MSG_ERROR([at least one API should be enabled])
1082 fi
1083
1084 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1085 if test "x$enable_opengl" = xno -a \
1086         "x$enable_gles1" = xyes; then
1087     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1088 fi
1089
1090 if test "x$enable_opengl" = xno -a \
1091         "x$enable_gles2" = xyes; then
1092     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1093 fi
1094
1095 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1096 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1097 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1098 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1099                                         "x$enable_gles1" = xyes -o \
1100                                         "x$enable_gles2" = xyes)
1101
1102 # Validate GLX options
1103 if test "x$enable_glx" = xyes; then
1104     if test "x$enable_dri" = xyes; then
1105         enable_glx=dri
1106     elif test -n "$with_gallium_drivers"; then
1107         enable_glx=gallium-xlib
1108     else
1109         enable_glx=xlib
1110     fi
1111 fi
1112 case "x$enable_glx" in
1113 xdri | xxlib | xgallium-xlib)
1114     # GLX requires OpenGL
1115     if test "x$enable_opengl" = xno; then
1116         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1117     fi
1118
1119     # Check individual dependencies
1120     case "x$enable_glx" in
1121     xdri)
1122         if test "x$enable_dri" = xno; then
1123             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1124         fi
1125         ;;
1126     xxlib)
1127         if test "x$enable_dri" = xyes; then
1128             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1129         fi
1130         ;;
1131     xgallium-xlib )
1132         if test "x$enable_dri" = xyes; then
1133             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1134         fi
1135         if test -z "$with_gallium_drivers"; then
1136             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1137         fi
1138         ;;
1139     esac
1140     ;;
1141 xno)
1142     ;;
1143 *)
1144     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1145     ;;
1146 esac
1147
1148 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1149 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1150 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1151 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1152
1153 dnl
1154 dnl Libglvnd configuration
1155 dnl
1156 AC_ARG_ENABLE([libglvnd],
1157     [AS_HELP_STRING([--enable-libglvnd],
1158         [Build for libglvnd @<:@default=disabled@:>@])],
1159     [enable_libglvnd="$enableval"],
1160     [enable_libglvnd=no])
1161 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1162 if test "x$enable_libglvnd" = xyes ; then
1163     dnl XXX: update once we can handle more than libGL/glx.
1164     dnl Namely: we should error out if neither of the glvnd enabled libraries
1165     dnl are built
1166     case "x$enable_glx" in
1167     xno)
1168         AC_MSG_ERROR([cannot build libglvnd without GLX])
1169         ;;
1170     xxlib | xgallium-xlib )
1171         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1172         ;;
1173     xdri)
1174         ;;
1175     esac
1176
1177     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1178     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1179     DEFAULT_GL_LIB_NAME=GLX_mesa
1180 fi
1181
1182 # Check for libdrm
1183 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1184                   [have_libdrm=yes], [have_libdrm=no])
1185 if test "x$have_libdrm" = xyes; then
1186         DEFINES="$DEFINES -DHAVE_LIBDRM"
1187 fi
1188
1189 require_libdrm() {
1190     if test "x$have_libdrm" != xyes; then
1191        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1192     fi
1193 }
1194
1195
1196 # Select which platform-dependent DRI code gets built
1197 case "$host_os" in
1198 darwin*)
1199     dri_platform='apple' ;;
1200 cygwin*)
1201     dri_platform='windows' ;;
1202 gnu*)
1203     dri_platform='none' ;;
1204 *)
1205     dri_platform='drm' ;;
1206 esac
1207
1208 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1209     have_drisw_kms='yes'
1210 fi
1211
1212 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1213 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1214 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1215 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1216 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1217 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1218 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1219 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1220 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1221
1222 AC_ARG_ENABLE([shared-glapi],
1223     [AS_HELP_STRING([--enable-shared-glapi],
1224         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1225     [enable_shared_glapi="$enableval"],
1226     [enable_shared_glapi=yes])
1227
1228 case "x$enable_opengl$enable_gles1$enable_gles2" in
1229 x*yes*yes*)
1230     if test "x$enable_shared_glapi" = xno; then
1231         AC_MSG_ERROR([shared GLAPI required when building two or more of
1232                       the following APIs - opengl, gles1 gles2])
1233     fi
1234     ;;
1235 esac
1236
1237 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1238
1239 # Build the pipe-drivers as separate libraries/modules.
1240 # Do not touch this unless you know what you are doing.
1241 # XXX: Expose via configure option ?
1242 enable_shared_pipe_drivers=no
1243
1244 dnl
1245 dnl Driver specific build directories
1246 dnl
1247
1248 if test "x$enable_gallium_osmesa" = xyes; then
1249     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1250         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1251     fi
1252     if test "x$enable_osmesa" = xyes; then
1253         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1254     fi
1255 fi
1256
1257 AC_SUBST([MESA_LLVM])
1258
1259 # SHA1 hashing
1260 AC_ARG_WITH([sha1],
1261         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1262         [choose SHA1 implementation])])
1263 case "x$with_sha1" in
1264 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1265   ;;
1266 *)
1267         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1268 esac
1269
1270 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1271 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1272         with_sha1=libc
1273 fi
1274 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1275         AC_MSG_ERROR([sha1 in libc requested but not found])
1276 fi
1277 if test "x$with_sha1" = xlibc; then
1278         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1279                 [Use libc SHA1 functions])
1280         SHA1_LIBS=""
1281 fi
1282 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1283 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1284         with_sha1=CommonCrypto
1285 fi
1286 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1287         AC_MSG_ERROR([CommonCrypto requested but not found])
1288 fi
1289 if test "x$with_sha1" = xCommonCrypto; then
1290         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1291                 [Use CommonCrypto SHA1 functions])
1292         SHA1_LIBS=""
1293 fi
1294 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1295 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1296 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1297         with_sha1=CryptoAPI
1298 fi
1299 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1300         AC_MSG_ERROR([CryptoAPI requested but not found])
1301 fi
1302 if test "x$with_sha1" = xCryptoAPI; then
1303         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1304                 [Use CryptoAPI SHA1 functions])
1305         SHA1_LIBS=""
1306 fi
1307 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1308 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1309         with_sha1=libmd
1310 fi
1311 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1312         AC_MSG_ERROR([libmd requested but not found])
1313 fi
1314 if test "x$with_sha1" = xlibmd; then
1315         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1316                   [Use libmd SHA1 functions])
1317         SHA1_LIBS=-lmd
1318 fi
1319 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1320 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1321    with_sha1=libsha1
1322 fi
1323 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1324         AC_MSG_ERROR([libsha1 requested but not found])
1325 fi
1326 if test "x$with_sha1" = xlibsha1; then
1327         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1328                   [Use libsha1 for SHA1])
1329         SHA1_LIBS=-lsha1
1330 fi
1331 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1332 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1333         with_sha1=libnettle
1334 fi
1335 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1336         AC_MSG_ERROR([libnettle requested but not found])
1337 fi
1338 if test "x$with_sha1" = xlibnettle; then
1339         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1340                   [Use libnettle SHA1 functions])
1341         SHA1_LIBS=-lnettle
1342 fi
1343 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1344 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1345         with_sha1=libgcrypt
1346 fi
1347 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1348         AC_MSG_ERROR([libgcrypt requested but not found])
1349 fi
1350 if test "x$with_sha1" = xlibgcrypt; then
1351         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1352                   [Use libgcrypt SHA1 functions])
1353         SHA1_LIBS=-lgcrypt
1354 fi
1355 # We don't need all of the OpenSSL libraries, just libcrypto
1356 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1357 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1358                   [HAVE_OPENSSL_PKC=no])
1359 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1360         if test "x$with_sha1" = x; then
1361                 with_sha1=libcrypto
1362         fi
1363 else
1364         if test "x$with_sha1" = xlibcrypto; then
1365                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1366         fi
1367 fi
1368 if test "x$with_sha1" = xlibcrypto; then
1369         if test "x$HAVE_LIBCRYPTO" = xyes; then
1370                 SHA1_LIBS=-lcrypto
1371         else
1372                 SHA1_LIBS="$OPENSSL_LIBS"
1373                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1374         fi
1375 fi
1376 AC_MSG_CHECKING([for SHA1 implementation])
1377 AC_MSG_RESULT([$with_sha1])
1378 AC_SUBST(SHA1_LIBS)
1379 AC_SUBST(SHA1_CFLAGS)
1380
1381 # Enable a define for SHA1
1382 if test "x$with_sha1" != "x"; then
1383         DEFINES="$DEFINES -DHAVE_SHA1"
1384 fi
1385
1386 # Allow user to configure out the shader-cache feature
1387 AC_ARG_ENABLE([shader-cache],
1388     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1389     [enable_shader_cache="$enableval"],
1390     [if test "x$with_sha1" != "x"; then
1391         enable_shader_cache=yes
1392      else
1393         enable_shader_cache=no
1394      fi])
1395 if test "x$with_sha1" = "x"; then
1396     if test "x$enable_shader_cache" = "xyes"; then
1397         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1398     fi
1399 fi
1400 if test "x$enable_shader_cache" = "xyes"; then
1401    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1402 fi
1403
1404 if test "x$enable_dri" = xyes; then
1405     if test "$enable_static" = yes; then
1406         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1407     fi
1408
1409     # not a hard requirement as swrast does not depend on it
1410     if test "x$have_libdrm" = xyes; then
1411         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1412     fi
1413 fi
1414
1415 AC_ARG_ENABLE([driglx-direct],
1416     [AS_HELP_STRING([--disable-driglx-direct],
1417         [disable direct rendering in GLX and EGL for DRI \
1418             @<:@default=auto@:>@])],
1419     [driglx_direct="$enableval"],
1420     [driglx_direct="yes"])
1421
1422 dnl
1423 dnl libGL configuration per driver
1424 dnl
1425 case "x$enable_glx" in
1426 xxlib | xgallium-xlib)
1427     # Xlib-based GLX
1428     dri_modules="x11 xext xcb"
1429     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1430     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1431     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1432     GL_LIB_DEPS="$XLIBGL_LIBS"
1433     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1434     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1435     ;;
1436 xdri)
1437     # DRI-based GLX
1438     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1439
1440     # find the DRI deps for libGL
1441     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1442
1443     if test x"$driglx_direct" = xyes; then
1444         if test x"$dri_platform" = xdrm ; then
1445             DEFINES="$DEFINES -DGLX_USE_DRM"
1446             require_libdrm "Direct rendering"
1447
1448             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1449             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1450             if test x"$enable_dri3" = xyes; then
1451                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1452                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1453             fi
1454
1455             if test x"$enable_dri" = xyes; then
1456                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1457             fi
1458
1459             if test x"$enable_dri3" = xyes; then
1460                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1461                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1462                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1463             fi
1464         fi
1465         if test x"$dri_platform" = xapple ; then
1466             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1467         fi
1468         if test x"$dri_platform" = xwindows ; then
1469             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1470         fi
1471     fi
1472
1473     # add xf86vidmode if available
1474     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1475     if test "$HAVE_XF86VIDMODE" = yes ; then
1476         dri_modules="$dri_modules xxf86vm"
1477     fi
1478
1479     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1480     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1481     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1482     GL_LIB_DEPS="$DRIGL_LIBS"
1483
1484     # need DRM libs, $PTHREAD_LIBS, etc.
1485     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1486     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1487     ;;
1488 esac
1489
1490 # This is outside the case (above) so that it is invoked even for non-GLX
1491 # builds.
1492 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1493
1494 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1495 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1496 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1497 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1498
1499 AC_SUBST([X11_INCLUDES])
1500 AC_SUBST([GL_LIB_DEPS])
1501 AC_SUBST([GL_PC_REQ_PRIV])
1502 AC_SUBST([GL_PC_LIB_PRIV])
1503 AC_SUBST([GL_PC_CFLAGS])
1504 AC_SUBST([DRI_PC_REQ_PRIV])
1505 AC_SUBST([GLESv1_CM_LIB_DEPS])
1506 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1507 AC_SUBST([GLESv2_LIB_DEPS])
1508 AC_SUBST([GLESv2_PC_LIB_PRIV])
1509
1510 AC_SUBST([HAVE_XF86VIDMODE])
1511
1512 dnl
1513 dnl More GLX setup
1514 dnl
1515 case "x$enable_glx" in
1516 xxlib | xgallium-xlib)
1517     DEFINES="$DEFINES -DUSE_XSHM"
1518     ;;
1519 xdri)
1520     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1521     if test "x$driglx_direct" = xyes; then
1522         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1523     fi
1524     ;;
1525 esac
1526
1527 dnl
1528 dnl TLS detection
1529 dnl
1530
1531 AC_ARG_ENABLE([glx-tls],
1532     [AS_HELP_STRING([--enable-glx-tls],
1533         [enable TLS support in GLX @<:@default=disabled@:>@])],
1534     [GLX_USE_TLS="$enableval"],
1535     [GLX_USE_TLS=no])
1536 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1537
1538 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1539       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1540
1541 dnl Read-only text section on x86 hardened platforms
1542 AC_ARG_ENABLE([glx-read-only-text],
1543     [AS_HELP_STRING([--enable-glx-read-only-text],
1544         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1545     [enable_glx_read_only_text="$enableval"],
1546     [enable_glx_read_only_text=no])
1547 if test "x$enable_glx_read_only_text" = xyes; then
1548     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1549 fi
1550
1551 dnl
1552 dnl More DRI setup
1553 dnl
1554 dnl Directory for DRI drivers
1555 AC_ARG_WITH([dri-driverdir],
1556     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1557         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1558     [DRI_DRIVER_INSTALL_DIR="$withval"],
1559     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1560 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1561 dnl Extra search path for DRI drivers
1562 AC_ARG_WITH([dri-searchpath],
1563     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1564         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1565     [DRI_DRIVER_SEARCH_DIR="$withval"],
1566     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1567 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1568 dnl Which drivers to build - default is chosen by platform
1569 AC_ARG_WITH([dri-drivers],
1570     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1571         [comma delimited classic DRI drivers list, e.g.
1572         "swrast,i965,radeon" @<:@default=auto@:>@])],
1573     [with_dri_drivers="$withval"],
1574     [with_dri_drivers=auto])
1575
1576 if test "x$with_dri_drivers" = xauto; then
1577     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1578         with_dri_drivers="yes"
1579     else
1580         with_dri_drivers="no"
1581     fi
1582 fi
1583 if test "x$with_dri_drivers" = xno; then
1584     with_dri_drivers=''
1585 fi
1586
1587 dnl If $with_dri_drivers is yes, drivers will be added through
1588 dnl platform checks. Set DEFINES and LIB_DEPS
1589 if test "x$enable_dri" = xyes; then
1590     # Platform specific settings and drivers to build
1591     case "$host_os" in
1592     linux*)
1593         DEFINES="$DEFINES -DHAVE_ALIAS"
1594         if test "x$enable_dri3" = xyes; then
1595             DEFINES="$DEFINES -DHAVE_DRI3"
1596         fi
1597
1598         case "$host_cpu" in
1599         powerpc* | sparc*)
1600             # Build only the drivers for cards that exist on PowerPC/sparc
1601             if test "x$with_dri_drivers" = "xyes"; then
1602                 with_dri_drivers="r200 radeon swrast"
1603             fi
1604             ;;
1605         esac
1606         ;;
1607     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1608         DEFINES="$DEFINES -DHAVE_ALIAS"
1609         ;;
1610     gnu*)
1611         DEFINES="$DEFINES -DHAVE_ALIAS"
1612         ;;
1613     cygwin*)
1614         if test "x$with_dri_drivers" = "xyes"; then
1615             with_dri_drivers="swrast"
1616         fi
1617         ;;
1618     darwin*)
1619         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1620         if test "x$with_dri_drivers" = "xyes"; then
1621             with_dri_drivers="swrast"
1622         fi
1623         ;;
1624     esac
1625
1626     # default drivers
1627     if test "x$with_dri_drivers" = "xyes"; then
1628         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1629     fi
1630
1631     # Check for expat
1632     PKG_CHECK_MODULES([EXPAT], [expat], [],
1633         # expat version 2.0 and earlier do not provide expat.pc
1634         [AC_CHECK_HEADER([expat.h],[],
1635                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1636          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1637                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1638          EXPAT_LIBS="-lexpat"])
1639
1640     # put all the necessary libs together
1641     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1642 fi
1643
1644 AC_SUBST([DRI_LIB_DEPS])
1645
1646 DRI_DIRS=''
1647 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1648 if test -n "$with_dri_drivers"; then
1649     if test "x$enable_opengl" != xyes; then
1650         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1651     fi
1652
1653     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1654     for driver in $dri_drivers; do
1655         DRI_DIRS="$DRI_DIRS $driver"
1656         case "x$driver" in
1657         xi915)
1658             HAVE_I915_DRI=yes;
1659             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1660             ;;
1661         xi965)
1662             HAVE_I965_DRI=yes;
1663             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1664             ;;
1665         xnouveau)
1666             HAVE_NOUVEAU_DRI=yes;
1667             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1668             ;;
1669         xradeon)
1670             HAVE_RADEON_DRI=yes;
1671             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1672             ;;
1673         xr200)
1674             HAVE_R200_DRI=yes;
1675             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1676             ;;
1677         xswrast)
1678             HAVE_SWRAST_DRI=yes;
1679             ;;
1680         *)
1681             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1682             ;;
1683         esac
1684     done
1685     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1686 fi
1687
1688
1689 #
1690 # Vulkan driver configuration
1691 #
1692
1693 AC_ARG_WITH([vulkan-drivers],
1694     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1695         [comma delimited Vulkan drivers list, e.g.
1696         "intel"
1697         @<:@default=no@:>@])],
1698     [with_vulkan_drivers="$withval"],
1699     [with_vulkan_drivers="no"])
1700
1701 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1702 # here so that the script doesn't choke on an unknown driver name later.
1703 case "x$with_vulkan_drivers" in
1704     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1705     xno) with_vulkan_drivers='' ;;
1706 esac
1707
1708 AC_ARG_WITH([vulkan-icddir],
1709     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1710         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1711     [VULKAN_ICD_INSTALL_DIR="$withval"],
1712     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1713 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1714
1715 if test -n "$with_vulkan_drivers"; then
1716     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1717     for driver in $VULKAN_DRIVERS; do
1718         case "x$driver" in
1719         xintel)
1720             if test "x$HAVE_I965_DRI" != xyes; then
1721                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1722             fi
1723             if test "x$with_sha1" == "x"; then
1724                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1725             fi
1726             HAVE_INTEL_VULKAN=yes;
1727
1728             ;;
1729         xradeon)
1730             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1731             HAVE_RADEON_VULKAN=yes;
1732             if test "x$with_sha1" == "x"; then
1733                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1734             fi
1735             ;;
1736         *)
1737             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1738             ;;
1739         esac
1740     done
1741     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1742 fi
1743
1744
1745 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1746 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1747                                   "x$enable_osmesa" = xyes -o \
1748                                   -n "$DRI_DIRS")
1749
1750 dnl
1751 dnl OSMesa configuration
1752 dnl
1753
1754 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1755 AC_ARG_WITH([osmesa-bits],
1756     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1757         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1758     [osmesa_bits="$withval"],
1759     [osmesa_bits=8])
1760 if test "x$osmesa_bits" != x8; then
1761     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1762         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1763         osmesa_bits=8
1764     fi
1765 fi
1766 case "x$osmesa_bits" in
1767 x8)
1768     OSMESA_LIB="${OSMESA_LIB}"
1769     ;;
1770 x16|x32)
1771     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1772     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1773     ;;
1774 *)
1775     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1776     ;;
1777 esac
1778
1779 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1780     # only link libraries with osmesa if shared
1781     if test "$enable_static" = no; then
1782         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1783     else
1784         OSMESA_LIB_DEPS=""
1785     fi
1786     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1787 fi
1788
1789 AC_SUBST([OSMESA_LIB_DEPS])
1790 AC_SUBST([OSMESA_PC_REQ])
1791 AC_SUBST([OSMESA_PC_LIB_PRIV])
1792
1793 dnl
1794 dnl gbm configuration
1795 dnl
1796 if test "x$enable_gbm" = xyes; then
1797     if test "x$enable_dri" = xyes; then
1798         if test "x$enable_shared_glapi" = xno; then
1799             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1800         fi
1801     else
1802         # Strictly speaking libgbm does not require --enable-dri, although
1803         # both of its backends do. Thus one can build libgbm without any
1804         # backends if --disable-dri is set.
1805         # To avoid unnecessary complexity of checking if at least one backend
1806         # is available when building, just mandate --enable-dri.
1807         AC_MSG_ERROR([gbm requires --enable-dri])
1808     fi
1809 fi
1810 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1811 # FINISHME: GBM has a number of dependencies which we should add below
1812 GBM_PC_REQ_PRIV=""
1813 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1814 AC_SUBST([GBM_PC_REQ_PRIV])
1815 AC_SUBST([GBM_PC_LIB_PRIV])
1816
1817 dnl
1818 dnl EGL configuration
1819 dnl
1820 EGL_CLIENT_APIS=""
1821
1822 if test "x$enable_egl" = xyes; then
1823     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1824
1825     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1826
1827     if test "$enable_static" != yes; then
1828         if test "x$enable_dri" = xyes; then
1829             HAVE_EGL_DRIVER_DRI2=1
1830             if test "x$enable_shared_glapi" = xno; then
1831                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1832             fi
1833             if test "x$enable_dri3" = xyes; then
1834                 HAVE_EGL_DRIVER_DRI3=1
1835                 if test "x$enable_shared_glapi" = xno; then
1836                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1837                 fi
1838             fi
1839         else
1840             # Avoid building an "empty" libEGL. Drop/update this
1841             # when other backends (haiku?) come along.
1842             AC_MSG_ERROR([egl requires --enable-dri])
1843         fi
1844
1845     fi
1846 fi
1847 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1848 AC_SUBST([EGL_LIB_DEPS])
1849
1850 gallium_st="mesa"
1851
1852 dnl
1853 dnl XA configuration
1854 dnl
1855 if test "x$enable_xa" = xyes; then
1856     if test "x$with_gallium_drivers" = xswrast; then
1857        AC_MSG_ERROR([
1858           Building xa requires at least one non swrast gallium driver.
1859           If you are looking to use libxatracker.so with the VMware driver,
1860           make sure to include svga in the gallium drivers list, apart from
1861           enabling XA.
1862           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1863     fi
1864     gallium_st="$gallium_st xa"
1865 fi
1866 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1867
1868 dnl
1869 dnl Gallium G3DVL configuration
1870 dnl
1871 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1872     if test "x$enable_xvmc" = xauto; then
1873         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1874     fi
1875
1876     if test "x$enable_vdpau" = xauto; then
1877         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1878     fi
1879
1880     if test "x$enable_omx" = xauto; then
1881         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1882     fi
1883
1884     if test "x$enable_va" = xauto; then
1885         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1886     fi
1887 fi
1888
1889 if test "x$enable_dri" = xyes -o \
1890         "x$enable_xvmc" = xyes -o \
1891         "x$enable_vdpau" = xyes -o \
1892         "x$enable_omx" = xyes -o \
1893         "x$enable_va" = xyes; then
1894     need_gallium_vl=yes
1895 fi
1896 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1897
1898 if test "x$enable_xvmc" = xyes -o \
1899         "x$enable_vdpau" = xyes -o \
1900         "x$enable_omx" = xyes -o \
1901         "x$enable_va" = xyes; then
1902     if test x"$enable_dri3" = xyes; then
1903         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1904                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1905     else
1906         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1907     fi
1908     need_gallium_vl_winsys=yes
1909 fi
1910 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1911
1912 if test "x$enable_xvmc" = xyes; then
1913     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1914     gallium_st="$gallium_st xvmc"
1915 fi
1916 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1917
1918 if test "x$enable_vdpau" = xyes; then
1919     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1920     gallium_st="$gallium_st vdpau"
1921     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1922 fi
1923 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1924
1925 if test "x$enable_omx" = xyes; then
1926     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1927     gallium_st="$gallium_st omx"
1928 fi
1929 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1930
1931 if test "x$enable_va" = xyes; then
1932     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1933     gallium_st="$gallium_st va"
1934 fi
1935 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1936
1937 dnl
1938 dnl Nine Direct3D9 configuration
1939 dnl
1940 if test "x$enable_nine" = xyes; then
1941     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1942         AC_MSG_ERROR([nine requires the gallium swrast driver])
1943     fi
1944     if test "x$with_gallium_drivers" = xswrast; then
1945         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1946     fi
1947     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1948         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1949     fi
1950
1951     if test "x$enable_dri3" = xno; then
1952         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1953     fi
1954
1955     gallium_st="$gallium_st nine"
1956 fi
1957 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1958
1959 dnl
1960 dnl OpenCL configuration
1961 dnl
1962
1963 AC_ARG_WITH([clang-libdir],
1964    [AS_HELP_STRING([--with-clang-libdir],
1965          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1966    [CLANG_LIBDIR="$withval"],
1967    [CLANG_LIBDIR=''])
1968
1969 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1970 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1971
1972 if test "x$have_libelf" = xno; then
1973    LIBELF_LIBS=''
1974    LIBELF_CFLAGS=''
1975    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1976    AC_SUBST([LIBELF_LIBS])
1977    AC_SUBST([LIBELF_CFLAGS])
1978 fi
1979
1980 if test "x$enable_opencl" = xyes; then
1981     if test -z "$with_gallium_drivers"; then
1982         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1983     fi
1984
1985     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1986         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1987     fi
1988
1989     if test "x$have_libclc" = xno; then
1990         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1991                     Make sure the directory containing libclc.pc is specified in your
1992                     PKG_CONFIG_PATH environment variable.
1993                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1994     else
1995         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1996         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1997         AC_SUBST([LIBCLC_INCLUDEDIR])
1998         AC_SUBST([LIBCLC_LIBEXECDIR])
1999     fi
2000
2001     gallium_st="$gallium_st clover"
2002
2003     if test "x$enable_opencl_icd" = xyes; then
2004         OPENCL_LIBNAME="MesaOpenCL"
2005     else
2006         OPENCL_LIBNAME="OpenCL"
2007     fi
2008
2009     if test "x$have_libelf" != xyes; then
2010        AC_MSG_ERROR([Clover requires libelf])
2011     fi
2012 fi
2013 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2014 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2015 AC_SUBST([OPENCL_LIBNAME])
2016
2017 dnl
2018 dnl Gallium configuration
2019 dnl
2020 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2021
2022 AC_SUBST([LLVM_BINDIR])
2023 AC_SUBST([LLVM_CFLAGS])
2024 AC_SUBST([LLVM_CPPFLAGS])
2025 AC_SUBST([LLVM_CXXFLAGS])
2026 AC_SUBST([LLVM_LIBDIR])
2027 AC_SUBST([LLVM_LIBS])
2028 AC_SUBST([LLVM_LDFLAGS])
2029 AC_SUBST([LLVM_INCLUDEDIR])
2030 AC_SUBST([LLVM_VERSION])
2031 AC_SUBST([CLANG_RESOURCE_DIR])
2032
2033 case "x$enable_opengl$enable_gles1$enable_gles2" in
2034 x*yes*)
2035     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2036     ;;
2037 esac
2038
2039 AC_SUBST([VG_LIB_DEPS])
2040 AC_SUBST([EGL_CLIENT_APIS])
2041
2042 dnl
2043 dnl EGL Platforms configuration
2044 dnl
2045 AC_ARG_WITH([egl-platforms],
2046     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2047         [comma delimited native platforms libEGL supports, e.g.
2048         "x11,drm" @<:@default=auto@:>@])],
2049     [with_egl_platforms="$withval"],
2050     [if test "x$enable_egl" = xyes; then
2051         if test "x$enable_gbm" = xyes; then
2052            with_egl_platforms="x11,drm"
2053         else
2054            with_egl_platforms="x11"
2055         fi
2056     else
2057         with_egl_platforms=""
2058     fi])
2059
2060 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2061     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2062 fi
2063
2064 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2065         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2066         WAYLAND_SCANNER='')
2067 if test "x$WAYLAND_SCANNER" = x; then
2068     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2069 fi
2070
2071 # Do per-EGL platform setups and checks
2072 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2073 for plat in $egl_platforms; do
2074         case "$plat" in
2075         wayland)
2076
2077                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2078
2079                 if test "x$WAYLAND_SCANNER" = x; then
2080                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2081                 fi
2082                 ;;
2083
2084         x11)
2085                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2086                 ;;
2087
2088         drm)
2089                 test "x$enable_gbm" = "xno" &&
2090                         AC_MSG_ERROR([EGL platform drm needs gbm])
2091                 ;;
2092
2093         surfaceless)
2094                 ;;
2095
2096         android)
2097                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2098                 ;;
2099
2100         *)
2101                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2102                 ;;
2103         esac
2104
2105         case "$plat" in
2106         wayland|drm|surfaceless)
2107                 require_libdrm "Platform $plat"
2108                 ;;
2109         esac
2110 done
2111
2112 # libEGL wants to default to the first platform specified in
2113 # ./configure.  parse that here.
2114 if test "x$egl_platforms" != "x"; then
2115     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2116     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2117 else
2118     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2119 fi
2120
2121 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2122 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2123 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2124 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2125 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2126
2127 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2128
2129 AC_SUBST([EGL_NATIVE_PLATFORM])
2130 AC_SUBST([EGL_CFLAGS])
2131
2132 # If we don't have the X11 platform, set this define so we don't try to include
2133 # the X11 headers.
2134 if ! echo "$egl_platforms" | grep -q 'x11'; then
2135     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2136     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2137 fi
2138
2139 dnl
2140 dnl Gallium LLVM
2141 dnl
2142 AC_ARG_ENABLE([gallium-llvm],
2143     [AS_HELP_STRING([--enable-gallium-llvm],
2144         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2145     [enable_gallium_llvm="$enableval"],
2146     [enable_gallium_llvm=auto])
2147
2148 AC_ARG_ENABLE([llvm-shared-libs],
2149     [AS_HELP_STRING([--enable-llvm-shared-libs],
2150         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2151     [enable_llvm_shared_libs="$enableval"],
2152     [enable_llvm_shared_libs=yes])
2153
2154 AC_ARG_WITH([llvm-prefix],
2155     [AS_HELP_STRING([--with-llvm-prefix],
2156         [Prefix for LLVM installations in non-standard locations])],
2157     [llvm_prefix="$withval"],
2158     [llvm_prefix=''])
2159
2160
2161 # Call this inside ` ` to get the return value.
2162 # $1 is the llvm-config command with arguments.
2163 strip_unwanted_llvm_flags() {
2164     # Use \> (marks the end of the word)
2165     echo `$1` | sed \
2166         -e 's/-march=\S*//g' \
2167         -e 's/-mtune=\S*//g' \
2168         -e 's/-mcpu=\S*//g' \
2169         -e 's/-DNDEBUG\>//g' \
2170         -e 's/-D_GNU_SOURCE\>//g' \
2171         -e 's/-pedantic\>//g' \
2172         -e 's/-Wcovered-switch-default\>//g' \
2173         -e 's/-O.\>//g' \
2174         -e 's/-g\>//g' \
2175         -e 's/-Wall\>//g' \
2176         -e 's/-Wcast-qual\>//g' \
2177         -e 's/-Woverloaded-virtual\>//g' \
2178         -e 's/-fcolor-diagnostics\>//g' \
2179         -e 's/-fdata-sections\>//g' \
2180         -e 's/-ffunction-sections\>//g' \
2181         -e 's/-fno-exceptions\>//g' \
2182         -e 's/-fomit-frame-pointer\>//g' \
2183         -e 's/-fvisibility-inlines-hidden\>//g' \
2184         -e 's/-fPIC\>//g' \
2185         -e 's/-fstack-protector-strong\>//g'
2186 }
2187
2188 llvm_check_version_for() {
2189     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2190         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2191     fi
2192 }
2193
2194
2195
2196 if test -z "$with_gallium_drivers"; then
2197     enable_gallium_llvm=no
2198 fi
2199 if test "x$enable_gallium_llvm" = xauto; then
2200     case "$host_cpu" in
2201     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2202     esac
2203 fi
2204 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2205     if test -z "$LLVM_CONFIG"; then
2206         if test -n "$llvm_prefix"; then
2207             AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2208         else
2209             AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2210         fi
2211     fi
2212
2213     if test "x$LLVM_CONFIG" != xno; then
2214         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2215         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2216         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2217         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2218         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2219         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2220         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2221         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2222
2223         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2224             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2225         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2226             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2227
2228         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2229         if test -z "$LLVM_VERSION_PATCH"; then
2230             LLVM_VERSION_PATCH=0
2231         fi
2232
2233         if test -n "${LLVM_VERSION_MAJOR}"; then
2234             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2235         else
2236             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2237         fi
2238
2239         LLVM_REQUIRED_VERSION_MAJOR="3"
2240         LLVM_REQUIRED_VERSION_MINOR="3"
2241         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2242             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2243         fi
2244
2245         llvm_add_default_components "gallium"
2246
2247         if test "x$enable_opencl" = xyes; then
2248             llvm_check_version_for "3" "6" "0" "opencl"
2249
2250             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2251             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2252         fi
2253         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2254         MESA_LLVM=1
2255
2256         dnl Check for Clang internal headers
2257         if test "x$enable_opencl" = xyes; then
2258             if test -z "$CLANG_LIBDIR"; then
2259                 CLANG_LIBDIR=${LLVM_LIBDIR}
2260             fi
2261             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2262             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2263                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2264         fi
2265     else
2266         MESA_LLVM=0
2267         LLVM_VERSION_INT=0
2268     fi
2269 else
2270     MESA_LLVM=0
2271     LLVM_VERSION_INT=0
2272
2273     if test "x$enable_opencl" = xyes; then
2274         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2275     fi
2276 fi
2277
2278 dnl Directory for XVMC libs
2279 AC_ARG_WITH([xvmc-libdir],
2280     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2281         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2282     [XVMC_LIB_INSTALL_DIR="$withval"],
2283     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2284 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2285
2286 dnl
2287 dnl Gallium Tests
2288 dnl
2289 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2290
2291 dnl Directory for VDPAU libs
2292 AC_ARG_WITH([vdpau-libdir],
2293     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2294         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2295     [VDPAU_LIB_INSTALL_DIR="$withval"],
2296     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2297 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2298
2299 dnl Directory for OMX libs
2300
2301 AC_ARG_WITH([omx-libdir],
2302     [AS_HELP_STRING([--with-omx-libdir=DIR],
2303         [directory for the OMX libraries])],
2304     [OMX_LIB_INSTALL_DIR="$withval"],
2305     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2306 AC_SUBST([OMX_LIB_INSTALL_DIR])
2307
2308 dnl Directory for VA libs
2309
2310 AC_ARG_WITH([va-libdir],
2311     [AS_HELP_STRING([--with-va-libdir=DIR],
2312         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2313     [VA_LIB_INSTALL_DIR="$withval"],
2314     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2315 AC_SUBST([VA_LIB_INSTALL_DIR])
2316
2317 AC_ARG_WITH([d3d-libdir],
2318     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2319         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2320     [D3D_DRIVER_INSTALL_DIR="$withval"],
2321     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2322 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2323
2324 dnl
2325 dnl Gallium helper functions
2326 dnl
2327 gallium_require_llvm() {
2328     if test "x$MESA_LLVM" = x0; then
2329         case "$host" in *gnux32) return;; esac
2330         case "$host_cpu" in
2331         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2332         esac
2333     fi
2334 }
2335
2336 dnl
2337 dnl DRM is needed by X, Wayland, and offscreen rendering.
2338 dnl Surfaceless is an alternative for the last one.
2339 dnl
2340 require_basic_egl() {
2341     case "$with_egl_platforms" in
2342         *drm*|*surfaceless*)
2343             ;;
2344         *)
2345             AC_MSG_ERROR([$1 requires one of these:
2346                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2347                   2) --with-egl-platforms=surfaceless (offscreen only)
2348                   Recommended options: drm,x11])
2349             ;;
2350     esac
2351 }
2352
2353 radeon_llvm_check() {
2354     if test ${LLVM_VERSION_INT} -lt 307; then
2355         amdgpu_llvm_target_name='r600'
2356     else
2357         amdgpu_llvm_target_name='amdgpu'
2358     fi
2359     llvm_check_version_for $2 $3 $4 $1
2360     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2361         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2362     fi
2363     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2364     NEED_RADEON_LLVM=yes
2365     if test "x$have_libelf" != xyes; then
2366        AC_MSG_ERROR([$1 requires libelf when using llvm])
2367     fi
2368 }
2369
2370 radeon_gallium_llvm_check() {
2371     if test "x$enable_gallium_llvm" != "xyes"; then
2372         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2373     fi
2374     radeon_llvm_check $*
2375 }
2376
2377 swr_llvm_check() {
2378     gallium_require_llvm $1
2379     if test ${LLVM_VERSION_INT} -lt 306; then
2380         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2381     fi
2382     if test "x$enable_gallium_llvm" != "xyes"; then
2383         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2384     fi
2385 }
2386
2387 swr_require_cxx_feature_flags() {
2388     feature_name="$1"
2389     preprocessor_test="$2"
2390     option_list="$3"
2391     output_var="$4"
2392
2393     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2394     AC_LANG_PUSH([C++])
2395     save_CXXFLAGS="$CXXFLAGS"
2396     save_IFS="$IFS"
2397     IFS=","
2398     found=0
2399     for opts in $option_list
2400     do
2401         unset IFS
2402         CXXFLAGS="$opts $save_CXXFLAGS"
2403         AC_COMPILE_IFELSE(
2404             [AC_LANG_PROGRAM(
2405                 [   #if !($preprocessor_test)
2406                     #error
2407                     #endif
2408                 ])],
2409             [found=1; break],
2410             [])
2411         IFS=","
2412     done
2413     IFS="$save_IFS"
2414     CXXFLAGS="$save_CXXFLAGS"
2415     AC_LANG_POP([C++])
2416     if test $found -eq 1; then
2417         AC_MSG_RESULT([$opts])
2418         eval "$output_var=\$opts"
2419         return 0
2420     fi
2421     AC_MSG_RESULT([no])
2422     AC_MSG_ERROR([swr requires $feature_name support])
2423     return 1
2424 }
2425
2426 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2427 if test -n "$with_gallium_drivers"; then
2428     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2429     for driver in $gallium_drivers; do
2430         case "x$driver" in
2431         xsvga)
2432             HAVE_GALLIUM_SVGA=yes
2433             require_libdrm "svga"
2434             ;;
2435         xi915)
2436             HAVE_GALLIUM_I915=yes
2437             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2438             require_libdrm "Gallium i915"
2439             ;;
2440         xilo)
2441             HAVE_GALLIUM_ILO=yes
2442             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2443             require_libdrm "Gallium i965/ilo"
2444             ;;
2445         xr300)
2446             HAVE_GALLIUM_R300=yes
2447             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2448             require_libdrm "Gallium R300"
2449             gallium_require_llvm "Gallium R300"
2450             ;;
2451         xr600)
2452             HAVE_GALLIUM_R600=yes
2453             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2454             require_libdrm "Gallium R600"
2455             if test "x$enable_opencl" = xyes; then
2456                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2457                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2458             fi
2459             ;;
2460         xradeonsi)
2461             HAVE_GALLIUM_RADEONSI=yes
2462             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2463             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2464             require_libdrm "radeonsi"
2465             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2466             require_basic_egl "radeonsi"
2467             ;;
2468         xnouveau)
2469             HAVE_GALLIUM_NOUVEAU=yes
2470             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2471             require_libdrm "nouveau"
2472             ;;
2473         xfreedreno)
2474             HAVE_GALLIUM_FREEDRENO=yes
2475             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2476             require_libdrm "freedreno"
2477             ;;
2478         xswrast)
2479             HAVE_GALLIUM_SOFTPIPE=yes
2480             if test "x$MESA_LLVM" = x1; then
2481                 HAVE_GALLIUM_LLVMPIPE=yes
2482             fi
2483             ;;
2484         xswr)
2485             swr_llvm_check "swr"
2486
2487             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2488                 ",-std=c++11" \
2489                 SWR_CXX11_CXXFLAGS
2490             AC_SUBST([SWR_CXX11_CXXFLAGS])
2491
2492             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2493                 ",-mavx,-march=core-avx" \
2494                 SWR_AVX_CXXFLAGS
2495             AC_SUBST([SWR_AVX_CXXFLAGS])
2496
2497             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2498                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2499                 SWR_AVX2_CXXFLAGS
2500             AC_SUBST([SWR_AVX2_CXXFLAGS])
2501
2502             HAVE_GALLIUM_SWR=yes
2503             ;;
2504         xvc4)
2505             HAVE_GALLIUM_VC4=yes
2506             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2507             require_libdrm "vc4"
2508
2509             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2510                               [USE_VC4_SIMULATOR=yes;
2511                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2512                               [USE_VC4_SIMULATOR=no])
2513             ;;
2514         xvirgl)
2515             HAVE_GALLIUM_VIRGL=yes
2516             require_libdrm "virgl"
2517             require_basic_egl "virgl"
2518             ;;
2519         *)
2520             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2521             ;;
2522         esac
2523     done
2524 fi
2525
2526 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2527     radeon_llvm_check "radv" "3" "9" "0"
2528 fi
2529
2530 dnl Set LLVM_LIBS - This is done after the driver configuration so
2531 dnl that drivers can add additional components to LLVM_COMPONENTS.
2532 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2533 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2534 dnl this was causing the same libraries to be appear multiple times
2535 dnl in LLVM_LIBS.
2536
2537 if test "x$MESA_LLVM" != x0; then
2538
2539     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2540        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2541     fi
2542     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2543
2544     dnl llvm-config may not give the right answer when llvm is a built as a
2545     dnl single shared library, so we must work the library name out for
2546     dnl ourselves.
2547     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2548     if test "x$enable_llvm_shared_libs" = xyes; then
2549         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2550         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2551         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2552
2553         if test "x$llvm_have_one_so" = xyes; then
2554             dnl LLVM was built using auto*, so there is only one shared object.
2555             LLVM_LIBS="-l$LLVM_SO_NAME"
2556         else
2557             dnl If LLVM was built with CMake, there will be one shared object per
2558             dnl component.
2559             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2560                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2561         Please make sure you have built llvm with the --enable-shared option
2562         and that your llvm libraries are installed in $LLVM_LIBDIR
2563         If you have installed your llvm libraries to a different directory you
2564         can use the --with-llvm-prefix= configure flag to specify this directory.
2565         NOTE: Mesa is attempting to use llvm shared libraries by default.
2566         If you do not want to build with llvm shared libraries and instead want to
2567         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2568         invocation and rebuild.])])
2569
2570            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2571            dnl install uses a shared object for each component and we have
2572            dnl already added all of these objects to LLVM_LIBS.
2573         fi
2574     else
2575         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2576         dnl We need to link to llvm system libs when using static libs
2577         dnl However, only llvm 3.5+ provides --system-libs
2578         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2579             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2580         fi
2581     fi
2582 fi
2583
2584 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2585 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2586 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2587 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2588 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2589 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2590 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2591                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2592 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2593 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2594 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2595 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2596 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2597 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2598                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2599                                          "x$HAVE_GALLIUM_SWR" = xyes)
2600 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2601 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2602
2603 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2604
2605 if test "x$enable_dri" = xyes; then
2606     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2607 fi
2608
2609 if test "x$have_drisw_kms" = xyes; then
2610     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2611 fi
2612 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2613
2614 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2615 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2616 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2617 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2618 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2619 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2620
2621 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2622 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2623
2624 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2625                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2626                                       "x$HAVE_RADEON_VULKAN" = xyes)
2627
2628 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2629                                         "x$HAVE_I965_DRI" = xyes)
2630
2631 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2632                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2633                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2634 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2635 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2636 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2637 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2638 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2639 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2640     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2641 fi
2642
2643 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2644 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2645 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2646 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2647                                         "x$enable_gallium_osmesa" = xyes)
2648
2649 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2650 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2651 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2652
2653 AC_SUBST([NINE_MAJOR], 1)
2654 AC_SUBST([NINE_MINOR], 0)
2655 AC_SUBST([NINE_TINY], 0)
2656 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2657
2658 AC_SUBST([VDPAU_MAJOR], 1)
2659 AC_SUBST([VDPAU_MINOR], 0)
2660
2661 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2662 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2663 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2664 AC_SUBST([VA_MINOR], $VA_MINOR)
2665
2666 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2667
2668 AC_SUBST([XVMC_MAJOR], 1)
2669 AC_SUBST([XVMC_MINOR], 0)
2670
2671 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2672 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2673 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2674 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2675
2676 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2677 AC_SUBST([XA_MINOR], $XA_MINOR)
2678 AC_SUBST([XA_TINY], $XA_TINY)
2679 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2680
2681 AC_ARG_ENABLE(valgrind,
2682               [AS_HELP_STRING([--enable-valgrind],
2683                              [Build mesa with valgrind support (default: auto)])],
2684                              [VALGRIND=$enableval], [VALGRIND=auto])
2685 if test "x$VALGRIND" != xno; then
2686         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2687 fi
2688 AC_MSG_CHECKING([whether to enable Valgrind support])
2689 if test "x$VALGRIND" = xauto; then
2690         VALGRIND="$have_valgrind"
2691 fi
2692
2693 if test "x$VALGRIND" = "xyes"; then
2694         if ! test "x$have_valgrind" = xyes; then
2695                 AC_MSG_ERROR([Valgrind support required but not present])
2696         fi
2697         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2698 fi
2699
2700 AC_MSG_RESULT([$VALGRIND])
2701
2702 dnl Restore LDFLAGS and CPPFLAGS
2703 LDFLAGS="$_SAVE_LDFLAGS"
2704 CPPFLAGS="$_SAVE_CPPFLAGS"
2705
2706 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2707 if test "x$acv_mesa_CLANG" = xyes; then
2708     CFLAGS="$CFLAGS -Qunused-arguments"
2709     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2710 fi
2711
2712 dnl Add user CFLAGS and CXXFLAGS
2713 CFLAGS="$CFLAGS $USER_CFLAGS"
2714 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2715
2716 dnl Substitute the config
2717 AC_CONFIG_FILES([Makefile
2718                 src/Makefile
2719                 src/amd/Makefile
2720                 src/amd/vulkan/Makefile
2721                 src/compiler/Makefile
2722                 src/egl/Makefile
2723                 src/egl/main/egl.pc
2724                 src/egl/wayland/wayland-drm/Makefile
2725                 src/egl/wayland/wayland-egl/Makefile
2726                 src/egl/wayland/wayland-egl/wayland-egl.pc
2727                 src/gallium/Makefile
2728                 src/gallium/auxiliary/Makefile
2729                 src/gallium/auxiliary/pipe-loader/Makefile
2730                 src/gallium/drivers/freedreno/Makefile
2731                 src/gallium/drivers/ddebug/Makefile
2732                 src/gallium/drivers/i915/Makefile
2733                 src/gallium/drivers/ilo/Makefile
2734                 src/gallium/drivers/llvmpipe/Makefile
2735                 src/gallium/drivers/noop/Makefile
2736                 src/gallium/drivers/nouveau/Makefile
2737                 src/gallium/drivers/r300/Makefile
2738                 src/gallium/drivers/r600/Makefile
2739                 src/gallium/drivers/radeon/Makefile
2740                 src/gallium/drivers/radeonsi/Makefile
2741                 src/gallium/drivers/rbug/Makefile
2742                 src/gallium/drivers/softpipe/Makefile
2743                 src/gallium/drivers/svga/Makefile
2744                 src/gallium/drivers/swr/Makefile
2745                 src/gallium/drivers/trace/Makefile
2746                 src/gallium/drivers/vc4/Makefile
2747                 src/gallium/drivers/virgl/Makefile
2748                 src/gallium/state_trackers/clover/Makefile
2749                 src/gallium/state_trackers/dri/Makefile
2750                 src/gallium/state_trackers/glx/xlib/Makefile
2751                 src/gallium/state_trackers/nine/Makefile
2752                 src/gallium/state_trackers/omx/Makefile
2753                 src/gallium/state_trackers/osmesa/Makefile
2754                 src/gallium/state_trackers/va/Makefile
2755                 src/gallium/state_trackers/vdpau/Makefile
2756                 src/gallium/state_trackers/xa/Makefile
2757                 src/gallium/state_trackers/xvmc/Makefile
2758                 src/gallium/targets/d3dadapter9/Makefile
2759                 src/gallium/targets/d3dadapter9/d3d.pc
2760                 src/gallium/targets/dri/Makefile
2761                 src/gallium/targets/libgl-xlib/Makefile
2762                 src/gallium/targets/omx/Makefile
2763                 src/gallium/targets/opencl/Makefile
2764                 src/gallium/targets/opencl/mesa.icd
2765                 src/gallium/targets/osmesa/Makefile
2766                 src/gallium/targets/osmesa/osmesa.pc
2767                 src/gallium/targets/pipe-loader/Makefile
2768                 src/gallium/targets/va/Makefile
2769                 src/gallium/targets/vdpau/Makefile
2770                 src/gallium/targets/xa/Makefile
2771                 src/gallium/targets/xa/xatracker.pc
2772                 src/gallium/targets/xvmc/Makefile
2773                 src/gallium/tests/trivial/Makefile
2774                 src/gallium/tests/unit/Makefile
2775                 src/gallium/winsys/freedreno/drm/Makefile
2776                 src/gallium/winsys/i915/drm/Makefile
2777                 src/gallium/winsys/intel/drm/Makefile
2778                 src/gallium/winsys/nouveau/drm/Makefile
2779                 src/gallium/winsys/radeon/drm/Makefile
2780                 src/gallium/winsys/amdgpu/drm/Makefile
2781                 src/gallium/winsys/svga/drm/Makefile
2782                 src/gallium/winsys/sw/dri/Makefile
2783                 src/gallium/winsys/sw/kms-dri/Makefile
2784                 src/gallium/winsys/sw/null/Makefile
2785                 src/gallium/winsys/sw/wrapper/Makefile
2786                 src/gallium/winsys/sw/xlib/Makefile
2787                 src/gallium/winsys/vc4/drm/Makefile
2788                 src/gallium/winsys/virgl/drm/Makefile
2789                 src/gallium/winsys/virgl/vtest/Makefile
2790                 src/gbm/Makefile
2791                 src/gbm/main/gbm.pc
2792                 src/glx/Makefile
2793                 src/glx/apple/Makefile
2794                 src/glx/tests/Makefile
2795                 src/glx/windows/Makefile
2796                 src/glx/windows/windowsdriproto.pc
2797                 src/gtest/Makefile
2798                 src/intel/Makefile
2799                 src/intel/tools/Makefile
2800                 src/intel/vulkan/Makefile
2801                 src/loader/Makefile
2802                 src/mapi/Makefile
2803                 src/mapi/es1api/glesv1_cm.pc
2804                 src/mapi/es2api/glesv2.pc
2805                 src/mapi/glapi/gen/Makefile
2806                 src/mesa/Makefile
2807                 src/mesa/gl.pc
2808                 src/mesa/drivers/dri/dri.pc
2809                 src/mesa/drivers/dri/common/Makefile
2810                 src/mesa/drivers/dri/common/xmlpool/Makefile
2811                 src/mesa/drivers/dri/i915/Makefile
2812                 src/mesa/drivers/dri/i965/Makefile
2813                 src/mesa/drivers/dri/Makefile
2814                 src/mesa/drivers/dri/nouveau/Makefile
2815                 src/mesa/drivers/dri/r200/Makefile
2816                 src/mesa/drivers/dri/radeon/Makefile
2817                 src/mesa/drivers/dri/swrast/Makefile
2818                 src/mesa/drivers/osmesa/Makefile
2819                 src/mesa/drivers/osmesa/osmesa.pc
2820                 src/mesa/drivers/x11/Makefile
2821                 src/mesa/main/tests/Makefile
2822                 src/util/Makefile
2823                 src/util/tests/hash_table/Makefile
2824                 src/vulkan/wsi/Makefile])
2825
2826 AC_OUTPUT
2827
2828 # Fix up dependencies in *.Plo files, where we changed the extension of a
2829 # source file
2830 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2831
2832
2833 dnl
2834 dnl Output some configuration info for the user
2835 dnl
2836 echo ""
2837 echo "        prefix:          $prefix"
2838 echo "        exec_prefix:     $exec_prefix"
2839 echo "        libdir:          $libdir"
2840 echo "        includedir:      $includedir"
2841
2842 dnl API info
2843 echo ""
2844 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2845
2846 dnl Driver info
2847 echo ""
2848 case "x$enable_osmesa$enable_gallium_osmesa" in
2849 xnoyes)
2850         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2851         ;;
2852 xyesno)
2853         echo "        OSMesa:          lib$OSMESA_LIB"
2854         ;;
2855 xnono)
2856         echo "        OSMesa:          no"
2857         ;;
2858 esac
2859
2860 echo ""
2861 if test "x$enable_dri" != xno; then
2862         echo "        DRI platform:    $dri_platform"
2863         if test -z "$DRI_DIRS"; then
2864             echo "        DRI drivers:     no"
2865         else
2866             echo "        DRI drivers:     $DRI_DIRS"
2867         fi
2868         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2869 fi
2870
2871 case "x$enable_glx" in
2872 xdri)
2873     echo "        GLX:             DRI-based"
2874     ;;
2875 xxlib)
2876     echo "        GLX:             Xlib-based"
2877     ;;
2878 xgallium-xlib)
2879     echo "        GLX:             Xlib-based (Gallium)"
2880     ;;
2881 *)
2882     echo "        GLX:             $enable_glx"
2883     ;;
2884 esac
2885
2886 dnl EGL
2887 echo ""
2888 echo "        EGL:             $enable_egl"
2889 if test "$enable_egl" = yes; then
2890     echo "        EGL platforms:   $egl_platforms"
2891
2892     egl_drivers=""
2893     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2894         egl_drivers="$egl_drivers builtin:egl_dri2"
2895     fi
2896     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2897         egl_drivers="$egl_drivers builtin:egl_dri3"
2898     fi
2899
2900     echo "        EGL drivers:    $egl_drivers"
2901 fi
2902 if test "x$enable_gbm" = xyes; then
2903     echo "        GBM:             yes"
2904 else
2905     echo "        GBM:             no"
2906 fi
2907
2908 # Vulkan
2909 echo ""
2910 if test "x$VULKAN_DRIVERS" != x; then
2911     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2912     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2913 else
2914     echo "        Vulkan drivers:  no"
2915 fi
2916
2917 echo ""
2918 if test "x$MESA_LLVM" = x1; then
2919     echo "        llvm:            yes"
2920     echo "        llvm-config:     $LLVM_CONFIG"
2921     echo "        llvm-version:    $LLVM_VERSION"
2922 else
2923     echo "        llvm:            no"
2924 fi
2925
2926 echo ""
2927 if test -n "$with_gallium_drivers"; then
2928     echo "        Gallium drivers: $gallium_drivers"
2929     echo "        Gallium st:      $gallium_st"
2930 else
2931     echo "        Gallium:         no"
2932 fi
2933
2934 echo ""
2935 if test "x$enable_gallium_extra_hud" != xyes; then
2936     echo "        HUD extra stats: no"
2937 else
2938     echo "        HUD extra stats: yes"
2939 fi
2940
2941 if test "x$enable_lmsensors" != xyes; then
2942     echo "        HUD lmsensors:   no"
2943 else
2944     echo "        HUD lmsensors:   yes"
2945 fi
2946
2947 dnl Shader cache
2948 echo ""
2949 echo "        Shader cache:    $enable_shader_cache"
2950 if test "x$enable_shader_cache" = "xyes"; then
2951     echo "        With SHA1 from:  $with_sha1"
2952 fi
2953
2954 dnl Libraries
2955 echo ""
2956 echo "        Shared libs:     $enable_shared"
2957 echo "        Static libs:     $enable_static"
2958 echo "        Shared-glapi:    $enable_shared_glapi"
2959
2960 dnl Compiler options
2961 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2962 cflags=`echo $CFLAGS | \
2963     $SED 's/^ *//;s/  */ /;s/ *$//'`
2964 cxxflags=`echo $CXXFLAGS | \
2965     $SED 's/^ *//;s/  */ /;s/ *$//'`
2966 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2967 echo ""
2968 echo "        CFLAGS:          $cflags"
2969 echo "        CXXFLAGS:        $cxxflags"
2970 echo "        Macros:          $defines"
2971 echo ""
2972 if test "x$MESA_LLVM" = x1; then
2973     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2974     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2975     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2976     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2977     echo ""
2978 fi
2979 echo "        PYTHON2:         $PYTHON2"
2980
2981 echo ""
2982 echo "        Run '${MAKE-make}' to build Mesa"
2983 echo ""