configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-* | amdgcn*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Disable libhsail-rt on unsupported systems.
 605 if test -d ${srcdir}/libhsail-rt; then
 606     if test x$enable_libhsail_rt = x; then
 607         AC_MSG_CHECKING([for libhsail-rt support])
 608         if (srcdir=${srcdir}/libhsail-rt; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test -n "$UNSUPPORTED")
 611         then
 612             AC_MSG_RESULT([no])
 613             unsupported_languages="$unsupported_languages brig"
 614             # This implicitly disables also target-libhsail-rt as it won't
 615             # get added to the build without BRIG FE.
 616         else
 617             AC_MSG_RESULT([yes])
 618         fi
 619     fi
 620 fi
 621
 622
 623 # Disable libquadmath for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     noconfigdirs="$noconfigdirs target-libquadmath"
 627     ;;
 628   # libquadmath is unused on AIX and libquadmath build process use of
 629   # LD_LIBRARY_PATH can break AIX bootstrap.
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633 esac
 634
 635 # Disable libssp for some systems.
 636 case "${target}" in
 637   avr-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   bpf-*-*)
 642     noconfigdirs="$noconfigdirs target-libssp"
 643     ;;
 644   powerpc-*-aix* | rs6000-*-aix*)
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   pru-*-*)
 648     # No hosted I/O support.
 649     noconfigdirs="$noconfigdirs target-libssp"
 650     ;;
 651   rl78-*-*)
 652     # libssp uses a misaligned load to trigger a fault, but the RL78
 653     # doesn't fault for those - instead, it gives a build-time error
 654     # for explicit misaligned loads.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   visium-*-*)
 658     # No hosted I/O support.
 659     noconfigdirs="$noconfigdirs target-libssp"
 660     ;;
 661 esac
 662
 663 # Disable libstdc++-v3 for some systems.
 664 # Allow user to override this if they pass --enable-libstdc++-v3
 665 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 666   case "${target}" in
 667     *-*-vxworks*)
 668       # VxWorks uses the Dinkumware C++ library.
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     arm*-wince-pe*)
 672       # the C++ libraries don't build on top of CE's C libraries
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     avr-*-*)
 676       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 677       ;;
 678     bpf-*-*)
 679       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 680       ;;
 681     ft32-*-*)
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684   esac
 685 fi
 686
 687 # Disable C++ on systems where it is known to not work.
 688 # For testing, you can override this with --enable-languages=c++.
 689 case ,${enable_languages}, in
 690   *,c++,*)
 691     ;;
 692   *)
 693       case "${target}" in
 694         bpf-*-*)
 695           unsupported_languages="$unsupported_languages c++"
 696           ;;
 697       esac
 698       ;;
 699 esac
 700
 701 # Disable Objc on systems where it is known to not work.
 702 # For testing, you can override this with --enable-languages=objc.
 703 case ,${enable_languages}, in
 704   *,objc,*)
 705     ;;
 706   *)
 707       case "${target}" in
 708         bpf-*-*)
 709           unsupported_languages="$unsupported_languages objc"
 710           ;;
 711       esac
 712       ;;
 713 esac
 714
 715 # Disable D on systems where it is known to not work.
 716 # For testing, you can override this with --enable-languages=d.
 717 case ,${enable_languages}, in
 718   *,d,*)
 719     ;;
 720   *)
 721     case "${target}" in
 722       *-*-darwin*)
 723         unsupported_languages="$unsupported_languages d"
 724         ;;
 725       bpf-*-*)
 726         unsupported_languages="$unsupported_languages d"
 727         ;;
 728     esac
 729     ;;
 730 esac
 731
 732 # Disable libphobos on unsupported systems.
 733 # For testing, you can override this with --enable-libphobos.
 734 if test -d ${srcdir}/libphobos; then
 735     if test x$enable_libphobos = x; then
 736         AC_MSG_CHECKING([for libphobos support])
 737         if (srcdir=${srcdir}/libphobos; \
 738                 . ${srcdir}/configure.tgt; \
 739                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 740         then
 741             AC_MSG_RESULT([no])
 742             noconfigdirs="$noconfigdirs target-libphobos"
 743         else
 744             AC_MSG_RESULT([yes])
 745         fi
 746     fi
 747 fi
 748
 749 # Disable Fortran for some systems.
 750 case "${target}" in
 751   mmix-*-*)
 752     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 753     unsupported_languages="$unsupported_languages fortran"
 754     ;;
 755   bpf-*-*)
 756     unsupported_languages="$unsupported_languages fortran"
 757     ;;
 758 esac
 759
 760 # Disable libffi for some systems.
 761 case "${target}" in
 762   powerpc-*-darwin*)
 763     ;;
 764   i[[3456789]]86-*-darwin*)
 765     ;;
 766   x86_64-*-darwin[[912]]*)
 767     ;;
 768   *-*-darwin*)
 769     noconfigdirs="$noconfigdirs target-libffi"
 770     ;;
 771   *-*-netware*)
 772     noconfigdirs="$noconfigdirs target-libffi"
 773     ;;
 774   *-*-phoenix*)
 775     noconfigdirs="$noconfigdirs target-libffi"
 776     ;;
 777   *-*-rtems*)
 778     noconfigdirs="$noconfigdirs target-libffi"
 779     ;;
 780   *-*-tpf*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-uclinux*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786   *-*-vxworks*)
 787     noconfigdirs="$noconfigdirs target-libffi"
 788     ;;
 789   aarch64*-*-freebsd*)
 790     noconfigdirs="$noconfigdirs target-libffi"
 791     ;;
 792   alpha*-*-*vms*)
 793     noconfigdirs="$noconfigdirs target-libffi"
 794     ;;
 795   arm*-*-freebsd*)
 796     noconfigdirs="$noconfigdirs target-libffi"
 797     ;;
 798   arm-wince-pe)
 799     noconfigdirs="$noconfigdirs target-libffi"
 800     ;;
 801   arm*-*-symbianelf*)
 802     noconfigdirs="$noconfigdirs target-libffi"
 803     ;;
 804   bpf-*-*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   cris-*-* | crisv32-*-*)
 808     case "${target}" in
 809       *-*-linux*)
 810         ;;
 811       *) # See PR46792 regarding target-libffi.
 812         noconfigdirs="$noconfigdirs target-libffi";;
 813     esac
 814     ;;
 815   hppa*64*-*-hpux*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   hppa*-hp-hpux11*)
 819     ;;
 820   hppa*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   ia64*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   i[[3456789]]86-w64-mingw*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   i[[3456789]]86-*-mingw*)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   x86_64-*-mingw*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   mmix-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   powerpc-*-aix*)
 839     ;;
 840   rs6000-*-aix*)
 841     ;;
 842   ft32-*-*)
 843     noconfigdirs="$noconfigdirs target-libffi"
 844     ;;
 845   *-*-lynxos*)
 846     noconfigdirs="$noconfigdirs target-libffi"
 847     ;;
 848 esac
 849
 850 # Disable the go frontend on systems where it is known to not work. Please keep
 851 # this in sync with contrib/config-list.mk.
 852 case "${target}" in
 853 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 854     unsupported_languages="$unsupported_languages go"
 855     ;;
 856 esac
 857
 858 # Only allow gdbserver on some systems.
 859 if test -d ${srcdir}/gdbserver; then
 860     if test x$enable_gdbserver = x; then
 861         AC_MSG_CHECKING([for gdbserver support])
 862         if (srcdir=${srcdir}/gdbserver; \
 863                 . ${srcdir}/configure.srv; \
 864                 test -n "$UNSUPPORTED")
 865         then
 866             AC_MSG_RESULT([no])
 867             noconfigdirs="$noconfigdirs gdbserver"
 868         else
 869             AC_MSG_RESULT([yes])
 870         fi
 871     fi
 872 fi
 873
 874 # Disable libgo for some systems where it is known to not work.
 875 # For testing, you can easily override this with --enable-libgo.
 876 if test x$enable_libgo = x; then
 877     case "${target}" in
 878     *-*-darwin*)
 879         # PR 46986
 880         noconfigdirs="$noconfigdirs target-libgo"
 881         ;;
 882     *-*-cygwin* | *-*-mingw*)
 883         noconfigdirs="$noconfigdirs target-libgo"
 884         ;;
 885     bpf-*-*)
 886         noconfigdirs="$noconfigdirs target-libgo"
 887         ;;
 888     esac
 889 fi
 890
 891 # Default libgloss CPU subdirectory.
 892 libgloss_dir="$target_cpu"
 893
 894 case "${target}" in
 895   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 896     libgloss_dir=wince
 897     ;;
 898   aarch64*-*-* )
 899     libgloss_dir=aarch64
 900     ;;
 901   arm*-*-*)
 902     libgloss_dir=arm
 903     ;;
 904   cris-*-* | crisv32-*-*)
 905     libgloss_dir=cris
 906     ;;
 907   hppa*-*-*)
 908     libgloss_dir=pa
 909     ;;
 910   i[[3456789]]86-*-*)
 911     libgloss_dir=i386
 912     ;;
 913   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 914     libgloss_dir=m68hc11
 915     ;;
 916   m68*-*-* | fido-*-*)
 917     libgloss_dir=m68k
 918     ;;
 919   mips*-*-*)
 920     libgloss_dir=mips
 921     ;;
 922   powerpc*-*-*)
 923     libgloss_dir=rs6000
 924     ;;
 925   pru-*-*)
 926     libgloss_dir=pru
 927     ;;
 928   sparc*-*-*)
 929     libgloss_dir=sparc
 930     ;;
 931 esac
 932
 933 # Disable newlib and libgloss for various target OSes.
 934 case "${target}" in
 935   alpha*-dec-osf*)
 936     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 937     ;;
 938   i[[3456789]]86-*-linux*)
 939     # This section makes it possible to build newlib natively on linux.
 940     # If we are using a cross compiler then don't configure newlib.
 941     if test x${is_cross_compiler} != xno ; then
 942       noconfigdirs="$noconfigdirs target-newlib"
 943     fi
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     # If we are not using a cross compiler, do configure newlib.
 946     # Note however, that newlib will only be configured in this situation
 947     # if the --with-newlib option has been given, because otherwise
 948     # 'target-newlib' will appear in skipdirs.
 949     ;;
 950   i[[3456789]]86-*-rdos*)
 951     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 952     ;;
 953   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 954     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 955     ;;
 956   sparc-*-sunos4*)
 957     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 958     ;;
 959   bpf-*-*)
 960     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 961     ;;
 962   *-*-aix*)
 963     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 964     ;;
 965   *-*-beos*)
 966     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 967     ;;
 968   *-*-chorusos)
 969     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 970     ;;
 971   *-*-dragonfly*)
 972     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 973     ;;
 974   *-*-freebsd*)
 975     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 976     ;;
 977   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 978     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 979     ;;
 980   *-*-lynxos*)
 981     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 982     ;;
 983   *-*-mingw*)
 984     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     ;;
 986   *-*-netbsd*)
 987     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 988     ;;
 989   *-*-netware*)
 990     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 991     ;;
 992   *-*-tpf*)
 993     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 994     ;;
 995   *-*-uclinux*)
 996     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 997     ;;
 998   *-*-vxworks*)
 999     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1000     ;;
1001 esac
1002
1003 case "${target}" in
1004   *-*-chorusos)
1005     ;;
1006   aarch64-*-darwin*)
1007     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1008     noconfigdirs="$noconfigdirs sim target-rda"
1009     ;;
1010   amdgcn*-*-*)
1011     ;;
1012   arm-*-darwin*)
1013     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1014     noconfigdirs="$noconfigdirs sim target-rda"
1015     ;;
1016   powerpc-*-darwin*)
1017     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1018     noconfigdirs="$noconfigdirs sim target-rda"
1019     ;;
1020   i[[3456789]]86-*-darwin*)
1021     noconfigdirs="$noconfigdirs ld gprof"
1022     noconfigdirs="$noconfigdirs sim target-rda"
1023     ;;
1024   x86_64-*-darwin[[912]]*)
1025     noconfigdirs="$noconfigdirs ld gas gprof"
1026     noconfigdirs="$noconfigdirs sim target-rda"
1027     ;;
1028   *-*-darwin*)
1029     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1030     noconfigdirs="$noconfigdirs sim target-rda"
1031     ;;
1032   *-*-dragonfly*)
1033     ;;
1034   *-*-freebsd*)
1035     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1036         && test -f /usr/local/include/gmp.h; then
1037       with_gmp=/usr/local
1038     fi
1039     ;;
1040   *-*-kaos*)
1041     # Remove unsupported stuff on all kaOS configurations.
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044   *-*-netbsd*)
1045     ;;
1046   *-*-netware*)
1047     ;;
1048   *-*-phoenix*)
1049     noconfigdirs="$noconfigdirs target-libgloss"
1050     ;;
1051   *-*-rtems*)
1052     noconfigdirs="$noconfigdirs target-libgloss"
1053     ;;
1054     # The tpf target doesn't support gdb yet.
1055   *-*-tpf*)
1056     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1057     ;;
1058   *-*-uclinux*)
1059     noconfigdirs="$noconfigdirs target-rda"
1060     ;;
1061   *-*-vxworks*)
1062     ;;
1063   alpha*-dec-osf*)
1064     # ld works, but does not support shared libraries.
1065     # gas doesn't generate exception information.
1066     noconfigdirs="$noconfigdirs gas ld"
1067     ;;
1068   alpha*-*-*vms*)
1069     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1070     ;;
1071   alpha*-*-*)
1072     # newlib is not 64 bit ready
1073     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1074     ;;
1075   bpf-*-*)
1076     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1077     ;;
1078   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1079     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1080     ;;
1081   arc*-*-*)
1082     noconfigdirs="$noconfigdirs sim"
1083     ;;
1084   arm-*-pe*)
1085     noconfigdirs="$noconfigdirs target-libgloss"
1086     ;;
1087   arm-*-riscix*)
1088     noconfigdirs="$noconfigdirs ld target-libgloss"
1089     ;;
1090   avr-*-*)
1091     if test x${with_avrlibc} != xno; then
1092       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1093     fi
1094     ;;
1095   c4x-*-* | tic4x-*-*)
1096     noconfigdirs="$noconfigdirs target-libgloss"
1097     ;;
1098   tic54x-*-*)
1099     noconfigdirs="$noconfigdirs target-libgloss gdb"
1100     ;;
1101   d10v-*-*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   d30v-*-*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   fr30-*-elf*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   ft32-*-*)
1111     noconfigdirs="$noconfigdirs target-rda gprof"
1112     ;;
1113   moxie-*-*)
1114     noconfigdirs="$noconfigdirs"
1115     ;;
1116   h8300*-*-*)
1117     noconfigdirs="$noconfigdirs target-libgloss"
1118     ;;
1119   h8500-*-*)
1120     noconfigdirs="$noconfigdirs target-libgloss"
1121     ;;
1122   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1123     ;;
1124   hppa*64*-*-hpux*)
1125     noconfigdirs="$noconfigdirs gdb"
1126     ;;
1127   hppa*-*-hpux11*)
1128     noconfigdirs="$noconfigdirs gdb ld"
1129     ;;
1130   hppa*64*-*-linux*)
1131     ;;
1132   hppa*-*-linux*)
1133     ;;
1134   hppa*-*-*elf* | \
1135   hppa*-*-lites* | \
1136   hppa*-*-openbsd* | \
1137   hppa*64*-*-*)
1138     ;;
1139   hppa*-*-pro*)
1140     ;;
1141   hppa*-*-*)
1142     noconfigdirs="$noconfigdirs ld"
1143     ;;
1144   i960-*-*)
1145     noconfigdirs="$noconfigdirs gdb"
1146     ;;
1147   ia64*-*-elf*)
1148     # No gdb support yet.
1149     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1150     ;;
1151   ia64*-**-hpux*)
1152     # No ld support yet.
1153     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1154     ;;
1155   ia64*-*-*vms*)
1156     # No ld support yet.
1157     noconfigdirs="$noconfigdirs libgui itcl ld"
1158     ;;
1159   i[[3456789]]86-w64-mingw*)
1160     ;;
1161   i[[3456789]]86-*-mingw*)
1162     target_configdirs="$target_configdirs target-winsup"
1163     ;;
1164   *-*-cygwin*)
1165     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1166     noconfigdirs="$noconfigdirs target-libgloss"
1167     # always build newlib if winsup directory is present.
1168     if test -d "$srcdir/winsup/cygwin"; then
1169       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1170     elif test -d "$srcdir/newlib"; then
1171       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1172     fi
1173     ;;
1174   i[[3456789]]86-*-pe)
1175     noconfigdirs="$noconfigdirs target-libgloss"
1176     ;;
1177   i[[3456789]]86-*-sco3.2v5*)
1178     # The linker does not yet know about weak symbols in COFF,
1179     # and is not configured to handle mixed ELF and COFF.
1180     noconfigdirs="$noconfigdirs ld target-libgloss"
1181     ;;
1182   i[[3456789]]86-*-sco*)
1183     noconfigdirs="$noconfigdirs gprof target-libgloss"
1184     ;;
1185   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1186     noconfigdirs="$noconfigdirs target-libgloss"
1187     ;;
1188   i[[3456789]]86-*-sysv4*)
1189     noconfigdirs="$noconfigdirs target-libgloss"
1190     ;;
1191   i[[3456789]]86-*-beos*)
1192     noconfigdirs="$noconfigdirs gdb"
1193     ;;
1194   i[[3456789]]86-*-rdos*)
1195     noconfigdirs="$noconfigdirs gdb"
1196     ;;
1197   mmix-*-*)
1198     noconfigdirs="$noconfigdirs gdb"
1199     ;;
1200   mt-*-*)
1201     noconfigdirs="$noconfigdirs sim"
1202     ;;
1203   nfp-*-*)
1204     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1205     noconfigdirs="$noconfigdirs $target_libraries"
1206     ;;
1207   pdp11-*-*)
1208     noconfigdirs="$noconfigdirs gdb gprof"
1209     ;;
1210   powerpc-*-aix*)
1211     # copied from rs6000-*-* entry
1212     noconfigdirs="$noconfigdirs gprof"
1213     ;;
1214   powerpc*-*-winnt* | powerpc*-*-pe*)
1215     target_configdirs="$target_configdirs target-winsup"
1216     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1217     # always build newlib.
1218     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1219     ;;
1220     # This is temporary until we can link against shared libraries
1221   powerpcle-*-solaris*)
1222     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1223     ;;
1224   powerpc-*-beos*)
1225     noconfigdirs="$noconfigdirs gdb"
1226     ;;
1227   rs6000-*-lynxos*)
1228     noconfigdirs="$noconfigdirs gprof"
1229     ;;
1230   rs6000-*-aix*)
1231     noconfigdirs="$noconfigdirs gprof"
1232     ;;
1233   rs6000-*-*)
1234     noconfigdirs="$noconfigdirs gprof"
1235     ;;
1236   m68k-apollo-*)
1237     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1238     ;;
1239   microblaze*)
1240     noconfigdirs="$noconfigdirs gprof"
1241     ;;
1242   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1243     if test x$with_newlib = xyes; then
1244       noconfigdirs="$noconfigdirs gprof"
1245     fi
1246     ;;
1247   mips*-*-irix5*)
1248     noconfigdirs="$noconfigdirs gprof target-libgloss"
1249     ;;
1250   mips*-*-irix6*)
1251     noconfigdirs="$noconfigdirs gprof target-libgloss"
1252     ;;
1253   mips*-*-bsd*)
1254     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1255     ;;
1256   mips*-*-linux*)
1257     ;;
1258   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1259   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1260     noconfigdirs="$noconfigdirs ld gas gprof"
1261     ;;
1262   mips*-*-*)
1263     noconfigdirs="$noconfigdirs gprof"
1264     ;;
1265   nvptx*-*-*)
1266     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1267     ;;
1268   sh-*-*)
1269     case "${target}" in
1270       sh*-*-elf)
1271          ;;
1272       *)
1273          noconfigdirs="$noconfigdirs target-libgloss" ;;
1274     esac
1275     ;;
1276   sparc-*-sunos4*)
1277     if test x${is_cross_compiler} = xno ; then
1278            use_gnu_ld=no
1279     fi
1280     ;;
1281   tic6x-*-*)
1282     noconfigdirs="$noconfigdirs sim"
1283     ;;
1284   tilepro*-*-* | tilegx*-*-*)
1285     noconfigdirs="$noconfigdirs sim"
1286     ;;
1287   v810-*-*)
1288     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1289     ;;
1290   vax-*-*)
1291     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1292     ;;
1293   wasm32-*-*)
1294     noconfigdirs="$noconfigdirs ld"
1295     ;;
1296 esac
1297
1298 # If we aren't building newlib, then don't build libgloss, since libgloss
1299 # depends upon some newlib header files.
1300 case "${noconfigdirs}" in
1301   *target-libgloss*) ;;
1302   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1303 esac
1304
1305 # Work in distributions that contain no compiler tools, like Autoconf.
1306 host_makefile_frag=/dev/null
1307 if test -d ${srcdir}/config ; then
1308 case "${host}" in
1309   i[[3456789]]86-*-msdosdjgpp*)
1310     host_makefile_frag="config/mh-djgpp"
1311     ;;
1312   *-cygwin*)
1313     ACX_CHECK_CYGWIN_CAT_WORKS
1314     host_makefile_frag="config/mh-cygwin"
1315     ;;
1316   *-mingw*)
1317     host_makefile_frag="config/mh-mingw"
1318     ;;
1319   alpha*-linux*)
1320     host_makefile_frag="config/mh-alpha-linux"
1321     ;;
1322   hppa*-hp-hpux10*)
1323     host_makefile_frag="config/mh-pa-hpux10"
1324     ;;
1325   hppa*-hp-hpux*)
1326     host_makefile_frag="config/mh-pa"
1327     ;;
1328   hppa*-*)
1329     host_makefile_frag="config/mh-pa"
1330     ;;
1331   *-*-darwin*)
1332     host_makefile_frag="config/mh-darwin"
1333     ;;
1334   powerpc-*-aix*)
1335     host_makefile_frag="config/mh-ppc-aix"
1336     ;;
1337   rs6000-*-aix*)
1338     host_makefile_frag="config/mh-ppc-aix"
1339     ;;
1340 esac
1341 fi
1342
1343 if test "${build}" != "${host}" ; then
1344   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1345   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1346   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1347   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1348   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1349   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1350   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1351   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1352   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1353   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1354   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1355   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1356   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1357 else
1358   AR_FOR_BUILD="\$(AR)"
1359   AS_FOR_BUILD="\$(AS)"
1360   CC_FOR_BUILD="\$(CC)"
1361   CXX_FOR_BUILD="\$(CXX)"
1362   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1363   GOC_FOR_BUILD="\$(GOC)"
1364   GDC_FOR_BUILD="\$(GDC)"
1365   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1366   LD_FOR_BUILD="\$(LD)"
1367   NM_FOR_BUILD="\$(NM)"
1368   RANLIB_FOR_BUILD="\$(RANLIB)"
1369   WINDRES_FOR_BUILD="\$(WINDRES)"
1370   WINDMC_FOR_BUILD="\$(WINDMC)"
1371 fi
1372
1373 AC_PROG_CC
1374 AC_PROG_CXX
1375
1376 # We must set the default linker to the linker used by gcc for the correct
1377 # operation of libtool.  If LD is not defined and we are using gcc, try to
1378 # set the LD default to the ld used by gcc.
1379 if test -z "$LD"; then
1380   if test "$GCC" = yes; then
1381     case $build in
1382     *-*-mingw*)
1383       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1384     *)
1385       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1386     esac
1387     case $gcc_prog_ld in
1388     # Accept absolute paths.
1389     [[\\/]* | [A-Za-z]:[\\/]*)]
1390       LD="$gcc_prog_ld" ;;
1391     esac
1392   fi
1393 fi
1394
1395 # Check whether -static-libstdc++ -static-libgcc is supported.
1396 have_static_libs=no
1397 if test "$GCC" = yes; then
1398   saved_LDFLAGS="$LDFLAGS"
1399
1400   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1401   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1402   AC_LANG_PUSH(C++)
1403   AC_LINK_IFELSE([AC_LANG_SOURCE([
1404 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1405 #error -static-libstdc++ not implemented
1406 #endif
1407 int main() {}])],
1408     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1409     [AC_MSG_RESULT([no])])
1410   AC_LANG_POP(C++)
1411
1412   LDFLAGS="$saved_LDFLAGS"
1413 fi
1414
1415 ACX_PROG_GNAT
1416 ACX_PROG_CMP_IGNORE_INITIAL
1417
1418 AC_ARG_ENABLE([bootstrap],
1419 [AS_HELP_STRING([--enable-bootstrap],
1420                 [enable bootstrapping @<:@yes if native build@:>@])],,
1421 enable_bootstrap=default)
1422
1423 # Issue errors and warnings for invalid/strange bootstrap combinations.
1424 if test -r $srcdir/gcc/configure; then
1425   have_compiler=yes
1426 else
1427   have_compiler=no
1428 fi
1429
1430 case "$have_compiler:$host:$target:$enable_bootstrap" in
1431   *:*:*:no) ;;
1432
1433   # Default behavior.  Enable bootstrap if we have a compiler
1434   # and we are in a native configuration.
1435   yes:$build:$build:default)
1436     enable_bootstrap=yes ;;
1437
1438   *:*:*:default)
1439     enable_bootstrap=no ;;
1440
1441   # We have a compiler and we are in a native configuration, bootstrap is ok
1442   yes:$build:$build:yes)
1443     ;;
1444
1445   # Other configurations, but we have a compiler.  Assume the user knows
1446   # what he's doing.
1447   yes:*:*:yes)
1448     AC_MSG_WARN([trying to bootstrap a cross compiler])
1449     ;;
1450
1451   # No compiler: if they passed --enable-bootstrap explicitly, fail
1452   no:*:*:yes)
1453     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1454
1455   # Fail if wrong command line
1456   *)
1457     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1458     ;;
1459 esac
1460
1461 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1462 # C++98 compiler can still start the bootstrap.
1463 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1464   CXX="$CXX -std=gnu++98"
1465 fi
1466
1467 # Used for setting $lt_cv_objdir
1468 _LT_CHECK_OBJDIR
1469
1470 # Check for GMP, MPFR and MPC
1471 gmplibs="-lmpc -lmpfr -lgmp"
1472 gmpinc=
1473 have_gmp=no
1474
1475 # Specify a location for mpc
1476 # check for this first so it ends up on the link line before mpfr.
1477 AC_ARG_WITH(mpc,
1478 [AS_HELP_STRING([--with-mpc=PATH],
1479                 [specify prefix directory for installed MPC package.
1480                  Equivalent to --with-mpc-include=PATH/include
1481                  plus --with-mpc-lib=PATH/lib])])
1482 AC_ARG_WITH(mpc-include,
1483 [AS_HELP_STRING([--with-mpc-include=PATH],
1484                 [specify directory for installed MPC include files])])
1485 AC_ARG_WITH(mpc-lib,
1486 [AS_HELP_STRING([--with-mpc-lib=PATH],
1487                 [specify directory for the installed MPC library])])
1488
1489 if test "x$with_mpc" != x; then
1490   gmplibs="-L$with_mpc/lib $gmplibs"
1491   gmpinc="-I$with_mpc/include $gmpinc"
1492 fi
1493 if test "x$with_mpc_include" != x; then
1494   gmpinc="-I$with_mpc_include $gmpinc"
1495 fi
1496 if test "x$with_mpc_lib" != x; then
1497   gmplibs="-L$with_mpc_lib $gmplibs"
1498 fi
1499 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1500   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1501   gmpinc='-I$$s/mpc/src '"$gmpinc"
1502   # Do not test the mpc version.  Assume that it is sufficient, since
1503   # it is in the source tree, and the library has not been built yet
1504   # but it would be included on the link line in the version check below
1505   # hence making the test fail.
1506   have_gmp=yes
1507 fi
1508
1509 # Specify a location for mpfr
1510 # check for this first so it ends up on the link line before gmp.
1511 AC_ARG_WITH(mpfr-dir,
1512 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1513 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1514 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1515
1516 AC_ARG_WITH(mpfr,
1517 [AS_HELP_STRING([--with-mpfr=PATH],
1518                 [specify prefix directory for installed MPFR package.
1519                  Equivalent to --with-mpfr-include=PATH/include
1520                  plus --with-mpfr-lib=PATH/lib])])
1521 AC_ARG_WITH(mpfr-include,
1522 [AS_HELP_STRING([--with-mpfr-include=PATH],
1523                 [specify directory for installed MPFR include files])])
1524 AC_ARG_WITH(mpfr-lib,
1525 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1526                 [specify directory for the installed MPFR library])])
1527
1528 if test "x$with_mpfr" != x; then
1529   gmplibs="-L$with_mpfr/lib $gmplibs"
1530   gmpinc="-I$with_mpfr/include $gmpinc"
1531 fi
1532 if test "x$with_mpfr_include" != x; then
1533   gmpinc="-I$with_mpfr_include $gmpinc"
1534 fi
1535 if test "x$with_mpfr_lib" != x; then
1536   gmplibs="-L$with_mpfr_lib $gmplibs"
1537 fi
1538 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1539   # MPFR v3.1.0 moved the sources into a src sub-directory.
1540   if ! test -d ${srcdir}/mpfr/src; then
1541     AC_MSG_ERROR([dnl
1542 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1543   fi
1544   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1545   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1546   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1547   # Do not test the mpfr version.  Assume that it is sufficient, since
1548   # it is in the source tree, and the library has not been built yet
1549   # but it would be included on the link line in the version check below
1550   # hence making the test fail.
1551   have_gmp=yes
1552 fi
1553
1554 # Specify a location for gmp
1555 AC_ARG_WITH(gmp-dir,
1556 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1557 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1558 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1559
1560 AC_ARG_WITH(gmp,
1561 [AS_HELP_STRING([--with-gmp=PATH],
1562                 [specify prefix directory for the installed GMP package.
1563                  Equivalent to --with-gmp-include=PATH/include
1564                  plus --with-gmp-lib=PATH/lib])])
1565 AC_ARG_WITH(gmp-include,
1566 [AS_HELP_STRING([--with-gmp-include=PATH],
1567                 [specify directory for installed GMP include files])])
1568 AC_ARG_WITH(gmp-lib,
1569 [AS_HELP_STRING([--with-gmp-lib=PATH],
1570                 [specify directory for the installed GMP library])])
1571
1572
1573 if test "x$with_gmp" != x; then
1574   gmplibs="-L$with_gmp/lib $gmplibs"
1575   gmpinc="-I$with_gmp/include $gmpinc"
1576 fi
1577 if test "x$with_gmp_include" != x; then
1578   gmpinc="-I$with_gmp_include $gmpinc"
1579 fi
1580 if test "x$with_gmp_lib" != x; then
1581   gmplibs="-L$with_gmp_lib $gmplibs"
1582 fi
1583 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1584   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1585   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1586   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1587   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1588   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1589   # Do not test the gmp version.  Assume that it is sufficient, since
1590   # it is in the source tree, and the library has not been built yet
1591   # but it would be included on the link line in the version check below
1592   # hence making the test fail.
1593   have_gmp=yes
1594 fi
1595
1596 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1597   have_gmp=yes
1598   saved_CFLAGS="$CFLAGS"
1599   CFLAGS="$CFLAGS $gmpinc"
1600   # Check for the recommended and required versions of GMP.
1601   AC_MSG_CHECKING([for the correct version of gmp.h])
1602   AC_TRY_COMPILE([#include "gmp.h"],[
1603   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1604   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1605   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1606   choke me
1607   #endif
1608   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1609   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1610   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1611   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1612   choke me
1613   #endif
1614   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1615    [AC_MSG_RESULT([no]); have_gmp=no])
1616
1617   # If we have GMP, check the MPFR version.
1618   if test x"$have_gmp" = xyes; then
1619     # Check for the recommended and required versions of MPFR.
1620     AC_MSG_CHECKING([for the correct version of mpfr.h])
1621     AC_TRY_COMPILE([#include <gmp.h>
1622     #include <mpfr.h>],[
1623     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1624     choke me
1625     #endif
1626     ], [AC_TRY_COMPILE([#include <gmp.h>
1627     #include <mpfr.h>],[
1628     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1629     choke me
1630     #endif
1631     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1632      [AC_MSG_RESULT([no]); have_gmp=no])
1633   fi
1634
1635   # Check for the MPC header version.
1636   if test x"$have_gmp" = xyes ; then
1637     # Check for the recommended and required versions of MPC.
1638     AC_MSG_CHECKING([for the correct version of mpc.h])
1639     AC_TRY_COMPILE([#include <mpc.h>],[
1640     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1641     choke me
1642     #endif
1643     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1644     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1645     choke me
1646     #endif
1647     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1648      [AC_MSG_RESULT([no]); have_gmp=no])
1649   fi
1650
1651   # Now check the MPFR library.
1652   if test x"$have_gmp" = xyes; then
1653     saved_LIBS="$LIBS"
1654     LIBS="$LIBS $gmplibs"
1655     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1656     AC_TRY_LINK([#include <mpc.h>],[
1657     mpfr_t n;
1658     mpfr_t x;
1659     mpc_t c;
1660     int t;
1661     mpfr_init (n);
1662     mpfr_init (x);
1663     mpfr_atan2 (n, n, x, MPFR_RNDN);
1664     mpfr_erfc (n, x, MPFR_RNDN);
1665     mpfr_subnormalize (x, t, MPFR_RNDN);
1666     mpfr_clear(n);
1667     mpfr_clear(x);
1668     mpc_init2 (c, 53);
1669     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1670     mpc_cosh (c, c, MPC_RNDNN);
1671     mpc_pow (c, c, c, MPC_RNDNN);
1672     mpc_acosh (c, c, MPC_RNDNN);
1673     mpc_clear (c);
1674     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1675     LIBS="$saved_LIBS"
1676   fi
1677
1678   CFLAGS="$saved_CFLAGS"
1679
1680 # The library versions listed in the error message below should match
1681 # the HARD-minimums enforced above.
1682   if test x$have_gmp != xyes; then
1683     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1684 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1685 their locations.  Source code for these libraries can be found at
1686 their respective hosting sites as well as at
1687 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1688 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1689 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1690 make sure that you have installed both the libraries and the header
1691 files.  They may be located in separate packages.])
1692   fi
1693 fi
1694
1695 # Flags needed for both GMP, MPFR and/or MPC.
1696 AC_SUBST(gmplibs)
1697 AC_SUBST(gmpinc)
1698 AC_SUBST(extra_mpfr_configure_flags)
1699 AC_SUBST(extra_mpc_gmp_configure_flags)
1700 AC_SUBST(extra_mpc_mpfr_configure_flags)
1701 AC_SUBST(extra_isl_gmp_configure_flags)
1702
1703 # Libraries to use for stage1 or when not bootstrapping.
1704 AC_ARG_WITH(stage1-libs,
1705 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1706 [if test "$withval" = "no" -o "$withval" = "yes"; then
1707    stage1_libs=
1708  else
1709    stage1_libs=$withval
1710  fi],
1711 [stage1_libs=])
1712 AC_SUBST(stage1_libs)
1713
1714 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1715 # default is yes if gcc is being built; no otherwise.  The reason for
1716 # this default is that gdb is sometimes linked against GNU Source
1717 # Highlight, which is a shared library that uses C++ exceptions.  In
1718 # this case, -static-libstdc++ will cause crashes.
1719 AC_ARG_WITH(static-standard-libraries,
1720 [AS_HELP_STRING([--with-static-standard-libraries],
1721                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1722 [], [with_static_standard_libraries=auto])
1723 if test "$with_static_standard_libraries" = auto; then
1724   with_static_standard_libraries=$have_compiler
1725 fi
1726
1727 # Linker flags to use for stage1 or when not bootstrapping.
1728 AC_ARG_WITH(stage1-ldflags,
1729 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1730 [if test "$withval" = "no" -o "$withval" = "yes"; then
1731    stage1_ldflags=
1732  else
1733    stage1_ldflags=$withval
1734  fi],
1735 [stage1_ldflags=
1736  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1737  # if supported.  But if the user explicitly specified the libraries to use,
1738  # trust that they are doing what they want.
1739  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1740      -a "$have_static_libs" = yes; then
1741    stage1_ldflags="-static-libstdc++ -static-libgcc"
1742  fi])
1743 AC_SUBST(stage1_ldflags)
1744
1745 # Libraries to use for stage2 and later builds.
1746 AC_ARG_WITH(boot-libs,
1747 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1748 [if test "$withval" = "no" -o "$withval" = "yes"; then
1749    poststage1_libs=
1750  else
1751    poststage1_libs=$withval
1752  fi],
1753 [poststage1_libs=])
1754 AC_SUBST(poststage1_libs)
1755
1756 # Linker flags to use for stage2 and later builds.
1757 AC_ARG_WITH(boot-ldflags,
1758 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1759                 [linker flags for stage2 and later])],
1760 [if test "$withval" = "no" -o "$withval" = "yes"; then
1761    poststage1_ldflags=
1762  else
1763    poststage1_ldflags=$withval
1764  fi],
1765 [poststage1_ldflags=
1766  # In stages 2 and 3, default to linking libstdc++ and libgcc
1767  # statically.  But if the user explicitly specified the libraries to
1768  # use, trust that they are doing what they want.
1769  if test "$poststage1_libs" = ""; then
1770    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1771  fi])
1772 AC_SUBST(poststage1_ldflags)
1773
1774 # GCC GRAPHITE dependency isl.
1775 # Basic setup is inlined here, actual checks are in config/isl.m4
1776
1777 AC_ARG_WITH(isl,
1778   [AS_HELP_STRING(
1779    [--with-isl=PATH],
1780    [Specify prefix directory for the installed isl package.
1781     Equivalent to --with-isl-include=PATH/include
1782     plus --with-isl-lib=PATH/lib])])
1783
1784 # Treat --without-isl as a request to disable
1785 # GRAPHITE support and skip all following checks.
1786 if test "x$with_isl" != "xno"; then
1787   # Check for isl
1788   dnl Provide configure switches and initialize islinc & isllibs
1789   dnl with user input.
1790   ISL_INIT_FLAGS
1791   dnl The versions of isl that work for Graphite
1792   ISL_CHECK_VERSION()
1793   dnl Only execute fail-action, if isl has been requested.
1794   ISL_IF_FAILED([
1795     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1796 fi
1797
1798 # If the isl check failed, disable builds of in-tree variant of isl
1799 if test "x$with_isl" = xno ||
1800    test "x$gcc_cv_isl" = xno; then
1801   noconfigdirs="$noconfigdirs isl"
1802   islinc=
1803 fi
1804
1805 AC_SUBST(isllibs)
1806 AC_SUBST(islinc)
1807
1808 # Check for LTO support.
1809 AC_ARG_ENABLE(lto,
1810 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1811 enable_lto=$enableval,
1812 enable_lto=yes; default_enable_lto=yes)
1813
1814 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1815   build_lto_plugin=yes
1816 ],[if test x"$default_enable_lto" = x"yes" ; then
1817     case $target in
1818       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1819       # On other non-ELF platforms, LTO has yet to be validated.
1820       *) enable_lto=no ;;
1821     esac
1822   else
1823   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1824   # It would also be nice to check the binutils support, but we don't
1825   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1826   # warn during gcc/ subconfigure; unless you're bootstrapping with
1827   # -flto it won't be needed until after installation anyway.
1828     case $target in
1829       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1830       *) if test x"$enable_lto" = x"yes"; then
1831         AC_MSG_ERROR([LTO support is not enabled for this target.])
1832         fi
1833       ;;
1834     esac
1835   fi
1836   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1837   # Build it unless LTO was explicitly disabled.
1838   case $target in
1839     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1840     *) ;;
1841   esac
1842 ])
1843
1844 AC_ARG_ENABLE(linker-plugin-configure-flags,
1845   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1846     [additional flags for configuring linker plugins @<:@none@:>@])],
1847   extra_linker_plugin_configure_flags=$enableval,
1848   extra_linker_plugin_configure_flags=)
1849 AC_SUBST(extra_linker_plugin_configure_flags)
1850 AC_ARG_ENABLE(linker-plugin-flags,
1851   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1852     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1853   extra_linker_plugin_flags=$enableval,
1854   extra_linker_plugin_flags=)
1855 AC_SUBST(extra_linker_plugin_flags)
1856
1857 # Enable --enable-host-shared.
1858 # Checked early to determine whether jit is an 'all' language
1859 AC_ARG_ENABLE(host-shared,
1860 [AS_HELP_STRING([--enable-host-shared],
1861                 [build host code as shared libraries])],
1862 [host_shared=$enableval], [host_shared=no])
1863 AC_SUBST(host_shared)
1864
1865 # By default, C and C++ are the only stage 1 languages.
1866 stage1_languages=,c,
1867
1868 # Target libraries that we bootstrap.
1869 bootstrap_target_libs=,target-libgcc,
1870
1871 # Figure out what language subdirectories are present.
1872 # Look if the user specified --enable-languages="..."; if not, use
1873 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1874 # go away some day.
1875 # NB:  embedded tabs in this IF block -- do not untabify
1876 if test -d ${srcdir}/gcc; then
1877   if test x"${enable_languages+set}" != xset; then
1878     if test x"${LANGUAGES+set}" = xset; then
1879       enable_languages="${LANGUAGES}"
1880         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1881     else
1882       enable_languages=default
1883     fi
1884   else
1885     if test x"${enable_languages}" = x ||
1886        test x"${enable_languages}" = xyes;
1887        then
1888       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1889       exit 1
1890     fi
1891   fi
1892   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1893
1894   # 'f95' is the old name for the 'fortran' language. We issue a warning
1895   # and make the substitution.
1896   case ,${enable_languages}, in
1897     *,f95,*)
1898       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1899       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1900       ;;
1901   esac
1902
1903   # If bootstrapping, C++ must be enabled.
1904   case ",$enable_languages,:$enable_bootstrap" in
1905     *,c++,*:*) ;;
1906     *:yes)
1907       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1908         enable_languages="${enable_languages},c++"
1909       else
1910         AC_MSG_ERROR([bootstrapping requires c++ sources])
1911       fi
1912       ;;
1913   esac
1914
1915   # First scan to see if an enabled language requires some other language.
1916   # We assume that a given config-lang.in will list all the language
1917   # front ends it requires, even if some are required indirectly.
1918   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1919     case ${lang_frag} in
1920       ..) ;;
1921       # The odd quoting in the next line works around
1922       # an apparent bug in bash 1.12 on linux.
1923       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1924       *)
1925         # From the config-lang.in, get $language, $lang_requires, and
1926         # $lang_requires_boot_languages.
1927         language=
1928         lang_requires=
1929         lang_requires_boot_languages=
1930         # set srcdir during sourcing lang_frag to the gcc dir.
1931         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1932         # polutes this shell
1933         saved_srcdir=${srcdir}
1934         srcdir=${srcdir}/gcc . ${lang_frag}
1935         srcdir=${saved_srcdir}
1936         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1937           case ,${enable_languages}, in
1938             *,$other,*) ;;
1939             *,default,*) ;;
1940             *,all,*) ;;
1941             *,$language,*)
1942               echo " \`$other' language required by \`$language'; enabling" 1>&2
1943               enable_languages="${enable_languages},${other}"
1944               ;;
1945           esac
1946         done
1947         for other in ${lang_requires_boot_languages} ; do
1948           if test "$other" != "c"; then
1949             case ,${enable_stage1_languages}, in
1950               *,$other,*) ;;
1951               *,default,*) ;;
1952               *,all,*) ;;
1953               *)
1954                 case ,${enable_languages}, in
1955                   *,$language,*)
1956                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1957                     enable_stage1_languages="$enable_stage1_languages,${other}"
1958                     ;;
1959                 esac
1960                 ;;
1961             esac
1962           fi
1963         done
1964         ;;
1965     esac
1966   done
1967
1968   new_enable_languages=,c,
1969
1970   # If LTO is enabled, add the LTO front end.
1971   if test "$enable_lto" = "yes" ; then
1972     case ,${enable_languages}, in
1973       *,lto,*) ;;
1974       *) enable_languages="${enable_languages},lto" ;;
1975     esac
1976     if test "${build_lto_plugin}" = "yes" ; then
1977       configdirs="$configdirs lto-plugin"
1978     fi
1979   fi
1980
1981   # If we're building an offloading compiler, add the LTO front end.
1982   if test x"$enable_as_accelerator_for" != x ; then
1983     case ,${enable_languages}, in
1984       *,lto,*) ;;
1985       *) enable_languages="${enable_languages},lto" ;;
1986     esac
1987   fi
1988
1989   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1990   potential_languages=,c,
1991
1992   enabled_target_libs=
1993   disabled_target_libs=
1994
1995   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1996     case ${lang_frag} in
1997       ..) ;;
1998       # The odd quoting in the next line works around
1999       # an apparent bug in bash 1.12 on linux.
2000       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2001       *)
2002         # From the config-lang.in, get $language, $target_libs,
2003         # $lang_dirs, $boot_language, and $build_by_default
2004         language=
2005         target_libs=
2006         lang_dirs=
2007         subdir_requires=
2008         boot_language=no
2009         build_by_default=yes
2010         # set srcdir during sourcing.  See above about save & restore
2011         saved_srcdir=${srcdir}
2012         srcdir=${srcdir}/gcc . ${lang_frag}
2013         srcdir=${saved_srcdir}
2014         if test x${language} = x; then
2015           echo "${lang_frag} doesn't set \$language." 1>&2
2016           exit 1
2017         fi
2018
2019         if test "$language" = "c++"; then
2020           boot_language=yes
2021         fi
2022
2023         add_this_lang=no
2024         # C is always enabled, so no need to add it again
2025         if test "$language" != "c"; then
2026           case ,${enable_languages}, in
2027             *,${language},*)
2028               # Language was explicitly selected; include it
2029               add_this_lang=yes
2030               ;;
2031             *,all,*)
2032               # All languages are enabled
2033               add_this_lang=all
2034               ;;
2035             *,default,*)
2036               # 'default' was selected, select it if it is a default language
2037               add_this_lang=${build_by_default}
2038               ;;
2039           esac
2040         fi
2041
2042         # Disable languages that need other directories if these aren't available.
2043         for i in $subdir_requires; do
2044           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2045           case ${add_this_lang} in
2046             yes)
2047               # Specifically requested language; tell them.
2048               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2049               ;;
2050             all)
2051               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2052               add_this_lang=unsupported
2053               ;;
2054             *)
2055               # Silently disable.
2056               add_this_lang=unsupported
2057               ;;
2058           esac
2059         done
2060
2061         # Disable Ada if no preexisting GNAT is available.
2062         case ${add_this_lang}:${language}:${have_gnat} in
2063           yes:ada:no)
2064             # Specifically requested language; tell them.
2065             AC_MSG_ERROR([GNAT is required to build $language])
2066             ;;
2067           all:ada:no)
2068             AC_MSG_WARN([GNAT is required to build $language])
2069             add_this_lang=unsupported
2070             ;;
2071           *:ada:no)
2072             # Silently disable.
2073             add_this_lang=unsupported
2074             ;;
2075         esac
2076
2077         # Disable jit if -enable-host-shared not specified
2078         case ${add_this_lang}:${language}:${host_shared} in
2079           yes:jit:no)
2080             # PR jit/64780: explicitly specify --enable-host-shared
2081             AC_MSG_ERROR([
2082 Enabling language "jit" requires --enable-host-shared.
2083
2084 --enable-host-shared typically slows the rest of the compiler down by
2085 a few %, so you must explicitly enable it.
2086
2087 If you want to build both the jit and the regular compiler, it is often
2088 best to do this via two separate configure/builds, in separate
2089 directories, to avoid imposing the performance cost of
2090 --enable-host-shared on the regular compiler.])
2091             ;;
2092           all:jit:no)
2093             AC_MSG_WARN([--enable-host-shared required to build $language])
2094             add_this_lang=unsupported
2095             ;;
2096           *:jit:no)
2097             # Silently disable.
2098             add_this_lang=unsupported
2099             ;;
2100         esac
2101
2102         # Disable a language that is unsupported by the target.
2103         case "${add_this_lang}: $unsupported_languages " in
2104           no:*) ;;
2105           unsupported:*) ;;
2106           *:*" $language "*)
2107             AC_MSG_WARN([${language} not supported for this target])
2108             add_this_lang=unsupported
2109             ;;
2110         esac
2111
2112         case $add_this_lang in
2113           unsupported)
2114             # Remove language-dependent dirs.
2115             disabled_target_libs="$disabled_target_libs $target_libs"
2116             noconfigdirs="$noconfigdirs $lang_dirs"
2117             ;;
2118           no)
2119             # Remove language-dependent dirs; still show language as supported.
2120             disabled_target_libs="$disabled_target_libs $target_libs"
2121             noconfigdirs="$noconfigdirs $lang_dirs"
2122             potential_languages="${potential_languages}${language},"
2123             ;;
2124           all|yes)
2125             new_enable_languages="${new_enable_languages}${language},"
2126             potential_languages="${potential_languages}${language},"
2127             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2128             enabled_target_libs="$enabled_target_libs $target_libs"
2129             case "${boot_language}:,$enable_stage1_languages," in
2130               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2131                 # Add to (comma-separated) list of stage 1 languages.
2132                 case ",$stage1_languages," in
2133                   *,$language,* | ,yes, | ,all,) ;;
2134                   *) stage1_languages="${stage1_languages}${language}," ;;
2135                 esac
2136                 # We need to bootstrap any supporting libraries.
2137                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2138                 ;;
2139             esac
2140             ;;
2141         esac
2142         ;;
2143     esac
2144   done
2145
2146   # Add target libraries which are only needed for disabled languages
2147   # to noconfigdirs.
2148   if test -n "$disabled_target_libs"; then
2149     for dir in $disabled_target_libs; do
2150       case " $enabled_target_libs " in
2151       *" ${dir} "*) ;;
2152       *) noconfigdirs="$noconfigdirs $dir" ;;
2153       esac
2154     done
2155   fi
2156
2157   AC_ARG_ENABLE(stage1-languages,
2158   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2159                   [choose additional languages to build during
2160                   stage1.  Mostly useful for compiler development])],
2161   [case ,${enable_stage1_languages}, in
2162     ,no,|,,)
2163       # Set it to something that will have no effect in the loop below
2164       enable_stage1_languages=c ;;
2165     ,yes,)
2166       enable_stage1_languages=`echo $new_enable_languages | \
2167         sed -e "s/^,//" -e "s/,$//" ` ;;
2168     *,all,*)
2169       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2170         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2171   esac
2172
2173   # Add "good" languages from enable_stage1_languages to stage1_languages,
2174   # while "bad" languages go in missing_languages.  Leave no duplicates.
2175   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2176     case $potential_languages in
2177       *,$i,*)
2178         case $stage1_languages in
2179           *,$i,*) ;;
2180           *) stage1_languages="$stage1_languages$i," ;;
2181         esac ;;
2182       *)
2183         case $missing_languages in
2184           *,$i,*) ;;
2185           *) missing_languages="$missing_languages$i," ;;
2186         esac ;;
2187      esac
2188   done])
2189
2190   # Remove leading/trailing commas that were added for simplicity
2191   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2192   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2193   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2194   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2195
2196   if test "x$missing_languages" != x; then
2197     AC_MSG_ERROR([
2198 The following requested languages could not be built: ${missing_languages}
2199 Supported languages are: ${potential_languages}])
2200   fi
2201   if test "x$new_enable_languages" != "x$enable_languages"; then
2202     echo The following languages will be built: ${new_enable_languages}
2203     enable_languages="$new_enable_languages"
2204   fi
2205
2206   AC_SUBST(stage1_languages)
2207   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2208 fi
2209
2210 # Handle --disable-<component> generically.
2211 for dir in $configdirs $build_configdirs $target_configdirs ; do
2212   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2213   varname=`echo $dirname | sed -e s/+/_/g`
2214   if eval test x\${enable_${varname}} "=" xno ; then
2215     noconfigdirs="$noconfigdirs $dir"
2216   fi
2217 done
2218
2219 # Check for Boehm's garbage collector
2220 AC_ARG_ENABLE(objc-gc,
2221 [AS_HELP_STRING([--enable-objc-gc],
2222                 [enable use of Boehm's garbage collector with the
2223                  GNU Objective-C runtime])])
2224 AC_ARG_WITH([target-bdw-gc],
2225 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2226                 [specify prefix directory for installed bdw-gc package.
2227                  Equivalent to --with-target-bdw-gc-include=PATH/include
2228                  plus --with-target-bdw-gc-lib=PATH/lib])])
2229 AC_ARG_WITH([target-bdw-gc-include],
2230 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2231                 [specify directories for installed bdw-gc include files])])
2232 AC_ARG_WITH([target-bdw-gc-lib],
2233 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2234                 [specify directories for installed bdw-gc library])])
2235
2236 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2237   AC_MSG_CHECKING([for bdw garbage collector])
2238   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2239     dnl no bdw-gw options, assume default locations
2240     AC_MSG_RESULT([using bdw-gc in default locations])
2241   else
2242     dnl bdw-gw options, first error checking, complete checking in libobjc
2243     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2244       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2245     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2246       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2247     else
2248       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2249     fi
2250   fi
2251 esac
2252
2253 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2254 case ,${enable_languages}, in
2255   *,c++,*)
2256     # Disable libitm, libsanitizer if we're not building libstdc++
2257     case "${noconfigdirs}" in
2258       *target-libstdc++-v3*)
2259         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2260         ;;
2261       *) ;;
2262     esac
2263     ;;
2264   *)
2265     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2266     ;;
2267 esac
2268
2269 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2270 # $build_configdirs and $target_configdirs.
2271 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2272
2273 notsupp=""
2274 for dir in . $skipdirs $noconfigdirs ; do
2275   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2276   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2277     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2278     if test -r $srcdir/$dirname/configure ; then
2279       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2280         true
2281       else
2282         notsupp="$notsupp $dir"
2283       fi
2284     fi
2285   fi
2286   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2287     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2288     if test -r $srcdir/$dirname/configure ; then
2289       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2290         true
2291       else
2292         notsupp="$notsupp $dir"
2293       fi
2294     fi
2295   fi
2296   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2297     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2298     if test -r $srcdir/$dirname/configure ; then
2299       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2300         true
2301       else
2302         notsupp="$notsupp $dir"
2303       fi
2304     fi
2305   fi
2306 done
2307
2308 # Quietly strip out all directories which aren't configurable in this tree.
2309 # This relies on all configurable subdirectories being autoconfiscated, which
2310 # is now the case.
2311 build_configdirs_all="$build_configdirs"
2312 build_configdirs=
2313 for i in ${build_configdirs_all} ; do
2314   j=`echo $i | sed -e s/build-//g`
2315   if test -f ${srcdir}/$j/configure ; then
2316     build_configdirs="${build_configdirs} $i"
2317   fi
2318 done
2319
2320 configdirs_all="$configdirs"
2321 configdirs=
2322 for i in ${configdirs_all} ; do
2323   if test -f ${srcdir}/$i/configure ; then
2324     configdirs="${configdirs} $i"
2325   fi
2326 done
2327
2328 target_configdirs_all="$target_configdirs"
2329 target_configdirs=
2330 for i in ${target_configdirs_all} ; do
2331   j=`echo $i | sed -e s/target-//g`
2332   if test -f ${srcdir}/$j/configure ; then
2333     target_configdirs="${target_configdirs} $i"
2334   fi
2335 done
2336
2337 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2338 # so we have to add it after the preceding checks.
2339 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2340 then
2341   case " $configdirs " in
2342     *" libiberty "*)
2343       # If we can build libiberty, we can also build libiberty-linker-plugin.
2344       configdirs="$configdirs libiberty-linker-plugin"
2345       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2346         --with-libiberty=../libiberty-linker-plugin";;
2347     *)
2348       AC_MSG_ERROR([libiberty missing]);;
2349   esac
2350 fi
2351
2352 # Sometimes we have special requirements for the host libiberty.
2353 extra_host_libiberty_configure_flags=
2354 extra_host_zlib_configure_flags=
2355 case " $configdirs " in
2356   *" lto-plugin "* | *" libcc1 "*)
2357     # When these are to be built as shared libraries, the same applies to
2358     # libiberty.
2359     extra_host_libiberty_configure_flags=--enable-shared
2360     ;;
2361   *" bfd "*)
2362     # When bfd is to be built as a shared library, the same applies to
2363     # zlib.
2364     if test "$enable_shared" = "yes"; then
2365       extra_host_zlib_configure_flags=--enable-host-shared
2366     fi
2367     ;;
2368 esac
2369 AC_SUBST(extra_host_libiberty_configure_flags)
2370 AC_SUBST(extra_host_zlib_configure_flags)
2371
2372 # Produce a warning message for the subdirs we can't configure.
2373 # This isn't especially interesting in the Cygnus tree, but in the individual
2374 # FSF releases, it's important to let people know when their machine isn't
2375 # supported by the one or two programs in a package.
2376
2377 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2378   # If $appdirs is non-empty, at least one of those directories must still
2379   # be configured, or we error out.  (E.g., if the gas release supports a
2380   # specified target in some subdirs but not the gas subdir, we shouldn't
2381   # pretend that all is well.)
2382   if test -n "$appdirs" ; then
2383     for dir in $appdirs ; do
2384       if test -r $dir/Makefile.in ; then
2385         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2386           appdirs=""
2387           break
2388         fi
2389         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2390           appdirs=""
2391           break
2392         fi
2393       fi
2394     done
2395     if test -n "$appdirs" ; then
2396       echo "*** This configuration is not supported by this package." 1>&2
2397       exit 1
2398     fi
2399   fi
2400   # Okay, some application will build, or we don't care to check.  Still
2401   # notify of subdirs not getting built.
2402   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2403   echo "    ${notsupp}" 1>&2
2404   echo "    (Any other directories should still work fine.)" 1>&2
2405 fi
2406
2407 case "$host" in
2408   *msdosdjgpp*)
2409     enable_gdbtk=no ;;
2410 esac
2411
2412 # To find our prefix, in gcc_cv_tool_prefix.
2413 ACX_TOOL_DIRS
2414
2415 copy_dirs=
2416
2417 AC_ARG_WITH([build-sysroot],
2418   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2419                   [use sysroot as the system root during the build])],
2420   [if test x"$withval" != x ; then
2421      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2422    fi],
2423   [SYSROOT_CFLAGS_FOR_TARGET=])
2424 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2425
2426 AC_ARG_WITH([debug-prefix-map],
2427   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2428                   [map A to B, C to D ... in debug information])],
2429   [if test x"$withval" != x; then
2430      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2431      for debug_map in $withval; do
2432        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2433      done
2434    fi],
2435   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2436 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2437
2438 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2439 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2440 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2441 # We want to ensure that TARGET libraries (which we know are built with
2442 # gcc) are built with "-O2 -g", so include those options when setting
2443 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2444 if test "x$CFLAGS_FOR_TARGET" = x; then
2445   if test "x${is_cross_compiler}" = xyes; then
2446     CFLAGS_FOR_TARGET="-g -O2"
2447   else
2448     CFLAGS_FOR_TARGET=$CFLAGS
2449     case " $CFLAGS " in
2450       *" -O2 "*) ;;
2451       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2452     esac
2453     case " $CFLAGS " in
2454       *" -g "* | *" -g3 "*) ;;
2455       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2456     esac
2457   fi
2458 fi
2459 AC_SUBST(CFLAGS_FOR_TARGET)
2460
2461 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2462   if test "x${is_cross_compiler}" = xyes; then
2463     CXXFLAGS_FOR_TARGET="-g -O2"
2464   else
2465     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2466     case " $CXXFLAGS " in
2467       *" -O2 "*) ;;
2468       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2469     esac
2470     case " $CXXFLAGS " in
2471       *" -g "* | *" -g3 "*) ;;
2472       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2473     esac
2474   fi
2475 fi
2476 AC_SUBST(CXXFLAGS_FOR_TARGET)
2477
2478 AC_SUBST(LDFLAGS_FOR_TARGET)
2479
2480 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2481 # the named directory are copied to $(tooldir)/sys-include.
2482 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2483   if test x${is_cross_compiler} = xno ; then
2484     echo 1>&2 '***' --with-headers is only supported when cross compiling
2485     exit 1
2486   fi
2487   if test x"${with_headers}" != xyes ; then
2488     x=${gcc_cv_tool_prefix}
2489     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2490   fi
2491 fi
2492
2493 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2494 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2495 # are permitted.
2496 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2497   if test x${is_cross_compiler} = xno ; then
2498     echo 1>&2 '***' --with-libs is only supported when cross compiling
2499     exit 1
2500   fi
2501   if test x"${with_libs}" != xyes ; then
2502     # Copy the libraries in reverse order, so that files in the first named
2503     # library override files in subsequent libraries.
2504     x=${gcc_cv_tool_prefix}
2505     for l in ${with_libs}; do
2506       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2507     done
2508   fi
2509 fi
2510
2511 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2512 #
2513 # This is done by determining whether or not the appropriate directory
2514 # is available, and by checking whether or not specific configurations
2515 # have requested that this magic not happen.
2516 #
2517 # The command line options always override the explicit settings in
2518 # configure.ac, and the settings in configure.ac override this magic.
2519 #
2520 # If the default for a toolchain is to use GNU as and ld, and you don't
2521 # want to do that, then you should use the --without-gnu-as and
2522 # --without-gnu-ld options for the configure script.  Similarly, if
2523 # the default is to use the included zlib and you don't want to do that,
2524 # you should use the --with-system-zlib option for the configure script.
2525
2526 if test x${use_gnu_as} = x &&
2527    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2528   with_gnu_as=yes
2529   extra_host_args="$extra_host_args --with-gnu-as"
2530 fi
2531
2532 if test x${use_gnu_ld} = x &&
2533    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2534   with_gnu_ld=yes
2535   extra_host_args="$extra_host_args --with-gnu-ld"
2536 fi
2537
2538 if test x${use_included_zlib} = x &&
2539    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2540   :
2541 else
2542   with_system_zlib=yes
2543   extra_host_args="$extra_host_args --with-system-zlib"
2544 fi
2545
2546 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2547 # can detect this case.
2548
2549 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2550   with_newlib=yes
2551   extra_host_args="$extra_host_args --with-newlib"
2552 fi
2553
2554 # Handle ${copy_dirs}
2555 set fnord ${copy_dirs}
2556 shift
2557 while test $# != 0 ; do
2558   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2559     :
2560   else
2561     echo Copying $1 to $2
2562
2563     # Use the install script to create the directory and all required
2564     # parent directories.
2565     if test -d $2 ; then
2566       :
2567     else
2568       echo >config.temp
2569       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2570     fi
2571
2572     # Copy the directory, assuming we have tar.
2573     # FIXME: Should we use B in the second tar?  Not all systems support it.
2574     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2575
2576     # It is the responsibility of the user to correctly adjust all
2577     # symlinks.  If somebody can figure out how to handle them correctly
2578     # here, feel free to add the code.
2579
2580     echo $1 > $2/COPIED
2581   fi
2582   shift; shift
2583 done
2584
2585 # Determine a target-dependent exec_prefix that the installed
2586 # gcc will search in.  Keep this list sorted by triplet, with
2587 # the *-*-osname triplets last.
2588 md_exec_prefix=
2589 case "${target}" in
2590   i[[34567]]86-pc-msdosdjgpp*)
2591     md_exec_prefix=/dev/env/DJDIR/bin
2592     ;;
2593   *-*-hpux* | \
2594   *-*-nto-qnx* | \
2595   *-*-solaris2*)
2596     md_exec_prefix=/usr/ccs/bin
2597     ;;
2598 esac
2599
2600 extra_arflags_for_target=
2601 extra_nmflags_for_target=
2602 extra_ranlibflags_for_target=
2603 target_makefile_frag=/dev/null
2604 case "${target}" in
2605   spu-*-*)
2606     target_makefile_frag="config/mt-spu"
2607     ;;
2608   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2609     target_makefile_frag="config/mt-sde"
2610     ;;
2611   mipsisa*-*-elfoabi*)
2612     target_makefile_frag="config/mt-mips-elfoabi"
2613     ;;
2614   mips*-*-*linux* | mips*-*-gnu*)
2615     target_makefile_frag="config/mt-mips-gnu"
2616     ;;
2617   nios2-*-elf*)
2618     target_makefile_frag="config/mt-nios2-elf"
2619     ;;
2620   *-*-linux-android*)
2621     target_makefile_frag="config/mt-android"
2622     ;;
2623   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2624     target_makefile_frag="config/mt-gnu"
2625     ;;
2626   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2627     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2628     # commands to handle both 32-bit and 64-bit objects.  These flags are
2629     # harmless if we're using GNU nm or ar.
2630     extra_arflags_for_target=" -X32_64"
2631     extra_nmflags_for_target=" -B -X32_64"
2632     ;;
2633 esac
2634
2635 alphaieee_frag=/dev/null
2636 case $target in
2637   alpha*-*-*)
2638     # This just makes sure to use the -mieee option to build target libs.
2639     # This should probably be set individually by each library.
2640     alphaieee_frag="config/mt-alphaieee"
2641     ;;
2642 esac
2643
2644 # If --enable-target-optspace always use -Os instead of -O2 to build
2645 # the target libraries, similarly if it is not specified, use -Os
2646 # on selected platforms.
2647 ospace_frag=/dev/null
2648 case "${enable_target_optspace}:${target}" in
2649   yes:*)
2650     ospace_frag="config/mt-ospace"
2651     ;;
2652   :d30v-*)
2653     ospace_frag="config/mt-d30v"
2654     ;;
2655   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2656     ospace_frag="config/mt-ospace"
2657     ;;
2658   no:* | :*)
2659     ;;
2660   *)
2661     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2662     ;;
2663 esac
2664
2665 # Some systems (e.g., one of the i386-aix systems the gas testers are
2666 # using) don't handle "\$" correctly, so don't use it here.
2667 tooldir='${exec_prefix}'/${target_noncanonical}
2668 build_tooldir=${tooldir}
2669
2670 # Create a .gdbinit file which runs the one in srcdir
2671 # and tells GDB to look there for source files.
2672
2673 if test -r ${srcdir}/.gdbinit ; then
2674   case ${srcdir} in
2675     .) ;;
2676     *) cat > ./.gdbinit <<EOF
2677 # ${NO_EDIT}
2678 dir ${srcdir}
2679 dir .
2680 source ${srcdir}/.gdbinit
2681 EOF
2682     ;;
2683   esac
2684 fi
2685
2686 # Make sure that the compiler is able to generate an executable.  If it
2687 # can't, we are probably in trouble.  We don't care whether we can run the
2688 # executable--we might be using a cross compiler--we only care whether it
2689 # can be created.  At this point the main configure script has set CC.
2690 we_are_ok=no
2691 echo "int main () { return 0; }" > conftest.c
2692 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2693 if test $? = 0 ; then
2694   if test -s conftest || test -s conftest.exe ; then
2695     we_are_ok=yes
2696   fi
2697 fi
2698 case $we_are_ok in
2699   no)
2700     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2701     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2702     rm -f conftest*
2703     exit 1
2704     ;;
2705 esac
2706 rm -f conftest*
2707
2708 # Decide which environment variable is used to find dynamic libraries.
2709 case "${host}" in
2710   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2711   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2712   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2713   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2714 esac
2715
2716 # On systems where the dynamic library environment variable is PATH,
2717 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2718 # built executables to PATH.
2719 if test "$RPATH_ENVVAR" = PATH; then
2720   GCC_SHLIB_SUBDIR=/shlib
2721 else
2722   GCC_SHLIB_SUBDIR=
2723 fi
2724
2725 # Adjust the toplevel makefile according to whether bootstrap was selected.
2726 case $enable_bootstrap in
2727   yes)
2728     bootstrap_suffix=bootstrap
2729     BUILD_CONFIG=bootstrap-debug
2730     ;;
2731   no)
2732     bootstrap_suffix=no-bootstrap
2733     BUILD_CONFIG=
2734     ;;
2735 esac
2736
2737 AC_MSG_CHECKING(for default BUILD_CONFIG)
2738
2739 AC_ARG_WITH([build-config],
2740   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2741                   [use config/NAME.mk build configuration])],
2742   [case $with_build_config in
2743    yes) with_build_config= ;;
2744    no) with_build_config= BUILD_CONFIG= ;;
2745    esac])
2746
2747 if test "x${with_build_config}" != x; then
2748   BUILD_CONFIG=$with_build_config
2749 else
2750   case $BUILD_CONFIG in
2751   bootstrap-debug)
2752     if echo "int f (void) { return 0; }" > conftest.c &&
2753        ${CC} -c conftest.c &&
2754        mv conftest.o conftest.o.g0 &&
2755        ${CC} -c -g conftest.c &&
2756        mv conftest.o conftest.o.g &&
2757        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2758       :
2759     else
2760       BUILD_CONFIG=
2761     fi
2762     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2763     ;;
2764   esac
2765 fi
2766 AC_MSG_RESULT($BUILD_CONFIG)
2767 AC_SUBST(BUILD_CONFIG)
2768
2769 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2770 AC_MSG_CHECKING([for --enable-vtable-verify])
2771 AC_ARG_ENABLE(vtable-verify,
2772 [AS_HELP_STRING([--enable-vtable-verify],
2773                 [Enable vtable verification feature])],
2774 [case "$enableval" in
2775  yes) enable_vtable_verify=yes ;;
2776  no)  enable_vtable_verify=no ;;
2777  *)   enable_vtable_verify=no;;
2778  esac],
2779 [enable_vtable_verify=no])
2780 AC_MSG_RESULT($enable_vtable_verify)
2781
2782 # Record target_configdirs and the configure arguments for target and
2783 # build configuration in Makefile.
2784 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2785 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2786 bootstrap_fixincludes=no
2787
2788 # If we are building libgomp, bootstrap it.
2789 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2790   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2791 fi
2792
2793 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2794 # or bootstrap-ubsan, bootstrap it.
2795 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2796   case "$BUILD_CONFIG" in
2797     *bootstrap-asan* | *bootstrap-ubsan* )
2798       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2799       bootstrap_fixincludes=yes
2800       ;;
2801   esac
2802 fi
2803
2804 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2805 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2806    test "$enable_vtable_verify" != no; then
2807   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2808 fi
2809
2810 # Determine whether gdb needs tk/tcl or not.
2811 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2812 # and in that case we want gdb to be built without tk.  Ugh!
2813 # In fact I believe gdb is the *only* package directly dependent on tk,
2814 # so we should be able to put the 'maybe's in unconditionally and
2815 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2816 # 100% sure that that's safe though.
2817
2818 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2819 case "$enable_gdbtk" in
2820   no)
2821     GDB_TK="" ;;
2822   yes)
2823     GDB_TK="${gdb_tk}" ;;
2824   *)
2825     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2826     # distro.  Eventually someone will fix this and move Insight, nee
2827     # gdbtk to a separate directory.
2828     if test -d ${srcdir}/gdb/gdbtk ; then
2829       GDB_TK="${gdb_tk}"
2830     else
2831       GDB_TK=""
2832     fi
2833     ;;
2834 esac
2835 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2836 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2837
2838 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2839 # else does, only include them if one of these is built.  The Makefile
2840 # provides the ordering, so it's enough here to add to the list.
2841 case " ${configdirs} " in
2842   *\ gdb\ *)
2843     configdirs="${configdirs} gnulib gdbsupport"
2844     ;;
2845   *\ gdbserver\ *)
2846     configdirs="${configdirs} gnulib gdbsupport"
2847     ;;
2848 esac
2849
2850 # Strip out unwanted targets.
2851
2852 # While at that, we remove Makefiles if we were started for recursive
2853 # configuration, so that the top-level Makefile reconfigures them,
2854 # like we used to do when configure itself was recursive.
2855
2856 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2857 # but now we're fixing up the Makefile ourselves with the additional
2858 # commands passed to AC_CONFIG_FILES.  Use separate variables
2859 # extrasub-{build,host,target} not because there is any reason to split
2860 # the substitutions up that way, but only to remain below the limit of
2861 # 99 commands in a script, for HP-UX sed.
2862
2863 # Do not nest @if/@endif or @unless/@endunless pairs, because
2864 # configure will not warn you at all.
2865
2866 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2867   yes:yes:*\ gold\ *:*,c++,*) ;;
2868   yes:yes:*\ gold\ *:*)
2869     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2870     ;;
2871 esac
2872
2873 extrasub_build=
2874 for module in ${build_configdirs} ; do
2875   if test -z "${no_recursion}" \
2876      && test -f ${build_subdir}/${module}/Makefile; then
2877     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2878     rm -f ${build_subdir}/${module}/Makefile
2879   fi
2880   extrasub_build="$extrasub_build
2881 /^@if build-$module\$/d
2882 /^@endif build-$module\$/d
2883 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2884 /^@if build-$module-$bootstrap_suffix\$/d
2885 /^@endif build-$module-$bootstrap_suffix\$/d
2886 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2887 done
2888 extrasub_host=
2889 for module in ${configdirs} ; do
2890   if test -z "${no_recursion}"; then
2891     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2892       if test -f ${file}; then
2893         echo 1>&2 "*** removing ${file} to force reconfigure"
2894         rm -f ${file}
2895       fi
2896     done
2897   fi
2898   case ${module},${bootstrap_fixincludes} in
2899     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2900     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2901   esac
2902   extrasub_host="$extrasub_host
2903 /^@if $module\$/d
2904 /^@endif $module\$/d
2905 /^@unless $module\$/,/^@endunless $module\$/d
2906 /^@if $module-$host_bootstrap_suffix\$/d
2907 /^@endif $module-$host_bootstrap_suffix\$/d
2908 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2909 done
2910 extrasub_target=
2911 for module in ${target_configdirs} ; do
2912   if test -z "${no_recursion}" \
2913      && test -f ${target_subdir}/${module}/Makefile; then
2914     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2915     rm -f ${target_subdir}/${module}/Makefile
2916   fi
2917
2918   # We only bootstrap target libraries listed in bootstrap_target_libs.
2919   case $bootstrap_target_libs in
2920     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2921     *) target_bootstrap_suffix=no-bootstrap ;;
2922   esac
2923
2924   extrasub_target="$extrasub_target
2925 /^@if target-$module\$/d
2926 /^@endif target-$module\$/d
2927 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2928 /^@if target-$module-$target_bootstrap_suffix\$/d
2929 /^@endif target-$module-$target_bootstrap_suffix\$/d
2930 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2931 done
2932
2933 # Do the final fixup along with target modules.
2934 extrasub_target="$extrasub_target
2935 /^@if /,/^@endif /d
2936 /^@unless /d
2937 /^@endunless /d"
2938
2939 # Create the serialization dependencies.  This uses a temporary file.
2940
2941 AC_ARG_ENABLE([serial-configure],
2942 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2943                 [force sequential configuration of
2944                  sub-packages for the host, target or build
2945                  machine, or all sub-packages])])
2946
2947 case ${enable_serial_configure} in
2948   yes)
2949     enable_serial_build_configure=yes
2950     enable_serial_host_configure=yes
2951     enable_serial_target_configure=yes
2952     ;;
2953 esac
2954
2955 # These force 'configure's to be done one at a time, to avoid problems
2956 # with contention over a shared config.cache.
2957 rm -f serdep.tmp
2958 echo '# serdep.tmp' > serdep.tmp
2959 olditem=
2960 test "x${enable_serial_build_configure}" = xyes &&
2961 for item in ${build_configdirs} ; do
2962   case ${olditem} in
2963     "") ;;
2964     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2965   esac
2966   olditem=${item}
2967 done
2968 olditem=
2969 test "x${enable_serial_host_configure}" = xyes &&
2970 for item in ${configdirs} ; do
2971   case ${olditem} in
2972     "") ;;
2973     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2974   esac
2975   olditem=${item}
2976 done
2977 olditem=
2978 test "x${enable_serial_target_configure}" = xyes &&
2979 for item in ${target_configdirs} ; do
2980   case ${olditem} in
2981     "") ;;
2982     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2983   esac
2984   olditem=${item}
2985 done
2986 serialization_dependencies=serdep.tmp
2987 AC_SUBST_FILE(serialization_dependencies)
2988
2989 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2990 # target, nonopt, and variable assignments.  These are the ones we
2991 # might not want to pass down to subconfigures.  The exception being
2992 # --cache-file=/dev/null, which is used to turn off the use of cache
2993 # files altogether, and which should be passed on to subconfigures.
2994 # Also strip program-prefix, program-suffix, and program-transform-name,
2995 # so that we can pass down a consistent program-transform-name.
2996 baseargs=
2997 tbaseargs=
2998 keep_next=no
2999 skip_next=no
3000 eval "set -- $ac_configure_args"
3001 for ac_arg
3002 do
3003   if test X"$skip_next" = X"yes"; then
3004     skip_next=no
3005     continue
3006   fi
3007   if test X"$keep_next" = X"yes"; then
3008     case $ac_arg in
3009       *\'*)
3010         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3011     esac
3012     baseargs="$baseargs '$ac_arg'"
3013     tbaseargs="$tbaseargs '$ac_arg'"
3014     keep_next=no
3015     continue
3016   fi
3017
3018   # Handle separated arguments.  Based on the logic generated by
3019   # autoconf 2.59.
3020   case $ac_arg in
3021     *=* | --config-cache | -C | -disable-* | --disable-* \
3022       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3023       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3024       | -with-* | --with-* | -without-* | --without-* | --x)
3025       separate_arg=no
3026       ;;
3027     -*)
3028       separate_arg=yes
3029       ;;
3030     *)
3031       separate_arg=no
3032       ;;
3033   esac
3034
3035   skip_targ=no
3036   case $ac_arg in
3037 changequote(,)
3038   --with-* | --without-*)
3039     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3040
3041     case $libopt in
3042     *[-_]include)
3043       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3044       ;;
3045     *[-_]lib)
3046       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3047       ;;
3048     *)
3049       lib=$libopt
3050       ;;
3051     esac
3052 changequote([,])
3053
3054     case $lib in
3055     mpc | mpfr | gmp | isl)
3056       # If we're processing --with-$lib, --with-$lib-include or
3057       # --with-$lib-lib, for one of the libs above, and target is
3058       # different from host, don't pass the current argument to any
3059       # target library's configure.
3060       if test x$is_cross_compiler = xyes; then
3061         skip_targ=yes
3062       fi
3063       ;;
3064     esac
3065     ;;
3066   esac
3067
3068   case "$ac_arg" in
3069     --cache-file=/dev/null | \
3070     -cache-file=/dev/null )
3071       # Handled here to avoid the test to skip args below.
3072       baseargs="$baseargs '$ac_arg'"
3073       tbaseargs="$tbaseargs '$ac_arg'"
3074       # Assert: $separate_arg should always be no.
3075       keep_next=$separate_arg
3076       ;;
3077     --no*)
3078       continue
3079       ;;
3080     --c* | \
3081     --sr* | \
3082     --ho* | \
3083     --bu* | \
3084     --t* | \
3085     --program-* | \
3086     -cache_file* | \
3087     -srcdir* | \
3088     -host* | \
3089     -build* | \
3090     -target* | \
3091     -program-prefix* | \
3092     -program-suffix* | \
3093     -program-transform-name* )
3094       skip_next=$separate_arg
3095       continue
3096       ;;
3097     -*)
3098       # An option.  Add it.
3099       case $ac_arg in
3100         *\'*)
3101           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3102       esac
3103       baseargs="$baseargs '$ac_arg'"
3104       if test X"$skip_targ" = Xno; then
3105         tbaseargs="$tbaseargs '$ac_arg'"
3106       fi
3107       keep_next=$separate_arg
3108       ;;
3109     *)
3110       # Either a variable assignment, or a nonopt (triplet).  Don't
3111       # pass it down; let the Makefile handle this.
3112       continue
3113       ;;
3114   esac
3115 done
3116 # Remove the initial space we just introduced and, as these will be
3117 # expanded by make, quote '$'.
3118 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3119
3120 # Add in --program-transform-name, after --program-prefix and
3121 # --program-suffix have been applied to it.  Autoconf has already
3122 # doubled dollar signs and backslashes in program_transform_name; we want
3123 # the backslashes un-doubled, and then the entire thing wrapped in single
3124 # quotes, because this will be expanded first by make and then by the shell.
3125 # Also, because we want to override the logic in subdir configure scripts to
3126 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3127 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3128 ${program_transform_name}
3129 EOF_SED
3130 gcc_transform_name=`cat conftestsed.out`
3131 rm -f conftestsed.out
3132 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3133 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3134 if test "$silent" = yes; then
3135   baseargs="$baseargs --silent"
3136   tbaseargs="$tbaseargs --silent"
3137 fi
3138 baseargs="$baseargs --disable-option-checking"
3139 tbaseargs="$tbaseargs --disable-option-checking"
3140
3141 # Record and document user additions to sub configure arguments.
3142 AC_ARG_VAR([build_configargs],
3143            [additional configure arguments for build directories])
3144 AC_ARG_VAR([host_configargs],
3145            [additional configure arguments for host directories])
3146 AC_ARG_VAR([target_configargs],
3147            [additional configure arguments for target directories])
3148
3149 # For the build-side libraries, we just need to pretend we're native,
3150 # and not use the same cache file.  Multilibs are neither needed nor
3151 # desired.  We can't even use the same cache file for all build-side
3152 # libraries, as they're compiled differently; some with C, some with
3153 # C++ or with different feature-enabling options.
3154 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3155
3156 # For host modules, accept cache file option, or specification as blank.
3157 case "${cache_file}" in
3158 "") # empty
3159   cache_file_option="" ;;
3160 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3161   cache_file_option="--cache-file=${cache_file}" ;;
3162 *) # relative path
3163   cache_file_option="--cache-file=../${cache_file}" ;;
3164 esac
3165
3166 # Host dirs don't like to share a cache file either, horribly enough.
3167 # This seems to be due to autoconf 2.5x stupidity.
3168 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3169
3170 target_configargs="$target_configargs ${tbaseargs}"
3171
3172 # Passing a --with-cross-host argument lets the target libraries know
3173 # whether they are being built with a cross-compiler or being built
3174 # native.  However, it would be better to use other mechanisms to make the
3175 # sorts of decisions they want to make on this basis.  Please consider
3176 # this option to be deprecated.  FIXME.
3177 if test x${is_cross_compiler} = xyes ; then
3178   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3179 fi
3180
3181 # Special user-friendly check for native x86_64-linux build, if
3182 # multilib is not explicitly enabled.
3183 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3184   x86_64-*linux*:yes:$build:$build:)
3185     # Make sure we have a development environment that handles 32-bit
3186     dev64=no
3187     echo "int main () { return 0; }" > conftest.c
3188     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3189     if test $? = 0 ; then
3190       if test -s conftest || test -s conftest.exe ; then
3191         dev64=yes
3192       fi
3193     fi
3194     rm -f conftest*
3195     if test x${dev64} != xyes ; then
3196       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3197     fi
3198     ;;
3199 esac
3200
3201 # Default to --enable-multilib.
3202 if test x${enable_multilib} = x ; then
3203   target_configargs="--enable-multilib ${target_configargs}"
3204 fi
3205
3206 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3207 # changed from the earlier setting of with_newlib.
3208 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3209   target_configargs="--with-newlib ${target_configargs}"
3210 fi
3211
3212 # Different target subdirs use different values of certain variables
3213 # (notably CXX).  Worse, multilibs use *lots* of different values.
3214 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3215 # it doesn't automatically accept command-line overrides of them.
3216 # This means it's not safe for target subdirs to share a cache file,
3217 # which is disgusting, but there you have it.  Hopefully this can be
3218 # fixed in future.  It's still worthwhile to use a cache file for each
3219 # directory.  I think.
3220
3221 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3222 # We need to pass --target, as newer autoconf's requires consistency
3223 # for target_alias and gcc doesn't manage it consistently.
3224 target_configargs="--cache-file=./config.cache ${target_configargs}"
3225
3226 FLAGS_FOR_TARGET=
3227 case " $target_configdirs " in
3228  *" newlib "*)
3229   case " $target_configargs " in
3230   *" --with-newlib "*)
3231    case "$target" in
3232     *-cygwin*)
3233       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3234       ;;
3235    esac
3236
3237    # If we're not building GCC, don't discard standard headers.
3238    if test -d ${srcdir}/gcc; then
3239      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3240
3241      if test "${build}" != "${host}"; then
3242        # On Canadian crosses, CC_FOR_TARGET will have already been set
3243        # by `configure', so we won't have an opportunity to add -Bgcc/
3244        # to it.  This is right: we don't want to search that directory
3245        # for binaries, but we want the header files in there, so add
3246        # them explicitly.
3247        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3248
3249        # Someone might think of using the pre-installed headers on
3250        # Canadian crosses, in case the installed compiler is not fully
3251        # compatible with the compiler being built.  In this case, it
3252        # would be better to flag an error than risking having
3253        # incompatible object files being constructed.  We can't
3254        # guarantee that an error will be flagged, but let's hope the
3255        # compiler will do it, when presented with incompatible header
3256        # files.
3257      fi
3258    fi
3259
3260    case "${target}-${is_cross_compiler}" in
3261    i[[3456789]]86-*-linux*-no)
3262       # Here host == target, so we don't need to build gcc,
3263       # so we don't want to discard standard headers.
3264       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3265       ;;
3266    *)
3267       # If we're building newlib, use its generic headers last, but search
3268       # for any libc-related directories first (so make it the last -B
3269       # switch).
3270       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3271
3272       # If we're building libgloss, find the startup file, simulator library
3273       # and linker script.
3274       case " $target_configdirs " in
3275         *" libgloss "*)
3276         # Look for startup file, simulator library and maybe linker script.
3277         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3278         # Look for libnosys.a in case the target needs it.
3279         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3280         # Most targets have the linker script in the source directory.
3281         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3282         ;;
3283       esac
3284       ;;
3285    esac
3286    ;;
3287   esac
3288   ;;
3289 esac
3290
3291 case "$target" in
3292   x86_64-*mingw* | *-w64-mingw*)
3293   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3294   # however, use a symlink named 'mingw' in ${prefix} .
3295     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3296     ;;
3297   *-mingw*)
3298   # MinGW can't be handled as Cygwin above since it does not use newlib.
3299     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3300     ;;
3301 esac
3302
3303 # Allow the user to override the flags for
3304 # our build compiler if desired.
3305 if test x"${build}" = x"${host}" ; then
3306   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3307   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3308   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3309 fi
3310
3311 # On Canadian crosses, we'll be searching the right directories for
3312 # the previously-installed cross compiler, so don't bother to add
3313 # flags for directories within the install tree of the compiler
3314 # being built; programs in there won't even run.
3315 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3316   # Search for pre-installed headers if nothing else fits.
3317   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3318 fi
3319
3320 if test "x${use_gnu_ld}" = x &&
3321    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3322   # Arrange for us to find uninstalled linker scripts.
3323   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3324 fi
3325
3326 # Search for other target-specific linker scripts and such.
3327 case "${target}" in
3328   mep*)
3329     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3330     ;;
3331 esac
3332
3333 # Makefile fragments.
3334 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3335 do
3336   eval fragval=\$$frag
3337   if test $fragval != /dev/null; then
3338     eval $frag=${srcdir}/$fragval
3339   fi
3340 done
3341 AC_SUBST_FILE(host_makefile_frag)
3342 AC_SUBST_FILE(target_makefile_frag)
3343 AC_SUBST_FILE(alphaieee_frag)
3344 AC_SUBST_FILE(ospace_frag)
3345
3346 # Miscellanea: directories, flags, etc.
3347 AC_SUBST(RPATH_ENVVAR)
3348 AC_SUBST(GCC_SHLIB_SUBDIR)
3349 AC_SUBST(tooldir)
3350 AC_SUBST(build_tooldir)
3351 AC_SUBST(CONFIGURE_GDB_TK)
3352 AC_SUBST(GDB_TK)
3353 AC_SUBST(INSTALL_GDB_TK)
3354
3355 # Build module lists & subconfigure args.
3356 AC_SUBST(build_configargs)
3357 AC_SUBST(build_configdirs)
3358
3359 # Host module lists & subconfigure args.
3360 AC_SUBST(host_configargs)
3361 AC_SUBST(configdirs)
3362 AC_SUBST(target_configdirs)
3363
3364 # Target module lists & subconfigure args.
3365 AC_SUBST(target_configargs)
3366
3367
3368 # Build tools.
3369 AC_SUBST(AR_FOR_BUILD)
3370 AC_SUBST(AS_FOR_BUILD)
3371 AC_SUBST(CC_FOR_BUILD)
3372 AC_SUBST(CFLAGS_FOR_BUILD)
3373 AC_SUBST(CXXFLAGS_FOR_BUILD)
3374 AC_SUBST(CXX_FOR_BUILD)
3375 AC_SUBST(DLLTOOL_FOR_BUILD)
3376 AC_SUBST(GFORTRAN_FOR_BUILD)
3377 AC_SUBST(GOC_FOR_BUILD)
3378 AC_SUBST(GDC_FOR_BUILD)
3379 AC_SUBST(LDFLAGS_FOR_BUILD)
3380 AC_SUBST(LD_FOR_BUILD)
3381 AC_SUBST(NM_FOR_BUILD)
3382 AC_SUBST(RANLIB_FOR_BUILD)
3383 AC_SUBST(WINDMC_FOR_BUILD)
3384 AC_SUBST(WINDRES_FOR_BUILD)
3385
3386 # Generate default definitions for YACC, M4, LEX and other programs that run
3387 # on the build machine.  These are used if the Makefile can't locate these
3388 # programs in objdir.
3389 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3390
3391 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3392 case " $build_configdirs " in
3393   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3394 esac
3395
3396 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3397 case " $build_configdirs " in
3398   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3399 esac
3400
3401 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3402 case " $build_configdirs " in
3403   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3404 esac
3405
3406 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3407 case " $build_configdirs " in
3408   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3409   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3410 esac
3411
3412 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3413 case " $build_configdirs " in
3414   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3415 esac
3416
3417 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3418 case " $build_configdirs " in
3419   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3420   *)
3421 changequote(,)
3422     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3423     # higher, else we use the "missing" dummy.
3424     if ${MAKEINFO} --version \
3425        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3426       :
3427     else
3428       MAKEINFO="$MISSING makeinfo"
3429     fi
3430     ;;
3431 changequote([,])
3432 esac
3433
3434 # FIXME: expect and dejagnu may become build tools?
3435
3436 AC_CHECK_PROGS(EXPECT, expect, expect)
3437 case " $configdirs " in
3438   *" expect "*)
3439     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3440     ;;
3441 esac
3442
3443 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3444 case " $configdirs " in
3445   *" dejagnu "*)
3446     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3447     ;;
3448 esac
3449
3450
3451 # Host tools.
3452 NCN_STRICT_CHECK_TOOLS(AR, ar)
3453 NCN_STRICT_CHECK_TOOLS(AS, as)
3454 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3455 NCN_STRICT_CHECK_TOOLS(LD, ld)
3456 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3457 NCN_STRICT_CHECK_TOOLS(NM, nm)
3458 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3459 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3460 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3461 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3462 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3463 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3464 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3465 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3466 AC_SUBST(CC)
3467 AC_SUBST(CXX)
3468 AC_SUBST(CFLAGS)
3469 AC_SUBST(CXXFLAGS)
3470
3471 # Target tools.
3472 AC_ARG_WITH([build-time-tools],
3473   [AS_HELP_STRING([--with-build-time-tools=PATH],
3474                   [use given path to find target tools during the build])],
3475   [case x"$withval" in
3476      x/*) ;;
3477      *)
3478        with_build_time_tools=
3479        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3480        ;;
3481    esac],
3482   [with_build_time_tools=])
3483
3484 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3485 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3486 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3487 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3488 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3489 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3490
3491 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3492 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3493 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3494 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3495 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3496 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3497 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3498 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3499 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3500 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3501 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3502 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3503 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3504 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3505
3506 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3507
3508 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3509 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3510 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3511 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3512 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3513                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3514                 c++)
3515 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3516                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3517                 c++)
3518 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3519 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3520 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3521                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3522 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3523                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3524 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3525                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3526 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3527 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3528 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3529 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3530 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3531 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3532 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3533 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3534 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3535 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3536 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3537
3538 AC_SUBST(FLAGS_FOR_TARGET)
3539 AC_SUBST(RAW_CXX_FOR_TARGET)
3540
3541 # Certain tools may need extra flags.
3542 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3543 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3544 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3545
3546 # When building target libraries, except in a Canadian cross, we use
3547 # the same toolchain as the compiler we just built.
3548 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3549 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3550 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3551 if test $host = $build; then
3552   case " $configdirs " in
3553     *" gcc "*)
3554       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3555       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3556       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3557       ;;
3558   esac
3559 fi
3560
3561 AC_SUBST(COMPILER_AS_FOR_TARGET)
3562 AC_SUBST(COMPILER_LD_FOR_TARGET)
3563 AC_SUBST(COMPILER_NM_FOR_TARGET)
3564
3565 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3566 AC_ARG_ENABLE(maintainer-mode,
3567 [AS_HELP_STRING([--enable-maintainer-mode],
3568                 [enable make rules and dependencies not useful
3569                  (and sometimes confusing) to the casual installer])],
3570       USE_MAINTAINER_MODE=$enableval,
3571       USE_MAINTAINER_MODE=no)
3572 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3573 AC_SUBST(MAINTAINER_MODE_TRUE)
3574 AC_SUBST(MAINTAINER_MODE_FALSE)
3575 if test "$USE_MAINTAINER_MODE" = yes; then
3576   MAINTAINER_MODE_TRUE=
3577   MAINTAINER_MODE_FALSE='#'
3578 else
3579   MAINTAINER_MODE_TRUE='#'
3580   MAINTAINER_MODE_FALSE=
3581 fi
3582 MAINT=$MAINTAINER_MODE_TRUE
3583 AC_SUBST(MAINT)dnl
3584
3585 # ---------------------
3586 # GCC bootstrap support
3587 # ---------------------
3588
3589 # Stage specific cflags for build.
3590 stage1_cflags="-g"
3591 case $build in
3592   vax-*-*)
3593     case ${GCC} in
3594       yes) stage1_cflags="-g -Wa,-J" ;;
3595       *) stage1_cflags="-g -J" ;;
3596     esac ;;
3597 esac
3598
3599 AC_SUBST(stage1_cflags)
3600
3601 # Enable --enable-checking in stage1 of the compiler.
3602 AC_ARG_ENABLE(stage1-checking,
3603 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3604                 [choose additional checking for stage1 of the compiler])],
3605 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3606 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3607   # For --disable-checking or implicit --enable-checking=release, avoid
3608   # setting --enable-checking=gc in the default stage1 checking for LTO
3609   # bootstraps.  See PR62077.
3610   case $BUILD_CONFIG in
3611     *lto*)
3612       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3613     *)
3614       stage1_checking=--enable-checking=yes,types;;
3615   esac
3616   if test "x$enable_checking" = x && \
3617      test -d ${srcdir}/gcc && \
3618      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3619     stage1_checking=--enable-checking=yes,types,extra
3620   fi
3621 else
3622   stage1_checking=--enable-checking=$enable_checking,types
3623 fi])
3624 AC_SUBST(stage1_checking)
3625
3626 # Enable -Werror in bootstrap stage2 and later.
3627 AC_ARG_ENABLE(werror,
3628 [AS_HELP_STRING([--enable-werror],
3629                 [enable -Werror in bootstrap stage2 and later])],
3630 [
3631 case ${enable_werror} in
3632   yes) stage2_werror_flag="--enable-werror-always" ;;
3633   *) stage2_werror_flag="" ;;
3634 esac
3635 ],
3636 [
3637 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3638   case $BUILD_CONFIG in
3639   bootstrap-debug)
3640       stage2_werror_flag="--enable-werror-always" ;;
3641   "")
3642       stage2_werror_flag="--enable-werror-always" ;;
3643   esac
3644 fi
3645 ])
3646
3647 AC_SUBST(stage2_werror_flag)
3648
3649 # Specify what files to not compare during bootstrap.
3650
3651 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3652 case "$target" in
3653   hppa*64*-*-hpux*) ;;
3654   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3655   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3656 esac
3657 AC_SUBST(compare_exclusions)
3658
3659 AC_CONFIG_FILES([Makefile],
3660   [sed "$extrasub_build" Makefile |
3661    sed "$extrasub_host" |
3662    sed "$extrasub_target" > mf$$
3663    mv -f mf$$ Makefile],
3664   [extrasub_build="$extrasub_build"
3665    extrasub_host="$extrasub_host"
3666    extrasub_target="$extrasub_target"])
3667 AC_OUTPUT