configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n'])])
   8 m4_ifval(mesa_version,[],[
   9     m4_errprint([Error: Failed to get the Mesa version from the output of
  10        running `make -f bin/version.mk version'
  11 ])
  12     m4_exit([1])
  13 ])
  14
  15 dnl Tell the user about autoconf.html in the --help output
  16 m4_divert_once([HELP_END], [
  17 See docs/autoconf.html for more details on the options for Mesa.])
  18
  19 AC_INIT([Mesa],[mesa_version],
  20     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  21 AC_CONFIG_AUX_DIR([bin])
  22 AC_CANONICAL_HOST
  23
  24 dnl Versions for external dependencies
  25 LIBDRM_REQUIRED=2.4.3
  26 DRI2PROTO_REQUIRED=1.99.3
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl We need a POSIX shell for parts of the build. Assume we have one
  37 dnl in most cases.
  38 case "$host_os" in
  39 solaris*)
  40     # Solaris /bin/sh is too old/non-POSIX compliant
  41     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  42     SHELL="$POSIX_SHELL"
  43     ;;
  44 esac
  45
  46 MKDEP_OPTIONS=-fdepend
  47 dnl Ask gcc where it's keeping its secret headers
  48 if test "x$GCC" = xyes; then
  49     for dir in include include-fixed; do
  50         GCC_INCLUDES=`$CC -print-file-name=$dir`
  51         if test "x$GCC_INCLUDES" != x && \
  52            test "$GCC_INCLUDES" != "$dir" && \
  53            test -d "$GCC_INCLUDES"; then
  54             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  55         fi
  56     done
  57 fi
  58 AC_SUBST([MKDEP_OPTIONS])
  59
  60 dnl Make sure the pkg-config macros are defined
  61 m4_ifdef([PKG_PROG_PKG_CONFIG],[],[
  62     m4_errprint([Error: Could not locate the pkg-config autoconf macros.
  63        These are usually located in /usr/share/aclocal/pkg.m4. If your
  64        macros are in a different location, try setting the environment
  65        variable ACLOCAL="aclocal -I/other/macro/dir" before running
  66        autoreconf.
  67 ])
  68     m4_exit([1])
  69 ])
  70 PKG_PROG_PKG_CONFIG()
  71
  72 dnl LIB_DIR - library basename
  73 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  74 AC_SUBST([LIB_DIR])
  75
  76 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
  77 _SAVE_LDFLAGS="$LDFLAGS"
  78 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
  79 AC_SUBST([EXTRA_LIB_PATH])
  80
  81 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
  82 _SAVE_CPPFLAGS="$CPPFLAGS"
  83 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
  84 AC_SUBST([X11_INCLUDES])
  85
  86 dnl Compiler macros
  87 DEFINES=""
  88 AC_SUBST([DEFINES])
  89 case "$host_os" in
  90 *-gnu*)
  91     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
  92     ;;
  93 solaris*)
  94     DEFINES="$DEFINES -DPTHREADS -DSVR4"
  95     ;;
  96 esac
  97
  98 dnl Add flags for gcc and g++
  99 if test "x$GCC" = xyes; then
 100     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 101
 102     # Work around aliasing bugs - developers should comment this out
 103     CFLAGS="$CFLAGS -fno-strict-aliasing"
 104 fi
 105 if test "x$GXX" = xyes; then
 106     CXXFLAGS="$CXXFLAGS -Wall"
 107
 108     # Work around aliasing bugs - developers should comment this out
 109     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 110 fi
 111
 112 dnl These should be unnecessary, but let the user set them if they want
 113 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 114     Default is to use CFLAGS.])
 115 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 116     compiler. Default is to use CFLAGS.])
 117 AC_SUBST([OPT_FLAGS])
 118 AC_SUBST([ARCH_FLAGS])
 119
 120 dnl
 121 dnl Hacks to enable 32 or 64 bit build
 122 dnl
 123 AC_ARG_ENABLE([32-bit],
 124     [AS_HELP_STRING([--enable-32-bit],
 125         [build 32-bit libraries @<:@default=auto@:>@])],
 126     [enable_32bit="$enableval"],
 127     [enable_32bit=auto]
 128 )
 129 if test "x$enable_32bit" = xyes; then
 130     if test "x$GCC" = xyes; then
 131         CFLAGS="$CFLAGS -m32"
 132     fi
 133     if test "x$GXX" = xyes; then
 134         CXXFLAGS="$CXXFLAGS -m32"
 135     fi
 136 fi
 137 AC_ARG_ENABLE([64-bit],
 138     [AS_HELP_STRING([--enable-64-bit],
 139         [build 64-bit libraries @<:@default=auto@:>@])],
 140     [enable_64bit="$enableval"],
 141     [enable_64bit=auto]
 142 )
 143 if test "x$enable_64bit" = xyes; then
 144     if test "x$GCC" = xyes; then
 145         CFLAGS="$CFLAGS -m64"
 146     fi
 147     if test "x$GXX" = xyes; then
 148         CXXFLAGS="$CXXFLAGS -m64"
 149     fi
 150 fi
 151
 152 dnl
 153 dnl shared/static libraries, mimic libtool options
 154 dnl
 155 AC_ARG_ENABLE([static],
 156     [AS_HELP_STRING([--enable-static],
 157         [build static libraries @<:@default=disabled@:>@])],
 158     [enable_static="$enableval"],
 159     [enable_static=no]
 160 )
 161 case "x$enable_static" in
 162 xyes|xno ) ;;
 163 x ) enable_static=no ;;
 164 * )
 165     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 166     ;;
 167 esac
 168 AC_ARG_ENABLE([shared],
 169     [AS_HELP_STRING([--disable-shared],
 170         [build shared libraries @<:@default=enabled@:>@])],
 171     [enable_shared="$enableval"],
 172     [enable_shared=yes]
 173 )
 174 case "x$enable_shared" in
 175 xyes|xno ) ;;
 176 x ) enable_shared=yes ;;
 177 * )
 178     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 179     ;;
 180 esac
 181
 182 dnl Can't have static and shared libraries, default to static if user
 183 dnl explicitly requested. If both disabled, set to static since shared
 184 dnl was explicitly requirested.
 185 case "x$enable_static$enable_shared" in
 186 xyesyes )
 187     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 188     enable_shared=no
 189     ;;
 190 xnono )
 191     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 192     enable_static=yes
 193     ;;
 194 esac
 195
 196 dnl
 197 dnl mklib options
 198 dnl
 199 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 200 if test "$enable_static" = yes; then
 201     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 202 fi
 203 AC_SUBST([MKLIB_OPTIONS])
 204
 205 dnl
 206 dnl other compiler options
 207 dnl
 208 AC_ARG_ENABLE([debug],
 209     [AS_HELP_STRING([--enable-debug],
 210         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 211     [enable_debug="$enableval"],
 212     [enable_debug=no]
 213 )
 214 if test "x$enable_debug" = xyes; then
 215     DEFINES="$DEFINES -DDEBUG"
 216     if test "x$GCC" = xyes; then
 217         CFLAGS="$CFLAGS -g"
 218     fi
 219     if test "x$GXX" = xyes; then
 220         CXXFLAGS="$CXXFLAGS -g"
 221     fi
 222 fi
 223
 224 dnl
 225 dnl library names
 226 dnl
 227 if test "$enable_static" = yes; then
 228     LIB_EXTENSION='a'
 229 else
 230     case "$host_os" in
 231     darwin* )
 232         LIB_EXTENSION='dylib' ;;
 233     * )
 234         LIB_EXTENSION='so' ;;
 235     esac
 236 fi
 237
 238 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 239 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 240 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 241 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 242 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 243
 244 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 245 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 246 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 247 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 248 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 249
 250 AC_SUBST([GL_LIB_NAME])
 251 AC_SUBST([GLU_LIB_NAME])
 252 AC_SUBST([GLUT_LIB_NAME])
 253 AC_SUBST([GLW_LIB_NAME])
 254 AC_SUBST([OSMESA_LIB_NAME])
 255
 256 AC_SUBST([GL_LIB_GLOB])
 257 AC_SUBST([GLU_LIB_GLOB])
 258 AC_SUBST([GLUT_LIB_GLOB])
 259 AC_SUBST([GLW_LIB_GLOB])
 260 AC_SUBST([OSMESA_LIB_GLOB])
 261
 262 dnl
 263 dnl Arch/platform-specific settings
 264 dnl
 265 AC_ARG_ENABLE([asm],
 266     [AS_HELP_STRING([--disable-asm],
 267         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 268     [enable_asm="$enableval"],
 269     [enable_asm=yes]
 270 )
 271 asm_arch=""
 272 ASM_FLAGS=""
 273 MESA_ASM_SOURCES=""
 274 GLAPI_ASM_SOURCES=""
 275 AC_MSG_CHECKING([whether to enable assembly])
 276 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 277 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 278 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 279     case "$host_cpu" in
 280     i?86 | x86_64)
 281         enable_asm=no
 282         AC_MSG_RESULT([no, cross compiling])
 283         ;;
 284     esac
 285 fi
 286 # check for supported arches
 287 if test "x$enable_asm" = xyes; then
 288     case "$host_cpu" in
 289     i?86)
 290         case "$host_os" in
 291         linux* | *freebsd* | dragonfly*)
 292             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 293             ;;
 294         esac
 295         ;;
 296     x86_64)
 297         case "$host_os" in
 298         linux* | *freebsd* | dragonfly*)
 299             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 300             ;;
 301         esac
 302         ;;
 303     powerpc)
 304         case "$host_os" in
 305         linux*)
 306             asm_arch=ppc
 307             ;;
 308         esac
 309         ;;
 310     esac
 311
 312     case "$asm_arch" in
 313     x86)
 314         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 315         MESA_ASM_SOURCES='$(X86_SOURCES)'
 316         GLAPI_ASM_SOURCES='$(X86_API)'
 317         AC_MSG_RESULT([yes, x86])
 318         ;;
 319     x86_64)
 320         ASM_FLAGS="-DUSE_X86_64_ASM"
 321         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 322         GLAPI_ASM_SOURCES='$(X86-64_API)'
 323         AC_MSG_RESULT([yes, x86_64])
 324         ;;
 325     ppc)
 326         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 327         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 328         AC_MSG_RESULT([yes, ppc])
 329         ;;
 330     *)
 331         AC_MSG_RESULT([no, platform not supported])
 332         ;;
 333     esac
 334 fi
 335 AC_SUBST([ASM_FLAGS])
 336 AC_SUBST([MESA_ASM_SOURCES])
 337 AC_SUBST([GLAPI_ASM_SOURCES])
 338
 339 dnl PIC code macro
 340 MESA_PIC_FLAGS
 341
 342 dnl Check to see if dlopen is in default libraries (like Solaris, which
 343 dnl has it in libc), or if libdl is needed to get it.
 344 AC_CHECK_FUNC([dlopen], [],
 345     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 346
 347 dnl See if posix_memalign is available
 348 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 349
 350 dnl SELinux awareness.
 351 AC_ARG_ENABLE([selinux],
 352     [AS_HELP_STRING([--enable-selinux],
 353         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 354     [MESA_SELINUX="$enableval"],
 355     [MESA_SELINUX=no])
 356 if test "x$enable_selinux" = "xyes"; then
 357     AC_CHECK_HEADER([selinux/selinux.h],[],
 358                     [AC_MSG_ERROR([SELinux headers not found])])
 359     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 360                  [AC_MSG_ERROR([SELinux library not found])])
 361     SELINUX_LIBS="-lselinux"
 362     DEFINES="$DEFINES -DMESA_SELINUX"
 363 fi
 364
 365 dnl OS-specific libraries
 366 OS_LIBS=""
 367 case "$host_os" in
 368 solaris*)
 369     OS_LIBS="-lc"
 370     if test "x$GXX" != xyes; then
 371         OS_CPLUSPLUS_LIBS="-lCrun $OS_LIBS"
 372     fi
 373     ;;
 374 esac
 375
 376 dnl
 377 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 378 dnl More later: directfb, fbdev, ...
 379 dnl
 380 default_driver="xlib"
 381
 382 case "$host_os" in
 383 linux*)
 384     case "$host_cpu" in
 385     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 386     esac
 387     ;;
 388 *freebsd* | dragonfly*)
 389     case "$host_cpu" in
 390     i*86|x86_64) default_driver="dri";;
 391     esac
 392     ;;
 393 esac
 394
 395 AC_ARG_WITH([driver],
 396     [AS_HELP_STRING([--with-driver=DRIVER],
 397         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 398     [mesa_driver="$withval"],
 399     [mesa_driver="$default_driver"])
 400 dnl Check for valid option
 401 case "x$mesa_driver" in
 402 xxlib|xdri|xosmesa)
 403     ;;
 404 *)
 405     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 406     ;;
 407 esac
 408
 409 dnl
 410 dnl Driver specific build directories
 411 dnl
 412 SRC_DIRS="mesa egl glew"
 413 GLU_DIRS="sgi"
 414 WINDOW_SYSTEM=""
 415 GALLIUM_DIRS="auxiliary drivers state_trackers"
 416 GALLIUM_WINSYS_DIRS=""
 417 GALLIUM_WINSYS_DRM_DIRS=""
 418 GALLIUM_AUXILIARY_DIRS="draw translate cso_cache pipebuffer tgsi sct rtasm util"
 419 GALLIUM_DRIVERS_DIRS="softpipe failover trace"
 420 GALLIUM_STATE_TRACKERS_DIRS=""
 421
 422 case "$mesa_driver" in
 423 xlib)
 424     DRIVER_DIRS="x11"
 425     ;;
 426 dri)
 427     SRC_DIRS="glx/x11 $SRC_DIRS"
 428     DRIVER_DIRS="dri"
 429     WINDOW_SYSTEM="dri"
 430     GALLIUM_WINSYS_DIRS="drm $GALLIUM_WINSYS_DIRS"
 431     ;;
 432 osmesa)
 433     DRIVER_DIRS="osmesa"
 434     ;;
 435 esac
 436 AC_SUBST([SRC_DIRS])
 437 AC_SUBST([GLU_DIRS])
 438 AC_SUBST([DRIVER_DIRS])
 439 AC_SUBST([WINDOW_SYSTEM])
 440 AC_SUBST([GALLIUM_DIRS])
 441 AC_SUBST([GALLIUM_WINSYS_DIRS])
 442 AC_SUBST([GALLIUM_WINSYS_DRM_DIRS])
 443 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 444 AC_SUBST([GALLIUM_AUXILIARY_DIRS])
 445 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 446
 447 dnl
 448 dnl User supplied program configuration
 449 dnl
 450 if test -d "$srcdir/progs/demos"; then
 451     default_demos=yes
 452 else
 453     default_demos=no
 454 fi
 455 AC_ARG_WITH([demos],
 456     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 457         [optional comma delimited demo directories to build
 458         @<:@default=auto if source available@:>@])],
 459     [with_demos="$withval"],
 460     [with_demos="$default_demos"])
 461 if test "x$with_demos" = x; then
 462     with_demos=no
 463 fi
 464
 465 dnl If $with_demos is yes, directories will be added as libs available
 466 PROGRAM_DIRS=""
 467 case "$with_demos" in
 468 no) ;;
 469 yes)
 470     # If the driver isn't osmesa, we have libGL and can build xdemos
 471     if test "$mesa_driver" != osmesa; then
 472         PROGRAM_DIRS="xdemos"
 473     fi
 474     ;;
 475 *)
 476     # verify the requested demos directories exist
 477     demos=`IFS=,; echo $with_demos`
 478     for demo in $demos; do
 479         test -d "$srcdir/progs/$demo" || \
 480             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 481     done
 482     PROGRAM_DIRS="$demos"
 483     ;;
 484 esac
 485
 486 dnl
 487 dnl Find out if X is available. The variable have_x is set if libX11 is
 488 dnl found to mimic AC_PATH_XTRA.
 489 dnl
 490 if test -n "$PKG_CONFIG"; then
 491     AC_MSG_CHECKING([pkg-config files for X11 are available])
 492     PKG_CHECK_EXISTS([x11],[
 493         x11_pkgconfig=yes
 494         have_x=yes
 495         ],[
 496         x11_pkgconfig=no
 497     ])
 498     AC_MSG_RESULT([$x11_pkgconfig])
 499 else
 500     x11_pkgconfig=no
 501 fi
 502 dnl Use the autoconf macro if no pkg-config files
 503 if test "$x11_pkgconfig" = no; then
 504     AC_PATH_XTRA
 505 fi
 506
 507 dnl Try to tell the user that the --x-* options are only used when
 508 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 509 m4_divert_once([HELP_BEGIN],
 510 [These options are only used when the X libraries cannot be found by the
 511 pkg-config utility.])
 512
 513 dnl We need X for xlib and dri, so bomb now if it's not found
 514 case "$mesa_driver" in
 515 xlib|dri)
 516     if test "$no_x" = yes; then
 517         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 518     fi
 519     ;;
 520 esac
 521
 522 dnl XCB - this is only used for GLX right now
 523 AC_ARG_ENABLE([xcb],
 524     [AS_HELP_STRING([--enable-xcb],
 525         [use XCB for GLX @<:@default=disabled@:>@])],
 526     [enable_xcb="$enableval"],
 527     [enable_xcb=no])
 528 if test "x$enable_xcb" = xyes; then
 529     DEFINES="$DEFINES -DUSE_XCB"
 530 else
 531     enable_xcb=no
 532 fi
 533
 534 dnl
 535 dnl libGL configuration per driver
 536 dnl
 537 case "$mesa_driver" in
 538 xlib)
 539     if test "$x11_pkgconfig" = yes; then
 540         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 541         GL_PC_REQ_PRIV="x11 xext"
 542         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 543         GL_LIB_DEPS="$XLIBGL_LIBS"
 544     else
 545         # should check these...
 546         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 547         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 548         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 549         GL_PC_CFLAGS="$X11_INCLUDES"
 550     fi
 551     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 552     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $OS_LIBS"
 553
 554     # if static, move the external libraries to the programs
 555     # and empty the libraries for libGL
 556     if test "$enable_static" = yes; then
 557         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 558         GL_LIB_DEPS=""
 559     fi
 560     ;;
 561 dri)
 562     # DRI must be shared, I think
 563     if test "$enable_static" = yes; then
 564         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 565     fi
 566
 567     # Check for libdrm
 568     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 569     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 570     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 571     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 572
 573     # find the DRI deps for libGL
 574     if test "$x11_pkgconfig" = yes; then
 575         # add xcb modules if necessary
 576         dri_modules="x11 xext xxf86vm xdamage xfixes"
 577         if test "$enable_xcb" = yes; then
 578             dri_modules="$dri_modules x11-xcb xcb-glx"
 579         fi
 580
 581         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 582         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 583         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 584         GL_LIB_DEPS="$DRIGL_LIBS"
 585     else
 586         # should check these...
 587         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 588         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 589         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 590         GL_PC_CFLAGS="$X11_INCLUDES"
 591
 592         # XCB can only be used from pkg-config
 593         if test "$enable_xcb" = yes; then
 594             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 595             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 596             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 597             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 598         fi
 599     fi
 600
 601     # need DRM libs, -lpthread, etc.
 602     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 603     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS $OS_LIBS"
 604     ;;
 605 osmesa)
 606     # No libGL for osmesa
 607     GL_LIB_DEPS="$OS_LIBS"
 608     ;;
 609 esac
 610 AC_SUBST([GL_LIB_DEPS])
 611 AC_SUBST([GL_PC_REQ_PRIV])
 612 AC_SUBST([GL_PC_LIB_PRIV])
 613 AC_SUBST([GL_PC_CFLAGS])
 614 AC_SUBST([DRI_PC_REQ_PRIV])
 615
 616 dnl
 617 dnl More X11 setup
 618 dnl
 619 if test "$mesa_driver" = xlib; then
 620     DEFINES="$DEFINES -DUSE_XSHM"
 621 fi
 622
 623 dnl
 624 dnl More DRI setup
 625 dnl
 626 AC_ARG_ENABLE([glx-tls],
 627     [AS_HELP_STRING([--enable-glx-tls],
 628         [enable TLS support in GLX @<:@default=disabled@:>@])],
 629     [GLX_USE_TLS="$enableval"],
 630     [GLX_USE_TLS=no])
 631 dnl Directory for DRI drivers
 632 AC_ARG_WITH([dri-driverdir],
 633     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 634         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 635     [DRI_DRIVER_INSTALL_DIR="$withval"],
 636     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 637 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 638 dnl Direct rendering or just indirect rendering
 639 AC_ARG_ENABLE([driglx-direct],
 640     [AS_HELP_STRING([--disable-driglx-direct],
 641         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 642     [driglx_direct="$enableval"],
 643     [driglx_direct="yes"])
 644 dnl Which drivers to build - default is chosen by platform
 645 AC_ARG_WITH([dri-drivers],
 646     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 647         [comma delimited DRI drivers list, e.g.
 648         "swrast,i965,radeon,nouveau" @<:@default=auto@:>@])],
 649     [with_dri_drivers="$withval"],
 650     [with_dri_drivers=yes])
 651 if test "x$with_dri_drivers" = x; then
 652     with_dri_drivers=no
 653 fi
 654
 655 dnl If $with_dri_drivers is yes, directories will be added through
 656 dnl platform checks
 657 DRI_DIRS=""
 658 case "$with_dri_drivers" in
 659 no) ;;
 660 yes)
 661     DRI_DIRS="yes"
 662     ;;
 663 *)
 664     # verify the requested driver directories exist
 665     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 666     for driver in $dri_drivers; do
 667         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 668             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 669     done
 670     DRI_DIRS="$dri_drivers"
 671     ;;
 672 esac
 673
 674 dnl Just default to no EGL for now
 675 USING_EGL=0
 676 AC_SUBST([USING_EGL])
 677
 678 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 679 if test "$mesa_driver" = dri; then
 680     # Use TLS in GLX?
 681     if test "x$GLX_USE_TLS" = xyes; then
 682         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 683     fi
 684
 685     if test "x$USING_EGL" = x1; then
 686         PROGRAM_DIRS="egl"
 687     fi
 688
 689     # Platform specific settings and drivers to build
 690     case "$host_os" in
 691     linux*)
 692         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 693         if test "x$driglx_direct" = xyes; then
 694             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 695         fi
 696         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 697
 698         case "$host_cpu" in
 699         x86_64)
 700             # ffb, gamma, and sis are missing because they have not be
 701             # converted to use the new interface.  i810 are missing
 702             # because there is no x86-64 system where they could *ever*
 703             # be used.
 704             if test "x$DRI_DIRS" = "xyes"; then
 705                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 radeon \
 706                     savage tdfx unichrome swrast"
 707             fi
 708             ;;
 709         powerpc*)
 710             # Build only the drivers for cards that exist on PowerPC.
 711             # At some point MGA will be added, but not yet.
 712             if test "x$DRI_DIRS" = "xyes"; then
 713                 DRI_DIRS="mach64 r128 r200 r300 radeon tdfx swrast"
 714             fi
 715             ;;
 716         sparc*)
 717             # Build only the drivers for cards that exist on sparc`
 718             if test "x$DRI_DIRS" = "xyes"; then
 719                 DRI_DIRS="mach64 r128 r200 r300 radeon ffb swrast"
 720             fi
 721             ;;
 722         esac
 723         ;;
 724     freebsd* | dragonfly*)
 725         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 726         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 727         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 728         if test "x$driglx_direct" = xyes; then
 729             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 730         fi
 731         if test "x$GXX" = xyes; then
 732             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 733         fi
 734
 735         # ffb and gamma are missing because they have not been converted
 736         # to use the new interface.
 737         if test "x$DRI_DIRS" = "xyes"; then
 738             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon tdfx \
 739                 unichrome savage sis swrast"
 740         fi
 741         ;;
 742     solaris*)
 743         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 744         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 745         if test "x$driglx_direct" = xyes; then
 746             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 747         fi
 748         ;;
 749     esac
 750
 751     # default drivers
 752     if test "x$DRI_DIRS" = "xyes"; then
 753         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 radeon s3v \
 754             savage sis tdfx trident unichrome ffb swrast"
 755     fi
 756
 757     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 758
 759     # Check for expat
 760     EXPAT_INCLUDES=""
 761     EXPAT_LIB=-lexpat
 762     AC_ARG_WITH([expat],
 763         [AS_HELP_STRING([--with-expat=DIR],
 764             [expat install directory])],[
 765         EXPAT_INCLUDES="-I$withval/include"
 766         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 767         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 768         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 769         ])
 770     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 771     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 772         [AC_MSG_ERROR([Expat required for DRI.])])
 773
 774     # put all the necessary libs together
 775     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 776 fi
 777 AC_SUBST([DRI_DIRS])
 778 AC_SUBST([EXPAT_INCLUDES])
 779 AC_SUBST([DRI_LIB_DEPS])
 780
 781 dnl
 782 dnl OSMesa configuration
 783 dnl
 784 if test "$mesa_driver" = xlib; then
 785     default_gl_osmesa=yes
 786 else
 787     default_gl_osmesa=no
 788 fi
 789 AC_ARG_ENABLE([gl-osmesa],
 790     [AS_HELP_STRING([--enable-gl-osmesa],
 791         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 792     [gl_osmesa="$enableval"],
 793     [gl_osmesa="$default_gl_osmesa"])
 794 if test "x$gl_osmesa" = xyes; then
 795     if test "$mesa_driver" = osmesa; then
 796         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 797     else
 798         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 799     fi
 800 fi
 801
 802 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 803 AC_ARG_WITH([osmesa-bits],
 804     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 805         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 806     [osmesa_bits="$withval"],
 807     [osmesa_bits=8])
 808 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 809     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 810     osmesa_bits=8
 811 fi
 812 case "x$osmesa_bits" in
 813 x8)
 814     OSMESA_LIB=OSMesa
 815     ;;
 816 x16|x32)
 817     OSMESA_LIB="OSMesa$osmesa_bits"
 818     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 819     ;;
 820 *)
 821     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 822     ;;
 823 esac
 824 AC_SUBST([OSMESA_LIB])
 825
 826 case "$mesa_driver" in
 827 osmesa)
 828     # only link libraries with osmesa if shared
 829     if test "$enable_static" = no; then
 830         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS"
 831     else
 832         OSMESA_LIB_DEPS=""
 833     fi
 834     OSMESA_MESA_DEPS=""
 835     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS"
 836     ;;
 837 *)
 838     # Link OSMesa to libGL otherwise
 839     OSMESA_LIB_DEPS=""
 840     # only link libraries with osmesa if shared
 841     if test "$enable_static" = no; then
 842         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 843     else
 844         OSMESA_MESA_DEPS=""
 845     fi
 846     OSMESA_PC_REQ="gl"
 847     ;;
 848 esac
 849 if test "$enable_static" = no; then
 850     OSMESA_LIB_DEPS="$OSMESA_LIB_DEPS $OS_LIBS"
 851 fi
 852 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV $OS_LIBS"
 853 AC_SUBST([OSMESA_LIB_DEPS])
 854 AC_SUBST([OSMESA_MESA_DEPS])
 855 AC_SUBST([OSMESA_PC_REQ])
 856 AC_SUBST([OSMESA_PC_LIB_PRIV])
 857
 858 dnl
 859 dnl EGL configuration
 860 dnl
 861 if test "$x11_pkgconfig" = yes; then
 862     PKG_CHECK_MODULES([EGL],[x11])
 863     EGL_LIB_DEPS="$EGL_LIBS"
 864 else
 865     # should check these...
 866     EGL_LIB_DEPS="$X_LIBS -lX11"
 867 fi
 868 EGL_LIB_DEPS="$EGL_LIB_DEPS $DLOPEN_LIBS $OS_LIBS"
 869 AC_SUBST([EGL_LIB_DEPS])
 870
 871 dnl
 872 dnl GLU configuration
 873 dnl
 874 AC_ARG_ENABLE([glu],
 875     [AS_HELP_STRING([--disable-glu],
 876         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 877     [enable_glu="$enableval"],
 878     [enable_glu=yes])
 879 if test "x$enable_glu" = xyes; then
 880     SRC_DIRS="$SRC_DIRS glu"
 881
 882     case "$mesa_driver" in
 883     osmesa)
 884         # If GLU is available and we have libOSMesa (not 16 or 32),
 885         # we can build the osdemos
 886         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
 887             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
 888         fi
 889
 890         # Link libGLU to libOSMesa instead of libGL
 891         GLU_LIB_DEPS=""
 892         GLU_PC_REQ="osmesa"
 893         if test "$enable_static" = no; then
 894             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 895         else
 896             GLU_MESA_DEPS=""
 897         fi
 898         ;;
 899     *)
 900         # If static, empty GLU_LIB_DEPS and add libs for programs to link
 901         GLU_PC_REQ="gl"
 902         GLU_PC_LIB_PRIV="-lm"
 903         if test "$enable_static" = no; then
 904             GLU_LIB_DEPS="-lm"
 905             GLU_MESA_DEPS='-l$(GL_LIB)'
 906         else
 907             GLU_LIB_DEPS=""
 908             GLU_MESA_DEPS=""
 909             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
 910         fi
 911         ;;
 912     esac
 913 fi
 914 if test "$enable_static" = no; then
 915     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
 916 fi
 917 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
 918 AC_SUBST([GLU_LIB_DEPS])
 919 AC_SUBST([GLU_MESA_DEPS])
 920 AC_SUBST([GLU_PC_REQ])
 921 AC_SUBST([GLU_PC_REQ_PRIV])
 922 AC_SUBST([GLU_PC_LIB_PRIV])
 923 AC_SUBST([GLU_PC_CFLAGS])
 924
 925 dnl
 926 dnl GLw configuration
 927 dnl
 928 AC_ARG_ENABLE([glw],
 929     [AS_HELP_STRING([--disable-glw],
 930         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
 931     [enable_glw="$enableval"],
 932     [enable_glw=yes])
 933 dnl Don't build GLw on osmesa
 934 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
 935     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
 936     enable_glw=no
 937 fi
 938 AC_ARG_ENABLE([motif],
 939     [AS_HELP_STRING([--enable-motif],
 940         [use Motif widgets in GLw @<:@default=disabled@:>@])],
 941     [enable_motif="$enableval"],
 942     [enable_motif=no])
 943
 944 if test "x$enable_glw" = xyes; then
 945     SRC_DIRS="$SRC_DIRS glw"
 946     if test "$x11_pkgconfig" = yes; then
 947         PKG_CHECK_MODULES([GLW],[x11 xt])
 948         GLW_PC_REQ_PRIV="x11 xt"
 949         GLW_LIB_DEPS="$GLW_LIBS"
 950     else
 951         # should check these...
 952         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
 953         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
 954         GLW_PC_CFLAGS="$X11_INCLUDES"
 955     fi
 956
 957     GLW_SOURCES="GLwDrawA.c"
 958     MOTIF_CFLAGS=
 959     if test "x$enable_motif" = xyes; then
 960         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
 961         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
 962         if test "x$MOTIF_CONFIG" != xno; then
 963             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
 964             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
 965         else
 966             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
 967                 [AC_MSG_ERROR([Can't locate Motif headers])])
 968             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
 969                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
 970         fi
 971         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
 972         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
 973         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
 974         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
 975     fi
 976
 977     # If static, empty GLW_LIB_DEPS and add libs for programs to link
 978     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV $OS_LIBS"
 979     if test "$enable_static" = no; then
 980         GLW_MESA_DEPS='-l$(GL_LIB)'
 981         GLW_LIB_DEPS="$GLW_LIB_DEPS $OS_LIBS"
 982     else
 983         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
 984         GLW_LIB_DEPS=""
 985         GLW_MESA_DEPS=""
 986     fi
 987 fi
 988 AC_SUBST([GLW_LIB_DEPS])
 989 AC_SUBST([GLW_MESA_DEPS])
 990 AC_SUBST([GLW_SOURCES])
 991 AC_SUBST([MOTIF_CFLAGS])
 992 AC_SUBST([GLW_PC_REQ_PRIV])
 993 AC_SUBST([GLW_PC_LIB_PRIV])
 994 AC_SUBST([GLW_PC_CFLAGS])
 995
 996 dnl
 997 dnl GLUT configuration
 998 dnl
 999 if test -f "$srcdir/include/GL/glut.h"; then
1000     default_glut=yes
1001 else
1002     default_glut=no
1003 fi
1004 AC_ARG_ENABLE([glut],
1005     [AS_HELP_STRING([--disable-glut],
1006         [enable GLUT library @<:@default=enabled if source available@:>@])],
1007     [enable_glut="$enableval"],
1008     [enable_glut="$default_glut"])
1009
1010 dnl Can't build glut if GLU not available
1011 if test "x$enable_glu$enable_glut" = xnoyes; then
1012     AC_MSG_WARN([Disabling glut since GLU is disabled])
1013     enable_glut=no
1014 fi
1015 dnl Don't build glut on osmesa
1016 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1017     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1018     enable_glut=no
1019 fi
1020
1021 if test "x$enable_glut" = xyes; then
1022     SRC_DIRS="$SRC_DIRS glut/glx"
1023     GLUT_CFLAGS=""
1024     if test "x$GCC" = xyes; then
1025         GLUT_CFLAGS="-fexceptions"
1026     fi
1027     if test "$x11_pkgconfig" = yes; then
1028         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1029         GLUT_PC_REQ_PRIV="x11 xmu xi"
1030         GLUT_LIB_DEPS="$GLUT_LIBS"
1031     else
1032         # should check these...
1033         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1034         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1035         GLUT_PC_CFLAGS="$X11_INCLUDES"
1036     fi
1037     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm $OS_LIBS"
1038     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm $OS_LIBS"
1039
1040     # If glut is available, we can build most programs
1041     if test "$with_demos" = yes; then
1042         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1043     fi
1044
1045     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1046     if test "$enable_static" = no; then
1047         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1048     else
1049         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1050         GLUT_LIB_DEPS=""
1051         GLUT_MESA_DEPS=""
1052     fi
1053 fi
1054 AC_SUBST([GLUT_LIB_DEPS])
1055 AC_SUBST([GLUT_MESA_DEPS])
1056 AC_SUBST([GLUT_CFLAGS])
1057 AC_SUBST([GLUT_PC_REQ_PRIV])
1058 AC_SUBST([GLUT_PC_LIB_PRIV])
1059 AC_SUBST([GLUT_PC_CFLAGS])
1060
1061 dnl
1062 dnl Program library dependencies
1063 dnl    Only libm is added here if necessary as the libraries should
1064 dnl    be pulled in by the linker
1065 dnl
1066 if test "x$APP_LIB_DEPS" = x; then
1067     case "$host_os" in
1068     solaris*)
1069         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1070         ;;
1071     *)
1072         APP_LIB_DEPS="-lm"
1073         ;;
1074     esac
1075 fi
1076 AC_SUBST([APP_LIB_DEPS])
1077 AC_SUBST([PROGRAM_DIRS])
1078
1079 dnl
1080 dnl Gallium configuration
1081 dnl
1082 AC_ARG_ENABLE([gallium],
1083     [AS_HELP_STRING([--disable-gallium],
1084         [build gallium @<:@default=enabled@:>@])],
1085     [enable_gallium="$enableval"],
1086     [enable_gallium=yes])
1087 if test "x$enable_gallium" = xyes; then
1088     SRC_DIRS="$SRC_DIRS gallium gallium/winsys"
1089 fi
1090
1091 dnl
1092 dnl Gallium state trackers configuration
1093 dnl
1094 AC_ARG_WITH([state-trackers],
1095     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1096         [comma delimited state_trackers list, e.g.
1097         "egl,glx" @<:@default=auto@:>@])],
1098     [with_state_trackers="$withval"],
1099     [with_state_trackers=yes])
1100
1101 case "$with_state_trackers" in
1102 no)
1103     GALLIUM_STATE_TRACKERS_DIRS=""
1104     ;;
1105 yes)
1106     # look at what else is built
1107     case "$mesa_driver" in
1108     dri)
1109         GALLIUM_STATE_TRACKERS_DIRS=egl
1110         ;;
1111     esac
1112     ;;
1113 *)
1114     # verify the requested state tracker exist
1115     state_trackers=`IFS=', '; echo $with_state_trackers`
1116     for tracker in $state_trackers; do
1117         test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1118             AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1119     done
1120     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1121     ;;
1122 esac
1123
1124 dnl
1125 dnl Gallium Intel configuration
1126 dnl
1127 AC_ARG_ENABLE([gallium-intel],
1128     [AS_HELP_STRING([--disable-gallium-intel],
1129         [build gallium intel @<:@default=enabled@:>@])],
1130     [enable_gallium_intel="$enableval"],
1131     [enable_gallium_intel=yes])
1132 if test "x$enable_gallium_intel" = xyes; then
1133     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS intel"
1134     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915simple"
1135 fi
1136
1137 dnl
1138 dnl Gallium Radeon configuration
1139 dnl
1140 AC_ARG_ENABLE([gallium-radeon],
1141     [AS_HELP_STRING([--enable-gallium-radeon],
1142         [build gallium radeon @<:@default=disabled@:>@])],
1143     [enable_gallium_radeon="$enableval"],
1144     [enable_gallium_radeon=no])
1145 if test "x$enable_gallium_radeon" = xyes; then
1146     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS radeon"
1147     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1148 fi
1149
1150 dnl
1151 dnl Gallium Radeon configuration
1152 dnl
1153 AC_ARG_ENABLE([gallium-nouveau],
1154     [AS_HELP_STRING([--enable-gallium-nouveau],
1155         [build gallium nouveau @<:@default=disabled@:>@])],
1156     [enable_gallium_nouveau="$enableval"],
1157     [enable_gallium_nouveau=no])
1158 if test "x$enable_gallium_nouveau" = xyes; then
1159     GALLIUM_WINSYS_DRM_DIRS="$GALLIUM_WINSYS_DRM_DIRS nouveau"
1160     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nv04 nv10 nv20 nv30 nv40 nv50"
1161 fi
1162
1163
1164 dnl Restore LDFLAGS and CPPFLAGS
1165 LDFLAGS="$_SAVE_LDFLAGS"
1166 CPPFLAGS="$_SAVE_CPPFLAGS"
1167
1168 dnl Substitute the config
1169 AC_CONFIG_FILES([configs/autoconf])
1170
1171 dnl Replace the configs/current symlink
1172 AC_CONFIG_COMMANDS([configs],[
1173 if test -f configs/current || test -L configs/current; then
1174     rm -f configs/current
1175 fi
1176 ln -s autoconf configs/current
1177 ])
1178
1179 AC_OUTPUT
1180
1181 dnl
1182 dnl Output some configuration info for the user
1183 dnl
1184 echo ""
1185 echo "        prefix:          $prefix"
1186 echo "        exec_prefix:     $exec_prefix"
1187 echo "        libdir:          $libdir"
1188 echo "        includedir:      $includedir"
1189
1190 dnl Driver info
1191 echo ""
1192 echo "        Driver:          $mesa_driver"
1193 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1194     echo "        OSMesa:          lib$OSMESA_LIB"
1195 else
1196     echo "        OSMesa:          no"
1197 fi
1198 if test "$mesa_driver" = dri; then
1199     # cleanup the drivers var
1200     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1201 if test "x$DRI_DIRS" = x; then
1202     echo "        DRI drivers:     no"
1203 else
1204     echo "        DRI drivers:     $dri_dirs"
1205 fi
1206     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1207 fi
1208 echo "        Use XCB:         $enable_xcb"
1209
1210 echo ""
1211 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1212     echo "        Gallium:         yes"
1213     echo "        Gallium dirs:    $GALLIUM_DIRS"
1214     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1215     echo "        Winsys drm dirs:$GALLIUM_WINSYS_DRM_DIRS"
1216     echo "        Auxiliary dirs:  $GALLIUM_AUXILIARY_DIRS"
1217     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1218     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1219 else
1220     echo "        Gallium:         no"
1221 fi
1222
1223 dnl Libraries
1224 echo ""
1225 echo "        Shared libs:     $enable_shared"
1226 echo "        Static libs:     $enable_static"
1227 echo "        GLU:             $enable_glu"
1228 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1229 echo "        glut:            $enable_glut"
1230
1231 dnl Programs
1232 # cleanup the programs var for display
1233 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1234 if test "x$program_dirs" = x; then
1235     echo "        Demos:           no"
1236 else
1237     echo "        Demos:           $program_dirs"
1238 fi
1239
1240 dnl Compiler options
1241 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1242 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1243     $SED 's/^ *//;s/  */ /;s/ *$//'`
1244 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1245     $SED 's/^ *//;s/  */ /;s/ *$//'`
1246 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1247 echo ""
1248 echo "        CFLAGS:          $cflags"
1249 echo "        CXXFLAGS:        $cxxflags"
1250 echo "        Macros:          $defines"
1251
1252 echo ""
1253 echo "        Run '${MAKE-make}' to build Mesa"
1254 echo ""