configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_HOST
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 LT_PREREQ([2.2])
  28 LT_INIT([disable-static])
  29
  30 dnl Set internal versions
  31 OSMESA_VERSION=8
  32 AC_SUBST([OSMESA_VERSION])
  33
  34 dnl Versions for external dependencies
  35 LIBDRM_REQUIRED=2.4.24
  36 LIBDRM_RADEON_REQUIRED=2.4.39
  37 LIBDRM_INTEL_REQUIRED=2.4.38
  38 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  39 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55 AC_PATH_PROG([MKDEP], [makedepend])
  56
  57 if test "x$MKDEP" = "x"; then
  58     AC_MSG_ERROR([makedepend is required to build Mesa])
  59 fi
  60
  61 AC_PROG_YACC
  62 AC_PATH_PROG([YACC_INST], $YACC)
  63 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  64     if test -z "$YACC_INST"; then
  65         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  66     fi
  67 fi
  68 AC_PROG_LEX
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  75 fi
  76
  77 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  78 dnl configuration in that case.
  79 AC_PROG_INSTALL
  80 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  81
  82 dnl We need a POSIX shell for parts of the build. Assume we have one
  83 dnl in most cases.
  84 case "$host_os" in
  85 solaris*)
  86     # Solaris /bin/sh is too old/non-POSIX compliant
  87     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  88     SHELL="$POSIX_SHELL"
  89     ;;
  90 esac
  91
  92 dnl clang is mostly GCC-compatible, but its version is much lower,
  93 dnl so we have to check for it.
  94 AC_MSG_CHECKING([if compiling with clang])
  95
  96 AC_COMPILE_IFELSE(
  97 [AC_LANG_PROGRAM([], [[
  98 #ifndef __clang__
  99        not clang
 100 #endif
 101 ]])],
 102 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 103
 104 AC_MSG_RESULT([$acv_mesa_CLANG])
 105
 106 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 107 dnl versions are explictly not supported.
 108 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 109     AC_MSG_CHECKING([whether gcc version is sufficient])
 110     major=0
 111     minor=0
 112
 113     GCC_VERSION=`$CC -dumpversion`
 114     if test $? -eq 0; then
 115         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 116         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 117     fi
 118
 119     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 120         AC_MSG_RESULT([no])
 121         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 122     else
 123         AC_MSG_RESULT([yes])
 124     fi
 125 fi
 126
 127
 128 MKDEP_OPTIONS=-fdepend
 129 dnl Ask gcc where it's keeping its secret headers
 130 if test "x$GCC" = xyes; then
 131     for dir in include include-fixed; do
 132         GCC_INCLUDES=`$CC -print-file-name=$dir`
 133         if test "x$GCC_INCLUDES" != x && \
 134            test "$GCC_INCLUDES" != "$dir" && \
 135            test -d "$GCC_INCLUDES"; then
 136             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 137         fi
 138     done
 139 fi
 140 AC_SUBST([MKDEP_OPTIONS])
 141
 142 dnl Make sure the pkg-config macros are defined
 143 m4_ifndef([PKG_PROG_PKG_CONFIG],
 144     [m4_fatal([Could not locate the pkg-config autoconf macros.
 145   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 146   are in a different location, try setting the environment variable
 147   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 148 PKG_PROG_PKG_CONFIG()
 149
 150 dnl LIB_DIR - library basename
 151 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 152 AC_SUBST([LIB_DIR])
 153
 154 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 155 _SAVE_LDFLAGS="$LDFLAGS"
 156 _SAVE_CPPFLAGS="$CPPFLAGS"
 157
 158 dnl Compiler macros
 159 DEFINES=""
 160 AC_SUBST([DEFINES])
 161 case "$host_os" in
 162 linux*|*-gnu*|gnu*)
 163     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 164     ;;
 165 solaris*)
 166     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 167     ;;
 168 cygwin*)
 169     DEFINES="$DEFINES -DPTHREADS"
 170     ;;
 171 esac
 172
 173 dnl Add flags for gcc and g++
 174 if test "x$GCC" = xyes; then
 175     CFLAGS="$CFLAGS -Wall -std=c99"
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Hacks to enable 32 or 64 bit build
 246 dnl
 247 AC_ARG_ENABLE([32-bit],
 248     [AS_HELP_STRING([--enable-32-bit],
 249         [build 32-bit libraries @<:@default=auto@:>@])],
 250     [enable_32bit="$enableval"],
 251     [enable_32bit=auto]
 252 )
 253 if test "x$enable_32bit" = xyes; then
 254     if test "x$GCC" = xyes; then
 255         CFLAGS="$CFLAGS -m32"
 256         CCASFLAGS="$CCASFLAGS -m32"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m32"
 260     fi
 261 fi
 262 AC_ARG_ENABLE([64-bit],
 263     [AS_HELP_STRING([--enable-64-bit],
 264         [build 64-bit libraries @<:@default=auto@:>@])],
 265     [enable_64bit="$enableval"],
 266     [enable_64bit=auto]
 267 )
 268 if test "x$enable_64bit" = xyes; then
 269     if test "x$GCC" = xyes; then
 270         CFLAGS="$CFLAGS -m64"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m64"
 274     fi
 275 fi
 276
 277 dnl Can't have static and shared libraries, default to static if user
 278 dnl explicitly requested. If both disabled, set to static since shared
 279 dnl was explicitly requested.
 280 case "x$enable_static$enable_shared" in
 281 xyesyes )
 282     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 283     enable_shared=no
 284     ;;
 285 xnono )
 286     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 287     enable_static=yes
 288     ;;
 289 esac
 290
 291 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 292
 293 dnl
 294 dnl mklib options
 295 dnl
 296 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 297 if test "$enable_static" = yes; then
 298     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 299 fi
 300 AC_SUBST([MKLIB_OPTIONS])
 301
 302 dnl
 303 dnl other compiler options
 304 dnl
 305 AC_ARG_ENABLE([debug],
 306     [AS_HELP_STRING([--enable-debug],
 307         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 308     [enable_debug="$enableval"],
 309     [enable_debug=no]
 310 )
 311 if test "x$enable_debug" = xyes; then
 312     DEFINES="$DEFINES -DDEBUG"
 313     if test "x$GCC" = xyes; then
 314         CFLAGS="$CFLAGS -g"
 315     fi
 316     if test "x$GXX" = xyes; then
 317         CXXFLAGS="$CXXFLAGS -g"
 318     fi
 319 fi
 320
 321 dnl
 322 dnl library names
 323 dnl
 324 LIB_PREFIX_GLOB='lib'
 325 LIB_VERSION_SEPARATOR='.'
 326 if test "$enable_static" = yes; then
 327     LIB_EXTENSION='a'
 328 else
 329     case "$host_os" in
 330     darwin* )
 331         LIB_EXTENSION='dylib' ;;
 332     cygwin* )
 333         dnl prefix can be 'cyg' or 'lib'
 334         LIB_PREFIX_GLOB='???'
 335         LIB_VERSION_SEPARATOR='-'
 336         LIB_EXTENSION='dll' ;;
 337     aix* )
 338         LIB_EXTENSION='a' ;;
 339     * )
 340         LIB_EXTENSION='so' ;;
 341     esac
 342 fi
 343 AC_ARG_WITH([gl-lib-name],
 344   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 345     [specify GL library name @<:@default=GL@:>@])],
 346   [GL_LIB=$withval],
 347   [GL_LIB=GL])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 355
 356 dnl
 357 dnl Mangled Mesa support
 358 dnl
 359 AC_ARG_ENABLE([mangling],
 360   [AS_HELP_STRING([--enable-mangling],
 361     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 362   [enable_mangling="${enableval}"],
 363   [enable_mangling=no]
 364 )
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="Mangled${GL_LIB}"
 368   OSMESA_LIB="Mangled${OSMESA_LIB}"
 369 fi
 370 AC_SUBST([GL_LIB])
 371 AC_SUBST([OSMESA_LIB])
 372
 373 dnl
 374 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 375 dnl
 376 AC_ARG_ENABLE([texture-float],
 377     [AS_HELP_STRING([--enable-texture-float],
 378         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 379     [enable_texture_float="$enableval"],
 380     [enable_texture_float=no]
 381 )
 382 if test "x$enable_texture_float" = xyes; then
 383     AC_MSG_WARN([Floating-point textures enabled.])
 384     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 385     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 386 fi
 387
 388 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 389 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 390 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 391 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 392 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 393 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 394 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 395
 396 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 397 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 398 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 399 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 400 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403
 404 AC_SUBST([GL_LIB_NAME])
 405 AC_SUBST([OSMESA_LIB_NAME])
 406 AC_SUBST([EGL_LIB_NAME])
 407 AC_SUBST([GLESv1_CM_LIB_NAME])
 408 AC_SUBST([GLESv2_LIB_NAME])
 409 AC_SUBST([VG_LIB_NAME])
 410 AC_SUBST([GLAPI_LIB_NAME])
 411
 412 AC_SUBST([GL_LIB_GLOB])
 413 AC_SUBST([EGL_LIB_GLOB])
 414 AC_SUBST([GLESv1_CM_LIB_GLOB])
 415 AC_SUBST([GLESv2_LIB_GLOB])
 416 AC_SUBST([VG_LIB_GLOB])
 417 AC_SUBST([GLAPI_LIB_GLOB])
 418
 419 dnl
 420 dnl Arch/platform-specific settings
 421 dnl
 422 AC_ARG_ENABLE([asm],
 423     [AS_HELP_STRING([--disable-asm],
 424         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 425     [enable_asm="$enableval"],
 426     [enable_asm=yes]
 427 )
 428 asm_arch=""
 429 MESA_ASM_FILES=""
 430 AC_MSG_CHECKING([whether to enable assembly])
 431 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 432 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 433 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 434     case "$host_cpu" in
 435     i?86 | x86_64)
 436         enable_asm=no
 437         AC_MSG_RESULT([no, cross compiling])
 438         ;;
 439     esac
 440 fi
 441 # check for supported arches
 442 if test "x$enable_asm" = xyes; then
 443     case "$host_cpu" in
 444     i?86)
 445         case "$host_os" in
 446         linux* | *freebsd* | dragonfly* | *netbsd*)
 447             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 448             ;;
 449         esac
 450         ;;
 451     x86_64)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 455             ;;
 456         esac
 457         ;;
 458     sparc*)
 459         case "$host_os" in
 460         linux*)
 461             asm_arch=sparc
 462             ;;
 463         esac
 464         ;;
 465     esac
 466
 467     case "$asm_arch" in
 468     x86)
 469         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 470         MESA_ASM_FILES='$(X86_FILES)'
 471         AC_MSG_RESULT([yes, x86])
 472         ;;
 473     x86_64)
 474         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 475         MESA_ASM_FILES='$(X86_64_FILES)'
 476         AC_MSG_RESULT([yes, x86_64])
 477         ;;
 478     sparc)
 479         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 480         MESA_ASM_FILES='$(SPARC_FILES)'
 481         AC_MSG_RESULT([yes, sparc])
 482         ;;
 483     *)
 484         AC_MSG_RESULT([no, platform not supported])
 485         ;;
 486     esac
 487 fi
 488 AC_SUBST([MESA_ASM_FILES])
 489
 490 dnl PIC code macro
 491 MESA_PIC_FLAGS
 492
 493 dnl Check to see if dlopen is in default libraries (like Solaris, which
 494 dnl has it in libc), or if libdl is needed to get it.
 495 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 496     [AC_CHECK_LIB([dl], [dlopen],
 497        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 498 AC_SUBST([DLOPEN_LIBS])
 499
 500 dnl See if posix_memalign is available
 501 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 502
 503 dnl signbit() is a macro in glibc's math.h, so AC_CHECK_FUNC fails. To handle
 504 dnl this, use AC_CHECK_DECLS and fallback to AC_CHECK_FUNC in case it fails.
 505 AC_CHECK_DECLS([signbit],[],
 506                AC_CHECK_FUNC([signbit],[],
 507                              AC_MSG_ERROR([could not find signbit()])),
 508                [#include <math.h>])
 509
 510 dnl Check for pthreads
 511 AX_PTHREAD
 512
 513 dnl SELinux awareness.
 514 AC_ARG_ENABLE([selinux],
 515     [AS_HELP_STRING([--enable-selinux],
 516         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 517     [MESA_SELINUX="$enableval"],
 518     [MESA_SELINUX=no])
 519 if test "x$enable_selinux" = "xyes"; then
 520     AC_CHECK_HEADER([selinux/selinux.h],[],
 521                     [AC_MSG_ERROR([SELinux headers not found])])
 522     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 523                  [AC_MSG_ERROR([SELinux library not found])])
 524     SELINUX_LIBS="-lselinux"
 525     DEFINES="$DEFINES -DMESA_SELINUX"
 526 fi
 527 AC_SUBST([SELINUX_LIBS])
 528
 529 dnl Options for APIs
 530 AC_ARG_ENABLE([opengl],
 531     [AS_HELP_STRING([--disable-opengl],
 532         [disable support for standard OpenGL API @<:@default=no@:>@])],
 533     [enable_opengl="$enableval"],
 534     [enable_opengl=yes])
 535 AC_ARG_ENABLE([gles1],
 536     [AS_HELP_STRING([--enable-gles1],
 537         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 538     [enable_gles1="$enableval"],
 539     [enable_gles1=no])
 540 AC_ARG_ENABLE([gles2],
 541     [AS_HELP_STRING([--enable-gles2],
 542         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 543     [enable_gles2="$enableval"],
 544     [enable_gles2=no])
 545 AC_ARG_ENABLE([openvg],
 546     [AS_HELP_STRING([--enable-openvg],
 547         [enable support for OpenVG API @<:@default=no@:>@])],
 548     [enable_openvg="$enableval"],
 549     [enable_openvg=no])
 550
 551 AC_ARG_ENABLE([dri],
 552     [AS_HELP_STRING([--enable-dri],
 553         [enable DRI modules @<:@default=enabled@:>@])],
 554     [enable_dri="$enableval"],
 555     [enable_dri=yes])
 556 AC_ARG_ENABLE([glx],
 557     [AS_HELP_STRING([--enable-glx],
 558         [enable GLX library @<:@default=enabled@:>@])],
 559     [enable_glx="$enableval"],
 560     [enable_glx=yes])
 561 AC_ARG_ENABLE([osmesa],
 562     [AS_HELP_STRING([--enable-osmesa],
 563         [enable OSMesa library @<:@default=disabled@:>@])],
 564     [enable_osmesa="$enableval"],
 565     [enable_osmesa=no])
 566 AC_ARG_ENABLE([egl],
 567     [AS_HELP_STRING([--disable-egl],
 568         [disable EGL library @<:@default=enabled@:>@])],
 569     [enable_egl="$enableval"],
 570     [enable_egl=yes])
 571
 572 AC_ARG_ENABLE([xorg],
 573     [AS_HELP_STRING([--enable-xorg],
 574         [enable support for X.Org DDX API @<:@default=no@:>@])],
 575     [enable_xorg="$enableval"],
 576     [enable_xorg=no])
 577 AC_ARG_ENABLE([xa],
 578     [AS_HELP_STRING([--enable-xa],
 579         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 580     [enable_xa="$enableval"],
 581     [enable_xa=no])
 582 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 583 enable_d3d1x=no
 584 dnl AC_ARG_ENABLE([d3d1x],
 585 dnl     [AS_HELP_STRING([--enable-d3d1x],
 586 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 587 dnl     [enable_d3d1x="$enableval"],
 588 dnl     [enable_d3d1x=no])
 589 AC_ARG_ENABLE([gbm],
 590    [AS_HELP_STRING([--enable-gbm],
 591          [enable gbm library @<:@default=auto@:>@])],
 592    [enable_gbm="$enableval"],
 593    [enable_gbm=auto])
 594
 595 AC_ARG_ENABLE([xvmc],
 596    [AS_HELP_STRING([--enable-xvmc],
 597          [enable xvmc library @<:@default=auto@:>@])],
 598    [enable_xvmc="$enableval"],
 599    [enable_xvmc=auto])
 600 AC_ARG_ENABLE([vdpau],
 601    [AS_HELP_STRING([--enable-vdpau],
 602          [enable vdpau library @<:@default=auto@:>@])],
 603    [enable_vdpau="$enableval"],
 604    [enable_vdpau=auto])
 605 AC_ARG_ENABLE([va],
 606    [AS_HELP_STRING([--enable-va],
 607          [enable va library @<:@default=auto@:>@])],
 608    [enable_va="$enableval"],
 609    [enable_va=auto])
 610 AC_ARG_ENABLE([opencl],
 611    [AS_HELP_STRING([--enable-opencl],
 612          [enable OpenCL library @<:@default=no@:>@])],
 613    [enable_opencl="$enableval"],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=no])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 649
 650 AC_ARG_WITH([gallium-drivers],
 651     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 652         [comma delimited Gallium drivers list, e.g.
 653         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 654         @<:@default=r300,r600,swrast@:>@])],
 655     [with_gallium_drivers="$withval"],
 656     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 657
 658 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 659 # here so that the script doesn't choke on an unknown driver name later.
 660 case "$with_gallium_drivers" in
 661     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 662     no) with_gallium_drivers='' ;;
 663 esac
 664
 665 if test "x$enable_opengl" = xno -a \
 666         "x$enable_gles1" = xno -a \
 667         "x$enable_gles2" = xno -a \
 668         "x$enable_openvg" = xno -a \
 669         "x$enable_xorg" = xno -a \
 670         "x$enable_xa" = xno -a \
 671         "x$enable_d3d1x" = xno -a \
 672         "x$enable_xvmc" = xno -a \
 673         "x$enable_vdpau" = xno -a \
 674         "x$enable_va" = xno -a \
 675         "x$enable_opencl" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 API_DEFINES=""
 680 if test "x$enable_opengl" = xno; then
 681     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 682 else
 683     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 684 fi
 685 if test "x$enable_gles1" = xyes; then
 686     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 687 fi
 688 if test "x$enable_gles2" = xyes; then
 689     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 690 fi
 691 AC_SUBST([API_DEFINES])
 692
 693 if test "x$enable_glx" = xno; then
 694     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 695     enable_xlib_glx=no
 696 fi
 697
 698 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 699     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 700 fi
 701
 702 # Disable GLX if DRI and Xlib-GLX are not enabled
 703 if test "x$enable_glx" = xyes -a \
 704         "x$enable_dri" = xno -a \
 705         "x$enable_xlib_glx" = xno; then
 706     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 707     enable_glx=no
 708 fi
 709
 710 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 711 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 712                                   "x$enable_osmesa" = xyes)
 713
 714 AC_ARG_ENABLE([shared-glapi],
 715     [AS_HELP_STRING([--enable-shared-glapi],
 716         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 717     [enable_shared_glapi="$enableval"],
 718     [enable_shared_glapi="$enable_dri"])
 719
 720 # Shared GLAPI is only useful for DRI
 721 if test "x$enable_dri" = xno; then
 722     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 723     enable_shared_glapi=no
 724 fi
 725
 726 # TODO: Get rid of SHARED_GLAPI variable
 727 SHARED_GLAPI="0"
 728 if test "x$enable_shared_glapi" = xyes; then
 729     SHARED_GLAPI="1"
 730     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 731     # the remap table)
 732     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 733     CORE_DIRS="mapi/shared-glapi"
 734 fi
 735 AC_SUBST([SHARED_GLAPI])
 736 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 737
 738 dnl
 739 dnl Driver specific build directories
 740 dnl
 741 SRC_DIRS="gtest"
 742 GALLIUM_DIRS="auxiliary drivers state_trackers"
 743 GALLIUM_TARGET_DIRS=""
 744 GALLIUM_WINSYS_DIRS="sw"
 745 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 746 GALLIUM_STATE_TRACKERS_DIRS=""
 747
 748 # build glapi if OpenGL is enabled
 749 if test "x$enable_opengl" = xyes; then
 750     CORE_DIRS="$CORE_DIRS mapi/glapi"
 751 fi
 752
 753 # build es1api if OpenGL ES 1.x is enabled
 754 if test "x$enable_gles1" = xyes; then
 755     CORE_DIRS="$CORE_DIRS mapi/es1api"
 756 fi
 757
 758 # build es2api if OpenGL ES 2.x is enabled
 759 if test "x$enable_gles2" = xyes; then
 760     CORE_DIRS="$CORE_DIRS mapi/es2api"
 761 fi
 762
 763 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 764 case "x$enable_opengl$enable_gles1$enable_gles2" in
 765 x*yes*)
 766     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 767     ;;
 768 esac
 769
 770 case "x$enable_glx$enable_xlib_glx" in
 771 xyesyes)
 772     DRIVER_DIRS="$DRIVER_DIRS x11"
 773     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 774     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 775     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 776     HAVE_WINSYS_XLIB="yes"
 777     ;;
 778 xyesno)
 779     # DRI-based GLX
 780     SRC_DIRS="$SRC_DIRS glx"
 781     ;;
 782 esac
 783
 784 if test "x$enable_dri" = xyes; then
 785     DRIVER_DIRS="$DRIVER_DIRS dri"
 786
 787     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 788     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 789     HAVE_ST_DRI="yes"
 790 fi
 791
 792 if test "x$enable_osmesa" = xyes; then
 793     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 794 fi
 795
 796 AC_SUBST([SRC_DIRS])
 797 AC_SUBST([DRIVER_DIRS])
 798 AC_SUBST([GALLIUM_DIRS])
 799 AC_SUBST([GALLIUM_TARGET_DIRS])
 800 AC_SUBST([GALLIUM_WINSYS_DIRS])
 801 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 802 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 803 AC_SUBST([MESA_LLVM])
 804
 805 # Check for libdrm
 806 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 807                   [have_libdrm=yes], [have_libdrm=no])
 808
 809 if test "x$enable_dri" = xyes; then
 810     # DRI must be shared, I think
 811     if test "$enable_static" = yes; then
 812         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 813     fi
 814
 815     # not a hard requirement as swrast does not depend on it
 816     if test "x$have_libdrm" = xyes; then
 817         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 818     fi
 819 fi
 820
 821 dnl Find out if X is available.
 822 PKG_CHECK_MODULES([X11], [x11])
 823
 824 dnl Try to tell the user that the --x-* options are only used when
 825 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 826 m4_divert_once([HELP_BEGIN],
 827 [These options are only used when the X libraries cannot be found by the
 828 pkg-config utility.])
 829
 830 dnl We need X for xlib and dri, so bomb now if it's not found
 831 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 832     AC_MSG_ERROR([X11 development libraries needed for GLX])
 833 fi
 834
 835 if test "x$enable_glx" = xyes; then
 836     DEFINES="$DEFINES -DUSE_XCB"
 837 fi
 838
 839 dnl Direct rendering or just indirect rendering
 840 case "$host_os" in
 841 gnu*)
 842     dnl Disable by default on GNU/Hurd
 843     driglx_direct_default="no"
 844     ;;
 845 cygwin*)
 846     dnl Disable by default on cygwin
 847     driglx_direct_default="no"
 848     ;;
 849 *)
 850     driglx_direct_default="yes"
 851     ;;
 852 esac
 853 AC_ARG_ENABLE([driglx-direct],
 854     [AS_HELP_STRING([--disable-driglx-direct],
 855         [enable direct rendering in GLX and EGL for DRI \
 856             @<:@default=auto@:>@])],
 857     [driglx_direct="$enableval"],
 858     [driglx_direct="$driglx_direct_default"])
 859
 860 dnl
 861 dnl libGL configuration per driver
 862 dnl
 863 case "x$enable_glx$enable_xlib_glx" in
 864 xyesyes)
 865     # Xlib-based GLX
 866     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 867     GL_PC_REQ_PRIV="x11 xext"
 868     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 869     GL_LIB_DEPS="$XLIBGL_LIBS"
 870     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 871     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 872     ;;
 873 xyesno)
 874     # DRI-based GLX
 875     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 876     if test x"$driglx_direct" = xyes; then
 877         if test "x$have_libdrm" != xyes; then
 878             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 879         fi
 880         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 881         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 882     fi
 883
 884     # find the DRI deps for libGL
 885     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 886
 887     # add xf86vidmode if available
 888     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 889     if test "$HAVE_XF86VIDMODE" = yes ; then
 890         dri_modules="$dri_modules xxf86vm"
 891     fi
 892
 893     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 894     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 895     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 896     GL_LIB_DEPS="$DRIGL_LIBS"
 897
 898     # need DRM libs, -lpthread, etc.
 899     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 900     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 901     ;;
 902 esac
 903
 904 # This is outside the case (above) so that it is invoked even for non-GLX
 905 # builds.
 906 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 907
 908 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 909 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 910 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 911 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 912
 913 AC_SUBST([X11_INCLUDES])
 914 AC_SUBST([GL_LIB_DEPS])
 915 AC_SUBST([GL_PC_REQ_PRIV])
 916 AC_SUBST([GL_PC_LIB_PRIV])
 917 AC_SUBST([GL_PC_CFLAGS])
 918 AC_SUBST([DRI_PC_REQ_PRIV])
 919 AC_SUBST([GLESv1_CM_LIB_DEPS])
 920 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 921 AC_SUBST([GLESv2_LIB_DEPS])
 922 AC_SUBST([GLESv2_PC_LIB_PRIV])
 923
 924 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 925
 926 AC_SUBST([HAVE_XF86VIDMODE])
 927
 928 dnl
 929 dnl More GLX setup
 930 dnl
 931 case "x$enable_glx$enable_xlib_glx" in
 932 xyesyes)
 933     DEFINES="$DEFINES -DUSE_XSHM"
 934     ;;
 935 xyesno)
 936     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 937     if test "x$driglx_direct" = xyes; then
 938         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 939     fi
 940     ;;
 941 esac
 942
 943 dnl
 944 dnl TLS detection
 945 dnl
 946
 947 AC_ARG_ENABLE([glx-tls],
 948     [AS_HELP_STRING([--enable-glx-tls],
 949         [enable TLS support in GLX @<:@default=disabled@:>@])],
 950     [GLX_USE_TLS="$enableval"],
 951     [GLX_USE_TLS=no])
 952 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 953
 954 AS_IF([test "x$GLX_USE_TLS" = xyes],
 955       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 956
 957 dnl
 958 dnl More DRI setup
 959 dnl
 960 dnl Directory for DRI drivers
 961 AC_ARG_WITH([dri-driverdir],
 962     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 963         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 964     [DRI_DRIVER_INSTALL_DIR="$withval"],
 965     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 966 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 967 dnl Extra search path for DRI drivers
 968 AC_ARG_WITH([dri-searchpath],
 969     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 970         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 971     [DRI_DRIVER_SEARCH_DIR="$withval"],
 972     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 973 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 974 dnl Which drivers to build - default is chosen by platform
 975 AC_ARG_WITH([dri-drivers],
 976     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 977         [comma delimited DRI drivers list, e.g.
 978         "swrast,i965,radeon" @<:@default=auto@:>@])],
 979     [with_dri_drivers="$withval"],
 980     [with_dri_drivers=yes])
 981 if test "x$with_dri_drivers" = x; then
 982     with_dri_drivers=no
 983 fi
 984
 985 dnl If $with_dri_drivers is yes, directories will be added through
 986 dnl platform checks
 987 DRI_DIRS=""
 988 case "$with_dri_drivers" in
 989 no) ;;
 990 yes)
 991     # classic DRI drivers require FEATURE_GL to build
 992     if test "x$enable_opengl" = xyes; then
 993         DRI_DIRS="yes"
 994     fi
 995     ;;
 996 *)
 997     # verify the requested driver directories exist
 998     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 999     for driver in $dri_drivers; do
1000         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1001             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1002     done
1003     DRI_DIRS="$dri_drivers"
1004     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1005         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1006     fi
1007     ;;
1008 esac
1009
1010 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1011 if test "x$enable_dri" = xyes; then
1012     # Platform specific settings and drivers to build
1013     case "$host_os" in
1014     linux*)
1015         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1016         DEFINES="$DEFINES -DHAVE_ALIAS"
1017
1018         case "$host_cpu" in
1019         x86_64)
1020             if test "x$DRI_DIRS" = "xyes"; then
1021                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1022             fi
1023             ;;
1024         powerpc*)
1025             # Build only the drivers for cards that exist on PowerPC.
1026             if test "x$DRI_DIRS" = "xyes"; then
1027                 DRI_DIRS="r200 radeon swrast"
1028             fi
1029             ;;
1030         sparc*)
1031             # Build only the drivers for cards that exist on sparc
1032             if test "x$DRI_DIRS" = "xyes"; then
1033                 DRI_DIRS="r200 radeon swrast"
1034             fi
1035             ;;
1036         esac
1037         ;;
1038     freebsd* | dragonfly* | *netbsd*)
1039         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1040         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1041
1042         if test "x$DRI_DIRS" = "xyes"; then
1043             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1044         fi
1045         ;;
1046     gnu*)
1047         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1048         DEFINES="$DEFINES -DHAVE_ALIAS"
1049         ;;
1050     solaris*)
1051         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1052         ;;
1053     cygwin*)
1054         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1055         if test "x$DRI_DIRS" = "xyes"; then
1056             DRI_DIRS="swrast"
1057         fi
1058         ;;
1059     esac
1060
1061     # default drivers
1062     if test "x$DRI_DIRS" = "xyes"; then
1063         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1064     fi
1065
1066     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1067
1068     # Check for expat
1069     if test "x$enable_dri" = xyes; then
1070         EXPAT_INCLUDES=""
1071         EXPAT_LIB=-lexpat
1072         AC_ARG_WITH([expat],
1073             [AS_HELP_STRING([--with-expat=DIR],
1074                 [expat install directory])],[
1075             EXPAT_INCLUDES="-I$withval/include"
1076             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1077             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1078             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1079             ])
1080         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1081         save_LIBS="$LIBS"
1082         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1083             [AC_MSG_ERROR([Expat required for DRI.])])
1084         LIBS="$save_LIBS"
1085     fi
1086
1087     # if we are building any dri driver other than swrast ...
1088     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1089         # ... libdrm is required
1090         if test "x$have_libdrm" != xyes; then
1091             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1092         fi
1093         # ... and build dricommon
1094         HAVE_COMMON_DRI=yes
1095     fi
1096
1097     # put all the necessary libs together
1098     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1099     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1100 fi
1101 AC_SUBST([DRI_DIRS])
1102 AC_SUBST([EXPAT_INCLUDES])
1103 AC_SUBST([DRI_LIB_DEPS])
1104 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1105
1106 case $DRI_DIRS in
1107 *i915*|*i965*)
1108     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1109
1110     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1111         case $d in
1112         i915)
1113             HAVE_I915_DRI=yes;
1114             ;;
1115         i965)
1116             HAVE_I965_DRI=yes;
1117             ;;
1118         esac
1119     done
1120
1121     ;;
1122 esac
1123
1124 case $DRI_DIRS in
1125 *nouveau*)
1126     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1127     HAVE_NOUVEAU_DRI=yes;
1128     ;;
1129 esac
1130
1131 case $DRI_DIRS in
1132 *radeon*|*r200*)
1133     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1134
1135     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1136         case $d in
1137         radeon)
1138             HAVE_RADEON_DRI=yes;
1139             ;;
1140         r200)
1141             HAVE_R200_DRI=yes;
1142             ;;
1143         esac
1144     done
1145
1146     ;;
1147 esac
1148
1149 case $DRI_DIRS in
1150 *swrast*)
1151     HAVE_SWRAST_DRI=yes;
1152     ;;
1153 esac
1154
1155 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1158 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1159 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1160 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1161 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1162
1163 dnl
1164 dnl OSMesa configuration
1165 dnl
1166
1167 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1168 AC_ARG_WITH([osmesa-bits],
1169     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1170         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1171     [osmesa_bits="$withval"],
1172     [osmesa_bits=8])
1173 if test "x$osmesa_bits" != x8; then
1174     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1175         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1176         osmesa_bits=8
1177     fi
1178 fi
1179 case "x$osmesa_bits" in
1180 x8)
1181     OSMESA_LIB="${OSMESA_LIB}"
1182     ;;
1183 x16|x32)
1184     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1185     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1186     ;;
1187 *)
1188     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1189     ;;
1190 esac
1191
1192 if test "x$enable_osmesa" = xyes; then
1193     # only link libraries with osmesa if shared
1194     if test "$enable_static" = no; then
1195         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1196     else
1197         OSMESA_LIB_DEPS=""
1198     fi
1199     OSMESA_MESA_DEPS=""
1200     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1201 fi
1202
1203 AC_SUBST([OSMESA_LIB_DEPS])
1204 AC_SUBST([OSMESA_MESA_DEPS])
1205 AC_SUBST([OSMESA_PC_REQ])
1206 AC_SUBST([OSMESA_PC_LIB_PRIV])
1207
1208 dnl
1209 dnl gbm configuration
1210 dnl
1211 if test "x$enable_gbm" = xauto; then
1212     case "$with_egl_platforms" in
1213         *drm*)
1214             enable_gbm=yes ;;
1215          *)
1216             enable_gbm=no ;;
1217     esac
1218 fi
1219 if test "x$enable_gbm" = xyes; then
1220     SRC_DIRS="$SRC_DIRS gbm"
1221
1222     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1223                       AC_MSG_ERROR([gbm needs udev]))
1224
1225     if test "x$enable_dri" = xyes; then
1226         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1227         if test "x$enable_shared_glapi" = xno; then
1228             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1229         fi
1230         PKG_CHECK_MODULES([LIBKMS], [libkms], [],
1231                           AC_MSG_ERROR([gbm needs libkms]))
1232     fi
1233 fi
1234 GBM_PC_REQ_PRIV="libudev"
1235 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1236 AC_SUBST([GBM_PC_REQ_PRIV])
1237 AC_SUBST([GBM_PC_LIB_PRIV])
1238
1239 dnl
1240 dnl EGL configuration
1241 dnl
1242 EGL_CLIENT_APIS=""
1243
1244 if test "x$enable_egl" = xyes; then
1245     SRC_DIRS="$SRC_DIRS egl"
1246     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1247
1248     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1249
1250     if test "$enable_static" != yes; then
1251         # build egl_glx when libGL is built
1252         if test "x$enable_glx" = xyes; then
1253             HAVE_EGL_DRIVER_GLX=1
1254         fi
1255
1256         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1257                           [have_libudev=yes],[have_libudev=no])
1258         if test "$have_libudev" = yes; then
1259             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1260         fi
1261
1262         if test "x$enable_dri" = xyes; then
1263             HAVE_EGL_DRIVER_DRI2=1
1264         fi
1265
1266     fi
1267 fi
1268 AC_SUBST([EGL_LIB_DEPS])
1269
1270 dnl
1271 dnl EGL Gallium configuration
1272 dnl
1273 if test "x$enable_gallium_egl" = xyes; then
1274     if test "x$with_gallium_drivers" = x; then
1275         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1276     fi
1277     if test "x$enable_egl" = xno; then
1278         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1279     fi
1280     if test "x$have_libdrm" != xyes; then
1281         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1282     fi
1283
1284     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1285     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1286     HAVE_ST_EGL="yes"
1287 fi
1288
1289 dnl
1290 dnl gbm Gallium configuration
1291 dnl
1292 if test "x$enable_gallium_gbm" = xauto; then
1293     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1294         yesyesyes*drm*)
1295             enable_gallium_gbm=yes ;;
1296          *)
1297             enable_gallium_gbm=no ;;
1298     esac
1299 fi
1300 if test "x$enable_gallium_gbm" = xyes; then
1301     if test "x$with_gallium_drivers" = x; then
1302         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1303     fi
1304     if test "x$enable_gbm" = xno; then
1305         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1306     fi
1307     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1308     if test "x$enable_dri" = xno; then
1309         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1310     fi
1311
1312     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1313     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1314     HAVE_ST_GBM="yes"
1315     enable_gallium_loader=yes
1316 fi
1317
1318 dnl
1319 dnl X.Org DDX configuration
1320 dnl
1321 if test "x$enable_xorg" = xyes; then
1322     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1323     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1324     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1325     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1326         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1327         HAVE_XEXTPROTO_71="no")
1328     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1329     HAVE_ST_XORG=yes
1330 fi
1331
1332 dnl
1333 dnl XA configuration
1334 dnl
1335 if test "x$enable_xa" = xyes; then
1336 AC_PROG_AWK
1337 AC_PROG_GREP
1338 AC_CHECK_PROG(NM, nm, "nm")
1339 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1340 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1341 enable_xa=no
1342 fi
1343 fi
1344 if test "x$enable_xa" = xyes; then
1345     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1346     HAVE_ST_XA=yes
1347     AC_SUBST(AWK)
1348     AC_SUBST(GREP)
1349     AC_SUBST(NM)
1350 fi
1351
1352 dnl
1353 dnl OpenVG configuration
1354 dnl
1355 VG_LIB_DEPS=""
1356
1357 if test "x$enable_openvg" = xyes; then
1358     if test "x$enable_egl" = xno; then
1359         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1360     fi
1361     if test "x$with_gallium_drivers" = x; then
1362         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1363     fi
1364     if test "x$enable_gallium_egl" = xno; then
1365         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1366     fi
1367
1368     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1369     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1370     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1371     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1372     HAVE_ST_VEGA=yes
1373     VG_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1374     AC_SUBST([VG_PC_LIB_PRIV])
1375 fi
1376
1377 dnl
1378 dnl D3D1X configuration
1379 dnl
1380
1381 if test "x$enable_d3d1x" = xyes; then
1382     if test "x$with_gallium_drivers" = x; then
1383         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1384     fi
1385
1386     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1387     HAVE_ST_D3D1X=yes
1388 fi
1389
1390 dnl
1391 dnl Gallium G3DVL configuration
1392 dnl
1393 AC_ARG_ENABLE([gallium-g3dvl],
1394     [AS_HELP_STRING([--enable-gallium-g3dvl],
1395         [build gallium g3dvl @<:@default=disabled@:>@])],
1396     [enable_gallium_g3dvl="$enableval"],
1397     [enable_gallium_g3dvl=no])
1398 if test "x$enable_gallium_g3dvl" = xyes; then
1399     if test "x$with_gallium_drivers" = x; then
1400         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1401     fi
1402
1403     if test "x$enable_xvmc" = xauto; then
1404         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1405     fi
1406
1407     if test "x$enable_vdpau" = xauto; then
1408         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1409     fi
1410
1411     if test "x$enable_va" = xauto; then
1412         #don't enable vaapi state tracker even if package exists
1413         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1414         enable_va=no
1415     fi
1416 fi
1417
1418 if test "x$enable_xvmc" = xyes; then
1419     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1420     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1421     HAVE_ST_XVMC="yes"
1422 fi
1423
1424 if test "x$enable_vdpau" = xyes; then
1425     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1426     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1427     HAVE_ST_VDPAU="yes"
1428 fi
1429
1430 if test "x$enable_va" = xyes; then
1431     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1432     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1433     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1434     HAVE_ST_VA="yes"
1435 fi
1436
1437 dnl
1438 dnl OpenCL configuration
1439 dnl
1440
1441 AC_ARG_WITH([libclc-path],
1442    [AS_HELP_STRING([--with-libclc-path],
1443          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1444    [LIBCLC_PATH="$withval"],
1445    [LIBCLC_PATH=""])
1446
1447 AC_ARG_WITH([clang-libdir],
1448    [AS_HELP_STRING([--with-clang-libdir],
1449          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1450    [CLANG_LIBDIR="$withval"],
1451    [CLANG_LIBDIR=""])
1452
1453 AC_SUBST([LIBCLC_PATH])
1454
1455 if test "x$enable_opencl" = xyes; then
1456     if test "x$with_gallium_drivers" = x; then
1457         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1458     fi
1459
1460     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1461         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1462     fi
1463
1464     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1465     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1466     enable_gallium_loader=yes
1467 fi
1468
1469 dnl
1470 dnl Gallium configuration
1471 dnl
1472 if test "x$with_gallium_drivers" != x; then
1473     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1474 fi
1475 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1476
1477 AC_SUBST([LLVM_BINDIR])
1478 AC_SUBST([LLVM_CFLAGS])
1479 AC_SUBST([LLVM_CPPFLAGS])
1480 AC_SUBST([LLVM_CXXFLAGS])
1481 AC_SUBST([LLVM_LIBDIR])
1482 AC_SUBST([LLVM_LIBS])
1483 AC_SUBST([LLVM_LDFLAGS])
1484 AC_SUBST([LLVM_INCLUDEDIR])
1485 AC_SUBST([LLVM_VERSION])
1486 AC_SUBST([CLANG_RESOURCE_DIR])
1487
1488 case "x$enable_opengl$enable_gles1$enable_gles2" in
1489 x*yes*)
1490     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1491     ;;
1492 esac
1493
1494 AC_SUBST([VG_LIB_DEPS])
1495 AC_SUBST([EGL_CLIENT_APIS])
1496
1497 dnl
1498 dnl EGL Platforms configuration
1499 dnl
1500 AC_ARG_WITH([egl-platforms],
1501     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1502         [comma delimited native platforms libEGL supports, e.g.
1503         "x11,drm" @<:@default=auto@:>@])],
1504     [with_egl_platforms="$withval"],
1505     [if test "x$enable_egl" = xyes; then
1506         with_egl_platforms="x11"
1507     else
1508         with_egl_platforms=""
1509     fi])
1510
1511 EGL_PLATFORMS=""
1512
1513 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1514     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1515 fi
1516
1517 # Do per-EGL platform setups and checks
1518 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1519 for plat in $egl_platforms; do
1520         case "$plat" in
1521         fbdev|null)
1522                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1523                 ;;
1524
1525         wayland)
1526                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1527                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1528                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1529
1530                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1531                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1532                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1533                 ;;
1534
1535         x11)
1536                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1537                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1538                 save_LIBS="$LIBS"
1539                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1540                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1541                 LIBS="$save_LIBS"
1542                 ;;
1543
1544         drm)
1545                 test "x$enable_gbm" = "xno" &&
1546                         AC_MSG_ERROR([EGL platform drm needs gbm])
1547                 ;;
1548
1549         android|gdi)
1550                 ;;
1551
1552         *)
1553                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1554                 ;;
1555         esac
1556
1557         case "$plat$have_libudev" in
1558                 waylandno|drmno)
1559                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1560         esac
1561 done
1562
1563 # libEGL wants to default to the first platform specified in
1564 # ./configure.  parse that here.
1565 if test "x$egl_platforms" != "x"; then
1566     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1567     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1568 else
1569     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1570 fi
1571
1572 EGL_PLATFORMS="$egl_platforms"
1573
1574 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1575 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1576 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1577 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1578 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1579
1580 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1581 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1582
1583 AC_SUBST([EGL_NATIVE_PLATFORM])
1584 AC_SUBST([EGL_PLATFORMS])
1585 AC_SUBST([EGL_CFLAGS])
1586
1587 AC_ARG_WITH([egl-driver-dir],
1588     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1589                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1590     [EGL_DRIVER_INSTALL_DIR="$withval"],
1591     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1592 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1593
1594 AC_ARG_WITH([xorg-driver-dir],
1595     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1596                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1597     [XORG_DRIVER_INSTALL_DIR="$withval"],
1598     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1599 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1600
1601 AC_ARG_WITH([max-width],
1602     [AS_HELP_STRING([--with-max-width=N],
1603                     [Maximum framebuffer width (4096)])],
1604     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1605      AS_IF([test "${withval}" -gt "4096"],
1606            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1607 )
1608 AC_ARG_WITH([max-height],
1609     [AS_HELP_STRING([--with-max-height=N],
1610                     [Maximum framebuffer height (4096)])],
1611     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1612      AS_IF([test "${withval}" -gt "4096"],
1613            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1614 )
1615
1616 dnl
1617 dnl Gallium LLVM
1618 dnl
1619 AC_ARG_ENABLE([gallium-llvm],
1620     [AS_HELP_STRING([--enable-gallium-llvm],
1621         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1622     [enable_gallium_llvm="$enableval"],
1623     [enable_gallium_llvm=auto])
1624
1625 AC_ARG_WITH([llvm-shared-libs],
1626     [AS_HELP_STRING([--with-llvm-shared-libs],
1627         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1628     [with_llvm_shared_libs=yes],
1629     [with_llvm_shared_libs=no])
1630
1631 AC_ARG_WITH([llvm-prefix],
1632     [AS_HELP_STRING([--with-llvm-prefix],
1633         [Prefix for LLVM installations in non-standard locations])],
1634     [llvm_prefix="$withval"],
1635     [llvm_prefix=""])
1636
1637
1638 if test "x$with_gallium_drivers" = x; then
1639     enable_gallium_llvm=no
1640 fi
1641 if test "x$enable_gallium_llvm" = xauto; then
1642     case "$host_cpu" in
1643     i*86|x86_64) enable_gallium_llvm=yes;;
1644     esac
1645 fi
1646 if test "x$enable_gallium_llvm" = xyes; then
1647     if test "x$llvm_prefix" != x; then
1648         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1649     else
1650         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1651     fi
1652
1653     if test "x$LLVM_CONFIG" != xno; then
1654         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1655         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1656         if test "x$with_llvm_shared_libs" = xyes; then
1657             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1658             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1659         else
1660             LLVM_COMPONENTS="engine bitwriter"
1661             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1662                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1663             fi
1664             if test "x$enable_opencl" = xyes; then
1665                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1666             fi
1667             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1668         fi
1669         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1670         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1671         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1672         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1673         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1674         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1675         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1676         MESA_LLVM=1
1677
1678         dnl Check for Clang interanl headers
1679         if test "x$enable_opencl" = xyes; then
1680             if test "x$CLANG_LIBDIR" = x; then
1681                 CLANG_LIBDIR=${LLVM_LIBDIR}
1682             fi
1683             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1684             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1685                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1686         fi
1687     else
1688         MESA_LLVM=0
1689     fi
1690 else
1691     MESA_LLVM=0
1692 fi
1693
1694 dnl Directory for XVMC libs
1695 AC_ARG_WITH([xvmc-libdir],
1696     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1697         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1698     [XVMC_LIB_INSTALL_DIR="$withval"],
1699     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1700 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1701
1702 dnl
1703 dnl Gallium Tests
1704 dnl
1705 if test "x$enable_gallium_tests" = xyes; then
1706     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1707     enable_gallium_loader=yes
1708 fi
1709
1710 dnl Directory for VDPAU libs
1711 AC_ARG_WITH([vdpau-libdir],
1712     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1713         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1714     [VDPAU_LIB_INSTALL_DIR="$withval"],
1715     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1716 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1717
1718 dnl Directory for VA libs
1719 AC_ARG_WITH([va-libdir],
1720     [AS_HELP_STRING([--with-va-libdir=DIR],
1721         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1722     [VA_LIB_INSTALL_DIR="$withval"],
1723     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1724 AC_SUBST([VA_LIB_INSTALL_DIR])
1725
1726 dnl Directory for OpenCL libs
1727 AC_ARG_WITH([opencl-libdir],
1728     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1729         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1730     [OPENCL_LIB_INSTALL_DIR="$withval"],
1731     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1732 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1733
1734 dnl
1735 dnl Gallium helper functions
1736 dnl
1737 gallium_check_st() {
1738     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1739          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1740          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1741          if test "x$have_libdrm" != xyes; then
1742             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1743          fi
1744          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1745     fi
1746     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1747          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1748     fi
1749     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1750          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1751     fi
1752     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1753          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1754     fi
1755     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1756          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1757     fi
1758     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1759          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1760     fi
1761     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1762          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1763     fi
1764 }
1765
1766 gallium_require_llvm() {
1767     if test "x$MESA_LLVM" = x0; then
1768         case "$host_cpu" in
1769         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1770         esac
1771     fi
1772 }
1773
1774 gallium_require_drm_loader() {
1775     if test "x$enable_gallium_loader" = xyes; then
1776         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1777                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1778         if test "x$have_libdrm" != xyes; then
1779             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1780         fi
1781         enable_gallium_drm_loader=yes
1782     fi
1783 }
1784
1785 dnl Gallium drivers
1786 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1787 if test "x$with_gallium_drivers" != x; then
1788     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1789     for driver in $gallium_drivers; do
1790         case "x$driver" in
1791         xsvga)
1792             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1793             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1794             ;;
1795         xi915)
1796             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1797             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1798             if test "x$MESA_LLVM" = x1; then
1799                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1800             fi
1801             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1802             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1803             ;;
1804         xr300)
1805             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1806             gallium_require_llvm "Gallium R300"
1807             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1808             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1809             ;;
1810         xr600)
1811             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1812             gallium_require_drm_loader
1813             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1814             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1815                 if test "x$LLVM_VERSION" != "x3.1"; then
1816                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1817                 fi
1818                 NEED_RADEON_GALLIUM=yes;
1819             fi
1820             if test "x$enable_r600_llvm" = xyes; then
1821                 USE_R600_LLVM_COMPILER=yes;
1822             fi
1823             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1824                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1825             fi
1826             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1827             ;;
1828         xradeonsi)
1829             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1830             gallium_require_drm_loader
1831             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1832             if test "x$LLVM_VERSION" != "x3.1"; then
1833                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1834             fi
1835             NEED_RADEON_GALLIUM=yes;
1836             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1837             ;;
1838         xnouveau)
1839             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1840             gallium_require_drm_loader
1841             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1842             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1843             ;;
1844         xswrast)
1845             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1846             if test "x$MESA_LLVM" = x1; then
1847                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1848             fi
1849
1850             if test "x$HAVE_ST_DRI" = xyes; then
1851                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1852             fi
1853             if test "x$HAVE_ST_VDPAU" = xyes; then
1854                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1855             fi
1856             if test "x$HAVE_ST_XVMC" = xyes; then
1857                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1858             fi
1859             if test "x$HAVE_ST_VA" = xyes; then
1860                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1861             fi
1862             if test "x$HAVE_ST_VDPAU" = xyes ||
1863                test "x$HAVE_ST_XVMC" = xyes ||
1864                test "x$HAVE_ST_VA" = xyes; then
1865                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1866                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1867                fi
1868             fi
1869             ;;
1870         *)
1871             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1872             ;;
1873         esac
1874     done
1875 fi
1876
1877 if test "x$enable_gallium_loader" = xyes; then
1878     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1879     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1880     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1881     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1882
1883     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1884         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1885         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1886     fi
1887
1888     if test "x$enable_gallium_drm_loader" = xyes; then
1889         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1890         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1891                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1892         if test "x$pipe_loader_have_xcb" = xyes; then
1893             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1894             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1895         fi
1896     fi
1897
1898     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1899     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1900 fi
1901
1902 dnl Tell Automake which drivers to build
1903 for driver in $GALLIUM_DRIVERS_DIRS; do
1904     case "x$driver" in
1905         xgalahad)
1906             HAVE_GALAHAD_GALLIUM=yes;
1907             ;;
1908         xidentity)
1909             HAVE_IDENTITY_GALLIUM=yes;
1910             ;;
1911         xnoop)
1912             HAVE_NOOP_GALLIUM=yes;
1913             ;;
1914         *)
1915             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1916             ;;
1917     esac
1918 done
1919
1920 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1921 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1922 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1923 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1924 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1925 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1926 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1927 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1928 AC_SUBST([GALLIUM_MAKE_DIRS])
1929
1930 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1931
1932 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1933 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1934 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1935
1936 dnl prepend CORE_DIRS to SRC_DIRS
1937 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1938
1939 dnl Restore LDFLAGS and CPPFLAGS
1940 LDFLAGS="$_SAVE_LDFLAGS"
1941 CPPFLAGS="$_SAVE_CPPFLAGS"
1942
1943 dnl Add user CFLAGS and CXXFLAGS
1944 CFLAGS="$CFLAGS $USER_CFLAGS"
1945 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1946
1947 dnl Substitute the config
1948 AC_CONFIG_FILES([configs/current
1949                 Makefile
1950                 src/egl/Makefile
1951                 src/egl/drivers/Makefile
1952                 src/egl/drivers/dri2/Makefile
1953                 src/egl/drivers/glx/Makefile
1954                 src/egl/main/Makefile
1955                 src/egl/main/egl.pc
1956                 src/egl/wayland/Makefile
1957                 src/egl/wayland/wayland-drm/Makefile
1958                 src/egl/wayland/wayland-egl/Makefile
1959                 src/egl/wayland/wayland-egl/wayland-egl.pc
1960                 src/gallium/Makefile
1961                 src/gallium/auxiliary/pipe-loader/Makefile
1962                 src/gallium/drivers/Makefile
1963                 src/gallium/drivers/r300/Makefile
1964                 src/gallium/drivers/r600/Makefile
1965                 src/gallium/state_trackers/clover/Makefile
1966                 src/gallium/targets/opencl/Makefile
1967                 src/gbm/Makefile
1968                 src/gbm/main/gbm.pc
1969                 src/glsl/Makefile
1970                 src/glsl/glcpp/Makefile
1971                 src/glsl/tests/Makefile
1972                 src/glx/Makefile
1973                 src/glx/tests/Makefile
1974                 src/gtest/Makefile
1975                 src/Makefile
1976                 src/mapi/es1api/Makefile
1977                 src/mapi/es1api/glesv1_cm.pc
1978                 src/mapi/es2api/Makefile
1979                 src/mapi/es2api/glesv2.pc
1980                 src/mapi/glapi/Makefile
1981                 src/mapi/glapi/gen/Makefile
1982                 src/mapi/glapi/tests/Makefile
1983                 src/mapi/shared-glapi/Makefile
1984                 src/mapi/shared-glapi/tests/Makefile
1985                 src/mapi/vgapi/Makefile
1986                 src/mapi/vgapi/vg.pc
1987                 src/mesa/Makefile
1988                 src/mesa/gl.pc
1989                 src/mesa/drivers/Makefile
1990                 src/mesa/drivers/dri/dri.pc
1991                 src/mesa/drivers/dri/common/Makefile
1992                 src/mesa/drivers/dri/i915/Makefile
1993                 src/mesa/drivers/dri/i965/Makefile
1994                 src/mesa/drivers/dri/Makefile
1995                 src/mesa/drivers/dri/nouveau/Makefile
1996                 src/mesa/drivers/dri/r200/Makefile
1997                 src/mesa/drivers/dri/radeon/Makefile
1998                 src/mesa/drivers/dri/swrast/Makefile
1999                 src/mesa/drivers/osmesa/Makefile
2000                 src/mesa/drivers/osmesa/osmesa.pc
2001                 src/mesa/drivers/x11/Makefile
2002                 src/mesa/libdricore/Makefile
2003                 src/mesa/main/tests/Makefile
2004                 src/mesa/x86-64/Makefile
2005                 src/mesa/x86/Makefile])
2006
2007 dnl Sort the dirs alphabetically
2008 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2009 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2010 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2011 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2012 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2013
2014 AC_OUTPUT
2015
2016 dnl
2017 dnl Output some configuration info for the user
2018 dnl
2019 echo ""
2020 echo "        prefix:          $prefix"
2021 echo "        exec_prefix:     $exec_prefix"
2022 echo "        libdir:          $libdir"
2023 echo "        includedir:      $includedir"
2024
2025 dnl API info
2026 echo ""
2027 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2028 echo "        OpenVG:          $enable_openvg"
2029
2030 dnl Driver info
2031 echo ""
2032 if test "x$enable_osmesa" != xno; then
2033         echo "        OSMesa:          lib$OSMESA_LIB"
2034 else
2035         echo "        OSMesa:          no"
2036 fi
2037
2038 if test "x$enable_dri" != xno; then
2039         # cleanup the drivers var
2040         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2041         if test "x$DRI_DIRS" = x; then
2042             echo "        DRI drivers:     no"
2043         else
2044             echo "        DRI drivers:     $dri_dirs"
2045         fi
2046         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2047 fi
2048
2049 case "x$enable_glx$enable_xlib_glx" in
2050 xyesyes)
2051     echo "        GLX:             Xlib-based"
2052     ;;
2053 xyesno)
2054     echo "        GLX:             DRI-based"
2055     ;;
2056 *)
2057     echo "        GLX:             $enable_glx"
2058     ;;
2059 esac
2060
2061 dnl EGL
2062 echo ""
2063 echo "        EGL:             $enable_egl"
2064 if test "$enable_egl" = yes; then
2065     echo "        EGL platforms:   $EGL_PLATFORMS"
2066
2067     egl_drivers=""
2068     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2069         egl_drivers="$egl_drivers builtin:egl_glx"
2070     fi
2071     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2072         egl_drivers="$egl_drivers builtin:egl_dri2"
2073     fi
2074
2075     if test "x$HAVE_ST_EGL" = xyes; then
2076         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2077         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2078     else
2079         echo "        EGL drivers:    $egl_drivers"
2080     fi
2081 fi
2082
2083 echo ""
2084 if test "x$MESA_LLVM" = x1; then
2085     echo "        llvm:            yes"
2086     echo "        llvm-config:     $LLVM_CONFIG"
2087     echo "        llvm-version:    $LLVM_VERSION"
2088 else
2089     echo "        llvm:            no"
2090 fi
2091
2092 echo ""
2093 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2094     echo "        Gallium:         yes"
2095     echo "        Gallium dirs:    $GALLIUM_DIRS"
2096     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2097     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2098     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2099     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2100 else
2101     echo "        Gallium:         no"
2102 fi
2103
2104
2105 dnl Libraries
2106 echo ""
2107 echo "        Shared libs:     $enable_shared"
2108 echo "        Static libs:     $enable_static"
2109 echo "        Shared-glapi:    $enable_shared_glapi"
2110
2111 dnl Compiler options
2112 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2113 cflags=`echo $CFLAGS $PIC_FLAGS | \
2114     $SED 's/^ *//;s/  */ /;s/ *$//'`
2115 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2116     $SED 's/^ *//;s/  */ /;s/ *$//'`
2117 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2118 echo ""
2119 echo "        CFLAGS:          $cflags"
2120 echo "        CXXFLAGS:        $cxxflags"
2121 echo "        Macros:          $defines"
2122 echo ""
2123 echo "        PYTHON2:         $PYTHON2"
2124
2125 echo ""
2126 echo "        Run '${MAKE-make}' to build Mesa"
2127 echo ""