configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.74
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 LIBDRM_ETNAVIV_REQUIRED=2.4.74
  80 DRI2PROTO_REQUIRED=2.6
  81 DRI3PROTO_REQUIRED=1.0
  82 PRESENTPROTO_REQUIRED=1.0
  83 GLPROTO_REQUIRED=1.4.14
  84 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  85 LIBVA_REQUIRED=0.38.0
  86 VDPAU_REQUIRED=1.1
  87 WAYLAND_REQUIRED=1.11
  88 XCB_REQUIRED=1.9.3
  89 XCBDRI2_REQUIRED=1.8
  90 XCBGLX_REQUIRED=1.8.1
  91 XSHMFENCE_REQUIRED=1.1
  92 XVMC_REQUIRED=1.0.6
  93 PYTHON_MAKO_REQUIRED=0.8.0
  94 LIBSENSORS_REQUIRED=4.0.0
  95
  96 dnl LLVM versions
  97 LLVM_REQUIRED_GALLIUM=3.3.0
  98 LLVM_REQUIRED_OPENCL=3.6.0
  99 LLVM_REQUIRED_R600=3.6.0
 100 LLVM_REQUIRED_RADEONSI=3.6.0
 101 LLVM_REQUIRED_RADV=3.9.0
 102 LLVM_REQUIRED_SWR=3.6.0
 103
 104 dnl Check for progs
 105 AC_PROG_CPP
 106 AC_PROG_CC
 107 AC_PROG_CXX
 108 AM_PROG_CC_C_O
 109 AM_PROG_AS
 110 AX_CHECK_GNU_MAKE
 111 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 112 AC_PROG_SED
 113 AC_PROG_MKDIR_P
 114
 115 AC_SYS_LARGEFILE
 116
 117 LT_PREREQ([2.2])
 118 LT_INIT([disable-static])
 119
 120 AC_CHECK_PROG(RM, rm, [rm -f])
 121 AC_CHECK_PROG(XXD, xxd, [xxd])
 122
 123 AX_PROG_BISON([],
 124               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 125                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 126 AX_PROG_FLEX([],
 127              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 128                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 129
 130 AC_CHECK_PROG(INDENT, indent, indent, cat)
 131 if test "x$INDENT" != "xcat"; then
 132     # Only GNU indent is supported
 133     INDENT_VERSION=`indent --version | grep GNU`
 134     if test $? -eq 0; then
 135        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 136     else
 137        INDENT="cat"
 138     fi
 139 fi
 140
 141 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 142
 143 if test -z "$PYTHON2"; then
 144     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 145         AC_MSG_ERROR([Python not found - unable to generate sources])
 146     fi
 147 else
 148     if test "x$acv_mako_found" = xno; then
 149         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 150             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 151         fi
 152     fi
 153 fi
 154
 155 AC_PROG_INSTALL
 156
 157 dnl We need a POSIX shell for parts of the build. Assume we have one
 158 dnl in most cases.
 159 case "$host_os" in
 160 solaris*)
 161     # Solaris /bin/sh is too old/non-POSIX compliant
 162     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 163     SHELL="$POSIX_SHELL"
 164     ;;
 165 esac
 166
 167 dnl clang is mostly GCC-compatible, but its version is much lower,
 168 dnl so we have to check for it.
 169 AC_MSG_CHECKING([if compiling with clang])
 170
 171 AC_COMPILE_IFELSE(
 172 [AC_LANG_PROGRAM([], [[
 173 #ifndef __clang__
 174        not clang
 175 #endif
 176 ]])],
 177 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 178
 179 AC_MSG_RESULT([$acv_mesa_CLANG])
 180
 181 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 182 dnl versions are explictly not supported.
 183 GEN_ASM_OFFSETS=no
 184 USE_GNU99=no
 185 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 186     AC_MSG_CHECKING([whether gcc version is sufficient])
 187     major=0
 188     minor=0
 189
 190     GCC_VERSION=`$CC -dumpversion`
 191     if test $? -eq 0; then
 192         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 193         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 194     fi
 195
 196     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 197         AC_MSG_RESULT([no])
 198         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 199     else
 200         AC_MSG_RESULT([yes])
 201     fi
 202
 203     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 204         USE_GNU99=yes
 205     fi
 206     if test "x$cross_compiling" = xyes; then
 207         GEN_ASM_OFFSETS=yes
 208     fi
 209 fi
 210
 211 dnl We don't support building Mesa with Sun C compiler
 212 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 213 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 214 if test "x$SUNCC" = xyes; then
 215     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 216 fi
 217
 218 dnl Check for compiler builtins
 219 AX_GCC_BUILTIN([__builtin_bswap32])
 220 AX_GCC_BUILTIN([__builtin_bswap64])
 221 AX_GCC_BUILTIN([__builtin_clz])
 222 AX_GCC_BUILTIN([__builtin_clzll])
 223 AX_GCC_BUILTIN([__builtin_ctz])
 224 AX_GCC_BUILTIN([__builtin_expect])
 225 AX_GCC_BUILTIN([__builtin_ffs])
 226 AX_GCC_BUILTIN([__builtin_ffsll])
 227 AX_GCC_BUILTIN([__builtin_popcount])
 228 AX_GCC_BUILTIN([__builtin_popcountll])
 229 AX_GCC_BUILTIN([__builtin_unreachable])
 230
 231 AX_GCC_FUNC_ATTRIBUTE([const])
 232 AX_GCC_FUNC_ATTRIBUTE([flatten])
 233 AX_GCC_FUNC_ATTRIBUTE([format])
 234 AX_GCC_FUNC_ATTRIBUTE([malloc])
 235 AX_GCC_FUNC_ATTRIBUTE([packed])
 236 AX_GCC_FUNC_ATTRIBUTE([pure])
 237 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 238 AX_GCC_FUNC_ATTRIBUTE([unused])
 239 AX_GCC_FUNC_ATTRIBUTE([visibility])
 240 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 241 AX_GCC_FUNC_ATTRIBUTE([weak])
 242
 243 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 244
 245 dnl Make sure the pkg-config macros are defined
 246 m4_ifndef([PKG_PROG_PKG_CONFIG],
 247     [m4_fatal([Could not locate the pkg-config autoconf macros.
 248   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 249   are in a different location, try setting the environment variable
 250   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 251 PKG_PROG_PKG_CONFIG()
 252
 253 dnl LIB_DIR - library basename
 254 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 255 AC_SUBST([LIB_DIR])
 256
 257 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 258 _SAVE_LDFLAGS="$LDFLAGS"
 259 _SAVE_CPPFLAGS="$CPPFLAGS"
 260
 261 dnl Compiler macros
 262 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 263 AC_SUBST([DEFINES])
 264 android=no
 265 case "$host_os" in
 266 *-android)
 267     android=yes
 268     ;;
 269 linux*|*-gnu*|gnu*|cygwin*)
 270     DEFINES="$DEFINES -D_GNU_SOURCE"
 271     ;;
 272 solaris*)
 273     DEFINES="$DEFINES -DSVR4"
 274     ;;
 275 esac
 276
 277 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 278
 279 dnl Add flags for gcc and g++
 280 if test "x$GCC" = xyes; then
 281     CFLAGS="$CFLAGS -Wall"
 282
 283     if test "x$USE_GNU99" = xyes; then
 284         CFLAGS="$CFLAGS -std=gnu99"
 285     else
 286         CFLAGS="$CFLAGS -std=c99"
 287     fi
 288
 289     # Enable -Werror=implicit-function-declaration and
 290     # -Werror=missing-prototypes, if available, or otherwise, just
 291     # -Wmissing-prototypes.  This is particularly useful to avoid
 292     # generating a loadable driver module that has undefined symbols.
 293     save_CFLAGS="$CFLAGS"
 294     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 295     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 296     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 297     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 298                    AC_MSG_RESULT([yes]),
 299                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 300                     AC_MSG_RESULT([no])]);
 301
 302     # Enable -fvisibility=hidden if using a gcc that supports it
 303     save_CFLAGS="$CFLAGS"
 304     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 305     VISIBILITY_CFLAGS="-fvisibility=hidden"
 306     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 307     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 308                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 309
 310     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 311     CFLAGS=$save_CFLAGS
 312
 313     # We don't want floating-point math functions to set errno or trap
 314     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 315
 316     # Flags to help ensure that certain portions of the code -- and only those
 317     # portions -- can be built with MSVC:
 318     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 319     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 320     #   supports most of C99)
 321     # - the rest has no compiler compiler restrictions
 322     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 323     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 324
 325     # Enable -Werror=vla if compiler supports it
 326     save_CFLAGS="$CFLAGS"
 327     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 328     CFLAGS="$CFLAGS -Werror=vla"
 329     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 330                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 331                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 332                     AC_MSG_RESULT([yes])],
 333                     AC_MSG_RESULT([no]));
 334     CFLAGS="$save_CFLAGS"
 335 fi
 336 if test "x$GXX" = xyes; then
 337     CXXFLAGS="$CXXFLAGS -Wall"
 338
 339     # Enable -fvisibility=hidden if using a gcc that supports it
 340     save_CXXFLAGS="$CXXFLAGS"
 341     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 342     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 343     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 344     AC_LANG_PUSH([C++])
 345     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 346                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 347     AC_LANG_POP([C++])
 348
 349     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 350     CXXFLAGS=$save_CXXFLAGS
 351
 352     # We don't want floating-point math functions to set errno or trap
 353     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 354 fi
 355
 356 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 357 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 358
 359 dnl even if the compiler appears to support it, using visibility attributes isn't
 360 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 361 case "$host_os" in
 362 cygwin*)
 363     VISIBILITY_CFLAGS=""
 364     VISIBILITY_CXXFLAGS=""
 365     ;;
 366 esac
 367
 368 AC_SUBST([VISIBILITY_CFLAGS])
 369 AC_SUBST([VISIBILITY_CXXFLAGS])
 370
 371 dnl
 372 dnl Optional flags, check for compiler support
 373 dnl
 374 SSE41_CFLAGS="-msse4.1"
 375 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 376 dnl stack, but on x86-32 such alignment is not guaranteed.
 377 case "$target_cpu" in
 378 i?86)
 379     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 380     ;;
 381 esac
 382 save_CFLAGS="$CFLAGS"
 383 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 384 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 385 #include <smmintrin.h>
 386 int param;
 387 int main () {
 388     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 389     c = _mm_max_epu32(a, b);
 390     return _mm_cvtsi128_si32(c);
 391 }]])], SSE41_SUPPORTED=1)
 392 CFLAGS="$save_CFLAGS"
 393 if test "x$SSE41_SUPPORTED" = x1; then
 394     DEFINES="$DEFINES -DUSE_SSE41"
 395 fi
 396 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 397 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 398
 399 dnl Check for new-style atomic builtins
 400 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 401 int main() {
 402     int n;
 403     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 404 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 405 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 406     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 407 fi
 408 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 409
 410 dnl Check for Endianness
 411 AC_C_BIGENDIAN(
 412    little_endian=no,
 413    little_endian=yes,
 414    little_endian=no,
 415    little_endian=no
 416 )
 417
 418 dnl Check for POWER8 Architecture
 419 PWR8_CFLAGS="-mpower8-vector"
 420 have_pwr8_intrinsics=no
 421 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 422 save_CFLAGS=$CFLAGS
 423 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 424 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 425 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 426 #error "Need GCC >= 4.8 for sane POWER8 support"
 427 #endif
 428 #include <altivec.h>
 429 int main () {
 430     vector unsigned char r;
 431     vector unsigned int v = vec_splat_u32 (1);
 432     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 433     return 0;
 434 }]])], have_pwr8_intrinsics=yes)
 435 CFLAGS=$save_CFLAGS
 436
 437 AC_ARG_ENABLE(pwr8,
 438    [AC_HELP_STRING([--disable-pwr8-inst],
 439                    [disable POWER8-specific instructions])],
 440    [enable_pwr8=$enableval], [enable_pwr8=auto])
 441
 442 if test "x$enable_pwr8" = xno ; then
 443    have_pwr8_intrinsics=disabled
 444 fi
 445
 446 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 447    DEFINES="$DEFINES -D_ARCH_PWR8"
 448    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 449    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 450 else
 451    PWR8_CFLAGS=
 452 fi
 453
 454 AC_MSG_RESULT($have_pwr8_intrinsics)
 455 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 456    AC_MSG_ERROR([POWER8 compiler support not detected])
 457 fi
 458
 459 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 460    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 461 fi
 462
 463 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 464
 465 dnl Can't have static and shared libraries, default to static if user
 466 dnl explicitly requested. If both disabled, set to static since shared
 467 dnl was explicitly requested.
 468 case "x$enable_static$enable_shared" in
 469 xyesyes)
 470     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 471     enable_shared=no
 472     ;;
 473 xnono)
 474     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 475     enable_shared=yes
 476     ;;
 477 esac
 478
 479 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 480
 481 dnl
 482 dnl other compiler options
 483 dnl
 484 AC_ARG_ENABLE([debug],
 485     [AS_HELP_STRING([--enable-debug],
 486         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 487     [enable_debug="$enableval"],
 488     [enable_debug=no]
 489 )
 490
 491 AC_ARG_ENABLE([profile],
 492     [AS_HELP_STRING([--enable-profile],
 493         [enable profiling of code @<:@default=disabled@:>@])],
 494     [enable_profile="$enableval"],
 495     [enable_profile=no]
 496 )
 497
 498 if test "x$enable_profile" = xyes; then
 499     DEFINES="$DEFINES -DPROFILE"
 500     if test "x$GCC" = xyes; then
 501         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 502     fi
 503     if test "x$GXX" = xyes; then
 504         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 505     fi
 506 fi
 507
 508 if test "x$enable_debug" = xyes; then
 509     DEFINES="$DEFINES -DDEBUG"
 510     if test "x$enable_profile" = xyes; then
 511         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 512     fi
 513     if test "x$GCC" = xyes; then
 514         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 515             CFLAGS="$CFLAGS -g"
 516         fi
 517         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 518             CFLAGS="$CFLAGS -O0"
 519         fi
 520     fi
 521     if test "x$GXX" = xyes; then
 522         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 523             CXXFLAGS="$CXXFLAGS -g"
 524         fi
 525         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 526             CXXFLAGS="$CXXFLAGS -O0"
 527         fi
 528     fi
 529 else
 530    DEFINES="$DEFINES -DNDEBUG"
 531 fi
 532
 533 DEFAULT_GL_LIB_NAME=GL
 534
 535 dnl
 536 dnl Check if linker supports -Bsymbolic
 537 dnl
 538 save_LDFLAGS=$LDFLAGS
 539 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 540 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 541 AC_LINK_IFELSE(
 542     [AC_LANG_SOURCE([int main() { return 0;}])],
 543     [AC_MSG_RESULT([yes])
 544         BSYMBOLIC="-Wl,-Bsymbolic";],
 545     [AC_MSG_RESULT([no])
 546         BSYMBOLIC="";])
 547 LDFLAGS=$save_LDFLAGS
 548
 549 AC_SUBST([BSYMBOLIC])
 550
 551 dnl
 552 dnl Check if linker supports garbage collection
 553 dnl
 554 save_LDFLAGS=$LDFLAGS
 555 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 556 AC_MSG_CHECKING([whether ld supports --gc-sections])
 557 AC_LINK_IFELSE(
 558     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 559     [AC_MSG_RESULT([yes])
 560         GC_SECTIONS="-Wl,--gc-sections";],
 561     [AC_MSG_RESULT([no])
 562         GC_SECTIONS="";])
 563 LDFLAGS=$save_LDFLAGS
 564
 565 AC_SUBST([GC_SECTIONS])
 566
 567 dnl
 568 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 569 dnl so when these flags are passed to ld via libtool the checks will fail
 570 dnl
 571 case "$host_os" in
 572 openbsd* | darwin* )
 573     LD_NO_UNDEFINED="" ;;
 574 *)
 575     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 576 esac
 577
 578 AC_SUBST([LD_NO_UNDEFINED])
 579
 580 dnl
 581 dnl Check if linker supports version scripts
 582 dnl
 583 AC_MSG_CHECKING([if the linker supports version-scripts])
 584 save_LDFLAGS=$LDFLAGS
 585 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 586 cat > conftest.map <<EOF
 587 VERSION_1 {
 588      global:
 589          main;
 590
 591      local:
 592          *;
 593 };
 594 EOF
 595 AC_LINK_IFELSE(
 596     [AC_LANG_SOURCE([int main() { return 0;}])],
 597     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 598     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 599 LDFLAGS=$save_LDFLAGS
 600 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 601
 602 dnl
 603 dnl Check if linker supports dynamic list files
 604 dnl
 605 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 606 save_LDFLAGS=$LDFLAGS
 607 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 608 cat > conftest.dyn <<EOF
 609 {
 610         radeon_drm_winsys_create;
 611 };
 612 EOF
 613 AC_LINK_IFELSE(
 614     [AC_LANG_SOURCE([int main() { return 0;}])],
 615     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 616     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 617 LDFLAGS=$save_LDFLAGS
 618 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 619
 620 dnl
 621 dnl compatibility symlinks
 622 dnl
 623 case "$host_os" in
 624 linux* )
 625     HAVE_COMPAT_SYMLINKS=yes ;;
 626 * )
 627     HAVE_COMPAT_SYMLINKS=no ;;
 628 esac
 629
 630 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 631
 632 DEFAULT_GL_LIB_NAME=GL
 633
 634 dnl
 635 dnl Libglvnd configuration
 636 dnl
 637 AC_ARG_ENABLE([libglvnd],
 638     [AS_HELP_STRING([--enable-libglvnd],
 639         [Build for libglvnd @<:@default=disabled@:>@])],
 640     [enable_libglvnd="$enableval"],
 641     [enable_libglvnd=no])
 642 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 643 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 644 if test "x$enable_libglvnd" = xyes ; then
 645     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 646     DEFAULT_GL_LIB_NAME=GLX_mesa
 647 fi
 648
 649 dnl
 650 dnl library names
 651 dnl
 652 dnl Unfortunately we need to do a few things that libtool can't help us with,
 653 dnl so we need some knowledge of shared library filenames:
 654 dnl
 655 dnl LIB_EXT is the extension used when creating symlinks for alternate
 656 dnl filenames for a shared library which will be dynamically loaded
 657 dnl
 658 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 659 dnl the file for a shared library we wish to link with
 660 dnl
 661 case "$host_os" in
 662 darwin* )
 663     LIB_EXT='dylib'
 664     IMP_LIB_EXT=$LIB_EXT
 665     ;;
 666 cygwin* )
 667     LIB_EXT='dll'
 668     IMP_LIB_EXT='dll.a'
 669     ;;
 670 aix* )
 671     LIB_EXT='a'
 672     IMP_LIB_EXT=$LIB_EXT
 673     ;;
 674 * )
 675     LIB_EXT='so'
 676     IMP_LIB_EXT=$LIB_EXT
 677     ;;
 678 esac
 679
 680 AC_SUBST([LIB_EXT])
 681
 682 AC_ARG_WITH([gl-lib-name],
 683   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 684     [specify GL library name @<:@default=GL@:>@])],
 685   [GL_LIB=$withval],
 686   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 687 AC_ARG_WITH([osmesa-lib-name],
 688   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 689     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 690   [OSMESA_LIB=$withval],
 691   [OSMESA_LIB=OSMesa])
 692 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 693 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 694
 695 dnl
 696 dnl Mangled Mesa support
 697 dnl
 698 AC_ARG_ENABLE([mangling],
 699   [AS_HELP_STRING([--enable-mangling],
 700     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 701   [enable_mangling="${enableval}"],
 702   [enable_mangling=no]
 703 )
 704 if test "x${enable_mangling}" = "xyes" ; then
 705   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 706   GL_LIB="Mangled${GL_LIB}"
 707   OSMESA_LIB="Mangled${OSMESA_LIB}"
 708 fi
 709 AC_SUBST([GL_LIB])
 710 AC_SUBST([OSMESA_LIB])
 711
 712 dnl
 713 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 714 dnl
 715 AC_ARG_ENABLE([texture-float],
 716     [AS_HELP_STRING([--enable-texture-float],
 717         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 718     [enable_texture_float="$enableval"],
 719     [enable_texture_float=no]
 720 )
 721 if test "x$enable_texture_float" = xyes; then
 722     AC_MSG_WARN([Floating-point textures enabled.])
 723     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 724     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 725 fi
 726
 727 dnl
 728 dnl Arch/platform-specific settings
 729 dnl
 730 AC_ARG_ENABLE([asm],
 731     [AS_HELP_STRING([--disable-asm],
 732         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 733     [enable_asm="$enableval"],
 734     [enable_asm=yes]
 735 )
 736 asm_arch=""
 737 AC_MSG_CHECKING([whether to enable assembly])
 738 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 739 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 740 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 741     case "$host_cpu" in
 742     i?86 | x86_64 | amd64)
 743         if test "x$host_cpu" != "x$target_cpu"; then
 744             enable_asm=no
 745             AC_MSG_RESULT([no, cross compiling])
 746         fi
 747         ;;
 748     esac
 749 fi
 750 # check for supported arches
 751 if test "x$enable_asm" = xyes; then
 752     case "$host_cpu" in
 753     i?86)
 754         case "$host_os" in
 755         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 756             asm_arch=x86
 757             ;;
 758         esac
 759         ;;
 760     x86_64|amd64)
 761         case "$host_os" in
 762         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 763             asm_arch=x86_64
 764             ;;
 765         esac
 766         ;;
 767     sparc*)
 768         case "$host_os" in
 769         linux*)
 770             asm_arch=sparc
 771             ;;
 772         esac
 773         ;;
 774     esac
 775
 776     case "$asm_arch" in
 777     x86)
 778         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 779         AC_MSG_RESULT([yes, x86])
 780         ;;
 781     x86_64|amd64)
 782         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 783         AC_MSG_RESULT([yes, x86_64])
 784         ;;
 785     sparc)
 786         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 787         AC_MSG_RESULT([yes, sparc])
 788         ;;
 789     *)
 790         AC_MSG_RESULT([no, platform not supported])
 791         ;;
 792     esac
 793 fi
 794
 795 AC_HEADER_MAJOR
 796 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 797 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 798 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 799 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 800
 801 dnl Check to see if dlopen is in default libraries (like Solaris, which
 802 dnl has it in libc), or if libdl is needed to get it.
 803 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 804     [AC_CHECK_LIB([dl], [dlopen],
 805        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 806 AC_SUBST([DLOPEN_LIBS])
 807
 808 dnl Check if that library also has dladdr
 809 save_LIBS="$LIBS"
 810 LIBS="$LIBS $DLOPEN_LIBS"
 811 AC_CHECK_FUNCS([dladdr])
 812 LIBS="$save_LIBS"
 813
 814 case "$host_os" in
 815 darwin*)
 816     ;;
 817 *)
 818     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 819                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 820                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 821     AC_SUBST([CLOCK_LIB])
 822     ;;
 823 esac
 824
 825 dnl See if posix_memalign is available
 826 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 827
 828 dnl Check for pthreads
 829 AX_PTHREAD
 830 if test "x$ax_pthread_ok" = xno; then
 831     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 832 fi
 833 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 834 dnl to -pthread, which causes problems if we need -lpthread to appear in
 835 dnl pkgconfig files.  Since Android doesn't have a pthread lib, this check
 836 dnl is not valid for that platform.
 837 if test "x$android" = xno; then
 838     test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 839 fi
 840
 841 dnl pthread-stubs is mandatory on targets where it exists
 842 case "$host_os" in
 843 cygwin* )
 844     pthread_stubs_possible="no"
 845     ;;
 846 * )
 847     pthread_stubs_possible="yes"
 848     ;;
 849 esac
 850
 851 if test "x$pthread_stubs_possible" = xyes; then
 852     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 853     AC_SUBST(PTHREADSTUBS_CFLAGS)
 854     AC_SUBST(PTHREADSTUBS_LIBS)
 855 fi
 856
 857 dnl SELinux awareness.
 858 AC_ARG_ENABLE([selinux],
 859     [AS_HELP_STRING([--enable-selinux],
 860         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 861     [MESA_SELINUX="$enableval"],
 862     [MESA_SELINUX=no])
 863 if test "x$enable_selinux" = "xyes"; then
 864     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 865         [AC_CHECK_HEADER([selinux/selinux.h],[],
 866                          [AC_MSG_ERROR([SELinux headers not found])])
 867          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 868                       [AC_MSG_ERROR([SELinux library not found])])
 869          SELINUX_LIBS="-lselinux"])
 870     DEFINES="$DEFINES -DMESA_SELINUX"
 871 fi
 872 AC_SUBST([SELINUX_CFLAGS])
 873 AC_SUBST([SELINUX_LIBS])
 874
 875 dnl
 876 dnl LLVM
 877 dnl
 878 AC_ARG_ENABLE([llvm-shared-libs],
 879     [AS_HELP_STRING([--enable-llvm-shared-libs],
 880         [link with LLVM shared libraries @<:@default=enabled@:>@])],
 881     [enable_llvm_shared_libs="$enableval"],
 882     [enable_llvm_shared_libs=yes])
 883
 884 AC_ARG_WITH([llvm-prefix],
 885     [AS_HELP_STRING([--with-llvm-prefix],
 886         [Prefix for LLVM installations in non-standard locations])],
 887     [llvm_prefix="$withval"],
 888     [llvm_prefix=''])
 889
 890 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
 891 if test "x$have_libelf" = xno; then
 892    LIBELF_LIBS=''
 893    LIBELF_CFLAGS=''
 894    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
 895    AC_SUBST([LIBELF_LIBS])
 896    AC_SUBST([LIBELF_CFLAGS])
 897 fi
 898
 899 if test -z "$LLVM_CONFIG"; then
 900     if test -n "$llvm_prefix"; then
 901         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
 902     else
 903         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
 904     fi
 905 fi
 906
 907 llvm_add_component() {
 908     new_llvm_component=$1
 909     driver_name=$2
 910
 911     if $LLVM_CONFIG --components | grep -iqw $new_llvm_component ; then
 912         LLVM_COMPONENTS="${LLVM_COMPONENTS} ${new_llvm_component}"
 913     else
 914         AC_MSG_ERROR([LLVM component '$new_llvm_component' not enabled in your LLVM build. Required by $driver_name.])
 915     fi
 916 }
 917
 918 llvm_add_default_components() {
 919     driver_name=$1
 920
 921     # Required default components
 922     llvm_add_component "bitwriter" $driver_name
 923     llvm_add_component "engine" $driver_name
 924     llvm_add_component "mcdisassembler" $driver_name
 925     llvm_add_component "mcjit" $driver_name
 926
 927     # Optional default components
 928     if $LLVM_CONFIG --components | grep -iqw inteljitevents ; then
 929         LLVM_COMPONENTS="$LLVM_COMPONENTS inteljitevents"
 930     fi
 931 }
 932
 933 llvm_add_target() {
 934     new_llvm_target=$1
 935     driver_name=$2
 936
 937     if $LLVM_CONFIG --targets-built | grep -iqw $new_llvm_target ; then
 938         llvm_add_component $new_llvm_target $driver_name
 939     else
 940         AC_MSG_ERROR([LLVM target '$new_llvm_target' not enabled in your LLVM build. Required by $driver_name.])
 941     fi
 942 }
 943
 944 # Call this inside ` ` to get the return value.
 945 # $1 is the llvm-config command with arguments.
 946 strip_unwanted_llvm_flags() {
 947     # Use \> (marks the end of the word)
 948     echo `$1` | sed \
 949         -e 's/-march=\S*//g' \
 950         -e 's/-mtune=\S*//g' \
 951         -e 's/-mcpu=\S*//g' \
 952         -e 's/-DNDEBUG\>//g' \
 953         -e 's/-D_GNU_SOURCE\>//g' \
 954         -e 's/-pedantic\>//g' \
 955         -e 's/-Wcovered-switch-default\>//g' \
 956         -e 's/-O.\>//g' \
 957         -e 's/-g\>//g' \
 958         -e 's/-Wall\>//g' \
 959         -e 's/-Wcast-qual\>//g' \
 960         -e 's/-Woverloaded-virtual\>//g' \
 961         -e 's/-fcolor-diagnostics\>//g' \
 962         -e 's/-fdata-sections\>//g' \
 963         -e 's/-ffunction-sections\>//g' \
 964         -e 's/-fno-exceptions\>//g' \
 965         -e 's/-fomit-frame-pointer\>//g' \
 966         -e 's/-fvisibility-inlines-hidden\>//g' \
 967         -e 's/-fPIC\>//g' \
 968         -e 's/-fstack-protector-strong\>//g'
 969 }
 970
 971 llvm_set_environment_variables() {
 972     if test "x$LLVM_CONFIG" != xno; then
 973         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
 974         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
 975         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
 976         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
 977         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
 978         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
 979         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
 980         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
 981
 982         # We need to respect LLVM_CFLAGS when compiling LLVM headers.
 983         save_CFLAGS="$CFLAGS"
 984         CFLAGS="$CFLAGS $LLVM_CFLAGS"
 985
 986         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
 987             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 988         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
 989             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 990         AC_COMPUTE_INT([LLVM_VERSION_PATCH], [LLVM_VERSION_PATCH],
 991             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
 992
 993         CFLAGS="$save_CFLAGS"
 994
 995         # Only needed for LLVM < 3.6.0
 996         if test -z "$LLVM_VERSION_PATCH"; then
 997             LLVM_VERSION_PATCH=0
 998         fi
 999
1000         if test "$LLVM_VERSION_MINOR" -lt 10; then
1001             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1002         else
1003             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}${LLVM_VERSION_MINOR}"
1004         fi
1005
1006         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1007         MESA_LLVM=1
1008     else
1009         MESA_LLVM=0
1010         LLVM_VERSION_INT=0
1011     fi
1012 }
1013
1014 llvm_check_version_for() {
1015     if test "x$MESA_LLVM" = x0; then
1016         AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1017         return
1018     fi
1019
1020     llvm_target_version_major=`echo $1 | cut -d. -f1 | egrep -o '^[[0-9]]+'`
1021     llvm_target_version_minor=`echo $1 | cut -d. -f2 | egrep -o '^[[0-9]]+'`
1022     llvm_target_version_patch=`echo $1 | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1023
1024     if test "$LLVM_VERSION_MAJOR" -gt "$llvm_target_version_major"; then
1025         # major > required major
1026         #  --> OK
1027         return
1028     fi
1029
1030     if test "$LLVM_VERSION_MAJOR" -eq "$llvm_target_version_major"; then
1031         if test "$LLVM_VERSION_MINOR" -gt "$llvm_target_version_minor"; then
1032             # major = required major and
1033             # minor > required minor
1034             #  --> OK
1035             return
1036         else
1037             if test "$LLVM_VERSION_MINOR" -eq "$llvm_target_version_minor"; then
1038                 if test "$LLVM_VERSION_PATCH" -ge "$llvm_target_version_patch"; then
1039                     # major = required major and
1040                     # minor = required minor and
1041                     # patch >= required patch
1042                     #  --> OK
1043                     return
1044                 fi
1045             fi
1046         fi
1047     fi
1048
1049     AC_MSG_ERROR([LLVM $1 or newer is required for $2])
1050 }
1051
1052 radeon_llvm_check() {
1053     if test ${LLVM_VERSION_INT} -lt 307; then
1054         amdgpu_llvm_target_name='r600'
1055     else
1056         amdgpu_llvm_target_name='amdgpu'
1057     fi
1058
1059     llvm_check_version_for $*
1060
1061     llvm_add_target $amdgpu_llvm_target_name $2
1062
1063     llvm_add_default_components $2
1064     llvm_add_component "bitreader" $2
1065     llvm_add_component "ipo" $2
1066
1067     NEED_RADEON_LLVM=yes
1068     if test "x$have_libelf" != xyes; then
1069        AC_MSG_ERROR([$1 requires libelf when using llvm])
1070     fi
1071 }
1072
1073 llvm_set_environment_variables
1074
1075 AC_SUBST([MESA_LLVM])
1076 AC_SUBST([LLVM_BINDIR])
1077 AC_SUBST([LLVM_CFLAGS])
1078 AC_SUBST([LLVM_CPPFLAGS])
1079 AC_SUBST([LLVM_CXXFLAGS])
1080 AC_SUBST([LLVM_LIBDIR])
1081 AC_SUBST([LLVM_LIBS])
1082 AC_SUBST([LLVM_LDFLAGS])
1083 AC_SUBST([LLVM_INCLUDEDIR])
1084 AC_SUBST([LLVM_VERSION])
1085
1086 dnl Options for APIs
1087 AC_ARG_ENABLE([opengl],
1088     [AS_HELP_STRING([--disable-opengl],
1089         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
1090     [enable_opengl="$enableval"],
1091     [enable_opengl=yes])
1092 AC_ARG_ENABLE([gles1],
1093     [AS_HELP_STRING([--disable-gles1],
1094         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
1095     [enable_gles1="$enableval"],
1096     [enable_gles1=yes])
1097 AC_ARG_ENABLE([gles2],
1098     [AS_HELP_STRING([--disable-gles2],
1099         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
1100     [enable_gles2="$enableval"],
1101     [enable_gles2=yes])
1102
1103 AC_ARG_ENABLE([dri],
1104     [AS_HELP_STRING([--enable-dri],
1105         [enable DRI modules @<:@default=enabled@:>@])],
1106     [enable_dri="$enableval"],
1107     [enable_dri=yes])
1108
1109 AC_ARG_ENABLE([gallium-extra-hud],
1110     [AS_HELP_STRING([--enable-gallium-extra-hud],
1111         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
1112     [enable_gallium_extra_hud="$enableval"],
1113     [enable_gallium_extra_hud=no])
1114 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
1115 if test "x$enable_gallium_extra_hud" = xyes ; then
1116     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
1117 fi
1118
1119 #TODO: no pkgconfig .pc available for libsensors.
1120 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
1121 AC_ARG_ENABLE([lmsensors],
1122     [AS_HELP_STRING([--enable-lmsensors],
1123         [enable HUD lmsensor support @<:@default=disabled@:>@])],
1124     [enable_lmsensors="$enableval"],
1125     [enable_lmsensors=no])
1126 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
1127 if test "x$enable_lmsensors" = xyes ; then
1128     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
1129     LIBSENSORS_LDFLAGS="-lsensors"
1130 else
1131     LIBSENSORS_LDFLAGS=""
1132 fi
1133 AC_SUBST(LIBSENSORS_LDFLAGS)
1134
1135 case "$host_os" in
1136 linux*)
1137     dri3_default=yes
1138     ;;
1139 *)
1140     dri3_default=no
1141     ;;
1142 esac
1143
1144 if test "x$enable_dri" = xno; then
1145     dri3_default=no
1146 fi
1147
1148 AC_ARG_ENABLE([dri3],
1149     [AS_HELP_STRING([--enable-dri3],
1150         [enable DRI3 @<:@default=auto@:>@])],
1151     [enable_dri3="$enableval"],
1152     [enable_dri3="$dri3_default"])
1153 AC_ARG_ENABLE([glx],
1154     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
1155         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
1156     [enable_glx="$enableval"],
1157     [enable_glx=yes])
1158 AC_ARG_ENABLE([osmesa],
1159     [AS_HELP_STRING([--enable-osmesa],
1160         [enable OSMesa library @<:@default=disabled@:>@])],
1161     [enable_osmesa="$enableval"],
1162     [enable_osmesa=no])
1163 AC_ARG_ENABLE([gallium-osmesa],
1164     [AS_HELP_STRING([--enable-gallium-osmesa],
1165         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
1166     [enable_gallium_osmesa="$enableval"],
1167     [enable_gallium_osmesa=no])
1168 AC_ARG_ENABLE([egl],
1169     [AS_HELP_STRING([--disable-egl],
1170         [disable EGL library @<:@default=enabled@:>@])],
1171     [enable_egl="$enableval"],
1172     [enable_egl=yes])
1173
1174 AC_ARG_ENABLE([xa],
1175     [AS_HELP_STRING([--enable-xa],
1176         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
1177     [enable_xa="$enableval"],
1178     [enable_xa=no])
1179 AC_ARG_ENABLE([gbm],
1180    [AS_HELP_STRING([--enable-gbm],
1181          [enable gbm library @<:@default=yes except cygwin@:>@])],
1182    [enable_gbm="$enableval"],
1183    [case "$host_os" in
1184        cygwin*)
1185           enable_gbm=no
1186           ;;
1187        *)
1188           enable_gbm=yes
1189           ;;
1190     esac])
1191 AC_ARG_ENABLE([nine],
1192     [AS_HELP_STRING([--enable-nine],
1193         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
1194     [enable_nine="$enableval"],
1195     [enable_nine=no])
1196
1197 AC_ARG_ENABLE([xvmc],
1198    [AS_HELP_STRING([--enable-xvmc],
1199          [enable xvmc library @<:@default=auto@:>@])],
1200    [enable_xvmc="$enableval"],
1201    [enable_xvmc=auto])
1202 AC_ARG_ENABLE([vdpau],
1203    [AS_HELP_STRING([--enable-vdpau],
1204          [enable vdpau library @<:@default=auto@:>@])],
1205    [enable_vdpau="$enableval"],
1206    [enable_vdpau=auto])
1207 AC_ARG_ENABLE([omx],
1208    [AS_HELP_STRING([--enable-omx],
1209          [enable OpenMAX library @<:@default=disabled@:>@])],
1210    [enable_omx="$enableval"],
1211    [enable_omx=no])
1212 AC_ARG_ENABLE([va],
1213    [AS_HELP_STRING([--enable-va],
1214          [enable va library @<:@default=auto@:>@])],
1215    [enable_va="$enableval"],
1216    [enable_va=auto])
1217 AC_ARG_ENABLE([opencl],
1218    [AS_HELP_STRING([--enable-opencl],
1219          [enable OpenCL library @<:@default=disabled@:>@])],
1220    [enable_opencl="$enableval"],
1221    [enable_opencl=no])
1222 AC_ARG_ENABLE([opencl_icd],
1223    [AS_HELP_STRING([--enable-opencl-icd],
1224           [Build an OpenCL ICD library to be loaded by an ICD implementation
1225            @<:@default=disabled@:>@])],
1226     [enable_opencl_icd="$enableval"],
1227     [enable_opencl_icd=no])
1228
1229 AC_ARG_ENABLE([gallium-tests],
1230     [AS_HELP_STRING([--enable-gallium-tests],
1231         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1232     [enable_gallium_tests="$enableval"],
1233     [enable_gallium_tests=no])
1234
1235 # Option for Gallium drivers
1236
1237 # Keep this in sync with the --with-gallium-drivers help string default value
1238 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1239
1240 AC_ARG_WITH([gallium-drivers],
1241     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1242         [comma delimited Gallium drivers list, e.g.
1243         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl,etnaviv,imx"
1244         @<:@default=r300,r600,svga,swrast@:>@])],
1245     [with_gallium_drivers="$withval"],
1246     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1247
1248 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1249 # here so that the script doesn't choke on an unknown driver name later.
1250 case "$with_gallium_drivers" in
1251     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1252     no) with_gallium_drivers='' ;;
1253 esac
1254
1255 if test "x$enable_opengl" = xno -a \
1256         "x$enable_gles1" = xno -a \
1257         "x$enable_gles2" = xno -a \
1258         "x$enable_nine" = xno -a \
1259         "x$enable_xa" = xno -a \
1260         "x$enable_xvmc" = xno -a \
1261         "x$enable_vdpau" = xno -a \
1262         "x$enable_omx" = xno -a \
1263         "x$enable_va" = xno -a \
1264         "x$enable_opencl" = xno; then
1265     AC_MSG_ERROR([at least one API should be enabled])
1266 fi
1267
1268 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1269 if test "x$enable_opengl" = xno -a \
1270         "x$enable_gles1" = xyes; then
1271     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1272 fi
1273
1274 if test "x$enable_opengl" = xno -a \
1275         "x$enable_gles2" = xyes; then
1276     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1277 fi
1278
1279 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1280 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1281 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1282 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1283                                         "x$enable_gles1" = xyes -o \
1284                                         "x$enable_gles2" = xyes)
1285
1286 # Validate GLX options
1287 if test "x$enable_glx" = xyes; then
1288     if test "x$enable_dri" = xyes; then
1289         enable_glx=dri
1290     elif test -n "$with_gallium_drivers"; then
1291         enable_glx=gallium-xlib
1292     else
1293         enable_glx=xlib
1294     fi
1295 fi
1296 case "x$enable_glx" in
1297 xdri | xxlib | xgallium-xlib)
1298     # GLX requires OpenGL
1299     if test "x$enable_opengl" = xno; then
1300         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1301     fi
1302
1303     # Check individual dependencies
1304     case "x$enable_glx" in
1305     xdri)
1306         if test "x$enable_dri" = xno; then
1307             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1308         fi
1309         ;;
1310     xxlib)
1311         if test "x$enable_dri" = xyes; then
1312             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1313         fi
1314         ;;
1315     xgallium-xlib )
1316         if test "x$enable_dri" = xyes; then
1317             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1318         fi
1319         if test -z "$with_gallium_drivers"; then
1320             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1321         fi
1322         ;;
1323     esac
1324     ;;
1325 xno)
1326     ;;
1327 *)
1328     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1329     ;;
1330 esac
1331
1332 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1333 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1334 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1335 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1336
1337 dnl
1338 dnl Libglvnd configuration
1339 dnl
1340 AC_ARG_ENABLE([libglvnd],
1341     [AS_HELP_STRING([--enable-libglvnd],
1342         [Build for libglvnd @<:@default=disabled@:>@])],
1343     [enable_libglvnd="$enableval"],
1344     [enable_libglvnd=no])
1345 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1346 if test "x$enable_libglvnd" = xyes ; then
1347     dnl XXX: update once we can handle more than libGL/glx.
1348     dnl Namely: we should error out if neither of the glvnd enabled libraries
1349     dnl are built
1350     case "x$enable_glx" in
1351     xno)
1352         AC_MSG_ERROR([cannot build libglvnd without GLX])
1353         ;;
1354     xxlib | xgallium-xlib )
1355         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1356         ;;
1357     xdri)
1358         ;;
1359     esac
1360
1361     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1362     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1363     DEFAULT_GL_LIB_NAME=GLX_mesa
1364 fi
1365
1366 # Check for libdrm
1367 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1368                   [have_libdrm=yes], [have_libdrm=no])
1369 if test "x$have_libdrm" = xyes; then
1370         DEFINES="$DEFINES -DHAVE_LIBDRM"
1371 fi
1372
1373 require_libdrm() {
1374     if test "x$have_libdrm" != xyes; then
1375        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1376     fi
1377 }
1378
1379
1380 # Select which platform-dependent DRI code gets built
1381 case "$host_os" in
1382 darwin*)
1383     dri_platform='apple' ;;
1384 cygwin*)
1385     dri_platform='windows' ;;
1386 gnu*)
1387     dri_platform='none' ;;
1388 *)
1389     dri_platform='drm' ;;
1390 esac
1391
1392 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1393     have_drisw_kms='yes'
1394 fi
1395
1396 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1397 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1398 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1399 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1400 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1401 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1402 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1403 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1404 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1405
1406 AC_ARG_ENABLE([shared-glapi],
1407     [AS_HELP_STRING([--enable-shared-glapi],
1408         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1409     [enable_shared_glapi="$enableval"],
1410     [enable_shared_glapi=yes])
1411
1412 case "x$enable_opengl$enable_gles1$enable_gles2" in
1413 x*yes*yes*)
1414     if test "x$enable_shared_glapi" = xno; then
1415         AC_MSG_ERROR([shared GLAPI required when building two or more of
1416                       the following APIs - opengl, gles1 gles2])
1417     fi
1418     ;;
1419 esac
1420
1421 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1422
1423 # Build the pipe-drivers as separate libraries/modules.
1424 # Do not touch this unless you know what you are doing.
1425 # XXX: Expose via configure option ?
1426 enable_shared_pipe_drivers=no
1427
1428 dnl
1429 dnl Driver specific build directories
1430 dnl
1431
1432 if test "x$enable_gallium_osmesa" = xyes; then
1433     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1434         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1435     fi
1436     if test "x$enable_osmesa" = xyes; then
1437         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1438     fi
1439 fi
1440
1441 # SHA1 hashing
1442 AC_ARG_WITH([sha1],
1443         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1444         [choose SHA1 implementation])])
1445 case "x$with_sha1" in
1446 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1447   ;;
1448 *)
1449         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1450 esac
1451
1452 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1453 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1454         with_sha1=libc
1455 fi
1456 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1457         AC_MSG_ERROR([sha1 in libc requested but not found])
1458 fi
1459 if test "x$with_sha1" = xlibc; then
1460         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1461                 [Use libc SHA1 functions])
1462         SHA1_LIBS=""
1463 fi
1464 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1465 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1466         with_sha1=CommonCrypto
1467 fi
1468 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1469         AC_MSG_ERROR([CommonCrypto requested but not found])
1470 fi
1471 if test "x$with_sha1" = xCommonCrypto; then
1472         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1473                 [Use CommonCrypto SHA1 functions])
1474         SHA1_LIBS=""
1475 fi
1476 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1477 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1478 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1479         with_sha1=CryptoAPI
1480 fi
1481 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1482         AC_MSG_ERROR([CryptoAPI requested but not found])
1483 fi
1484 if test "x$with_sha1" = xCryptoAPI; then
1485         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1486                 [Use CryptoAPI SHA1 functions])
1487         SHA1_LIBS=""
1488 fi
1489 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1490 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1491         with_sha1=libmd
1492 fi
1493 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1494         AC_MSG_ERROR([libmd requested but not found])
1495 fi
1496 if test "x$with_sha1" = xlibmd; then
1497         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1498                   [Use libmd SHA1 functions])
1499         SHA1_LIBS=-lmd
1500 fi
1501 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1502 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1503    with_sha1=libsha1
1504 fi
1505 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1506         AC_MSG_ERROR([libsha1 requested but not found])
1507 fi
1508 if test "x$with_sha1" = xlibsha1; then
1509         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1510                   [Use libsha1 for SHA1])
1511         SHA1_LIBS=-lsha1
1512 fi
1513 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1514 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1515         with_sha1=libnettle
1516 fi
1517 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1518         AC_MSG_ERROR([libnettle requested but not found])
1519 fi
1520 if test "x$with_sha1" = xlibnettle; then
1521         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1522                   [Use libnettle SHA1 functions])
1523         SHA1_LIBS=-lnettle
1524 fi
1525 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1526 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1527         with_sha1=libgcrypt
1528 fi
1529 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1530         AC_MSG_ERROR([libgcrypt requested but not found])
1531 fi
1532 if test "x$with_sha1" = xlibgcrypt; then
1533         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1534                   [Use libgcrypt SHA1 functions])
1535         SHA1_LIBS=-lgcrypt
1536 fi
1537 # We don't need all of the OpenSSL libraries, just libcrypto
1538 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1539 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1540                   [HAVE_OPENSSL_PKC=no])
1541 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1542         if test "x$with_sha1" = x; then
1543                 with_sha1=libcrypto
1544         fi
1545 else
1546         if test "x$with_sha1" = xlibcrypto; then
1547                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1548         fi
1549 fi
1550 if test "x$with_sha1" = xlibcrypto; then
1551         if test "x$HAVE_LIBCRYPTO" = xyes; then
1552                 SHA1_LIBS=-lcrypto
1553         else
1554                 SHA1_LIBS="$OPENSSL_LIBS"
1555                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1556         fi
1557 fi
1558 AC_MSG_CHECKING([for SHA1 implementation])
1559 AC_MSG_RESULT([$with_sha1])
1560 AC_SUBST(SHA1_LIBS)
1561 AC_SUBST(SHA1_CFLAGS)
1562
1563 # Enable a define for SHA1
1564 if test "x$with_sha1" != "x"; then
1565         DEFINES="$DEFINES -DHAVE_SHA1"
1566 fi
1567
1568 # Allow user to configure out the shader-cache feature
1569 AC_ARG_ENABLE([shader-cache],
1570     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1571     [enable_shader_cache="$enableval"],
1572     [if test "x$with_sha1" != "x"; then
1573         enable_shader_cache=yes
1574      else
1575         enable_shader_cache=no
1576      fi])
1577 if test "x$with_sha1" = "x"; then
1578     if test "x$enable_shader_cache" = "xyes"; then
1579         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1580     fi
1581 fi
1582 if test "x$enable_shader_cache" = "xyes"; then
1583    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1584 fi
1585
1586 if test "x$enable_dri" = xyes; then
1587     if test "$enable_static" = yes; then
1588         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1589     fi
1590
1591     # not a hard requirement as swrast does not depend on it
1592     if test "x$have_libdrm" = xyes; then
1593         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1594     fi
1595 fi
1596
1597 AC_ARG_ENABLE([driglx-direct],
1598     [AS_HELP_STRING([--disable-driglx-direct],
1599         [disable direct rendering in GLX and EGL for DRI \
1600             @<:@default=auto@:>@])],
1601     [driglx_direct="$enableval"],
1602     [driglx_direct="yes"])
1603
1604 dnl
1605 dnl libGL configuration per driver
1606 dnl
1607 if test "x$enable_glx" != xno; then
1608     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1609 fi
1610 case "x$enable_glx" in
1611 xxlib | xgallium-xlib)
1612     # Xlib-based GLX
1613     dri_modules="x11 xext xcb"
1614     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1615     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1616     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1617     GL_LIB_DEPS="$XLIBGL_LIBS"
1618     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1619     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1620     ;;
1621 xdri)
1622     # DRI-based GLX
1623
1624     # find the DRI deps for libGL
1625     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1626
1627     if test x"$driglx_direct" = xyes; then
1628         if test x"$dri_platform" = xdrm ; then
1629             DEFINES="$DEFINES -DGLX_USE_DRM"
1630             require_libdrm "Direct rendering"
1631
1632             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1633             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1634             if test x"$enable_dri3" = xyes; then
1635                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1636                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1637             fi
1638
1639             if test x"$enable_dri" = xyes; then
1640                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1641             fi
1642
1643             if test x"$enable_dri3" = xyes; then
1644                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1645                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1646                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1647             fi
1648         fi
1649         if test x"$dri_platform" = xapple ; then
1650             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1651         fi
1652         if test x"$dri_platform" = xwindows ; then
1653             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1654         fi
1655     fi
1656
1657     # add xf86vidmode if available
1658     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1659     if test "$HAVE_XF86VIDMODE" = yes ; then
1660         dri_modules="$dri_modules xxf86vm"
1661     fi
1662
1663     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1664     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1665     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1666     GL_LIB_DEPS="$DRIGL_LIBS"
1667
1668     # need DRM libs, $PTHREAD_LIBS, etc.
1669     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1670     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1671     ;;
1672 esac
1673
1674 # This is outside the case (above) so that it is invoked even for non-GLX
1675 # builds.
1676 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1677
1678 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1679 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1680 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1681 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1682
1683 AC_SUBST([X11_INCLUDES])
1684 AC_SUBST([GL_LIB_DEPS])
1685 AC_SUBST([GL_PC_REQ_PRIV])
1686 AC_SUBST([GL_PC_LIB_PRIV])
1687 AC_SUBST([GL_PC_CFLAGS])
1688 AC_SUBST([DRI_PC_REQ_PRIV])
1689 AC_SUBST([GLESv1_CM_LIB_DEPS])
1690 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1691 AC_SUBST([GLESv2_LIB_DEPS])
1692 AC_SUBST([GLESv2_PC_LIB_PRIV])
1693
1694 AC_SUBST([HAVE_XF86VIDMODE])
1695
1696 dnl
1697 dnl More GLX setup
1698 dnl
1699 case "x$enable_glx" in
1700 xxlib | xgallium-xlib)
1701     DEFINES="$DEFINES -DUSE_XSHM"
1702     ;;
1703 xdri)
1704     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1705     if test "x$driglx_direct" = xyes; then
1706         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1707     fi
1708     ;;
1709 esac
1710
1711 dnl
1712 dnl TLS detection
1713 dnl
1714
1715 AC_ARG_ENABLE([glx-tls],
1716     [AS_HELP_STRING([--enable-glx-tls],
1717         [enable TLS support in GLX @<:@default=enabled@:>@])],
1718     [GLX_USE_TLS="$enableval"],
1719     [GLX_USE_TLS=yes])
1720 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1721
1722 if test "x$GLX_USE_TLS" = xyes; then
1723     DEFINES="$DEFINES -DGLX_USE_TLS"
1724 fi
1725
1726 dnl Read-only text section on x86 hardened platforms
1727 AC_ARG_ENABLE([glx-read-only-text],
1728     [AS_HELP_STRING([--enable-glx-read-only-text],
1729         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1730     [enable_glx_read_only_text="$enableval"],
1731     [enable_glx_read_only_text=no])
1732 if test "x$enable_glx_read_only_text" = xyes; then
1733     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1734 fi
1735
1736 dnl
1737 dnl More DRI setup
1738 dnl
1739 dnl Directory for DRI drivers
1740 AC_ARG_WITH([dri-driverdir],
1741     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1742         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1743     [DRI_DRIVER_INSTALL_DIR="$withval"],
1744     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1745 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1746 dnl Extra search path for DRI drivers
1747 AC_ARG_WITH([dri-searchpath],
1748     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1749         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1750     [DRI_DRIVER_SEARCH_DIR="$withval"],
1751     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1752 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1753 dnl Which drivers to build - default is chosen by platform
1754 AC_ARG_WITH([dri-drivers],
1755     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1756         [comma delimited classic DRI drivers list, e.g.
1757         "swrast,i965,radeon" @<:@default=auto@:>@])],
1758     [with_dri_drivers="$withval"],
1759     [with_dri_drivers=auto])
1760
1761 if test "x$with_dri_drivers" = xauto; then
1762     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1763         with_dri_drivers="yes"
1764     else
1765         with_dri_drivers="no"
1766     fi
1767 fi
1768 if test "x$with_dri_drivers" = xno; then
1769     with_dri_drivers=''
1770 fi
1771
1772 dnl If $with_dri_drivers is yes, drivers will be added through
1773 dnl platform checks. Set DEFINES and LIB_DEPS
1774 if test "x$enable_dri" = xyes; then
1775     # Platform specific settings and drivers to build
1776     case "$host_os" in
1777     linux*)
1778         DEFINES="$DEFINES -DHAVE_ALIAS"
1779         if test "x$enable_dri3" = xyes; then
1780             DEFINES="$DEFINES -DHAVE_DRI3"
1781         fi
1782
1783         case "$host_cpu" in
1784         powerpc* | sparc*)
1785             # Build only the drivers for cards that exist on PowerPC/sparc
1786             if test "x$with_dri_drivers" = "xyes"; then
1787                 with_dri_drivers="r200 radeon swrast"
1788             fi
1789             ;;
1790         esac
1791         ;;
1792     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1793         DEFINES="$DEFINES -DHAVE_ALIAS"
1794         ;;
1795     gnu*)
1796         DEFINES="$DEFINES -DHAVE_ALIAS"
1797         ;;
1798     cygwin*)
1799         if test "x$with_dri_drivers" = "xyes"; then
1800             with_dri_drivers="swrast"
1801         fi
1802         ;;
1803     darwin*)
1804         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1805         if test "x$with_dri_drivers" = "xyes"; then
1806             with_dri_drivers="swrast"
1807         fi
1808         ;;
1809     esac
1810
1811     # default drivers
1812     if test "x$with_dri_drivers" = "xyes"; then
1813         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1814     fi
1815
1816     # Check for expat
1817     PKG_CHECK_MODULES([EXPAT], [expat], [],
1818         # expat version 2.0 and earlier do not provide expat.pc
1819         [AC_CHECK_HEADER([expat.h],[],
1820                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1821          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1822                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1823          EXPAT_LIBS="-lexpat"])
1824
1825     # put all the necessary libs together
1826     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1827 fi
1828
1829 AC_SUBST([DRI_LIB_DEPS])
1830
1831 DRI_DIRS=''
1832 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1833 if test -n "$with_dri_drivers"; then
1834     if test "x$enable_opengl" != xyes; then
1835         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1836     fi
1837
1838     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1839     for driver in $dri_drivers; do
1840         DRI_DIRS="$DRI_DIRS $driver"
1841         case "x$driver" in
1842         xi915)
1843             HAVE_I915_DRI=yes;
1844             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1845             ;;
1846         xi965)
1847             HAVE_I965_DRI=yes;
1848             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1849             ;;
1850         xnouveau)
1851             HAVE_NOUVEAU_DRI=yes;
1852             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1853             ;;
1854         xradeon)
1855             HAVE_RADEON_DRI=yes;
1856             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1857             ;;
1858         xr200)
1859             HAVE_R200_DRI=yes;
1860             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1861             ;;
1862         xswrast)
1863             HAVE_SWRAST_DRI=yes;
1864             ;;
1865         *)
1866             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1867             ;;
1868         esac
1869     done
1870     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1871 fi
1872
1873
1874 #
1875 # Vulkan driver configuration
1876 #
1877
1878 AC_ARG_WITH([vulkan-drivers],
1879     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1880         [comma delimited Vulkan drivers list, e.g.
1881         "intel"
1882         @<:@default=no@:>@])],
1883     [with_vulkan_drivers="$withval"],
1884     [with_vulkan_drivers="no"])
1885
1886 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1887 # here so that the script doesn't choke on an unknown driver name later.
1888 case "x$with_vulkan_drivers" in
1889     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1890     xno) with_vulkan_drivers='' ;;
1891 esac
1892
1893 AC_ARG_WITH([vulkan-icddir],
1894     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1895         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1896     [VULKAN_ICD_INSTALL_DIR="$withval"],
1897     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1898 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1899
1900 if test -n "$with_vulkan_drivers"; then
1901     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1902     for driver in $VULKAN_DRIVERS; do
1903         case "x$driver" in
1904         xintel)
1905             if test "x$HAVE_I965_DRI" != xyes; then
1906                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1907             fi
1908             if test "x$with_sha1" == "x"; then
1909                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1910             fi
1911             HAVE_INTEL_VULKAN=yes;
1912
1913             ;;
1914         xradeon)
1915             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1916             radeon_llvm_check $LLVM_REQUIRED_RADV "radv"
1917             HAVE_RADEON_VULKAN=yes;
1918             if test "x$with_sha1" == "x"; then
1919                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1920             fi
1921             ;;
1922         *)
1923             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1924             ;;
1925         esac
1926     done
1927     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1928 fi
1929
1930
1931 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1932 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1933                                   "x$enable_osmesa" = xyes -o \
1934                                   -n "$DRI_DIRS")
1935
1936 dnl
1937 dnl OSMesa configuration
1938 dnl
1939
1940 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1941 AC_ARG_WITH([osmesa-bits],
1942     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1943         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1944     [osmesa_bits="$withval"],
1945     [osmesa_bits=8])
1946 if test "x$osmesa_bits" != x8; then
1947     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1948         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1949         osmesa_bits=8
1950     fi
1951 fi
1952 case "x$osmesa_bits" in
1953 x8)
1954     OSMESA_LIB="${OSMESA_LIB}"
1955     ;;
1956 x16|x32)
1957     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1958     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1959     ;;
1960 *)
1961     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1962     ;;
1963 esac
1964
1965 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1966     # only link libraries with osmesa if shared
1967     if test "$enable_static" = no; then
1968         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1969     else
1970         OSMESA_LIB_DEPS=""
1971     fi
1972     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1973 fi
1974
1975 AC_SUBST([OSMESA_LIB_DEPS])
1976 AC_SUBST([OSMESA_PC_REQ])
1977 AC_SUBST([OSMESA_PC_LIB_PRIV])
1978
1979 dnl
1980 dnl gbm configuration
1981 dnl
1982 if test "x$enable_gbm" = xyes; then
1983     if test "x$enable_dri" = xyes; then
1984         if test "x$enable_shared_glapi" = xno; then
1985             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1986         fi
1987     else
1988         # Strictly speaking libgbm does not require --enable-dri, although
1989         # both of its backends do. Thus one can build libgbm without any
1990         # backends if --disable-dri is set.
1991         # To avoid unnecessary complexity of checking if at least one backend
1992         # is available when building, just mandate --enable-dri.
1993         AC_MSG_ERROR([gbm requires --enable-dri])
1994     fi
1995 fi
1996 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1997 # FINISHME: GBM has a number of dependencies which we should add below
1998 GBM_PC_REQ_PRIV=""
1999 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
2000 AC_SUBST([GBM_PC_REQ_PRIV])
2001 AC_SUBST([GBM_PC_LIB_PRIV])
2002
2003 dnl
2004 dnl EGL configuration
2005 dnl
2006 EGL_CLIENT_APIS=""
2007
2008 if test "x$enable_egl" = xyes; then
2009     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
2010
2011     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
2012
2013     if test "$enable_static" != yes; then
2014         if test "x$enable_dri" = xyes; then
2015             HAVE_EGL_DRIVER_DRI2=1
2016             if test "x$enable_shared_glapi" = xno; then
2017                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
2018             fi
2019             if test "x$enable_dri3" = xyes; then
2020                 HAVE_EGL_DRIVER_DRI3=1
2021                 if test "x$enable_shared_glapi" = xno; then
2022                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
2023                 fi
2024             fi
2025         else
2026             # Avoid building an "empty" libEGL. Drop/update this
2027             # when other backends (haiku?) come along.
2028             AC_MSG_ERROR([egl requires --enable-dri])
2029         fi
2030
2031     fi
2032 fi
2033 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
2034 AC_SUBST([EGL_LIB_DEPS])
2035
2036 gallium_st="mesa"
2037
2038 dnl
2039 dnl XA configuration
2040 dnl
2041 if test "x$enable_xa" = xyes; then
2042     if test "x$with_gallium_drivers" = xswrast; then
2043        AC_MSG_ERROR([
2044           Building xa requires at least one non swrast gallium driver.
2045           If you are looking to use libxatracker.so with the VMware driver,
2046           make sure to include svga in the gallium drivers list, apart from
2047           enabling XA.
2048           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
2049     fi
2050     gallium_st="$gallium_st xa"
2051 fi
2052 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
2053
2054 dnl
2055 dnl Gallium G3DVL configuration
2056 dnl
2057 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
2058     if test "x$enable_xvmc" = xauto; then
2059         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
2060     fi
2061
2062     if test "x$enable_vdpau" = xauto; then
2063         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
2064     fi
2065
2066     if test "x$enable_omx" = xauto; then
2067         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
2068     fi
2069
2070     if test "x$enable_va" = xauto; then
2071         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
2072     fi
2073 fi
2074
2075 if test "x$enable_dri" = xyes -o \
2076         "x$enable_xvmc" = xyes -o \
2077         "x$enable_vdpau" = xyes -o \
2078         "x$enable_omx" = xyes -o \
2079         "x$enable_va" = xyes; then
2080     need_gallium_vl=yes
2081 fi
2082 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
2083
2084 if test "x$enable_xvmc" = xyes -o \
2085         "x$enable_vdpau" = xyes -o \
2086         "x$enable_omx" = xyes -o \
2087         "x$enable_va" = xyes; then
2088     if test x"$enable_dri3" = xyes; then
2089         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
2090                                  xcb-xfixes x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2091     else
2092         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
2093     fi
2094     need_gallium_vl_winsys=yes
2095 fi
2096 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
2097
2098 if test "x$enable_xvmc" = xyes; then
2099     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
2100     gallium_st="$gallium_st xvmc"
2101 fi
2102 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
2103
2104 if test "x$enable_vdpau" = xyes; then
2105     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
2106     gallium_st="$gallium_st vdpau"
2107     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
2108 fi
2109 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
2110
2111 if test "x$enable_omx" = xyes; then
2112     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
2113     gallium_st="$gallium_st omx"
2114 fi
2115 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
2116
2117 if test "x$enable_va" = xyes; then
2118     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
2119     gallium_st="$gallium_st va"
2120 fi
2121 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
2122
2123 dnl
2124 dnl Nine Direct3D9 configuration
2125 dnl
2126 if test "x$enable_nine" = xyes; then
2127     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
2128         AC_MSG_ERROR([nine requires the gallium swrast driver])
2129     fi
2130     if test "x$with_gallium_drivers" = xswrast; then
2131         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
2132     fi
2133     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
2134         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
2135     fi
2136
2137     if test "x$enable_dri3" = xno; then
2138         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
2139     fi
2140
2141     gallium_st="$gallium_st nine"
2142 fi
2143 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
2144
2145 dnl
2146 dnl OpenCL configuration
2147 dnl
2148
2149 AC_ARG_WITH([clang-libdir],
2150    [AS_HELP_STRING([--with-clang-libdir],
2151          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
2152    [CLANG_LIBDIR="$withval"],
2153    [CLANG_LIBDIR=''])
2154
2155 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
2156
2157 if test "x$enable_opencl" = xyes; then
2158     if test -z "$with_gallium_drivers"; then
2159         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
2160     fi
2161
2162     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
2163         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
2164     fi
2165
2166     if test "x$have_libclc" = xno; then
2167         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
2168                     Make sure the directory containing libclc.pc is specified in your
2169                     PKG_CONFIG_PATH environment variable.
2170                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
2171     else
2172         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
2173         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
2174         AC_SUBST([LIBCLC_INCLUDEDIR])
2175         AC_SUBST([LIBCLC_LIBEXECDIR])
2176     fi
2177
2178     gallium_st="$gallium_st clover"
2179
2180     if test "x$enable_opencl_icd" = xyes; then
2181         OPENCL_LIBNAME="MesaOpenCL"
2182     else
2183         OPENCL_LIBNAME="OpenCL"
2184     fi
2185
2186     if test "x$have_libelf" != xyes; then
2187        AC_MSG_ERROR([Clover requires libelf])
2188     fi
2189
2190     llvm_check_version_for $LLVM_REQUIRED_OPENCL "opencl"
2191
2192     llvm_add_default_components "opencl"
2193     llvm_add_component "all-targets" "opencl"
2194     llvm_add_component "linker" "opencl"
2195     llvm_add_component "instrumentation" "opencl"
2196     llvm_add_component "ipo" "opencl"
2197     llvm_add_component "irreader" "opencl"
2198     llvm_add_component "option" "opencl"
2199     llvm_add_component "objcarcopts" "opencl"
2200     llvm_add_component "profiledata" "opencl"
2201
2202     dnl Check for Clang internal headers
2203     if test -z "$CLANG_LIBDIR"; then
2204         CLANG_LIBDIR=${LLVM_LIBDIR}
2205     fi
2206     CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2207     AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2208         [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2209 fi
2210 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
2211 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
2212 AC_SUBST([OPENCL_LIBNAME])
2213 AC_SUBST([CLANG_RESOURCE_DIR])
2214
2215 dnl
2216 dnl Gallium configuration
2217 dnl
2218 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
2219
2220 case "x$enable_opengl$enable_gles1$enable_gles2" in
2221 x*yes*)
2222     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
2223     ;;
2224 esac
2225
2226 AC_SUBST([VG_LIB_DEPS])
2227 AC_SUBST([EGL_CLIENT_APIS])
2228
2229 dnl
2230 dnl EGL Platforms configuration
2231 dnl
2232 AC_ARG_WITH([egl-platforms],
2233     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2234         [comma delimited native platforms libEGL supports, e.g.
2235         "x11,drm" @<:@default=auto@:>@])],
2236     [with_egl_platforms="$withval"],
2237     [if test "x$enable_egl" = xyes; then
2238         if test "x$enable_gbm" = xyes; then
2239            with_egl_platforms="x11,drm"
2240         else
2241            with_egl_platforms="x11"
2242         fi
2243     else
2244         with_egl_platforms=""
2245     fi])
2246
2247 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2248     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2249 fi
2250
2251 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2252         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2253         WAYLAND_SCANNER='')
2254 if test "x$WAYLAND_SCANNER" = x; then
2255     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2256 fi
2257
2258 # Do per-EGL platform setups and checks
2259 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2260 for plat in $egl_platforms; do
2261         case "$plat" in
2262         wayland)
2263
2264                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2265
2266                 if test "x$WAYLAND_SCANNER" = x; then
2267                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2268                 fi
2269                 ;;
2270
2271         x11)
2272                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2273                 ;;
2274
2275         drm)
2276                 test "x$enable_gbm" = "xno" &&
2277                         AC_MSG_ERROR([EGL platform drm needs gbm])
2278                 ;;
2279
2280         surfaceless)
2281                 ;;
2282
2283         android)
2284                 PKG_CHECK_MODULES([ANDROID], [cutils hardware sync])
2285                 ;;
2286
2287         *)
2288                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2289                 ;;
2290         esac
2291
2292         case "$plat" in
2293         wayland|drm|surfaceless)
2294                 require_libdrm "Platform $plat"
2295                 ;;
2296         esac
2297 done
2298
2299 # libEGL wants to default to the first platform specified in
2300 # ./configure.  parse that here.
2301 if test "x$egl_platforms" != "x"; then
2302     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2303     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2304 else
2305     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2306 fi
2307
2308 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2309 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2310 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2311 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2312 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2313
2314 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2315
2316 AC_SUBST([EGL_NATIVE_PLATFORM])
2317 AC_SUBST([EGL_CFLAGS])
2318
2319 # If we don't have the X11 platform, set this define so we don't try to include
2320 # the X11 headers.
2321 if ! echo "$egl_platforms" | grep -q 'x11'; then
2322     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2323     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2324 fi
2325
2326 dnl
2327 dnl Gallium LLVM
2328 dnl
2329 AC_ARG_ENABLE([gallium-llvm],
2330     [AS_HELP_STRING([--enable-gallium-llvm],
2331         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2332     [enable_gallium_llvm="$enableval"],
2333     [enable_gallium_llvm=auto])
2334
2335 if test -z "$with_gallium_drivers"; then
2336     enable_gallium_llvm=no
2337 fi
2338 if test "x$enable_gallium_llvm" = xauto; then
2339     case "$host_cpu" in
2340     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2341     esac
2342 fi
2343
2344 dnl Directory for XVMC libs
2345 AC_ARG_WITH([xvmc-libdir],
2346     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2347         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2348     [XVMC_LIB_INSTALL_DIR="$withval"],
2349     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2350 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2351
2352 dnl
2353 dnl Gallium Tests
2354 dnl
2355 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2356
2357 dnl Directory for VDPAU libs
2358 AC_ARG_WITH([vdpau-libdir],
2359     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2360         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2361     [VDPAU_LIB_INSTALL_DIR="$withval"],
2362     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2363 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2364
2365 dnl Directory for OMX libs
2366
2367 AC_ARG_WITH([omx-libdir],
2368     [AS_HELP_STRING([--with-omx-libdir=DIR],
2369         [directory for the OMX libraries])],
2370     [OMX_LIB_INSTALL_DIR="$withval"],
2371     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2372 AC_SUBST([OMX_LIB_INSTALL_DIR])
2373
2374 dnl Directory for VA libs
2375
2376 AC_ARG_WITH([va-libdir],
2377     [AS_HELP_STRING([--with-va-libdir=DIR],
2378         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2379     [VA_LIB_INSTALL_DIR="$withval"],
2380     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2381 AC_SUBST([VA_LIB_INSTALL_DIR])
2382
2383 AC_ARG_WITH([d3d-libdir],
2384     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2385         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2386     [D3D_DRIVER_INSTALL_DIR="$withval"],
2387     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2388 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2389
2390 dnl
2391 dnl Gallium helper functions
2392 dnl
2393 gallium_require_llvm() {
2394     if test "x$enable_gallium_llvm" = "xyes"; then
2395         llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2396     else
2397         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2398     fi
2399 }
2400
2401 dnl
2402 dnl DRM is needed by X, Wayland, and offscreen rendering.
2403 dnl Surfaceless is an alternative for the last one.
2404 dnl
2405 require_basic_egl() {
2406     case "$with_egl_platforms" in
2407         *drm*|*surfaceless*)
2408             ;;
2409         *)
2410             AC_MSG_ERROR([$1 requires one of these:
2411                   1) --with-egl-platforms=drm (X, Wayland, offscreen rendering based on DRM)
2412                   2) --with-egl-platforms=surfaceless (offscreen only)
2413                   Recommended options: drm,x11])
2414             ;;
2415     esac
2416 }
2417
2418 radeon_gallium_llvm_check() {
2419     if test "x$enable_gallium_llvm" != "xyes"; then
2420         AC_MSG_ERROR([--enable-gallium-llvm is required when building $2])
2421     fi
2422     radeon_llvm_check $*
2423 }
2424
2425 swr_require_cxx_feature_flags() {
2426     feature_name="$1"
2427     preprocessor_test="$2"
2428     option_list="$3"
2429     output_var="$4"
2430
2431     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2432     AC_LANG_PUSH([C++])
2433     save_CXXFLAGS="$CXXFLAGS"
2434     save_IFS="$IFS"
2435     IFS=","
2436     found=0
2437     for opts in $option_list
2438     do
2439         unset IFS
2440         CXXFLAGS="$opts $save_CXXFLAGS"
2441         AC_COMPILE_IFELSE(
2442             [AC_LANG_PROGRAM(
2443                 [   #if !($preprocessor_test)
2444                     #error
2445                     #endif
2446                 ])],
2447             [found=1; break],
2448             [])
2449         IFS=","
2450     done
2451     IFS="$save_IFS"
2452     CXXFLAGS="$save_CXXFLAGS"
2453     AC_LANG_POP([C++])
2454     if test $found -eq 1; then
2455         AC_MSG_RESULT([$opts])
2456         eval "$output_var=\$opts"
2457         return 0
2458     fi
2459     AC_MSG_RESULT([no])
2460     AC_MSG_ERROR([swr requires $feature_name support])
2461     return 1
2462 }
2463
2464 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2465 if test -n "$with_gallium_drivers"; then
2466     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2467     for driver in $gallium_drivers; do
2468         case "x$driver" in
2469         xsvga)
2470             HAVE_GALLIUM_SVGA=yes
2471             require_libdrm "svga"
2472             ;;
2473         xi915)
2474             HAVE_GALLIUM_I915=yes
2475             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2476             require_libdrm "Gallium i915"
2477             ;;
2478         xilo)
2479             HAVE_GALLIUM_ILO=yes
2480             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2481             require_libdrm "Gallium i965/ilo"
2482             ;;
2483         xr300)
2484             HAVE_GALLIUM_R300=yes
2485             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2486             require_libdrm "r300"
2487             gallium_require_llvm "r300"
2488             ;;
2489         xr600)
2490             HAVE_GALLIUM_R600=yes
2491             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2492             require_libdrm "r600"
2493             if test "x$enable_opencl" = xyes; then
2494                 radeon_gallium_llvm_check $LLVM_REQUIRED_R600 "r600"
2495
2496                 llvm_add_component "asmparser" "r600"
2497                 llvm_add_component "bitreader" "r600"
2498             fi
2499             ;;
2500         xradeonsi)
2501             HAVE_GALLIUM_RADEONSI=yes
2502             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2503             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2504             require_libdrm "radeonsi"
2505             radeon_gallium_llvm_check $LLVM_REQUIRED_RADEONSI "radeonsi"
2506             require_basic_egl "radeonsi"
2507             ;;
2508         xnouveau)
2509             HAVE_GALLIUM_NOUVEAU=yes
2510             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2511             require_libdrm "nouveau"
2512             ;;
2513         xfreedreno)
2514             HAVE_GALLIUM_FREEDRENO=yes
2515             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2516             require_libdrm "freedreno"
2517             ;;
2518         xetnaviv)
2519             HAVE_GALLIUM_ETNAVIV=yes
2520             PKG_CHECK_MODULES([ETNAVIV], [libdrm_etnaviv >= $LIBDRM_ETNAVIV_REQUIRED])
2521             require_libdrm "etnaviv"
2522             ;;
2523        ximx)
2524             HAVE_GALLIUM_IMX=yes
2525             ;;
2526         xswrast)
2527             HAVE_GALLIUM_SOFTPIPE=yes
2528             if test "x$MESA_LLVM" = x1 && test "x$enable_gallium_llvm" == "xyes";  then
2529                 HAVE_GALLIUM_LLVMPIPE=yes
2530             fi
2531             ;;
2532         xswr)
2533             llvm_check_version_for $LLVM_REQUIRED_SWR "swr"
2534             gallium_require_llvm "swr"
2535
2536             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2537                 ",-std=c++11" \
2538                 SWR_CXX11_CXXFLAGS
2539             AC_SUBST([SWR_CXX11_CXXFLAGS])
2540
2541             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2542                 ",-mavx,-march=core-avx" \
2543                 SWR_AVX_CXXFLAGS
2544             AC_SUBST([SWR_AVX_CXXFLAGS])
2545
2546             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2547                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2548                 SWR_AVX2_CXXFLAGS
2549             AC_SUBST([SWR_AVX2_CXXFLAGS])
2550
2551             HAVE_GALLIUM_SWR=yes
2552             ;;
2553         xvc4)
2554             HAVE_GALLIUM_VC4=yes
2555             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2556             require_libdrm "vc4"
2557
2558             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2559                               [USE_VC4_SIMULATOR=yes;
2560                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2561                               [USE_VC4_SIMULATOR=no])
2562             ;;
2563         xvirgl)
2564             HAVE_GALLIUM_VIRGL=yes
2565             require_libdrm "virgl"
2566             require_basic_egl "virgl"
2567             ;;
2568         *)
2569             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2570             ;;
2571         esac
2572     done
2573 fi
2574
2575 if test "x$enable_gallium_llvm" == "xyes"; then
2576     llvm_check_version_for $LLVM_REQUIRED_GALLIUM "gallium"
2577     llvm_add_default_components "gallium"
2578 fi
2579
2580 dnl We need to validate some needed dependencies for renderonly drivers.
2581
2582 if test "x$HAVE_GALLIUM_ETNAVIV" != xyes -a "x$HAVE_GALLIUM_IMX" == xyes  ; then
2583     AC_ERROR([Building with imx requires etnaviv])
2584 fi
2585
2586 dnl Set LLVM_LIBS - This is done after the driver configuration so
2587 dnl that drivers can add additional components to LLVM_COMPONENTS.
2588 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2589 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2590 dnl this was causing the same libraries to be appear multiple times
2591 dnl in LLVM_LIBS.
2592
2593 if test "x$MESA_LLVM" != x0; then
2594
2595     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2596        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2597     fi
2598     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2599
2600     dnl llvm-config may not give the right answer when llvm is a built as a
2601     dnl single shared library, so we must work the library name out for
2602     dnl ourselves.
2603     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2604     if test "x$enable_llvm_shared_libs" = xyes; then
2605         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2606         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2607         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2608
2609         if test "x$llvm_have_one_so" = xyes; then
2610             dnl LLVM was built using auto*, so there is only one shared object.
2611             LLVM_LIBS="-l$LLVM_SO_NAME"
2612         else
2613             dnl If LLVM was built with CMake, there will be one shared object per
2614             dnl component.
2615             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2616                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2617         Please make sure you have built llvm with the --enable-shared option
2618         and that your llvm libraries are installed in $LLVM_LIBDIR
2619         If you have installed your llvm libraries to a different directory you
2620         can use the --with-llvm-prefix= configure flag to specify this directory.
2621         NOTE: Mesa is attempting to use llvm shared libraries by default.
2622         If you do not want to build with llvm shared libraries and instead want to
2623         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2624         invocation and rebuild.])])
2625
2626            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2627            dnl install uses a shared object for each component and we have
2628            dnl already added all of these objects to LLVM_LIBS.
2629         fi
2630     else
2631         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2632         dnl We need to link to llvm system libs when using static libs
2633         dnl However, only llvm 3.5+ provides --system-libs
2634         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2635             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2636         fi
2637     fi
2638 fi
2639
2640 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2641 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2642 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2643 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2644 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2645 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2646 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2647                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2648 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2649 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2650 AM_CONDITIONAL(HAVE_GALLIUM_ETNAVIV, test "x$HAVE_GALLIUM_ETNAVIV" = xyes)
2651 AM_CONDITIONAL(HAVE_GALLIUM_IMX, test "x$HAVE_GALLIUM_IMX" = xyes)
2652 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2653 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2654 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2655 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2656                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2657                                          "x$HAVE_GALLIUM_SWR" = xyes)
2658 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2659 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2660
2661 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2662
2663 if test "x$enable_dri" = xyes; then
2664     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2665 fi
2666
2667 if test "x$have_drisw_kms" = xyes; then
2668     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2669 fi
2670 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2671
2672 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2673 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2674 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2675 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2676 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2677 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2678
2679 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2680 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2681
2682 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2683                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2684                                       "x$HAVE_RADEON_VULKAN" = xyes)
2685
2686 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2687                                         "x$HAVE_I965_DRI" = xyes)
2688
2689 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2690                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2691                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2692 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2693 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2694 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2695 AM_CONDITIONAL(HAVE_GALLIUM_LLVM, test "x$MESA_LLVM" = x1 -a \
2696                                        "x$enable_gallium_llvm" = xyes)
2697 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2698 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2699     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2700 fi
2701
2702 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2703 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2704 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2705 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2706                                         "x$enable_gallium_osmesa" = xyes)
2707
2708 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2709 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2710 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2711
2712 AC_SUBST([NINE_MAJOR], 1)
2713 AC_SUBST([NINE_MINOR], 0)
2714 AC_SUBST([NINE_TINY], 0)
2715 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2716
2717 AC_SUBST([VDPAU_MAJOR], 1)
2718 AC_SUBST([VDPAU_MINOR], 0)
2719
2720 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2721 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2722 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2723 AC_SUBST([VA_MINOR], $VA_MINOR)
2724
2725 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2726
2727 AC_SUBST([XVMC_MAJOR], 1)
2728 AC_SUBST([XVMC_MINOR], 0)
2729
2730 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2731 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2732 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2733 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2734
2735 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2736 AC_SUBST([XA_MINOR], $XA_MINOR)
2737 AC_SUBST([XA_TINY], $XA_TINY)
2738 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2739
2740 AC_ARG_ENABLE(valgrind,
2741               [AS_HELP_STRING([--enable-valgrind],
2742                              [Build mesa with valgrind support (default: auto)])],
2743                              [VALGRIND=$enableval], [VALGRIND=auto])
2744 if test "x$VALGRIND" != xno; then
2745         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2746 fi
2747 AC_MSG_CHECKING([whether to enable Valgrind support])
2748 if test "x$VALGRIND" = xauto; then
2749         VALGRIND="$have_valgrind"
2750 fi
2751
2752 if test "x$VALGRIND" = "xyes"; then
2753         if ! test "x$have_valgrind" = xyes; then
2754                 AC_MSG_ERROR([Valgrind support required but not present])
2755         fi
2756         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2757 fi
2758
2759 AC_MSG_RESULT([$VALGRIND])
2760
2761 dnl Restore LDFLAGS and CPPFLAGS
2762 LDFLAGS="$_SAVE_LDFLAGS"
2763 CPPFLAGS="$_SAVE_CPPFLAGS"
2764
2765 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2766 if test "x$acv_mesa_CLANG" = xyes; then
2767     CFLAGS="$CFLAGS -Qunused-arguments"
2768     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2769 fi
2770
2771 dnl Add user CFLAGS and CXXFLAGS
2772 CFLAGS="$CFLAGS $USER_CFLAGS"
2773 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2774
2775 dnl Substitute the config
2776 AC_CONFIG_FILES([Makefile
2777                 src/Makefile
2778                 src/amd/Makefile
2779                 src/amd/vulkan/Makefile
2780                 src/compiler/Makefile
2781                 src/egl/Makefile
2782                 src/egl/main/egl.pc
2783                 src/egl/wayland/wayland-drm/Makefile
2784                 src/egl/wayland/wayland-egl/Makefile
2785                 src/egl/wayland/wayland-egl/wayland-egl.pc
2786                 src/gallium/Makefile
2787                 src/gallium/auxiliary/Makefile
2788                 src/gallium/auxiliary/pipe-loader/Makefile
2789                 src/gallium/drivers/freedreno/Makefile
2790                 src/gallium/drivers/ddebug/Makefile
2791                 src/gallium/drivers/i915/Makefile
2792                 src/gallium/drivers/ilo/Makefile
2793                 src/gallium/drivers/llvmpipe/Makefile
2794                 src/gallium/drivers/noop/Makefile
2795                 src/gallium/drivers/nouveau/Makefile
2796                 src/gallium/drivers/r300/Makefile
2797                 src/gallium/drivers/r600/Makefile
2798                 src/gallium/drivers/radeon/Makefile
2799                 src/gallium/drivers/radeonsi/Makefile
2800                 src/gallium/drivers/rbug/Makefile
2801                 src/gallium/drivers/softpipe/Makefile
2802                 src/gallium/drivers/svga/Makefile
2803                 src/gallium/drivers/swr/Makefile
2804                 src/gallium/drivers/trace/Makefile
2805                 src/gallium/drivers/etnaviv/Makefile
2806                 src/gallium/drivers/imx/Makefile
2807                 src/gallium/drivers/vc4/Makefile
2808                 src/gallium/drivers/virgl/Makefile
2809                 src/gallium/state_trackers/clover/Makefile
2810                 src/gallium/state_trackers/dri/Makefile
2811                 src/gallium/state_trackers/glx/xlib/Makefile
2812                 src/gallium/state_trackers/nine/Makefile
2813                 src/gallium/state_trackers/omx/Makefile
2814                 src/gallium/state_trackers/osmesa/Makefile
2815                 src/gallium/state_trackers/va/Makefile
2816                 src/gallium/state_trackers/vdpau/Makefile
2817                 src/gallium/state_trackers/xa/Makefile
2818                 src/gallium/state_trackers/xvmc/Makefile
2819                 src/gallium/targets/d3dadapter9/Makefile
2820                 src/gallium/targets/d3dadapter9/d3d.pc
2821                 src/gallium/targets/dri/Makefile
2822                 src/gallium/targets/libgl-xlib/Makefile
2823                 src/gallium/targets/omx/Makefile
2824                 src/gallium/targets/opencl/Makefile
2825                 src/gallium/targets/opencl/mesa.icd
2826                 src/gallium/targets/osmesa/Makefile
2827                 src/gallium/targets/osmesa/osmesa.pc
2828                 src/gallium/targets/pipe-loader/Makefile
2829                 src/gallium/targets/va/Makefile
2830                 src/gallium/targets/vdpau/Makefile
2831                 src/gallium/targets/xa/Makefile
2832                 src/gallium/targets/xa/xatracker.pc
2833                 src/gallium/targets/xvmc/Makefile
2834                 src/gallium/tests/trivial/Makefile
2835                 src/gallium/tests/unit/Makefile
2836                 src/gallium/winsys/etnaviv/drm/Makefile
2837                 src/gallium/winsys/imx/drm/Makefile
2838                 src/gallium/winsys/freedreno/drm/Makefile
2839                 src/gallium/winsys/i915/drm/Makefile
2840                 src/gallium/winsys/intel/drm/Makefile
2841                 src/gallium/winsys/nouveau/drm/Makefile
2842                 src/gallium/winsys/radeon/drm/Makefile
2843                 src/gallium/winsys/amdgpu/drm/Makefile
2844                 src/gallium/winsys/svga/drm/Makefile
2845                 src/gallium/winsys/sw/dri/Makefile
2846                 src/gallium/winsys/sw/kms-dri/Makefile
2847                 src/gallium/winsys/sw/null/Makefile
2848                 src/gallium/winsys/sw/wrapper/Makefile
2849                 src/gallium/winsys/sw/xlib/Makefile
2850                 src/gallium/winsys/vc4/drm/Makefile
2851                 src/gallium/winsys/virgl/drm/Makefile
2852                 src/gallium/winsys/virgl/vtest/Makefile
2853                 src/gbm/Makefile
2854                 src/gbm/main/gbm.pc
2855                 src/glx/Makefile
2856                 src/glx/apple/Makefile
2857                 src/glx/tests/Makefile
2858                 src/glx/windows/Makefile
2859                 src/glx/windows/windowsdriproto.pc
2860                 src/gtest/Makefile
2861                 src/intel/Makefile
2862                 src/intel/tools/Makefile
2863                 src/intel/vulkan/Makefile
2864                 src/loader/Makefile
2865                 src/mapi/Makefile
2866                 src/mapi/es1api/glesv1_cm.pc
2867                 src/mapi/es2api/glesv2.pc
2868                 src/mapi/glapi/gen/Makefile
2869                 src/mesa/Makefile
2870                 src/mesa/gl.pc
2871                 src/mesa/drivers/dri/dri.pc
2872                 src/mesa/drivers/dri/common/Makefile
2873                 src/mesa/drivers/dri/common/xmlpool/Makefile
2874                 src/mesa/drivers/dri/i915/Makefile
2875                 src/mesa/drivers/dri/i965/Makefile
2876                 src/mesa/drivers/dri/Makefile
2877                 src/mesa/drivers/dri/nouveau/Makefile
2878                 src/mesa/drivers/dri/r200/Makefile
2879                 src/mesa/drivers/dri/radeon/Makefile
2880                 src/mesa/drivers/dri/swrast/Makefile
2881                 src/mesa/drivers/osmesa/Makefile
2882                 src/mesa/drivers/osmesa/osmesa.pc
2883                 src/mesa/drivers/x11/Makefile
2884                 src/mesa/main/tests/Makefile
2885                 src/util/Makefile
2886                 src/util/tests/hash_table/Makefile
2887                 src/vulkan/wsi/Makefile])
2888
2889 AC_OUTPUT
2890
2891 # Fix up dependencies in *.Plo files, where we changed the extension of a
2892 # source file
2893 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2894
2895
2896 dnl
2897 dnl Output some configuration info for the user
2898 dnl
2899 echo ""
2900 echo "        prefix:          $prefix"
2901 echo "        exec_prefix:     $exec_prefix"
2902 echo "        libdir:          $libdir"
2903 echo "        includedir:      $includedir"
2904
2905 dnl API info
2906 echo ""
2907 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2908
2909 dnl Driver info
2910 echo ""
2911 case "x$enable_osmesa$enable_gallium_osmesa" in
2912 xnoyes)
2913         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2914         ;;
2915 xyesno)
2916         echo "        OSMesa:          lib$OSMESA_LIB"
2917         ;;
2918 xnono)
2919         echo "        OSMesa:          no"
2920         ;;
2921 esac
2922
2923 echo ""
2924 if test "x$enable_dri" != xno; then
2925         echo "        DRI platform:    $dri_platform"
2926         if test -z "$DRI_DIRS"; then
2927             echo "        DRI drivers:     no"
2928         else
2929             echo "        DRI drivers:     $DRI_DIRS"
2930         fi
2931         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2932 fi
2933
2934 case "x$enable_glx" in
2935 xdri)
2936     echo "        GLX:             DRI-based"
2937     ;;
2938 xxlib)
2939     echo "        GLX:             Xlib-based"
2940     ;;
2941 xgallium-xlib)
2942     echo "        GLX:             Xlib-based (Gallium)"
2943     ;;
2944 *)
2945     echo "        GLX:             $enable_glx"
2946     ;;
2947 esac
2948
2949 dnl EGL
2950 echo ""
2951 echo "        EGL:             $enable_egl"
2952 if test "$enable_egl" = yes; then
2953     echo "        EGL platforms:   $egl_platforms"
2954
2955     egl_drivers=""
2956     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2957         egl_drivers="$egl_drivers builtin:egl_dri2"
2958     fi
2959     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2960         egl_drivers="$egl_drivers builtin:egl_dri3"
2961     fi
2962
2963     echo "        EGL drivers:    $egl_drivers"
2964 fi
2965 if test "x$enable_gbm" = xyes; then
2966     echo "        GBM:             yes"
2967 else
2968     echo "        GBM:             no"
2969 fi
2970
2971 # Vulkan
2972 echo ""
2973 if test "x$VULKAN_DRIVERS" != x; then
2974     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2975     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2976 else
2977     echo "        Vulkan drivers:  no"
2978 fi
2979
2980 echo ""
2981 if test "x$MESA_LLVM" = x1; then
2982     echo "        llvm:            yes"
2983     echo "        llvm-config:     $LLVM_CONFIG"
2984     echo "        llvm-version:    $LLVM_VERSION"
2985 else
2986     echo "        llvm:            no"
2987 fi
2988
2989 echo ""
2990 if test -n "$with_gallium_drivers"; then
2991     echo "        Gallium drivers: $gallium_drivers"
2992     echo "        Gallium st:      $gallium_st"
2993 else
2994     echo "        Gallium:         no"
2995 fi
2996
2997 echo ""
2998 if test "x$enable_gallium_extra_hud" != xyes; then
2999     echo "        HUD extra stats: no"
3000 else
3001     echo "        HUD extra stats: yes"
3002 fi
3003
3004 if test "x$enable_lmsensors" != xyes; then
3005     echo "        HUD lmsensors:   no"
3006 else
3007     echo "        HUD lmsensors:   yes"
3008 fi
3009
3010 dnl Shader cache
3011 echo ""
3012 echo "        Shader cache:    $enable_shader_cache"
3013 if test "x$enable_shader_cache" = "xyes"; then
3014     echo "        With SHA1 from:  $with_sha1"
3015 fi
3016
3017 dnl Libraries
3018 echo ""
3019 echo "        Shared libs:     $enable_shared"
3020 echo "        Static libs:     $enable_static"
3021 echo "        Shared-glapi:    $enable_shared_glapi"
3022
3023 dnl Compiler options
3024 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
3025 cflags=`echo $CFLAGS | \
3026     $SED 's/^ *//;s/  */ /;s/ *$//'`
3027 cxxflags=`echo $CXXFLAGS | \
3028     $SED 's/^ *//;s/  */ /;s/ *$//'`
3029 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
3030 echo ""
3031 echo "        CFLAGS:          $cflags"
3032 echo "        CXXFLAGS:        $cxxflags"
3033 echo "        Macros:          $defines"
3034 echo ""
3035 if test "x$MESA_LLVM" = x1; then
3036     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
3037     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
3038     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
3039     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
3040     echo ""
3041 fi
3042 echo "        PYTHON2:         $PYTHON2"
3043
3044 echo ""
3045 echo "        Run '${MAKE-make}' to build Mesa"
3046 echo ""