configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 dnl http://people.gnome.org/~walters/docs/build-api.txt
  18 dnl We don't support srcdir != builddir.
  19 echo \#buildapi-variable-no-builddir >/dev/null
  20
  21 # Support silent build rules, requires at least automake-1.11. Disable
  22 # by either passing --disable-silent-rules to configure or passing V=1
  23 # to make
  24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  25     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  26
  27 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  28
  29 dnl Set internal versions
  30 OSMESA_VERSION=8
  31 AC_SUBST([OSMESA_VERSION])
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.46
  36 LIBDRM_INTEL_REQUIRED=2.4.38
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  39 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  40 DRI2PROTO_REQUIRED=2.6
  41 GLPROTO_REQUIRED=1.4.14
  42 LIBDRM_XORG_REQUIRED=2.4.24
  43 LIBKMS_XORG_REQUIRED=1.0.0
  44
  45 dnl Check for progs
  46 AC_PROG_CPP
  47 AC_PROG_CC
  48 AC_PROG_CXX
  49 AM_PROG_CC_C_O
  50 AM_PROG_AS
  51 AC_CHECK_PROGS([MAKE], [gmake make])
  52 AC_CHECK_PROGS([PYTHON2], [python2 python])
  53 AX_PYTHON_MODULE([libxml2], [needed])
  54 AC_PROG_SED
  55 AC_PROG_MKDIR_P
  56
  57 LT_PREREQ([2.2])
  58 LT_INIT([disable-static])
  59
  60 AX_PROG_BISON([],
  61               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  62                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  63 AX_PROG_FLEX([],
  64              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  65                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  72 fi
  73
  74 AC_PROG_INSTALL
  75
  76 dnl We need a POSIX shell for parts of the build. Assume we have one
  77 dnl in most cases.
  78 case "$host_os" in
  79 solaris*)
  80     # Solaris /bin/sh is too old/non-POSIX compliant
  81     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  82     SHELL="$POSIX_SHELL"
  83     ;;
  84 esac
  85
  86 dnl clang is mostly GCC-compatible, but its version is much lower,
  87 dnl so we have to check for it.
  88 AC_MSG_CHECKING([if compiling with clang])
  89
  90 AC_COMPILE_IFELSE(
  91 [AC_LANG_PROGRAM([], [[
  92 #ifndef __clang__
  93        not clang
  94 #endif
  95 ]])],
  96 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  97
  98 AC_MSG_RESULT([$acv_mesa_CLANG])
  99
 100 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 101 dnl versions are explictly not supported.
 102 GEN_ASM_OFFSETS=no
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120
 121     if test "x$cross_compiling" = xyes; then
 122         GEN_ASM_OFFSETS=yes
 123     fi
 124 fi
 125 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 126
 127 dnl Make sure the pkg-config macros are defined
 128 m4_ifndef([PKG_PROG_PKG_CONFIG],
 129     [m4_fatal([Could not locate the pkg-config autoconf macros.
 130   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 131   are in a different location, try setting the environment variable
 132   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 133 PKG_PROG_PKG_CONFIG()
 134
 135 dnl LIB_DIR - library basename
 136 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 137 AC_SUBST([LIB_DIR])
 138
 139 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 140 _SAVE_LDFLAGS="$LDFLAGS"
 141 _SAVE_CPPFLAGS="$CPPFLAGS"
 142
 143 dnl Compiler macros
 144 DEFINES=""
 145 AC_SUBST([DEFINES])
 146 case "$host_os" in
 147 linux*|*-gnu*|gnu*)
 148     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 149     ;;
 150 solaris*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 152     ;;
 153 cygwin*)
 154     DEFINES="$DEFINES -DHAVE_PTHREAD"
 155     ;;
 156 esac
 157
 158 dnl Add flags for gcc and g++
 159 if test "x$GCC" = xyes; then
 160     case "$host_os" in
 161     cygwin*)
 162         CFLAGS="$CFLAGS -Wall -std=gnu99"
 163         ;;
 164     *)
 165         CFLAGS="$CFLAGS -Wall -std=c99"
 166         ;;
 167     esac
 168
 169     # Enable -Werror=implicit-function-declaration and
 170     # -Werror=missing-prototypes, if available, or otherwise, just
 171     # -Wmissing-prototypes.  This is particularly useful to avoid
 172     # generating a loadable driver module that has undefined symbols.
 173     save_CFLAGS="$CFLAGS"
 174     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 175     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 176     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 177     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 178                    AC_MSG_RESULT([yes]),
 179                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 180                     AC_MSG_RESULT([no])]);
 181
 182     # Enable -fvisibility=hidden if using a gcc that supports it
 183     save_CFLAGS="$CFLAGS"
 184     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 185     VISIBILITY_CFLAGS="-fvisibility=hidden"
 186     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 187     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 188                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 189
 190     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 191     CFLAGS=$save_CFLAGS
 192
 193     # Work around aliasing bugs - developers should comment this out
 194     CFLAGS="$CFLAGS -fno-strict-aliasing"
 195
 196     # gcc's builtin memcmp is slower than glibc's
 197     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 198     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 199 fi
 200 if test "x$GXX" = xyes; then
 201     CXXFLAGS="$CXXFLAGS -Wall"
 202
 203     # Enable -fvisibility=hidden if using a gcc that supports it
 204     save_CXXFLAGS="$CXXFLAGS"
 205     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 206     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 207     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 208     AC_LANG_PUSH([C++])
 209     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 210                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 211     AC_LANG_POP([C++])
 212
 213     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 214     CXXFLAGS=$save_CXXFLAGS
 215
 216     # Work around aliasing bugs - developers should comment this out
 217     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 218
 219     # gcc's builtin memcmp is slower than glibc's
 220     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 221     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 222 fi
 223
 224 dnl even if the compiler appears to support it, using visibility attributes isn't
 225 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 226 case "$host_os" in
 227 cygwin*)
 228     VISIBILITY_CFLAGS=""
 229     VISIBILITY_CXXFLAGS=""
 230     ;;
 231 esac
 232
 233 AC_SUBST([VISIBILITY_CFLAGS])
 234 AC_SUBST([VISIBILITY_CXXFLAGS])
 235
 236 dnl
 237 dnl Hacks to enable 32 or 64 bit build
 238 dnl
 239 AC_ARG_ENABLE([32-bit],
 240     [AS_HELP_STRING([--enable-32-bit],
 241         [build 32-bit libraries @<:@default=auto@:>@])],
 242     [enable_32bit="$enableval"],
 243     [enable_32bit=auto]
 244 )
 245 if test "x$enable_32bit" = xyes; then
 246     if test "x$GCC" = xyes; then
 247         CFLAGS="$CFLAGS -m32"
 248         CCASFLAGS="$CCASFLAGS -m32"
 249     fi
 250     if test "x$GXX" = xyes; then
 251         CXXFLAGS="$CXXFLAGS -m32"
 252     fi
 253 fi
 254 AC_ARG_ENABLE([64-bit],
 255     [AS_HELP_STRING([--enable-64-bit],
 256         [build 64-bit libraries @<:@default=auto@:>@])],
 257     [enable_64bit="$enableval"],
 258     [enable_64bit=auto]
 259 )
 260 if test "x$enable_64bit" = xyes; then
 261     if test "x$GCC" = xyes; then
 262         CFLAGS="$CFLAGS -m64"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m64"
 266     fi
 267 fi
 268
 269 dnl Can't have static and shared libraries, default to static if user
 270 dnl explicitly requested. If both disabled, set to static since shared
 271 dnl was explicitly requested.
 272 case "x$enable_static$enable_shared" in
 273 xyesyes )
 274     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 275     enable_shared=no
 276     ;;
 277 xnono )
 278     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 279     enable_static=yes
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 284
 285 dnl
 286 dnl other compiler options
 287 dnl
 288 AC_ARG_ENABLE([debug],
 289     [AS_HELP_STRING([--enable-debug],
 290         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 291     [enable_debug="$enableval"],
 292     [enable_debug=no]
 293 )
 294 if test "x$enable_debug" = xyes; then
 295     DEFINES="$DEFINES -DDEBUG"
 296     if test "x$GCC" = xyes; then
 297         CFLAGS="$CFLAGS -g -O0"
 298     fi
 299     if test "x$GXX" = xyes; then
 300         CXXFLAGS="$CXXFLAGS -g -O0"
 301     fi
 302 fi
 303
 304 dnl
 305 dnl library names
 306 dnl
 307 LIB_PREFIX_GLOB='lib'
 308 LIB_VERSION_SEPARATOR='.'
 309 if test "$enable_static" = yes; then
 310     LIB_EXTENSION='a'
 311 else
 312     case "$host_os" in
 313     darwin* )
 314         LIB_EXTENSION='dylib' ;;
 315     cygwin* )
 316         dnl prefix can be 'cyg' or 'lib'
 317         LIB_PREFIX_GLOB='???'
 318         LIB_VERSION_SEPARATOR='-'
 319         LIB_EXTENSION='dll' ;;
 320     aix* )
 321         LIB_EXTENSION='a' ;;
 322     * )
 323         LIB_EXTENSION='so' ;;
 324     esac
 325 fi
 326 AC_ARG_WITH([gl-lib-name],
 327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 328     [specify GL library name @<:@default=GL@:>@])],
 329   [GL_LIB=$withval],
 330   [GL_LIB=GL])
 331 AC_ARG_WITH([osmesa-lib-name],
 332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 334   [OSMESA_LIB=$withval],
 335   [OSMESA_LIB=OSMesa])
 336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 338
 339 dnl
 340 dnl Mangled Mesa support
 341 dnl
 342 AC_ARG_ENABLE([mangling],
 343   [AS_HELP_STRING([--enable-mangling],
 344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 345   [enable_mangling="${enableval}"],
 346   [enable_mangling=no]
 347 )
 348 if test "x${enable_mangling}" = "xyes" ; then
 349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 350   GL_LIB="Mangled${GL_LIB}"
 351   OSMESA_LIB="Mangled${OSMESA_LIB}"
 352 fi
 353 AC_SUBST([GL_LIB])
 354 AC_SUBST([OSMESA_LIB])
 355
 356 dnl
 357 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 358 dnl
 359 AC_ARG_ENABLE([texture-float],
 360     [AS_HELP_STRING([--enable-texture-float],
 361         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 362     [enable_texture_float="$enableval"],
 363     [enable_texture_float=no]
 364 )
 365 if test "x$enable_texture_float" = xyes; then
 366     AC_MSG_WARN([Floating-point textures enabled.])
 367     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 368     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 369 fi
 370
 371 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 372 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 373 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 374 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 375 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 376 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 377 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 378
 379 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 381 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 382 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386
 387 AC_SUBST([GL_LIB_NAME])
 388 AC_SUBST([OSMESA_LIB_NAME])
 389 AC_SUBST([EGL_LIB_NAME])
 390 AC_SUBST([GLESv1_CM_LIB_NAME])
 391 AC_SUBST([GLESv2_LIB_NAME])
 392 AC_SUBST([VG_LIB_NAME])
 393 AC_SUBST([GLAPI_LIB_NAME])
 394
 395 AC_SUBST([GL_LIB_GLOB])
 396 AC_SUBST([EGL_LIB_GLOB])
 397 AC_SUBST([GLESv1_CM_LIB_GLOB])
 398 AC_SUBST([GLESv2_LIB_GLOB])
 399 AC_SUBST([VG_LIB_GLOB])
 400 AC_SUBST([GLAPI_LIB_GLOB])
 401
 402 dnl
 403 dnl Arch/platform-specific settings
 404 dnl
 405 AC_ARG_ENABLE([asm],
 406     [AS_HELP_STRING([--disable-asm],
 407         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 408     [enable_asm="$enableval"],
 409     [enable_asm=yes]
 410 )
 411 asm_arch=""
 412 AC_MSG_CHECKING([whether to enable assembly])
 413 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 414 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 415 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 416     case "$host_cpu" in
 417     i?86 | x86_64 | amd64)
 418         enable_asm=no
 419         AC_MSG_RESULT([no, cross compiling])
 420         ;;
 421     esac
 422 fi
 423 # check for supported arches
 424 if test "x$enable_asm" = xyes; then
 425     case "$host_cpu" in
 426     i?86)
 427         case "$host_os" in
 428         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 429             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 430             ;;
 431         gnu*)
 432             asm_arch=x86
 433             ;;
 434         esac
 435         ;;
 436     x86_64|amd64)
 437         case "$host_os" in
 438         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 439             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 440             ;;
 441         esac
 442         ;;
 443     sparc*)
 444         case "$host_os" in
 445         linux*)
 446             asm_arch=sparc
 447             ;;
 448         esac
 449         ;;
 450     esac
 451
 452     case "$asm_arch" in
 453     x86)
 454         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 455         AC_MSG_RESULT([yes, x86])
 456         ;;
 457     x86_64|amd64)
 458         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 459         AC_MSG_RESULT([yes, x86_64])
 460         ;;
 461     sparc)
 462         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 463         AC_MSG_RESULT([yes, sparc])
 464         ;;
 465     *)
 466         AC_MSG_RESULT([no, platform not supported])
 467         ;;
 468     esac
 469 fi
 470
 471 dnl Check to see if dlopen is in default libraries (like Solaris, which
 472 dnl has it in libc), or if libdl is needed to get it.
 473 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 474     [AC_CHECK_LIB([dl], [dlopen],
 475        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 476 AC_SUBST([DLOPEN_LIBS])
 477
 478 case "$host_os" in
 479 darwin*|mingw*)
 480     ;;
 481 *)
 482     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 483                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 484                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 485     AC_SUBST([CLOCK_LIB])
 486     ;;
 487 esac
 488
 489 dnl See if posix_memalign is available
 490 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 491
 492 dnl Check for pthreads
 493 AX_PTHREAD
 494 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 495 dnl to -pthread, which causes problems if we need -lpthread to appear in
 496 dnl pkgconfig files.
 497 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 498
 499 dnl SELinux awareness.
 500 AC_ARG_ENABLE([selinux],
 501     [AS_HELP_STRING([--enable-selinux],
 502         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 503     [MESA_SELINUX="$enableval"],
 504     [MESA_SELINUX=no])
 505 if test "x$enable_selinux" = "xyes"; then
 506     AC_CHECK_HEADER([selinux/selinux.h],[],
 507                     [AC_MSG_ERROR([SELinux headers not found])])
 508     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 509                  [AC_MSG_ERROR([SELinux library not found])])
 510     SELINUX_LIBS="-lselinux"
 511     DEFINES="$DEFINES -DMESA_SELINUX"
 512 fi
 513 AC_SUBST([SELINUX_LIBS])
 514
 515 dnl Options for APIs
 516 AC_ARG_ENABLE([opengl],
 517     [AS_HELP_STRING([--disable-opengl],
 518         [disable support for standard OpenGL API @<:@default=no@:>@])],
 519     [enable_opengl="$enableval"],
 520     [enable_opengl=yes])
 521 AC_ARG_ENABLE([gles1],
 522     [AS_HELP_STRING([--enable-gles1],
 523         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 524     [enable_gles1="$enableval"],
 525     [enable_gles1=no])
 526 AC_ARG_ENABLE([gles2],
 527     [AS_HELP_STRING([--enable-gles2],
 528         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 529     [enable_gles2="$enableval"],
 530     [enable_gles2=no])
 531 AC_ARG_ENABLE([openvg],
 532     [AS_HELP_STRING([--enable-openvg],
 533         [enable support for OpenVG API @<:@default=no@:>@])],
 534     [enable_openvg="$enableval"],
 535     [enable_openvg=no])
 536
 537 AC_ARG_ENABLE([dri],
 538     [AS_HELP_STRING([--enable-dri],
 539         [enable DRI modules @<:@default=enabled@:>@])],
 540     [enable_dri="$enableval"],
 541     [enable_dri=yes])
 542 AC_ARG_ENABLE([glx],
 543     [AS_HELP_STRING([--enable-glx],
 544         [enable GLX library @<:@default=enabled@:>@])],
 545     [enable_glx="$enableval"],
 546     [enable_glx=yes])
 547 AC_ARG_ENABLE([osmesa],
 548     [AS_HELP_STRING([--enable-osmesa],
 549         [enable OSMesa library @<:@default=disabled@:>@])],
 550     [enable_osmesa="$enableval"],
 551     [enable_osmesa=no])
 552 AC_ARG_ENABLE([gallium-osmesa],
 553     [AS_HELP_STRING([--enable-gallium-osmesa],
 554         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 555     [enable_gallium_osmesa="$enableval"],
 556     [enable_gallium_osmesa=no])
 557 AC_ARG_ENABLE([egl],
 558     [AS_HELP_STRING([--disable-egl],
 559         [disable EGL library @<:@default=enabled@:>@])],
 560     [enable_egl="$enableval"],
 561     [enable_egl=yes])
 562
 563 AC_ARG_ENABLE([xorg],
 564     [AS_HELP_STRING([--enable-xorg],
 565         [enable support for X.Org DDX API @<:@default=no@:>@])],
 566     [enable_xorg="$enableval"],
 567     [enable_xorg=no])
 568 AC_ARG_ENABLE([xa],
 569     [AS_HELP_STRING([--enable-xa],
 570         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 571     [enable_xa="$enableval"],
 572     [enable_xa=no])
 573 AC_ARG_ENABLE([gbm],
 574    [AS_HELP_STRING([--enable-gbm],
 575          [enable gbm library @<:@default=auto@:>@])],
 576    [enable_gbm="$enableval"],
 577    [enable_gbm=auto])
 578
 579 AC_ARG_ENABLE([xvmc],
 580    [AS_HELP_STRING([--enable-xvmc],
 581          [enable xvmc library @<:@default=auto@:>@])],
 582    [enable_xvmc="$enableval"],
 583    [enable_xvmc=auto])
 584 AC_ARG_ENABLE([vdpau],
 585    [AS_HELP_STRING([--enable-vdpau],
 586          [enable vdpau library @<:@default=auto@:>@])],
 587    [enable_vdpau="$enableval"],
 588    [enable_vdpau=auto])
 589 AC_ARG_ENABLE([opencl],
 590    [AS_HELP_STRING([--enable-opencl],
 591          [enable OpenCL library NOTE: Enabling this option will also enable
 592           --with-llvm-shared-libs
 593           @<:@default=no@:>@])],
 594    [],
 595    [enable_opencl=no])
 596 AC_ARG_ENABLE([opencl_icd],
 597    [AS_HELP_STRING([--enable-opencl-icd],
 598           [Build an OpenCL ICD library to be loaded by an ICD implementation
 599            @<:@default=no@:>@])],
 600     [enable_opencl_icd="$enableval"],
 601     [enable_opencl_icd=no])
 602 AC_ARG_ENABLE([xlib-glx],
 603     [AS_HELP_STRING([--enable-xlib-glx],
 604         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 605     [enable_xlib_glx="$enableval"],
 606     [enable_xlib_glx=no])
 607 AC_ARG_ENABLE([gallium-egl],
 608     [AS_HELP_STRING([--enable-gallium-egl],
 609         [enable optional EGL state tracker (not required
 610          for EGL support in Gallium with OpenGL and OpenGL ES)
 611          @<:@default=disable@:>@])],
 612     [enable_gallium_egl="$enableval"],
 613     [enable_gallium_egl=no])
 614 AC_ARG_ENABLE([gallium-gbm],
 615     [AS_HELP_STRING([--enable-gallium-gbm],
 616         [enable optional gbm state tracker (not required for
 617          gbm support in Gallium)
 618          @<:@default=auto@:>@])],
 619     [enable_gallium_gbm="$enableval"],
 620     [enable_gallium_gbm=auto])
 621
 622 AC_ARG_ENABLE([r600-llvm-compiler],
 623     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 624         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 625     [enable_r600_llvm="$enableval"],
 626     [enable_r600_llvm=no])
 627
 628 AC_ARG_ENABLE([gallium-tests],
 629     [AS_HELP_STRING([--enable-gallium-tests],
 630         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 631     [enable_gallium_tests="$enableval"],
 632     [enable_gallium_tests=no])
 633
 634 # Option for Gallium drivers
 635
 636 # Keep this in sync with the --with-gallium-drivers help string default value
 637 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 638
 639 AC_ARG_WITH([gallium-drivers],
 640     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 641         [comma delimited Gallium drivers list, e.g.
 642         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 643         @<:@default=r300,r600,svga,swrast@:>@])],
 644     [with_gallium_drivers="$withval"],
 645     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 646
 647 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 648 # here so that the script doesn't choke on an unknown driver name later.
 649 case "$with_gallium_drivers" in
 650     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 651     no) with_gallium_drivers='' ;;
 652 esac
 653
 654 if test "x$enable_opengl" = xno -a \
 655         "x$enable_gles1" = xno -a \
 656         "x$enable_gles2" = xno -a \
 657         "x$enable_openvg" = xno -a \
 658         "x$enable_xorg" = xno -a \
 659         "x$enable_xa" = xno -a \
 660         "x$enable_xvmc" = xno -a \
 661         "x$enable_vdpau" = xno -a \
 662         "x$enable_opencl" = xno; then
 663     AC_MSG_ERROR([at least one API should be enabled])
 664 fi
 665
 666 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xyes; then
 669     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 670 fi
 671
 672 if test "x$enable_opengl" = xno -a \
 673         "x$enable_gles2" = xyes; then
 674     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 675 fi
 676
 677 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 678 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 679 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 680 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 681                                         "x$enable_gles1" = xyes -o \
 682                                         "x$enable_gles2" = xyes)
 683
 684 if test "x$enable_glx" = xno; then
 685     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 686     enable_xlib_glx=no
 687 fi
 688
 689 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 690     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 691 fi
 692
 693 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 694     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 695 fi
 696
 697 # Disable GLX if OpenGL is not enabled
 698 if test "x$enable_glx$enable_opengl" = xyesno; then
 699     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 700     enable_glx=no
 701 fi
 702
 703 # Disable GLX if DRI and Xlib-GLX are not enabled
 704 if test "x$enable_glx" = xyes -a \
 705         "x$enable_dri" = xno -a \
 706         "x$enable_xlib_glx" = xno; then
 707     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 708     enable_glx=no
 709 fi
 710
 711 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 712                                   "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 714
 715 AC_ARG_ENABLE([shared-glapi],
 716     [AS_HELP_STRING([--enable-shared-glapi],
 717         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 718     [enable_shared_glapi="$enableval"],
 719     [enable_shared_glapi="$enable_dri"])
 720
 721 # Shared GLAPI is only useful for DRI
 722 if test "x$enable_dri" = xno; then
 723     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 724     enable_shared_glapi=no
 725 fi
 726
 727 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 728
 729 dnl
 730 dnl Driver specific build directories
 731 dnl
 732 GALLIUM_TARGET_DIRS=""
 733 GALLIUM_WINSYS_DIRS="sw"
 734 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 735 GALLIUM_STATE_TRACKERS_DIRS=""
 736
 737 case "x$enable_glx$enable_xlib_glx" in
 738 xyesyes)
 739     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 740     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 741     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 742     NEED_WINSYS_XLIB="yes"
 743     ;;
 744 esac
 745
 746 if test "x$enable_dri" = xyes; then
 747     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 748     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 749 fi
 750
 751 if test "x$enable_gallium_osmesa" = xyes; then
 752     if test -z "$with_gallium_drivers"; then
 753         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 754     fi
 755     if test "x$enable_osmesa" = xyes; then
 756         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 757     fi
 758     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 759     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 760 fi
 761
 762 AC_SUBST([MESA_LLVM])
 763
 764 # Check for libdrm
 765 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 766                   [have_libdrm=yes], [have_libdrm=no])
 767
 768 if test "x$enable_dri" = xyes; then
 769     # DRI must be shared, I think
 770     if test "$enable_static" = yes; then
 771         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 772     fi
 773
 774     # not a hard requirement as swrast does not depend on it
 775     if test "x$have_libdrm" = xyes; then
 776         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 777     fi
 778 fi
 779
 780 dnl Direct rendering or just indirect rendering
 781 case "$host_os" in
 782 gnu*)
 783     dnl Disable by default on GNU/Hurd
 784     driglx_direct_default="no"
 785     ;;
 786 cygwin*)
 787     dnl Disable by default on cygwin
 788     driglx_direct_default="no"
 789     ;;
 790 *)
 791     driglx_direct_default="yes"
 792     ;;
 793 esac
 794 AC_ARG_ENABLE([driglx-direct],
 795     [AS_HELP_STRING([--disable-driglx-direct],
 796         [disable direct rendering in GLX and EGL for DRI \
 797             @<:@default=auto@:>@])],
 798     [driglx_direct="$enableval"],
 799     [driglx_direct="$driglx_direct_default"])
 800
 801 dnl
 802 dnl libGL configuration per driver
 803 dnl
 804 case "x$enable_glx$enable_xlib_glx" in
 805 xyesyes)
 806     # Xlib-based GLX
 807     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 808     GL_PC_REQ_PRIV="x11 xext"
 809     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 810     GL_LIB_DEPS="$XLIBGL_LIBS"
 811     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 812     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 813     ;;
 814 xyesno)
 815     # DRI-based GLX
 816     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 817     if test x"$driglx_direct" = xyes; then
 818         if test "x$have_libdrm" != xyes; then
 819             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 820         fi
 821         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 822         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 823     fi
 824
 825     # find the DRI deps for libGL
 826     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 827
 828     # add xf86vidmode if available
 829     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 830     if test "$HAVE_XF86VIDMODE" = yes ; then
 831         dri_modules="$dri_modules xxf86vm"
 832     fi
 833
 834     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 835     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 836     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 837     GL_LIB_DEPS="$DRIGL_LIBS"
 838
 839     # need DRM libs, $PTHREAD_LIBS, etc.
 840     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 841     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 842     ;;
 843 esac
 844
 845 # This is outside the case (above) so that it is invoked even for non-GLX
 846 # builds.
 847 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 848
 849 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 850 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 851 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 852 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853
 854 AC_SUBST([X11_INCLUDES])
 855 AC_SUBST([GL_LIB_DEPS])
 856 AC_SUBST([GL_PC_REQ_PRIV])
 857 AC_SUBST([GL_PC_LIB_PRIV])
 858 AC_SUBST([GL_PC_CFLAGS])
 859 AC_SUBST([DRI_PC_REQ_PRIV])
 860 AC_SUBST([GLESv1_CM_LIB_DEPS])
 861 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 862 AC_SUBST([GLESv2_LIB_DEPS])
 863 AC_SUBST([GLESv2_PC_LIB_PRIV])
 864
 865 AC_SUBST([HAVE_XF86VIDMODE])
 866
 867 dnl
 868 dnl More GLX setup
 869 dnl
 870 case "x$enable_glx$enable_xlib_glx" in
 871 xyesyes)
 872     DEFINES="$DEFINES -DUSE_XSHM"
 873     ;;
 874 xyesno)
 875     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 876     if test "x$driglx_direct" = xyes; then
 877         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 878     fi
 879     ;;
 880 esac
 881
 882 dnl
 883 dnl TLS detection
 884 dnl
 885
 886 AC_ARG_ENABLE([glx-tls],
 887     [AS_HELP_STRING([--enable-glx-tls],
 888         [enable TLS support in GLX @<:@default=disabled@:>@])],
 889     [GLX_USE_TLS="$enableval"],
 890     [GLX_USE_TLS=no])
 891 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 892
 893 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 894       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 895
 896 dnl
 897 dnl More DRI setup
 898 dnl
 899 dnl Directory for DRI drivers
 900 AC_ARG_WITH([dri-driverdir],
 901     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 902         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 903     [DRI_DRIVER_INSTALL_DIR="$withval"],
 904     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 905 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 906 dnl Extra search path for DRI drivers
 907 AC_ARG_WITH([dri-searchpath],
 908     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 909         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 910     [DRI_DRIVER_SEARCH_DIR="$withval"],
 911     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 912 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 913 dnl Which drivers to build - default is chosen by platform
 914 AC_ARG_WITH([dri-drivers],
 915     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 916         [comma delimited DRI drivers list, e.g.
 917         "swrast,i965,radeon" @<:@default=auto@:>@])],
 918     [with_dri_drivers="$withval"],
 919     [with_dri_drivers=yes])
 920 if test "x$with_dri_drivers" = x; then
 921     with_dri_drivers=no
 922 fi
 923
 924 dnl If $with_dri_drivers is yes, directories will be added through
 925 dnl platform checks
 926 DRI_DIRS=""
 927 case "$with_dri_drivers" in
 928 no) ;;
 929 yes)
 930     # classic DRI drivers
 931     if test "x$enable_opengl" = xyes; then
 932         DRI_DIRS="yes"
 933     fi
 934     ;;
 935 *)
 936     # verify the requested driver directories exist
 937     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 938     for driver in $dri_drivers; do
 939         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 940             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 941     done
 942     DRI_DIRS="$dri_drivers"
 943     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 944         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 945     fi
 946     ;;
 947 esac
 948
 949 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 950 if test "x$enable_dri" = xyes; then
 951     # Platform specific settings and drivers to build
 952     case "$host_os" in
 953     linux*)
 954         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 955         DEFINES="$DEFINES -DHAVE_ALIAS"
 956
 957         case "$host_cpu" in
 958         x86_64|amd64)
 959             if test "x$DRI_DIRS" = "xyes"; then
 960                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 961             fi
 962             ;;
 963         powerpc*)
 964             # Build only the drivers for cards that exist on PowerPC.
 965             if test "x$DRI_DIRS" = "xyes"; then
 966                 DRI_DIRS="r200 radeon swrast"
 967             fi
 968             ;;
 969         sparc*)
 970             # Build only the drivers for cards that exist on sparc
 971             if test "x$DRI_DIRS" = "xyes"; then
 972                 DRI_DIRS="r200 radeon swrast"
 973             fi
 974             ;;
 975         esac
 976         ;;
 977     freebsd* | dragonfly* | *netbsd* | openbsd*)
 978         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 979         DEFINES="$DEFINES -DHAVE_ALIAS"
 980
 981         if test "x$DRI_DIRS" = "xyes"; then
 982             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 983         fi
 984         ;;
 985     gnu*)
 986         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 987         DEFINES="$DEFINES -DHAVE_ALIAS"
 988         ;;
 989     solaris*)
 990         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 991         ;;
 992     cygwin*)
 993         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 994         if test "x$DRI_DIRS" = "xyes"; then
 995             DRI_DIRS="swrast"
 996         fi
 997         ;;
 998     esac
 999
1000     # default drivers
1001     if test "x$DRI_DIRS" = "xyes"; then
1002         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1003     fi
1004
1005     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1006
1007     # Check for expat
1008     PKG_CHECK_MODULES([EXPAT], [expat], [],
1009                       AC_MSG_ERROR([Expat required for DRI.]))
1010
1011
1012     # If we are building any DRI driver other than swrast.
1013     if test -n "$DRI_DIRS"; then
1014         if test x"$DRI_DIRS" != xswrast; then
1015             # ... libdrm is required
1016             if test "x$have_libdrm" != xyes; then
1017                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1018             fi
1019             DRICOMMON_NEED_LIBDRM=yes
1020         else
1021             DRICOMMON_NEED_LIBDRM=no
1022         fi
1023     fi
1024
1025     # put all the necessary libs together
1026     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1027     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1028
1029     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1030 fi
1031
1032 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1033 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1034                                   "x$enable_osmesa" = xyes -o \
1035                                   -n "$DRI_DIRS")
1036 AC_SUBST([DRI_LIB_DEPS])
1037 AC_SUBST([DRI_DRIVER_LDFLAGS])
1038 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1039
1040 case $DRI_DIRS in
1041 *i915*|*i965*)
1042     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1043
1044     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1045         case $d in
1046         i915)
1047             HAVE_I915_DRI=yes;
1048             ;;
1049         i965)
1050             HAVE_I965_DRI=yes;
1051             ;;
1052         esac
1053     done
1054
1055     ;;
1056 esac
1057
1058 case $DRI_DIRS in
1059 *nouveau*)
1060     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1061     HAVE_NOUVEAU_DRI=yes;
1062     ;;
1063 esac
1064
1065 case $DRI_DIRS in
1066 *radeon*|*r200*)
1067     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1068
1069     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1070         case $d in
1071         radeon)
1072             HAVE_RADEON_DRI=yes;
1073             ;;
1074         r200)
1075             HAVE_R200_DRI=yes;
1076             ;;
1077         esac
1078     done
1079
1080     ;;
1081 esac
1082
1083 case $DRI_DIRS in
1084 *swrast*)
1085     HAVE_SWRAST_DRI=yes;
1086     ;;
1087 esac
1088
1089 dnl
1090 dnl OSMesa configuration
1091 dnl
1092
1093 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1094 AC_ARG_WITH([osmesa-bits],
1095     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1096         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1097     [osmesa_bits="$withval"],
1098     [osmesa_bits=8])
1099 if test "x$osmesa_bits" != x8; then
1100     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1101         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1102         osmesa_bits=8
1103     fi
1104 fi
1105 case "x$osmesa_bits" in
1106 x8)
1107     OSMESA_LIB="${OSMESA_LIB}"
1108     ;;
1109 x16|x32)
1110     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1111     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1112     ;;
1113 *)
1114     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1115     ;;
1116 esac
1117
1118 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1119     # only link libraries with osmesa if shared
1120     if test "$enable_static" = no; then
1121         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1122     else
1123         OSMESA_LIB_DEPS=""
1124     fi
1125     OSMESA_MESA_DEPS=""
1126     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1127 fi
1128
1129 AC_SUBST([OSMESA_LIB_DEPS])
1130 AC_SUBST([OSMESA_MESA_DEPS])
1131 AC_SUBST([OSMESA_PC_REQ])
1132 AC_SUBST([OSMESA_PC_LIB_PRIV])
1133
1134 dnl
1135 dnl gbm configuration
1136 dnl
1137 if test "x$enable_gbm" = xauto; then
1138     case "$with_egl_platforms" in
1139         *drm*)
1140             enable_gbm=yes ;;
1141          *)
1142             enable_gbm=no ;;
1143     esac
1144 fi
1145 if test "x$enable_gbm" = xyes; then
1146     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1147                       AC_MSG_ERROR([gbm needs udev]))
1148
1149     if test "x$enable_dri" = xyes; then
1150         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1151         if test "x$enable_shared_glapi" = xno; then
1152             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1153         fi
1154     fi
1155 fi
1156 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1157 GBM_PC_REQ_PRIV="libudev"
1158 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1159 AC_SUBST([GBM_PC_REQ_PRIV])
1160 AC_SUBST([GBM_PC_LIB_PRIV])
1161
1162 dnl
1163 dnl EGL configuration
1164 dnl
1165 EGL_CLIENT_APIS=""
1166
1167 if test "x$enable_egl" = xyes; then
1168     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1169
1170     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1171
1172     if test "$enable_static" != yes; then
1173         # build egl_glx when libGL is built
1174         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1175                           [have_libudev=yes],[have_libudev=no])
1176         if test "$have_libudev" = yes; then
1177             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1178         fi
1179
1180         if test "x$enable_dri" = xyes; then
1181             HAVE_EGL_DRIVER_DRI2=1
1182         fi
1183
1184     fi
1185 fi
1186 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1187 AC_SUBST([EGL_LIB_DEPS])
1188
1189 dnl
1190 dnl EGL Gallium configuration
1191 dnl
1192 if test "x$enable_gallium_egl" = xyes; then
1193     if test "x$with_gallium_drivers" = x; then
1194         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1195     fi
1196     if test "x$enable_egl" = xno; then
1197         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1198     fi
1199     if test "x$have_libdrm" != xyes; then
1200         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1201     fi
1202
1203     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1204     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1205 fi
1206 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1207
1208 dnl
1209 dnl gbm Gallium configuration
1210 dnl
1211 if test "x$enable_gallium_gbm" = xauto; then
1212     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1213         yesyesyes*drm*)
1214             enable_gallium_gbm=yes ;;
1215          *)
1216             enable_gallium_gbm=no ;;
1217     esac
1218 fi
1219 if test "x$enable_gallium_gbm" = xyes; then
1220     if test "x$with_gallium_drivers" = x; then
1221         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1222     fi
1223     if test "x$enable_gbm" = xno; then
1224         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1225     fi
1226     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1227     if test "x$enable_dri" = xno; then
1228         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1229     fi
1230
1231     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1232     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1233     enable_gallium_loader=yes
1234 fi
1235 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1236
1237 dnl
1238 dnl X.Org DDX configuration
1239 dnl
1240 if test "x$enable_xorg" = xyes; then
1241     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1242     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1243     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1244     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1245         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1246         HAVE_XEXTPROTO_71="no")
1247     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1248 fi
1249 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1250
1251 dnl
1252 dnl XA configuration
1253 dnl
1254 if test "x$enable_xa" = xyes; then
1255     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1256 fi
1257 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1258
1259 dnl
1260 dnl OpenVG configuration
1261 dnl
1262 VG_LIB_DEPS=""
1263
1264 if test "x$enable_openvg" = xyes; then
1265     if test "x$enable_egl" = xno; then
1266         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1267     fi
1268     if test "x$with_gallium_drivers" = x; then
1269         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1270     fi
1271     if test "x$enable_gallium_egl" = xno; then
1272         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1273     fi
1274
1275     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1276     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1277     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1278     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1279     AC_SUBST([VG_PC_LIB_PRIV])
1280 fi
1281 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1282
1283 dnl
1284 dnl Gallium G3DVL configuration
1285 dnl
1286 if test -n "$with_gallium_drivers"; then
1287     if test "x$enable_xvmc" = xauto; then
1288         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1289     fi
1290
1291     if test "x$enable_vdpau" = xauto; then
1292         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1293     fi
1294 fi
1295
1296 if test "x$enable_xvmc" = xyes; then
1297     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1298     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1299 fi
1300 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1301
1302 if test "x$enable_vdpau" = xyes; then
1303     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1304     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1305 fi
1306 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1307
1308 dnl
1309 dnl OpenCL configuration
1310 dnl
1311
1312 AC_ARG_WITH([libclc-path],
1313    [AS_HELP_STRING([--with-libclc-path],
1314          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1315    [LIBCLC_PATH="$withval"],
1316    [LIBCLC_PATH=""])
1317
1318 if test "x$LIBCLC_PATH" != x; then
1319    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1320                   Please review the updated build instructions for clover:
1321                   http://dri.freedesktop.org/wiki/GalliumCompute])
1322 fi
1323
1324
1325 AC_ARG_WITH([clang-libdir],
1326    [AS_HELP_STRING([--with-clang-libdir],
1327          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1328    [CLANG_LIBDIR="$withval"],
1329    [CLANG_LIBDIR=""])
1330
1331 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1332
1333 if test "x$enable_opencl" = xyes; then
1334     if test "x$with_gallium_drivers" = x; then
1335         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1336     fi
1337
1338     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1339         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1340     fi
1341
1342     if test "x$have_libclc" = xno; then
1343         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1344                     Make sure the directory containing libclc.pc is specified in your
1345                     PKG_CONFIG_PATH environment variable.
1346                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1347     else
1348         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1349         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1350         AC_SUBST([LIBCLC_INCLUDEDIR])
1351         AC_SUBST([LIBCLC_LIBEXECDIR])
1352     fi
1353
1354     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1355     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1356     enable_gallium_loader=yes
1357
1358     if test "x$enable_opencl_icd" = xyes; then
1359         OPENCL_LIBNAME="MesaOpenCL"
1360     else
1361         OPENCL_LIBNAME="OpenCL"
1362     fi
1363 fi
1364 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1365 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1366 AC_SUBST([OPENCL_LIBNAME])
1367
1368 dnl
1369 dnl Gallium configuration
1370 dnl
1371 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1372
1373 AC_SUBST([LLVM_BINDIR])
1374 AC_SUBST([LLVM_CFLAGS])
1375 AC_SUBST([LLVM_CPPFLAGS])
1376 AC_SUBST([LLVM_CXXFLAGS])
1377 AC_SUBST([LLVM_LIBDIR])
1378 AC_SUBST([LLVM_LIBS])
1379 AC_SUBST([LLVM_LDFLAGS])
1380 AC_SUBST([LLVM_INCLUDEDIR])
1381 AC_SUBST([LLVM_VERSION])
1382 AC_SUBST([CLANG_RESOURCE_DIR])
1383
1384 case "x$enable_opengl$enable_gles1$enable_gles2" in
1385 x*yes*)
1386     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1387     ;;
1388 esac
1389
1390 AC_SUBST([VG_LIB_DEPS])
1391 AC_SUBST([EGL_CLIENT_APIS])
1392
1393 dnl
1394 dnl EGL Platforms configuration
1395 dnl
1396 AC_ARG_WITH([egl-platforms],
1397     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1398         [comma delimited native platforms libEGL supports, e.g.
1399         "x11,drm" @<:@default=auto@:>@])],
1400     [with_egl_platforms="$withval"],
1401     [if test "x$enable_egl" = xyes; then
1402         with_egl_platforms="x11"
1403     else
1404         with_egl_platforms=""
1405     fi])
1406
1407 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1408     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1409 fi
1410
1411 # Do per-EGL platform setups and checks
1412 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1413 for plat in $egl_platforms; do
1414         case "$plat" in
1415         wayland)
1416                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1417                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1418
1419                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1420                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1421                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1422                 ;;
1423
1424         x11)
1425                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1426
1427                 if test "x$enable_glx" = xyes; then
1428                         HAVE_EGL_DRIVER_GLX=1
1429                 fi
1430                 ;;
1431
1432         drm)
1433                 test "x$enable_gbm" = "xno" &&
1434                         AC_MSG_ERROR([EGL platform drm needs gbm])
1435                 ;;
1436
1437         android|fbdev|gdi|null)
1438                 ;;
1439
1440         *)
1441                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1442                 ;;
1443         esac
1444
1445         case "$plat$have_libudev" in
1446                 waylandno|drmno)
1447                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1448         esac
1449 done
1450
1451 # libEGL wants to default to the first platform specified in
1452 # ./configure.  parse that here.
1453 if test "x$egl_platforms" != "x"; then
1454     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1455     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1456 else
1457     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1458 fi
1459
1460 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1461     NEED_WINSYS_XLIB=yes
1462 fi
1463 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1464 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1465 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1466 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1467 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1468
1469 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1470 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1471
1472 AC_SUBST([EGL_NATIVE_PLATFORM])
1473 AC_SUBST([EGL_CFLAGS])
1474
1475 # If we don't have the X11 platform, set this define so we don't try to include
1476 # the X11 headers.
1477 if ! echo "$egl_platforms" | grep -q 'x11'; then
1478     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1479     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1480 fi
1481
1482 AC_ARG_WITH([egl-driver-dir],
1483     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1484                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1485     [EGL_DRIVER_INSTALL_DIR="$withval"],
1486     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1487 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1488
1489 AC_ARG_WITH([xorg-driver-dir],
1490     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1491                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1492     [XORG_DRIVER_INSTALL_DIR="$withval"],
1493     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1494 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1495
1496 AC_ARG_WITH([max-width],
1497     [AS_HELP_STRING([--with-max-width=N],
1498                     [Maximum framebuffer width (4096)])],
1499     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1500      AS_IF([test "${withval}" -gt "4096"],
1501            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1502 )
1503 AC_ARG_WITH([max-height],
1504     [AS_HELP_STRING([--with-max-height=N],
1505                     [Maximum framebuffer height (4096)])],
1506     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1507      AS_IF([test "${withval}" -gt "4096"],
1508            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1509 )
1510
1511 dnl
1512 dnl Gallium LLVM
1513 dnl
1514 AC_ARG_ENABLE([gallium-llvm],
1515     [AS_HELP_STRING([--enable-gallium-llvm],
1516         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1517     [enable_gallium_llvm="$enableval"],
1518     [enable_gallium_llvm=auto])
1519
1520 AC_ARG_WITH([llvm-shared-libs],
1521     [AS_HELP_STRING([--with-llvm-shared-libs],
1522         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1523     [],
1524     [with_llvm_shared_libs=no])
1525 AS_IF([test x$enable_opencl = xyes],
1526     [
1527         if test "x$with_llvm_shared_libs" != xyes; then
1528             AC_MSG_ERROR([OpenCL requires LLVM shared libraries])
1529         fi
1530     ])
1531
1532 AC_ARG_WITH([llvm-prefix],
1533     [AS_HELP_STRING([--with-llvm-prefix],
1534         [Prefix for LLVM installations in non-standard locations])],
1535     [llvm_prefix="$withval"],
1536     [llvm_prefix=""])
1537
1538
1539 # Call this inside ` ` to get the return value.
1540 # $1 is the llvm-config command with arguments.
1541 strip_unwanted_llvm_flags() {
1542     # Use \> (marks the end of the word)
1543     echo `$1` | sed \
1544         -e 's/-DNDEBUG\>//g' \
1545         -e 's/-pedantic\>//g' \
1546         -e 's/-Wcovered-switch-default\>//g' \
1547         -e 's/-O.\>//g' \
1548         -e 's/-g\>//g' \
1549         -e 's/-Wall\>//g' \
1550         -e 's/-fomit-frame-pointer\>//g'
1551 }
1552
1553
1554 if test "x$with_gallium_drivers" = x; then
1555     enable_gallium_llvm=no
1556 fi
1557 if test "x$enable_gallium_llvm" = xauto; then
1558     case "$host_cpu" in
1559     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1560     esac
1561 fi
1562 if test "x$enable_gallium_llvm" = xyes; then
1563     if test "x$llvm_prefix" != x; then
1564         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1565     else
1566         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1567     fi
1568
1569     if test "x$LLVM_CONFIG" != xno; then
1570         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1571         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1572         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1573         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1574         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1575         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1576         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1577         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1578
1579         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1580             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1581         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1582             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1583
1584         if test "x${LLVM_VERSION_MAJOR}" != x; then
1585             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1586         else
1587             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1588         fi
1589
1590         LLVM_COMPONENTS="engine bitwriter"
1591         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1592             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1593         fi
1594
1595         if test "x$enable_opencl" = xyes; then
1596             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1597             # LLVM 3.3 >= 177971 requires IRReader
1598             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1599                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1600             fi
1601             # LLVM 3.4 requires Option
1602             if $LLVM_CONFIG --components | grep -qw 'option'; then
1603                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1604             fi
1605         fi
1606         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1607         MESA_LLVM=1
1608
1609         dnl Check for Clang internal headers
1610         if test "x$enable_opencl" = xyes; then
1611             if test "x$CLANG_LIBDIR" = x; then
1612                 CLANG_LIBDIR=${LLVM_LIBDIR}
1613             fi
1614             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1615             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1616                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1617         fi
1618     else
1619         MESA_LLVM=0
1620         LLVM_VERSION_INT=0
1621     fi
1622 else
1623     MESA_LLVM=0
1624     LLVM_VERSION_INT=0
1625 fi
1626
1627 dnl Directory for XVMC libs
1628 AC_ARG_WITH([xvmc-libdir],
1629     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1630         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1631     [XVMC_LIB_INSTALL_DIR="$withval"],
1632     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1633 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1634
1635 dnl
1636 dnl Gallium Tests
1637 dnl
1638 if test "x$enable_gallium_tests" = xyes; then
1639     enable_gallium_loader=yes
1640 fi
1641 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1642
1643 if test "x$enable_gallium_loader" = xyes; then
1644     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1645 fi
1646 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1647
1648 dnl Directory for VDPAU libs
1649 AC_ARG_WITH([vdpau-libdir],
1650     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1651         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1652     [VDPAU_LIB_INSTALL_DIR="$withval"],
1653     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1654 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1655
1656 dnl Directory for OpenCL libs
1657 AC_ARG_WITH([opencl-libdir],
1658     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1659         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1660     [OPENCL_LIB_INSTALL_DIR="$withval"],
1661     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1662 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1663
1664 dnl
1665 dnl Gallium helper functions
1666 dnl
1667 gallium_check_st() {
1668     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1669          if test "x$have_libdrm" != xyes; then
1670             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1671          fi
1672          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1673     fi
1674     if test "x$enable_dri" = xyes && test "x$2" != x; then
1675          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1676     fi
1677     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1678          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1679     fi
1680     if test "x$enable_xa" = xyes && test "x$4" != x; then
1681          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1682     fi
1683     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1684          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1685     fi
1686     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1687          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1688     fi
1689 }
1690
1691 gallium_require_llvm() {
1692     if test "x$MESA_LLVM" = x0; then
1693         case "$host_cpu" in
1694         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1695         esac
1696     fi
1697 }
1698
1699 gallium_require_drm_loader() {
1700     if test "x$enable_gallium_loader" = xyes; then
1701         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1702                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1703         if test "x$have_libdrm" != xyes; then
1704             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1705         fi
1706         enable_gallium_drm_loader=yes
1707     fi
1708 }
1709
1710 radeon_llvm_check() {
1711     LLVM_REQUIRED_VERSION_MAJOR="3"
1712     LLVM_REQUIRED_VERSION_MINOR="3"
1713     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1714         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1715     fi
1716     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1717         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1718                       sources with the --enable-experimental-targets=R600
1719                       configure flag])
1720     fi
1721     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1722     NEED_RADEON_LLVM=yes
1723     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1724                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1725 }
1726
1727 dnl Gallium drivers
1728 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1729         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1730         "x$enable_vdpau" = xyes; then
1731     NEED_NONNULL_WINSYS=yes
1732 fi
1733 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1734
1735 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1736 if test "x$with_gallium_drivers" != x; then
1737     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1738     for driver in $gallium_drivers; do
1739         case "x$driver" in
1740         xsvga)
1741             HAVE_GALLIUM_SVGA=yes
1742             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1743             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1744             ;;
1745         xi915)
1746             HAVE_GALLIUM_I915=yes
1747             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1748             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1749             if test "x$MESA_LLVM" = x1; then
1750                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1751             fi
1752             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1753             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1754             DRICOMMON_NEED_LIBDRM=yes
1755             ;;
1756         xilo)
1757             HAVE_GALLIUM_ILO=yes
1758             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1759             gallium_require_drm_loader
1760             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1761             gallium_check_st "intel/drm" "dri-ilo"
1762             DRICOMMON_NEED_LIBDRM=yes
1763             ;;
1764         xr300)
1765             HAVE_GALLIUM_R300=yes
1766             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1767             gallium_require_llvm "Gallium R300"
1768             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1769             gallium_check_st "radeon/drm" "r300/dri" "" "" "r300/xvmc" "r300/vdpau"
1770             DRICOMMON_NEED_LIBDRM=yes
1771             ;;
1772         xr600)
1773             HAVE_GALLIUM_R600=yes
1774             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1775             gallium_require_drm_loader
1776             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1777             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1778                 radeon_llvm_check
1779                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1780             fi
1781             if test "x$enable_r600_llvm" = xyes; then
1782                 USE_R600_LLVM_COMPILER=yes;
1783             fi
1784             if test "x$enable_opencl" = xyes; then
1785                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1786             fi
1787             gallium_check_st "radeon/drm" "r600/dri" "r600/xorg" "" "r600/xvmc" "r600/vdpau"
1788             DRICOMMON_NEED_LIBDRM=yes
1789             ;;
1790         xradeonsi)
1791             HAVE_GALLIUM_RADEONSI=yes
1792             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1793             gallium_require_drm_loader
1794             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1795             radeon_llvm_check
1796             gallium_check_st "radeon/drm" "radeonsi/dri" "radeonsi/xorg" "" "" "radeonsi/vdpau" ""
1797             DRICOMMON_NEED_LIBDRM=yes
1798             ;;
1799         xnouveau)
1800             HAVE_GALLIUM_NOUVEAU=yes
1801             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1802             gallium_require_drm_loader
1803             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1804             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1805             DRICOMMON_NEED_LIBDRM=yes
1806             ;;
1807         xfreedreno)
1808             HAVE_GALLIUM_FREEDRENO=yes
1809             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1810             gallium_require_drm_loader
1811             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1812             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1813             DRICOMMON_NEED_LIBDRM=yes
1814             ;;
1815         xswrast)
1816             HAVE_GALLIUM_SOFTPIPE=yes
1817             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1818             if test "x$MESA_LLVM" = x1; then
1819                 HAVE_GALLIUM_LLVMPIPE=yes
1820                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1821             fi
1822
1823             if test "x$enable_dri" = xyes; then
1824                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1825             fi
1826             if test "x$enable_vdpau" = xyes; then
1827                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1828             fi
1829             if test "x$enable_xvmc" = xyes; then
1830                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1831             fi
1832             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1833                 NEED_WINSYS_XLIB=yes
1834                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1835             fi
1836             ;;
1837         *)
1838             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1839             ;;
1840         esac
1841     done
1842 fi
1843
1844 dnl Set LLVM_LIBS - This is done after the driver configuration so
1845 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1846 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1847 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1848 dnl this was causing the same libraries to be appear multiple times
1849 dnl in LLVM_LIBS.
1850
1851 if test "x$MESA_LLVM" != x0; then
1852
1853     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1854
1855     if test "x$with_llvm_shared_libs" = xyes; then
1856         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1857         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1858         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1859
1860         if test "x$llvm_have_one_so" = xyes; then
1861             dnl LLVM was built using auto*, so there is only one shared object.
1862             LLVM_LIBS="-l$LLVM_SO_NAME"
1863         else
1864             dnl If LLVM was built with CMake, there will be one shared object per
1865             dnl component.
1866             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1867                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1868         Please make sure you have built llvm with the --enable-shared option
1869         and that your llvm libraries are installed in $LLVM_LIBDIR
1870         If you have installed your llvm libraries to a different directory you
1871         can use the --with-llvm-prefix= configure flag to specify this directory.
1872         NOTE: Mesa is attempting to use llvm shared libraries because you have
1873         passed one of the following options to configure:
1874                 --with-llvm-shared-libs
1875                 --enable-opencl
1876         If you do not want to build with llvm shared libraries and instead want to
1877         use llvm static libraries then remove these options from your configure
1878         invocation and reconfigure.])])
1879
1880            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1881            dnl install uses a shared object for each compoenent and we have
1882            dnl already added all of these objects to LLVM_LIBS.
1883         fi
1884     fi
1885 fi
1886
1887 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1890 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1891 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1892 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1893 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1894 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1895 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1896 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1897
1898 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1899                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1900                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1901 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1902                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1903                                                   && test "x$MESA_LLVM" = x1)
1904
1905 if test "x$enable_gallium_loader" = xyes; then
1906     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1907
1908     if test "x$enable_gallium_drm_loader" = xyes; then
1909         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1910         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1911                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1912         if test "x$pipe_loader_have_xcb" = xyes; then
1913             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1914             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1915         fi
1916     fi
1917
1918     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1919     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1920 fi
1921
1922 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1923 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1924 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1925 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1926 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1927 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1928
1929 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1930                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1931                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1932                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1933 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1934                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1935 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1936 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1937 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1938 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1939 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1941 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1942
1943 AC_SUBST([ELF_LIB])
1944
1945 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1946 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1947 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1948 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1949
1950 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1951 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1952 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1953
1954 AC_SUBST([VDPAU_MAJOR], 1)
1955 AC_SUBST([VDPAU_MINOR], 0)
1956
1957 AC_SUBST([XVMC_MAJOR], 1)
1958 AC_SUBST([XVMC_MINOR], 0)
1959
1960 AC_SUBST([XA_MAJOR], 2)
1961 AC_SUBST([XA_MINOR], 0)
1962 AC_SUBST([XA_TINY], 0)
1963 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1964
1965 dnl Restore LDFLAGS and CPPFLAGS
1966 LDFLAGS="$_SAVE_LDFLAGS"
1967 CPPFLAGS="$_SAVE_CPPFLAGS"
1968
1969 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1970 if test "x$acv_mesa_CLANG" = xyes; then
1971     CFLAGS="$CFLAGS -Qunused-arguments"
1972     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1973 fi
1974
1975 dnl Add user CFLAGS and CXXFLAGS
1976 CFLAGS="$CFLAGS $USER_CFLAGS"
1977 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1978
1979 dnl Substitute the config
1980 AC_CONFIG_FILES([Makefile
1981                 src/Makefile
1982                 src/egl/Makefile
1983                 src/egl/drivers/Makefile
1984                 src/egl/drivers/dri2/Makefile
1985                 src/egl/drivers/glx/Makefile
1986                 src/egl/main/Makefile
1987                 src/egl/main/egl.pc
1988                 src/egl/wayland/Makefile
1989                 src/egl/wayland/wayland-drm/Makefile
1990                 src/egl/wayland/wayland-egl/Makefile
1991                 src/egl/wayland/wayland-egl/wayland-egl.pc
1992                 src/gallium/auxiliary/Makefile
1993                 src/gallium/auxiliary/pipe-loader/Makefile
1994                 src/gallium/drivers/Makefile
1995                 src/gallium/drivers/freedreno/Makefile
1996                 src/gallium/drivers/freedreno/a2xx/Makefile
1997                 src/gallium/drivers/freedreno/a3xx/Makefile
1998                 src/gallium/drivers/galahad/Makefile
1999                 src/gallium/drivers/i915/Makefile
2000                 src/gallium/drivers/identity/Makefile
2001                 src/gallium/drivers/ilo/Makefile
2002                 src/gallium/drivers/llvmpipe/Makefile
2003                 src/gallium/drivers/noop/Makefile
2004                 src/gallium/drivers/nouveau/Makefile
2005                 src/gallium/drivers/r300/Makefile
2006                 src/gallium/drivers/r600/Makefile
2007                 src/gallium/drivers/radeon/Makefile
2008                 src/gallium/drivers/radeonsi/Makefile
2009                 src/gallium/drivers/rbug/Makefile
2010                 src/gallium/drivers/softpipe/Makefile
2011                 src/gallium/drivers/svga/Makefile
2012                 src/gallium/drivers/trace/Makefile
2013                 src/gallium/state_trackers/Makefile
2014                 src/gallium/state_trackers/clover/Makefile
2015                 src/gallium/state_trackers/dri/Makefile
2016                 src/gallium/state_trackers/dri/drm/Makefile
2017                 src/gallium/state_trackers/dri/sw/Makefile
2018                 src/gallium/state_trackers/egl/Makefile
2019                 src/gallium/state_trackers/gbm/Makefile
2020                 src/gallium/state_trackers/glx/xlib/Makefile
2021                 src/gallium/state_trackers/osmesa/Makefile
2022                 src/gallium/state_trackers/vdpau/Makefile
2023                 src/gallium/state_trackers/vega/Makefile
2024                 src/gallium/state_trackers/xa/Makefile
2025                 src/gallium/state_trackers/xorg/Makefile
2026                 src/gallium/state_trackers/xvmc/Makefile
2027                 src/gallium/targets/Makefile
2028                 src/gallium/targets/dri-freedreno/Makefile
2029                 src/gallium/targets/dri-i915/Makefile
2030                 src/gallium/targets/dri-ilo/Makefile
2031                 src/gallium/targets/dri-nouveau/Makefile
2032                 src/gallium/targets/dri-swrast/Makefile
2033                 src/gallium/targets/dri-vmwgfx/Makefile
2034                 src/gallium/targets/egl-static/Makefile
2035                 src/gallium/targets/gbm/Makefile
2036                 src/gallium/targets/opencl/Makefile
2037                 src/gallium/targets/osmesa/Makefile
2038                 src/gallium/targets/osmesa/osmesa.pc
2039                 src/gallium/targets/pipe-loader/Makefile
2040                 src/gallium/targets/radeonsi/dri/Makefile
2041                 src/gallium/targets/radeonsi/vdpau/Makefile
2042                 src/gallium/targets/radeonsi/xorg/Makefile
2043                 src/gallium/targets/r300/dri/Makefile
2044                 src/gallium/targets/r300/vdpau/Makefile
2045                 src/gallium/targets/r300/xvmc/Makefile
2046                 src/gallium/targets/r600/dri/Makefile
2047                 src/gallium/targets/r600/vdpau/Makefile
2048                 src/gallium/targets/r600/xorg/Makefile
2049                 src/gallium/targets/r600/xvmc/Makefile
2050                 src/gallium/targets/libgl-xlib/Makefile
2051                 src/gallium/targets/vdpau-nouveau/Makefile
2052                 src/gallium/targets/vdpau-softpipe/Makefile
2053                 src/gallium/targets/xa-vmwgfx/Makefile
2054                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2055                 src/gallium/targets/xorg-i915/Makefile
2056                 src/gallium/targets/xorg-nouveau/Makefile
2057                 src/gallium/targets/xvmc-nouveau/Makefile
2058                 src/gallium/targets/xvmc-softpipe/Makefile
2059                 src/gallium/tests/trivial/Makefile
2060                 src/gallium/tests/unit/Makefile
2061                 src/gallium/winsys/Makefile
2062                 src/gallium/winsys/freedreno/drm/Makefile
2063                 src/gallium/winsys/i915/drm/Makefile
2064                 src/gallium/winsys/i915/sw/Makefile
2065                 src/gallium/winsys/intel/drm/Makefile
2066                 src/gallium/winsys/nouveau/drm/Makefile
2067                 src/gallium/winsys/radeon/drm/Makefile
2068                 src/gallium/winsys/svga/drm/Makefile
2069                 src/gallium/winsys/sw/dri/Makefile
2070                 src/gallium/winsys/sw/fbdev/Makefile
2071                 src/gallium/winsys/sw/null/Makefile
2072                 src/gallium/winsys/sw/wayland/Makefile
2073                 src/gallium/winsys/sw/wrapper/Makefile
2074                 src/gallium/winsys/sw/xlib/Makefile
2075                 src/gbm/Makefile
2076                 src/gbm/main/gbm.pc
2077                 src/glsl/Makefile
2078                 src/glx/Makefile
2079                 src/glx/tests/Makefile
2080                 src/gtest/Makefile
2081                 src/mapi/Makefile
2082                 src/mapi/es1api/Makefile
2083                 src/mapi/es1api/glesv1_cm.pc
2084                 src/mapi/es2api/Makefile
2085                 src/mapi/es2api/glesv2.pc
2086                 src/mapi/glapi/Makefile
2087                 src/mapi/glapi/gen/Makefile
2088                 src/mapi/glapi/tests/Makefile
2089                 src/mapi/shared-glapi/Makefile
2090                 src/mapi/shared-glapi/tests/Makefile
2091                 src/mapi/vgapi/Makefile
2092                 src/mapi/vgapi/vg.pc
2093                 src/mesa/Makefile
2094                 src/mesa/gl.pc
2095                 src/mesa/drivers/dri/dri.pc
2096                 src/mesa/drivers/dri/common/Makefile
2097                 src/mesa/drivers/dri/common/xmlpool/Makefile
2098                 src/mesa/drivers/dri/i915/Makefile
2099                 src/mesa/drivers/dri/i965/Makefile
2100                 src/mesa/drivers/dri/Makefile
2101                 src/mesa/drivers/dri/nouveau/Makefile
2102                 src/mesa/drivers/dri/r200/Makefile
2103                 src/mesa/drivers/dri/radeon/Makefile
2104                 src/mesa/drivers/dri/swrast/Makefile
2105                 src/mesa/drivers/osmesa/Makefile
2106                 src/mesa/drivers/osmesa/osmesa.pc
2107                 src/mesa/drivers/x11/Makefile
2108                 src/mesa/main/tests/Makefile
2109                 src/mesa/main/tests/hash_table/Makefile
2110                 src/mesa/program/Makefile
2111                 src/mesa/x86-64/Makefile
2112                 src/mesa/x86/Makefile])
2113
2114 dnl Sort the dirs alphabetically
2115 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2116 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2117 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2118 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2119
2120 AC_OUTPUT
2121
2122 dnl
2123 dnl Output some configuration info for the user
2124 dnl
2125 echo ""
2126 echo "        prefix:          $prefix"
2127 echo "        exec_prefix:     $exec_prefix"
2128 echo "        libdir:          $libdir"
2129 echo "        includedir:      $includedir"
2130
2131 dnl API info
2132 echo ""
2133 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2134 echo "        OpenVG:          $enable_openvg"
2135
2136 dnl Driver info
2137 echo ""
2138 case "x$enable_osmesa$enable_gallium_osmesa" in
2139 xnoyes)
2140         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2141         ;;
2142 xyesno)
2143         echo "        OSMesa:          lib$OSMESA_LIB"
2144         ;;
2145 xnono)
2146         echo "        OSMesa:          no"
2147         ;;
2148 esac
2149
2150 if test "x$enable_dri" != xno; then
2151         # cleanup the drivers var
2152         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2153         if test "x$DRI_DIRS" = x; then
2154             echo "        DRI drivers:     no"
2155         else
2156             echo "        DRI drivers:     $dri_dirs"
2157         fi
2158         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2159 fi
2160
2161 case "x$enable_glx$enable_xlib_glx" in
2162 xyesyes)
2163     echo "        GLX:             Xlib-based"
2164     ;;
2165 xyesno)
2166     echo "        GLX:             DRI-based"
2167     ;;
2168 *)
2169     echo "        GLX:             $enable_glx"
2170     ;;
2171 esac
2172
2173 dnl EGL
2174 echo ""
2175 echo "        EGL:             $enable_egl"
2176 if test "$enable_egl" = yes; then
2177     echo "        EGL platforms:   $egl_platforms"
2178
2179     egl_drivers=""
2180     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2181         egl_drivers="$egl_drivers builtin:egl_glx"
2182     fi
2183     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2184         egl_drivers="$egl_drivers builtin:egl_dri2"
2185     fi
2186
2187     if test "x$enable_gallium_egl" = xyes; then
2188         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2189         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2190     else
2191         echo "        EGL drivers:    $egl_drivers"
2192     fi
2193 fi
2194
2195 echo ""
2196 if test "x$MESA_LLVM" = x1; then
2197     echo "        llvm:            yes"
2198     echo "        llvm-config:     $LLVM_CONFIG"
2199     echo "        llvm-version:    $LLVM_VERSION"
2200 else
2201     echo "        llvm:            no"
2202 fi
2203
2204 echo ""
2205 if test -n "$with_gallium_drivers"; then
2206     echo "        Gallium:         yes"
2207     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2208     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2209     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2210     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2211 else
2212     echo "        Gallium:         no"
2213 fi
2214
2215
2216 dnl Libraries
2217 echo ""
2218 echo "        Shared libs:     $enable_shared"
2219 echo "        Static libs:     $enable_static"
2220 echo "        Shared-glapi:    $enable_shared_glapi"
2221
2222 dnl Compiler options
2223 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2224 cflags=`echo $CFLAGS | \
2225     $SED 's/^ *//;s/  */ /;s/ *$//'`
2226 cxxflags=`echo $CXXFLAGS | \
2227     $SED 's/^ *//;s/  */ /;s/ *$//'`
2228 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2229 echo ""
2230 echo "        CFLAGS:          $cflags"
2231 echo "        CXXFLAGS:        $cxxflags"
2232 echo "        Macros:          $defines"
2233 echo ""
2234 if test "x$MESA_LLVM" = x1; then
2235     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2236     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2237     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2238     echo ""
2239 fi
2240 echo "        PYTHON2:         $PYTHON2"
2241
2242 echo ""
2243 echo "        Run '${MAKE-make}' to build Mesa"
2244 echo ""