configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.50
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.51
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AX_PYTHON_MODULE([libxml2], [needed])
  51 AC_PROG_SED
  52 AC_PROG_MKDIR_P
  53
  54 LT_PREREQ([2.2])
  55 LT_INIT([disable-static])
  56
  57 AX_PROG_BISON([],
  58               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  59                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  60 AX_PROG_FLEX([],
  61              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  62                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  63
  64 AC_PATH_PROG([PERL], [perl])
  65
  66 AC_CHECK_PROG(INDENT, indent, indent, cat)
  67 if test "x$INDENT" != "xcat"; then
  68     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  69 fi
  70
  71 AC_PROG_INSTALL
  72
  73 dnl We need a POSIX shell for parts of the build. Assume we have one
  74 dnl in most cases.
  75 case "$host_os" in
  76 solaris*)
  77     # Solaris /bin/sh is too old/non-POSIX compliant
  78     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  79     SHELL="$POSIX_SHELL"
  80     ;;
  81 esac
  82
  83 dnl clang is mostly GCC-compatible, but its version is much lower,
  84 dnl so we have to check for it.
  85 AC_MSG_CHECKING([if compiling with clang])
  86
  87 AC_COMPILE_IFELSE(
  88 [AC_LANG_PROGRAM([], [[
  89 #ifndef __clang__
  90        not clang
  91 #endif
  92 ]])],
  93 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  94
  95 AC_MSG_RESULT([$acv_mesa_CLANG])
  96
  97 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  98 dnl versions are explictly not supported.
  99 GEN_ASM_OFFSETS=no
 100 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 101     AC_MSG_CHECKING([whether gcc version is sufficient])
 102     major=0
 103     minor=0
 104
 105     GCC_VERSION=`$CC -dumpversion`
 106     if test $? -eq 0; then
 107         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 108         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 109     fi
 110
 111     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 112         AC_MSG_RESULT([no])
 113         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 114     else
 115         AC_MSG_RESULT([yes])
 116     fi
 117
 118     if test "x$cross_compiling" = xyes; then
 119         GEN_ASM_OFFSETS=yes
 120     fi
 121 fi
 122 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 123
 124 dnl Make sure the pkg-config macros are defined
 125 m4_ifndef([PKG_PROG_PKG_CONFIG],
 126     [m4_fatal([Could not locate the pkg-config autoconf macros.
 127   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 128   are in a different location, try setting the environment variable
 129   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 130 PKG_PROG_PKG_CONFIG()
 131
 132 dnl LIB_DIR - library basename
 133 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 134 AC_SUBST([LIB_DIR])
 135
 136 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 137 _SAVE_LDFLAGS="$LDFLAGS"
 138 _SAVE_CPPFLAGS="$CPPFLAGS"
 139
 140 dnl Compiler macros
 141 DEFINES=""
 142 AC_SUBST([DEFINES])
 143 case "$host_os" in
 144 linux*|*-gnu*|gnu*)
 145     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 146     ;;
 147 solaris*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 149     ;;
 150 cygwin*)
 151     DEFINES="$DEFINES -DHAVE_PTHREAD"
 152     ;;
 153 esac
 154
 155 dnl Add flags for gcc and g++
 156 if test "x$GCC" = xyes; then
 157     case "$host_os" in
 158     cygwin*)
 159         CFLAGS="$CFLAGS -Wall -std=gnu99"
 160         ;;
 161     *)
 162         CFLAGS="$CFLAGS -Wall -std=c99"
 163         ;;
 164     esac
 165
 166     # Enable -Werror=implicit-function-declaration and
 167     # -Werror=missing-prototypes, if available, or otherwise, just
 168     # -Wmissing-prototypes.  This is particularly useful to avoid
 169     # generating a loadable driver module that has undefined symbols.
 170     save_CFLAGS="$CFLAGS"
 171     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 172     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 173     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 174     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 175                    AC_MSG_RESULT([yes]),
 176                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 177                     AC_MSG_RESULT([no])]);
 178
 179     # Enable -fvisibility=hidden if using a gcc that supports it
 180     save_CFLAGS="$CFLAGS"
 181     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 182     VISIBILITY_CFLAGS="-fvisibility=hidden"
 183     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 184     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 185                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 186
 187     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 188     CFLAGS=$save_CFLAGS
 189
 190     # Work around aliasing bugs - developers should comment this out
 191     CFLAGS="$CFLAGS -fno-strict-aliasing"
 192
 193     # gcc's builtin memcmp is slower than glibc's
 194     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 195     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 196 fi
 197 if test "x$GXX" = xyes; then
 198     CXXFLAGS="$CXXFLAGS -Wall"
 199
 200     # Enable -fvisibility=hidden if using a gcc that supports it
 201     save_CXXFLAGS="$CXXFLAGS"
 202     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 203     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 204     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 205     AC_LANG_PUSH([C++])
 206     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 207                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 208     AC_LANG_POP([C++])
 209
 210     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 211     CXXFLAGS=$save_CXXFLAGS
 212
 213     # Work around aliasing bugs - developers should comment this out
 214     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 215
 216     # gcc's builtin memcmp is slower than glibc's
 217     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 218     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 219 fi
 220
 221 dnl even if the compiler appears to support it, using visibility attributes isn't
 222 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 223 case "$host_os" in
 224 cygwin*)
 225     VISIBILITY_CFLAGS=""
 226     VISIBILITY_CXXFLAGS=""
 227     ;;
 228 esac
 229
 230 AC_SUBST([VISIBILITY_CFLAGS])
 231 AC_SUBST([VISIBILITY_CXXFLAGS])
 232
 233 dnl
 234 dnl Optional flags, check for compiler support
 235 dnl
 236 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 237 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl other compiler options
 290 dnl
 291 AC_ARG_ENABLE([debug],
 292     [AS_HELP_STRING([--enable-debug],
 293         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 294     [enable_debug="$enableval"],
 295     [enable_debug=no]
 296 )
 297 if test "x$enable_debug" = xyes; then
 298     DEFINES="$DEFINES -DDEBUG"
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -g -O0"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -g -O0"
 304     fi
 305 fi
 306
 307 dnl
 308 dnl library names
 309 dnl
 310 LIB_PREFIX_GLOB='lib'
 311 LIB_VERSION_SEPARATOR='.'
 312 if test "$enable_static" = yes; then
 313     LIB_EXTENSION='a'
 314 else
 315     case "$host_os" in
 316     darwin* )
 317         LIB_EXTENSION='dylib' ;;
 318     cygwin* )
 319         dnl prefix can be 'cyg' or 'lib'
 320         LIB_PREFIX_GLOB='???'
 321         LIB_VERSION_SEPARATOR='-'
 322         LIB_EXTENSION='dll' ;;
 323     aix* )
 324         LIB_EXTENSION='a' ;;
 325     * )
 326         LIB_EXTENSION='so' ;;
 327     esac
 328 fi
 329 AC_ARG_WITH([gl-lib-name],
 330   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 331     [specify GL library name @<:@default=GL@:>@])],
 332   [GL_LIB=$withval],
 333   [GL_LIB=GL])
 334 AC_ARG_WITH([osmesa-lib-name],
 335   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 336     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 337   [OSMESA_LIB=$withval],
 338   [OSMESA_LIB=OSMesa])
 339 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 340 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 341
 342 dnl
 343 dnl Mangled Mesa support
 344 dnl
 345 AC_ARG_ENABLE([mangling],
 346   [AS_HELP_STRING([--enable-mangling],
 347     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 348   [enable_mangling="${enableval}"],
 349   [enable_mangling=no]
 350 )
 351 if test "x${enable_mangling}" = "xyes" ; then
 352   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 353   GL_LIB="Mangled${GL_LIB}"
 354   OSMESA_LIB="Mangled${OSMESA_LIB}"
 355 fi
 356 AC_SUBST([GL_LIB])
 357 AC_SUBST([OSMESA_LIB])
 358
 359 dnl
 360 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 361 dnl
 362 AC_ARG_ENABLE([texture-float],
 363     [AS_HELP_STRING([--enable-texture-float],
 364         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 365     [enable_texture_float="$enableval"],
 366     [enable_texture_float=no]
 367 )
 368 if test "x$enable_texture_float" = xyes; then
 369     AC_MSG_WARN([Floating-point textures enabled.])
 370     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 371     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 372 fi
 373
 374 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 375 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 376 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 377 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 378 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 379 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 380 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 381
 382 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 383 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 384 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 385 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 386 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 387 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 388 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 389
 390 AC_SUBST([GL_LIB_NAME])
 391 AC_SUBST([OSMESA_LIB_NAME])
 392 AC_SUBST([EGL_LIB_NAME])
 393 AC_SUBST([GLESv1_CM_LIB_NAME])
 394 AC_SUBST([GLESv2_LIB_NAME])
 395 AC_SUBST([VG_LIB_NAME])
 396 AC_SUBST([GLAPI_LIB_NAME])
 397
 398 AC_SUBST([GL_LIB_GLOB])
 399 AC_SUBST([EGL_LIB_GLOB])
 400 AC_SUBST([GLESv1_CM_LIB_GLOB])
 401 AC_SUBST([GLESv2_LIB_GLOB])
 402 AC_SUBST([VG_LIB_GLOB])
 403 AC_SUBST([GLAPI_LIB_GLOB])
 404
 405 dnl
 406 dnl Arch/platform-specific settings
 407 dnl
 408 AC_ARG_ENABLE([asm],
 409     [AS_HELP_STRING([--disable-asm],
 410         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 411     [enable_asm="$enableval"],
 412     [enable_asm=yes]
 413 )
 414 asm_arch=""
 415 AC_MSG_CHECKING([whether to enable assembly])
 416 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 417 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 418 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 419     case "$host_cpu" in
 420     i?86 | x86_64 | amd64)
 421         enable_asm=no
 422         AC_MSG_RESULT([no, cross compiling])
 423         ;;
 424     esac
 425 fi
 426 # check for supported arches
 427 if test "x$enable_asm" = xyes; then
 428     case "$host_cpu" in
 429     i?86)
 430         case "$host_os" in
 431         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 432             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 433             ;;
 434         gnu*)
 435             asm_arch=x86
 436             ;;
 437         esac
 438         ;;
 439     x86_64|amd64)
 440         case "$host_os" in
 441         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 442             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 443             ;;
 444         esac
 445         ;;
 446     sparc*)
 447         case "$host_os" in
 448         linux*)
 449             asm_arch=sparc
 450             ;;
 451         esac
 452         ;;
 453     esac
 454
 455     case "$asm_arch" in
 456     x86)
 457         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 458         AC_MSG_RESULT([yes, x86])
 459         ;;
 460     x86_64|amd64)
 461         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 462         AC_MSG_RESULT([yes, x86_64])
 463         ;;
 464     sparc)
 465         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 466         AC_MSG_RESULT([yes, sparc])
 467         ;;
 468     *)
 469         AC_MSG_RESULT([no, platform not supported])
 470         ;;
 471     esac
 472 fi
 473
 474 dnl Check to see if dlopen is in default libraries (like Solaris, which
 475 dnl has it in libc), or if libdl is needed to get it.
 476 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 477     [AC_CHECK_LIB([dl], [dlopen],
 478        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 479 AC_SUBST([DLOPEN_LIBS])
 480
 481 case "$host_os" in
 482 darwin*|mingw*)
 483     ;;
 484 *)
 485     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 486                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 487                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 488     AC_SUBST([CLOCK_LIB])
 489     ;;
 490 esac
 491
 492 dnl See if posix_memalign is available
 493 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 494
 495 dnl Check for pthreads
 496 AX_PTHREAD
 497 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 498 dnl to -pthread, which causes problems if we need -lpthread to appear in
 499 dnl pkgconfig files.
 500 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 501
 502 dnl SELinux awareness.
 503 AC_ARG_ENABLE([selinux],
 504     [AS_HELP_STRING([--enable-selinux],
 505         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 506     [MESA_SELINUX="$enableval"],
 507     [MESA_SELINUX=no])
 508 if test "x$enable_selinux" = "xyes"; then
 509     AC_CHECK_HEADER([selinux/selinux.h],[],
 510                     [AC_MSG_ERROR([SELinux headers not found])])
 511     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 512                  [AC_MSG_ERROR([SELinux library not found])])
 513     SELINUX_LIBS="-lselinux"
 514     DEFINES="$DEFINES -DMESA_SELINUX"
 515 fi
 516 AC_SUBST([SELINUX_LIBS])
 517
 518 dnl Options for APIs
 519 AC_ARG_ENABLE([opengl],
 520     [AS_HELP_STRING([--disable-opengl],
 521         [disable support for standard OpenGL API @<:@default=no@:>@])],
 522     [enable_opengl="$enableval"],
 523     [enable_opengl=yes])
 524 AC_ARG_ENABLE([gles1],
 525     [AS_HELP_STRING([--enable-gles1],
 526         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 527     [enable_gles1="$enableval"],
 528     [enable_gles1=no])
 529 AC_ARG_ENABLE([gles2],
 530     [AS_HELP_STRING([--enable-gles2],
 531         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 532     [enable_gles2="$enableval"],
 533     [enable_gles2=no])
 534 AC_ARG_ENABLE([openvg],
 535     [AS_HELP_STRING([--enable-openvg],
 536         [enable support for OpenVG API @<:@default=no@:>@])],
 537     [enable_openvg="$enableval"],
 538     [enable_openvg=no])
 539
 540 AC_ARG_ENABLE([dri],
 541     [AS_HELP_STRING([--enable-dri],
 542         [enable DRI modules @<:@default=enabled@:>@])],
 543     [enable_dri="$enableval"],
 544     [enable_dri=yes])
 545 AC_ARG_ENABLE([dri3],
 546     [AS_HELP_STRING([--enable-dri3],
 547         [enable DRI3 @<:@default=enabled@:>@])],
 548     [enable_dri3="$enableval"],
 549     [enable_dri3=yes])
 550 AC_ARG_ENABLE([glx],
 551     [AS_HELP_STRING([--enable-glx],
 552         [enable GLX library @<:@default=enabled@:>@])],
 553     [enable_glx="$enableval"],
 554     [enable_glx=yes])
 555 AC_ARG_ENABLE([osmesa],
 556     [AS_HELP_STRING([--enable-osmesa],
 557         [enable OSMesa library @<:@default=disabled@:>@])],
 558     [enable_osmesa="$enableval"],
 559     [enable_osmesa=no])
 560 AC_ARG_ENABLE([gallium-osmesa],
 561     [AS_HELP_STRING([--enable-gallium-osmesa],
 562         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 563     [enable_gallium_osmesa="$enableval"],
 564     [enable_gallium_osmesa=no])
 565 AC_ARG_ENABLE([egl],
 566     [AS_HELP_STRING([--disable-egl],
 567         [disable EGL library @<:@default=enabled@:>@])],
 568     [enable_egl="$enableval"],
 569     [enable_egl=yes])
 570
 571 AC_ARG_ENABLE([xa],
 572     [AS_HELP_STRING([--enable-xa],
 573         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 574     [enable_xa="$enableval"],
 575     [enable_xa=no])
 576 AC_ARG_ENABLE([gbm],
 577    [AS_HELP_STRING([--enable-gbm],
 578          [enable gbm library @<:@default=auto@:>@])],
 579    [enable_gbm="$enableval"],
 580    [enable_gbm=auto])
 581
 582 AC_ARG_ENABLE([xvmc],
 583    [AS_HELP_STRING([--enable-xvmc],
 584          [enable xvmc library @<:@default=auto@:>@])],
 585    [enable_xvmc="$enableval"],
 586    [enable_xvmc=no])
 587 AC_ARG_ENABLE([vdpau],
 588    [AS_HELP_STRING([--enable-vdpau],
 589          [enable vdpau library @<:@default=auto@:>@])],
 590    [enable_vdpau="$enableval"],
 591    [enable_vdpau=auto])
 592 AC_ARG_ENABLE([opencl],
 593    [AS_HELP_STRING([--enable-opencl],
 594          [enable OpenCL library NOTE: Enabling this option will also enable
 595           --with-llvm-shared-libs
 596           @<:@default=no@:>@])],
 597    [],
 598    [enable_opencl=no])
 599 AC_ARG_ENABLE([opencl_icd],
 600    [AS_HELP_STRING([--enable-opencl-icd],
 601           [Build an OpenCL ICD library to be loaded by an ICD implementation
 602            @<:@default=no@:>@])],
 603     [enable_opencl_icd="$enableval"],
 604     [enable_opencl_icd=no])
 605 AC_ARG_ENABLE([xlib-glx],
 606     [AS_HELP_STRING([--enable-xlib-glx],
 607         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 608     [enable_xlib_glx="$enableval"],
 609     [enable_xlib_glx=no])
 610 AC_ARG_ENABLE([gallium-egl],
 611     [AS_HELP_STRING([--enable-gallium-egl],
 612         [enable optional EGL state tracker (not required
 613          for EGL support in Gallium with OpenGL and OpenGL ES)
 614          @<:@default=disable@:>@])],
 615     [enable_gallium_egl="$enableval"],
 616     [enable_gallium_egl=no])
 617 AC_ARG_ENABLE([gallium-gbm],
 618     [AS_HELP_STRING([--enable-gallium-gbm],
 619         [enable optional gbm state tracker (not required for
 620          gbm support in Gallium)
 621          @<:@default=auto@:>@])],
 622     [enable_gallium_gbm="$enableval"],
 623     [enable_gallium_gbm=auto])
 624
 625 AC_ARG_ENABLE([r600-llvm-compiler],
 626     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 627         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 628     [enable_r600_llvm="$enableval"],
 629     [enable_r600_llvm=no])
 630
 631 AC_ARG_ENABLE([gallium-tests],
 632     [AS_HELP_STRING([--enable-gallium-tests],
 633         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 634     [enable_gallium_tests="$enableval"],
 635     [enable_gallium_tests=no])
 636
 637 # Option for Gallium drivers
 638
 639 # Keep this in sync with the --with-gallium-drivers help string default value
 640 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 641
 642 AC_ARG_WITH([gallium-drivers],
 643     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 644         [comma delimited Gallium drivers list, e.g.
 645         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 646         @<:@default=r300,r600,svga,swrast@:>@])],
 647     [with_gallium_drivers="$withval"],
 648     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 649
 650 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 651 # here so that the script doesn't choke on an unknown driver name later.
 652 case "$with_gallium_drivers" in
 653     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 654     no) with_gallium_drivers='' ;;
 655 esac
 656
 657 if test "x$enable_opengl" = xno -a \
 658         "x$enable_gles1" = xno -a \
 659         "x$enable_gles2" = xno -a \
 660         "x$enable_openvg" = xno -a \
 661         "x$enable_xa" = xno -a \
 662         "x$enable_xvmc" = xno -a \
 663         "x$enable_vdpau" = xno -a \
 664         "x$enable_opencl" = xno; then
 665     AC_MSG_ERROR([at least one API should be enabled])
 666 fi
 667
 668 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 669 if test "x$enable_opengl" = xno -a \
 670         "x$enable_gles1" = xyes; then
 671     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 672 fi
 673
 674 if test "x$enable_opengl" = xno -a \
 675         "x$enable_gles2" = xyes; then
 676     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 677 fi
 678
 679 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 680 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 681 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 682 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 683                                         "x$enable_gles1" = xyes -o \
 684                                         "x$enable_gles2" = xyes)
 685
 686 if test "x$enable_glx" = xno; then
 687     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 688     enable_xlib_glx=no
 689 fi
 690
 691 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 692     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 693 fi
 694
 695 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 696     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 697 fi
 698
 699 # Disable GLX if OpenGL is not enabled
 700 if test "x$enable_glx$enable_opengl" = xyesno; then
 701     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 702     enable_glx=no
 703 fi
 704
 705 # Disable GLX if DRI and Xlib-GLX are not enabled
 706 if test "x$enable_glx" = xyes -a \
 707         "x$enable_dri" = xno -a \
 708         "x$enable_xlib_glx" = xno; then
 709     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 710     enable_glx=no
 711 fi
 712
 713 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 714                                   "x$enable_dri" = xyes)
 715 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 716 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes)
 717
 718 AC_ARG_ENABLE([shared-glapi],
 719     [AS_HELP_STRING([--enable-shared-glapi],
 720         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 721     [enable_shared_glapi="$enableval"],
 722     [enable_shared_glapi="$enable_dri"])
 723
 724 # Shared GLAPI is only useful for DRI
 725 if test "x$enable_dri" = xno; then
 726     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 727     enable_shared_glapi=no
 728 fi
 729
 730 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 731
 732 dnl
 733 dnl Driver specific build directories
 734 dnl
 735 GALLIUM_TARGET_DIRS=""
 736 GALLIUM_WINSYS_DIRS="sw"
 737 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 738 GALLIUM_STATE_TRACKERS_DIRS=""
 739
 740 case "x$enable_glx$enable_xlib_glx" in
 741 xyesyes)
 742     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 743     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 744     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 745     NEED_WINSYS_XLIB="yes"
 746     ;;
 747 esac
 748
 749 if test "x$enable_dri" = xyes; then
 750     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 751     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 752 fi
 753
 754 if test "x$enable_gallium_osmesa" = xyes; then
 755     if test -z "$with_gallium_drivers"; then
 756         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 757     fi
 758     if test "x$enable_osmesa" = xyes; then
 759         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 760     fi
 761     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 762     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 763 fi
 764
 765 AC_SUBST([MESA_LLVM])
 766
 767 # Check for libdrm
 768 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 769                   [have_libdrm=yes], [have_libdrm=no])
 770 if test "x$have_libdrm" = xyes; then
 771         DEFINES="$DEFINES -DHAVE_LIBDRM"
 772 fi
 773
 774 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 775                   have_libudev=yes, have_libudev=no)
 776
 777 if test "x$enable_dri" = xyes; then
 778     # DRI must be shared, I think
 779     if test "$enable_static" = yes; then
 780         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 781     fi
 782
 783     # not a hard requirement as swrast does not depend on it
 784     if test "x$have_libdrm" = xyes; then
 785         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 786     fi
 787 fi
 788
 789 dnl Direct rendering or just indirect rendering
 790 case "$host_os" in
 791 gnu*)
 792     dnl Disable by default on GNU/Hurd
 793     driglx_direct_default="no"
 794     ;;
 795 cygwin*)
 796     dnl Disable by default on cygwin
 797     driglx_direct_default="no"
 798     ;;
 799 *)
 800     driglx_direct_default="yes"
 801     ;;
 802 esac
 803 AC_ARG_ENABLE([driglx-direct],
 804     [AS_HELP_STRING([--disable-driglx-direct],
 805         [disable direct rendering in GLX and EGL for DRI \
 806             @<:@default=auto@:>@])],
 807     [driglx_direct="$enableval"],
 808     [driglx_direct="$driglx_direct_default"])
 809
 810 dnl
 811 dnl libGL configuration per driver
 812 dnl
 813 case "x$enable_glx$enable_xlib_glx" in
 814 xyesyes)
 815     # Xlib-based GLX
 816     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 817     GL_PC_REQ_PRIV="x11 xext"
 818     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 819     GL_LIB_DEPS="$XLIBGL_LIBS"
 820     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 821     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 822     ;;
 823 xyesno)
 824     # DRI-based GLX
 825     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 826     if test x"$driglx_direct" = xyes; then
 827         if test "x$have_libdrm" != xyes; then
 828             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 829         fi
 830         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 831         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 832         if test x"$enable_dri3" = xyes; then
 833             if test x"$have_libudev" != xyes; then
 834               AC_MSG_ERROR([DRI3 requires libudev >= $LIBUDEV_REQUIRED])
 835             fi
 836             PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 837             PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 838         fi
 839     fi
 840
 841     # find the DRI deps for libGL
 842     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 843
 844     if test x"$enable_dri3" = xyes; then
 845         dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= 1.1"
 846     fi
 847
 848     # add xf86vidmode if available
 849     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 850     if test "$HAVE_XF86VIDMODE" = yes ; then
 851         dri_modules="$dri_modules xxf86vm"
 852     fi
 853
 854     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 855     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 856     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 857     GL_LIB_DEPS="$DRIGL_LIBS"
 858
 859     if test x"$enable_dri3$have_libudev" = xyesyes; then
 860         X11_INCLUDES="$X11_INCLUDES $LIBUDEV_CFLAGS"
 861         GL_LIB_DEPS="$GL_LIB_DEPS"
 862     fi
 863
 864     # need DRM libs, $PTHREAD_LIBS, etc.
 865     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 866     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 867     ;;
 868 esac
 869
 870 if test "$have_libudev" = yes; then
 871     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 872 fi
 873
 874 # This is outside the case (above) so that it is invoked even for non-GLX
 875 # builds.
 876 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 877
 878 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 879 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 880 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 881 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 882
 883 AC_SUBST([X11_INCLUDES])
 884 AC_SUBST([GL_LIB_DEPS])
 885 AC_SUBST([GL_PC_REQ_PRIV])
 886 AC_SUBST([GL_PC_LIB_PRIV])
 887 AC_SUBST([GL_PC_CFLAGS])
 888 AC_SUBST([DRI_PC_REQ_PRIV])
 889 AC_SUBST([GLESv1_CM_LIB_DEPS])
 890 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 891 AC_SUBST([GLESv2_LIB_DEPS])
 892 AC_SUBST([GLESv2_PC_LIB_PRIV])
 893
 894 AC_SUBST([HAVE_XF86VIDMODE])
 895
 896 dnl
 897 dnl More GLX setup
 898 dnl
 899 case "x$enable_glx$enable_xlib_glx" in
 900 xyesyes)
 901     DEFINES="$DEFINES -DUSE_XSHM"
 902     ;;
 903 xyesno)
 904     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 905     if test "x$driglx_direct" = xyes; then
 906         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 907     fi
 908     ;;
 909 esac
 910
 911 dnl
 912 dnl TLS detection
 913 dnl
 914
 915 AC_ARG_ENABLE([glx-tls],
 916     [AS_HELP_STRING([--enable-glx-tls],
 917         [enable TLS support in GLX @<:@default=disabled@:>@])],
 918     [GLX_USE_TLS="$enableval"],
 919     [GLX_USE_TLS=no])
 920 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 921
 922 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 923       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 924
 925 dnl
 926 dnl More DRI setup
 927 dnl
 928 dnl Directory for DRI drivers
 929 AC_ARG_WITH([dri-driverdir],
 930     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 931         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 932     [DRI_DRIVER_INSTALL_DIR="$withval"],
 933     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 934 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 935 dnl Extra search path for DRI drivers
 936 AC_ARG_WITH([dri-searchpath],
 937     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 938         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 939     [DRI_DRIVER_SEARCH_DIR="$withval"],
 940     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 941 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 942 dnl Which drivers to build - default is chosen by platform
 943 AC_ARG_WITH([dri-drivers],
 944     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 945         [comma delimited DRI drivers list, e.g.
 946         "swrast,i965,radeon" @<:@default=auto@:>@])],
 947     [with_dri_drivers="$withval"],
 948     [with_dri_drivers=yes])
 949 if test "x$with_dri_drivers" = x; then
 950     with_dri_drivers=no
 951 fi
 952
 953 dnl If $with_dri_drivers is yes, directories will be added through
 954 dnl platform checks
 955 DRI_DIRS=""
 956 case "$with_dri_drivers" in
 957 no) ;;
 958 yes)
 959     # classic DRI drivers
 960     if test "x$enable_opengl" = xyes; then
 961         DRI_DIRS="yes"
 962     fi
 963     ;;
 964 *)
 965     # verify the requested driver directories exist
 966     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 967     for driver in $dri_drivers; do
 968         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 969             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 970     done
 971     DRI_DIRS="$dri_drivers"
 972     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 973         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 974     fi
 975     ;;
 976 esac
 977
 978 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 979 if test "x$enable_dri" = xyes; then
 980     # Platform specific settings and drivers to build
 981     case "$host_os" in
 982     linux*)
 983         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 984         DEFINES="$DEFINES -DHAVE_ALIAS"
 985         if test "x$enable_dri3" = xyes; then
 986             DEFINES="$DEFINES -DHAVE_DRI3"
 987         fi
 988
 989         case "$host_cpu" in
 990         x86_64|amd64)
 991             if test "x$DRI_DIRS" = "xyes"; then
 992                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 993             fi
 994             ;;
 995         powerpc*)
 996             # Build only the drivers for cards that exist on PowerPC.
 997             if test "x$DRI_DIRS" = "xyes"; then
 998                 DRI_DIRS="r200 radeon swrast"
 999             fi
1000             ;;
1001         sparc*)
1002             # Build only the drivers for cards that exist on sparc
1003             if test "x$DRI_DIRS" = "xyes"; then
1004                 DRI_DIRS="r200 radeon swrast"
1005             fi
1006             ;;
1007         esac
1008         ;;
1009     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1010         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1011         DEFINES="$DEFINES -DHAVE_ALIAS"
1012
1013         if test "x$DRI_DIRS" = "xyes"; then
1014             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1015         fi
1016         ;;
1017     gnu*)
1018         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1019         DEFINES="$DEFINES -DHAVE_ALIAS"
1020         ;;
1021     solaris*)
1022         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1023         ;;
1024     cygwin*)
1025         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1026         if test "x$DRI_DIRS" = "xyes"; then
1027             DRI_DIRS="swrast"
1028         fi
1029         ;;
1030     esac
1031
1032     # default drivers
1033     if test "x$DRI_DIRS" = "xyes"; then
1034         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1035     fi
1036
1037     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1038
1039     # Check for expat
1040     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
1041     if test "x$have_expat" = "xyes"; then
1042        PKG_CHECK_MODULES([EXPAT], [expat], [],
1043                          AC_MSG_ERROR([Expat required for DRI.]))
1044     else
1045        # expat version 2.0 and earlier do not provide expat.pc
1046        EXPAT_LIBS=-lexpat
1047     fi
1048
1049     # If we are building any DRI driver other than swrast.
1050     if test -n "$DRI_DIRS"; then
1051         if test x"$DRI_DIRS" != xswrast; then
1052             # ... libdrm is required
1053             if test "x$have_libdrm" != xyes; then
1054                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1055             fi
1056             DRICOMMON_NEED_LIBDRM=yes
1057         else
1058             DRICOMMON_NEED_LIBDRM=no
1059         fi
1060     fi
1061
1062     # put all the necessary libs together
1063     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1064     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1065
1066 fi
1067
1068 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1069 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1070                                   "x$enable_osmesa" = xyes -o \
1071                                   -n "$DRI_DIRS")
1072 AC_SUBST([DRI_LIB_DEPS])
1073 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1074
1075 case $DRI_DIRS in
1076 *i915*|*i965*)
1077     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1078
1079     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1080         case $d in
1081         i915)
1082             HAVE_I915_DRI=yes;
1083             ;;
1084         i965)
1085             HAVE_I965_DRI=yes;
1086             ;;
1087         esac
1088     done
1089
1090     ;;
1091 esac
1092
1093 case $DRI_DIRS in
1094 *nouveau*)
1095     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1096     HAVE_NOUVEAU_DRI=yes;
1097     ;;
1098 esac
1099
1100 case $DRI_DIRS in
1101 *radeon*|*r200*)
1102     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1103
1104     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1105         case $d in
1106         radeon)
1107             HAVE_RADEON_DRI=yes;
1108             ;;
1109         r200)
1110             HAVE_R200_DRI=yes;
1111             ;;
1112         esac
1113     done
1114
1115     ;;
1116 esac
1117
1118 case $DRI_DIRS in
1119 *swrast*)
1120     HAVE_SWRAST_DRI=yes;
1121     ;;
1122 esac
1123
1124 dnl
1125 dnl OSMesa configuration
1126 dnl
1127
1128 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1129 AC_ARG_WITH([osmesa-bits],
1130     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1131         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1132     [osmesa_bits="$withval"],
1133     [osmesa_bits=8])
1134 if test "x$osmesa_bits" != x8; then
1135     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1136         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1137         osmesa_bits=8
1138     fi
1139 fi
1140 case "x$osmesa_bits" in
1141 x8)
1142     OSMESA_LIB="${OSMESA_LIB}"
1143     ;;
1144 x16|x32)
1145     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1146     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1147     ;;
1148 *)
1149     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1150     ;;
1151 esac
1152
1153 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1154     # only link libraries with osmesa if shared
1155     if test "$enable_static" = no; then
1156         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1157     else
1158         OSMESA_LIB_DEPS=""
1159     fi
1160     OSMESA_MESA_DEPS=""
1161     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1162 fi
1163
1164 AC_SUBST([OSMESA_LIB_DEPS])
1165 AC_SUBST([OSMESA_MESA_DEPS])
1166 AC_SUBST([OSMESA_PC_REQ])
1167 AC_SUBST([OSMESA_PC_LIB_PRIV])
1168
1169 dnl
1170 dnl gbm configuration
1171 dnl
1172 if test "x$enable_gbm" = xauto; then
1173     case "$with_egl_platforms" in
1174         *drm*)
1175             enable_gbm=yes ;;
1176          *)
1177             enable_gbm=no ;;
1178     esac
1179 fi
1180 if test "x$enable_gbm" = xyes; then
1181     if test x"$have_libudev" != xyes; then
1182         AC_MSG_ERROR([gbm needs udev])
1183     fi
1184
1185     if test "x$enable_dri" = xyes; then
1186         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1187         if test "x$enable_shared_glapi" = xno; then
1188             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1189         fi
1190     fi
1191 fi
1192 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1193 GBM_PC_REQ_PRIV="libudev"
1194 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1195 AC_SUBST([GBM_PC_REQ_PRIV])
1196 AC_SUBST([GBM_PC_LIB_PRIV])
1197
1198 dnl
1199 dnl EGL configuration
1200 dnl
1201 EGL_CLIENT_APIS=""
1202
1203 if test "x$enable_egl" = xyes; then
1204     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1205
1206     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1207
1208     if test "$enable_static" != yes; then
1209         # build egl_glx when libGL is built
1210
1211         if test "x$enable_dri" = xyes; then
1212             HAVE_EGL_DRIVER_DRI2=1
1213         fi
1214
1215     fi
1216 fi
1217 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1218 AC_SUBST([EGL_LIB_DEPS])
1219
1220 dnl
1221 dnl EGL Gallium configuration
1222 dnl
1223 if test "x$enable_gallium_egl" = xyes; then
1224     if test "x$with_gallium_drivers" = x; then
1225         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1226     fi
1227     if test "x$enable_egl" = xno; then
1228         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1229     fi
1230     if test "x$have_libdrm" != xyes; then
1231         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1232     fi
1233
1234     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1235     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1236 fi
1237 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1238
1239 dnl
1240 dnl gbm Gallium configuration
1241 dnl
1242 if test "x$enable_gallium_gbm" = xauto; then
1243     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1244         yesyesyes*drm*)
1245             enable_gallium_gbm=yes ;;
1246          *)
1247             enable_gallium_gbm=no ;;
1248     esac
1249 fi
1250 if test "x$enable_gallium_gbm" = xyes; then
1251     if test "x$with_gallium_drivers" = x; then
1252         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1253     fi
1254     if test "x$enable_gbm" = xno; then
1255         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1256     fi
1257     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1258     if test "x$enable_dri" = xno; then
1259         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1260     fi
1261
1262     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1263     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1264     enable_gallium_loader=yes
1265 fi
1266 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1267
1268 dnl
1269 dnl XA configuration
1270 dnl
1271 if test "x$enable_xa" = xyes; then
1272     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1273 fi
1274 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1275
1276 dnl
1277 dnl OpenVG configuration
1278 dnl
1279 VG_LIB_DEPS=""
1280
1281 if test "x$enable_openvg" = xyes; then
1282     if test "x$enable_egl" = xno; then
1283         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1284     fi
1285     if test "x$with_gallium_drivers" = x; then
1286         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1287     fi
1288     if test "x$enable_gallium_egl" = xno; then
1289         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1290     fi
1291
1292     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1293     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1294     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1295     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1296     AC_SUBST([VG_PC_LIB_PRIV])
1297 fi
1298 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1299
1300 dnl
1301 dnl Gallium G3DVL configuration
1302 dnl
1303 if test -n "$with_gallium_drivers"; then
1304     if test "x$enable_xvmc" = xauto; then
1305         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1306     fi
1307
1308     if test "x$enable_vdpau" = xauto; then
1309         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1310     fi
1311 fi
1312
1313 if test "x$enable_xvmc" = xyes; then
1314     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1315     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1316 fi
1317 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1318
1319 if test "x$enable_vdpau" = xyes; then
1320     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1321     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1322 fi
1323 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1324
1325 dnl
1326 dnl OpenCL configuration
1327 dnl
1328
1329 AC_ARG_WITH([libclc-path],
1330    [AS_HELP_STRING([--with-libclc-path],
1331          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1332    [LIBCLC_PATH="$withval"],
1333    [LIBCLC_PATH=""])
1334
1335 if test "x$LIBCLC_PATH" != x; then
1336    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1337                   Please review the updated build instructions for clover:
1338                   http://dri.freedesktop.org/wiki/GalliumCompute])
1339 fi
1340
1341
1342 AC_ARG_WITH([clang-libdir],
1343    [AS_HELP_STRING([--with-clang-libdir],
1344          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1345    [CLANG_LIBDIR="$withval"],
1346    [CLANG_LIBDIR=""])
1347
1348 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1349
1350 if test "x$enable_opencl" = xyes; then
1351     if test "x$with_gallium_drivers" = x; then
1352         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1353     fi
1354
1355     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1356         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1357     fi
1358
1359     if test "x$have_libclc" = xno; then
1360         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1361                     Make sure the directory containing libclc.pc is specified in your
1362                     PKG_CONFIG_PATH environment variable.
1363                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1364     else
1365         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1366         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1367         AC_SUBST([LIBCLC_INCLUDEDIR])
1368         AC_SUBST([LIBCLC_LIBEXECDIR])
1369     fi
1370
1371     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1372     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1373     enable_gallium_loader=yes
1374
1375     if test "x$enable_opencl_icd" = xyes; then
1376         OPENCL_LIBNAME="MesaOpenCL"
1377     else
1378         OPENCL_LIBNAME="OpenCL"
1379     fi
1380 fi
1381 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1382 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1383 AC_SUBST([OPENCL_LIBNAME])
1384
1385 dnl
1386 dnl Gallium configuration
1387 dnl
1388 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1389
1390 AC_SUBST([LLVM_BINDIR])
1391 AC_SUBST([LLVM_CFLAGS])
1392 AC_SUBST([LLVM_CPPFLAGS])
1393 AC_SUBST([LLVM_CXXFLAGS])
1394 AC_SUBST([LLVM_LIBDIR])
1395 AC_SUBST([LLVM_LIBS])
1396 AC_SUBST([LLVM_LDFLAGS])
1397 AC_SUBST([LLVM_INCLUDEDIR])
1398 AC_SUBST([LLVM_VERSION])
1399 AC_SUBST([CLANG_RESOURCE_DIR])
1400
1401 case "x$enable_opengl$enable_gles1$enable_gles2" in
1402 x*yes*)
1403     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1404     ;;
1405 esac
1406
1407 AC_SUBST([VG_LIB_DEPS])
1408 AC_SUBST([EGL_CLIENT_APIS])
1409
1410 dnl
1411 dnl EGL Platforms configuration
1412 dnl
1413 AC_ARG_WITH([egl-platforms],
1414     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1415         [comma delimited native platforms libEGL supports, e.g.
1416         "x11,drm" @<:@default=auto@:>@])],
1417     [with_egl_platforms="$withval"],
1418     [if test "x$enable_egl" = xyes; then
1419         with_egl_platforms="x11"
1420     else
1421         with_egl_platforms=""
1422     fi])
1423
1424 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1425     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1426 fi
1427
1428 # Do per-EGL platform setups and checks
1429 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1430 for plat in $egl_platforms; do
1431         case "$plat" in
1432         wayland)
1433                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1434                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1435
1436                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1437                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1438                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1439                 ;;
1440
1441         x11)
1442                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1443
1444                 if test "x$enable_glx" = xyes; then
1445                         HAVE_EGL_DRIVER_GLX=1
1446                 fi
1447                 ;;
1448
1449         drm)
1450                 test "x$enable_gbm" = "xno" &&
1451                         AC_MSG_ERROR([EGL platform drm needs gbm])
1452                 test "x$have_libdrm" != xyes &&
1453                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1454                 ;;
1455
1456         android|fbdev|gdi|null)
1457                 ;;
1458
1459         *)
1460                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1461                 ;;
1462         esac
1463
1464         case "$plat$have_libudev" in
1465                 waylandno|drmno)
1466                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1467         esac
1468 done
1469
1470 # libEGL wants to default to the first platform specified in
1471 # ./configure.  parse that here.
1472 if test "x$egl_platforms" != "x"; then
1473     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1474     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1475 else
1476     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1477 fi
1478
1479 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1480     NEED_WINSYS_XLIB=yes
1481 fi
1482 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1483 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1484 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1485 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1486 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1487
1488 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1489 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1490
1491 AC_SUBST([EGL_NATIVE_PLATFORM])
1492 AC_SUBST([EGL_CFLAGS])
1493
1494 # If we don't have the X11 platform, set this define so we don't try to include
1495 # the X11 headers.
1496 if ! echo "$egl_platforms" | grep -q 'x11'; then
1497     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1498     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1499 fi
1500
1501 AC_ARG_WITH([egl-driver-dir],
1502     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1503                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1504     [EGL_DRIVER_INSTALL_DIR="$withval"],
1505     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1506 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1507
1508 AC_ARG_WITH([max-width],
1509     [AS_HELP_STRING([--with-max-width=N],
1510                     [Maximum framebuffer width (4096)])],
1511     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1512      AS_IF([test "${withval}" -gt "4096"],
1513            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1514 )
1515 AC_ARG_WITH([max-height],
1516     [AS_HELP_STRING([--with-max-height=N],
1517                     [Maximum framebuffer height (4096)])],
1518     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1519      AS_IF([test "${withval}" -gt "4096"],
1520            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1521 )
1522
1523 dnl
1524 dnl Gallium LLVM
1525 dnl
1526 AC_ARG_ENABLE([gallium-llvm],
1527     [AS_HELP_STRING([--enable-gallium-llvm],
1528         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1529     [enable_gallium_llvm="$enableval"],
1530     [enable_gallium_llvm=auto])
1531
1532 AC_ARG_WITH([llvm-shared-libs],
1533     [AS_HELP_STRING([--with-llvm-shared-libs],
1534         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1535     [],
1536     [with_llvm_shared_libs=no])
1537
1538 AC_ARG_WITH([llvm-prefix],
1539     [AS_HELP_STRING([--with-llvm-prefix],
1540         [Prefix for LLVM installations in non-standard locations])],
1541     [llvm_prefix="$withval"],
1542     [llvm_prefix=""])
1543
1544
1545 # Call this inside ` ` to get the return value.
1546 # $1 is the llvm-config command with arguments.
1547 strip_unwanted_llvm_flags() {
1548     # Use \> (marks the end of the word)
1549     echo `$1` | sed \
1550         -e 's/-DNDEBUG\>//g' \
1551         -e 's/-pedantic\>//g' \
1552         -e 's/-Wcovered-switch-default\>//g' \
1553         -e 's/-O.\>//g' \
1554         -e 's/-g\>//g' \
1555         -e 's/-Wall\>//g' \
1556         -e 's/-fcolor-diagnostics\>//g' \
1557         -e 's/-fomit-frame-pointer\>//g'
1558 }
1559
1560
1561 if test "x$with_gallium_drivers" = x; then
1562     enable_gallium_llvm=no
1563 fi
1564 if test "x$enable_gallium_llvm" = xauto; then
1565     case "$host_cpu" in
1566     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1567     esac
1568 fi
1569 if test "x$enable_gallium_llvm" = xyes; then
1570     if test "x$llvm_prefix" != x; then
1571         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1572     else
1573         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1574     fi
1575
1576     if test "x$LLVM_CONFIG" != xno; then
1577         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1578         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1579         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1580         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1581         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1582         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1583         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1584         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1585
1586         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1587             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1588         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1589             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1590
1591         if test "x${LLVM_VERSION_MAJOR}" != x; then
1592             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1593         else
1594             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1595         fi
1596
1597         LLVM_COMPONENTS="engine bitwriter"
1598         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1599             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1600         fi
1601
1602         if test "x$enable_opencl" = xyes; then
1603             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1604             # LLVM 3.3 >= 177971 requires IRReader
1605             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1606                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1607             fi
1608             # LLVM 3.4 requires Option
1609             if $LLVM_CONFIG --components | grep -qw 'option'; then
1610                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1611             fi
1612         fi
1613         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1614         MESA_LLVM=1
1615
1616         dnl Check for Clang internal headers
1617         if test "x$enable_opencl" = xyes; then
1618             if test "x$CLANG_LIBDIR" = x; then
1619                 CLANG_LIBDIR=${LLVM_LIBDIR}
1620             fi
1621             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1622             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1623                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1624         fi
1625     else
1626         MESA_LLVM=0
1627         LLVM_VERSION_INT=0
1628     fi
1629 else
1630     MESA_LLVM=0
1631     LLVM_VERSION_INT=0
1632 fi
1633
1634 dnl Directory for XVMC libs
1635 AC_ARG_WITH([xvmc-libdir],
1636     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1637         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1638     [XVMC_LIB_INSTALL_DIR="$withval"],
1639     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1640 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1641
1642 dnl
1643 dnl Gallium Tests
1644 dnl
1645 if test "x$enable_gallium_tests" = xyes; then
1646     enable_gallium_loader=yes
1647 fi
1648 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1649
1650 if test "x$enable_gallium_loader" = xyes; then
1651     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1652 fi
1653 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1654
1655 dnl Directory for VDPAU libs
1656 AC_ARG_WITH([vdpau-libdir],
1657     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1658         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1659     [VDPAU_LIB_INSTALL_DIR="$withval"],
1660     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1661 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1662
1663 dnl Directory for OpenCL libs
1664 AC_ARG_WITH([opencl-libdir],
1665     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1666         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1667     [OPENCL_LIB_INSTALL_DIR="$withval"],
1668     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1669 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1670
1671 dnl
1672 dnl Gallium helper functions
1673 dnl
1674 gallium_check_st() {
1675     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1676          if test "x$have_libdrm" != xyes; then
1677             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1678          fi
1679          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1680     fi
1681     if test "x$enable_dri" = xyes && test "x$2" != x; then
1682          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1683     fi
1684     if test "x$enable_xa" = xyes && test "x$3" != x; then
1685          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1686     fi
1687     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1688          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1689     fi
1690     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1691          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1692     fi
1693 }
1694
1695 gallium_require_llvm() {
1696     if test "x$MESA_LLVM" = x0; then
1697         case "$host_cpu" in
1698         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1699         esac
1700     fi
1701 }
1702
1703 gallium_require_drm_loader() {
1704     if test "x$enable_gallium_loader" = xyes; then
1705         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1706                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1707         if test "x$have_libdrm" != xyes; then
1708             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1709         fi
1710         enable_gallium_drm_loader=yes
1711     fi
1712 }
1713
1714 radeon_llvm_check() {
1715     LLVM_REQUIRED_VERSION_MAJOR="3"
1716     LLVM_REQUIRED_VERSION_MINOR="3"
1717     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1718         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1719     fi
1720     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1721         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1722                       sources with the --enable-experimental-targets=R600
1723                       configure flag])
1724     fi
1725     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1726     NEED_RADEON_LLVM=yes
1727     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1728                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1729 }
1730
1731 dnl Gallium drivers
1732 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1733         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1734     NEED_NONNULL_WINSYS=yes
1735 fi
1736 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1737
1738 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1739 if test "x$with_gallium_drivers" != x; then
1740     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1741     for driver in $gallium_drivers; do
1742         case "x$driver" in
1743         xsvga)
1744             HAVE_GALLIUM_SVGA=yes
1745             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1746             gallium_check_st "svga/drm" "dri-vmwgfx" "xa-vmwgfx"
1747             ;;
1748         xi915)
1749             HAVE_GALLIUM_I915=yes
1750             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1751             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1752             if test "x$MESA_LLVM" = x1; then
1753                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1754             fi
1755             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1756             gallium_check_st "i915/drm" "dri-i915"
1757             DRICOMMON_NEED_LIBDRM=yes
1758             ;;
1759         xilo)
1760             HAVE_GALLIUM_ILO=yes
1761             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1762             gallium_require_drm_loader
1763             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1764             gallium_check_st "intel/drm" "dri-ilo"
1765             DRICOMMON_NEED_LIBDRM=yes
1766             ;;
1767         xr300)
1768             HAVE_GALLIUM_R300=yes
1769             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1770             gallium_require_llvm "Gallium R300"
1771             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1772             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1773             DRICOMMON_NEED_LIBDRM=yes
1774             ;;
1775         xr600)
1776             HAVE_GALLIUM_R600=yes
1777             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1778             gallium_require_drm_loader
1779             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1780             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1781                 radeon_llvm_check
1782                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1783             fi
1784             if test "x$enable_r600_llvm" = xyes; then
1785                 USE_R600_LLVM_COMPILER=yes;
1786             fi
1787             if test "x$enable_opencl" = xyes; then
1788                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1789             fi
1790             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau"
1791             DRICOMMON_NEED_LIBDRM=yes
1792             ;;
1793         xradeonsi)
1794             HAVE_GALLIUM_RADEONSI=yes
1795             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1796             gallium_require_drm_loader
1797             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1798             radeon_llvm_check
1799             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau"
1800             DRICOMMON_NEED_LIBDRM=yes
1801             ;;
1802         xnouveau)
1803             HAVE_GALLIUM_NOUVEAU=yes
1804             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1805             gallium_require_drm_loader
1806             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1807             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1808             DRICOMMON_NEED_LIBDRM=yes
1809             ;;
1810         xfreedreno)
1811             HAVE_GALLIUM_FREEDRENO=yes
1812             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1813             gallium_require_drm_loader
1814             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1815             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1816             DRICOMMON_NEED_LIBDRM=yes
1817             ;;
1818         xswrast)
1819             HAVE_GALLIUM_SOFTPIPE=yes
1820             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1821             if test "x$MESA_LLVM" = x1; then
1822                 HAVE_GALLIUM_LLVMPIPE=yes
1823                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1824             fi
1825
1826             if test "x$enable_dri" = xyes; then
1827                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1828             fi
1829             ;;
1830         *)
1831             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1832             ;;
1833         esac
1834     done
1835 fi
1836
1837 dnl Set LLVM_LIBS - This is done after the driver configuration so
1838 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1839 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1840 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1841 dnl this was causing the same libraries to be appear multiple times
1842 dnl in LLVM_LIBS.
1843
1844 if test "x$MESA_LLVM" != x0; then
1845
1846     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1847
1848     if test "x$with_llvm_shared_libs" = xyes; then
1849         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1850         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1851         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1852
1853         if test "x$llvm_have_one_so" = xyes; then
1854             dnl LLVM was built using auto*, so there is only one shared object.
1855             LLVM_LIBS="-l$LLVM_SO_NAME"
1856         else
1857             dnl If LLVM was built with CMake, there will be one shared object per
1858             dnl component.
1859             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1860                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1861         Please make sure you have built llvm with the --enable-shared option
1862         and that your llvm libraries are installed in $LLVM_LIBDIR
1863         If you have installed your llvm libraries to a different directory you
1864         can use the --with-llvm-prefix= configure flag to specify this directory.
1865         NOTE: Mesa is attempting to use llvm shared libraries because you have
1866         passed one of the following options to configure:
1867                 --with-llvm-shared-libs
1868                 --enable-opencl
1869         If you do not want to build with llvm shared libraries and instead want to
1870         use llvm static libraries then remove these options from your configure
1871         invocation and reconfigure.])])
1872
1873            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1874            dnl install uses a shared object for each compoenent and we have
1875            dnl already added all of these objects to LLVM_LIBS.
1876         fi
1877     fi
1878 fi
1879
1880 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1881 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1882 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1883 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1884 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1885 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1886 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1887 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1890
1891 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1892                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1893                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1894 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1895                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1896                                                   && test "x$MESA_LLVM" = x1)
1897
1898 if test "x$enable_gallium_loader" = xyes; then
1899     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1900
1901     if test "x$enable_gallium_drm_loader" = xyes; then
1902         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1903         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1904                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1905         if test "x$pipe_loader_have_xcb" = xyes; then
1906             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1907             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1908         fi
1909     fi
1910
1911     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1912     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1913 fi
1914
1915 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1916 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1917 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1918 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1919 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1920 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1921
1922 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1923                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1924                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1925                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1926 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1927                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1928 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1929 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1930 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1931 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1932 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1933 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1934 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1935
1936 AC_SUBST([ELF_LIB])
1937
1938 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1939 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
1940 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1941 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1942 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1943
1944 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1945 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1946 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1947
1948 AC_SUBST([VDPAU_MAJOR], 1)
1949 AC_SUBST([VDPAU_MINOR], 0)
1950
1951 AC_SUBST([XVMC_MAJOR], 1)
1952 AC_SUBST([XVMC_MINOR], 0)
1953
1954 AC_SUBST([XA_MAJOR], 2)
1955 AC_SUBST([XA_MINOR], 1)
1956 AC_SUBST([XA_TINY], 0)
1957 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1958
1959 dnl Restore LDFLAGS and CPPFLAGS
1960 LDFLAGS="$_SAVE_LDFLAGS"
1961 CPPFLAGS="$_SAVE_CPPFLAGS"
1962
1963 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1964 if test "x$acv_mesa_CLANG" = xyes; then
1965     CFLAGS="$CFLAGS -Qunused-arguments"
1966     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1967 fi
1968
1969 dnl Add user CFLAGS and CXXFLAGS
1970 CFLAGS="$CFLAGS $USER_CFLAGS"
1971 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1972
1973 dnl Substitute the config
1974 AC_CONFIG_FILES([Makefile
1975                 src/Makefile
1976                 src/egl/Makefile
1977                 src/egl/drivers/Makefile
1978                 src/egl/drivers/dri2/Makefile
1979                 src/egl/drivers/glx/Makefile
1980                 src/egl/main/Makefile
1981                 src/egl/main/egl.pc
1982                 src/egl/wayland/Makefile
1983                 src/egl/wayland/wayland-drm/Makefile
1984                 src/egl/wayland/wayland-egl/Makefile
1985                 src/egl/wayland/wayland-egl/wayland-egl.pc
1986                 src/gallium/auxiliary/Makefile
1987                 src/gallium/auxiliary/pipe-loader/Makefile
1988                 src/gallium/drivers/Makefile
1989                 src/gallium/drivers/freedreno/Makefile
1990                 src/gallium/drivers/galahad/Makefile
1991                 src/gallium/drivers/i915/Makefile
1992                 src/gallium/drivers/identity/Makefile
1993                 src/gallium/drivers/ilo/Makefile
1994                 src/gallium/drivers/llvmpipe/Makefile
1995                 src/gallium/drivers/noop/Makefile
1996                 src/gallium/drivers/nouveau/Makefile
1997                 src/gallium/drivers/r300/Makefile
1998                 src/gallium/drivers/r600/Makefile
1999                 src/gallium/drivers/radeon/Makefile
2000                 src/gallium/drivers/radeonsi/Makefile
2001                 src/gallium/drivers/rbug/Makefile
2002                 src/gallium/drivers/softpipe/Makefile
2003                 src/gallium/drivers/svga/Makefile
2004                 src/gallium/drivers/trace/Makefile
2005                 src/gallium/state_trackers/Makefile
2006                 src/gallium/state_trackers/clover/Makefile
2007                 src/gallium/state_trackers/dri/Makefile
2008                 src/gallium/state_trackers/dri/drm/Makefile
2009                 src/gallium/state_trackers/dri/sw/Makefile
2010                 src/gallium/state_trackers/egl/Makefile
2011                 src/gallium/state_trackers/gbm/Makefile
2012                 src/gallium/state_trackers/glx/xlib/Makefile
2013                 src/gallium/state_trackers/osmesa/Makefile
2014                 src/gallium/state_trackers/vdpau/Makefile
2015                 src/gallium/state_trackers/vega/Makefile
2016                 src/gallium/state_trackers/xa/Makefile
2017                 src/gallium/state_trackers/xvmc/Makefile
2018                 src/gallium/targets/Makefile
2019                 src/gallium/targets/dri-freedreno/Makefile
2020                 src/gallium/targets/dri-i915/Makefile
2021                 src/gallium/targets/dri-ilo/Makefile
2022                 src/gallium/targets/dri-nouveau/Makefile
2023                 src/gallium/targets/dri-swrast/Makefile
2024                 src/gallium/targets/dri-vmwgfx/Makefile
2025                 src/gallium/targets/egl-static/Makefile
2026                 src/gallium/targets/gbm/Makefile
2027                 src/gallium/targets/opencl/Makefile
2028                 src/gallium/targets/osmesa/Makefile
2029                 src/gallium/targets/osmesa/osmesa.pc
2030                 src/gallium/targets/pipe-loader/Makefile
2031                 src/gallium/targets/radeonsi/dri/Makefile
2032                 src/gallium/targets/radeonsi/vdpau/Makefile
2033                 src/gallium/targets/r300/dri/Makefile
2034                 src/gallium/targets/r600/dri/Makefile
2035                 src/gallium/targets/r600/vdpau/Makefile
2036                 src/gallium/targets/r600/xvmc/Makefile
2037                 src/gallium/targets/libgl-xlib/Makefile
2038                 src/gallium/targets/vdpau-nouveau/Makefile
2039                 src/gallium/targets/xa-vmwgfx/Makefile
2040                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2041                 src/gallium/targets/xvmc-nouveau/Makefile
2042                 src/gallium/tests/trivial/Makefile
2043                 src/gallium/tests/unit/Makefile
2044                 src/gallium/winsys/Makefile
2045                 src/gallium/winsys/freedreno/drm/Makefile
2046                 src/gallium/winsys/i915/drm/Makefile
2047                 src/gallium/winsys/i915/sw/Makefile
2048                 src/gallium/winsys/intel/drm/Makefile
2049                 src/gallium/winsys/nouveau/drm/Makefile
2050                 src/gallium/winsys/radeon/drm/Makefile
2051                 src/gallium/winsys/svga/drm/Makefile
2052                 src/gallium/winsys/sw/dri/Makefile
2053                 src/gallium/winsys/sw/fbdev/Makefile
2054                 src/gallium/winsys/sw/null/Makefile
2055                 src/gallium/winsys/sw/wayland/Makefile
2056                 src/gallium/winsys/sw/wrapper/Makefile
2057                 src/gallium/winsys/sw/xlib/Makefile
2058                 src/gbm/Makefile
2059                 src/gbm/main/gbm.pc
2060                 src/glsl/Makefile
2061                 src/glx/Makefile
2062                 src/glx/tests/Makefile
2063                 src/gtest/Makefile
2064                 src/loader/Makefile
2065                 src/mapi/Makefile
2066                 src/mapi/es1api/Makefile
2067                 src/mapi/es1api/glesv1_cm.pc
2068                 src/mapi/es2api/Makefile
2069                 src/mapi/es2api/glesv2.pc
2070                 src/mapi/glapi/Makefile
2071                 src/mapi/glapi/gen/Makefile
2072                 src/mapi/glapi/tests/Makefile
2073                 src/mapi/shared-glapi/Makefile
2074                 src/mapi/shared-glapi/tests/Makefile
2075                 src/mapi/vgapi/Makefile
2076                 src/mapi/vgapi/vg.pc
2077                 src/mesa/Makefile
2078                 src/mesa/gl.pc
2079                 src/mesa/drivers/dri/dri.pc
2080                 src/mesa/drivers/dri/common/Makefile
2081                 src/mesa/drivers/dri/common/xmlpool/Makefile
2082                 src/mesa/drivers/dri/i915/Makefile
2083                 src/mesa/drivers/dri/i965/Makefile
2084                 src/mesa/drivers/dri/Makefile
2085                 src/mesa/drivers/dri/nouveau/Makefile
2086                 src/mesa/drivers/dri/r200/Makefile
2087                 src/mesa/drivers/dri/radeon/Makefile
2088                 src/mesa/drivers/dri/swrast/Makefile
2089                 src/mesa/drivers/osmesa/Makefile
2090                 src/mesa/drivers/osmesa/osmesa.pc
2091                 src/mesa/drivers/x11/Makefile
2092                 src/mesa/main/tests/Makefile
2093                 src/mesa/main/tests/hash_table/Makefile])
2094
2095 dnl Sort the dirs alphabetically
2096 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2097 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2098 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2099 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2100
2101 AC_OUTPUT
2102
2103 dnl
2104 dnl Output some configuration info for the user
2105 dnl
2106 echo ""
2107 echo "        prefix:          $prefix"
2108 echo "        exec_prefix:     $exec_prefix"
2109 echo "        libdir:          $libdir"
2110 echo "        includedir:      $includedir"
2111
2112 dnl API info
2113 echo ""
2114 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2115 echo "        OpenVG:          $enable_openvg"
2116
2117 dnl Driver info
2118 echo ""
2119 case "x$enable_osmesa$enable_gallium_osmesa" in
2120 xnoyes)
2121         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2122         ;;
2123 xyesno)
2124         echo "        OSMesa:          lib$OSMESA_LIB"
2125         ;;
2126 xnono)
2127         echo "        OSMesa:          no"
2128         ;;
2129 esac
2130
2131 if test "x$enable_dri" != xno; then
2132         # cleanup the drivers var
2133         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2134         if test "x$DRI_DIRS" = x; then
2135             echo "        DRI drivers:     no"
2136         else
2137             echo "        DRI drivers:     $dri_dirs"
2138         fi
2139         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2140 fi
2141
2142 case "x$enable_glx$enable_xlib_glx" in
2143 xyesyes)
2144     echo "        GLX:             Xlib-based"
2145     ;;
2146 xyesno)
2147     echo "        GLX:             DRI-based"
2148     ;;
2149 *)
2150     echo "        GLX:             $enable_glx"
2151     ;;
2152 esac
2153
2154 dnl EGL
2155 echo ""
2156 echo "        EGL:             $enable_egl"
2157 if test "$enable_egl" = yes; then
2158     echo "        EGL platforms:   $egl_platforms"
2159
2160     egl_drivers=""
2161     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2162         egl_drivers="$egl_drivers builtin:egl_glx"
2163     fi
2164     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2165         egl_drivers="$egl_drivers builtin:egl_dri2"
2166     fi
2167
2168     if test "x$enable_gallium_egl" = xyes; then
2169         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2170         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2171     else
2172         echo "        EGL drivers:    $egl_drivers"
2173     fi
2174 fi
2175
2176 echo ""
2177 if test "x$MESA_LLVM" = x1; then
2178     echo "        llvm:            yes"
2179     echo "        llvm-config:     $LLVM_CONFIG"
2180     echo "        llvm-version:    $LLVM_VERSION"
2181 else
2182     echo "        llvm:            no"
2183 fi
2184
2185 echo ""
2186 if test -n "$with_gallium_drivers"; then
2187     echo "        Gallium:         yes"
2188     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2189     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2190     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2191     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2192 else
2193     echo "        Gallium:         no"
2194 fi
2195
2196
2197 dnl Libraries
2198 echo ""
2199 echo "        Shared libs:     $enable_shared"
2200 echo "        Static libs:     $enable_static"
2201 echo "        Shared-glapi:    $enable_shared_glapi"
2202
2203 dnl Compiler options
2204 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2205 cflags=`echo $CFLAGS | \
2206     $SED 's/^ *//;s/  */ /;s/ *$//'`
2207 cxxflags=`echo $CXXFLAGS | \
2208     $SED 's/^ *//;s/  */ /;s/ *$//'`
2209 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2210 echo ""
2211 echo "        CFLAGS:          $cflags"
2212 echo "        CXXFLAGS:        $cxxflags"
2213 echo "        Macros:          $defines"
2214 echo ""
2215 if test "x$MESA_LLVM" = x1; then
2216     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2217     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2218     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2219     echo ""
2220 fi
2221 echo "        PYTHON2:         $PYTHON2"
2222
2223 echo ""
2224 echo "        Run '${MAKE-make}' to build Mesa"
2225 echo ""