configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCBDRI2_REQUIRED=1.8
  45 XCBGLX_REQUIRED=1.8.1
  46 XSHMFENCE_REQUIRED=1.1
  47 XVMC_REQUIRED=1.0.6
  48
  49 dnl Check for progs
  50 AC_PROG_CPP
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 AM_PROG_CC_C_O
  54 AM_PROG_AS
  55 AC_CHECK_PROGS([MAKE], [gmake make])
  56 AC_CHECK_PROGS([PYTHON2], [python2 python])
  57 AC_PROG_SED
  58 AC_PROG_MKDIR_P
  59
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63 AX_PROG_BISON([],
  64               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  65                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  66 AX_PROG_FLEX([],
  67              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  68                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  69
  70 AC_PATH_PROG([PERL], [perl])
  71
  72 AC_CHECK_PROG(INDENT, indent, indent, cat)
  73 if test "x$INDENT" != "xcat"; then
  74     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  75 fi
  76
  77 AC_PROG_INSTALL
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 GEN_ASM_OFFSETS=no
 106 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 107     AC_MSG_CHECKING([whether gcc version is sufficient])
 108     major=0
 109     minor=0
 110
 111     GCC_VERSION=`$CC -dumpversion`
 112     if test $? -eq 0; then
 113         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 114         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 115     fi
 116
 117     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 118         AC_MSG_RESULT([no])
 119         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 120     else
 121         AC_MSG_RESULT([yes])
 122     fi
 123
 124     if test "x$cross_compiling" = xyes; then
 125         GEN_ASM_OFFSETS=yes
 126     fi
 127 fi
 128
 129 dnl Check for compiler builtins
 130 AX_GCC_BUILTIN([__builtin_bswap32])
 131 AX_GCC_BUILTIN([__builtin_bswap64])
 132
 133 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 134
 135 dnl Make sure the pkg-config macros are defined
 136 m4_ifndef([PKG_PROG_PKG_CONFIG],
 137     [m4_fatal([Could not locate the pkg-config autoconf macros.
 138   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 139   are in a different location, try setting the environment variable
 140   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 141 PKG_PROG_PKG_CONFIG()
 142
 143 dnl LIB_DIR - library basename
 144 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 145 AC_SUBST([LIB_DIR])
 146
 147 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 148 _SAVE_LDFLAGS="$LDFLAGS"
 149 _SAVE_CPPFLAGS="$CPPFLAGS"
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS="$CFLAGS -Wall -std=c99"
 174         ;;
 175     esac
 176
 177     # Enable -Werror=implicit-function-declaration and
 178     # -Werror=missing-prototypes, if available, or otherwise, just
 179     # -Wmissing-prototypes.  This is particularly useful to avoid
 180     # generating a loadable driver module that has undefined symbols.
 181     save_CFLAGS="$CFLAGS"
 182     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 183     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 184     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 185     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 186                    AC_MSG_RESULT([yes]),
 187                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 188                     AC_MSG_RESULT([no])]);
 189
 190     # Enable -fvisibility=hidden if using a gcc that supports it
 191     save_CFLAGS="$CFLAGS"
 192     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 193     VISIBILITY_CFLAGS="-fvisibility=hidden"
 194     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 195     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 196                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 197
 198     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 199     CFLAGS=$save_CFLAGS
 200
 201     # Work around aliasing bugs - developers should comment this out
 202     CFLAGS="$CFLAGS -fno-strict-aliasing"
 203
 204     # gcc's builtin memcmp is slower than glibc's
 205     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 206     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 207 fi
 208 if test "x$GXX" = xyes; then
 209     CXXFLAGS="$CXXFLAGS -Wall"
 210
 211     # Enable -fvisibility=hidden if using a gcc that supports it
 212     save_CXXFLAGS="$CXXFLAGS"
 213     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 214     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 215     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 216     AC_LANG_PUSH([C++])
 217     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 218                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 219     AC_LANG_POP([C++])
 220
 221     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 222     CXXFLAGS=$save_CXXFLAGS
 223
 224     # Work around aliasing bugs - developers should comment this out
 225     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 226
 227     # gcc's builtin memcmp is slower than glibc's
 228     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 229     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 230 fi
 231
 232 dnl even if the compiler appears to support it, using visibility attributes isn't
 233 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 234 case "$host_os" in
 235 cygwin*)
 236     VISIBILITY_CFLAGS=""
 237     VISIBILITY_CXXFLAGS=""
 238     ;;
 239 esac
 240
 241 AC_SUBST([VISIBILITY_CFLAGS])
 242 AC_SUBST([VISIBILITY_CXXFLAGS])
 243
 244 dnl
 245 dnl Optional flags, check for compiler support
 246 dnl
 247 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 248 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes)
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono)
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 293     enable_shared=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES="$DEFINES -DDEBUG"
 310     if test "x$GCC" = xyes; then
 311         CFLAGS="$CFLAGS -g -O0"
 312     fi
 313     if test "x$GXX" = xyes; then
 314         CXXFLAGS="$CXXFLAGS -g -O0"
 315     fi
 316 fi
 317
 318 dnl
 319 dnl Check if linker supports garbage collection
 320 dnl
 321 save_LDFLAGS=$LDFLAGS
 322 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 323 AC_MSG_CHECKING([whether ld supports --gc-sections])
 324 AC_LINK_IFELSE(
 325     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 326     [AC_MSG_RESULT([yes])
 327         GC_SECTIONS="-Wl,--gc-sections";],
 328     [AC_MSG_RESULT([no])
 329         GC_SECTIONS="";])
 330 LDFLAGS=$save_LDFLAGS
 331
 332 AC_SUBST([GC_SECTIONS])
 333
 334 dnl
 335 dnl compatibility symlinks
 336 dnl
 337 case "$host_os" in
 338 linux* )
 339     HAVE_COMPAT_SYMLINKS=yes ;;
 340 * )
 341     HAVE_COMPAT_SYMLINKS=no ;;
 342 esac
 343
 344 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 345
 346 dnl
 347 dnl library names
 348 dnl
 349 case "$host_os" in
 350 darwin* )
 351     LIB_EXT='dylib' ;;
 352 cygwin* )
 353     LIB_EXT='dll' ;;
 354 aix* )
 355     LIB_EXT='a' ;;
 356 * )
 357     LIB_EXT='so' ;;
 358 esac
 359
 360 AC_SUBST([LIB_EXT])
 361
 362 AC_ARG_WITH([gl-lib-name],
 363   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 364     [specify GL library name @<:@default=GL@:>@])],
 365   [GL_LIB=$withval],
 366   [GL_LIB=GL])
 367 AC_ARG_WITH([osmesa-lib-name],
 368   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 369     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 370   [OSMESA_LIB=$withval],
 371   [OSMESA_LIB=OSMesa])
 372 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 373 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 374
 375 dnl
 376 dnl Mangled Mesa support
 377 dnl
 378 AC_ARG_ENABLE([mangling],
 379   [AS_HELP_STRING([--enable-mangling],
 380     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 381   [enable_mangling="${enableval}"],
 382   [enable_mangling=no]
 383 )
 384 if test "x${enable_mangling}" = "xyes" ; then
 385   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 386   GL_LIB="Mangled${GL_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([OSMESA_LIB])
 391
 392 dnl
 393 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 394 dnl
 395 AC_ARG_ENABLE([texture-float],
 396     [AS_HELP_STRING([--enable-texture-float],
 397         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 398     [enable_texture_float="$enableval"],
 399     [enable_texture_float=no]
 400 )
 401 if test "x$enable_texture_float" = xyes; then
 402     AC_MSG_WARN([Floating-point textures enabled.])
 403     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 404     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 405 fi
 406
 407 dnl
 408 dnl Arch/platform-specific settings
 409 dnl
 410 AC_ARG_ENABLE([asm],
 411     [AS_HELP_STRING([--disable-asm],
 412         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 413     [enable_asm="$enableval"],
 414     [enable_asm=yes]
 415 )
 416 asm_arch=""
 417 AC_MSG_CHECKING([whether to enable assembly])
 418 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 419 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 420 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 421     case "$host_cpu" in
 422     i?86 | x86_64 | amd64)
 423         enable_asm=no
 424         AC_MSG_RESULT([no, cross compiling])
 425         ;;
 426     esac
 427 fi
 428 # check for supported arches
 429 if test "x$enable_asm" = xyes; then
 430     case "$host_cpu" in
 431     i?86)
 432         case "$host_os" in
 433         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 434             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 435             ;;
 436         gnu*)
 437             asm_arch=x86
 438             ;;
 439         esac
 440         ;;
 441     x86_64|amd64)
 442         case "$host_os" in
 443         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 444             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 445             ;;
 446         esac
 447         ;;
 448     sparc*)
 449         case "$host_os" in
 450         linux*)
 451             asm_arch=sparc
 452             ;;
 453         esac
 454         ;;
 455     esac
 456
 457     case "$asm_arch" in
 458     x86)
 459         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 460         AC_MSG_RESULT([yes, x86])
 461         ;;
 462     x86_64|amd64)
 463         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 464         AC_MSG_RESULT([yes, x86_64])
 465         ;;
 466     sparc)
 467         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 468         AC_MSG_RESULT([yes, sparc])
 469         ;;
 470     *)
 471         AC_MSG_RESULT([no, platform not supported])
 472         ;;
 473     esac
 474 fi
 475
 476 dnl Check to see if dlopen is in default libraries (like Solaris, which
 477 dnl has it in libc), or if libdl is needed to get it.
 478 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 479     [AC_CHECK_LIB([dl], [dlopen],
 480        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 481 AC_SUBST([DLOPEN_LIBS])
 482
 483 case "$host_os" in
 484 darwin*|mingw*)
 485     ;;
 486 *)
 487     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 488                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 489                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 490     AC_SUBST([CLOCK_LIB])
 491     ;;
 492 esac
 493
 494 dnl See if posix_memalign is available
 495 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 496
 497 dnl Check for pthreads
 498 AX_PTHREAD
 499 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 500 dnl to -pthread, which causes problems if we need -lpthread to appear in
 501 dnl pkgconfig files.
 502 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 503
 504 dnl SELinux awareness.
 505 AC_ARG_ENABLE([selinux],
 506     [AS_HELP_STRING([--enable-selinux],
 507         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 508     [MESA_SELINUX="$enableval"],
 509     [MESA_SELINUX=no])
 510 if test "x$enable_selinux" = "xyes"; then
 511     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 512         [AC_CHECK_HEADER([selinux/selinux.h],[],
 513                          [AC_MSG_ERROR([SELinux headers not found])])
 514          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 515                       [AC_MSG_ERROR([SELinux library not found])])
 516          SELINUX_LIBS="-lselinux"])
 517     DEFINES="$DEFINES -DMESA_SELINUX"
 518 fi
 519 AC_SUBST([SELINUX_CFLAGS])
 520 AC_SUBST([SELINUX_LIBS])
 521
 522 dnl Options for APIs
 523 AC_ARG_ENABLE([opengl],
 524     [AS_HELP_STRING([--disable-opengl],
 525         [disable support for standard OpenGL API @<:@default=no@:>@])],
 526     [enable_opengl="$enableval"],
 527     [enable_opengl=yes])
 528 AC_ARG_ENABLE([gles1],
 529     [AS_HELP_STRING([--enable-gles1],
 530         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 531     [enable_gles1="$enableval"],
 532     [enable_gles1=no])
 533 AC_ARG_ENABLE([gles2],
 534     [AS_HELP_STRING([--enable-gles2],
 535         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 536     [enable_gles2="$enableval"],
 537     [enable_gles2=no])
 538 AC_ARG_ENABLE([openvg],
 539     [AS_HELP_STRING([--enable-openvg],
 540         [enable support for OpenVG API @<:@default=no@:>@])],
 541     [enable_openvg="$enableval"],
 542     [enable_openvg=no])
 543
 544 AC_ARG_ENABLE([dri],
 545     [AS_HELP_STRING([--enable-dri],
 546         [enable DRI modules @<:@default=enabled@:>@])],
 547     [enable_dri="$enableval"],
 548     [enable_dri=yes])
 549
 550 case "$host_os" in
 551 linux*)
 552     dri3_default=yes
 553     ;;
 554 *)
 555     dri3_default=no
 556     ;;
 557 esac
 558 AC_ARG_ENABLE([dri3],
 559     [AS_HELP_STRING([--enable-dri3],
 560         [enable DRI3 @<:@default=auto@:>@])],
 561     [enable_dri3="$enableval"],
 562     [enable_dri3="$dri3_default"])
 563 AC_ARG_ENABLE([glx],
 564     [AS_HELP_STRING([--enable-glx],
 565         [enable GLX library @<:@default=enabled@:>@])],
 566     [enable_glx="$enableval"],
 567     [enable_glx=yes])
 568 AC_ARG_ENABLE([osmesa],
 569     [AS_HELP_STRING([--enable-osmesa],
 570         [enable OSMesa library @<:@default=disabled@:>@])],
 571     [enable_osmesa="$enableval"],
 572     [enable_osmesa=no])
 573 AC_ARG_ENABLE([gallium-osmesa],
 574     [AS_HELP_STRING([--enable-gallium-osmesa],
 575         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 576     [enable_gallium_osmesa="$enableval"],
 577     [enable_gallium_osmesa=no])
 578 AC_ARG_ENABLE([egl],
 579     [AS_HELP_STRING([--disable-egl],
 580         [disable EGL library @<:@default=enabled@:>@])],
 581     [enable_egl="$enableval"],
 582     [enable_egl=yes])
 583
 584 AC_ARG_ENABLE([xa],
 585     [AS_HELP_STRING([--enable-xa],
 586         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 587     [enable_xa="$enableval"],
 588     [enable_xa=no])
 589 AC_ARG_ENABLE([gbm],
 590    [AS_HELP_STRING([--enable-gbm],
 591          [enable gbm library @<:@default=auto@:>@])],
 592    [enable_gbm="$enableval"],
 593    [enable_gbm=auto])
 594
 595 AC_ARG_ENABLE([xvmc],
 596    [AS_HELP_STRING([--enable-xvmc],
 597          [enable xvmc library @<:@default=auto@:>@])],
 598    [enable_xvmc="$enableval"],
 599    [enable_xvmc=no])
 600 AC_ARG_ENABLE([vdpau],
 601    [AS_HELP_STRING([--enable-vdpau],
 602          [enable vdpau library @<:@default=auto@:>@])],
 603    [enable_vdpau="$enableval"],
 604    [enable_vdpau=auto])
 605 AC_ARG_ENABLE([omx],
 606    [AS_HELP_STRING([--enable-omx],
 607          [enable OpenMAX library @<:@default=no@:>@])],
 608    [enable_omx="$enableval"],
 609    [enable_omx=no])
 610 AC_ARG_ENABLE([opencl],
 611    [AS_HELP_STRING([--enable-opencl],
 612          [enable OpenCL library @<:@default=no@:>@])],
 613    [enable_opencl="$enableval"],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([opencl_icd],
 616    [AS_HELP_STRING([--enable-opencl-icd],
 617           [Build an OpenCL ICD library to be loaded by an ICD implementation
 618            @<:@default=no@:>@])],
 619     [enable_opencl_icd="$enableval"],
 620     [enable_opencl_icd=no])
 621 AC_ARG_ENABLE([xlib-glx],
 622     [AS_HELP_STRING([--enable-xlib-glx],
 623         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 624     [enable_xlib_glx="$enableval"],
 625     [enable_xlib_glx=no])
 626 AC_ARG_ENABLE([gallium-egl],
 627     [AS_HELP_STRING([--enable-gallium-egl],
 628         [enable optional EGL state tracker (not required
 629          for EGL support in Gallium with OpenGL and OpenGL ES)
 630          @<:@default=disable@:>@])],
 631     [enable_gallium_egl="$enableval"],
 632     [enable_gallium_egl=no])
 633 AC_ARG_ENABLE([gallium-gbm],
 634     [AS_HELP_STRING([--enable-gallium-gbm],
 635         [enable optional gbm state tracker (not required for
 636          gbm support in Gallium)
 637          @<:@default=auto@:>@])],
 638     [enable_gallium_gbm="$enableval"],
 639     [enable_gallium_gbm=auto])
 640
 641 AC_ARG_ENABLE([r600-llvm-compiler],
 642     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 643         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 644     [enable_r600_llvm="$enableval"],
 645     [enable_r600_llvm=no])
 646
 647 AC_ARG_ENABLE([gallium-tests],
 648     [AS_HELP_STRING([--enable-gallium-tests],
 649         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 650     [enable_gallium_tests="$enableval"],
 651     [enable_gallium_tests=no])
 652
 653 # Option for Gallium drivers
 654
 655 # Keep this in sync with the --with-gallium-drivers help string default value
 656 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 657
 658 AC_ARG_WITH([gallium-drivers],
 659     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 660         [comma delimited Gallium drivers list, e.g.
 661         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 662         @<:@default=r300,r600,svga,swrast@:>@])],
 663     [with_gallium_drivers="$withval"],
 664     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 665
 666 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 667 # here so that the script doesn't choke on an unknown driver name later.
 668 case "$with_gallium_drivers" in
 669     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 670     no) with_gallium_drivers='' ;;
 671 esac
 672
 673 if test "x$enable_opengl" = xno -a \
 674         "x$enable_gles1" = xno -a \
 675         "x$enable_gles2" = xno -a \
 676         "x$enable_openvg" = xno -a \
 677         "x$enable_xa" = xno -a \
 678         "x$enable_xvmc" = xno -a \
 679         "x$enable_vdpau" = xno -a \
 680         "x$enable_omx" = xno -a \
 681         "x$enable_opencl" = xno; then
 682     AC_MSG_ERROR([at least one API should be enabled])
 683 fi
 684
 685 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 686 if test "x$enable_opengl" = xno -a \
 687         "x$enable_gles1" = xyes; then
 688     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 689 fi
 690
 691 if test "x$enable_opengl" = xno -a \
 692         "x$enable_gles2" = xyes; then
 693     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 694 fi
 695
 696 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 697 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 698 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 699 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 700                                         "x$enable_gles1" = xyes -o \
 701                                         "x$enable_gles2" = xyes)
 702
 703 if test "x$enable_glx" = xno; then
 704     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 705     enable_xlib_glx=no
 706 fi
 707
 708 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 709     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 710 fi
 711
 712 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 713     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 714 fi
 715
 716 # Disable GLX if OpenGL is not enabled
 717 if test "x$enable_glx$enable_opengl" = xyesno; then
 718     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 719     enable_glx=no
 720 fi
 721
 722 # Disable GLX if DRI and Xlib-GLX are not enabled
 723 if test "x$enable_glx" = xyes -a \
 724         "x$enable_dri" = xno -a \
 725         "x$enable_xlib_glx" = xno; then
 726     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 727     enable_glx=no
 728 fi
 729
 730 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 731                                   "x$enable_dri" = xyes)
 732 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 733 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 734
 735 AC_ARG_ENABLE([shared-glapi],
 736     [AS_HELP_STRING([--enable-shared-glapi],
 737         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 738     [enable_shared_glapi="$enableval"],
 739     [enable_shared_glapi=yes])
 740
 741 case "x$enable_opengl$enable_gles1$enable_gles2" in
 742 x*yes*yes*)
 743     if test "x$enable_shared_glapi" = xno; then
 744         AC_MSG_ERROR([shared GLAPI required when building two or more of
 745                       the following APIs - opengl, gles1 gles2])
 746     fi
 747     ;;
 748 esac
 749
 750 # Building Xlib-GLX requires shared glapi to be disabled.
 751 if test "x$enable_xlib_glx" = xyes; then
 752     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 753     enable_shared_glapi=no
 754 fi
 755
 756 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 757
 758 dnl
 759 dnl Driver specific build directories
 760 dnl
 761 GALLIUM_TARGET_DIRS=""
 762 GALLIUM_WINSYS_DIRS="sw"
 763 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 764 GALLIUM_STATE_TRACKERS_DIRS=""
 765
 766 case "x$enable_glx$enable_xlib_glx" in
 767 xyesyes)
 768     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 769     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 770     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 771     NEED_WINSYS_XLIB="yes"
 772     ;;
 773 esac
 774
 775 if test "x$enable_dri" = xyes; then
 776     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 777     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 778 fi
 779
 780 if test "x$enable_gallium_osmesa" = xyes; then
 781     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 782         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 783     fi
 784     if test "x$enable_osmesa" = xyes; then
 785         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 786     fi
 787     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 788     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 789 fi
 790
 791 AC_SUBST([MESA_LLVM])
 792
 793 # Check for libdrm
 794 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 795                   [have_libdrm=yes], [have_libdrm=no])
 796 if test "x$have_libdrm" = xyes; then
 797         DEFINES="$DEFINES -DHAVE_LIBDRM"
 798 fi
 799
 800 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 801                   have_libudev=yes, have_libudev=no)
 802
 803 if test "x$enable_dri" = xyes; then
 804     if test "$enable_static" = yes; then
 805         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 806     fi
 807
 808     # not a hard requirement as swrast does not depend on it
 809     if test "x$have_libdrm" = xyes; then
 810         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 811     fi
 812 fi
 813
 814 dnl Direct rendering or just indirect rendering
 815 case "$host_os" in
 816 gnu*)
 817     dnl Disable by default on GNU/Hurd
 818     driglx_direct_default="no"
 819     ;;
 820 cygwin*)
 821     dnl Disable by default on cygwin
 822     driglx_direct_default="no"
 823     ;;
 824 *)
 825     driglx_direct_default="yes"
 826     ;;
 827 esac
 828 AC_ARG_ENABLE([driglx-direct],
 829     [AS_HELP_STRING([--disable-driglx-direct],
 830         [disable direct rendering in GLX and EGL for DRI \
 831             @<:@default=auto@:>@])],
 832     [driglx_direct="$enableval"],
 833     [driglx_direct="$driglx_direct_default"])
 834
 835 dnl
 836 dnl libGL configuration per driver
 837 dnl
 838 case "x$enable_glx$enable_xlib_glx" in
 839 xyesyes)
 840     # Xlib-based GLX
 841     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 842     GL_PC_REQ_PRIV="x11 xext"
 843     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 844     GL_LIB_DEPS="$XLIBGL_LIBS"
 845     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 846     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 847     ;;
 848 xyesno)
 849     # DRI-based GLX
 850     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 851     if test x"$driglx_direct" = xyes; then
 852         if test "x$have_libdrm" != xyes; then
 853             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 854         fi
 855         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 856         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 857         if test x"$enable_dri3" = xyes; then
 858             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 859             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 860         fi
 861     fi
 862
 863     # find the DRI deps for libGL
 864     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= $XCBGLX_REQUIRED xcb-dri2 >= $XCBDRI2_REQUIRED"
 865
 866     if test x"$enable_dri3" = xyes; then
 867         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 868     fi
 869
 870     # add xf86vidmode if available
 871     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 872     if test "$HAVE_XF86VIDMODE" = yes ; then
 873         dri_modules="$dri_modules xxf86vm"
 874     fi
 875
 876     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 877     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 878     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 879     GL_LIB_DEPS="$DRIGL_LIBS"
 880
 881     # need DRM libs, $PTHREAD_LIBS, etc.
 882     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 883     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 884     ;;
 885 esac
 886
 887 if test "$have_libudev" = yes; then
 888     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 889 fi
 890
 891 # This is outside the case (above) so that it is invoked even for non-GLX
 892 # builds.
 893 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 894
 895 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 896 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 897 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 898 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 899
 900 AC_SUBST([X11_INCLUDES])
 901 AC_SUBST([GL_LIB_DEPS])
 902 AC_SUBST([GL_PC_REQ_PRIV])
 903 AC_SUBST([GL_PC_LIB_PRIV])
 904 AC_SUBST([GL_PC_CFLAGS])
 905 AC_SUBST([DRI_PC_REQ_PRIV])
 906 AC_SUBST([GLESv1_CM_LIB_DEPS])
 907 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 908 AC_SUBST([GLESv2_LIB_DEPS])
 909 AC_SUBST([GLESv2_PC_LIB_PRIV])
 910
 911 AC_SUBST([HAVE_XF86VIDMODE])
 912
 913 dnl
 914 dnl More GLX setup
 915 dnl
 916 case "x$enable_glx$enable_xlib_glx" in
 917 xyesyes)
 918     DEFINES="$DEFINES -DUSE_XSHM"
 919     ;;
 920 xyesno)
 921     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 922     if test "x$driglx_direct" = xyes; then
 923         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 924     fi
 925     ;;
 926 esac
 927
 928 dnl
 929 dnl TLS detection
 930 dnl
 931
 932 AC_ARG_ENABLE([glx-tls],
 933     [AS_HELP_STRING([--enable-glx-tls],
 934         [enable TLS support in GLX @<:@default=disabled@:>@])],
 935     [GLX_USE_TLS="$enableval"],
 936     [GLX_USE_TLS=no])
 937 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 938
 939 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 940       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 941
 942 dnl
 943 dnl More DRI setup
 944 dnl
 945 dnl Directory for DRI drivers
 946 AC_ARG_WITH([dri-driverdir],
 947     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 948         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 949     [DRI_DRIVER_INSTALL_DIR="$withval"],
 950     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 951 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 952 dnl Extra search path for DRI drivers
 953 AC_ARG_WITH([dri-searchpath],
 954     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 955         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 956     [DRI_DRIVER_SEARCH_DIR="$withval"],
 957     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 958 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 959 dnl Which drivers to build - default is chosen by platform
 960 AC_ARG_WITH([dri-drivers],
 961     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 962         [comma delimited classic DRI drivers list, e.g.
 963         "swrast,i965,radeon" @<:@default=auto@:>@])],
 964     [with_dri_drivers="$withval"],
 965     [with_dri_drivers=auto])
 966
 967 if test "x$with_dri_drivers" = xauto; then
 968     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
 969         with_dri_drivers="yes"
 970     else
 971         with_dri_drivers="no"
 972     fi
 973 fi
 974 if test "x$with_dri_drivers" = xno; then
 975     with_dri_drivers=''
 976 fi
 977
 978 dnl If $with_dri_drivers is yes, drivers will be added through
 979 dnl platform checks. Set DEFINES and LIB_DEPS
 980 if test "x$enable_dri" = xyes; then
 981     # Platform specific settings and drivers to build
 982     case "$host_os" in
 983     linux*)
 984         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 985         DEFINES="$DEFINES -DHAVE_ALIAS"
 986         if test "x$enable_dri3" = xyes; then
 987             DEFINES="$DEFINES -DHAVE_DRI3"
 988         fi
 989
 990         if test "x$have_libudev" != xyes; then
 991             AC_MSG_ERROR([libudev-dev required for building DRI])
 992         fi
 993
 994         case "$host_cpu" in
 995         powerpc* | sparc*)
 996             # Build only the drivers for cards that exist on PowerPC/sparc
 997             if test "x$with_dri_drivers" = "xyes"; then
 998                 with_dri_drivers="r200 radeon swrast"
 999             fi
1000             ;;
1001         esac
1002         ;;
1003     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1004         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1005         DEFINES="$DEFINES -DHAVE_ALIAS"
1006         ;;
1007     gnu*)
1008         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1009         DEFINES="$DEFINES -DHAVE_ALIAS"
1010         ;;
1011     solaris*)
1012         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1013         ;;
1014     cygwin*)
1015         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1016         if test "x$with_dri_drivers" = "xyes"; then
1017             with_dri_drivers="swrast"
1018         fi
1019         ;;
1020     esac
1021
1022     # default drivers
1023     if test "x$with_dri_drivers" = "xyes"; then
1024         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1025     fi
1026
1027     # Check for expat
1028     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1029     if test "x$have_expat" = "xyes"; then
1030        PKG_CHECK_MODULES([EXPAT], [expat], [],
1031                          AC_MSG_ERROR([Expat required for DRI.]))
1032     else
1033        # expat version 2.0 and earlier do not provide expat.pc
1034        EXPAT_LIBS=-lexpat
1035     fi
1036
1037     # If we are building any DRI driver other than swrast.
1038     if test -n "$with_dri_drivers"; then
1039         if test "x$with_dri_drivers" != xswrast; then
1040             # ... libdrm is required
1041             if test "x$have_libdrm" != xyes; then
1042                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1043             fi
1044             DRICOMMON_NEED_LIBDRM=yes
1045         else
1046             DRICOMMON_NEED_LIBDRM=no
1047         fi
1048     fi
1049
1050     # put all the necessary libs together
1051     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1052     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1053
1054 fi
1055
1056 AC_SUBST([DRI_LIB_DEPS])
1057 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1058
1059 DRI_DIRS=''
1060 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1061 if test -n "$with_dri_drivers"; then
1062     if test "x$enable_opengl" != xyes; then
1063         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1064     fi
1065
1066     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1067     for driver in $dri_drivers; do
1068         DRI_DIRS="$DRI_DIRS $driver"
1069         case "x$driver" in
1070         xi915)
1071             HAVE_I915_DRI=yes;
1072             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1073             ;;
1074         xi965)
1075             HAVE_I965_DRI=yes;
1076             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1077             ;;
1078         xnouveau)
1079             HAVE_NOUVEAU_DRI=yes;
1080             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1081             ;;
1082         xradeon)
1083             HAVE_RADEON_DRI=yes;
1084             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1085             ;;
1086         xr200)
1087             HAVE_R200_DRI=yes;
1088             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1089             ;;
1090         xswrast)
1091             HAVE_SWRAST_DRI=yes;
1092             ;;
1093         *)
1094             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1095             ;;
1096         esac
1097     done
1098     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1099 fi
1100
1101 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1102 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1103                                   "x$enable_osmesa" = xyes -o \
1104                                   -n "$DRI_DIRS")
1105
1106 dnl
1107 dnl OSMesa configuration
1108 dnl
1109
1110 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1111 AC_ARG_WITH([osmesa-bits],
1112     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1113         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1114     [osmesa_bits="$withval"],
1115     [osmesa_bits=8])
1116 if test "x$osmesa_bits" != x8; then
1117     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1118         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1119         osmesa_bits=8
1120     fi
1121 fi
1122 case "x$osmesa_bits" in
1123 x8)
1124     OSMESA_LIB="${OSMESA_LIB}"
1125     ;;
1126 x16|x32)
1127     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1128     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1129     ;;
1130 *)
1131     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1132     ;;
1133 esac
1134
1135 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1136     # only link libraries with osmesa if shared
1137     if test "$enable_static" = no; then
1138         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1139     else
1140         OSMESA_LIB_DEPS=""
1141     fi
1142     OSMESA_MESA_DEPS=""
1143     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1144 fi
1145
1146 AC_SUBST([OSMESA_LIB_DEPS])
1147 AC_SUBST([OSMESA_MESA_DEPS])
1148 AC_SUBST([OSMESA_PC_REQ])
1149 AC_SUBST([OSMESA_PC_LIB_PRIV])
1150
1151 dnl
1152 dnl gbm configuration
1153 dnl
1154 if test "x$enable_gbm" = xauto; then
1155     case "$with_egl_platforms" in
1156         *drm*)
1157             enable_gbm=yes ;;
1158          *)
1159             enable_gbm=no ;;
1160     esac
1161 fi
1162 if test "x$enable_gbm" = xyes; then
1163     if test x"$have_libudev" != xyes; then
1164         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED])
1165     fi
1166
1167     if test "x$enable_dri" = xyes; then
1168         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1169         if test "x$enable_shared_glapi" = xno; then
1170             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1171         fi
1172     fi
1173 fi
1174 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1175 GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1176 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1177 AC_SUBST([GBM_PC_REQ_PRIV])
1178 AC_SUBST([GBM_PC_LIB_PRIV])
1179
1180 dnl
1181 dnl EGL configuration
1182 dnl
1183 EGL_CLIENT_APIS=""
1184
1185 if test "x$enable_egl" = xyes; then
1186     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1187
1188     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1189
1190     if test "$enable_static" != yes; then
1191         if test "x$enable_dri" = xyes; then
1192             HAVE_EGL_DRIVER_DRI2=1
1193         fi
1194
1195     fi
1196 fi
1197 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1198 AC_SUBST([EGL_LIB_DEPS])
1199
1200 dnl
1201 dnl EGL Gallium configuration
1202 dnl
1203 if test "x$enable_gallium_egl" = xyes; then
1204     if test -z "$with_gallium_drivers"; then
1205         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1206     fi
1207     if test "x$enable_egl" = xno; then
1208         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1209     fi
1210     if test "x$have_libdrm" != xyes; then
1211         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1212     fi
1213
1214     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1215     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1216 fi
1217 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1218
1219 dnl
1220 dnl gbm Gallium configuration
1221 dnl
1222 if test "x$enable_gallium_gbm" = xauto; then
1223     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1224         yesyesyes*drm*)
1225             enable_gallium_gbm=yes ;;
1226          *)
1227             enable_gallium_gbm=no ;;
1228     esac
1229 fi
1230 if test "x$enable_gallium_gbm" = xyes; then
1231     if test -z "$with_gallium_drivers"; then
1232         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1233     fi
1234     if test "x$enable_gbm" = xno; then
1235         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1236     fi
1237     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1238     if test "x$enable_dri" = xno; then
1239         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1240     fi
1241
1242     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1243     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1244     enable_gallium_loader=yes
1245 fi
1246 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1247
1248 dnl
1249 dnl XA configuration
1250 dnl
1251 if test "x$enable_xa" = xyes; then
1252     if test "x$with_gallium_drivers" = xswrast; then
1253        AC_MSG_ERROR([
1254           Building xa requires at least one non swrast gallium driver.
1255           If you are looking to use libxatracker.so with vmware's virtual gpu,
1256           make sure to include svga in the gallium drivers list, apart from
1257           enabling XA.
1258           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1259     fi
1260     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1261     enable_gallium_loader=yes
1262 fi
1263 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1264
1265 dnl
1266 dnl OpenVG configuration
1267 dnl
1268 VG_LIB_DEPS=""
1269
1270 if test "x$enable_openvg" = xyes; then
1271     if test "x$enable_egl" = xno; then
1272         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1273     fi
1274     if test -z "$with_gallium_drivers"; then
1275         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1276     fi
1277     if test "x$enable_gallium_egl" = xno; then
1278         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1279     fi
1280
1281     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1282     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1283     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1284     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1285     AC_SUBST([VG_PC_LIB_PRIV])
1286 fi
1287 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1288
1289 dnl
1290 dnl Gallium G3DVL configuration
1291 dnl
1292 if test -n "$with_gallium_drivers" && ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1293     if test "x$enable_xvmc" = xauto; then
1294         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1295     fi
1296
1297     if test "x$enable_vdpau" = xauto; then
1298         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1299     fi
1300
1301     if test "x$enable_omx" = xauto; then
1302         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1303     fi
1304 fi
1305
1306 if test "x$enable_xvmc" = xyes; then
1307     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1308     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1309 fi
1310 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1311
1312 if test "x$enable_vdpau" = xyes; then
1313     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1314                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1315     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1316 fi
1317 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1318
1319 if test "x$enable_omx" = xyes; then
1320     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1321     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS omx"
1322 fi
1323 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1324
1325 dnl
1326 dnl OpenCL configuration
1327 dnl
1328
1329 AC_ARG_WITH([libclc-path],
1330    [AS_HELP_STRING([--with-libclc-path],
1331          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1332    [LIBCLC_PATH="$withval"],
1333    [LIBCLC_PATH=''])
1334
1335 if test -n "$LIBCLC_PATH"; then
1336    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1337                   Please review the updated build instructions for clover:
1338                   http://dri.freedesktop.org/wiki/GalliumCompute])
1339 fi
1340
1341
1342 AC_ARG_WITH([clang-libdir],
1343    [AS_HELP_STRING([--with-clang-libdir],
1344          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1345    [CLANG_LIBDIR="$withval"],
1346    [CLANG_LIBDIR=''])
1347
1348 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1349
1350 if test "x$enable_opencl" = xyes; then
1351     if test -z "$with_gallium_drivers"; then
1352         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1353     fi
1354
1355     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1356         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1357     fi
1358
1359     if test "x$have_libclc" = xno; then
1360         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1361                     Make sure the directory containing libclc.pc is specified in your
1362                     PKG_CONFIG_PATH environment variable.
1363                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1364     else
1365         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1366         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1367         AC_SUBST([LIBCLC_INCLUDEDIR])
1368         AC_SUBST([LIBCLC_LIBEXECDIR])
1369     fi
1370
1371     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1372     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1373     enable_gallium_loader=yes
1374
1375     if test "x$enable_opencl_icd" = xyes; then
1376         OPENCL_LIBNAME="MesaOpenCL"
1377     else
1378         OPENCL_LIBNAME="OpenCL"
1379     fi
1380 fi
1381 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1382 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1383 AC_SUBST([OPENCL_LIBNAME])
1384
1385 dnl
1386 dnl Gallium configuration
1387 dnl
1388 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1389
1390 AC_SUBST([LLVM_BINDIR])
1391 AC_SUBST([LLVM_CFLAGS])
1392 AC_SUBST([LLVM_CPPFLAGS])
1393 AC_SUBST([LLVM_CXXFLAGS])
1394 AC_SUBST([LLVM_LIBDIR])
1395 AC_SUBST([LLVM_LIBS])
1396 AC_SUBST([LLVM_LDFLAGS])
1397 AC_SUBST([LLVM_INCLUDEDIR])
1398 AC_SUBST([LLVM_VERSION])
1399 AC_SUBST([CLANG_RESOURCE_DIR])
1400
1401 case "x$enable_opengl$enable_gles1$enable_gles2" in
1402 x*yes*)
1403     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1404     ;;
1405 esac
1406
1407 AC_SUBST([VG_LIB_DEPS])
1408 AC_SUBST([EGL_CLIENT_APIS])
1409
1410 dnl
1411 dnl EGL Platforms configuration
1412 dnl
1413 AC_ARG_WITH([egl-platforms],
1414     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1415         [comma delimited native platforms libEGL supports, e.g.
1416         "x11,drm" @<:@default=auto@:>@])],
1417     [with_egl_platforms="$withval"],
1418     [if test "x$enable_egl" = xyes; then
1419         with_egl_platforms="x11"
1420     else
1421         with_egl_platforms=""
1422     fi])
1423
1424 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1425     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1426 fi
1427
1428 # Do per-EGL platform setups and checks
1429 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1430 for plat in $egl_platforms; do
1431         case "$plat" in
1432         wayland)
1433                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1434                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1435
1436                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1437                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1438                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1439                 ;;
1440
1441         x11)
1442                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1443                 ;;
1444
1445         drm)
1446                 test "x$enable_gbm" = "xno" &&
1447                         AC_MSG_ERROR([EGL platform drm needs gbm])
1448                 test "x$have_libdrm" != xyes &&
1449                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1450                 ;;
1451
1452         android|fbdev|gdi|null)
1453                 ;;
1454
1455         *)
1456                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1457                 ;;
1458         esac
1459
1460         case "$plat$have_libudev" in
1461                 waylandno|drmno)
1462                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED]) ;;
1463         esac
1464 done
1465
1466 # libEGL wants to default to the first platform specified in
1467 # ./configure.  parse that here.
1468 if test "x$egl_platforms" != "x"; then
1469     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1470     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1471 else
1472     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1473 fi
1474
1475 if echo "$egl_platforms" | grep -q 'x11'; then
1476     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1477     NEED_WINSYS_XLIB=yes
1478 fi
1479 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1480 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1481 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1482 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1483 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1484
1485 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1486
1487 AC_SUBST([EGL_NATIVE_PLATFORM])
1488 AC_SUBST([EGL_CFLAGS])
1489
1490 # If we don't have the X11 platform, set this define so we don't try to include
1491 # the X11 headers.
1492 if ! echo "$egl_platforms" | grep -q 'x11'; then
1493     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1494     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1495 fi
1496
1497 AC_ARG_WITH([egl-driver-dir],
1498     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1499                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1500     [EGL_DRIVER_INSTALL_DIR="$withval"],
1501     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1502 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1503
1504 AC_ARG_WITH([max-width],
1505     [AS_HELP_STRING([--with-max-width=N],
1506                     [Maximum framebuffer width (4096)])],
1507     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1508      AS_IF([test "${withval}" -gt "4096"],
1509            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1510 )
1511 AC_ARG_WITH([max-height],
1512     [AS_HELP_STRING([--with-max-height=N],
1513                     [Maximum framebuffer height (4096)])],
1514     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1515      AS_IF([test "${withval}" -gt "4096"],
1516            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1517 )
1518
1519 dnl
1520 dnl Gallium LLVM
1521 dnl
1522 AC_ARG_ENABLE([gallium-llvm],
1523     [AS_HELP_STRING([--enable-gallium-llvm],
1524         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1525     [enable_gallium_llvm="$enableval"],
1526     [enable_gallium_llvm=auto])
1527
1528 AC_ARG_ENABLE([llvm-shared-libs],
1529     [AS_HELP_STRING([--enable-llvm-shared-libs],
1530         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1531     [enable_llvm_shared_libs="$enableval"],
1532     [enable_llvm_shared_libs=yes])
1533
1534 AC_ARG_WITH([llvm-prefix],
1535     [AS_HELP_STRING([--with-llvm-prefix],
1536         [Prefix for LLVM installations in non-standard locations])],
1537     [llvm_prefix="$withval"],
1538     [llvm_prefix=''])
1539
1540
1541 # Call this inside ` ` to get the return value.
1542 # $1 is the llvm-config command with arguments.
1543 strip_unwanted_llvm_flags() {
1544     # Use \> (marks the end of the word)
1545     echo `$1` | sed \
1546         -e 's/-DNDEBUG\>//g' \
1547         -e 's/-pedantic\>//g' \
1548         -e 's/-Wcovered-switch-default\>//g' \
1549         -e 's/-O.\>//g' \
1550         -e 's/-g\>//g' \
1551         -e 's/-Wall\>//g' \
1552         -e 's/-Wcast-qual\>//g' \
1553         -e 's/-Woverloaded-virtual\>//g' \
1554         -e 's/-fcolor-diagnostics\>//g' \
1555         -e 's/-fdata-sections\>//g' \
1556         -e 's/-ffunction-sections\>//g' \
1557         -e 's/-fno-exceptions\>//g' \
1558         -e 's/-fomit-frame-pointer\>//g' \
1559         -e 's/-fvisibility-inlines-hidden\>//g' \
1560         -e 's/-fPIC\>//g'
1561 }
1562
1563
1564 if test -z "$with_gallium_drivers"; then
1565     enable_gallium_llvm=no
1566 fi
1567 if test "x$enable_gallium_llvm" = xauto; then
1568     case "$host_cpu" in
1569     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1570     esac
1571 fi
1572 if test "x$enable_gallium_llvm" = xyes; then
1573     if test -n "$llvm_prefix"; then
1574         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1575     else
1576         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1577     fi
1578
1579     if test "x$LLVM_CONFIG" != xno; then
1580         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1581         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1582         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1583         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1584         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1585         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1586         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1587         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1588
1589         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1590             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1591         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1592             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1593
1594         if test -n "${LLVM_VERSION_MAJOR}"; then
1595             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1596         else
1597             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1598         fi
1599
1600         LLVM_COMPONENTS="engine bitwriter"
1601         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1602             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1603         fi
1604
1605         if test "x$enable_opencl" = xyes; then
1606             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1607             # LLVM 3.3 >= 177971 requires IRReader
1608             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1609                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1610             fi
1611             # LLVM 3.4 requires Option
1612             if $LLVM_CONFIG --components | grep -qw 'option'; then
1613                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1614             fi
1615         fi
1616         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1617         MESA_LLVM=1
1618
1619         dnl Check for Clang internal headers
1620         if test "x$enable_opencl" = xyes; then
1621             if test -z "$CLANG_LIBDIR"; then
1622                 CLANG_LIBDIR=${LLVM_LIBDIR}
1623             fi
1624             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1625             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1626                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1627         fi
1628     else
1629         MESA_LLVM=0
1630         LLVM_VERSION_INT=0
1631     fi
1632 else
1633     MESA_LLVM=0
1634     LLVM_VERSION_INT=0
1635 fi
1636
1637 dnl Directory for XVMC libs
1638 AC_ARG_WITH([xvmc-libdir],
1639     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1640         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1641     [XVMC_LIB_INSTALL_DIR="$withval"],
1642     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1643 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1644
1645 dnl
1646 dnl Gallium Tests
1647 dnl
1648 if test "x$enable_gallium_tests" = xyes; then
1649     enable_gallium_loader=yes
1650 fi
1651 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1652
1653 if test "x$enable_gallium_loader" = xyes; then
1654     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1655 fi
1656 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1657
1658 dnl Directory for VDPAU libs
1659 AC_ARG_WITH([vdpau-libdir],
1660     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1661         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1662     [VDPAU_LIB_INSTALL_DIR="$withval"],
1663     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1664 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1665
1666 OMX_LIB_INSTALL_DIR_DEFAULT=''
1667 if test "x$enable_omx" = xyes; then
1668     OMX_LIB_INSTALL_DIR_DEFAULT=`$PKG_CONFIG --variable=pluginsdir libomxil-bellagio`
1669 fi
1670
1671 AC_ARG_WITH([omx-libdir],
1672     [AS_HELP_STRING([--with-omx-libdir=DIR],
1673         [directory for the OMX libraries])],
1674     [OMX_LIB_INSTALL_DIR="$withval"],
1675     [OMX_LIB_INSTALL_DIR="$OMX_LIB_INSTALL_DIR_DEFAULT"])
1676 AC_SUBST([OMX_LIB_INSTALL_DIR])
1677
1678 dnl Directory for OpenCL libs
1679 AC_ARG_WITH([opencl-libdir],
1680     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1681         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1682     [OPENCL_LIB_INSTALL_DIR="$withval"],
1683     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1684 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1685
1686 dnl
1687 dnl Gallium helper functions
1688 dnl
1689 gallium_check_st() {
1690     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1691          if test "x$have_libdrm" != xyes; then
1692             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1693          fi
1694          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1695     fi
1696     if test "x$enable_dri" = xyes && test -n "$2"; then
1697          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1698     fi
1699     if test "x$enable_xa" = xyes && test -n "$3"; then
1700          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1701     fi
1702     if test "x$enable_xvmc" = xyes && test -n "$4"; then
1703          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1704     fi
1705     if test "x$enable_vdpau" = xyes && test -n "$5"; then
1706          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1707     fi
1708     if test "x$enable_omx" = xyes && test "x$6" != x; then
1709          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1710     fi
1711 }
1712
1713 gallium_require_llvm() {
1714     if test "x$MESA_LLVM" = x0; then
1715         case "$host_cpu" in
1716         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1717         esac
1718     fi
1719 }
1720
1721 gallium_require_drm_loader() {
1722     if test "x$enable_gallium_loader" = xyes; then
1723         if test "x$have_libudev" != xyes; then
1724             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED])
1725         fi
1726         if test "x$have_libdrm" != xyes; then
1727             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1728         fi
1729         enable_gallium_drm_loader=yes
1730     fi
1731 }
1732
1733 radeon_llvm_check() {
1734     if test "x$enable_gallium_llvm" != "xyes"; then
1735         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1736     fi
1737     LLVM_REQUIRED_VERSION_MAJOR="3"
1738     LLVM_REQUIRED_VERSION_MINOR="3"
1739     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1740         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for $1])
1741     fi
1742     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1743         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1744                       sources with the --enable-experimental-targets=R600
1745                       configure flag])
1746     fi
1747     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1748     NEED_RADEON_LLVM=yes
1749     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1750                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1751 }
1752
1753 dnl Gallium drivers
1754 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1755         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1756     NEED_NONNULL_WINSYS=yes
1757 fi
1758 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1759
1760 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1761 if test -n "$with_gallium_drivers"; then
1762     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1763     for driver in $gallium_drivers; do
1764         case "x$driver" in
1765         xsvga)
1766             HAVE_GALLIUM_SVGA=yes
1767             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1768             gallium_require_drm_loader
1769             gallium_check_st "svga/drm" "dri-vmwgfx" ""
1770             ;;
1771         xi915)
1772             HAVE_GALLIUM_I915=yes
1773             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1774             gallium_require_drm_loader
1775             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1776             if test "x$MESA_LLVM" = x1; then
1777                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1778             fi
1779             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1780             gallium_check_st "i915/drm" "dri-i915"
1781             DRICOMMON_NEED_LIBDRM=yes
1782             ;;
1783         xilo)
1784             HAVE_GALLIUM_ILO=yes
1785             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1786             gallium_require_drm_loader
1787             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1788             gallium_check_st "intel/drm" "dri-ilo"
1789             DRICOMMON_NEED_LIBDRM=yes
1790             ;;
1791         xr300)
1792             HAVE_GALLIUM_R300=yes
1793             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1794             gallium_require_drm_loader
1795             gallium_require_llvm "Gallium R300"
1796             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1797             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1798             DRICOMMON_NEED_LIBDRM=yes
1799             ;;
1800         xr600)
1801             HAVE_GALLIUM_R600=yes
1802             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1803             gallium_require_drm_loader
1804             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1805             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1806                 radeon_llvm_check "r600g"
1807                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1808             fi
1809             if test "x$enable_r600_llvm" = xyes; then
1810                 USE_R600_LLVM_COMPILER=yes;
1811             fi
1812             if test "x$enable_opencl" = xyes; then
1813                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1814             fi
1815             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau" "r600/omx"
1816             DRICOMMON_NEED_LIBDRM=yes
1817             ;;
1818         xradeonsi)
1819             HAVE_GALLIUM_RADEONSI=yes
1820             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1821             gallium_require_drm_loader
1822             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1823             radeon_llvm_check "radeonsi"
1824             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau" "radeonsi/omx"
1825             DRICOMMON_NEED_LIBDRM=yes
1826             ;;
1827         xnouveau)
1828             HAVE_GALLIUM_NOUVEAU=yes
1829             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1830             gallium_require_drm_loader
1831             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1832             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1833             DRICOMMON_NEED_LIBDRM=yes
1834             ;;
1835         xfreedreno)
1836             HAVE_GALLIUM_FREEDRENO=yes
1837             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1838             gallium_require_drm_loader
1839             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1840             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1841             DRICOMMON_NEED_LIBDRM=yes
1842             ;;
1843         xswrast)
1844             HAVE_GALLIUM_SOFTPIPE=yes
1845             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1846             if test "x$MESA_LLVM" = x1; then
1847                 HAVE_GALLIUM_LLVMPIPE=yes
1848                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1849             fi
1850
1851             if test "x$enable_dri" = xyes; then
1852                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1853             fi
1854             ;;
1855         *)
1856             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1857             ;;
1858         esac
1859     done
1860 fi
1861
1862 dnl Set LLVM_LIBS - This is done after the driver configuration so
1863 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1864 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1865 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1866 dnl this was causing the same libraries to be appear multiple times
1867 dnl in LLVM_LIBS.
1868
1869 if test "x$MESA_LLVM" != x0; then
1870
1871     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1872
1873     if test "x$enable_llvm_shared_libs" = xyes; then
1874         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1875         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1876         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1877
1878         if test "x$llvm_have_one_so" = xyes; then
1879             dnl LLVM was built using auto*, so there is only one shared object.
1880             LLVM_LIBS="-l$LLVM_SO_NAME"
1881         else
1882             dnl If LLVM was built with CMake, there will be one shared object per
1883             dnl component.
1884             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1885                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1886         Please make sure you have built llvm with the --enable-shared option
1887         and that your llvm libraries are installed in $LLVM_LIBDIR
1888         If you have installed your llvm libraries to a different directory you
1889         can use the --with-llvm-prefix= configure flag to specify this directory.
1890         NOTE: Mesa is attempting to use llvm shared libraries by default.
1891         If you do not want to build with llvm shared libraries and instead want to
1892         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1893         invocation and rebuild.])])
1894
1895            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1896            dnl install uses a shared object for each compoenent and we have
1897            dnl already added all of these objects to LLVM_LIBS.
1898         fi
1899     else
1900         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
1901     fi
1902 fi
1903
1904 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1905 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1906 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1907 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1908 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1909 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1910 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1911 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1912 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1913 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1914
1915 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1916                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1917                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1918 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1919                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1920                                                   && test "x$MESA_LLVM" = x1)
1921
1922 # NOTE: anything using xcb or other client side libs ends up in separate
1923 #       _CLIENT variables.  The pipe loader is built in two variants,
1924 #       one that is standalone and does not link any x client libs (for
1925 #       use by XA tracker in particular, but could be used in any case
1926 #       where communication with xserver is not desired).
1927 if test "x$enable_gallium_loader" = xyes; then
1928     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1929
1930     if test "x$enable_gallium_xlib_loader" = xyes; then
1931         GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1932         NEED_WINSYS_XLIB="yes"
1933         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1934     fi
1935
1936     if test "x$enable_gallium_drm_loader" = xyes; then
1937         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1938         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1939                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1940         if test "x$pipe_loader_have_xcb" = xyes; then
1941             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
1942             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1943         fi
1944     fi
1945
1946     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
1947     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
1948
1949     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1950     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1951     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
1952     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
1953 fi
1954 AM_CONDITIONAL(NEED_PIPE_LOADER_XLIB, test "x$enable_gallium_xlib_loader" = xyes)
1955
1956 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1957 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1958 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1959 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1960 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1961 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1962
1963 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1964                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1965                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1966                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1967 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1968                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1969 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1970 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1971 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1972 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1973 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1974 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1975 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1976
1977 AC_SUBST([ELF_LIB])
1978
1979 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1980 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1981 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1982 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1983 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1984
1985 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1986 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1987 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1988
1989 AC_SUBST([VDPAU_MAJOR], 1)
1990 AC_SUBST([VDPAU_MINOR], 0)
1991
1992 AC_SUBST([XVMC_MAJOR], 1)
1993 AC_SUBST([XVMC_MINOR], 0)
1994
1995 AC_SUBST([XA_MAJOR], 2)
1996 AC_SUBST([XA_MINOR], 2)
1997 AC_SUBST([XA_TINY], 0)
1998 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1999
2000 dnl Restore LDFLAGS and CPPFLAGS
2001 LDFLAGS="$_SAVE_LDFLAGS"
2002 CPPFLAGS="$_SAVE_CPPFLAGS"
2003
2004 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2005 if test "x$acv_mesa_CLANG" = xyes; then
2006     CFLAGS="$CFLAGS -Qunused-arguments"
2007     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2008 fi
2009
2010 dnl Add user CFLAGS and CXXFLAGS
2011 CFLAGS="$CFLAGS $USER_CFLAGS"
2012 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2013
2014 dnl Substitute the config
2015 AC_CONFIG_FILES([Makefile
2016                 src/Makefile
2017                 src/egl/Makefile
2018                 src/egl/drivers/Makefile
2019                 src/egl/drivers/dri2/Makefile
2020                 src/egl/main/Makefile
2021                 src/egl/main/egl.pc
2022                 src/egl/wayland/Makefile
2023                 src/egl/wayland/wayland-drm/Makefile
2024                 src/egl/wayland/wayland-egl/Makefile
2025                 src/egl/wayland/wayland-egl/wayland-egl.pc
2026                 src/gallium/auxiliary/Makefile
2027                 src/gallium/auxiliary/pipe-loader/Makefile
2028                 src/gallium/drivers/Makefile
2029                 src/gallium/drivers/freedreno/Makefile
2030                 src/gallium/drivers/galahad/Makefile
2031                 src/gallium/drivers/i915/Makefile
2032                 src/gallium/drivers/identity/Makefile
2033                 src/gallium/drivers/ilo/Makefile
2034                 src/gallium/drivers/llvmpipe/Makefile
2035                 src/gallium/drivers/noop/Makefile
2036                 src/gallium/drivers/nouveau/Makefile
2037                 src/gallium/drivers/r300/Makefile
2038                 src/gallium/drivers/r600/Makefile
2039                 src/gallium/drivers/radeon/Makefile
2040                 src/gallium/drivers/radeonsi/Makefile
2041                 src/gallium/drivers/rbug/Makefile
2042                 src/gallium/drivers/softpipe/Makefile
2043                 src/gallium/drivers/svga/Makefile
2044                 src/gallium/drivers/trace/Makefile
2045                 src/gallium/state_trackers/Makefile
2046                 src/gallium/state_trackers/clover/Makefile
2047                 src/gallium/state_trackers/dri/Makefile
2048                 src/gallium/state_trackers/dri/drm/Makefile
2049                 src/gallium/state_trackers/dri/sw/Makefile
2050                 src/gallium/state_trackers/egl/Makefile
2051                 src/gallium/state_trackers/gbm/Makefile
2052                 src/gallium/state_trackers/glx/xlib/Makefile
2053                 src/gallium/state_trackers/omx/Makefile
2054                 src/gallium/state_trackers/osmesa/Makefile
2055                 src/gallium/state_trackers/vdpau/Makefile
2056                 src/gallium/state_trackers/vega/Makefile
2057                 src/gallium/state_trackers/xa/Makefile
2058                 src/gallium/state_trackers/xvmc/Makefile
2059                 src/gallium/targets/Makefile
2060                 src/gallium/targets/dri-freedreno/Makefile
2061                 src/gallium/targets/dri-i915/Makefile
2062                 src/gallium/targets/dri-ilo/Makefile
2063                 src/gallium/targets/dri-nouveau/Makefile
2064                 src/gallium/targets/dri-swrast/Makefile
2065                 src/gallium/targets/dri-vmwgfx/Makefile
2066                 src/gallium/targets/egl-static/Makefile
2067                 src/gallium/targets/gbm/Makefile
2068                 src/gallium/targets/opencl/Makefile
2069                 src/gallium/targets/xa/Makefile
2070                 src/gallium/targets/xa/xatracker.pc
2071                 src/gallium/targets/osmesa/Makefile
2072                 src/gallium/targets/osmesa/osmesa.pc
2073                 src/gallium/targets/pipe-loader/Makefile
2074                 src/gallium/targets/radeonsi/dri/Makefile
2075                 src/gallium/targets/radeonsi/omx/Makefile
2076                 src/gallium/targets/radeonsi/vdpau/Makefile
2077                 src/gallium/targets/r300/dri/Makefile
2078                 src/gallium/targets/r600/dri/Makefile
2079                 src/gallium/targets/r600/omx/Makefile
2080                 src/gallium/targets/r600/vdpau/Makefile
2081                 src/gallium/targets/r600/xvmc/Makefile
2082                 src/gallium/targets/libgl-xlib/Makefile
2083                 src/gallium/targets/vdpau-nouveau/Makefile
2084                 src/gallium/targets/xvmc-nouveau/Makefile
2085                 src/gallium/tests/trivial/Makefile
2086                 src/gallium/tests/unit/Makefile
2087                 src/gallium/winsys/Makefile
2088                 src/gallium/winsys/freedreno/drm/Makefile
2089                 src/gallium/winsys/i915/drm/Makefile
2090                 src/gallium/winsys/i915/sw/Makefile
2091                 src/gallium/winsys/intel/drm/Makefile
2092                 src/gallium/winsys/nouveau/drm/Makefile
2093                 src/gallium/winsys/radeon/drm/Makefile
2094                 src/gallium/winsys/svga/drm/Makefile
2095                 src/gallium/winsys/sw/dri/Makefile
2096                 src/gallium/winsys/sw/fbdev/Makefile
2097                 src/gallium/winsys/sw/null/Makefile
2098                 src/gallium/winsys/sw/wayland/Makefile
2099                 src/gallium/winsys/sw/wrapper/Makefile
2100                 src/gallium/winsys/sw/xlib/Makefile
2101                 src/gbm/Makefile
2102                 src/gbm/main/gbm.pc
2103                 src/glsl/Makefile
2104                 src/glx/Makefile
2105                 src/glx/tests/Makefile
2106                 src/gtest/Makefile
2107                 src/loader/Makefile
2108                 src/mapi/Makefile
2109                 src/mapi/es1api/Makefile
2110                 src/mapi/es1api/glesv1_cm.pc
2111                 src/mapi/es2api/Makefile
2112                 src/mapi/es2api/glesv2.pc
2113                 src/mapi/glapi/Makefile
2114                 src/mapi/glapi/gen/Makefile
2115                 src/mapi/glapi/tests/Makefile
2116                 src/mapi/shared-glapi/Makefile
2117                 src/mapi/shared-glapi/tests/Makefile
2118                 src/mapi/vgapi/Makefile
2119                 src/mapi/vgapi/vg.pc
2120                 src/mesa/Makefile
2121                 src/mesa/gl.pc
2122                 src/mesa/drivers/dri/dri.pc
2123                 src/mesa/drivers/dri/common/Makefile
2124                 src/mesa/drivers/dri/common/xmlpool/Makefile
2125                 src/mesa/drivers/dri/i915/Makefile
2126                 src/mesa/drivers/dri/i965/Makefile
2127                 src/mesa/drivers/dri/Makefile
2128                 src/mesa/drivers/dri/nouveau/Makefile
2129                 src/mesa/drivers/dri/r200/Makefile
2130                 src/mesa/drivers/dri/radeon/Makefile
2131                 src/mesa/drivers/dri/swrast/Makefile
2132                 src/mesa/drivers/osmesa/Makefile
2133                 src/mesa/drivers/osmesa/osmesa.pc
2134                 src/mesa/drivers/x11/Makefile
2135                 src/mesa/main/tests/Makefile
2136                 src/mesa/main/tests/hash_table/Makefile])
2137
2138 dnl Sort the dirs alphabetically
2139 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2140 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2141 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2142 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2143
2144 AC_OUTPUT
2145
2146 dnl
2147 dnl Output some configuration info for the user
2148 dnl
2149 echo ""
2150 echo "        prefix:          $prefix"
2151 echo "        exec_prefix:     $exec_prefix"
2152 echo "        libdir:          $libdir"
2153 echo "        includedir:      $includedir"
2154
2155 dnl API info
2156 echo ""
2157 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2158 echo "        OpenVG:          $enable_openvg"
2159
2160 dnl Driver info
2161 echo ""
2162 case "x$enable_osmesa$enable_gallium_osmesa" in
2163 xnoyes)
2164         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2165         ;;
2166 xyesno)
2167         echo "        OSMesa:          lib$OSMESA_LIB"
2168         ;;
2169 xnono)
2170         echo "        OSMesa:          no"
2171         ;;
2172 esac
2173
2174 if test "x$enable_dri" != xno; then
2175         if test -z "$DRI_DIRS"; then
2176             echo "        DRI drivers:     no"
2177         else
2178             echo "        DRI drivers:     $DRI_DIRS"
2179         fi
2180         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2181 fi
2182
2183 case "x$enable_glx$enable_xlib_glx" in
2184 xyesyes)
2185     echo "        GLX:             Xlib-based"
2186     ;;
2187 xyesno)
2188     echo "        GLX:             DRI-based"
2189     ;;
2190 *)
2191     echo "        GLX:             $enable_glx"
2192     ;;
2193 esac
2194
2195 dnl EGL
2196 echo ""
2197 echo "        EGL:             $enable_egl"
2198 if test "$enable_egl" = yes; then
2199     echo "        EGL platforms:   $egl_platforms"
2200
2201     egl_drivers=""
2202     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2203         egl_drivers="$egl_drivers builtin:egl_dri2"
2204     fi
2205
2206     if test "x$enable_gallium_egl" = xyes; then
2207         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2208         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2209     else
2210         echo "        EGL drivers:    $egl_drivers"
2211     fi
2212 fi
2213
2214 echo ""
2215 if test "x$MESA_LLVM" = x1; then
2216     echo "        llvm:            yes"
2217     echo "        llvm-config:     $LLVM_CONFIG"
2218     echo "        llvm-version:    $LLVM_VERSION"
2219 else
2220     echo "        llvm:            no"
2221 fi
2222
2223 echo ""
2224 if test -n "$with_gallium_drivers"; then
2225     echo "        Gallium:         yes"
2226     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2227     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2228     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2229     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2230 else
2231     echo "        Gallium:         no"
2232 fi
2233
2234
2235 dnl Libraries
2236 echo ""
2237 echo "        Shared libs:     $enable_shared"
2238 echo "        Static libs:     $enable_static"
2239 echo "        Shared-glapi:    $enable_shared_glapi"
2240
2241 dnl Compiler options
2242 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2243 cflags=`echo $CFLAGS | \
2244     $SED 's/^ *//;s/  */ /;s/ *$//'`
2245 cxxflags=`echo $CXXFLAGS | \
2246     $SED 's/^ *//;s/  */ /;s/ *$//'`
2247 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2248 echo ""
2249 echo "        CFLAGS:          $cflags"
2250 echo "        CXXFLAGS:        $cxxflags"
2251 echo "        Macros:          $defines"
2252 echo ""
2253 if test "x$MESA_LLVM" = x1; then
2254     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2255     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2256     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2257     echo ""
2258 fi
2259 echo "        PYTHON2:         $PYTHON2"
2260
2261 echo ""
2262 echo "        Run '${MAKE-make}' to build Mesa"
2263 echo ""