configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.54
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports -Bsymbolic
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 323 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         BSYMBOLIC="-Wl,-Bsymbolic";],
 328     [AC_MSG_RESULT([no])
 329         BSYMBOLIC="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([BSYMBOLIC])
 333
 334 dnl
 335 dnl Check if linker supports garbage collection
 336 dnl
 337 save_LDFLAGS=$LDFLAGS
 338 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 339 AC_MSG_CHECKING([whether ld supports --gc-sections])
 340 AC_LINK_IFELSE(
 341     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 342     [AC_MSG_RESULT([yes])
 343         GC_SECTIONS="-Wl,--gc-sections";],
 344     [AC_MSG_RESULT([no])
 345         GC_SECTIONS="";])
 346 LDFLAGS=$save_LDFLAGS
 347
 348 AC_SUBST([GC_SECTIONS])
 349
 350 dnl
 351 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 352 dnl so when these flags are passed to ld via libtool the checks will fail
 353 dnl
 354 case "$host_os" in
 355 openbsd* | darwin* )
 356     LD_NO_UNDEFINED="" ;;
 357 *)
 358     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 359 esac
 360
 361 AC_SUBST([LD_NO_UNDEFINED])
 362
 363 dnl
 364 dnl Check if linker supports version scripts
 365 dnl
 366 AC_MSG_CHECKING([if the linker supports version-scripts])
 367 save_LDFLAGS=$LDFLAGS
 368 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 369 cat > conftest.map <<EOF
 370 VERSION_1 {
 371      global:
 372          main;
 373
 374      local:
 375          *;
 376 };
 377 EOF
 378 AC_LINK_IFELSE(
 379     [AC_LANG_SOURCE([int main() { return 0;}])],
 380     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 381     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 382 LDFLAGS=$save_LDFLAGS
 383 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 384
 385 dnl
 386 dnl compatibility symlinks
 387 dnl
 388 case "$host_os" in
 389 linux* )
 390     HAVE_COMPAT_SYMLINKS=yes ;;
 391 * )
 392     HAVE_COMPAT_SYMLINKS=no ;;
 393 esac
 394
 395 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 396
 397 dnl
 398 dnl library names
 399 dnl
 400 case "$host_os" in
 401 darwin* )
 402     LIB_EXT='dylib' ;;
 403 cygwin* )
 404     LIB_EXT='dll' ;;
 405 aix* )
 406     LIB_EXT='a' ;;
 407 * )
 408     LIB_EXT='so' ;;
 409 esac
 410
 411 AC_SUBST([LIB_EXT])
 412
 413 AC_ARG_WITH([gl-lib-name],
 414   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 415     [specify GL library name @<:@default=GL@:>@])],
 416   [GL_LIB=$withval],
 417   [GL_LIB=GL])
 418 AC_ARG_WITH([osmesa-lib-name],
 419   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 420     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 421   [OSMESA_LIB=$withval],
 422   [OSMESA_LIB=OSMesa])
 423 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 424 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 425
 426 dnl
 427 dnl Mangled Mesa support
 428 dnl
 429 AC_ARG_ENABLE([mangling],
 430   [AS_HELP_STRING([--enable-mangling],
 431     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 432   [enable_mangling="${enableval}"],
 433   [enable_mangling=no]
 434 )
 435 if test "x${enable_mangling}" = "xyes" ; then
 436   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 437   GL_LIB="Mangled${GL_LIB}"
 438   OSMESA_LIB="Mangled${OSMESA_LIB}"
 439 fi
 440 AC_SUBST([GL_LIB])
 441 AC_SUBST([OSMESA_LIB])
 442
 443 dnl
 444 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 445 dnl
 446 AC_ARG_ENABLE([texture-float],
 447     [AS_HELP_STRING([--enable-texture-float],
 448         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 449     [enable_texture_float="$enableval"],
 450     [enable_texture_float=no]
 451 )
 452 if test "x$enable_texture_float" = xyes; then
 453     AC_MSG_WARN([Floating-point textures enabled.])
 454     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 455     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 456 fi
 457
 458 dnl
 459 dnl Arch/platform-specific settings
 460 dnl
 461 AC_ARG_ENABLE([asm],
 462     [AS_HELP_STRING([--disable-asm],
 463         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 464     [enable_asm="$enableval"],
 465     [enable_asm=yes]
 466 )
 467 asm_arch=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64 | amd64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         gnu*)
 488             asm_arch=x86
 489             ;;
 490         esac
 491         ;;
 492     x86_64|amd64)
 493         case "$host_os" in
 494         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 495             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 496             ;;
 497         esac
 498         ;;
 499     sparc*)
 500         case "$host_os" in
 501         linux*)
 502             asm_arch=sparc
 503             ;;
 504         esac
 505         ;;
 506     esac
 507
 508     case "$asm_arch" in
 509     x86)
 510         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 511         AC_MSG_RESULT([yes, x86])
 512         ;;
 513     x86_64|amd64)
 514         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 515         AC_MSG_RESULT([yes, x86_64])
 516         ;;
 517     sparc)
 518         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526
 527 dnl Check to see if dlopen is in default libraries (like Solaris, which
 528 dnl has it in libc), or if libdl is needed to get it.
 529 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 530     [AC_CHECK_LIB([dl], [dlopen],
 531        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 532 AC_SUBST([DLOPEN_LIBS])
 533
 534 dnl Check if that library also has dladdr
 535 save_LDFLAGS="$LDFLAGS"
 536 LDFLAGS="$LDFLAGS $DLOPEN_LIBS"
 537 AC_CHECK_FUNCS([dladdr])
 538 LDFLAGS="$save_LDFLAGS"
 539
 540 case "$host_os" in
 541 darwin*|mingw*)
 542     ;;
 543 *)
 544     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 545                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 546                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 547     AC_SUBST([CLOCK_LIB])
 548     ;;
 549 esac
 550
 551 dnl See if posix_memalign is available
 552 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 553
 554 dnl Check for pthreads
 555 case "$host_os" in
 556 mingw*)
 557     ;;
 558 *)
 559     AX_PTHREAD
 560     ;;
 561 esac
 562 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 563 dnl to -pthread, which causes problems if we need -lpthread to appear in
 564 dnl pkgconfig files.
 565 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 566
 567 dnl SELinux awareness.
 568 AC_ARG_ENABLE([selinux],
 569     [AS_HELP_STRING([--enable-selinux],
 570         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 571     [MESA_SELINUX="$enableval"],
 572     [MESA_SELINUX=no])
 573 if test "x$enable_selinux" = "xyes"; then
 574     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 575         [AC_CHECK_HEADER([selinux/selinux.h],[],
 576                          [AC_MSG_ERROR([SELinux headers not found])])
 577          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 578                       [AC_MSG_ERROR([SELinux library not found])])
 579          SELINUX_LIBS="-lselinux"])
 580     DEFINES="$DEFINES -DMESA_SELINUX"
 581 fi
 582 AC_SUBST([SELINUX_CFLAGS])
 583 AC_SUBST([SELINUX_LIBS])
 584
 585 dnl Options for APIs
 586 AC_ARG_ENABLE([opengl],
 587     [AS_HELP_STRING([--disable-opengl],
 588         [disable support for standard OpenGL API @<:@default=no@:>@])],
 589     [enable_opengl="$enableval"],
 590     [enable_opengl=yes])
 591 AC_ARG_ENABLE([gles1],
 592     [AS_HELP_STRING([--enable-gles1],
 593         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 594     [enable_gles1="$enableval"],
 595     [enable_gles1=no])
 596 AC_ARG_ENABLE([gles2],
 597     [AS_HELP_STRING([--enable-gles2],
 598         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 599     [enable_gles2="$enableval"],
 600     [enable_gles2=no])
 601 AC_ARG_ENABLE([openvg],
 602     [AS_HELP_STRING([--enable-openvg],
 603         [enable support for OpenVG API @<:@default=no@:>@])],
 604     [enable_openvg="$enableval"],
 605     [enable_openvg=no])
 606
 607 AC_ARG_ENABLE([dri],
 608     [AS_HELP_STRING([--enable-dri],
 609         [enable DRI modules @<:@default=enabled@:>@])],
 610     [enable_dri="$enableval"],
 611     [enable_dri=yes])
 612
 613 case "$host_os" in
 614 linux*)
 615     dri3_default=yes
 616     ;;
 617 *)
 618     dri3_default=no
 619     ;;
 620 esac
 621 AC_ARG_ENABLE([dri3],
 622     [AS_HELP_STRING([--enable-dri3],
 623         [enable DRI3 @<:@default=auto@:>@])],
 624     [enable_dri3="$enableval"],
 625     [enable_dri3="$dri3_default"])
 626 AC_ARG_ENABLE([glx],
 627     [AS_HELP_STRING([--enable-glx],
 628         [enable GLX library @<:@default=enabled@:>@])],
 629     [enable_glx="$enableval"],
 630     [enable_glx=yes])
 631 AC_ARG_ENABLE([osmesa],
 632     [AS_HELP_STRING([--enable-osmesa],
 633         [enable OSMesa library @<:@default=disabled@:>@])],
 634     [enable_osmesa="$enableval"],
 635     [enable_osmesa=no])
 636 AC_ARG_ENABLE([gallium-osmesa],
 637     [AS_HELP_STRING([--enable-gallium-osmesa],
 638         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 639     [enable_gallium_osmesa="$enableval"],
 640     [enable_gallium_osmesa=no])
 641 AC_ARG_ENABLE([egl],
 642     [AS_HELP_STRING([--disable-egl],
 643         [disable EGL library @<:@default=enabled@:>@])],
 644     [enable_egl="$enableval"],
 645     [enable_egl=yes])
 646
 647 AC_ARG_ENABLE([xa],
 648     [AS_HELP_STRING([--enable-xa],
 649         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 650     [enable_xa="$enableval"],
 651     [enable_xa=no])
 652 AC_ARG_ENABLE([gbm],
 653    [AS_HELP_STRING([--enable-gbm],
 654          [enable gbm library @<:@default=auto@:>@])],
 655    [enable_gbm="$enableval"],
 656    [enable_gbm=auto])
 657
 658 AC_ARG_ENABLE([xvmc],
 659    [AS_HELP_STRING([--enable-xvmc],
 660          [enable xvmc library @<:@default=auto@:>@])],
 661    [enable_xvmc="$enableval"],
 662    [enable_xvmc=no])
 663 AC_ARG_ENABLE([vdpau],
 664    [AS_HELP_STRING([--enable-vdpau],
 665          [enable vdpau library @<:@default=auto@:>@])],
 666    [enable_vdpau="$enableval"],
 667    [enable_vdpau=auto])
 668 AC_ARG_ENABLE([omx],
 669    [AS_HELP_STRING([--enable-omx],
 670          [enable OpenMAX library @<:@default=no@:>@])],
 671    [enable_omx="$enableval"],
 672    [enable_omx=no])
 673 AC_ARG_ENABLE([opencl],
 674    [AS_HELP_STRING([--enable-opencl],
 675          [enable OpenCL library @<:@default=no@:>@])],
 676    [enable_opencl="$enableval"],
 677    [enable_opencl=no])
 678 AC_ARG_ENABLE([opencl_icd],
 679    [AS_HELP_STRING([--enable-opencl-icd],
 680           [Build an OpenCL ICD library to be loaded by an ICD implementation
 681            @<:@default=no@:>@])],
 682     [enable_opencl_icd="$enableval"],
 683     [enable_opencl_icd=no])
 684 AC_ARG_ENABLE([xlib-glx],
 685     [AS_HELP_STRING([--enable-xlib-glx],
 686         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 687     [enable_xlib_glx="$enableval"],
 688     [enable_xlib_glx=no])
 689 AC_ARG_ENABLE([gallium-egl],
 690     [AS_HELP_STRING([--enable-gallium-egl],
 691         [enable optional EGL state tracker (not required
 692          for EGL support in Gallium with OpenGL and OpenGL ES)
 693          @<:@default=disable@:>@])],
 694     [enable_gallium_egl="$enableval"],
 695     [enable_gallium_egl=no])
 696 AC_ARG_ENABLE([gallium-gbm],
 697     [AS_HELP_STRING([--enable-gallium-gbm],
 698         [enable optional gbm state tracker (not required for
 699          gbm support in Gallium)
 700          @<:@default=auto@:>@])],
 701     [enable_gallium_gbm="$enableval"],
 702     [enable_gallium_gbm=auto])
 703
 704 AC_ARG_ENABLE([r600-llvm-compiler],
 705     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 706         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 707     [enable_r600_llvm="$enableval"],
 708     [enable_r600_llvm=no])
 709
 710 AC_ARG_ENABLE([gallium-tests],
 711     [AS_HELP_STRING([--enable-gallium-tests],
 712         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 713     [enable_gallium_tests="$enableval"],
 714     [enable_gallium_tests=no])
 715
 716 # Option for Gallium drivers
 717
 718 # Keep this in sync with the --with-gallium-drivers help string default value
 719 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 720
 721 AC_ARG_WITH([gallium-drivers],
 722     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 723         [comma delimited Gallium drivers list, e.g.
 724         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 725         @<:@default=r300,r600,svga,swrast@:>@])],
 726     [with_gallium_drivers="$withval"],
 727     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 728
 729 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 730 # here so that the script doesn't choke on an unknown driver name later.
 731 case "$with_gallium_drivers" in
 732     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 733     no) with_gallium_drivers='' ;;
 734 esac
 735
 736 if test "x$enable_opengl" = xno -a \
 737         "x$enable_gles1" = xno -a \
 738         "x$enable_gles2" = xno -a \
 739         "x$enable_openvg" = xno -a \
 740         "x$enable_xa" = xno -a \
 741         "x$enable_xvmc" = xno -a \
 742         "x$enable_vdpau" = xno -a \
 743         "x$enable_omx" = xno -a \
 744         "x$enable_opencl" = xno; then
 745     AC_MSG_ERROR([at least one API should be enabled])
 746 fi
 747
 748 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 749 if test "x$enable_opengl" = xno -a \
 750         "x$enable_gles1" = xyes; then
 751     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 752 fi
 753
 754 if test "x$enable_opengl" = xno -a \
 755         "x$enable_gles2" = xyes; then
 756     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 757 fi
 758
 759 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 760 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 761 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 762 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 763                                         "x$enable_gles1" = xyes -o \
 764                                         "x$enable_gles2" = xyes)
 765
 766 if test "x$enable_glx" = xno; then
 767     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 768     enable_xlib_glx=no
 769 fi
 770
 771 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 772     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 773 fi
 774
 775 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 776     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 777 fi
 778
 779 # Disable GLX if OpenGL is not enabled
 780 if test "x$enable_glx$enable_opengl" = xyesno; then
 781     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 782     enable_glx=no
 783 fi
 784
 785 # Disable GLX if DRI and Xlib-GLX are not enabled
 786 if test "x$enable_glx" = xyes -a \
 787         "x$enable_dri" = xno -a \
 788         "x$enable_xlib_glx" = xno; then
 789     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 790     enable_glx=no
 791 fi
 792
 793 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 794                                   "x$enable_dri" = xyes)
 795
 796 # Select which platform-dependent DRI code gets built
 797 case "$host_os" in
 798 darwin*)
 799     dri_platform='apple' ;;
 800 gnu*|mingw*|cygwin*)
 801     dri_platform='none' ;;
 802 *)
 803     dri_platform='drm' ;;
 804 esac
 805
 806 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 807 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 808 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes && test "x$dri_platform" = xdrm )
 809 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes && test "x$dri_platform" = xdrm )
 810 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes && test "x$dri_platform" = xapple )
 811
 812 AC_ARG_ENABLE([shared-glapi],
 813     [AS_HELP_STRING([--enable-shared-glapi],
 814         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 815     [enable_shared_glapi="$enableval"],
 816     [enable_shared_glapi=yes])
 817
 818 case "x$enable_opengl$enable_gles1$enable_gles2" in
 819 x*yes*yes*)
 820     if test "x$enable_shared_glapi" = xno; then
 821         AC_MSG_ERROR([shared GLAPI required when building two or more of
 822                       the following APIs - opengl, gles1 gles2])
 823     fi
 824     ;;
 825 esac
 826
 827 # Building Xlib-GLX requires shared glapi to be disabled.
 828 if test "x$enable_xlib_glx" = xyes; then
 829     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 830     enable_shared_glapi=no
 831 fi
 832
 833 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 834
 835 dnl
 836 dnl Driver specific build directories
 837 dnl
 838 GALLIUM_TARGET_DIRS=""
 839 GALLIUM_WINSYS_DIRS="sw"
 840 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 841 GALLIUM_STATE_TRACKERS_DIRS=""
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 846     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 847     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 848     NEED_WINSYS_XLIB="yes"
 849     ;;
 850 esac
 851
 852 if test "x$enable_dri" = xyes; then
 853     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 854     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 855 fi
 856
 857 if test "x$enable_gallium_osmesa" = xyes; then
 858     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 859         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 860     fi
 861     if test "x$enable_osmesa" = xyes; then
 862         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 863     fi
 864     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 865     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 866 fi
 867
 868 AC_SUBST([MESA_LLVM])
 869
 870 # Check for libdrm
 871 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 872                   [have_libdrm=yes], [have_libdrm=no])
 873 if test "x$have_libdrm" = xyes; then
 874         DEFINES="$DEFINES -DHAVE_LIBDRM"
 875 fi
 876
 877 case "$host_os" in
 878 linux*)
 879     need_pci_id=yes ;;
 880 *)
 881     need_pci_id=no ;;
 882 esac
 883
 884 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 885                   have_libudev=yes, have_libudev=no)
 886
 887 AC_ARG_ENABLE([sysfs],
 888     [AS_HELP_STRING([--enable-sysfs],
 889         [enable /sys PCI identification @<:@default=disabled@:>@])],
 890     [have_sysfs="$enableval"],
 891     [have_sysfs=no]
 892 )
 893
 894 if test "x$enable_dri" = xyes; then
 895     if test "$enable_static" = yes; then
 896         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 897     fi
 898
 899     # not a hard requirement as swrast does not depend on it
 900     if test "x$have_libdrm" = xyes; then
 901         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 902     fi
 903 fi
 904
 905 AC_ARG_ENABLE([driglx-direct],
 906     [AS_HELP_STRING([--disable-driglx-direct],
 907         [disable direct rendering in GLX and EGL for DRI \
 908             @<:@default=auto@:>@])],
 909     [driglx_direct="$enableval"],
 910     [driglx_direct="yes"])
 911
 912 dnl
 913 dnl libGL configuration per driver
 914 dnl
 915 case "x$enable_glx$enable_xlib_glx" in
 916 xyesyes)
 917     # Xlib-based GLX
 918     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 919     GL_PC_REQ_PRIV="x11 xext"
 920     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 921     GL_LIB_DEPS="$XLIBGL_LIBS"
 922     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 923     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 924     ;;
 925 xyesno)
 926     # DRI-based GLX
 927     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 928
 929     # find the DRI deps for libGL
 930     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED"
 931
 932     if test x"$driglx_direct" = xyes; then
 933         if test x"$dri_platform" = xdrm ; then
 934             DEFINES="$DEFINES -DGLX_USE_DRM"
 935             if test "x$have_libdrm" != xyes; then
 936                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 937             fi
 938
 939             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 940             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 941             if test x"$enable_dri3" = xyes; then
 942                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 943                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 944             fi
 945
 946             if test x"$enable_dri" = xyes; then
 947                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 948             fi
 949
 950             if test x"$enable_dri3" = xyes; then
 951                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 952             fi
 953         fi
 954         if test x"$dri_platform" = xapple ; then
 955             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 956         fi
 957     fi
 958
 959     # add xf86vidmode if available
 960     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 961     if test "$HAVE_XF86VIDMODE" = yes ; then
 962         dri_modules="$dri_modules xxf86vm"
 963     fi
 964
 965     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 966     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 967     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 968     GL_LIB_DEPS="$DRIGL_LIBS"
 969
 970     # need DRM libs, $PTHREAD_LIBS, etc.
 971     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 972     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 973     ;;
 974 esac
 975
 976 have_pci_id=no
 977 if test "$have_libudev" = yes; then
 978     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 979     have_pci_id=yes
 980 fi
 981
 982 if test "$have_sysfs" = yes; then
 983     DEFINES="$DEFINES -DHAVE_SYSFS"
 984     have_pci_id=yes
 985 fi
 986
 987 # This is outside the case (above) so that it is invoked even for non-GLX
 988 # builds.
 989 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 990
 991 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 992 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 993 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 994 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 995
 996 AC_SUBST([X11_INCLUDES])
 997 AC_SUBST([GL_LIB_DEPS])
 998 AC_SUBST([GL_PC_REQ_PRIV])
 999 AC_SUBST([GL_PC_LIB_PRIV])
1000 AC_SUBST([GL_PC_CFLAGS])
1001 AC_SUBST([DRI_PC_REQ_PRIV])
1002 AC_SUBST([GLESv1_CM_LIB_DEPS])
1003 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1004 AC_SUBST([GLESv2_LIB_DEPS])
1005 AC_SUBST([GLESv2_PC_LIB_PRIV])
1006
1007 AC_SUBST([HAVE_XF86VIDMODE])
1008
1009 dnl
1010 dnl More GLX setup
1011 dnl
1012 case "x$enable_glx$enable_xlib_glx" in
1013 xyesyes)
1014     DEFINES="$DEFINES -DUSE_XSHM"
1015     ;;
1016 xyesno)
1017     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1018     if test "x$driglx_direct" = xyes; then
1019         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1020     fi
1021     ;;
1022 esac
1023
1024 dnl
1025 dnl TLS detection
1026 dnl
1027
1028 AC_ARG_ENABLE([glx-tls],
1029     [AS_HELP_STRING([--enable-glx-tls],
1030         [enable TLS support in GLX @<:@default=disabled@:>@])],
1031     [GLX_USE_TLS="$enableval"],
1032     [GLX_USE_TLS=no])
1033 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1034
1035 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1036       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
1037
1038 dnl
1039 dnl More DRI setup
1040 dnl
1041 dnl Directory for DRI drivers
1042 AC_ARG_WITH([dri-driverdir],
1043     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1044         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1045     [DRI_DRIVER_INSTALL_DIR="$withval"],
1046     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1047 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1048 dnl Extra search path for DRI drivers
1049 AC_ARG_WITH([dri-searchpath],
1050     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1051         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1052     [DRI_DRIVER_SEARCH_DIR="$withval"],
1053     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1054 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1055 dnl Which drivers to build - default is chosen by platform
1056 AC_ARG_WITH([dri-drivers],
1057     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1058         [comma delimited classic DRI drivers list, e.g.
1059         "swrast,i965,radeon" @<:@default=auto@:>@])],
1060     [with_dri_drivers="$withval"],
1061     [with_dri_drivers=auto])
1062
1063 if test "x$with_dri_drivers" = xauto; then
1064     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1065         with_dri_drivers="yes"
1066     else
1067         with_dri_drivers="no"
1068     fi
1069 fi
1070 if test "x$with_dri_drivers" = xno; then
1071     with_dri_drivers=''
1072 fi
1073
1074 dnl If $with_dri_drivers is yes, drivers will be added through
1075 dnl platform checks. Set DEFINES and LIB_DEPS
1076 if test "x$enable_dri" = xyes; then
1077     # Platform specific settings and drivers to build
1078     case "$host_os" in
1079     linux*)
1080         DEFINES="$DEFINES -DHAVE_ALIAS"
1081         if test "x$enable_dri3" = xyes; then
1082             DEFINES="$DEFINES -DHAVE_DRI3"
1083         fi
1084
1085         if test "x$have_pci_id" != xyes; then
1086             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1087         fi
1088
1089         case "$host_cpu" in
1090         powerpc* | sparc*)
1091             # Build only the drivers for cards that exist on PowerPC/sparc
1092             if test "x$with_dri_drivers" = "xyes"; then
1093                 with_dri_drivers="r200 radeon swrast"
1094             fi
1095             ;;
1096         esac
1097         ;;
1098     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1099         DEFINES="$DEFINES -DHAVE_PTHREAD"
1100         DEFINES="$DEFINES -DHAVE_ALIAS"
1101         ;;
1102     gnu*)
1103         DEFINES="$DEFINES -DHAVE_ALIAS"
1104         ;;
1105     cygwin*)
1106         if test "x$with_dri_drivers" = "xyes"; then
1107             with_dri_drivers="swrast"
1108         fi
1109         ;;
1110     darwin*)
1111         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1112         if test "x$with_dri_drivers" = "xyes"; then
1113             with_dri_drivers="swrast"
1114         fi
1115         ;;
1116     esac
1117
1118     # default drivers
1119     if test "x$with_dri_drivers" = "xyes"; then
1120         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1121     fi
1122
1123     # Check for expat
1124     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1125     if test "x$have_expat" = "xyes"; then
1126        PKG_CHECK_MODULES([EXPAT], [expat], [],
1127                          AC_MSG_ERROR([Expat required for DRI.]))
1128     else
1129        # expat version 2.0 and earlier do not provide expat.pc
1130        EXPAT_LIBS=-lexpat
1131     fi
1132
1133     # If we are building any DRI driver other than swrast.
1134     if test -n "$with_dri_drivers"; then
1135         if test "x$with_dri_drivers" != xswrast; then
1136             # ... libdrm is required
1137             if test "x$have_libdrm" != xyes; then
1138                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1139             fi
1140             DRICOMMON_NEED_LIBDRM=yes
1141         else
1142             DRICOMMON_NEED_LIBDRM=no
1143         fi
1144     fi
1145
1146     # put all the necessary libs together
1147     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1148 fi
1149
1150 AC_SUBST([DRI_LIB_DEPS])
1151
1152 DRI_DIRS=''
1153 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1154 if test -n "$with_dri_drivers"; then
1155     if test "x$enable_opengl" != xyes; then
1156         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1157     fi
1158
1159     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1160     for driver in $dri_drivers; do
1161         DRI_DIRS="$DRI_DIRS $driver"
1162         case "x$driver" in
1163         xi915)
1164             HAVE_I915_DRI=yes;
1165             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1166             ;;
1167         xi965)
1168             HAVE_I965_DRI=yes;
1169             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1170             ;;
1171         xnouveau)
1172             HAVE_NOUVEAU_DRI=yes;
1173             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1174             ;;
1175         xradeon)
1176             HAVE_RADEON_DRI=yes;
1177             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1178             ;;
1179         xr200)
1180             HAVE_R200_DRI=yes;
1181             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1182             ;;
1183         xswrast)
1184             HAVE_SWRAST_DRI=yes;
1185             ;;
1186         *)
1187             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1188             ;;
1189         esac
1190     done
1191     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1192 fi
1193
1194 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1195 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1196                                   "x$enable_osmesa" = xyes -o \
1197                                   -n "$DRI_DIRS")
1198
1199 dnl
1200 dnl OSMesa configuration
1201 dnl
1202
1203 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1204 AC_ARG_WITH([osmesa-bits],
1205     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1206         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1207     [osmesa_bits="$withval"],
1208     [osmesa_bits=8])
1209 if test "x$osmesa_bits" != x8; then
1210     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1211         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1212         osmesa_bits=8
1213     fi
1214 fi
1215 case "x$osmesa_bits" in
1216 x8)
1217     OSMESA_LIB="${OSMESA_LIB}"
1218     ;;
1219 x16|x32)
1220     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1221     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1222     ;;
1223 *)
1224     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1225     ;;
1226 esac
1227
1228 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1229     # only link libraries with osmesa if shared
1230     if test "$enable_static" = no; then
1231         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1232     else
1233         OSMESA_LIB_DEPS=""
1234     fi
1235     OSMESA_MESA_DEPS=""
1236     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1237 fi
1238
1239 AC_SUBST([OSMESA_LIB_DEPS])
1240 AC_SUBST([OSMESA_MESA_DEPS])
1241 AC_SUBST([OSMESA_PC_REQ])
1242 AC_SUBST([OSMESA_PC_LIB_PRIV])
1243
1244 dnl
1245 dnl gbm configuration
1246 dnl
1247 if test "x$enable_gbm" = xauto; then
1248     case "$with_egl_platforms" in
1249         *drm*)
1250             enable_gbm=yes ;;
1251          *)
1252             enable_gbm=no ;;
1253     esac
1254 fi
1255 if test "x$enable_gbm" = xyes; then
1256     if test "x$need_pci_id$have_pci_id" = xyesno; then
1257         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1258     fi
1259
1260     if test "x$enable_dri" = xyes; then
1261         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1262         if test "x$enable_shared_glapi" = xno; then
1263             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1264         fi
1265     else
1266         # Strictly speaking libgbm does not require --enable-dri, although
1267         # both of its backends do. Thus one can build libgbm without any
1268         # backends if --disable-dri is set.
1269         # To avoid unnecessary complexity of checking if at least one backend
1270         # is available when building, just mandate --enable-dri.
1271         AC_MSG_ERROR([gbm requires --enable-dri])
1272     fi
1273 fi
1274 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1275 if test "x$need_pci_id$have_libudev" = xyesyes; then
1276     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1277 else
1278     GBM_PC_REQ_PRIV=""
1279 fi
1280 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1281 AC_SUBST([GBM_PC_REQ_PRIV])
1282 AC_SUBST([GBM_PC_LIB_PRIV])
1283
1284 dnl
1285 dnl EGL configuration
1286 dnl
1287 EGL_CLIENT_APIS=""
1288
1289 if test "x$enable_egl" = xyes; then
1290     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1291
1292     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1293
1294     if test "$enable_static" != yes; then
1295         if test "x$enable_dri" = xyes; then
1296             HAVE_EGL_DRIVER_DRI2=1
1297         fi
1298
1299     fi
1300 fi
1301 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1302 AC_SUBST([EGL_LIB_DEPS])
1303
1304 dnl
1305 dnl EGL Gallium configuration
1306 dnl
1307 if test "x$enable_gallium_egl" = xyes; then
1308     if test -z "$with_gallium_drivers"; then
1309         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1310     fi
1311     if test "x$enable_egl" = xno; then
1312         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1313     fi
1314     if test "x$have_libdrm" != xyes; then
1315         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1316     fi
1317
1318     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1319     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1320 fi
1321 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1322
1323 dnl
1324 dnl gbm Gallium configuration
1325 dnl
1326 if test "x$enable_gallium_gbm" = xauto; then
1327     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1328         yesyesyes*drm*)
1329             enable_gallium_gbm=yes ;;
1330          *)
1331             enable_gallium_gbm=no ;;
1332     esac
1333 fi
1334 if test "x$enable_gallium_gbm" = xyes; then
1335     if test -z "$with_gallium_drivers"; then
1336         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1337     fi
1338     if test "x$enable_gbm" = xno; then
1339         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1340     fi
1341     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1342     if test "x$enable_dri" = xno; then
1343         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1344     fi
1345
1346     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1347     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1348     enable_gallium_loader=yes
1349 fi
1350 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1351
1352 dnl
1353 dnl XA configuration
1354 dnl
1355 if test "x$enable_xa" = xyes; then
1356     if test "x$with_gallium_drivers" = xswrast; then
1357        AC_MSG_ERROR([
1358           Building xa requires at least one non swrast gallium driver.
1359           If you are looking to use libxatracker.so with the VMware driver,
1360           make sure to include svga in the gallium drivers list, apart from
1361           enabling XA.
1362           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1363     fi
1364     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1365     enable_gallium_loader=yes
1366 fi
1367 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1368
1369 dnl
1370 dnl OpenVG configuration
1371 dnl
1372 VG_LIB_DEPS=""
1373
1374 if test "x$enable_openvg" = xyes; then
1375     if test "x$enable_egl" = xno; then
1376         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1377     fi
1378     if test -z "$with_gallium_drivers"; then
1379         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1380     fi
1381     if test "x$enable_gallium_egl" = xno; then
1382         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1383     fi
1384
1385     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1386     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1387     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1388     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1389     AC_SUBST([VG_PC_LIB_PRIV])
1390 fi
1391 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1392
1393 dnl
1394 dnl Gallium G3DVL configuration
1395 dnl
1396 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1397     if test "x$enable_xvmc" = xauto; then
1398         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1399     fi
1400
1401     if test "x$enable_vdpau" = xauto; then
1402         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1403     fi
1404
1405     if test "x$enable_omx" = xauto; then
1406         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1407     fi
1408 fi
1409
1410 if test "x$enable_xvmc" = xyes; then
1411     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1412     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1413 fi
1414 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1415
1416 if test "x$enable_vdpau" = xyes; then
1417     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1418                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1419     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1420 fi
1421 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1422
1423 if test "x$enable_omx" = xyes; then
1424     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1425     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1426 fi
1427 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1428
1429 dnl
1430 dnl OpenCL configuration
1431 dnl
1432
1433 AC_ARG_WITH([libclc-path],
1434    [AS_HELP_STRING([--with-libclc-path],
1435          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1436    [LIBCLC_PATH="$withval"],
1437    [LIBCLC_PATH=''])
1438
1439 if test -n "$LIBCLC_PATH"; then
1440    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1441                   Please review the updated build instructions for clover:
1442                   http://dri.freedesktop.org/wiki/GalliumCompute])
1443 fi
1444
1445
1446 AC_ARG_WITH([clang-libdir],
1447    [AS_HELP_STRING([--with-clang-libdir],
1448          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1449    [CLANG_LIBDIR="$withval"],
1450    [CLANG_LIBDIR=''])
1451
1452 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1453
1454 if test "x$enable_opencl" = xyes; then
1455     if test -z "$with_gallium_drivers"; then
1456         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1457     fi
1458
1459     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1460         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1461     fi
1462
1463     if test "x$have_libclc" = xno; then
1464         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1465                     Make sure the directory containing libclc.pc is specified in your
1466                     PKG_CONFIG_PATH environment variable.
1467                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1468     else
1469         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1470         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1471         AC_SUBST([LIBCLC_INCLUDEDIR])
1472         AC_SUBST([LIBCLC_LIBEXECDIR])
1473     fi
1474
1475     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1476     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1477     enable_gallium_loader=yes
1478
1479     if test "x$enable_opencl_icd" = xyes; then
1480         OPENCL_LIBNAME="MesaOpenCL"
1481     else
1482         OPENCL_LIBNAME="OpenCL"
1483     fi
1484 fi
1485 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1486 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1487 AC_SUBST([OPENCL_LIBNAME])
1488
1489 dnl
1490 dnl Gallium configuration
1491 dnl
1492 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1493
1494 AC_SUBST([LLVM_BINDIR])
1495 AC_SUBST([LLVM_CFLAGS])
1496 AC_SUBST([LLVM_CPPFLAGS])
1497 AC_SUBST([LLVM_CXXFLAGS])
1498 AC_SUBST([LLVM_LIBDIR])
1499 AC_SUBST([LLVM_LIBS])
1500 AC_SUBST([LLVM_LDFLAGS])
1501 AC_SUBST([LLVM_INCLUDEDIR])
1502 AC_SUBST([LLVM_VERSION])
1503 AC_SUBST([CLANG_RESOURCE_DIR])
1504
1505 case "x$enable_opengl$enable_gles1$enable_gles2" in
1506 x*yes*)
1507     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1508     ;;
1509 esac
1510
1511 AC_SUBST([VG_LIB_DEPS])
1512 AC_SUBST([EGL_CLIENT_APIS])
1513
1514 dnl
1515 dnl EGL Platforms configuration
1516 dnl
1517 AC_ARG_WITH([egl-platforms],
1518     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1519         [comma delimited native platforms libEGL supports, e.g.
1520         "x11,drm" @<:@default=auto@:>@])],
1521     [with_egl_platforms="$withval"],
1522     [if test "x$enable_egl" = xyes; then
1523         with_egl_platforms="x11"
1524     else
1525         with_egl_platforms=""
1526     fi])
1527
1528 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1529     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1530 fi
1531
1532 # Do per-EGL platform setups and checks
1533 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1534 for plat in $egl_platforms; do
1535         case "$plat" in
1536         wayland)
1537                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1538                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1539
1540                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1541                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1542                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1543                 ;;
1544
1545         x11)
1546                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1547                 ;;
1548
1549         drm)
1550                 test "x$enable_gbm" = "xno" &&
1551                         AC_MSG_ERROR([EGL platform drm needs gbm])
1552                 test "x$have_libdrm" != xyes &&
1553                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1554                 ;;
1555
1556         android|fbdev|gdi|null)
1557                 ;;
1558
1559         *)
1560                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1561                 ;;
1562         esac
1563
1564         case "$plat$need_pci_id$have_pci_id" in
1565                 waylandyesno|drmyesno)
1566                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1567         esac
1568 done
1569
1570 # libEGL wants to default to the first platform specified in
1571 # ./configure.  parse that here.
1572 if test "x$egl_platforms" != "x"; then
1573     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1574     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1575 else
1576     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1577 fi
1578
1579 if echo "$egl_platforms" | grep -q 'x11'; then
1580     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1581     NEED_WINSYS_XLIB=yes
1582 fi
1583 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1584 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1585 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1586 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1587 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1588
1589 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1590
1591 AC_SUBST([EGL_NATIVE_PLATFORM])
1592 AC_SUBST([EGL_CFLAGS])
1593
1594 # If we don't have the X11 platform, set this define so we don't try to include
1595 # the X11 headers.
1596 if ! echo "$egl_platforms" | grep -q 'x11'; then
1597     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1598     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1599 fi
1600
1601 AC_ARG_WITH([egl-driver-dir],
1602     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1603                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1604     [EGL_DRIVER_INSTALL_DIR="$withval"],
1605     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1606 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1607
1608 AC_ARG_WITH([max-width],
1609     [AS_HELP_STRING([--with-max-width=N],
1610                     [Maximum framebuffer width (4096)])],
1611     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1612      AS_IF([test "${withval}" -gt "4096"],
1613            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1614 )
1615 AC_ARG_WITH([max-height],
1616     [AS_HELP_STRING([--with-max-height=N],
1617                     [Maximum framebuffer height (4096)])],
1618     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1619      AS_IF([test "${withval}" -gt "4096"],
1620            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1621 )
1622
1623 dnl
1624 dnl Gallium LLVM
1625 dnl
1626 AC_ARG_ENABLE([gallium-llvm],
1627     [AS_HELP_STRING([--enable-gallium-llvm],
1628         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1629     [enable_gallium_llvm="$enableval"],
1630     [enable_gallium_llvm=auto])
1631
1632 AC_ARG_ENABLE([llvm-shared-libs],
1633     [AS_HELP_STRING([--enable-llvm-shared-libs],
1634         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1635     [enable_llvm_shared_libs="$enableval"],
1636     [enable_llvm_shared_libs=yes])
1637
1638 AC_ARG_WITH([llvm-prefix],
1639     [AS_HELP_STRING([--with-llvm-prefix],
1640         [Prefix for LLVM installations in non-standard locations])],
1641     [llvm_prefix="$withval"],
1642     [llvm_prefix=''])
1643
1644
1645 # Call this inside ` ` to get the return value.
1646 # $1 is the llvm-config command with arguments.
1647 strip_unwanted_llvm_flags() {
1648     # Use \> (marks the end of the word)
1649     echo `$1` | sed \
1650         -e 's/-DNDEBUG\>//g' \
1651         -e 's/-pedantic\>//g' \
1652         -e 's/-Wcovered-switch-default\>//g' \
1653         -e 's/-O.\>//g' \
1654         -e 's/-g\>//g' \
1655         -e 's/-Wall\>//g' \
1656         -e 's/-Wcast-qual\>//g' \
1657         -e 's/-Woverloaded-virtual\>//g' \
1658         -e 's/-fcolor-diagnostics\>//g' \
1659         -e 's/-fdata-sections\>//g' \
1660         -e 's/-ffunction-sections\>//g' \
1661         -e 's/-fno-exceptions\>//g' \
1662         -e 's/-fomit-frame-pointer\>//g' \
1663         -e 's/-fvisibility-inlines-hidden\>//g' \
1664         -e 's/-fPIC\>//g' \
1665         -e 's/-fstack-protector-strong\>//g'
1666 }
1667
1668
1669 if test -z "$with_gallium_drivers"; then
1670     enable_gallium_llvm=no
1671 fi
1672 if test "x$enable_gallium_llvm" = xauto; then
1673     case "$host_cpu" in
1674     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1675     esac
1676 fi
1677 if test "x$enable_gallium_llvm" = xyes; then
1678     if test -n "$llvm_prefix"; then
1679         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1680     else
1681         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1682     fi
1683
1684     if test "x$LLVM_CONFIG" != xno; then
1685         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1686         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1687         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1688         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1689         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1690         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1691         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1692         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1693
1694         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1695             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1696         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1697             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1698
1699         dnl In LLVM 3.4.1 patch level was defined in config.h and not
1700         dnl llvm-config.h
1701         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
1702             [#include "${LLVM_INCLUDEDIR}/llvm/Config/config.h"],
1703             LLVM_VERSION_PATCH=0) dnl Default if LLVM_VERSION_PATCH not found
1704
1705         if test -n "${LLVM_VERSION_MAJOR}"; then
1706             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1707         else
1708             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1709         fi
1710
1711         LLVM_REQUIRED_VERSION_MAJOR="3"
1712         LLVM_REQUIRED_VERSION_MINOR="1"
1713         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1714             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1715         fi
1716
1717         LLVM_COMPONENTS="engine bitwriter"
1718         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1719             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1720         fi
1721
1722         if test "x$enable_opencl" = xyes; then
1723             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1724             # LLVM 3.3 >= 177971 requires IRReader
1725             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1726                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1727             fi
1728             # LLVM 3.4 requires Option
1729             if $LLVM_CONFIG --components | grep -qw 'option'; then
1730                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1731             fi
1732             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1733             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1734                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1735             fi
1736             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1737                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1738             fi
1739         fi
1740         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1741         MESA_LLVM=1
1742
1743         dnl Check for Clang internal headers
1744         if test "x$enable_opencl" = xyes; then
1745             if test -z "$CLANG_LIBDIR"; then
1746                 CLANG_LIBDIR=${LLVM_LIBDIR}
1747             fi
1748             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1749             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1750                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1751         fi
1752     else
1753         MESA_LLVM=0
1754         LLVM_VERSION_INT=0
1755     fi
1756 else
1757     MESA_LLVM=0
1758     LLVM_VERSION_INT=0
1759
1760     if test "x$enable_opencl" = xyes; then
1761         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1762     fi
1763 fi
1764
1765 dnl Directory for XVMC libs
1766 AC_ARG_WITH([xvmc-libdir],
1767     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1768         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1769     [XVMC_LIB_INSTALL_DIR="$withval"],
1770     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1771 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1772
1773 dnl
1774 dnl Gallium Tests
1775 dnl
1776 if test "x$enable_gallium_tests" = xyes; then
1777     enable_gallium_loader=yes
1778 fi
1779 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1780
1781 if test "x$enable_gallium_loader" = xyes; then
1782     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1783 fi
1784 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1785
1786 dnl Directory for VDPAU libs
1787 AC_ARG_WITH([vdpau-libdir],
1788     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1789         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1790     [VDPAU_LIB_INSTALL_DIR="$withval"],
1791     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1792 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1793
1794 OMX_LIB_INSTALL_DIR_DEFAULT=''
1795 if test "x$enable_omx" = xyes; then
1796     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1797 fi
1798
1799 AC_ARG_WITH([omx-libdir],
1800     [AS_HELP_STRING([--with-omx-libdir=DIR],
1801         [directory for the OMX libraries])],
1802     [OMX_LIB_INSTALL_DIR="$withval"],
1803     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1804 AC_SUBST([OMX_LIB_INSTALL_DIR])
1805
1806 dnl Directory for OpenCL libs
1807 AC_ARG_WITH([opencl-libdir],
1808     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1809         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1810     [OPENCL_LIB_INSTALL_DIR="$withval"],
1811     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1812 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1813
1814 dnl
1815 dnl Gallium helper functions
1816 dnl
1817 gallium_check_st() {
1818     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1819          if test "x$have_libdrm" != xyes; then
1820             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1821          fi
1822          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1823     fi
1824     if test "x$enable_dri" = xyes && test -n "$2"; then
1825          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1826     fi
1827     if test "x$enable_xa" = xyes && test -n "$3"; then
1828          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1829     fi
1830     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1831          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1832     fi
1833     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1834          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1835     fi
1836     if test "x$enable_omx" = xyes && test "x$6" != x; then
1837          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1838     fi
1839 }
1840
1841 gallium_require_llvm() {
1842     if test "x$MESA_LLVM" = x0; then
1843         case "$host_cpu" in
1844         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1845         esac
1846     fi
1847 }
1848
1849 gallium_require_drm_loader() {
1850     if test "x$enable_gallium_loader" = xyes; then
1851         if test "x$need_pci_id$have_pci_id" = xyesno; then
1852             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1853         fi
1854         if test "x$have_libdrm" != xyes; then
1855             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1856         fi
1857         enable_gallium_drm_loader=yes
1858     fi
1859 }
1860
1861 require_egl_drm() {
1862     case "$with_egl_platforms" in
1863         *drm*)
1864             ;;
1865          *)
1866             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1867             ;;
1868     esac
1869     if test "x$enable_gbm" != xyes; then
1870             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1871     fi
1872 }
1873
1874 radeon_llvm_check() {
1875     if test "x$enable_gallium_llvm" != "xyes"; then
1876         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1877     fi
1878     LLVM_REQUIRED_VERSION_MAJOR="3"
1879     LLVM_REQUIRED_VERSION_MINOR="3"
1880     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1881         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1882     fi
1883     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1884         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1885                       sources with the --enable-experimental-targets=R600
1886                       configure flag])
1887     fi
1888     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1889     NEED_RADEON_LLVM=yes
1890     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1891                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1892 }
1893
1894 dnl Gallium drivers
1895 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1896         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1897     NEED_NONNULL_WINSYS=yes
1898 fi
1899 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1900
1901 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1902 if test -n "$with_gallium_drivers"; then
1903     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1904     for driver in $gallium_drivers; do
1905         case "x$driver" in
1906         xsvga)
1907             HAVE_GALLIUM_SVGA=yes
1908             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1909             gallium_require_drm_loader
1910             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1911             ;;
1912         xi915)
1913             HAVE_GALLIUM_I915=yes
1914             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1915             gallium_require_drm_loader
1916             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1917             gallium_check_st "i915/drm" "dri-i915"
1918             DRICOMMON_NEED_LIBDRM=yes
1919             ;;
1920         xilo)
1921             HAVE_GALLIUM_ILO=yes
1922             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1923             gallium_require_drm_loader
1924             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1925             gallium_check_st "intel/drm" "dri-ilo"
1926             DRICOMMON_NEED_LIBDRM=yes
1927             ;;
1928         xr300)
1929             HAVE_GALLIUM_R300=yes
1930             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1931             gallium_require_drm_loader
1932             gallium_require_llvm "Gallium R300"
1933             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1934             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1935             DRICOMMON_NEED_LIBDRM=yes
1936             ;;
1937         xr600)
1938             HAVE_GALLIUM_R600=yes
1939             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1940             gallium_require_drm_loader
1941             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1942             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1943                 radeon_llvm_check "r600g"
1944                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1945             fi
1946             if test "x$enable_r600_llvm" = xyes; then
1947                 USE_R600_LLVM_COMPILER=yes;
1948             fi
1949             if test "x$enable_opencl" = xyes; then
1950                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1951             fi
1952             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1953             DRICOMMON_NEED_LIBDRM=yes
1954             ;;
1955         xradeonsi)
1956             HAVE_GALLIUM_RADEONSI=yes
1957             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1958             gallium_require_drm_loader
1959             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1960             radeon_llvm_check "radeonsi"
1961             require_egl_drm "radeonsi"
1962             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1963             DRICOMMON_NEED_LIBDRM=yes
1964             ;;
1965         xnouveau)
1966             HAVE_GALLIUM_NOUVEAU=yes
1967             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1968             gallium_require_drm_loader
1969             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1970             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau" "omx-nouveau"
1971             DRICOMMON_NEED_LIBDRM=yes
1972             ;;
1973         xfreedreno)
1974             HAVE_GALLIUM_FREEDRENO=yes
1975             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1976             gallium_require_drm_loader
1977             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1978             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1979             DRICOMMON_NEED_LIBDRM=yes
1980             ;;
1981         xswrast)
1982             HAVE_GALLIUM_SOFTPIPE=yes
1983             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1984             if test "x$MESA_LLVM" = x1; then
1985                 HAVE_GALLIUM_LLVMPIPE=yes
1986                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1987             fi
1988
1989             if test "x$enable_dri" = xyes; then
1990                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1991             fi
1992             ;;
1993         *)
1994             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1995             ;;
1996         esac
1997     done
1998 fi
1999
2000 dnl Set LLVM_LIBS - This is done after the driver configuration so
2001 dnl that drivers can add additonal components to LLVM_COMPONENTS.
2002 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2003 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2004 dnl this was causing the same libraries to be appear multiple times
2005 dnl in LLVM_LIBS.
2006
2007 if test "x$MESA_LLVM" != x0; then
2008
2009     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2010
2011     if test "x$enable_llvm_shared_libs" = xyes; then
2012         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2013         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2014         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
2015
2016         if test "x$llvm_have_one_so" = xyes; then
2017             dnl LLVM was built using auto*, so there is only one shared object.
2018             LLVM_LIBS="-l$LLVM_SO_NAME"
2019         else
2020             dnl If LLVM was built with CMake, there will be one shared object per
2021             dnl component.
2022             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
2023                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2024         Please make sure you have built llvm with the --enable-shared option
2025         and that your llvm libraries are installed in $LLVM_LIBDIR
2026         If you have installed your llvm libraries to a different directory you
2027         can use the --with-llvm-prefix= configure flag to specify this directory.
2028         NOTE: Mesa is attempting to use llvm shared libraries by default.
2029         If you do not want to build with llvm shared libraries and instead want to
2030         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2031         invocation and rebuild.])])
2032
2033            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2034            dnl install uses a shared object for each compoenent and we have
2035            dnl already added all of these objects to LLVM_LIBS.
2036         fi
2037     else
2038         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2039     fi
2040 fi
2041
2042 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2043 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2044 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2045 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2046 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2047 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2048 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2049                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2050 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2051 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2052 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2053 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2054
2055 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
2056                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2057 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
2058                                                   && test "x$MESA_LLVM" = x1)
2059
2060 # Enable static gallium targets for now.
2061 # Do not touch this unless you know what you are doing.
2062 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "xyes" = xyes)
2063
2064 # NOTE: anything using xcb or other client side libs ends up in separate
2065 #       _CLIENT variables.  The pipe loader is built in two variants,
2066 #       one that is standalone and does not link any x client libs (for
2067 #       use by XA tracker in particular, but could be used in any case
2068 #       where communication with xserver is not desired).
2069 if test "x$enable_gallium_loader" = xyes; then
2070     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2071
2072     if test "x$NEED_WINSYS_XLIB" = xyes; then
2073         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2074     fi
2075
2076     if test "x$enable_dri" = xyes; then
2077         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2078     fi
2079
2080     if test "x$enable_gallium_drm_loader" = xyes; then
2081         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2082         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2083                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2084         if test "x$pipe_loader_have_xcb" = xyes; then
2085             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2086             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2087         fi
2088     fi
2089
2090     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2091     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2092
2093     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2094     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2095     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2096     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2097 fi
2098
2099 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2100 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2101 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2102 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2103 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2104 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2105
2106 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
2107                                             "x$HAVE_GALLIUM_R300" = xyes -o \
2108                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2109                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2110 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
2111                                          "x$HAVE_GALLIUM_SVGA" = xyes)
2112 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2113 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2114 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2115 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2116 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2117 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2118 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2119
2120 AC_SUBST([ELF_LIB])
2121
2122 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2123 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2124 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2125 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2126 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2127
2128 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2129 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2130 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2131
2132 AC_SUBST([VDPAU_MAJOR], 1)
2133 AC_SUBST([VDPAU_MINOR], 0)
2134
2135 AC_SUBST([XVMC_MAJOR], 1)
2136 AC_SUBST([XVMC_MINOR], 0)
2137
2138 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2139 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2140 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2141 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2142
2143 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2144 AC_SUBST([XA_MINOR], $XA_MINOR)
2145 AC_SUBST([XA_TINY], $XA_TINY)
2146 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2147
2148 dnl Restore LDFLAGS and CPPFLAGS
2149 LDFLAGS="$_SAVE_LDFLAGS"
2150 CPPFLAGS="$_SAVE_CPPFLAGS"
2151
2152 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2153 if test "x$acv_mesa_CLANG" = xyes; then
2154     CFLAGS="$CFLAGS -Qunused-arguments"
2155     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2156 fi
2157
2158 dnl Add user CFLAGS and CXXFLAGS
2159 CFLAGS="$CFLAGS $USER_CFLAGS"
2160 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2161
2162 dnl Substitute the config
2163 AC_CONFIG_FILES([Makefile
2164                 src/Makefile
2165                 src/egl/drivers/dri2/Makefile
2166                 src/egl/main/Makefile
2167                 src/egl/main/egl.pc
2168                 src/egl/wayland/Makefile
2169                 src/egl/wayland/wayland-drm/Makefile
2170                 src/egl/wayland/wayland-egl/Makefile
2171                 src/egl/wayland/wayland-egl/wayland-egl.pc
2172                 src/gallium/auxiliary/Makefile
2173                 src/gallium/auxiliary/pipe-loader/Makefile
2174                 src/gallium/drivers/Makefile
2175                 src/gallium/drivers/freedreno/Makefile
2176                 src/gallium/drivers/galahad/Makefile
2177                 src/gallium/drivers/i915/Makefile
2178                 src/gallium/drivers/identity/Makefile
2179                 src/gallium/drivers/ilo/Makefile
2180                 src/gallium/drivers/llvmpipe/Makefile
2181                 src/gallium/drivers/noop/Makefile
2182                 src/gallium/drivers/nouveau/Makefile
2183                 src/gallium/drivers/r300/Makefile
2184                 src/gallium/drivers/r600/Makefile
2185                 src/gallium/drivers/radeon/Makefile
2186                 src/gallium/drivers/radeonsi/Makefile
2187                 src/gallium/drivers/rbug/Makefile
2188                 src/gallium/drivers/softpipe/Makefile
2189                 src/gallium/drivers/svga/Makefile
2190                 src/gallium/drivers/trace/Makefile
2191                 src/gallium/state_trackers/Makefile
2192                 src/gallium/state_trackers/clover/Makefile
2193                 src/gallium/state_trackers/dri/Makefile
2194                 src/gallium/state_trackers/dri/drm/Makefile
2195                 src/gallium/state_trackers/dri/sw/Makefile
2196                 src/gallium/state_trackers/egl/Makefile
2197                 src/gallium/state_trackers/gbm/Makefile
2198                 src/gallium/state_trackers/glx/xlib/Makefile
2199                 src/gallium/state_trackers/omx/Makefile
2200                 src/gallium/state_trackers/osmesa/Makefile
2201                 src/gallium/state_trackers/vdpau/Makefile
2202                 src/gallium/state_trackers/vega/Makefile
2203                 src/gallium/state_trackers/xa/Makefile
2204                 src/gallium/state_trackers/xvmc/Makefile
2205                 src/gallium/targets/Makefile
2206                 src/gallium/targets/dri-freedreno/Makefile
2207                 src/gallium/targets/dri-i915/Makefile
2208                 src/gallium/targets/dri-ilo/Makefile
2209                 src/gallium/targets/dri-nouveau/Makefile
2210                 src/gallium/targets/dri-swrast/Makefile
2211                 src/gallium/targets/dri-vmwgfx/Makefile
2212                 src/gallium/targets/egl-static/Makefile
2213                 src/gallium/targets/gbm/Makefile
2214                 src/gallium/targets/libgl-xlib/Makefile
2215                 src/gallium/targets/omx-nouveau/Makefile
2216                 src/gallium/targets/opencl/Makefile
2217                 src/gallium/targets/osmesa/Makefile
2218                 src/gallium/targets/osmesa/osmesa.pc
2219                 src/gallium/targets/pipe-loader/Makefile
2220                 src/gallium/targets/r300/dri/Makefile
2221                 src/gallium/targets/r600/dri/Makefile
2222                 src/gallium/targets/r600/omx/Makefile
2223                 src/gallium/targets/r600/vdpau/Makefile
2224                 src/gallium/targets/r600/xvmc/Makefile
2225                 src/gallium/targets/radeonsi/dri/Makefile
2226                 src/gallium/targets/radeonsi/omx/Makefile
2227                 src/gallium/targets/radeonsi/vdpau/Makefile
2228                 src/gallium/targets/vdpau-nouveau/Makefile
2229                 src/gallium/targets/xa/Makefile
2230                 src/gallium/targets/xa/xatracker.pc
2231                 src/gallium/targets/xvmc-nouveau/Makefile
2232                 src/gallium/tests/trivial/Makefile
2233                 src/gallium/tests/unit/Makefile
2234                 src/gallium/winsys/Makefile
2235                 src/gallium/winsys/freedreno/drm/Makefile
2236                 src/gallium/winsys/i915/drm/Makefile
2237                 src/gallium/winsys/intel/drm/Makefile
2238                 src/gallium/winsys/nouveau/drm/Makefile
2239                 src/gallium/winsys/radeon/drm/Makefile
2240                 src/gallium/winsys/svga/drm/Makefile
2241                 src/gallium/winsys/sw/dri/Makefile
2242                 src/gallium/winsys/sw/fbdev/Makefile
2243                 src/gallium/winsys/sw/null/Makefile
2244                 src/gallium/winsys/sw/wayland/Makefile
2245                 src/gallium/winsys/sw/wrapper/Makefile
2246                 src/gallium/winsys/sw/xlib/Makefile
2247                 src/gbm/Makefile
2248                 src/gbm/main/gbm.pc
2249                 src/glsl/Makefile
2250                 src/glx/Makefile
2251                 src/glx/apple/Makefile
2252                 src/glx/tests/Makefile
2253                 src/gtest/Makefile
2254                 src/loader/Makefile
2255                 src/mapi/Makefile
2256                 src/mapi/es1api/Makefile
2257                 src/mapi/es1api/glesv1_cm.pc
2258                 src/mapi/es2api/Makefile
2259                 src/mapi/es2api/glesv2.pc
2260                 src/mapi/glapi/Makefile
2261                 src/mapi/glapi/gen/Makefile
2262                 src/mapi/glapi/tests/Makefile
2263                 src/mapi/shared-glapi/Makefile
2264                 src/mapi/shared-glapi/tests/Makefile
2265                 src/mapi/vgapi/Makefile
2266                 src/mapi/vgapi/vg.pc
2267                 src/mesa/Makefile
2268                 src/mesa/gl.pc
2269                 src/mesa/drivers/dri/dri.pc
2270                 src/mesa/drivers/dri/common/Makefile
2271                 src/mesa/drivers/dri/common/xmlpool/Makefile
2272                 src/mesa/drivers/dri/i915/Makefile
2273                 src/mesa/drivers/dri/i965/Makefile
2274                 src/mesa/drivers/dri/Makefile
2275                 src/mesa/drivers/dri/nouveau/Makefile
2276                 src/mesa/drivers/dri/r200/Makefile
2277                 src/mesa/drivers/dri/radeon/Makefile
2278                 src/mesa/drivers/dri/swrast/Makefile
2279                 src/mesa/drivers/osmesa/Makefile
2280                 src/mesa/drivers/osmesa/osmesa.pc
2281                 src/mesa/drivers/x11/Makefile
2282                 src/mesa/main/tests/Makefile
2283                 src/mesa/main/tests/hash_table/Makefile])
2284
2285 dnl Sort the dirs alphabetically
2286 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2287 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2288 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2289 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2290
2291 AC_OUTPUT
2292
2293 dnl
2294 dnl Output some configuration info for the user
2295 dnl
2296 echo ""
2297 echo "        prefix:          $prefix"
2298 echo "        exec_prefix:     $exec_prefix"
2299 echo "        libdir:          $libdir"
2300 echo "        includedir:      $includedir"
2301
2302 dnl API info
2303 echo ""
2304 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2305 echo "        OpenVG:          $enable_openvg"
2306
2307 dnl Driver info
2308 echo ""
2309 case "x$enable_osmesa$enable_gallium_osmesa" in
2310 xnoyes)
2311         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2312         ;;
2313 xyesno)
2314         echo "        OSMesa:          lib$OSMESA_LIB"
2315         ;;
2316 xnono)
2317         echo "        OSMesa:          no"
2318         ;;
2319 esac
2320
2321 echo ""
2322 if test "x$enable_dri" != xno; then
2323         echo "        DRI platform:    $dri_platform"
2324         if test -z "$DRI_DIRS"; then
2325             echo "        DRI drivers:     no"
2326         else
2327             echo "        DRI drivers:     $DRI_DIRS"
2328         fi
2329         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2330 fi
2331
2332 case "x$enable_glx$enable_xlib_glx" in
2333 xyesyes)
2334     echo "        GLX:             Xlib-based"
2335     ;;
2336 xyesno)
2337     echo "        GLX:             DRI-based"
2338     ;;
2339 *)
2340     echo "        GLX:             $enable_glx"
2341     ;;
2342 esac
2343
2344 dnl EGL
2345 echo ""
2346 echo "        EGL:             $enable_egl"
2347 if test "$enable_egl" = yes; then
2348     echo "        EGL platforms:   $egl_platforms"
2349
2350     egl_drivers=""
2351     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2352         egl_drivers="$egl_drivers builtin:egl_dri2"
2353     fi
2354
2355     if test "x$enable_gallium_egl" = xyes; then
2356         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2357         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2358     else
2359         echo "        EGL drivers:    $egl_drivers"
2360     fi
2361 fi
2362
2363 echo ""
2364 if test "x$MESA_LLVM" = x1; then
2365     echo "        llvm:            yes"
2366     echo "        llvm-config:     $LLVM_CONFIG"
2367     echo "        llvm-version:    $LLVM_VERSION"
2368 else
2369     echo "        llvm:            no"
2370 fi
2371
2372 echo ""
2373 if test -n "$with_gallium_drivers"; then
2374     echo "        Gallium:         yes"
2375     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2376     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2377     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2378     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2379 else
2380     echo "        Gallium:         no"
2381 fi
2382
2383
2384 dnl Libraries
2385 echo ""
2386 echo "        Shared libs:     $enable_shared"
2387 echo "        Static libs:     $enable_static"
2388 echo "        Shared-glapi:    $enable_shared_glapi"
2389
2390 dnl Compiler options
2391 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2392 cflags=`echo $CFLAGS | \
2393     $SED 's/^ *//;s/  */ /;s/ *$//'`
2394 cxxflags=`echo $CXXFLAGS | \
2395     $SED 's/^ *//;s/  */ /;s/ *$//'`
2396 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2397 echo ""
2398 echo "        CFLAGS:          $cflags"
2399 echo "        CXXFLAGS:        $cxxflags"
2400 echo "        Macros:          $defines"
2401 echo ""
2402 if test "x$MESA_LLVM" = x1; then
2403     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2404     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2405     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2406     echo ""
2407 fi
2408 echo "        PYTHON2:         $PYTHON2"
2409
2410 echo ""
2411 echo "        Run '${MAKE-make}' to build Mesa"
2412 echo ""