configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.67
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 LIBUDEV_REQUIRED=151
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.2.0
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.3.4
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112
 113 AX_PROG_BISON([],
 114               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 115                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 116 AX_PROG_FLEX([],
 117              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 118                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 119
 120 AC_CHECK_PROG(INDENT, indent, indent, cat)
 121 if test "x$INDENT" != "xcat"; then
 122     # Only GNU indent is supported
 123     INDENT_VERSION=`indent --version | grep GNU`
 124     if test $? -eq 0; then
 125        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 126     else
 127        INDENT="cat"
 128     fi
 129 fi
 130
 131 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 132
 133 if test -z "$PYTHON2"; then
 134     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 135         AC_MSG_ERROR([Python not found - unable to generate sources])
 136     fi
 137 else
 138     if test "x$acv_mako_found" = xno; then
 139         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 140             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 141         fi
 142     fi
 143 fi
 144
 145 AC_PROG_INSTALL
 146
 147 dnl We need a POSIX shell for parts of the build. Assume we have one
 148 dnl in most cases.
 149 case "$host_os" in
 150 solaris*)
 151     # Solaris /bin/sh is too old/non-POSIX compliant
 152     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 153     SHELL="$POSIX_SHELL"
 154     ;;
 155 esac
 156
 157 dnl clang is mostly GCC-compatible, but its version is much lower,
 158 dnl so we have to check for it.
 159 AC_MSG_CHECKING([if compiling with clang])
 160
 161 AC_COMPILE_IFELSE(
 162 [AC_LANG_PROGRAM([], [[
 163 #ifndef __clang__
 164        not clang
 165 #endif
 166 ]])],
 167 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 168
 169 AC_MSG_RESULT([$acv_mesa_CLANG])
 170
 171 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 172 dnl versions are explictly not supported.
 173 GEN_ASM_OFFSETS=no
 174 USE_GNU99=no
 175 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 176     AC_MSG_CHECKING([whether gcc version is sufficient])
 177     major=0
 178     minor=0
 179
 180     GCC_VERSION=`$CC -dumpversion`
 181     if test $? -eq 0; then
 182         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 183         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 184     fi
 185
 186     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 187         AC_MSG_RESULT([no])
 188         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 189     else
 190         AC_MSG_RESULT([yes])
 191     fi
 192
 193     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 194         USE_GNU99=yes
 195     fi
 196     if test "x$cross_compiling" = xyes; then
 197         GEN_ASM_OFFSETS=yes
 198     fi
 199 fi
 200
 201 dnl We don't support building Mesa with Sun C compiler
 202 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 203 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 204 if test "x$SUNCC" = xyes; then
 205     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 206 fi
 207
 208 dnl Check for compiler builtins
 209 AX_GCC_BUILTIN([__builtin_bswap32])
 210 AX_GCC_BUILTIN([__builtin_bswap64])
 211 AX_GCC_BUILTIN([__builtin_clz])
 212 AX_GCC_BUILTIN([__builtin_clzll])
 213 AX_GCC_BUILTIN([__builtin_ctz])
 214 AX_GCC_BUILTIN([__builtin_expect])
 215 AX_GCC_BUILTIN([__builtin_ffs])
 216 AX_GCC_BUILTIN([__builtin_ffsll])
 217 AX_GCC_BUILTIN([__builtin_popcount])
 218 AX_GCC_BUILTIN([__builtin_popcountll])
 219 AX_GCC_BUILTIN([__builtin_unreachable])
 220
 221 AX_GCC_FUNC_ATTRIBUTE([const])
 222 AX_GCC_FUNC_ATTRIBUTE([flatten])
 223 AX_GCC_FUNC_ATTRIBUTE([format])
 224 AX_GCC_FUNC_ATTRIBUTE([malloc])
 225 AX_GCC_FUNC_ATTRIBUTE([packed])
 226 AX_GCC_FUNC_ATTRIBUTE([pure])
 227 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 228 AX_GCC_FUNC_ATTRIBUTE([unused])
 229 AX_GCC_FUNC_ATTRIBUTE([visibility])
 230 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 231 AX_GCC_FUNC_ATTRIBUTE([weak])
 232
 233 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 234
 235 dnl Make sure the pkg-config macros are defined
 236 m4_ifndef([PKG_PROG_PKG_CONFIG],
 237     [m4_fatal([Could not locate the pkg-config autoconf macros.
 238   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 239   are in a different location, try setting the environment variable
 240   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 241 PKG_PROG_PKG_CONFIG()
 242
 243 dnl LIB_DIR - library basename
 244 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 245 AC_SUBST([LIB_DIR])
 246
 247 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 248 _SAVE_LDFLAGS="$LDFLAGS"
 249 _SAVE_CPPFLAGS="$CPPFLAGS"
 250
 251 dnl Compiler macros
 252 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 253 AC_SUBST([DEFINES])
 254 android=no
 255 case "$host_os" in
 256 *-android)
 257     android=yes
 258     ;;
 259 linux*|*-gnu*|gnu*|cygwin*)
 260     DEFINES="$DEFINES -D_GNU_SOURCE"
 261     ;;
 262 solaris*)
 263     DEFINES="$DEFINES -DSVR4"
 264     ;;
 265 esac
 266
 267 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 268
 269 dnl Add flags for gcc and g++
 270 if test "x$GCC" = xyes; then
 271     CFLAGS="$CFLAGS -Wall"
 272
 273     if test "x$USE_GNU99" = xyes; then
 274         CFLAGS="$CFLAGS -std=gnu99"
 275     else
 276         CFLAGS="$CFLAGS -std=c99"
 277     fi
 278
 279     # Enable -Werror=implicit-function-declaration and
 280     # -Werror=missing-prototypes, if available, or otherwise, just
 281     # -Wmissing-prototypes.  This is particularly useful to avoid
 282     # generating a loadable driver module that has undefined symbols.
 283     save_CFLAGS="$CFLAGS"
 284     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 285     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 286     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 287     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 288                    AC_MSG_RESULT([yes]),
 289                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 290                     AC_MSG_RESULT([no])]);
 291
 292     # Enable -fvisibility=hidden if using a gcc that supports it
 293     save_CFLAGS="$CFLAGS"
 294     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 295     VISIBILITY_CFLAGS="-fvisibility=hidden"
 296     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 297     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 298                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 299
 300     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 301     CFLAGS=$save_CFLAGS
 302
 303     # Work around aliasing bugs - developers should comment this out
 304     CFLAGS="$CFLAGS -fno-strict-aliasing"
 305
 306     # We don't want floating-point math functions to set errno or trap
 307     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 308
 309     # Flags to help ensure that certain portions of the code -- and only those
 310     # portions -- can be built with MSVC:
 311     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 312     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 313     #   supports most of C99)
 314     # - the rest has no compiler compiler restrictions
 315     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 316     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 317
 318     # Enable -Werror=vla if compiler supports it
 319     save_CFLAGS="$CFLAGS"
 320     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 321     CFLAGS="$CFLAGS -Werror=vla"
 322     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 323                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 324                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 325                     AC_MSG_RESULT([yes])],
 326                     AC_MSG_RESULT([no]));
 327     CFLAGS="$save_CFLAGS"
 328 fi
 329 if test "x$GXX" = xyes; then
 330     CXXFLAGS="$CXXFLAGS -Wall"
 331
 332     # Enable -fvisibility=hidden if using a gcc that supports it
 333     save_CXXFLAGS="$CXXFLAGS"
 334     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 335     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 336     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 337     AC_LANG_PUSH([C++])
 338     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 339                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 340     AC_LANG_POP([C++])
 341
 342     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 343     CXXFLAGS=$save_CXXFLAGS
 344
 345     # Work around aliasing bugs - developers should comment this out
 346     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 347
 348     # We don't want floating-point math functions to set errno or trap
 349     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 350 fi
 351
 352 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 353 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 354
 355 dnl even if the compiler appears to support it, using visibility attributes isn't
 356 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 357 case "$host_os" in
 358 cygwin*)
 359     VISIBILITY_CFLAGS=""
 360     VISIBILITY_CXXFLAGS=""
 361     ;;
 362 esac
 363
 364 AC_SUBST([VISIBILITY_CFLAGS])
 365 AC_SUBST([VISIBILITY_CXXFLAGS])
 366
 367 dnl
 368 dnl Optional flags, check for compiler support
 369 dnl
 370 SSE41_CFLAGS="-msse4.1"
 371 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 372 dnl stack, but on x86-32 such alignment is not guaranteed.
 373 case "$target_cpu" in
 374 i?86)
 375     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 376     ;;
 377 esac
 378 save_CFLAGS="$CFLAGS"
 379 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 380 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 381 #include <smmintrin.h>
 382 int param;
 383 int main () {
 384     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 385     c = _mm_max_epu32(a, b);
 386     return _mm_cvtsi128_si32(c);
 387 }]])], SSE41_SUPPORTED=1)
 388 CFLAGS="$save_CFLAGS"
 389 if test "x$SSE41_SUPPORTED" = x1; then
 390     DEFINES="$DEFINES -DUSE_SSE41"
 391 fi
 392 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 393 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 394
 395 dnl Check for Endianness
 396 AC_C_BIGENDIAN(
 397    little_endian=no,
 398    little_endian=yes,
 399    little_endian=no,
 400    little_endian=no
 401 )
 402
 403 dnl Check for POWER8 Architecture
 404 PWR8_CFLAGS="-mpower8-vector"
 405 have_pwr8_intrinsics=no
 406 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 407 save_CFLAGS=$CFLAGS
 408 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 409 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 410 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 411 #error "Need GCC >= 4.8 for sane POWER8 support"
 412 #endif
 413 #include <altivec.h>
 414 int main () {
 415     vector unsigned char r;
 416     vector unsigned int v = vec_splat_u32 (1);
 417     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 418     return 0;
 419 }]])], have_pwr8_intrinsics=yes)
 420 CFLAGS=$save_CFLAGS
 421
 422 AC_ARG_ENABLE(pwr8,
 423    [AC_HELP_STRING([--disable-pwr8-inst],
 424                    [disable POWER8-specific instructions])],
 425    [enable_pwr8=$enableval], [enable_pwr8=auto])
 426
 427 if test "x$enable_pwr8" = xno ; then
 428    have_pwr8_intrinsics=disabled
 429 fi
 430
 431 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 432    DEFINES="$DEFINES -D_ARCH_PWR8"
 433    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 434    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 435 else
 436    PWR8_CFLAGS=
 437 fi
 438
 439 AC_MSG_RESULT($have_pwr8_intrinsics)
 440 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 441    AC_MSG_ERROR([POWER8 compiler support not detected])
 442 fi
 443
 444 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 445    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 446 fi
 447
 448 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 449
 450 dnl Can't have static and shared libraries, default to static if user
 451 dnl explicitly requested. If both disabled, set to static since shared
 452 dnl was explicitly requested.
 453 case "x$enable_static$enable_shared" in
 454 xyesyes)
 455     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 456     enable_shared=no
 457     ;;
 458 xnono)
 459     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 460     enable_shared=yes
 461     ;;
 462 esac
 463
 464 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 465
 466 dnl
 467 dnl other compiler options
 468 dnl
 469 AC_ARG_ENABLE([debug],
 470     [AS_HELP_STRING([--enable-debug],
 471         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 472     [enable_debug="$enableval"],
 473     [enable_debug=no]
 474 )
 475
 476 AC_ARG_ENABLE([profile],
 477     [AS_HELP_STRING([--enable-profile],
 478         [enable profiling of code @<:@default=disabled@:>@])],
 479     [enable_profile="$enableval"],
 480     [enable_profile=no]
 481 )
 482
 483 if test "x$enable_profile" = xyes; then
 484     DEFINES="$DEFINES -DPROFILE"
 485     if test "x$GCC" = xyes; then
 486         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 487     fi
 488     if test "x$GXX" = xyes; then
 489         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 490     fi
 491 fi
 492
 493 if test "x$enable_debug" = xyes; then
 494     DEFINES="$DEFINES -DDEBUG"
 495     if test "x$enable_profile" = xyes; then
 496         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 497     fi
 498     if test "x$GCC" = xyes; then
 499         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 500             CFLAGS="$CFLAGS -g"
 501         fi
 502         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 503             CFLAGS="$CFLAGS -O0"
 504         fi
 505     fi
 506     if test "x$GXX" = xyes; then
 507         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 508             CXXFLAGS="$CXXFLAGS -g"
 509         fi
 510         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 511             CXXFLAGS="$CXXFLAGS -O0"
 512         fi
 513     fi
 514 else
 515    DEFINES="$DEFINES -DNDEBUG"
 516 fi
 517
 518 DEFAULT_GL_LIB_NAME=GL
 519
 520 dnl
 521 dnl Check if linker supports -Bsymbolic
 522 dnl
 523 save_LDFLAGS=$LDFLAGS
 524 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 525 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 526 AC_LINK_IFELSE(
 527     [AC_LANG_SOURCE([int main() { return 0;}])],
 528     [AC_MSG_RESULT([yes])
 529         BSYMBOLIC="-Wl,-Bsymbolic";],
 530     [AC_MSG_RESULT([no])
 531         BSYMBOLIC="";])
 532 LDFLAGS=$save_LDFLAGS
 533
 534 AC_SUBST([BSYMBOLIC])
 535
 536 dnl
 537 dnl Check if linker supports garbage collection
 538 dnl
 539 save_LDFLAGS=$LDFLAGS
 540 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 541 AC_MSG_CHECKING([whether ld supports --gc-sections])
 542 AC_LINK_IFELSE(
 543     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 544     [AC_MSG_RESULT([yes])
 545         GC_SECTIONS="-Wl,--gc-sections";],
 546     [AC_MSG_RESULT([no])
 547         GC_SECTIONS="";])
 548 LDFLAGS=$save_LDFLAGS
 549
 550 AC_SUBST([GC_SECTIONS])
 551
 552 dnl
 553 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 554 dnl so when these flags are passed to ld via libtool the checks will fail
 555 dnl
 556 case "$host_os" in
 557 openbsd* | darwin* )
 558     LD_NO_UNDEFINED="" ;;
 559 *)
 560     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 561 esac
 562
 563 AC_SUBST([LD_NO_UNDEFINED])
 564
 565 dnl
 566 dnl Check if linker supports version scripts
 567 dnl
 568 AC_MSG_CHECKING([if the linker supports version-scripts])
 569 save_LDFLAGS=$LDFLAGS
 570 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 571 cat > conftest.map <<EOF
 572 VERSION_1 {
 573      global:
 574          main;
 575
 576      local:
 577          *;
 578 };
 579 EOF
 580 AC_LINK_IFELSE(
 581     [AC_LANG_SOURCE([int main() { return 0;}])],
 582     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 583     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 584 LDFLAGS=$save_LDFLAGS
 585 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 586
 587 dnl
 588 dnl Check if linker supports dynamic list files
 589 dnl
 590 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 591 save_LDFLAGS=$LDFLAGS
 592 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 593 cat > conftest.dyn <<EOF
 594 {
 595         radeon_drm_winsys_create;
 596 };
 597 EOF
 598 AC_LINK_IFELSE(
 599     [AC_LANG_SOURCE([int main() { return 0;}])],
 600     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 601     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 602 LDFLAGS=$save_LDFLAGS
 603 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 604
 605 dnl
 606 dnl compatibility symlinks
 607 dnl
 608 case "$host_os" in
 609 linux* )
 610     HAVE_COMPAT_SYMLINKS=yes ;;
 611 * )
 612     HAVE_COMPAT_SYMLINKS=no ;;
 613 esac
 614
 615 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 616
 617 DEFAULT_GL_LIB_NAME=GL
 618
 619 dnl
 620 dnl Libglvnd configuration
 621 dnl
 622 AC_ARG_ENABLE([libglvnd],
 623     [AS_HELP_STRING([--enable-libglvnd],
 624         [Build for libglvnd @<:@default=disabled@:>@])],
 625     [enable_libglvnd="$enableval"],
 626     [enable_libglvnd=no])
 627 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 628 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 629 if test "x$enable_libglvnd" = xyes ; then
 630     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 631     DEFAULT_GL_LIB_NAME=GLX_mesa
 632 fi
 633
 634 dnl
 635 dnl library names
 636 dnl
 637 dnl Unfortunately we need to do a few things that libtool can't help us with,
 638 dnl so we need some knowledge of shared library filenames:
 639 dnl
 640 dnl LIB_EXT is the extension used when creating symlinks for alternate
 641 dnl filenames for a shared library which will be dynamically loaded
 642 dnl
 643 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 644 dnl the file for a shared library we wish to link with
 645 dnl
 646 case "$host_os" in
 647 darwin* )
 648     LIB_EXT='dylib'
 649     IMP_LIB_EXT=$LIB_EXT
 650     ;;
 651 cygwin* )
 652     LIB_EXT='dll'
 653     IMP_LIB_EXT='dll.a'
 654     ;;
 655 aix* )
 656     LIB_EXT='a'
 657     IMP_LIB_EXT=$LIB_EXT
 658     ;;
 659 * )
 660     LIB_EXT='so'
 661     IMP_LIB_EXT=$LIB_EXT
 662     ;;
 663 esac
 664
 665 AC_SUBST([LIB_EXT])
 666
 667 AC_ARG_WITH([gl-lib-name],
 668   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 669     [specify GL library name @<:@default=GL@:>@])],
 670   [GL_LIB=$withval],
 671   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 672 AC_ARG_WITH([osmesa-lib-name],
 673   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 674     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 675   [OSMESA_LIB=$withval],
 676   [OSMESA_LIB=OSMesa])
 677 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 679
 680 dnl
 681 dnl Mangled Mesa support
 682 dnl
 683 AC_ARG_ENABLE([mangling],
 684   [AS_HELP_STRING([--enable-mangling],
 685     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 686   [enable_mangling="${enableval}"],
 687   [enable_mangling=no]
 688 )
 689 if test "x${enable_mangling}" = "xyes" ; then
 690   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 691   GL_LIB="Mangled${GL_LIB}"
 692   OSMESA_LIB="Mangled${OSMESA_LIB}"
 693 fi
 694 AC_SUBST([GL_LIB])
 695 AC_SUBST([OSMESA_LIB])
 696
 697 dnl
 698 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 699 dnl
 700 AC_ARG_ENABLE([texture-float],
 701     [AS_HELP_STRING([--enable-texture-float],
 702         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 703     [enable_texture_float="$enableval"],
 704     [enable_texture_float=no]
 705 )
 706 if test "x$enable_texture_float" = xyes; then
 707     AC_MSG_WARN([Floating-point textures enabled.])
 708     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 709     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 710 fi
 711
 712 dnl
 713 dnl Arch/platform-specific settings
 714 dnl
 715 AC_ARG_ENABLE([asm],
 716     [AS_HELP_STRING([--disable-asm],
 717         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 718     [enable_asm="$enableval"],
 719     [enable_asm=yes]
 720 )
 721 asm_arch=""
 722 AC_MSG_CHECKING([whether to enable assembly])
 723 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 724 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 725 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 726     case "$host_cpu" in
 727     i?86 | x86_64 | amd64)
 728         if test "x$host_cpu" != "x$target_cpu"; then
 729             enable_asm=no
 730             AC_MSG_RESULT([no, cross compiling])
 731         fi
 732         ;;
 733     esac
 734 fi
 735 # check for supported arches
 736 if test "x$enable_asm" = xyes; then
 737     case "$host_cpu" in
 738     i?86)
 739         case "$host_os" in
 740         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 741             asm_arch=x86
 742             ;;
 743         esac
 744         ;;
 745     x86_64|amd64)
 746         case "$host_os" in
 747         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 748             asm_arch=x86_64
 749             ;;
 750         esac
 751         ;;
 752     sparc*)
 753         case "$host_os" in
 754         linux*)
 755             asm_arch=sparc
 756             ;;
 757         esac
 758         ;;
 759     esac
 760
 761     case "$asm_arch" in
 762     x86)
 763         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 764         AC_MSG_RESULT([yes, x86])
 765         ;;
 766     x86_64|amd64)
 767         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 768         AC_MSG_RESULT([yes, x86_64])
 769         ;;
 770     sparc)
 771         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 772         AC_MSG_RESULT([yes, sparc])
 773         ;;
 774     *)
 775         AC_MSG_RESULT([no, platform not supported])
 776         ;;
 777     esac
 778 fi
 779
 780 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 781 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 782 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 783 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 784
 785 dnl Check to see if dlopen is in default libraries (like Solaris, which
 786 dnl has it in libc), or if libdl is needed to get it.
 787 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 788     [AC_CHECK_LIB([dl], [dlopen],
 789        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 790 AC_SUBST([DLOPEN_LIBS])
 791
 792 dnl Check if that library also has dladdr
 793 save_LIBS="$LIBS"
 794 LIBS="$LIBS $DLOPEN_LIBS"
 795 AC_CHECK_FUNCS([dladdr])
 796 LIBS="$save_LIBS"
 797
 798 case "$host_os" in
 799 darwin*)
 800     ;;
 801 *)
 802     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 803                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 804                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 805     AC_SUBST([CLOCK_LIB])
 806     ;;
 807 esac
 808
 809 dnl See if posix_memalign is available
 810 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 811
 812 dnl Check for pthreads
 813 AX_PTHREAD
 814 if test "x$ax_pthread_ok" = xno; then
 815     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 816 fi
 817 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 818 dnl to -pthread, which causes problems if we need -lpthread to appear in
 819 dnl pkgconfig files.
 820 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 821
 822 dnl pthread-stubs is mandatory on targets where it exists
 823 case "$host_os" in
 824 cygwin* )
 825     pthread_stubs_possible="no"
 826     ;;
 827 * )
 828     pthread_stubs_possible="yes"
 829     ;;
 830 esac
 831
 832 if test "x$pthread_stubs_possible" = xyes; then
 833     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 834     AC_SUBST(PTHREADSTUBS_CFLAGS)
 835     AC_SUBST(PTHREADSTUBS_LIBS)
 836 fi
 837
 838 dnl SELinux awareness.
 839 AC_ARG_ENABLE([selinux],
 840     [AS_HELP_STRING([--enable-selinux],
 841         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 842     [MESA_SELINUX="$enableval"],
 843     [MESA_SELINUX=no])
 844 if test "x$enable_selinux" = "xyes"; then
 845     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 846         [AC_CHECK_HEADER([selinux/selinux.h],[],
 847                          [AC_MSG_ERROR([SELinux headers not found])])
 848          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 849                       [AC_MSG_ERROR([SELinux library not found])])
 850          SELINUX_LIBS="-lselinux"])
 851     DEFINES="$DEFINES -DMESA_SELINUX"
 852 fi
 853 AC_SUBST([SELINUX_CFLAGS])
 854 AC_SUBST([SELINUX_LIBS])
 855
 856 dnl Options for APIs
 857 AC_ARG_ENABLE([opengl],
 858     [AS_HELP_STRING([--disable-opengl],
 859         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 860     [enable_opengl="$enableval"],
 861     [enable_opengl=yes])
 862 AC_ARG_ENABLE([gles1],
 863     [AS_HELP_STRING([--disable-gles1],
 864         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 865     [enable_gles1="$enableval"],
 866     [enable_gles1=yes])
 867 AC_ARG_ENABLE([gles2],
 868     [AS_HELP_STRING([--disable-gles2],
 869         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 870     [enable_gles2="$enableval"],
 871     [enable_gles2=yes])
 872
 873 AC_ARG_ENABLE([dri],
 874     [AS_HELP_STRING([--enable-dri],
 875         [enable DRI modules @<:@default=enabled@:>@])],
 876     [enable_dri="$enableval"],
 877     [enable_dri=yes])
 878
 879 case "$host_os" in
 880 linux*)
 881     dri3_default=yes
 882     ;;
 883 *)
 884     dri3_default=no
 885     ;;
 886 esac
 887
 888 if test "x$enable_dri" = xno; then
 889     dri3_default=no
 890 fi
 891
 892 AC_ARG_ENABLE([dri3],
 893     [AS_HELP_STRING([--enable-dri3],
 894         [enable DRI3 @<:@default=auto@:>@])],
 895     [enable_dri3="$enableval"],
 896     [enable_dri3="$dri3_default"])
 897 AC_ARG_ENABLE([glx],
 898     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 899         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 900     [enable_glx="$enableval"],
 901     [enable_glx=yes])
 902 AC_ARG_ENABLE([osmesa],
 903     [AS_HELP_STRING([--enable-osmesa],
 904         [enable OSMesa library @<:@default=disabled@:>@])],
 905     [enable_osmesa="$enableval"],
 906     [enable_osmesa=no])
 907 AC_ARG_ENABLE([gallium-osmesa],
 908     [AS_HELP_STRING([--enable-gallium-osmesa],
 909         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 910     [enable_gallium_osmesa="$enableval"],
 911     [enable_gallium_osmesa=no])
 912 AC_ARG_ENABLE([egl],
 913     [AS_HELP_STRING([--disable-egl],
 914         [disable EGL library @<:@default=enabled@:>@])],
 915     [enable_egl="$enableval"],
 916     [enable_egl=yes])
 917
 918 AC_ARG_ENABLE([xa],
 919     [AS_HELP_STRING([--enable-xa],
 920         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 921     [enable_xa="$enableval"],
 922     [enable_xa=no])
 923 AC_ARG_ENABLE([gbm],
 924    [AS_HELP_STRING([--enable-gbm],
 925          [enable gbm library @<:@default=auto@:>@])],
 926    [enable_gbm="$enableval"],
 927    [enable_gbm=auto])
 928 AC_ARG_ENABLE([nine],
 929     [AS_HELP_STRING([--enable-nine],
 930         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 931     [enable_nine="$enableval"],
 932     [enable_nine=no])
 933
 934 AC_ARG_ENABLE([xvmc],
 935    [AS_HELP_STRING([--enable-xvmc],
 936          [enable xvmc library @<:@default=auto@:>@])],
 937    [enable_xvmc="$enableval"],
 938    [enable_xvmc=auto])
 939 AC_ARG_ENABLE([vdpau],
 940    [AS_HELP_STRING([--enable-vdpau],
 941          [enable vdpau library @<:@default=auto@:>@])],
 942    [enable_vdpau="$enableval"],
 943    [enable_vdpau=auto])
 944 AC_ARG_ENABLE([omx],
 945    [AS_HELP_STRING([--enable-omx],
 946          [enable OpenMAX library @<:@default=disabled@:>@])],
 947    [enable_omx="$enableval"],
 948    [enable_omx=no])
 949 AC_ARG_ENABLE([va],
 950    [AS_HELP_STRING([--enable-va],
 951          [enable va library @<:@default=auto@:>@])],
 952    [enable_va="$enableval"],
 953    [enable_va=auto])
 954 AC_ARG_ENABLE([opencl],
 955    [AS_HELP_STRING([--enable-opencl],
 956          [enable OpenCL library @<:@default=disabled@:>@])],
 957    [enable_opencl="$enableval"],
 958    [enable_opencl=no])
 959 AC_ARG_ENABLE([opencl_icd],
 960    [AS_HELP_STRING([--enable-opencl-icd],
 961           [Build an OpenCL ICD library to be loaded by an ICD implementation
 962            @<:@default=disabled@:>@])],
 963     [enable_opencl_icd="$enableval"],
 964     [enable_opencl_icd=no])
 965
 966 AC_ARG_ENABLE([gallium-tests],
 967     [AS_HELP_STRING([--enable-gallium-tests],
 968         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 969     [enable_gallium_tests="$enableval"],
 970     [enable_gallium_tests=no])
 971
 972 # Option for Gallium drivers
 973
 974 # Keep this in sync with the --with-gallium-drivers help string default value
 975 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 976
 977 AC_ARG_WITH([gallium-drivers],
 978     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 979         [comma delimited Gallium drivers list, e.g.
 980         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
 981         @<:@default=r300,r600,svga,swrast@:>@])],
 982     [with_gallium_drivers="$withval"],
 983     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 984
 985 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 986 # here so that the script doesn't choke on an unknown driver name later.
 987 case "$with_gallium_drivers" in
 988     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 989     no) with_gallium_drivers='' ;;
 990 esac
 991
 992 if test "x$enable_opengl" = xno -a \
 993         "x$enable_gles1" = xno -a \
 994         "x$enable_gles2" = xno -a \
 995         "x$enable_nine" = xno -a \
 996         "x$enable_xa" = xno -a \
 997         "x$enable_xvmc" = xno -a \
 998         "x$enable_vdpau" = xno -a \
 999         "x$enable_omx" = xno -a \
1000         "x$enable_va" = xno -a \
1001         "x$enable_opencl" = xno; then
1002     AC_MSG_ERROR([at least one API should be enabled])
1003 fi
1004
1005 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1006 if test "x$enable_opengl" = xno -a \
1007         "x$enable_gles1" = xyes; then
1008     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1009 fi
1010
1011 if test "x$enable_opengl" = xno -a \
1012         "x$enable_gles2" = xyes; then
1013     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1014 fi
1015
1016 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1017 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1018 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1019 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1020                                         "x$enable_gles1" = xyes -o \
1021                                         "x$enable_gles2" = xyes)
1022
1023 # Validate GLX options
1024 if test "x$enable_glx" = xyes; then
1025     if test "x$enable_dri" = xyes; then
1026         enable_glx=dri
1027     elif test -n "$with_gallium_drivers"; then
1028         enable_glx=gallium-xlib
1029     else
1030         enable_glx=xlib
1031     fi
1032 fi
1033 case "x$enable_glx" in
1034 xdri | xxlib | xgallium-xlib)
1035     # GLX requires OpenGL
1036     if test "x$enable_opengl" = xno; then
1037         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1038     fi
1039
1040     # Check individual dependencies
1041     case "x$enable_glx" in
1042     xdri)
1043         if test "x$enable_dri" = xno; then
1044             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1045         fi
1046         ;;
1047     xxlib)
1048         if test "x$enable_dri" = xyes; then
1049             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1050         fi
1051         ;;
1052     xgallium-xlib )
1053         if test "x$enable_dri" = xyes; then
1054             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1055         fi
1056         if test -z "$with_gallium_drivers"; then
1057             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1058         fi
1059         ;;
1060     esac
1061     ;;
1062 xno)
1063     ;;
1064 *)
1065     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1066     ;;
1067 esac
1068
1069 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1070 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1071 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1072 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1073
1074 dnl
1075 dnl Libglvnd configuration
1076 dnl
1077 AC_ARG_ENABLE([libglvnd],
1078     [AS_HELP_STRING([--enable-libglvnd],
1079         [Build for libglvnd @<:@default=disabled@:>@])],
1080     [enable_libglvnd="$enableval"],
1081     [enable_libglvnd=no])
1082 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1083 if test "x$enable_libglvnd" = xyes ; then
1084     dnl XXX: update once we can handle more than libGL/glx.
1085     dnl Namely: we should error out if neither of the glvnd enabled libraries
1086     dnl are built
1087     case "x$enable_glx" in
1088     xno)
1089         AC_MSG_ERROR([cannot build libglvnd without GLX])
1090         ;;
1091     xxlib | xgallium-xlib )
1092         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1093         ;;
1094     xdri)
1095         ;;
1096     esac
1097
1098     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1099     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1100     DEFAULT_GL_LIB_NAME=GLX_mesa
1101 fi
1102
1103 # Check for libdrm
1104 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1105                   [have_libdrm=yes], [have_libdrm=no])
1106 if test "x$have_libdrm" = xyes; then
1107         DEFINES="$DEFINES -DHAVE_LIBDRM"
1108 fi
1109
1110 # Select which platform-dependent DRI code gets built
1111 case "$host_os" in
1112 darwin*)
1113     dri_platform='apple' ;;
1114 gnu*|cygwin*)
1115     dri_platform='none' ;;
1116 *)
1117     dri_platform='drm' ;;
1118 esac
1119
1120 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1121     have_drisw_kms='yes'
1122 fi
1123
1124 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1125 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1126 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1127 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1128 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1129 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1130
1131 AC_ARG_ENABLE([shared-glapi],
1132     [AS_HELP_STRING([--enable-shared-glapi],
1133         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1134     [enable_shared_glapi="$enableval"],
1135     [enable_shared_glapi=yes])
1136
1137 case "x$enable_opengl$enable_gles1$enable_gles2" in
1138 x*yes*yes*)
1139     if test "x$enable_shared_glapi" = xno; then
1140         AC_MSG_ERROR([shared GLAPI required when building two or more of
1141                       the following APIs - opengl, gles1 gles2])
1142     fi
1143     ;;
1144 esac
1145
1146 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1147
1148 # Build the pipe-drivers as separate libraries/modules.
1149 # Do not touch this unless you know what you are doing.
1150 # XXX: Expose via configure option ?
1151 enable_shared_pipe_drivers=no
1152
1153 dnl
1154 dnl Driver specific build directories
1155 dnl
1156
1157 if test "x$enable_gallium_osmesa" = xyes; then
1158     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1159         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1160     fi
1161     if test "x$enable_osmesa" = xyes; then
1162         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1163     fi
1164 fi
1165
1166 AC_SUBST([MESA_LLVM])
1167
1168 # SHA1 hashing
1169 AC_ARG_WITH([sha1],
1170         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1171         [choose SHA1 implementation])])
1172 case "x$with_sha1" in
1173 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1174   ;;
1175 *)
1176         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1177 esac
1178
1179 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1180 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1181         with_sha1=libc
1182 fi
1183 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1184         AC_MSG_ERROR([sha1 in libc requested but not found])
1185 fi
1186 if test "x$with_sha1" = xlibc; then
1187         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1188                 [Use libc SHA1 functions])
1189         SHA1_LIBS=""
1190 fi
1191 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1192 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1193         with_sha1=CommonCrypto
1194 fi
1195 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1196         AC_MSG_ERROR([CommonCrypto requested but not found])
1197 fi
1198 if test "x$with_sha1" = xCommonCrypto; then
1199         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1200                 [Use CommonCrypto SHA1 functions])
1201         SHA1_LIBS=""
1202 fi
1203 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1204 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1205 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1206         with_sha1=CryptoAPI
1207 fi
1208 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1209         AC_MSG_ERROR([CryptoAPI requested but not found])
1210 fi
1211 if test "x$with_sha1" = xCryptoAPI; then
1212         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1213                 [Use CryptoAPI SHA1 functions])
1214         SHA1_LIBS=""
1215 fi
1216 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1217 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1218         with_sha1=libmd
1219 fi
1220 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1221         AC_MSG_ERROR([libmd requested but not found])
1222 fi
1223 if test "x$with_sha1" = xlibmd; then
1224         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1225                   [Use libmd SHA1 functions])
1226         SHA1_LIBS=-lmd
1227 fi
1228 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1229 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1230    with_sha1=libsha1
1231 fi
1232 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1233         AC_MSG_ERROR([libsha1 requested but not found])
1234 fi
1235 if test "x$with_sha1" = xlibsha1; then
1236         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1237                   [Use libsha1 for SHA1])
1238         SHA1_LIBS=-lsha1
1239 fi
1240 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1241 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1242         with_sha1=libnettle
1243 fi
1244 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1245         AC_MSG_ERROR([libnettle requested but not found])
1246 fi
1247 if test "x$with_sha1" = xlibnettle; then
1248         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1249                   [Use libnettle SHA1 functions])
1250         SHA1_LIBS=-lnettle
1251 fi
1252 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1253 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1254         with_sha1=libgcrypt
1255 fi
1256 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1257         AC_MSG_ERROR([libgcrypt requested but not found])
1258 fi
1259 if test "x$with_sha1" = xlibgcrypt; then
1260         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1261                   [Use libgcrypt SHA1 functions])
1262         SHA1_LIBS=-lgcrypt
1263 fi
1264 # We don't need all of the OpenSSL libraries, just libcrypto
1265 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1266 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1267                   [HAVE_OPENSSL_PKC=no])
1268 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1269         if test "x$with_sha1" = x; then
1270                 with_sha1=libcrypto
1271         fi
1272 else
1273         if test "x$with_sha1" = xlibcrypto; then
1274                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1275         fi
1276 fi
1277 if test "x$with_sha1" = xlibcrypto; then
1278         if test "x$HAVE_LIBCRYPTO" = xyes; then
1279                 SHA1_LIBS=-lcrypto
1280         else
1281                 SHA1_LIBS="$OPENSSL_LIBS"
1282                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1283         fi
1284 fi
1285 AC_MSG_CHECKING([for SHA1 implementation])
1286 AC_MSG_RESULT([$with_sha1])
1287 AC_SUBST(SHA1_LIBS)
1288 AC_SUBST(SHA1_CFLAGS)
1289
1290 # Enable a define for SHA1
1291 if test "x$with_sha1" != "x"; then
1292         DEFINES="$DEFINES -DHAVE_SHA1"
1293 fi
1294
1295 # Allow user to configure out the shader-cache feature
1296 AC_ARG_ENABLE([shader-cache],
1297     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1298     [enable_shader_cache="$enableval"],
1299     [if test "x$with_sha1" != "x"; then
1300         enable_shader_cache=yes
1301      else
1302         enable_shader_cache=no
1303      fi])
1304 if test "x$with_sha1" = "x"; then
1305     if test "x$enable_shader_cache" = "xyes"; then
1306         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1307     fi
1308 fi
1309 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1310
1311 case "$host_os" in
1312 linux*)
1313     need_pci_id=yes ;;
1314 *)
1315     need_pci_id=no ;;
1316 esac
1317
1318 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
1319                   have_libudev=yes, have_libudev=no)
1320
1321 AC_ARG_ENABLE([sysfs],
1322     [AS_HELP_STRING([--enable-sysfs],
1323         [enable /sys PCI identification @<:@default=disabled@:>@])],
1324     [have_sysfs="$enableval"],
1325     [have_sysfs=no]
1326 )
1327
1328 if test "x$enable_dri" = xyes; then
1329     if test "$enable_static" = yes; then
1330         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1331     fi
1332
1333     # not a hard requirement as swrast does not depend on it
1334     if test "x$have_libdrm" = xyes; then
1335         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1336     fi
1337 fi
1338
1339 AC_ARG_ENABLE([driglx-direct],
1340     [AS_HELP_STRING([--disable-driglx-direct],
1341         [disable direct rendering in GLX and EGL for DRI \
1342             @<:@default=auto@:>@])],
1343     [driglx_direct="$enableval"],
1344     [driglx_direct="yes"])
1345
1346 dnl
1347 dnl libGL configuration per driver
1348 dnl
1349 case "x$enable_glx" in
1350 xxlib | xgallium-xlib)
1351     # Xlib-based GLX
1352     dri_modules="x11 xext xcb"
1353     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1354     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1355     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1356     GL_LIB_DEPS="$XLIBGL_LIBS"
1357     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1358     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1359     ;;
1360 xdri)
1361     # DRI-based GLX
1362     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1363
1364     # find the DRI deps for libGL
1365     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1366
1367     if test x"$driglx_direct" = xyes; then
1368         if test x"$dri_platform" = xdrm ; then
1369             DEFINES="$DEFINES -DGLX_USE_DRM"
1370             if test "x$have_libdrm" != xyes; then
1371                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1372             fi
1373
1374             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1375             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1376             if test x"$enable_dri3" = xyes; then
1377                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1378                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1379             fi
1380
1381             if test x"$enable_dri" = xyes; then
1382                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1383             fi
1384
1385             if test x"$enable_dri3" = xyes; then
1386                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1387                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1388                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1389             fi
1390         fi
1391         if test x"$dri_platform" = xapple ; then
1392             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1393         fi
1394     fi
1395
1396     # add xf86vidmode if available
1397     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1398     if test "$HAVE_XF86VIDMODE" = yes ; then
1399         dri_modules="$dri_modules xxf86vm"
1400     fi
1401
1402     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1403     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1404     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1405     GL_LIB_DEPS="$DRIGL_LIBS"
1406
1407     # need DRM libs, $PTHREAD_LIBS, etc.
1408     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1409     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1410     ;;
1411 esac
1412
1413 have_pci_id=no
1414 if test "$have_libudev" = yes; then
1415     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1416     have_pci_id=yes
1417 fi
1418
1419 if test "$have_sysfs" = yes; then
1420     DEFINES="$DEFINES -DHAVE_SYSFS"
1421     have_pci_id=yes
1422 fi
1423
1424 # This is outside the case (above) so that it is invoked even for non-GLX
1425 # builds.
1426 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1427
1428 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1429 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1430 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1431 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1432
1433 AC_SUBST([X11_INCLUDES])
1434 AC_SUBST([GL_LIB_DEPS])
1435 AC_SUBST([GL_PC_REQ_PRIV])
1436 AC_SUBST([GL_PC_LIB_PRIV])
1437 AC_SUBST([GL_PC_CFLAGS])
1438 AC_SUBST([DRI_PC_REQ_PRIV])
1439 AC_SUBST([GLESv1_CM_LIB_DEPS])
1440 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1441 AC_SUBST([GLESv2_LIB_DEPS])
1442 AC_SUBST([GLESv2_PC_LIB_PRIV])
1443
1444 AC_SUBST([HAVE_XF86VIDMODE])
1445
1446 dnl
1447 dnl More GLX setup
1448 dnl
1449 case "x$enable_glx" in
1450 xxlib | xgallium-xlib)
1451     DEFINES="$DEFINES -DUSE_XSHM"
1452     ;;
1453 xdri)
1454     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1455     if test "x$driglx_direct" = xyes; then
1456         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1457     fi
1458     ;;
1459 esac
1460
1461 dnl
1462 dnl TLS detection
1463 dnl
1464
1465 AC_ARG_ENABLE([glx-tls],
1466     [AS_HELP_STRING([--enable-glx-tls],
1467         [enable TLS support in GLX @<:@default=disabled@:>@])],
1468     [GLX_USE_TLS="$enableval"],
1469     [GLX_USE_TLS=no])
1470 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1471
1472 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1473       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1474
1475 dnl Read-only text section on x86 hardened platforms
1476 AC_ARG_ENABLE([glx-read-only-text],
1477     [AS_HELP_STRING([--enable-glx-read-only-text],
1478         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1479     [enable_glx_read_only_text="$enableval"],
1480     [enable_glx_read_only_text=no])
1481 if test "x$enable_glx_read_only_text" = xyes; then
1482     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1483 fi
1484
1485 dnl
1486 dnl More DRI setup
1487 dnl
1488 dnl Directory for DRI drivers
1489 AC_ARG_WITH([dri-driverdir],
1490     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1491         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1492     [DRI_DRIVER_INSTALL_DIR="$withval"],
1493     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1494 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1495 dnl Extra search path for DRI drivers
1496 AC_ARG_WITH([dri-searchpath],
1497     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1498         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1499     [DRI_DRIVER_SEARCH_DIR="$withval"],
1500     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1501 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1502 dnl Which drivers to build - default is chosen by platform
1503 AC_ARG_WITH([dri-drivers],
1504     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1505         [comma delimited classic DRI drivers list, e.g.
1506         "swrast,i965,radeon" @<:@default=auto@:>@])],
1507     [with_dri_drivers="$withval"],
1508     [with_dri_drivers=auto])
1509
1510 if test "x$with_dri_drivers" = xauto; then
1511     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1512         with_dri_drivers="yes"
1513     else
1514         with_dri_drivers="no"
1515     fi
1516 fi
1517 if test "x$with_dri_drivers" = xno; then
1518     with_dri_drivers=''
1519 fi
1520
1521 dnl If $with_dri_drivers is yes, drivers will be added through
1522 dnl platform checks. Set DEFINES and LIB_DEPS
1523 if test "x$enable_dri" = xyes; then
1524     # Platform specific settings and drivers to build
1525     case "$host_os" in
1526     linux*)
1527         DEFINES="$DEFINES -DHAVE_ALIAS"
1528         if test "x$enable_dri3" = xyes; then
1529             DEFINES="$DEFINES -DHAVE_DRI3"
1530         fi
1531
1532         if test "x$have_pci_id" != xyes; then
1533             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1534         fi
1535
1536         case "$host_cpu" in
1537         powerpc* | sparc*)
1538             # Build only the drivers for cards that exist on PowerPC/sparc
1539             if test "x$with_dri_drivers" = "xyes"; then
1540                 with_dri_drivers="r200 radeon swrast"
1541             fi
1542             ;;
1543         esac
1544         ;;
1545     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1546         DEFINES="$DEFINES -DHAVE_ALIAS"
1547         ;;
1548     gnu*)
1549         DEFINES="$DEFINES -DHAVE_ALIAS"
1550         ;;
1551     cygwin*)
1552         if test "x$with_dri_drivers" = "xyes"; then
1553             with_dri_drivers="swrast"
1554         fi
1555         ;;
1556     darwin*)
1557         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1558         if test "x$with_dri_drivers" = "xyes"; then
1559             with_dri_drivers="swrast"
1560         fi
1561         ;;
1562     esac
1563
1564     # default drivers
1565     if test "x$with_dri_drivers" = "xyes"; then
1566         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1567     fi
1568
1569     # Check for expat
1570     PKG_CHECK_MODULES([EXPAT], [expat], [],
1571         # expat version 2.0 and earlier do not provide expat.pc
1572         [AC_CHECK_HEADER([expat.h],[],
1573                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1574          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1575                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1576          EXPAT_LIBS="-lexpat"])
1577
1578     # put all the necessary libs together
1579     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1580 fi
1581
1582 AC_SUBST([DRI_LIB_DEPS])
1583
1584 DRI_DIRS=''
1585 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1586 if test -n "$with_dri_drivers"; then
1587     if test "x$enable_opengl" != xyes; then
1588         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1589     fi
1590
1591     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1592     for driver in $dri_drivers; do
1593         DRI_DIRS="$DRI_DIRS $driver"
1594         case "x$driver" in
1595         xi915)
1596             HAVE_I915_DRI=yes;
1597             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1598             ;;
1599         xi965)
1600             HAVE_I965_DRI=yes;
1601             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1602             ;;
1603         xnouveau)
1604             HAVE_NOUVEAU_DRI=yes;
1605             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1606             ;;
1607         xradeon)
1608             HAVE_RADEON_DRI=yes;
1609             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1610             ;;
1611         xr200)
1612             HAVE_R200_DRI=yes;
1613             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1614             ;;
1615         xswrast)
1616             HAVE_SWRAST_DRI=yes;
1617             ;;
1618         *)
1619             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1620             ;;
1621         esac
1622     done
1623     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1624 fi
1625
1626
1627 #
1628 # Vulkan driver configuration
1629 #
1630
1631 AC_ARG_WITH([vulkan-drivers],
1632     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1633         [comma delimited Vulkan drivers list, e.g.
1634         "intel"
1635         @<:@default=no@:>@])],
1636     [with_vulkan_drivers="$withval"],
1637     [with_vulkan_drivers="no"])
1638
1639 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1640 # here so that the script doesn't choke on an unknown driver name later.
1641 case "x$with_vulkan_drivers" in
1642     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1643     xno) with_vulkan_drivers='' ;;
1644 esac
1645
1646 AC_ARG_WITH([vulkan-icddir],
1647     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1648         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1649     [VULKAN_ICD_INSTALL_DIR="$withval"],
1650     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1651 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1652
1653 if test -n "$with_vulkan_drivers"; then
1654     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1655     for driver in $VULKAN_DRIVERS; do
1656         case "x$driver" in
1657         xintel)
1658             if test "x$HAVE_I965_DRI" != xyes; then
1659                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1660             fi
1661             if test "x$with_sha1" == "x"; then
1662                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1663             fi
1664             HAVE_INTEL_VULKAN=yes;
1665
1666             ;;
1667         *)
1668             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1669             ;;
1670         esac
1671     done
1672     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1673 fi
1674
1675
1676 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1677 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1678                                   "x$enable_osmesa" = xyes -o \
1679                                   -n "$DRI_DIRS")
1680
1681 dnl
1682 dnl OSMesa configuration
1683 dnl
1684
1685 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1686 AC_ARG_WITH([osmesa-bits],
1687     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1688         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1689     [osmesa_bits="$withval"],
1690     [osmesa_bits=8])
1691 if test "x$osmesa_bits" != x8; then
1692     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1693         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1694         osmesa_bits=8
1695     fi
1696 fi
1697 case "x$osmesa_bits" in
1698 x8)
1699     OSMESA_LIB="${OSMESA_LIB}"
1700     ;;
1701 x16|x32)
1702     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1703     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1704     ;;
1705 *)
1706     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1707     ;;
1708 esac
1709
1710 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1711     # only link libraries with osmesa if shared
1712     if test "$enable_static" = no; then
1713         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1714     else
1715         OSMESA_LIB_DEPS=""
1716     fi
1717     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1718 fi
1719
1720 AC_SUBST([OSMESA_LIB_DEPS])
1721 AC_SUBST([OSMESA_PC_REQ])
1722 AC_SUBST([OSMESA_PC_LIB_PRIV])
1723
1724 dnl
1725 dnl gbm configuration
1726 dnl
1727 if test "x$enable_gbm" = xauto; then
1728     case "$with_egl_platforms" in
1729         *drm*)
1730             enable_gbm=yes ;;
1731          *)
1732             enable_gbm=no ;;
1733     esac
1734 fi
1735 if test "x$enable_gbm" = xyes; then
1736     if test "x$need_pci_id$have_pci_id" = xyesno; then
1737         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1738     fi
1739
1740     if test "x$enable_dri" = xyes; then
1741         if test "x$enable_shared_glapi" = xno; then
1742             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1743         fi
1744     else
1745         # Strictly speaking libgbm does not require --enable-dri, although
1746         # both of its backends do. Thus one can build libgbm without any
1747         # backends if --disable-dri is set.
1748         # To avoid unnecessary complexity of checking if at least one backend
1749         # is available when building, just mandate --enable-dri.
1750         AC_MSG_ERROR([gbm requires --enable-dri])
1751     fi
1752 fi
1753 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1754 if test "x$need_pci_id$have_libudev" = xyesyes; then
1755     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1756 else
1757     GBM_PC_REQ_PRIV=""
1758 fi
1759 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1760 AC_SUBST([GBM_PC_REQ_PRIV])
1761 AC_SUBST([GBM_PC_LIB_PRIV])
1762
1763 dnl
1764 dnl EGL configuration
1765 dnl
1766 EGL_CLIENT_APIS=""
1767
1768 if test "x$enable_egl" = xyes; then
1769     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1770
1771     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1772
1773     if test "$enable_static" != yes; then
1774         if test "x$enable_dri" = xyes; then
1775             HAVE_EGL_DRIVER_DRI2=1
1776             if test "x$enable_shared_glapi" = xno; then
1777                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1778             fi
1779             if test "x$enable_dri3" = xyes; then
1780                 HAVE_EGL_DRIVER_DRI3=1
1781                 if test "x$enable_shared_glapi" = xno; then
1782                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1783                 fi
1784             fi
1785         else
1786             # Avoid building an "empty" libEGL. Drop/update this
1787             # when other backends (haiku?) come along.
1788             AC_MSG_ERROR([egl requires --enable-dri])
1789         fi
1790
1791     fi
1792 fi
1793 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1794 AC_SUBST([EGL_LIB_DEPS])
1795
1796 gallium_st="mesa"
1797
1798 dnl
1799 dnl XA configuration
1800 dnl
1801 if test "x$enable_xa" = xyes; then
1802     if test "x$with_gallium_drivers" = xswrast; then
1803        AC_MSG_ERROR([
1804           Building xa requires at least one non swrast gallium driver.
1805           If you are looking to use libxatracker.so with the VMware driver,
1806           make sure to include svga in the gallium drivers list, apart from
1807           enabling XA.
1808           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1809     fi
1810     gallium_st="$gallium_st xa"
1811 fi
1812 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1813
1814 dnl
1815 dnl Gallium G3DVL configuration
1816 dnl
1817 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1818     if test "x$enable_xvmc" = xauto; then
1819         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1820     fi
1821
1822     if test "x$enable_vdpau" = xauto; then
1823         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1824     fi
1825
1826     if test "x$enable_omx" = xauto; then
1827         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1828     fi
1829
1830     if test "x$enable_va" = xauto; then
1831         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1832     fi
1833 fi
1834
1835 if test "x$enable_dri" = xyes -o \
1836         "x$enable_xvmc" = xyes -o \
1837         "x$enable_vdpau" = xyes -o \
1838         "x$enable_omx" = xyes -o \
1839         "x$enable_va" = xyes; then
1840     need_gallium_vl=yes
1841 fi
1842 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1843
1844 if test "x$enable_xvmc" = xyes -o \
1845         "x$enable_vdpau" = xyes -o \
1846         "x$enable_omx" = xyes -o \
1847         "x$enable_va" = xyes; then
1848     if test x"$enable_dri3" = xyes; then
1849         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1850                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1851     else
1852         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1853     fi
1854     need_gallium_vl_winsys=yes
1855 fi
1856 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1857
1858 if test "x$enable_xvmc" = xyes; then
1859     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1860     gallium_st="$gallium_st xvmc"
1861 fi
1862 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1863
1864 if test "x$enable_vdpau" = xyes; then
1865     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1866     gallium_st="$gallium_st vdpau"
1867     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1868 fi
1869 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1870
1871 if test "x$enable_omx" = xyes; then
1872     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1873     gallium_st="$gallium_st omx"
1874 fi
1875 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1876
1877 if test "x$enable_va" = xyes; then
1878     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1879     gallium_st="$gallium_st va"
1880 fi
1881 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1882
1883 dnl
1884 dnl Nine Direct3D9 configuration
1885 dnl
1886 if test "x$enable_nine" = xyes; then
1887     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1888         AC_MSG_ERROR([nine requires the gallium swrast driver])
1889     fi
1890     if test "x$with_gallium_drivers" = xswrast; then
1891         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1892     fi
1893     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1894         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1895     fi
1896
1897     if test "x$enable_dri3" = xno; then
1898         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1899     fi
1900
1901     gallium_st="$gallium_st nine"
1902 fi
1903 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1904
1905 dnl
1906 dnl OpenCL configuration
1907 dnl
1908
1909 AC_ARG_WITH([clang-libdir],
1910    [AS_HELP_STRING([--with-clang-libdir],
1911          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1912    [CLANG_LIBDIR="$withval"],
1913    [CLANG_LIBDIR=''])
1914
1915 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1916 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1917
1918 if test "x$have_libelf" = xno; then
1919    LIBELF_LIBS=''
1920    LIBELF_CFLAGS=''
1921    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1922    AC_SUBST([LIBELF_LIBS])
1923    AC_SUBST([LIBELF_CFLAGS])
1924 fi
1925
1926 if test "x$enable_opencl" = xyes; then
1927     if test -z "$with_gallium_drivers"; then
1928         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1929     fi
1930
1931     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1932         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1933     fi
1934
1935     if test "x$have_libclc" = xno; then
1936         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1937                     Make sure the directory containing libclc.pc is specified in your
1938                     PKG_CONFIG_PATH environment variable.
1939                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1940     else
1941         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1942         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1943         AC_SUBST([LIBCLC_INCLUDEDIR])
1944         AC_SUBST([LIBCLC_LIBEXECDIR])
1945     fi
1946
1947     gallium_st="$gallium_st clover"
1948
1949     if test "x$enable_opencl_icd" = xyes; then
1950         OPENCL_LIBNAME="MesaOpenCL"
1951     else
1952         OPENCL_LIBNAME="OpenCL"
1953     fi
1954
1955     if test "x$have_libelf" != xyes; then
1956        AC_MSG_ERROR([Clover requires libelf])
1957     fi
1958 fi
1959 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1960 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1961 AC_SUBST([OPENCL_LIBNAME])
1962
1963 dnl
1964 dnl Gallium configuration
1965 dnl
1966 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1967
1968 AC_SUBST([LLVM_BINDIR])
1969 AC_SUBST([LLVM_CFLAGS])
1970 AC_SUBST([LLVM_CPPFLAGS])
1971 AC_SUBST([LLVM_CXXFLAGS])
1972 AC_SUBST([LLVM_LIBDIR])
1973 AC_SUBST([LLVM_LIBS])
1974 AC_SUBST([LLVM_LDFLAGS])
1975 AC_SUBST([LLVM_INCLUDEDIR])
1976 AC_SUBST([LLVM_VERSION])
1977 AC_SUBST([CLANG_RESOURCE_DIR])
1978
1979 case "x$enable_opengl$enable_gles1$enable_gles2" in
1980 x*yes*)
1981     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1982     ;;
1983 esac
1984
1985 AC_SUBST([VG_LIB_DEPS])
1986 AC_SUBST([EGL_CLIENT_APIS])
1987
1988 dnl
1989 dnl EGL Platforms configuration
1990 dnl
1991 AC_ARG_WITH([egl-platforms],
1992     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1993         [comma delimited native platforms libEGL supports, e.g.
1994         "x11,drm" @<:@default=auto@:>@])],
1995     [with_egl_platforms="$withval"],
1996     [if test "x$enable_egl" = xyes; then
1997         with_egl_platforms="x11"
1998     else
1999         with_egl_platforms=""
2000     fi])
2001
2002 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2003     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2004 fi
2005
2006 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland_scanner],
2007         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland_scanner`,
2008         WAYLAND_SCANNER='')
2009 if test "x$WAYLAND_SCANNER" = x; then
2010     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2011 fi
2012
2013 # Do per-EGL platform setups and checks
2014 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2015 for plat in $egl_platforms; do
2016         case "$plat" in
2017         wayland)
2018                 test "x$have_libdrm" != xyes &&
2019                         AC_MSG_ERROR([EGL platform wayland requires libdrm >= $LIBDRM_REQUIRED])
2020
2021                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2022
2023                 if test "x$WAYLAND_SCANNER" = x; then
2024                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2025                 fi
2026                 ;;
2027
2028         x11)
2029                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2030                 ;;
2031
2032         drm)
2033                 test "x$enable_gbm" = "xno" &&
2034                         AC_MSG_ERROR([EGL platform drm needs gbm])
2035                 test "x$have_libdrm" != xyes &&
2036                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
2037                 ;;
2038
2039         surfaceless)
2040                 test "x$have_libdrm" != xyes &&
2041                         AC_MSG_ERROR([EGL platform surfaceless requires libdrm >= $LIBDRM_REQUIRED])
2042                 ;;
2043
2044         android)
2045                 ;;
2046
2047         *)
2048                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2049                 ;;
2050         esac
2051
2052         case "$plat$need_pci_id$have_pci_id" in
2053                 waylandyesno|drmyesno)
2054                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
2055         esac
2056 done
2057
2058 # libEGL wants to default to the first platform specified in
2059 # ./configure.  parse that here.
2060 if test "x$egl_platforms" != "x"; then
2061     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2062     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2063 else
2064     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2065 fi
2066
2067 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2068 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2069 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2070 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2071 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2072
2073 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2074
2075 AC_SUBST([EGL_NATIVE_PLATFORM])
2076 AC_SUBST([EGL_CFLAGS])
2077
2078 # If we don't have the X11 platform, set this define so we don't try to include
2079 # the X11 headers.
2080 if ! echo "$egl_platforms" | grep -q 'x11'; then
2081     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2082     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2083 fi
2084
2085 dnl
2086 dnl Gallium LLVM
2087 dnl
2088 AC_ARG_ENABLE([gallium-llvm],
2089     [AS_HELP_STRING([--enable-gallium-llvm],
2090         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2091     [enable_gallium_llvm="$enableval"],
2092     [enable_gallium_llvm=auto])
2093
2094 AC_ARG_ENABLE([llvm-shared-libs],
2095     [AS_HELP_STRING([--enable-llvm-shared-libs],
2096         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2097     [enable_llvm_shared_libs="$enableval"],
2098     [enable_llvm_shared_libs=yes])
2099
2100 AC_ARG_WITH([llvm-prefix],
2101     [AS_HELP_STRING([--with-llvm-prefix],
2102         [Prefix for LLVM installations in non-standard locations])],
2103     [llvm_prefix="$withval"],
2104     [llvm_prefix=''])
2105
2106
2107 # Call this inside ` ` to get the return value.
2108 # $1 is the llvm-config command with arguments.
2109 strip_unwanted_llvm_flags() {
2110     # Use \> (marks the end of the word)
2111     echo `$1` | sed \
2112         -e 's/-march=\S*//g' \
2113         -e 's/-mtune=\S*//g' \
2114         -e 's/-mcpu=\S*//g' \
2115         -e 's/-DNDEBUG\>//g' \
2116         -e 's/-D_GNU_SOURCE\>//g' \
2117         -e 's/-pedantic\>//g' \
2118         -e 's/-Wcovered-switch-default\>//g' \
2119         -e 's/-O.\>//g' \
2120         -e 's/-g\>//g' \
2121         -e 's/-Wall\>//g' \
2122         -e 's/-Wcast-qual\>//g' \
2123         -e 's/-Woverloaded-virtual\>//g' \
2124         -e 's/-fcolor-diagnostics\>//g' \
2125         -e 's/-fdata-sections\>//g' \
2126         -e 's/-ffunction-sections\>//g' \
2127         -e 's/-fno-exceptions\>//g' \
2128         -e 's/-fomit-frame-pointer\>//g' \
2129         -e 's/-fvisibility-inlines-hidden\>//g' \
2130         -e 's/-fPIC\>//g' \
2131         -e 's/-fstack-protector-strong\>//g'
2132 }
2133
2134 llvm_check_version_for() {
2135     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2136         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2137     fi
2138 }
2139
2140
2141
2142 if test -z "$with_gallium_drivers"; then
2143     enable_gallium_llvm=no
2144 fi
2145 if test "x$enable_gallium_llvm" = xauto; then
2146     case "$host_cpu" in
2147     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2148     esac
2149 fi
2150 if test "x$enable_gallium_llvm" = xyes; then
2151     if test -n "$llvm_prefix"; then
2152         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2153     else
2154         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2155     fi
2156
2157     if test "x$LLVM_CONFIG" != xno; then
2158         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2159         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2160         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2161         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2162         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2163         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2164         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2165         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2166
2167         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2168             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2169         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2170             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2171
2172         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2173         if test -z "$LLVM_VERSION_PATCH"; then
2174             LLVM_VERSION_PATCH=0
2175         fi
2176
2177         if test -n "${LLVM_VERSION_MAJOR}"; then
2178             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2179         else
2180             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2181         fi
2182
2183         LLVM_REQUIRED_VERSION_MAJOR="3"
2184         LLVM_REQUIRED_VERSION_MINOR="3"
2185         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2186             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2187         fi
2188
2189         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2190
2191         if test "x$enable_opencl" = xyes; then
2192             llvm_check_version_for "3" "6" "0" "opencl"
2193
2194             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2195             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2196         fi
2197         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2198         MESA_LLVM=1
2199
2200         dnl Check for Clang internal headers
2201         if test "x$enable_opencl" = xyes; then
2202             if test -z "$CLANG_LIBDIR"; then
2203                 CLANG_LIBDIR=${LLVM_LIBDIR}
2204             fi
2205             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2206             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2207                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2208         fi
2209     else
2210         MESA_LLVM=0
2211         LLVM_VERSION_INT=0
2212     fi
2213 else
2214     MESA_LLVM=0
2215     LLVM_VERSION_INT=0
2216
2217     if test "x$enable_opencl" = xyes; then
2218         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2219     fi
2220 fi
2221
2222 dnl Directory for XVMC libs
2223 AC_ARG_WITH([xvmc-libdir],
2224     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2225         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2226     [XVMC_LIB_INSTALL_DIR="$withval"],
2227     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2228 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2229
2230 dnl
2231 dnl Gallium Tests
2232 dnl
2233 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2234
2235 dnl Directory for VDPAU libs
2236 AC_ARG_WITH([vdpau-libdir],
2237     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2238         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2239     [VDPAU_LIB_INSTALL_DIR="$withval"],
2240     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2241 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2242
2243 dnl Directory for OMX libs
2244
2245 AC_ARG_WITH([omx-libdir],
2246     [AS_HELP_STRING([--with-omx-libdir=DIR],
2247         [directory for the OMX libraries])],
2248     [OMX_LIB_INSTALL_DIR="$withval"],
2249     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2250 AC_SUBST([OMX_LIB_INSTALL_DIR])
2251
2252 dnl Directory for VA libs
2253
2254 AC_ARG_WITH([va-libdir],
2255     [AS_HELP_STRING([--with-va-libdir=DIR],
2256         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2257     [VA_LIB_INSTALL_DIR="$withval"],
2258     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2259 AC_SUBST([VA_LIB_INSTALL_DIR])
2260
2261 AC_ARG_WITH([d3d-libdir],
2262     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2263         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2264     [D3D_DRIVER_INSTALL_DIR="$withval"],
2265     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2266 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2267
2268 dnl
2269 dnl Gallium helper functions
2270 dnl
2271 gallium_require_drm() {
2272     if test "x$have_libdrm" != xyes; then
2273        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
2274     fi
2275 }
2276
2277 gallium_require_llvm() {
2278     if test "x$MESA_LLVM" = x0; then
2279         case "$host" in *gnux32) return;; esac
2280         case "$host_cpu" in
2281         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2282         esac
2283     fi
2284 }
2285
2286 gallium_require_drm_loader() {
2287     if test "x$need_pci_id$have_pci_id" = xyesno; then
2288         AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
2289     fi
2290 }
2291
2292 dnl This is for Glamor. Skip this if OpenGL is disabled.
2293 require_egl_drm() {
2294     if test "x$enable_opengl" = xno; then
2295         return 0
2296     fi
2297
2298     case "$with_egl_platforms" in
2299         *drm*)
2300             ;;
2301          *)
2302             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2303             ;;
2304     esac
2305     if test "x$enable_gbm" != xyes; then
2306             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2307     fi
2308 }
2309
2310 radeon_llvm_check() {
2311     if test ${LLVM_VERSION_INT} -lt 307; then
2312         amdgpu_llvm_target_name='r600'
2313     else
2314         amdgpu_llvm_target_name='amdgpu'
2315     fi
2316     if test "x$enable_gallium_llvm" != "xyes"; then
2317         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2318     fi
2319     llvm_check_version_for "3" "6" "0" $1
2320     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2321         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2322     fi
2323     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2324     NEED_RADEON_LLVM=yes
2325     if test "x$have_libelf" != xyes; then
2326        AC_MSG_ERROR([$1 requires libelf when using llvm])
2327     fi
2328 }
2329
2330 swr_llvm_check() {
2331     gallium_require_llvm $1
2332     if test ${LLVM_VERSION_INT} -lt 306; then
2333         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2334     fi
2335     if test "x$enable_gallium_llvm" != "xyes"; then
2336         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2337     fi
2338 }
2339
2340 swr_require_cxx_feature_flags() {
2341     feature_name="$1"
2342     preprocessor_test="$2"
2343     option_list="$3"
2344     output_var="$4"
2345
2346     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2347     AC_LANG_PUSH([C++])
2348     save_CXXFLAGS="$CXXFLAGS"
2349     save_IFS="$IFS"
2350     IFS=","
2351     found=0
2352     for opts in $option_list
2353     do
2354         unset IFS
2355         CXXFLAGS="$opts $save_CXXFLAGS"
2356         AC_COMPILE_IFELSE(
2357             [AC_LANG_PROGRAM(
2358                 [   #if !($preprocessor_test)
2359                     #error
2360                     #endif
2361                 ])],
2362             [found=1; break],
2363             [])
2364         IFS=","
2365     done
2366     IFS="$save_IFS"
2367     CXXFLAGS="$save_CXXFLAGS"
2368     AC_LANG_POP([C++])
2369     if test $found -eq 1; then
2370         AC_MSG_RESULT([$opts])
2371         eval "$output_var=\$opts"
2372         return 0
2373     fi
2374     AC_MSG_RESULT([no])
2375     AC_MSG_ERROR([swr requires $feature_name support])
2376     return 1
2377 }
2378
2379 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2380 if test -n "$with_gallium_drivers"; then
2381     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2382     for driver in $gallium_drivers; do
2383         case "x$driver" in
2384         xsvga)
2385             HAVE_GALLIUM_SVGA=yes
2386             gallium_require_drm "svga"
2387             gallium_require_drm_loader
2388             ;;
2389         xi915)
2390             HAVE_GALLIUM_I915=yes
2391             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2392             gallium_require_drm "Gallium i915"
2393             gallium_require_drm_loader
2394             ;;
2395         xilo)
2396             HAVE_GALLIUM_ILO=yes
2397             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2398             gallium_require_drm "Gallium i965/ilo"
2399             gallium_require_drm_loader
2400             ;;
2401         xr300)
2402             HAVE_GALLIUM_R300=yes
2403             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2404             gallium_require_drm "Gallium R300"
2405             gallium_require_drm_loader
2406             gallium_require_llvm "Gallium R300"
2407             ;;
2408         xr600)
2409             HAVE_GALLIUM_R600=yes
2410             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2411             gallium_require_drm "Gallium R600"
2412             gallium_require_drm_loader
2413             if test "x$enable_opencl" = xyes; then
2414                 radeon_llvm_check "r600g"
2415                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2416             fi
2417             ;;
2418         xradeonsi)
2419             HAVE_GALLIUM_RADEONSI=yes
2420             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2421             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2422             gallium_require_drm "radeonsi"
2423             gallium_require_drm_loader
2424             radeon_llvm_check "radeonsi"
2425             require_egl_drm "radeonsi"
2426             ;;
2427         xnouveau)
2428             HAVE_GALLIUM_NOUVEAU=yes
2429             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2430             gallium_require_drm "nouveau"
2431             gallium_require_drm_loader
2432             ;;
2433         xfreedreno)
2434             HAVE_GALLIUM_FREEDRENO=yes
2435             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2436             gallium_require_drm "freedreno"
2437             gallium_require_drm_loader
2438             ;;
2439         xswrast)
2440             HAVE_GALLIUM_SOFTPIPE=yes
2441             if test "x$MESA_LLVM" = x1; then
2442                 HAVE_GALLIUM_LLVMPIPE=yes
2443             fi
2444             ;;
2445         xswr)
2446             swr_llvm_check "swr"
2447
2448             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2449                 ",-std=c++11" \
2450                 SWR_CXX11_CXXFLAGS
2451             AC_SUBST([SWR_CXX11_CXXFLAGS])
2452
2453             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2454                 ",-mavx,-march=core-avx" \
2455                 SWR_AVX_CXXFLAGS
2456             AC_SUBST([SWR_AVX_CXXFLAGS])
2457
2458             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2459                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2460                 SWR_AVX2_CXXFLAGS
2461             AC_SUBST([SWR_AVX2_CXXFLAGS])
2462
2463             HAVE_GALLIUM_SWR=yes
2464             ;;
2465         xvc4)
2466             HAVE_GALLIUM_VC4=yes
2467             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2468             gallium_require_drm "vc4"
2469             gallium_require_drm_loader
2470
2471             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2472                               [USE_VC4_SIMULATOR=yes;
2473                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2474                               [USE_VC4_SIMULATOR=no])
2475             ;;
2476         xvirgl)
2477             HAVE_GALLIUM_VIRGL=yes
2478             gallium_require_drm "virgl"
2479             gallium_require_drm_loader
2480             require_egl_drm "virgl"
2481             ;;
2482         *)
2483             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2484             ;;
2485         esac
2486     done
2487 fi
2488
2489 dnl Set LLVM_LIBS - This is done after the driver configuration so
2490 dnl that drivers can add additional components to LLVM_COMPONENTS.
2491 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2492 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2493 dnl this was causing the same libraries to be appear multiple times
2494 dnl in LLVM_LIBS.
2495
2496 if test "x$MESA_LLVM" != x0; then
2497
2498     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2499        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2500     fi
2501     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2502
2503     dnl llvm-config may not give the right answer when llvm is a built as a
2504     dnl single shared library, so we must work the library name out for
2505     dnl ourselves.
2506     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2507     if test "x$enable_llvm_shared_libs" = xyes; then
2508         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2509         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2510         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2511
2512         if test "x$llvm_have_one_so" = xyes; then
2513             dnl LLVM was built using auto*, so there is only one shared object.
2514             LLVM_LIBS="-l$LLVM_SO_NAME"
2515         else
2516             dnl If LLVM was built with CMake, there will be one shared object per
2517             dnl component.
2518             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2519                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2520         Please make sure you have built llvm with the --enable-shared option
2521         and that your llvm libraries are installed in $LLVM_LIBDIR
2522         If you have installed your llvm libraries to a different directory you
2523         can use the --with-llvm-prefix= configure flag to specify this directory.
2524         NOTE: Mesa is attempting to use llvm shared libraries by default.
2525         If you do not want to build with llvm shared libraries and instead want to
2526         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2527         invocation and rebuild.])])
2528
2529            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2530            dnl install uses a shared object for each component and we have
2531            dnl already added all of these objects to LLVM_LIBS.
2532         fi
2533     else
2534         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2535         dnl We need to link to llvm system libs when using static libs
2536         dnl However, only llvm 3.5+ provides --system-libs
2537         if test $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2538             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2539         fi
2540     fi
2541 fi
2542
2543 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2544 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2545 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2546 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2547 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2548 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2550                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2552 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2557                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2558                                          "x$HAVE_GALLIUM_SWR" = xyes)
2559 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2560 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2561
2562 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2563
2564 if test "x$enable_dri" = xyes; then
2565     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2566 fi
2567
2568 if test "x$have_drisw_kms" = xyes; then
2569     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2570 fi
2571 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2572
2573 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2574 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2575 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2576 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2577 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2578 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2579
2580 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2581
2582 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2583                                         "x$HAVE_I965_DRI" = xyes)
2584
2585 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2586                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2587                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2588 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2589 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2590 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2591 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2592 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2593 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2594     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2595 fi
2596
2597 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2598 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2599 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2600
2601 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2602 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2603 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2604
2605 AC_SUBST([NINE_MAJOR], 1)
2606 AC_SUBST([NINE_MINOR], 0)
2607 AC_SUBST([NINE_TINY], 0)
2608 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2609
2610 AC_SUBST([VDPAU_MAJOR], 1)
2611 AC_SUBST([VDPAU_MINOR], 0)
2612
2613 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2614 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2615 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2616 AC_SUBST([VA_MINOR], $VA_MINOR)
2617
2618 AC_SUBST([XVMC_MAJOR], 1)
2619 AC_SUBST([XVMC_MINOR], 0)
2620
2621 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2622 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2623 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2624 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2625
2626 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2627 AC_SUBST([XA_MINOR], $XA_MINOR)
2628 AC_SUBST([XA_TINY], $XA_TINY)
2629 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2630
2631 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2632
2633 AC_ARG_ENABLE(valgrind,
2634               [AS_HELP_STRING([--enable-valgrind],
2635                              [Build mesa with valgrind support (default: auto)])],
2636                              [VALGRIND=$enableval], [VALGRIND=auto])
2637 if test "x$VALGRIND" != xno; then
2638         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2639 fi
2640 AC_MSG_CHECKING([whether to enable Valgrind support])
2641 if test "x$VALGRIND" = xauto; then
2642         VALGRIND="$have_valgrind"
2643 fi
2644
2645 if test "x$VALGRIND" = "xyes"; then
2646         if ! test "x$have_valgrind" = xyes; then
2647                 AC_MSG_ERROR([Valgrind support required but not present])
2648         fi
2649         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2650 fi
2651
2652 AC_MSG_RESULT([$VALGRIND])
2653
2654 dnl Restore LDFLAGS and CPPFLAGS
2655 LDFLAGS="$_SAVE_LDFLAGS"
2656 CPPFLAGS="$_SAVE_CPPFLAGS"
2657
2658 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2659 if test "x$acv_mesa_CLANG" = xyes; then
2660     CFLAGS="$CFLAGS -Qunused-arguments"
2661     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2662 fi
2663
2664 dnl Add user CFLAGS and CXXFLAGS
2665 CFLAGS="$CFLAGS $USER_CFLAGS"
2666 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2667
2668 dnl Substitute the config
2669 AC_CONFIG_FILES([Makefile
2670                 src/Makefile
2671                 src/compiler/Makefile
2672                 src/egl/Makefile
2673                 src/egl/main/egl.pc
2674                 src/egl/wayland/wayland-drm/Makefile
2675                 src/egl/wayland/wayland-egl/Makefile
2676                 src/egl/wayland/wayland-egl/wayland-egl.pc
2677                 src/gallium/Makefile
2678                 src/gallium/auxiliary/Makefile
2679                 src/gallium/auxiliary/pipe-loader/Makefile
2680                 src/gallium/drivers/freedreno/Makefile
2681                 src/gallium/drivers/ddebug/Makefile
2682                 src/gallium/drivers/i915/Makefile
2683                 src/gallium/drivers/ilo/Makefile
2684                 src/gallium/drivers/llvmpipe/Makefile
2685                 src/gallium/drivers/noop/Makefile
2686                 src/gallium/drivers/nouveau/Makefile
2687                 src/gallium/drivers/r300/Makefile
2688                 src/gallium/drivers/r600/Makefile
2689                 src/gallium/drivers/radeon/Makefile
2690                 src/gallium/drivers/radeonsi/Makefile
2691                 src/gallium/drivers/rbug/Makefile
2692                 src/gallium/drivers/softpipe/Makefile
2693                 src/gallium/drivers/svga/Makefile
2694                 src/gallium/drivers/swr/Makefile
2695                 src/gallium/drivers/trace/Makefile
2696                 src/gallium/drivers/vc4/Makefile
2697                 src/gallium/drivers/virgl/Makefile
2698                 src/gallium/state_trackers/clover/Makefile
2699                 src/gallium/state_trackers/dri/Makefile
2700                 src/gallium/state_trackers/glx/xlib/Makefile
2701                 src/gallium/state_trackers/nine/Makefile
2702                 src/gallium/state_trackers/omx/Makefile
2703                 src/gallium/state_trackers/osmesa/Makefile
2704                 src/gallium/state_trackers/va/Makefile
2705                 src/gallium/state_trackers/vdpau/Makefile
2706                 src/gallium/state_trackers/xa/Makefile
2707                 src/gallium/state_trackers/xvmc/Makefile
2708                 src/gallium/targets/d3dadapter9/Makefile
2709                 src/gallium/targets/d3dadapter9/d3d.pc
2710                 src/gallium/targets/dri/Makefile
2711                 src/gallium/targets/libgl-xlib/Makefile
2712                 src/gallium/targets/omx/Makefile
2713                 src/gallium/targets/opencl/Makefile
2714                 src/gallium/targets/opencl/mesa.icd
2715                 src/gallium/targets/osmesa/Makefile
2716                 src/gallium/targets/osmesa/osmesa.pc
2717                 src/gallium/targets/pipe-loader/Makefile
2718                 src/gallium/targets/va/Makefile
2719                 src/gallium/targets/vdpau/Makefile
2720                 src/gallium/targets/xa/Makefile
2721                 src/gallium/targets/xa/xatracker.pc
2722                 src/gallium/targets/xvmc/Makefile
2723                 src/gallium/tests/trivial/Makefile
2724                 src/gallium/tests/unit/Makefile
2725                 src/gallium/winsys/freedreno/drm/Makefile
2726                 src/gallium/winsys/i915/drm/Makefile
2727                 src/gallium/winsys/intel/drm/Makefile
2728                 src/gallium/winsys/nouveau/drm/Makefile
2729                 src/gallium/winsys/radeon/drm/Makefile
2730                 src/gallium/winsys/amdgpu/drm/Makefile
2731                 src/gallium/winsys/svga/drm/Makefile
2732                 src/gallium/winsys/sw/dri/Makefile
2733                 src/gallium/winsys/sw/kms-dri/Makefile
2734                 src/gallium/winsys/sw/null/Makefile
2735                 src/gallium/winsys/sw/wrapper/Makefile
2736                 src/gallium/winsys/sw/xlib/Makefile
2737                 src/gallium/winsys/vc4/drm/Makefile
2738                 src/gallium/winsys/virgl/drm/Makefile
2739                 src/gallium/winsys/virgl/vtest/Makefile
2740                 src/gbm/Makefile
2741                 src/gbm/main/gbm.pc
2742                 src/glx/Makefile
2743                 src/glx/apple/Makefile
2744                 src/glx/tests/Makefile
2745                 src/gtest/Makefile
2746                 src/intel/Makefile
2747                 src/intel/genxml/Makefile
2748                 src/intel/isl/Makefile
2749                 src/intel/vulkan/Makefile
2750                 src/loader/Makefile
2751                 src/mapi/Makefile
2752                 src/mapi/es1api/glesv1_cm.pc
2753                 src/mapi/es2api/glesv2.pc
2754                 src/mapi/glapi/gen/Makefile
2755                 src/mesa/Makefile
2756                 src/mesa/gl.pc
2757                 src/mesa/drivers/dri/dri.pc
2758                 src/mesa/drivers/dri/common/Makefile
2759                 src/mesa/drivers/dri/common/xmlpool/Makefile
2760                 src/mesa/drivers/dri/i915/Makefile
2761                 src/mesa/drivers/dri/i965/Makefile
2762                 src/mesa/drivers/dri/Makefile
2763                 src/mesa/drivers/dri/nouveau/Makefile
2764                 src/mesa/drivers/dri/r200/Makefile
2765                 src/mesa/drivers/dri/radeon/Makefile
2766                 src/mesa/drivers/dri/swrast/Makefile
2767                 src/mesa/drivers/osmesa/Makefile
2768                 src/mesa/drivers/osmesa/osmesa.pc
2769                 src/mesa/drivers/x11/Makefile
2770                 src/mesa/main/tests/Makefile
2771                 src/util/Makefile
2772                 src/util/tests/hash_table/Makefile])
2773
2774 AC_OUTPUT
2775
2776 # Fix up dependencies in *.Plo files, where we changed the extension of a
2777 # source file
2778 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2779 $SED -i -e 's/gen6_blorp.cpp/gen6_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen6_blorp.Plo
2780 $SED -i -e 's/gen7_blorp.cpp/gen7_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen7_blorp.Plo
2781 $SED -i -e 's/gen8_blorp.cpp/gen8_blorp.c/' src/mesa/drivers/dri/i965/.deps/gen8_blorp.Plo
2782
2783
2784 dnl
2785 dnl Output some configuration info for the user
2786 dnl
2787 echo ""
2788 echo "        prefix:          $prefix"
2789 echo "        exec_prefix:     $exec_prefix"
2790 echo "        libdir:          $libdir"
2791 echo "        includedir:      $includedir"
2792
2793 dnl API info
2794 echo ""
2795 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2796
2797 dnl Driver info
2798 echo ""
2799 case "x$enable_osmesa$enable_gallium_osmesa" in
2800 xnoyes)
2801         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2802         ;;
2803 xyesno)
2804         echo "        OSMesa:          lib$OSMESA_LIB"
2805         ;;
2806 xnono)
2807         echo "        OSMesa:          no"
2808         ;;
2809 esac
2810
2811 echo ""
2812 if test "x$enable_dri" != xno; then
2813         echo "        DRI platform:    $dri_platform"
2814         if test -z "$DRI_DIRS"; then
2815             echo "        DRI drivers:     no"
2816         else
2817             echo "        DRI drivers:     $DRI_DIRS"
2818         fi
2819         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2820 fi
2821
2822 case "x$enable_glx" in
2823 xdri)
2824     echo "        GLX:             DRI-based"
2825     ;;
2826 xxlib)
2827     echo "        GLX:             Xlib-based"
2828     ;;
2829 xgallium-xlib)
2830     echo "        GLX:             Xlib-based (Gallium)"
2831     ;;
2832 *)
2833     echo "        GLX:             $enable_glx"
2834     ;;
2835 esac
2836
2837 dnl EGL
2838 echo ""
2839 echo "        EGL:             $enable_egl"
2840 if test "$enable_egl" = yes; then
2841     echo "        EGL platforms:   $egl_platforms"
2842
2843     egl_drivers=""
2844     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2845         egl_drivers="$egl_drivers builtin:egl_dri2"
2846     fi
2847     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2848         egl_drivers="$egl_drivers builtin:egl_dri3"
2849     fi
2850
2851     echo "        EGL drivers:    $egl_drivers"
2852 fi
2853
2854 # Vulkan
2855 echo ""
2856 if test "x$VULKAN_DRIVERS" != x; then
2857     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2858     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2859 else
2860     echo "        Vulkan drivers:  no"
2861 fi
2862
2863 echo ""
2864 if test "x$MESA_LLVM" = x1; then
2865     echo "        llvm:            yes"
2866     echo "        llvm-config:     $LLVM_CONFIG"
2867     echo "        llvm-version:    $LLVM_VERSION"
2868 else
2869     echo "        llvm:            no"
2870 fi
2871
2872 echo ""
2873 if test -n "$with_gallium_drivers"; then
2874     echo "        Gallium drivers: $gallium_drivers"
2875     echo "        Gallium st:      $gallium_st"
2876 else
2877     echo "        Gallium:         no"
2878 fi
2879
2880 dnl Shader cache
2881 echo ""
2882 echo "        Shader cache:    $enable_shader_cache"
2883 if test "x$enable_shader_cache" = "xyes"; then
2884     echo "        With SHA1 from:  $with_sha1"
2885 fi
2886
2887 dnl Libraries
2888 echo ""
2889 echo "        Shared libs:     $enable_shared"
2890 echo "        Static libs:     $enable_static"
2891 echo "        Shared-glapi:    $enable_shared_glapi"
2892
2893 dnl Compiler options
2894 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2895 cflags=`echo $CFLAGS | \
2896     $SED 's/^ *//;s/  */ /;s/ *$//'`
2897 cxxflags=`echo $CXXFLAGS | \
2898     $SED 's/^ *//;s/  */ /;s/ *$//'`
2899 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2900 echo ""
2901 echo "        CFLAGS:          $cflags"
2902 echo "        CXXFLAGS:        $cxxflags"
2903 echo "        Macros:          $defines"
2904 echo ""
2905 if test "x$MESA_LLVM" = x1; then
2906     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2907     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2908     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2909     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2910     echo ""
2911 fi
2912 echo "        PYTHON2:         $PYTHON2"
2913
2914 echo ""
2915 echo "        Run '${MAKE-make}' to build Mesa"
2916 echo ""