configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign])
  20
  21 dnl http://people.gnome.org/~walters/docs/build-api.txt
  22 dnl We don't support srcdir != builddir.
  23 echo \#buildapi-variable-no-builddir >/dev/null
  24
  25 # Support silent build rules, requires at least automake-1.11. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  29
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  34 USER_CFLAGS="$CFLAGS"
  35 USER_CXXFLAGS="$CXXFLAGS"
  36
  37 dnl Versions for external dependencies
  38 LIBDRM_REQUIRED=2.4.24
  39 LIBDRM_RADEON_REQUIRED=2.4.31
  40 LIBDRM_INTEL_REQUIRED=2.4.30
  41 LIBDRM_NOUVEAU_REQUIRED=0.6
  42 DRI2PROTO_REQUIRED=2.6
  43 GLPROTO_REQUIRED=1.4.14
  44 LIBDRM_XORG_REQUIRED=2.4.24
  45 LIBKMS_XORG_REQUIRED=1.0.0
  46
  47 dnl Check for progs
  48 AC_PROG_CPP
  49 AC_PROG_CC
  50 AC_PROG_CXX
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  71 dnl configuration in that case.
  72 AC_PROG_INSTALL
  73 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  74
  75 dnl We need a POSIX shell for parts of the build. Assume we have one
  76 dnl in most cases.
  77 case "$host_os" in
  78 solaris*)
  79     # Solaris /bin/sh is too old/non-POSIX compliant
  80     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  81     SHELL="$POSIX_SHELL"
  82     ;;
  83 esac
  84
  85 AC_PATH_PROG([GTESTCONFIG], [gtest-config])
  86 if test "x$GTESTCONFIG" != "x"; then
  87     GTEST_CFLAGS=`gtest-config --cppflags --cxxflags`
  88     GTEST_LIBS=`gtest-config --ldflags --libs`
  89     AC_SUBST([GTEST_CFLAGS])
  90     AC_SUBST([GTEST_LIBS])
  91     HAVE_GTEST=yes
  92 else
  93     HAVE_GTEST=no
  94 fi
  95 AM_CONDITIONAL(HAVE_GTEST, test x$HAVE_GTEST = xyes)
  96
  97 dnl clang is mostly GCC-compatible, but its version is much lower,
  98 dnl so we have to check for it.
  99 AC_MSG_CHECKING([if compiling with clang])
 100
 101 AC_COMPILE_IFELSE(
 102 [AC_LANG_PROGRAM([], [[
 103 #ifndef __clang__
 104        not clang
 105 #endif
 106 ]])],
 107 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 108
 109 AC_MSG_RESULT([$acv_mesa_CLANG])
 110
 111 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 112 dnl versions are explictly not supported.
 113 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 114     AC_MSG_CHECKING([whether gcc version is sufficient])
 115     major=0
 116     minor=0
 117
 118     GCC_VERSION=`$CC -dumpversion`
 119     if test $? -eq 0; then
 120         major=`echo $GCC_VERSION | cut -d. -f1`
 121         minor=`echo $GCC_VERSION | cut -d. -f2`
 122     fi
 123
 124     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
 125         AC_MSG_RESULT([no])
 126         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 127     else
 128         AC_MSG_RESULT([yes])
 129     fi
 130 fi
 131
 132
 133 MKDEP_OPTIONS=-fdepend
 134 dnl Ask gcc where it's keeping its secret headers
 135 if test "x$GCC" = xyes; then
 136     for dir in include include-fixed; do
 137         GCC_INCLUDES=`$CC -print-file-name=$dir`
 138         if test "x$GCC_INCLUDES" != x && \
 139            test "$GCC_INCLUDES" != "$dir" && \
 140            test -d "$GCC_INCLUDES"; then
 141             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 142         fi
 143     done
 144 fi
 145 AC_SUBST([MKDEP_OPTIONS])
 146
 147 dnl Make sure the pkg-config macros are defined
 148 m4_ifndef([PKG_PROG_PKG_CONFIG],
 149     [m4_fatal([Could not locate the pkg-config autoconf macros.
 150   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 151   are in a different location, try setting the environment variable
 152   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 153 PKG_PROG_PKG_CONFIG()
 154
 155 dnl LIB_DIR - library basename
 156 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 157 AC_SUBST([LIB_DIR])
 158
 159 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 160 _SAVE_LDFLAGS="$LDFLAGS"
 161 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 162 AC_SUBST([EXTRA_LIB_PATH])
 163
 164 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 165 _SAVE_CPPFLAGS="$CPPFLAGS"
 166 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 167 AC_SUBST([X11_INCLUDES])
 168
 169 dnl Compiler macros
 170 DEFINES=""
 171 AC_SUBST([DEFINES])
 172 case "$host_os" in
 173 linux*|*-gnu*|gnu*)
 174     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 175     ;;
 176 solaris*)
 177     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 178     ;;
 179 cygwin*)
 180     DEFINES="$DEFINES -DPTHREADS"
 181     ;;
 182 esac
 183
 184 dnl Add flags for gcc and g++
 185 if test "x$GCC" = xyes; then
 186     CFLAGS="$CFLAGS -Wall -std=c99"
 187
 188     # Enable -Werror=implicit-function-declaration and
 189     # -Werror=missing-prototypes, if available, or otherwise, just
 190     # -Wmissing-prototypes.  This is particularly useful to avoid
 191     # generating a loadable driver module that has undefined symbols.
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 194     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 195     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 197                    AC_MSG_RESULT([yes]),
 198                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 199                     AC_MSG_RESULT([no])]);
 200
 201     # Enable -fvisibility=hidden if using a gcc that supports it
 202     save_CFLAGS="$CFLAGS"
 203     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 204     VISIBILITY_CFLAGS="-fvisibility=hidden"
 205     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 208
 209     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 210     CFLAGS=$save_CFLAGS
 211
 212     # Work around aliasing bugs - developers should comment this out
 213     CFLAGS="$CFLAGS -fno-strict-aliasing"
 214
 215     # gcc's builtin memcmp is slower than glibc's
 216     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 217     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 218 fi
 219 if test "x$GXX" = xyes; then
 220     CXXFLAGS="$CXXFLAGS -Wall"
 221
 222     # Enable -fvisibility=hidden if using a gcc that supports it
 223     save_CXXFLAGS="$CXXFLAGS"
 224     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 225     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 226     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 227     AC_LANG_PUSH([C++])
 228     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 229                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 230     AC_LANG_POP([C++])
 231
 232     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 233     CXXFLAGS=$save_CXXFLAGS
 234
 235     # Work around aliasing bugs - developers should comment this out
 236     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 237
 238     # gcc's builtin memcmp is slower than glibc's
 239     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 240     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 241 fi
 242
 243 dnl even if the compiler appears to support it, using visibility attributes isn't
 244 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 245 case "$host_os" in
 246 cygwin*)
 247     VISIBILITY_CFLAGS=""
 248     VISIBILITY_CXXFLAGS=""
 249     ;;
 250 esac
 251
 252 AC_SUBST([VISIBILITY_CFLAGS])
 253 AC_SUBST([VISIBILITY_CXXFLAGS])
 254
 255 dnl These should be unnecessary, but let the user set them if they want
 256 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 257     Default is to use CFLAGS.])
 258 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 259     compiler. Default is to use CFLAGS.])
 260 AC_SUBST([OPT_FLAGS])
 261 AC_SUBST([ARCH_FLAGS])
 262
 263 dnl
 264 dnl Hacks to enable 32 or 64 bit build
 265 dnl
 266 AC_ARG_ENABLE([32-bit],
 267     [AS_HELP_STRING([--enable-32-bit],
 268         [build 32-bit libraries @<:@default=auto@:>@])],
 269     [enable_32bit="$enableval"],
 270     [enable_32bit=auto]
 271 )
 272 if test "x$enable_32bit" = xyes; then
 273     if test "x$GCC" = xyes; then
 274         CFLAGS="$CFLAGS -m32"
 275         ARCH_FLAGS="$ARCH_FLAGS -m32"
 276     fi
 277     if test "x$GXX" = xyes; then
 278         CXXFLAGS="$CXXFLAGS -m32"
 279     fi
 280 fi
 281 AC_ARG_ENABLE([64-bit],
 282     [AS_HELP_STRING([--enable-64-bit],
 283         [build 64-bit libraries @<:@default=auto@:>@])],
 284     [enable_64bit="$enableval"],
 285     [enable_64bit=auto]
 286 )
 287 if test "x$enable_64bit" = xyes; then
 288     if test "x$GCC" = xyes; then
 289         CFLAGS="$CFLAGS -m64"
 290     fi
 291     if test "x$GXX" = xyes; then
 292         CXXFLAGS="$CXXFLAGS -m64"
 293     fi
 294 fi
 295
 296 dnl Can't have static and shared libraries, default to static if user
 297 dnl explicitly requested. If both disabled, set to static since shared
 298 dnl was explicitly requested.
 299 case "x$enable_static$enable_shared" in
 300 xyesyes )
 301     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 302     enable_shared=no
 303     ;;
 304 xnono )
 305     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 306     enable_static=yes
 307     ;;
 308 esac
 309
 310 dnl
 311 dnl mklib options
 312 dnl
 313 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 314 if test "$enable_static" = yes; then
 315     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 316 fi
 317 AC_SUBST([MKLIB_OPTIONS])
 318
 319 dnl
 320 dnl other compiler options
 321 dnl
 322 AC_ARG_ENABLE([debug],
 323     [AS_HELP_STRING([--enable-debug],
 324         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 325     [enable_debug="$enableval"],
 326     [enable_debug=no]
 327 )
 328 if test "x$enable_debug" = xyes; then
 329     DEFINES="$DEFINES -DDEBUG"
 330     if test "x$GCC" = xyes; then
 331         CFLAGS="$CFLAGS -g"
 332     fi
 333     if test "x$GXX" = xyes; then
 334         CXXFLAGS="$CXXFLAGS -g"
 335     fi
 336 fi
 337
 338 dnl
 339 dnl library names
 340 dnl
 341 LIB_PREFIX_GLOB='lib'
 342 LIB_VERSION_SEPARATOR='.'
 343 if test "$enable_static" = yes; then
 344     LIB_EXTENSION='a'
 345 else
 346     case "$host_os" in
 347     darwin* )
 348         LIB_EXTENSION='dylib' ;;
 349     cygwin* )
 350         dnl prefix can be 'cyg' or 'lib'
 351         LIB_PREFIX_GLOB='???'
 352         LIB_VERSION_SEPARATOR='-'
 353         LIB_EXTENSION='dll' ;;
 354     aix* )
 355         LIB_EXTENSION='a' ;;
 356     * )
 357         LIB_EXTENSION='so' ;;
 358     esac
 359 fi
 360
 361 dnl
 362 dnl Mangled Mesa support
 363 dnl
 364 AC_ARG_ENABLE([mangling],
 365   [AS_HELP_STRING([--enable-mangling],
 366     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 367   [enable_mangling="${enableval}"],
 368   [enable_mangling=no]
 369 )
 370 GL_LIB="GL"
 371 GLU_LIB="GLU"
 372 OSMESA_LIB="OSMesa"
 373 if test "x${enable_mangling}" = "xyes" ; then
 374   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 375   GL_LIB="MangledGL"
 376   GLU_LIB="MangledGLU"
 377   OSMESA_LIB="MangledOSMesa"
 378 fi
 379 AC_SUBST([GL_LIB])
 380 AC_SUBST([GLU_LIB])
 381 AC_SUBST([OSMESA_LIB])
 382
 383 dnl
 384 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 385 dnl
 386 AC_ARG_ENABLE([texture-float],
 387     [AS_HELP_STRING([--enable-texture-float],
 388         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 389     [enable_texture_float="$enableval"],
 390     [enable_texture_float=no]
 391 )
 392 if test "x$enable_texture_float" = xyes; then
 393     AC_MSG_WARN([Floating-point textures enabled.])
 394     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 395     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 396 fi
 397
 398 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 399 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 400 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 401 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 402 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 403 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 404 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 405 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 406
 407 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 411 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 412 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 413 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 414 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 415 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 416
 417 AC_SUBST([GL_LIB_NAME])
 418 AC_SUBST([GLU_LIB_NAME])
 419 AC_SUBST([OSMESA_LIB_NAME])
 420 AC_SUBST([EGL_LIB_NAME])
 421 AC_SUBST([GLESv1_CM_LIB_NAME])
 422 AC_SUBST([GLESv2_LIB_NAME])
 423 AC_SUBST([VG_LIB_NAME])
 424 AC_SUBST([GLAPI_LIB_NAME])
 425
 426 AC_SUBST([GL_LIB_GLOB])
 427 AC_SUBST([GLU_LIB_GLOB])
 428 AC_SUBST([OSMESA_LIB_GLOB])
 429 AC_SUBST([EGL_LIB_GLOB])
 430 AC_SUBST([GLESv1_CM_LIB_GLOB])
 431 AC_SUBST([GLESv2_LIB_GLOB])
 432 AC_SUBST([VG_LIB_GLOB])
 433 AC_SUBST([GLAPI_LIB_GLOB])
 434
 435 dnl
 436 dnl Arch/platform-specific settings
 437 dnl
 438 AC_ARG_ENABLE([asm],
 439     [AS_HELP_STRING([--disable-asm],
 440         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 441     [enable_asm="$enableval"],
 442     [enable_asm=yes]
 443 )
 444 asm_arch=""
 445 ASM_FLAGS=""
 446 MESA_ASM_SOURCES=""
 447 GLAPI_ASM_SOURCES=""
 448 AC_MSG_CHECKING([whether to enable assembly])
 449 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 450 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 451 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 452     case "$host_cpu" in
 453     i?86 | x86_64)
 454         enable_asm=no
 455         AC_MSG_RESULT([no, cross compiling])
 456         ;;
 457     esac
 458 fi
 459 # check for supported arches
 460 if test "x$enable_asm" = xyes; then
 461     case "$host_cpu" in
 462     i?86)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 466             ;;
 467         esac
 468         ;;
 469     x86_64)
 470         case "$host_os" in
 471         linux* | *freebsd* | dragonfly* | *netbsd*)
 472             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 473             ;;
 474         esac
 475         ;;
 476     powerpc)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=ppc
 480             ;;
 481         esac
 482         ;;
 483     sparc*)
 484         case "$host_os" in
 485         linux*)
 486             asm_arch=sparc
 487             ;;
 488         esac
 489         ;;
 490     esac
 491
 492     case "$asm_arch" in
 493     x86)
 494         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 495         MESA_ASM_SOURCES='$(X86_SOURCES)'
 496         GLAPI_ASM_SOURCES='$(X86_API)'
 497         AC_MSG_RESULT([yes, x86])
 498         ;;
 499     x86_64)
 500         ASM_FLAGS="-DUSE_X86_64_ASM"
 501         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 502         GLAPI_ASM_SOURCES='$(X86-64_API)'
 503         AC_MSG_RESULT([yes, x86_64])
 504         ;;
 505     sparc)
 506         ASM_FLAGS="-DUSE_SPARC_ASM"
 507         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 508         GLAPI_ASM_SOURCES='$(SPARC_API)'
 509         AC_MSG_RESULT([yes, sparc])
 510         ;;
 511     *)
 512         AC_MSG_RESULT([no, platform not supported])
 513         ;;
 514     esac
 515 fi
 516 AC_SUBST([ASM_FLAGS])
 517 AC_SUBST([MESA_ASM_SOURCES])
 518 AC_SUBST([GLAPI_ASM_SOURCES])
 519
 520 dnl PIC code macro
 521 MESA_PIC_FLAGS
 522
 523 dnl Check to see if dlopen is in default libraries (like Solaris, which
 524 dnl has it in libc), or if libdl is needed to get it.
 525 AC_CHECK_FUNC([dlopen], [],
 526     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 527 AC_SUBST([DLOPEN_LIBS])
 528
 529 dnl See if posix_memalign is available
 530 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 531
 532 dnl SELinux awareness.
 533 AC_ARG_ENABLE([selinux],
 534     [AS_HELP_STRING([--enable-selinux],
 535         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 536     [MESA_SELINUX="$enableval"],
 537     [MESA_SELINUX=no])
 538 if test "x$enable_selinux" = "xyes"; then
 539     AC_CHECK_HEADER([selinux/selinux.h],[],
 540                     [AC_MSG_ERROR([SELinux headers not found])])
 541     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 542                  [AC_MSG_ERROR([SELinux library not found])])
 543     SELINUX_LIBS="-lselinux"
 544     DEFINES="$DEFINES -DMESA_SELINUX"
 545 fi
 546
 547 dnl Options for APIs
 548 AC_ARG_ENABLE([opengl],
 549     [AS_HELP_STRING([--disable-opengl],
 550         [disable support for standard OpenGL API @<:@default=no@:>@])],
 551     [enable_opengl="$enableval"],
 552     [enable_opengl=yes])
 553 AC_ARG_ENABLE([gles1],
 554     [AS_HELP_STRING([--enable-gles1],
 555         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 556     [enable_gles1="$enableval"],
 557     [enable_gles1=no])
 558 AC_ARG_ENABLE([gles2],
 559     [AS_HELP_STRING([--enable-gles2],
 560         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 561     [enable_gles2="$enableval"],
 562     [enable_gles2=no])
 563 AC_ARG_ENABLE([openvg],
 564     [AS_HELP_STRING([--enable-openvg],
 565         [enable support for OpenVG API @<:@default=no@:>@])],
 566     [enable_openvg="$enableval"],
 567     [enable_openvg=no])
 568
 569 AC_ARG_ENABLE([dri],
 570     [AS_HELP_STRING([--enable-dri],
 571         [enable DRI modules @<:@default=auto@:>@])],
 572     [enable_dri="$enableval"],
 573     [enable_dri=auto])
 574 AC_ARG_ENABLE([glx],
 575     [AS_HELP_STRING([--enable-glx],
 576         [enable GLX library @<:@default=auto@:>@])],
 577     [enable_glx="$enableval"],
 578     [enable_glx=auto])
 579 AC_ARG_ENABLE([osmesa],
 580     [AS_HELP_STRING([--enable-osmesa],
 581         [enable OSMesa library @<:@default=auto@:>@])],
 582     [enable_osmesa="$enableval"],
 583     [enable_osmesa=auto])
 584 AC_ARG_ENABLE([egl],
 585     [AS_HELP_STRING([--disable-egl],
 586         [disable EGL library @<:@default=enabled@:>@])],
 587     [enable_egl="$enableval"],
 588     [enable_egl=yes])
 589
 590 AC_ARG_ENABLE([xorg],
 591     [AS_HELP_STRING([--enable-xorg],
 592         [enable support for X.Org DDX API @<:@default=no@:>@])],
 593     [enable_xorg="$enableval"],
 594     [enable_xorg=no])
 595 AC_ARG_ENABLE([xa],
 596     [AS_HELP_STRING([--enable-xa],
 597         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 598     [enable_xa="$enableval"],
 599     [enable_xa=no])
 600 AC_ARG_ENABLE([d3d1x],
 601     [AS_HELP_STRING([--enable-d3d1x],
 602         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 603     [enable_d3d1x="$enableval"],
 604     [enable_d3d1x=no])
 605 AC_ARG_ENABLE([gbm],
 606    [AS_HELP_STRING([--enable-gbm],
 607          [enable gbm library @<:@default=auto@:>@])],
 608    [enable_gbm="$enableval"],
 609    [enable_gbm=auto])
 610
 611 AC_ARG_ENABLE([xvmc],
 612    [AS_HELP_STRING([--enable-xvmc],
 613          [enable xvmc library @<:@default=auto@:>@])],
 614    [enable_xvmc="$enableval"],
 615    [enable_xvmc=auto])
 616 AC_ARG_ENABLE([vdpau],
 617    [AS_HELP_STRING([--enable-vdpau],
 618          [enable vdpau library @<:@default=auto@:>@])],
 619    [enable_vdpau="$enableval"],
 620    [enable_vdpau=auto])
 621 AC_ARG_ENABLE([va],
 622    [AS_HELP_STRING([--enable-va],
 623          [enable va library @<:@default=auto@:>@])],
 624    [enable_va="$enableval"],
 625    [enable_va=auto])
 626
 627 AC_ARG_ENABLE([xlib_glx],
 628     [AS_HELP_STRING([--enable-xlib-glx],
 629         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 630     [enable_xlib_glx="$enableval"],
 631     [enable_xlib_glx=auto])
 632 AC_ARG_ENABLE([gallium_egl],
 633     [AS_HELP_STRING([--enable-gallium-egl],
 634         [enable optional EGL state tracker (not required
 635          for EGL support in Gallium with OpenGL and OpenGL ES)
 636          @<:@default=disable@:>@])],
 637     [enable_gallium_egl="$enableval"],
 638     [enable_gallium_egl=no])
 639 AC_ARG_ENABLE([gallium_gbm],
 640     [AS_HELP_STRING([--enable-gallium-gbm],
 641         [enable optional gbm state tracker (not required for
 642          gbm support in Gallium)
 643          @<:@default=auto@:>@])],
 644     [enable_gallium_gbm="$enableval"],
 645     [enable_gallium_gbm=auto])
 646
 647 # Option for Gallium drivers
 648 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 649
 650 AC_ARG_WITH([gallium-drivers],
 651     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 652         [comma delimited Gallium drivers list, e.g.
 653         "i915,nouveau,r300,r600,svga,swrast"
 654         @<:@default=r300,r600,swrast@:>@])],
 655     [with_gallium_drivers="$withval"],
 656     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 657
 658 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 659 # here so that the script doesn't choke on an unknown driver name later.
 660 case "$with_gallium_drivers" in
 661     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 662     no) with_gallium_drivers='' ;;
 663 esac
 664
 665 if test "x$enable_opengl" = xno -a \
 666         "x$enable_gles1" = xno -a \
 667         "x$enable_gles2" = xno -a \
 668         "x$enable_openvg" = xno -a \
 669         "x$enable_xorg" = xno -a \
 670         "x$enable_xa" = xno -a \
 671         "x$enable_d3d1x" = xno -a \
 672         "x$enable_xvmc" = xno -a \
 673         "x$enable_vdpau" = xno -a \
 674         "x$enable_va" = xno; then
 675     AC_MSG_ERROR([at least one API should be enabled])
 676 fi
 677
 678 API_DEFINES=""
 679 if test "x$enable_opengl" = xno; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 681 else
 682     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 683 fi
 684 if test "x$enable_gles1" = xyes; then
 685     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 686 fi
 687 if test "x$enable_gles2" = xyes; then
 688     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 689 fi
 690 AC_SUBST([API_DEFINES])
 691
 692 AC_ARG_ENABLE([shared-glapi],
 693     [AS_HELP_STRING([--enable-shared-glapi],
 694         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 695     [enable_shared_glapi="$enableval"],
 696     [enable_shared_glapi=no])
 697
 698 SHARED_GLAPI="0"
 699 if test "x$enable_shared_glapi" = xyes; then
 700     SHARED_GLAPI="1"
 701     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 702     # the remap table)
 703     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 704 fi
 705 AC_SUBST([SHARED_GLAPI])
 706
 707 dnl
 708 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 709 dnl More later: fbdev, ...
 710 dnl
 711 default_driver="xlib"
 712
 713 case "$host_os" in
 714 linux*)
 715     case "$host_cpu" in
 716     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 717     esac
 718     ;;
 719 *freebsd* | dragonfly* | *netbsd*)
 720     case "$host_cpu" in
 721     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 722     esac
 723     ;;
 724 esac
 725
 726 if test "x$enable_opengl" = xno; then
 727     default_driver="no"
 728 fi
 729
 730 AC_ARG_WITH([driver],
 731     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 732     [mesa_driver="$withval"],
 733     [mesa_driver=auto])
 734 dnl Check for valid option
 735 case "x$mesa_driver" in
 736 xxlib|xdri|xosmesa|xno)
 737     if test "x$enable_dri" != xauto -o \
 738             "x$enable_glx" != xauto -o \
 739             "x$enable_osmesa" != xauto -o \
 740             "x$enable_xlib_glx" != xauto; then
 741         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 742     fi
 743     ;;
 744 xauto)
 745     mesa_driver="$default_driver"
 746     ;;
 747 *)
 748     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 749     ;;
 750 esac
 751
 752 # map $mesa_driver to APIs
 753 if test "x$enable_dri" = xauto; then
 754     case "x$mesa_driver" in
 755     xdri) enable_dri=yes ;;
 756     *)    enable_dri=no ;;
 757     esac
 758 fi
 759
 760 if test "x$enable_glx" = xauto; then
 761     case "x$mesa_driver" in
 762     xdri|xxlib) enable_glx=yes ;;
 763     *)          enable_glx=no ;;
 764     esac
 765 fi
 766
 767 if test "x$enable_osmesa" = xauto; then
 768     case "x$mesa_driver" in
 769     xxlib|xosmesa) enable_osmesa=yes ;;
 770     *)             enable_osmesa=no ;;
 771     esac
 772 fi
 773
 774 if test "x$enable_xlib_glx" = xauto; then
 775     case "x$mesa_driver" in
 776     xxlib) enable_xlib_glx=yes ;;
 777     *)     enable_xlib_glx=no ;;
 778     esac
 779 fi
 780
 781 if test "x$enable_glx" = xno; then
 782     enable_xlib_glx=no
 783 fi
 784
 785 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 786
 787 dnl
 788 dnl Driver specific build directories
 789 dnl
 790
 791 dnl this variable will be prepended to SRC_DIRS and is not exported
 792 CORE_DIRS=""
 793
 794 SRC_DIRS=""
 795 GLU_DIRS="sgi"
 796 GALLIUM_DIRS="auxiliary drivers state_trackers"
 797 GALLIUM_TARGET_DIRS=""
 798 GALLIUM_WINSYS_DIRS="sw"
 799 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 800 GALLIUM_STATE_TRACKERS_DIRS=""
 801
 802 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 803 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 804 x*yes*)
 805     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 806     ;;
 807 esac
 808
 809 # build glapi if OpenGL is enabled
 810 if test "x$enable_opengl" = xyes; then
 811     CORE_DIRS="$CORE_DIRS mapi/glapi"
 812 fi
 813
 814 # build es1api if OpenGL ES 1.x is enabled
 815 if test "x$enable_gles1" = xyes; then
 816     CORE_DIRS="$CORE_DIRS mapi/es1api"
 817 fi
 818
 819 # build es2api if OpenGL ES 2.x is enabled
 820 if test "x$enable_gles2" = xyes; then
 821     CORE_DIRS="$CORE_DIRS mapi/es2api"
 822 fi
 823
 824 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 825 case "x$enable_opengl$enable_gles1$enable_gles2" in
 826 x*yes*)
 827     CORE_DIRS="$CORE_DIRS glsl mesa"
 828     ;;
 829 esac
 830
 831 case "x$enable_glx$enable_xlib_glx" in
 832 xyesyes)
 833     DRIVER_DIRS="$DRIVER_DIRS x11"
 834     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 835     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 836     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 837     HAVE_WINSYS_XLIB="yes"
 838     ;;
 839 xyesno)
 840     # DRI-based GLX
 841     SRC_DIRS="$SRC_DIRS glx"
 842     ;;
 843 esac
 844
 845 if test "x$enable_dri" = xyes; then
 846     DRIVER_DIRS="$DRIVER_DIRS dri"
 847
 848     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 849     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 850     HAVE_ST_DRI="yes"
 851 fi
 852
 853 if test "x$enable_osmesa" = xyes; then
 854     # the empty space matters for osmesa... (see src/mesa/Makefile)
 855     if test -n "$DRIVER_DIRS"; then
 856         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 857     else
 858         DRIVER_DIRS="osmesa"
 859     fi
 860 fi
 861
 862 AC_SUBST([SRC_DIRS])
 863 AC_SUBST([GLU_DIRS])
 864 AC_SUBST([DRIVER_DIRS])
 865 AC_SUBST([GALLIUM_DIRS])
 866 AC_SUBST([GALLIUM_TARGET_DIRS])
 867 AC_SUBST([GALLIUM_WINSYS_DIRS])
 868 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 869 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 870 AC_SUBST([MESA_LLVM])
 871
 872 # Check for libdrm
 873 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 874                   [have_libdrm=yes], [have_libdrm=no])
 875
 876 if test "x$enable_dri" = xyes; then
 877     # DRI must be shared, I think
 878     if test "$enable_static" = yes; then
 879         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 880     fi
 881
 882     # not a hard requirement as swrast does not depend on it
 883     if test "x$have_libdrm" = xyes; then
 884         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 885     fi
 886 fi
 887
 888 dnl
 889 dnl Find out if X is available. The variable have_x is set if libX11 is
 890 dnl found to mimic AC_PATH_XTRA.
 891 dnl
 892 if test -n "$PKG_CONFIG"; then
 893     AC_MSG_CHECKING([pkg-config files for X11 are available])
 894     PKG_CHECK_EXISTS([x11],[
 895         x11_pkgconfig=yes
 896         have_x=yes
 897         ],[
 898         x11_pkgconfig=no
 899     ])
 900     AC_MSG_RESULT([$x11_pkgconfig])
 901 else
 902     x11_pkgconfig=no
 903 fi
 904 dnl Use the autoconf macro if no pkg-config files
 905 if test "$x11_pkgconfig" = yes; then
 906     PKG_CHECK_MODULES([X11], [x11])
 907 else
 908     AC_PATH_XTRA
 909     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 910     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 911     AC_SUBST([X11_CFLAGS])
 912     AC_SUBST([X11_LIBS])
 913 fi
 914
 915 dnl Try to tell the user that the --x-* options are only used when
 916 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 917 m4_divert_once([HELP_BEGIN],
 918 [These options are only used when the X libraries cannot be found by the
 919 pkg-config utility.])
 920
 921 dnl We need X for xlib and dri, so bomb now if it's not found
 922 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 923     AC_MSG_ERROR([X11 development libraries needed for GLX])
 924 fi
 925
 926 if test "x$enable_glx" = xyes; then
 927     DEFINES="$DEFINES -DUSE_XCB"
 928 fi
 929
 930 dnl Direct rendering or just indirect rendering
 931 case "$host_os" in
 932 gnu*)
 933     dnl Disable by default on GNU/Hurd
 934     driglx_direct_default="no"
 935     ;;
 936 cygwin*)
 937     dnl Disable by default on cygwin
 938     driglx_direct_default="no"
 939     ;;
 940 *)
 941     driglx_direct_default="yes"
 942     ;;
 943 esac
 944 AC_ARG_ENABLE([driglx-direct],
 945     [AS_HELP_STRING([--disable-driglx-direct],
 946         [enable direct rendering in GLX and EGL for DRI \
 947             @<:@default=auto@:>@])],
 948     [driglx_direct="$enableval"],
 949     [driglx_direct="$driglx_direct_default"])
 950
 951 dnl
 952 dnl libGL configuration per driver
 953 dnl
 954 case "x$enable_glx$enable_xlib_glx" in
 955 xyesyes)
 956     # Xlib-based GLX
 957     if test "$x11_pkgconfig" = yes; then
 958         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 959         GL_PC_REQ_PRIV="x11 xext"
 960         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 961         GL_LIB_DEPS="$XLIBGL_LIBS"
 962     else
 963         # should check these...
 964         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 965         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 966         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 967         GL_PC_CFLAGS="$X11_INCLUDES"
 968     fi
 969     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 970     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 971     ;;
 972 xyesno)
 973     # DRI-based GLX
 974     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 975     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 976     if test x"$driglx_direct" = xyes; then
 977         if test "x$have_libdrm" != xyes; then
 978             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 979         fi
 980         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 981         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 982     fi
 983
 984     # find the DRI deps for libGL
 985     if test "$x11_pkgconfig" = yes; then
 986         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 987
 988         # add xf86vidmode if available
 989         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 990         if test "$HAVE_XF86VIDMODE" = yes ; then
 991             dri_modules="$dri_modules xxf86vm"
 992         fi
 993
 994         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 995         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 996         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 997         GL_LIB_DEPS="$DRIGL_LIBS"
 998     else
 999         # should check these...
1000         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1001         if test "x$HAVE_XF86VIDMODE" == xyes; then
1002            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1003         else
1004            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1005         fi
1006         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1007         GL_PC_CFLAGS="$X11_INCLUDES"
1008
1009         # XCB can only be used from pkg-config
1010         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1011         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1012         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1013         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1014     fi
1015
1016     # Check to see if the xcb-glx library is new enough to support
1017     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1018     # is released.
1019     save_CPPFLAGS="$CPPFLAGS"
1020     save_LDFLAGS="$LDFLAGS"
1021     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1022     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1023     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1024         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1025         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1026     CPPFLAGS="$save_CPPFLAGS"
1027     LDFLAGS="$save_LDFLAGS"
1028
1029     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1030         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1031     fi
1032
1033     # need DRM libs, -lpthread, etc.
1034     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1035     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1036     ;;
1037 esac
1038
1039 # This is outside the case (above) so that it is invoked even for non-GLX
1040 # builds.
1041 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1042     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1043
1044 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1045 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1046 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1047 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1048
1049 AC_SUBST([GL_LIB_DEPS])
1050 AC_SUBST([GL_PC_REQ_PRIV])
1051 AC_SUBST([GL_PC_LIB_PRIV])
1052 AC_SUBST([GL_PC_CFLAGS])
1053 AC_SUBST([DRI_PC_REQ_PRIV])
1054 AC_SUBST([GLESv1_CM_LIB_DEPS])
1055 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1056 AC_SUBST([GLESv2_LIB_DEPS])
1057 AC_SUBST([GLESv2_PC_LIB_PRIV])
1058
1059 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1060 AC_SUBST([GLAPI_LIB_DEPS])
1061
1062
1063 dnl Setup default DRI CFLAGS
1064 DRI_CFLAGS='$(CFLAGS)'
1065 DRI_CXXFLAGS='$(CXXFLAGS)'
1066 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1067 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1068
1069 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1070     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1071     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1072     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1073     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1074     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1075     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1076     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1077 fi
1078 AC_SUBST([DRICORE_LIBS])
1079 AC_SUBST([DRICORE_GLSL_LIBS])
1080 AC_SUBST([DRICORE_LIB_DEPS])
1081 AC_SUBST([DRI_CXXFLAGS])
1082 AC_SUBST([DRI_CFLAGS])
1083 AC_SUBST([MESA_MODULES])
1084
1085 AC_SUBST([HAVE_XF86VIDMODE])
1086
1087 dnl
1088 dnl More GLX setup
1089 dnl
1090 case "x$enable_glx$enable_xlib_glx" in
1091 xyesyes)
1092     DEFINES="$DEFINES -DUSE_XSHM"
1093     ;;
1094 xyesno)
1095     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1096     if test "x$driglx_direct" = xyes; then
1097         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1098     fi
1099     ;;
1100 esac
1101
1102 dnl
1103 dnl TLS detection
1104 dnl
1105
1106 AC_ARG_ENABLE([glx-tls],
1107     [AS_HELP_STRING([--enable-glx-tls],
1108         [enable TLS support in GLX @<:@default=disabled@:>@])],
1109     [GLX_USE_TLS="$enableval"],
1110     [GLX_USE_TLS=no])
1111 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1112
1113 AS_IF([test "x$GLX_USE_TLS" = xyes],
1114       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1115
1116 dnl
1117 dnl More DRI setup
1118 dnl
1119 dnl Directory for DRI drivers
1120 AC_ARG_WITH([dri-driverdir],
1121     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1122         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1123     [DRI_DRIVER_INSTALL_DIR="$withval"],
1124     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1125 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1126 dnl Extra search path for DRI drivers
1127 AC_ARG_WITH([dri-searchpath],
1128     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1129         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1130     [DRI_DRIVER_SEARCH_DIR="$withval"],
1131     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1132 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1133 dnl Which drivers to build - default is chosen by platform
1134 AC_ARG_WITH([dri-drivers],
1135     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1136         [comma delimited DRI drivers list, e.g.
1137         "swrast,i965,radeon" @<:@default=auto@:>@])],
1138     [with_dri_drivers="$withval"],
1139     [with_dri_drivers=yes])
1140 if test "x$with_dri_drivers" = x; then
1141     with_dri_drivers=no
1142 fi
1143
1144 dnl If $with_dri_drivers is yes, directories will be added through
1145 dnl platform checks
1146 DRI_DIRS=""
1147 case "$with_dri_drivers" in
1148 no) ;;
1149 yes)
1150     # classic DRI drivers require FEATURE_GL to build
1151     if test "x$enable_opengl" = xyes; then
1152         DRI_DIRS="yes"
1153     fi
1154     ;;
1155 *)
1156     # verify the requested driver directories exist
1157     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1158     for driver in $dri_drivers; do
1159         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1160             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1161     done
1162     DRI_DIRS="$dri_drivers"
1163     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1164         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1165     fi
1166     ;;
1167 esac
1168
1169 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1170 if test "x$enable_dri" = xyes; then
1171     # Platform specific settings and drivers to build
1172     case "$host_os" in
1173     linux*)
1174         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1175         DEFINES="$DEFINES -DHAVE_ALIAS"
1176
1177         case "$host_cpu" in
1178         x86_64)
1179             if test "x$DRI_DIRS" = "xyes"; then
1180                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1181             fi
1182             ;;
1183         powerpc*)
1184             # Build only the drivers for cards that exist on PowerPC.
1185             if test "x$DRI_DIRS" = "xyes"; then
1186                 DRI_DIRS="r200 radeon swrast"
1187             fi
1188             ;;
1189         sparc*)
1190             # Build only the drivers for cards that exist on sparc
1191             if test "x$DRI_DIRS" = "xyes"; then
1192                 DRI_DIRS="r200 radeon swrast"
1193             fi
1194             ;;
1195         esac
1196         ;;
1197     freebsd* | dragonfly* | *netbsd*)
1198         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1199         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1200
1201         if test "x$DRI_DIRS" = "xyes"; then
1202             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1203         fi
1204         ;;
1205     gnu*)
1206         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1207         DEFINES="$DEFINES -DHAVE_ALIAS"
1208         ;;
1209     solaris*)
1210         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1211         ;;
1212     cygwin*)
1213         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1214         if test "x$DRI_DIRS" = "xyes"; then
1215             DRI_DIRS="swrast"
1216         fi
1217         ;;
1218     esac
1219
1220     # default drivers
1221     if test "x$DRI_DIRS" = "xyes"; then
1222         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1223     fi
1224
1225     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1226
1227     # Check for expat
1228     if test "x$enable_dri" = xyes; then
1229         EXPAT_INCLUDES=""
1230         EXPAT_LIB=-lexpat
1231         AC_ARG_WITH([expat],
1232             [AS_HELP_STRING([--with-expat=DIR],
1233                 [expat install directory])],[
1234             EXPAT_INCLUDES="-I$withval/include"
1235             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1236             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1237             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1238             ])
1239         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1240         save_LIBS="$LIBS"
1241         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1242             [AC_MSG_ERROR([Expat required for DRI.])])
1243         LIBS="$save_LIBS"
1244     fi
1245
1246     # if we are building any dri driver other than swrast ...
1247     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1248         # ... libdrm is required
1249         if test "x$have_libdrm" != xyes; then
1250             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1251         fi
1252         # ... and build dricommon
1253         HAVE_COMMON_DRI=yes
1254     fi
1255
1256     # put all the necessary libs together
1257     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1258 fi
1259 AC_SUBST([DRI_DIRS])
1260 AC_SUBST([EXPAT_INCLUDES])
1261 AC_SUBST([DRI_LIB_DEPS])
1262
1263 case $DRI_DIRS in
1264 *i915*|*i965*)
1265     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1266
1267     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1268         case $d in
1269         i915)
1270             HAVE_I915_DRI=yes;
1271             ;;
1272         i965)
1273             HAVE_I965_DRI=yes;
1274             ;;
1275         esac
1276     done
1277
1278     ;;
1279 esac
1280
1281 case $DRI_DIRS in
1282 *nouveau*)
1283     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1284     HAVE_NOUVEAU_DRI=yes;
1285     ;;
1286 esac
1287
1288 case $DRI_DIRS in
1289 *radeon*|*r200*)
1290     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1291
1292     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1293         case $d in
1294         radeon)
1295             HAVE_RADEON_DRI=yes;
1296             ;;
1297         r200)
1298             HAVE_R200_DRI=yes;
1299             ;;
1300         esac
1301     done
1302
1303     ;;
1304 esac
1305
1306 case $DRI_DIRS in
1307 *swrast*)
1308     HAVE_SWRAST_DRI=yes;
1309     ;;
1310 esac
1311
1312 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1313 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1314 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1315 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1316 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1317 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1318 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1319
1320 dnl
1321 dnl OSMesa configuration
1322 dnl
1323
1324 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1325 AC_ARG_WITH([osmesa-bits],
1326     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1327         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1328     [osmesa_bits="$withval"],
1329     [osmesa_bits=8])
1330 if test "x$osmesa_bits" != x8; then
1331     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1332         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1333         osmesa_bits=8
1334     fi
1335 fi
1336 case "x$osmesa_bits" in
1337 x8)
1338     OSMESA_LIB="${OSMESA_LIB}"
1339     ;;
1340 x16|x32)
1341     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1342     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1343     ;;
1344 *)
1345     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1346     ;;
1347 esac
1348
1349 if test "x$enable_osmesa" = xyes; then
1350     # only link libraries with osmesa if shared
1351     if test "$enable_static" = no; then
1352         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1353     else
1354         OSMESA_LIB_DEPS=""
1355     fi
1356     OSMESA_MESA_DEPS=""
1357     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1358 fi
1359 AC_SUBST([OSMESA_LIB_DEPS])
1360 AC_SUBST([OSMESA_MESA_DEPS])
1361 AC_SUBST([OSMESA_PC_REQ])
1362 AC_SUBST([OSMESA_PC_LIB_PRIV])
1363
1364 dnl
1365 dnl gbm configuration
1366 dnl
1367 if test "x$enable_gbm" = xauto; then
1368     case "$with_egl_platforms" in
1369         *drm*)
1370             enable_gbm=yes ;;
1371          *)
1372             enable_gbm=no ;;
1373     esac
1374 fi
1375 if test "x$enable_gbm" = xyes; then
1376     SRC_DIRS="$SRC_DIRS gbm"
1377
1378     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1379                       AC_MSG_ERROR([gbm needs udev]))
1380
1381     if test "x$enable_dri" = xyes; then
1382         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1383         if test "$SHARED_GLAPI" -eq 0; then
1384             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1385         fi
1386     fi
1387 fi
1388 GBM_PC_REQ_PRIV="libudev"
1389 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1390 AC_SUBST([GBM_PC_REQ_PRIV])
1391 AC_SUBST([GBM_PC_LIB_PRIV])
1392
1393 dnl
1394 dnl EGL configuration
1395 dnl
1396 EGL_CLIENT_APIS=""
1397
1398 if test "x$enable_egl" = xyes; then
1399     SRC_DIRS="$SRC_DIRS egl"
1400     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1401     EGL_DRIVERS_DIRS=""
1402
1403     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1404
1405     if test "$enable_static" != yes; then
1406         # build egl_glx when libGL is built
1407         if test "x$enable_glx" = xyes; then
1408             EGL_DRIVERS_DIRS="glx"
1409         fi
1410
1411         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1412                           [have_libudev=yes],[have_libudev=no])
1413         if test "$have_libudev" = yes; then
1414             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1415         fi
1416         if test "x$enable_dri" = xyes; then
1417             # build egl_dri2 when xcb-dri2 is available
1418             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1419                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1420
1421             if test "$have_xcb_dri2" = yes; then
1422                 EGL_DRIVER_DRI2=dri2
1423                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1424                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1425                 save_LIBS="$LIBS"
1426                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1427                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1428                 LIBS="$save_LIBS"
1429             fi
1430         fi
1431
1432         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1433     fi
1434 fi
1435 AC_SUBST([EGL_LIB_DEPS])
1436 AC_SUBST([EGL_DRIVERS_DIRS])
1437
1438 dnl
1439 dnl EGL Gallium configuration
1440 dnl
1441 if test "x$enable_gallium_egl" = xyes; then
1442     if test "x$with_gallium_drivers" = x; then
1443         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1444     fi
1445     if test "x$enable_egl" = xno; then
1446         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1447     fi
1448     if test "x$have_libdrm" != xyes; then
1449         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1450     fi
1451
1452     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1453     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1454     HAVE_ST_EGL="yes"
1455 fi
1456
1457 dnl
1458 dnl gbm Gallium configuration
1459 dnl
1460 if test "x$enable_gallium_gbm" = xauto; then
1461     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1462         yesyesyes*drm*)
1463             enable_gallium_gbm=yes ;;
1464          *)
1465             enable_gallium_gbm=no ;;
1466     esac
1467 fi
1468 if test "x$enable_gallium_gbm" = xyes; then
1469     if test "x$with_gallium_drivers" = x; then
1470         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1471     fi
1472     if test "x$enable_gbm" = xno; then
1473         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1474     fi
1475     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1476     if test "x$enable_dri" = xno; then
1477         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1478     fi
1479
1480     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1481     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1482     HAVE_ST_GBM="yes"
1483 fi
1484
1485 dnl
1486 dnl X.Org DDX configuration
1487 dnl
1488 if test "x$enable_xorg" = xyes; then
1489     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1490     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1491     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1492     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1493         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1494         HAVE_XEXTPROTO_71="no")
1495     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1496     HAVE_ST_XORG=yes
1497 fi
1498
1499 dnl
1500 dnl XA configuration
1501 dnl
1502 if test "x$enable_xa" = xyes; then
1503 AC_PROG_AWK
1504 AC_PROG_GREP
1505 AC_CHECK_PROG(NM, nm, "nm")
1506 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1507 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1508 enable_xa=no
1509 fi
1510 fi
1511 if test "x$enable_xa" = xyes; then
1512     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1513     HAVE_ST_XA=yes
1514     AC_SUBST(AWK)
1515     AC_SUBST(GREP)
1516     AC_SUBST(NM)
1517 fi
1518
1519 dnl
1520 dnl OpenVG configuration
1521 dnl
1522 VG_LIB_DEPS=""
1523
1524 if test "x$enable_openvg" = xyes; then
1525     if test "x$enable_egl" = xno; then
1526         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1527     fi
1528     if test "x$with_gallium_drivers" = x; then
1529         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1530     fi
1531     if test "x$enable_gallium_egl" = xno; then
1532         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1533     fi
1534
1535     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1536     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1537     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1538     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1539     HAVE_ST_VEGA=yes
1540 fi
1541
1542 dnl
1543 dnl D3D1X configuration
1544 dnl
1545
1546 if test "x$enable_d3d1x" = xyes; then
1547     if test "x$with_gallium_drivers" = x; then
1548         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1549     fi
1550
1551     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1552     HAVE_ST_D3D1X=yes
1553 fi
1554
1555 dnl
1556 dnl Gallium G3DVL configuration
1557 dnl
1558 AC_ARG_ENABLE([gallium-g3dvl],
1559     [AS_HELP_STRING([--enable-gallium-g3dvl],
1560         [build gallium g3dvl @<:@default=disabled@:>@])],
1561     [enable_gallium_g3dvl="$enableval"],
1562     [enable_gallium_g3dvl=no])
1563 if test "x$enable_gallium_g3dvl" = xyes; then
1564     if test "x$with_gallium_drivers" = x; then
1565         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1566     fi
1567
1568     if test "x$enable_xvmc" = xauto; then
1569         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1570     fi
1571
1572     if test "x$enable_vdpau" = xauto; then
1573         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1574     fi
1575
1576     if test "x$enable_va" = xauto; then
1577         #don't enable vaapi state tracker even if package exists
1578         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1579         enable_va=no
1580     fi
1581 fi
1582
1583 if test "x$enable_xvmc" = xyes; then
1584     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6])
1585     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg/xvmc"
1586     HAVE_ST_XVMC="yes"
1587 fi
1588
1589 if test "x$enable_vdpau" = xyes; then
1590     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1])
1591     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1592     HAVE_ST_VDPAU="yes"
1593 fi
1594
1595 if test "x$enable_va" = xyes; then
1596     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1])
1597     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1598     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1599     HAVE_ST_VA="yes"
1600 fi
1601
1602 dnl
1603 dnl GLU configuration
1604 dnl
1605 AC_ARG_ENABLE([glu],
1606     [AS_HELP_STRING([--disable-glu],
1607         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1608     [enable_glu="$enableval"],
1609     [enable_glu=yes])
1610
1611 if test "x$enable_glu" = xyes; then
1612     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1613         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1614         enable_glu=no
1615     fi
1616 fi
1617
1618 if test "x$enable_glu" = xyes; then
1619     SRC_DIRS="$SRC_DIRS glu"
1620
1621     if test "x$enable_glx" = xno; then
1622         # Link libGLU to libOSMesa instead of libGL
1623         GLU_LIB_DEPS=""
1624         GLU_PC_REQ="osmesa"
1625         if test "$enable_static" = no; then
1626             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1627         else
1628             GLU_MESA_DEPS=""
1629         fi
1630     else
1631         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1632         GLU_PC_REQ="gl"
1633         GLU_PC_LIB_PRIV="-lm"
1634         if test "$enable_static" = no; then
1635             GLU_LIB_DEPS="-lm"
1636             GLU_MESA_DEPS='-l$(GL_LIB)'
1637         else
1638             GLU_LIB_DEPS=""
1639             GLU_MESA_DEPS=""
1640         fi
1641     fi
1642 fi
1643 if test "$enable_static" = no; then
1644     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1645 fi
1646 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1647 AC_SUBST([GLU_LIB_DEPS])
1648 AC_SUBST([GLU_MESA_DEPS])
1649 AC_SUBST([GLU_PC_REQ])
1650 AC_SUBST([GLU_PC_REQ_PRIV])
1651 AC_SUBST([GLU_PC_LIB_PRIV])
1652 AC_SUBST([GLU_PC_CFLAGS])
1653
1654 AC_SUBST([PROGRAM_DIRS])
1655
1656 dnl
1657 dnl Gallium configuration
1658 dnl
1659 if test "x$with_gallium_drivers" != x; then
1660     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1661 fi
1662
1663 AC_SUBST([LLVM_CFLAGS])
1664 AC_SUBST([LLVM_LIBS])
1665 AC_SUBST([LLVM_LDFLAGS])
1666 AC_SUBST([LLVM_VERSION])
1667
1668 case "x$enable_opengl$enable_gles1$enable_gles2" in
1669 x*yes*)
1670     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1671     ;;
1672 esac
1673
1674 AC_SUBST([VG_LIB_DEPS])
1675 AC_SUBST([EGL_CLIENT_APIS])
1676
1677 AC_ARG_WITH([egl-platforms],
1678     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1679         [comma delimited native platforms libEGL supports, e.g.
1680         "x11,drm" @<:@default=auto@:>@])],
1681     [with_egl_platforms="$withval"],
1682     [with_egl_platforms=yes])
1683
1684 EGL_PLATFORMS=""
1685
1686 case "$with_egl_platforms" in
1687 yes)
1688     if test "x$enable_egl" = xyes; then
1689         EGL_PLATFORMS="x11"
1690     fi
1691     ;;
1692 *)
1693     if test "x$enable_egl" != xyes; then
1694         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1695     fi
1696     # verify the requested driver directories exist
1697     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1698     for plat in $egl_platforms; do
1699         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1700             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1701         if test "$plat" = "fbdev"; then
1702                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1703         fi
1704         if test "$plat" = "null"; then
1705                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1706         fi
1707         if test "$plat" = "wayland"; then
1708                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1709                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1710                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1711
1712                 m4_ifdef([WAYLAND_SCANNER_RULES],
1713                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1714         fi
1715         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1716                 AC_MSG_ERROR([EGL platform drm needs gbm])
1717         fi
1718         case "$plat$have_libudev" in
1719                 waylandno|drmno)
1720                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1721         esac
1722     done
1723     EGL_PLATFORMS="$egl_platforms"
1724     ;;
1725 esac
1726 AC_SUBST([EGL_PLATFORMS])
1727
1728 AC_ARG_WITH([egl-driver-dir],
1729     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1730                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1731     [EGL_DRIVER_INSTALL_DIR="$withval"],
1732     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1733 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1734
1735 AC_ARG_WITH([xorg-driver-dir],
1736     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1737                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1738     [XORG_DRIVER_INSTALL_DIR="$withval"],
1739     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1740 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1741
1742 AC_ARG_WITH([max-width],
1743     [AS_HELP_STRING([--with-max-width=N],
1744                     [Maximum framebuffer width (4096)])],
1745     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1746      AS_IF([test "${withval}" -gt "4096"],
1747            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1748 )
1749 AC_ARG_WITH([max-height],
1750     [AS_HELP_STRING([--with-max-height=N],
1751                     [Maximum framebuffer height (4096)])],
1752     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1753      AS_IF([test "${withval}" -gt "4096"],
1754            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1755 )
1756
1757 dnl
1758 dnl Gallium LLVM
1759 dnl
1760 AC_ARG_ENABLE([gallium-llvm],
1761     [AS_HELP_STRING([--enable-gallium-llvm],
1762         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1763     [enable_gallium_llvm="$enableval"],
1764     [enable_gallium_llvm=auto])
1765 if test "x$with_gallium_drivers" = x; then
1766     enable_gallium_llvm=no
1767 fi
1768 if test "x$enable_gallium_llvm" = xauto; then
1769     case "$host_cpu" in
1770     i*86|x86_64) enable_gallium_llvm=yes;;
1771     esac
1772 fi
1773 if test "x$enable_gallium_llvm" = xyes; then
1774     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1775
1776     if test "x$LLVM_CONFIG" != xno; then
1777         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1778         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1779         LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1780
1781         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1782         DEFINES="$DEFINES -D__STDC_CONSTANT_MACROS"
1783         MESA_LLVM=1
1784     else
1785         MESA_LLVM=0
1786     fi
1787 else
1788     MESA_LLVM=0
1789 fi
1790
1791 dnl Directory for VDPAU libs
1792 AC_ARG_WITH([vdpau-libdir],
1793     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1794         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1795     [VDPAU_LIB_INSTALL_DIR="$withval"],
1796     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1797 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1798
1799 dnl Directory for VA libs
1800 AC_ARG_WITH([va-libdir],
1801     [AS_HELP_STRING([--with-va-libdir=DIR],
1802         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1803     [VA_LIB_INSTALL_DIR="$withval"],
1804     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1805 AC_SUBST([VA_LIB_INSTALL_DIR])
1806
1807 dnl
1808 dnl Gallium helper functions
1809 dnl
1810 gallium_check_st() {
1811     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1812          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1813          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1814          if test "x$have_libdrm" != xyes; then
1815             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1816          fi
1817          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1818     fi
1819     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1820          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1821     fi
1822     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1823          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1824     fi
1825     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1826          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1827     fi
1828     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1829          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1830          NEED_G3DVL_DRI="yes"
1831     fi
1832     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1833          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1834          NEED_G3DVL_DRI="yes"
1835     fi
1836     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1837          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1838          NEED_G3DVL_DRI="yes"
1839     fi
1840 }
1841
1842 gallium_require_llvm() {
1843     if test "x$MESA_LLVM" = x0; then
1844         case "$host_cpu" in
1845         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1846         esac
1847     fi
1848 }
1849
1850 dnl Gallium drivers
1851 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1852 if test "x$with_gallium_drivers" != x; then
1853     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1854     for driver in $gallium_drivers; do
1855         case "x$driver" in
1856         xsvga)
1857             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1858             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1859             ;;
1860         xi915)
1861             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1862             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1863             if test "x$MESA_LLVM" = x1; then
1864                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1865             fi
1866             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1867             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1868             ;;
1869         xr300)
1870             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1871             gallium_require_llvm "Gallium R300"
1872             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1873             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1874             ;;
1875         xr600)
1876             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1877             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1878             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1879             ;;
1880         xnouveau)
1881             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1882             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50 nvc0"
1883             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1884             ;;
1885         xswrast)
1886             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1887             if test "x$MESA_LLVM" = x1; then
1888                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1889             fi
1890
1891             if test "x$HAVE_ST_DRI" = xyes; then
1892                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1893             fi
1894             if test "x$HAVE_ST_VDPAU" = xyes; then
1895                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1896             fi
1897             if test "x$HAVE_ST_XVMC" = xyes; then
1898                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1899             fi
1900             if test "x$HAVE_ST_VA" = xyes; then
1901                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1902             fi
1903             if test "x$HAVE_ST_VDPAU" = xyes ||
1904                test "x$HAVE_ST_XVMC" = xyes ||
1905                test "x$HAVE_ST_VA" = xyes; then
1906                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1907                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1908                fi
1909             fi
1910             ;;
1911         *)
1912             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1913             ;;
1914         esac
1915     done
1916 fi
1917
1918 if test "x$NEED_G3DVL_DRI" = xyes; then
1919     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS g3dvl/dri"
1920 fi
1921
1922 dnl prepend CORE_DIRS to SRC_DIRS
1923 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1924
1925 dnl Restore LDFLAGS and CPPFLAGS
1926 LDFLAGS="$_SAVE_LDFLAGS"
1927 CPPFLAGS="$_SAVE_CPPFLAGS"
1928
1929 dnl Add user CFLAGS and CXXFLAGS
1930 CFLAGS="$CFLAGS $USER_CFLAGS"
1931 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1932
1933 dnl Substitute the config
1934 AC_CONFIG_FILES([configs/autoconf
1935                 src/gbm/Makefile
1936                 src/gbm/main/gbm.pc
1937                 src/egl/wayland/Makefile
1938                 src/egl/wayland/wayland-egl/Makefile
1939                 src/egl/wayland/wayland-egl/wayland-egl.pc
1940                 src/egl/wayland/wayland-drm/Makefile
1941                 src/mesa/drivers/dri/dri.pc
1942                 src/mesa/drivers/dri/Makefile
1943                 src/mesa/drivers/dri/common/Makefile
1944                 src/mesa/drivers/dri/i915/Makefile
1945                 src/mesa/drivers/dri/i965/Makefile
1946                 src/mesa/drivers/dri/nouveau/Makefile
1947                 src/mesa/drivers/dri/r200/Makefile
1948                 src/mesa/drivers/dri/radeon/Makefile
1949                 src/mesa/drivers/dri/swrast/Makefile
1950                 tests/Makefile
1951                 tests/glx/Makefile])
1952
1953 dnl Replace the configs/current symlink
1954 AC_CONFIG_COMMANDS([configs],[
1955 if test -f configs/current || test -L configs/current; then
1956     rm -f configs/current
1957 fi
1958 ln -s autoconf configs/current
1959 ])
1960
1961 dnl Sort the dirs alphabetically
1962 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1963 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1964 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1965 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1966
1967 AC_OUTPUT
1968
1969 dnl
1970 dnl Output some configuration info for the user
1971 dnl
1972 echo ""
1973 echo "        prefix:          $prefix"
1974 echo "        exec_prefix:     $exec_prefix"
1975 echo "        libdir:          $libdir"
1976 echo "        includedir:      $includedir"
1977
1978 dnl API info
1979 echo ""
1980 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1981 echo "        OpenVG:          $enable_openvg"
1982
1983 dnl Driver info
1984 echo ""
1985 if test "x$enable_osmesa" != xno; then
1986         echo "        OSMesa:          lib$OSMESA_LIB"
1987 else
1988         echo "        OSMesa:          no"
1989 fi
1990
1991 if test "x$enable_dri" != xno; then
1992         # cleanup the drivers var
1993         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1994         if test "x$DRI_DIRS" = x; then
1995             echo "        DRI drivers:     no"
1996         else
1997             echo "        DRI drivers:     $dri_dirs"
1998         fi
1999         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2000 fi
2001
2002 case "x$enable_glx$enable_xlib_glx" in
2003 xyesyes)
2004     echo "        GLX:             Xlib-based"
2005     ;;
2006 xyesno)
2007     echo "        GLX:             DRI-based"
2008     ;;
2009 *)
2010     echo "        GLX:             $enable_glx"
2011     ;;
2012 esac
2013
2014 echo ""
2015 echo "        GLU:             $enable_glu"
2016
2017 dnl EGL
2018 echo ""
2019 echo "        EGL:             $enable_egl"
2020 if test "$enable_egl" = yes; then
2021     echo "        EGL platforms:   $EGL_PLATFORMS"
2022
2023     egl_drivers=""
2024     for d in $EGL_DRIVERS_DIRS; do
2025         egl_drivers="$egl_drivers builtin:egl_$d"
2026     done
2027
2028     if test "x$HAVE_ST_EGL" = xyes; then
2029         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2030         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2031     else
2032         echo "        EGL drivers:    $egl_drivers"
2033     fi
2034 fi
2035
2036 echo ""
2037 if test "x$MESA_LLVM" = x1; then
2038     echo "        llvm:            yes"
2039     echo "        llvm-config:     $LLVM_CONFIG"
2040     echo "        llvm-version:    $LLVM_VERSION"
2041 else
2042     echo "        llvm:            no"
2043 fi
2044
2045 echo ""
2046 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2047     echo "        Gallium:         yes"
2048     echo "        Gallium dirs:    $GALLIUM_DIRS"
2049     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2050     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2051     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2052     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2053 else
2054     echo "        Gallium:         no"
2055 fi
2056
2057
2058 dnl Libraries
2059 echo ""
2060 echo "        Shared libs:     $enable_shared"
2061 echo "        Static libs:     $enable_static"
2062
2063 dnl Compiler options
2064 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2065 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2066     $SED 's/^ *//;s/  */ /;s/ *$//'`
2067 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2068     $SED 's/^ *//;s/  */ /;s/ *$//'`
2069 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2070 echo ""
2071 echo "        CFLAGS:          $cflags"
2072 echo "        CXXFLAGS:        $cxxflags"
2073 echo "        Macros:          $defines"
2074 echo ""
2075 echo "        PYTHON2:         $PYTHON2"
2076
2077 echo ""
2078 echo "        Run '${MAKE-make}' to build Mesa"
2079 echo ""