configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.90
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.89
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.9.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=4.0.0
 107 LLVM_REQUIRED_RADV=4.0.0
 108 LLVM_REQUIRED_SWR=4.0.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 dnl add this here, so the help for this environmnet variable is close to
 115 dnl other CC/CXX flags related help
 116 AC_ARG_VAR([CXX11_CXXFLAGS], [Compiler flag to enable C++11 support (only needed if not
 117                               enabled by default and different  from -std=c++11)])
 118 AM_PROG_CC_C_O
 119 AM_PROG_AS
 120 AX_CHECK_GNU_MAKE
 121 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 122 AC_PROG_SED
 123 AC_PROG_MKDIR_P
 124
 125 AC_SYS_LARGEFILE
 126
 127
 128 LT_PREREQ([2.2])
 129 LT_INIT([disable-static])
 130
 131 AC_CHECK_PROG(RM, rm, [rm -f])
 132
 133 AX_PROG_BISON([],
 134               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 135                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 136 AX_PROG_FLEX([],
 137              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 138                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 139
 140 AC_CHECK_PROG(INDENT, indent, indent, cat)
 141 if test "x$INDENT" != "xcat"; then
 142     # Only GNU indent is supported
 143     INDENT_VERSION=`indent --version | grep GNU`
 144     if test $? -eq 0; then
 145        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 146     else
 147        INDENT="cat"
 148     fi
 149 fi
 150
 151 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 152
 153 if test -z "$PYTHON2"; then
 154     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 155         AC_MSG_ERROR([Python not found - unable to generate sources])
 156     fi
 157 else
 158     if test "x$acv_mako_found" = xno; then
 159         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 160             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 161         fi
 162     fi
 163 fi
 164
 165 AC_PROG_INSTALL
 166
 167 dnl We need a POSIX shell for parts of the build. Assume we have one
 168 dnl in most cases.
 169 case "$host_os" in
 170 solaris*)
 171     # Solaris /bin/sh is too old/non-POSIX compliant
 172     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 173     SHELL="$POSIX_SHELL"
 174     ;;
 175 esac
 176
 177 dnl clang is mostly GCC-compatible, but its version is much lower,
 178 dnl so we have to check for it.
 179 AC_MSG_CHECKING([if compiling with clang])
 180
 181 AC_COMPILE_IFELSE(
 182 [AC_LANG_PROGRAM([], [[
 183 #ifndef __clang__
 184        not clang
 185 #endif
 186 ]])],
 187 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 188
 189 AC_MSG_RESULT([$acv_mesa_CLANG])
 190
 191 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 192 dnl versions are explictly not supported.
 193 GEN_ASM_OFFSETS=no
 194 USE_GNU99=no
 195 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 196     AC_MSG_CHECKING([whether gcc version is sufficient])
 197     major=0
 198     minor=0
 199
 200     GCC_VERSION=`$CC -dumpversion`
 201     if test $? -eq 0; then
 202         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 203         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 204     fi
 205
 206     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 207         AC_MSG_RESULT([no])
 208         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 209     else
 210         AC_MSG_RESULT([yes])
 211     fi
 212
 213     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 214         USE_GNU99=yes
 215     fi
 216     if test "x$cross_compiling" = xyes; then
 217         GEN_ASM_OFFSETS=yes
 218     fi
 219 fi
 220
 221 dnl We don't support building Mesa with Sun C compiler
 222 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 223 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 224 if test "x$SUNCC" = xyes; then
 225     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 226 fi
 227
 228 dnl Check for compiler builtins
 229 AX_GCC_BUILTIN([__builtin_bswap32])
 230 AX_GCC_BUILTIN([__builtin_bswap64])
 231 AX_GCC_BUILTIN([__builtin_clz])
 232 AX_GCC_BUILTIN([__builtin_clzll])
 233 AX_GCC_BUILTIN([__builtin_ctz])
 234 AX_GCC_BUILTIN([__builtin_expect])
 235 AX_GCC_BUILTIN([__builtin_ffs])
 236 AX_GCC_BUILTIN([__builtin_ffsll])
 237 AX_GCC_BUILTIN([__builtin_popcount])
 238 AX_GCC_BUILTIN([__builtin_popcountll])
 239 AX_GCC_BUILTIN([__builtin_unreachable])
 240
 241 AX_GCC_FUNC_ATTRIBUTE([const])
 242 AX_GCC_FUNC_ATTRIBUTE([flatten])
 243 AX_GCC_FUNC_ATTRIBUTE([format])
 244 AX_GCC_FUNC_ATTRIBUTE([malloc])
 245 AX_GCC_FUNC_ATTRIBUTE([packed])
 246 AX_GCC_FUNC_ATTRIBUTE([pure])
 247 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 248 AX_GCC_FUNC_ATTRIBUTE([unused])
 249 AX_GCC_FUNC_ATTRIBUTE([visibility])
 250 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 251 AX_GCC_FUNC_ATTRIBUTE([weak])
 252 AX_GCC_FUNC_ATTRIBUTE([alias])
 253 AX_GCC_FUNC_ATTRIBUTE([noreturn])
 254
 255 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 256
 257 dnl Make sure the pkg-config macros are defined
 258 m4_ifndef([PKG_PROG_PKG_CONFIG],
 259     [m4_fatal([Could not locate the pkg-config autoconf macros.
 260   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 261   are in a different location, try setting the environment variable
 262   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 263 PKG_PROG_PKG_CONFIG()
 264
 265 dnl LIB_DIR - library basename
 266 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 267 AC_SUBST([LIB_DIR])
 268
 269 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 270 _SAVE_LDFLAGS="$LDFLAGS"
 271 _SAVE_CPPFLAGS="$CPPFLAGS"
 272
 273 dnl Compiler macros
 274 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 275 AC_SUBST([DEFINES])
 276 android=no
 277 case "$host_os" in
 278 *-android*)
 279     android=yes
 280     ;;
 281 linux*|*-gnu*|gnu*|cygwin*)
 282     DEFINES="$DEFINES -D_GNU_SOURCE"
 283     ;;
 284 solaris*)
 285     DEFINES="$DEFINES -DSVR4"
 286     ;;
 287 esac
 288
 289 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 290
 291 dnl
 292 dnl Check compiler flags
 293 dnl
 294 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 295 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 296 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 297 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 298 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 299 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 300 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 301
 302 dnl
 303 dnl Check C++ compiler flags
 304 dnl
 305 AC_LANG_PUSH([C++])
 306 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 307 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 308 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 309 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 310 AC_LANG_POP([C++])
 311
 312 # Flags to help ensure that certain portions of the code -- and only those
 313 # portions -- can be built with MSVC:
 314 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 315 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 316 #   supports most of C99)
 317 # - the rest has no compiler compiler restrictions
 318 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=pointer-arith"])
 319 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla"])
 320 AC_LANG_PUSH([C++])
 321 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=pointer-arith"])
 322 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla"])
 323 AC_LANG_POP([C++])
 324
 325 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 326 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 327
 328 if test "x$GCC" = xyes; then
 329     if test "x$USE_GNU99" = xyes; then
 330         CFLAGS="$CFLAGS -std=gnu99"
 331     else
 332         CFLAGS="$CFLAGS -std=c99"
 333     fi
 334 fi
 335
 336 dnl
 337 dnl Check whether C++11 is supported, if the environment variable
 338 dnl CXX11_CXXFLAGS is set it takes precedence.
 339 dnl
 340
 341 AC_LANG_PUSH([C++])
 342
 343 check_cxx11_available() {
 344     output_support=$1
 345     AC_COMPILE_IFELSE(
 346         [AC_LANG_PROGRAM([
 347              #if !(__cplusplus >= 201103L)
 348              #error
 349              #endif
 350              #include <tuple>
 351         ])
 352     ], [
 353          AC_MSG_RESULT(yes)
 354          cxx11_support=yes
 355     ], AC_MSG_RESULT(no))
 356     eval "$output_support=\$cxx11_support"
 357 }
 358
 359 HAVE_CXX11=no
 360 save_CXXFLAGS="$CXXFLAGS"
 361
 362 dnl If the user provides a flag to enable c++11, then we test only this
 363 if test "x$CXX11_CXXFLAGS" != "x"; then
 364    CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 365    AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 366    check_cxx11_available HAVE_CXX11
 367 else
 368    dnl test whether c++11 is enabled by default
 369    AC_MSG_CHECKING(whether c++11 is enabled by default)
 370    check_cxx11_available HAVE_CXX11
 371
 372    dnl C++11 not enabled by default, test whether -std=c++11 does the job
 373    if test "x$HAVE_CXX11" != "xyes"; then
 374        CXX11_CXXFLAGS=-std=c++11
 375        CXXFLAGS="$CXXFLAGS $CXX11_CXXFLAGS"
 376        AC_MSG_CHECKING(whether c++11 is enabled by via $CXX11_CXXFLAGS)
 377        check_cxx11_available HAVE_CXX11
 378    fi
 379 fi
 380
 381 CXXFLAGS="$save_CXXFLAGS"
 382 AM_CONDITIONAL(HAVE_STD_CXX11, test "x$HAVE_CXX11" = "xyes")
 383 AC_SUBST(CXX11_CXXFLAGS)
 384 AC_LANG_POP([C++])
 385
 386 dnl even if the compiler appears to support it, using visibility attributes isn't
 387 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 388 case "$host_os" in
 389 cygwin*)
 390     VISIBILITY_CFLAGS=""
 391     VISIBILITY_CXXFLAGS=""
 392     ;;
 393 esac
 394
 395 AC_SUBST([VISIBILITY_CFLAGS])
 396 AC_SUBST([VISIBILITY_CXXFLAGS])
 397
 398 dnl For some reason, the test for -Wno-foo always succeeds with gcc, even if the
 399 dnl option is not supported. Hence, check for -Wfoo instead.
 400 AX_CHECK_COMPILE_FLAG([-Woverride-init],                    [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-override-init"])         # gcc
 401 AX_CHECK_COMPILE_FLAG([-Winitializer-overrides],            [WNO_OVERRIDE_INIT="$WNO_OVERRIDE_INIT -Wno-initializer-overrides"]) # clang
 402 AC_SUBST([WNO_OVERRIDE_INIT])
 403
 404 dnl
 405 dnl Optional flags, check for compiler support
 406 dnl
 407 SSE41_CFLAGS="-msse4.1"
 408 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 409 dnl stack, but on x86-32 such alignment is not guaranteed.
 410 case "$target_cpu" in
 411 i?86)
 412     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 413     ;;
 414 esac
 415 save_CFLAGS="$CFLAGS"
 416 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 417 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 418 #include <smmintrin.h>
 419 int param;
 420 int main () {
 421     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 422     c = _mm_max_epu32(a, b);
 423     return _mm_cvtsi128_si32(c);
 424 }]])], SSE41_SUPPORTED=1)
 425 CFLAGS="$save_CFLAGS"
 426 if test "x$SSE41_SUPPORTED" = x1; then
 427     DEFINES="$DEFINES -DUSE_SSE41"
 428 fi
 429 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 430 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 431
 432 dnl Check for new-style atomic builtins
 433 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 434 int main() {
 435     int n;
 436     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 437 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 438 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 439     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 440     dnl On some platforms, new-style atomics need a helper library
 441     AC_MSG_CHECKING(whether -latomic is needed)
 442     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 443     #include <stdint.h>
 444     uint64_t v;
 445     int main() {
 446         return (int)__atomic_load_n(&v, __ATOMIC_ACQUIRE);
 447     }]])], GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=no, GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC=yes)
 448     AC_MSG_RESULT($GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC)
 449     if test "x$GCC_ATOMIC_BUILTINS_NEED_LIBATOMIC" = xyes; then
 450         LIBATOMIC_LIBS="-latomic"
 451     fi
 452 fi
 453 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 454 AC_SUBST([LIBATOMIC_LIBS])
 455
 456 dnl Check if host supports 64-bit atomics
 457 dnl note that lack of support usually results in link (not compile) error
 458 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 459 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 460 #include <stdint.h>
 461 uint64_t v;
 462 int main() {
 463     return __sync_add_and_fetch(&v, (uint64_t)1);
 464 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 465 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 466     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 467 fi
 468 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 469
 470 dnl Check for Endianness
 471 AC_C_BIGENDIAN(
 472    little_endian=no,
 473    little_endian=yes,
 474    little_endian=no,
 475    little_endian=no
 476 )
 477
 478 dnl Check for POWER8 Architecture
 479 PWR8_CFLAGS="-mpower8-vector"
 480 have_pwr8_intrinsics=no
 481 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 482 save_CFLAGS=$CFLAGS
 483 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 484 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 485 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 486 #error "Need GCC >= 4.8 for sane POWER8 support"
 487 #endif
 488 #include <altivec.h>
 489 int main () {
 490     vector unsigned char r;
 491     vector unsigned int v = vec_splat_u32 (1);
 492     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 493     return 0;
 494 }]])], have_pwr8_intrinsics=yes)
 495 CFLAGS=$save_CFLAGS
 496
 497 AC_ARG_ENABLE(pwr8,
 498    [AS_HELP_STRING([--disable-pwr8],
 499                    [disable POWER8-specific instructions])],
 500    [enable_pwr8=$enableval], [enable_pwr8=auto])
 501
 502 if test "x$enable_pwr8" = xno ; then
 503    have_pwr8_intrinsics=disabled
 504 fi
 505
 506 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 507    DEFINES="$DEFINES -D_ARCH_PWR8"
 508    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 509    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 510 else
 511    PWR8_CFLAGS=
 512 fi
 513
 514 AC_MSG_RESULT($have_pwr8_intrinsics)
 515 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 516    AC_MSG_ERROR([POWER8 compiler support not detected])
 517 fi
 518
 519 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 520    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 521 fi
 522
 523 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 524
 525 dnl Can't have static and shared libraries, default to static if user
 526 dnl explicitly requested. If both disabled, set to static since shared
 527 dnl was explicitly requested.
 528 case "x$enable_static$enable_shared" in
 529 xyesyes)
 530     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 531     ;;
 532 xnono)
 533     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 534     ;;
 535 esac
 536
 537 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 538
 539 dnl
 540 dnl other compiler options
 541 dnl
 542 AC_ARG_ENABLE([debug],
 543     [AS_HELP_STRING([--enable-debug],
 544         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 545     [enable_debug="$enableval"],
 546     [enable_debug=no]
 547 )
 548
 549 AC_ARG_ENABLE([profile],
 550     [AS_HELP_STRING([--enable-profile],
 551         [enable profiling of code @<:@default=disabled@:>@])],
 552     [enable_profile="$enableval"],
 553     [enable_profile=no]
 554 )
 555
 556 AC_ARG_ENABLE([sanitize],
 557     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 558         [enable code sanitizer @<:@default=disabled@:>@])],
 559     [enable_sanitize="$enableval"],
 560     [enable_sanitize=no])
 561
 562 if test "x$enable_profile" = xyes; then
 563     DEFINES="$DEFINES -DPROFILE"
 564     if test "x$GCC" = xyes; then
 565         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 566     fi
 567     if test "x$GXX" = xyes; then
 568         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 569     fi
 570 fi
 571
 572 if test "x$enable_debug" = xyes; then
 573     DEFINES="$DEFINES -DDEBUG"
 574     if test "x$enable_profile" = xyes; then
 575         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 576     fi
 577     if test "x$GCC" = xyes; then
 578         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 579             CFLAGS="$CFLAGS -g"
 580         fi
 581         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 582             CFLAGS="$CFLAGS -O0"
 583         fi
 584     fi
 585     if test "x$GXX" = xyes; then
 586         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 587             CXXFLAGS="$CXXFLAGS -g"
 588         fi
 589         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 590             CXXFLAGS="$CXXFLAGS -O0"
 591         fi
 592     fi
 593 else
 594    DEFINES="$DEFINES -DNDEBUG"
 595 fi
 596
 597 if test "x$enable_sanitize" != xno; then
 598     if test "x$enable_profile" = xyes; then
 599         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 600     fi
 601
 602     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 603     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 604     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 605
 606     AC_LINK_IFELSE(
 607         [AC_LANG_SOURCE([int main(){return 0;}])],
 608         [],
 609         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 610 fi
 611
 612 dnl
 613 dnl Check if linker supports -Bsymbolic
 614 dnl
 615 save_LDFLAGS=$LDFLAGS
 616 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 617 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 618 AC_LINK_IFELSE(
 619     [AC_LANG_SOURCE([int main() { return 0;}])],
 620     [AC_MSG_RESULT([yes])
 621         BSYMBOLIC="-Wl,-Bsymbolic";],
 622     [AC_MSG_RESULT([no])
 623         BSYMBOLIC="";])
 624 LDFLAGS=$save_LDFLAGS
 625
 626 AC_SUBST([BSYMBOLIC])
 627
 628 dnl
 629 dnl Check if linker supports garbage collection
 630 dnl
 631 save_LDFLAGS=$LDFLAGS
 632 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 633 AC_MSG_CHECKING([whether ld supports --gc-sections])
 634 AC_LINK_IFELSE(
 635     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 636     [AC_MSG_RESULT([yes])
 637         GC_SECTIONS="-Wl,--gc-sections";],
 638     [AC_MSG_RESULT([no])
 639         GC_SECTIONS="";])
 640 LDFLAGS=$save_LDFLAGS
 641
 642 AC_SUBST([GC_SECTIONS])
 643
 644 dnl
 645 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 646 dnl so when these flags are passed to ld via libtool the checks will fail
 647 dnl
 648 case "$host_os" in
 649 openbsd* | darwin* )
 650     LD_NO_UNDEFINED="" ;;
 651 *)
 652     if test "x$enable_sanitize" = xno; then
 653         LD_NO_UNDEFINED="-Wl,--no-undefined"
 654     else
 655         LD_NO_UNDEFINED=""
 656     fi
 657     ;;
 658 esac
 659
 660 AC_SUBST([LD_NO_UNDEFINED])
 661
 662 dnl
 663 dnl Check if linker supports version scripts
 664 dnl
 665 AC_MSG_CHECKING([if the linker supports version-scripts])
 666 save_LDFLAGS=$LDFLAGS
 667 LDFLAGS="$LDFLAGS -Wl,--version-script=$srcdir/build-support/conftest.map"
 668 AC_LINK_IFELSE(
 669     [AC_LANG_SOURCE([int main() { return 0;}])],
 670     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 671     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 672 LDFLAGS=$save_LDFLAGS
 673 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 674
 675 dnl
 676 dnl Check if linker supports dynamic list files
 677 dnl
 678 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 679 save_LDFLAGS=$LDFLAGS
 680 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=$srcdir/build-support/conftest.dyn"
 681 AC_LINK_IFELSE(
 682     [AC_LANG_SOURCE([int main() { return 0;}])],
 683     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 684     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 685 LDFLAGS=$save_LDFLAGS
 686 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 687
 688 dnl
 689 dnl OSX linker does not support build-id
 690 dnl
 691 case "$host_os" in
 692 darwin*)
 693     LD_BUILD_ID=""
 694     ;;
 695 *)
 696     LD_BUILD_ID="-Wl,--build-id=sha1"
 697     ;;
 698 esac
 699 AC_SUBST([LD_BUILD_ID])
 700
 701 dnl
 702 dnl compatibility symlinks
 703 dnl
 704 case "$host_os" in
 705 linux* )
 706     HAVE_COMPAT_SYMLINKS=yes ;;
 707 * )
 708     HAVE_COMPAT_SYMLINKS=no ;;
 709 esac
 710
 711 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 712
 713 dnl
 714 dnl library names
 715 dnl
 716 dnl Unfortunately we need to do a few things that libtool can't help us with,
 717 dnl so we need some knowledge of shared library filenames:
 718 dnl
 719 dnl LIB_EXT is the extension used when creating symlinks for alternate
 720 dnl filenames for a shared library which will be dynamically loaded
 721 dnl
 722 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 723 dnl the file for a shared library we wish to link with
 724 dnl
 725 case "$host_os" in
 726 darwin* )
 727     LIB_EXT='dylib'
 728     IMP_LIB_EXT=$LIB_EXT
 729     ;;
 730 cygwin* )
 731     LIB_EXT='dll'
 732     IMP_LIB_EXT='dll.a'
 733     ;;
 734 aix* )
 735     LIB_EXT='a'
 736     IMP_LIB_EXT=$LIB_EXT
 737     ;;
 738 * )
 739     LIB_EXT='so'
 740     IMP_LIB_EXT=$LIB_EXT
 741     ;;
 742 esac
 743
 744 AC_SUBST([LIB_EXT])
 745
 746 dnl
 747 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 748 dnl
 749 AC_ARG_ENABLE([texture-float],
 750     [AS_HELP_STRING([--enable-texture-float],
 751         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 752     [enable_texture_float="$enableval"],
 753     [enable_texture_float=no]
 754 )
 755 if test "x$enable_texture_float" = xyes; then
 756     AC_MSG_WARN([Floating-point textures enabled.])
 757     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 758     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 759 fi
 760
 761 dnl
 762 dnl Arch/platform-specific settings
 763 dnl
 764 AC_ARG_ENABLE([asm],
 765     [AS_HELP_STRING([--disable-asm],
 766         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 767     [enable_asm="$enableval"],
 768     [enable_asm=yes]
 769 )
 770 asm_arch=""
 771 AC_MSG_CHECKING([whether to enable assembly])
 772 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 773 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 774 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 775     case "$host_cpu" in
 776     i?86 | x86_64 | amd64)
 777         if test "x$host_cpu" != "x$target_cpu"; then
 778             enable_asm=no
 779             AC_MSG_RESULT([no, cross compiling])
 780         fi
 781         ;;
 782     esac
 783 fi
 784 # check for supported arches
 785 if test "x$enable_asm" = xyes; then
 786     case "$host_cpu" in
 787     i?86)
 788         case "$host_os" in
 789         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 790             asm_arch=x86
 791             ;;
 792         esac
 793         ;;
 794     x86_64|amd64)
 795         case "$host_os" in
 796         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 797             asm_arch=x86_64
 798             ;;
 799         esac
 800         ;;
 801     sparc*)
 802         case "$host_os" in
 803         linux*)
 804             asm_arch=sparc
 805             ;;
 806         esac
 807         ;;
 808     powerpc64le)
 809         case "$host_os" in
 810         linux*)
 811             asm_arch=ppc64le
 812             ;;
 813         esac
 814         ;;
 815     aarch64)
 816         case "$host_os" in
 817         linux*)
 818             asm_arch=aarch64
 819             ;;
 820         esac
 821         ;;
 822     arm)
 823         case "$host_os" in
 824         linux*)
 825             asm_arch=arm
 826             ;;
 827         esac
 828         ;;
 829     esac
 830
 831     case "$asm_arch" in
 832     x86)
 833         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 834         AC_MSG_RESULT([yes, x86])
 835         ;;
 836     x86_64|amd64)
 837         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 838         AC_MSG_RESULT([yes, x86_64])
 839         ;;
 840     sparc)
 841         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 842         AC_MSG_RESULT([yes, sparc])
 843         ;;
 844     ppc64le)
 845         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 846         AC_MSG_RESULT([yes, ppc64le])
 847         ;;
 848     aarch64)
 849         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 850         AC_MSG_RESULT([yes, aarch64])
 851         ;;
 852     arm)
 853         DEFINES="$DEFINES -DUSE_ARM_ASM"
 854         AC_MSG_RESULT([yes, arm])
 855         ;;
 856     *)
 857         AC_MSG_RESULT([no, platform not supported])
 858         ;;
 859     esac
 860 fi
 861
 862 AC_HEADER_MAJOR
 863 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 864 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 865 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 866 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 867 AC_CHECK_FUNC([timespec_get], [DEFINES="$DEFINES -DHAVE_TIMESPEC_GET"])
 868 AC_CHECK_FUNC([memfd_create], [DEFINES="$DEFINES -DHAVE_MEMFD_CREATE"])
 869
 870 AC_MSG_CHECKING([whether strtod has locale support])
 871 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 872     #define _GNU_SOURCE
 873     #include <stdlib.h>
 874     #include <locale.h>
 875     #ifdef HAVE_XLOCALE_H
 876     #include <xlocale.h>
 877     #endif
 878     int main() {
 879        locale_t loc = newlocale(LC_CTYPE_MASK, "C", NULL);
 880        const char *s = "1.0";
 881        char *end;
 882        double d = strtod_l(s, end, loc);
 883        float f = strtof_l(s, end, loc);
 884        freelocale(loc);
 885        return 0;
 886     }]])],
 887   [DEFINES="$DEFINES -DHAVE_STRTOD_L"];
 888    AC_MSG_RESULT([yes]),
 889    AC_MSG_RESULT([no]))
 890
 891 dnl Check to see if dlopen is in default libraries (like Solaris, which
 892 dnl has it in libc), or if libdl is needed to get it.
 893 AC_CHECK_FUNC([dlopen], [],
 894     [AC_CHECK_LIB([dl], [dlopen],
 895        [DLOPEN_LIBS="-ldl"])])
 896 AC_SUBST([DLOPEN_LIBS])
 897
 898 dnl Check if that library also has dladdr
 899 save_LIBS="$LIBS"
 900 LIBS="$LIBS $DLOPEN_LIBS"
 901 AC_CHECK_FUNCS([dladdr])
 902 LIBS="$save_LIBS"
 903
 904 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 905
 906 case "$host_os" in
 907 darwin*)
 908     ;;
 909 *)
 910     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 911                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 912                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 913     AC_SUBST([CLOCK_LIB])
 914     ;;
 915 esac
 916
 917 dnl See if posix_memalign is available
 918 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 919
 920 dnl Check for zlib
 921 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 922 DEFINES="$DEFINES -DHAVE_ZLIB"
 923
 924 dnl Check for pthreads
 925 AX_PTHREAD
 926 if test "x$ax_pthread_ok" = xno; then
 927     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 928 fi
 929 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 930 dnl to -pthread, which causes problems if we need -lpthread to appear in
 931 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 932 dnl is not valid for that platform.
 933 if test "x$android" = xno; then
 934     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 935 fi
 936 dnl According to the manual when using pthreads, one should add -pthread to
 937 dnl both compile and link-time arguments.
 938 dnl In practise that should be sufficient for all platforms, since any
 939 dnl platforms build with GCC and Clang support the flag.
 940 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 941
 942 dnl pthread-stubs is mandatory on some BSD platforms, due to the nature of the
 943 dnl project. Even then there's a notable issue as described in the project README
 944 case "$host_os" in
 945 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu* | openbsd*)
 946     pthread_stubs_possible="no"
 947     ;;
 948 * )
 949     pthread_stubs_possible="yes"
 950     ;;
 951 esac
 952
 953 if test "x$pthread_stubs_possible" = xyes; then
 954     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 955 fi
 956
 957 dnl Check for futex for fast inline simple_mtx_t.
 958 AC_CHECK_HEADER([linux/futex.h], [DEFINES="$DEFINES -DHAVE_LINUX_FUTEX_H"])
 959
 960 dnl SELinux awareness.
 961 AC_ARG_ENABLE([selinux],
 962     [AS_HELP_STRING([--enable-selinux],
 963         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 964     [MESA_SELINUX="$enableval"],
 965     [MESA_SELINUX=no])
 966 if test "x$enable_selinux" = "xyes"; then
 967     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 968         [AC_CHECK_HEADER([selinux/selinux.h],[],
 969                          [AC_MSG_ERROR([SELinux headers not found])])
 970          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 971                       [AC_MSG_ERROR([SELinux library not found])])
 972          SELINUX_LIBS="-lselinux"])
 973     DEFINES="$DEFINES -DMESA_SELINUX"
 974 fi
 975 AC_SUBST([SELINUX_CFLAGS])
 976 AC_SUBST([SELINUX_LIBS])
 977
 978 dnl
 979 dnl LLVM
 980 dnl
 981 AC_ARG_ENABLE([llvm-shared-libs],
 982     [AS_HELP_STRING([--enable-llvm-shared-libs],
 983         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 984     [enable_llvm_shared_libs="$enableval"],
 985     [enable_llvm_shared_libs=yes])
 986
 987 AC_ARG_WITH([llvm-prefix],
 988     [AS_HELP_STRING([--with-llvm-prefix],
 989         [Prefix for LLVM installations in non-standard locations])],
 990     [llvm_prefix="$withval"],
 991     [llvm_prefix=''])
 992
 993 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 994 if test "x$have_libelf" = xno; then
 995    LIBELF_LIBS=''
 996    LIBELF_CFLAGS=''
 997    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 998    AC_SUBST([LIBELF_LIBS])
 999    AC_SUBST([LIBELF_CFLAGS])
1000 fi
1001
1002 if test -z "$LLVM_CONFIG"; then
1003     if test -n "$llvm_prefix"; then
1004         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1005     else
1006         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1007     fi
1008 fi
1009
1010 llvm_add_component() {
1011     new_llvm_component=$1
1012     driver_name=$2
1013
1014     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1015         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1016     else
1017         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
1018     fi
1019 }
1020
1021 llvm_add_optional_component() {
1022     new_llvm_component=$1
1023     driver_name=$2
1024
1025     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
1026         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
1027     fi
1028 }
1029
1030 llvm_add_default_components() {
1031     driver_name=$1
1032
1033     # Required default components
1034     llvm_add_component "bitwriter" $driver_name
1035     llvm_add_component "engine" $driver_name
1036     llvm_add_component "mcdisassembler" $driver_name
1037     llvm_add_component "mcjit" $driver_name
1038
1039     # Optional default components
1040     llvm_add_optional_component "inteljitevents" $driver_name
1041 }
1042
1043 llvm_add_target() {
1044     new_llvm_target=$1
1045     driver_name=$2
1046
1047     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
1048         llvm_add_component $new_llvm_target $driver_name
1049     else
1050         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
1051     fi
1052 }
1053
1054 # Call this inside ` ` to get the return value.
1055 # $1 is the llvm-config command with arguments.
1056 strip_unwanted_llvm_flags() {
1057     echo " `$1` " | sed -E \
1058         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
1059         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
1060         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
1061         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
1062         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
1063         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
1064         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
1065         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
1066         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
1067         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
1068         -e 's/^[[[:space:]]]//' \
1069         -e 's/[[[:space:]]]$//'
1070 }
1071
1072 llvm_set_environment_variables() {
1073     if test "x$LLVM_CONFIG" != xno; then
1074         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1075         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1076         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1077         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1078
1079         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
1080         save_CFLAGS="$CFLAGS"
1081         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
1082
1083         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1084             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1085         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1086             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1087         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1088             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1089
1090         CFLAGS="$save_CFLAGS"
1091
1092         # Only needed for LLVM < 3.6.0
1093         if test -z "$LLVM_VERSION_PATCH"; then
1094             LLVM_VERSION_PATCH=0
1095         fi
1096
1097         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1098
1099         FOUND_LLVM=yes
1100     else
1101         FOUND_LLVM=no
1102         LLVM_VERSION_INT=0
1103     fi
1104 }
1105
1106 require_llvm() {
1107     if test "x$enable_llvm" != "xyes"; then
1108         AC_MSG_ERROR([--enable-llvm is required when building $1])
1109     fi
1110 }
1111
1112 llvm_require_version() {
1113     require_llvm $2
1114
1115     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1116     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1117     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1118
1119     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1120         # major > required major
1121         #  --> OK
1122         return
1123     fi
1124
1125     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1126         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1127             # major = required major and
1128             # minor > required minor
1129             #  --> OK
1130             return
1131         else
1132             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1133                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1134                     # major = required major and
1135                     # minor = required minor and
1136                     # patch >= required patch
1137                     #  --> OK
1138                     return
1139                 fi
1140             fi
1141         fi
1142     fi
1143
1144     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1145 }
1146
1147 radeon_llvm_check() {
1148     if test ${LLVM_VERSION_INT} -lt 307; then
1149         amdgpu_llvm_target_name='r600'
1150     else
1151         amdgpu_llvm_target_name='amdgpu'
1152     fi
1153
1154     llvm_require_version $*
1155
1156     llvm_add_target $amdgpu_llvm_target_name $2
1157
1158     llvm_add_default_components $2
1159     llvm_add_component "bitreader" $2
1160     llvm_add_component "ipo" $2
1161
1162     if test "x$have_libelf" != xyes; then
1163        AC_MSG_ERROR([$2 requires libelf when using llvm])
1164     fi
1165 }
1166
1167 llvm_set_environment_variables
1168
1169 AC_SUBST([LLVM_CFLAGS])
1170 AC_SUBST([LLVM_CXXFLAGS])
1171 AC_SUBST([LLVM_LIBS])
1172 AC_SUBST([LLVM_LDFLAGS])
1173 AC_SUBST([LLVM_INCLUDEDIR])
1174
1175 dnl
1176 dnl libunwind
1177 dnl
1178 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1179 AC_ARG_ENABLE([libunwind],
1180     [AS_HELP_STRING([--enable-libunwind],
1181             [Use libunwind for backtracing (default: auto)])],
1182         [LIBUNWIND="$enableval"],
1183         [LIBUNWIND="$HAVE_LIBUNWIND"])
1184
1185 if test "x$LIBUNWIND" = "xyes"; then
1186     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1187     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1188 fi
1189
1190
1191 dnl Options for APIs
1192 AC_ARG_ENABLE([opengl],
1193     [AS_HELP_STRING([--disable-opengl],
1194         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1195     [enable_opengl="$enableval"],
1196     [enable_opengl=yes])
1197 AC_ARG_ENABLE([gles1],
1198     [AS_HELP_STRING([--disable-gles1],
1199         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1200     [enable_gles1="$enableval"],
1201     [enable_gles1=yes])
1202 AC_ARG_ENABLE([gles2],
1203     [AS_HELP_STRING([--disable-gles2],
1204         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1205     [enable_gles2="$enableval"],
1206     [enable_gles2=yes])
1207
1208 AC_ARG_ENABLE([dri],
1209     [AS_HELP_STRING([--enable-dri],
1210         [enable DRI modules @<:@default=enabled@:>@])],
1211     [enable_dri="$enableval"],
1212     [enable_dri=yes])
1213
1214 AC_ARG_ENABLE([gallium-extra-hud],
1215     [AS_HELP_STRING([--enable-gallium-extra-hud],
1216         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1217     [enable_gallium_extra_hud="$enableval"],
1218     [enable_gallium_extra_hud=no])
1219 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1220 if test "x$enable_gallium_extra_hud" = xyes ; then
1221     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1222 fi
1223
1224 #TODO: no pkgconfig .pc available for libsensors.
1225 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1226 AC_ARG_ENABLE([lmsensors],
1227     [AS_HELP_STRING([--enable-lmsensors],
1228         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1229     [enable_lmsensors="$enableval"],
1230     [enable_lmsensors=no])
1231 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1232 if test "x$enable_lmsensors" = xyes ; then
1233     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1234     LIBSENSORS_LIBS="-lsensors"
1235 else
1236     LIBSENSORS_LIBS=""
1237 fi
1238 AC_SUBST(LIBSENSORS_LIBS)
1239
1240 case "$host_os" in
1241 linux*)
1242     dri3_default=yes
1243     ;;
1244 *)
1245     dri3_default=no
1246     ;;
1247 esac
1248
1249 if test "x$enable_dri" = xno; then
1250     dri3_default=no
1251 fi
1252
1253 AC_ARG_ENABLE([dri3],
1254     [AS_HELP_STRING([--enable-dri3],
1255         [enable DRI3 @<:@default=auto@:>@])],
1256     [enable_dri3="$enableval"],
1257     [enable_dri3="$dri3_default"])
1258 AC_ARG_ENABLE([glx],
1259     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1260         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1261     [enable_glx="$enableval"],
1262     [enable_glx=yes])
1263 AC_ARG_ENABLE([osmesa],
1264     [AS_HELP_STRING([--enable-osmesa],
1265         [enable OSMesa library @<:@default=disabled@:>@])],
1266     [enable_osmesa="$enableval"],
1267     [enable_osmesa=no])
1268 AC_ARG_ENABLE([gallium-osmesa],
1269     [AS_HELP_STRING([--enable-gallium-osmesa],
1270         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1271     [enable_gallium_osmesa="$enableval"],
1272     [enable_gallium_osmesa=no])
1273 AC_ARG_ENABLE([egl],
1274     [AS_HELP_STRING([--disable-egl],
1275         [disable EGL library @<:@default=enabled@:>@])],
1276     [enable_egl="$enableval"],
1277     [enable_egl=yes])
1278
1279 AC_ARG_ENABLE([xa],
1280     [AS_HELP_STRING([--enable-xa],
1281         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1282     [enable_xa="$enableval"],
1283     [enable_xa=no])
1284 AC_ARG_ENABLE([gbm],
1285    [AS_HELP_STRING([--enable-gbm],
1286          [enable gbm library @<:@default=yes except cygwin and macOS@:>@])],
1287    [enable_gbm="$enableval"],
1288    [case "$host_os" in
1289        cygwin* | darwin*)
1290           enable_gbm=no
1291           ;;
1292        *)
1293           enable_gbm=yes
1294           ;;
1295     esac])
1296 AC_ARG_ENABLE([nine],
1297     [AS_HELP_STRING([--enable-nine],
1298         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1299     [enable_nine="$enableval"],
1300     [enable_nine=no])
1301
1302 AC_ARG_ENABLE([xvmc],
1303    [AS_HELP_STRING([--enable-xvmc],
1304          [enable xvmc library @<:@default=auto@:>@])],
1305    [enable_xvmc="$enableval"],
1306    [enable_xvmc=auto])
1307 AC_ARG_ENABLE([vdpau],
1308    [AS_HELP_STRING([--enable-vdpau],
1309          [enable vdpau library @<:@default=auto@:>@])],
1310    [enable_vdpau="$enableval"],
1311    [enable_vdpau=auto])
1312 AC_ARG_ENABLE([omx],
1313    [AS_HELP_STRING([--enable-omx],
1314          [DEPRECATED: Use --enable-omx-bellagio instead @<:@default=auto@:>@])],
1315    [AC_MSG_ERROR([--enable-omx is deprecated. Use --enable-omx-bellagio instead.])],
1316    [])
1317 AC_ARG_ENABLE([omx-bellagio],
1318    [AS_HELP_STRING([--enable-omx-bellagio],
1319          [enable OpenMAX Bellagio library @<:@default=disabled@:>@])],
1320    [enable_omx_bellagio="$enableval"],
1321    [enable_omx_bellagio=no])
1322 AC_ARG_ENABLE([va],
1323    [AS_HELP_STRING([--enable-va],
1324          [enable va library @<:@default=auto@:>@])],
1325    [enable_va="$enableval"],
1326    [enable_va=auto])
1327 AC_ARG_ENABLE([opencl],
1328    [AS_HELP_STRING([--enable-opencl],
1329          [enable OpenCL library @<:@default=disabled@:>@])],
1330    [enable_opencl="$enableval"],
1331    [enable_opencl=no])
1332 AC_ARG_ENABLE([opencl_icd],
1333    [AS_HELP_STRING([--enable-opencl-icd],
1334           [Build an OpenCL ICD library to be loaded by an ICD implementation
1335            @<:@default=enabled@:>@])],
1336     [enable_opencl_icd="$enableval"],
1337     [enable_opencl_icd=yes])
1338
1339 AC_ARG_ENABLE([gallium-tests],
1340     [AS_HELP_STRING([--enable-gallium-tests],
1341         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1342     [enable_gallium_tests="$enableval"],
1343     [enable_gallium_tests=no])
1344
1345 # Option for Gallium drivers
1346
1347 # Keep this in sync with the --with-gallium-drivers help string default value
1348 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1349
1350 AC_ARG_WITH([gallium-drivers],
1351     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1352         [comma delimited Gallium drivers list, e.g.
1353         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,vc5,virgl,etnaviv,imx"
1354         @<:@default=r300,r600,svga,swrast@:>@])],
1355     [with_gallium_drivers="$withval"],
1356     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1357
1358 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1359 # here so that the script doesn't choke on an unknown driver name later.
1360 case "$with_gallium_drivers" in
1361     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1362     no) with_gallium_drivers='' ;;
1363 esac
1364
1365 if test "x$enable_opengl" = xno -a \
1366         "x$enable_gles1" = xno -a \
1367         "x$enable_gles2" = xno -a \
1368         "x$enable_nine" = xno -a \
1369         "x$enable_xa" = xno -a \
1370         "x$enable_xvmc" = xno -a \
1371         "x$enable_vdpau" = xno -a \
1372         "x$enable_omx_bellagio" = xno -a \
1373         "x$enable_va" = xno -a \
1374         "x$enable_opencl" = xno; then
1375     AC_MSG_ERROR([at least one API should be enabled])
1376 fi
1377
1378 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1379 if test "x$enable_opengl" = xno -a \
1380         "x$enable_gles1" = xyes; then
1381     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1382 fi
1383
1384 if test "x$enable_opengl" = xno -a \
1385         "x$enable_gles2" = xyes; then
1386     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1387 fi
1388
1389 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1390 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1391 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1392 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1393                                         "x$enable_gles1" = xyes -o \
1394                                         "x$enable_gles2" = xyes)
1395 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1396                                       "x$enable_gles1" = xyes -o \
1397                                       "x$enable_gles2" = xyes)
1398
1399 # Validate GLX options
1400 if test "x$enable_glx" = xyes; then
1401     if test "x$enable_dri" = xyes; then
1402         enable_glx=dri
1403     elif test -n "$with_gallium_drivers"; then
1404         enable_glx=gallium-xlib
1405     else
1406         enable_glx=xlib
1407     fi
1408 fi
1409 case "x$enable_glx" in
1410 xdri | xxlib | xgallium-xlib)
1411     # GLX requires OpenGL
1412     if test "x$enable_opengl" = xno; then
1413         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1414     fi
1415
1416     # Check individual dependencies
1417     case "x$enable_glx" in
1418     xdri)
1419         if test "x$enable_dri" = xno; then
1420             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1421         fi
1422         ;;
1423     xxlib)
1424         if test "x$enable_dri" = xyes; then
1425             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1426         fi
1427         ;;
1428     xgallium-xlib )
1429         if test "x$enable_dri" = xyes; then
1430             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1431         fi
1432         if test -z "$with_gallium_drivers"; then
1433             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1434         fi
1435         ;;
1436     esac
1437     ;;
1438 xno)
1439     ;;
1440 *)
1441     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1442     ;;
1443 esac
1444
1445 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1446 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1447 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1448 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1449
1450 DEFAULT_GL_LIB_NAME=GL
1451
1452 dnl
1453 dnl Libglvnd configuration
1454 dnl
1455 AC_ARG_ENABLE([libglvnd],
1456     [AS_HELP_STRING([--enable-libglvnd],
1457         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1458     [enable_libglvnd="$enableval"],
1459     [enable_libglvnd=no])
1460 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1461
1462 if test "x$enable_libglvnd" = xyes ; then
1463     case "x$enable_glx" in
1464     xxlib | xgallium-xlib )
1465         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1466         ;;
1467     esac
1468
1469     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1470     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1471     AC_SUBST([LIBGLVND_DATADIR])
1472
1473     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1474     DEFAULT_GL_LIB_NAME=GLX_mesa
1475
1476     if test "x$enable_glx" = xno -a "x$enable_egl" = xno; then
1477         AC_MSG_ERROR([cannot build libglvnd without GLX or EGL])
1478     fi
1479 fi
1480
1481 AC_ARG_WITH([gl-lib-name],
1482   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1483     [specify GL library name @<:@default=GL@:>@])],
1484   [GL_LIB=$withval],
1485   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1486 AC_ARG_WITH([osmesa-lib-name],
1487   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1488     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1489   [OSMESA_LIB=$withval],
1490   [OSMESA_LIB=OSMesa])
1491 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1492 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1493
1494 dnl
1495 dnl Mangled Mesa support
1496 dnl
1497 AC_ARG_ENABLE([mangling],
1498   [AS_HELP_STRING([--enable-mangling],
1499     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1500   [enable_mangling="${enableval}"],
1501   [enable_mangling=no]
1502 )
1503 if test "x${enable_mangling}" = "xyes" ; then
1504   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1505   GL_LIB="Mangled${GL_LIB}"
1506   OSMESA_LIB="Mangled${OSMESA_LIB}"
1507 fi
1508 AC_SUBST([GL_LIB])
1509 AC_SUBST([OSMESA_LIB])
1510
1511 # Check for libdrm
1512 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1513                   [have_libdrm=yes], [have_libdrm=no])
1514 if test "x$have_libdrm" = xyes; then
1515     DEFINES="$DEFINES -DHAVE_LIBDRM"
1516 fi
1517
1518 require_libdrm() {
1519     if test "x$have_libdrm" != xyes; then
1520        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1521     fi
1522 }
1523
1524
1525 # Select which platform-dependent DRI code gets built
1526 case "$host_os" in
1527 darwin*)
1528     dri_platform='apple' ;;
1529 cygwin*)
1530     dri_platform='windows' ;;
1531 gnu*)
1532     dri_platform='none' ;;
1533 *)
1534     dri_platform='drm' ;;
1535 esac
1536
1537 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1538     have_drisw_kms='yes'
1539 fi
1540
1541 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1542 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1543 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1544 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1545 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1546 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1547 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1548 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1549 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1550
1551 AC_ARG_ENABLE([shared-glapi],
1552     [AS_HELP_STRING([--enable-shared-glapi],
1553         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1554     [enable_shared_glapi="$enableval"],
1555     [enable_shared_glapi=yes])
1556
1557 case "x$enable_opengl$enable_gles1$enable_gles2" in
1558 x*yes*yes*)
1559     if test "x$enable_shared_glapi" = xno; then
1560         AC_MSG_ERROR([shared GLAPI required when building two or more of
1561                       the following APIs - opengl, gles1 gles2])
1562     fi
1563     ;;
1564 esac
1565
1566 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1567
1568 # Build the pipe-drivers as separate libraries/modules.
1569 # Do not touch this unless you know what you are doing.
1570 # XXX: Expose via configure option ?
1571 enable_shared_pipe_drivers=no
1572
1573 dnl
1574 dnl Driver specific build directories
1575 dnl
1576
1577 if test "x$enable_gallium_osmesa" = xyes; then
1578     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1579         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1580     fi
1581     if test "x$enable_osmesa" = xyes; then
1582         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1583     fi
1584 fi
1585
1586 require_dri_shared_libs_and_glapi() {
1587     if test "x$enable_static" = xyes; then
1588         AC_MSG_ERROR([$1 cannot be build as static library])
1589     fi
1590
1591     if test "x$enable_dri" != xyes; then
1592         # There is only a single backend which won't be build/used otherwise.
1593         # XXX: Revisit this as the egl/haiku is a thing.
1594         AC_MSG_ERROR([$1 requires --enable-dri])
1595     fi
1596
1597     if test "x$enable_shared_glapi" != xyes; then
1598         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1599     fi
1600 }
1601
1602 if test "x$enable_dri" = xyes; then
1603     require_dri_shared_libs_and_glapi "DRI"
1604
1605     # not a hard requirement as swrast does not depend on it
1606     if test "x$have_libdrm" = xyes; then
1607         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1608     fi
1609 fi
1610
1611 AC_ARG_ENABLE([driglx-direct],
1612     [AS_HELP_STRING([--disable-driglx-direct],
1613         [disable direct rendering in GLX and EGL for DRI \
1614             @<:@default=enabled@:>@])],
1615     [driglx_direct="$enableval"],
1616     [driglx_direct="yes"])
1617
1618 dnl
1619 dnl libGL configuration per driver
1620 dnl
1621 if test "x$enable_glx" != xno; then
1622     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1623 fi
1624 case "x$enable_glx" in
1625 xxlib | xgallium-xlib)
1626     # Xlib-based GLX
1627     dri_modules="x11 xext xcb"
1628     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1629     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1630     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1631     GL_LIB_DEPS="$XLIBGL_LIBS"
1632     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1633     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1634     ;;
1635 xdri)
1636     # DRI-based GLX
1637
1638     # find the DRI deps for libGL
1639     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1640
1641     if test x"$driglx_direct" = xyes; then
1642         if test x"$dri_platform" = xdrm ; then
1643             DEFINES="$DEFINES -DGLX_USE_DRM"
1644             require_libdrm "Direct rendering"
1645
1646             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1647             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1648
1649             if test x"$enable_dri" = xyes; then
1650                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1651             fi
1652         fi
1653         if test x"$dri_platform" = xapple ; then
1654             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1655         fi
1656         if test x"$dri_platform" = xwindows ; then
1657             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1658         fi
1659     fi
1660
1661     # add xf86vidmode if available
1662     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1663     if test "$HAVE_XF86VIDMODE" = yes ; then
1664         dri_modules="$dri_modules xxf86vm"
1665     fi
1666
1667     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1668     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1669     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1670     GL_LIB_DEPS="$DRIGL_LIBS"
1671
1672     # need DRM libs, $PTHREAD_LIBS, etc.
1673     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1674     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1675     ;;
1676 esac
1677
1678 # This is outside the case (above) so that it is invoked even for non-GLX
1679 # builds.
1680 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1681
1682 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1683 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1684 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1685 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1686
1687 AC_SUBST([X11_INCLUDES])
1688 AC_SUBST([GL_LIB_DEPS])
1689 AC_SUBST([GL_PC_REQ_PRIV])
1690 AC_SUBST([GL_PC_LIB_PRIV])
1691 AC_SUBST([GL_PC_CFLAGS])
1692 AC_SUBST([DRI_PC_REQ_PRIV])
1693 AC_SUBST([GLESv1_CM_LIB_DEPS])
1694 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1695 AC_SUBST([GLESv2_LIB_DEPS])
1696 AC_SUBST([GLESv2_PC_LIB_PRIV])
1697
1698 AC_SUBST([HAVE_XF86VIDMODE])
1699
1700 dnl
1701 dnl More GLX setup
1702 dnl
1703 case "x$enable_glx" in
1704 xxlib | xgallium-xlib)
1705     DEFINES="$DEFINES -DUSE_XSHM"
1706     ;;
1707 xdri)
1708     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1709     if test "x$driglx_direct" = xyes; then
1710         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1711     fi
1712     ;;
1713 esac
1714
1715 dnl
1716 dnl TLS detection
1717 dnl
1718
1719 AC_ARG_ENABLE([glx-tls],
1720     [AS_HELP_STRING([--enable-glx-tls],
1721         [enable TLS support in GLX @<:@default=enabled@:>@])],
1722     [GLX_USE_TLS="$enableval"],
1723     [GLX_USE_TLS=yes])
1724 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1725
1726 if test "x$GLX_USE_TLS" = xyes; then
1727     DEFINES="$DEFINES -DGLX_USE_TLS"
1728 fi
1729
1730 dnl Read-only text section on x86 hardened platforms
1731 AC_ARG_ENABLE([glx-read-only-text],
1732     [AS_HELP_STRING([--enable-glx-read-only-text],
1733         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1734     [enable_glx_read_only_text="$enableval"],
1735     [enable_glx_read_only_text=no])
1736 if test "x$enable_glx_read_only_text" = xyes; then
1737     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1738 fi
1739
1740 dnl
1741 dnl DEPRECATED: EGL Platforms configuration
1742 dnl
1743 AC_ARG_WITH([egl-platforms],
1744     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1745         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1746     [with_egl_platforms="$withval"],
1747     [with_egl_platforms=auto])
1748
1749 if test "x$with_egl_platforms" = xauto; then
1750     with_egl_platforms="x11,surfaceless"
1751     if test "x$enable_gbm" = xyes; then
1752         with_egl_platforms="$with_egl_platforms,drm"
1753     fi
1754 else
1755     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1756 fi
1757
1758 dnl
1759 dnl Platforms configuration
1760 dnl
1761 AC_ARG_WITH([platforms],
1762     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1763         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1764         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1765     [with_platforms="$withval"],
1766     [with_platforms=auto])
1767
1768 # Reuse the autodetection rather than duplicating it.
1769 if test "x$with_platforms" = xauto; then
1770     with_platforms=$with_egl_platforms
1771 fi
1772
1773 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1774         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1775         WAYLAND_SCANNER='')
1776 if test "x$WAYLAND_SCANNER" = x; then
1777     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1778 fi
1779
1780 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1781 if test "x$have_wayland_protocols" = xyes; then
1782     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1783 fi
1784 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1785
1786 # Do per platform setups and checks
1787 platforms=`IFS=', '; echo $with_platforms`
1788 for plat in $platforms; do
1789     case "$plat" in
1790     wayland)
1791
1792         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= $WAYLAND_REQUIRED])
1793         PKG_CHECK_MODULES([WAYLAND_SERVER], [wayland-server >= $WAYLAND_REQUIRED])
1794
1795         if test "x$WAYLAND_SCANNER" = "x:"; then
1796                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1797         fi
1798         if test "x$have_wayland_protocols" = xno; then
1799                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1800         fi
1801         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM -DWL_HIDE_DEPRECATED"
1802         ;;
1803
1804     x11)
1805         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1806         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1807         ;;
1808
1809     drm)
1810         test "x$enable_gbm" = "xno" &&
1811                 AC_MSG_ERROR([EGL platform drm needs gbm])
1812         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1813         ;;
1814
1815     surfaceless)
1816         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1817         ;;
1818
1819     android)
1820         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1821         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1822         ;;
1823
1824     *)
1825         AC_MSG_ERROR([platform '$plat' does not exist])
1826         ;;
1827     esac
1828
1829     case "$plat" in
1830     wayland|drm|surfaceless)
1831         require_libdrm "Platform $plat"
1832         ;;
1833     esac
1834 done
1835
1836 if test "x$enable_glx" != xno; then
1837     if ! echo "$platforms" | grep -q 'x11'; then
1838         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1839     fi
1840 fi
1841
1842 if test x"$enable_dri3" = xyes; then
1843     DEFINES="$DEFINES -DHAVE_DRI3"
1844
1845     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1846     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1847 fi
1848
1849 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1850 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1851 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1852 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1853 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1854
1855 dnl
1856 dnl More DRI setup
1857 dnl
1858 dnl Directory for DRI drivers
1859 AC_ARG_WITH([dri-driverdir],
1860     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1861         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1862     [DRI_DRIVER_INSTALL_DIR="$withval"],
1863     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1864 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1865 dnl Extra search path for DRI drivers
1866 AC_ARG_WITH([dri-searchpath],
1867     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1868         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1869     [DRI_DRIVER_SEARCH_DIR="$withval"],
1870     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1871 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1872 dnl Which drivers to build - default is chosen by platform
1873 AC_ARG_WITH([dri-drivers],
1874     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1875         [comma delimited classic DRI drivers list, e.g.
1876         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1877     [with_dri_drivers="$withval"],
1878     [with_dri_drivers=auto])
1879
1880 if test "x$with_dri_drivers" = xauto; then
1881     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1882         with_dri_drivers="yes"
1883     else
1884         with_dri_drivers="no"
1885     fi
1886 fi
1887 if test "x$with_dri_drivers" = xno; then
1888     with_dri_drivers=''
1889 fi
1890
1891 # Check for expat
1892 PKG_CHECK_MODULES([EXPAT], [expat],,
1893     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1894 )
1895
1896 dnl If $with_dri_drivers is yes, drivers will be added through
1897 dnl platform checks. Set DEFINES and LIB_DEPS
1898 if test "x$enable_dri" = xyes; then
1899     # Platform specific settings and drivers to build
1900     case "$host_os" in
1901     linux*)
1902         case "$host_cpu" in
1903         powerpc* | sparc*)
1904             # Build only the drivers for cards that exist on PowerPC/sparc
1905             if test "x$with_dri_drivers" = "xyes"; then
1906                 with_dri_drivers="r200 radeon swrast"
1907             fi
1908             ;;
1909         esac
1910         ;;
1911     cygwin*)
1912         if test "x$with_dri_drivers" = "xyes"; then
1913             with_dri_drivers="swrast"
1914         fi
1915         ;;
1916     darwin*)
1917         DEFINES="$DEFINES -DBUILDING_MESA"
1918         if test "x$with_dri_drivers" = "xyes"; then
1919             with_dri_drivers="swrast"
1920         fi
1921         ;;
1922     esac
1923
1924     # default drivers
1925     if test "x$with_dri_drivers" = "xyes"; then
1926         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1927     fi
1928
1929     # put all the necessary libs together
1930     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1931 fi
1932
1933 AC_SUBST([DRI_LIB_DEPS])
1934
1935 DRI_DIRS=''
1936 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1937 if test -n "$with_dri_drivers"; then
1938     if test "x$enable_opengl" != xyes; then
1939         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1940     fi
1941
1942     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1943     for driver in $dri_drivers; do
1944         DRI_DIRS="$DRI_DIRS $driver"
1945         case "x$driver" in
1946         xi915)
1947             require_libdrm "i915"
1948             HAVE_I915_DRI=yes
1949             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1950             ;;
1951         xi965)
1952             require_libdrm "i965"
1953             HAVE_I965_DRI=yes
1954             ;;
1955         xnouveau)
1956             require_libdrm "nouveau"
1957             HAVE_NOUVEAU_DRI=yes
1958             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1959             ;;
1960         xradeon)
1961             require_libdrm "radeon"
1962             HAVE_RADEON_DRI=yes;
1963             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1964             ;;
1965         xr200)
1966             require_libdrm "r200"
1967             HAVE_R200_DRI=yes
1968             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1969             ;;
1970         xswrast)
1971             HAVE_SWRAST_DRI=yes
1972             ;;
1973         *)
1974             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1975             ;;
1976         esac
1977     done
1978     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1979 fi
1980
1981
1982 dnl
1983 dnl Gallium LLVM
1984 dnl Deprecated: kept for backwards compatibility
1985 dnl
1986 AC_ARG_ENABLE([gallium-llvm],
1987     [AS_HELP_STRING([--enable-gallium-llvm],
1988         [DEPRECATED: use --enable-llvm instead])],
1989     [enable_gallium_llvm="$enableval"],
1990     [enable_gallium_llvm=auto])
1991
1992 if test "x$enable_gallium_llvm" != xauto; then
1993    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1994    enable_llvm=$enable_gallium_llvm
1995 fi
1996
1997 dnl
1998 dnl LLVM
1999 dnl
2000 AC_ARG_ENABLE([llvm],
2001     [AS_HELP_STRING([--enable-llvm],
2002         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2003     [enable_llvm="$enableval"],
2004     [enable_llvm=auto])
2005
2006 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
2007     if test "x$FOUND_LLVM" = xyes; then
2008         case "$host_cpu" in
2009         i*86|x86_64|amd64) enable_llvm=yes;;
2010         *) enable_llvm=no;;
2011         esac
2012     else
2013         enable_llvm=no
2014     fi
2015 fi
2016
2017 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
2018     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
2019 fi
2020
2021 #
2022 # Vulkan driver configuration
2023 #
2024
2025 AC_ARG_WITH([vulkan-drivers],
2026     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
2027         [comma delimited Vulkan drivers list, e.g.
2028         "intel,radeon"
2029         @<:@default=no@:>@])],
2030     [with_vulkan_drivers="$withval"],
2031     [with_vulkan_drivers="no"])
2032
2033 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
2034 # here so that the script doesn't choke on an unknown driver name later.
2035 case "x$with_vulkan_drivers" in
2036     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
2037     xno) with_vulkan_drivers='' ;;
2038 esac
2039
2040 AC_ARG_WITH([vulkan-icddir],
2041     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
2042         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
2043     [VULKAN_ICD_INSTALL_DIR="$withval"],
2044     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
2045 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
2046
2047 require_x11_dri3() {
2048     if echo "$platforms" | grep -q 'x11'; then
2049         if test "x$enable_dri3" != xyes; then
2050             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
2051         fi
2052     fi
2053 }
2054
2055 if test -n "$with_vulkan_drivers"; then
2056     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
2057         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
2058     fi
2059
2060     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
2061     for driver in $VULKAN_DRIVERS; do
2062         case "x$driver" in
2063         xintel)
2064             require_libdrm "ANV"
2065             require_x11_dri3 "ANV"
2066             HAVE_INTEL_VULKAN=yes
2067             ;;
2068         xradeon)
2069             require_libdrm "radv"
2070             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2071             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
2072             require_x11_dri3 "radv"
2073             HAVE_RADEON_VULKAN=yes
2074             ;;
2075         *)
2076             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
2077             ;;
2078         esac
2079     done
2080     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
2081 fi
2082
2083
2084 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
2085 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
2086 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
2087                                   "x$enable_osmesa" = xyes -o \
2088                                   -n "$DRI_DIRS")
2089
2090 dnl
2091 dnl OSMesa configuration
2092 dnl
2093
2094 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
2095 AC_ARG_WITH([osmesa-bits],
2096     [AS_HELP_STRING([--with-osmesa-bits=BITS],
2097         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
2098     [osmesa_bits="$withval"],
2099     [osmesa_bits=8])
2100 if test "x$osmesa_bits" != x8; then
2101     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
2102         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
2103         osmesa_bits=8
2104     fi
2105 fi
2106 case "x$osmesa_bits" in
2107 x8)
2108     OSMESA_LIB="${OSMESA_LIB}"
2109     ;;
2110 x16|x32)
2111     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2112     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2113     ;;
2114 *)
2115     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2116     ;;
2117 esac
2118
2119 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2120     # only link libraries with osmesa if shared
2121     if test "$enable_static" = no; then
2122         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2123     else
2124         OSMESA_LIB_DEPS=""
2125     fi
2126     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2127 fi
2128
2129 AC_SUBST([OSMESA_LIB_DEPS])
2130 AC_SUBST([OSMESA_PC_REQ])
2131 AC_SUBST([OSMESA_PC_LIB_PRIV])
2132
2133 dnl
2134 dnl gbm configuration
2135 dnl
2136 if test "x$enable_gbm" = xyes; then
2137     require_dri_shared_libs_and_glapi "gbm"
2138 fi
2139 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2140 # FINISHME: GBM has a number of dependencies which we should add below
2141 GBM_PC_REQ_PRIV=""
2142 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2143 AC_SUBST([GBM_PC_REQ_PRIV])
2144 AC_SUBST([GBM_PC_LIB_PRIV])
2145
2146 dnl
2147 dnl EGL configuration
2148 dnl
2149
2150 if test "x$enable_egl" = xyes; then
2151     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2152
2153     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2154
2155     require_dri_shared_libs_and_glapi "egl"
2156 fi
2157 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2158 AC_SUBST([EGL_LIB_DEPS])
2159
2160 gallium_st="mesa"
2161
2162 dnl
2163 dnl XA configuration
2164 dnl
2165 if test "x$enable_xa" = xyes; then
2166     if test "x$with_gallium_drivers" = xswrast; then
2167        AC_MSG_ERROR([
2168           Building xa requires at least one non swrast gallium driver.
2169           If you are looking to use libxatracker.so with the VMware driver,
2170           make sure to include svga in the gallium drivers list, apart from
2171           enabling XA.
2172           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2173     fi
2174     gallium_st="$gallium_st xa"
2175 fi
2176 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2177
2178 if echo $platforms | grep -q "x11"; then
2179     have_xvmc_platform=yes
2180 else
2181     have_xvmc_platform=no
2182 fi
2183
2184 if echo $platforms | grep -q "x11"; then
2185     have_vdpau_platform=yes
2186 else
2187     have_vdpau_platform=no
2188 fi
2189
2190 if echo $platforms | grep -q "x11\|drm"; then
2191     have_omx_platform=yes
2192 else
2193     have_omx_platform=no
2194 fi
2195
2196 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2197     have_va_platform=yes
2198 else
2199     have_va_platform=no
2200 fi
2201
2202 dnl
2203 dnl Gallium G3DVL configuration
2204 dnl
2205 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2206     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2207         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2208     fi
2209
2210     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2211         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2212     fi
2213
2214     if test "x$enable_omx_bellagio" = xauto -a "x$have_omx_platform" = xyes; then
2215         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx_bellagio=yes], [enable_omx_bellagio=no])
2216     fi
2217
2218     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2219         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2220     fi
2221 fi
2222
2223 if test "x$enable_dri" = xyes -o \
2224         "x$enable_xvmc" = xyes -o \
2225         "x$enable_vdpau" = xyes -o \
2226         "x$enable_omx_bellagio" = xyes -o \
2227         "x$enable_va" = xyes; then
2228     need_gallium_vl=yes
2229 fi
2230 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2231
2232 if test "x$enable_xvmc" = xyes -o \
2233         "x$enable_vdpau" = xyes -o \
2234         "x$enable_omx_bellagio" = xyes -o \
2235         "x$enable_va" = xyes; then
2236     if echo $platforms | grep -q "x11"; then
2237         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2238     fi
2239     need_gallium_vl_winsys=yes
2240 fi
2241 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2242
2243 if test "x$enable_xvmc" = xyes; then
2244     if test "x$have_xvmc_platform" != xyes; then
2245         AC_MSG_ERROR([XVMC requires the x11 platforms])
2246     fi
2247     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2248     gallium_st="$gallium_st xvmc"
2249 fi
2250 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2251
2252 if test "x$enable_vdpau" = xyes; then
2253     if test "x$have_vdpau_platform" != xyes; then
2254         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2255     fi
2256     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2257     gallium_st="$gallium_st vdpau"
2258     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2259 fi
2260 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2261
2262 if test "x$enable_omx_bellagio" = xyes; then
2263     if test "x$have_omx_platform" != xyes; then
2264         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2265     fi
2266     PKG_CHECK_MODULES([OMX_BELLAGIO], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2267     gallium_st="$gallium_st omx_bellagio"
2268 fi
2269 AM_CONDITIONAL(HAVE_ST_OMX_BELLAGIO, test "x$enable_omx_bellagio" = xyes)
2270
2271 if test "x$enable_va" = xyes; then
2272     if test "x$have_va_platform" != xyes; then
2273         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2274     fi
2275     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2276     gallium_st="$gallium_st va"
2277 fi
2278 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2279
2280 dnl
2281 dnl Nine Direct3D9 configuration
2282 dnl
2283 if test "x$enable_nine" = xyes; then
2284     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2285         AC_MSG_ERROR([nine requires the gallium swrast driver])
2286     fi
2287     if test "x$with_gallium_drivers" = xswrast; then
2288         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2289     fi
2290     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2291         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2292     fi
2293
2294     if test "x$enable_dri3" = xno; then
2295         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2296     fi
2297
2298     gallium_st="$gallium_st nine"
2299 fi
2300 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2301
2302 dnl
2303 dnl OpenCL configuration
2304 dnl
2305
2306 AC_ARG_WITH([clang-libdir],
2307    [AS_HELP_STRING([--with-clang-libdir],
2308          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2309    [CLANG_LIBDIR="$withval"],
2310    [CLANG_LIBDIR=''])
2311
2312 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2313
2314 if test "x$enable_opencl" = xyes; then
2315     if test -z "$with_gallium_drivers"; then
2316         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2317     fi
2318
2319     if test "x$HAVE_CXX11" != "xyes"; then
2320        AC_MSG_ERROR([clover requires c++11 support])
2321     fi
2322
2323     if test "x$have_libclc" = xno; then
2324         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2325                     Make sure the directory containing libclc.pc is specified in your
2326                     PKG_CONFIG_PATH environment variable.
2327                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2328     else
2329         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2330         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2331         AC_SUBST([LIBCLC_INCLUDEDIR])
2332         AC_SUBST([LIBCLC_LIBEXECDIR])
2333     fi
2334
2335     gallium_st="$gallium_st clover"
2336
2337     if test "x$enable_opencl_icd" = xyes; then
2338         OPENCL_LIBNAME="MesaOpenCL"
2339     else
2340         OPENCL_LIBNAME="OpenCL"
2341     fi
2342
2343     if test "x$have_libelf" != xyes; then
2344        AC_MSG_ERROR([Clover requires libelf])
2345     fi
2346
2347     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2348         altivec_enabled=no
2349         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2350         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2351         #error "AltiVec not enabled"
2352         #endif
2353         ])], altivec_enabled=yes)
2354
2355         if test "$altivec_enabled" = yes; then
2356             CLOVER_STD_OVERRIDE="-std=gnu++11"
2357         fi
2358         AC_SUBST([CLOVER_STD_OVERRIDE])
2359     fi
2360
2361     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2362
2363     llvm_add_default_components "opencl"
2364     llvm_add_component "all-targets" "opencl"
2365     llvm_add_component "coverage" "opencl"
2366     llvm_add_component "linker" "opencl"
2367     llvm_add_component "instrumentation" "opencl"
2368     llvm_add_component "ipo" "opencl"
2369     llvm_add_component "irreader" "opencl"
2370     llvm_add_component "lto" "opencl"
2371     llvm_add_component "option" "opencl"
2372     llvm_add_component "objcarcopts" "opencl"
2373     llvm_add_component "profiledata" "opencl"
2374     llvm_add_optional_component "coroutines" "opencl"
2375
2376     dnl Check for Clang internal headers
2377     if test -z "$CLANG_LIBDIR"; then
2378         CLANG_LIBDIR=${LLVM_LIBDIR}
2379     fi
2380     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2381     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2382         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2383 fi
2384 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2385 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2386 AC_SUBST([OPENCL_LIBNAME])
2387 AC_SUBST([CLANG_RESOURCE_DIR])
2388
2389 dnl
2390 dnl Gallium configuration
2391 dnl
2392 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2393
2394 # libEGL wants to default to the first platform specified in
2395 # ./configure.  parse that here.
2396 if test "x$platforms" != "x"; then
2397     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2398     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2399 else
2400     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2401 fi
2402
2403 AC_SUBST([EGL_NATIVE_PLATFORM])
2404 AC_SUBST([EGL_CFLAGS])
2405
2406 # If we don't have the X11 platform, set this define so we don't try to include
2407 # the X11 headers.
2408 if ! echo "$platforms" | grep -q 'x11'; then
2409     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2410     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2411 fi
2412
2413 dnl Directory for XVMC libs
2414 AC_ARG_WITH([xvmc-libdir],
2415     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2416         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2417     [XVMC_LIB_INSTALL_DIR="$withval"],
2418     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2419 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2420
2421 dnl
2422 dnl Gallium Tests
2423 dnl
2424 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2425
2426 dnl Directory for VDPAU libs
2427 AC_ARG_WITH([vdpau-libdir],
2428     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2429         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2430     [VDPAU_LIB_INSTALL_DIR="$withval"],
2431     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2432 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2433
2434 dnl Directory for OMX_BELLAGIO libs
2435
2436 AC_ARG_WITH([omx-bellagio-libdir],
2437     [AS_HELP_STRING([--with-omx-bellagio-libdir=DIR],
2438         [directory for the OMX_BELLAGIO libraries])],
2439     [OMX_BELLAGIO_LIB_INSTALL_DIR="$withval"],
2440     [OMX_BELLAGIO_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2441                                    $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2442 AC_SUBST([OMX_BELLAGIO_LIB_INSTALL_DIR])
2443
2444 dnl Directory for VA libs
2445
2446 AC_ARG_WITH([va-libdir],
2447     [AS_HELP_STRING([--with-va-libdir=DIR],
2448         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2449     [VA_LIB_INSTALL_DIR="$withval"],
2450     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2451 AC_SUBST([VA_LIB_INSTALL_DIR])
2452
2453 AC_ARG_WITH([d3d-libdir],
2454     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2455         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2456     [D3D_DRIVER_INSTALL_DIR="$withval"],
2457     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2458 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2459
2460 dnl Architectures to build SWR library for
2461
2462 AC_ARG_WITH([swr-archs],
2463     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2464         [comma delimited swr architectures list, e.g.
2465         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2466     [with_swr_archs="$withval"],
2467     [with_swr_archs="avx,avx2"])
2468
2469 dnl
2470 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2471 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2472 dnl architectures.
2473 dnl
2474 r300_require_llvm() {
2475     case "$host" in *gnux32) return;; esac
2476     case "$host_cpu" in
2477     i*86|x86_64|amd64) require_llvm $1
2478         ;;
2479     esac
2480 }
2481
2482 dnl
2483 dnl DRM is needed by X, Wayland, and offscreen rendering.
2484 dnl Surfaceless is an alternative for the last one.
2485 dnl
2486 require_basic_egl() {
2487     case "$with_platforms" in
2488         *drm*|*surfaceless*|*android*)
2489             ;;
2490         *)
2491             AC_MSG_ERROR([$1 requires one of these:
2492                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2493                   2) --with-platforms=surfaceless (offscreen only)
2494                   3) --with-platforms=android (Android only)
2495                   Recommended options: drm,x11])
2496             ;;
2497     esac
2498 }
2499
2500 swr_require_cxx_feature_flags() {
2501     feature_name="$1"
2502     preprocessor_test="$2"
2503     option_list="$3"
2504     output_var="$4"
2505
2506     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2507     AC_LANG_PUSH([C++])
2508     save_CXXFLAGS="$CXXFLAGS"
2509     save_IFS="$IFS"
2510     IFS=","
2511     found=0
2512     for opts in $option_list
2513     do
2514         unset IFS
2515         CXXFLAGS="$opts $save_CXXFLAGS"
2516         AC_COMPILE_IFELSE(
2517             [AC_LANG_PROGRAM(
2518                 [   #if !($preprocessor_test)
2519                     #error
2520                     #endif
2521                 ])],
2522             [found=1; break],
2523             [])
2524         IFS=","
2525     done
2526     IFS="$save_IFS"
2527     CXXFLAGS="$save_CXXFLAGS"
2528     AC_LANG_POP([C++])
2529     if test $found -eq 1; then
2530         AC_MSG_RESULT([$opts])
2531         eval "$output_var=\$opts"
2532         return 0
2533     fi
2534     AC_MSG_RESULT([no])
2535     AC_MSG_ERROR([swr requires $feature_name support])
2536     return 1
2537 }
2538
2539 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2540 if test -n "$with_gallium_drivers"; then
2541     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2542     for driver in $gallium_drivers; do
2543         case "x$driver" in
2544         xsvga)
2545             HAVE_GALLIUM_SVGA=yes
2546             require_libdrm "svga"
2547             ;;
2548         xi915)
2549             HAVE_GALLIUM_I915=yes
2550             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2551             require_libdrm "Gallium i915"
2552             ;;
2553         xr300)
2554             HAVE_GALLIUM_R300=yes
2555             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2556             require_libdrm "r300"
2557             r300_require_llvm "r300"
2558             ;;
2559         xr600)
2560             HAVE_GALLIUM_R600=yes
2561             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2562             require_libdrm "r600"
2563             if test "x$enable_llvm" = xyes; then
2564                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2565
2566                 llvm_add_component "asmparser" "r600"
2567                 llvm_add_component "bitreader" "r600"
2568             fi
2569             ;;
2570         xradeonsi)
2571             HAVE_GALLIUM_RADEONSI=yes
2572             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2573             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2574             require_libdrm "radeonsi"
2575             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2576             if test "x$enable_egl" = xyes; then
2577                 require_basic_egl "radeonsi"
2578             fi
2579             ;;
2580         xnouveau)
2581             HAVE_GALLIUM_NOUVEAU=yes
2582             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2583             require_libdrm "nouveau"
2584             ;;
2585         xfreedreno)
2586             HAVE_GALLIUM_FREEDRENO=yes
2587             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2588             require_libdrm "freedreno"
2589             ;;
2590         xetnaviv)
2591             HAVE_GALLIUM_ETNAVIV=yes
2592             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2593             require_libdrm "etnaviv"
2594             ;;
2595        ximx)
2596             HAVE_GALLIUM_IMX=yes
2597             ;;
2598         xswrast)
2599             HAVE_GALLIUM_SOFTPIPE=yes
2600             if test "x$enable_llvm" = xyes; then
2601                 HAVE_GALLIUM_LLVMPIPE=yes
2602             fi
2603             ;;
2604         xswr)
2605             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2606
2607             if test "x$HAVE_CXX11" != "xyes"; then
2608                 AC_MSG_ERROR([swr requires c++11 support])
2609             fi
2610
2611             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2612                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2613                 SWR_AVX_CXXFLAGS
2614             AC_SUBST([SWR_AVX_CXXFLAGS])
2615
2616             swr_archs=`IFS=', '; echo $with_swr_archs`
2617             for arch in $swr_archs; do
2618                 case "x$arch" in
2619                 xavx)
2620                     HAVE_SWR_AVX=yes
2621                     ;;
2622                 xavx2)
2623                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2624                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2625                         SWR_AVX2_CXXFLAGS
2626                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2627                     HAVE_SWR_AVX2=yes
2628                     ;;
2629                 xknl)
2630                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2631                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2632                         SWR_KNL_CXXFLAGS
2633                     AC_SUBST([SWR_KNL_CXXFLAGS])
2634                     HAVE_SWR_KNL=yes
2635                     ;;
2636                 xskx)
2637                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2638                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2639                         SWR_SKX_CXXFLAGS
2640                     AC_SUBST([SWR_SKX_CXXFLAGS])
2641                     HAVE_SWR_SKX=yes
2642                     ;;
2643                 *)
2644                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2645                     ;;
2646                 esac
2647             done
2648
2649             if test "x$HAVE_SWR_AVX" != xyes -a \
2650                     "x$HAVE_SWR_AVX2" != xyes -a \
2651                     "x$HAVE_SWR_KNL" != xyes -a \
2652                     "x$HAVE_SWR_SKX" != xyes; then
2653                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2654             fi
2655
2656             # test if more than one swr arch configured
2657             if test `echo $swr_archs | wc -w` -eq 1; then
2658                 HAVE_SWR_BUILTIN=yes
2659             fi
2660
2661             HAVE_GALLIUM_SWR=yes
2662             ;;
2663         xvc4)
2664             HAVE_GALLIUM_VC4=yes
2665             require_libdrm "vc4"
2666
2667             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2668                               [USE_VC4_SIMULATOR=yes;
2669                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2670                               [USE_VC4_SIMULATOR=no])
2671             ;;
2672         xvc5)
2673             HAVE_GALLIUM_VC5=yes
2674
2675             PKG_CHECK_MODULES([VC5_SIMULATOR], [v3dv3],
2676                               [USE_VC5_SIMULATOR=yes;
2677                                DEFINES="$DEFINES -DUSE_VC5_SIMULATOR"],
2678                               [AC_MSG_ERROR([vc5 requires the simulator])])
2679             ;;
2680         xpl111)
2681             HAVE_GALLIUM_PL111=yes
2682             ;;
2683         xvirgl)
2684             HAVE_GALLIUM_VIRGL=yes
2685             require_libdrm "virgl"
2686             if test "x$enable_egl" = xyes; then
2687                 require_basic_egl "virgl"
2688             fi
2689             ;;
2690         *)
2691             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2692             ;;
2693         esac
2694     done
2695 fi
2696
2697 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2698 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x4.0.0 -a \
2699                                               "x$LLVM_VERSION" != x4.0.1)
2700
2701 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2702     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2703     llvm_add_default_components "gallium"
2704 fi
2705
2706 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2707 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2708 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2709 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2710 AM_CONDITIONAL(HAVE_SWR_BUILTIN, test "x$HAVE_SWR_BUILTIN" = xyes)
2711
2712 dnl We need to validate some needed dependencies for renderonly drivers.
2713
2714 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2715     AC_MSG_ERROR([Building with imx requires etnaviv])
2716 fi
2717
2718 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2719     AC_MSG_ERROR([Building with pl111 requires vc4])
2720 fi
2721
2722
2723 detect_old_buggy_llvm() {
2724     dnl llvm-config may not give the right answer when llvm is a built as a
2725     dnl single shared library, so we must work the library name out for
2726     dnl ourselves.
2727     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2728     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2729     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2730     AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2731
2732     if test "x$llvm_have_one_so" = xyes; then
2733         dnl LLVM was built using auto*, so there is only one shared object.
2734         LLVM_LIBS="-l$LLVM_SO_NAME"
2735     else
2736         dnl If LLVM was built with CMake, there will be one shared object per
2737         dnl component.
2738         AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2739                [AC_MSG_ERROR([Could not find llvm shared libraries:
2740                 Please make sure you have built llvm with the --enable-shared option
2741                 and that your llvm libraries are installed in $LLVM_LIBDIR
2742                 If you have installed your llvm libraries to a different directory you
2743                 can use the --with-llvm-prefix= configure flag to specify this directory.
2744                 NOTE: Mesa is attempting to use llvm shared libraries by default.
2745                 If you do not want to build with llvm shared libraries and instead want to
2746                 use llvm static libraries then add --disable-llvm-shared-libs to your configure
2747                 invocation and rebuild.])])
2748
2749         dnl We don't need to update LLVM_LIBS in this case because the LLVM
2750         dnl install uses a shared object for each component and we have
2751         dnl already added all of these objects to LLVM_LIBS.
2752     fi
2753 }
2754
2755 dnl
2756 dnl Set defines and buildtime variables only when using LLVM.
2757 dnl
2758 if test "x$enable_llvm" = xyes; then
2759     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2760
2761     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2762     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2763     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2764
2765     dnl Set LLVM_LIBS - This is done after the driver configuration so
2766     dnl that drivers can add additional components to LLVM_COMPONENTS.
2767     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2768     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2769     dnl this was causing the same libraries to be appear multiple times
2770     dnl in LLVM_LIBS.
2771
2772     if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 9; then
2773         if test "x$enable_llvm_shared_libs" = xyes; then
2774             LLVM_LIBS="`$LLVM_CONFIG --link-shared --libs ${LLVM_COMPONENTS}`"
2775         else
2776             dnl Invoking llvm-config with both -libs and --system-libs produces the
2777             dnl two separate lines - each for the set of libraries.
2778                 dnl Call the program twice, effectively folding them into a single line.
2779             LLVM_LIBS="`$LLVM_CONFIG --link-static --libs ${LLVM_COMPONENTS}`"
2780             dnl We need to link to llvm system libs when using static libs
2781             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --link-static --system-libs`"
2782         fi
2783     else
2784         LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2785         if test "x$enable_llvm_shared_libs" = xyes; then
2786             detect_old_buggy_llvm
2787         else
2788             AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2789             dnl We need to link to llvm system libs when using static libs
2790             dnl However, only llvm 3.5+ provides --system-libs
2791             if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2792                 LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2793             fi
2794         fi
2795     fi
2796
2797     dnl The gallium-xlib GLX and gallium OSMesa targets directly embed the
2798     dnl swr/llvmpipe driver into the final binary.  Adding LLVM_LIBS results in
2799     dnl the LLVM library propagated in the Libs.private of the respective .pc
2800     dnl file which ensures complete dependency information when statically
2801     dnl linking.
2802     if test "x$enable_glx" == xgallium-xlib; then
2803         GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $LLVM_LIBS"
2804     fi
2805     if test "x$enable_gallium_osmesa" = xyes; then
2806         OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $LLVM_LIBS"
2807     fi
2808 fi
2809
2810 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2811 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2812 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2813 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2814 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2815 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2816 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2817 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2818 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2819 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2820 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2821 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2822 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2823 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2824 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2825                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2826                                          "x$HAVE_GALLIUM_SWR" = xyes)
2827 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2828 AM_CONDITIONAL(HAVE_GALLIUM_VC5, test "x$HAVE_GALLIUM_VC5" = xyes)
2829 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2830
2831 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2832
2833 if test "x$enable_dri" = xyes; then
2834     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2835 fi
2836
2837 if test "x$have_drisw_kms" = xyes; then
2838     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2839 fi
2840 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2841
2842 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2843 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2844 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2845 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2846 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2847 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2848
2849 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2850 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2851
2852 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2853                                       "x$HAVE_RADEON_VULKAN" = xyes)
2854
2855 AM_CONDITIONAL(HAVE_BROADCOM_DRIVERS, test "x$HAVE_GALLIUM_VC4" = xyes -o \
2856                                       "x$HAVE_GALLIUM_VC5" = xyes)
2857
2858 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2859                                         "x$HAVE_I965_DRI" = xyes)
2860
2861 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2862                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2863                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2864 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2865 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2866 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2867 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2868 AM_CONDITIONAL(USE_VC5_SIMULATOR, test x$USE_VC5_SIMULATOR = xyes)
2869
2870 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2871 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2872 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2873 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2874                                         "x$enable_gallium_osmesa" = xyes)
2875
2876 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2877 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2878 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2879 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2880 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2881 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2882
2883 AC_SUBST([NINE_MAJOR], 1)
2884 AC_SUBST([NINE_MINOR], 0)
2885 AC_SUBST([NINE_PATCH], 0)
2886 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_PATCH")
2887
2888 AC_SUBST([VDPAU_MAJOR], 1)
2889 AC_SUBST([VDPAU_MINOR], 0)
2890
2891 if test "x$enable_va" = xyes; then
2892     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2893     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2894 fi
2895 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2896 AC_SUBST([VA_MINOR], $VA_MINOR)
2897
2898 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2899
2900 AC_SUBST([XVMC_MAJOR], 1)
2901 AC_SUBST([XVMC_MINOR], 0)
2902
2903 AC_SUBST([XA_MAJOR], 2)
2904 AC_SUBST([XA_MINOR], 3)
2905 AC_SUBST([XA_PATCH], 0)
2906 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_PATCH")
2907
2908 AC_ARG_ENABLE(valgrind,
2909               [AS_HELP_STRING([--enable-valgrind],
2910                              [Build mesa with valgrind support (default: auto)])],
2911                              [VALGRIND=$enableval], [VALGRIND=auto])
2912 if test "x$VALGRIND" != xno; then
2913     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2914 fi
2915 AC_MSG_CHECKING([whether to enable Valgrind support])
2916 if test "x$VALGRIND" = xauto; then
2917     VALGRIND="$have_valgrind"
2918 fi
2919
2920 if test "x$VALGRIND" = "xyes"; then
2921     if ! test "x$have_valgrind" = xyes; then
2922         AC_MSG_ERROR([Valgrind support required but not present])
2923     fi
2924     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2925 fi
2926
2927 AC_MSG_RESULT([$VALGRIND])
2928
2929 dnl Restore LDFLAGS and CPPFLAGS
2930 LDFLAGS="$_SAVE_LDFLAGS"
2931 CPPFLAGS="$_SAVE_CPPFLAGS"
2932
2933 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2934 if test "x$acv_mesa_CLANG" = xyes; then
2935     CFLAGS="$CFLAGS -Qunused-arguments"
2936     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2937 fi
2938
2939 dnl Add user CFLAGS and CXXFLAGS
2940 CFLAGS="$CFLAGS $USER_CFLAGS"
2941 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2942
2943 dnl Substitute the config
2944 AC_CONFIG_FILES([Makefile
2945                  src/Makefile
2946                  src/amd/Makefile
2947                  src/amd/vulkan/Makefile
2948                  src/broadcom/Makefile
2949                  src/compiler/Makefile
2950                  src/egl/Makefile
2951                  src/egl/main/egl.pc
2952                  src/egl/wayland/wayland-drm/Makefile
2953                  src/egl/wayland/wayland-egl/Makefile
2954                  src/egl/wayland/wayland-egl/wayland-egl.pc
2955                  src/gallium/Makefile
2956                  src/gallium/auxiliary/Makefile
2957                  src/gallium/auxiliary/pipe-loader/Makefile
2958                  src/gallium/drivers/freedreno/Makefile
2959                  src/gallium/drivers/ddebug/Makefile
2960                  src/gallium/drivers/i915/Makefile
2961                  src/gallium/drivers/llvmpipe/Makefile
2962                  src/gallium/drivers/noop/Makefile
2963                  src/gallium/drivers/nouveau/Makefile
2964                  src/gallium/drivers/pl111/Makefile
2965                  src/gallium/drivers/r300/Makefile
2966                  src/gallium/drivers/r600/Makefile
2967                  src/gallium/drivers/radeon/Makefile
2968                  src/gallium/drivers/radeonsi/Makefile
2969                  src/gallium/drivers/rbug/Makefile
2970                  src/gallium/drivers/softpipe/Makefile
2971                  src/gallium/drivers/svga/Makefile
2972                  src/gallium/drivers/swr/Makefile
2973                  src/gallium/drivers/trace/Makefile
2974                  src/gallium/drivers/etnaviv/Makefile
2975                  src/gallium/drivers/imx/Makefile
2976                  src/gallium/drivers/vc4/Makefile
2977                  src/gallium/drivers/vc5/Makefile
2978                  src/gallium/drivers/virgl/Makefile
2979                  src/gallium/state_trackers/clover/Makefile
2980                  src/gallium/state_trackers/dri/Makefile
2981                  src/gallium/state_trackers/glx/xlib/Makefile
2982                  src/gallium/state_trackers/nine/Makefile
2983                  src/gallium/state_trackers/omx_bellagio/Makefile
2984                  src/gallium/state_trackers/osmesa/Makefile
2985                  src/gallium/state_trackers/va/Makefile
2986                  src/gallium/state_trackers/vdpau/Makefile
2987                  src/gallium/state_trackers/xa/Makefile
2988                  src/gallium/state_trackers/xa/xa_tracker.h
2989                  src/gallium/state_trackers/xvmc/Makefile
2990                  src/gallium/targets/d3dadapter9/Makefile
2991                  src/gallium/targets/d3dadapter9/d3d.pc
2992                  src/gallium/targets/dri/Makefile
2993                  src/gallium/targets/libgl-xlib/Makefile
2994                  src/gallium/targets/omx-bellagio/Makefile
2995                  src/gallium/targets/opencl/Makefile
2996                  src/gallium/targets/opencl/mesa.icd
2997                  src/gallium/targets/osmesa/Makefile
2998                  src/gallium/targets/osmesa/osmesa.pc
2999                  src/gallium/targets/pipe-loader/Makefile
3000                  src/gallium/targets/va/Makefile
3001                  src/gallium/targets/vdpau/Makefile
3002                  src/gallium/targets/xa/Makefile
3003                  src/gallium/targets/xa/xatracker.pc
3004                  src/gallium/targets/xvmc/Makefile
3005                  src/gallium/tests/trivial/Makefile
3006                  src/gallium/tests/unit/Makefile
3007                  src/gallium/winsys/etnaviv/drm/Makefile
3008                  src/gallium/winsys/imx/drm/Makefile
3009                  src/gallium/winsys/freedreno/drm/Makefile
3010                  src/gallium/winsys/i915/drm/Makefile
3011                  src/gallium/winsys/nouveau/drm/Makefile
3012                  src/gallium/winsys/pl111/drm/Makefile
3013                  src/gallium/winsys/radeon/drm/Makefile
3014                  src/gallium/winsys/amdgpu/drm/Makefile
3015                  src/gallium/winsys/svga/drm/Makefile
3016                  src/gallium/winsys/sw/dri/Makefile
3017                  src/gallium/winsys/sw/kms-dri/Makefile
3018                  src/gallium/winsys/sw/null/Makefile
3019                  src/gallium/winsys/sw/wrapper/Makefile
3020                  src/gallium/winsys/sw/xlib/Makefile
3021                  src/gallium/winsys/vc4/drm/Makefile
3022                  src/gallium/winsys/vc5/drm/Makefile
3023                  src/gallium/winsys/virgl/drm/Makefile
3024                  src/gallium/winsys/virgl/vtest/Makefile
3025                  src/gbm/Makefile
3026                  src/gbm/main/gbm.pc
3027                  src/glx/Makefile
3028                  src/glx/apple/Makefile
3029                  src/glx/tests/Makefile
3030                  src/glx/windows/Makefile
3031                  src/glx/windows/windowsdriproto.pc
3032                  src/gtest/Makefile
3033                  src/intel/Makefile
3034                  src/loader/Makefile
3035                  src/mapi/Makefile
3036                  src/mapi/es1api/glesv1_cm.pc
3037                  src/mapi/es2api/glesv2.pc
3038                  src/mapi/glapi/gen/Makefile
3039                  src/mesa/Makefile
3040                  src/mesa/gl.pc
3041                  src/mesa/drivers/dri/dri.pc
3042                  src/mesa/drivers/dri/common/Makefile
3043                  src/mesa/drivers/dri/i915/Makefile
3044                  src/mesa/drivers/dri/i965/Makefile
3045                  src/mesa/drivers/dri/Makefile
3046                  src/mesa/drivers/dri/nouveau/Makefile
3047                  src/mesa/drivers/dri/r200/Makefile
3048                  src/mesa/drivers/dri/radeon/Makefile
3049                  src/mesa/drivers/dri/swrast/Makefile
3050                  src/mesa/drivers/osmesa/Makefile
3051                  src/mesa/drivers/osmesa/osmesa.pc
3052                  src/mesa/drivers/x11/Makefile
3053                  src/mesa/main/tests/Makefile
3054                  src/mesa/state_tracker/tests/Makefile
3055                  src/util/Makefile
3056                  src/util/tests/hash_table/Makefile
3057                  src/util/tests/string_buffer/Makefile
3058                  src/util/xmlpool/Makefile
3059                  src/vulkan/Makefile])
3060
3061 AC_OUTPUT
3062
3063 # Fix up dependencies in *.Plo files, where we changed the extension of a
3064 # source file
3065 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
3066
3067 rm -f src/compiler/spirv/spirv_info.lo
3068 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
3069
3070 dnl
3071 dnl Output some configuration info for the user
3072 dnl
3073 echo ""
3074 echo "        prefix:          $prefix"
3075 echo "        exec_prefix:     $exec_prefix"
3076 echo "        libdir:          $libdir"
3077 echo "        includedir:      $includedir"
3078
3079 dnl API info
3080 echo ""
3081 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
3082
3083 dnl Driver info
3084 echo ""
3085 case "x$enable_osmesa$enable_gallium_osmesa" in
3086 xnoyes)
3087         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
3088         ;;
3089 xyesno)
3090         echo "        OSMesa:          lib$OSMESA_LIB"
3091         ;;
3092 xnono)
3093         echo "        OSMesa:          no"
3094         ;;
3095 esac
3096
3097 echo ""
3098 if test "x$enable_dri" != xno; then
3099         echo "        DRI platform:    $dri_platform"
3100         if test -z "$DRI_DIRS"; then
3101             echo "        DRI drivers:     no"
3102         else
3103             echo "        DRI drivers:     $DRI_DIRS"
3104         fi
3105         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
3106 fi
3107
3108 case "x$enable_glx" in
3109 xdri)
3110     echo "        GLX:             DRI-based"
3111     ;;
3112 xxlib)
3113     echo "        GLX:             Xlib-based"
3114     ;;
3115 xgallium-xlib)
3116     echo "        GLX:             Xlib-based (Gallium)"
3117     ;;
3118 *)
3119     echo "        GLX:             $enable_glx"
3120     ;;
3121 esac
3122
3123 dnl EGL
3124 echo ""
3125 echo "        EGL:             $enable_egl"
3126 if test "$enable_egl" = yes; then
3127
3128     egl_drivers=""
3129     if test "x$enable_dri" != "xno"; then
3130         egl_drivers="$egl_drivers builtin:egl_dri2"
3131     fi
3132     if test "x$enable_dri3" != "xno"; then
3133         egl_drivers="$egl_drivers builtin:egl_dri3"
3134     fi
3135
3136     echo "        EGL drivers:    $egl_drivers"
3137 fi
3138 if test "x$enable_gbm" = xyes; then
3139     echo "        GBM:             yes"
3140 else
3141     echo "        GBM:             no"
3142 fi
3143
3144     echo "        EGL/Vulkan/VL platforms:   $platforms"
3145
3146 # Vulkan
3147 echo ""
3148 if test "x$VULKAN_DRIVERS" != x; then
3149     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
3150     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
3151 else
3152     echo "        Vulkan drivers:  no"
3153 fi
3154
3155 echo ""
3156 if test "x$enable_llvm" = xyes; then
3157     echo "        llvm:            yes"
3158     echo "        llvm-config:     $LLVM_CONFIG"
3159     echo "        llvm-version:    $LLVM_VERSION"
3160 else
3161     echo "        llvm:            no"
3162 fi
3163
3164 echo ""
3165 if test -n "$with_gallium_drivers"; then
3166     echo "        Gallium drivers: $gallium_drivers"
3167     echo "        Gallium st:      $gallium_st"
3168 else
3169     echo "        Gallium:         no"
3170 fi
3171
3172 echo ""
3173 if test "x$enable_gallium_extra_hud" != xyes; then
3174     echo "        HUD extra stats: no"
3175 else
3176     echo "        HUD extra stats: yes"
3177 fi
3178
3179 if test "x$enable_lmsensors" != xyes; then
3180     echo "        HUD lmsensors:   no"
3181 else
3182     echo "        HUD lmsensors:   yes"
3183 fi
3184
3185 echo ""
3186 if test "x$HAVE_GALLIUM_SWR" != x; then
3187     if test "x$HAVE_SWR_BUILTIN" = xyes; then
3188         echo "        SWR archs:       $swr_archs (builtin)"
3189     else
3190         echo "        SWR archs:       $swr_archs"
3191     fi
3192 fi
3193
3194 dnl Libraries
3195 echo ""
3196 echo "        Shared libs:     $enable_shared"
3197 echo "        Static libs:     $enable_static"
3198 echo "        Shared-glapi:    $enable_shared_glapi"
3199
3200 dnl Compiler options
3201 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3202 cflags=`echo $CFLAGS | \
3203     $SED 's/^ *//;s/  */ /;s/ *$//'`
3204 cxxflags=`echo $CXXFLAGS | \
3205     $SED 's/^ *//;s/  */ /;s/ *$//'`
3206 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3207 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3208 echo ""
3209 echo "        CFLAGS:          $cflags"
3210 echo "        CXXFLAGS:        $cxxflags"
3211 echo "        CXX11_CXXFLAGS:  $CXX11_CXXFLAGS"
3212 echo "        LDFLAGS:         $ldflags"
3213 echo "        Macros:          $defines"
3214 echo ""
3215 if test "x$enable_llvm" = xyes; then
3216     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3217     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3218     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3219     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3220     echo ""
3221 fi
3222 echo "        PYTHON2:         $PYTHON2"
3223
3224 echo ""
3225 echo "        Run '${MAKE-make}' to build Mesa"
3226 echo ""