configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libstdc++-v3 \
 158                 target-libmudflap \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-boehm-gc \
 163                 ${libgcj} \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 # Make sure we don't let ZLIB be added if we didn't want it.
 242 if test x$with_system_zlib = xyes ; then
 243   use_included_zlib=no
 244   noconfigdirs="$noconfigdirs zlib"
 245 fi
 246
 247 # some tools are so dependent upon X11 that if we're not building with X,
 248 # it's not even worth trying to configure, much less build, that tool.
 249
 250 case ${with_x} in
 251   yes | "") ;; # the default value for this tree is that X11 is available
 252   no)
 253     skipdirs="${skipdirs} tk itcl libgui"
 254     # We won't be able to build gdbtk without X.
 255     enable_gdbtk=no
 256     ;;
 257   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 258 esac
 259
 260 # Some are only suitable for cross toolchains.
 261 # Remove these if host=target.
 262 cross_only="target-libgloss target-newlib target-opcodes"
 263
 264 case $is_cross_compiler in
 265   no) skipdirs="${skipdirs} ${cross_only}" ;;
 266 esac
 267
 268 # If both --with-headers and --with-libs are specified, default to
 269 # --without-newlib.
 270 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 271    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 272   if test x"${with_newlib}" = x ; then
 273     with_newlib=no
 274   fi
 275 fi
 276
 277 # Recognize --with-newlib/--without-newlib.
 278 case ${with_newlib} in
 279   no) skipdirs="${skipdirs} target-newlib" ;;
 280   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 281 esac
 282
 283 # Handle --enable-gold, --enable-ld.
 284 # --disable-gold [--enable-ld]
 285 #     Build only ld.  Default option.
 286 # --enable-gold [--enable-ld]
 287 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 288 #     as "ld.bfd" and "ld".
 289 # --enable-gold=default [--enable-ld]
 290 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 291 #     install ld as "ld.bfd".
 292 # --enable-gold[=default] --disable-ld
 293 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 294 # --enable-gold --enable-ld=default
 295 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 296 #     and ld.bfd).
 297 #     In other words, ld is default
 298 # --enable-gold=default --enable-ld=default
 299 #     Error.
 300
 301 default_ld=
 302 AC_ARG_ENABLE(gold,
 303 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 304                 [build gold @<:@ARG={default,yes,no}@:>@])],
 305 ENABLE_GOLD=$enableval,
 306 ENABLE_GOLD=no)
 307 case "${ENABLE_GOLD}" in
 308   yes|default)
 309     # Check for ELF target.
 310     is_elf=no
 311     case "${target}" in
 312       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 313       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 314       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 315       | *-*-solaris2* | *-*-nto*)
 316         case "${target}" in
 317           *-*-linux*aout* | *-*-linux*oldld*)
 318             ;;
 319           *)
 320             is_elf=yes
 321             ;;
 322         esac
 323     esac
 324
 325     if test "$is_elf" = "yes"; then
 326       # Check for target supported by gold.
 327       case "${target}" in
 328         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 329           configdirs="$configdirs gold"
 330           if test x${ENABLE_GOLD} = xdefault; then
 331             default_ld=gold
 332           fi
 333           ENABLE_GOLD=yes
 334           ;;
 335       esac
 336     fi
 337     ;;
 338   no)
 339     ;;
 340   *)
 341     AC_MSG_ERROR([invalid --enable-gold argument])
 342     ;;
 343 esac
 344
 345 AC_ARG_ENABLE(ld,
 346 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 347                 [build ld @<:@ARG={default,yes,no}@:>@])],
 348 ENABLE_LD=$enableval,
 349 ENABLE_LD=yes)
 350
 351 case "${ENABLE_LD}" in
 352   default)
 353     if test x${default_ld} != x; then
 354       AC_MSG_ERROR([either gold or ld can be the default ld])
 355     fi
 356     ;;
 357   yes)
 358     ;;
 359   no)
 360     if test x${ENABLE_GOLD} != xyes; then
 361       AC_MSG_WARN([neither ld nor gold are enabled])
 362     fi
 363     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-ld argument])
 367     ;;
 368 esac
 369
 370 # Configure extra directories which are host specific
 371
 372 case "${host}" in
 373   *-cygwin*)
 374     configdirs="$configdirs libtermcap" ;;
 375 esac
 376
 377 # A target can indicate whether a language isn't supported for some reason.
 378 # Only spaces may be used in this macro; not newlines or tabs.
 379 unsupported_languages=
 380
 381 # Remove more programs from consideration, based on the host or
 382 # target this usually means that a port of the program doesn't
 383 # exist yet.
 384
 385 case "${host}" in
 386   i[[3456789]]86-*-msdosdjgpp*)
 387     noconfigdirs="$noconfigdirs tcl tk itcl"
 388     ;;
 389 esac
 390
 391
 392 AC_ARG_ENABLE(libquadmath,
 393 AS_HELP_STRING([--disable-libquadmath],
 394   [do not build libquadmath directory]),
 395 ENABLE_LIBQUADMATH=$enableval,
 396 ENABLE_LIBQUADMATH=yes)
 397 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 398   noconfigdirs="$noconfigdirs target-libquadmath"
 399 fi
 400
 401
 402 AC_ARG_ENABLE(libquadmath-support,
 403 AS_HELP_STRING([--disable-libquadmath-support],
 404   [disable libquadmath support for Fortran]),
 405 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 406 ENABLE_LIBQUADMATH_SUPPORT=yes)
 407 enable_libquadmath_support=
 408 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 409   enable_libquadmath_support=no
 410 fi
 411
 412
 413 AC_ARG_ENABLE(libada,
 414 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 415 ENABLE_LIBADA=$enableval,
 416 ENABLE_LIBADA=yes)
 417 if test "${ENABLE_LIBADA}" != "yes" ; then
 418   noconfigdirs="$noconfigdirs gnattools"
 419 fi
 420
 421 AC_ARG_ENABLE(libssp,
 422 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 423 ENABLE_LIBSSP=$enableval,
 424 ENABLE_LIBSSP=yes)
 425
 426 # Save it here so that, even in case of --enable-libgcj, if the Java
 427 # front-end isn't enabled, we still get libgcj disabled.
 428 libgcj_saved=$libgcj
 429 case $enable_libgcj in
 430 yes)
 431   # If we reset it here, it won't get added to noconfigdirs in the
 432   # target-specific build rules, so it will be forcibly enabled
 433   # (unless the Java language itself isn't enabled).
 434   libgcj=
 435   ;;
 436 no)
 437   # Make sure we get it printed in the list of not supported target libs.
 438   # Don't disable libffi, though, other languages use it.
 439   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 440   # Clear libgcj_saved so that even if java is enabled libffi won't be
 441   # built.
 442   libgcj_saved=
 443   ;;
 444 esac
 445
 446
 447 # Disable libmudflap on some systems.
 448 if test x$enable_libmudflap = x ; then
 449     case "${target}" in
 450     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 451         # Enable libmudflap by default in GNU and friends.
 452         ;;
 453     *-*-freebsd*)
 454         # Enable libmudflap by default in FreeBSD.
 455         ;;
 456     *)
 457         # Disable it by default everywhere else.
 458         noconfigdirs="$noconfigdirs target-libmudflap"
 459         ;;
 460     esac
 461 fi
 462
 463 # Disable libgomp on non POSIX hosted systems.
 464 if test x$enable_libgomp = x ; then
 465     # Enable libgomp by default on hosted POSIX systems.
 466     case "${target}" in
 467     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 468         ;;
 469     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 470         ;;
 471     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 472         ;;
 473     *-*-darwin* | *-*-aix*)
 474         ;;
 475     *)
 476         noconfigdirs="$noconfigdirs target-libgomp"
 477         ;;
 478     esac
 479 fi
 480
 481 # Disable libssp for some systems.
 482 case "${target}" in
 483   avr-*-*)
 484     # No hosted I/O support.
 485     noconfigdirs="$noconfigdirs target-libssp"
 486     ;;
 487   powerpc-*-aix* | rs6000-*-aix*)
 488     noconfigdirs="$noconfigdirs target-libssp"
 489     ;;
 490 esac
 491
 492 # Disable libstdc++-v3 for some systems.
 493 case "${target}" in
 494   *-*-vxworks*)
 495     # VxWorks uses the Dinkumware C++ library.
 496     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 497     ;;
 498   arm*-wince-pe*)
 499     # the C++ libraries don't build on top of CE's C libraries
 500     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 501     ;;
 502   avr-*-*)
 503     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 504     ;;
 505 esac
 506
 507 # Disable Fortran for some systems.
 508 case "${target}" in
 509   mmix-*-*)
 510     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 511     unsupported_languages="$unsupported_languages fortran"
 512     ;;
 513 esac
 514
 515 # Disable Java if libffi is not supported.
 516 case "${target}" in
 517   alpha*-*-*)
 518     ;;
 519   arm*-*-*)
 520     ;;
 521   cris-*-*)
 522     ;;
 523   frv-*-*)
 524     ;;
 525   hppa*-*-linux*)
 526     ;;
 527   hppa*-*-hpux*)
 528     ;;
 529   i?86-*-*)
 530     ;;
 531   ia64*-*-*)
 532     ;;
 533   m32r*-*-*)
 534     ;;
 535   m68k-*-*)
 536     ;;
 537   mips-sgi-irix6.* | mips*-*-rtems*)
 538     ;;
 539   mips*-*-linux*)
 540     ;;
 541   powerpc*-*-linux*)
 542     ;;
 543   powerpc-*-darwin*)
 544     ;;
 545   powerpc-*-aix* | rs6000-*-aix*)
 546     ;;
 547   powerpc-*-freebsd*)
 548     ;;
 549   powerpc64-*-freebsd*)
 550     ;;
 551   powerpc*-*-rtems*)
 552     ;;
 553   s390-*-* | s390x-*-*)
 554     ;;
 555   sh-*-* | sh[[34]]*-*-*)
 556     ;;
 557   sh64-*-* | sh5*-*-*)
 558     ;;
 559   sparc*-*-*)
 560     ;;
 561   x86_64-*-*)
 562     ;;
 563   *-*-*)
 564     unsupported_languages="$unsupported_languages java"
 565     ;;
 566 esac
 567
 568 # Disable Java, libgcj or related libraries for some systems.
 569 case "${target}" in
 570   powerpc-*-darwin*)
 571     ;;
 572   i[[3456789]]86-*-darwin*)
 573     ;;
 574   x86_64-*-darwin[[912]]*)
 575     ;;
 576   *-*-darwin*)
 577     noconfigdirs="$noconfigdirs ${libgcj}"
 578     ;;
 579   *-*-netware*)
 580     noconfigdirs="$noconfigdirs ${libgcj}"
 581     ;;
 582   *-*-rtems*)
 583     noconfigdirs="$noconfigdirs ${libgcj}"
 584     ;;
 585   *-*-tpf*)
 586     noconfigdirs="$noconfigdirs ${libgcj}"
 587     ;;
 588   *-*-uclinux*)
 589     noconfigdirs="$noconfigdirs ${libgcj}"
 590     ;;
 591   *-*-vxworks*)
 592     noconfigdirs="$noconfigdirs ${libgcj}"
 593     ;;
 594   alpha*-*-*vms*)
 595     noconfigdirs="$noconfigdirs ${libgcj}"
 596     ;;
 597   arm-wince-pe)
 598     noconfigdirs="$noconfigdirs ${libgcj}"
 599     ;;
 600   arm*-*-symbianelf*)
 601     noconfigdirs="$noconfigdirs ${libgcj}"
 602     ;;
 603   bfin-*-*)
 604     noconfigdirs="$noconfigdirs target-boehm-gc"
 605     ;;
 606   cris-*-* | crisv32-*-*)
 607     unsupported_languages="$unsupported_languages java"
 608     case "${target}" in
 609       *-*-linux*)
 610         ;;
 611       *) # See PR46792 regarding target-libffi.
 612         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 613     esac
 614     ;;
 615   hppa*64*-*-linux*)
 616     # In this case, it's because the hppa64-linux target is for
 617     # the kernel only at this point and has no libc, and thus no
 618     # headers, crt*.o, etc., all of which are needed by these.
 619     unsupported_languages="$unsupported_languages java"
 620     ;;
 621   hppa*64*-*-hpux*)
 622     noconfigdirs="$noconfigdirs ${libgcj}"
 623     ;;
 624   hppa*-hp-hpux11*)
 625     ;;
 626   hppa*-*-hpux*)
 627     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 628     # build on HP-UX 10.20.
 629     noconfigdirs="$noconfigdirs ${libgcj}"
 630     ;;
 631   ia64*-*-*vms*)
 632     noconfigdirs="$noconfigdirs ${libgcj}"
 633     ;;
 634   i[[3456789]]86-w64-mingw*)
 635     noconfigdirs="$noconfigdirs ${libgcj}"
 636     ;;
 637   i[[3456789]]86-*-mingw*)
 638     noconfigdirs="$noconfigdirs ${libgcj}"
 639     ;;
 640   x86_64-*-mingw*)
 641     noconfigdirs="$noconfigdirs ${libgcj}"
 642     ;;
 643   mmix-*-*)
 644     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 645     ;;
 646   powerpc-*-aix*)
 647     # copied from rs6000-*-* entry
 648     noconfigdirs="$noconfigdirs ${libgcj}"
 649     ;;
 650   rs6000-*-aix*)
 651     noconfigdirs="$noconfigdirs ${libgcj}"
 652     ;;
 653   mips*-*-irix6*)
 654     # Linking libjava exceeds command-line length limits on at least
 655     # IRIX 6.2, but not on IRIX 6.5.
 656     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 657     # <oldham@codesourcery.com>
 658     noconfigdirs="$noconfigdirs ${libgcj}"
 659     ;;
 660   *-*-lynxos*)
 661     noconfigdirs="$noconfigdirs ${libgcj}"
 662     ;;
 663 esac
 664
 665 # Default libgloss CPU subdirectory.
 666 libgloss_dir="$target_cpu"
 667
 668 case "${target}" in
 669   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 670     libgloss_dir=wince
 671     ;;
 672   arm*-*-*)
 673     libgloss_dir=arm
 674     ;;
 675   cris-*-* | crisv32-*-*)
 676     libgloss_dir=cris
 677     ;;
 678   hppa*-*-*)
 679     libgloss_dir=pa
 680     ;;
 681   i[[3456789]]86-*-*)
 682     libgloss_dir=i386
 683     ;;
 684   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 685     libgloss_dir=m68hc11
 686     ;;
 687   m68*-*-* | fido-*-*)
 688     libgloss_dir=m68k
 689     ;;
 690   mips*-*-*)
 691     libgloss_dir=mips
 692     ;;
 693   powerpc*-*-*)
 694     libgloss_dir=rs6000
 695     ;;
 696   sparc*-*-*)
 697     libgloss_dir=sparc
 698     ;;
 699 esac
 700
 701 # Disable newlib and libgloss for various target OSes.
 702 case "${target}" in
 703   alpha*-dec-osf*)
 704     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 705     ;;
 706   i[[3456789]]86-*-linux*)
 707     # This section makes it possible to build newlib natively on linux.
 708     # If we are using a cross compiler then don't configure newlib.
 709     if test x${is_cross_compiler} != xno ; then
 710       noconfigdirs="$noconfigdirs target-newlib"
 711     fi
 712     noconfigdirs="$noconfigdirs target-libgloss"
 713     # If we are not using a cross compiler, do configure newlib.
 714     # Note however, that newlib will only be configured in this situation
 715     # if the --with-newlib option has been given, because otherwise
 716     # 'target-newlib' will appear in skipdirs.
 717     ;;
 718   i[[3456789]]86-*-rdos*)
 719     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 720     ;;
 721   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 722     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 723     ;;
 724   sparc-*-sunos4*)
 725     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 726     ;;
 727   *-*-aix*)
 728     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 729     ;;
 730   *-*-beos*)
 731     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 732     ;;
 733   *-*-chorusos)
 734     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 735     ;;
 736   *-*-dragonfly*)
 737     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 738     ;;
 739   *-*-freebsd*)
 740     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 741     ;;
 742   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 743     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 744     ;;
 745   *-*-lynxos*)
 746     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 747     ;;
 748   *-*-mingw*)
 749     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 750     ;;
 751   *-*-netbsd*)
 752     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 753     ;;
 754   *-*-netware*)
 755     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 756     ;;
 757   *-*-tpf*)
 758     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 759     ;;
 760   *-*-uclinux*)
 761     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 762     ;;
 763   *-*-vxworks*)
 764     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 765     ;;
 766 esac
 767
 768 case "${target}" in
 769   *-*-chorusos)
 770     ;;
 771   powerpc-*-darwin*)
 772     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 773     noconfigdirs="$noconfigdirs sim target-rda"
 774     ;;
 775   i[[3456789]]86-*-darwin*)
 776     noconfigdirs="$noconfigdirs ld gprof"
 777     noconfigdirs="$noconfigdirs sim target-rda"
 778     ;;
 779   x86_64-*-darwin[[912]]*)
 780     noconfigdirs="$noconfigdirs ld gas gprof"
 781     noconfigdirs="$noconfigdirs sim target-rda"
 782     ;;
 783   *-*-darwin*)
 784     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 785     noconfigdirs="$noconfigdirs sim target-rda"
 786     ;;
 787   *-*-dragonfly*)
 788     ;;
 789   *-*-freebsd*)
 790     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 791         && test -f /usr/local/include/gmp.h; then
 792       with_gmp=/usr/local
 793     fi
 794     ;;
 795   *-*-kaos*)
 796     # Remove unsupported stuff on all kaOS configurations.
 797     noconfigdirs="$noconfigdirs target-libgloss"
 798     ;;
 799   *-*-netbsd*)
 800     ;;
 801   *-*-netware*)
 802     ;;
 803   *-*-rtems*)
 804     noconfigdirs="$noconfigdirs target-libgloss"
 805     ;;
 806     # The tpf target doesn't support gdb yet.
 807   *-*-tpf*)
 808     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 809     ;;
 810   *-*-uclinux*)
 811     noconfigdirs="$noconfigdirs target-rda"
 812     ;;
 813   *-*-vxworks*)
 814     ;;
 815   alpha*-dec-osf*)
 816     # ld works, but does not support shared libraries.
 817     # gas doesn't generate exception information.
 818     noconfigdirs="$noconfigdirs gas ld"
 819     ;;
 820   alpha*-*-*vms*)
 821     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 822     ;;
 823   alpha*-*-*)
 824     # newlib is not 64 bit ready
 825     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 826     ;;
 827   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 828     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 829     ;;
 830   arc-*-*)
 831     noconfigdirs="$noconfigdirs target-libgloss"
 832     ;;
 833   arm-*-pe*)
 834     noconfigdirs="$noconfigdirs target-libgloss"
 835     ;;
 836   arm-*-riscix*)
 837     noconfigdirs="$noconfigdirs ld target-libgloss"
 838     ;;
 839   c4x-*-* | tic4x-*-*)
 840     noconfigdirs="$noconfigdirs target-libgloss"
 841     ;;
 842   tic54x-*-*)
 843     noconfigdirs="$noconfigdirs target-libgloss gdb"
 844     ;;
 845   cr16-*-*)
 846     noconfigdirs="$noconfigdirs gdb"
 847     ;;
 848   d10v-*-*)
 849     noconfigdirs="$noconfigdirs target-libgloss"
 850     ;;
 851   d30v-*-*)
 852     noconfigdirs="$noconfigdirs gdb"
 853     ;;
 854   fr30-*-elf*)
 855     noconfigdirs="$noconfigdirs gdb"
 856     ;;
 857   moxie-*-*)
 858     noconfigdirs="$noconfigdirs gprof"
 859     ;;
 860   h8300*-*-*)
 861     noconfigdirs="$noconfigdirs target-libgloss"
 862     ;;
 863   h8500-*-*)
 864     noconfigdirs="$noconfigdirs target-libgloss"
 865     ;;
 866   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 867     ;;
 868   hppa*64*-*-linux*)
 869     ;;
 870   hppa*-*-linux*)
 871     ;;
 872   hppa*-*-*elf* | \
 873   hppa*-*-lites* | \
 874   hppa*-*-openbsd* | \
 875   hppa*64*-*-*)
 876     ;;
 877   hppa*-hp-hpux11*)
 878     noconfigdirs="$noconfigdirs ld"
 879     ;;
 880   hppa*-*-pro*)
 881     ;;
 882   hppa*-*-*)
 883     noconfigdirs="$noconfigdirs ld"
 884     ;;
 885   i960-*-*)
 886     noconfigdirs="$noconfigdirs gdb"
 887     ;;
 888   ia64*-*-elf*)
 889     # No gdb support yet.
 890     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 891     ;;
 892   ia64*-**-hpux*)
 893     # No ld support yet.
 894     noconfigdirs="$noconfigdirs libgui itcl ld"
 895     ;;
 896   ia64*-*-*vms*)
 897     # No gdb or ld support yet.
 898     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 899     ;;
 900   i[[3456789]]86-w64-mingw*)
 901     ;;
 902   i[[3456789]]86-*-mingw*)
 903     target_configdirs="$target_configdirs target-winsup"
 904     ;;
 905   *-*-cygwin*)
 906     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 907     noconfigdirs="$noconfigdirs target-libgloss"
 908     # always build newlib if winsup directory is present.
 909     if test -d "$srcdir/winsup/cygwin"; then
 910       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 911     elif test -d "$srcdir/newlib"; then
 912       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 913     fi
 914     ;;
 915   i[[3456789]]86-*-pe)
 916     noconfigdirs="$noconfigdirs target-libgloss"
 917     ;;
 918   i[[3456789]]86-*-sco3.2v5*)
 919     # The linker does not yet know about weak symbols in COFF,
 920     # and is not configured to handle mixed ELF and COFF.
 921     noconfigdirs="$noconfigdirs ld target-libgloss"
 922     ;;
 923   i[[3456789]]86-*-sco*)
 924     noconfigdirs="$noconfigdirs gprof target-libgloss"
 925     ;;
 926   i[[3456789]]86-*-solaris2*)
 927     noconfigdirs="$noconfigdirs target-libgloss"
 928     ;;
 929   i[[3456789]]86-*-sysv4*)
 930     noconfigdirs="$noconfigdirs target-libgloss"
 931     ;;
 932   i[[3456789]]86-*-beos*)
 933     noconfigdirs="$noconfigdirs gdb"
 934     ;;
 935   i[[3456789]]86-*-rdos*)
 936     noconfigdirs="$noconfigdirs gdb"
 937     ;;
 938   mmix-*-*)
 939     noconfigdirs="$noconfigdirs gdb"
 940     ;;
 941   mt-*-*)
 942     noconfigdirs="$noconfigdirs sim"
 943     ;;
 944   powerpc-*-aix*)
 945     # copied from rs6000-*-* entry
 946     noconfigdirs="$noconfigdirs gprof"
 947     ;;
 948   powerpc*-*-winnt* | powerpc*-*-pe*)
 949     target_configdirs="$target_configdirs target-winsup"
 950     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 951     # always build newlib.
 952     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 953     ;;
 954     # This is temporary until we can link against shared libraries
 955   powerpcle-*-solaris*)
 956     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 957     ;;
 958   powerpc-*-beos*)
 959     noconfigdirs="$noconfigdirs gdb"
 960     ;;
 961   rs6000-*-lynxos*)
 962     noconfigdirs="$noconfigdirs gprof"
 963     ;;
 964   rs6000-*-aix*)
 965     noconfigdirs="$noconfigdirs gprof"
 966     ;;
 967   rs6000-*-*)
 968     noconfigdirs="$noconfigdirs gprof"
 969     ;;
 970   m68k-apollo-*)
 971     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
 972     ;;
 973   microblaze*)
 974     noconfigdirs="$noconfigdirs gprof"
 975     ;;
 976   mips*-sde-elf*)
 977     if test x$with_newlib = xyes; then
 978       noconfigdirs="$noconfigdirs gprof"
 979     fi
 980     ;;
 981   mips*-*-irix5*)
 982     noconfigdirs="$noconfigdirs gprof target-libgloss"
 983     ;;
 984   mips*-*-irix6*)
 985     noconfigdirs="$noconfigdirs gprof target-libgloss"
 986     ;;
 987   mips*-*-bsd*)
 988     noconfigdirs="$noconfigdirs gprof target-libgloss"
 989     ;;
 990   mips*-*-linux*)
 991     ;;
 992   mips*-*-*)
 993     noconfigdirs="$noconfigdirs gprof"
 994     ;;
 995   sh-*-* | sh64-*-*)
 996     case "${target}" in
 997       sh*-*-elf)
 998          ;;
 999       *)
1000          noconfigdirs="$noconfigdirs target-libgloss" ;;
1001     esac
1002     ;;
1003   sparc-*-sunos4*)
1004     if test x${is_cross_compiler} = xno ; then
1005            use_gnu_ld=no
1006     fi
1007     ;;
1008   tic6x-*-*)
1009     noconfigdirs="$noconfigdirs gdb sim"
1010     ;;
1011   tilepro-*-* | tilegx-*-*)
1012     noconfigdirs="$noconfigdirs sim"
1013     ;;
1014   v810-*-*)
1015     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1016     ;;
1017   vax-*-*)
1018     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1019     ;;
1020 esac
1021
1022 # If we aren't building newlib, then don't build libgloss, since libgloss
1023 # depends upon some newlib header files.
1024 case "${noconfigdirs}" in
1025   *target-libgloss*) ;;
1026   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1027 esac
1028
1029 # Work in distributions that contain no compiler tools, like Autoconf.
1030 host_makefile_frag=/dev/null
1031 if test -d ${srcdir}/config ; then
1032 case "${host}" in
1033   i[[3456789]]86-*-msdosdjgpp*)
1034     host_makefile_frag="config/mh-djgpp"
1035     ;;
1036   *-cygwin*)
1037     ACX_CHECK_CYGWIN_CAT_WORKS
1038     host_makefile_frag="config/mh-cygwin"
1039     ;;
1040   *-mingw*)
1041     host_makefile_frag="config/mh-mingw"
1042     ;;
1043   *-interix*)
1044     host_makefile_frag="config/mh-interix"
1045     ;;
1046   hppa*-hp-hpux10*)
1047     host_makefile_frag="config/mh-pa-hpux10"
1048     ;;
1049   hppa*-hp-hpux*)
1050     host_makefile_frag="config/mh-pa"
1051     ;;
1052   hppa*-*)
1053     host_makefile_frag="config/mh-pa"
1054     ;;
1055   *-*-darwin*)
1056     host_makefile_frag="config/mh-darwin"
1057     ;;
1058   powerpc-*-aix*)
1059     host_makefile_frag="config/mh-ppc-aix"
1060     ;;
1061   rs6000-*-aix*)
1062     host_makefile_frag="config/mh-ppc-aix"
1063     ;;
1064 esac
1065 fi
1066
1067 if test "${build}" != "${host}" ; then
1068   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1069   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1070   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1071   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1072   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1073   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1074   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1075   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1076   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1077   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1078   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1079   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1080   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1081 else
1082   AR_FOR_BUILD="\$(AR)"
1083   AS_FOR_BUILD="\$(AS)"
1084   CC_FOR_BUILD="\$(CC)"
1085   CXX_FOR_BUILD="\$(CXX)"
1086   GCJ_FOR_BUILD="\$(GCJ)"
1087   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1088   GOC_FOR_BUILD="\$(GOC)"
1089   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1090   LD_FOR_BUILD="\$(LD)"
1091   NM_FOR_BUILD="\$(NM)"
1092   RANLIB_FOR_BUILD="\$(RANLIB)"
1093   WINDRES_FOR_BUILD="\$(WINDRES)"
1094   WINDMC_FOR_BUILD="\$(WINDMC)"
1095 fi
1096
1097 AC_PROG_CC
1098 AC_PROG_CXX
1099
1100 # We must set the default linker to the linker used by gcc for the correct
1101 # operation of libtool.  If LD is not defined and we are using gcc, try to
1102 # set the LD default to the ld used by gcc.
1103 if test -z "$LD"; then
1104   if test "$GCC" = yes; then
1105     case $build in
1106     *-*-mingw*)
1107       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1108     *)
1109       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1110     esac
1111     case $gcc_prog_ld in
1112     # Accept absolute paths.
1113     [[\\/]* | [A-Za-z]:[\\/]*)]
1114       LD="$gcc_prog_ld" ;;
1115     esac
1116   fi
1117 fi
1118
1119 ACX_PROG_GNAT
1120 ACX_PROG_CMP_IGNORE_INITIAL
1121
1122 # See if we are building gcc with C++.
1123 AC_ARG_ENABLE(build-with-cxx,
1124 [AS_HELP_STRING([--enable-build-with-cxx],
1125                 [build with C++ compiler instead of C compiler])],
1126 ENABLE_BUILD_WITH_CXX=$enableval,
1127 ENABLE_BUILD_WITH_CXX=no)
1128
1129 # Used for setting $lt_cv_objdir
1130 _LT_CHECK_OBJDIR
1131
1132 # Check for GMP, MPFR and MPC
1133 gmplibs="-lmpc -lmpfr -lgmp"
1134 gmpinc=
1135 have_gmp=no
1136
1137 # Specify a location for mpc
1138 # check for this first so it ends up on the link line before mpfr.
1139 AC_ARG_WITH(mpc,
1140 [AS_HELP_STRING([--with-mpc=PATH],
1141                 [specify prefix directory for installed MPC package.
1142                  Equivalent to --with-mpc-include=PATH/include
1143                  plus --with-mpc-lib=PATH/lib])])
1144 AC_ARG_WITH(mpc-include,
1145 [AS_HELP_STRING([--with-mpc-include=PATH],
1146                 [specify directory for installed MPC include files])])
1147 AC_ARG_WITH(mpc-lib,
1148 [AS_HELP_STRING([--with-mpc-lib=PATH],
1149                 [specify directory for the installed MPC library])])
1150
1151 if test "x$with_mpc" != x; then
1152   gmplibs="-L$with_mpc/lib $gmplibs"
1153   gmpinc="-I$with_mpc/include $gmpinc"
1154 fi
1155 if test "x$with_mpc_include" != x; then
1156   gmpinc="-I$with_mpc_include $gmpinc"
1157 fi
1158 if test "x$with_mpc_lib" != x; then
1159   gmplibs="-L$with_mpc_lib $gmplibs"
1160 fi
1161 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1162   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1163   gmpinc='-I$$s/mpc/src '"$gmpinc"
1164   # Do not test the mpc version.  Assume that it is sufficient, since
1165   # it is in the source tree, and the library has not been built yet
1166   # but it would be included on the link line in the version check below
1167   # hence making the test fail.
1168   have_gmp=yes
1169 fi
1170
1171 # Specify a location for mpfr
1172 # check for this first so it ends up on the link line before gmp.
1173 AC_ARG_WITH(mpfr-dir,
1174 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1175 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1176 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1177
1178 AC_ARG_WITH(mpfr,
1179 [AS_HELP_STRING([--with-mpfr=PATH],
1180                 [specify prefix directory for installed MPFR package.
1181                  Equivalent to --with-mpfr-include=PATH/include
1182                  plus --with-mpfr-lib=PATH/lib])])
1183 AC_ARG_WITH(mpfr-include,
1184 [AS_HELP_STRING([--with-mpfr-include=PATH],
1185                 [specify directory for installed MPFR include files])])
1186 AC_ARG_WITH(mpfr-lib,
1187 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1188                 [specify directory for the installed MPFR library])])
1189
1190 if test "x$with_mpfr" != x; then
1191   gmplibs="-L$with_mpfr/lib $gmplibs"
1192   gmpinc="-I$with_mpfr/include $gmpinc"
1193 fi
1194 if test "x$with_mpfr_include" != x; then
1195   gmpinc="-I$with_mpfr_include $gmpinc"
1196 fi
1197 if test "x$with_mpfr_lib" != x; then
1198   gmplibs="-L$with_mpfr_lib $gmplibs"
1199 fi
1200 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1201   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1202   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1203   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1204   # Do not test the mpfr version.  Assume that it is sufficient, since
1205   # it is in the source tree, and the library has not been built yet
1206   # but it would be included on the link line in the version check below
1207   # hence making the test fail.
1208   have_gmp=yes
1209 fi
1210
1211 # Specify a location for gmp
1212 AC_ARG_WITH(gmp-dir,
1213 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1214 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1215 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1216
1217 AC_ARG_WITH(gmp,
1218 [AS_HELP_STRING([--with-gmp=PATH],
1219                 [specify prefix directory for the installed GMP package.
1220                  Equivalent to --with-gmp-include=PATH/include
1221                  plus --with-gmp-lib=PATH/lib])])
1222 AC_ARG_WITH(gmp-include,
1223 [AS_HELP_STRING([--with-gmp-include=PATH],
1224                 [specify directory for installed GMP include files])])
1225 AC_ARG_WITH(gmp-lib,
1226 [AS_HELP_STRING([--with-gmp-lib=PATH],
1227                 [specify directory for the installed GMP library])])
1228
1229
1230 if test "x$with_gmp" != x; then
1231   gmplibs="-L$with_gmp/lib $gmplibs"
1232   gmpinc="-I$with_gmp/include $gmpinc"
1233 fi
1234 if test "x$with_gmp_include" != x; then
1235   gmpinc="-I$with_gmp_include $gmpinc"
1236 fi
1237 if test "x$with_gmp_lib" != x; then
1238   gmplibs="-L$with_gmp_lib $gmplibs"
1239 fi
1240 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1241   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1242   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1243   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1244   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1245   # Do not test the gmp version.  Assume that it is sufficient, since
1246   # it is in the source tree, and the library has not been built yet
1247   # but it would be included on the link line in the version check below
1248   # hence making the test fail.
1249   have_gmp=yes
1250 fi
1251
1252 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1253   have_gmp=yes
1254   saved_CFLAGS="$CFLAGS"
1255   CFLAGS="$CFLAGS $gmpinc"
1256   # Check for the recommended and required versions of GMP.
1257   AC_MSG_CHECKING([for the correct version of gmp.h])
1258   AC_TRY_COMPILE([#include "gmp.h"],[
1259   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1260   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1261   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1262   choke me
1263   #endif
1264   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1265   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1266   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1267   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1268   choke me
1269   #endif
1270   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1271    [AC_MSG_RESULT([no]); have_gmp=no])
1272
1273   # If we have GMP, check the MPFR version.
1274   if test x"$have_gmp" = xyes; then
1275     # Check for the recommended and required versions of MPFR.
1276     AC_MSG_CHECKING([for the correct version of mpfr.h])
1277     AC_TRY_COMPILE([#include <gmp.h>
1278     #include <mpfr.h>],[
1279     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1280     choke me
1281     #endif
1282     ], [AC_TRY_COMPILE([#include <gmp.h>
1283     #include <mpfr.h>],[
1284     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1285     choke me
1286     #endif
1287     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1288      [AC_MSG_RESULT([no]); have_gmp=no])
1289   fi
1290
1291   # Check for the MPC header version.
1292   if test x"$have_gmp" = xyes ; then
1293     # Check for the recommended and required versions of MPC.
1294     AC_MSG_CHECKING([for the correct version of mpc.h])
1295     AC_TRY_COMPILE([#include <mpc.h>],[
1296     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1297     choke me
1298     #endif
1299     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1300     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1301     choke me
1302     #endif
1303     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1304      [AC_MSG_RESULT([no]); have_gmp=no])
1305   fi
1306
1307   # Now check the MPFR library.
1308   if test x"$have_gmp" = xyes; then
1309     saved_LIBS="$LIBS"
1310     LIBS="$LIBS $gmplibs"
1311     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1312     AC_TRY_LINK([#include <mpc.h>],[
1313     mpfr_t n;
1314     mpfr_t x;
1315     mpc_t c;
1316     int t;
1317     mpfr_init (n);
1318     mpfr_init (x);
1319     mpfr_atan2 (n, n, x, GMP_RNDN);
1320     mpfr_erfc (n, x, GMP_RNDN);
1321     mpfr_subnormalize (x, t, GMP_RNDN);
1322     mpfr_clear(n);
1323     mpfr_clear(x);
1324     mpc_init2 (c, 53);
1325     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1326     mpc_cosh (c, c, MPC_RNDNN);
1327     mpc_pow (c, c, c, MPC_RNDNN);
1328     mpc_acosh (c, c, MPC_RNDNN);
1329     mpc_clear (c);
1330     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1331     LIBS="$saved_LIBS"
1332   fi
1333
1334   CFLAGS="$saved_CFLAGS"
1335
1336 # The library versions listed in the error message below should match
1337 # the HARD-minimums enforced above.
1338   if test x$have_gmp != xyes; then
1339     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1340 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1341 their locations.  Source code for these libraries can be found at
1342 their respective hosting sites as well as at
1343 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1344 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1345 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1346 make sure that you have installed both the libraries and the header
1347 files.  They may be located in separate packages.])
1348   fi
1349 fi
1350
1351 # Flags needed for both GMP, MPFR and/or MPC.
1352 AC_SUBST(gmplibs)
1353 AC_SUBST(gmpinc)
1354 AC_SUBST(extra_mpfr_configure_flags)
1355 AC_SUBST(extra_mpc_gmp_configure_flags)
1356 AC_SUBST(extra_mpc_mpfr_configure_flags)
1357
1358 # Allow host libstdc++ to be specified for static linking with PPL.
1359 AC_ARG_WITH(host-libstdcxx,
1360 [AS_HELP_STRING([--with-host-libstdcxx=L],
1361                 [use linker arguments L to link with libstdc++
1362                  when linking with PPL])])
1363
1364 case $with_host_libstdcxx in
1365   no|yes)
1366     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1367     ;;
1368 esac
1369
1370 # Linker flags to use for stage1 or when not boostrapping.
1371 AC_ARG_WITH(stage1-ldflags,
1372 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1373 [if test "$withval" = "no" -o "$withval" = "yes"; then
1374    stage1_ldflags=
1375  else
1376    stage1_ldflags=$withval
1377  fi],
1378 [stage1_ldflags=])
1379 AC_SUBST(stage1_ldflags)
1380
1381 # Libraries to use for stage1 or when not bootstrapping.
1382 AC_ARG_WITH(stage1-libs,
1383 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1384 [if test "$withval" = "no" -o "$withval" = "yes"; then
1385    stage1_libs=
1386  else
1387    stage1_libs=$withval
1388  fi],
1389 [stage1_libs=$with_host_libstdcxx])
1390 AC_SUBST(stage1_libs)
1391
1392 # Libraries to use for stage2 and later builds.  This defaults to the
1393 # argument passed to --with-host-libstdcxx.
1394 AC_ARG_WITH(boot-libs,
1395 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1396 [if test "$withval" = "no" -o "$withval" = "yes"; then
1397    poststage1_libs=
1398  else
1399    poststage1_libs=$withval
1400  fi],
1401 [poststage1_libs=$with_host_libstdcxx])
1402 AC_SUBST(poststage1_libs)
1403
1404 # Linker flags to use for stage2 and later builds.
1405 AC_ARG_WITH(boot-ldflags,
1406 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1407                 [linker flags for stage2 and later])],
1408 [if test "$withval" = "no" -o "$withval" = "yes"; then
1409    poststage1_ldflags=
1410  else
1411    poststage1_ldflags=$withval
1412  fi],
1413 [poststage1_ldflags=
1414  # In stages 2 and 3, default to linking libstdc++ and libgcc
1415  # statically.  But if the user explicitly specified the libraries to
1416  # use, trust that they are doing what they want.
1417  if test "$poststage1_libs" = ""; then
1418    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1419  fi])
1420 AC_SUBST(poststage1_ldflags)
1421
1422 # Check for PPL
1423 ppllibs=
1424 pplinc=
1425 pwllib=
1426
1427 AC_ARG_WITH(ppl,
1428 [AS_HELP_STRING([--with-ppl=PATH],
1429                 [specify prefix directory for the installed PPL package.
1430                  Equivalent to --with-ppl-include=PATH/include
1431                  plus --with-ppl-lib=PATH/lib])])
1432 AC_ARG_WITH(ppl-include,
1433 [AS_HELP_STRING([--with-ppl-include=PATH],
1434                 [specify directory for installed PPL include files])])
1435 AC_ARG_WITH(ppl-lib,
1436 [AS_HELP_STRING([--with-ppl-lib=PATH],
1437                 [specify directory for the installed PPL library])])
1438
1439 AC_ARG_ENABLE(ppl-version-check,
1440 [AS_HELP_STRING([--disable-ppl-version-check],
1441                 [disable check for PPL version])])
1442
1443 case $with_ppl in
1444   yes | no | "")
1445     ;;
1446   *)
1447     ppllibs="-L$with_ppl/lib"
1448     pplinc="-I$with_ppl/include $pplinc"
1449     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1450       with_ppl=yes
1451     else
1452       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1453     fi
1454     ;;
1455 esac
1456
1457 if test x"$with_ppl_include" != x; then
1458   pplinc="-I$with_ppl_include $pplinc"
1459   with_ppl=yes
1460 fi
1461
1462 if test "x$with_ppl_lib" != x; then
1463   ppllibs="-L$with_ppl_lib"
1464   with_ppl=yes
1465 fi
1466
1467 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1468   if test x"$enable_watchdog" = xyes; then
1469     pwllib="-lpwl"
1470   fi
1471   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1472   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1473   enable_ppl_version_check=no
1474   with_ppl=yes
1475 fi
1476
1477 if test "x$with_ppl" != xno; then
1478   if test "x$pwllib" = x; then
1479     saved_LIBS="$LIBS"
1480     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1481     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1482     LIBS="$saved_LIBS"
1483   fi
1484
1485   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1486
1487   if test "$enable_ppl_version_check" != no; then
1488     saved_CFLAGS="$CFLAGS"
1489     CFLAGS="$CFLAGS $pplinc $gmpinc"
1490     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1491     AC_TRY_COMPILE([#include "ppl_c.h"],[
1492     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1493     choke me
1494     #endif
1495     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1496     CFLAGS="$saved_CFLAGS"
1497   fi
1498 fi
1499
1500 # Flags needed for PPL
1501 AC_SUBST(ppllibs)
1502 AC_SUBST(pplinc)
1503
1504
1505 # Check for CLOOG
1506
1507 dnl Provide configure switches and initialize clooginc & clooglibs
1508 dnl with user input.
1509 CLOOG_INIT_FLAGS
1510 if test "x$with_ppl" = "xno"; then
1511   dnl Only execute fail-action, if CLooG has been requested.
1512   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1513   if test "${graphite_requested}" = yes; then
1514     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1515   fi
1516   with_cloog=no
1517 fi
1518 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1519   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1520   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1521   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1522 fi
1523 if test "x$with_cloog" != "xno"; then
1524   dnl The minimal version of CLooG required for Graphite.
1525   dnl
1526   dnl If we use CLooG-Legacy, the provided version information is
1527   dnl ignored.
1528   CLOOG_CHECK_VERSION(0,16,1)
1529
1530   dnl Only execute fail-action, if CLooG has been requested.
1531   CLOOG_IF_FAILED([
1532     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1533 fi
1534
1535 # Check for LTO support.
1536 AC_ARG_ENABLE(lto,
1537 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1538 enable_lto=$enableval,
1539 enable_lto=yes; default_enable_lto=yes)
1540
1541 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1542   build_lto_plugin=yes
1543 ],[if test x"$default_enable_lto" = x"yes" ; then
1544     case $target in
1545       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1546       # On other non-ELF platforms, LTO has yet to be validated.
1547       *) enable_lto=no ;;
1548     esac
1549   else
1550   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1551   # It would also be nice to check the binutils support, but we don't
1552   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1553   # warn during gcc/ subconfigure; unless you're bootstrapping with
1554   # -flto it won't be needed until after installation anyway.
1555     case $target in
1556       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1557       *) if test x"$enable_lto" = x"yes"; then
1558         AC_MSG_ERROR([LTO support is not enabled for this target.])
1559         fi
1560       ;;
1561     esac
1562   fi
1563   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1564   # Build it unless LTO was explicitly disabled.
1565   case $target in
1566     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1567     *) ;;
1568   esac
1569 ])
1570
1571
1572 # By default, C is the only stage 1 language.
1573 stage1_languages=,c,
1574
1575 # Target libraries that we bootstrap.
1576 bootstrap_target_libs=,target-libgcc,
1577
1578 # Figure out what language subdirectories are present.
1579 # Look if the user specified --enable-languages="..."; if not, use
1580 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1581 # go away some day.
1582 # NB:  embedded tabs in this IF block -- do not untabify
1583 if test -d ${srcdir}/gcc; then
1584   if test x"${enable_languages+set}" != xset; then
1585     if test x"${LANGUAGES+set}" = xset; then
1586       enable_languages="${LANGUAGES}"
1587         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1588     else
1589       enable_languages=all
1590     fi
1591   else
1592     if test x"${enable_languages}" = x ||
1593        test x"${enable_languages}" = xyes;
1594        then
1595       echo configure.in: --enable-languages needs at least one language argument 1>&2
1596       exit 1
1597     fi
1598   fi
1599   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1600
1601   # 'f95' is the old name for the 'fortran' language. We issue a warning
1602   # and make the substitution.
1603   case ,${enable_languages}, in
1604     *,f95,*)
1605       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1606       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1607       ;;
1608   esac
1609
1610   # First scan to see if an enabled language requires some other language.
1611   # We assume that a given config-lang.in will list all the language
1612   # front ends it requires, even if some are required indirectly.
1613   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1614     case ${lang_frag} in
1615       ..) ;;
1616       # The odd quoting in the next line works around
1617       # an apparent bug in bash 1.12 on linux.
1618       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1619       *)
1620         # From the config-lang.in, get $language, $lang_requires, and
1621         # $lang_requires_boot_languages.
1622         language=
1623         lang_requires=
1624         lang_requires_boot_languages=
1625         . ${lang_frag}
1626         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1627           case ,${enable_languages}, in
1628             *,$other,*) ;;
1629             *,all,*) ;;
1630             *,$language,*)
1631               echo " \`$other' language required by \`$language'; enabling" 1>&2
1632               enable_languages="${enable_languages},${other}"
1633               ;;
1634           esac
1635         done
1636         for other in ${lang_requires_boot_languages} ; do
1637           if test "$other" != "c"; then
1638             case ,${enable_stage1_languages}, in
1639               *,$other,*) ;;
1640               *,all,*) ;;
1641               *)
1642                 case ,${enable_languages}, in
1643                   *,$language,*)
1644                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1645                     enable_stage1_languages="$enable_stage1_languages,${other}"
1646                     ;;
1647                 esac
1648                 ;;
1649             esac
1650           fi
1651         done
1652         ;;
1653     esac
1654   done
1655
1656   new_enable_languages=,c,
1657
1658   # If LTO is enabled, add the LTO front end.
1659   extra_host_libiberty_configure_flags=
1660   if test "$enable_lto" = "yes" ; then
1661     case ,${enable_languages}, in
1662       *,lto,*) ;;
1663       *) enable_languages="${enable_languages},lto" ;;
1664     esac
1665     if test "${build_lto_plugin}" = "yes" ; then
1666       configdirs="$configdirs lto-plugin"
1667       extra_host_libiberty_configure_flags=--enable-shared
1668     fi
1669   fi
1670   AC_SUBST(extra_host_libiberty_configure_flags)
1671
1672   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1673   potential_languages=,c,
1674
1675   enabled_target_libs=
1676   disabled_target_libs=
1677
1678   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1679     case ${lang_frag} in
1680       ..) ;;
1681       # The odd quoting in the next line works around
1682       # an apparent bug in bash 1.12 on linux.
1683       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1684       *)
1685         # From the config-lang.in, get $language, $target_libs,
1686         # $lang_dirs, $boot_language, and $build_by_default
1687         language=
1688         target_libs=
1689         lang_dirs=
1690         subdir_requires=
1691         boot_language=no
1692         build_by_default=yes
1693         . ${lang_frag}
1694         if test x${language} = x; then
1695           echo "${lang_frag} doesn't set \$language." 1>&2
1696           exit 1
1697         fi
1698
1699         if test "$language" = "c++" \
1700            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1701           boot_language=yes
1702         fi
1703
1704         case ,${enable_languages}, in
1705           *,${language},*)
1706             # Language was explicitly selected; include it.
1707             add_this_lang=yes
1708             ;;
1709           *,all,*)
1710             # 'all' was selected, select it if it is a default language
1711             add_this_lang=${build_by_default}
1712             ;;
1713           *)
1714             add_this_lang=no
1715             ;;
1716         esac
1717
1718         # Disable languages that need other directories if these aren't available.
1719         for i in $subdir_requires; do
1720           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1721           case ,${enable_languages}, in
1722             *,${language},*)
1723               # Specifically requested language; tell them.
1724               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1725               ;;
1726             *)
1727               # Silently disable.
1728               add_this_lang=unsupported
1729               ;;
1730           esac
1731         done
1732
1733         # Disable Ada if no preexisting GNAT is available.
1734         case ,${enable_languages},:${language}:${have_gnat} in
1735           *,${language},*:ada:no)
1736             # Specifically requested language; tell them.
1737             AC_MSG_ERROR([GNAT is required to build $language])
1738             ;;
1739           *:ada:no)
1740             # Silently disable.
1741             add_this_lang=unsupported
1742             ;;
1743         esac
1744
1745         # Disable a language that is unsupported by the target.
1746         case " $unsupported_languages " in
1747           *" $language "*)
1748             add_this_lang=unsupported
1749             ;;
1750         esac
1751
1752         case $add_this_lang in
1753           unsupported)
1754             # Remove language-dependent dirs.
1755             disabled_target_libs="$disabled_target_libs $target_libs"
1756             noconfigdirs="$noconfigdirs $lang_dirs"
1757             ;;
1758           no)
1759             # Remove language-dependent dirs; still show language as supported.
1760             disabled_target_libs="$disabled_target_libs $target_libs"
1761             noconfigdirs="$noconfigdirs $lang_dirs"
1762             potential_languages="${potential_languages}${language},"
1763             ;;
1764           yes)
1765             new_enable_languages="${new_enable_languages}${language},"
1766             potential_languages="${potential_languages}${language},"
1767             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1768             enabled_target_libs="$enabled_target_libs $target_libs"
1769             case "${boot_language}:,$enable_stage1_languages," in
1770               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1771                 # Add to (comma-separated) list of stage 1 languages.
1772                 case ",$stage1_languages," in
1773                   *,$language,* | ,yes, | ,all,) ;;
1774                   *) stage1_languages="${stage1_languages}${language}," ;;
1775                 esac
1776                 # We need to bootstrap any supporting libraries.
1777                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1778                 ;;
1779             esac
1780             ;;
1781         esac
1782         ;;
1783     esac
1784   done
1785
1786   # Add target libraries which are only needed for disabled languages
1787   # to noconfigdirs.
1788   if test -n "$disabled_target_libs"; then
1789     for dir in $disabled_target_libs; do
1790       case " $enabled_target_libs " in
1791       *" ${dir} "*) ;;
1792       *) noconfigdirs="$noconfigdirs $dir" ;;
1793       esac
1794     done
1795   fi
1796
1797   AC_ARG_ENABLE(stage1-languages,
1798   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1799                   [choose additional languages to build during
1800                   stage1.  Mostly useful for compiler development])],
1801   [case ,${enable_stage1_languages}, in
1802     ,no,|,,)
1803       # Set it to something that will have no effect in the loop below
1804       enable_stage1_languages=c ;;
1805     ,yes,)
1806       enable_stage1_languages=`echo $new_enable_languages | \
1807         sed -e "s/^,//" -e "s/,$//" ` ;;
1808     *,all,*)
1809       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1810         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1811   esac
1812
1813   # Add "good" languages from enable_stage1_languages to stage1_languages,
1814   # while "bad" languages go in missing_languages.  Leave no duplicates.
1815   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1816     case $potential_languages in
1817       *,$i,*)
1818         case $stage1_languages in
1819           *,$i,*) ;;
1820           *) stage1_languages="$stage1_languages$i," ;;
1821         esac ;;
1822       *)
1823         case $missing_languages in
1824           *,$i,*) ;;
1825           *) missing_languages="$missing_languages$i," ;;
1826         esac ;;
1827      esac
1828   done])
1829
1830   # Remove leading/trailing commas that were added for simplicity
1831   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1832   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1833   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1834   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1835
1836   if test "x$missing_languages" != x; then
1837     AC_MSG_ERROR([
1838 The following requested languages could not be built: ${missing_languages}
1839 Supported languages are: ${potential_languages}])
1840   fi
1841   if test "x$new_enable_languages" != "x$enable_languages"; then
1842     echo The following languages will be built: ${new_enable_languages}
1843     enable_languages="$new_enable_languages"
1844   fi
1845
1846   AC_SUBST(stage1_languages)
1847   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1848 fi
1849
1850 # Handle --disable-<component> generically.
1851 for dir in $configdirs $build_configdirs $target_configdirs ; do
1852   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1853   varname=`echo $dirname | sed -e s/+/_/g`
1854   if eval test x\${enable_${varname}} "=" xno ; then
1855     noconfigdirs="$noconfigdirs $dir"
1856   fi
1857 done
1858
1859 # Check for Boehm's garbage collector
1860 AC_ARG_ENABLE(objc-gc,
1861 [AS_HELP_STRING([--enable-objc-gc],
1862                 [enable use of Boehm's garbage collector with the
1863                  GNU Objective-C runtime])],
1864 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1865   *,objc,*:*:yes:*target-boehm-gc*)
1866     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1867     ;;
1868 esac])
1869
1870 # Make sure we only build Boehm's garbage collector if required.
1871 case ,${enable_languages},:${enable_objc_gc} in
1872   *,objc,*:yes)
1873     # Keep target-boehm-gc if requested for Objective-C.
1874     ;;
1875   *)
1876     # Otherwise remove target-boehm-gc depending on target-libjava.
1877     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1878       noconfigdirs="$noconfigdirs target-boehm-gc"
1879     fi
1880     ;;
1881 esac
1882
1883 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1884 # $build_configdirs and $target_configdirs.
1885 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1886
1887 notsupp=""
1888 for dir in . $skipdirs $noconfigdirs ; do
1889   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1890   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1891     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1892     if test -r $srcdir/$dirname/configure ; then
1893       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1894         true
1895       else
1896         notsupp="$notsupp $dir"
1897       fi
1898     fi
1899   fi
1900   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1901     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1902     if test -r $srcdir/$dirname/configure ; then
1903       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1904         true
1905       else
1906         notsupp="$notsupp $dir"
1907       fi
1908     fi
1909   fi
1910   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1911     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1912     if test -r $srcdir/$dirname/configure ; then
1913       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1914         true
1915       else
1916         notsupp="$notsupp $dir"
1917       fi
1918     fi
1919   fi
1920 done
1921
1922 # Quietly strip out all directories which aren't configurable in this tree.
1923 # This relies on all configurable subdirectories being autoconfiscated, which
1924 # is now the case.
1925 build_configdirs_all="$build_configdirs"
1926 build_configdirs=
1927 for i in ${build_configdirs_all} ; do
1928   j=`echo $i | sed -e s/build-//g`
1929   if test -f ${srcdir}/$j/configure ; then
1930     build_configdirs="${build_configdirs} $i"
1931   fi
1932 done
1933
1934 configdirs_all="$configdirs"
1935 configdirs=
1936 for i in ${configdirs_all} ; do
1937   if test -f ${srcdir}/$i/configure ; then
1938     configdirs="${configdirs} $i"
1939   fi
1940 done
1941
1942 target_configdirs_all="$target_configdirs"
1943 target_configdirs=
1944 for i in ${target_configdirs_all} ; do
1945   j=`echo $i | sed -e s/target-//g`
1946   if test -f ${srcdir}/$j/configure ; then
1947     target_configdirs="${target_configdirs} $i"
1948   fi
1949 done
1950
1951 # Produce a warning message for the subdirs we can't configure.
1952 # This isn't especially interesting in the Cygnus tree, but in the individual
1953 # FSF releases, it's important to let people know when their machine isn't
1954 # supported by the one or two programs in a package.
1955
1956 if test -n "${notsupp}" && test -z "${norecursion}" ; then
1957   # If $appdirs is non-empty, at least one of those directories must still
1958   # be configured, or we error out.  (E.g., if the gas release supports a
1959   # specified target in some subdirs but not the gas subdir, we shouldn't
1960   # pretend that all is well.)
1961   if test -n "$appdirs" ; then
1962     for dir in $appdirs ; do
1963       if test -r $dir/Makefile.in ; then
1964         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1965           appdirs=""
1966           break
1967         fi
1968         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
1969           appdirs=""
1970           break
1971         fi
1972       fi
1973     done
1974     if test -n "$appdirs" ; then
1975       echo "*** This configuration is not supported by this package." 1>&2
1976       exit 1
1977     fi
1978   fi
1979   # Okay, some application will build, or we don't care to check.  Still
1980   # notify of subdirs not getting built.
1981   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
1982   echo "    ${notsupp}" 1>&2
1983   echo "    (Any other directories should still work fine.)" 1>&2
1984 fi
1985
1986 case "$host" in
1987   *msdosdjgpp*)
1988     enable_gdbtk=no ;;
1989 esac
1990
1991 # To find our prefix, in gcc_cv_tool_prefix.
1992 ACX_TOOL_DIRS
1993
1994 copy_dirs=
1995
1996 AC_ARG_WITH([build-sysroot],
1997   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
1998                   [use sysroot as the system root during the build])],
1999   [if test x"$withval" != x ; then
2000      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2001    fi],
2002   [SYSROOT_CFLAGS_FOR_TARGET=])
2003 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2004
2005 AC_ARG_WITH([debug-prefix-map],
2006   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2007                   [map A to B, C to D ... in debug information])],
2008   [if test x"$withval" != x; then
2009      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2010      for debug_map in $withval; do
2011        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2012      done
2013    fi],
2014   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2015 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2016
2017 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2018 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2019 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2020 # We want to ensure that TARGET libraries (which we know are built with
2021 # gcc) are built with "-O2 -g", so include those options when setting
2022 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2023 if test "x$CFLAGS_FOR_TARGET" = x; then
2024   CFLAGS_FOR_TARGET=$CFLAGS
2025   case " $CFLAGS " in
2026     *" -O2 "*) ;;
2027     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2028   esac
2029   case " $CFLAGS " in
2030     *" -g "* | *" -g3 "*) ;;
2031     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2032   esac
2033 fi
2034 AC_SUBST(CFLAGS_FOR_TARGET)
2035
2036 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2037   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2038   case " $CXXFLAGS " in
2039     *" -O2 "*) ;;
2040     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2041   esac
2042   case " $CXXFLAGS " in
2043     *" -g "* | *" -g3 "*) ;;
2044     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2045   esac
2046 fi
2047 AC_SUBST(CXXFLAGS_FOR_TARGET)
2048
2049 AC_SUBST(LDFLAGS_FOR_TARGET)
2050
2051 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2052 # the named directory are copied to $(tooldir)/sys-include.
2053 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2054   if test x${is_cross_compiler} = xno ; then
2055     echo 1>&2 '***' --with-headers is only supported when cross compiling
2056     exit 1
2057   fi
2058   if test x"${with_headers}" != xyes ; then
2059     x=${gcc_cv_tool_prefix}
2060     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2061   fi
2062 fi
2063
2064 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2065 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2066 # are permitted.
2067 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2068   if test x${is_cross_compiler} = xno ; then
2069     echo 1>&2 '***' --with-libs is only supported when cross compiling
2070     exit 1
2071   fi
2072   if test x"${with_libs}" != xyes ; then
2073     # Copy the libraries in reverse order, so that files in the first named
2074     # library override files in subsequent libraries.
2075     x=${gcc_cv_tool_prefix}
2076     for l in ${with_libs}; do
2077       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2078     done
2079   fi
2080 fi
2081
2082 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2083 #
2084 # This is done by determining whether or not the appropriate directory
2085 # is available, and by checking whether or not specific configurations
2086 # have requested that this magic not happen.
2087 #
2088 # The command line options always override the explicit settings in
2089 # configure.in, and the settings in configure.in override this magic.
2090 #
2091 # If the default for a toolchain is to use GNU as and ld, and you don't
2092 # want to do that, then you should use the --without-gnu-as and
2093 # --without-gnu-ld options for the configure script.  Similarly, if
2094 # the default is to use the included zlib and you don't want to do that,
2095 # you should use the --with-system-zlib option for the configure script.
2096
2097 if test x${use_gnu_as} = x &&
2098    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2099   with_gnu_as=yes
2100   extra_host_args="$extra_host_args --with-gnu-as"
2101 fi
2102
2103 if test x${use_gnu_ld} = x &&
2104    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2105   with_gnu_ld=yes
2106   extra_host_args="$extra_host_args --with-gnu-ld"
2107 fi
2108
2109 if test x${use_included_zlib} = x &&
2110    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2111   :
2112 else
2113   with_system_zlib=yes
2114   extra_host_args="$extra_host_args --with-system-zlib"
2115 fi
2116
2117 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2118 # can detect this case.
2119
2120 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2121   with_newlib=yes
2122   extra_host_args="$extra_host_args --with-newlib"
2123 fi
2124
2125 # Handle ${copy_dirs}
2126 set fnord ${copy_dirs}
2127 shift
2128 while test $# != 0 ; do
2129   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2130     :
2131   else
2132     echo Copying $1 to $2
2133
2134     # Use the install script to create the directory and all required
2135     # parent directories.
2136     if test -d $2 ; then
2137       :
2138     else
2139       echo >config.temp
2140       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2141     fi
2142
2143     # Copy the directory, assuming we have tar.
2144     # FIXME: Should we use B in the second tar?  Not all systems support it.
2145     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2146
2147     # It is the responsibility of the user to correctly adjust all
2148     # symlinks.  If somebody can figure out how to handle them correctly
2149     # here, feel free to add the code.
2150
2151     echo $1 > $2/COPIED
2152   fi
2153   shift; shift
2154 done
2155
2156 # Determine a target-dependent exec_prefix that the installed
2157 # gcc will search in.  Keep this list sorted by triplet, with
2158 # the *-*-osname triplets last.
2159 md_exec_prefix=
2160 case "${target}" in
2161   i[[34567]]86-pc-msdosdjgpp*)
2162     md_exec_prefix=/dev/env/DJDIR/bin
2163     ;;
2164   *-*-hpux* | \
2165   *-*-nto-qnx* | \
2166   *-*-solaris2*)
2167     md_exec_prefix=/usr/ccs/bin
2168     ;;
2169 esac
2170
2171 extra_arflags_for_target=
2172 extra_nmflags_for_target=
2173 extra_ranlibflags_for_target=
2174 target_makefile_frag=/dev/null
2175 case "${target}" in
2176   spu-*-*)
2177     target_makefile_frag="config/mt-spu"
2178     ;;
2179   mips*-sde-elf*)
2180     target_makefile_frag="config/mt-sde"
2181     ;;
2182   mipsisa*-*-elfoabi*)
2183     target_makefile_frag="config/mt-mips-elfoabi"
2184     ;;
2185   mips*-*-*linux* | mips*-*-gnu*)
2186     target_makefile_frag="config/mt-mips-gnu"
2187     ;;
2188   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2189     target_makefile_frag="config/mt-gnu"
2190     ;;
2191   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2192     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2193     # commands to handle both 32-bit and 64-bit objects.  These flags are
2194     # harmless if we're using GNU nm or ar.
2195     extra_arflags_for_target=" -X32_64"
2196     extra_nmflags_for_target=" -B -X32_64"
2197     ;;
2198   *-*-darwin[[3-9]]*)
2199     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2200     extra_ranlibflags_for_target=" -c"
2201     ;;
2202 esac
2203
2204 alphaieee_frag=/dev/null
2205 case $target in
2206   alpha*-*-*)
2207     # This just makes sure to use the -mieee option to build target libs.
2208     # This should probably be set individually by each library.
2209     alphaieee_frag="config/mt-alphaieee"
2210     ;;
2211 esac
2212
2213 # If --enable-target-optspace always use -Os instead of -O2 to build
2214 # the target libraries, similarly if it is not specified, use -Os
2215 # on selected platforms.
2216 ospace_frag=/dev/null
2217 case "${enable_target_optspace}:${target}" in
2218   yes:*)
2219     ospace_frag="config/mt-ospace"
2220     ;;
2221   :d30v-*)
2222     ospace_frag="config/mt-d30v"
2223     ;;
2224   :m32r-* | :d10v-* | :fr30-*)
2225     ospace_frag="config/mt-ospace"
2226     ;;
2227   no:* | :*)
2228     ;;
2229   *)
2230     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2231     ;;
2232 esac
2233
2234 # Default to using --with-stabs for certain targets.
2235 if test x${with_stabs} = x ; then
2236   case "${target}" in
2237   mips*-*-irix[[56]]*)
2238     ;;
2239   mips*-*-* | alpha*-*-osf*)
2240     with_stabs=yes;
2241     extra_host_args="${extra_host_args} --with-stabs"
2242     ;;
2243   esac
2244 fi
2245
2246 # Some systems (e.g., one of the i386-aix systems the gas testers are
2247 # using) don't handle "\$" correctly, so don't use it here.
2248 tooldir='${exec_prefix}'/${target_noncanonical}
2249 build_tooldir=${tooldir}
2250
2251 # Create a .gdbinit file which runs the one in srcdir
2252 # and tells GDB to look there for source files.
2253
2254 if test -r ${srcdir}/.gdbinit ; then
2255   case ${srcdir} in
2256     .) ;;
2257     *) cat > ./.gdbinit <<EOF
2258 # ${NO_EDIT}
2259 dir ${srcdir}
2260 dir .
2261 source ${srcdir}/.gdbinit
2262 EOF
2263     ;;
2264   esac
2265 fi
2266
2267 # Make sure that the compiler is able to generate an executable.  If it
2268 # can't, we are probably in trouble.  We don't care whether we can run the
2269 # executable--we might be using a cross compiler--we only care whether it
2270 # can be created.  At this point the main configure script has set CC.
2271 we_are_ok=no
2272 echo "int main () { return 0; }" > conftest.c
2273 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2274 if test $? = 0 ; then
2275   if test -s conftest || test -s conftest.exe ; then
2276     we_are_ok=yes
2277   fi
2278 fi
2279 case $we_are_ok in
2280   no)
2281     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2282     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2283     rm -f conftest*
2284     exit 1
2285     ;;
2286 esac
2287 rm -f conftest*
2288
2289 # Decide which environment variable is used to find dynamic libraries.
2290 case "${host}" in
2291   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2292   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2293   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2294   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2295 esac
2296
2297 # On systems where the dynamic library environment variable is PATH,
2298 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2299 # built executables to PATH.
2300 if test "$RPATH_ENVVAR" = PATH; then
2301   GCC_SHLIB_SUBDIR=/shlib
2302 else
2303   GCC_SHLIB_SUBDIR=
2304 fi
2305
2306 # Record target_configdirs and the configure arguments for target and
2307 # build configuration in Makefile.
2308 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2309 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2310
2311 # If we are building libgomp, bootstrap it.
2312 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2313   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2314 fi
2315
2316 # Determine whether gdb needs tk/tcl or not.
2317 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2318 # and in that case we want gdb to be built without tk.  Ugh!
2319 # In fact I believe gdb is the *only* package directly dependent on tk,
2320 # so we should be able to put the 'maybe's in unconditionally and
2321 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2322 # 100% sure that that's safe though.
2323
2324 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2325 case "$enable_gdbtk" in
2326   no)
2327     GDB_TK="" ;;
2328   yes)
2329     GDB_TK="${gdb_tk}" ;;
2330   *)
2331     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2332     # distro.  Eventually someone will fix this and move Insight, nee
2333     # gdbtk to a separate directory.
2334     if test -d ${srcdir}/gdb/gdbtk ; then
2335       GDB_TK="${gdb_tk}"
2336     else
2337       GDB_TK=""
2338     fi
2339     ;;
2340 esac
2341 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2342 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2343
2344 # Strip out unwanted targets.
2345
2346 # While at that, we remove Makefiles if we were started for recursive
2347 # configuration, so that the top-level Makefile reconfigures them,
2348 # like we used to do when configure itself was recursive.
2349
2350 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2351 # but now we're fixing up the Makefile ourselves with the additional
2352 # commands passed to AC_CONFIG_FILES.  Use separate variables
2353 # extrasub-{build,host,target} not because there is any reason to split
2354 # the substitutions up that way, but only to remain below the limit of
2355 # 99 commands in a script, for HP-UX sed.
2356 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2357
2358 AC_ARG_ENABLE([bootstrap],
2359 [AS_HELP_STRING([--enable-bootstrap],
2360                 [enable bootstrapping @<:@yes if native build@:>@])],,
2361 enable_bootstrap=default)
2362
2363 # Issue errors and warnings for invalid/strange bootstrap combinations.
2364 case "$configdirs" in
2365   *gcc*) have_compiler=yes ;;
2366   *) have_compiler=no ;;
2367 esac
2368
2369 case "$have_compiler:$host:$target:$enable_bootstrap" in
2370   *:*:*:no) ;;
2371
2372   # Default behavior.  Enable bootstrap if we have a compiler
2373   # and we are in a native configuration.
2374   yes:$build:$build:default)
2375     enable_bootstrap=yes ;;
2376
2377   *:*:*:default)
2378     enable_bootstrap=no ;;
2379
2380   # We have a compiler and we are in a native configuration, bootstrap is ok
2381   yes:$build:$build:yes)
2382     ;;
2383
2384   # Other configurations, but we have a compiler.  Assume the user knows
2385   # what he's doing.
2386   yes:*:*:yes)
2387     AC_MSG_WARN([trying to bootstrap a cross compiler])
2388     ;;
2389
2390   # No compiler: if they passed --enable-bootstrap explicitly, fail
2391   no:*:*:yes)
2392     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2393
2394   # Fail if wrong command line
2395   *)
2396     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2397     ;;
2398 esac
2399
2400 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2401   *,c++,*:yes:yes) ;;
2402   *:yes:yes)
2403     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2404     ;;
2405 esac
2406
2407 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2408   yes:yes:*\ gold\ *:*,c++,*) ;;
2409   yes:yes:*\ gold\ *:*)
2410     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2411     ;;
2412 esac
2413
2414 # Adjust the toplevel makefile according to whether bootstrap was selected.
2415 case $enable_bootstrap in
2416   yes)
2417     bootstrap_suffix=bootstrap
2418     BUILD_CONFIG=bootstrap-debug
2419     ;;
2420   no)
2421     bootstrap_suffix=no-bootstrap
2422     BUILD_CONFIG=
2423     ;;
2424 esac
2425
2426 AC_MSG_CHECKING(for default BUILD_CONFIG)
2427
2428 AC_ARG_WITH([build-config],
2429   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2430                   [use config/NAME.mk build configuration])],
2431   [case $with_build_config in
2432    yes) with_build_config= ;;
2433    no) with_build_config= BUILD_CONFIG= ;;
2434    esac])
2435
2436 if test "x${with_build_config}" != x; then
2437   BUILD_CONFIG=$with_build_config
2438 else
2439   case $BUILD_CONFIG in
2440   bootstrap-debug)
2441     if echo "int f (void) { return 0; }" > conftest.c &&
2442        ${CC} -c conftest.c &&
2443        mv conftest.o conftest.o.g0 &&
2444        ${CC} -c -g conftest.c &&
2445        mv conftest.o conftest.o.g &&
2446        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2447       :
2448     else
2449       BUILD_CONFIG=
2450     fi
2451     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2452     ;;
2453   esac
2454 fi
2455 AC_MSG_RESULT($BUILD_CONFIG)
2456 AC_SUBST(BUILD_CONFIG)
2457
2458 extrasub_build=
2459 for module in ${build_configdirs} ; do
2460   if test -z "${no_recursion}" \
2461      && test -f ${build_subdir}/${module}/Makefile; then
2462     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2463     rm -f ${build_subdir}/${module}/Makefile
2464   fi
2465   extrasub_build="$extrasub_build
2466 /^@if build-$module\$/d
2467 /^@endif build-$module\$/d
2468 /^@if build-$module-$bootstrap_suffix\$/d
2469 /^@endif build-$module-$bootstrap_suffix\$/d"
2470 done
2471 extrasub_host=
2472 for module in ${configdirs} ; do
2473   if test -z "${no_recursion}"; then
2474     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2475       if test -f ${file}; then
2476         echo 1>&2 "*** removing ${file} to force reconfigure"
2477         rm -f ${file}
2478       fi
2479     done
2480   fi
2481   extrasub_host="$extrasub_host
2482 /^@if $module\$/d
2483 /^@endif $module\$/d
2484 /^@if $module-$bootstrap_suffix\$/d
2485 /^@endif $module-$bootstrap_suffix\$/d"
2486 done
2487 extrasub_target=
2488 for module in ${target_configdirs} ; do
2489   if test -z "${no_recursion}" \
2490      && test -f ${target_subdir}/${module}/Makefile; then
2491     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2492     rm -f ${target_subdir}/${module}/Makefile
2493   fi
2494
2495   # We only bootstrap target libraries listed in bootstrap_target_libs.
2496   case $bootstrap_target_libs in
2497     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2498     *) target_bootstrap_suffix=no-bootstrap ;;
2499   esac
2500
2501   extrasub_target="$extrasub_target
2502 /^@if target-$module\$/d
2503 /^@endif target-$module\$/d
2504 /^@if target-$module-$target_bootstrap_suffix\$/d
2505 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2506 done
2507
2508 # Do the final fixup along with target modules.
2509 extrasub_target="$extrasub_target
2510 /^@if /,/^@endif /d"
2511
2512 # Create the serialization dependencies.  This uses a temporary file.
2513
2514 AC_ARG_ENABLE([serial-configure],
2515 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2516                 [force sequential configuration of
2517                  sub-packages for the host, target or build
2518                  machine, or all sub-packages])])
2519
2520 case ${enable_serial_configure} in
2521   yes)
2522     enable_serial_build_configure=yes
2523     enable_serial_host_configure=yes
2524     enable_serial_target_configure=yes
2525     ;;
2526 esac
2527
2528 # These force 'configure's to be done one at a time, to avoid problems
2529 # with contention over a shared config.cache.
2530 rm -f serdep.tmp
2531 echo '# serdep.tmp' > serdep.tmp
2532 olditem=
2533 test "x${enable_serial_build_configure}" = xyes &&
2534 for item in ${build_configdirs} ; do
2535   case ${olditem} in
2536     "") ;;
2537     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2538   esac
2539   olditem=${item}
2540 done
2541 olditem=
2542 test "x${enable_serial_host_configure}" = xyes &&
2543 for item in ${configdirs} ; do
2544   case ${olditem} in
2545     "") ;;
2546     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2547   esac
2548   olditem=${item}
2549 done
2550 olditem=
2551 test "x${enable_serial_target_configure}" = xyes &&
2552 for item in ${target_configdirs} ; do
2553   case ${olditem} in
2554     "") ;;
2555     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2556   esac
2557   olditem=${item}
2558 done
2559 serialization_dependencies=serdep.tmp
2560 AC_SUBST_FILE(serialization_dependencies)
2561
2562 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2563 # target, nonopt, and variable assignments.  These are the ones we
2564 # might not want to pass down to subconfigures.  The exception being
2565 # --cache-file=/dev/null, which is used to turn off the use of cache
2566 # files altogether, and which should be passed on to subconfigures.
2567 # Also strip program-prefix, program-suffix, and program-transform-name,
2568 # so that we can pass down a consistent program-transform-name.
2569 baseargs=
2570 tbaseargs=
2571 keep_next=no
2572 skip_next=no
2573 eval "set -- $ac_configure_args"
2574 for ac_arg
2575 do
2576   if test X"$skip_next" = X"yes"; then
2577     skip_next=no
2578     continue
2579   fi
2580   if test X"$keep_next" = X"yes"; then
2581     case $ac_arg in
2582       *\'*)
2583         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2584     esac
2585     baseargs="$baseargs '$ac_arg'"
2586     tbaseargs="$tbaseargs '$ac_arg'"
2587     keep_next=no
2588     continue
2589   fi
2590
2591   # Handle separated arguments.  Based on the logic generated by
2592   # autoconf 2.59.
2593   case $ac_arg in
2594     *=* | --config-cache | -C | -disable-* | --disable-* \
2595       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2596       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2597       | -with-* | --with-* | -without-* | --without-* | --x)
2598       separate_arg=no
2599       ;;
2600     -*)
2601       separate_arg=yes
2602       ;;
2603     *)
2604       separate_arg=no
2605       ;;
2606   esac
2607
2608   skip_targ=no
2609   case $ac_arg in
2610 changequote(,)
2611   --with-* | --without-*)
2612     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2613
2614     case $libopt in
2615     *[-_]include)
2616       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2617       ;;
2618     *[-_]lib)
2619       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2620       ;;
2621     *)
2622       lib=$libopt
2623       ;;
2624     esac
2625 changequote([,])
2626
2627     case $lib in
2628     mpc | mpfr | gmp | ppl | cloog)
2629       # If we're processing --with-$lib, --with-$lib-include or
2630       # --with-$lib-lib, for one of the libs above, and target is
2631       # different from host, don't pass the current argument to any
2632       # target library's configure.
2633       if test x$is_cross_compiler = xyes; then
2634         skip_targ=yes
2635       fi
2636       ;;
2637     esac
2638     ;;
2639   esac
2640
2641   case "$ac_arg" in
2642     --cache-file=/dev/null | \
2643     -cache-file=/dev/null )
2644       # Handled here to avoid the test to skip args below.
2645       baseargs="$baseargs '$ac_arg'"
2646       tbaseargs="$tbaseargs '$ac_arg'"
2647       # Assert: $separate_arg should always be no.
2648       keep_next=$separate_arg
2649       ;;
2650     --no*)
2651       continue
2652       ;;
2653     --c* | \
2654     --sr* | \
2655     --ho* | \
2656     --bu* | \
2657     --t* | \
2658     --program-* | \
2659     -cache_file* | \
2660     -srcdir* | \
2661     -host* | \
2662     -build* | \
2663     -target* | \
2664     -program-prefix* | \
2665     -program-suffix* | \
2666     -program-transform-name* )
2667       skip_next=$separate_arg
2668       continue
2669       ;;
2670     -*)
2671       # An option.  Add it.
2672       case $ac_arg in
2673         *\'*)
2674           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2675       esac
2676       baseargs="$baseargs '$ac_arg'"
2677       if test X"$skip_targ" = Xno; then
2678         tbaseargs="$tbaseargs '$ac_arg'"
2679       fi
2680       keep_next=$separate_arg
2681       ;;
2682     *)
2683       # Either a variable assignment, or a nonopt (triplet).  Don't
2684       # pass it down; let the Makefile handle this.
2685       continue
2686       ;;
2687   esac
2688 done
2689 # Remove the initial space we just introduced and, as these will be
2690 # expanded by make, quote '$'.
2691 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2692
2693 # Add in --program-transform-name, after --program-prefix and
2694 # --program-suffix have been applied to it.  Autoconf has already
2695 # doubled dollar signs and backslashes in program_transform_name; we want
2696 # the backslashes un-doubled, and then the entire thing wrapped in single
2697 # quotes, because this will be expanded first by make and then by the shell.
2698 # Also, because we want to override the logic in subdir configure scripts to
2699 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2700 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2701 ${program_transform_name}
2702 EOF_SED
2703 gcc_transform_name=`cat conftestsed.out`
2704 rm -f conftestsed.out
2705 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2706 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2707 if test "$silent" = yes; then
2708   baseargs="$baseargs --silent"
2709   tbaseargs="$tbaseargs --silent"
2710 fi
2711 baseargs="$baseargs --disable-option-checking"
2712 tbaseargs="$tbaseargs --disable-option-checking"
2713
2714 # Record and document user additions to sub configure arguments.
2715 AC_ARG_VAR([build_configargs],
2716            [additional configure arguments for build directories])
2717 AC_ARG_VAR([host_configargs],
2718            [additional configure arguments for host directories])
2719 AC_ARG_VAR([target_configargs],
2720            [additional configure arguments for target directories])
2721
2722 # For the build-side libraries, we just need to pretend we're native,
2723 # and not use the same cache file.  Multilibs are neither needed nor
2724 # desired.
2725 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2726
2727 # For host modules, accept cache file option, or specification as blank.
2728 case "${cache_file}" in
2729 "") # empty
2730   cache_file_option="" ;;
2731 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2732   cache_file_option="--cache-file=${cache_file}" ;;
2733 *) # relative path
2734   cache_file_option="--cache-file=../${cache_file}" ;;
2735 esac
2736
2737 # Host dirs don't like to share a cache file either, horribly enough.
2738 # This seems to be due to autoconf 2.5x stupidity.
2739 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2740
2741 target_configargs="$target_configargs ${tbaseargs}"
2742
2743 # Passing a --with-cross-host argument lets the target libraries know
2744 # whether they are being built with a cross-compiler or being built
2745 # native.  However, it would be better to use other mechanisms to make the
2746 # sorts of decisions they want to make on this basis.  Please consider
2747 # this option to be deprecated.  FIXME.
2748 if test x${is_cross_compiler} = xyes ; then
2749   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2750 fi
2751
2752 # Default to --enable-multilib.
2753 if test x${enable_multilib} = x ; then
2754   target_configargs="--enable-multilib ${target_configargs}"
2755 fi
2756
2757 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2758 # changed from the earlier setting of with_newlib.
2759 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2760   target_configargs="--with-newlib ${target_configargs}"
2761 fi
2762
2763 # Different target subdirs use different values of certain variables
2764 # (notably CXX).  Worse, multilibs use *lots* of different values.
2765 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2766 # it doesn't automatically accept command-line overrides of them.
2767 # This means it's not safe for target subdirs to share a cache file,
2768 # which is disgusting, but there you have it.  Hopefully this can be
2769 # fixed in future.  It's still worthwhile to use a cache file for each
2770 # directory.  I think.
2771
2772 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2773 # We need to pass --target, as newer autoconf's requires consistency
2774 # for target_alias and gcc doesn't manage it consistently.
2775 target_configargs="--cache-file=./config.cache ${target_configargs}"
2776
2777 FLAGS_FOR_TARGET=
2778 case " $target_configdirs " in
2779  *" newlib "*)
2780   case " $target_configargs " in
2781   *" --with-newlib "*)
2782    case "$target" in
2783     *-cygwin*)
2784       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2785       ;;
2786    esac
2787
2788    # If we're not building GCC, don't discard standard headers.
2789    if test -d ${srcdir}/gcc; then
2790      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2791
2792      if test "${build}" != "${host}"; then
2793        # On Canadian crosses, CC_FOR_TARGET will have already been set
2794        # by `configure', so we won't have an opportunity to add -Bgcc/
2795        # to it.  This is right: we don't want to search that directory
2796        # for binaries, but we want the header files in there, so add
2797        # them explicitly.
2798        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2799
2800        # Someone might think of using the pre-installed headers on
2801        # Canadian crosses, in case the installed compiler is not fully
2802        # compatible with the compiler being built.  In this case, it
2803        # would be better to flag an error than risking having
2804        # incompatible object files being constructed.  We can't
2805        # guarantee that an error will be flagged, but let's hope the
2806        # compiler will do it, when presented with incompatible header
2807        # files.
2808      fi
2809    fi
2810
2811    case "${target}-${is_cross_compiler}" in
2812    i[[3456789]]86-*-linux*-no)
2813       # Here host == target, so we don't need to build gcc,
2814       # so we don't want to discard standard headers.
2815       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2816       ;;
2817    *)
2818       # If we're building newlib, use its generic headers last, but search
2819       # for any libc-related directories first (so make it the last -B
2820       # switch).
2821       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2822
2823       # If we're building libgloss, find the startup file, simulator library
2824       # and linker script.
2825       case " $target_configdirs " in
2826         *" libgloss "*)
2827         # Look for startup file, simulator library and maybe linker script.
2828         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2829         # Look for libnosys.a in case the target needs it.
2830         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2831         # Most targets have the linker script in the source directory.
2832         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2833         ;;
2834       esac
2835       ;;
2836    esac
2837    ;;
2838   esac
2839   ;;
2840 esac
2841
2842 case "$target" in
2843   x86_64-*mingw* | *-w64-mingw*)
2844   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2845   # however, use a symlink named 'mingw' in ${prefix} .
2846     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2847     ;;
2848   *-mingw*)
2849   # MinGW can't be handled as Cygwin above since it does not use newlib.
2850     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2851     ;;
2852 esac
2853
2854 # Allow the user to override the flags for
2855 # our build compiler if desired.
2856 if test x"${build}" = x"${host}" ; then
2857   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2858   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2859   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2860 fi
2861
2862 # On Canadian crosses, we'll be searching the right directories for
2863 # the previously-installed cross compiler, so don't bother to add
2864 # flags for directories within the install tree of the compiler
2865 # being built; programs in there won't even run.
2866 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2867   # Search for pre-installed headers if nothing else fits.
2868   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2869 fi
2870
2871 if test "x${use_gnu_ld}" = x &&
2872    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2873   # Arrange for us to find uninstalled linker scripts.
2874   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2875 fi
2876
2877 # Search for other target-specific linker scripts and such.
2878 case "${target}" in
2879   mep*)
2880     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2881     ;;
2882 esac
2883
2884 # Makefile fragments.
2885 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2886 do
2887   eval fragval=\$$frag
2888   if test $fragval != /dev/null; then
2889     eval $frag=${srcdir}/$fragval
2890   fi
2891 done
2892 AC_SUBST_FILE(host_makefile_frag)
2893 AC_SUBST_FILE(target_makefile_frag)
2894 AC_SUBST_FILE(alphaieee_frag)
2895 AC_SUBST_FILE(ospace_frag)
2896
2897 # Miscellanea: directories, flags, etc.
2898 AC_SUBST(RPATH_ENVVAR)
2899 AC_SUBST(GCC_SHLIB_SUBDIR)
2900 AC_SUBST(tooldir)
2901 AC_SUBST(build_tooldir)
2902 AC_SUBST(CONFIGURE_GDB_TK)
2903 AC_SUBST(GDB_TK)
2904 AC_SUBST(INSTALL_GDB_TK)
2905
2906 # Build module lists & subconfigure args.
2907 AC_SUBST(build_configargs)
2908 AC_SUBST(build_configdirs)
2909
2910 # Host module lists & subconfigure args.
2911 AC_SUBST(host_configargs)
2912 AC_SUBST(configdirs)
2913 AC_SUBST(target_configdirs)
2914
2915 # Target module lists & subconfigure args.
2916 AC_SUBST(target_configargs)
2917
2918
2919 # Build tools.
2920 AC_SUBST(AR_FOR_BUILD)
2921 AC_SUBST(AS_FOR_BUILD)
2922 AC_SUBST(CC_FOR_BUILD)
2923 AC_SUBST(CFLAGS_FOR_BUILD)
2924 AC_SUBST(CXXFLAGS_FOR_BUILD)
2925 AC_SUBST(CXX_FOR_BUILD)
2926 AC_SUBST(DLLTOOL_FOR_BUILD)
2927 AC_SUBST(GCJ_FOR_BUILD)
2928 AC_SUBST(GFORTRAN_FOR_BUILD)
2929 AC_SUBST(GOC_FOR_BUILD)
2930 AC_SUBST(LDFLAGS_FOR_BUILD)
2931 AC_SUBST(LD_FOR_BUILD)
2932 AC_SUBST(NM_FOR_BUILD)
2933 AC_SUBST(RANLIB_FOR_BUILD)
2934 AC_SUBST(WINDMC_FOR_BUILD)
2935 AC_SUBST(WINDRES_FOR_BUILD)
2936
2937 # Generate default definitions for YACC, M4, LEX and other programs that run
2938 # on the build machine.  These are used if the Makefile can't locate these
2939 # programs in objdir.
2940 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2941
2942 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2943 case " $build_configdirs " in
2944   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2945 esac
2946
2947 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2948 case " $build_configdirs " in
2949   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2950 esac
2951
2952 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2953 case " $build_configdirs " in
2954   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2955 esac
2956
2957 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2958 case " $build_configdirs " in
2959   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2960   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2961 esac
2962
2963 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2964 case " $build_configdirs " in
2965   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2966 esac
2967
2968 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2969 case " $build_configdirs " in
2970   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
2971   *)
2972 changequote(,)
2973     # For an installed makeinfo, we require it to be from texinfo 4.7 or
2974     # higher, else we use the "missing" dummy.
2975     if ${MAKEINFO} --version \
2976        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
2977       :
2978     else
2979       MAKEINFO="$MISSING makeinfo"
2980     fi
2981     ;;
2982 changequote([,])
2983 esac
2984
2985 # FIXME: expect and dejagnu may become build tools?
2986
2987 AC_CHECK_PROGS(EXPECT, expect, expect)
2988 case " $configdirs " in
2989   *" expect "*)
2990     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
2991     ;;
2992 esac
2993
2994 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
2995 case " $configdirs " in
2996   *" dejagnu "*)
2997     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
2998     ;;
2999 esac
3000
3001
3002 # Host tools.
3003 NCN_STRICT_CHECK_TOOLS(AR, ar)
3004 NCN_STRICT_CHECK_TOOLS(AS, as)
3005 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3006 NCN_STRICT_CHECK_TOOLS(LD, ld)
3007 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3008 NCN_STRICT_CHECK_TOOLS(NM, nm)
3009 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3010 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3011 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3012 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3013 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3014 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3015 AC_SUBST(CC)
3016 AC_SUBST(CXX)
3017 AC_SUBST(CFLAGS)
3018 AC_SUBST(CXXFLAGS)
3019
3020 # Target tools.
3021 AC_ARG_WITH([build-time-tools],
3022   [AS_HELP_STRING([--with-build-time-tools=PATH],
3023                   [use given path to find target tools during the build])],
3024   [case x"$withval" in
3025      x/*) ;;
3026      *)
3027        with_build_time_tools=
3028        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3029        ;;
3030    esac],
3031   [with_build_time_tools=])
3032
3033 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3034 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3035 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3036 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3037 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3038 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3039
3040 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3041 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3042 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3043 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3044 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3045 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3046 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3047 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3048 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3049 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3050 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3051
3052 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3053
3054 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3055 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3056 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3057 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3058 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3059                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3060                 c++)
3061 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3062                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3063                 c++)
3064 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3065 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3066 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3067                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3068 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3069                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3070 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3071                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3072 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3073 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3074 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3075 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3076 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3077 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3078 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3079 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3080
3081 AC_SUBST(FLAGS_FOR_TARGET)
3082 AC_SUBST(RAW_CXX_FOR_TARGET)
3083
3084 # Certain tools may need extra flags.
3085 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3086 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3087 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3088
3089 # When building target libraries, except in a Canadian cross, we use
3090 # the same toolchain as the compiler we just built.
3091 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3092 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3093 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3094 if test $host = $build; then
3095   case " $configdirs " in
3096     *" gcc "*)
3097       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3098       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3099       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3100       ;;
3101   esac
3102 fi
3103
3104 AC_SUBST(COMPILER_AS_FOR_TARGET)
3105 AC_SUBST(COMPILER_LD_FOR_TARGET)
3106 AC_SUBST(COMPILER_NM_FOR_TARGET)
3107
3108 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3109 AC_ARG_ENABLE(maintainer-mode,
3110 [AS_HELP_STRING([--enable-maintainer-mode],
3111                 [enable make rules and dependencies not useful
3112                  (and sometimes confusing) to the casual installer])],
3113       USE_MAINTAINER_MODE=$enableval,
3114       USE_MAINTAINER_MODE=no)
3115 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3116 AC_SUBST(MAINTAINER_MODE_TRUE)
3117 AC_SUBST(MAINTAINER_MODE_FALSE)
3118 if test "$USE_MAINTAINER_MODE" = yes; then
3119   MAINTAINER_MODE_TRUE=
3120   MAINTAINER_MODE_FALSE='#'
3121 else
3122   MAINTAINER_MODE_TRUE='#'
3123   MAINTAINER_MODE_FALSE=
3124 fi
3125 MAINT=$MAINTAINER_MODE_TRUE
3126 AC_SUBST(MAINT)dnl
3127
3128 # ---------------------
3129 # GCC bootstrap support
3130 # ---------------------
3131
3132 # Stage specific cflags for build.
3133 stage1_cflags="-g"
3134 case $build in
3135   vax-*-*)
3136     case ${GCC} in
3137       yes) stage1_cflags="-g -Wa,-J" ;;
3138       *) stage1_cflags="-g -J" ;;
3139     esac ;;
3140 esac
3141
3142 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3143 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3144   saved_CFLAGS="$CFLAGS"
3145
3146   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3147   CFLAGS="$CFLAGS -fkeep-inline-functions"
3148   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3149   AC_TRY_COMPILE([
3150 #if (__GNUC__ < 3) \
3151     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3152                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3153 #error http://gcc.gnu.org/PR29382
3154 #endif
3155     ],,
3156     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3157     [AC_MSG_RESULT([no])])
3158
3159   CFLAGS="$saved_CFLAGS"
3160 fi
3161
3162 AC_SUBST(stage1_cflags)
3163
3164 # Enable --enable-checking in stage1 of the compiler.
3165 AC_ARG_ENABLE(stage1-checking,
3166 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3167                 [choose additional checking for stage1 of the compiler])],
3168 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3169 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3170   stage1_checking=--enable-checking=yes,types
3171 else
3172   stage1_checking=--enable-checking=$enable_checking,types
3173 fi])
3174 AC_SUBST(stage1_checking)
3175
3176 # Enable -Werror in bootstrap stage2 and later.
3177 AC_ARG_ENABLE(werror,
3178 [AS_HELP_STRING([--enable-werror],
3179                 [enable -Werror in bootstrap stage2 and later])], [],
3180 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3181   enable_werror=yes
3182 else
3183   enable_werror=no
3184 fi])
3185 case ${enable_werror} in
3186   yes) stage2_werror_flag="--enable-werror-always" ;;
3187   *) stage2_werror_flag="" ;;
3188 esac
3189 AC_SUBST(stage2_werror_flag)
3190
3191 # Specify what files to not compare during bootstrap.
3192
3193 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3194 case "$target" in
3195   hppa*64*-*-hpux*) ;;
3196   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3197 esac
3198 case " $configdirs " in
3199 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3200 esac
3201 AC_SUBST(compare_exclusions)
3202
3203 AC_CONFIG_FILES([Makefile],
3204   [sed "$extrasub_build" Makefile |
3205    sed "$extrasub_host" |
3206    sed "$extrasub_target" > mf$$
3207    mv -f mf$$ Makefile],
3208   [extrasub_build="$extrasub_build"
3209    extrasub_host="$extrasub_host"
3210    extrasub_target="$extrasub_target"])
3211 AC_OUTPUT