configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447 AC_ARG_ENABLE(static-libjava,
 448 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 449                 [build static libjava @<:@default=no@:>@])],
 450 ENABLE_STATIC_LIBJAVA=$enableval,
 451 ENABLE_STATIC_LIBJAVA=no)
 452 enable_static_libjava=
 453 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 454   enable_static_libjava=yes
 455 fi
 456
 457 if test x$enable_static_libjava != xyes ; then
 458   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 459 fi
 460 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 461
 462 # Disable libmudflap on some systems.
 463 if test x$enable_libmudflap = x ; then
 464     case "${target}" in
 465     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 466         # Enable libmudflap by default in GNU and friends.
 467         ;;
 468     *-*-freebsd*)
 469         # Enable libmudflap by default in FreeBSD.
 470         ;;
 471     *)
 472         # Disable it by default everywhere else.
 473         noconfigdirs="$noconfigdirs target-libmudflap"
 474         ;;
 475     esac
 476 fi
 477
 478 # Disable libgomp on non POSIX hosted systems.
 479 if test x$enable_libgomp = x ; then
 480     # Enable libgomp by default on hosted POSIX systems.
 481     case "${target}" in
 482     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 483         ;;
 484     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 485         ;;
 486     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 487         ;;
 488     *-*-darwin* | *-*-aix*)
 489         ;;
 490     *)
 491         noconfigdirs="$noconfigdirs target-libgomp"
 492         ;;
 493     esac
 494 fi
 495
 496 # Disable libitm on unsupported systems.
 497 if test -d ${srcdir}/libitm; then
 498     if test x$enable_libitm = x; then
 499         AC_MSG_CHECKING([for libitm support])
 500         if (srcdir=${srcdir}/libitm; \
 501                 . ${srcdir}/configure.tgt; \
 502                 test -n "$UNSUPPORTED")
 503         then
 504             AC_MSG_RESULT([no])
 505             noconfigdirs="$noconfigdirs target-libitm"
 506         else
 507             AC_MSG_RESULT([yes])
 508         fi
 509     fi
 510 fi
 511
 512 # Disable libssp for some systems.
 513 case "${target}" in
 514   avr-*-*)
 515     # No hosted I/O support.
 516     noconfigdirs="$noconfigdirs target-libssp"
 517     ;;
 518   powerpc-*-aix* | rs6000-*-aix*)
 519     noconfigdirs="$noconfigdirs target-libssp"
 520     ;;
 521 esac
 522
 523 # Disable libstdc++-v3 for some systems.
 524 case "${target}" in
 525   *-*-vxworks*)
 526     # VxWorks uses the Dinkumware C++ library.
 527     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 528     ;;
 529   arm*-wince-pe*)
 530     # the C++ libraries don't build on top of CE's C libraries
 531     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 532     ;;
 533   avr-*-*)
 534     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 535     ;;
 536 esac
 537
 538 # Disable Fortran for some systems.
 539 case "${target}" in
 540   mmix-*-*)
 541     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 542     unsupported_languages="$unsupported_languages fortran"
 543     ;;
 544 esac
 545
 546 # Disable Java if libffi is not supported.
 547 case "${target}" in
 548   alpha*-*-*)
 549     ;;
 550   arm*-*-*)
 551     ;;
 552   cris-*-*)
 553     ;;
 554   frv-*-*)
 555     ;;
 556   hppa*-*-linux*)
 557     ;;
 558   hppa*-*-hpux*)
 559     ;;
 560   i?86-*-*)
 561     ;;
 562   ia64*-*-*)
 563     ;;
 564   m32r*-*-*)
 565     ;;
 566   m68k-*-*)
 567     ;;
 568   mips-sgi-irix6.* | mips*-*-rtems*)
 569     ;;
 570   mips*-*-linux*)
 571     ;;
 572   powerpc*-*-linux*)
 573     ;;
 574   powerpc-*-darwin*)
 575     ;;
 576   powerpc-*-aix* | rs6000-*-aix*)
 577     ;;
 578   powerpc-*-freebsd*)
 579     ;;
 580   powerpc64-*-freebsd*)
 581     ;;
 582   powerpc*-*-rtems*)
 583     ;;
 584   s390-*-* | s390x-*-*)
 585     ;;
 586   sh-*-* | sh[[34]]*-*-*)
 587     ;;
 588   sh64-*-* | sh5*-*-*)
 589     ;;
 590   sparc*-*-*)
 591     ;;
 592   x86_64-*-*)
 593     ;;
 594   *-*-*)
 595     unsupported_languages="$unsupported_languages java"
 596     ;;
 597 esac
 598
 599 # Disable Java, libgcj or related libraries for some systems.
 600 case "${target}" in
 601   powerpc-*-darwin*)
 602     ;;
 603   i[[3456789]]86-*-darwin*)
 604     ;;
 605   x86_64-*-darwin[[912]]*)
 606     ;;
 607   *-*-darwin*)
 608     noconfigdirs="$noconfigdirs ${libgcj}"
 609     ;;
 610   *-*-netware*)
 611     noconfigdirs="$noconfigdirs ${libgcj}"
 612     ;;
 613   *-*-rtems*)
 614     noconfigdirs="$noconfigdirs ${libgcj}"
 615     ;;
 616   *-*-tpf*)
 617     noconfigdirs="$noconfigdirs ${libgcj}"
 618     ;;
 619   *-*-uclinux*)
 620     noconfigdirs="$noconfigdirs ${libgcj}"
 621     ;;
 622   *-*-vxworks*)
 623     noconfigdirs="$noconfigdirs ${libgcj}"
 624     ;;
 625   alpha*-*-*vms*)
 626     noconfigdirs="$noconfigdirs ${libgcj}"
 627     ;;
 628   arm-wince-pe)
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   arm*-*-symbianelf*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   bfin-*-*)
 635     noconfigdirs="$noconfigdirs target-boehm-gc"
 636     ;;
 637   cris-*-* | crisv32-*-*)
 638     unsupported_languages="$unsupported_languages java"
 639     case "${target}" in
 640       *-*-linux*)
 641         ;;
 642       *) # See PR46792 regarding target-libffi.
 643         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 644     esac
 645     ;;
 646   hppa*64*-*-linux*)
 647     # In this case, it's because the hppa64-linux target is for
 648     # the kernel only at this point and has no libc, and thus no
 649     # headers, crt*.o, etc., all of which are needed by these.
 650     unsupported_languages="$unsupported_languages java"
 651     ;;
 652   hppa*64*-*-hpux*)
 653     noconfigdirs="$noconfigdirs ${libgcj}"
 654     ;;
 655   hppa*-hp-hpux11*)
 656     ;;
 657   hppa*-*-hpux*)
 658     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 659     # build on HP-UX 10.20.
 660     noconfigdirs="$noconfigdirs ${libgcj}"
 661     ;;
 662   ia64*-*-*vms*)
 663     noconfigdirs="$noconfigdirs ${libgcj}"
 664     ;;
 665   i[[3456789]]86-w64-mingw*)
 666     noconfigdirs="$noconfigdirs ${libgcj}"
 667     ;;
 668   i[[3456789]]86-*-mingw*)
 669     noconfigdirs="$noconfigdirs ${libgcj}"
 670     ;;
 671   x86_64-*-mingw*)
 672     noconfigdirs="$noconfigdirs ${libgcj}"
 673     ;;
 674   mmix-*-*)
 675     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 676     ;;
 677   powerpc-*-aix*)
 678     # copied from rs6000-*-* entry
 679     noconfigdirs="$noconfigdirs ${libgcj}"
 680     ;;
 681   rs6000-*-aix*)
 682     noconfigdirs="$noconfigdirs ${libgcj}"
 683     ;;
 684   mips*-*-irix6*)
 685     # Linking libjava exceeds command-line length limits on at least
 686     # IRIX 6.2, but not on IRIX 6.5.
 687     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 688     # <oldham@codesourcery.com>
 689     noconfigdirs="$noconfigdirs ${libgcj}"
 690     ;;
 691   *-*-lynxos*)
 692     noconfigdirs="$noconfigdirs ${libgcj}"
 693     ;;
 694 esac
 695
 696 # Default libgloss CPU subdirectory.
 697 libgloss_dir="$target_cpu"
 698
 699 case "${target}" in
 700   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 701     libgloss_dir=wince
 702     ;;
 703   arm*-*-*)
 704     libgloss_dir=arm
 705     ;;
 706   cris-*-* | crisv32-*-*)
 707     libgloss_dir=cris
 708     ;;
 709   hppa*-*-*)
 710     libgloss_dir=pa
 711     ;;
 712   i[[3456789]]86-*-*)
 713     libgloss_dir=i386
 714     ;;
 715   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 716     libgloss_dir=m68hc11
 717     ;;
 718   m68*-*-* | fido-*-*)
 719     libgloss_dir=m68k
 720     ;;
 721   mips*-*-*)
 722     libgloss_dir=mips
 723     ;;
 724   powerpc*-*-*)
 725     libgloss_dir=rs6000
 726     ;;
 727   sparc*-*-*)
 728     libgloss_dir=sparc
 729     ;;
 730 esac
 731
 732 # Disable newlib and libgloss for various target OSes.
 733 case "${target}" in
 734   alpha*-dec-osf*)
 735     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 736     ;;
 737   i[[3456789]]86-*-linux*)
 738     # This section makes it possible to build newlib natively on linux.
 739     # If we are using a cross compiler then don't configure newlib.
 740     if test x${is_cross_compiler} != xno ; then
 741       noconfigdirs="$noconfigdirs target-newlib"
 742     fi
 743     noconfigdirs="$noconfigdirs target-libgloss"
 744     # If we are not using a cross compiler, do configure newlib.
 745     # Note however, that newlib will only be configured in this situation
 746     # if the --with-newlib option has been given, because otherwise
 747     # 'target-newlib' will appear in skipdirs.
 748     ;;
 749   i[[3456789]]86-*-rdos*)
 750     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 751     ;;
 752   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 753     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 754     ;;
 755   sparc-*-sunos4*)
 756     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 757     ;;
 758   *-*-aix*)
 759     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 760     ;;
 761   *-*-beos*)
 762     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 763     ;;
 764   *-*-chorusos)
 765     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 766     ;;
 767   *-*-dragonfly*)
 768     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 769     ;;
 770   *-*-freebsd*)
 771     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 772     ;;
 773   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 774     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 775     ;;
 776   *-*-lynxos*)
 777     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 778     ;;
 779   *-*-mingw*)
 780     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 781     ;;
 782   *-*-netbsd*)
 783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 784     ;;
 785   *-*-netware*)
 786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 787     ;;
 788   *-*-tpf*)
 789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 790     ;;
 791   *-*-uclinux*)
 792     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 793     ;;
 794   *-*-vxworks*)
 795     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 796     ;;
 797 esac
 798
 799 case "${target}" in
 800   *-*-chorusos)
 801     ;;
 802   powerpc-*-darwin*)
 803     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 804     noconfigdirs="$noconfigdirs sim target-rda"
 805     ;;
 806   i[[3456789]]86-*-darwin*)
 807     noconfigdirs="$noconfigdirs ld gprof"
 808     noconfigdirs="$noconfigdirs sim target-rda"
 809     ;;
 810   x86_64-*-darwin[[912]]*)
 811     noconfigdirs="$noconfigdirs ld gas gprof"
 812     noconfigdirs="$noconfigdirs sim target-rda"
 813     ;;
 814   *-*-darwin*)
 815     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 816     noconfigdirs="$noconfigdirs sim target-rda"
 817     ;;
 818   *-*-dragonfly*)
 819     ;;
 820   *-*-freebsd*)
 821     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 822         && test -f /usr/local/include/gmp.h; then
 823       with_gmp=/usr/local
 824     fi
 825     ;;
 826   *-*-kaos*)
 827     # Remove unsupported stuff on all kaOS configurations.
 828     noconfigdirs="$noconfigdirs target-libgloss"
 829     ;;
 830   *-*-netbsd*)
 831     ;;
 832   *-*-netware*)
 833     ;;
 834   *-*-rtems*)
 835     noconfigdirs="$noconfigdirs target-libgloss"
 836     ;;
 837     # The tpf target doesn't support gdb yet.
 838   *-*-tpf*)
 839     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 840     ;;
 841   *-*-uclinux*)
 842     noconfigdirs="$noconfigdirs target-rda"
 843     ;;
 844   *-*-vxworks*)
 845     ;;
 846   alpha*-dec-osf*)
 847     # ld works, but does not support shared libraries.
 848     # gas doesn't generate exception information.
 849     noconfigdirs="$noconfigdirs gas ld"
 850     ;;
 851   alpha*-*-*vms*)
 852     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 853     ;;
 854   alpha*-*-*)
 855     # newlib is not 64 bit ready
 856     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 857     ;;
 858   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 859     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 860     ;;
 861   arc-*-*)
 862     noconfigdirs="$noconfigdirs target-libgloss"
 863     ;;
 864   arm-*-pe*)
 865     noconfigdirs="$noconfigdirs target-libgloss"
 866     ;;
 867   arm-*-riscix*)
 868     noconfigdirs="$noconfigdirs ld target-libgloss"
 869     ;;
 870   c4x-*-* | tic4x-*-*)
 871     noconfigdirs="$noconfigdirs target-libgloss"
 872     ;;
 873   tic54x-*-*)
 874     noconfigdirs="$noconfigdirs target-libgloss gdb"
 875     ;;
 876   cr16-*-*)
 877     noconfigdirs="$noconfigdirs gdb"
 878     ;;
 879   d10v-*-*)
 880     noconfigdirs="$noconfigdirs target-libgloss"
 881     ;;
 882   d30v-*-*)
 883     noconfigdirs="$noconfigdirs gdb"
 884     ;;
 885   fr30-*-elf*)
 886     noconfigdirs="$noconfigdirs gdb"
 887     ;;
 888   moxie-*-*)
 889     noconfigdirs="$noconfigdirs gprof"
 890     ;;
 891   h8300*-*-*)
 892     noconfigdirs="$noconfigdirs target-libgloss"
 893     ;;
 894   h8500-*-*)
 895     noconfigdirs="$noconfigdirs target-libgloss"
 896     ;;
 897   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 898     ;;
 899   hppa*64*-*-linux*)
 900     ;;
 901   hppa*-*-linux*)
 902     ;;
 903   hppa*-*-*elf* | \
 904   hppa*-*-lites* | \
 905   hppa*-*-openbsd* | \
 906   hppa*64*-*-*)
 907     ;;
 908   hppa*-hp-hpux11*)
 909     noconfigdirs="$noconfigdirs ld"
 910     ;;
 911   hppa*-*-pro*)
 912     ;;
 913   hppa*-*-*)
 914     noconfigdirs="$noconfigdirs ld"
 915     ;;
 916   i960-*-*)
 917     noconfigdirs="$noconfigdirs gdb"
 918     ;;
 919   ia64*-*-elf*)
 920     # No gdb support yet.
 921     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 922     ;;
 923   ia64*-**-hpux*)
 924     # No ld support yet.
 925     noconfigdirs="$noconfigdirs libgui itcl ld"
 926     ;;
 927   ia64*-*-*vms*)
 928     # No gdb or ld support yet.
 929     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 930     ;;
 931   i[[3456789]]86-w64-mingw*)
 932     ;;
 933   i[[3456789]]86-*-mingw*)
 934     target_configdirs="$target_configdirs target-winsup"
 935     ;;
 936   *-*-cygwin*)
 937     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 938     noconfigdirs="$noconfigdirs target-libgloss"
 939     # always build newlib if winsup directory is present.
 940     if test -d "$srcdir/winsup/cygwin"; then
 941       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 942     elif test -d "$srcdir/newlib"; then
 943       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 944     fi
 945     ;;
 946   i[[3456789]]86-*-pe)
 947     noconfigdirs="$noconfigdirs target-libgloss"
 948     ;;
 949   i[[3456789]]86-*-sco3.2v5*)
 950     # The linker does not yet know about weak symbols in COFF,
 951     # and is not configured to handle mixed ELF and COFF.
 952     noconfigdirs="$noconfigdirs ld target-libgloss"
 953     ;;
 954   i[[3456789]]86-*-sco*)
 955     noconfigdirs="$noconfigdirs gprof target-libgloss"
 956     ;;
 957   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   i[[3456789]]86-*-sysv4*)
 961     noconfigdirs="$noconfigdirs target-libgloss"
 962     ;;
 963   i[[3456789]]86-*-beos*)
 964     noconfigdirs="$noconfigdirs gdb"
 965     ;;
 966   i[[3456789]]86-*-rdos*)
 967     noconfigdirs="$noconfigdirs gdb"
 968     ;;
 969   mmix-*-*)
 970     noconfigdirs="$noconfigdirs gdb"
 971     ;;
 972   mt-*-*)
 973     noconfigdirs="$noconfigdirs sim"
 974     ;;
 975   powerpc-*-aix*)
 976     # copied from rs6000-*-* entry
 977     noconfigdirs="$noconfigdirs gprof"
 978     ;;
 979   powerpc*-*-winnt* | powerpc*-*-pe*)
 980     target_configdirs="$target_configdirs target-winsup"
 981     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 982     # always build newlib.
 983     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 984     ;;
 985     # This is temporary until we can link against shared libraries
 986   powerpcle-*-solaris*)
 987     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 988     ;;
 989   powerpc-*-beos*)
 990     noconfigdirs="$noconfigdirs gdb"
 991     ;;
 992   rs6000-*-lynxos*)
 993     noconfigdirs="$noconfigdirs gprof"
 994     ;;
 995   rs6000-*-aix*)
 996     noconfigdirs="$noconfigdirs gprof"
 997     ;;
 998   rs6000-*-*)
 999     noconfigdirs="$noconfigdirs gprof"
1000     ;;
1001   m68k-apollo-*)
1002     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1003     ;;
1004   microblaze*)
1005     noconfigdirs="$noconfigdirs gprof"
1006     ;;
1007   mips*-sde-elf*)
1008     if test x$with_newlib = xyes; then
1009       noconfigdirs="$noconfigdirs gprof"
1010     fi
1011     ;;
1012   mips*-*-irix5*)
1013     noconfigdirs="$noconfigdirs gprof target-libgloss"
1014     ;;
1015   mips*-*-irix6*)
1016     noconfigdirs="$noconfigdirs gprof target-libgloss"
1017     ;;
1018   mips*-*-bsd*)
1019     noconfigdirs="$noconfigdirs gprof target-libgloss"
1020     ;;
1021   mips*-*-linux*)
1022     ;;
1023   mips*-*-*)
1024     noconfigdirs="$noconfigdirs gprof"
1025     ;;
1026   sh-*-* | sh64-*-*)
1027     case "${target}" in
1028       sh*-*-elf)
1029          ;;
1030       *)
1031          noconfigdirs="$noconfigdirs target-libgloss" ;;
1032     esac
1033     ;;
1034   sparc-*-sunos4*)
1035     if test x${is_cross_compiler} = xno ; then
1036            use_gnu_ld=no
1037     fi
1038     ;;
1039   tic6x-*-*)
1040     noconfigdirs="$noconfigdirs sim"
1041     ;;
1042   tilepro-*-* | tilegx-*-*)
1043     noconfigdirs="$noconfigdirs sim"
1044     ;;
1045   v810-*-*)
1046     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1047     ;;
1048   vax-*-*)
1049     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1050     ;;
1051 esac
1052
1053 # If we aren't building newlib, then don't build libgloss, since libgloss
1054 # depends upon some newlib header files.
1055 case "${noconfigdirs}" in
1056   *target-libgloss*) ;;
1057   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1058 esac
1059
1060 # Work in distributions that contain no compiler tools, like Autoconf.
1061 host_makefile_frag=/dev/null
1062 if test -d ${srcdir}/config ; then
1063 case "${host}" in
1064   i[[3456789]]86-*-msdosdjgpp*)
1065     host_makefile_frag="config/mh-djgpp"
1066     ;;
1067   *-cygwin*)
1068     ACX_CHECK_CYGWIN_CAT_WORKS
1069     host_makefile_frag="config/mh-cygwin"
1070     ;;
1071   *-mingw*)
1072     host_makefile_frag="config/mh-mingw"
1073     ;;
1074   *-interix*)
1075     host_makefile_frag="config/mh-interix"
1076     ;;
1077   hppa*-hp-hpux10*)
1078     host_makefile_frag="config/mh-pa-hpux10"
1079     ;;
1080   hppa*-hp-hpux*)
1081     host_makefile_frag="config/mh-pa"
1082     ;;
1083   hppa*-*)
1084     host_makefile_frag="config/mh-pa"
1085     ;;
1086   *-*-darwin*)
1087     host_makefile_frag="config/mh-darwin"
1088     ;;
1089   powerpc-*-aix*)
1090     host_makefile_frag="config/mh-ppc-aix"
1091     ;;
1092   rs6000-*-aix*)
1093     host_makefile_frag="config/mh-ppc-aix"
1094     ;;
1095 esac
1096 fi
1097
1098 if test "${build}" != "${host}" ; then
1099   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1100   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1101   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1102   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1103   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1104   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1105   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1106   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1107   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1108   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1109   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1110   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1111   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1112 else
1113   AR_FOR_BUILD="\$(AR)"
1114   AS_FOR_BUILD="\$(AS)"
1115   CC_FOR_BUILD="\$(CC)"
1116   CXX_FOR_BUILD="\$(CXX)"
1117   GCJ_FOR_BUILD="\$(GCJ)"
1118   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1119   GOC_FOR_BUILD="\$(GOC)"
1120   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1121   LD_FOR_BUILD="\$(LD)"
1122   NM_FOR_BUILD="\$(NM)"
1123   RANLIB_FOR_BUILD="\$(RANLIB)"
1124   WINDRES_FOR_BUILD="\$(WINDRES)"
1125   WINDMC_FOR_BUILD="\$(WINDMC)"
1126 fi
1127
1128 AC_PROG_CC
1129 AC_PROG_CXX
1130
1131 # We must set the default linker to the linker used by gcc for the correct
1132 # operation of libtool.  If LD is not defined and we are using gcc, try to
1133 # set the LD default to the ld used by gcc.
1134 if test -z "$LD"; then
1135   if test "$GCC" = yes; then
1136     case $build in
1137     *-*-mingw*)
1138       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1139     *)
1140       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1141     esac
1142     case $gcc_prog_ld in
1143     # Accept absolute paths.
1144     [[\\/]* | [A-Za-z]:[\\/]*)]
1145       LD="$gcc_prog_ld" ;;
1146     esac
1147   fi
1148 fi
1149
1150 ACX_PROG_GNAT
1151 ACX_PROG_CMP_IGNORE_INITIAL
1152
1153 AC_ARG_ENABLE([bootstrap],
1154 [AS_HELP_STRING([--enable-bootstrap],
1155                 [enable bootstrapping @<:@yes if native build@:>@])],,
1156 enable_bootstrap=default)
1157
1158 # Issue errors and warnings for invalid/strange bootstrap combinations.
1159 if test -r $srcdir/gcc/configure; then
1160   have_compiler=yes
1161 else
1162   have_compiler=no
1163 fi
1164
1165 case "$have_compiler:$host:$target:$enable_bootstrap" in
1166   *:*:*:no) ;;
1167
1168   # Default behavior.  Enable bootstrap if we have a compiler
1169   # and we are in a native configuration.
1170   yes:$build:$build:default)
1171     enable_bootstrap=yes ;;
1172
1173   *:*:*:default)
1174     enable_bootstrap=no ;;
1175
1176   # We have a compiler and we are in a native configuration, bootstrap is ok
1177   yes:$build:$build:yes)
1178     ;;
1179
1180   # Other configurations, but we have a compiler.  Assume the user knows
1181   # what he's doing.
1182   yes:*:*:yes)
1183     AC_MSG_WARN([trying to bootstrap a cross compiler])
1184     ;;
1185
1186   # No compiler: if they passed --enable-bootstrap explicitly, fail
1187   no:*:*:yes)
1188     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1189
1190   # Fail if wrong command line
1191   *)
1192     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1193     ;;
1194 esac
1195
1196 # See if we are building gcc with C++.
1197 AC_ARG_ENABLE(build-with-cxx,
1198 [AS_HELP_STRING([--enable-build-with-cxx],
1199                 [build with C++ compiler instead of C compiler])],
1200 ENABLE_BUILD_WITH_CXX=$enableval,
1201 ENABLE_BUILD_WITH_CXX=no)
1202
1203 # Build stage1 with C and build stages 2 and 3 with C++.
1204 AC_ARG_ENABLE(build-poststage1-with-cxx,
1205 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1206                 [build stages 2 and 3 with C++, not C])],
1207 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1208 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1209
1210 # Used for setting $lt_cv_objdir
1211 _LT_CHECK_OBJDIR
1212
1213 # Check for GMP, MPFR and MPC
1214 gmplibs="-lmpc -lmpfr -lgmp"
1215 gmpinc=
1216 have_gmp=no
1217
1218 # Specify a location for mpc
1219 # check for this first so it ends up on the link line before mpfr.
1220 AC_ARG_WITH(mpc,
1221 [AS_HELP_STRING([--with-mpc=PATH],
1222                 [specify prefix directory for installed MPC package.
1223                  Equivalent to --with-mpc-include=PATH/include
1224                  plus --with-mpc-lib=PATH/lib])])
1225 AC_ARG_WITH(mpc-include,
1226 [AS_HELP_STRING([--with-mpc-include=PATH],
1227                 [specify directory for installed MPC include files])])
1228 AC_ARG_WITH(mpc-lib,
1229 [AS_HELP_STRING([--with-mpc-lib=PATH],
1230                 [specify directory for the installed MPC library])])
1231
1232 if test "x$with_mpc" != x; then
1233   gmplibs="-L$with_mpc/lib $gmplibs"
1234   gmpinc="-I$with_mpc/include $gmpinc"
1235 fi
1236 if test "x$with_mpc_include" != x; then
1237   gmpinc="-I$with_mpc_include $gmpinc"
1238 fi
1239 if test "x$with_mpc_lib" != x; then
1240   gmplibs="-L$with_mpc_lib $gmplibs"
1241 fi
1242 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1243   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1244   gmpinc='-I$$s/mpc/src '"$gmpinc"
1245   # Do not test the mpc version.  Assume that it is sufficient, since
1246   # it is in the source tree, and the library has not been built yet
1247   # but it would be included on the link line in the version check below
1248   # hence making the test fail.
1249   have_gmp=yes
1250 fi
1251
1252 # Specify a location for mpfr
1253 # check for this first so it ends up on the link line before gmp.
1254 AC_ARG_WITH(mpfr-dir,
1255 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1256 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1257 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1258
1259 AC_ARG_WITH(mpfr,
1260 [AS_HELP_STRING([--with-mpfr=PATH],
1261                 [specify prefix directory for installed MPFR package.
1262                  Equivalent to --with-mpfr-include=PATH/include
1263                  plus --with-mpfr-lib=PATH/lib])])
1264 AC_ARG_WITH(mpfr-include,
1265 [AS_HELP_STRING([--with-mpfr-include=PATH],
1266                 [specify directory for installed MPFR include files])])
1267 AC_ARG_WITH(mpfr-lib,
1268 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1269                 [specify directory for the installed MPFR library])])
1270
1271 if test "x$with_mpfr" != x; then
1272   gmplibs="-L$with_mpfr/lib $gmplibs"
1273   gmpinc="-I$with_mpfr/include $gmpinc"
1274 fi
1275 if test "x$with_mpfr_include" != x; then
1276   gmpinc="-I$with_mpfr_include $gmpinc"
1277 fi
1278 if test "x$with_mpfr_lib" != x; then
1279   gmplibs="-L$with_mpfr_lib $gmplibs"
1280 fi
1281 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1282   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1283   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1284   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1285   # Do not test the mpfr version.  Assume that it is sufficient, since
1286   # it is in the source tree, and the library has not been built yet
1287   # but it would be included on the link line in the version check below
1288   # hence making the test fail.
1289   have_gmp=yes
1290 fi
1291
1292 # Specify a location for gmp
1293 AC_ARG_WITH(gmp-dir,
1294 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1295 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1296 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1297
1298 AC_ARG_WITH(gmp,
1299 [AS_HELP_STRING([--with-gmp=PATH],
1300                 [specify prefix directory for the installed GMP package.
1301                  Equivalent to --with-gmp-include=PATH/include
1302                  plus --with-gmp-lib=PATH/lib])])
1303 AC_ARG_WITH(gmp-include,
1304 [AS_HELP_STRING([--with-gmp-include=PATH],
1305                 [specify directory for installed GMP include files])])
1306 AC_ARG_WITH(gmp-lib,
1307 [AS_HELP_STRING([--with-gmp-lib=PATH],
1308                 [specify directory for the installed GMP library])])
1309
1310
1311 if test "x$with_gmp" != x; then
1312   gmplibs="-L$with_gmp/lib $gmplibs"
1313   gmpinc="-I$with_gmp/include $gmpinc"
1314 fi
1315 if test "x$with_gmp_include" != x; then
1316   gmpinc="-I$with_gmp_include $gmpinc"
1317 fi
1318 if test "x$with_gmp_lib" != x; then
1319   gmplibs="-L$with_gmp_lib $gmplibs"
1320 fi
1321 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1322   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1323   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1324   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1325   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1326   # Do not test the gmp version.  Assume that it is sufficient, since
1327   # it is in the source tree, and the library has not been built yet
1328   # but it would be included on the link line in the version check below
1329   # hence making the test fail.
1330   have_gmp=yes
1331 fi
1332
1333 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1334   have_gmp=yes
1335   saved_CFLAGS="$CFLAGS"
1336   CFLAGS="$CFLAGS $gmpinc"
1337   # Check for the recommended and required versions of GMP.
1338   AC_MSG_CHECKING([for the correct version of gmp.h])
1339   AC_TRY_COMPILE([#include "gmp.h"],[
1340   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1341   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1342   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1343   choke me
1344   #endif
1345   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1346   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1347   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1348   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1349   choke me
1350   #endif
1351   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1352    [AC_MSG_RESULT([no]); have_gmp=no])
1353
1354   # If we have GMP, check the MPFR version.
1355   if test x"$have_gmp" = xyes; then
1356     # Check for the recommended and required versions of MPFR.
1357     AC_MSG_CHECKING([for the correct version of mpfr.h])
1358     AC_TRY_COMPILE([#include <gmp.h>
1359     #include <mpfr.h>],[
1360     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1361     choke me
1362     #endif
1363     ], [AC_TRY_COMPILE([#include <gmp.h>
1364     #include <mpfr.h>],[
1365     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1366     choke me
1367     #endif
1368     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1369      [AC_MSG_RESULT([no]); have_gmp=no])
1370   fi
1371
1372   # Check for the MPC header version.
1373   if test x"$have_gmp" = xyes ; then
1374     # Check for the recommended and required versions of MPC.
1375     AC_MSG_CHECKING([for the correct version of mpc.h])
1376     AC_TRY_COMPILE([#include <mpc.h>],[
1377     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1378     choke me
1379     #endif
1380     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1381     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1382     choke me
1383     #endif
1384     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1385      [AC_MSG_RESULT([no]); have_gmp=no])
1386   fi
1387
1388   # Now check the MPFR library.
1389   if test x"$have_gmp" = xyes; then
1390     saved_LIBS="$LIBS"
1391     LIBS="$LIBS $gmplibs"
1392     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1393     AC_TRY_LINK([#include <mpc.h>],[
1394     mpfr_t n;
1395     mpfr_t x;
1396     mpc_t c;
1397     int t;
1398     mpfr_init (n);
1399     mpfr_init (x);
1400     mpfr_atan2 (n, n, x, GMP_RNDN);
1401     mpfr_erfc (n, x, GMP_RNDN);
1402     mpfr_subnormalize (x, t, GMP_RNDN);
1403     mpfr_clear(n);
1404     mpfr_clear(x);
1405     mpc_init2 (c, 53);
1406     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1407     mpc_cosh (c, c, MPC_RNDNN);
1408     mpc_pow (c, c, c, MPC_RNDNN);
1409     mpc_acosh (c, c, MPC_RNDNN);
1410     mpc_clear (c);
1411     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1412     LIBS="$saved_LIBS"
1413   fi
1414
1415   CFLAGS="$saved_CFLAGS"
1416
1417 # The library versions listed in the error message below should match
1418 # the HARD-minimums enforced above.
1419   if test x$have_gmp != xyes; then
1420     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1421 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1422 their locations.  Source code for these libraries can be found at
1423 their respective hosting sites as well as at
1424 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1425 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1426 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1427 make sure that you have installed both the libraries and the header
1428 files.  They may be located in separate packages.])
1429   fi
1430 fi
1431
1432 # Flags needed for both GMP, MPFR and/or MPC.
1433 AC_SUBST(gmplibs)
1434 AC_SUBST(gmpinc)
1435 AC_SUBST(extra_mpfr_configure_flags)
1436 AC_SUBST(extra_mpc_gmp_configure_flags)
1437 AC_SUBST(extra_mpc_mpfr_configure_flags)
1438
1439 # Allow host libstdc++ to be specified for static linking with PPL.
1440 AC_ARG_WITH(host-libstdcxx,
1441 [AS_HELP_STRING([--with-host-libstdcxx=L],
1442                 [use linker arguments L to link with libstdc++
1443                  when linking with PPL])])
1444
1445 case $with_host_libstdcxx in
1446   no|yes)
1447     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1448     ;;
1449 esac
1450
1451 # Linker flags to use for stage1 or when not boostrapping.
1452 AC_ARG_WITH(stage1-ldflags,
1453 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1454 [if test "$withval" = "no" -o "$withval" = "yes"; then
1455    stage1_ldflags=
1456  else
1457    stage1_ldflags=$withval
1458  fi],
1459 [stage1_ldflags=])
1460 AC_SUBST(stage1_ldflags)
1461
1462 # Libraries to use for stage1 or when not bootstrapping.
1463 AC_ARG_WITH(stage1-libs,
1464 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1465 [if test "$withval" = "no" -o "$withval" = "yes"; then
1466    stage1_libs=
1467  else
1468    stage1_libs=$withval
1469  fi],
1470 [stage1_libs=$with_host_libstdcxx])
1471 AC_SUBST(stage1_libs)
1472
1473 # Libraries to use for stage2 and later builds.  This defaults to the
1474 # argument passed to --with-host-libstdcxx.
1475 AC_ARG_WITH(boot-libs,
1476 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1477 [if test "$withval" = "no" -o "$withval" = "yes"; then
1478    poststage1_libs=
1479  else
1480    poststage1_libs=$withval
1481  fi],
1482 [poststage1_libs=$with_host_libstdcxx])
1483 AC_SUBST(poststage1_libs)
1484
1485 # Linker flags to use for stage2 and later builds.
1486 AC_ARG_WITH(boot-ldflags,
1487 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1488                 [linker flags for stage2 and later])],
1489 [if test "$withval" = "no" -o "$withval" = "yes"; then
1490    poststage1_ldflags=
1491  else
1492    poststage1_ldflags=$withval
1493  fi],
1494 [poststage1_ldflags=
1495  # In stages 2 and 3, default to linking libstdc++ and libgcc
1496  # statically.  But if the user explicitly specified the libraries to
1497  # use, trust that they are doing what they want.
1498  if test "$poststage1_libs" = ""; then
1499    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1500  fi])
1501 AC_SUBST(poststage1_ldflags)
1502
1503 # Check for PPL
1504 ppllibs=
1505 pplinc=
1506 pwllib=
1507
1508 AC_ARG_WITH(ppl,
1509 [AS_HELP_STRING([--with-ppl=PATH],
1510                 [specify prefix directory for the installed PPL package.
1511                  Equivalent to --with-ppl-include=PATH/include
1512                  plus --with-ppl-lib=PATH/lib])])
1513 AC_ARG_WITH(ppl-include,
1514 [AS_HELP_STRING([--with-ppl-include=PATH],
1515                 [specify directory for installed PPL include files])])
1516 AC_ARG_WITH(ppl-lib,
1517 [AS_HELP_STRING([--with-ppl-lib=PATH],
1518                 [specify directory for the installed PPL library])])
1519
1520 AC_ARG_ENABLE(ppl-version-check,
1521 [AS_HELP_STRING([--disable-ppl-version-check],
1522                 [disable check for PPL version])])
1523
1524 case $with_ppl in
1525   yes | no | "")
1526     ;;
1527   *)
1528     ppllibs="-L$with_ppl/lib"
1529     pplinc="-I$with_ppl/include $pplinc"
1530     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1531       with_ppl=yes
1532     else
1533       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1534     fi
1535     ;;
1536 esac
1537
1538 if test x"$with_ppl_include" != x; then
1539   pplinc="-I$with_ppl_include $pplinc"
1540   with_ppl=yes
1541 fi
1542
1543 if test "x$with_ppl_lib" != x; then
1544   ppllibs="-L$with_ppl_lib"
1545   with_ppl=yes
1546 fi
1547
1548 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1549   if test x"$enable_watchdog" = xyes; then
1550     pwllib="-lpwl"
1551   fi
1552   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1553   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1554   enable_ppl_version_check=no
1555   with_ppl=yes
1556 fi
1557
1558 if test "x$with_ppl" != xno; then
1559   if test "x$pwllib" = x; then
1560     saved_LIBS="$LIBS"
1561     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1562     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1563     LIBS="$saved_LIBS"
1564   fi
1565
1566   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1567
1568   if test "$enable_ppl_version_check" != no; then
1569     saved_CFLAGS="$CFLAGS"
1570     CFLAGS="$CFLAGS $pplinc $gmpinc"
1571     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1572     AC_TRY_COMPILE([#include "ppl_c.h"],[
1573     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1574     choke me
1575     #endif
1576     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1577     CFLAGS="$saved_CFLAGS"
1578   fi
1579 fi
1580
1581 # Flags needed for PPL
1582 AC_SUBST(ppllibs)
1583 AC_SUBST(pplinc)
1584
1585
1586 # Check for CLOOG
1587
1588 dnl Provide configure switches and initialize clooginc & clooglibs
1589 dnl with user input.
1590 CLOOG_INIT_FLAGS
1591 if test "x$with_ppl" = "xno"; then
1592   dnl Only execute fail-action, if CLooG has been requested.
1593   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1594   if test "${graphite_requested}" = yes; then
1595     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1596   fi
1597   with_cloog=no
1598 fi
1599 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1600   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1601   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1602   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1603 fi
1604 if test "x$with_cloog" != "xno"; then
1605   dnl The minimal version of CLooG required for Graphite.
1606   dnl
1607   dnl If we use CLooG-Legacy, the provided version information is
1608   dnl ignored.
1609   CLOOG_CHECK_VERSION(0,16,1)
1610
1611   dnl Only execute fail-action, if CLooG has been requested.
1612   CLOOG_IF_FAILED([
1613     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1614 fi
1615
1616 # Check for LTO support.
1617 AC_ARG_ENABLE(lto,
1618 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1619 enable_lto=$enableval,
1620 enable_lto=yes; default_enable_lto=yes)
1621
1622 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1623   build_lto_plugin=yes
1624 ],[if test x"$default_enable_lto" = x"yes" ; then
1625     case $target in
1626       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1627       # On other non-ELF platforms, LTO has yet to be validated.
1628       *) enable_lto=no ;;
1629     esac
1630   else
1631   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1632   # It would also be nice to check the binutils support, but we don't
1633   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1634   # warn during gcc/ subconfigure; unless you're bootstrapping with
1635   # -flto it won't be needed until after installation anyway.
1636     case $target in
1637       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1638       *) if test x"$enable_lto" = x"yes"; then
1639         AC_MSG_ERROR([LTO support is not enabled for this target.])
1640         fi
1641       ;;
1642     esac
1643   fi
1644   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1645   # Build it unless LTO was explicitly disabled.
1646   case $target in
1647     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1648     *) ;;
1649   esac
1650 ])
1651
1652
1653 # By default, C is the only stage 1 language.
1654 stage1_languages=,c,
1655
1656 # Target libraries that we bootstrap.
1657 bootstrap_target_libs=,target-libgcc,
1658
1659 # Figure out what language subdirectories are present.
1660 # Look if the user specified --enable-languages="..."; if not, use
1661 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1662 # go away some day.
1663 # NB:  embedded tabs in this IF block -- do not untabify
1664 if test -d ${srcdir}/gcc; then
1665   if test x"${enable_languages+set}" != xset; then
1666     if test x"${LANGUAGES+set}" = xset; then
1667       enable_languages="${LANGUAGES}"
1668         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1669     else
1670       enable_languages=all
1671     fi
1672   else
1673     if test x"${enable_languages}" = x ||
1674        test x"${enable_languages}" = xyes;
1675        then
1676       echo configure.in: --enable-languages needs at least one language argument 1>&2
1677       exit 1
1678     fi
1679   fi
1680   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1681
1682   # 'f95' is the old name for the 'fortran' language. We issue a warning
1683   # and make the substitution.
1684   case ,${enable_languages}, in
1685     *,f95,*)
1686       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1687       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1688       ;;
1689   esac
1690
1691   # If bootstrapping, then using --enable-build-with-cxx or
1692   # --enable-build-poststage1-with-cxx requires enabling C++.
1693   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1694     *,c++,*:*:*) ;;
1695     *:*,yes,*:yes)
1696       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1697         enable_languages="${enable_languages},c++"
1698       else
1699         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1700       fi
1701       ;;
1702   esac
1703
1704   # First scan to see if an enabled language requires some other language.
1705   # We assume that a given config-lang.in will list all the language
1706   # front ends it requires, even if some are required indirectly.
1707   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1708     case ${lang_frag} in
1709       ..) ;;
1710       # The odd quoting in the next line works around
1711       # an apparent bug in bash 1.12 on linux.
1712       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1713       *)
1714         # From the config-lang.in, get $language, $lang_requires, and
1715         # $lang_requires_boot_languages.
1716         language=
1717         lang_requires=
1718         lang_requires_boot_languages=
1719         . ${lang_frag}
1720         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1721           case ,${enable_languages}, in
1722             *,$other,*) ;;
1723             *,all,*) ;;
1724             *,$language,*)
1725               echo " \`$other' language required by \`$language'; enabling" 1>&2
1726               enable_languages="${enable_languages},${other}"
1727               ;;
1728           esac
1729         done
1730         for other in ${lang_requires_boot_languages} ; do
1731           if test "$other" != "c"; then
1732             case ,${enable_stage1_languages}, in
1733               *,$other,*) ;;
1734               *,all,*) ;;
1735               *)
1736                 case ,${enable_languages}, in
1737                   *,$language,*)
1738                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1739                     enable_stage1_languages="$enable_stage1_languages,${other}"
1740                     ;;
1741                 esac
1742                 ;;
1743             esac
1744           fi
1745         done
1746         ;;
1747     esac
1748   done
1749
1750   new_enable_languages=,c,
1751
1752   # If LTO is enabled, add the LTO front end.
1753   extra_host_libiberty_configure_flags=
1754   if test "$enable_lto" = "yes" ; then
1755     case ,${enable_languages}, in
1756       *,lto,*) ;;
1757       *) enable_languages="${enable_languages},lto" ;;
1758     esac
1759     if test "${build_lto_plugin}" = "yes" ; then
1760       configdirs="$configdirs lto-plugin"
1761       extra_host_libiberty_configure_flags=--enable-shared
1762     fi
1763   fi
1764   AC_SUBST(extra_host_libiberty_configure_flags)
1765
1766   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1767   potential_languages=,c,
1768
1769   enabled_target_libs=
1770   disabled_target_libs=
1771
1772   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1773     case ${lang_frag} in
1774       ..) ;;
1775       # The odd quoting in the next line works around
1776       # an apparent bug in bash 1.12 on linux.
1777       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1778       *)
1779         # From the config-lang.in, get $language, $target_libs,
1780         # $lang_dirs, $boot_language, and $build_by_default
1781         language=
1782         target_libs=
1783         lang_dirs=
1784         subdir_requires=
1785         boot_language=no
1786         build_by_default=yes
1787         . ${lang_frag}
1788         if test x${language} = x; then
1789           echo "${lang_frag} doesn't set \$language." 1>&2
1790           exit 1
1791         fi
1792
1793         if test "$language" = "c++"; then
1794           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1795              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1796             boot_language=yes
1797           fi
1798         fi
1799
1800         case ,${enable_languages}, in
1801           *,${language},*)
1802             # Language was explicitly selected; include it.
1803             add_this_lang=yes
1804             ;;
1805           *,all,*)
1806             # 'all' was selected, select it if it is a default language
1807             add_this_lang=${build_by_default}
1808             ;;
1809           *)
1810             add_this_lang=no
1811             ;;
1812         esac
1813
1814         # Disable languages that need other directories if these aren't available.
1815         for i in $subdir_requires; do
1816           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1817           case ,${enable_languages}, in
1818             *,${language},*)
1819               # Specifically requested language; tell them.
1820               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1821               ;;
1822             *)
1823               # Silently disable.
1824               add_this_lang=unsupported
1825               ;;
1826           esac
1827         done
1828
1829         # Disable Ada if no preexisting GNAT is available.
1830         case ,${enable_languages},:${language}:${have_gnat} in
1831           *,${language},*:ada:no)
1832             # Specifically requested language; tell them.
1833             AC_MSG_ERROR([GNAT is required to build $language])
1834             ;;
1835           *:ada:no)
1836             # Silently disable.
1837             add_this_lang=unsupported
1838             ;;
1839         esac
1840
1841         # Disable a language that is unsupported by the target.
1842         case " $unsupported_languages " in
1843           *" $language "*)
1844             add_this_lang=unsupported
1845             ;;
1846         esac
1847
1848         case $add_this_lang in
1849           unsupported)
1850             # Remove language-dependent dirs.
1851             disabled_target_libs="$disabled_target_libs $target_libs"
1852             noconfigdirs="$noconfigdirs $lang_dirs"
1853             ;;
1854           no)
1855             # Remove language-dependent dirs; still show language as supported.
1856             disabled_target_libs="$disabled_target_libs $target_libs"
1857             noconfigdirs="$noconfigdirs $lang_dirs"
1858             potential_languages="${potential_languages}${language},"
1859             ;;
1860           yes)
1861             new_enable_languages="${new_enable_languages}${language},"
1862             potential_languages="${potential_languages}${language},"
1863             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1864             enabled_target_libs="$enabled_target_libs $target_libs"
1865             case "${boot_language}:,$enable_stage1_languages," in
1866               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1867                 # Add to (comma-separated) list of stage 1 languages.
1868                 case ",$stage1_languages," in
1869                   *,$language,* | ,yes, | ,all,) ;;
1870                   *) stage1_languages="${stage1_languages}${language}," ;;
1871                 esac
1872                 # We need to bootstrap any supporting libraries.
1873                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1874                 ;;
1875             esac
1876             ;;
1877         esac
1878         ;;
1879     esac
1880   done
1881
1882   # Add target libraries which are only needed for disabled languages
1883   # to noconfigdirs.
1884   if test -n "$disabled_target_libs"; then
1885     for dir in $disabled_target_libs; do
1886       case " $enabled_target_libs " in
1887       *" ${dir} "*) ;;
1888       *) noconfigdirs="$noconfigdirs $dir" ;;
1889       esac
1890     done
1891   fi
1892
1893   AC_ARG_ENABLE(stage1-languages,
1894   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1895                   [choose additional languages to build during
1896                   stage1.  Mostly useful for compiler development])],
1897   [case ,${enable_stage1_languages}, in
1898     ,no,|,,)
1899       # Set it to something that will have no effect in the loop below
1900       enable_stage1_languages=c ;;
1901     ,yes,)
1902       enable_stage1_languages=`echo $new_enable_languages | \
1903         sed -e "s/^,//" -e "s/,$//" ` ;;
1904     *,all,*)
1905       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1906         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1907   esac
1908
1909   # Add "good" languages from enable_stage1_languages to stage1_languages,
1910   # while "bad" languages go in missing_languages.  Leave no duplicates.
1911   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1912     case $potential_languages in
1913       *,$i,*)
1914         case $stage1_languages in
1915           *,$i,*) ;;
1916           *) stage1_languages="$stage1_languages$i," ;;
1917         esac ;;
1918       *)
1919         case $missing_languages in
1920           *,$i,*) ;;
1921           *) missing_languages="$missing_languages$i," ;;
1922         esac ;;
1923      esac
1924   done])
1925
1926   # Remove leading/trailing commas that were added for simplicity
1927   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1928   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1929   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1930   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1931
1932   if test "x$missing_languages" != x; then
1933     AC_MSG_ERROR([
1934 The following requested languages could not be built: ${missing_languages}
1935 Supported languages are: ${potential_languages}])
1936   fi
1937   if test "x$new_enable_languages" != "x$enable_languages"; then
1938     echo The following languages will be built: ${new_enable_languages}
1939     enable_languages="$new_enable_languages"
1940   fi
1941
1942   AC_SUBST(stage1_languages)
1943   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1944 fi
1945
1946 # Handle --disable-<component> generically.
1947 for dir in $configdirs $build_configdirs $target_configdirs ; do
1948   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1949   varname=`echo $dirname | sed -e s/+/_/g`
1950   if eval test x\${enable_${varname}} "=" xno ; then
1951     noconfigdirs="$noconfigdirs $dir"
1952   fi
1953 done
1954
1955 # Check for Boehm's garbage collector
1956 AC_ARG_ENABLE(objc-gc,
1957 [AS_HELP_STRING([--enable-objc-gc],
1958                 [enable use of Boehm's garbage collector with the
1959                  GNU Objective-C runtime])],
1960 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1961   *,objc,*:*:yes:*target-boehm-gc*)
1962     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1963     ;;
1964 esac])
1965
1966 # Make sure we only build Boehm's garbage collector if required.
1967 case ,${enable_languages},:${enable_objc_gc} in
1968   *,objc,*:yes)
1969     # Keep target-boehm-gc if requested for Objective-C.
1970     ;;
1971   *)
1972     # Otherwise remove target-boehm-gc depending on target-libjava.
1973     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1974       noconfigdirs="$noconfigdirs target-boehm-gc"
1975     fi
1976     ;;
1977 esac
1978
1979 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1980 # $build_configdirs and $target_configdirs.
1981 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1982
1983 notsupp=""
1984 for dir in . $skipdirs $noconfigdirs ; do
1985   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1986   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1987     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1988     if test -r $srcdir/$dirname/configure ; then
1989       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1990         true
1991       else
1992         notsupp="$notsupp $dir"
1993       fi
1994     fi
1995   fi
1996   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1997     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1998     if test -r $srcdir/$dirname/configure ; then
1999       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2000         true
2001       else
2002         notsupp="$notsupp $dir"
2003       fi
2004     fi
2005   fi
2006   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2007     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2008     if test -r $srcdir/$dirname/configure ; then
2009       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2010         true
2011       else
2012         notsupp="$notsupp $dir"
2013       fi
2014     fi
2015   fi
2016 done
2017
2018 # Quietly strip out all directories which aren't configurable in this tree.
2019 # This relies on all configurable subdirectories being autoconfiscated, which
2020 # is now the case.
2021 build_configdirs_all="$build_configdirs"
2022 build_configdirs=
2023 for i in ${build_configdirs_all} ; do
2024   j=`echo $i | sed -e s/build-//g`
2025   if test -f ${srcdir}/$j/configure ; then
2026     build_configdirs="${build_configdirs} $i"
2027   fi
2028 done
2029
2030 configdirs_all="$configdirs"
2031 configdirs=
2032 for i in ${configdirs_all} ; do
2033   if test -f ${srcdir}/$i/configure ; then
2034     configdirs="${configdirs} $i"
2035   fi
2036 done
2037
2038 target_configdirs_all="$target_configdirs"
2039 target_configdirs=
2040 for i in ${target_configdirs_all} ; do
2041   j=`echo $i | sed -e s/target-//g`
2042   if test -f ${srcdir}/$j/configure ; then
2043     target_configdirs="${target_configdirs} $i"
2044   fi
2045 done
2046
2047 # Produce a warning message for the subdirs we can't configure.
2048 # This isn't especially interesting in the Cygnus tree, but in the individual
2049 # FSF releases, it's important to let people know when their machine isn't
2050 # supported by the one or two programs in a package.
2051
2052 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2053   # If $appdirs is non-empty, at least one of those directories must still
2054   # be configured, or we error out.  (E.g., if the gas release supports a
2055   # specified target in some subdirs but not the gas subdir, we shouldn't
2056   # pretend that all is well.)
2057   if test -n "$appdirs" ; then
2058     for dir in $appdirs ; do
2059       if test -r $dir/Makefile.in ; then
2060         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2061           appdirs=""
2062           break
2063         fi
2064         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2065           appdirs=""
2066           break
2067         fi
2068       fi
2069     done
2070     if test -n "$appdirs" ; then
2071       echo "*** This configuration is not supported by this package." 1>&2
2072       exit 1
2073     fi
2074   fi
2075   # Okay, some application will build, or we don't care to check.  Still
2076   # notify of subdirs not getting built.
2077   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2078   echo "    ${notsupp}" 1>&2
2079   echo "    (Any other directories should still work fine.)" 1>&2
2080 fi
2081
2082 case "$host" in
2083   *msdosdjgpp*)
2084     enable_gdbtk=no ;;
2085 esac
2086
2087 # To find our prefix, in gcc_cv_tool_prefix.
2088 ACX_TOOL_DIRS
2089
2090 copy_dirs=
2091
2092 AC_ARG_WITH([build-sysroot],
2093   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2094                   [use sysroot as the system root during the build])],
2095   [if test x"$withval" != x ; then
2096      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2097    fi],
2098   [SYSROOT_CFLAGS_FOR_TARGET=])
2099 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2100
2101 AC_ARG_WITH([debug-prefix-map],
2102   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2103                   [map A to B, C to D ... in debug information])],
2104   [if test x"$withval" != x; then
2105      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2106      for debug_map in $withval; do
2107        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2108      done
2109    fi],
2110   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2111 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2112
2113 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2114 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2115 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2116 # We want to ensure that TARGET libraries (which we know are built with
2117 # gcc) are built with "-O2 -g", so include those options when setting
2118 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2119 if test "x$CFLAGS_FOR_TARGET" = x; then
2120   CFLAGS_FOR_TARGET=$CFLAGS
2121   case " $CFLAGS " in
2122     *" -O2 "*) ;;
2123     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2124   esac
2125   case " $CFLAGS " in
2126     *" -g "* | *" -g3 "*) ;;
2127     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2128   esac
2129 fi
2130 AC_SUBST(CFLAGS_FOR_TARGET)
2131
2132 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2133   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2134   case " $CXXFLAGS " in
2135     *" -O2 "*) ;;
2136     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2137   esac
2138   case " $CXXFLAGS " in
2139     *" -g "* | *" -g3 "*) ;;
2140     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2141   esac
2142 fi
2143 AC_SUBST(CXXFLAGS_FOR_TARGET)
2144
2145 AC_SUBST(LDFLAGS_FOR_TARGET)
2146
2147 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2148 # the named directory are copied to $(tooldir)/sys-include.
2149 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2150   if test x${is_cross_compiler} = xno ; then
2151     echo 1>&2 '***' --with-headers is only supported when cross compiling
2152     exit 1
2153   fi
2154   if test x"${with_headers}" != xyes ; then
2155     x=${gcc_cv_tool_prefix}
2156     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2157   fi
2158 fi
2159
2160 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2161 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2162 # are permitted.
2163 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2164   if test x${is_cross_compiler} = xno ; then
2165     echo 1>&2 '***' --with-libs is only supported when cross compiling
2166     exit 1
2167   fi
2168   if test x"${with_libs}" != xyes ; then
2169     # Copy the libraries in reverse order, so that files in the first named
2170     # library override files in subsequent libraries.
2171     x=${gcc_cv_tool_prefix}
2172     for l in ${with_libs}; do
2173       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2174     done
2175   fi
2176 fi
2177
2178 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2179 #
2180 # This is done by determining whether or not the appropriate directory
2181 # is available, and by checking whether or not specific configurations
2182 # have requested that this magic not happen.
2183 #
2184 # The command line options always override the explicit settings in
2185 # configure.in, and the settings in configure.in override this magic.
2186 #
2187 # If the default for a toolchain is to use GNU as and ld, and you don't
2188 # want to do that, then you should use the --without-gnu-as and
2189 # --without-gnu-ld options for the configure script.  Similarly, if
2190 # the default is to use the included zlib and you don't want to do that,
2191 # you should use the --with-system-zlib option for the configure script.
2192
2193 if test x${use_gnu_as} = x &&
2194    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2195   with_gnu_as=yes
2196   extra_host_args="$extra_host_args --with-gnu-as"
2197 fi
2198
2199 if test x${use_gnu_ld} = x &&
2200    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2201   with_gnu_ld=yes
2202   extra_host_args="$extra_host_args --with-gnu-ld"
2203 fi
2204
2205 if test x${use_included_zlib} = x &&
2206    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2207   :
2208 else
2209   with_system_zlib=yes
2210   extra_host_args="$extra_host_args --with-system-zlib"
2211 fi
2212
2213 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2214 # can detect this case.
2215
2216 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2217   with_newlib=yes
2218   extra_host_args="$extra_host_args --with-newlib"
2219 fi
2220
2221 # Handle ${copy_dirs}
2222 set fnord ${copy_dirs}
2223 shift
2224 while test $# != 0 ; do
2225   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2226     :
2227   else
2228     echo Copying $1 to $2
2229
2230     # Use the install script to create the directory and all required
2231     # parent directories.
2232     if test -d $2 ; then
2233       :
2234     else
2235       echo >config.temp
2236       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2237     fi
2238
2239     # Copy the directory, assuming we have tar.
2240     # FIXME: Should we use B in the second tar?  Not all systems support it.
2241     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2242
2243     # It is the responsibility of the user to correctly adjust all
2244     # symlinks.  If somebody can figure out how to handle them correctly
2245     # here, feel free to add the code.
2246
2247     echo $1 > $2/COPIED
2248   fi
2249   shift; shift
2250 done
2251
2252 # Determine a target-dependent exec_prefix that the installed
2253 # gcc will search in.  Keep this list sorted by triplet, with
2254 # the *-*-osname triplets last.
2255 md_exec_prefix=
2256 case "${target}" in
2257   i[[34567]]86-pc-msdosdjgpp*)
2258     md_exec_prefix=/dev/env/DJDIR/bin
2259     ;;
2260   *-*-hpux* | \
2261   *-*-nto-qnx* | \
2262   *-*-solaris2*)
2263     md_exec_prefix=/usr/ccs/bin
2264     ;;
2265 esac
2266
2267 extra_arflags_for_target=
2268 extra_nmflags_for_target=
2269 extra_ranlibflags_for_target=
2270 target_makefile_frag=/dev/null
2271 case "${target}" in
2272   spu-*-*)
2273     target_makefile_frag="config/mt-spu"
2274     ;;
2275   mips*-sde-elf*)
2276     target_makefile_frag="config/mt-sde"
2277     ;;
2278   mipsisa*-*-elfoabi*)
2279     target_makefile_frag="config/mt-mips-elfoabi"
2280     ;;
2281   mips*-*-*linux* | mips*-*-gnu*)
2282     target_makefile_frag="config/mt-mips-gnu"
2283     ;;
2284   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2285     target_makefile_frag="config/mt-gnu"
2286     ;;
2287   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2288     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2289     # commands to handle both 32-bit and 64-bit objects.  These flags are
2290     # harmless if we're using GNU nm or ar.
2291     extra_arflags_for_target=" -X32_64"
2292     extra_nmflags_for_target=" -B -X32_64"
2293     ;;
2294   *-*-darwin[[3-9]]*)
2295     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2296     extra_ranlibflags_for_target=" -c"
2297     ;;
2298 esac
2299
2300 alphaieee_frag=/dev/null
2301 case $target in
2302   alpha*-*-*)
2303     # This just makes sure to use the -mieee option to build target libs.
2304     # This should probably be set individually by each library.
2305     alphaieee_frag="config/mt-alphaieee"
2306     ;;
2307 esac
2308
2309 # If --enable-target-optspace always use -Os instead of -O2 to build
2310 # the target libraries, similarly if it is not specified, use -Os
2311 # on selected platforms.
2312 ospace_frag=/dev/null
2313 case "${enable_target_optspace}:${target}" in
2314   yes:*)
2315     ospace_frag="config/mt-ospace"
2316     ;;
2317   :d30v-*)
2318     ospace_frag="config/mt-d30v"
2319     ;;
2320   :m32r-* | :d10v-* | :fr30-*)
2321     ospace_frag="config/mt-ospace"
2322     ;;
2323   no:* | :*)
2324     ;;
2325   *)
2326     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2327     ;;
2328 esac
2329
2330 # Default to using --with-stabs for certain targets.
2331 if test x${with_stabs} = x ; then
2332   case "${target}" in
2333   mips*-*-irix[[56]]*)
2334     ;;
2335   mips*-*-* | alpha*-*-osf*)
2336     with_stabs=yes;
2337     extra_host_args="${extra_host_args} --with-stabs"
2338     ;;
2339   esac
2340 fi
2341
2342 # Some systems (e.g., one of the i386-aix systems the gas testers are
2343 # using) don't handle "\$" correctly, so don't use it here.
2344 tooldir='${exec_prefix}'/${target_noncanonical}
2345 build_tooldir=${tooldir}
2346
2347 # Create a .gdbinit file which runs the one in srcdir
2348 # and tells GDB to look there for source files.
2349
2350 if test -r ${srcdir}/.gdbinit ; then
2351   case ${srcdir} in
2352     .) ;;
2353     *) cat > ./.gdbinit <<EOF
2354 # ${NO_EDIT}
2355 dir ${srcdir}
2356 dir .
2357 source ${srcdir}/.gdbinit
2358 EOF
2359     ;;
2360   esac
2361 fi
2362
2363 # Make sure that the compiler is able to generate an executable.  If it
2364 # can't, we are probably in trouble.  We don't care whether we can run the
2365 # executable--we might be using a cross compiler--we only care whether it
2366 # can be created.  At this point the main configure script has set CC.
2367 we_are_ok=no
2368 echo "int main () { return 0; }" > conftest.c
2369 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2370 if test $? = 0 ; then
2371   if test -s conftest || test -s conftest.exe ; then
2372     we_are_ok=yes
2373   fi
2374 fi
2375 case $we_are_ok in
2376   no)
2377     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2378     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2379     rm -f conftest*
2380     exit 1
2381     ;;
2382 esac
2383 rm -f conftest*
2384
2385 # Decide which environment variable is used to find dynamic libraries.
2386 case "${host}" in
2387   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2388   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2389   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2390   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2391 esac
2392
2393 # On systems where the dynamic library environment variable is PATH,
2394 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2395 # built executables to PATH.
2396 if test "$RPATH_ENVVAR" = PATH; then
2397   GCC_SHLIB_SUBDIR=/shlib
2398 else
2399   GCC_SHLIB_SUBDIR=
2400 fi
2401
2402 # Record target_configdirs and the configure arguments for target and
2403 # build configuration in Makefile.
2404 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2405 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2406
2407 # If we are building libgomp, bootstrap it.
2408 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2409   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2410 fi
2411
2412 # Determine whether gdb needs tk/tcl or not.
2413 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2414 # and in that case we want gdb to be built without tk.  Ugh!
2415 # In fact I believe gdb is the *only* package directly dependent on tk,
2416 # so we should be able to put the 'maybe's in unconditionally and
2417 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2418 # 100% sure that that's safe though.
2419
2420 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2421 case "$enable_gdbtk" in
2422   no)
2423     GDB_TK="" ;;
2424   yes)
2425     GDB_TK="${gdb_tk}" ;;
2426   *)
2427     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2428     # distro.  Eventually someone will fix this and move Insight, nee
2429     # gdbtk to a separate directory.
2430     if test -d ${srcdir}/gdb/gdbtk ; then
2431       GDB_TK="${gdb_tk}"
2432     else
2433       GDB_TK=""
2434     fi
2435     ;;
2436 esac
2437 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2438 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2439
2440 # Strip out unwanted targets.
2441
2442 # While at that, we remove Makefiles if we were started for recursive
2443 # configuration, so that the top-level Makefile reconfigures them,
2444 # like we used to do when configure itself was recursive.
2445
2446 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2447 # but now we're fixing up the Makefile ourselves with the additional
2448 # commands passed to AC_CONFIG_FILES.  Use separate variables
2449 # extrasub-{build,host,target} not because there is any reason to split
2450 # the substitutions up that way, but only to remain below the limit of
2451 # 99 commands in a script, for HP-UX sed.
2452 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2453
2454 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2455   yes:yes:*\ gold\ *:*,c++,*) ;;
2456   yes:yes:*\ gold\ *:*)
2457     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2458     ;;
2459 esac
2460
2461 # Adjust the toplevel makefile according to whether bootstrap was selected.
2462 case $enable_bootstrap in
2463   yes)
2464     bootstrap_suffix=bootstrap
2465     BUILD_CONFIG=bootstrap-debug
2466     ;;
2467   no)
2468     bootstrap_suffix=no-bootstrap
2469     BUILD_CONFIG=
2470     ;;
2471 esac
2472
2473 AC_MSG_CHECKING(for default BUILD_CONFIG)
2474
2475 AC_ARG_WITH([build-config],
2476   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2477                   [use config/NAME.mk build configuration])],
2478   [case $with_build_config in
2479    yes) with_build_config= ;;
2480    no) with_build_config= BUILD_CONFIG= ;;
2481    esac])
2482
2483 if test "x${with_build_config}" != x; then
2484   BUILD_CONFIG=$with_build_config
2485 else
2486   case $BUILD_CONFIG in
2487   bootstrap-debug)
2488     if echo "int f (void) { return 0; }" > conftest.c &&
2489        ${CC} -c conftest.c &&
2490        mv conftest.o conftest.o.g0 &&
2491        ${CC} -c -g conftest.c &&
2492        mv conftest.o conftest.o.g &&
2493        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2494       :
2495     else
2496       BUILD_CONFIG=
2497     fi
2498     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2499     ;;
2500   esac
2501 fi
2502 AC_MSG_RESULT($BUILD_CONFIG)
2503 AC_SUBST(BUILD_CONFIG)
2504
2505 extrasub_build=
2506 for module in ${build_configdirs} ; do
2507   if test -z "${no_recursion}" \
2508      && test -f ${build_subdir}/${module}/Makefile; then
2509     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2510     rm -f ${build_subdir}/${module}/Makefile
2511   fi
2512   extrasub_build="$extrasub_build
2513 /^@if build-$module\$/d
2514 /^@endif build-$module\$/d
2515 /^@if build-$module-$bootstrap_suffix\$/d
2516 /^@endif build-$module-$bootstrap_suffix\$/d"
2517 done
2518 extrasub_host=
2519 for module in ${configdirs} ; do
2520   if test -z "${no_recursion}"; then
2521     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2522       if test -f ${file}; then
2523         echo 1>&2 "*** removing ${file} to force reconfigure"
2524         rm -f ${file}
2525       fi
2526     done
2527   fi
2528   extrasub_host="$extrasub_host
2529 /^@if $module\$/d
2530 /^@endif $module\$/d
2531 /^@if $module-$bootstrap_suffix\$/d
2532 /^@endif $module-$bootstrap_suffix\$/d"
2533 done
2534 extrasub_target=
2535 for module in ${target_configdirs} ; do
2536   if test -z "${no_recursion}" \
2537      && test -f ${target_subdir}/${module}/Makefile; then
2538     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2539     rm -f ${target_subdir}/${module}/Makefile
2540   fi
2541
2542   # We only bootstrap target libraries listed in bootstrap_target_libs.
2543   case $bootstrap_target_libs in
2544     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2545     *) target_bootstrap_suffix=no-bootstrap ;;
2546   esac
2547
2548   extrasub_target="$extrasub_target
2549 /^@if target-$module\$/d
2550 /^@endif target-$module\$/d
2551 /^@if target-$module-$target_bootstrap_suffix\$/d
2552 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2553 done
2554
2555 # Do the final fixup along with target modules.
2556 extrasub_target="$extrasub_target
2557 /^@if /,/^@endif /d"
2558
2559 # Create the serialization dependencies.  This uses a temporary file.
2560
2561 AC_ARG_ENABLE([serial-configure],
2562 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2563                 [force sequential configuration of
2564                  sub-packages for the host, target or build
2565                  machine, or all sub-packages])])
2566
2567 case ${enable_serial_configure} in
2568   yes)
2569     enable_serial_build_configure=yes
2570     enable_serial_host_configure=yes
2571     enable_serial_target_configure=yes
2572     ;;
2573 esac
2574
2575 # These force 'configure's to be done one at a time, to avoid problems
2576 # with contention over a shared config.cache.
2577 rm -f serdep.tmp
2578 echo '# serdep.tmp' > serdep.tmp
2579 olditem=
2580 test "x${enable_serial_build_configure}" = xyes &&
2581 for item in ${build_configdirs} ; do
2582   case ${olditem} in
2583     "") ;;
2584     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2585   esac
2586   olditem=${item}
2587 done
2588 olditem=
2589 test "x${enable_serial_host_configure}" = xyes &&
2590 for item in ${configdirs} ; do
2591   case ${olditem} in
2592     "") ;;
2593     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2594   esac
2595   olditem=${item}
2596 done
2597 olditem=
2598 test "x${enable_serial_target_configure}" = xyes &&
2599 for item in ${target_configdirs} ; do
2600   case ${olditem} in
2601     "") ;;
2602     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2603   esac
2604   olditem=${item}
2605 done
2606 serialization_dependencies=serdep.tmp
2607 AC_SUBST_FILE(serialization_dependencies)
2608
2609 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2610 # target, nonopt, and variable assignments.  These are the ones we
2611 # might not want to pass down to subconfigures.  The exception being
2612 # --cache-file=/dev/null, which is used to turn off the use of cache
2613 # files altogether, and which should be passed on to subconfigures.
2614 # Also strip program-prefix, program-suffix, and program-transform-name,
2615 # so that we can pass down a consistent program-transform-name.
2616 baseargs=
2617 tbaseargs=
2618 keep_next=no
2619 skip_next=no
2620 eval "set -- $ac_configure_args"
2621 for ac_arg
2622 do
2623   if test X"$skip_next" = X"yes"; then
2624     skip_next=no
2625     continue
2626   fi
2627   if test X"$keep_next" = X"yes"; then
2628     case $ac_arg in
2629       *\'*)
2630         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2631     esac
2632     baseargs="$baseargs '$ac_arg'"
2633     tbaseargs="$tbaseargs '$ac_arg'"
2634     keep_next=no
2635     continue
2636   fi
2637
2638   # Handle separated arguments.  Based on the logic generated by
2639   # autoconf 2.59.
2640   case $ac_arg in
2641     *=* | --config-cache | -C | -disable-* | --disable-* \
2642       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2643       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2644       | -with-* | --with-* | -without-* | --without-* | --x)
2645       separate_arg=no
2646       ;;
2647     -*)
2648       separate_arg=yes
2649       ;;
2650     *)
2651       separate_arg=no
2652       ;;
2653   esac
2654
2655   skip_targ=no
2656   case $ac_arg in
2657 changequote(,)
2658   --with-* | --without-*)
2659     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2660
2661     case $libopt in
2662     *[-_]include)
2663       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2664       ;;
2665     *[-_]lib)
2666       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2667       ;;
2668     *)
2669       lib=$libopt
2670       ;;
2671     esac
2672 changequote([,])
2673
2674     case $lib in
2675     mpc | mpfr | gmp | ppl | cloog)
2676       # If we're processing --with-$lib, --with-$lib-include or
2677       # --with-$lib-lib, for one of the libs above, and target is
2678       # different from host, don't pass the current argument to any
2679       # target library's configure.
2680       if test x$is_cross_compiler = xyes; then
2681         skip_targ=yes
2682       fi
2683       ;;
2684     esac
2685     ;;
2686   esac
2687
2688   case "$ac_arg" in
2689     --cache-file=/dev/null | \
2690     -cache-file=/dev/null )
2691       # Handled here to avoid the test to skip args below.
2692       baseargs="$baseargs '$ac_arg'"
2693       tbaseargs="$tbaseargs '$ac_arg'"
2694       # Assert: $separate_arg should always be no.
2695       keep_next=$separate_arg
2696       ;;
2697     --no*)
2698       continue
2699       ;;
2700     --c* | \
2701     --sr* | \
2702     --ho* | \
2703     --bu* | \
2704     --t* | \
2705     --program-* | \
2706     -cache_file* | \
2707     -srcdir* | \
2708     -host* | \
2709     -build* | \
2710     -target* | \
2711     -program-prefix* | \
2712     -program-suffix* | \
2713     -program-transform-name* )
2714       skip_next=$separate_arg
2715       continue
2716       ;;
2717     -*)
2718       # An option.  Add it.
2719       case $ac_arg in
2720         *\'*)
2721           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2722       esac
2723       baseargs="$baseargs '$ac_arg'"
2724       if test X"$skip_targ" = Xno; then
2725         tbaseargs="$tbaseargs '$ac_arg'"
2726       fi
2727       keep_next=$separate_arg
2728       ;;
2729     *)
2730       # Either a variable assignment, or a nonopt (triplet).  Don't
2731       # pass it down; let the Makefile handle this.
2732       continue
2733       ;;
2734   esac
2735 done
2736 # Remove the initial space we just introduced and, as these will be
2737 # expanded by make, quote '$'.
2738 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2739
2740 # Add in --program-transform-name, after --program-prefix and
2741 # --program-suffix have been applied to it.  Autoconf has already
2742 # doubled dollar signs and backslashes in program_transform_name; we want
2743 # the backslashes un-doubled, and then the entire thing wrapped in single
2744 # quotes, because this will be expanded first by make and then by the shell.
2745 # Also, because we want to override the logic in subdir configure scripts to
2746 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2747 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2748 ${program_transform_name}
2749 EOF_SED
2750 gcc_transform_name=`cat conftestsed.out`
2751 rm -f conftestsed.out
2752 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2753 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2754 if test "$silent" = yes; then
2755   baseargs="$baseargs --silent"
2756   tbaseargs="$tbaseargs --silent"
2757 fi
2758 baseargs="$baseargs --disable-option-checking"
2759 tbaseargs="$tbaseargs --disable-option-checking"
2760
2761 # Record and document user additions to sub configure arguments.
2762 AC_ARG_VAR([build_configargs],
2763            [additional configure arguments for build directories])
2764 AC_ARG_VAR([host_configargs],
2765            [additional configure arguments for host directories])
2766 AC_ARG_VAR([target_configargs],
2767            [additional configure arguments for target directories])
2768
2769 # For the build-side libraries, we just need to pretend we're native,
2770 # and not use the same cache file.  Multilibs are neither needed nor
2771 # desired.
2772 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2773
2774 # For host modules, accept cache file option, or specification as blank.
2775 case "${cache_file}" in
2776 "") # empty
2777   cache_file_option="" ;;
2778 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2779   cache_file_option="--cache-file=${cache_file}" ;;
2780 *) # relative path
2781   cache_file_option="--cache-file=../${cache_file}" ;;
2782 esac
2783
2784 # Host dirs don't like to share a cache file either, horribly enough.
2785 # This seems to be due to autoconf 2.5x stupidity.
2786 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2787
2788 target_configargs="$target_configargs ${tbaseargs}"
2789
2790 # Passing a --with-cross-host argument lets the target libraries know
2791 # whether they are being built with a cross-compiler or being built
2792 # native.  However, it would be better to use other mechanisms to make the
2793 # sorts of decisions they want to make on this basis.  Please consider
2794 # this option to be deprecated.  FIXME.
2795 if test x${is_cross_compiler} = xyes ; then
2796   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2797 fi
2798
2799 # Default to --enable-multilib.
2800 if test x${enable_multilib} = x ; then
2801   target_configargs="--enable-multilib ${target_configargs}"
2802 fi
2803
2804 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2805 # changed from the earlier setting of with_newlib.
2806 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2807   target_configargs="--with-newlib ${target_configargs}"
2808 fi
2809
2810 # Different target subdirs use different values of certain variables
2811 # (notably CXX).  Worse, multilibs use *lots* of different values.
2812 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2813 # it doesn't automatically accept command-line overrides of them.
2814 # This means it's not safe for target subdirs to share a cache file,
2815 # which is disgusting, but there you have it.  Hopefully this can be
2816 # fixed in future.  It's still worthwhile to use a cache file for each
2817 # directory.  I think.
2818
2819 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2820 # We need to pass --target, as newer autoconf's requires consistency
2821 # for target_alias and gcc doesn't manage it consistently.
2822 target_configargs="--cache-file=./config.cache ${target_configargs}"
2823
2824 FLAGS_FOR_TARGET=
2825 case " $target_configdirs " in
2826  *" newlib "*)
2827   case " $target_configargs " in
2828   *" --with-newlib "*)
2829    case "$target" in
2830     *-cygwin*)
2831       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2832       ;;
2833    esac
2834
2835    # If we're not building GCC, don't discard standard headers.
2836    if test -d ${srcdir}/gcc; then
2837      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2838
2839      if test "${build}" != "${host}"; then
2840        # On Canadian crosses, CC_FOR_TARGET will have already been set
2841        # by `configure', so we won't have an opportunity to add -Bgcc/
2842        # to it.  This is right: we don't want to search that directory
2843        # for binaries, but we want the header files in there, so add
2844        # them explicitly.
2845        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2846
2847        # Someone might think of using the pre-installed headers on
2848        # Canadian crosses, in case the installed compiler is not fully
2849        # compatible with the compiler being built.  In this case, it
2850        # would be better to flag an error than risking having
2851        # incompatible object files being constructed.  We can't
2852        # guarantee that an error will be flagged, but let's hope the
2853        # compiler will do it, when presented with incompatible header
2854        # files.
2855      fi
2856    fi
2857
2858    case "${target}-${is_cross_compiler}" in
2859    i[[3456789]]86-*-linux*-no)
2860       # Here host == target, so we don't need to build gcc,
2861       # so we don't want to discard standard headers.
2862       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2863       ;;
2864    *)
2865       # If we're building newlib, use its generic headers last, but search
2866       # for any libc-related directories first (so make it the last -B
2867       # switch).
2868       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2869
2870       # If we're building libgloss, find the startup file, simulator library
2871       # and linker script.
2872       case " $target_configdirs " in
2873         *" libgloss "*)
2874         # Look for startup file, simulator library and maybe linker script.
2875         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2876         # Look for libnosys.a in case the target needs it.
2877         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2878         # Most targets have the linker script in the source directory.
2879         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2880         ;;
2881       esac
2882       ;;
2883    esac
2884    ;;
2885   esac
2886   ;;
2887 esac
2888
2889 case "$target" in
2890   x86_64-*mingw* | *-w64-mingw*)
2891   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2892   # however, use a symlink named 'mingw' in ${prefix} .
2893     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2894     ;;
2895   *-mingw*)
2896   # MinGW can't be handled as Cygwin above since it does not use newlib.
2897     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2898     ;;
2899 esac
2900
2901 # Allow the user to override the flags for
2902 # our build compiler if desired.
2903 if test x"${build}" = x"${host}" ; then
2904   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2905   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2906   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2907 fi
2908
2909 # On Canadian crosses, we'll be searching the right directories for
2910 # the previously-installed cross compiler, so don't bother to add
2911 # flags for directories within the install tree of the compiler
2912 # being built; programs in there won't even run.
2913 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2914   # Search for pre-installed headers if nothing else fits.
2915   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2916 fi
2917
2918 if test "x${use_gnu_ld}" = x &&
2919    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2920   # Arrange for us to find uninstalled linker scripts.
2921   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2922 fi
2923
2924 # Search for other target-specific linker scripts and such.
2925 case "${target}" in
2926   mep*)
2927     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2928     ;;
2929 esac
2930
2931 # Makefile fragments.
2932 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2933 do
2934   eval fragval=\$$frag
2935   if test $fragval != /dev/null; then
2936     eval $frag=${srcdir}/$fragval
2937   fi
2938 done
2939 AC_SUBST_FILE(host_makefile_frag)
2940 AC_SUBST_FILE(target_makefile_frag)
2941 AC_SUBST_FILE(alphaieee_frag)
2942 AC_SUBST_FILE(ospace_frag)
2943
2944 # Miscellanea: directories, flags, etc.
2945 AC_SUBST(RPATH_ENVVAR)
2946 AC_SUBST(GCC_SHLIB_SUBDIR)
2947 AC_SUBST(tooldir)
2948 AC_SUBST(build_tooldir)
2949 AC_SUBST(CONFIGURE_GDB_TK)
2950 AC_SUBST(GDB_TK)
2951 AC_SUBST(INSTALL_GDB_TK)
2952
2953 # Build module lists & subconfigure args.
2954 AC_SUBST(build_configargs)
2955 AC_SUBST(build_configdirs)
2956
2957 # Host module lists & subconfigure args.
2958 AC_SUBST(host_configargs)
2959 AC_SUBST(configdirs)
2960 AC_SUBST(target_configdirs)
2961
2962 # Target module lists & subconfigure args.
2963 AC_SUBST(target_configargs)
2964
2965
2966 # Build tools.
2967 AC_SUBST(AR_FOR_BUILD)
2968 AC_SUBST(AS_FOR_BUILD)
2969 AC_SUBST(CC_FOR_BUILD)
2970 AC_SUBST(CFLAGS_FOR_BUILD)
2971 AC_SUBST(CXXFLAGS_FOR_BUILD)
2972 AC_SUBST(CXX_FOR_BUILD)
2973 AC_SUBST(DLLTOOL_FOR_BUILD)
2974 AC_SUBST(GCJ_FOR_BUILD)
2975 AC_SUBST(GFORTRAN_FOR_BUILD)
2976 AC_SUBST(GOC_FOR_BUILD)
2977 AC_SUBST(LDFLAGS_FOR_BUILD)
2978 AC_SUBST(LD_FOR_BUILD)
2979 AC_SUBST(NM_FOR_BUILD)
2980 AC_SUBST(RANLIB_FOR_BUILD)
2981 AC_SUBST(WINDMC_FOR_BUILD)
2982 AC_SUBST(WINDRES_FOR_BUILD)
2983
2984 # Generate default definitions for YACC, M4, LEX and other programs that run
2985 # on the build machine.  These are used if the Makefile can't locate these
2986 # programs in objdir.
2987 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2988
2989 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2990 case " $build_configdirs " in
2991   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2992 esac
2993
2994 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2995 case " $build_configdirs " in
2996   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2997 esac
2998
2999 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3000 case " $build_configdirs " in
3001   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3002 esac
3003
3004 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3005 case " $build_configdirs " in
3006   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3007   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3008 esac
3009
3010 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3011 case " $build_configdirs " in
3012   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3013 esac
3014
3015 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3016 case " $build_configdirs " in
3017   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3018   *)
3019 changequote(,)
3020     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3021     # higher, else we use the "missing" dummy.
3022     if ${MAKEINFO} --version \
3023        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3024       :
3025     else
3026       MAKEINFO="$MISSING makeinfo"
3027     fi
3028     ;;
3029 changequote([,])
3030 esac
3031
3032 # FIXME: expect and dejagnu may become build tools?
3033
3034 AC_CHECK_PROGS(EXPECT, expect, expect)
3035 case " $configdirs " in
3036   *" expect "*)
3037     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3038     ;;
3039 esac
3040
3041 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3042 case " $configdirs " in
3043   *" dejagnu "*)
3044     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3045     ;;
3046 esac
3047
3048
3049 # Host tools.
3050 NCN_STRICT_CHECK_TOOLS(AR, ar)
3051 NCN_STRICT_CHECK_TOOLS(AS, as)
3052 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3053 NCN_STRICT_CHECK_TOOLS(LD, ld)
3054 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3055 NCN_STRICT_CHECK_TOOLS(NM, nm)
3056 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3057 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3058 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3059 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3060 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3061 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3062 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3063 AC_SUBST(CC)
3064 AC_SUBST(CXX)
3065 AC_SUBST(CFLAGS)
3066 AC_SUBST(CXXFLAGS)
3067
3068 # Target tools.
3069 AC_ARG_WITH([build-time-tools],
3070   [AS_HELP_STRING([--with-build-time-tools=PATH],
3071                   [use given path to find target tools during the build])],
3072   [case x"$withval" in
3073      x/*) ;;
3074      *)
3075        with_build_time_tools=
3076        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3077        ;;
3078    esac],
3079   [with_build_time_tools=])
3080
3081 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3082 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3083 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3084 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3085 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3086 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3087
3088 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3089 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3095 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3096 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3097 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3098 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3099 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3100
3101 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3102
3103 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3104 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3105 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3106 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3107 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3108                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3109                 c++)
3110 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3111                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3112                 c++)
3113 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3114 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3115 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3116                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3117 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3118                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3119 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3120                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3121 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3122 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3123 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3124 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3125 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3126 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3127 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3128 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3129 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3130
3131 AC_SUBST(FLAGS_FOR_TARGET)
3132 AC_SUBST(RAW_CXX_FOR_TARGET)
3133
3134 # Certain tools may need extra flags.
3135 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3136 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3137 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3138
3139 # When building target libraries, except in a Canadian cross, we use
3140 # the same toolchain as the compiler we just built.
3141 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3142 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3143 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3144 if test $host = $build; then
3145   case " $configdirs " in
3146     *" gcc "*)
3147       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3148       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3149       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3150       ;;
3151   esac
3152 fi
3153
3154 AC_SUBST(COMPILER_AS_FOR_TARGET)
3155 AC_SUBST(COMPILER_LD_FOR_TARGET)
3156 AC_SUBST(COMPILER_NM_FOR_TARGET)
3157
3158 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3159 AC_ARG_ENABLE(maintainer-mode,
3160 [AS_HELP_STRING([--enable-maintainer-mode],
3161                 [enable make rules and dependencies not useful
3162                  (and sometimes confusing) to the casual installer])],
3163       USE_MAINTAINER_MODE=$enableval,
3164       USE_MAINTAINER_MODE=no)
3165 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3166 AC_SUBST(MAINTAINER_MODE_TRUE)
3167 AC_SUBST(MAINTAINER_MODE_FALSE)
3168 if test "$USE_MAINTAINER_MODE" = yes; then
3169   MAINTAINER_MODE_TRUE=
3170   MAINTAINER_MODE_FALSE='#'
3171 else
3172   MAINTAINER_MODE_TRUE='#'
3173   MAINTAINER_MODE_FALSE=
3174 fi
3175 MAINT=$MAINTAINER_MODE_TRUE
3176 AC_SUBST(MAINT)dnl
3177
3178 # ---------------------
3179 # GCC bootstrap support
3180 # ---------------------
3181
3182 # Stage specific cflags for build.
3183 stage1_cflags="-g"
3184 case $build in
3185   vax-*-*)
3186     case ${GCC} in
3187       yes) stage1_cflags="-g -Wa,-J" ;;
3188       *) stage1_cflags="-g -J" ;;
3189     esac ;;
3190 esac
3191
3192 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3193 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3194   saved_CFLAGS="$CFLAGS"
3195
3196   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3197   CFLAGS="$CFLAGS -fkeep-inline-functions"
3198   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3199   AC_TRY_COMPILE([
3200 #if (__GNUC__ < 3) \
3201     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3202                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3203 #error http://gcc.gnu.org/PR29382
3204 #endif
3205     ],,
3206     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3207     [AC_MSG_RESULT([no])])
3208
3209   CFLAGS="$saved_CFLAGS"
3210 fi
3211
3212 AC_SUBST(stage1_cflags)
3213
3214 # Enable --enable-checking in stage1 of the compiler.
3215 AC_ARG_ENABLE(stage1-checking,
3216 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3217                 [choose additional checking for stage1 of the compiler])],
3218 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3219 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3220   stage1_checking=--enable-checking=yes,types
3221 else
3222   stage1_checking=--enable-checking=$enable_checking,types
3223 fi])
3224 AC_SUBST(stage1_checking)
3225
3226 # Enable -Werror in bootstrap stage2 and later.
3227 AC_ARG_ENABLE(werror,
3228 [AS_HELP_STRING([--enable-werror],
3229                 [enable -Werror in bootstrap stage2 and later])], [],
3230 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3231   enable_werror=yes
3232 else
3233   enable_werror=no
3234 fi])
3235 case ${enable_werror} in
3236   yes) stage2_werror_flag="--enable-werror-always" ;;
3237   *) stage2_werror_flag="" ;;
3238 esac
3239 AC_SUBST(stage2_werror_flag)
3240
3241 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3242 # --enable-build-with-cxx after stage1.
3243 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3244   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3245 else
3246   POSTSTAGE1_CONFIGURE_FLAGS=
3247 fi
3248 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3249
3250 # Specify what files to not compare during bootstrap.
3251
3252 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3253 case "$target" in
3254   hppa*64*-*-hpux*) ;;
3255   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3256 esac
3257 case " $configdirs " in
3258 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3259 esac
3260 AC_SUBST(compare_exclusions)
3261
3262 AC_CONFIG_FILES([Makefile],
3263   [sed "$extrasub_build" Makefile |
3264    sed "$extrasub_host" |
3265    sed "$extrasub_target" > mf$$
3266    mv -f mf$$ Makefile],
3267   [extrasub_build="$extrasub_build"
3268    extrasub_host="$extrasub_host"
3269    extrasub_target="$extrasub_target"])
3270 AC_OUTPUT