configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.82
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_ETNAVIV_REQUIRED=2.4.82
  83
  84 dnl Versions for external dependencies
  85 DRI2PROTO_REQUIRED=2.8
  86 GLPROTO_REQUIRED=1.4.14
  87 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  88 LIBVA_REQUIRED=0.38.0
  89 VDPAU_REQUIRED=1.1
  90 WAYLAND_REQUIRED=1.11
  91 WAYLAND_PROTOCOLS_REQUIRED=1.8
  92 XCB_REQUIRED=1.9.3
  93 XCBDRI2_REQUIRED=1.8
  94 XCBGLX_REQUIRED=1.8.1
  95 XDAMAGE_REQUIRED=1.1
  96 XSHMFENCE_REQUIRED=1.1
  97 XVMC_REQUIRED=1.0.6
  98 PYTHON_MAKO_REQUIRED=0.8.0
  99 LIBSENSORS_REQUIRED=4.0.0
 100 ZLIB_REQUIRED=1.2.3
 101
 102 dnl LLVM versions
 103 LLVM_REQUIRED_GALLIUM=3.3.0
 104 LLVM_REQUIRED_OPENCL=3.6.0
 105 LLVM_REQUIRED_R600=3.9.0
 106 LLVM_REQUIRED_RADEONSI=3.9.0
 107 LLVM_REQUIRED_RADV=3.9.0
 108 LLVM_REQUIRED_SWR=3.9.0
 109
 110 dnl Check for progs
 111 AC_PROG_CPP
 112 AC_PROG_CC
 113 AC_PROG_CXX
 114 AM_PROG_CC_C_O
 115 AM_PROG_AS
 116 AX_CHECK_GNU_MAKE
 117 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 118 AC_PROG_SED
 119 AC_PROG_MKDIR_P
 120
 121 AC_SYS_LARGEFILE
 122
 123 LT_PREREQ([2.2])
 124 LT_INIT([disable-static])
 125
 126 AC_CHECK_PROG(RM, rm, [rm -f])
 127
 128 AX_PROG_BISON([],
 129               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 130                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 131 AX_PROG_FLEX([],
 132              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 133                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 134
 135 AC_CHECK_PROG(INDENT, indent, indent, cat)
 136 if test "x$INDENT" != "xcat"; then
 137     # Only GNU indent is supported
 138     INDENT_VERSION=`indent --version | grep GNU`
 139     if test $? -eq 0; then
 140        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 141     else
 142        INDENT="cat"
 143     fi
 144 fi
 145
 146 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 147
 148 if test -z "$PYTHON2"; then
 149     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 150         AC_MSG_ERROR([Python not found - unable to generate sources])
 151     fi
 152 else
 153     if test "x$acv_mako_found" = xno; then
 154         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 155             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 156         fi
 157     fi
 158 fi
 159
 160 AC_PROG_INSTALL
 161
 162 dnl We need a POSIX shell for parts of the build. Assume we have one
 163 dnl in most cases.
 164 case "$host_os" in
 165 solaris*)
 166     # Solaris /bin/sh is too old/non-POSIX compliant
 167     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 168     SHELL="$POSIX_SHELL"
 169     ;;
 170 esac
 171
 172 dnl clang is mostly GCC-compatible, but its version is much lower,
 173 dnl so we have to check for it.
 174 AC_MSG_CHECKING([if compiling with clang])
 175
 176 AC_COMPILE_IFELSE(
 177 [AC_LANG_PROGRAM([], [[
 178 #ifndef __clang__
 179        not clang
 180 #endif
 181 ]])],
 182 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 183
 184 AC_MSG_RESULT([$acv_mesa_CLANG])
 185
 186 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 187 dnl versions are explictly not supported.
 188 GEN_ASM_OFFSETS=no
 189 USE_GNU99=no
 190 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 191     AC_MSG_CHECKING([whether gcc version is sufficient])
 192     major=0
 193     minor=0
 194
 195     GCC_VERSION=`$CC -dumpversion`
 196     if test $? -eq 0; then
 197         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 198         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 199     fi
 200
 201     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 202         AC_MSG_RESULT([no])
 203         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 204     else
 205         AC_MSG_RESULT([yes])
 206     fi
 207
 208     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 209         USE_GNU99=yes
 210     fi
 211     if test "x$cross_compiling" = xyes; then
 212         GEN_ASM_OFFSETS=yes
 213     fi
 214 fi
 215
 216 dnl We don't support building Mesa with Sun C compiler
 217 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 218 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 219 if test "x$SUNCC" = xyes; then
 220     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 221 fi
 222
 223 dnl Check for compiler builtins
 224 AX_GCC_BUILTIN([__builtin_bswap32])
 225 AX_GCC_BUILTIN([__builtin_bswap64])
 226 AX_GCC_BUILTIN([__builtin_clz])
 227 AX_GCC_BUILTIN([__builtin_clzll])
 228 AX_GCC_BUILTIN([__builtin_ctz])
 229 AX_GCC_BUILTIN([__builtin_expect])
 230 AX_GCC_BUILTIN([__builtin_ffs])
 231 AX_GCC_BUILTIN([__builtin_ffsll])
 232 AX_GCC_BUILTIN([__builtin_popcount])
 233 AX_GCC_BUILTIN([__builtin_popcountll])
 234 AX_GCC_BUILTIN([__builtin_unreachable])
 235
 236 AX_GCC_FUNC_ATTRIBUTE([const])
 237 AX_GCC_FUNC_ATTRIBUTE([flatten])
 238 AX_GCC_FUNC_ATTRIBUTE([format])
 239 AX_GCC_FUNC_ATTRIBUTE([malloc])
 240 AX_GCC_FUNC_ATTRIBUTE([packed])
 241 AX_GCC_FUNC_ATTRIBUTE([pure])
 242 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 243 AX_GCC_FUNC_ATTRIBUTE([unused])
 244 AX_GCC_FUNC_ATTRIBUTE([visibility])
 245 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 246 AX_GCC_FUNC_ATTRIBUTE([weak])
 247 AX_GCC_FUNC_ATTRIBUTE([alias])
 248
 249 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 250
 251 dnl Make sure the pkg-config macros are defined
 252 m4_ifndef([PKG_PROG_PKG_CONFIG],
 253     [m4_fatal([Could not locate the pkg-config autoconf macros.
 254   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 255   are in a different location, try setting the environment variable
 256   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 257 PKG_PROG_PKG_CONFIG()
 258
 259 dnl LIB_DIR - library basename
 260 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 261 AC_SUBST([LIB_DIR])
 262
 263 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 264 _SAVE_LDFLAGS="$LDFLAGS"
 265 _SAVE_CPPFLAGS="$CPPFLAGS"
 266
 267 dnl Compiler macros
 268 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 269 AC_SUBST([DEFINES])
 270 android=no
 271 case "$host_os" in
 272 *-android*)
 273     android=yes
 274     ;;
 275 linux*|*-gnu*|gnu*|cygwin*)
 276     DEFINES="$DEFINES -D_GNU_SOURCE"
 277     ;;
 278 solaris*)
 279     DEFINES="$DEFINES -DSVR4"
 280     ;;
 281 esac
 282
 283 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 284
 285 dnl
 286 dnl Check compiler flags
 287 dnl
 288 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CFLAGS="$CFLAGS -Wall"])
 289 AX_CHECK_COMPILE_FLAG([-Werror=implicit-function-declaration], [CFLAGS="$CFLAGS -Werror=implicit-function-declaration"])
 290 AX_CHECK_COMPILE_FLAG([-Werror=missing-prototypes],            [CFLAGS="$CFLAGS -Werror=missing-prototypes"])
 291 AX_CHECK_COMPILE_FLAG([-Wmissing-prototypes],                  [CFLAGS="$CFLAGS -Wmissing-prototypes"])
 292 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CFLAGS="$CFLAGS -fno-math-errno"])
 293 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CFLAGS="$CFLAGS -fno-trapping-math"])
 294 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CFLAGS="-fvisibility=hidden"])
 295
 296 dnl
 297 dnl Check C++ compiler flags
 298 dnl
 299 AC_LANG_PUSH([C++])
 300 AX_CHECK_COMPILE_FLAG([-Wall],                                 [CXXFLAGS="$CXXFLAGS -Wall"])
 301 AX_CHECK_COMPILE_FLAG([-fno-math-errno],                       [CXXFLAGS="$CXXFLAGS -fno-math-errno"])
 302 AX_CHECK_COMPILE_FLAG([-fno-trapping-math],                    [CXXFLAGS="$CXXFLAGS -fno-trapping-math"])
 303 AX_CHECK_COMPILE_FLAG([-fvisibility=hidden],                   [VISIBILITY_CXXFLAGS="-fvisibility=hidden"])
 304 AC_LANG_POP([C++])
 305
 306 # Flags to help ensure that certain portions of the code -- and only those
 307 # portions -- can be built with MSVC:
 308 # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 309 # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 310 #   supports most of C99)
 311 # - the rest has no compiler compiler restrictions
 312 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"])
 313 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CFLAGS="-Werror=vla"])
 314 AC_LANG_PUSH([C++])
 315 AX_CHECK_COMPILE_FLAG([-Werror=pointer-arith],                 [MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"])
 316 AX_CHECK_COMPILE_FLAG([-Werror=vla],                           [MSVC2013_COMPAT_CXXFLAGS="-Werror=vla"])
 317 AC_LANG_POP([C++])
 318
 319 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 320 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 321
 322 if test "x$GCC" = xyes; then
 323     if test "x$USE_GNU99" = xyes; then
 324         CFLAGS="$CFLAGS -std=gnu99"
 325     else
 326         CFLAGS="$CFLAGS -std=c99"
 327     fi
 328 fi
 329
 330 dnl even if the compiler appears to support it, using visibility attributes isn't
 331 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 332 case "$host_os" in
 333 cygwin*)
 334     VISIBILITY_CFLAGS=""
 335     VISIBILITY_CXXFLAGS=""
 336     ;;
 337 esac
 338
 339 AC_SUBST([VISIBILITY_CFLAGS])
 340 AC_SUBST([VISIBILITY_CXXFLAGS])
 341
 342 AX_CHECK_COMPILE_FLAG([-Wno-override-init],                    [WNO_OVERRIDE_INIT="-Wno-override-init"])         # gcc
 343 AX_CHECK_COMPILE_FLAG([-Wno-initializer-overrides],            [WNO_OVERRIDE_INIT="-Wno-initializer-overrides"]) # clang
 344 AC_SUBST([WNO_OVERRIDE_INIT])
 345
 346 dnl
 347 dnl Optional flags, check for compiler support
 348 dnl
 349 SSE41_CFLAGS="-msse4.1"
 350 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 351 dnl stack, but on x86-32 such alignment is not guaranteed.
 352 case "$target_cpu" in
 353 i?86)
 354     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 355     ;;
 356 esac
 357 save_CFLAGS="$CFLAGS"
 358 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 359 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 360 #include <smmintrin.h>
 361 int param;
 362 int main () {
 363     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 364     c = _mm_max_epu32(a, b);
 365     return _mm_cvtsi128_si32(c);
 366 }]])], SSE41_SUPPORTED=1)
 367 CFLAGS="$save_CFLAGS"
 368 if test "x$SSE41_SUPPORTED" = x1; then
 369     DEFINES="$DEFINES -DUSE_SSE41"
 370 fi
 371 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 372 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 373
 374 dnl Check for new-style atomic builtins
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 int main() {
 377     int n;
 378     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 379 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 380 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 381     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 382 fi
 383 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 384
 385 dnl Check if host supports 64-bit atomics
 386 dnl note that lack of support usually results in link (not compile) error
 387 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 388 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 389 #include <stdint.h>
 390 uint64_t v;
 391 int main() {
 392     return __sync_add_and_fetch(&v, (uint64_t)1);
 393 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 394 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 395     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 396 fi
 397 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 398
 399 dnl Check for Endianness
 400 AC_C_BIGENDIAN(
 401    little_endian=no,
 402    little_endian=yes,
 403    little_endian=no,
 404    little_endian=no
 405 )
 406
 407 dnl Check for POWER8 Architecture
 408 PWR8_CFLAGS="-mpower8-vector"
 409 have_pwr8_intrinsics=no
 410 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 411 save_CFLAGS=$CFLAGS
 412 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 413 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 414 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 415 #error "Need GCC >= 4.8 for sane POWER8 support"
 416 #endif
 417 #include <altivec.h>
 418 int main () {
 419     vector unsigned char r;
 420     vector unsigned int v = vec_splat_u32 (1);
 421     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 422     return 0;
 423 }]])], have_pwr8_intrinsics=yes)
 424 CFLAGS=$save_CFLAGS
 425
 426 AC_ARG_ENABLE(pwr8,
 427    [AS_HELP_STRING([--disable-pwr8],
 428                    [disable POWER8-specific instructions])],
 429    [enable_pwr8=$enableval], [enable_pwr8=auto])
 430
 431 if test "x$enable_pwr8" = xno ; then
 432    have_pwr8_intrinsics=disabled
 433 fi
 434
 435 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 436    DEFINES="$DEFINES -D_ARCH_PWR8"
 437    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 438    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 439 else
 440    PWR8_CFLAGS=
 441 fi
 442
 443 AC_MSG_RESULT($have_pwr8_intrinsics)
 444 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 445    AC_MSG_ERROR([POWER8 compiler support not detected])
 446 fi
 447
 448 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 449    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 450 fi
 451
 452 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 453
 454 dnl Can't have static and shared libraries, default to static if user
 455 dnl explicitly requested. If both disabled, set to static since shared
 456 dnl was explicitly requested.
 457 case "x$enable_static$enable_shared" in
 458 xyesyes)
 459     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 460     ;;
 461 xnono)
 462     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 463     ;;
 464 esac
 465
 466 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 467
 468 dnl
 469 dnl other compiler options
 470 dnl
 471 AC_ARG_ENABLE([debug],
 472     [AS_HELP_STRING([--enable-debug],
 473         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 474     [enable_debug="$enableval"],
 475     [enable_debug=no]
 476 )
 477
 478 AC_ARG_ENABLE([profile],
 479     [AS_HELP_STRING([--enable-profile],
 480         [enable profiling of code @<:@default=disabled@:>@])],
 481     [enable_profile="$enableval"],
 482     [enable_profile=no]
 483 )
 484
 485 AC_ARG_ENABLE([sanitize],
 486     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 487         [enable code sanitizer @<:@default=disabled@:>@])],
 488     [enable_sanitize="$enableval"],
 489     [enable_sanitize=no])
 490
 491 if test "x$enable_profile" = xyes; then
 492     DEFINES="$DEFINES -DPROFILE"
 493     if test "x$GCC" = xyes; then
 494         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 495     fi
 496     if test "x$GXX" = xyes; then
 497         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 498     fi
 499 fi
 500
 501 if test "x$enable_debug" = xyes; then
 502     DEFINES="$DEFINES -DDEBUG"
 503     if test "x$enable_profile" = xyes; then
 504         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 505     fi
 506     if test "x$GCC" = xyes; then
 507         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 508             CFLAGS="$CFLAGS -g"
 509         fi
 510         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 511             CFLAGS="$CFLAGS -O0"
 512         fi
 513     fi
 514     if test "x$GXX" = xyes; then
 515         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 516             CXXFLAGS="$CXXFLAGS -g"
 517         fi
 518         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 519             CXXFLAGS="$CXXFLAGS -O0"
 520         fi
 521     fi
 522 else
 523    DEFINES="$DEFINES -DNDEBUG"
 524 fi
 525
 526 if test "x$enable_sanitize" != xno; then
 527     if test "x$enable_profile" = xyes; then
 528         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 529     fi
 530
 531     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 532     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 533     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 534
 535     AC_LINK_IFELSE(
 536         [AC_LANG_SOURCE([int main(){return 0;}])],
 537         [],
 538         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 539 fi
 540
 541 dnl
 542 dnl Check if linker supports -Bsymbolic
 543 dnl
 544 save_LDFLAGS=$LDFLAGS
 545 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 546 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 547 AC_LINK_IFELSE(
 548     [AC_LANG_SOURCE([int main() { return 0;}])],
 549     [AC_MSG_RESULT([yes])
 550         BSYMBOLIC="-Wl,-Bsymbolic";],
 551     [AC_MSG_RESULT([no])
 552         BSYMBOLIC="";])
 553 LDFLAGS=$save_LDFLAGS
 554
 555 AC_SUBST([BSYMBOLIC])
 556
 557 dnl
 558 dnl Check if linker supports garbage collection
 559 dnl
 560 save_LDFLAGS=$LDFLAGS
 561 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 562 AC_MSG_CHECKING([whether ld supports --gc-sections])
 563 AC_LINK_IFELSE(
 564     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 565     [AC_MSG_RESULT([yes])
 566         GC_SECTIONS="-Wl,--gc-sections";],
 567     [AC_MSG_RESULT([no])
 568         GC_SECTIONS="";])
 569 LDFLAGS=$save_LDFLAGS
 570
 571 AC_SUBST([GC_SECTIONS])
 572
 573 dnl
 574 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 575 dnl so when these flags are passed to ld via libtool the checks will fail
 576 dnl
 577 case "$host_os" in
 578 openbsd* | darwin* )
 579     LD_NO_UNDEFINED="" ;;
 580 *)
 581     if test "x$enable_sanitize" = xno; then
 582         LD_NO_UNDEFINED="-Wl,--no-undefined"
 583     else
 584         LD_NO_UNDEFINED=""
 585     fi
 586     ;;
 587 esac
 588
 589 AC_SUBST([LD_NO_UNDEFINED])
 590
 591 dnl
 592 dnl Check if linker supports version scripts
 593 dnl
 594 AC_MSG_CHECKING([if the linker supports version-scripts])
 595 save_LDFLAGS=$LDFLAGS
 596 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 597 cat > conftest.map <<EOF
 598 VERSION_1 {
 599      global:
 600          main;
 601
 602      local:
 603          *;
 604 };
 605 EOF
 606 AC_LINK_IFELSE(
 607     [AC_LANG_SOURCE([int main() { return 0;}])],
 608     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 609     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 610 LDFLAGS=$save_LDFLAGS
 611 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 612
 613 dnl
 614 dnl Check if linker supports dynamic list files
 615 dnl
 616 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 617 save_LDFLAGS=$LDFLAGS
 618 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 619 cat > conftest.dyn <<EOF
 620 {
 621         radeon_drm_winsys_create;
 622 };
 623 EOF
 624 AC_LINK_IFELSE(
 625     [AC_LANG_SOURCE([int main() { return 0;}])],
 626     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 627     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 628 LDFLAGS=$save_LDFLAGS
 629 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 630
 631 dnl
 632 dnl compatibility symlinks
 633 dnl
 634 case "$host_os" in
 635 linux* )
 636     HAVE_COMPAT_SYMLINKS=yes ;;
 637 * )
 638     HAVE_COMPAT_SYMLINKS=no ;;
 639 esac
 640
 641 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 642
 643 dnl
 644 dnl library names
 645 dnl
 646 dnl Unfortunately we need to do a few things that libtool can't help us with,
 647 dnl so we need some knowledge of shared library filenames:
 648 dnl
 649 dnl LIB_EXT is the extension used when creating symlinks for alternate
 650 dnl filenames for a shared library which will be dynamically loaded
 651 dnl
 652 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 653 dnl the file for a shared library we wish to link with
 654 dnl
 655 case "$host_os" in
 656 darwin* )
 657     LIB_EXT='dylib'
 658     IMP_LIB_EXT=$LIB_EXT
 659     ;;
 660 cygwin* )
 661     LIB_EXT='dll'
 662     IMP_LIB_EXT='dll.a'
 663     ;;
 664 aix* )
 665     LIB_EXT='a'
 666     IMP_LIB_EXT=$LIB_EXT
 667     ;;
 668 * )
 669     LIB_EXT='so'
 670     IMP_LIB_EXT=$LIB_EXT
 671     ;;
 672 esac
 673
 674 AC_SUBST([LIB_EXT])
 675
 676 dnl
 677 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 678 dnl
 679 AC_ARG_ENABLE([texture-float],
 680     [AS_HELP_STRING([--enable-texture-float],
 681         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 682     [enable_texture_float="$enableval"],
 683     [enable_texture_float=no]
 684 )
 685 if test "x$enable_texture_float" = xyes; then
 686     AC_MSG_WARN([Floating-point textures enabled.])
 687     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 688     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 689 fi
 690
 691 dnl
 692 dnl Arch/platform-specific settings
 693 dnl
 694 AC_ARG_ENABLE([asm],
 695     [AS_HELP_STRING([--disable-asm],
 696         [disable assembly usage @<:@default=enabled on supported platforms@:>@])],
 697     [enable_asm="$enableval"],
 698     [enable_asm=yes]
 699 )
 700 asm_arch=""
 701 AC_MSG_CHECKING([whether to enable assembly])
 702 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 703 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 704 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 705     case "$host_cpu" in
 706     i?86 | x86_64 | amd64)
 707         if test "x$host_cpu" != "x$target_cpu"; then
 708             enable_asm=no
 709             AC_MSG_RESULT([no, cross compiling])
 710         fi
 711         ;;
 712     esac
 713 fi
 714 # check for supported arches
 715 if test "x$enable_asm" = xyes; then
 716     case "$host_cpu" in
 717     i?86)
 718         case "$host_os" in
 719         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 720             asm_arch=x86
 721             ;;
 722         esac
 723         ;;
 724     x86_64|amd64)
 725         case "$host_os" in
 726         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 727             asm_arch=x86_64
 728             ;;
 729         esac
 730         ;;
 731     sparc*)
 732         case "$host_os" in
 733         linux*)
 734             asm_arch=sparc
 735             ;;
 736         esac
 737         ;;
 738     powerpc64le)
 739         case "$host_os" in
 740         linux*)
 741             asm_arch=ppc64le
 742             ;;
 743         esac
 744         ;;
 745     aarch64)
 746         case "$host_os" in
 747         linux*)
 748             asm_arch=aarch64
 749             ;;
 750         esac
 751         ;;
 752     arm)
 753         case "$host_os" in
 754         linux*)
 755             asm_arch=arm
 756             ;;
 757         esac
 758         ;;
 759     esac
 760
 761     case "$asm_arch" in
 762     x86)
 763         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 764         AC_MSG_RESULT([yes, x86])
 765         ;;
 766     x86_64|amd64)
 767         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 768         AC_MSG_RESULT([yes, x86_64])
 769         ;;
 770     sparc)
 771         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 772         AC_MSG_RESULT([yes, sparc])
 773         ;;
 774     ppc64le)
 775         DEFINES="$DEFINES -DUSE_PPC64LE_ASM"
 776         AC_MSG_RESULT([yes, ppc64le])
 777         ;;
 778     aarch64)
 779         DEFINES="$DEFINES -DUSE_AARCH64_ASM"
 780         AC_MSG_RESULT([yes, aarch64])
 781         ;;
 782     arm)
 783         DEFINES="$DEFINES -DUSE_ARM_ASM"
 784         AC_MSG_RESULT([yes, arm])
 785         ;;
 786     *)
 787         AC_MSG_RESULT([no, platform not supported])
 788         ;;
 789     esac
 790 fi
 791
 792 AC_HEADER_MAJOR
 793 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 794 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 795 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 796 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 797
 798 dnl Check to see if dlopen is in default libraries (like Solaris, which
 799 dnl has it in libc), or if libdl is needed to get it.
 800 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 801     [AC_CHECK_LIB([dl], [dlopen],
 802        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 803 AC_SUBST([DLOPEN_LIBS])
 804
 805 dnl Check if that library also has dladdr
 806 save_LIBS="$LIBS"
 807 LIBS="$LIBS $DLOPEN_LIBS"
 808 AC_CHECK_FUNCS([dladdr])
 809 LIBS="$save_LIBS"
 810
 811 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 812
 813 case "$host_os" in
 814 darwin*)
 815     ;;
 816 *)
 817     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 818                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 819                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 820     AC_SUBST([CLOCK_LIB])
 821     ;;
 822 esac
 823
 824 dnl See if posix_memalign is available
 825 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 826
 827 dnl Check for zlib
 828 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 829
 830 dnl Check for pthreads
 831 AX_PTHREAD
 832 if test "x$ax_pthread_ok" = xno; then
 833     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 834 fi
 835 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 836 dnl to -pthread, which causes problems if we need -lpthread to appear in
 837 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 838 dnl is not valid for that platform.
 839 if test "x$android" = xno; then
 840     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 841 fi
 842 dnl According to the manual when using pthreads, one should add -pthread to
 843 dnl both compile and link-time arguments.
 844 dnl In practise that should be sufficient for all platforms, since any
 845 dnl platforms build with GCC and Clang support the flag.
 846 PTHREAD_LIBS="$PTHREAD_LIBS -pthread"
 847
 848 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 849 dnl project. Even then there's a notable issue as described in the project README
 850 case "$host_os" in
 851 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 852     pthread_stubs_possible="no"
 853     ;;
 854 * )
 855     pthread_stubs_possible="yes"
 856     ;;
 857 esac
 858
 859 if test "x$pthread_stubs_possible" = xyes; then
 860     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 861 fi
 862
 863 dnl SELinux awareness.
 864 AC_ARG_ENABLE([selinux],
 865     [AS_HELP_STRING([--enable-selinux],
 866         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 867     [MESA_SELINUX="$enableval"],
 868     [MESA_SELINUX=no])
 869 if test "x$enable_selinux" = "xyes"; then
 870     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 871         [AC_CHECK_HEADER([selinux/selinux.h],[],
 872                          [AC_MSG_ERROR([SELinux headers not found])])
 873          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 874                       [AC_MSG_ERROR([SELinux library not found])])
 875          SELINUX_LIBS="-lselinux"])
 876     DEFINES="$DEFINES -DMESA_SELINUX"
 877 fi
 878 AC_SUBST([SELINUX_CFLAGS])
 879 AC_SUBST([SELINUX_LIBS])
 880
 881 dnl
 882 dnl LLVM
 883 dnl
 884 AC_ARG_ENABLE([llvm-shared-libs],
 885     [AS_HELP_STRING([--enable-llvm-shared-libs],
 886         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 887     [enable_llvm_shared_libs="$enableval"],
 888     [enable_llvm_shared_libs=yes])
 889
 890 AC_ARG_WITH([llvm-prefix],
 891     [AS_HELP_STRING([--with-llvm-prefix],
 892         [Prefix for LLVM installations in non-standard locations])],
 893     [llvm_prefix="$withval"],
 894     [llvm_prefix=''])
 895
 896 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 897 if test "x$have_libelf" = xno; then
 898    LIBELF_LIBS=''
 899    LIBELF_CFLAGS=''
 900    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 901    AC_SUBST([LIBELF_LIBS])
 902    AC_SUBST([LIBELF_CFLAGS])
 903 fi
 904
 905 if test -z "$LLVM_CONFIG"; then
 906     if test -n "$llvm_prefix"; then
 907         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 908     else
 909         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 910     fi
 911 fi
 912
 913 llvm_add_component() {
 914     new_llvm_component=$1
 915     driver_name=$2
 916
 917     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 918         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 919     else
 920         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 921     fi
 922 }
 923
 924 llvm_add_default_components() {
 925     driver_name=$1
 926
 927     # Required default components
 928     llvm_add_component "bitwriter" $driver_name
 929     llvm_add_component "engine" $driver_name
 930     llvm_add_component "mcdisassembler" $driver_name
 931     llvm_add_component "mcjit" $driver_name
 932
 933     # Optional default components
 934     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 935         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 936     fi
 937 }
 938
 939 llvm_add_target() {
 940     new_llvm_target=$1
 941     driver_name=$2
 942
 943     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 944         llvm_add_component $new_llvm_target $driver_name
 945     else
 946         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 947     fi
 948 }
 949
 950 # Call this inside ` ` to get the return value.
 951 # $1 is the llvm-config command with arguments.
 952 strip_unwanted_llvm_flags() {
 953     echo " `$1` " | sed -E \
 954         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 955         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 956         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 957         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 958         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 959         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 960         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 961         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 962         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 963         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 964         -e 's/^[[[:space:]]]//' \
 965         -e 's/[[[:space:]]]$//'
 966 }
 967
 968 llvm_set_environment_variables() {
 969     if test "x$LLVM_CONFIG" != xno; then
 970         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 971         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 972         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 973         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 974
 975         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 976         save_CFLAGS="$CFLAGS"
 977         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 978
 979         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 980             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 981         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 982             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 983         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 984             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 985
 986         CFLAGS="$save_CFLAGS"
 987
 988         # Only needed for LLVM < 3.6.0
 989         if test -z "$LLVM_VERSION_PATCH"; then
 990             LLVM_VERSION_PATCH=0
 991         fi
 992
 993         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 994
 995         FOUND_LLVM=yes
 996     else
 997         FOUND_LLVM=no
 998         LLVM_VERSION_INT=0
 999     fi
1000 }
1001
1002 require_llvm() {
1003     if test "x$enable_llvm" != "xyes"; then
1004         AC_MSG_ERROR([--enable-llvm is required when building $1])
1005     fi
1006 }
1007
1008 llvm_require_version() {
1009     require_llvm $2
1010
1011     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1012     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1013     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1014
1015     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1016         # major > required major
1017         #  --> OK
1018         return
1019     fi
1020
1021     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1022         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1023             # major = required major and
1024             # minor > required minor
1025             #  --> OK
1026             return
1027         else
1028             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1029                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1030                     # major = required major and
1031                     # minor = required minor and
1032                     # patch >= required patch
1033                     #  --> OK
1034                     return
1035                 fi
1036             fi
1037         fi
1038     fi
1039
1040     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1041 }
1042
1043 radeon_llvm_check() {
1044     if test ${LLVM_VERSION_INT} -lt 307; then
1045         amdgpu_llvm_target_name='r600'
1046     else
1047         amdgpu_llvm_target_name='amdgpu'
1048     fi
1049
1050     llvm_require_version $*
1051
1052     llvm_add_target $amdgpu_llvm_target_name $2
1053
1054     llvm_add_default_components $2
1055     llvm_add_component "bitreader" $2
1056     llvm_add_component "ipo" $2
1057
1058     if test "x$have_libelf" != xyes; then
1059        AC_MSG_ERROR([$2 requires libelf when using llvm])
1060     fi
1061 }
1062
1063 llvm_set_environment_variables
1064
1065 AC_SUBST([LLVM_CFLAGS])
1066 AC_SUBST([LLVM_CXXFLAGS])
1067 AC_SUBST([LLVM_LIBS])
1068 AC_SUBST([LLVM_LDFLAGS])
1069 AC_SUBST([LLVM_INCLUDEDIR])
1070
1071 dnl
1072 dnl libunwind
1073 dnl
1074 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1075 AC_ARG_ENABLE([libunwind],
1076     [AS_HELP_STRING([--enable-libunwind],
1077             [Use libunwind for backtracing (default: auto)])],
1078         [LIBUNWIND="$enableval"],
1079         [LIBUNWIND="$HAVE_LIBUNWIND"])
1080
1081 if test "x$LIBUNWIND" = "xyes"; then
1082     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1083     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1084 fi
1085
1086
1087 dnl Options for APIs
1088 AC_ARG_ENABLE([opengl],
1089     [AS_HELP_STRING([--disable-opengl],
1090         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1091     [enable_opengl="$enableval"],
1092     [enable_opengl=yes])
1093 AC_ARG_ENABLE([gles1],
1094     [AS_HELP_STRING([--disable-gles1],
1095         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1096     [enable_gles1="$enableval"],
1097     [enable_gles1=yes])
1098 AC_ARG_ENABLE([gles2],
1099     [AS_HELP_STRING([--disable-gles2],
1100         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1101     [enable_gles2="$enableval"],
1102     [enable_gles2=yes])
1103
1104 AC_ARG_ENABLE([dri],
1105     [AS_HELP_STRING([--enable-dri],
1106         [enable DRI modules @<:@default=enabled@:>@])],
1107     [enable_dri="$enableval"],
1108     [enable_dri=yes])
1109
1110 AC_ARG_ENABLE([gallium-extra-hud],
1111     [AS_HELP_STRING([--enable-gallium-extra-hud],
1112         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1113     [enable_gallium_extra_hud="$enableval"],
1114     [enable_gallium_extra_hud=no])
1115 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1116 if test "x$enable_gallium_extra_hud" = xyes ; then
1117     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1118 fi
1119
1120 #TODO: no pkgconfig .pc available for libsensors.
1121 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1122 AC_ARG_ENABLE([lmsensors],
1123     [AS_HELP_STRING([--enable-lmsensors],
1124         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1125     [enable_lmsensors="$enableval"],
1126     [enable_lmsensors=no])
1127 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1128 if test "x$enable_lmsensors" = xyes ; then
1129     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1130     LIBSENSORS_LIBS="-lsensors"
1131 else
1132     LIBSENSORS_LIBS=""
1133 fi
1134 AC_SUBST(LIBSENSORS_LIBS)
1135
1136 case "$host_os" in
1137 linux*)
1138     dri3_default=yes
1139     ;;
1140 *)
1141     dri3_default=no
1142     ;;
1143 esac
1144
1145 if test "x$enable_dri" = xno; then
1146     dri3_default=no
1147 fi
1148
1149 AC_ARG_ENABLE([dri3],
1150     [AS_HELP_STRING([--enable-dri3],
1151         [enable DRI3 @<:@default=auto@:>@])],
1152     [enable_dri3="$enableval"],
1153     [enable_dri3="$dri3_default"])
1154 AC_ARG_ENABLE([glx],
1155     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1156         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1157     [enable_glx="$enableval"],
1158     [enable_glx=yes])
1159 AC_ARG_ENABLE([osmesa],
1160     [AS_HELP_STRING([--enable-osmesa],
1161         [enable OSMesa library @<:@default=disabled@:>@])],
1162     [enable_osmesa="$enableval"],
1163     [enable_osmesa=no])
1164 AC_ARG_ENABLE([gallium-osmesa],
1165     [AS_HELP_STRING([--enable-gallium-osmesa],
1166         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1167     [enable_gallium_osmesa="$enableval"],
1168     [enable_gallium_osmesa=no])
1169 AC_ARG_ENABLE([egl],
1170     [AS_HELP_STRING([--disable-egl],
1171         [disable EGL library @<:@default=enabled@:>@])],
1172     [enable_egl="$enableval"],
1173     [enable_egl=yes])
1174
1175 AC_ARG_ENABLE([xa],
1176     [AS_HELP_STRING([--enable-xa],
1177         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1178     [enable_xa="$enableval"],
1179     [enable_xa=no])
1180 AC_ARG_ENABLE([gbm],
1181    [AS_HELP_STRING([--enable-gbm],
1182          [enable gbm library @<:@default=yes except cygwin@:>@])],
1183    [enable_gbm="$enableval"],
1184    [case "$host_os" in
1185        cygwin*)
1186           enable_gbm=no
1187           ;;
1188        *)
1189           enable_gbm=yes
1190           ;;
1191     esac])
1192 AC_ARG_ENABLE([nine],
1193     [AS_HELP_STRING([--enable-nine],
1194         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1195     [enable_nine="$enableval"],
1196     [enable_nine=no])
1197
1198 AC_ARG_ENABLE([xvmc],
1199    [AS_HELP_STRING([--enable-xvmc],
1200          [enable xvmc library @<:@default=auto@:>@])],
1201    [enable_xvmc="$enableval"],
1202    [enable_xvmc=auto])
1203 AC_ARG_ENABLE([vdpau],
1204    [AS_HELP_STRING([--enable-vdpau],
1205          [enable vdpau library @<:@default=auto@:>@])],
1206    [enable_vdpau="$enableval"],
1207    [enable_vdpau=auto])
1208 AC_ARG_ENABLE([omx],
1209    [AS_HELP_STRING([--enable-omx],
1210          [enable OpenMAX library @<:@default=disabled@:>@])],
1211    [enable_omx="$enableval"],
1212    [enable_omx=no])
1213 AC_ARG_ENABLE([va],
1214    [AS_HELP_STRING([--enable-va],
1215          [enable va library @<:@default=auto@:>@])],
1216    [enable_va="$enableval"],
1217    [enable_va=auto])
1218 AC_ARG_ENABLE([opencl],
1219    [AS_HELP_STRING([--enable-opencl],
1220          [enable OpenCL library @<:@default=disabled@:>@])],
1221    [enable_opencl="$enableval"],
1222    [enable_opencl=no])
1223 AC_ARG_ENABLE([opencl_icd],
1224    [AS_HELP_STRING([--enable-opencl-icd],
1225           [Build an OpenCL ICD library to be loaded by an ICD implementation
1226            @<:@default=disabled@:>@])],
1227     [enable_opencl_icd="$enableval"],
1228     [enable_opencl_icd=no])
1229
1230 AC_ARG_ENABLE([gallium-tests],
1231     [AS_HELP_STRING([--enable-gallium-tests],
1232         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1233     [enable_gallium_tests="$enableval"],
1234     [enable_gallium_tests=no])
1235
1236 # Option for Gallium drivers
1237
1238 # Keep this in sync with the --with-gallium-drivers help string default value
1239 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1240
1241 AC_ARG_WITH([gallium-drivers],
1242     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1243         [comma delimited Gallium drivers list, e.g.
1244         "i915,nouveau,r300,r600,radeonsi,freedreno,pl111,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1245         @<:@default=r300,r600,svga,swrast@:>@])],
1246     [with_gallium_drivers="$withval"],
1247     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1248
1249 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1250 # here so that the script doesn't choke on an unknown driver name later.
1251 case "$with_gallium_drivers" in
1252     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1253     no) with_gallium_drivers='' ;;
1254 esac
1255
1256 if test "x$enable_opengl" = xno -a \
1257         "x$enable_gles1" = xno -a \
1258         "x$enable_gles2" = xno -a \
1259         "x$enable_nine" = xno -a \
1260         "x$enable_xa" = xno -a \
1261         "x$enable_xvmc" = xno -a \
1262         "x$enable_vdpau" = xno -a \
1263         "x$enable_omx" = xno -a \
1264         "x$enable_va" = xno -a \
1265         "x$enable_opencl" = xno; then
1266     AC_MSG_ERROR([at least one API should be enabled])
1267 fi
1268
1269 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1270 if test "x$enable_opengl" = xno -a \
1271         "x$enable_gles1" = xyes; then
1272     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1273 fi
1274
1275 if test "x$enable_opengl" = xno -a \
1276         "x$enable_gles2" = xyes; then
1277     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1278 fi
1279
1280 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1282 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1283 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1284                                         "x$enable_gles1" = xyes -o \
1285                                         "x$enable_gles2" = xyes)
1286 AM_CONDITIONAL(NEED_KHRPLATFORM, test "x$enable_egl" = xyes -o \
1287                                       "x$enable_gles1" = xyes -o \
1288                                       "x$enable_gles2" = xyes)
1289
1290 # Validate GLX options
1291 if test "x$enable_glx" = xyes; then
1292     if test "x$enable_dri" = xyes; then
1293         enable_glx=dri
1294     elif test -n "$with_gallium_drivers"; then
1295         enable_glx=gallium-xlib
1296     else
1297         enable_glx=xlib
1298     fi
1299 fi
1300 case "x$enable_glx" in
1301 xdri | xxlib | xgallium-xlib)
1302     # GLX requires OpenGL
1303     if test "x$enable_opengl" = xno; then
1304         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1305     fi
1306
1307     # Check individual dependencies
1308     case "x$enable_glx" in
1309     xdri)
1310         if test "x$enable_dri" = xno; then
1311             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1312         fi
1313         ;;
1314     xxlib)
1315         if test "x$enable_dri" = xyes; then
1316             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1317         fi
1318         ;;
1319     xgallium-xlib )
1320         if test "x$enable_dri" = xyes; then
1321             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1322         fi
1323         if test -z "$with_gallium_drivers"; then
1324             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1325         fi
1326         ;;
1327     esac
1328     ;;
1329 xno)
1330     ;;
1331 *)
1332     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1333     ;;
1334 esac
1335
1336 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1337 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1338 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1339 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1340
1341 DEFAULT_GL_LIB_NAME=GL
1342
1343 dnl
1344 dnl Libglvnd configuration
1345 dnl
1346 AC_ARG_ENABLE([libglvnd],
1347     [AS_HELP_STRING([--enable-libglvnd],
1348         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1349     [enable_libglvnd="$enableval"],
1350     [enable_libglvnd=no])
1351 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1352
1353 if test "x$enable_libglvnd" = xyes ; then
1354     dnl XXX: update once we can handle more than libGL/glx.
1355     dnl Namely: we should error out if neither of the glvnd enabled libraries
1356     dnl are built
1357     case "x$enable_glx" in
1358     xno)
1359         AC_MSG_ERROR([cannot build libglvnd without GLX])
1360         ;;
1361     xxlib | xgallium-xlib )
1362         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1363         ;;
1364     xdri)
1365         ;;
1366     esac
1367
1368     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1369     LIBGLVND_DATADIR=`$PKG_CONFIG --variable=datadir libglvnd`
1370     AC_SUBST([LIBGLVND_DATADIR])
1371
1372     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1373     DEFAULT_GL_LIB_NAME=GLX_mesa
1374 fi
1375
1376 AC_ARG_WITH([gl-lib-name],
1377   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1378     [specify GL library name @<:@default=GL@:>@])],
1379   [GL_LIB=$withval],
1380   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1381 AC_ARG_WITH([osmesa-lib-name],
1382   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1383     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1384   [OSMESA_LIB=$withval],
1385   [OSMESA_LIB=OSMesa])
1386 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1387 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1388
1389 dnl
1390 dnl Mangled Mesa support
1391 dnl
1392 AC_ARG_ENABLE([mangling],
1393   [AS_HELP_STRING([--enable-mangling],
1394     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1395   [enable_mangling="${enableval}"],
1396   [enable_mangling=no]
1397 )
1398 if test "x${enable_mangling}" = "xyes" ; then
1399   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1400   GL_LIB="Mangled${GL_LIB}"
1401   OSMESA_LIB="Mangled${OSMESA_LIB}"
1402 fi
1403 AC_SUBST([GL_LIB])
1404 AC_SUBST([OSMESA_LIB])
1405
1406 # Check for libdrm
1407 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1408                   [have_libdrm=yes], [have_libdrm=no])
1409 if test "x$have_libdrm" = xyes; then
1410     DEFINES="$DEFINES -DHAVE_LIBDRM"
1411 fi
1412
1413 require_libdrm() {
1414     if test "x$have_libdrm" != xyes; then
1415        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1416     fi
1417 }
1418
1419
1420 # Select which platform-dependent DRI code gets built
1421 case "$host_os" in
1422 darwin*)
1423     dri_platform='apple' ;;
1424 cygwin*)
1425     dri_platform='windows' ;;
1426 gnu*)
1427     dri_platform='none' ;;
1428 *)
1429     dri_platform='drm' ;;
1430 esac
1431
1432 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1433     have_drisw_kms='yes'
1434 fi
1435
1436 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1437 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1438 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1439 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1440 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1441 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1442 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1443 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1444 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1445
1446 AC_ARG_ENABLE([shared-glapi],
1447     [AS_HELP_STRING([--enable-shared-glapi],
1448         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1449     [enable_shared_glapi="$enableval"],
1450     [enable_shared_glapi=yes])
1451
1452 case "x$enable_opengl$enable_gles1$enable_gles2" in
1453 x*yes*yes*)
1454     if test "x$enable_shared_glapi" = xno; then
1455         AC_MSG_ERROR([shared GLAPI required when building two or more of
1456                       the following APIs - opengl, gles1 gles2])
1457     fi
1458     ;;
1459 esac
1460
1461 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1462
1463 # Build the pipe-drivers as separate libraries/modules.
1464 # Do not touch this unless you know what you are doing.
1465 # XXX: Expose via configure option ?
1466 enable_shared_pipe_drivers=no
1467
1468 dnl
1469 dnl Driver specific build directories
1470 dnl
1471
1472 if test "x$enable_gallium_osmesa" = xyes; then
1473     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1474         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1475     fi
1476     if test "x$enable_osmesa" = xyes; then
1477         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1478     fi
1479 fi
1480
1481 require_dri_shared_libs_and_glapi() {
1482     if test "x$enable_static" = xyes; then
1483         AC_MSG_ERROR([$1 cannot be build as static library])
1484     fi
1485
1486     if test "x$enable_dri" != xyes; then
1487         # There is only a single backend which won't be build/used otherwise.
1488         # XXX: Revisit this as the egl/haiku is a thing.
1489         AC_MSG_ERROR([$1 requires --enable-dri])
1490     fi
1491
1492     if test "x$enable_shared_glapi" != xyes; then
1493         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1494     fi
1495 }
1496
1497 if test "x$enable_dri" = xyes; then
1498     require_dri_shared_libs_and_glapi "DRI"
1499
1500     # not a hard requirement as swrast does not depend on it
1501     if test "x$have_libdrm" = xyes; then
1502         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1503     fi
1504 fi
1505
1506 AC_ARG_ENABLE([driglx-direct],
1507     [AS_HELP_STRING([--disable-driglx-direct],
1508         [disable direct rendering in GLX and EGL for DRI \
1509             @<:@default=auto@:>@])],
1510     [driglx_direct="$enableval"],
1511     [driglx_direct="yes"])
1512
1513 dnl
1514 dnl libGL configuration per driver
1515 dnl
1516 if test "x$enable_glx" != xno; then
1517     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1518 fi
1519 case "x$enable_glx" in
1520 xxlib | xgallium-xlib)
1521     # Xlib-based GLX
1522     dri_modules="x11 xext xcb"
1523     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1524     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1525     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1526     GL_LIB_DEPS="$XLIBGL_LIBS"
1527     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1528     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1529     ;;
1530 xdri)
1531     # DRI-based GLX
1532
1533     # find the DRI deps for libGL
1534     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1535
1536     if test x"$driglx_direct" = xyes; then
1537         if test x"$dri_platform" = xdrm ; then
1538             DEFINES="$DEFINES -DGLX_USE_DRM"
1539             require_libdrm "Direct rendering"
1540
1541             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1542             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1543
1544             if test x"$enable_dri" = xyes; then
1545                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1546             fi
1547         fi
1548         if test x"$dri_platform" = xapple ; then
1549             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1550         fi
1551         if test x"$dri_platform" = xwindows ; then
1552             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1553         fi
1554     fi
1555
1556     # add xf86vidmode if available
1557     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1558     if test "$HAVE_XF86VIDMODE" = yes ; then
1559         dri_modules="$dri_modules xxf86vm"
1560     fi
1561
1562     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1563     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1564     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1565     GL_LIB_DEPS="$DRIGL_LIBS"
1566
1567     # need DRM libs, $PTHREAD_LIBS, etc.
1568     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1569     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1570     ;;
1571 esac
1572
1573 # This is outside the case (above) so that it is invoked even for non-GLX
1574 # builds.
1575 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1576
1577 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1578 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1579 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1581
1582 AC_SUBST([X11_INCLUDES])
1583 AC_SUBST([GL_LIB_DEPS])
1584 AC_SUBST([GL_PC_REQ_PRIV])
1585 AC_SUBST([GL_PC_LIB_PRIV])
1586 AC_SUBST([GL_PC_CFLAGS])
1587 AC_SUBST([DRI_PC_REQ_PRIV])
1588 AC_SUBST([GLESv1_CM_LIB_DEPS])
1589 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1590 AC_SUBST([GLESv2_LIB_DEPS])
1591 AC_SUBST([GLESv2_PC_LIB_PRIV])
1592
1593 AC_SUBST([HAVE_XF86VIDMODE])
1594
1595 dnl
1596 dnl More GLX setup
1597 dnl
1598 case "x$enable_glx" in
1599 xxlib | xgallium-xlib)
1600     DEFINES="$DEFINES -DUSE_XSHM"
1601     ;;
1602 xdri)
1603     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1604     if test "x$driglx_direct" = xyes; then
1605         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1606     fi
1607     ;;
1608 esac
1609
1610 dnl
1611 dnl TLS detection
1612 dnl
1613
1614 AC_ARG_ENABLE([glx-tls],
1615     [AS_HELP_STRING([--enable-glx-tls],
1616         [enable TLS support in GLX @<:@default=enabled@:>@])],
1617     [GLX_USE_TLS="$enableval"],
1618     [GLX_USE_TLS=yes])
1619 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1620
1621 if test "x$GLX_USE_TLS" = xyes; then
1622     DEFINES="$DEFINES -DGLX_USE_TLS"
1623 fi
1624
1625 dnl Read-only text section on x86 hardened platforms
1626 AC_ARG_ENABLE([glx-read-only-text],
1627     [AS_HELP_STRING([--enable-glx-read-only-text],
1628         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1629     [enable_glx_read_only_text="$enableval"],
1630     [enable_glx_read_only_text=no])
1631 if test "x$enable_glx_read_only_text" = xyes; then
1632     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1633 fi
1634
1635 dnl
1636 dnl DEPRECATED: EGL Platforms configuration
1637 dnl
1638 AC_ARG_WITH([egl-platforms],
1639     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1640         [DEPRECATED: use --with-platforms instead@<:@default=auto@:>@])],
1641     [with_egl_platforms="$withval"],
1642     [with_egl_platforms=auto])
1643
1644 if test "x$with_egl_platforms" = xauto; then
1645     with_egl_platforms="x11,surfaceless"
1646     if test "x$enable_gbm" = xyes; then
1647         with_egl_platforms="$with_egl_platforms,drm"
1648     fi
1649 else
1650     AC_MSG_WARN([--with-egl-platforms is deprecated. Use --with-platforms instead.])
1651 fi
1652
1653 dnl
1654 dnl Platforms configuration
1655 dnl
1656 AC_ARG_WITH([platforms],
1657     [AS_HELP_STRING([--with-platforms@<:@=DIRS...@:>@],
1658         [comma delimited native platforms libEGL/Vulkan/other supports, e.g.
1659         "x11,drm,wayland,surfaceless..." @<:@default=auto@:>@])],
1660     [with_platforms="$withval"],
1661     [with_platforms=auto])
1662
1663 # Reuse the autodetection rather than duplicating it.
1664 if test "x$with_platforms" = xauto; then
1665     with_platforms=$with_egl_platforms
1666 fi
1667
1668 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
1669         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
1670         WAYLAND_SCANNER='')
1671 if test "x$WAYLAND_SCANNER" = x; then
1672     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
1673 fi
1674
1675 PKG_CHECK_EXISTS([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED], [have_wayland_protocols=yes], [have_wayland_protocols=no])
1676 if test "x$have_wayland_protocols" = xyes; then
1677     ac_wayland_protocols_pkgdatadir=`$PKG_CONFIG --variable=pkgdatadir wayland-protocols`
1678 fi
1679 AC_SUBST(WAYLAND_PROTOCOLS_DATADIR, $ac_wayland_protocols_pkgdatadir)
1680
1681 # Do per platform setups and checks
1682 platforms=`IFS=', '; echo $with_platforms`
1683 for plat in $platforms; do
1684     case "$plat" in
1685     wayland)
1686
1687         PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1688
1689         if test "x$WAYLAND_SCANNER" = "x:"; then
1690                 AC_MSG_ERROR([wayland-scanner is needed to compile the wayland platform])
1691         fi
1692         if test "x$have_wayland_protocols" = xno; then
1693                 AC_MSG_ERROR([wayland-protocols >= $WAYLAND_PROTOCOLS_REQUIRED is needed to compile the wayland platform])
1694         fi
1695         DEFINES="$DEFINES -DHAVE_WAYLAND_PLATFORM"
1696         ;;
1697
1698     x11)
1699         PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1700         DEFINES="$DEFINES -DHAVE_X11_PLATFORM"
1701         ;;
1702
1703     drm)
1704         test "x$enable_gbm" = "xno" &&
1705                 AC_MSG_ERROR([EGL platform drm needs gbm])
1706         DEFINES="$DEFINES -DHAVE_DRM_PLATFORM"
1707         ;;
1708
1709     surfaceless)
1710         DEFINES="$DEFINES -DHAVE_SURFACELESS_PLATFORM"
1711         ;;
1712
1713     android)
1714         PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
1715         DEFINES="$DEFINES -DHAVE_ANDROID_PLATFORM"
1716         ;;
1717
1718     *)
1719         AC_MSG_ERROR([platform '$plat' does not exist])
1720         ;;
1721     esac
1722
1723     case "$plat" in
1724     wayland|drm|surfaceless)
1725         require_libdrm "Platform $plat"
1726         ;;
1727     esac
1728 done
1729
1730 if test "x$enable_glx" != xno; then
1731     if ! echo "$platforms" | grep -q 'x11'; then
1732         AC_MSG_ERROR([Building GLX without the x11 platform is not supported])
1733     fi
1734 fi
1735
1736 if test x"$enable_dri3" = xyes; then
1737     DEFINES="$DEFINES -DHAVE_DRI3"
1738
1739     dri3_modules="x11-xcb xcb >= $XCB_REQUIRED xcb-dri3 xcb-xfixes xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1740     PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1741 fi
1742
1743 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$platforms" | grep -q 'x11')
1744 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$platforms" | grep -q 'wayland')
1745 AM_CONDITIONAL(HAVE_PLATFORM_DRM, echo "$platforms" | grep -q 'drm')
1746 AM_CONDITIONAL(HAVE_PLATFORM_SURFACELESS, echo "$platforms" | grep -q 'surfaceless')
1747 AM_CONDITIONAL(HAVE_PLATFORM_ANDROID, echo "$platforms" | grep -q 'android')
1748
1749 dnl
1750 dnl More DRI setup
1751 dnl
1752 dnl Directory for DRI drivers
1753 AC_ARG_WITH([dri-driverdir],
1754     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1755         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1756     [DRI_DRIVER_INSTALL_DIR="$withval"],
1757     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1758 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1759 dnl Extra search path for DRI drivers
1760 AC_ARG_WITH([dri-searchpath],
1761     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1762         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1763     [DRI_DRIVER_SEARCH_DIR="$withval"],
1764     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1765 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1766 dnl Which drivers to build - default is chosen by platform
1767 AC_ARG_WITH([dri-drivers],
1768     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1769         [comma delimited classic DRI drivers list, e.g.
1770         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1771     [with_dri_drivers="$withval"],
1772     [with_dri_drivers=auto])
1773
1774 if test "x$with_dri_drivers" = xauto; then
1775     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1776         with_dri_drivers="yes"
1777     else
1778         with_dri_drivers="no"
1779     fi
1780 fi
1781 if test "x$with_dri_drivers" = xno; then
1782     with_dri_drivers=''
1783 fi
1784
1785 # Check for expat
1786 PKG_CHECK_MODULES([EXPAT], [expat],,
1787     [PKG_CHECK_MODULES([EXPAT], [expat21])]
1788 )
1789
1790 dnl If $with_dri_drivers is yes, drivers will be added through
1791 dnl platform checks. Set DEFINES and LIB_DEPS
1792 if test "x$enable_dri" = xyes; then
1793     # Platform specific settings and drivers to build
1794     case "$host_os" in
1795     linux*)
1796         case "$host_cpu" in
1797         powerpc* | sparc*)
1798             # Build only the drivers for cards that exist on PowerPC/sparc
1799             if test "x$with_dri_drivers" = "xyes"; then
1800                 with_dri_drivers="r200 radeon swrast"
1801             fi
1802             ;;
1803         esac
1804         ;;
1805     cygwin*)
1806         if test "x$with_dri_drivers" = "xyes"; then
1807             with_dri_drivers="swrast"
1808         fi
1809         ;;
1810     darwin*)
1811         DEFINES="$DEFINES -DBUILDING_MESA"
1812         if test "x$with_dri_drivers" = "xyes"; then
1813             with_dri_drivers="swrast"
1814         fi
1815         ;;
1816     esac
1817
1818     # default drivers
1819     if test "x$with_dri_drivers" = "xyes"; then
1820         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1821     fi
1822
1823     # put all the necessary libs together
1824     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1825 fi
1826
1827 AC_SUBST([DRI_LIB_DEPS])
1828
1829 DRI_DIRS=''
1830 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1831 if test -n "$with_dri_drivers"; then
1832     if test "x$enable_opengl" != xyes; then
1833         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1834     fi
1835
1836     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1837     for driver in $dri_drivers; do
1838         DRI_DIRS="$DRI_DIRS $driver"
1839         case "x$driver" in
1840         xi915)
1841             require_libdrm "i915"
1842             HAVE_I915_DRI=yes
1843             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1844             ;;
1845         xi965)
1846             require_libdrm "i965"
1847             HAVE_I965_DRI=yes
1848             ;;
1849         xnouveau)
1850             require_libdrm "nouveau"
1851             HAVE_NOUVEAU_DRI=yes
1852             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1853             ;;
1854         xradeon)
1855             require_libdrm "radeon"
1856             HAVE_RADEON_DRI=yes;
1857             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1858             ;;
1859         xr200)
1860             require_libdrm "r200"
1861             HAVE_R200_DRI=yes
1862             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1863             ;;
1864         xswrast)
1865             HAVE_SWRAST_DRI=yes
1866             ;;
1867         *)
1868             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1869             ;;
1870         esac
1871     done
1872     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1873 fi
1874
1875
1876 dnl
1877 dnl Gallium LLVM
1878 dnl Deprecated: kept for backwards compatibility
1879 dnl
1880 AC_ARG_ENABLE([gallium-llvm],
1881     [AS_HELP_STRING([--enable-gallium-llvm],
1882         [DEPRECATED: use --enable-llvm instead])],
1883     [enable_gallium_llvm="$enableval"],
1884     [enable_gallium_llvm=auto])
1885
1886 if test "x$enable_gallium_llvm" != xauto; then
1887    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1888    enable_llvm=$enable_gallium_llvm
1889 fi
1890
1891 dnl
1892 dnl LLVM
1893 dnl
1894 AC_ARG_ENABLE([llvm],
1895     [AS_HELP_STRING([--enable-llvm],
1896         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1897     [enable_llvm="$enableval"],
1898     [enable_llvm=auto])
1899
1900 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1901     if test "x$FOUND_LLVM" = xyes; then
1902         case "$host_cpu" in
1903         i*86|x86_64|amd64) enable_llvm=yes;;
1904         *) enable_llvm=no;;
1905         esac
1906     else
1907         enable_llvm=no
1908     fi
1909 fi
1910
1911 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1912     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1913 fi
1914
1915 #
1916 # Vulkan driver configuration
1917 #
1918
1919 AC_ARG_WITH([vulkan-drivers],
1920     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1921         [comma delimited Vulkan drivers list, e.g.
1922         "intel,radeon"
1923         @<:@default=no@:>@])],
1924     [with_vulkan_drivers="$withval"],
1925     [with_vulkan_drivers="no"])
1926
1927 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1928 # here so that the script doesn't choke on an unknown driver name later.
1929 case "x$with_vulkan_drivers" in
1930     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1931     xno) with_vulkan_drivers='' ;;
1932 esac
1933
1934 AC_ARG_WITH([vulkan-icddir],
1935     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1936         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1937     [VULKAN_ICD_INSTALL_DIR="$withval"],
1938     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1939 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1940
1941 require_x11_dri3() {
1942     if echo "$platforms" | grep -q 'x11'; then
1943         if test "x$enable_dri3" != xyes; then
1944             AC_MSG_ERROR([$1 Vulkan driver requires DRI3 when built with X11])
1945         fi
1946     fi
1947 }
1948
1949 if test -n "$with_vulkan_drivers"; then
1950     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1951         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1952     fi
1953
1954     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1955     for driver in $VULKAN_DRIVERS; do
1956         case "x$driver" in
1957         xintel)
1958             require_libdrm "ANV"
1959             require_x11_dri3 "ANV"
1960             HAVE_INTEL_VULKAN=yes
1961             ;;
1962         xradeon)
1963             require_libdrm "radv"
1964             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1965             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1966             require_x11_dri3 "radv"
1967             HAVE_RADEON_VULKAN=yes
1968             ;;
1969         *)
1970             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1971             ;;
1972         esac
1973     done
1974     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1975 fi
1976
1977
1978 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1979 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1980 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1981                                   "x$enable_osmesa" = xyes -o \
1982                                   -n "$DRI_DIRS")
1983
1984 dnl
1985 dnl OSMesa configuration
1986 dnl
1987
1988 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1989 AC_ARG_WITH([osmesa-bits],
1990     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1991         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1992     [osmesa_bits="$withval"],
1993     [osmesa_bits=8])
1994 if test "x$osmesa_bits" != x8; then
1995     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1996         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1997         osmesa_bits=8
1998     fi
1999 fi
2000 case "x$osmesa_bits" in
2001 x8)
2002     OSMESA_LIB="${OSMESA_LIB}"
2003     ;;
2004 x16|x32)
2005     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
2006     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
2007     ;;
2008 *)
2009     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
2010     ;;
2011 esac
2012
2013 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
2014     # only link libraries with osmesa if shared
2015     if test "$enable_static" = no; then
2016         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2017     else
2018         OSMESA_LIB_DEPS=""
2019     fi
2020     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
2021 fi
2022
2023 AC_SUBST([OSMESA_LIB_DEPS])
2024 AC_SUBST([OSMESA_PC_REQ])
2025 AC_SUBST([OSMESA_PC_LIB_PRIV])
2026
2027 dnl
2028 dnl gbm configuration
2029 dnl
2030 if test "x$enable_gbm" = xyes; then
2031     require_dri_shared_libs_and_glapi "gbm"
2032 fi
2033 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
2034 # FINISHME: GBM has a number of dependencies which we should add below
2035 GBM_PC_REQ_PRIV=""
2036 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2037 AC_SUBST([GBM_PC_REQ_PRIV])
2038 AC_SUBST([GBM_PC_LIB_PRIV])
2039
2040 dnl
2041 dnl EGL configuration
2042 dnl
2043
2044 if test "x$enable_egl" = xyes; then
2045     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2046
2047     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2048
2049     require_dri_shared_libs_and_glapi "egl"
2050 fi
2051 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2052 AC_SUBST([EGL_LIB_DEPS])
2053
2054 gallium_st="mesa"
2055
2056 dnl
2057 dnl XA configuration
2058 dnl
2059 if test "x$enable_xa" = xyes; then
2060     if test "x$with_gallium_drivers" = xswrast; then
2061        AC_MSG_ERROR([
2062           Building xa requires at least one non swrast gallium driver.
2063           If you are looking to use libxatracker.so with the VMware driver,
2064           make sure to include svga in the gallium drivers list, apart from
2065           enabling XA.
2066           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2067     fi
2068     gallium_st="$gallium_st xa"
2069 fi
2070 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2071
2072 if echo $platforms | grep -q "x11"; then
2073     have_xvmc_platform=yes
2074 else
2075     have_xvmc_platform=no
2076 fi
2077
2078 if echo $platforms | grep -q "x11"; then
2079     have_vdpau_platform=yes
2080 else
2081     have_vdpau_platform=no
2082 fi
2083
2084 if echo $platforms | grep -q "x11\|drm"; then
2085     have_omx_platform=yes
2086 else
2087     have_omx_platform=no
2088 fi
2089
2090 if echo $platforms | grep -q "x11\|drm\|wayland"; then
2091     have_va_platform=yes
2092 else
2093     have_va_platform=no
2094 fi
2095
2096 dnl
2097 dnl Gallium G3DVL configuration
2098 dnl
2099 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2100     if test "x$enable_xvmc" = xauto -a "x$have_xvmc_platform" = xyes; then
2101         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2102     fi
2103
2104     if test "x$enable_vdpau" = xauto -a "x$have_vdpau_platform" = xyes; then
2105         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2106     fi
2107
2108     if test "x$enable_omx" = xauto -a "x$have_omx_platform" = xyes; then
2109         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2110     fi
2111
2112     if test "x$enable_va" = xauto -a "x$have_va_platform" = xyes; then
2113         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2114     fi
2115 fi
2116
2117 if test "x$enable_dri" = xyes -o \
2118         "x$enable_xvmc" = xyes -o \
2119         "x$enable_vdpau" = xyes -o \
2120         "x$enable_omx" = xyes -o \
2121         "x$enable_va" = xyes; then
2122     need_gallium_vl=yes
2123 fi
2124 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2125
2126 if test "x$enable_xvmc" = xyes -o \
2127         "x$enable_vdpau" = xyes -o \
2128         "x$enable_omx" = xyes -o \
2129         "x$enable_va" = xyes; then
2130     PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2131     need_gallium_vl_winsys=yes
2132 fi
2133 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2134
2135 if test "x$enable_xvmc" = xyes; then
2136     if test "x$have_xvmc_platform" != xyes; then
2137         AC_MSG_ERROR([XVMC requires the x11 platforms])
2138     fi
2139     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2140     gallium_st="$gallium_st xvmc"
2141 fi
2142 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2143
2144 if test "x$enable_vdpau" = xyes; then
2145     if test "x$have_vdpau_platform" != xyes; then
2146         AC_MSG_ERROR([VDPAU requires the x11 platforms])
2147     fi
2148     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2149     gallium_st="$gallium_st vdpau"
2150     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2151 fi
2152 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2153
2154 if test "x$enable_omx" = xyes; then
2155     if test "x$have_omx_platform" != xyes; then
2156         AC_MSG_ERROR([OMX requires at least one of the x11 or drm platforms])
2157     fi
2158     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2159     gallium_st="$gallium_st omx"
2160 fi
2161 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2162
2163 if test "x$enable_va" = xyes; then
2164     if test "x$have_va_platform" != xyes; then
2165         AC_MSG_ERROR([VA requires at least one of the x11 drm or wayland platforms])
2166     fi
2167     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2168     gallium_st="$gallium_st va"
2169 fi
2170 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2171
2172 dnl
2173 dnl Nine Direct3D9 configuration
2174 dnl
2175 if test "x$enable_nine" = xyes; then
2176     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2177         AC_MSG_ERROR([nine requires the gallium swrast driver])
2178     fi
2179     if test "x$with_gallium_drivers" = xswrast; then
2180         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2181     fi
2182     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2183         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2184     fi
2185
2186     if test "x$enable_dri3" = xno; then
2187         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2188     fi
2189
2190     gallium_st="$gallium_st nine"
2191 fi
2192 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2193
2194 dnl
2195 dnl OpenCL configuration
2196 dnl
2197
2198 AC_ARG_WITH([clang-libdir],
2199    [AS_HELP_STRING([--with-clang-libdir],
2200          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2201    [CLANG_LIBDIR="$withval"],
2202    [CLANG_LIBDIR=''])
2203
2204 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2205
2206 if test "x$enable_opencl" = xyes; then
2207     if test -z "$with_gallium_drivers"; then
2208         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2209     fi
2210
2211     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2212         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2213     fi
2214
2215     if test "x$have_libclc" = xno; then
2216         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2217                     Make sure the directory containing libclc.pc is specified in your
2218                     PKG_CONFIG_PATH environment variable.
2219                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2220     else
2221         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2222         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2223         AC_SUBST([LIBCLC_INCLUDEDIR])
2224         AC_SUBST([LIBCLC_LIBEXECDIR])
2225     fi
2226
2227     gallium_st="$gallium_st clover"
2228
2229     if test "x$enable_opencl_icd" = xyes; then
2230         OPENCL_LIBNAME="MesaOpenCL"
2231     else
2232         OPENCL_LIBNAME="OpenCL"
2233     fi
2234
2235     if test "x$have_libelf" != xyes; then
2236        AC_MSG_ERROR([Clover requires libelf])
2237     fi
2238
2239     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2240         altivec_enabled=no
2241         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2242         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2243         #error "AltiVec not enabled"
2244         #endif
2245         ])], altivec_enabled=yes)
2246
2247         if test "$altivec_enabled" = yes; then
2248             CLOVER_STD_OVERRIDE="-std=gnu++11"
2249         fi
2250         AC_SUBST([CLOVER_STD_OVERRIDE])
2251     fi
2252
2253     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2254
2255     llvm_add_default_components "opencl"
2256     llvm_add_component "all-targets" "opencl"
2257     llvm_add_component "linker" "opencl"
2258     llvm_add_component "instrumentation" "opencl"
2259     llvm_add_component "ipo" "opencl"
2260     llvm_add_component "irreader" "opencl"
2261     llvm_add_component "option" "opencl"
2262     llvm_add_component "objcarcopts" "opencl"
2263     llvm_add_component "profiledata" "opencl"
2264
2265     dnl Check for Clang internal headers
2266     if test -z "$CLANG_LIBDIR"; then
2267         CLANG_LIBDIR=${LLVM_LIBDIR}
2268     fi
2269     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2270     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2271         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2272 fi
2273 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2274 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2275 AC_SUBST([OPENCL_LIBNAME])
2276 AC_SUBST([CLANG_RESOURCE_DIR])
2277
2278 dnl
2279 dnl Gallium configuration
2280 dnl
2281 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2282
2283 # libEGL wants to default to the first platform specified in
2284 # ./configure.  parse that here.
2285 if test "x$platforms" != "x"; then
2286     FIRST_PLATFORM_CAPS=`echo $platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2287     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2288 else
2289     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2290 fi
2291
2292 AC_SUBST([EGL_NATIVE_PLATFORM])
2293 AC_SUBST([EGL_CFLAGS])
2294
2295 # If we don't have the X11 platform, set this define so we don't try to include
2296 # the X11 headers.
2297 if ! echo "$platforms" | grep -q 'x11'; then
2298     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2299     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2300 fi
2301
2302 dnl Directory for XVMC libs
2303 AC_ARG_WITH([xvmc-libdir],
2304     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2305         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2306     [XVMC_LIB_INSTALL_DIR="$withval"],
2307     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2308 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2309
2310 dnl
2311 dnl Gallium Tests
2312 dnl
2313 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2314
2315 dnl Directory for VDPAU libs
2316 AC_ARG_WITH([vdpau-libdir],
2317     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2318         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2319     [VDPAU_LIB_INSTALL_DIR="$withval"],
2320     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2321 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2322
2323 dnl Directory for OMX libs
2324
2325 AC_ARG_WITH([omx-libdir],
2326     [AS_HELP_STRING([--with-omx-libdir=DIR],
2327         [directory for the OMX libraries])],
2328     [OMX_LIB_INSTALL_DIR="$withval"],
2329     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2330                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2331 AC_SUBST([OMX_LIB_INSTALL_DIR])
2332
2333 dnl Directory for VA libs
2334
2335 AC_ARG_WITH([va-libdir],
2336     [AS_HELP_STRING([--with-va-libdir=DIR],
2337         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2338     [VA_LIB_INSTALL_DIR="$withval"],
2339     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2340 AC_SUBST([VA_LIB_INSTALL_DIR])
2341
2342 AC_ARG_WITH([d3d-libdir],
2343     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2344         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2345     [D3D_DRIVER_INSTALL_DIR="$withval"],
2346     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2347 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2348
2349 dnl Architectures to build SWR library for
2350
2351 AC_ARG_WITH([swr-archs],
2352     [AS_HELP_STRING([--with-swr-archs@<:@=DIRS...@:>@],
2353         [comma delimited swr architectures list, e.g.
2354         "avx,avx2,knl,skx" @<:@default="avx,avx2"@:>@])],
2355     [with_swr_archs="$withval"],
2356     [with_swr_archs="avx,avx2"])
2357
2358 dnl
2359 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2360 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2361 dnl architectures.
2362 dnl
2363 r300_require_llvm() {
2364     case "$host" in *gnux32) return;; esac
2365     case "$host_cpu" in
2366     i*86|x86_64|amd64) require_llvm $1
2367         ;;
2368     esac
2369 }
2370
2371 dnl
2372 dnl DRM is needed by X, Wayland, and offscreen rendering.
2373 dnl Surfaceless is an alternative for the last one.
2374 dnl
2375 require_basic_egl() {
2376     case "$with_platforms" in
2377         *drm*|*surfaceless*)
2378             ;;
2379         *)
2380             AC_MSG_ERROR([$1 requires one of these:
2381                   1) --with-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2382                   2) --with-platforms=surfaceless (offscreen only)
2383                   Recommended options: drm,x11])
2384             ;;
2385     esac
2386 }
2387
2388 swr_require_cxx_feature_flags() {
2389     feature_name="$1"
2390     preprocessor_test="$2"
2391     option_list="$3"
2392     output_var="$4"
2393
2394     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2395     AC_LANG_PUSH([C++])
2396     save_CXXFLAGS="$CXXFLAGS"
2397     save_IFS="$IFS"
2398     IFS=","
2399     found=0
2400     for opts in $option_list
2401     do
2402         unset IFS
2403         CXXFLAGS="$opts $save_CXXFLAGS"
2404         AC_COMPILE_IFELSE(
2405             [AC_LANG_PROGRAM(
2406                 [   #if !($preprocessor_test)
2407                     #error
2408                     #endif
2409                 ])],
2410             [found=1; break],
2411             [])
2412         IFS=","
2413     done
2414     IFS="$save_IFS"
2415     CXXFLAGS="$save_CXXFLAGS"
2416     AC_LANG_POP([C++])
2417     if test $found -eq 1; then
2418         AC_MSG_RESULT([$opts])
2419         eval "$output_var=\$opts"
2420         return 0
2421     fi
2422     AC_MSG_RESULT([no])
2423     AC_MSG_ERROR([swr requires $feature_name support])
2424     return 1
2425 }
2426
2427 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2428 if test -n "$with_gallium_drivers"; then
2429     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2430     for driver in $gallium_drivers; do
2431         case "x$driver" in
2432         xsvga)
2433             HAVE_GALLIUM_SVGA=yes
2434             require_libdrm "svga"
2435             ;;
2436         xi915)
2437             HAVE_GALLIUM_I915=yes
2438             PKG_CHECK_MODULES([I915], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2439             require_libdrm "Gallium i915"
2440             ;;
2441         xr300)
2442             HAVE_GALLIUM_R300=yes
2443             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2444             require_libdrm "r300"
2445             r300_require_llvm "r300"
2446             ;;
2447         xr600)
2448             HAVE_GALLIUM_R600=yes
2449             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2450             require_libdrm "r600"
2451             if test "x$enable_llvm" = xyes; then
2452                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2453
2454                 llvm_add_component "asmparser" "r600"
2455                 llvm_add_component "bitreader" "r600"
2456             fi
2457             ;;
2458         xradeonsi)
2459             HAVE_GALLIUM_RADEONSI=yes
2460             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2461             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2462             require_libdrm "radeonsi"
2463             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2464             if test "x$enable_egl" = xyes; then
2465                 require_basic_egl "radeonsi"
2466             fi
2467             ;;
2468         xnouveau)
2469             HAVE_GALLIUM_NOUVEAU=yes
2470             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2471             require_libdrm "nouveau"
2472             ;;
2473         xfreedreno)
2474             HAVE_GALLIUM_FREEDRENO=yes
2475             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2476             require_libdrm "freedreno"
2477             ;;
2478         xetnaviv)
2479             HAVE_GALLIUM_ETNAVIV=yes
2480             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2481             require_libdrm "etnaviv"
2482             ;;
2483        ximx)
2484             HAVE_GALLIUM_IMX=yes
2485             ;;
2486         xswrast)
2487             HAVE_GALLIUM_SOFTPIPE=yes
2488             if test "x$enable_llvm" = xyes; then
2489                 HAVE_GALLIUM_LLVMPIPE=yes
2490             fi
2491             ;;
2492         xswr)
2493             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2494
2495             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2496                 ",-std=c++11" \
2497                 SWR_CXX11_CXXFLAGS
2498             AC_SUBST([SWR_CXX11_CXXFLAGS])
2499
2500             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2501                 ",-target-cpu=sandybridge,-mavx,-march=core-avx,-tp=sandybridge" \
2502                 SWR_AVX_CXXFLAGS
2503             AC_SUBST([SWR_AVX_CXXFLAGS])
2504
2505             swr_archs=`IFS=', '; echo $with_swr_archs`
2506             for arch in $swr_archs; do
2507                 case "x$arch" in
2508                 xavx)
2509                     HAVE_SWR_AVX=yes
2510                     ;;
2511                 xavx2)
2512                     swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2513                         ",-target-cpu=haswell,-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2,-tp=haswell" \
2514                         SWR_AVX2_CXXFLAGS
2515                     AC_SUBST([SWR_AVX2_CXXFLAGS])
2516                     HAVE_SWR_AVX2=yes
2517                     ;;
2518                 xknl)
2519                     swr_require_cxx_feature_flags "KNL" "defined(__AVX512F__) && defined(__AVX512ER__)" \
2520                         ",-target-cpu=mic-knl,-march=knl,-xMIC-AVX512" \
2521                         SWR_KNL_CXXFLAGS
2522                     AC_SUBST([SWR_KNL_CXXFLAGS])
2523                     HAVE_SWR_KNL=yes
2524                     ;;
2525                 xskx)
2526                     swr_require_cxx_feature_flags "SKX" "defined(__AVX512F__) && defined(__AVX512BW__)" \
2527                         ",-target-cpu=x86-skylake,-march=skylake-avx512,-xCORE-AVX512" \
2528                         SWR_SKX_CXXFLAGS
2529                     AC_SUBST([SWR_SKX_CXXFLAGS])
2530                     HAVE_SWR_SKX=yes
2531                     ;;
2532                 *)
2533                     AC_MSG_ERROR([unknown SWR build architecture '$arch'])
2534                     ;;
2535                 esac
2536             done
2537
2538             if test "x$HAVE_SWR_AVX" != xyes -a \
2539                     "x$HAVE_SWR_AVX2" != xyes -a \
2540                     "x$HAVE_SWR_KNL" != xyes -a \
2541                     "x$HAVE_SWR_SKX" != xyes; then
2542                AC_MSG_ERROR([swr enabled but no swr architectures selected])
2543             fi
2544
2545             HAVE_GALLIUM_SWR=yes
2546             ;;
2547         xvc4)
2548             HAVE_GALLIUM_VC4=yes
2549             require_libdrm "vc4"
2550
2551             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2552                               [USE_VC4_SIMULATOR=yes;
2553                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2554                               [USE_VC4_SIMULATOR=no])
2555             ;;
2556         xpl111)
2557             HAVE_GALLIUM_PL111=yes
2558             ;;
2559         xvirgl)
2560             HAVE_GALLIUM_VIRGL=yes
2561             require_libdrm "virgl"
2562             if test "x$enable_egl" = xyes; then
2563                 require_basic_egl "virgl"
2564             fi
2565             ;;
2566         *)
2567             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2568             ;;
2569         esac
2570     done
2571 fi
2572
2573 # XXX: Keep in sync with LLVM_REQUIRED_SWR
2574 AM_CONDITIONAL(SWR_INVALID_LLVM_VERSION, test "x$LLVM_VERSION" != x3.9.0 -a \
2575                                               "x$LLVM_VERSION" != x3.9.1)
2576
2577 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2578     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2579     llvm_add_default_components "gallium"
2580 fi
2581
2582 AM_CONDITIONAL(HAVE_SWR_AVX, test "x$HAVE_SWR_AVX" = xyes)
2583 AM_CONDITIONAL(HAVE_SWR_AVX2, test "x$HAVE_SWR_AVX2" = xyes)
2584 AM_CONDITIONAL(HAVE_SWR_KNL, test "x$HAVE_SWR_KNL" = xyes)
2585 AM_CONDITIONAL(HAVE_SWR_SKX, test "x$HAVE_SWR_SKX" = xyes)
2586
2587 dnl We need to validate some needed dependencies for renderonly drivers.
2588
2589 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2590     AC_MSG_ERROR([Building with imx requires etnaviv])
2591 fi
2592
2593 if test "x$HAVE_GALLIUM_VC4" != xyes -a "x$HAVE_GALLIUM_PL111" = xyes  ; then
2594     AC_MSG_ERROR([Building with pl111 requires vc4])
2595 fi
2596
2597 dnl
2598 dnl Set defines and buildtime variables only when using LLVM.
2599 dnl
2600 if test "x$enable_llvm" = xyes; then
2601     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2602
2603     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2604     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2605     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2606
2607     dnl Set LLVM_LIBS - This is done after the driver configuration so
2608     dnl that drivers can add additional components to LLVM_COMPONENTS.
2609     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2610     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2611     dnl this was causing the same libraries to be appear multiple times
2612     dnl in LLVM_LIBS.
2613
2614     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2615        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2616     fi
2617     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2618
2619     if test "x$enable_llvm_shared_libs" = xyes; then
2620         if test $LLVM_VERSION_MAJOR -lt 4 -o "`$LLVM_CONFIG --shared-mode ${LLVM_COMPONENTS}`" = static; then
2621             dnl llvm-config may not give the right answer when llvm is a built as a
2622             dnl single shared library, so we must work the library name out for
2623             dnl ourselves.
2624             dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2625             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2626             LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2627             AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2628
2629             if test "x$llvm_have_one_so" = xyes; then
2630                dnl LLVM was built using auto*, so there is only one shared object.
2631                LLVM_LIBS="-l$LLVM_SO_NAME"
2632             else
2633                 dnl If LLVM was built with CMake, there will be one shared object per
2634                 dnl component.
2635                 AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2636                       [AC_MSG_ERROR([Could not find llvm shared libraries:
2637                        Please make sure you have built llvm with the --enable-shared option
2638                        and that your llvm libraries are installed in $LLVM_LIBDIR
2639                        If you have installed your llvm libraries to a different directory you
2640                        can use the --with-llvm-prefix= configure flag to specify this directory.
2641                        NOTE: Mesa is attempting to use llvm shared libraries by default.
2642                        If you do not want to build with llvm shared libraries and instead want to
2643                        use llvm static libraries then add --disable-llvm-shared-libs to your configure
2644                        invocation and rebuild.])])
2645
2646                 dnl We don't need to update LLVM_LIBS in this case because the LLVM
2647                 dnl install uses a shared object for each component and we have
2648                 dnl already added all of these objects to LLVM_LIBS.
2649             fi
2650         fi
2651     else
2652         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2653         dnl We need to link to llvm system libs when using static libs
2654         dnl However, only llvm 3.5+ provides --system-libs
2655         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2656             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2657         fi
2658     fi
2659 fi
2660
2661 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2662 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2663 AM_CONDITIONAL(HAVE_GALLIUM_PL111, test "x$HAVE_GALLIUM_PL111" = xyes)
2664 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2665 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2666 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2667 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2668                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2669 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2670 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2671 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2672 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2673 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2674 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2675 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2676 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2677                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2678                                          "x$HAVE_GALLIUM_SWR" = xyes)
2679 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2680 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2681
2682 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2683
2684 if test "x$enable_dri" = xyes; then
2685     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2686 fi
2687
2688 if test "x$have_drisw_kms" = xyes; then
2689     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2690 fi
2691 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2692
2693 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2694 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2695 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2696 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2697 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2698 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2699
2700 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2701 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2702
2703 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2704                                       "x$HAVE_RADEON_VULKAN" = xyes)
2705
2706 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2707                                         "x$HAVE_I965_DRI" = xyes)
2708
2709 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2710                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2711                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2712 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2713 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2714 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2715 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2716
2717 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2718 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2719 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2720 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2721                                         "x$enable_gallium_osmesa" = xyes)
2722
2723 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2724 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2725 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2726 AM_CONDITIONAL(HAVE_PPC64LE_ASM, test "x$asm_arch" = xppc64le)
2727 AM_CONDITIONAL(HAVE_AARCH64_ASM, test "x$asm_arch" = xaarch64)
2728 AM_CONDITIONAL(HAVE_ARM_ASM, test "x$asm_arch" = xarm)
2729
2730 AC_SUBST([NINE_MAJOR], 1)
2731 AC_SUBST([NINE_MINOR], 0)
2732 AC_SUBST([NINE_TINY], 0)
2733 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2734
2735 AC_SUBST([VDPAU_MAJOR], 1)
2736 AC_SUBST([VDPAU_MINOR], 0)
2737
2738 if test "x$enable_va" = xyes; then
2739     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2740     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2741 fi
2742 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2743 AC_SUBST([VA_MINOR], $VA_MINOR)
2744
2745 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2746
2747 AC_SUBST([XVMC_MAJOR], 1)
2748 AC_SUBST([XVMC_MINOR], 0)
2749
2750 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2751 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2752 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2753 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2754
2755 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2756 AC_SUBST([XA_MINOR], $XA_MINOR)
2757 AC_SUBST([XA_TINY], $XA_TINY)
2758 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2759
2760 AC_ARG_ENABLE(valgrind,
2761               [AS_HELP_STRING([--enable-valgrind],
2762                              [Build mesa with valgrind support (default: auto)])],
2763                              [VALGRIND=$enableval], [VALGRIND=auto])
2764 if test "x$VALGRIND" != xno; then
2765     PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2766 fi
2767 AC_MSG_CHECKING([whether to enable Valgrind support])
2768 if test "x$VALGRIND" = xauto; then
2769     VALGRIND="$have_valgrind"
2770 fi
2771
2772 if test "x$VALGRIND" = "xyes"; then
2773     if ! test "x$have_valgrind" = xyes; then
2774         AC_MSG_ERROR([Valgrind support required but not present])
2775     fi
2776     AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2777 fi
2778
2779 AC_MSG_RESULT([$VALGRIND])
2780
2781 dnl Restore LDFLAGS and CPPFLAGS
2782 LDFLAGS="$_SAVE_LDFLAGS"
2783 CPPFLAGS="$_SAVE_CPPFLAGS"
2784
2785 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2786 if test "x$acv_mesa_CLANG" = xyes; then
2787     CFLAGS="$CFLAGS -Qunused-arguments"
2788     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2789 fi
2790
2791 dnl Add user CFLAGS and CXXFLAGS
2792 CFLAGS="$CFLAGS $USER_CFLAGS"
2793 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2794
2795 dnl Substitute the config
2796 AC_CONFIG_FILES([Makefile
2797                  src/Makefile
2798                  src/amd/Makefile
2799                  src/amd/vulkan/Makefile
2800                  src/broadcom/Makefile
2801                  src/compiler/Makefile
2802                  src/egl/Makefile
2803                  src/egl/main/egl.pc
2804                  src/egl/wayland/wayland-drm/Makefile
2805                  src/egl/wayland/wayland-egl/Makefile
2806                  src/egl/wayland/wayland-egl/wayland-egl.pc
2807                  src/gallium/Makefile
2808                  src/gallium/auxiliary/Makefile
2809                  src/gallium/auxiliary/pipe-loader/Makefile
2810                  src/gallium/drivers/freedreno/Makefile
2811                  src/gallium/drivers/ddebug/Makefile
2812                  src/gallium/drivers/i915/Makefile
2813                  src/gallium/drivers/llvmpipe/Makefile
2814                  src/gallium/drivers/noop/Makefile
2815                  src/gallium/drivers/nouveau/Makefile
2816                  src/gallium/drivers/pl111/Makefile
2817                  src/gallium/drivers/r300/Makefile
2818                  src/gallium/drivers/r600/Makefile
2819                  src/gallium/drivers/radeon/Makefile
2820                  src/gallium/drivers/radeonsi/Makefile
2821                  src/gallium/drivers/rbug/Makefile
2822                  src/gallium/drivers/softpipe/Makefile
2823                  src/gallium/drivers/svga/Makefile
2824                  src/gallium/drivers/swr/Makefile
2825                  src/gallium/drivers/trace/Makefile
2826                  src/gallium/drivers/etnaviv/Makefile
2827                  src/gallium/drivers/imx/Makefile
2828                  src/gallium/drivers/vc4/Makefile
2829                  src/gallium/drivers/virgl/Makefile
2830                  src/gallium/state_trackers/clover/Makefile
2831                  src/gallium/state_trackers/dri/Makefile
2832                  src/gallium/state_trackers/glx/xlib/Makefile
2833                  src/gallium/state_trackers/nine/Makefile
2834                  src/gallium/state_trackers/omx/Makefile
2835                  src/gallium/state_trackers/osmesa/Makefile
2836                  src/gallium/state_trackers/va/Makefile
2837                  src/gallium/state_trackers/vdpau/Makefile
2838                  src/gallium/state_trackers/xa/Makefile
2839                  src/gallium/state_trackers/xvmc/Makefile
2840                  src/gallium/targets/d3dadapter9/Makefile
2841                  src/gallium/targets/d3dadapter9/d3d.pc
2842                  src/gallium/targets/dri/Makefile
2843                  src/gallium/targets/libgl-xlib/Makefile
2844                  src/gallium/targets/omx/Makefile
2845                  src/gallium/targets/opencl/Makefile
2846                  src/gallium/targets/opencl/mesa.icd
2847                  src/gallium/targets/osmesa/Makefile
2848                  src/gallium/targets/osmesa/osmesa.pc
2849                  src/gallium/targets/pipe-loader/Makefile
2850                  src/gallium/targets/va/Makefile
2851                  src/gallium/targets/vdpau/Makefile
2852                  src/gallium/targets/xa/Makefile
2853                  src/gallium/targets/xa/xatracker.pc
2854                  src/gallium/targets/xvmc/Makefile
2855                  src/gallium/tests/trivial/Makefile
2856                  src/gallium/tests/unit/Makefile
2857                  src/gallium/winsys/etnaviv/drm/Makefile
2858                  src/gallium/winsys/imx/drm/Makefile
2859                  src/gallium/winsys/freedreno/drm/Makefile
2860                  src/gallium/winsys/i915/drm/Makefile
2861                  src/gallium/winsys/nouveau/drm/Makefile
2862                  src/gallium/winsys/pl111/drm/Makefile
2863                  src/gallium/winsys/radeon/drm/Makefile
2864                  src/gallium/winsys/amdgpu/drm/Makefile
2865                  src/gallium/winsys/svga/drm/Makefile
2866                  src/gallium/winsys/sw/dri/Makefile
2867                  src/gallium/winsys/sw/kms-dri/Makefile
2868                  src/gallium/winsys/sw/null/Makefile
2869                  src/gallium/winsys/sw/wrapper/Makefile
2870                  src/gallium/winsys/sw/xlib/Makefile
2871                  src/gallium/winsys/vc4/drm/Makefile
2872                  src/gallium/winsys/virgl/drm/Makefile
2873                  src/gallium/winsys/virgl/vtest/Makefile
2874                  src/gbm/Makefile
2875                  src/gbm/main/gbm.pc
2876                  src/glx/Makefile
2877                  src/glx/apple/Makefile
2878                  src/glx/tests/Makefile
2879                  src/glx/windows/Makefile
2880                  src/glx/windows/windowsdriproto.pc
2881                  src/gtest/Makefile
2882                  src/intel/Makefile
2883                  src/loader/Makefile
2884                  src/mapi/Makefile
2885                  src/mapi/es1api/glesv1_cm.pc
2886                  src/mapi/es2api/glesv2.pc
2887                  src/mapi/glapi/gen/Makefile
2888                  src/mesa/Makefile
2889                  src/mesa/gl.pc
2890                  src/mesa/drivers/dri/dri.pc
2891                  src/mesa/drivers/dri/common/Makefile
2892                  src/mesa/drivers/dri/i915/Makefile
2893                  src/mesa/drivers/dri/i965/Makefile
2894                  src/mesa/drivers/dri/Makefile
2895                  src/mesa/drivers/dri/nouveau/Makefile
2896                  src/mesa/drivers/dri/r200/Makefile
2897                  src/mesa/drivers/dri/radeon/Makefile
2898                  src/mesa/drivers/dri/swrast/Makefile
2899                  src/mesa/drivers/osmesa/Makefile
2900                  src/mesa/drivers/osmesa/osmesa.pc
2901                  src/mesa/drivers/x11/Makefile
2902                  src/mesa/main/tests/Makefile
2903                  src/util/Makefile
2904                  src/util/tests/hash_table/Makefile
2905                  src/util/xmlpool/Makefile
2906                  src/vulkan/Makefile])
2907
2908 AC_OUTPUT
2909
2910 # Fix up dependencies in *.Plo files, where we changed the extension of a
2911 # source file
2912 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2913
2914 rm -f src/compiler/spirv/spirv_info.lo
2915 echo "# dummy" > src/compiler/spirv/.deps/spirv_info.Plo
2916
2917 dnl
2918 dnl Output some configuration info for the user
2919 dnl
2920 echo ""
2921 echo "        prefix:          $prefix"
2922 echo "        exec_prefix:     $exec_prefix"
2923 echo "        libdir:          $libdir"
2924 echo "        includedir:      $includedir"
2925
2926 dnl API info
2927 echo ""
2928 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2929
2930 dnl Driver info
2931 echo ""
2932 case "x$enable_osmesa$enable_gallium_osmesa" in
2933 xnoyes)
2934         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2935         ;;
2936 xyesno)
2937         echo "        OSMesa:          lib$OSMESA_LIB"
2938         ;;
2939 xnono)
2940         echo "        OSMesa:          no"
2941         ;;
2942 esac
2943
2944 echo ""
2945 if test "x$enable_dri" != xno; then
2946         echo "        DRI platform:    $dri_platform"
2947         if test -z "$DRI_DIRS"; then
2948             echo "        DRI drivers:     no"
2949         else
2950             echo "        DRI drivers:     $DRI_DIRS"
2951         fi
2952         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2953 fi
2954
2955 case "x$enable_glx" in
2956 xdri)
2957     echo "        GLX:             DRI-based"
2958     ;;
2959 xxlib)
2960     echo "        GLX:             Xlib-based"
2961     ;;
2962 xgallium-xlib)
2963     echo "        GLX:             Xlib-based (Gallium)"
2964     ;;
2965 *)
2966     echo "        GLX:             $enable_glx"
2967     ;;
2968 esac
2969
2970 dnl EGL
2971 echo ""
2972 echo "        EGL:             $enable_egl"
2973 if test "$enable_egl" = yes; then
2974
2975     egl_drivers=""
2976     if test "x$enable_dri" != "xno"; then
2977         egl_drivers="$egl_drivers builtin:egl_dri2"
2978     fi
2979     if test "x$enable_dri3" != "xno"; then
2980         egl_drivers="$egl_drivers builtin:egl_dri3"
2981     fi
2982
2983     echo "        EGL drivers:    $egl_drivers"
2984 fi
2985 if test "x$enable_gbm" = xyes; then
2986     echo "        GBM:             yes"
2987 else
2988     echo "        GBM:             no"
2989 fi
2990
2991     echo "        EGL/Vulkan/VL platforms:   $platforms"
2992
2993 # Vulkan
2994 echo ""
2995 if test "x$VULKAN_DRIVERS" != x; then
2996     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2997     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2998 else
2999     echo "        Vulkan drivers:  no"
3000 fi
3001
3002 echo ""
3003 if test "x$enable_llvm" = xyes; then
3004     echo "        llvm:            yes"
3005     echo "        llvm-config:     $LLVM_CONFIG"
3006     echo "        llvm-version:    $LLVM_VERSION"
3007 else
3008     echo "        llvm:            no"
3009 fi
3010
3011 echo ""
3012 if test -n "$with_gallium_drivers"; then
3013     echo "        Gallium drivers: $gallium_drivers"
3014     echo "        Gallium st:      $gallium_st"
3015 else
3016     echo "        Gallium:         no"
3017 fi
3018
3019 echo ""
3020 if test "x$enable_gallium_extra_hud" != xyes; then
3021     echo "        HUD extra stats: no"
3022 else
3023     echo "        HUD extra stats: yes"
3024 fi
3025
3026 if test "x$enable_lmsensors" != xyes; then
3027     echo "        HUD lmsensors:   no"
3028 else
3029     echo "        HUD lmsensors:   yes"
3030 fi
3031
3032 echo ""
3033 if test "x$HAVE_GALLIUM_SWR" != x; then
3034     echo "        SWR archs:       $swr_archs"
3035 fi
3036
3037 dnl Libraries
3038 echo ""
3039 echo "        Shared libs:     $enable_shared"
3040 echo "        Static libs:     $enable_static"
3041 echo "        Shared-glapi:    $enable_shared_glapi"
3042
3043 dnl Compiler options
3044 # cleanup the CFLAGS/CXXFLAGS/LDFLAGS/DEFINES vars
3045 cflags=`echo $CFLAGS | \
3046     $SED 's/^ *//;s/  */ /;s/ *$//'`
3047 cxxflags=`echo $CXXFLAGS | \
3048     $SED 's/^ *//;s/  */ /;s/ *$//'`
3049 ldflags=`echo $LDFLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
3050 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3051 echo ""
3052 echo "        CFLAGS:          $cflags"
3053 echo "        CXXFLAGS:        $cxxflags"
3054 echo "        LDFLAGS:         $ldflags"
3055 echo "        Macros:          $defines"
3056 echo ""
3057 if test "x$enable_llvm" = xyes; then
3058     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3059     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3060     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3061     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3062     echo ""
3063 fi
3064 echo "        PYTHON2:         $PYTHON2"
3065
3066 echo ""
3067 echo "        Run '${MAKE-make}' to build Mesa"
3068 echo ""