configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl
  13 dnl Permission is hereby granted, free of charge, to any person obtaining a
  14 dnl copy of this software and associated documentation files (the "Software"),
  15 dnl to deal in the Software without restriction, including without limitation
  16 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  17 dnl and/or sell copies of the Software, and to permit persons to whom the
  18 dnl Software is furnished to do so, subject to the following conditions:
  19 dnl
  20 dnl The above copyright notice and this permission notice (including the next
  21 dnl paragraph) shall be included in all copies or substantial portions of the
  22 dnl Software.
  23 dnl
  24 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  25 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  26 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  27 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  28 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  29 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  30 dnl DEALINGS IN THE SOFTWARE.
  31 dnl
  32 dnl Process this file with autoconf to create configure.
  33
  34 AC_PREREQ([2.60])
  35
  36 dnl Tell the user about autoconf.html in the --help output
  37 m4_divert_once([HELP_END], [
  38 See docs/autoconf.html for more details on the options for Mesa.])
  39
  40 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  41 AC_INIT([Mesa], [MESA_VERSION],
  42     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  43 AC_CONFIG_AUX_DIR([bin])
  44 AC_CONFIG_MACRO_DIR([m4])
  45 AC_CANONICAL_SYSTEM
  46 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  47
  48 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  49 case "$host_os" in
  50 mingw*)
  51     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  52     ;;
  53 esac
  54
  55 # Support silent build rules, requires at least automake-1.11. Disable
  56 # by either passing --disable-silent-rules to configure or passing V=1
  57 # to make
  58 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  59     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  60
  61 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  62
  63 dnl Set internal versions
  64 OSMESA_VERSION=8
  65 AC_SUBST([OSMESA_VERSION])
  66 OPENCL_VERSION=1
  67 AC_SUBST([OPENCL_VERSION])
  68
  69 # The idea is that libdrm is distributed as one cohesive package, even
  70 # though it is composed of multiple libraries. However some drivers
  71 # may have different version requirements than others. This list
  72 # codifies which drivers need which version of libdrm. Any libdrm
  73 # version dependencies in non-driver-specific code should be reflected
  74 # in the first entry.
  75 LIBDRM_REQUIRED=2.4.75
  76 LIBDRM_RADEON_REQUIRED=2.4.71
  77 LIBDRM_AMDGPU_REQUIRED=2.4.79
  78 LIBDRM_INTEL_REQUIRED=2.4.75
  79 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  80 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  81 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  82 LIBDRM_VC4_REQUIRED=2.4.69
  83 LIBDRM_ETNAVIV_REQUIRED=2.4.80
  84
  85 dnl Versions for external dependencies
  86 DRI2PROTO_REQUIRED=2.8
  87 DRI3PROTO_REQUIRED=1.0
  88 PRESENTPROTO_REQUIRED=1.0
  89 GLPROTO_REQUIRED=1.4.14
  90 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  91 LIBVA_REQUIRED=0.38.0
  92 VDPAU_REQUIRED=1.1
  93 WAYLAND_REQUIRED=1.11
  94 XCB_REQUIRED=1.9.3
  95 XCBDRI2_REQUIRED=1.8
  96 XCBGLX_REQUIRED=1.8.1
  97 XDAMAGE_REQUIRED=1.1
  98 XSHMFENCE_REQUIRED=1.1
  99 XVMC_REQUIRED=1.0.6
 100 PYTHON_MAKO_REQUIRED=0.8.0
 101 LIBSENSORS_REQUIRED=4.0.0
 102 ZLIB_REQUIRED=1.2.8
 103
 104 dnl LLVM versions
 105 LLVM_REQUIRED_GALLIUM=3.3.0
 106 LLVM_REQUIRED_OPENCL=3.6.0
 107 LLVM_REQUIRED_R600=3.8.0
 108 LLVM_REQUIRED_RADEONSI=3.8.0
 109 LLVM_REQUIRED_RADV=3.9.0
 110 LLVM_REQUIRED_SWR=3.9.0
 111
 112 dnl Check for progs
 113 AC_PROG_CPP
 114 AC_PROG_CC
 115 AC_PROG_CXX
 116 AM_PROG_CC_C_O
 117 AM_PROG_AS
 118 AX_CHECK_GNU_MAKE
 119 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 120 AC_PROG_SED
 121 AC_PROG_MKDIR_P
 122
 123 AC_SYS_LARGEFILE
 124
 125 LT_PREREQ([2.2])
 126 LT_INIT([disable-static])
 127
 128 AC_CHECK_PROG(RM, rm, [rm -f])
 129
 130 AX_PROG_BISON([],
 131               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 132                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 133 AX_PROG_FLEX([],
 134              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 135                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 136
 137 AC_CHECK_PROG(INDENT, indent, indent, cat)
 138 if test "x$INDENT" != "xcat"; then
 139     # Only GNU indent is supported
 140     INDENT_VERSION=`indent --version | grep GNU`
 141     if test $? -eq 0; then
 142        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 143     else
 144        INDENT="cat"
 145     fi
 146 fi
 147
 148 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 149
 150 if test -z "$PYTHON2"; then
 151     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 152         AC_MSG_ERROR([Python not found - unable to generate sources])
 153     fi
 154 else
 155     if test "x$acv_mako_found" = xno; then
 156         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 157             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 158         fi
 159     fi
 160 fi
 161
 162 AC_PROG_INSTALL
 163
 164 dnl We need a POSIX shell for parts of the build. Assume we have one
 165 dnl in most cases.
 166 case "$host_os" in
 167 solaris*)
 168     # Solaris /bin/sh is too old/non-POSIX compliant
 169     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 170     SHELL="$POSIX_SHELL"
 171     ;;
 172 esac
 173
 174 dnl clang is mostly GCC-compatible, but its version is much lower,
 175 dnl so we have to check for it.
 176 AC_MSG_CHECKING([if compiling with clang])
 177
 178 AC_COMPILE_IFELSE(
 179 [AC_LANG_PROGRAM([], [[
 180 #ifndef __clang__
 181        not clang
 182 #endif
 183 ]])],
 184 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 185
 186 AC_MSG_RESULT([$acv_mesa_CLANG])
 187
 188 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 189 dnl versions are explictly not supported.
 190 GEN_ASM_OFFSETS=no
 191 USE_GNU99=no
 192 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 193     AC_MSG_CHECKING([whether gcc version is sufficient])
 194     major=0
 195     minor=0
 196
 197     GCC_VERSION=`$CC -dumpversion`
 198     if test $? -eq 0; then
 199         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 200         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 204         AC_MSG_RESULT([no])
 205         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 206     else
 207         AC_MSG_RESULT([yes])
 208     fi
 209
 210     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 211         USE_GNU99=yes
 212     fi
 213     if test "x$cross_compiling" = xyes; then
 214         GEN_ASM_OFFSETS=yes
 215     fi
 216 fi
 217
 218 dnl We don't support building Mesa with Sun C compiler
 219 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 220 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 221 if test "x$SUNCC" = xyes; then
 222     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 223 fi
 224
 225 dnl Check for compiler builtins
 226 AX_GCC_BUILTIN([__builtin_bswap32])
 227 AX_GCC_BUILTIN([__builtin_bswap64])
 228 AX_GCC_BUILTIN([__builtin_clz])
 229 AX_GCC_BUILTIN([__builtin_clzll])
 230 AX_GCC_BUILTIN([__builtin_ctz])
 231 AX_GCC_BUILTIN([__builtin_expect])
 232 AX_GCC_BUILTIN([__builtin_ffs])
 233 AX_GCC_BUILTIN([__builtin_ffsll])
 234 AX_GCC_BUILTIN([__builtin_popcount])
 235 AX_GCC_BUILTIN([__builtin_popcountll])
 236 AX_GCC_BUILTIN([__builtin_unreachable])
 237
 238 AX_GCC_FUNC_ATTRIBUTE([const])
 239 AX_GCC_FUNC_ATTRIBUTE([flatten])
 240 AX_GCC_FUNC_ATTRIBUTE([format])
 241 AX_GCC_FUNC_ATTRIBUTE([malloc])
 242 AX_GCC_FUNC_ATTRIBUTE([packed])
 243 AX_GCC_FUNC_ATTRIBUTE([pure])
 244 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 245 AX_GCC_FUNC_ATTRIBUTE([unused])
 246 AX_GCC_FUNC_ATTRIBUTE([visibility])
 247 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 248 AX_GCC_FUNC_ATTRIBUTE([weak])
 249 AX_GCC_FUNC_ATTRIBUTE([alias])
 250
 251 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 252
 253 dnl Make sure the pkg-config macros are defined
 254 m4_ifndef([PKG_PROG_PKG_CONFIG],
 255     [m4_fatal([Could not locate the pkg-config autoconf macros.
 256   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 257   are in a different location, try setting the environment variable
 258   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 259 PKG_PROG_PKG_CONFIG()
 260
 261 dnl LIB_DIR - library basename
 262 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 263 AC_SUBST([LIB_DIR])
 264
 265 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 266 _SAVE_LDFLAGS="$LDFLAGS"
 267 _SAVE_CPPFLAGS="$CPPFLAGS"
 268
 269 dnl Compiler macros
 270 DEFINES="-D__STDC_CONSTANT_MACROS -D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS"
 271 AC_SUBST([DEFINES])
 272 android=no
 273 case "$host_os" in
 274 *-android)
 275     android=yes
 276     ;;
 277 linux*|*-gnu*|gnu*|cygwin*)
 278     DEFINES="$DEFINES -D_GNU_SOURCE"
 279     ;;
 280 solaris*)
 281     DEFINES="$DEFINES -DSVR4"
 282     ;;
 283 esac
 284
 285 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 286
 287 dnl Add flags for gcc and g++
 288 if test "x$GCC" = xyes; then
 289     CFLAGS="$CFLAGS -Wall"
 290
 291     if test "x$USE_GNU99" = xyes; then
 292         CFLAGS="$CFLAGS -std=gnu99"
 293     else
 294         CFLAGS="$CFLAGS -std=c99"
 295     fi
 296
 297     # Enable -Werror=implicit-function-declaration and
 298     # -Werror=missing-prototypes, if available, or otherwise, just
 299     # -Wmissing-prototypes.  This is particularly useful to avoid
 300     # generating a loadable driver module that has undefined symbols.
 301     save_CFLAGS="$CFLAGS"
 302     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 303     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 304     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 305     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 306                    AC_MSG_RESULT([yes]),
 307                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 308                     AC_MSG_RESULT([no])])
 309
 310     # Enable -fvisibility=hidden if using a gcc that supports it
 311     save_CFLAGS="$CFLAGS"
 312     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 313     VISIBILITY_CFLAGS="-fvisibility=hidden"
 314     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 315     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 316                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])])
 317
 318     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 319     CFLAGS=$save_CFLAGS
 320
 321     # We don't want floating-point math functions to set errno or trap
 322     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 323
 324     # Flags to help ensure that certain portions of the code -- and only those
 325     # portions -- can be built with MSVC:
 326     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 327     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 328     #   supports most of C99)
 329     # - the rest has no compiler compiler restrictions
 330     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 331     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 332
 333     # Enable -Werror=vla if compiler supports it
 334     save_CFLAGS="$CFLAGS"
 335     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 336     CFLAGS="$CFLAGS -Werror=vla"
 337     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 338                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 339                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 340                     AC_MSG_RESULT([yes])],
 341                     AC_MSG_RESULT([no]))
 342     CFLAGS="$save_CFLAGS"
 343 fi
 344 if test "x$GXX" = xyes; then
 345     CXXFLAGS="$CXXFLAGS -Wall"
 346
 347     # Enable -fvisibility=hidden if using a gcc that supports it
 348     save_CXXFLAGS="$CXXFLAGS"
 349     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 350     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 351     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 352     AC_LANG_PUSH([C++])
 353     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 354                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])])
 355     AC_LANG_POP([C++])
 356
 357     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 358     CXXFLAGS=$save_CXXFLAGS
 359
 360     # We don't want floating-point math functions to set errno or trap
 361     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 362 fi
 363
 364 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 365 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 366
 367 dnl even if the compiler appears to support it, using visibility attributes isn't
 368 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 369 case "$host_os" in
 370 cygwin*)
 371     VISIBILITY_CFLAGS=""
 372     VISIBILITY_CXXFLAGS=""
 373     ;;
 374 esac
 375
 376 AC_SUBST([VISIBILITY_CFLAGS])
 377 AC_SUBST([VISIBILITY_CXXFLAGS])
 378
 379 dnl
 380 dnl Optional flags, check for compiler support
 381 dnl
 382 SSE41_CFLAGS="-msse4.1"
 383 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 384 dnl stack, but on x86-32 such alignment is not guaranteed.
 385 case "$target_cpu" in
 386 i?86)
 387     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 388     ;;
 389 esac
 390 save_CFLAGS="$CFLAGS"
 391 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 392 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 393 #include <smmintrin.h>
 394 int param;
 395 int main () {
 396     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 397     c = _mm_max_epu32(a, b);
 398     return _mm_cvtsi128_si32(c);
 399 }]])], SSE41_SUPPORTED=1)
 400 CFLAGS="$save_CFLAGS"
 401 if test "x$SSE41_SUPPORTED" = x1; then
 402     DEFINES="$DEFINES -DUSE_SSE41"
 403 fi
 404 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 405 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 406
 407 dnl Check for new-style atomic builtins
 408 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409 int main() {
 410     int n;
 411     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 412 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 413 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 414     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 415 fi
 416 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 417
 418 dnl Check if host supports 64-bit atomics
 419 dnl note that lack of support usually results in link (not compile) error
 420 AC_MSG_CHECKING(whether __sync_add_and_fetch_8 is supported)
 421 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 422 #include <stdint.h>
 423 uint64_t v;
 424 int main() {
 425     return __sync_add_and_fetch(&v, (uint64_t)1);
 426 }]])], GCC_64BIT_ATOMICS_SUPPORTED=yes, GCC_64BIT_ATOMICS_SUPPORTED=no)
 427 if test "x$GCC_64BIT_ATOMICS_SUPPORTED" != xyes; then
 428     DEFINES="$DEFINES -DMISSING_64BIT_ATOMICS"
 429 fi
 430 AC_MSG_RESULT($GCC_64BIT_ATOMICS_SUPPORTED)
 431
 432 dnl Check for Endianness
 433 AC_C_BIGENDIAN(
 434    little_endian=no,
 435    little_endian=yes,
 436    little_endian=no,
 437    little_endian=no
 438 )
 439
 440 dnl Check for POWER8 Architecture
 441 PWR8_CFLAGS="-mpower8-vector"
 442 have_pwr8_intrinsics=no
 443 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 444 save_CFLAGS=$CFLAGS
 445 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 446 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 447 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 448 #error "Need GCC >= 4.8 for sane POWER8 support"
 449 #endif
 450 #include <altivec.h>
 451 int main () {
 452     vector unsigned char r;
 453     vector unsigned int v = vec_splat_u32 (1);
 454     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 455     return 0;
 456 }]])], have_pwr8_intrinsics=yes)
 457 CFLAGS=$save_CFLAGS
 458
 459 AC_ARG_ENABLE(pwr8,
 460    [AS_HELP_STRING([--disable-pwr8-inst],
 461                    [disable POWER8-specific instructions])],
 462    [enable_pwr8=$enableval], [enable_pwr8=auto])
 463
 464 if test "x$enable_pwr8" = xno ; then
 465    have_pwr8_intrinsics=disabled
 466 fi
 467
 468 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 469    DEFINES="$DEFINES -D_ARCH_PWR8"
 470    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 471    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 472 else
 473    PWR8_CFLAGS=
 474 fi
 475
 476 AC_MSG_RESULT($have_pwr8_intrinsics)
 477 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 478    AC_MSG_ERROR([POWER8 compiler support not detected])
 479 fi
 480
 481 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 482    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 483 fi
 484
 485 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 486
 487 dnl Can't have static and shared libraries, default to static if user
 488 dnl explicitly requested. If both disabled, set to static since shared
 489 dnl was explicitly requested.
 490 case "x$enable_static$enable_shared" in
 491 xyesyes)
 492     AC_MSG_ERROR([Cannot enable both static and shared. Building using --enable-shared is strongly recommended])
 493     ;;
 494 xnono)
 495     AC_MSG_ERROR([Cannot disable both static and shared. Building using --enable-shared is strongly recommended])
 496     ;;
 497 esac
 498
 499 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 500
 501 dnl
 502 dnl other compiler options
 503 dnl
 504 AC_ARG_ENABLE([debug],
 505     [AS_HELP_STRING([--enable-debug],
 506         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 507     [enable_debug="$enableval"],
 508     [enable_debug=no]
 509 )
 510
 511 AC_ARG_ENABLE([profile],
 512     [AS_HELP_STRING([--enable-profile],
 513         [enable profiling of code @<:@default=disabled@:>@])],
 514     [enable_profile="$enableval"],
 515     [enable_profile=no]
 516 )
 517
 518 AC_ARG_ENABLE([sanitize],
 519     [AS_HELP_STRING([--enable-sanitize@<:@=address|undefined@:>@],
 520         [enable code sanitizer @<:@default=disabled@:>@])],
 521     [enable_sanitize="$enableval"],
 522     [enable_sanitize=no])
 523
 524 if test "x$enable_profile" = xyes; then
 525     DEFINES="$DEFINES -DPROFILE"
 526     if test "x$GCC" = xyes; then
 527         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 528     fi
 529     if test "x$GXX" = xyes; then
 530         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 531     fi
 532 fi
 533
 534 if test "x$enable_debug" = xyes; then
 535     DEFINES="$DEFINES -DDEBUG"
 536     if test "x$enable_profile" = xyes; then
 537         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 538     fi
 539     if test "x$GCC" = xyes; then
 540         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 541             CFLAGS="$CFLAGS -g"
 542         fi
 543         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 544             CFLAGS="$CFLAGS -O0"
 545         fi
 546     fi
 547     if test "x$GXX" = xyes; then
 548         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 549             CXXFLAGS="$CXXFLAGS -g"
 550         fi
 551         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 552             CXXFLAGS="$CXXFLAGS -O0"
 553         fi
 554     fi
 555 else
 556    DEFINES="$DEFINES -DNDEBUG"
 557 fi
 558
 559 if test "x$enable_sanitize" != xno; then
 560     if test "x$enable_profile" = xyes; then
 561         AC_MSG_WARN([Sanitize and Profile are enabled at the same time])
 562     fi
 563
 564     CFLAGS="$CFLAGS -fsanitize=$enable_sanitize"
 565     CXXFLAGS="$CXXFLAGS -fsanitize=$enable_sanitize"
 566     LDFLAGS="$LDFLAGS -fsanitize=$enable_sanitize"
 567
 568     AC_LINK_IFELSE(
 569         [AC_LANG_SOURCE([int main(){return 0;}])],
 570         [],
 571         [AC_MSG_FAILURE([sanitize flags '$enable_sanitize' not supported])])
 572 fi
 573
 574 dnl
 575 dnl Check if linker supports -Bsymbolic
 576 dnl
 577 save_LDFLAGS=$LDFLAGS
 578 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 579 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 580 AC_LINK_IFELSE(
 581     [AC_LANG_SOURCE([int main() { return 0;}])],
 582     [AC_MSG_RESULT([yes])
 583         BSYMBOLIC="-Wl,-Bsymbolic";],
 584     [AC_MSG_RESULT([no])
 585         BSYMBOLIC="";])
 586 LDFLAGS=$save_LDFLAGS
 587
 588 AC_SUBST([BSYMBOLIC])
 589
 590 dnl
 591 dnl Check if linker supports garbage collection
 592 dnl
 593 save_LDFLAGS=$LDFLAGS
 594 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 595 AC_MSG_CHECKING([whether ld supports --gc-sections])
 596 AC_LINK_IFELSE(
 597     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 598     [AC_MSG_RESULT([yes])
 599         GC_SECTIONS="-Wl,--gc-sections";],
 600     [AC_MSG_RESULT([no])
 601         GC_SECTIONS="";])
 602 LDFLAGS=$save_LDFLAGS
 603
 604 AC_SUBST([GC_SECTIONS])
 605
 606 dnl
 607 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 608 dnl so when these flags are passed to ld via libtool the checks will fail
 609 dnl
 610 case "$host_os" in
 611 openbsd* | darwin* )
 612     LD_NO_UNDEFINED="" ;;
 613 *)
 614     if test "x$enable_sanitize" = xno; then
 615         LD_NO_UNDEFINED="-Wl,--no-undefined"
 616     else
 617         LD_NO_UNDEFINED=""
 618     fi
 619     ;;
 620 esac
 621
 622 AC_SUBST([LD_NO_UNDEFINED])
 623
 624 dnl
 625 dnl Check if linker supports version scripts
 626 dnl
 627 AC_MSG_CHECKING([if the linker supports version-scripts])
 628 save_LDFLAGS=$LDFLAGS
 629 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 630 cat > conftest.map <<EOF
 631 VERSION_1 {
 632      global:
 633          main;
 634
 635      local:
 636          *;
 637 };
 638 EOF
 639 AC_LINK_IFELSE(
 640     [AC_LANG_SOURCE([int main() { return 0;}])],
 641     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 642     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 643 LDFLAGS=$save_LDFLAGS
 644 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 645
 646 dnl
 647 dnl Check if linker supports dynamic list files
 648 dnl
 649 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 650 save_LDFLAGS=$LDFLAGS
 651 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 652 cat > conftest.dyn <<EOF
 653 {
 654         radeon_drm_winsys_create;
 655 };
 656 EOF
 657 AC_LINK_IFELSE(
 658     [AC_LANG_SOURCE([int main() { return 0;}])],
 659     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 660     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 661 LDFLAGS=$save_LDFLAGS
 662 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 663
 664 dnl
 665 dnl compatibility symlinks
 666 dnl
 667 case "$host_os" in
 668 linux* )
 669     HAVE_COMPAT_SYMLINKS=yes ;;
 670 * )
 671     HAVE_COMPAT_SYMLINKS=no ;;
 672 esac
 673
 674 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 675
 676 dnl
 677 dnl library names
 678 dnl
 679 dnl Unfortunately we need to do a few things that libtool can't help us with,
 680 dnl so we need some knowledge of shared library filenames:
 681 dnl
 682 dnl LIB_EXT is the extension used when creating symlinks for alternate
 683 dnl filenames for a shared library which will be dynamically loaded
 684 dnl
 685 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 686 dnl the file for a shared library we wish to link with
 687 dnl
 688 case "$host_os" in
 689 darwin* )
 690     LIB_EXT='dylib'
 691     IMP_LIB_EXT=$LIB_EXT
 692     ;;
 693 cygwin* )
 694     LIB_EXT='dll'
 695     IMP_LIB_EXT='dll.a'
 696     ;;
 697 aix* )
 698     LIB_EXT='a'
 699     IMP_LIB_EXT=$LIB_EXT
 700     ;;
 701 * )
 702     LIB_EXT='so'
 703     IMP_LIB_EXT=$LIB_EXT
 704     ;;
 705 esac
 706
 707 AC_SUBST([LIB_EXT])
 708
 709 dnl
 710 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 711 dnl
 712 AC_ARG_ENABLE([texture-float],
 713     [AS_HELP_STRING([--enable-texture-float],
 714         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 715     [enable_texture_float="$enableval"],
 716     [enable_texture_float=no]
 717 )
 718 if test "x$enable_texture_float" = xyes; then
 719     AC_MSG_WARN([Floating-point textures enabled.])
 720     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 721     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 722 fi
 723
 724 dnl
 725 dnl Arch/platform-specific settings
 726 dnl
 727 AC_ARG_ENABLE([asm],
 728     [AS_HELP_STRING([--disable-asm],
 729         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 730     [enable_asm="$enableval"],
 731     [enable_asm=yes]
 732 )
 733 asm_arch=""
 734 AC_MSG_CHECKING([whether to enable assembly])
 735 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 736 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 737 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 738     case "$host_cpu" in
 739     i?86 | x86_64 | amd64)
 740         if test "x$host_cpu" != "x$target_cpu"; then
 741             enable_asm=no
 742             AC_MSG_RESULT([no, cross compiling])
 743         fi
 744         ;;
 745     esac
 746 fi
 747 # check for supported arches
 748 if test "x$enable_asm" = xyes; then
 749     case "$host_cpu" in
 750     i?86)
 751         case "$host_os" in
 752         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 753             asm_arch=x86
 754             ;;
 755         esac
 756         ;;
 757     x86_64|amd64)
 758         case "$host_os" in
 759         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 760             asm_arch=x86_64
 761             ;;
 762         esac
 763         ;;
 764     sparc*)
 765         case "$host_os" in
 766         linux*)
 767             asm_arch=sparc
 768             ;;
 769         esac
 770         ;;
 771     esac
 772
 773     case "$asm_arch" in
 774     x86)
 775         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 776         AC_MSG_RESULT([yes, x86])
 777         ;;
 778     x86_64|amd64)
 779         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 780         AC_MSG_RESULT([yes, x86_64])
 781         ;;
 782     sparc)
 783         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 784         AC_MSG_RESULT([yes, sparc])
 785         ;;
 786     *)
 787         AC_MSG_RESULT([no, platform not supported])
 788         ;;
 789     esac
 790 fi
 791
 792 AC_HEADER_MAJOR
 793 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 794 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 795 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 796 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 797
 798 dnl Check to see if dlopen is in default libraries (like Solaris, which
 799 dnl has it in libc), or if libdl is needed to get it.
 800 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 801     [AC_CHECK_LIB([dl], [dlopen],
 802        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 803 AC_SUBST([DLOPEN_LIBS])
 804
 805 dnl Check if that library also has dladdr
 806 save_LIBS="$LIBS"
 807 LIBS="$LIBS $DLOPEN_LIBS"
 808 AC_CHECK_FUNCS([dladdr])
 809 LIBS="$save_LIBS"
 810
 811 AC_CHECK_FUNC([dl_iterate_phdr], [DEFINES="$DEFINES -DHAVE_DL_ITERATE_PHDR"])
 812
 813 case "$host_os" in
 814 darwin*)
 815     ;;
 816 *)
 817     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 818                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 819                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 820     AC_SUBST([CLOCK_LIB])
 821     ;;
 822 esac
 823
 824 dnl See if posix_memalign is available
 825 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 826
 827 dnl Check for zlib
 828 PKG_CHECK_MODULES([ZLIB], [zlib >= $ZLIB_REQUIRED])
 829
 830 dnl Check for pthreads
 831 AX_PTHREAD
 832 if test "x$ax_pthread_ok" = xno; then
 833     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 834 fi
 835 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 836 dnl to -pthread, which causes problems if we need -lpthread to appear in
 837 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 838 dnl is not valid for that platform.
 839 if test "x$android" = xno; then
 840     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 841 fi
 842
 843 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
 844 dnl project. Even then there's a notable issue as described in the project README
 845 case "$host_os" in
 846 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
 847     pthread_stubs_possible="no"
 848     ;;
 849 * )
 850     pthread_stubs_possible="yes"
 851     ;;
 852 esac
 853
 854 if test "x$pthread_stubs_possible" = xyes; then
 855     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
 856     AC_SUBST(PTHREADSTUBS_CFLAGS)
 857     AC_SUBST(PTHREADSTUBS_LIBS)
 858 fi
 859
 860 dnl SELinux awareness.
 861 AC_ARG_ENABLE([selinux],
 862     [AS_HELP_STRING([--enable-selinux],
 863         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 864     [MESA_SELINUX="$enableval"],
 865     [MESA_SELINUX=no])
 866 if test "x$enable_selinux" = "xyes"; then
 867     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 868         [AC_CHECK_HEADER([selinux/selinux.h],[],
 869                          [AC_MSG_ERROR([SELinux headers not found])])
 870          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 871                       [AC_MSG_ERROR([SELinux library not found])])
 872          SELINUX_LIBS="-lselinux"])
 873     DEFINES="$DEFINES -DMESA_SELINUX"
 874 fi
 875 AC_SUBST([SELINUX_CFLAGS])
 876 AC_SUBST([SELINUX_LIBS])
 877
 878 dnl
 879 dnl LLVM
 880 dnl
 881 AC_ARG_ENABLE([llvm-shared-libs],
 882     [AS_HELP_STRING([--enable-llvm-shared-libs],
 883         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 884     [enable_llvm_shared_libs="$enableval"],
 885     [enable_llvm_shared_libs=yes])
 886
 887 AC_ARG_WITH([llvm-prefix],
 888     [AS_HELP_STRING([--with-llvm-prefix],
 889         [Prefix for LLVM installations in non-standard locations])],
 890     [llvm_prefix="$withval"],
 891     [llvm_prefix=''])
 892
 893 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 894 if test "x$have_libelf" = xno; then
 895    LIBELF_LIBS=''
 896    LIBELF_CFLAGS=''
 897    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 898    AC_SUBST([LIBELF_LIBS])
 899    AC_SUBST([LIBELF_CFLAGS])
 900 fi
 901
 902 if test -z "$LLVM_CONFIG"; then
 903     if test -n "$llvm_prefix"; then
 904         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 905     else
 906         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 907     fi
 908 fi
 909
 910 llvm_add_component() {
 911     new_llvm_component=$1
 912     driver_name=$2
 913
 914     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 915         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 916     else
 917         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 918     fi
 919 }
 920
 921 llvm_add_default_components() {
 922     driver_name=$1
 923
 924     # Required default components
 925     llvm_add_component "bitwriter" $driver_name
 926     llvm_add_component "engine" $driver_name
 927     llvm_add_component "mcdisassembler" $driver_name
 928     llvm_add_component "mcjit" $driver_name
 929
 930     # Optional default components
 931     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 932         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 933     fi
 934 }
 935
 936 llvm_add_target() {
 937     new_llvm_target=$1
 938     driver_name=$2
 939
 940     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 941         llvm_add_component $new_llvm_target $driver_name
 942     else
 943         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 944     fi
 945 }
 946
 947 # Call this inside ` ` to get the return value.
 948 # $1 is the llvm-config command with arguments.
 949 strip_unwanted_llvm_flags() {
 950     echo " `$1` " | sed -E \
 951         -e 's/[[[:space:]]]+-m[[^[:space:]]]*//g' \
 952         -e 's/[[[:space:]]]+-DNDEBUG[[[:space:]]]/ /g' \
 953         -e 's/[[[:space:]]]+-D_GNU_SOURCE[[[:space:]]]/ /g' \
 954         -e 's/[[[:space:]]]+-pedantic[[[:space:]]]/ /g' \
 955         -e 's/[[[:space:]]]+-W[[^[:space:]]]*//g' \
 956         -e 's/[[[:space:]]]+-O[[^[:space:]]]*//g' \
 957         -e 's/[[[:space:]]]+-g[[^[:space:]]]*//g' \
 958         -e 's/-fno-rtti[[[:space:]]]/-Fno-rtti /g' \
 959         -e 's/[[[:space:]]]+-f[[^[:space:]]]*//g' \
 960         -e 's/-Fno-rtti[[[:space:]]]/-fno-rtti /g' \
 961         -e 's/^[[[:space:]]]//' \
 962         -e 's/[[[:space:]]]$//'
 963 }
 964
 965 llvm_set_environment_variables() {
 966     if test "x$LLVM_CONFIG" != xno; then
 967         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 968         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 969         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 970         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 971
 972         # We need to respect LLVM_CPPFLAGS when compiling LLVM headers.
 973         save_CFLAGS="$CFLAGS"
 974         CFLAGS="$CFLAGS $LLVM_CPPFLAGS"
 975
 976         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 977             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 978         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 979             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 980         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 981             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 982
 983         CFLAGS="$save_CFLAGS"
 984
 985         # Only needed for LLVM < 3.6.0
 986         if test -z "$LLVM_VERSION_PATCH"; then
 987             LLVM_VERSION_PATCH=0
 988         fi
 989
 990         LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
 991
 992         FOUND_LLVM=yes
 993     else
 994         FOUND_LLVM=no
 995         LLVM_VERSION_INT=0
 996     fi
 997 }
 998
 999 require_llvm() {
1000     if test "x$enable_llvm" != "xyes"; then
1001         AC_MSG_ERROR([--enable-llvm is required when building $1])
1002     fi
1003 }
1004
1005 llvm_require_version() {
1006     require_llvm $2
1007
1008     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1009     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1010     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1011
1012     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1013         # major > required major
1014         #  --> OK
1015         return
1016     fi
1017
1018     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1019         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1020             # major = required major and
1021             # minor > required minor
1022             #  --> OK
1023             return
1024         else
1025             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1026                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1027                     # major = required major and
1028                     # minor = required minor and
1029                     # patch >= required patch
1030                     #  --> OK
1031                     return
1032                 fi
1033             fi
1034         fi
1035     fi
1036
1037     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1038 }
1039
1040 radeon_llvm_check() {
1041     if test ${LLVM_VERSION_INT} -lt 307; then
1042         amdgpu_llvm_target_name='r600'
1043     else
1044         amdgpu_llvm_target_name='amdgpu'
1045     fi
1046
1047     llvm_require_version $*
1048
1049     llvm_add_target $amdgpu_llvm_target_name $2
1050
1051     llvm_add_default_components $2
1052     llvm_add_component "bitreader" $2
1053     llvm_add_component "ipo" $2
1054
1055     if test "x$have_libelf" != xyes; then
1056        AC_MSG_ERROR([$2 requires libelf when using llvm])
1057     fi
1058 }
1059
1060 llvm_set_environment_variables
1061
1062 AC_SUBST([LLVM_CFLAGS])
1063 AC_SUBST([LLVM_CXXFLAGS])
1064 AC_SUBST([LLVM_LIBS])
1065 AC_SUBST([LLVM_LDFLAGS])
1066 AC_SUBST([LLVM_INCLUDEDIR])
1067
1068 dnl
1069 dnl libunwind
1070 dnl
1071 AC_ARG_ENABLE([libunwind],
1072     [AS_HELP_STRING([--enable-libunwind],
1073             [Use libunwind for backtracing (default: auto)])],
1074         [LIBUNWIND="$enableval"],
1075         [LIBUNWIND="auto"])
1076
1077 PKG_CHECK_EXISTS(libunwind, [HAVE_LIBUNWIND=yes], [HAVE_LIBUNWIND=no])
1078 if test "x$LIBUNWIND" = "xauto"; then
1079     LIBUNWIND="$HAVE_LIBUNWIND"
1080 fi
1081
1082 if test "x$LIBUNWIND" = "xyes"; then
1083     PKG_CHECK_MODULES(LIBUNWIND, libunwind)
1084     if test "x$HAVE_LIBUNWIND" != "xyes"; then
1085         AC_MSG_ERROR([libunwind requested but not installed.])
1086     fi
1087     AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
1088 fi
1089
1090 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$LIBUNWIND" = xyes])
1091
1092
1093 dnl Options for APIs
1094 AC_ARG_ENABLE([opengl],
1095     [AS_HELP_STRING([--disable-opengl],
1096         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1097     [enable_opengl="$enableval"],
1098     [enable_opengl=yes])
1099 AC_ARG_ENABLE([gles1],
1100     [AS_HELP_STRING([--disable-gles1],
1101         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1102     [enable_gles1="$enableval"],
1103     [enable_gles1=yes])
1104 AC_ARG_ENABLE([gles2],
1105     [AS_HELP_STRING([--disable-gles2],
1106         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1107     [enable_gles2="$enableval"],
1108     [enable_gles2=yes])
1109
1110 AC_ARG_ENABLE([dri],
1111     [AS_HELP_STRING([--enable-dri],
1112         [enable DRI modules @<:@default=enabled@:>@])],
1113     [enable_dri="$enableval"],
1114     [enable_dri=yes])
1115
1116 AC_ARG_ENABLE([gallium-extra-hud],
1117     [AS_HELP_STRING([--enable-gallium-extra-hud],
1118         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1119     [enable_gallium_extra_hud="$enableval"],
1120     [enable_gallium_extra_hud=no])
1121 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1122 if test "x$enable_gallium_extra_hud" = xyes ; then
1123     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1124 fi
1125
1126 #TODO: no pkgconfig .pc available for libsensors.
1127 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1128 AC_ARG_ENABLE([lmsensors],
1129     [AS_HELP_STRING([--enable-lmsensors],
1130         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1131     [enable_lmsensors="$enableval"],
1132     [enable_lmsensors=no])
1133 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1134 if test "x$enable_lmsensors" = xyes ; then
1135     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1136     LIBSENSORS_LIBS="-lsensors"
1137 else
1138     LIBSENSORS_LIBS=""
1139 fi
1140 AC_SUBST(LIBSENSORS_LIBS)
1141
1142 case "$host_os" in
1143 linux*)
1144     dri3_default=yes
1145     ;;
1146 *)
1147     dri3_default=no
1148     ;;
1149 esac
1150
1151 if test "x$enable_dri" = xno; then
1152     dri3_default=no
1153 fi
1154
1155 AC_ARG_ENABLE([dri3],
1156     [AS_HELP_STRING([--enable-dri3],
1157         [enable DRI3 @<:@default=auto@:>@])],
1158     [enable_dri3="$enableval"],
1159     [enable_dri3="$dri3_default"])
1160 AC_ARG_ENABLE([glx],
1161     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1162         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1163     [enable_glx="$enableval"],
1164     [enable_glx=yes])
1165 AC_ARG_ENABLE([osmesa],
1166     [AS_HELP_STRING([--enable-osmesa],
1167         [enable OSMesa library @<:@default=disabled@:>@])],
1168     [enable_osmesa="$enableval"],
1169     [enable_osmesa=no])
1170 AC_ARG_ENABLE([gallium-osmesa],
1171     [AS_HELP_STRING([--enable-gallium-osmesa],
1172         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1173     [enable_gallium_osmesa="$enableval"],
1174     [enable_gallium_osmesa=no])
1175 AC_ARG_ENABLE([egl],
1176     [AS_HELP_STRING([--disable-egl],
1177         [disable EGL library @<:@default=enabled@:>@])],
1178     [enable_egl="$enableval"],
1179     [enable_egl=yes])
1180
1181 AC_ARG_ENABLE([xa],
1182     [AS_HELP_STRING([--enable-xa],
1183         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1184     [enable_xa="$enableval"],
1185     [enable_xa=no])
1186 AC_ARG_ENABLE([gbm],
1187    [AS_HELP_STRING([--enable-gbm],
1188          [enable gbm library @<:@default=yes except cygwin@:>@])],
1189    [enable_gbm="$enableval"],
1190    [case "$host_os" in
1191        cygwin*)
1192           enable_gbm=no
1193           ;;
1194        *)
1195           enable_gbm=yes
1196           ;;
1197     esac])
1198 AC_ARG_ENABLE([nine],
1199     [AS_HELP_STRING([--enable-nine],
1200         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1201     [enable_nine="$enableval"],
1202     [enable_nine=no])
1203
1204 AC_ARG_ENABLE([xvmc],
1205    [AS_HELP_STRING([--enable-xvmc],
1206          [enable xvmc library @<:@default=auto@:>@])],
1207    [enable_xvmc="$enableval"],
1208    [enable_xvmc=auto])
1209 AC_ARG_ENABLE([vdpau],
1210    [AS_HELP_STRING([--enable-vdpau],
1211          [enable vdpau library @<:@default=auto@:>@])],
1212    [enable_vdpau="$enableval"],
1213    [enable_vdpau=auto])
1214 AC_ARG_ENABLE([omx],
1215    [AS_HELP_STRING([--enable-omx],
1216          [enable OpenMAX library @<:@default=disabled@:>@])],
1217    [enable_omx="$enableval"],
1218    [enable_omx=no])
1219 AC_ARG_ENABLE([va],
1220    [AS_HELP_STRING([--enable-va],
1221          [enable va library @<:@default=auto@:>@])],
1222    [enable_va="$enableval"],
1223    [enable_va=auto])
1224 AC_ARG_ENABLE([opencl],
1225    [AS_HELP_STRING([--enable-opencl],
1226          [enable OpenCL library @<:@default=disabled@:>@])],
1227    [enable_opencl="$enableval"],
1228    [enable_opencl=no])
1229 AC_ARG_ENABLE([opencl_icd],
1230    [AS_HELP_STRING([--enable-opencl-icd],
1231           [Build an OpenCL ICD library to be loaded by an ICD implementation
1232            @<:@default=disabled@:>@])],
1233     [enable_opencl_icd="$enableval"],
1234     [enable_opencl_icd=no])
1235
1236 AC_ARG_ENABLE([gallium-tests],
1237     [AS_HELP_STRING([--enable-gallium-tests],
1238         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1239     [enable_gallium_tests="$enableval"],
1240     [enable_gallium_tests=no])
1241
1242 # Option for Gallium drivers
1243
1244 # Keep this in sync with the --with-gallium-drivers help string default value
1245 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1246
1247 AC_ARG_WITH([gallium-drivers],
1248     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1249         [comma delimited Gallium drivers list, e.g.
1250         "i915,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,swr,vc4,virgl,etnaviv,imx"
1251         @<:@default=r300,r600,svga,swrast@:>@])],
1252     [with_gallium_drivers="$withval"],
1253     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1254
1255 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1256 # here so that the script doesn't choke on an unknown driver name later.
1257 case "$with_gallium_drivers" in
1258     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1259     no) with_gallium_drivers='' ;;
1260 esac
1261
1262 if test "x$enable_opengl" = xno -a \
1263         "x$enable_gles1" = xno -a \
1264         "x$enable_gles2" = xno -a \
1265         "x$enable_nine" = xno -a \
1266         "x$enable_xa" = xno -a \
1267         "x$enable_xvmc" = xno -a \
1268         "x$enable_vdpau" = xno -a \
1269         "x$enable_omx" = xno -a \
1270         "x$enable_va" = xno -a \
1271         "x$enable_opencl" = xno; then
1272     AC_MSG_ERROR([at least one API should be enabled])
1273 fi
1274
1275 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1276 if test "x$enable_opengl" = xno -a \
1277         "x$enable_gles1" = xyes; then
1278     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1279 fi
1280
1281 if test "x$enable_opengl" = xno -a \
1282         "x$enable_gles2" = xyes; then
1283     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1284 fi
1285
1286 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1287 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1288 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1289 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1290                                         "x$enable_gles1" = xyes -o \
1291                                         "x$enable_gles2" = xyes)
1292
1293 # Validate GLX options
1294 if test "x$enable_glx" = xyes; then
1295     if test "x$enable_dri" = xyes; then
1296         enable_glx=dri
1297     elif test -n "$with_gallium_drivers"; then
1298         enable_glx=gallium-xlib
1299     else
1300         enable_glx=xlib
1301     fi
1302 fi
1303 case "x$enable_glx" in
1304 xdri | xxlib | xgallium-xlib)
1305     # GLX requires OpenGL
1306     if test "x$enable_opengl" = xno; then
1307         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1308     fi
1309
1310     # Check individual dependencies
1311     case "x$enable_glx" in
1312     xdri)
1313         if test "x$enable_dri" = xno; then
1314             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1315         fi
1316         ;;
1317     xxlib)
1318         if test "x$enable_dri" = xyes; then
1319             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1320         fi
1321         ;;
1322     xgallium-xlib )
1323         if test "x$enable_dri" = xyes; then
1324             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1325         fi
1326         if test -z "$with_gallium_drivers"; then
1327             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1328         fi
1329         ;;
1330     esac
1331     ;;
1332 xno)
1333     ;;
1334 *)
1335     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1336     ;;
1337 esac
1338
1339 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1340 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1341 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1342 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1343
1344 DEFAULT_GL_LIB_NAME=GL
1345
1346 dnl
1347 dnl Libglvnd configuration
1348 dnl
1349 AC_ARG_ENABLE([libglvnd],
1350     [AS_HELP_STRING([--enable-libglvnd],
1351         [Build GLX and EGL for libglvnd @<:@default=disabled@:>@])],
1352     [enable_libglvnd="$enableval"],
1353     [enable_libglvnd=no])
1354 AM_CONDITIONAL(USE_LIBGLVND, test "x$enable_libglvnd" = xyes)
1355
1356 if test "x$enable_libglvnd" = xyes ; then
1357     dnl XXX: update once we can handle more than libGL/glx.
1358     dnl Namely: we should error out if neither of the glvnd enabled libraries
1359     dnl are built
1360     case "x$enable_glx" in
1361     xno)
1362         AC_MSG_ERROR([cannot build libglvnd without GLX])
1363         ;;
1364     xxlib | xgallium-xlib )
1365         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1366         ;;
1367     xdri)
1368         ;;
1369     esac
1370
1371     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.2.0)
1372     PKG_CHECK_VAR(LIBGLVND_DATADIR, libglvnd, datadir)
1373     AC_SUBST([LIBGLVND_DATADIR])
1374
1375     DEFINES="${DEFINES} -DUSE_LIBGLVND=1"
1376     DEFAULT_GL_LIB_NAME=GLX_mesa
1377 fi
1378
1379 AC_ARG_WITH([gl-lib-name],
1380   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
1381     [specify GL library name @<:@default=GL@:>@])],
1382   [GL_LIB=$withval],
1383   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1384 AC_ARG_WITH([osmesa-lib-name],
1385   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
1386     [specify OSMesa library name @<:@default=OSMesa@:>@])],
1387   [OSMESA_LIB=$withval],
1388   [OSMESA_LIB=OSMesa])
1389 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
1390 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
1391
1392 dnl
1393 dnl Mangled Mesa support
1394 dnl
1395 AC_ARG_ENABLE([mangling],
1396   [AS_HELP_STRING([--enable-mangling],
1397     [enable mangled symbols and library name @<:@default=disabled@:>@])],
1398   [enable_mangling="${enableval}"],
1399   [enable_mangling=no]
1400 )
1401 if test "x${enable_mangling}" = "xyes" ; then
1402   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
1403   GL_LIB="Mangled${GL_LIB}"
1404   OSMESA_LIB="Mangled${OSMESA_LIB}"
1405 fi
1406 AC_SUBST([GL_LIB])
1407 AC_SUBST([OSMESA_LIB])
1408
1409 # Check for libdrm
1410 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1411                   [have_libdrm=yes], [have_libdrm=no])
1412 if test "x$have_libdrm" = xyes; then
1413         DEFINES="$DEFINES -DHAVE_LIBDRM"
1414 fi
1415
1416 require_libdrm() {
1417     if test "x$have_libdrm" != xyes; then
1418        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1419     fi
1420 }
1421
1422
1423 # Select which platform-dependent DRI code gets built
1424 case "$host_os" in
1425 darwin*)
1426     dri_platform='apple' ;;
1427 cygwin*)
1428     dri_platform='windows' ;;
1429 gnu*)
1430     dri_platform='none' ;;
1431 *)
1432     dri_platform='drm' ;;
1433 esac
1434
1435 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1436     have_drisw_kms='yes'
1437 fi
1438
1439 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1440 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1441 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1442 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1443 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1444 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1445 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1446 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1447 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1448
1449 AC_ARG_ENABLE([shared-glapi],
1450     [AS_HELP_STRING([--enable-shared-glapi],
1451         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1452     [enable_shared_glapi="$enableval"],
1453     [enable_shared_glapi=yes])
1454
1455 case "x$enable_opengl$enable_gles1$enable_gles2" in
1456 x*yes*yes*)
1457     if test "x$enable_shared_glapi" = xno; then
1458         AC_MSG_ERROR([shared GLAPI required when building two or more of
1459                       the following APIs - opengl, gles1 gles2])
1460     fi
1461     ;;
1462 esac
1463
1464 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1465
1466 # Build the pipe-drivers as separate libraries/modules.
1467 # Do not touch this unless you know what you are doing.
1468 # XXX: Expose via configure option ?
1469 enable_shared_pipe_drivers=no
1470
1471 dnl
1472 dnl Driver specific build directories
1473 dnl
1474
1475 if test "x$enable_gallium_osmesa" = xyes; then
1476     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1477         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1478     fi
1479     if test "x$enable_osmesa" = xyes; then
1480         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1481     fi
1482 fi
1483
1484 require_dri_shared_libs_and_glapi() {
1485     if test "x$enable_static" = xyes; then
1486         AC_MSG_ERROR([$1 cannot be build as static library])
1487     fi
1488
1489     if test "x$enable_dri" != xyes; then
1490         # There is only a single backend which won't be build/used otherwise.
1491         # XXX: Revisit this as the egl/haiku is a thing.
1492         AC_MSG_ERROR([$1 requires --enable-dri])
1493     fi
1494
1495     if test "x$enable_shared_glapi" != xyes; then
1496         AC_MSG_ERROR([$1 requires --enable-shared-glapi])
1497     fi
1498 }
1499
1500 if test "x$enable_dri" = xyes; then
1501     require_dri_shared_libs_and_glapi "DRI"
1502
1503     # not a hard requirement as swrast does not depend on it
1504     if test "x$have_libdrm" = xyes; then
1505         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1506     fi
1507 fi
1508
1509 AC_ARG_ENABLE([driglx-direct],
1510     [AS_HELP_STRING([--disable-driglx-direct],
1511         [disable direct rendering in GLX and EGL for DRI \
1512             @<:@default=auto@:>@])],
1513     [driglx_direct="$enableval"],
1514     [driglx_direct="yes"])
1515
1516 dnl
1517 dnl libGL configuration per driver
1518 dnl
1519 if test "x$enable_glx" != xno; then
1520     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1521 fi
1522 case "x$enable_glx" in
1523 xxlib | xgallium-xlib)
1524     # Xlib-based GLX
1525     dri_modules="x11 xext xcb"
1526     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1527     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1528     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1529     GL_LIB_DEPS="$XLIBGL_LIBS"
1530     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1531     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1532     ;;
1533 xdri)
1534     # DRI-based GLX
1535
1536     # find the DRI deps for libGL
1537     dri_modules="x11 xext xdamage >= $XDAMAGE_REQUIRED xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1538
1539     if test x"$driglx_direct" = xyes; then
1540         if test x"$dri_platform" = xdrm ; then
1541             DEFINES="$DEFINES -DGLX_USE_DRM"
1542             require_libdrm "Direct rendering"
1543
1544             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1545             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1546             if test x"$enable_dri3" = xyes; then
1547                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1548                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1549             fi
1550
1551             if test x"$enable_dri" = xyes; then
1552                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1553             fi
1554
1555             if test x"$enable_dri3" = xyes; then
1556                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1557                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1558                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1559             fi
1560         fi
1561         if test x"$dri_platform" = xapple ; then
1562             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1563         fi
1564         if test x"$dri_platform" = xwindows ; then
1565             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1566         fi
1567     fi
1568
1569     # add xf86vidmode if available
1570     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1571     if test "$HAVE_XF86VIDMODE" = yes ; then
1572         dri_modules="$dri_modules xxf86vm"
1573     fi
1574
1575     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1576     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1577     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1578     GL_LIB_DEPS="$DRIGL_LIBS"
1579
1580     # need DRM libs, $PTHREAD_LIBS, etc.
1581     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1582     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1583     ;;
1584 esac
1585
1586 # This is outside the case (above) so that it is invoked even for non-GLX
1587 # builds.
1588 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1589
1590 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1591 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1592 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1593 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1594
1595 AC_SUBST([X11_INCLUDES])
1596 AC_SUBST([GL_LIB_DEPS])
1597 AC_SUBST([GL_PC_REQ_PRIV])
1598 AC_SUBST([GL_PC_LIB_PRIV])
1599 AC_SUBST([GL_PC_CFLAGS])
1600 AC_SUBST([DRI_PC_REQ_PRIV])
1601 AC_SUBST([GLESv1_CM_LIB_DEPS])
1602 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1603 AC_SUBST([GLESv2_LIB_DEPS])
1604 AC_SUBST([GLESv2_PC_LIB_PRIV])
1605
1606 AC_SUBST([HAVE_XF86VIDMODE])
1607
1608 dnl
1609 dnl More GLX setup
1610 dnl
1611 case "x$enable_glx" in
1612 xxlib | xgallium-xlib)
1613     DEFINES="$DEFINES -DUSE_XSHM"
1614     ;;
1615 xdri)
1616     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1617     if test "x$driglx_direct" = xyes; then
1618         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1619     fi
1620     ;;
1621 esac
1622
1623 dnl
1624 dnl TLS detection
1625 dnl
1626
1627 AC_ARG_ENABLE([glx-tls],
1628     [AS_HELP_STRING([--enable-glx-tls],
1629         [enable TLS support in GLX @<:@default=enabled@:>@])],
1630     [GLX_USE_TLS="$enableval"],
1631     [GLX_USE_TLS=yes])
1632 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1633
1634 if test "x$GLX_USE_TLS" = xyes; then
1635     DEFINES="$DEFINES -DGLX_USE_TLS"
1636 fi
1637
1638 dnl Read-only text section on x86 hardened platforms
1639 AC_ARG_ENABLE([glx-read-only-text],
1640     [AS_HELP_STRING([--enable-glx-read-only-text],
1641         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1642     [enable_glx_read_only_text="$enableval"],
1643     [enable_glx_read_only_text=no])
1644 if test "x$enable_glx_read_only_text" = xyes; then
1645     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1646 fi
1647
1648 dnl
1649 dnl More DRI setup
1650 dnl
1651 dnl Directory for DRI drivers
1652 AC_ARG_WITH([dri-driverdir],
1653     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1654         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1655     [DRI_DRIVER_INSTALL_DIR="$withval"],
1656     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1657 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1658 dnl Extra search path for DRI drivers
1659 AC_ARG_WITH([dri-searchpath],
1660     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1661         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1662     [DRI_DRIVER_SEARCH_DIR="$withval"],
1663     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1664 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1665 dnl Which drivers to build - default is chosen by platform
1666 AC_ARG_WITH([dri-drivers],
1667     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1668         [comma delimited classic DRI drivers list, e.g.
1669         "i915,i965,nouveau,radeon,r200,swrast" @<:@default=auto@:>@])],
1670     [with_dri_drivers="$withval"],
1671     [with_dri_drivers=auto])
1672
1673 if test "x$with_dri_drivers" = xauto; then
1674     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1675         with_dri_drivers="yes"
1676     else
1677         with_dri_drivers="no"
1678     fi
1679 fi
1680 if test "x$with_dri_drivers" = xno; then
1681     with_dri_drivers=''
1682 fi
1683
1684 dnl If $with_dri_drivers is yes, drivers will be added through
1685 dnl platform checks. Set DEFINES and LIB_DEPS
1686 if test "x$enable_dri" = xyes; then
1687     # Platform specific settings and drivers to build
1688     case "$host_os" in
1689     linux*)
1690         if test "x$enable_dri3" = xyes; then
1691             DEFINES="$DEFINES -DHAVE_DRI3"
1692         fi
1693
1694         case "$host_cpu" in
1695         powerpc* | sparc*)
1696             # Build only the drivers for cards that exist on PowerPC/sparc
1697             if test "x$with_dri_drivers" = "xyes"; then
1698                 with_dri_drivers="r200 radeon swrast"
1699             fi
1700             ;;
1701         esac
1702         ;;
1703     cygwin*)
1704         if test "x$with_dri_drivers" = "xyes"; then
1705             with_dri_drivers="swrast"
1706         fi
1707         ;;
1708     darwin*)
1709         DEFINES="$DEFINES -DBUILDING_MESA"
1710         if test "x$with_dri_drivers" = "xyes"; then
1711             with_dri_drivers="swrast"
1712         fi
1713         ;;
1714     esac
1715
1716     # default drivers
1717     if test "x$with_dri_drivers" = "xyes"; then
1718         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1719     fi
1720
1721     # Check for expat
1722     PKG_CHECK_MODULES([EXPAT], [expat], [],
1723         # expat version 2.0 and earlier do not provide expat.pc
1724         [AC_CHECK_HEADER([expat.h],[],
1725                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1726          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1727                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1728          EXPAT_LIBS="-lexpat"])
1729
1730     # put all the necessary libs together
1731     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1732 fi
1733
1734 AC_SUBST([DRI_LIB_DEPS])
1735
1736 DRI_DIRS=''
1737 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1738 if test -n "$with_dri_drivers"; then
1739     if test "x$enable_opengl" != xyes; then
1740         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1741     fi
1742
1743     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1744     for driver in $dri_drivers; do
1745         DRI_DIRS="$DRI_DIRS $driver"
1746         case "x$driver" in
1747         xi915)
1748             require_libdrm "i915"
1749             HAVE_I915_DRI=yes
1750             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1751             ;;
1752         xi965)
1753             require_libdrm "i965"
1754             HAVE_I965_DRI=yes
1755             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1756             ;;
1757         xnouveau)
1758             require_libdrm "nouveau"
1759             HAVE_NOUVEAU_DRI=yes
1760             PKG_CHECK_MODULES([NVVIEUX], [libdrm >= $LIBDRM_NVVIEUX_REQUIRED libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1761             ;;
1762         xradeon)
1763             require_libdrm "radeon"
1764             HAVE_RADEON_DRI=yes;
1765             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1766             ;;
1767         xr200)
1768             require_libdrm "r200"
1769             HAVE_R200_DRI=yes
1770             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1771             ;;
1772         xswrast)
1773             HAVE_SWRAST_DRI=yes
1774             ;;
1775         *)
1776             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1777             ;;
1778         esac
1779     done
1780     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1781 fi
1782
1783
1784 dnl
1785 dnl Gallium LLVM
1786 dnl Deprecated: kept for backwards compatibility
1787 dnl
1788 AC_ARG_ENABLE([gallium-llvm],
1789     [AS_HELP_STRING([--enable-gallium-llvm],
1790         [DEPRECATED: use --enable-llvm instead])],
1791     [enable_gallium_llvm="$enableval"],
1792     [enable_gallium_llvm=auto])
1793
1794 if test "x$enable_gallium_llvm" != xauto; then
1795    AC_MSG_WARN([The --enable-gallium-llvm option has been deprecated. Use --enable-llvm instead.])
1796    enable_llvm=$enable_gallium_llvm
1797 fi
1798
1799 dnl
1800 dnl LLVM
1801 dnl
1802 AC_ARG_ENABLE([llvm],
1803     [AS_HELP_STRING([--enable-llvm],
1804         [build with LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1805     [enable_llvm="$enableval"],
1806     [enable_llvm=auto])
1807
1808 if test "x$enable_llvm" = xauto -a "x$FOUND_LLVM" = xyes; then
1809     if test "x$FOUND_LLVM" = xyes; then
1810         case "$host_cpu" in
1811         i*86|x86_64|amd64) enable_llvm=yes;;
1812         *) enable_llvm=no;;
1813         esac
1814     else
1815         enable_llvm=no
1816     fi
1817 fi
1818
1819 if test "x$enable_llvm" = xyes -a "x$FOUND_LLVM" = xno; then
1820     AC_MSG_ERROR([--enable-llvm selected but llvm-config is not found])
1821 fi
1822
1823 #
1824 # Vulkan driver configuration
1825 #
1826
1827 AC_ARG_WITH([vulkan-drivers],
1828     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1829         [comma delimited Vulkan drivers list, e.g.
1830         "intel,radeon"
1831         @<:@default=no@:>@])],
1832     [with_vulkan_drivers="$withval"],
1833     [with_vulkan_drivers="no"])
1834
1835 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1836 # here so that the script doesn't choke on an unknown driver name later.
1837 case "x$with_vulkan_drivers" in
1838     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1839     xno) with_vulkan_drivers='' ;;
1840 esac
1841
1842 AC_ARG_WITH([vulkan-icddir],
1843     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1844         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1845     [VULKAN_ICD_INSTALL_DIR="$withval"],
1846     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1847 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1848
1849 if test -n "$with_vulkan_drivers"; then
1850     if test "x$ac_cv_func_dl_iterate_phdr" = xno; then
1851         AC_MSG_ERROR([Vulkan drivers require the dl_iterate_phdr function])
1852     fi
1853
1854     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1855     for driver in $VULKAN_DRIVERS; do
1856         case "x$driver" in
1857         xintel)
1858             require_libdrm "ANV"
1859             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1860             HAVE_INTEL_VULKAN=yes
1861             ;;
1862         xradeon)
1863             require_libdrm "radv"
1864             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1865             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1866             HAVE_RADEON_VULKAN=yes
1867             ;;
1868         *)
1869             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1870             ;;
1871         esac
1872     done
1873     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1874 fi
1875
1876
1877 DEFINES="$DEFINES -DENABLE_SHADER_CACHE"
1878 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1879 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1880                                   "x$enable_osmesa" = xyes -o \
1881                                   -n "$DRI_DIRS")
1882
1883 dnl
1884 dnl OSMesa configuration
1885 dnl
1886
1887 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1888 AC_ARG_WITH([osmesa-bits],
1889     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1890         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1891     [osmesa_bits="$withval"],
1892     [osmesa_bits=8])
1893 if test "x$osmesa_bits" != x8; then
1894     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1895         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1896         osmesa_bits=8
1897     fi
1898 fi
1899 case "x$osmesa_bits" in
1900 x8)
1901     OSMESA_LIB="${OSMESA_LIB}"
1902     ;;
1903 x16|x32)
1904     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1905     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1906     ;;
1907 *)
1908     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1909     ;;
1910 esac
1911
1912 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1913     # only link libraries with osmesa if shared
1914     if test "$enable_static" = no; then
1915         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1916     else
1917         OSMESA_LIB_DEPS=""
1918     fi
1919     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1920 fi
1921
1922 AC_SUBST([OSMESA_LIB_DEPS])
1923 AC_SUBST([OSMESA_PC_REQ])
1924 AC_SUBST([OSMESA_PC_LIB_PRIV])
1925
1926 dnl
1927 dnl gbm configuration
1928 dnl
1929 if test "x$enable_gbm" = xyes; then
1930     require_dri_shared_libs_and_glapi "gbm"
1931 fi
1932 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1933 # FINISHME: GBM has a number of dependencies which we should add below
1934 GBM_PC_REQ_PRIV=""
1935 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1936 AC_SUBST([GBM_PC_REQ_PRIV])
1937 AC_SUBST([GBM_PC_LIB_PRIV])
1938
1939 dnl
1940 dnl EGL configuration
1941 dnl
1942
1943 if test "x$enable_egl" = xyes; then
1944     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1945
1946     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1947
1948     require_dri_shared_libs_and_glapi "egl"
1949 fi
1950 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1951 AC_SUBST([EGL_LIB_DEPS])
1952
1953 gallium_st="mesa"
1954
1955 dnl
1956 dnl XA configuration
1957 dnl
1958 if test "x$enable_xa" = xyes; then
1959     if test "x$with_gallium_drivers" = xswrast; then
1960        AC_MSG_ERROR([
1961           Building xa requires at least one non swrast gallium driver.
1962           If you are looking to use libxatracker.so with the VMware driver,
1963           make sure to include svga in the gallium drivers list, apart from
1964           enabling XA.
1965           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1966     fi
1967     gallium_st="$gallium_st xa"
1968 fi
1969 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1970
1971 dnl
1972 dnl Gallium G3DVL configuration
1973 dnl
1974 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1975     if test "x$enable_xvmc" = xauto; then
1976         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1977     fi
1978
1979     if test "x$enable_vdpau" = xauto; then
1980         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1981     fi
1982
1983     if test "x$enable_omx" = xauto; then
1984         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1985     fi
1986
1987     if test "x$enable_va" = xauto; then
1988         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1989     fi
1990 fi
1991
1992 if test "x$enable_dri" = xyes -o \
1993         "x$enable_xvmc" = xyes -o \
1994         "x$enable_vdpau" = xyes -o \
1995         "x$enable_omx" = xyes -o \
1996         "x$enable_va" = xyes; then
1997     need_gallium_vl=yes
1998 fi
1999 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2000
2001 if test "x$enable_xvmc" = xyes -o \
2002         "x$enable_vdpau" = xyes -o \
2003         "x$enable_omx" = xyes -o \
2004         "x$enable_va" = xyes; then
2005     if test x"$enable_dri3" = xyes; then
2006         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2007                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2008     else
2009         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2010     fi
2011     need_gallium_vl_winsys=yes
2012 fi
2013 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2014
2015 if test "x$enable_xvmc" = xyes; then
2016     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2017     gallium_st="$gallium_st xvmc"
2018 fi
2019 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2020
2021 if test "x$enable_vdpau" = xyes; then
2022     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2023     gallium_st="$gallium_st vdpau"
2024     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2025 fi
2026 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2027
2028 if test "x$enable_omx" = xyes; then
2029     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2030     gallium_st="$gallium_st omx"
2031 fi
2032 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2033
2034 if test "x$enable_va" = xyes; then
2035     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2036     gallium_st="$gallium_st va"
2037 fi
2038 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2039
2040 dnl
2041 dnl Nine Direct3D9 configuration
2042 dnl
2043 if test "x$enable_nine" = xyes; then
2044     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2045         AC_MSG_ERROR([nine requires the gallium swrast driver])
2046     fi
2047     if test "x$with_gallium_drivers" = xswrast; then
2048         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2049     fi
2050     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2051         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2052     fi
2053
2054     if test "x$enable_dri3" = xno; then
2055         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2056     fi
2057
2058     gallium_st="$gallium_st nine"
2059 fi
2060 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2061
2062 dnl
2063 dnl OpenCL configuration
2064 dnl
2065
2066 AC_ARG_WITH([clang-libdir],
2067    [AS_HELP_STRING([--with-clang-libdir],
2068          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2069    [CLANG_LIBDIR="$withval"],
2070    [CLANG_LIBDIR=''])
2071
2072 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2073
2074 if test "x$enable_opencl" = xyes; then
2075     if test -z "$with_gallium_drivers"; then
2076         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2077     fi
2078
2079     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2080         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2081     fi
2082
2083     if test "x$have_libclc" = xno; then
2084         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2085                     Make sure the directory containing libclc.pc is specified in your
2086                     PKG_CONFIG_PATH environment variable.
2087                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2088     else
2089         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2090         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2091         AC_SUBST([LIBCLC_INCLUDEDIR])
2092         AC_SUBST([LIBCLC_LIBEXECDIR])
2093     fi
2094
2095     gallium_st="$gallium_st clover"
2096
2097     if test "x$enable_opencl_icd" = xyes; then
2098         OPENCL_LIBNAME="MesaOpenCL"
2099     else
2100         OPENCL_LIBNAME="OpenCL"
2101     fi
2102
2103     if test "x$have_libelf" != xyes; then
2104        AC_MSG_ERROR([Clover requires libelf])
2105     fi
2106
2107     if test "x${ac_cv_cxx_compiler_gnu}" = xyes; then
2108         altivec_enabled=no
2109         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
2110         #if !defined(__VEC__) || !defined(__ALTIVEC__)
2111         #error "AltiVec not enabled"
2112         #endif
2113         ])], altivec_enabled=yes)
2114
2115         if test "$altivec_enabled" = yes; then
2116             CLOVER_STD_OVERRIDE="-std=gnu++11"
2117         fi
2118         AC_SUBST([CLOVER_STD_OVERRIDE])
2119     fi
2120
2121     llvm_require_version $LLVM_REQUIRED_OPENCL "opencl"
2122
2123     llvm_add_default_components "opencl"
2124     llvm_add_component "all-targets" "opencl"
2125     llvm_add_component "linker" "opencl"
2126     llvm_add_component "instrumentation" "opencl"
2127     llvm_add_component "ipo" "opencl"
2128     llvm_add_component "irreader" "opencl"
2129     llvm_add_component "option" "opencl"
2130     llvm_add_component "objcarcopts" "opencl"
2131     llvm_add_component "profiledata" "opencl"
2132
2133     dnl Check for Clang internal headers
2134     if test -z "$CLANG_LIBDIR"; then
2135         CLANG_LIBDIR=${LLVM_LIBDIR}
2136     fi
2137     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2138     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2139         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2140 fi
2141 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2142 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2143 AC_SUBST([OPENCL_LIBNAME])
2144 AC_SUBST([CLANG_RESOURCE_DIR])
2145
2146 dnl
2147 dnl Gallium configuration
2148 dnl
2149 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2150
2151 dnl
2152 dnl EGL Platforms configuration
2153 dnl
2154 AC_ARG_WITH([egl-platforms],
2155     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2156         [comma delimited native platforms libEGL supports, e.g.
2157         "x11,drm" @<:@default=auto@:>@])],
2158     [with_egl_platforms="$withval"],
2159     [if test "x$enable_egl" = xyes; then
2160         if test "x$enable_gbm" = xyes; then
2161            with_egl_platforms="x11,drm"
2162         else
2163            with_egl_platforms="x11"
2164         fi
2165     else
2166         with_egl_platforms=""
2167     fi])
2168
2169 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2170     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2171 fi
2172
2173 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2174         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2175         WAYLAND_SCANNER='')
2176 if test "x$WAYLAND_SCANNER" = x; then
2177     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner], [:])
2178 fi
2179
2180 # Do per-EGL platform setups and checks
2181 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2182 for plat in $egl_platforms; do
2183         case "$plat" in
2184         wayland)
2185
2186                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2187
2188                 if test "x$WAYLAND_SCANNER" = "x:"; then
2189                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2190                 fi
2191                 ;;
2192
2193         x11)
2194                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2195                 ;;
2196
2197         drm)
2198                 test "x$enable_gbm" = "xno" &&
2199                         AC_MSG_ERROR([EGL platform drm needs gbm])
2200                 ;;
2201
2202         surfaceless)
2203                 ;;
2204
2205         android)
2206                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2207                 ;;
2208
2209         *)
2210                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2211                 ;;
2212         esac
2213
2214         case "$plat" in
2215         wayland|drm|surfaceless)
2216                 require_libdrm "Platform $plat"
2217                 ;;
2218         esac
2219 done
2220
2221 # libEGL wants to default to the first platform specified in
2222 # ./configure.  parse that here.
2223 if test "x$egl_platforms" != "x"; then
2224     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2225     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2226 else
2227     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2228 fi
2229
2230 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2231 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2232 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2233 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2234 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2235
2236 AC_SUBST([EGL_NATIVE_PLATFORM])
2237 AC_SUBST([EGL_CFLAGS])
2238
2239 # If we don't have the X11 platform, set this define so we don't try to include
2240 # the X11 headers.
2241 if ! echo "$egl_platforms" | grep -q 'x11'; then
2242     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2243     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2244 fi
2245
2246 dnl Directory for XVMC libs
2247 AC_ARG_WITH([xvmc-libdir],
2248     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2249         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2250     [XVMC_LIB_INSTALL_DIR="$withval"],
2251     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2252 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2253
2254 dnl
2255 dnl Gallium Tests
2256 dnl
2257 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2258
2259 dnl Directory for VDPAU libs
2260 AC_ARG_WITH([vdpau-libdir],
2261     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2262         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2263     [VDPAU_LIB_INSTALL_DIR="$withval"],
2264     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2265 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2266
2267 dnl Directory for OMX libs
2268
2269 AC_ARG_WITH([omx-libdir],
2270     [AS_HELP_STRING([--with-omx-libdir=DIR],
2271         [directory for the OMX libraries])],
2272     [OMX_LIB_INSTALL_DIR="$withval"],
2273     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --exists libomxil-bellagio && \
2274                           $PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2275 AC_SUBST([OMX_LIB_INSTALL_DIR])
2276
2277 dnl Directory for VA libs
2278
2279 AC_ARG_WITH([va-libdir],
2280     [AS_HELP_STRING([--with-va-libdir=DIR],
2281         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2282     [VA_LIB_INSTALL_DIR="$withval"],
2283     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2284 AC_SUBST([VA_LIB_INSTALL_DIR])
2285
2286 AC_ARG_WITH([d3d-libdir],
2287     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2288         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2289     [D3D_DRIVER_INSTALL_DIR="$withval"],
2290     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2291 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2292
2293 dnl
2294 dnl r300 doesn't strictly require LLVM, but for performance reasons we
2295 dnl highly recommend LLVM usage. So require it at least on x86 and x86_64
2296 dnl architectures.
2297 dnl
2298 r300_require_llvm() {
2299     case "$host" in *gnux32) return;; esac
2300     case "$host_cpu" in
2301     i*86|x86_64|amd64) require_llvm $1
2302         ;;
2303     esac
2304 }
2305
2306 dnl
2307 dnl DRM is needed by X, Wayland, and offscreen rendering.
2308 dnl Surfaceless is an alternative for the last one.
2309 dnl
2310 require_basic_egl() {
2311     case "$with_egl_platforms" in
2312         *drm*|*surfaceless*)
2313             ;;
2314         *)
2315             AC_MSG_ERROR([$1 requires one of these:
2316                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2317                   2) --with-egl-platforms=surfaceless (offscreen only)
2318                   Recommended options: drm,x11])
2319             ;;
2320     esac
2321 }
2322
2323 swr_require_cxx_feature_flags() {
2324     feature_name="$1"
2325     preprocessor_test="$2"
2326     option_list="$3"
2327     output_var="$4"
2328
2329     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2330     AC_LANG_PUSH([C++])
2331     save_CXXFLAGS="$CXXFLAGS"
2332     save_IFS="$IFS"
2333     IFS=","
2334     found=0
2335     for opts in $option_list
2336     do
2337         unset IFS
2338         CXXFLAGS="$opts $save_CXXFLAGS"
2339         AC_COMPILE_IFELSE(
2340             [AC_LANG_PROGRAM(
2341                 [   #if !($preprocessor_test)
2342                     #error
2343                     #endif
2344                 ])],
2345             [found=1; break],
2346             [])
2347         IFS=","
2348     done
2349     IFS="$save_IFS"
2350     CXXFLAGS="$save_CXXFLAGS"
2351     AC_LANG_POP([C++])
2352     if test $found -eq 1; then
2353         AC_MSG_RESULT([$opts])
2354         eval "$output_var=\$opts"
2355         return 0
2356     fi
2357     AC_MSG_RESULT([no])
2358     AC_MSG_ERROR([swr requires $feature_name support])
2359     return 1
2360 }
2361
2362 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2363 if test -n "$with_gallium_drivers"; then
2364     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2365     for driver in $gallium_drivers; do
2366         case "x$driver" in
2367         xsvga)
2368             HAVE_GALLIUM_SVGA=yes
2369             require_libdrm "svga"
2370             ;;
2371         xi915)
2372             HAVE_GALLIUM_I915=yes
2373             PKG_CHECK_MODULES([INTEL], [libdrm >= $LIBDRM_INTEL_REQUIRED libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2374             require_libdrm "Gallium i915"
2375             ;;
2376         xr300)
2377             HAVE_GALLIUM_R300=yes
2378             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2379             require_libdrm "r300"
2380             r300_require_llvm "r300"
2381             ;;
2382         xr600)
2383             HAVE_GALLIUM_R600=yes
2384             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2385             require_libdrm "r600"
2386             if test "x$enable_llvm" = xyes; then
2387                 radeon_llvm_check $LLVM_REQUIRED_R600 "r600"
2388
2389                 llvm_add_component "asmparser" "r600"
2390                 llvm_add_component "bitreader" "r600"
2391             fi
2392             ;;
2393         xradeonsi)
2394             HAVE_GALLIUM_RADEONSI=yes
2395             PKG_CHECK_MODULES([RADEON], [libdrm >= $LIBDRM_RADEON_REQUIRED libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2396             PKG_CHECK_MODULES([AMDGPU], [libdrm >= $LIBDRM_AMDGPU_REQUIRED libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2397             require_libdrm "radeonsi"
2398             radeon_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2399             if test "x$enable_egl" = xyes; then
2400                 require_basic_egl "radeonsi"
2401             fi
2402             ;;
2403         xnouveau)
2404             HAVE_GALLIUM_NOUVEAU=yes
2405             PKG_CHECK_MODULES([NOUVEAU], [libdrm >= $LIBDRM_NOUVEAU_REQUIRED libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2406             require_libdrm "nouveau"
2407             ;;
2408         xfreedreno)
2409             HAVE_GALLIUM_FREEDRENO=yes
2410             PKG_CHECK_MODULES([FREEDRENO], [libdrm >= $LIBDRM_FREEDRENO_REQUIRED libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2411             require_libdrm "freedreno"
2412             ;;
2413         xetnaviv)
2414             HAVE_GALLIUM_ETNAVIV=yes
2415             PKG_CHECK_MODULES([ETNAVIV], [libdrm >= $LIBDRM_ETNAVIV_REQUIRED libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2416             require_libdrm "etnaviv"
2417             ;;
2418        ximx)
2419             HAVE_GALLIUM_IMX=yes
2420             ;;
2421         xswrast)
2422             HAVE_GALLIUM_SOFTPIPE=yes
2423             if test "x$enable_llvm" = xyes; then
2424                 HAVE_GALLIUM_LLVMPIPE=yes
2425             fi
2426             ;;
2427         xswr)
2428             llvm_require_version $LLVM_REQUIRED_SWR "swr"
2429
2430             swr_require_cxx_feature_flags "C++14" "__cplusplus >= 201402L" \
2431                 "-std=c++14" \
2432                 SWR_CXX14_CXXFLAGS
2433             AC_SUBST([SWR_CXX14_CXXFLAGS])
2434
2435             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2436                 ",-mavx,-march=core-avx" \
2437                 SWR_AVX_CXXFLAGS
2438             AC_SUBST([SWR_AVX_CXXFLAGS])
2439
2440             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2441                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2442                 SWR_AVX2_CXXFLAGS
2443             AC_SUBST([SWR_AVX2_CXXFLAGS])
2444
2445             HAVE_GALLIUM_SWR=yes
2446             ;;
2447         xvc4)
2448             HAVE_GALLIUM_VC4=yes
2449             PKG_CHECK_MODULES([VC4], [libdrm >= $LIBDRM_VC4_REQUIRED libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2450             require_libdrm "vc4"
2451
2452             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2453                               [USE_VC4_SIMULATOR=yes;
2454                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2455                               [USE_VC4_SIMULATOR=no])
2456             ;;
2457         xvirgl)
2458             HAVE_GALLIUM_VIRGL=yes
2459             require_libdrm "virgl"
2460             require_basic_egl "virgl"
2461             ;;
2462         *)
2463             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2464             ;;
2465         esac
2466     done
2467 fi
2468
2469 if test "x$enable_llvm" = "xyes" -a "$with_gallium_drivers"; then
2470     llvm_require_version $LLVM_REQUIRED_GALLIUM "gallium"
2471     llvm_add_default_components "gallium"
2472 fi
2473
2474 dnl We need to validate some needed dependencies for renderonly drivers.
2475
2476 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" = xyes  ; then
2477     AC_MSG_ERROR([Building with imx requires etnaviv])
2478 fi
2479
2480 dnl
2481 dnl Set defines and buildtime variables only when using LLVM.
2482 dnl
2483 if test "x$enable_llvm" = xyes; then
2484     DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2485
2486     LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2487     LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2488     LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2489
2490     dnl Set LLVM_LIBS - This is done after the driver configuration so
2491     dnl that drivers can add additional components to LLVM_COMPONENTS.
2492     dnl Previously, gallium drivers were updating LLVM_LIBS directly
2493     dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2494     dnl this was causing the same libraries to be appear multiple times
2495     dnl in LLVM_LIBS.
2496
2497     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2498        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2499     fi
2500     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2501
2502     dnl llvm-config may not give the right answer when llvm is a built as a
2503     dnl single shared library, so we must work the library name out for
2504     dnl ourselves.
2505     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2506     if test "x$enable_llvm_shared_libs" = xyes; then
2507         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2508         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2509         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2510
2511         if test "x$llvm_have_one_so" = xyes; then
2512             dnl LLVM was built using auto*, so there is only one shared object.
2513             LLVM_LIBS="-l$LLVM_SO_NAME"
2514         else
2515             dnl If LLVM was built with CMake, there will be one shared object per
2516             dnl component.
2517             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2518                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2519         Please make sure you have built llvm with the --enable-shared option
2520         and that your llvm libraries are installed in $LLVM_LIBDIR
2521         If you have installed your llvm libraries to a different directory you
2522         can use the --with-llvm-prefix= configure flag to specify this directory.
2523         NOTE: Mesa is attempting to use llvm shared libraries by default.
2524         If you do not want to build with llvm shared libraries and instead want to
2525         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2526         invocation and rebuild.])])
2527
2528            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2529            dnl install uses a shared object for each component and we have
2530            dnl already added all of these objects to LLVM_LIBS.
2531         fi
2532     else
2533         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2534         dnl We need to link to llvm system libs when using static libs
2535         dnl However, only llvm 3.5+ provides --system-libs
2536         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2537             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2538         fi
2539     fi
2540 fi
2541
2542 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2543 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2544 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2545 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2546 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2547 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2548                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2550 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2557                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2558                                          "x$HAVE_GALLIUM_SWR" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2561
2562 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2563
2564 if test "x$enable_dri" = xyes; then
2565     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2566 fi
2567
2568 if test "x$have_drisw_kms" = xyes; then
2569     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2570 fi
2571 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2572
2573 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2574 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2575 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2576 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2577 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2578 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2579
2580 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2581 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2582
2583 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2584                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2585                                       "x$HAVE_RADEON_VULKAN" = xyes)
2586
2587 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2588                                         "x$HAVE_I965_DRI" = xyes)
2589
2590 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2591                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2592                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2593 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2594 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2595 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$enable_llvm" = xyes)
2596 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2597
2598 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2599 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2600 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2601 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2602                                         "x$enable_gallium_osmesa" = xyes)
2603
2604 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2605 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2606 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2607
2608 AC_SUBST([NINE_MAJOR], 1)
2609 AC_SUBST([NINE_MINOR], 0)
2610 AC_SUBST([NINE_TINY], 0)
2611 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2612
2613 AC_SUBST([VDPAU_MAJOR], 1)
2614 AC_SUBST([VDPAU_MINOR], 0)
2615
2616 if test "x$enable_va" = xyes; then
2617     VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2618     VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2619 fi
2620 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2621 AC_SUBST([VA_MINOR], $VA_MINOR)
2622
2623 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2624
2625 AC_SUBST([XVMC_MAJOR], 1)
2626 AC_SUBST([XVMC_MINOR], 0)
2627
2628 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2629 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2630 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2631 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2632
2633 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2634 AC_SUBST([XA_MINOR], $XA_MINOR)
2635 AC_SUBST([XA_TINY], $XA_TINY)
2636 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2637
2638 AC_ARG_ENABLE(valgrind,
2639               [AS_HELP_STRING([--enable-valgrind],
2640                              [Build mesa with valgrind support (default: auto)])],
2641                              [VALGRIND=$enableval], [VALGRIND=auto])
2642 if test "x$VALGRIND" != xno; then
2643         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2644 fi
2645 AC_MSG_CHECKING([whether to enable Valgrind support])
2646 if test "x$VALGRIND" = xauto; then
2647         VALGRIND="$have_valgrind"
2648 fi
2649
2650 if test "x$VALGRIND" = "xyes"; then
2651         if ! test "x$have_valgrind" = xyes; then
2652                 AC_MSG_ERROR([Valgrind support required but not present])
2653         fi
2654         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2655 fi
2656
2657 AC_MSG_RESULT([$VALGRIND])
2658
2659 dnl Restore LDFLAGS and CPPFLAGS
2660 LDFLAGS="$_SAVE_LDFLAGS"
2661 CPPFLAGS="$_SAVE_CPPFLAGS"
2662
2663 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2664 if test "x$acv_mesa_CLANG" = xyes; then
2665     CFLAGS="$CFLAGS -Qunused-arguments"
2666     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2667 fi
2668
2669 dnl Add user CFLAGS and CXXFLAGS
2670 CFLAGS="$CFLAGS $USER_CFLAGS"
2671 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2672
2673 dnl Substitute the config
2674 AC_CONFIG_FILES([Makefile
2675                 src/Makefile
2676                 src/amd/Makefile
2677                 src/amd/vulkan/Makefile
2678                 src/compiler/Makefile
2679                 src/egl/Makefile
2680                 src/egl/main/egl.pc
2681                 src/egl/wayland/wayland-drm/Makefile
2682                 src/egl/wayland/wayland-egl/Makefile
2683                 src/egl/wayland/wayland-egl/wayland-egl.pc
2684                 src/gallium/Makefile
2685                 src/gallium/auxiliary/Makefile
2686                 src/gallium/auxiliary/pipe-loader/Makefile
2687                 src/gallium/drivers/freedreno/Makefile
2688                 src/gallium/drivers/ddebug/Makefile
2689                 src/gallium/drivers/i915/Makefile
2690                 src/gallium/drivers/llvmpipe/Makefile
2691                 src/gallium/drivers/noop/Makefile
2692                 src/gallium/drivers/nouveau/Makefile
2693                 src/gallium/drivers/r300/Makefile
2694                 src/gallium/drivers/r600/Makefile
2695                 src/gallium/drivers/radeon/Makefile
2696                 src/gallium/drivers/radeonsi/Makefile
2697                 src/gallium/drivers/rbug/Makefile
2698                 src/gallium/drivers/softpipe/Makefile
2699                 src/gallium/drivers/svga/Makefile
2700                 src/gallium/drivers/swr/Makefile
2701                 src/gallium/drivers/trace/Makefile
2702                 src/gallium/drivers/etnaviv/Makefile
2703                 src/gallium/drivers/imx/Makefile
2704                 src/gallium/drivers/vc4/Makefile
2705                 src/gallium/drivers/virgl/Makefile
2706                 src/gallium/state_trackers/clover/Makefile
2707                 src/gallium/state_trackers/dri/Makefile
2708                 src/gallium/state_trackers/glx/xlib/Makefile
2709                 src/gallium/state_trackers/nine/Makefile
2710                 src/gallium/state_trackers/omx/Makefile
2711                 src/gallium/state_trackers/osmesa/Makefile
2712                 src/gallium/state_trackers/va/Makefile
2713                 src/gallium/state_trackers/vdpau/Makefile
2714                 src/gallium/state_trackers/xa/Makefile
2715                 src/gallium/state_trackers/xvmc/Makefile
2716                 src/gallium/targets/d3dadapter9/Makefile
2717                 src/gallium/targets/d3dadapter9/d3d.pc
2718                 src/gallium/targets/dri/Makefile
2719                 src/gallium/targets/libgl-xlib/Makefile
2720                 src/gallium/targets/omx/Makefile
2721                 src/gallium/targets/opencl/Makefile
2722                 src/gallium/targets/opencl/mesa.icd
2723                 src/gallium/targets/osmesa/Makefile
2724                 src/gallium/targets/osmesa/osmesa.pc
2725                 src/gallium/targets/pipe-loader/Makefile
2726                 src/gallium/targets/va/Makefile
2727                 src/gallium/targets/vdpau/Makefile
2728                 src/gallium/targets/xa/Makefile
2729                 src/gallium/targets/xa/xatracker.pc
2730                 src/gallium/targets/xvmc/Makefile
2731                 src/gallium/tests/trivial/Makefile
2732                 src/gallium/tests/unit/Makefile
2733                 src/gallium/winsys/etnaviv/drm/Makefile
2734                 src/gallium/winsys/imx/drm/Makefile
2735                 src/gallium/winsys/freedreno/drm/Makefile
2736                 src/gallium/winsys/i915/drm/Makefile
2737                 src/gallium/winsys/nouveau/drm/Makefile
2738                 src/gallium/winsys/radeon/drm/Makefile
2739                 src/gallium/winsys/amdgpu/drm/Makefile
2740                 src/gallium/winsys/svga/drm/Makefile
2741                 src/gallium/winsys/sw/dri/Makefile
2742                 src/gallium/winsys/sw/kms-dri/Makefile
2743                 src/gallium/winsys/sw/null/Makefile
2744                 src/gallium/winsys/sw/wrapper/Makefile
2745                 src/gallium/winsys/sw/xlib/Makefile
2746                 src/gallium/winsys/vc4/drm/Makefile
2747                 src/gallium/winsys/virgl/drm/Makefile
2748                 src/gallium/winsys/virgl/vtest/Makefile
2749                 src/gbm/Makefile
2750                 src/gbm/main/gbm.pc
2751                 src/glx/Makefile
2752                 src/glx/apple/Makefile
2753                 src/glx/tests/Makefile
2754                 src/glx/windows/Makefile
2755                 src/glx/windows/windowsdriproto.pc
2756                 src/gtest/Makefile
2757                 src/intel/Makefile
2758                 src/loader/Makefile
2759                 src/mapi/Makefile
2760                 src/mapi/es1api/glesv1_cm.pc
2761                 src/mapi/es2api/glesv2.pc
2762                 src/mapi/glapi/gen/Makefile
2763                 src/mesa/Makefile
2764                 src/mesa/gl.pc
2765                 src/mesa/drivers/dri/dri.pc
2766                 src/mesa/drivers/dri/common/Makefile
2767                 src/mesa/drivers/dri/common/xmlpool/Makefile
2768                 src/mesa/drivers/dri/i915/Makefile
2769                 src/mesa/drivers/dri/i965/Makefile
2770                 src/mesa/drivers/dri/Makefile
2771                 src/mesa/drivers/dri/nouveau/Makefile
2772                 src/mesa/drivers/dri/r200/Makefile
2773                 src/mesa/drivers/dri/radeon/Makefile
2774                 src/mesa/drivers/dri/swrast/Makefile
2775                 src/mesa/drivers/osmesa/Makefile
2776                 src/mesa/drivers/osmesa/osmesa.pc
2777                 src/mesa/drivers/x11/Makefile
2778                 src/mesa/main/tests/Makefile
2779                 src/util/Makefile
2780                 src/util/tests/hash_table/Makefile
2781                 src/vulkan/Makefile])
2782
2783 AC_OUTPUT
2784
2785 # Fix up dependencies in *.Plo files, where we changed the extension of a
2786 # source file
2787 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2788
2789
2790 dnl
2791 dnl Output some configuration info for the user
2792 dnl
2793 echo ""
2794 echo "        prefix:          $prefix"
2795 echo "        exec_prefix:     $exec_prefix"
2796 echo "        libdir:          $libdir"
2797 echo "        includedir:      $includedir"
2798
2799 dnl API info
2800 echo ""
2801 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2802
2803 dnl Driver info
2804 echo ""
2805 case "x$enable_osmesa$enable_gallium_osmesa" in
2806 xnoyes)
2807         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2808         ;;
2809 xyesno)
2810         echo "        OSMesa:          lib$OSMESA_LIB"
2811         ;;
2812 xnono)
2813         echo "        OSMesa:          no"
2814         ;;
2815 esac
2816
2817 echo ""
2818 if test "x$enable_dri" != xno; then
2819         echo "        DRI platform:    $dri_platform"
2820         if test -z "$DRI_DIRS"; then
2821             echo "        DRI drivers:     no"
2822         else
2823             echo "        DRI drivers:     $DRI_DIRS"
2824         fi
2825         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2826 fi
2827
2828 case "x$enable_glx" in
2829 xdri)
2830     echo "        GLX:             DRI-based"
2831     ;;
2832 xxlib)
2833     echo "        GLX:             Xlib-based"
2834     ;;
2835 xgallium-xlib)
2836     echo "        GLX:             Xlib-based (Gallium)"
2837     ;;
2838 *)
2839     echo "        GLX:             $enable_glx"
2840     ;;
2841 esac
2842
2843 dnl EGL
2844 echo ""
2845 echo "        EGL:             $enable_egl"
2846 if test "$enable_egl" = yes; then
2847     echo "        EGL platforms:   $egl_platforms"
2848
2849     egl_drivers=""
2850     if test "x$enable_dri" != "xno"; then
2851         egl_drivers="$egl_drivers builtin:egl_dri2"
2852     fi
2853     if test "x$enable_dri3" != "xno"; then
2854         egl_drivers="$egl_drivers builtin:egl_dri3"
2855     fi
2856
2857     echo "        EGL drivers:    $egl_drivers"
2858 fi
2859 if test "x$enable_gbm" = xyes; then
2860     echo "        GBM:             yes"
2861 else
2862     echo "        GBM:             no"
2863 fi
2864
2865 # Vulkan
2866 echo ""
2867 if test "x$VULKAN_DRIVERS" != x; then
2868     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2869     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2870 else
2871     echo "        Vulkan drivers:  no"
2872 fi
2873
2874 echo ""
2875 if test "x$enable_llvm" = xyes; then
2876     echo "        llvm:            yes"
2877     echo "        llvm-config:     $LLVM_CONFIG"
2878     echo "        llvm-version:    $LLVM_VERSION"
2879 else
2880     echo "        llvm:            no"
2881 fi
2882
2883 echo ""
2884 if test -n "$with_gallium_drivers"; then
2885     echo "        Gallium drivers: $gallium_drivers"
2886     echo "        Gallium st:      $gallium_st"
2887 else
2888     echo "        Gallium:         no"
2889 fi
2890
2891 echo ""
2892 if test "x$enable_gallium_extra_hud" != xyes; then
2893     echo "        HUD extra stats: no"
2894 else
2895     echo "        HUD extra stats: yes"
2896 fi
2897
2898 if test "x$enable_lmsensors" != xyes; then
2899     echo "        HUD lmsensors:   no"
2900 else
2901     echo "        HUD lmsensors:   yes"
2902 fi
2903
2904 dnl Libraries
2905 echo ""
2906 echo "        Shared libs:     $enable_shared"
2907 echo "        Static libs:     $enable_static"
2908 echo "        Shared-glapi:    $enable_shared_glapi"
2909
2910 dnl Compiler options
2911 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2912 cflags=`echo $CFLAGS | \
2913     $SED 's/^ *//;s/  */ /;s/ *$//'`
2914 cxxflags=`echo $CXXFLAGS | \
2915     $SED 's/^ *//;s/  */ /;s/ *$//'`
2916 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2917 echo ""
2918 echo "        CFLAGS:          $cflags"
2919 echo "        CXXFLAGS:        $cxxflags"
2920 echo "        Macros:          $defines"
2921 echo ""
2922 if test "x$enable_llvm" = xyes; then
2923     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2924     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2925     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2926     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2927     echo ""
2928 fi
2929 echo "        PYTHON2:         $PYTHON2"
2930
2931 echo ""
2932 echo "        Run '${MAKE-make}' to build Mesa"
2933 echo ""