configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.66
  76 LIBDRM_RADEON_REQUIRED=2.4.56
  77 LIBDRM_AMDGPU_REQUIRED=2.4.63
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.6
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XSHMFENCE_REQUIRED=1.1
  98 XVMC_REQUIRED=1.0.6
  99 PYTHON_MAKO_REQUIRED=0.8.0
 100 LIBSENSORS_REQUIRED=4.0.0
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.6.0
 106 LLVM_REQUIRED_RADEONSI=3.6.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.6.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127 AC_CHECK_PROG(XXD, xxd, [xxd])
 128
 129 AX_PROG_BISON([],
 130               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 131                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 132 AX_PROG_FLEX([],
 133              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 134                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 135
 136 AC_CHECK_PROG(INDENT, indent, indent, cat)
 137 if test "x$INDENT" != "xcat"; then
 138     # Only GNU indent is supported
 139     INDENT_VERSION=`indent --version | grep GNU`
 140     if test $? -eq 0; then
 141        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 142     else
 143        INDENT="cat"
 144     fi
 145 fi
 146
 147 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 148
 149 if test -z "$PYTHON2"; then
 150     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 151         AC_MSG_ERROR([Python not found - unable to generate sources])
 152     fi
 153 else
 154     if test "x$acv_mako_found" = xno; then
 155         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 156             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 157         fi
 158     fi
 159 fi
 160
 161 AC_PROG_INSTALL
 162
 163 dnl We need a POSIX shell for parts of the build. Assume we have one
 164 dnl in most cases.
 165 case "$host_os" in
 166 solaris*)
 167     # Solaris /bin/sh is too old/non-POSIX compliant
 168     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 169     SHELL="$POSIX_SHELL"
 170     ;;
 171 esac
 172
 173 dnl clang is mostly GCC-compatible, but its version is much lower,
 174 dnl so we have to check for it.
 175 AC_MSG_CHECKING([if compiling with clang])
 176
 177 AC_COMPILE_IFELSE(
 178 [AC_LANG_PROGRAM([], [[
 179 #ifndef __clang__
 180        not clang
 181 #endif
 182 ]])],
 183 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 184
 185 AC_MSG_RESULT([$acv_mesa_CLANG])
 186
 187 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 188 dnl versions are explictly not supported.
 189 GEN_ASM_OFFSETS=no
 190 USE_GNU99=no
 191 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 192     AC_MSG_CHECKING([whether gcc version is sufficient])
 193     major=0
 194     minor=0
 195
 196     GCC_VERSION=`$CC -dumpversion`
 197     if test $? -eq 0; then
 198         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 199         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 200     fi
 201
 202     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 203         AC_MSG_RESULT([no])
 204         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 205     else
 206         AC_MSG_RESULT([yes])
 207     fi
 208
 209     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 210         USE_GNU99=yes
 211     fi
 212     if test "x$cross_compiling" = xyes; then
 213         GEN_ASM_OFFSETS=yes
 214     fi
 215 fi
 216
 217 dnl We don't support building Mesa with Sun C compiler
 218 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 219 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 220 if test "x$SUNCC" = xyes; then
 221     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 222 fi
 223
 224 dnl Check for compiler builtins
 225 AX_GCC_BUILTIN([__builtin_bswap32])
 226 AX_GCC_BUILTIN([__builtin_bswap64])
 227 AX_GCC_BUILTIN([__builtin_clz])
 228 AX_GCC_BUILTIN([__builtin_clzll])
 229 AX_GCC_BUILTIN([__builtin_ctz])
 230 AX_GCC_BUILTIN([__builtin_expect])
 231 AX_GCC_BUILTIN([__builtin_ffs])
 232 AX_GCC_BUILTIN([__builtin_ffsll])
 233 AX_GCC_BUILTIN([__builtin_popcount])
 234 AX_GCC_BUILTIN([__builtin_popcountll])
 235 AX_GCC_BUILTIN([__builtin_unreachable])
 236
 237 AX_GCC_FUNC_ATTRIBUTE([const])
 238 AX_GCC_FUNC_ATTRIBUTE([flatten])
 239 AX_GCC_FUNC_ATTRIBUTE([format])
 240 AX_GCC_FUNC_ATTRIBUTE([malloc])
 241 AX_GCC_FUNC_ATTRIBUTE([packed])
 242 AX_GCC_FUNC_ATTRIBUTE([pure])
 243 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 244 AX_GCC_FUNC_ATTRIBUTE([unused])
 245 AX_GCC_FUNC_ATTRIBUTE([visibility])
 246 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 247 AX_GCC_FUNC_ATTRIBUTE([weak])
 248 AX_GCC_FUNC_ATTRIBUTE([alias])
 249
 250 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 251
 252 dnl Make sure the pkg-config macros are defined
 253 m4_ifndef([PKG_PROG_PKG_CONFIG],
 254     [m4_fatal([Could not locate the pkg-config autoconf macros.
 255   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 256   are in a different location, try setting the environment variable
 257   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 258 PKG_PROG_PKG_CONFIG()
 259
 260 dnl LIB_DIR - library basename
 261 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 262 AC_SUBST([LIB_DIR])
 263
 264 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 265 _SAVE_LDFLAGS="$LDFLAGS"
 266 _SAVE_CPPFLAGS="$CPPFLAGS"
 267
 268 dnl Compiler macros
 269 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 270 AC_SUBST([DEFINES])
 271 android=no
 272 case "$host_os" in
 273 *-android)
 274     android=yes
 275     ;;
 276 linux*|*-gnu*|gnu*|cygwin*)
 277     DEFINES="$DEFINES -D_GNU_SOURCE"
 278     ;;
 279 solaris*)
 280     DEFINES="$DEFINES -DSVR4"
 281     ;;
 282 esac
 283
 284 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 285
 286 dnl Add flags for gcc and g++
 287 if test "x$GCC" = xyes; then
 288     CFLAGS="$CFLAGS -Wall"
 289
 290     if test "x$USE_GNU99" = xyes; then
 291         CFLAGS="$CFLAGS -std=gnu99"
 292     else
 293         CFLAGS="$CFLAGS -std=c99"
 294     fi
 295
 296     # Enable -Werror=implicit-function-declaration and
 297     # -Werror=missing-prototypes, if available, or otherwise, just
 298     # -Wmissing-prototypes.  This is particularly useful to avoid
 299     # generating a loadable driver module that has undefined symbols.
 300     save_CFLAGS="$CFLAGS"
 301     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 302     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 303     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 304     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 305                    AC_MSG_RESULT([yes]),
 306                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 307                     AC_MSG_RESULT([no])]);
 308
 309     # Enable -fvisibility=hidden if using a gcc that supports it
 310     save_CFLAGS="$CFLAGS"
 311     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 312     VISIBILITY_CFLAGS="-fvisibility=hidden"
 313     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 314     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 315                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 316
 317     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 318     CFLAGS=$save_CFLAGS
 319
 320     # We don't want floating-point math functions to set errno or trap
 321     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 322
 323     # Flags to help ensure that certain portions of the code -- and only those
 324     # portions -- can be built with MSVC:
 325     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 326     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 327     #   supports most of C99)
 328     # - the rest has no compiler compiler restrictions
 329     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 330     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 331
 332     # Enable -Werror=vla if compiler supports it
 333     save_CFLAGS="$CFLAGS"
 334     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 335     CFLAGS="$CFLAGS -Werror=vla"
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 337                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 338                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 339                     AC_MSG_RESULT([yes])],
 340                     AC_MSG_RESULT([no]));
 341     CFLAGS="$save_CFLAGS"
 342 fi
 343 if test "x$GXX" = xyes; then
 344     CXXFLAGS="$CXXFLAGS -Wall"
 345
 346     # Enable -fvisibility=hidden if using a gcc that supports it
 347     save_CXXFLAGS="$CXXFLAGS"
 348     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 349     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 350     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 351     AC_LANG_PUSH([C++])
 352     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 353                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 354     AC_LANG_POP([C++])
 355
 356     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 357     CXXFLAGS=$save_CXXFLAGS
 358
 359     # We don't want floating-point math functions to set errno or trap
 360     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 361 fi
 362
 363 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 364 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 365
 366 dnl even if the compiler appears to support it, using visibility attributes isn't
 367 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 368 case "$host_os" in
 369 cygwin*)
 370     VISIBILITY_CFLAGS=""
 371     VISIBILITY_CXXFLAGS=""
 372     ;;
 373 esac
 374
 375 AC_SUBST([VISIBILITY_CFLAGS])
 376 AC_SUBST([VISIBILITY_CXXFLAGS])
 377
 378 dnl
 379 dnl Optional flags, check for compiler support
 380 dnl
 381 SSE41_CFLAGS="-msse4.1"
 382 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 383 dnl stack, but on x86-32 such alignment is not guaranteed.
 384 case "$target_cpu" in
 385 i?86)
 386     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 387     ;;
 388 esac
 389 save_CFLAGS="$CFLAGS"
 390 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 #include <smmintrin.h>
 393 int param;
 394 int main () {
 395     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 396     c = _mm_max_epu32(a, b);
 397     return _mm_cvtsi128_si32(c);
 398 }]])], SSE41_SUPPORTED=1)
 399 CFLAGS="$save_CFLAGS"
 400 if test "x$SSE41_SUPPORTED" = x1; then
 401     DEFINES="$DEFINES -DUSE_SSE41"
 402 fi
 403 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 404 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 405
 406 dnl Check for new-style atomic builtins
 407 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 408 int main() {
 409     int n;
 410     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 411 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 412 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 413     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 414 fi
 415 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 416
 417 dnl Check for Endianness
 418 AC_C_BIGENDIAN(
 419    little_endian=no,
 420    little_endian=yes,
 421    little_endian=no,
 422    little_endian=no
 423 )
 424
 425 dnl Check for POWER8 Architecture
 426 PWR8_CFLAGS="-mpower8-vector"
 427 have_pwr8_intrinsics=no
 428 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 429 save_CFLAGS=$CFLAGS
 430 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 431 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 432 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 433 #error "Need GCC >= 4.8 for sane POWER8 support"
 434 #endif
 435 #include <altivec.h>
 436 int main () {
 437     vector unsigned char r;
 438     vector unsigned int v = vec_splat_u32 (1);
 439     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 440     return 0;
 441 }]])], have_pwr8_intrinsics=yes)
 442 CFLAGS=$save_CFLAGS
 443
 444 AC_ARG_ENABLE(pwr8,
 445    [AC_HELP_STRING([--disable-pwr8-inst],
 446                    [disable POWER8-specific instructions])],
 447    [enable_pwr8=$enableval], [enable_pwr8=auto])
 448
 449 if test "x$enable_pwr8" = xno ; then
 450    have_pwr8_intrinsics=disabled
 451 fi
 452
 453 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 454    DEFINES="$DEFINES -D_ARCH_PWR8"
 455    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 456    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 457 else
 458    PWR8_CFLAGS=
 459 fi
 460
 461 AC_MSG_RESULT($have_pwr8_intrinsics)
 462 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 463    AC_MSG_ERROR([POWER8 compiler support not detected])
 464 fi
 465
 466 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 467    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 468 fi
 469
 470 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 471
 472 dnl Can't have static and shared libraries, default to static if user
 473 dnl explicitly requested. If both disabled, set to static since shared
 474 dnl was explicitly requested.
 475 case "x$enable_static$enable_shared" in
 476 xyesyes)
 477     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 478     ;;
 479 xnono)
 480     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 481     ;;
 482 esac
 483
 484 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 485
 486 dnl
 487 dnl other compiler options
 488 dnl
 489 AC_ARG_ENABLE([debug],
 490     [AS_HELP_STRING([--enable-debug],
 491         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 492     [enable_debug="$enableval"],
 493     [enable_debug=no]
 494 )
 495
 496 AC_ARG_ENABLE([profile],
 497     [AS_HELP_STRING([--enable-profile],
 498         [enable profiling of code @<:@default=disabled@:>@])],
 499     [enable_profile="$enableval"],
 500     [enable_profile=no]
 501 )
 502
 503 if test "x$enable_profile" = xyes; then
 504     DEFINES="$DEFINES -DPROFILE"
 505     if test "x$GCC" = xyes; then
 506         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 507     fi
 508     if test "x$GXX" = xyes; then
 509         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 510     fi
 511 fi
 512
 513 if test "x$enable_debug" = xyes; then
 514     DEFINES="$DEFINES -DDEBUG"
 515     if test "x$enable_profile" = xyes; then
 516         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 517     fi
 518     if test "x$GCC" = xyes; then
 519         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 520             CFLAGS="$CFLAGS -g"
 521         fi
 522         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 523             CFLAGS="$CFLAGS -O0"
 524         fi
 525     fi
 526     if test "x$GXX" = xyes; then
 527         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 528             CXXFLAGS="$CXXFLAGS -g"
 529         fi
 530         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 531             CXXFLAGS="$CXXFLAGS -O0"
 532         fi
 533     fi
 534 else
 535    DEFINES="$DEFINES -DNDEBUG"
 536 fi
 537
 538 dnl
 539 dnl Check if linker supports -Bsymbolic
 540 dnl
 541 save_LDFLAGS=$LDFLAGS
 542 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 543 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 544 AC_LINK_IFELSE(
 545     [AC_LANG_SOURCE([int main() { return 0;}])],
 546     [AC_MSG_RESULT([yes])
 547         BSYMBOLIC="-Wl,-Bsymbolic";],
 548     [AC_MSG_RESULT([no])
 549         BSYMBOLIC="";])
 550 LDFLAGS=$save_LDFLAGS
 551
 552 AC_SUBST([BSYMBOLIC])
 553
 554 dnl
 555 dnl Check if linker supports garbage collection
 556 dnl
 557 save_LDFLAGS=$LDFLAGS
 558 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 559 AC_MSG_CHECKING([whether ld supports --gc-sections])
 560 AC_LINK_IFELSE(
 561     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 562     [AC_MSG_RESULT([yes])
 563         GC_SECTIONS="-Wl,--gc-sections";],
 564     [AC_MSG_RESULT([no])
 565         GC_SECTIONS="";])
 566 LDFLAGS=$save_LDFLAGS
 567
 568 AC_SUBST([GC_SECTIONS])
 569
 570 dnl
 571 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 572 dnl so when these flags are passed to ld via libtool the checks will fail
 573 dnl
 574 case "$host_os" in
 575 openbsd* | darwin* )
 576     LD_NO_UNDEFINED="" ;;
 577 *)
 578     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 579 esac
 580
 581 AC_SUBST([LD_NO_UNDEFINED])
 582
 583 dnl
 584 dnl Check if linker supports version scripts
 585 dnl
 586 AC_MSG_CHECKING([if the linker supports version-scripts])
 587 save_LDFLAGS=$LDFLAGS
 588 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 589 cat > conftest.map <<EOF
 590 VERSION_1 {
 591      global:
 592          main;
 593
 594      local:
 595          *;
 596 };
 597 EOF
 598 AC_LINK_IFELSE(
 599     [AC_LANG_SOURCE([int main() { return 0;}])],
 600     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 601     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 602 LDFLAGS=$save_LDFLAGS
 603 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 604
 605 dnl
 606 dnl Check if linker supports dynamic list files
 607 dnl
 608 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 609 save_LDFLAGS=$LDFLAGS
 610 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 611 cat > conftest.dyn <<EOF
 612 {
 613         radeon_drm_winsys_create;
 614 };
 615 EOF
 616 AC_LINK_IFELSE(
 617     [AC_LANG_SOURCE([int main() { return 0;}])],
 618     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 619     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 620 LDFLAGS=$save_LDFLAGS
 621 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 622
 623 dnl
 624 dnl compatibility symlinks
 625 dnl
 626 case "$host_os" in
 627 linux* )
 628     HAVE_COMPAT_SYMLINKS=yes ;;
 629 * )
 630     HAVE_COMPAT_SYMLINKS=no ;;
 631 esac
 632
 633 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 634
 635 dnl
 636 dnl library names
 637 dnl
 638 dnl Unfortunately we need to do a few things that libtool can't help us with,
 639 dnl so we need some knowledge of shared library filenames:
 640 dnl
 641 dnl LIB_EXT is the extension used when creating symlinks for alternate
 642 dnl filenames for a shared library which will be dynamically loaded
 643 dnl
 644 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 645 dnl the file for a shared library we wish to link with
 646 dnl
 647 case "$host_os" in
 648 darwin* )
 649     LIB_EXT='dylib'
 650     IMP_LIB_EXT=$LIB_EXT
 651     ;;
 652 cygwin* )
 653     LIB_EXT='dll'
 654     IMP_LIB_EXT='dll.a'
 655     ;;
 656 aix* )
 657     LIB_EXT='a'
 658     IMP_LIB_EXT=$LIB_EXT
 659     ;;
 660 * )
 661     LIB_EXT='so'
 662     IMP_LIB_EXT=$LIB_EXT
 663     ;;
 664 esac
 665
 666 AC_SUBST([LIB_EXT])
 667
 668 dnl
 669 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 670 dnl
 671 AC_ARG_ENABLE([texture-float],
 672     [AS_HELP_STRING([--enable-texture-float],
 673         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 674     [enable_texture_float="$enableval"],
 675     [enable_texture_float=no]
 676 )
 677 if test "x$enable_texture_float" = xyes; then
 678     AC_MSG_WARN([Floating-point textures enabled.])
 679     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 680     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 681 fi
 682
 683 dnl
 684 dnl Arch/platform-specific settings
 685 dnl
 686 AC_ARG_ENABLE([asm],
 687     [AS_HELP_STRING([--disable-asm],
 688         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 689     [enable_asm="$enableval"],
 690     [enable_asm=yes]
 691 )
 692 asm_arch=""
 693 AC_MSG_CHECKING([whether to enable assembly])
 694 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 695 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 696 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 697     case "$host_cpu" in
 698     i?86 | x86_64 | amd64)
 699         if test "x$host_cpu" != "x$target_cpu"; then
 700             enable_asm=no
 701             AC_MSG_RESULT([no, cross compiling])
 702         fi
 703         ;;
 704     esac
 705 fi
 706 # check for supported arches
 707 if test "x$enable_asm" = xyes; then
 708     case "$host_cpu" in
 709     i?86)
 710         case "$host_os" in
 711         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 712             asm_arch=x86
 713             ;;
 714         esac
 715         ;;
 716     x86_64|amd64)
 717         case "$host_os" in
 718         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 719             asm_arch=x86_64
 720             ;;
 721         esac
 722         ;;
 723     sparc*)
 724         case "$host_os" in
 725         linux*)
 726             asm_arch=sparc
 727             ;;
 728         esac
 729         ;;
 730     esac
 731
 732     case "$asm_arch" in
 733     x86)
 734         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 735         AC_MSG_RESULT([yes, x86])
 736         ;;
 737     x86_64|amd64)
 738         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 739         AC_MSG_RESULT([yes, x86_64])
 740         ;;
 741     sparc)
 742         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 743         AC_MSG_RESULT([yes, sparc])
 744         ;;
 745     *)
 746         AC_MSG_RESULT([no, platform not supported])
 747         ;;
 748     esac
 749 fi
 750
 751 AC_HEADER_MAJOR
 752 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 753 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 754 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 755 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 756
 757 dnl Check to see if dlopen is in default libraries (like Solaris, which
 758 dnl has it in libc), or if libdl is needed to get it.
 759 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 760     [AC_CHECK_LIB([dl], [dlopen],
 761        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 762 AC_SUBST([DLOPEN_LIBS])
 763
 764 dnl Check if that library also has dladdr
 765 save_LIBS="$LIBS"
 766 LIBS="$LIBS $DLOPEN_LIBS"
 767 AC_CHECK_FUNCS([dladdr])
 768 LIBS="$save_LIBS"
 769
 770 case "$host_os" in
 771 darwin*)
 772     ;;
 773 *)
 774     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 775                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 776                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 777     AC_SUBST([CLOCK_LIB])
 778     ;;
 779 esac
 780
 781 dnl See if posix_memalign is available
 782 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 783
 784 dnl Check for pthreads
 785 AX_PTHREAD
 786 if test "x$ax_pthread_ok" = xno; then
 787     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 788 fi
 789 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 790 dnl to -pthread, which causes problems if we need -lpthread to appear in
 791 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 792 dnl is not valid for that platform.
 793 if test "x$android" = xno; then
 794     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 795 fi
 796
 797 dnl pthread-stubs is mandatory on targets where it exists
 798 case "$host_os" in
 799 cygwin* )
 800     pthread_stubs_possible="no"
 801     ;;
 802 * )
 803     pthread_stubs_possible="yes"
 804     ;;
 805 esac
 806
 807 if test "x$pthread_stubs_possible" = xyes; then
 808     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 809     AC_SUBST(PTHREADSTUBS_CFLAGS)
 810     AC_SUBST(PTHREADSTUBS_LIBS)
 811 fi
 812
 813 dnl SELinux awareness.
 814 AC_ARG_ENABLE([selinux],
 815     [AS_HELP_STRING([--enable-selinux],
 816         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 817     [MESA_SELINUX="$enableval"],
 818     [MESA_SELINUX=no])
 819 if test "x$enable_selinux" = "xyes"; then
 820     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 821         [AC_CHECK_HEADER([selinux/selinux.h],[],
 822                          [AC_MSG_ERROR([SELinux headers not found])])
 823          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 824                       [AC_MSG_ERROR([SELinux library not found])])
 825          SELINUX_LIBS="-lselinux"])
 826     DEFINES="$DEFINES -DMESA_SELINUX"
 827 fi
 828 AC_SUBST([SELINUX_CFLAGS])
 829 AC_SUBST([SELINUX_LIBS])
 830
 831 dnl
 832 dnl LLVM
 833 dnl
 834 AC_ARG_ENABLE([llvm-shared-libs],
 835     [AS_HELP_STRING([--enable-llvm-shared-libs],
 836         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 837     [enable_llvm_shared_libs="$enableval"],
 838     [enable_llvm_shared_libs=yes])
 839
 840 AC_ARG_WITH([llvm-prefix],
 841     [AS_HELP_STRING([--with-llvm-prefix],
 842         [Prefix for LLVM installations in non-standard locations])],
 843     [llvm_prefix="$withval"],
 844     [llvm_prefix=''])
 845
 846 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 847 if test "x$have_libelf" = xno; then
 848    LIBELF_LIBS=''
 849    LIBELF_CFLAGS=''
 850    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 851    AC_SUBST([LIBELF_LIBS])
 852    AC_SUBST([LIBELF_CFLAGS])
 853 fi
 854
 855 if test -z "$LLVM_CONFIG"; then
 856     if test -n "$llvm_prefix"; then
 857         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 858     else
 859         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 860     fi
 861 fi
 862
 863 llvm_add_component() {
 864     new_llvm_component=$1
 865     driver_name=$2
 866
 867     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 868         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 869     else
 870         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 871     fi
 872 }
 873
 874 llvm_add_default_components() {
 875     driver_name=$1
 876
 877     # Required default components
 878     llvm_add_component "bitwriter" $driver_name
 879     llvm_add_component "engine" $driver_name
 880     llvm_add_component "mcdisassembler" $driver_name
 881     llvm_add_component "mcjit" $driver_name
 882
 883     # Optional default components
 884     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 885         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 886     fi
 887 }
 888
 889 llvm_add_target() {
 890     new_llvm_target=$1
 891     driver_name=$2
 892
 893     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 894         llvm_add_component $new_llvm_target $driver_name
 895     else
 896         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 897     fi
 898 }
 899
 900 # Call this inside ` ` to get the return value.
 901 # $1 is the llvm-config command with arguments.
 902 strip_unwanted_llvm_flags() {
 903     # Use \> (marks the end of the word)
 904     echo `$1` | sed \
 905         -e 's/-march=\S*//g' \
 906         -e 's/-mtune=\S*//g' \
 907         -e 's/-mcpu=\S*//g' \
 908         -e 's/-DNDEBUG\>//g' \
 909         -e 's/-D_GNU_SOURCE\>//g' \
 910         -e 's/-pedantic\>//g' \
 911         -e 's/-Wcovered-switch-default\>//g' \
 912         -e 's/-O.\>//g' \
 913         -e 's/-g\>//g' \
 914         -e 's/-Wall\>//g' \
 915         -e 's/-Wcast-qual\>//g' \
 916         -e 's/-Woverloaded-virtual\>//g' \
 917         -e 's/-fcolor-diagnostics\>//g' \
 918         -e 's/-fdata-sections\>//g' \
 919         -e 's/-ffunction-sections\>//g' \
 920         -e 's/-fno-exceptions\>//g' \
 921         -e 's/-fomit-frame-pointer\>//g' \
 922         -e 's/-fvisibility-inlines-hidden\>//g' \
 923         -e 's/-fPIC\>//g' \
 924         -e 's/-fstack-protector-strong\>//g'
 925 }
 926
 927 llvm_set_environment_variables() {
 928     if test "x$LLVM_CONFIG" != xno; then
 929         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 930         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 931         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 932         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 933         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 934         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 935         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 936         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 937
 938         # We need to respect LLVM_CFLAGS when compiling LLVM headers.
 939         save_CFLAGS="$CFLAGS"
 940         CFLAGS="$CFLAGS $LLVM_CFLAGS"
 941
 942         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 943             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 944         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 945             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 946         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 947             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 948
 949         CFLAGS="$save_CFLAGS"
 950
 951         # Only needed for LLVM < 3.6.0
 952         if test -z "$LLVM_VERSION_PATCH"; then
 953             LLVM_VERSION_PATCH=0
 954         fi
 955
 956         if test "$LLVM_VERSION_MINOR" -lt 10; then
 957             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 958         else
 959             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
 960         fi
 961
 962         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
 963         FOUND_LLVM=yes
 964     else
 965         FOUND_LLVM=no
 966         LLVM_VERSION_INT=0
 967     fi
 968 }
 969
 970 require_llvm() {
 971     if test "x$enable_gallium_llvm" != "xyes"; then
 972         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
 973     fi
 974 }
 975
 976 llvm_require_version() {
 977     require_llvm $2
 978
 979     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
 980     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
 981     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
 982
 983     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
 984         # major > required major
 985         #  --> OK
 986         return
 987     fi
 988
 989     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
 990         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
 991             # major = required major and
 992             # minor > required minor
 993             #  --> OK
 994             return
 995         else
 996             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
 997                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
 998                     # major = required major and
 999                     # minor = required minor and
1000                     # patch >= required patch
1001                     #  --> OK
1002                     return
1003                 fi
1004             fi
1005         fi
1006     fi
1007
1008     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1009 }
1010
1011 radeon_llvm_check() {
1012     if test ${LLVM_VERSION_INT} -lt 307; then
1013         amdgpu_llvm_target_name='r600'
1014     else
1015         amdgpu_llvm_target_name='amdgpu'
1016     fi
1017
1018     llvm_require_version $*
1019
1020     llvm_add_target $amdgpu_llvm_target_name $2
1021
1022     llvm_add_default_components $2
1023     llvm_add_component "bitreader" $2
1024     llvm_add_component "ipo" $2
1025
1026     NEED_RADEON_LLVM=yes
1027     if test "x$have_libelf" != xyes; then
1028        AC_MSG_ERROR([$1 requires libelf when using llvm])
1029     fi
1030 }
1031
1032 llvm_set_environment_variables
1033
1034 AC_SUBST([LLVM_BINDIR])
1035 AC_SUBST([LLVM_CFLAGS])
1036 AC_SUBST([LLVM_CPPFLAGS])
1037 AC_SUBST([LLVM_CXXFLAGS])
1038 AC_SUBST([LLVM_LIBDIR])
1039 AC_SUBST([LLVM_LIBS])
1040 AC_SUBST([LLVM_LDFLAGS])
1041 AC_SUBST([LLVM_INCLUDEDIR])
1042 AC_SUBST([LLVM_VERSION])
1043
1044 dnl Options for APIs
1045 AC_ARG_ENABLE([opengl],
1046     [AS_HELP_STRING([--disable-opengl],
1047         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1048     [enable_opengl="$enableval"],
1049     [enable_opengl=yes])
1050 AC_ARG_ENABLE([gles1],
1051     [AS_HELP_STRING([--disable-gles1],
1052         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1053     [enable_gles1="$enableval"],
1054     [enable_gles1=yes])
1055 AC_ARG_ENABLE([gles2],
1056     [AS_HELP_STRING([--disable-gles2],
1057         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1058     [enable_gles2="$enableval"],
1059     [enable_gles2=yes])
1060
1061 AC_ARG_ENABLE([dri],
1062     [AS_HELP_STRING([--enable-dri],
1063         [enable DRI modules @<:@default=enabled@:>@])],
1064     [enable_dri="$enableval"],
1065     [enable_dri=yes])
1066
1067 AC_ARG_ENABLE([gallium-extra-hud],
1068     [AS_HELP_STRING([--enable-gallium-extra-hud],
1069         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1070     [enable_gallium_extra_hud="$enableval"],
1071     [enable_gallium_extra_hud=no])
1072 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1073 if test "x$enable_gallium_extra_hud" = xyes ; then
1074     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1075 fi
1076
1077 #TODO: no pkgconfig .pc available for libsensors.
1078 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1079 AC_ARG_ENABLE([lmsensors],
1080     [AS_HELP_STRING([--enable-lmsensors],
1081         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1082     [enable_lmsensors="$enableval"],
1083     [enable_lmsensors=no])
1084 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1085 if test "x$enable_lmsensors" = xyes ; then
1086     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1087     LIBSENSORS_LIBS="-lsensors"
1088 else
1089     LIBSENSORS_LIBS=""
1090 fi
1091 AC_SUBST(LIBSENSORS_LIBS)
1092
1093 case "$host_os" in
1094 linux*)
1095     dri3_default=yes
1096     ;;
1097 *)
1098     dri3_default=no
1099     ;;
1100 esac
1101
1102 if test "x$enable_dri" = xno; then
1103     dri3_default=no
1104 fi
1105
1106 AC_ARG_ENABLE([dri3],
1107     [AS_HELP_STRING([--enable-dri3],
1108         [enable DRI3 @<:@default=auto@:>@])],
1109     [enable_dri3="$enableval"],
1110     [enable_dri3="$dri3_default"])
1111 AC_ARG_ENABLE([glx],
1112     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1113         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1114     [enable_glx="$enableval"],
1115     [enable_glx=yes])
1116 AC_ARG_ENABLE([osmesa],
1117     [AS_HELP_STRING([--enable-osmesa],
1118         [enable OSMesa library @<:@default=disabled@:>@])],
1119     [enable_osmesa="$enableval"],
1120     [enable_osmesa=no])
1121 AC_ARG_ENABLE([gallium-osmesa],
1122     [AS_HELP_STRING([--enable-gallium-osmesa],
1123         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1124     [enable_gallium_osmesa="$enableval"],
1125     [enable_gallium_osmesa=no])
1126 AC_ARG_ENABLE([egl],
1127     [AS_HELP_STRING([--disable-egl],
1128         [disable EGL library @<:@default=enabled@:>@])],
1129     [enable_egl="$enableval"],
1130     [enable_egl=yes])
1131
1132 AC_ARG_ENABLE([xa],
1133     [AS_HELP_STRING([--enable-xa],
1134         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1135     [enable_xa="$enableval"],
1136     [enable_xa=no])
1137 AC_ARG_ENABLE([gbm],
1138    [AS_HELP_STRING([--enable-gbm],
1139          [enable gbm library @<:@default=yes except cygwin@:>@])],
1140    [enable_gbm="$enableval"],
1141    [case "$host_os" in
1142        cygwin*)
1143           enable_gbm=no
1144           ;;
1145        *)
1146           enable_gbm=yes
1147           ;;
1148     esac])
1149 AC_ARG_ENABLE([nine],
1150     [AS_HELP_STRING([--enable-nine],
1151         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1152     [enable_nine="$enableval"],
1153     [enable_nine=no])
1154
1155 AC_ARG_ENABLE([xvmc],
1156    [AS_HELP_STRING([--enable-xvmc],
1157          [enable xvmc library @<:@default=auto@:>@])],
1158    [enable_xvmc="$enableval"],
1159    [enable_xvmc=auto])
1160 AC_ARG_ENABLE([vdpau],
1161    [AS_HELP_STRING([--enable-vdpau],
1162          [enable vdpau library @<:@default=auto@:>@])],
1163    [enable_vdpau="$enableval"],
1164    [enable_vdpau=auto])
1165 AC_ARG_ENABLE([omx],
1166    [AS_HELP_STRING([--enable-omx],
1167          [enable OpenMAX library @<:@default=disabled@:>@])],
1168    [enable_omx="$enableval"],
1169    [enable_omx=no])
1170 AC_ARG_ENABLE([va],
1171    [AS_HELP_STRING([--enable-va],
1172          [enable va library @<:@default=auto@:>@])],
1173    [enable_va="$enableval"],
1174    [enable_va=auto])
1175 AC_ARG_ENABLE([opencl],
1176    [AS_HELP_STRING([--enable-opencl],
1177          [enable OpenCL library @<:@default=disabled@:>@])],
1178    [enable_opencl="$enableval"],
1179    [enable_opencl=no])
1180 AC_ARG_ENABLE([opencl_icd],
1181    [AS_HELP_STRING([--enable-opencl-icd],
1182           [Build an OpenCL ICD library to be loaded by an ICD implementation
1183            @<:@default=disabled@:>@])],
1184     [enable_opencl_icd="$enableval"],
1185     [enable_opencl_icd=no])
1186
1187 AC_ARG_ENABLE([gallium-tests],
1188     [AS_HELP_STRING([--enable-gallium-tests],
1189         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1190     [enable_gallium_tests="$enableval"],
1191     [enable_gallium_tests=no])
1192
1193 # Option for Gallium drivers
1194
1195 # Keep this in sync with the --with-gallium-drivers help string default value
1196 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1197
1198 AC_ARG_WITH([gallium-drivers],
1199     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1200         [comma delimited Gallium drivers list, e.g.
1201         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1202         @<:@default=r300,r600,svga,swrast@:>@])],
1203     [with_gallium_drivers="$withval"],
1204     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1205
1206 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1207 # here so that the script doesn't choke on an unknown driver name later.
1208 case "$with_gallium_drivers" in
1209     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1210     no) with_gallium_drivers='' ;;
1211 esac
1212
1213 if test "x$enable_opengl" = xno -a \
1214         "x$enable_gles1" = xno -a \
1215         "x$enable_gles2" = xno -a \
1216         "x$enable_nine" = xno -a \
1217         "x$enable_xa" = xno -a \
1218         "x$enable_xvmc" = xno -a \
1219         "x$enable_vdpau" = xno -a \
1220         "x$enable_omx" = xno -a \
1221         "x$enable_va" = xno -a \
1222         "x$enable_opencl" = xno; then
1223     AC_MSG_ERROR([at least one API should be enabled])
1224 fi
1225
1226 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1227 if test "x$enable_opengl" = xno -a \
1228         "x$enable_gles1" = xyes; then
1229     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1230 fi
1231
1232 if test "x$enable_opengl" = xno -a \
1233         "x$enable_gles2" = xyes; then
1234     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1235 fi
1236
1237 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1238 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1239 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1240 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1241                                         "x$enable_gles1" = xyes -o \
1242                                         "x$enable_gles2" = xyes)
1243
1244 # Validate GLX options
1245 if test "x$enable_glx" = xyes; then
1246     if test "x$enable_dri" = xyes; then
1247         enable_glx=dri
1248     elif test -n "$with_gallium_drivers"; then
1249         enable_glx=gallium-xlib
1250     else
1251         enable_glx=xlib
1252     fi
1253 fi
1254 case "x$enable_glx" in
1255 xdri | xxlib | xgallium-xlib)
1256     # GLX requires OpenGL
1257     if test "x$enable_opengl" = xno; then
1258         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1259     fi
1260
1261     # Check individual dependencies
1262     case "x$enable_glx" in
1263     xdri)
1264         if test "x$enable_dri" = xno; then
1265             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1266         fi
1267         ;;
1268     xxlib)
1269         if test "x$enable_dri" = xyes; then
1270             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1271         fi
1272         ;;
1273     xgallium-xlib )
1274         if test "x$enable_dri" = xyes; then
1275             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1276         fi
1277         if test -z "$with_gallium_drivers"; then
1278             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1279         fi
1280         ;;
1281     esac
1282     ;;
1283 xno)
1284     ;;
1285 *)
1286     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1287     ;;
1288 esac
1289
1290 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1291 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1292 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1293 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1294
1295 DEFAULT_GL_LIB_NAME=GL
1296
1297 dnl
1298 dnl Libglvnd configuration
1299 dnl
1300 AC_ARG_ENABLE([libglvnd],
1301     [AS_HELP_STRING([--enable-libglvnd],
1302         [Build for libglvnd @<:@default=disabled@:>@])],
1303     [enable_libglvnd="$enableval"],
1304     [enable_libglvnd=no])
1305 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1306 if test "x$enable_libglvnd" = xyes ; then
1307     dnl XXX: update once we can handle more than libGL/glx.
1308     dnl Namely: we should error out if neither of the glvnd enabled libraries
1309     dnl are built
1310     case "x$enable_glx" in
1311     xno)
1312         AC_MSG_ERROR([cannot build libglvnd without GLX])
1313         ;;
1314     xxlib | xgallium-xlib )
1315         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1316         ;;
1317     xdri)
1318         ;;
1319     esac
1320
1321     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1322     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1323     DEFAULT_GL_LIB_NAME=GLX_mesa
1324 fi
1325
1326 AC_ARG_WITH([gl-lib-name],
1327   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1328     [specify GL library name @<:@default=GL@:>@])],
1329   [GL_LIB=$withval],
1330   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1331 AC_ARG_WITH([osmesa-lib-name],
1332   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1333     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1334   [OSMESA_LIB=$withval],
1335   [OSMESA_LIB=OSMesa])
1336 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1337 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1338
1339 dnl
1340 dnl Mangled Mesa support
1341 dnl
1342 AC_ARG_ENABLE([mangling],
1343   [AS_HELP_STRING([--enable-mangling],
1344     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1345   [enable_mangling="${enableval}"],
1346   [enable_mangling=no]
1347 )
1348 if test "x${enable_mangling}" = "xyes" ; then
1349   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1350   GL_LIB="Mangled${GL_LIB}"
1351   OSMESA_LIB="Mangled${OSMESA_LIB}"
1352 fi
1353 AC_SUBST([GL_LIB])
1354 AC_SUBST([OSMESA_LIB])
1355
1356 # Check for libdrm
1357 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1358                   [have_libdrm=yes], [have_libdrm=no])
1359 if test "x$have_libdrm" = xyes; then
1360         DEFINES="$DEFINES -DHAVE_LIBDRM"
1361 fi
1362
1363 require_libdrm() {
1364     if test "x$have_libdrm" != xyes; then
1365        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1366     fi
1367 }
1368
1369
1370 # Select which platform-dependent DRI code gets built
1371 case "$host_os" in
1372 darwin*)
1373     dri_platform='apple' ;;
1374 cygwin*)
1375     dri_platform='windows' ;;
1376 gnu*)
1377     dri_platform='none' ;;
1378 *)
1379     dri_platform='drm' ;;
1380 esac
1381
1382 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1383     have_drisw_kms='yes'
1384 fi
1385
1386 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1387 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1388 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1389 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1390 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1391 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1392 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1393 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1394 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1395
1396 AC_ARG_ENABLE([shared-glapi],
1397     [AS_HELP_STRING([--enable-shared-glapi],
1398         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1399     [enable_shared_glapi="$enableval"],
1400     [enable_shared_glapi=yes])
1401
1402 case "x$enable_opengl$enable_gles1$enable_gles2" in
1403 x*yes*yes*)
1404     if test "x$enable_shared_glapi" = xno; then
1405         AC_MSG_ERROR([shared GLAPI required when building two or more of
1406                       the following APIs - opengl, gles1 gles2])
1407     fi
1408     ;;
1409 esac
1410
1411 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1412
1413 # Build the pipe-drivers as separate libraries/modules.
1414 # Do not touch this unless you know what you are doing.
1415 # XXX: Expose via configure option ?
1416 enable_shared_pipe_drivers=no
1417
1418 dnl
1419 dnl Driver specific build directories
1420 dnl
1421
1422 if test "x$enable_gallium_osmesa" = xyes; then
1423     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1424         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1425     fi
1426     if test "x$enable_osmesa" = xyes; then
1427         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1428     fi
1429 fi
1430
1431 require_dri_shared_libs_and_glapi() {
1432     if test "x$enable_static" = xyes; then
1433         AC_MSG_ERROR([$1 cannot be build as static library])
1434     fi
1435
1436     if test "x$enable_dri" != xyes; then
1437         # There is only a single backend which won't be build/used otherwise.
1438         # XXX: Revisit this as the egl/haiku is a thing.
1439         AC_MSG_ERROR([$1 requires --enable-dri])
1440     fi
1441
1442     if test "x$enable_shared_glapi" != xyes; then
1443         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1444     fi
1445 }
1446
1447 if test "x$enable_dri" = xyes; then
1448     require_dri_shared_libs_and_glapi "DRI"
1449
1450     # not a hard requirement as swrast does not depend on it
1451     if test "x$have_libdrm" = xyes; then
1452         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1453     fi
1454 fi
1455
1456 AC_ARG_ENABLE([driglx-direct],
1457     [AS_HELP_STRING([--disable-driglx-direct],
1458         [disable direct rendering in GLX and EGL for DRI \
1459             @<:@default=auto@:>@])],
1460     [driglx_direct="$enableval"],
1461     [driglx_direct="yes"])
1462
1463 dnl
1464 dnl libGL configuration per driver
1465 dnl
1466 if test "x$enable_glx" != xno; then
1467     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1468 fi
1469 case "x$enable_glx" in
1470 xxlib | xgallium-xlib)
1471     # Xlib-based GLX
1472     dri_modules="x11 xext xcb"
1473     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1474     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1475     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1476     GL_LIB_DEPS="$XLIBGL_LIBS"
1477     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1478     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1479     ;;
1480 xdri)
1481     # DRI-based GLX
1482
1483     # find the DRI deps for libGL
1484     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1485
1486     if test x"$driglx_direct" = xyes; then
1487         if test x"$dri_platform" = xdrm ; then
1488             DEFINES="$DEFINES -DGLX_USE_DRM"
1489             require_libdrm "Direct rendering"
1490
1491             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1492             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1493             if test x"$enable_dri3" = xyes; then
1494                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1495                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1496             fi
1497
1498             if test x"$enable_dri" = xyes; then
1499                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1500             fi
1501
1502             if test x"$enable_dri3" = xyes; then
1503                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1504                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1505                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1506             fi
1507         fi
1508         if test x"$dri_platform" = xapple ; then
1509             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1510         fi
1511         if test x"$dri_platform" = xwindows ; then
1512             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1513         fi
1514     fi
1515
1516     # add xf86vidmode if available
1517     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1518     if test "$HAVE_XF86VIDMODE" = yes ; then
1519         dri_modules="$dri_modules xxf86vm"
1520     fi
1521
1522     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1523     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1524     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1525     GL_LIB_DEPS="$DRIGL_LIBS"
1526
1527     # need DRM libs, $PTHREAD_LIBS, etc.
1528     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1529     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1530     ;;
1531 esac
1532
1533 # This is outside the case (above) so that it is invoked even for non-GLX
1534 # builds.
1535 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1536
1537 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1538 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1539 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1540 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1541
1542 AC_SUBST([X11_INCLUDES])
1543 AC_SUBST([GL_LIB_DEPS])
1544 AC_SUBST([GL_PC_REQ_PRIV])
1545 AC_SUBST([GL_PC_LIB_PRIV])
1546 AC_SUBST([GL_PC_CFLAGS])
1547 AC_SUBST([DRI_PC_REQ_PRIV])
1548 AC_SUBST([GLESv1_CM_LIB_DEPS])
1549 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1550 AC_SUBST([GLESv2_LIB_DEPS])
1551 AC_SUBST([GLESv2_PC_LIB_PRIV])
1552
1553 AC_SUBST([HAVE_XF86VIDMODE])
1554
1555 dnl
1556 dnl More GLX setup
1557 dnl
1558 case "x$enable_glx" in
1559 xxlib | xgallium-xlib)
1560     DEFINES="$DEFINES -DUSE_XSHM"
1561     ;;
1562 xdri)
1563     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1564     if test "x$driglx_direct" = xyes; then
1565         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1566     fi
1567     ;;
1568 esac
1569
1570 dnl
1571 dnl TLS detection
1572 dnl
1573
1574 AC_ARG_ENABLE([glx-tls],
1575     [AS_HELP_STRING([--enable-glx-tls],
1576         [enable TLS support in GLX @<:@default=enabled@:>@])],
1577     [GLX_USE_TLS="$enableval"],
1578     [GLX_USE_TLS=yes])
1579 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1580
1581 if test "x$GLX_USE_TLS" = xyes; then
1582     DEFINES="$DEFINES -DGLX_USE_TLS"
1583 fi
1584
1585 dnl Read-only text section on x86 hardened platforms
1586 AC_ARG_ENABLE([glx-read-only-text],
1587     [AS_HELP_STRING([--enable-glx-read-only-text],
1588         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1589     [enable_glx_read_only_text="$enableval"],
1590     [enable_glx_read_only_text=no])
1591 if test "x$enable_glx_read_only_text" = xyes; then
1592     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1593 fi
1594
1595 dnl
1596 dnl More DRI setup
1597 dnl
1598 dnl Directory for DRI drivers
1599 AC_ARG_WITH([dri-driverdir],
1600     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1601         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1602     [DRI_DRIVER_INSTALL_DIR="$withval"],
1603     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1604 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1605 dnl Extra search path for DRI drivers
1606 AC_ARG_WITH([dri-searchpath],
1607     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1608         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1609     [DRI_DRIVER_SEARCH_DIR="$withval"],
1610     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1611 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1612 dnl Which drivers to build - default is chosen by platform
1613 AC_ARG_WITH([dri-drivers],
1614     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1615         [comma delimited classic DRI drivers list, e.g.
1616         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1617     [with_dri_drivers="$withval"],
1618     [with_dri_drivers=auto])
1619
1620 if test "x$with_dri_drivers" = xauto; then
1621     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1622         with_dri_drivers="yes"
1623     else
1624         with_dri_drivers="no"
1625     fi
1626 fi
1627 if test "x$with_dri_drivers" = xno; then
1628     with_dri_drivers=''
1629 fi
1630
1631 dnl If $with_dri_drivers is yes, drivers will be added through
1632 dnl platform checks. Set DEFINES and LIB_DEPS
1633 if test "x$enable_dri" = xyes; then
1634     # Platform specific settings and drivers to build
1635     case "$host_os" in
1636     linux*)
1637         if test "x$enable_dri3" = xyes; then
1638             DEFINES="$DEFINES -DHAVE_DRI3"
1639         fi
1640
1641         case "$host_cpu" in
1642         powerpc* | sparc*)
1643             # Build only the drivers for cards that exist on PowerPC/sparc
1644             if test "x$with_dri_drivers" = "xyes"; then
1645                 with_dri_drivers="r200 radeon swrast"
1646             fi
1647             ;;
1648         esac
1649         ;;
1650     cygwin*)
1651         if test "x$with_dri_drivers" = "xyes"; then
1652             with_dri_drivers="swrast"
1653         fi
1654         ;;
1655     darwin*)
1656         DEFINES="$DEFINES -DBUILDING_MESA"
1657         if test "x$with_dri_drivers" = "xyes"; then
1658             with_dri_drivers="swrast"
1659         fi
1660         ;;
1661     esac
1662
1663     # default drivers
1664     if test "x$with_dri_drivers" = "xyes"; then
1665         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1666     fi
1667
1668     # Check for expat
1669     PKG_CHECK_MODULES([EXPAT], [expat], [],
1670         # expat version 2.0 and earlier do not provide expat.pc
1671         [AC_CHECK_HEADER([expat.h],[],
1672                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1673          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1674                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1675          EXPAT_LIBS="-lexpat"])
1676
1677     # put all the necessary libs together
1678     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1679 fi
1680
1681 AC_SUBST([DRI_LIB_DEPS])
1682
1683 DRI_DIRS=''
1684 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1685 if test -n "$with_dri_drivers"; then
1686     if test "x$enable_opengl" != xyes; then
1687         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1688     fi
1689
1690     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1691     for driver in $dri_drivers; do
1692         DRI_DIRS="$DRI_DIRS $driver"
1693         case "x$driver" in
1694         xi915)
1695             require_libdrm "i915"
1696             HAVE_I915_DRI=yes;
1697             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1698             ;;
1699         xi965)
1700             require_libdrm "i965"
1701             HAVE_I965_DRI=yes;
1702             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1703             ;;
1704         xnouveau)
1705             require_libdrm "nouveau"
1706             HAVE_NOUVEAU_DRI=yes;
1707             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1708             ;;
1709         xradeon)
1710             require_libdrm "radeon"
1711             HAVE_RADEON_DRI=yes;
1712             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1713             ;;
1714         xr200)
1715             require_libdrm "r200"
1716             HAVE_R200_DRI=yes;
1717             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1718             ;;
1719         xswrast)
1720             HAVE_SWRAST_DRI=yes;
1721             ;;
1722         *)
1723             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1724             ;;
1725         esac
1726     done
1727     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1728 fi
1729
1730
1731 dnl
1732 dnl Gallium LLVM
1733 dnl
1734 dnl With follow-up commits we'll rework --enable-gallium-llvm to --enable-llvm
1735 dnl Since that is too invasive to stable, do the more conservative thing for now
1736 dnl and consider it as a global LLVM toggle.
1737 dnl
1738 AC_ARG_ENABLE([gallium-llvm],
1739     [AS_HELP_STRING([--enable-gallium-llvm],
1740         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1741     [enable_gallium_llvm="$enableval"],
1742     [enable_gallium_llvm=auto])
1743
1744 if test "x$enable_gallium_llvm" = xauto; then
1745     case "$host_cpu" in
1746     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1747     esac
1748 fi
1749
1750 if test "x$enable_gallium_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1751     AC_MSG_ERROR([--enable-gallium-llvm selected but llvm-config is not found])
1752 fi
1753
1754 #
1755 # Vulkan driver configuration
1756 #
1757
1758 AC_ARG_WITH([vulkan-drivers],
1759     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1760         [comma delimited Vulkan drivers list, e.g.
1761         "intel,radeon"
1762         @<:@default=no@:>@])],
1763     [with_vulkan_drivers="$withval"],
1764     [with_vulkan_drivers="no"])
1765
1766 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1767 # here so that the script doesn't choke on an unknown driver name later.
1768 case "x$with_vulkan_drivers" in
1769     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1770     xno) with_vulkan_drivers='' ;;
1771 esac
1772
1773 AC_ARG_WITH([vulkan-icddir],
1774     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1775         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1776     [VULKAN_ICD_INSTALL_DIR="$withval"],
1777     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1778 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1779
1780 if test -n "$with_vulkan_drivers"; then
1781     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1782     for driver in $VULKAN_DRIVERS; do
1783         case "x$driver" in
1784         xintel)
1785             if test "x$HAVE_I965_DRI" != xyes; then
1786                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1787             fi
1788             HAVE_INTEL_VULKAN=yes;
1789
1790             ;;
1791         xradeon)
1792             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1793             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1794             HAVE_RADEON_VULKAN=yes;
1795             ;;
1796         *)
1797             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1798             ;;
1799         esac
1800     done
1801     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1802 fi
1803
1804
1805 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1806 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1807 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1808                                   "x$enable_osmesa" = xyes -o \
1809                                   -n "$DRI_DIRS")
1810
1811 dnl
1812 dnl OSMesa configuration
1813 dnl
1814
1815 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1816 AC_ARG_WITH([osmesa-bits],
1817     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1818         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1819     [osmesa_bits="$withval"],
1820     [osmesa_bits=8])
1821 if test "x$osmesa_bits" != x8; then
1822     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1823         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1824         osmesa_bits=8
1825     fi
1826 fi
1827 case "x$osmesa_bits" in
1828 x8)
1829     OSMESA_LIB="${OSMESA_LIB}"
1830     ;;
1831 x16|x32)
1832     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1833     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1834     ;;
1835 *)
1836     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1837     ;;
1838 esac
1839
1840 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1841     # only link libraries with osmesa if shared
1842     if test "$enable_static" = no; then
1843         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1844     else
1845         OSMESA_LIB_DEPS=""
1846     fi
1847     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1848 fi
1849
1850 AC_SUBST([OSMESA_LIB_DEPS])
1851 AC_SUBST([OSMESA_PC_REQ])
1852 AC_SUBST([OSMESA_PC_LIB_PRIV])
1853
1854 dnl
1855 dnl gbm configuration
1856 dnl
1857 if test "x$enable_gbm" = xyes; then
1858     require_dri_shared_libs_and_glapi "gbm"
1859 fi
1860 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1861 # FINISHME: GBM has a number of dependencies which we should add below
1862 GBM_PC_REQ_PRIV=""
1863 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1864 AC_SUBST([GBM_PC_REQ_PRIV])
1865 AC_SUBST([GBM_PC_LIB_PRIV])
1866
1867 dnl
1868 dnl EGL configuration
1869 dnl
1870
1871 if test "x$enable_egl" = xyes; then
1872     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1873
1874     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1875
1876     require_dri_shared_libs_and_glapi "egl"
1877 fi
1878 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1879 AC_SUBST([EGL_LIB_DEPS])
1880
1881 gallium_st="mesa"
1882
1883 dnl
1884 dnl XA configuration
1885 dnl
1886 if test "x$enable_xa" = xyes; then
1887     if test "x$with_gallium_drivers" = xswrast; then
1888        AC_MSG_ERROR([
1889           Building xa requires at least one non swrast gallium driver.
1890           If you are looking to use libxatracker.so with the VMware driver,
1891           make sure to include svga in the gallium drivers list, apart from
1892           enabling XA.
1893           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1894     fi
1895     gallium_st="$gallium_st xa"
1896 fi
1897 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1898
1899 dnl
1900 dnl Gallium G3DVL configuration
1901 dnl
1902 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1903     if test "x$enable_xvmc" = xauto; then
1904         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1905     fi
1906
1907     if test "x$enable_vdpau" = xauto; then
1908         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1909     fi
1910
1911     if test "x$enable_omx" = xauto; then
1912         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1913     fi
1914
1915     if test "x$enable_va" = xauto; then
1916         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1917     fi
1918 fi
1919
1920 if test "x$enable_dri" = xyes -o \
1921         "x$enable_xvmc" = xyes -o \
1922         "x$enable_vdpau" = xyes -o \
1923         "x$enable_omx" = xyes -o \
1924         "x$enable_va" = xyes; then
1925     need_gallium_vl=yes
1926 fi
1927 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1928
1929 if test "x$enable_xvmc" = xyes -o \
1930         "x$enable_vdpau" = xyes -o \
1931         "x$enable_omx" = xyes -o \
1932         "x$enable_va" = xyes; then
1933     if test x"$enable_dri3" = xyes; then
1934         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1935                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1936     else
1937         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1938     fi
1939     need_gallium_vl_winsys=yes
1940 fi
1941 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1942
1943 if test "x$enable_xvmc" = xyes; then
1944     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1945     gallium_st="$gallium_st xvmc"
1946 fi
1947 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1948
1949 if test "x$enable_vdpau" = xyes; then
1950     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1951     gallium_st="$gallium_st vdpau"
1952     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1953 fi
1954 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1955
1956 if test "x$enable_omx" = xyes; then
1957     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1958     gallium_st="$gallium_st omx"
1959 fi
1960 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1961
1962 if test "x$enable_va" = xyes; then
1963     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1964     gallium_st="$gallium_st va"
1965 fi
1966 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1967
1968 dnl
1969 dnl Nine Direct3D9 configuration
1970 dnl
1971 if test "x$enable_nine" = xyes; then
1972     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1973         AC_MSG_ERROR([nine requires the gallium swrast driver])
1974     fi
1975     if test "x$with_gallium_drivers" = xswrast; then
1976         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1977     fi
1978     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1979         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1980     fi
1981
1982     if test "x$enable_dri3" = xno; then
1983         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1984     fi
1985
1986     gallium_st="$gallium_st nine"
1987 fi
1988 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1989
1990 dnl
1991 dnl OpenCL configuration
1992 dnl
1993
1994 AC_ARG_WITH([clang-libdir],
1995    [AS_HELP_STRING([--with-clang-libdir],
1996          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1997    [CLANG_LIBDIR="$withval"],
1998    [CLANG_LIBDIR=''])
1999
2000 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2001
2002 if test "x$enable_opencl" = xyes; then
2003     if test -z "$with_gallium_drivers"; then
2004         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2005     fi
2006
2007     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2008         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2009     fi
2010
2011     if test "x$have_libclc" = xno; then
2012         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2013                     Make sure the directory containing libclc.pc is specified in your
2014                     PKG_CONFIG_PATH environment variable.
2015                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2016     else
2017         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2018         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2019         AC_SUBST([LIBCLC_INCLUDEDIR])
2020         AC_SUBST([LIBCLC_LIBEXECDIR])
2021     fi
2022
2023     gallium_st="$gallium_st clover"
2024
2025     if test "x$enable_opencl_icd" = xyes; then
2026         OPENCL_LIBNAME="MesaOpenCL"
2027     else
2028         OPENCL_LIBNAME="OpenCL"
2029     fi
2030
2031     if test "x$have_libelf" != xyes; then
2032        AC_MSG_ERROR([Clover requires libelf])
2033     fi
2034
2035     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2036
2037     llvm_add_default_components "opencl"
2038     llvm_add_component "all-targets" "opencl"
2039     llvm_add_component "linker" "opencl"
2040     llvm_add_component "instrumentation" "opencl"
2041     llvm_add_component "ipo" "opencl"
2042     llvm_add_component "irreader" "opencl"
2043     llvm_add_component "option" "opencl"
2044     llvm_add_component "objcarcopts" "opencl"
2045     llvm_add_component "profiledata" "opencl"
2046
2047     dnl Check for Clang internal headers
2048     if test -z "$CLANG_LIBDIR"; then
2049         CLANG_LIBDIR=${LLVM_LIBDIR}
2050     fi
2051     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2052     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2053         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2054 fi
2055 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2056 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2057 AC_SUBST([OPENCL_LIBNAME])
2058 AC_SUBST([CLANG_RESOURCE_DIR])
2059
2060 dnl
2061 dnl Gallium configuration
2062 dnl
2063 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2064
2065 dnl
2066 dnl EGL Platforms configuration
2067 dnl
2068 AC_ARG_WITH([egl-platforms],
2069     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2070         [comma delimited native platforms libEGL supports, e.g.
2071         "x11,drm" @<:@default=auto@:>@])],
2072     [with_egl_platforms="$withval"],
2073     [if test "x$enable_egl" = xyes; then
2074         if test "x$enable_gbm" = xyes; then
2075            with_egl_platforms="x11,drm"
2076         else
2077            with_egl_platforms="x11"
2078         fi
2079     else
2080         with_egl_platforms=""
2081     fi])
2082
2083 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2084     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2085 fi
2086
2087 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2088         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2089         WAYLAND_SCANNER='')
2090 if test "x$WAYLAND_SCANNER" = x; then
2091     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2092 fi
2093
2094 # Do per-EGL platform setups and checks
2095 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2096 for plat in $egl_platforms; do
2097         case "$plat" in
2098         wayland)
2099
2100                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2101
2102                 if test "x$WAYLAND_SCANNER" = x; then
2103                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2104                 fi
2105                 ;;
2106
2107         x11)
2108                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2109                 ;;
2110
2111         drm)
2112                 test "x$enable_gbm" = "xno" &&
2113                         AC_MSG_ERROR([EGL platform drm needs gbm])
2114                 ;;
2115
2116         surfaceless)
2117                 ;;
2118
2119         android)
2120                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2121                 ;;
2122
2123         *)
2124                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2125                 ;;
2126         esac
2127
2128         case "$plat" in
2129         wayland|drm|surfaceless)
2130                 require_libdrm "Platform $plat"
2131                 ;;
2132         esac
2133 done
2134
2135 # libEGL wants to default to the first platform specified in
2136 # ./configure.  parse that here.
2137 if test "x$egl_platforms" != "x"; then
2138     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2139     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2140 else
2141     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2142 fi
2143
2144 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2145 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2146 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2147 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2148 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2149
2150 AC_SUBST([EGL_NATIVE_PLATFORM])
2151 AC_SUBST([EGL_CFLAGS])
2152
2153 # If we don't have the X11 platform, set this define so we don't try to include
2154 # the X11 headers.
2155 if ! echo "$egl_platforms" | grep -q 'x11'; then
2156     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2157     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2158 fi
2159
2160 dnl Directory for XVMC libs
2161 AC_ARG_WITH([xvmc-libdir],
2162     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2163         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2164     [XVMC_LIB_INSTALL_DIR="$withval"],
2165     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2166 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2167
2168 dnl
2169 dnl Gallium Tests
2170 dnl
2171 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2172
2173 dnl Directory for VDPAU libs
2174 AC_ARG_WITH([vdpau-libdir],
2175     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2176         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2177     [VDPAU_LIB_INSTALL_DIR="$withval"],
2178     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2179 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2180
2181 dnl Directory for OMX libs
2182
2183 AC_ARG_WITH([omx-libdir],
2184     [AS_HELP_STRING([--with-omx-libdir=DIR],
2185         [directory for the OMX libraries])],
2186     [OMX_LIB_INSTALL_DIR="$withval"],
2187     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2188 AC_SUBST([OMX_LIB_INSTALL_DIR])
2189
2190 dnl Directory for VA libs
2191
2192 AC_ARG_WITH([va-libdir],
2193     [AS_HELP_STRING([--with-va-libdir=DIR],
2194         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2195     [VA_LIB_INSTALL_DIR="$withval"],
2196     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2197 AC_SUBST([VA_LIB_INSTALL_DIR])
2198
2199 AC_ARG_WITH([d3d-libdir],
2200     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2201         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2202     [D3D_DRIVER_INSTALL_DIR="$withval"],
2203     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2204 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2205
2206 dnl
2207 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2208 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2209 dnl architectures.
2210 dnl
2211 r300_require_llvm() {
2212     case "$host" in *gnux32) return;; esac
2213     case "$host_cpu" in
2214     i*86|x86_64|amd64) require_llvm $1
2215         ;;
2216     esac
2217 }
2218
2219 dnl
2220 dnl DRM is needed by X, Wayland, and offscreen rendering.
2221 dnl Surfaceless is an alternative for the last one.
2222 dnl
2223 require_basic_egl() {
2224     case "$with_egl_platforms" in
2225         *drm*|*surfaceless*)
2226             ;;
2227         *)
2228             AC_MSG_ERROR([$1 requires one of these:
2229                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2230                   2) --with-egl-platforms=surfaceless (offscreen only)
2231                   Recommended options: drm,x11])
2232             ;;
2233     esac
2234 }
2235
2236 radeon_gallium_llvm_check() {
2237     if test "x$enable_gallium_llvm" != "xyes"; then
2238         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2239     fi
2240     radeon_llvm_check $*
2241 }
2242
2243 swr_require_cxx_feature_flags() {
2244     feature_name="$1"
2245     preprocessor_test="$2"
2246     option_list="$3"
2247     output_var="$4"
2248
2249     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2250     AC_LANG_PUSH([C++])
2251     save_CXXFLAGS="$CXXFLAGS"
2252     save_IFS="$IFS"
2253     IFS=","
2254     found=0
2255     for opts in $option_list
2256     do
2257         unset IFS
2258         CXXFLAGS="$opts $save_CXXFLAGS"
2259         AC_COMPILE_IFELSE(
2260             [AC_LANG_PROGRAM(
2261                 [   #if !($preprocessor_test)
2262                     #error
2263                     #endif
2264                 ])],
2265             [found=1; break],
2266             [])
2267         IFS=","
2268     done
2269     IFS="$save_IFS"
2270     CXXFLAGS="$save_CXXFLAGS"
2271     AC_LANG_POP([C++])
2272     if test $found -eq 1; then
2273         AC_MSG_RESULT([$opts])
2274         eval "$output_var=\$opts"
2275         return 0
2276     fi
2277     AC_MSG_RESULT([no])
2278     AC_MSG_ERROR([swr requires $feature_name support])
2279     return 1
2280 }
2281
2282 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2283 if test -n "$with_gallium_drivers"; then
2284     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2285     for driver in $gallium_drivers; do
2286         case "x$driver" in
2287         xsvga)
2288             HAVE_GALLIUM_SVGA=yes
2289             require_libdrm "svga"
2290             ;;
2291         xi915)
2292             HAVE_GALLIUM_I915=yes
2293             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2294             require_libdrm "Gallium i915"
2295             ;;
2296         xr300)
2297             HAVE_GALLIUM_R300=yes
2298             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2299             require_libdrm "r300"
2300             r300_require_llvm "r300"
2301             ;;
2302         xr600)
2303             HAVE_GALLIUM_R600=yes
2304             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2305             require_libdrm "r600"
2306             if test "x$enable_opencl" = xyes; then
2307                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2308
2309                 llvm_add_component "asmparser" "r600"
2310                 llvm_add_component "bitreader" "r600"
2311             fi
2312             ;;
2313         xradeonsi)
2314             HAVE_GALLIUM_RADEONSI=yes
2315             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2316             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2317             require_libdrm "radeonsi"
2318             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2319             require_basic_egl "radeonsi"
2320             ;;
2321         xnouveau)
2322             HAVE_GALLIUM_NOUVEAU=yes
2323             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2324             require_libdrm "nouveau"
2325             ;;
2326         xfreedreno)
2327             HAVE_GALLIUM_FREEDRENO=yes
2328             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2329             require_libdrm "freedreno"
2330             ;;
2331         xetnaviv)
2332             HAVE_GALLIUM_ETNAVIV=yes
2333             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2334             require_libdrm "etnaviv"
2335             ;;
2336        ximx)
2337             HAVE_GALLIUM_IMX=yes
2338             ;;
2339         xswrast)
2340             HAVE_GALLIUM_SOFTPIPE=yes
2341             if test "x$enable_gallium_llvm" = xyes; then
2342                 HAVE_GALLIUM_LLVMPIPE=yes
2343             fi
2344             ;;
2345         xswr)
2346             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2347
2348             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2349                 ",-std=c++11" \
2350                 SWR_CXX11_CXXFLAGS
2351             AC_SUBST([SWR_CXX11_CXXFLAGS])
2352
2353             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2354                 ",-mavx,-march=core-avx" \
2355                 SWR_AVX_CXXFLAGS
2356             AC_SUBST([SWR_AVX_CXXFLAGS])
2357
2358             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2359                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2360                 SWR_AVX2_CXXFLAGS
2361             AC_SUBST([SWR_AVX2_CXXFLAGS])
2362
2363             HAVE_GALLIUM_SWR=yes
2364             ;;
2365         xvc4)
2366             HAVE_GALLIUM_VC4=yes
2367             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2368             require_libdrm "vc4"
2369
2370             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2371                               [USE_VC4_SIMULATOR=yes;
2372                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2373                               [USE_VC4_SIMULATOR=no])
2374             ;;
2375         xvirgl)
2376             HAVE_GALLIUM_VIRGL=yes
2377             require_libdrm "virgl"
2378             require_basic_egl "virgl"
2379             ;;
2380         *)
2381             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2382             ;;
2383         esac
2384     done
2385 fi
2386
2387 if test "x$enable_gallium_llvm" == "xyes" -a "$with_gallium_drivers"; then
2388     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2389     llvm_add_default_components "gallium"
2390 fi
2391
2392 dnl We need to validate some needed dependencies for renderonly drivers.
2393
2394 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes  ; then
2395     AC_ERROR([Building with imx requires etnaviv])
2396 fi
2397
2398 dnl Set LLVM_LIBS - This is done after the driver configuration so
2399 dnl that drivers can add additional components to LLVM_COMPONENTS.
2400 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2401 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2402 dnl this was causing the same libraries to be appear multiple times
2403 dnl in LLVM_LIBS.
2404
2405 if test "x$enable_gallium_llvm" = xyes; then
2406
2407     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2408        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2409     fi
2410     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2411
2412     dnl llvm-config may not give the right answer when llvm is a built as a
2413     dnl single shared library, so we must work the library name out for
2414     dnl ourselves.
2415     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2416     if test "x$enable_llvm_shared_libs" = xyes; then
2417         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2418         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2419         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2420
2421         if test "x$llvm_have_one_so" = xyes; then
2422             dnl LLVM was built using auto*, so there is only one shared object.
2423             LLVM_LIBS="-l$LLVM_SO_NAME"
2424         else
2425             dnl If LLVM was built with CMake, there will be one shared object per
2426             dnl component.
2427             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2428                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2429         Please make sure you have built llvm with the --enable-shared option
2430         and that your llvm libraries are installed in $LLVM_LIBDIR
2431         If you have installed your llvm libraries to a different directory you
2432         can use the --with-llvm-prefix= configure flag to specify this directory.
2433         NOTE: Mesa is attempting to use llvm shared libraries by default.
2434         If you do not want to build with llvm shared libraries and instead want to
2435         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2436         invocation and rebuild.])])
2437
2438            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2439            dnl install uses a shared object for each component and we have
2440            dnl already added all of these objects to LLVM_LIBS.
2441         fi
2442     else
2443         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2444         dnl We need to link to llvm system libs when using static libs
2445         dnl However, only llvm 3.5+ provides --system-libs
2446         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2447             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2448         fi
2449     fi
2450 fi
2451
2452 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2453 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2454 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2455 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2456 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2457 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2458                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2459 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2460 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2461 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2462 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2463 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2464 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2465 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2466 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2467                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2468                                          "x$HAVE_GALLIUM_SWR" = xyes)
2469 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2470 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2471
2472 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2473
2474 if test "x$enable_dri" = xyes; then
2475     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2476 fi
2477
2478 if test "x$have_drisw_kms" = xyes; then
2479     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2480 fi
2481 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2482
2483 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2484 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2485 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2486 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2487 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2488 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2489
2490 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2491 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2492
2493 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2494                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2495                                       "x$HAVE_RADEON_VULKAN" = xyes)
2496
2497 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2498                                         "x$HAVE_I965_DRI" = xyes)
2499
2500 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2501                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2502                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2503 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2504 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2505 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2506 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_gallium_llvm" = xyes)
2507 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2508
2509 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2510 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2511 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2512 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2513                                         "x$enable_gallium_osmesa" = xyes)
2514
2515 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2516 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2517 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2518
2519 AC_SUBST([NINE_MAJOR], 1)
2520 AC_SUBST([NINE_MINOR], 0)
2521 AC_SUBST([NINE_TINY], 0)
2522 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2523
2524 AC_SUBST([VDPAU_MAJOR], 1)
2525 AC_SUBST([VDPAU_MINOR], 0)
2526
2527 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2528 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2529 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2530 AC_SUBST([VA_MINOR], $VA_MINOR)
2531
2532 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2533
2534 AC_SUBST([XVMC_MAJOR], 1)
2535 AC_SUBST([XVMC_MINOR], 0)
2536
2537 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2538 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2539 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2540 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2541
2542 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2543 AC_SUBST([XA_MINOR], $XA_MINOR)
2544 AC_SUBST([XA_TINY], $XA_TINY)
2545 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2546
2547 AC_ARG_ENABLE(valgrind,
2548               [AS_HELP_STRING([--enable-valgrind],
2549                              [Build mesa with valgrind support (default: auto)])],
2550                              [VALGRIND=$enableval], [VALGRIND=auto])
2551 if test "x$VALGRIND" != xno; then
2552         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2553 fi
2554 AC_MSG_CHECKING([whether to enable Valgrind support])
2555 if test "x$VALGRIND" = xauto; then
2556         VALGRIND="$have_valgrind"
2557 fi
2558
2559 if test "x$VALGRIND" = "xyes"; then
2560         if ! test "x$have_valgrind" = xyes; then
2561                 AC_MSG_ERROR([Valgrind support required but not present])
2562         fi
2563         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2564 fi
2565
2566 AC_MSG_RESULT([$VALGRIND])
2567
2568 dnl Restore LDFLAGS and CPPFLAGS
2569 LDFLAGS="$_SAVE_LDFLAGS"
2570 CPPFLAGS="$_SAVE_CPPFLAGS"
2571
2572 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2573 if test "x$acv_mesa_CLANG" = xyes; then
2574     CFLAGS="$CFLAGS -Qunused-arguments"
2575     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2576 fi
2577
2578 dnl Add user CFLAGS and CXXFLAGS
2579 CFLAGS="$CFLAGS $USER_CFLAGS"
2580 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2581
2582 dnl Substitute the config
2583 AC_CONFIG_FILES([Makefile
2584                 src/Makefile
2585                 src/amd/Makefile
2586                 src/amd/vulkan/Makefile
2587                 src/compiler/Makefile
2588                 src/egl/Makefile
2589                 src/egl/main/egl.pc
2590                 src/egl/wayland/wayland-drm/Makefile
2591                 src/egl/wayland/wayland-egl/Makefile
2592                 src/egl/wayland/wayland-egl/wayland-egl.pc
2593                 src/gallium/Makefile
2594                 src/gallium/auxiliary/Makefile
2595                 src/gallium/auxiliary/pipe-loader/Makefile
2596                 src/gallium/drivers/freedreno/Makefile
2597                 src/gallium/drivers/ddebug/Makefile
2598                 src/gallium/drivers/i915/Makefile
2599                 src/gallium/drivers/llvmpipe/Makefile
2600                 src/gallium/drivers/noop/Makefile
2601                 src/gallium/drivers/nouveau/Makefile
2602                 src/gallium/drivers/r300/Makefile
2603                 src/gallium/drivers/r600/Makefile
2604                 src/gallium/drivers/radeon/Makefile
2605                 src/gallium/drivers/radeonsi/Makefile
2606                 src/gallium/drivers/rbug/Makefile
2607                 src/gallium/drivers/softpipe/Makefile
2608                 src/gallium/drivers/svga/Makefile
2609                 src/gallium/drivers/swr/Makefile
2610                 src/gallium/drivers/trace/Makefile
2611                 src/gallium/drivers/etnaviv/Makefile
2612                 src/gallium/drivers/imx/Makefile
2613                 src/gallium/drivers/vc4/Makefile
2614                 src/gallium/drivers/virgl/Makefile
2615                 src/gallium/state_trackers/clover/Makefile
2616                 src/gallium/state_trackers/dri/Makefile
2617                 src/gallium/state_trackers/glx/xlib/Makefile
2618                 src/gallium/state_trackers/nine/Makefile
2619                 src/gallium/state_trackers/omx/Makefile
2620                 src/gallium/state_trackers/osmesa/Makefile
2621                 src/gallium/state_trackers/va/Makefile
2622                 src/gallium/state_trackers/vdpau/Makefile
2623                 src/gallium/state_trackers/xa/Makefile
2624                 src/gallium/state_trackers/xvmc/Makefile
2625                 src/gallium/targets/d3dadapter9/Makefile
2626                 src/gallium/targets/d3dadapter9/d3d.pc
2627                 src/gallium/targets/dri/Makefile
2628                 src/gallium/targets/libgl-xlib/Makefile
2629                 src/gallium/targets/omx/Makefile
2630                 src/gallium/targets/opencl/Makefile
2631                 src/gallium/targets/opencl/mesa.icd
2632                 src/gallium/targets/osmesa/Makefile
2633                 src/gallium/targets/osmesa/osmesa.pc
2634                 src/gallium/targets/pipe-loader/Makefile
2635                 src/gallium/targets/va/Makefile
2636                 src/gallium/targets/vdpau/Makefile
2637                 src/gallium/targets/xa/Makefile
2638                 src/gallium/targets/xa/xatracker.pc
2639                 src/gallium/targets/xvmc/Makefile
2640                 src/gallium/tests/trivial/Makefile
2641                 src/gallium/tests/unit/Makefile
2642                 src/gallium/winsys/etnaviv/drm/Makefile
2643                 src/gallium/winsys/imx/drm/Makefile
2644                 src/gallium/winsys/freedreno/drm/Makefile
2645                 src/gallium/winsys/i915/drm/Makefile
2646                 src/gallium/winsys/nouveau/drm/Makefile
2647                 src/gallium/winsys/radeon/drm/Makefile
2648                 src/gallium/winsys/amdgpu/drm/Makefile
2649                 src/gallium/winsys/svga/drm/Makefile
2650                 src/gallium/winsys/sw/dri/Makefile
2651                 src/gallium/winsys/sw/kms-dri/Makefile
2652                 src/gallium/winsys/sw/null/Makefile
2653                 src/gallium/winsys/sw/wrapper/Makefile
2654                 src/gallium/winsys/sw/xlib/Makefile
2655                 src/gallium/winsys/vc4/drm/Makefile
2656                 src/gallium/winsys/virgl/drm/Makefile
2657                 src/gallium/winsys/virgl/vtest/Makefile
2658                 src/gbm/Makefile
2659                 src/gbm/main/gbm.pc
2660                 src/glx/Makefile
2661                 src/glx/apple/Makefile
2662                 src/glx/tests/Makefile
2663                 src/glx/windows/Makefile
2664                 src/glx/windows/windowsdriproto.pc
2665                 src/gtest/Makefile
2666                 src/intel/Makefile
2667                 src/intel/tools/Makefile
2668                 src/intel/vulkan/Makefile
2669                 src/loader/Makefile
2670                 src/mapi/Makefile
2671                 src/mapi/es1api/glesv1_cm.pc
2672                 src/mapi/es2api/glesv2.pc
2673                 src/mapi/glapi/gen/Makefile
2674                 src/mesa/Makefile
2675                 src/mesa/gl.pc
2676                 src/mesa/drivers/dri/dri.pc
2677                 src/mesa/drivers/dri/common/Makefile
2678                 src/mesa/drivers/dri/common/xmlpool/Makefile
2679                 src/mesa/drivers/dri/i915/Makefile
2680                 src/mesa/drivers/dri/i965/Makefile
2681                 src/mesa/drivers/dri/Makefile
2682                 src/mesa/drivers/dri/nouveau/Makefile
2683                 src/mesa/drivers/dri/r200/Makefile
2684                 src/mesa/drivers/dri/radeon/Makefile
2685                 src/mesa/drivers/dri/swrast/Makefile
2686                 src/mesa/drivers/osmesa/Makefile
2687                 src/mesa/drivers/osmesa/osmesa.pc
2688                 src/mesa/drivers/x11/Makefile
2689                 src/mesa/main/tests/Makefile
2690                 src/util/Makefile
2691                 src/util/tests/hash_table/Makefile
2692                 src/vulkan/wsi/Makefile])
2693
2694 AC_OUTPUT
2695
2696 # Fix up dependencies in *.Plo files, where we changed the extension of a
2697 # source file
2698 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2699
2700
2701 dnl
2702 dnl Output some configuration info for the user
2703 dnl
2704 echo ""
2705 echo "        prefix:          $prefix"
2706 echo "        exec_prefix:     $exec_prefix"
2707 echo "        libdir:          $libdir"
2708 echo "        includedir:      $includedir"
2709
2710 dnl API info
2711 echo ""
2712 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2713
2714 dnl Driver info
2715 echo ""
2716 case "x$enable_osmesa$enable_gallium_osmesa" in
2717 xnoyes)
2718         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2719         ;;
2720 xyesno)
2721         echo "        OSMesa:          lib$OSMESA_LIB"
2722         ;;
2723 xnono)
2724         echo "        OSMesa:          no"
2725         ;;
2726 esac
2727
2728 echo ""
2729 if test "x$enable_dri" != xno; then
2730         echo "        DRI platform:    $dri_platform"
2731         if test -z "$DRI_DIRS"; then
2732             echo "        DRI drivers:     no"
2733         else
2734             echo "        DRI drivers:     $DRI_DIRS"
2735         fi
2736         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2737 fi
2738
2739 case "x$enable_glx" in
2740 xdri)
2741     echo "        GLX:             DRI-based"
2742     ;;
2743 xxlib)
2744     echo "        GLX:             Xlib-based"
2745     ;;
2746 xgallium-xlib)
2747     echo "        GLX:             Xlib-based (Gallium)"
2748     ;;
2749 *)
2750     echo "        GLX:             $enable_glx"
2751     ;;
2752 esac
2753
2754 dnl EGL
2755 echo ""
2756 echo "        EGL:             $enable_egl"
2757 if test "$enable_egl" = yes; then
2758     echo "        EGL platforms:   $egl_platforms"
2759
2760     egl_drivers=""
2761     if test "x$enable_dri" != "xno"; then
2762         egl_drivers="$egl_drivers builtin:egl_dri2"
2763     fi
2764     if test "x$enable_dri3" != "xno"; then
2765         egl_drivers="$egl_drivers builtin:egl_dri3"
2766     fi
2767
2768     echo "        EGL drivers:    $egl_drivers"
2769 fi
2770 if test "x$enable_gbm" = xyes; then
2771     echo "        GBM:             yes"
2772 else
2773     echo "        GBM:             no"
2774 fi
2775
2776 # Vulkan
2777 echo ""
2778 if test "x$VULKAN_DRIVERS" != x; then
2779     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2780     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2781 else
2782     echo "        Vulkan drivers:  no"
2783 fi
2784
2785 echo ""
2786 if test "x$enable_gallium_llvm" = xyes; then
2787     echo "        llvm:            yes"
2788     echo "        llvm-config:     $LLVM_CONFIG"
2789     echo "        llvm-version:    $LLVM_VERSION"
2790 else
2791     echo "        llvm:            no"
2792 fi
2793
2794 echo ""
2795 if test -n "$with_gallium_drivers"; then
2796     echo "        Gallium drivers: $gallium_drivers"
2797     echo "        Gallium st:      $gallium_st"
2798 else
2799     echo "        Gallium:         no"
2800 fi
2801
2802 echo ""
2803 if test "x$enable_gallium_extra_hud" != xyes; then
2804     echo "        HUD extra stats: no"
2805 else
2806     echo "        HUD extra stats: yes"
2807 fi
2808
2809 if test "x$enable_lmsensors" != xyes; then
2810     echo "        HUD lmsensors:   no"
2811 else
2812     echo "        HUD lmsensors:   yes"
2813 fi
2814
2815 dnl Libraries
2816 echo ""
2817 echo "        Shared libs:     $enable_shared"
2818 echo "        Static libs:     $enable_static"
2819 echo "        Shared-glapi:    $enable_shared_glapi"
2820
2821 dnl Compiler options
2822 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2823 cflags=`echo $CFLAGS | \
2824     $SED 's/^ *//;s/  */ /;s/ *$//'`
2825 cxxflags=`echo $CXXFLAGS | \
2826     $SED 's/^ *//;s/  */ /;s/ *$//'`
2827 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2828 echo ""
2829 echo "        CFLAGS:          $cflags"
2830 echo "        CXXFLAGS:        $cxxflags"
2831 echo "        Macros:          $defines"
2832 echo ""
2833 if test "x$enable_gallium_llvm" = xyes; then
2834     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2835     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2836     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2837     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2838     echo ""
2839 fi
2840 echo "        PYTHON2:         $PYTHON2"
2841
2842 echo ""
2843 echo "        Run '${MAKE-make}' to build Mesa"
2844 echo ""