configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.3.1
  22 DRI2PROTO_REQUIRED=1.1
  23
  24 dnl Check for progs
  25 AC_PROG_CPP
  26 AC_PROG_CC
  27 AC_PROG_CXX
  28 AC_CHECK_PROGS([MAKE], [gmake make])
  29 AC_PATH_PROG([MKDEP], [makedepend])
  30 AC_PATH_PROG([SED], [sed])
  31
  32 MKDEP_OPTIONS=-fdepend
  33 dnl Ask gcc where it's keeping its secret headers
  34 if test "x$GCC" = xyes; then
  35     GCC_INCLUDES=`$CC -print-file-name=include`
  36     if test "x$GCC_INCLUDES" != x; then
  37         MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  38     fi
  39 fi
  40 AC_SUBST([MKDEP_OPTIONS])
  41
  42 dnl Check to see if dlopen is in default libraries (like Solaris, which
  43 dnl has it in libc), or if libdl is needed to get it.
  44 AC_CHECK_FUNC([dlopen], [],
  45         [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
  46
  47 dnl Make sure the pkg-config macros are defined
  48 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  49     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  50        These are usually located in /usr/share/aclocal/pkg.m4. If your
  51        macros are in a different location, try setting the environment
  52        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  53        autoreconf.
  54 ])
  55     m4_exit([1])
  56 ])
  57 PKG_PROG_PKG_CONFIG()
  58
  59 dnl LIB_DIR - library basename
  60 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  61 AC_SUBST([LIB_DIR])
  62
  63 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  64 _SAVE_LDFLAGS="$LDFLAGS"
  65 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  66 AC_SUBST([EXTRA_LIB_PATH])
  67
  68 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  69 _SAVE_CPPFLAGS="$CPPFLAGS"
  70 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  71 AC_SUBST([X11_INCLUDES])
  72
  73 dnl Compiler macros
  74 DEFINES=""
  75 AC_SUBST([DEFINES])
  76 case "$host_os" in
  77 linux*)
  78 if test "x$GCC" = xyes; then
  79     DEFINES="$DEFINES -D_POSIX_SOURCE -D_POSIX_C_SOURCE=199309L -D_BSD_SOURCE"
  80 fi
  81     DEFINES="$DEFINES -D_SVID_SOURCE -D_GNU_SOURCE -DPTHREADS -DHAVE_POSIX_MEMALIGN"
  82     ;;
  83 esac
  84
  85 dnl Add flags for gcc and g++
  86 if test "x$GCC" = xyes; then
  87     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
  88
  89     # Work around aliasing bugs - developers should comment this out
  90     CFLAGS="$CFLAGS -fno-strict-aliasing"
  91 fi
  92 if test "x$GXX" = xyes; then
  93     CXXFLAGS="$CXXFLAGS -Wall"
  94
  95     # Work around aliasing bugs - developers should comment this out
  96     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
  97 fi
  98
  99 dnl These should be unnecessary, but let the user set them if they want
 100 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 101     Default is to use CFLAGS.])
 102 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 103     compiler. Default is to use CFLAGS.])
 104 AC_SUBST([OPT_FLAGS])
 105 AC_SUBST([ARCH_FLAGS])
 106
 107 dnl
 108 dnl Hacks to enable 32 or 64 bit build
 109 dnl
 110 AC_ARG_ENABLE([32-bit],
 111     [AS_HELP_STRING([--enable-32-bit],
 112         [build 32-bit libraries @<:@default=auto@:>@])],
 113     [enable_32bit="$enableval"],
 114     [enable_32bit=auto]
 115 )
 116 if test "x$enable_32bit" = xyes; then
 117     if test "x$GCC" = xyes; then
 118         CFLAGS="$CFLAGS -m32"
 119     fi
 120     if test "x$GXX" = xyes; then
 121         CXXFLAGS="$CXXFLAGS -m32"
 122     fi
 123 fi
 124 AC_ARG_ENABLE([64-bit],
 125     [AS_HELP_STRING([--enable-64-bit],
 126         [build 64-bit libraries @<:@default=auto@:>@])],
 127     [enable_64bit="$enableval"],
 128     [enable_64bit=auto]
 129 )
 130 if test "x$enable_64bit" = xyes; then
 131     if test "x$GCC" = xyes; then
 132         CFLAGS="$CFLAGS -m64"
 133     fi
 134     if test "x$GXX" = xyes; then
 135         CXXFLAGS="$CXXFLAGS -m64"
 136     fi
 137 fi
 138
 139 dnl
 140 dnl shared/static libraries, mimic libtool options
 141 dnl
 142 AC_ARG_ENABLE([static],
 143     [AS_HELP_STRING([--enable-static],
 144         [build static libraries @<:@default=disabled@:>@])],
 145     [enable_static="$enableval"],
 146     [enable_static=no]
 147 )
 148 case "x$enable_static" in
 149 xyes|xno ) ;;
 150 x ) enable_static=no ;;
 151 * )
 152     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 153     ;;
 154 esac
 155 AC_ARG_ENABLE([shared],
 156     [AS_HELP_STRING([--disable-shared],
 157         [build shared libraries @<:@default=enabled@:>@])],
 158     [enable_shared="$enableval"],
 159     [enable_shared=yes]
 160 )
 161 case "x$enable_shared" in
 162 xyes|xno ) ;;
 163 x ) enable_shared=yes ;;
 164 * )
 165     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 166     ;;
 167 esac
 168
 169 dnl Can't have static and shared libraries, default to static if user
 170 dnl explicitly requested. If both disabled, set to static since shared
 171 dnl was explicitly requirested.
 172 case "x$enable_static$enable_shared" in
 173 xyesyes )
 174     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 175     enable_shared=no
 176     ;;
 177 xnono )
 178     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 179     enable_static=yes
 180     ;;
 181 esac
 182
 183 dnl
 184 dnl mklib options
 185 dnl
 186 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 187 if test "$enable_static" = yes; then
 188     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 189 fi
 190 AC_SUBST([MKLIB_OPTIONS])
 191
 192 dnl
 193 dnl other compiler options
 194 dnl
 195 AC_ARG_ENABLE([debug],
 196     [AS_HELP_STRING([--enable-debug],
 197         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 198     [enable_debug="$enableval"],
 199     [enable_debug=no]
 200 )
 201 if test "x$enable_debug" = xyes; then
 202     DEFINES="$DEFINES -DDEBUG"
 203     if test "x$GCC" = xyes; then
 204         CFLAGS="$CFLAGS -g"
 205     fi
 206     if test "x$GXX" = xyes; then
 207         CXXFLAGS="$CXXFLAGS -g"
 208     fi
 209 fi
 210
 211 dnl
 212 dnl library names
 213 dnl
 214 if test "$enable_static" = yes; then
 215     GL_LIB_NAME='lib$(GL_LIB).a'
 216     GLU_LIB_NAME='lib$(GLU_LIB).a'
 217     GLUT_LIB_NAME='lib$(GLUT_LIB).a'
 218     GLW_LIB_NAME='lib$(GLW_LIB).a'
 219     OSMESA_LIB_NAME='lib$(OSMESA_LIB).a'
 220 else
 221     GL_LIB_NAME='lib$(GL_LIB).so'
 222     GLU_LIB_NAME='lib$(GLU_LIB).so'
 223     GLUT_LIB_NAME='lib$(GLUT_LIB).so'
 224     GLW_LIB_NAME='lib$(GLW_LIB).so'
 225     OSMESA_LIB_NAME='lib$(OSMESA_LIB).so'
 226 fi
 227 AC_SUBST([GL_LIB_NAME])
 228 AC_SUBST([GLU_LIB_NAME])
 229 AC_SUBST([GLUT_LIB_NAME])
 230 AC_SUBST([GLW_LIB_NAME])
 231 AC_SUBST([OSMESA_LIB_NAME])
 232
 233 dnl
 234 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 235 dnl More later: directfb, fbdev, ...
 236 dnl
 237 default_driver="xlib"
 238
 239 case "$host_os" in
 240 linux*)
 241     case "$host_cpu" in
 242     i*86|x86_64|powerpc*) default_driver="dri";;
 243     esac
 244     ;;
 245 freebsd* | dragonfly*)
 246     case "$host_cpu" in
 247     i*86|x86_64) default_driver="dri";;
 248     esac
 249     ;;
 250 esac
 251
 252 AC_ARG_WITH([driver],
 253     [AS_HELP_STRING([--with-driver=DRIVER],
 254         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 255     [mesa_driver="$withval"],
 256     [mesa_driver="$default_driver"])
 257 dnl Check for valid option
 258 case "x$mesa_driver" in
 259 xxlib|xdri|xosmesa)
 260     ;;
 261 *)
 262     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 263     ;;
 264 esac
 265
 266 dnl
 267 dnl Driver specific build directories
 268 dnl
 269 SRC_DIRS="mesa"
 270 GLU_DIRS="sgi"
 271 WINDOW_SYSTEM=""
 272 case "$mesa_driver" in
 273 xlib)
 274     DRIVER_DIRS="x11"
 275     ;;
 276 dri)
 277     SRC_DIRS="glx/x11 $SRC_DIRS"
 278     DRIVER_DIRS="dri"
 279     WINDOW_SYSTEM="dri"
 280     ;;
 281 osmesa)
 282     DRIVER_DIRS="osmesa"
 283     ;;
 284 esac
 285 AC_SUBST([SRC_DIRS])
 286 AC_SUBST([GLU_DIRS])
 287 AC_SUBST([DRIVER_DIRS])
 288 AC_SUBST([WINDOW_SYSTEM])
 289
 290 dnl
 291 dnl User supplied program configuration
 292 dnl
 293 if test -d "$srcdir/progs/demos"; then
 294     default_demos=yes
 295 else
 296     default_demos=no
 297 fi
 298 AC_ARG_WITH([demos],
 299     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 300         [optional comma delimited demo directories to build
 301         @<:@default=auto if source available@:>@])],
 302     [with_demos="$withval"],
 303     [with_demos="$default_demos"])
 304 if test "x$with_demos" = x; then
 305     with_demos=no
 306 fi
 307
 308 dnl If $with_demos is yes, directories will be added as libs available
 309 PROGRAM_DIRS=""
 310 case "$with_demos" in
 311 no) ;;
 312 yes)
 313     # If the driver isn't osmesa, we have libGL and can build xdemos
 314     if test "$mesa_driver" != osmesa; then
 315         PROGRAM_DIRS="xdemos"
 316     fi
 317     ;;
 318 *)
 319     # verify the requested demos directories exist
 320     demos=`IFS=,; echo $with_demos`
 321     for demo in $demos; do
 322         test -d "$srcdir/progs/$demo" || \
 323             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 324     done
 325     PROGRAM_DIRS="$demos"
 326     ;;
 327 esac
 328
 329 dnl
 330 dnl Find out if X is available. The variable have_x is set if libX11 is
 331 dnl to mimic AC_PATH_XTRA.
 332 dnl
 333 if test -n "$PKG_CONFIG"; then
 334     AC_MSG_CHECKING([pkg-config files for X11 are available])
 335     PKG_CHECK_EXISTS([x11],[
 336         x11_pkgconfig=yes
 337         have_x=yes
 338         ],[
 339         x11_pkgconfig=no
 340     ])
 341     AC_MSG_RESULT([$x11_pkgconfig])
 342 else
 343     x11_pkgconfig=no
 344 fi
 345 dnl Use the autoconf macro if no pkg-config files
 346 if test "$x11_pkgconfig" = no; then
 347     AC_PATH_XTRA
 348 fi
 349
 350 dnl We need X for xlib and dri, so bomb now if it's not found
 351 case "$mesa_driver" in
 352 xlib|dri)
 353     if test "$no_x" = yes; then
 354         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 355     fi
 356     ;;
 357 esac
 358
 359 dnl XCB - this is only used for GLX right now
 360 AC_ARG_ENABLE([xcb],
 361     [AS_HELP_STRING([--enable-xcb],
 362         [use XCB for GLX @<:@default=disabled@:>@])],
 363     [enable_xcb="$enableval"],
 364     [enable_xcb=no])
 365 if test "x$enable_xcb" = xyes; then
 366     DEFINES="$DEFINES -DUSE_XCB"
 367 else
 368     enable_xcb=no
 369 fi
 370
 371 # SELinux awareness.
 372 AC_ARG_ENABLE([selinux],
 373     [AS_HELP_STRING([--enable-selinux],
 374         [Build SELinux-aware Mesa (default: disabled)])],
 375     [MESA_SELINUX="$enableval"],
 376     [MESA_SELINUX=no])
 377 if test "x$enable_selinux" = "xyes"; then
 378     AC_CHECK_HEADER([selinux/selinux.h],[],
 379                     [AC_MSG_ERROR([SELinux headers not found])])
 380     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 381                  [AC_MSG_ERROR([SELinux library not found])])
 382     SELINUX_LIBS="-lselinux"
 383     DEFINES="$DEFINES -DMESA_SELINUX"
 384 fi
 385
 386 dnl
 387 dnl libGL configuration per driver
 388 dnl
 389 case "$mesa_driver" in
 390 xlib)
 391     if test "$x11_pkgconfig" = yes; then
 392         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 393         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 394         GL_LIB_DEPS="$XLIBGL_LIBS"
 395     else
 396         # should check these...
 397         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 398         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 399     fi
 400     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 401
 402     # if static, move the external libraries to the programs
 403     # and empty the libraries for libGL
 404     if test "$enable_static" = yes; then
 405         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 406         GL_LIB_DEPS=""
 407     fi
 408     ;;
 409 dri)
 410     # DRI must be shared, I think
 411     if test "$enable_static" = yes; then
 412         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 413     fi
 414
 415     # Check for libdrm
 416     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 417     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 418
 419     # find the DRI deps for libGL
 420     if test "$x11_pkgconfig" = yes; then
 421         # add xcb modules if necessary
 422         dri_modules="x11 xext xxf86vm xdamage xfixes"
 423         if test "$enable_xcb" = yes; then
 424             dri_modules="$dri_modules x11-xcb xcb-glx"
 425         fi
 426
 427         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 428         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 429         GL_LIB_DEPS="$DRIGL_LIBS"
 430     else
 431         # should check these...
 432         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 433         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 434
 435         # XCB can only be used from pkg-config
 436         if test "$enable_xcb" = yes; then
 437             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 438             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 439             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 440         fi
 441     fi
 442
 443     # need DRM libs, -lpthread, etc.
 444     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 445     ;;
 446 osmesa)
 447     # No libGL for osmesa
 448     GL_LIB_DEPS=""
 449     ;;
 450 esac
 451 AC_SUBST([GL_LIB_DEPS])
 452
 453 dnl
 454 dnl More X11 setup
 455 dnl
 456 if test "$mesa_driver" = xlib; then
 457     DEFINES="$DEFINES -DUSE_XSHM"
 458 fi
 459
 460 dnl
 461 dnl More DRI setup
 462 dnl
 463 AC_ARG_ENABLE([glx-tls],
 464     [AS_HELP_STRING([--enable-glx-tls],
 465         [enable TLS support in GLX @<:@default=disabled@:>@])],
 466     [GLX_USE_TLS="$enableval"],
 467     [GLX_USE_TLS=no])
 468 dnl Directory for DRI drivers
 469 AC_ARG_WITH([dri-driverdir],
 470     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 471         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 472     [DRI_DRIVER_INSTALL_DIR="$withval"],
 473     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 474 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 475 dnl Direct rendering or just indirect rendering
 476 AC_ARG_ENABLE([driglx-direct],
 477     [AS_HELP_STRING([--disable-driglx-direct],
 478         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 479     [driglx_direct="$enableval"],
 480     [driglx_direct="yes"])
 481
 482 dnl Which drivers to build - default is chosen by platform
 483 AC_ARG_WITH([dri-drivers],
 484     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 485         [comma delimited DRI drivers, e.g. "i965,radeon,nouveau" @<:@default=auto@:>@])],
 486     [with_dri_drivers="$withval"],
 487     [with_dri_drivers=yes])
 488 if test "x$with_dri_drivers" = x; then
 489     with_dri_drivers=no
 490 fi
 491
 492 dnl If $with_dri_drivers is yes, directories will be added through
 493 dnl platform checks
 494 DRI_DIRS=""
 495 case "$with_dri_drivers" in
 496 no|yes) ;;
 497 *)
 498     # verify the requested driver directories exist
 499     dri_drivers=`IFS=,; echo $with_dri_drivers`
 500     for driver in $dri_drivers; do
 501         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 502             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 503     done
 504     DRI_DIRS="$dri_drivers"
 505     ;;
 506 esac
 507
 508 dnl Just default to no EGL for now
 509 USING_EGL=0
 510 AC_SUBST([USING_EGL])
 511
 512 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 513 if test "$mesa_driver" = dri; then
 514     # Use TLS in GLX?
 515     if test "x$GLX_USE_TLS" = xyes; then
 516         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 517     fi
 518
 519     if test "x$USING_EGL" = x1; then
 520         PROGRAM_DIRS="egl"
 521     fi
 522
 523     # Platform specific settings and drivers to build
 524     case "$host_os" in
 525     linux*)
 526         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 527         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 528         if test "x$driglx_direct" = xyes; then
 529             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 530         fi
 531
 532         case "$host_cpu" in
 533         x86_64)
 534             # ffb, gamma, and sis are missing because they have not be
 535             # converted to use the new interface.  i810 are missing
 536             # because there is no x86-64 system where they could *ever*
 537             # be used.
 538             if test "x$DRI_DIRS" = x; then
 539                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 540                     savage tdfx unichrome swrast"
 541             fi
 542             ;;
 543         powerpc*)
 544             # Build only the drivers for cards that exist on PowerPC.
 545             # At some point MGA will be added, but not yet.
 546             if test "x$DRI_DIRS" = x; then
 547                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 548             fi
 549             ;;
 550         esac
 551         ;;
 552     freebsd* | dragonfly*)
 553         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 554         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 555         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 556         if test "x$driglx_direct" = xyes; then
 557             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 558         fi
 559         if test "x$GXX" = xyes; then
 560             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 561         fi
 562
 563         # ffb and gamma are missing because they have not been converted
 564         # to use the new interface.
 565         if test "x$DRI_DIRS" = x; then
 566             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 567                 unichrome savage sis swrast"
 568         fi
 569         ;;
 570     esac
 571
 572     # default drivers
 573     if test "x$DRI_DIRS" = x; then
 574         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 575             savage sis tdfx trident unichrome ffb swrast"
 576     fi
 577
 578     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 579
 580     # Check for expat
 581     EXPAT_INCLUDES=""
 582     EXPAT_LIB=-lexpat
 583     AC_ARG_WITH([expat],
 584         [AS_HELP_STRING([--with-expat=DIR],
 585             [expat install directory])],[
 586         EXPAT_INCLUDES="-I$withval/include"
 587         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 588         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 589         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 590         ])
 591     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 592     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 593         [AC_MSG_ERROR([Expat required for DRI.])])
 594
 595     # put all the necessary libs together
 596     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 597 fi
 598 AC_SUBST([DRI_DIRS])
 599 AC_SUBST([EXPAT_INCLUDES])
 600 AC_SUBST([DRI_LIB_DEPS])
 601
 602 dnl
 603 dnl OSMesa configuration
 604 dnl
 605 if test "$mesa_driver" = xlib; then
 606     default_gl_osmesa=yes
 607 else
 608     default_gl_osmesa=no
 609 fi
 610 AC_ARG_ENABLE([gl-osmesa],
 611     [AS_HELP_STRING([--enable-gl-osmesa],
 612         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 613     [gl_osmesa="$enableval"],
 614     [gl_osmesa="$default_gl_osmesa"])
 615 if test "x$gl_osmesa" = xyes; then
 616     if test "$mesa_driver" = osmesa; then
 617         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 618     else
 619         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 620     fi
 621 fi
 622
 623 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 624 AC_ARG_WITH([osmesa-bits],
 625     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 626         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 627     [osmesa_bits="$withval"],
 628     [osmesa_bits=8])
 629 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 630     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 631     osmesa_bits=8
 632 fi
 633 case "x$osmesa_bits" in
 634 x8)
 635     OSMESA_LIB=OSMesa
 636     ;;
 637 x16|x32)
 638     OSMESA_LIB="OSMesa$osmesa_bits"
 639     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 640     ;;
 641 *)
 642     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 643     ;;
 644 esac
 645 AC_SUBST([OSMESA_LIB])
 646
 647 case "$mesa_driver" in
 648 osmesa)
 649     # only link librararies with osmesa if shared
 650     if test "$enable_static" = no; then
 651         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 652     else
 653         OSMESA_LIB_DEPS=""
 654     fi
 655     OSMESA_MESA_DEPS=""
 656     ;;
 657 *)
 658     # Link OSMesa to libGL otherwise
 659     OSMESA_LIB_DEPS=""
 660     # only link librararies with osmesa if shared
 661     if test "$enable_static" = no; then
 662         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 663     else
 664         OSMESA_MESA_DEPS=""
 665     fi
 666     ;;
 667 esac
 668 AC_SUBST([OSMESA_LIB_DEPS])
 669 AC_SUBST([OSMESA_MESA_DEPS])
 670
 671 dnl
 672 dnl GLU configuration
 673 dnl
 674 AC_ARG_ENABLE([glu],
 675     [AS_HELP_STRING([--disable-glu],
 676         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 677     [enable_glu="$enableval"],
 678     [enable_glu=yes])
 679 if test "x$enable_glu" = xyes; then
 680     SRC_DIRS="$SRC_DIRS glu"
 681
 682     case "$mesa_driver" in
 683     osmesa)
 684         # If GLU is available and we have libOSMesa (not 16 or 32),
 685         # we can build the osdemos
 686         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 687             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 688         fi
 689
 690         # Link libGLU to libOSMesa instead of libGL
 691         GLU_LIB_DEPS=""
 692         if test "$enable_static" = no; then
 693             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 694         else
 695             GLU_MESA_DEPS=""
 696         fi
 697         ;;
 698     *)
 699         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 700         if test "$enable_static" = no; then
 701             GLU_LIB_DEPS="-lm"
 702             GLU_MESA_DEPS='-l$(GL_LIB)'
 703         else
 704             GLU_LIB_DEPS=""
 705             GLU_MESA_DEPS=""
 706             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 707         fi
 708         ;;
 709     esac
 710 fi
 711 AC_SUBST([GLU_LIB_DEPS])
 712 AC_SUBST([GLU_MESA_DEPS])
 713
 714 dnl
 715 dnl GLw configuration
 716 dnl
 717 AC_ARG_ENABLE([glw],
 718     [AS_HELP_STRING([--disable-glw],
 719         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 720     [enable_glw="$enableval"],
 721     [enable_glw=yes])
 722 dnl Don't build GLw on osmesa
 723 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 724     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 725     enable_glw=no
 726 fi
 727 if test "x$enable_glw" = xyes; then
 728     SRC_DIRS="$SRC_DIRS glw"
 729     if test "$x11_pkgconfig" = yes; then
 730         PKG_CHECK_MODULES([GLW],[x11 xt])
 731         GLW_LIB_DEPS="$GLW_LIBS"
 732     else
 733         # should check these...
 734         GLW_LIB_DEPS="$X_LIBS -lX11 -lXt"
 735     fi
 736
 737     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 738     if test "$enable_static" = no; then
 739         GLW_MESA_DEPS='-l$(GL_LIB)'
 740     else
 741         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 742         GLW_LIB_DEPS=""
 743         GLW_MESA_DEPS=""
 744     fi
 745 fi
 746 AC_SUBST([GLW_LIB_DEPS])
 747 AC_SUBST([GLW_MESA_DEPS])
 748
 749 dnl
 750 dnl GLUT configuration
 751 dnl
 752 if test -f "$srcdir/include/GL/glut.h"; then
 753     default_glut=yes
 754 else
 755     default_glut=no
 756 fi
 757 AC_ARG_ENABLE([glut],
 758     [AS_HELP_STRING([--disable-glut],
 759         [enable GLUT library @<:@default=enabled if source available@:>@])],
 760     [enable_glut="$enableval"],
 761     [enable_glut="$default_glut"])
 762
 763 dnl Can't build glut if GLU not available
 764 if test "x$enable_glu$enable_glut" = xnoyes; then
 765     AC_MSG_WARN([Disabling glut since GLU is disabled])
 766     enable_glut=no
 767 fi
 768 dnl Don't build glut on osmesa
 769 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
 770     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
 771     enable_glut=no
 772 fi
 773
 774 if test "x$enable_glut" = xyes; then
 775     SRC_DIRS="$SRC_DIRS glut/glx"
 776     GLUT_CFLAGS=""
 777     if test "x$GCC" = xyes; then
 778         GLUT_CFLAGS="-fexceptions"
 779     fi
 780     if test "$x11_pkgconfig" = yes; then
 781         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
 782         GLUT_LIB_DEPS="$GLUT_LIBS"
 783     else
 784         # should check these...
 785         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
 786     fi
 787     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
 788
 789     # If glut is available, we can build most programs
 790     if test "$with_demos" = yes; then
 791         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
 792     fi
 793
 794     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
 795     if test "$enable_static" = no; then
 796         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
 797     else
 798         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
 799         GLUT_LIB_DEPS=""
 800         GLUT_MESA_DEPS=""
 801     fi
 802 fi
 803 AC_SUBST([GLUT_LIB_DEPS])
 804 AC_SUBST([GLUT_MESA_DEPS])
 805 AC_SUBST([GLUT_CFLAGS])
 806
 807 dnl
 808 dnl Program library dependencies
 809 dnl    Only libm is added here if necessary as the libraries should
 810 dnl    be pulled in by the linker
 811 dnl
 812 if test "x$APP_LIB_DEPS" = x; then
 813     APP_LIB_DEPS="-lm"
 814 fi
 815 AC_SUBST([APP_LIB_DEPS])
 816 AC_SUBST([PROGRAM_DIRS])
 817
 818 dnl
 819 dnl Arch/platform-specific settings
 820 dnl
 821 AC_ARG_ENABLE([asm],
 822     [AS_HELP_STRING([--disable-asm],
 823         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 824     [enable_asm="$enableval"],
 825     [enable_asm=yes]
 826 )
 827 asm_arch=""
 828 ASM_FLAGS=""
 829 ASM_SOURCES=""
 830 ASM_API=""
 831 AC_MSG_CHECKING([whether to enable assembly])
 832 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 833 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 834 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 835     case "$host_cpu" in
 836     i?86 | x86_64)
 837         enable_asm=no
 838         AC_MSG_RESULT([no, cross compiling])
 839         ;;
 840     esac
 841 fi
 842 # check for supported arches
 843 if test "x$enable_asm" = xyes; then
 844     case "$host_cpu" in
 845     i?86)
 846         case "$host_os" in
 847         linux* | freebsd* | dragonfly*)
 848             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 849             ;;
 850         esac
 851         ;;
 852     x86_64)
 853         case "$host_os" in
 854         linux* | freebsd* | dragonfly*)
 855             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 856             ;;
 857         esac
 858         ;;
 859     powerpc)
 860         case "$host_os" in
 861         linux*)
 862             asm_arch=ppc
 863             ;;
 864         esac
 865         ;;
 866     esac
 867
 868     case "$asm_arch" in
 869     x86)
 870         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 871         ASM_SOURCES='$(X86_SOURCES)'
 872         ASM_API='$(X86_API)'
 873         AC_MSG_RESULT([yes, x86])
 874         ;;
 875     x86_64)
 876         ASM_FLAGS="-DUSE_X86_64_ASM"
 877         ASM_SOURCES='$(X86-64_SOURCES)'
 878         ASM_API='$(X86-64_API)'
 879         AC_MSG_RESULT([yes, x86_64])
 880         ;;
 881     ppc)
 882         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 883         ASM_SOURCES='$(PPC_SOURCES)'
 884         AC_MSG_RESULT([yes, ppc])
 885         ;;
 886     *)
 887         AC_MSG_RESULT([no, platform not supported])
 888         ;;
 889     esac
 890 fi
 891 AC_SUBST([ASM_FLAGS])
 892 AC_SUBST([ASM_SOURCES])
 893 AC_SUBST([ASM_API])
 894
 895 dnl PIC code macro
 896 MESA_PIC_FLAGS
 897
 898
 899 dnl Restore LDFLAGS and CPPFLAGS
 900 LDFLAGS="$_SAVE_LDFLAGS"
 901 CPPFLAGS="$_SAVE_CPPFLAGS"
 902
 903 dnl Substitute the config
 904 AC_CONFIG_FILES([configs/autoconf])
 905
 906 dnl Replace the configs/current symlink
 907 AC_CONFIG_COMMANDS([configs],[
 908 if test -f configs/current || test -L configs/current; then
 909     rm -f configs/current
 910 fi
 911 ln -s autoconf configs/current
 912 ])
 913
 914 AC_OUTPUT
 915
 916 dnl
 917 dnl Output some configuration info for the user
 918 dnl
 919 echo ""
 920 echo "        prefix:          $prefix"
 921 echo "        exec_prefix:     $exec_prefix"
 922 echo "        libdir:          $libdir"
 923
 924 dnl Driver info
 925 echo ""
 926 echo "        Driver:          $mesa_driver"
 927 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
 928     echo "        OSMesa:          lib$OSMESA_LIB"
 929 else
 930     echo "        OSMesa:          no"
 931 fi
 932 if test "$mesa_driver" = dri; then
 933     # cleanup the drivers var
 934     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
 935     echo "        DRI drivers:     $dri_dirs"
 936     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
 937 fi
 938
 939 dnl Libraries
 940 echo ""
 941 echo "        Shared libs:     $enable_shared"
 942 echo "        Static libs:     $enable_static"
 943 echo "        GLU:             $enable_glu"
 944 echo "        GLw:             $enable_glw"
 945 echo "        glut:            $enable_glut"
 946
 947 dnl Programs
 948 # cleanup the programs var for display
 949 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
 950 if test "x$program_dirs" = x; then
 951     echo "        Demos:           no"
 952 else
 953     echo "        Demos:           $program_dirs"
 954 fi
 955
 956 dnl Compiler options
 957 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
 958 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
 959     $SED 's/^ *//;s/  */ /;s/ *$//'`
 960 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
 961     $SED 's/^ *//;s/  */ /;s/ *$//'`
 962 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
 963 echo ""
 964 echo "        CFLAGS:          $cflags"
 965 echo "        CXXFLAGS:        $cxxflags"
 966 echo "        Macros:          $defines"
 967
 968 echo ""
 969 echo "        Run '${MAKE-make}' to build Mesa"
 970 echo ""