configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.60
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.62
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.65
  78 DRI2PROTO_REQUIRED=2.6
  79 DRI3PROTO_REQUIRED=1.0
  80 PRESENTPROTO_REQUIRED=1.0
  81 LIBUDEV_REQUIRED=151
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.3.4
  93
  94 dnl Check for progs
  95 AC_PROG_CPP
  96 AC_PROG_CC
  97 AC_PROG_CXX
  98 AM_PROG_CC_C_O
  99 AM_PROG_AS
 100 AX_CHECK_GNU_MAKE
 101 AC_CHECK_PROGS([PYTHON2], [python2 python])
 102 AC_PROG_SED
 103 AC_PROG_MKDIR_P
 104
 105 AC_SYS_LARGEFILE
 106
 107 LT_PREREQ([2.2])
 108 LT_INIT([disable-static])
 109
 110 AC_CHECK_PROG(RM, rm, [rm -f])
 111
 112 AX_PROG_BISON([],
 113               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
 114                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 115 AX_PROG_FLEX([],
 116              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
 117                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 118
 119 AC_CHECK_PROG(INDENT, indent, indent, cat)
 120 if test "x$INDENT" != "xcat"; then
 121     # Only GNU indent is supported
 122     INDENT_VERSION=`indent --version | grep GNU`
 123     if test $? -eq 0; then
 124        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 125     else
 126        INDENT="cat"
 127     fi
 128 fi
 129
 130 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 131
 132 if test -z "$PYTHON2"; then
 133     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 134         AC_MSG_ERROR([Python not found - unable to generate sources])
 135     fi
 136 else
 137     if test "x$acv_mako_found" = xno; then
 138         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 139             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 140         fi
 141     fi
 142 fi
 143
 144 AC_PROG_INSTALL
 145
 146 dnl We need a POSIX shell for parts of the build. Assume we have one
 147 dnl in most cases.
 148 case "$host_os" in
 149 solaris*)
 150     # Solaris /bin/sh is too old/non-POSIX compliant
 151     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 152     SHELL="$POSIX_SHELL"
 153     ;;
 154 esac
 155
 156 dnl clang is mostly GCC-compatible, but its version is much lower,
 157 dnl so we have to check for it.
 158 AC_MSG_CHECKING([if compiling with clang])
 159
 160 AC_COMPILE_IFELSE(
 161 [AC_LANG_PROGRAM([], [[
 162 #ifndef __clang__
 163        not clang
 164 #endif
 165 ]])],
 166 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 167
 168 AC_MSG_RESULT([$acv_mesa_CLANG])
 169
 170 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 171 dnl versions are explictly not supported.
 172 GEN_ASM_OFFSETS=no
 173 USE_GNU99=no
 174 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 175     AC_MSG_CHECKING([whether gcc version is sufficient])
 176     major=0
 177     minor=0
 178
 179     GCC_VERSION=`$CC -dumpversion`
 180     if test $? -eq 0; then
 181         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 182         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 183     fi
 184
 185     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 186         AC_MSG_RESULT([no])
 187         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 188     else
 189         AC_MSG_RESULT([yes])
 190     fi
 191
 192     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 193         USE_GNU99=yes
 194     fi
 195     if test "x$cross_compiling" = xyes; then
 196         GEN_ASM_OFFSETS=yes
 197     fi
 198 fi
 199
 200 dnl Check for compiler builtins
 201 AX_GCC_BUILTIN([__builtin_bswap32])
 202 AX_GCC_BUILTIN([__builtin_bswap64])
 203 AX_GCC_BUILTIN([__builtin_clz])
 204 AX_GCC_BUILTIN([__builtin_clzll])
 205 AX_GCC_BUILTIN([__builtin_ctz])
 206 AX_GCC_BUILTIN([__builtin_expect])
 207 AX_GCC_BUILTIN([__builtin_ffs])
 208 AX_GCC_BUILTIN([__builtin_ffsll])
 209 AX_GCC_BUILTIN([__builtin_popcount])
 210 AX_GCC_BUILTIN([__builtin_popcountll])
 211 AX_GCC_BUILTIN([__builtin_unreachable])
 212
 213 AX_GCC_FUNC_ATTRIBUTE([const])
 214 AX_GCC_FUNC_ATTRIBUTE([flatten])
 215 AX_GCC_FUNC_ATTRIBUTE([format])
 216 AX_GCC_FUNC_ATTRIBUTE([malloc])
 217 AX_GCC_FUNC_ATTRIBUTE([packed])
 218 AX_GCC_FUNC_ATTRIBUTE([pure])
 219 AX_GCC_FUNC_ATTRIBUTE([unused])
 220 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 221
 222 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 223
 224 dnl Make sure the pkg-config macros are defined
 225 m4_ifndef([PKG_PROG_PKG_CONFIG],
 226     [m4_fatal([Could not locate the pkg-config autoconf macros.
 227   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 228   are in a different location, try setting the environment variable
 229   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 230 PKG_PROG_PKG_CONFIG()
 231
 232 dnl LIB_DIR - library basename
 233 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 234 AC_SUBST([LIB_DIR])
 235
 236 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 237 _SAVE_LDFLAGS="$LDFLAGS"
 238 _SAVE_CPPFLAGS="$CPPFLAGS"
 239
 240 dnl Compiler macros
 241 DEFINES="-D__STDC_LIMIT_MACROS"
 242 AC_SUBST([DEFINES])
 243 case "$host_os" in
 244 linux*|*-gnu*|gnu*)
 245     DEFINES="$DEFINES -D_GNU_SOURCE"
 246     ;;
 247 solaris*)
 248     DEFINES="$DEFINES -DSVR4"
 249     ;;
 250 cygwin*)
 251     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 252     ;;
 253 esac
 254
 255 dnl Add flags for gcc and g++
 256 if test "x$GCC" = xyes; then
 257     CFLAGS="$CFLAGS -Wall"
 258
 259     if test "x$USE_GNU99" = xyes; then
 260         CFLAGS="$CFLAGS -std=gnu99"
 261     else
 262         CFLAGS="$CFLAGS -std=c99"
 263     fi
 264
 265     # Enable -Werror=implicit-function-declaration and
 266     # -Werror=missing-prototypes, if available, or otherwise, just
 267     # -Wmissing-prototypes.  This is particularly useful to avoid
 268     # generating a loadable driver module that has undefined symbols.
 269     save_CFLAGS="$CFLAGS"
 270     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 271     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 272     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 273     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 274                    AC_MSG_RESULT([yes]),
 275                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 276                     AC_MSG_RESULT([no])]);
 277
 278     # Enable -fvisibility=hidden if using a gcc that supports it
 279     save_CFLAGS="$CFLAGS"
 280     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 281     VISIBILITY_CFLAGS="-fvisibility=hidden"
 282     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 283     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 284                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 285
 286     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 287     CFLAGS=$save_CFLAGS
 288
 289     # Work around aliasing bugs - developers should comment this out
 290     CFLAGS="$CFLAGS -fno-strict-aliasing"
 291
 292     # We don't want floating-point math functions to set errno or trap
 293     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 294
 295     # gcc's builtin memcmp is slower than glibc's
 296     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 297     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 298
 299     # Flags to help ensure that certain portions of the code -- and only those
 300     # portions -- can be built with MSVC:
 301     # - src/util, src/gallium/auxiliary, and src/gallium/drivers/llvmpipe needs
 302     #   to build with Windows SDK 7.0.7600, which bundles MSVC 2008
 303     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 304     #   supports most of C99)
 305     # - the rest has no compiler compiler restrictions
 306     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 307     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 308
 309     # Enable -Werror=vla if compiler supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 312     CFLAGS="$CFLAGS -Werror=vla"
 313     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 314                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 315                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 316                     AC_MSG_RESULT([yes])],
 317                     AC_MSG_RESULT([no]));
 318     CFLAGS="$save_CFLAGS"
 319
 320     MSVC2008_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=declaration-after-statement"
 321     MSVC2008_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS"
 322 fi
 323 if test "x$GXX" = xyes; then
 324     CXXFLAGS="$CXXFLAGS -Wall"
 325
 326     # Enable -fvisibility=hidden if using a gcc that supports it
 327     save_CXXFLAGS="$CXXFLAGS"
 328     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 329     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 330     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 331     AC_LANG_PUSH([C++])
 332     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 333                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 334     AC_LANG_POP([C++])
 335
 336     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 337     CXXFLAGS=$save_CXXFLAGS
 338
 339     # Work around aliasing bugs - developers should comment this out
 340     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 341
 342     # gcc's builtin memcmp is slower than glibc's
 343     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 344     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349 AC_SUBST([MSVC2008_COMPAT_CFLAGS])
 350 AC_SUBST([MSVC2008_COMPAT_CXXFLAGS])
 351
 352 dnl even if the compiler appears to support it, using visibility attributes isn't
 353 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 354 case "$host_os" in
 355 cygwin*)
 356     VISIBILITY_CFLAGS=""
 357     VISIBILITY_CXXFLAGS=""
 358     ;;
 359 esac
 360
 361 AC_SUBST([VISIBILITY_CFLAGS])
 362 AC_SUBST([VISIBILITY_CXXFLAGS])
 363
 364 dnl
 365 dnl Optional flags, check for compiler support
 366 dnl
 367 SSE41_CFLAGS="-msse4.1"
 368 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 369 dnl stack, but on x86-32 such alignment is not guaranteed.
 370 case "$target_cpu" in
 371 i?86)
 372     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 373     ;;
 374 esac
 375 save_CFLAGS="$CFLAGS"
 376 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 377 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 378 #include <smmintrin.h>
 379 int main () {
 380     __m128i a = _mm_set1_epi32 (0), b = _mm_set1_epi32 (0), c;
 381     c = _mm_max_epu32(a, b);
 382     return 0;
 383 }]])], SSE41_SUPPORTED=1)
 384 CFLAGS="$save_CFLAGS"
 385 if test "x$SSE41_SUPPORTED" = x1; then
 386     DEFINES="$DEFINES -DUSE_SSE41"
 387 fi
 388 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 389 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 390
 391 dnl Can't have static and shared libraries, default to static if user
 392 dnl explicitly requested. If both disabled, set to static since shared
 393 dnl was explicitly requested.
 394 case "x$enable_static$enable_shared" in
 395 xyesyes)
 396     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 397     enable_shared=no
 398     ;;
 399 xnono)
 400     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 401     enable_shared=yes
 402     ;;
 403 esac
 404
 405 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 406
 407 dnl
 408 dnl other compiler options
 409 dnl
 410 AC_ARG_ENABLE([debug],
 411     [AS_HELP_STRING([--enable-debug],
 412         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 413     [enable_debug="$enableval"],
 414     [enable_debug=no]
 415 )
 416 if test "x$enable_debug" = xyes; then
 417     DEFINES="$DEFINES -DDEBUG"
 418     if test "x$GCC" = xyes; then
 419         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 420             CFLAGS="$CFLAGS -g"
 421         fi
 422         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 423             CFLAGS="$CFLAGS -O0"
 424         fi
 425     fi
 426     if test "x$GXX" = xyes; then
 427         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 428             CXXFLAGS="$CXXFLAGS -g"
 429         fi
 430         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 431             CXXFLAGS="$CXXFLAGS -O0"
 432         fi
 433     fi
 434 else
 435    DEFINES="$DEFINES -DNDEBUG"
 436 fi
 437
 438 dnl
 439 dnl Check if linker supports -Bsymbolic
 440 dnl
 441 save_LDFLAGS=$LDFLAGS
 442 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 443 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 444 AC_LINK_IFELSE(
 445     [AC_LANG_SOURCE([int main() { return 0;}])],
 446     [AC_MSG_RESULT([yes])
 447         BSYMBOLIC="-Wl,-Bsymbolic";],
 448     [AC_MSG_RESULT([no])
 449         BSYMBOLIC="";])
 450 LDFLAGS=$save_LDFLAGS
 451
 452 AC_SUBST([BSYMBOLIC])
 453
 454 dnl
 455 dnl Check if linker supports garbage collection
 456 dnl
 457 save_LDFLAGS=$LDFLAGS
 458 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 459 AC_MSG_CHECKING([whether ld supports --gc-sections])
 460 AC_LINK_IFELSE(
 461     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 462     [AC_MSG_RESULT([yes])
 463         GC_SECTIONS="-Wl,--gc-sections";],
 464     [AC_MSG_RESULT([no])
 465         GC_SECTIONS="";])
 466 LDFLAGS=$save_LDFLAGS
 467
 468 AC_SUBST([GC_SECTIONS])
 469
 470 dnl
 471 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 472 dnl so when these flags are passed to ld via libtool the checks will fail
 473 dnl
 474 case "$host_os" in
 475 openbsd* | darwin* )
 476     LD_NO_UNDEFINED="" ;;
 477 *)
 478     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 479 esac
 480
 481 AC_SUBST([LD_NO_UNDEFINED])
 482
 483 dnl
 484 dnl Check if linker supports version scripts
 485 dnl
 486 AC_MSG_CHECKING([if the linker supports version-scripts])
 487 save_LDFLAGS=$LDFLAGS
 488 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 489 cat > conftest.map <<EOF
 490 VERSION_1 {
 491      global:
 492          main;
 493
 494      local:
 495          *;
 496 };
 497 EOF
 498 AC_LINK_IFELSE(
 499     [AC_LANG_SOURCE([int main() { return 0;}])],
 500     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 501     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 502 LDFLAGS=$save_LDFLAGS
 503 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 504
 505 dnl
 506 dnl Check if linker supports dynamic list files
 507 dnl
 508 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 509 save_LDFLAGS=$LDFLAGS
 510 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 511 cat > conftest.dyn <<EOF
 512 {
 513         radeon_drm_winsys_create;
 514 };
 515 EOF
 516 AC_LINK_IFELSE(
 517     [AC_LANG_SOURCE([int main() { return 0;}])],
 518     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 519     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 520 LDFLAGS=$save_LDFLAGS
 521 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 522
 523 dnl
 524 dnl compatibility symlinks
 525 dnl
 526 case "$host_os" in
 527 linux* )
 528     HAVE_COMPAT_SYMLINKS=yes ;;
 529 * )
 530     HAVE_COMPAT_SYMLINKS=no ;;
 531 esac
 532
 533 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 534
 535 dnl
 536 dnl library names
 537 dnl
 538 dnl Unfortunately we need to do a few things that libtool can't help us with,
 539 dnl so we need some knowledge of shared library filenames:
 540 dnl
 541 dnl LIB_EXT is the extension used when creating symlinks for alternate
 542 dnl filenames for a shared library which will be dynamically loaded
 543 dnl
 544 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 545 dnl the file for a shared library we wish to link with
 546 dnl
 547 case "$host_os" in
 548 darwin* )
 549     LIB_EXT='dylib'
 550     IMP_LIB_EXT=$LIB_EXT
 551     ;;
 552 cygwin* )
 553     LIB_EXT='dll'
 554     IMP_LIB_EXT='dll.a'
 555     ;;
 556 aix* )
 557     LIB_EXT='a'
 558     IMP_LIB_EXT=$LIB_EXT
 559     ;;
 560 * )
 561     LIB_EXT='so'
 562     IMP_LIB_EXT=$LIB_EXT
 563     ;;
 564 esac
 565
 566 AC_SUBST([LIB_EXT])
 567
 568 AC_ARG_WITH([gl-lib-name],
 569   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 570     [specify GL library name @<:@default=GL@:>@])],
 571   [GL_LIB=$withval],
 572   [GL_LIB=GL])
 573 AC_ARG_WITH([osmesa-lib-name],
 574   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 575     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 576   [OSMESA_LIB=$withval],
 577   [OSMESA_LIB=OSMesa])
 578 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 579 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 580
 581 dnl
 582 dnl Mangled Mesa support
 583 dnl
 584 AC_ARG_ENABLE([mangling],
 585   [AS_HELP_STRING([--enable-mangling],
 586     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 587   [enable_mangling="${enableval}"],
 588   [enable_mangling=no]
 589 )
 590 if test "x${enable_mangling}" = "xyes" ; then
 591   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 592   GL_LIB="Mangled${GL_LIB}"
 593   OSMESA_LIB="Mangled${OSMESA_LIB}"
 594 fi
 595 AC_SUBST([GL_LIB])
 596 AC_SUBST([OSMESA_LIB])
 597
 598 dnl
 599 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 600 dnl
 601 AC_ARG_ENABLE([texture-float],
 602     [AS_HELP_STRING([--enable-texture-float],
 603         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 604     [enable_texture_float="$enableval"],
 605     [enable_texture_float=no]
 606 )
 607 if test "x$enable_texture_float" = xyes; then
 608     AC_MSG_WARN([Floating-point textures enabled.])
 609     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 610     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 611 fi
 612
 613 dnl
 614 dnl Arch/platform-specific settings
 615 dnl
 616 AC_ARG_ENABLE([asm],
 617     [AS_HELP_STRING([--disable-asm],
 618         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 619     [enable_asm="$enableval"],
 620     [enable_asm=yes]
 621 )
 622 asm_arch=""
 623 AC_MSG_CHECKING([whether to enable assembly])
 624 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 625 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 626 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 627     case "$host_cpu" in
 628     i?86 | x86_64 | amd64)
 629         enable_asm=no
 630         AC_MSG_RESULT([no, cross compiling])
 631         ;;
 632     esac
 633 fi
 634 # check for supported arches
 635 if test "x$enable_asm" = xyes; then
 636     case "$host_cpu" in
 637     i?86)
 638         case "$host_os" in
 639         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 640             asm_arch=x86
 641             ;;
 642         esac
 643         ;;
 644     x86_64|amd64)
 645         case "$host_os" in
 646         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 647             asm_arch=x86_64
 648             ;;
 649         esac
 650         ;;
 651     sparc*)
 652         case "$host_os" in
 653         linux*)
 654             asm_arch=sparc
 655             ;;
 656         esac
 657         ;;
 658     esac
 659
 660     case "$asm_arch" in
 661     x86)
 662         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 663         AC_MSG_RESULT([yes, x86])
 664         ;;
 665     x86_64|amd64)
 666         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 667         AC_MSG_RESULT([yes, x86_64])
 668         ;;
 669     sparc)
 670         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 671         AC_MSG_RESULT([yes, sparc])
 672         ;;
 673     *)
 674         AC_MSG_RESULT([no, platform not supported])
 675         ;;
 676     esac
 677 fi
 678
 679 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 680 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 681 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 682 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 683
 684 dnl Check to see if dlopen is in default libraries (like Solaris, which
 685 dnl has it in libc), or if libdl is needed to get it.
 686 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 687     [AC_CHECK_LIB([dl], [dlopen],
 688        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 689 AC_SUBST([DLOPEN_LIBS])
 690
 691 dnl Check if that library also has dladdr
 692 save_LIBS="$LIBS"
 693 LIBS="$LIBS $DLOPEN_LIBS"
 694 AC_CHECK_FUNCS([dladdr])
 695 LIBS="$save_LIBS"
 696
 697 case "$host_os" in
 698 darwin*)
 699     ;;
 700 *)
 701     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 702                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 703                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 704     AC_SUBST([CLOCK_LIB])
 705     ;;
 706 esac
 707
 708 dnl See if posix_memalign is available
 709 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 710
 711 dnl Check for pthreads
 712 AX_PTHREAD
 713 if test "x$ax_pthread_ok" = xno; then
 714     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 715 fi
 716 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 717 dnl to -pthread, which causes problems if we need -lpthread to appear in
 718 dnl pkgconfig files.
 719 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 720
 721 dnl SELinux awareness.
 722 AC_ARG_ENABLE([selinux],
 723     [AS_HELP_STRING([--enable-selinux],
 724         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 725     [MESA_SELINUX="$enableval"],
 726     [MESA_SELINUX=no])
 727 if test "x$enable_selinux" = "xyes"; then
 728     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 729         [AC_CHECK_HEADER([selinux/selinux.h],[],
 730                          [AC_MSG_ERROR([SELinux headers not found])])
 731          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 732                       [AC_MSG_ERROR([SELinux library not found])])
 733          SELINUX_LIBS="-lselinux"])
 734     DEFINES="$DEFINES -DMESA_SELINUX"
 735 fi
 736 AC_SUBST([SELINUX_CFLAGS])
 737 AC_SUBST([SELINUX_LIBS])
 738
 739 dnl Options for APIs
 740 AC_ARG_ENABLE([opengl],
 741     [AS_HELP_STRING([--disable-opengl],
 742         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 743     [enable_opengl="$enableval"],
 744     [enable_opengl=yes])
 745 AC_ARG_ENABLE([gles1],
 746     [AS_HELP_STRING([--disable-gles1],
 747         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 748     [enable_gles1="$enableval"],
 749     [enable_gles1=yes])
 750 AC_ARG_ENABLE([gles2],
 751     [AS_HELP_STRING([--disable-gles2],
 752         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 753     [enable_gles2="$enableval"],
 754     [enable_gles2=yes])
 755
 756 AC_ARG_ENABLE([dri],
 757     [AS_HELP_STRING([--enable-dri],
 758         [enable DRI modules @<:@default=enabled@:>@])],
 759     [enable_dri="$enableval"],
 760     [enable_dri=yes])
 761
 762 case "$host_os" in
 763 linux*)
 764     dri3_default=yes
 765     ;;
 766 *)
 767     dri3_default=no
 768     ;;
 769 esac
 770 AC_ARG_ENABLE([dri3],
 771     [AS_HELP_STRING([--enable-dri3],
 772         [enable DRI3 @<:@default=auto@:>@])],
 773     [enable_dri3="$enableval"],
 774     [enable_dri3="$dri3_default"])
 775 AC_ARG_ENABLE([glx],
 776     [AS_HELP_STRING([--enable-glx],
 777         [enable GLX library @<:@default=enabled@:>@])],
 778     [enable_glx="$enableval"],
 779     [enable_glx=yes])
 780 AC_ARG_ENABLE([osmesa],
 781     [AS_HELP_STRING([--enable-osmesa],
 782         [enable OSMesa library @<:@default=disabled@:>@])],
 783     [enable_osmesa="$enableval"],
 784     [enable_osmesa=no])
 785 AC_ARG_ENABLE([gallium-osmesa],
 786     [AS_HELP_STRING([--enable-gallium-osmesa],
 787         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 788     [enable_gallium_osmesa="$enableval"],
 789     [enable_gallium_osmesa=no])
 790 AC_ARG_ENABLE([egl],
 791     [AS_HELP_STRING([--disable-egl],
 792         [disable EGL library @<:@default=enabled@:>@])],
 793     [enable_egl="$enableval"],
 794     [enable_egl=yes])
 795
 796 AC_ARG_ENABLE([xa],
 797     [AS_HELP_STRING([--enable-xa],
 798         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 799     [enable_xa="$enableval"],
 800     [enable_xa=no])
 801 AC_ARG_ENABLE([gbm],
 802    [AS_HELP_STRING([--enable-gbm],
 803          [enable gbm library @<:@default=auto@:>@])],
 804    [enable_gbm="$enableval"],
 805    [enable_gbm=auto])
 806 AC_ARG_ENABLE([nine],
 807     [AS_HELP_STRING([--enable-nine],
 808         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 809     [enable_nine="$enableval"],
 810     [enable_nine=no])
 811
 812 AC_ARG_ENABLE([xvmc],
 813    [AS_HELP_STRING([--enable-xvmc],
 814          [enable xvmc library @<:@default=auto@:>@])],
 815    [enable_xvmc="$enableval"],
 816    [enable_xvmc=auto])
 817 AC_ARG_ENABLE([vdpau],
 818    [AS_HELP_STRING([--enable-vdpau],
 819          [enable vdpau library @<:@default=auto@:>@])],
 820    [enable_vdpau="$enableval"],
 821    [enable_vdpau=auto])
 822 AC_ARG_ENABLE([omx],
 823    [AS_HELP_STRING([--enable-omx],
 824          [enable OpenMAX library @<:@default=disabled@:>@])],
 825    [enable_omx="$enableval"],
 826    [enable_omx=no])
 827 AC_ARG_ENABLE([va],
 828    [AS_HELP_STRING([--enable-va],
 829          [enable va library @<:@default=auto@:>@])],
 830    [enable_va="$enableval"],
 831    [enable_va=auto])
 832 AC_ARG_ENABLE([opencl],
 833    [AS_HELP_STRING([--enable-opencl],
 834          [enable OpenCL library @<:@default=disabled@:>@])],
 835    [enable_opencl="$enableval"],
 836    [enable_opencl=no])
 837 AC_ARG_ENABLE([opencl_icd],
 838    [AS_HELP_STRING([--enable-opencl-icd],
 839           [Build an OpenCL ICD library to be loaded by an ICD implementation
 840            @<:@default=disabled@:>@])],
 841     [enable_opencl_icd="$enableval"],
 842     [enable_opencl_icd=no])
 843 AC_ARG_ENABLE([xlib-glx],
 844     [AS_HELP_STRING([--enable-xlib-glx],
 845         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 846     [enable_xlib_glx="$enableval"],
 847     [enable_xlib_glx=no])
 848
 849 AC_ARG_ENABLE([r600-llvm-compiler],
 850     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 851         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 852     [enable_r600_llvm="$enableval"],
 853     [enable_r600_llvm=no])
 854
 855 AC_ARG_ENABLE([gallium-tests],
 856     [AS_HELP_STRING([--enable-gallium-tests],
 857         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 858     [enable_gallium_tests="$enableval"],
 859     [enable_gallium_tests=no])
 860
 861 # Option for Gallium drivers
 862
 863 # Keep this in sync with the --with-gallium-drivers help string default value
 864 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 865
 866 AC_ARG_WITH([gallium-drivers],
 867     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 868         [comma delimited Gallium drivers list, e.g.
 869         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 870         @<:@default=r300,r600,svga,swrast@:>@])],
 871     [with_gallium_drivers="$withval"],
 872     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 873
 874 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 875 # here so that the script doesn't choke on an unknown driver name later.
 876 case "$with_gallium_drivers" in
 877     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 878     no) with_gallium_drivers='' ;;
 879 esac
 880
 881 if test "x$enable_opengl" = xno -a \
 882         "x$enable_gles1" = xno -a \
 883         "x$enable_gles2" = xno -a \
 884         "x$enable_nine" = xno -a \
 885         "x$enable_xa" = xno -a \
 886         "x$enable_xvmc" = xno -a \
 887         "x$enable_vdpau" = xno -a \
 888         "x$enable_omx" = xno -a \
 889         "x$enable_va" = xno -a \
 890         "x$enable_opencl" = xno; then
 891     AC_MSG_ERROR([at least one API should be enabled])
 892 fi
 893
 894 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 895 if test "x$enable_opengl" = xno -a \
 896         "x$enable_gles1" = xyes; then
 897     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 898 fi
 899
 900 if test "x$enable_opengl" = xno -a \
 901         "x$enable_gles2" = xyes; then
 902     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 903 fi
 904
 905 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 906 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 907 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 908 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 909                                         "x$enable_gles1" = xyes -o \
 910                                         "x$enable_gles2" = xyes)
 911
 912 if test "x$enable_glx" = xno; then
 913     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 914     enable_xlib_glx=no
 915 fi
 916
 917 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 918     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 919 fi
 920
 921 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 922     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 923 fi
 924
 925 # Disable GLX if OpenGL is not enabled
 926 if test "x$enable_glx$enable_opengl" = xyesno; then
 927     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 928     enable_glx=no
 929 fi
 930
 931 # Disable GLX if DRI and Xlib-GLX are not enabled
 932 if test "x$enable_glx" = xyes -a \
 933         "x$enable_dri" = xno -a \
 934         "x$enable_xlib_glx" = xno; then
 935     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 936     enable_glx=no
 937 fi
 938
 939 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 940                                   "x$enable_dri" = xyes)
 941
 942 # Check for libdrm
 943 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 944                   [have_libdrm=yes], [have_libdrm=no])
 945 if test "x$have_libdrm" = xyes; then
 946         DEFINES="$DEFINES -DHAVE_LIBDRM"
 947 fi
 948
 949 # Select which platform-dependent DRI code gets built
 950 case "$host_os" in
 951 darwin*)
 952     dri_platform='apple' ;;
 953 gnu*|cygwin*)
 954     dri_platform='none' ;;
 955 *)
 956     dri_platform='drm' ;;
 957 esac
 958
 959 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
 960     have_drisw_kms='yes'
 961 fi
 962
 963 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 964 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 965 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
 966 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 967 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
 968 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 969
 970 AC_ARG_ENABLE([shared-glapi],
 971     [AS_HELP_STRING([--enable-shared-glapi],
 972         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 973     [enable_shared_glapi="$enableval"],
 974     [enable_shared_glapi=yes])
 975
 976 case "x$enable_opengl$enable_gles1$enable_gles2" in
 977 x*yes*yes*)
 978     if test "x$enable_shared_glapi" = xno; then
 979         AC_MSG_ERROR([shared GLAPI required when building two or more of
 980                       the following APIs - opengl, gles1 gles2])
 981     fi
 982     ;;
 983 esac
 984
 985 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 986
 987 # Build the pipe-drivers as separate libraries/modules.
 988 # Do not touch this unless you know what you are doing.
 989 # XXX: Expose via configure option ?
 990 enable_shared_pipe_drivers=no
 991
 992 dnl
 993 dnl Driver specific build directories
 994 dnl
 995
 996 if test -n "$with_gallium_drivers" -a "x$enable_glx$enable_xlib_glx" = xyesyes; then
 997     NEED_WINSYS_XLIB="yes"
 998 fi
 999
1000 if test "x$enable_gallium_osmesa" = xyes; then
1001     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1002         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1003     fi
1004     if test "x$enable_osmesa" = xyes; then
1005         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1006     fi
1007 fi
1008
1009 AC_SUBST([MESA_LLVM])
1010
1011 # SHA1 hashing
1012 AC_ARG_WITH([sha1],
1013         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1014         [choose SHA1 implementation])])
1015 case "x$with_sha1" in
1016 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1017   ;;
1018 *)
1019         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1020 esac
1021
1022 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1023 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1024         with_sha1=libc
1025 fi
1026 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1027         AC_MSG_ERROR([sha1 in libc requested but not found])
1028 fi
1029 if test "x$with_sha1" = xlibc; then
1030         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1031                 [Use libc SHA1 functions])
1032         SHA1_LIBS=""
1033 fi
1034 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1035 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1036         with_sha1=CommonCrypto
1037 fi
1038 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1039         AC_MSG_ERROR([CommonCrypto requested but not found])
1040 fi
1041 if test "x$with_sha1" = xCommonCrypto; then
1042         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1043                 [Use CommonCrypto SHA1 functions])
1044         SHA1_LIBS=""
1045 fi
1046 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1047 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1048 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1049         with_sha1=CryptoAPI
1050 fi
1051 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1052         AC_MSG_ERROR([CryptoAPI requested but not found])
1053 fi
1054 if test "x$with_sha1" = xCryptoAPI; then
1055         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1056                 [Use CryptoAPI SHA1 functions])
1057         SHA1_LIBS=""
1058 fi
1059 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1060 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1061         with_sha1=libmd
1062 fi
1063 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1064         AC_MSG_ERROR([libmd requested but not found])
1065 fi
1066 if test "x$with_sha1" = xlibmd; then
1067         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1068                   [Use libmd SHA1 functions])
1069         SHA1_LIBS=-lmd
1070 fi
1071 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1072 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1073    with_sha1=libsha1
1074 fi
1075 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1076         AC_MSG_ERROR([libsha1 requested but not found])
1077 fi
1078 if test "x$with_sha1" = xlibsha1; then
1079         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1080                   [Use libsha1 for SHA1])
1081         SHA1_LIBS=-lsha1
1082 fi
1083 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1084 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1085         with_sha1=libnettle
1086 fi
1087 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1088         AC_MSG_ERROR([libnettle requested but not found])
1089 fi
1090 if test "x$with_sha1" = xlibnettle; then
1091         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1092                   [Use libnettle SHA1 functions])
1093         SHA1_LIBS=-lnettle
1094 fi
1095 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1096 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1097         with_sha1=libgcrypt
1098 fi
1099 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1100         AC_MSG_ERROR([libgcrypt requested but not found])
1101 fi
1102 if test "x$with_sha1" = xlibgcrypt; then
1103         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1104                   [Use libgcrypt SHA1 functions])
1105         SHA1_LIBS=-lgcrypt
1106 fi
1107 # We don't need all of the OpenSSL libraries, just libcrypto
1108 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1109 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1110                   [HAVE_OPENSSL_PKC=no])
1111 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1112         if test "x$with_sha1" = x; then
1113                 with_sha1=libcrypto
1114         fi
1115 else
1116         if test "x$with_sha1" = xlibcrypto; then
1117                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1118         fi
1119 fi
1120 if test "x$with_sha1" = xlibcrypto; then
1121         if test "x$HAVE_LIBCRYPTO" = xyes; then
1122                 SHA1_LIBS=-lcrypto
1123         else
1124                 SHA1_LIBS="$OPENSSL_LIBS"
1125                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1126         fi
1127 fi
1128 AC_MSG_CHECKING([for SHA1 implementation])
1129 AC_MSG_RESULT([$with_sha1])
1130 AC_SUBST(SHA1_LIBS)
1131 AC_SUBST(SHA1_CFLAGS)
1132
1133 # Enable a define for SHA1
1134 if test "x$with_sha1" != "x"; then
1135         DEFINES="$DEFINES -DHAVE_SHA1"
1136 fi
1137
1138 # Allow user to configure out the shader-cache feature
1139 AC_ARG_ENABLE([shader-cache],
1140     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1141     [enable_shader_cache="$enableval"],
1142     [if test "x$with_sha1" != "x"; then
1143         enable_shader_cache=yes
1144      else
1145         enable_shader_cache=no
1146      fi])
1147 if test "x$with_sha1" = "x"; then
1148     if test "x$enable_shader_cache" = "xyes"; then
1149         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1150     fi
1151 fi
1152 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1153
1154 case "$host_os" in
1155 linux*)
1156     need_pci_id=yes ;;
1157 *)
1158     need_pci_id=no ;;
1159 esac
1160
1161 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1162                   have_libudev=yes, have_libudev=no)
1163
1164 AC_ARG_ENABLE([sysfs],
1165     [AS_HELP_STRING([--enable-sysfs],
1166         [enable /sys PCI identification @<:@default=disabled@:>@])],
1167     [have_sysfs="$enableval"],
1168     [have_sysfs=no]
1169 )
1170
1171 if test "x$enable_dri" = xyes; then
1172     if test "$enable_static" = yes; then
1173         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1174     fi
1175
1176     # not a hard requirement as swrast does not depend on it
1177     if test "x$have_libdrm" = xyes; then
1178         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1179     fi
1180 fi
1181
1182 AC_ARG_ENABLE([driglx-direct],
1183     [AS_HELP_STRING([--disable-driglx-direct],
1184         [disable direct rendering in GLX and EGL for DRI \
1185             @<:@default=auto@:>@])],
1186     [driglx_direct="$enableval"],
1187     [driglx_direct="yes"])
1188
1189 dnl
1190 dnl libGL configuration per driver
1191 dnl
1192 case "x$enable_glx$enable_xlib_glx" in
1193 xyesyes)
1194     # Xlib-based GLX
1195     dri_modules="x11 xext xcb"
1196     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1197     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1198     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1199     GL_LIB_DEPS="$XLIBGL_LIBS"
1200     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1201     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1202     ;;
1203 xyesno)
1204     # DRI-based GLX
1205     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1206
1207     # find the DRI deps for libGL
1208     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1209
1210     if test x"$driglx_direct" = xyes; then
1211         if test x"$dri_platform" = xdrm ; then
1212             DEFINES="$DEFINES -DGLX_USE_DRM"
1213             if test "x$have_libdrm" != xyes; then
1214                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1215             fi
1216
1217             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1218             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1219             if test x"$enable_dri3" = xyes; then
1220                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1221                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1222             fi
1223
1224             if test x"$enable_dri" = xyes; then
1225                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1226             fi
1227
1228             if test x"$enable_dri3" = xyes; then
1229                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1230                dri3_modules="xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1231                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1232             fi
1233         fi
1234         if test x"$dri_platform" = xapple ; then
1235             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1236         fi
1237     fi
1238
1239     # add xf86vidmode if available
1240     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1241     if test "$HAVE_XF86VIDMODE" = yes ; then
1242         dri_modules="$dri_modules xxf86vm"
1243     fi
1244
1245     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1246     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1247     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1248     GL_LIB_DEPS="$DRIGL_LIBS"
1249
1250     # need DRM libs, $PTHREAD_LIBS, etc.
1251     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1252     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1253     ;;
1254 esac
1255
1256 have_pci_id=no
1257 if test "$have_libudev" = yes; then
1258     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1259     have_pci_id=yes
1260 fi
1261
1262 if test "$have_sysfs" = yes; then
1263     DEFINES="$DEFINES -DHAVE_SYSFS"
1264     have_pci_id=yes
1265 fi
1266
1267 # This is outside the case (above) so that it is invoked even for non-GLX
1268 # builds.
1269 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1270
1271 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1272 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1273 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1274 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1275
1276 AC_SUBST([X11_INCLUDES])
1277 AC_SUBST([GL_LIB_DEPS])
1278 AC_SUBST([GL_PC_REQ_PRIV])
1279 AC_SUBST([GL_PC_LIB_PRIV])
1280 AC_SUBST([GL_PC_CFLAGS])
1281 AC_SUBST([DRI_PC_REQ_PRIV])
1282 AC_SUBST([GLESv1_CM_LIB_DEPS])
1283 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1284 AC_SUBST([GLESv2_LIB_DEPS])
1285 AC_SUBST([GLESv2_PC_LIB_PRIV])
1286
1287 AC_SUBST([HAVE_XF86VIDMODE])
1288
1289 dnl
1290 dnl More GLX setup
1291 dnl
1292 case "x$enable_glx$enable_xlib_glx" in
1293 xyesyes)
1294     DEFINES="$DEFINES -DUSE_XSHM"
1295     ;;
1296 xyesno)
1297     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1298     if test "x$driglx_direct" = xyes; then
1299         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1300     fi
1301     ;;
1302 esac
1303
1304 dnl
1305 dnl TLS detection
1306 dnl
1307
1308 AC_ARG_ENABLE([glx-tls],
1309     [AS_HELP_STRING([--enable-glx-tls],
1310         [enable TLS support in GLX @<:@default=disabled@:>@])],
1311     [GLX_USE_TLS="$enableval"],
1312     [GLX_USE_TLS=no])
1313 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1314
1315 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1316       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1317
1318 dnl Read-only text section on x86 hardened platforms
1319 AC_ARG_ENABLE([glx-read-only-text],
1320     [AS_HELP_STRING([--enable-glx-read-only-text],
1321         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1322     [enable_glx_read_only_text="$enableval"],
1323     [enable_glx_read_only_text=no])
1324 if test "x$enable_glx_read_only_text" = xyes; then
1325     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1326 fi
1327
1328 dnl
1329 dnl More DRI setup
1330 dnl
1331 dnl Directory for DRI drivers
1332 AC_ARG_WITH([dri-driverdir],
1333     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1334         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1335     [DRI_DRIVER_INSTALL_DIR="$withval"],
1336     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1337 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1338 dnl Extra search path for DRI drivers
1339 AC_ARG_WITH([dri-searchpath],
1340     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1341         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1342     [DRI_DRIVER_SEARCH_DIR="$withval"],
1343     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1344 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1345 dnl Which drivers to build - default is chosen by platform
1346 AC_ARG_WITH([dri-drivers],
1347     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1348         [comma delimited classic DRI drivers list, e.g.
1349         "swrast,i965,radeon" @<:@default=auto@:>@])],
1350     [with_dri_drivers="$withval"],
1351     [with_dri_drivers=auto])
1352
1353 if test "x$with_dri_drivers" = xauto; then
1354     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1355         with_dri_drivers="yes"
1356     else
1357         with_dri_drivers="no"
1358     fi
1359 fi
1360 if test "x$with_dri_drivers" = xno; then
1361     with_dri_drivers=''
1362 fi
1363
1364 dnl If $with_dri_drivers is yes, drivers will be added through
1365 dnl platform checks. Set DEFINES and LIB_DEPS
1366 if test "x$enable_dri" = xyes; then
1367     # Platform specific settings and drivers to build
1368     case "$host_os" in
1369     linux*)
1370         DEFINES="$DEFINES -DHAVE_ALIAS"
1371         if test "x$enable_dri3" = xyes; then
1372             DEFINES="$DEFINES -DHAVE_DRI3"
1373         fi
1374
1375         if test "x$have_pci_id" != xyes; then
1376             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1377         fi
1378
1379         case "$host_cpu" in
1380         powerpc* | sparc*)
1381             # Build only the drivers for cards that exist on PowerPC/sparc
1382             if test "x$with_dri_drivers" = "xyes"; then
1383                 with_dri_drivers="r200 radeon swrast"
1384             fi
1385             ;;
1386         esac
1387         ;;
1388     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1389         DEFINES="$DEFINES -DHAVE_ALIAS"
1390         ;;
1391     gnu*)
1392         DEFINES="$DEFINES -DHAVE_ALIAS"
1393         ;;
1394     cygwin*)
1395         if test "x$with_dri_drivers" = "xyes"; then
1396             with_dri_drivers="swrast"
1397         fi
1398         ;;
1399     darwin*)
1400         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1401         if test "x$with_dri_drivers" = "xyes"; then
1402             with_dri_drivers="swrast"
1403         fi
1404         ;;
1405     esac
1406
1407     # default drivers
1408     if test "x$with_dri_drivers" = "xyes"; then
1409         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1410     fi
1411
1412     # Check for expat
1413     PKG_CHECK_MODULES([EXPAT], [expat], [],
1414         # expat version 2.0 and earlier do not provide expat.pc
1415         [AC_CHECK_HEADER([expat.h],[],
1416                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1417          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1418                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1419          EXPAT_LIBS="-lexpat"])
1420
1421     # put all the necessary libs together
1422     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1423 fi
1424
1425 AC_SUBST([DRI_LIB_DEPS])
1426
1427 DRI_DIRS=''
1428 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1429 if test -n "$with_dri_drivers"; then
1430     if test "x$enable_opengl" != xyes; then
1431         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1432     fi
1433
1434     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1435     for driver in $dri_drivers; do
1436         DRI_DIRS="$DRI_DIRS $driver"
1437         case "x$driver" in
1438         xi915)
1439             HAVE_I915_DRI=yes;
1440             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1441             ;;
1442         xi965)
1443             HAVE_I965_DRI=yes;
1444             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1445             ;;
1446         xnouveau)
1447             HAVE_NOUVEAU_DRI=yes;
1448             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1449             ;;
1450         xradeon)
1451             HAVE_RADEON_DRI=yes;
1452             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1453             ;;
1454         xr200)
1455             HAVE_R200_DRI=yes;
1456             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1457             ;;
1458         xswrast)
1459             HAVE_SWRAST_DRI=yes;
1460             ;;
1461         *)
1462             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1463             ;;
1464         esac
1465     done
1466     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1467 fi
1468
1469 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1470 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1471                                   "x$enable_osmesa" = xyes -o \
1472                                   -n "$DRI_DIRS")
1473
1474 dnl
1475 dnl OSMesa configuration
1476 dnl
1477
1478 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1479 AC_ARG_WITH([osmesa-bits],
1480     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1481         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1482     [osmesa_bits="$withval"],
1483     [osmesa_bits=8])
1484 if test "x$osmesa_bits" != x8; then
1485     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1486         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1487         osmesa_bits=8
1488     fi
1489 fi
1490 case "x$osmesa_bits" in
1491 x8)
1492     OSMESA_LIB="${OSMESA_LIB}"
1493     ;;
1494 x16|x32)
1495     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1496     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1497     ;;
1498 *)
1499     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1500     ;;
1501 esac
1502
1503 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1504     # only link libraries with osmesa if shared
1505     if test "$enable_static" = no; then
1506         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1507     else
1508         OSMESA_LIB_DEPS=""
1509     fi
1510     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1511 fi
1512
1513 AC_SUBST([OSMESA_LIB_DEPS])
1514 AC_SUBST([OSMESA_PC_REQ])
1515 AC_SUBST([OSMESA_PC_LIB_PRIV])
1516
1517 dnl
1518 dnl gbm configuration
1519 dnl
1520 if test "x$enable_gbm" = xauto; then
1521     case "$with_egl_platforms" in
1522         *drm*)
1523             enable_gbm=yes ;;
1524          *)
1525             enable_gbm=no ;;
1526     esac
1527 fi
1528 if test "x$enable_gbm" = xyes; then
1529     if test "x$need_pci_id$have_pci_id" = xyesno; then
1530         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1531     fi
1532
1533     if test "x$enable_dri" = xyes; then
1534         if test "x$enable_shared_glapi" = xno; then
1535             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1536         fi
1537     else
1538         # Strictly speaking libgbm does not require --enable-dri, although
1539         # both of its backends do. Thus one can build libgbm without any
1540         # backends if --disable-dri is set.
1541         # To avoid unnecessary complexity of checking if at least one backend
1542         # is available when building, just mandate --enable-dri.
1543         AC_MSG_ERROR([gbm requires --enable-dri])
1544     fi
1545 fi
1546 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1547 if test "x$need_pci_id$have_libudev" = xyesyes; then
1548     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1549 else
1550     GBM_PC_REQ_PRIV=""
1551 fi
1552 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1553 AC_SUBST([GBM_PC_REQ_PRIV])
1554 AC_SUBST([GBM_PC_LIB_PRIV])
1555
1556 dnl
1557 dnl EGL configuration
1558 dnl
1559 EGL_CLIENT_APIS=""
1560
1561 if test "x$enable_egl" = xyes; then
1562     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1563
1564     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1565
1566     if test "$enable_static" != yes; then
1567         if test "x$enable_dri" = xyes; then
1568             HAVE_EGL_DRIVER_DRI2=1
1569             if test "x$enable_shared_glapi" = xno; then
1570                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1571             fi
1572             if test "x$enable_dri3" = xyes; then
1573                 HAVE_EGL_DRIVER_DRI3=1
1574                 if test "x$enable_shared_glapi" = xno; then
1575                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1576                 fi
1577             fi
1578         else
1579             # Avoid building an "empty" libEGL. Drop/update this
1580             # when other backends (haiku?) come along.
1581             AC_MSG_ERROR([egl requires --enable-dri])
1582         fi
1583
1584     fi
1585 fi
1586 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1587 AC_SUBST([EGL_LIB_DEPS])
1588
1589 gallium_st="mesa"
1590
1591 dnl
1592 dnl XA configuration
1593 dnl
1594 if test "x$enable_xa" = xyes; then
1595     if test "x$with_gallium_drivers" = xswrast; then
1596        AC_MSG_ERROR([
1597           Building xa requires at least one non swrast gallium driver.
1598           If you are looking to use libxatracker.so with the VMware driver,
1599           make sure to include svga in the gallium drivers list, apart from
1600           enabling XA.
1601           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1602     fi
1603     gallium_st="$gallium_st xa"
1604 fi
1605 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1606
1607 dnl
1608 dnl Gallium G3DVL configuration
1609 dnl
1610 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1611     if test "x$enable_xvmc" = xauto; then
1612         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1613     fi
1614
1615     if test "x$enable_vdpau" = xauto; then
1616         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1617     fi
1618
1619     if test "x$enable_omx" = xauto; then
1620         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1621     fi
1622
1623     if test "x$enable_va" = xauto; then
1624         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1625     fi
1626 fi
1627
1628 if test "x$enable_dri" = xyes -o \
1629         "x$enable_xvmc" = xyes -o \
1630         "x$enable_vdpau" = xyes -o \
1631         "x$enable_omx" = xyes -o \
1632         "x$enable_va" = xyes; then
1633     need_gallium_vl=yes
1634 fi
1635 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1636
1637 if test "x$enable_xvmc" = xyes -o \
1638         "x$enable_vdpau" = xyes -o \
1639         "x$enable_omx" = xyes -o \
1640         "x$enable_va" = xyes; then
1641     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1642     need_gallium_vl_winsys=yes
1643 fi
1644 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1645
1646 if test "x$enable_xvmc" = xyes; then
1647     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1648     gallium_st="$gallium_st xvmc"
1649 fi
1650 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1651
1652 if test "x$enable_vdpau" = xyes; then
1653     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1654     gallium_st="$gallium_st vdpau"
1655 fi
1656 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1657
1658 if test "x$enable_omx" = xyes; then
1659     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1660     gallium_st="$gallium_st omx"
1661 fi
1662 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1663
1664 if test "x$enable_va" = xyes; then
1665     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1666     gallium_st="$gallium_st va"
1667 fi
1668 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1669
1670 dnl
1671 dnl Nine Direct3D9 configuration
1672 dnl
1673 if test "x$enable_nine" = xyes; then
1674     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1675         AC_MSG_ERROR([nine requires the gallium swrast driver])
1676     fi
1677     if test "x$with_gallium_drivers" = xswrast; then
1678         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1679     fi
1680     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1681         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1682     fi
1683
1684     if test "x$enable_dri3" = xno; then
1685         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1686     fi
1687
1688     gallium_st="$gallium_st nine"
1689 fi
1690 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1691
1692 dnl
1693 dnl OpenCL configuration
1694 dnl
1695
1696 AC_ARG_WITH([clang-libdir],
1697    [AS_HELP_STRING([--with-clang-libdir],
1698          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1699    [CLANG_LIBDIR="$withval"],
1700    [CLANG_LIBDIR=''])
1701
1702 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1703 AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;ELF_LIB=-lelf])
1704
1705 if test "x$enable_opencl" = xyes; then
1706     if test -z "$with_gallium_drivers"; then
1707         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1708     fi
1709
1710     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1711         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1712     fi
1713
1714     if test "x$have_libclc" = xno; then
1715         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1716                     Make sure the directory containing libclc.pc is specified in your
1717                     PKG_CONFIG_PATH environment variable.
1718                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1719     else
1720         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1721         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1722         AC_SUBST([LIBCLC_INCLUDEDIR])
1723         AC_SUBST([LIBCLC_LIBEXECDIR])
1724     fi
1725
1726     gallium_st="$gallium_st clover"
1727
1728     if test "x$enable_opencl_icd" = xyes; then
1729         OPENCL_LIBNAME="MesaOpenCL"
1730     else
1731         OPENCL_LIBNAME="OpenCL"
1732     fi
1733
1734     if test "x$have_libelf" != xyes; then
1735        AC_MSG_ERROR([Clover requires libelf])
1736     fi
1737 fi
1738 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1739 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1740 AC_SUBST([OPENCL_LIBNAME])
1741
1742 dnl
1743 dnl Gallium configuration
1744 dnl
1745 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1746
1747 AC_SUBST([LLVM_BINDIR])
1748 AC_SUBST([LLVM_CFLAGS])
1749 AC_SUBST([LLVM_CPPFLAGS])
1750 AC_SUBST([LLVM_CXXFLAGS])
1751 AC_SUBST([LLVM_LIBDIR])
1752 AC_SUBST([LLVM_LIBS])
1753 AC_SUBST([LLVM_LDFLAGS])
1754 AC_SUBST([LLVM_INCLUDEDIR])
1755 AC_SUBST([LLVM_VERSION])
1756 AC_SUBST([CLANG_RESOURCE_DIR])
1757
1758 case "x$enable_opengl$enable_gles1$enable_gles2" in
1759 x*yes*)
1760     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1761     ;;
1762 esac
1763
1764 AC_SUBST([VG_LIB_DEPS])
1765 AC_SUBST([EGL_CLIENT_APIS])
1766
1767 dnl
1768 dnl EGL Platforms configuration
1769 dnl
1770 AC_ARG_WITH([egl-platforms],
1771     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1772         [comma delimited native platforms libEGL supports, e.g.
1773         "x11,drm" @<:@default=auto@:>@])],
1774     [with_egl_platforms="$withval"],
1775     [if test "x$enable_egl" = xyes; then
1776         with_egl_platforms="x11"
1777     else
1778         with_egl_platforms=""
1779     fi])
1780
1781 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1782     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1783 fi
1784
1785 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
1786         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
1787         WAYLAND_SCANNER='')
1788 if test "x$WAYLAND_SCANNER" = x; then
1789     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
1790 fi
1791
1792 # Do per-EGL platform setups and checks
1793 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1794 for plat in $egl_platforms; do
1795         case "$plat" in
1796         wayland)
1797                 test "x$have_libdrm" != xyes &&
1798                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
1799
1800                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1801
1802                 if test "x$WAYLAND_SCANNER" = x; then
1803                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
1804                 fi
1805                 ;;
1806
1807         x11)
1808                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1809                 ;;
1810
1811         drm)
1812                 test "x$enable_gbm" = "xno" &&
1813                         AC_MSG_ERROR([EGL platform drm needs gbm])
1814                 test "x$have_libdrm" != xyes &&
1815                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1816                 ;;
1817
1818         surfaceless)
1819                 test "x$have_libdrm" != xyes &&
1820                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
1821                 ;;
1822
1823         *)
1824                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1825                 ;;
1826         esac
1827
1828         case "$plat$need_pci_id$have_pci_id" in
1829                 waylandyesno|drmyesno)
1830                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1831         esac
1832 done
1833
1834 # libEGL wants to default to the first platform specified in
1835 # ./configure.  parse that here.
1836 if test "x$egl_platforms" != "x"; then
1837     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
1838     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1839 else
1840     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1841 fi
1842
1843 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1844 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1845 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1846 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
1847 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1848
1849 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1850
1851 AC_SUBST([EGL_NATIVE_PLATFORM])
1852 AC_SUBST([EGL_CFLAGS])
1853
1854 # If we don't have the X11 platform, set this define so we don't try to include
1855 # the X11 headers.
1856 if ! echo "$egl_platforms" | grep -q 'x11'; then
1857     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1858     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1859 fi
1860
1861 dnl
1862 dnl Gallium LLVM
1863 dnl
1864 AC_ARG_ENABLE([gallium-llvm],
1865     [AS_HELP_STRING([--enable-gallium-llvm],
1866         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1867     [enable_gallium_llvm="$enableval"],
1868     [enable_gallium_llvm=auto])
1869
1870 AC_ARG_ENABLE([llvm-shared-libs],
1871     [AS_HELP_STRING([--enable-llvm-shared-libs],
1872         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1873     [enable_llvm_shared_libs="$enableval"],
1874     [enable_llvm_shared_libs=yes])
1875
1876 AC_ARG_WITH([llvm-prefix],
1877     [AS_HELP_STRING([--with-llvm-prefix],
1878         [Prefix for LLVM installations in non-standard locations])],
1879     [llvm_prefix="$withval"],
1880     [llvm_prefix=''])
1881
1882
1883 # Call this inside ` ` to get the return value.
1884 # $1 is the llvm-config command with arguments.
1885 strip_unwanted_llvm_flags() {
1886     # Use \> (marks the end of the word)
1887     echo `$1` | sed \
1888         -e 's/-DNDEBUG\>//g' \
1889         -e 's/-D_GNU_SOURCE\>//g' \
1890         -e 's/-pedantic\>//g' \
1891         -e 's/-Wcovered-switch-default\>//g' \
1892         -e 's/-O.\>//g' \
1893         -e 's/-g\>//g' \
1894         -e 's/-Wall\>//g' \
1895         -e 's/-Wcast-qual\>//g' \
1896         -e 's/-Woverloaded-virtual\>//g' \
1897         -e 's/-fcolor-diagnostics\>//g' \
1898         -e 's/-fdata-sections\>//g' \
1899         -e 's/-ffunction-sections\>//g' \
1900         -e 's/-fno-exceptions\>//g' \
1901         -e 's/-fomit-frame-pointer\>//g' \
1902         -e 's/-fvisibility-inlines-hidden\>//g' \
1903         -e 's/-fPIC\>//g' \
1904         -e 's/-fstack-protector-strong\>//g'
1905 }
1906
1907 llvm_check_version_for() {
1908     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
1909         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
1910     fi
1911 }
1912
1913
1914
1915 if test -z "$with_gallium_drivers"; then
1916     enable_gallium_llvm=no
1917 fi
1918 if test "x$enable_gallium_llvm" = xauto; then
1919     case "$host_cpu" in
1920     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1921     esac
1922 fi
1923 if test "x$enable_gallium_llvm" = xyes; then
1924     if test -n "$llvm_prefix"; then
1925         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1926     else
1927         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1928     fi
1929
1930     if test "x$LLVM_CONFIG" != xno; then
1931         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1932         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1933         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1934         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1935         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1936         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1937         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1938         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1939
1940         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1941             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1942         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1943             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1944
1945         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1946         if test -z "$LLVM_VERSION_PATCH"; then
1947             LLVM_VERSION_PATCH=0
1948         fi
1949
1950         if test -n "${LLVM_VERSION_MAJOR}"; then
1951             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1952         else
1953             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1954         fi
1955
1956         LLVM_REQUIRED_VERSION_MAJOR="3"
1957         LLVM_REQUIRED_VERSION_MINOR="3"
1958         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1959             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1960         fi
1961
1962         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
1963
1964         if test "x$enable_opencl" = xyes; then
1965             llvm_check_version_for "3" "5" "0" "opencl"
1966
1967             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
1968             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
1969         fi
1970         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1971         MESA_LLVM=1
1972
1973         dnl Check for Clang internal headers
1974         if test "x$enable_opencl" = xyes; then
1975             if test -z "$CLANG_LIBDIR"; then
1976                 CLANG_LIBDIR=${LLVM_LIBDIR}
1977             fi
1978             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1979             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1980                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1981         fi
1982     else
1983         MESA_LLVM=0
1984         LLVM_VERSION_INT=0
1985     fi
1986 else
1987     MESA_LLVM=0
1988     LLVM_VERSION_INT=0
1989
1990     if test "x$enable_opencl" = xyes; then
1991         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1992     fi
1993 fi
1994
1995 dnl Directory for XVMC libs
1996 AC_ARG_WITH([xvmc-libdir],
1997     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1998         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1999     [XVMC_LIB_INSTALL_DIR="$withval"],
2000     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2001 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2002
2003 dnl
2004 dnl Gallium Tests
2005 dnl
2006 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2007
2008 dnl Directory for VDPAU libs
2009 AC_ARG_WITH([vdpau-libdir],
2010     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2011         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2012     [VDPAU_LIB_INSTALL_DIR="$withval"],
2013     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2014 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2015
2016 dnl Directory for OMX libs
2017
2018 AC_ARG_WITH([omx-libdir],
2019     [AS_HELP_STRING([--with-omx-libdir=DIR],
2020         [directory for the OMX libraries])],
2021     [OMX_LIB_INSTALL_DIR="$withval"],
2022     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2023 AC_SUBST([OMX_LIB_INSTALL_DIR])
2024
2025 dnl Directory for VA libs
2026
2027 AC_ARG_WITH([va-libdir],
2028     [AS_HELP_STRING([--with-va-libdir=DIR],
2029         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2030     [VA_LIB_INSTALL_DIR="$withval"],
2031     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2032 AC_SUBST([VA_LIB_INSTALL_DIR])
2033
2034 AC_ARG_WITH([d3d-libdir],
2035     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2036         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2037     [D3D_DRIVER_INSTALL_DIR="$withval"],
2038     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2039 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2040
2041 dnl
2042 dnl Gallium helper functions
2043 dnl
2044 gallium_require_drm() {
2045     if test "x$have_libdrm" != xyes; then
2046        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2047     fi
2048 }
2049
2050 gallium_require_llvm() {
2051     if test "x$MESA_LLVM" = x0; then
2052         case "$host" in *gnux32) return;; esac
2053         case "$host_cpu" in
2054         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2055         esac
2056     fi
2057 }
2058
2059 gallium_require_drm_loader() {
2060     if test "x$need_pci_id$have_pci_id" = xyesno; then
2061         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2062     fi
2063 }
2064
2065 require_egl_drm() {
2066     case "$with_egl_platforms" in
2067         *drm*)
2068             ;;
2069          *)
2070             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2071             ;;
2072     esac
2073     if test "x$enable_gbm" != xyes; then
2074             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2075     fi
2076 }
2077
2078 radeon_llvm_check() {
2079     if test ${LLVM_VERSION_INT} -lt 307; then
2080         amdgpu_llvm_target_name='r600'
2081     else
2082         amdgpu_llvm_target_name='amdgpu'
2083     fi
2084     if test "x$enable_gallium_llvm" != "xyes"; then
2085         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2086     fi
2087     llvm_check_version_for "3" "5" "0" $1
2088     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2089         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2090     fi
2091     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2092     NEED_RADEON_LLVM=yes
2093     if test "x$have_libelf" != xyes; then
2094        AC_MSG_ERROR([$1 requires libelf when using llvm])
2095     fi
2096 }
2097
2098 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2099 if test -n "$with_gallium_drivers"; then
2100     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2101     for driver in $gallium_drivers; do
2102         case "x$driver" in
2103         xsvga)
2104             HAVE_GALLIUM_SVGA=yes
2105             gallium_require_drm "svga"
2106             gallium_require_drm_loader
2107             ;;
2108         xi915)
2109             HAVE_GALLIUM_I915=yes
2110             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2111             gallium_require_drm "Gallium i915"
2112             gallium_require_drm_loader
2113             ;;
2114         xilo)
2115             HAVE_GALLIUM_ILO=yes
2116             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2117             gallium_require_drm "Gallium i965/ilo"
2118             gallium_require_drm_loader
2119             ;;
2120         xr300)
2121             HAVE_GALLIUM_R300=yes
2122             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2123             gallium_require_drm "Gallium R300"
2124             gallium_require_drm_loader
2125             gallium_require_llvm "Gallium R300"
2126             ;;
2127         xr600)
2128             HAVE_GALLIUM_R600=yes
2129             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2130             gallium_require_drm "Gallium R600"
2131             gallium_require_drm_loader
2132             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2133                 radeon_llvm_check "r600g"
2134                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2135             fi
2136             if test "x$enable_r600_llvm" = xyes; then
2137                 USE_R600_LLVM_COMPILER=yes;
2138             fi
2139             if test "x$enable_opencl" = xyes; then
2140                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2141             fi
2142             ;;
2143         xradeonsi)
2144             HAVE_GALLIUM_RADEONSI=yes
2145             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2146             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2147             gallium_require_drm "radeonsi"
2148             gallium_require_drm_loader
2149             radeon_llvm_check "radeonsi"
2150             require_egl_drm "radeonsi"
2151             ;;
2152         xnouveau)
2153             HAVE_GALLIUM_NOUVEAU=yes
2154             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2155             gallium_require_drm "nouveau"
2156             gallium_require_drm_loader
2157             ;;
2158         xfreedreno)
2159             HAVE_GALLIUM_FREEDRENO=yes
2160             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2161             gallium_require_drm "freedreno"
2162             gallium_require_drm_loader
2163             ;;
2164         xswrast)
2165             HAVE_GALLIUM_SOFTPIPE=yes
2166             if test "x$MESA_LLVM" = x1; then
2167                 HAVE_GALLIUM_LLVMPIPE=yes
2168             fi
2169             ;;
2170         xvc4)
2171             HAVE_GALLIUM_VC4=yes
2172             gallium_require_drm "vc4"
2173             gallium_require_drm_loader
2174
2175             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2176                               [USE_VC4_SIMULATOR=yes], [USE_VC4_SIMULATOR=no])
2177             ;;
2178         xvirgl)
2179             HAVE_GALLIUM_VIRGL=yes
2180             gallium_require_drm "virgl"
2181             gallium_require_drm_loader
2182             require_egl_drm "virgl"
2183             ;;
2184         *)
2185             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2186             ;;
2187         esac
2188     done
2189 fi
2190
2191 dnl Set LLVM_LIBS - This is done after the driver configuration so
2192 dnl that drivers can add additional components to LLVM_COMPONENTS.
2193 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2194 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2195 dnl this was causing the same libraries to be appear multiple times
2196 dnl in LLVM_LIBS.
2197
2198 if test "x$MESA_LLVM" != x0; then
2199
2200     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2201
2202     dnl llvm-config may not give the right answer when llvm is a built as a
2203     dnl single shared library, so we must work the library name out for
2204     dnl ourselves.
2205     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2206     if test "x$enable_llvm_shared_libs" = xyes; then
2207         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2208         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2209         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2210
2211         if test "x$llvm_have_one_so" = xyes; then
2212             dnl LLVM was built using auto*, so there is only one shared object.
2213             LLVM_LIBS="-l$LLVM_SO_NAME"
2214         else
2215             dnl If LLVM was built with CMake, there will be one shared object per
2216             dnl component.
2217             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2218                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2219         Please make sure you have built llvm with the --enable-shared option
2220         and that your llvm libraries are installed in $LLVM_LIBDIR
2221         If you have installed your llvm libraries to a different directory you
2222         can use the --with-llvm-prefix= configure flag to specify this directory.
2223         NOTE: Mesa is attempting to use llvm shared libraries by default.
2224         If you do not want to build with llvm shared libraries and instead want to
2225         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2226         invocation and rebuild.])])
2227
2228            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2229            dnl install uses a shared object for each component and we have
2230            dnl already added all of these objects to LLVM_LIBS.
2231         fi
2232     else
2233         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2234         dnl We need to link to llvm system libs when using static libs
2235         dnl However, only llvm 3.5+ provides --system-libs
2236         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2237             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2238         fi
2239     fi
2240 fi
2241
2242 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2243 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2244 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2245 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2246 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2247 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2248 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2249                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2250 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2251 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2252 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2253 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2254 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2255 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2256
2257 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2258
2259 if test "x$enable_dri" = xyes; then
2260     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2261 fi
2262
2263 if test "x$have_drisw_kms" = xyes; then
2264     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2265 fi
2266 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2267
2268 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2269 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2270 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2271 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2272 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2273 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2274
2275 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2276                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2277                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2278 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2279 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2280 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2281 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2282 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2283 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2284 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2285     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2286 fi
2287
2288 AC_SUBST([ELF_LIB])
2289
2290 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2291 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2292 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2293 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2294
2295 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2296 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2297 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2298
2299 AC_SUBST([NINE_MAJOR], 1)
2300 AC_SUBST([NINE_MINOR], 0)
2301 AC_SUBST([NINE_TINY], 0)
2302 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2303
2304 AC_SUBST([VDPAU_MAJOR], 1)
2305 AC_SUBST([VDPAU_MINOR], 0)
2306
2307 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2308 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2309 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2310 AC_SUBST([VA_MINOR], $VA_MINOR)
2311
2312 AC_SUBST([XVMC_MAJOR], 1)
2313 AC_SUBST([XVMC_MINOR], 0)
2314
2315 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2316 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2317 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2318 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2319
2320 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2321 AC_SUBST([XA_MINOR], $XA_MINOR)
2322 AC_SUBST([XA_TINY], $XA_TINY)
2323 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2324
2325 dnl Restore LDFLAGS and CPPFLAGS
2326 LDFLAGS="$_SAVE_LDFLAGS"
2327 CPPFLAGS="$_SAVE_CPPFLAGS"
2328
2329 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2330 if test "x$acv_mesa_CLANG" = xyes; then
2331     CFLAGS="$CFLAGS -Qunused-arguments"
2332     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2333 fi
2334
2335 dnl Add user CFLAGS and CXXFLAGS
2336 CFLAGS="$CFLAGS $USER_CFLAGS"
2337 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2338
2339 dnl Substitute the config
2340 AC_CONFIG_FILES([Makefile
2341                 src/Makefile
2342                 src/egl/Makefile
2343                 src/egl/main/egl.pc
2344                 src/egl/wayland/wayland-drm/Makefile
2345                 src/egl/wayland/wayland-egl/Makefile
2346                 src/egl/wayland/wayland-egl/wayland-egl.pc
2347                 src/gallium/Makefile
2348                 src/gallium/auxiliary/Makefile
2349                 src/gallium/auxiliary/pipe-loader/Makefile
2350                 src/gallium/drivers/freedreno/Makefile
2351                 src/gallium/drivers/ddebug/Makefile
2352                 src/gallium/drivers/i915/Makefile
2353                 src/gallium/drivers/ilo/Makefile
2354                 src/gallium/drivers/llvmpipe/Makefile
2355                 src/gallium/drivers/noop/Makefile
2356                 src/gallium/drivers/nouveau/Makefile
2357                 src/gallium/drivers/r300/Makefile
2358                 src/gallium/drivers/r600/Makefile
2359                 src/gallium/drivers/radeon/Makefile
2360                 src/gallium/drivers/radeonsi/Makefile
2361                 src/gallium/drivers/rbug/Makefile
2362                 src/gallium/drivers/softpipe/Makefile
2363                 src/gallium/drivers/svga/Makefile
2364                 src/gallium/drivers/trace/Makefile
2365                 src/gallium/drivers/vc4/Makefile
2366                 src/gallium/drivers/virgl/Makefile
2367                 src/gallium/state_trackers/clover/Makefile
2368                 src/gallium/state_trackers/dri/Makefile
2369                 src/gallium/state_trackers/glx/xlib/Makefile
2370                 src/gallium/state_trackers/nine/Makefile
2371                 src/gallium/state_trackers/omx/Makefile
2372                 src/gallium/state_trackers/osmesa/Makefile
2373                 src/gallium/state_trackers/va/Makefile
2374                 src/gallium/state_trackers/vdpau/Makefile
2375                 src/gallium/state_trackers/xa/Makefile
2376                 src/gallium/state_trackers/xvmc/Makefile
2377                 src/gallium/targets/d3dadapter9/Makefile
2378                 src/gallium/targets/d3dadapter9/d3d.pc
2379                 src/gallium/targets/dri/Makefile
2380                 src/gallium/targets/libgl-xlib/Makefile
2381                 src/gallium/targets/omx/Makefile
2382                 src/gallium/targets/opencl/Makefile
2383                 src/gallium/targets/opencl/mesa.icd
2384                 src/gallium/targets/osmesa/Makefile
2385                 src/gallium/targets/osmesa/osmesa.pc
2386                 src/gallium/targets/pipe-loader/Makefile
2387                 src/gallium/targets/va/Makefile
2388                 src/gallium/targets/vdpau/Makefile
2389                 src/gallium/targets/xa/Makefile
2390                 src/gallium/targets/xa/xatracker.pc
2391                 src/gallium/targets/xvmc/Makefile
2392                 src/gallium/tests/trivial/Makefile
2393                 src/gallium/tests/unit/Makefile
2394                 src/gallium/winsys/freedreno/drm/Makefile
2395                 src/gallium/winsys/i915/drm/Makefile
2396                 src/gallium/winsys/intel/drm/Makefile
2397                 src/gallium/winsys/nouveau/drm/Makefile
2398                 src/gallium/winsys/radeon/drm/Makefile
2399                 src/gallium/winsys/amdgpu/drm/Makefile
2400                 src/gallium/winsys/svga/drm/Makefile
2401                 src/gallium/winsys/sw/dri/Makefile
2402                 src/gallium/winsys/sw/kms-dri/Makefile
2403                 src/gallium/winsys/sw/null/Makefile
2404                 src/gallium/winsys/sw/wrapper/Makefile
2405                 src/gallium/winsys/sw/xlib/Makefile
2406                 src/gallium/winsys/vc4/drm/Makefile
2407                 src/gallium/winsys/virgl/drm/Makefile
2408                 src/gallium/winsys/virgl/vtest/Makefile
2409                 src/gbm/Makefile
2410                 src/gbm/main/gbm.pc
2411                 src/glsl/Makefile
2412                 src/glx/Makefile
2413                 src/glx/apple/Makefile
2414                 src/glx/tests/Makefile
2415                 src/gtest/Makefile
2416                 src/loader/Makefile
2417                 src/mapi/Makefile
2418                 src/mapi/es1api/glesv1_cm.pc
2419                 src/mapi/es2api/glesv2.pc
2420                 src/mapi/glapi/gen/Makefile
2421                 src/mesa/Makefile
2422                 src/mesa/gl.pc
2423                 src/mesa/drivers/dri/dri.pc
2424                 src/mesa/drivers/dri/common/Makefile
2425                 src/mesa/drivers/dri/common/xmlpool/Makefile
2426                 src/mesa/drivers/dri/i915/Makefile
2427                 src/mesa/drivers/dri/i965/Makefile
2428                 src/mesa/drivers/dri/Makefile
2429                 src/mesa/drivers/dri/nouveau/Makefile
2430                 src/mesa/drivers/dri/r200/Makefile
2431                 src/mesa/drivers/dri/radeon/Makefile
2432                 src/mesa/drivers/dri/swrast/Makefile
2433                 src/mesa/drivers/osmesa/Makefile
2434                 src/mesa/drivers/osmesa/osmesa.pc
2435                 src/mesa/drivers/x11/Makefile
2436                 src/mesa/main/tests/Makefile
2437                 src/util/Makefile
2438                 src/util/tests/hash_table/Makefile])
2439
2440 AC_OUTPUT
2441
2442 dnl
2443 dnl Output some configuration info for the user
2444 dnl
2445 echo ""
2446 echo "        prefix:          $prefix"
2447 echo "        exec_prefix:     $exec_prefix"
2448 echo "        libdir:          $libdir"
2449 echo "        includedir:      $includedir"
2450
2451 dnl API info
2452 echo ""
2453 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2454
2455 dnl Driver info
2456 echo ""
2457 case "x$enable_osmesa$enable_gallium_osmesa" in
2458 xnoyes)
2459         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2460         ;;
2461 xyesno)
2462         echo "        OSMesa:          lib$OSMESA_LIB"
2463         ;;
2464 xnono)
2465         echo "        OSMesa:          no"
2466         ;;
2467 esac
2468
2469 echo ""
2470 if test "x$enable_dri" != xno; then
2471         echo "        DRI platform:    $dri_platform"
2472         if test -z "$DRI_DIRS"; then
2473             echo "        DRI drivers:     no"
2474         else
2475             echo "        DRI drivers:     $DRI_DIRS"
2476         fi
2477         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2478 fi
2479
2480 case "x$enable_glx$enable_xlib_glx" in
2481 xyesyes)
2482     echo "        GLX:             Xlib-based"
2483     ;;
2484 xyesno)
2485     echo "        GLX:             DRI-based"
2486     ;;
2487 *)
2488     echo "        GLX:             $enable_glx"
2489     ;;
2490 esac
2491
2492 dnl EGL
2493 echo ""
2494 echo "        EGL:             $enable_egl"
2495 if test "$enable_egl" = yes; then
2496     echo "        EGL platforms:   $egl_platforms"
2497
2498     egl_drivers=""
2499     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2500         egl_drivers="$egl_drivers builtin:egl_dri2"
2501     fi
2502     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2503         egl_drivers="$egl_drivers builtin:egl_dri3"
2504     fi
2505
2506     echo "        EGL drivers:    $egl_drivers"
2507 fi
2508
2509 echo ""
2510 if test "x$MESA_LLVM" = x1; then
2511     echo "        llvm:            yes"
2512     echo "        llvm-config:     $LLVM_CONFIG"
2513     echo "        llvm-version:    $LLVM_VERSION"
2514 else
2515     echo "        llvm:            no"
2516 fi
2517
2518 echo ""
2519 if test -n "$with_gallium_drivers"; then
2520     echo "        Gallium drivers: $gallium_drivers"
2521     echo "        Gallium st:      $gallium_st"
2522 else
2523     echo "        Gallium:         no"
2524 fi
2525
2526 dnl Shader cache
2527 echo ""
2528 echo "        Shader cache:    $enable_shader_cache"
2529 if test "x$enable_shader_cache" = "xyes"; then
2530     echo "        With SHA1 from:  $with_sha1"
2531 fi
2532
2533 dnl Libraries
2534 echo ""
2535 echo "        Shared libs:     $enable_shared"
2536 echo "        Static libs:     $enable_static"
2537 echo "        Shared-glapi:    $enable_shared_glapi"
2538
2539 dnl Compiler options
2540 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2541 cflags=`echo $CFLAGS | \
2542     $SED 's/^ *//;s/  */ /;s/ *$//'`
2543 cxxflags=`echo $CXXFLAGS | \
2544     $SED 's/^ *//;s/  */ /;s/ *$//'`
2545 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2546 echo ""
2547 echo "        CFLAGS:          $cflags"
2548 echo "        CXXFLAGS:        $cxxflags"
2549 echo "        Macros:          $defines"
2550 echo ""
2551 if test "x$MESA_LLVM" = x1; then
2552     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2553     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2554     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2555     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2556     echo ""
2557 fi
2558 echo "        PYTHON2:         $PYTHON2"
2559
2560 echo ""
2561 echo "        Run '${MAKE-make}' to build Mesa"
2562 echo ""