configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll.a' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 285
 286 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 287 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 288 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 289 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 290 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 291 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 293 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 294 VG_LIB_GLOB='lib$(VG_LIB).*'${LIB_EXTENSION}'*'
 295
 296 AC_SUBST([GL_LIB_NAME])
 297 AC_SUBST([GLU_LIB_NAME])
 298 AC_SUBST([GLUT_LIB_NAME])
 299 AC_SUBST([GLW_LIB_NAME])
 300 AC_SUBST([OSMESA_LIB_NAME])
 301 AC_SUBST([EGL_LIB_NAME])
 302 AC_SUBST([GLESv1_CM_LIB_NAME])
 303 AC_SUBST([GLESv2_LIB_NAME])
 304 AC_SUBST([VG_LIB_NAME])
 305
 306 AC_SUBST([GL_LIB_GLOB])
 307 AC_SUBST([GLU_LIB_GLOB])
 308 AC_SUBST([GLUT_LIB_GLOB])
 309 AC_SUBST([GLW_LIB_GLOB])
 310 AC_SUBST([OSMESA_LIB_GLOB])
 311 AC_SUBST([EGL_LIB_GLOB])
 312 AC_SUBST([GLESv1_CM_LIB_GLOB])
 313 AC_SUBST([GLESv2_LIB_GLOB])
 314 AC_SUBST([VG_LIB_GLOB])
 315
 316 dnl
 317 dnl Arch/platform-specific settings
 318 dnl
 319 AC_ARG_ENABLE([asm],
 320     [AS_HELP_STRING([--disable-asm],
 321         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 322     [enable_asm="$enableval"],
 323     [enable_asm=yes]
 324 )
 325 asm_arch=""
 326 ASM_FLAGS=""
 327 MESA_ASM_SOURCES=""
 328 GLAPI_ASM_SOURCES=""
 329 AC_MSG_CHECKING([whether to enable assembly])
 330 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 331 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 332 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 333     case "$host_cpu" in
 334     i?86 | x86_64)
 335         enable_asm=no
 336         AC_MSG_RESULT([no, cross compiling])
 337         ;;
 338     esac
 339 fi
 340 # check for supported arches
 341 if test "x$enable_asm" = xyes; then
 342     case "$host_cpu" in
 343     i?86)
 344         case "$host_os" in
 345         linux* | *freebsd* | dragonfly*)
 346             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 347             ;;
 348         esac
 349         ;;
 350     x86_64)
 351         case "$host_os" in
 352         linux* | *freebsd* | dragonfly*)
 353             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 354             ;;
 355         esac
 356         ;;
 357     powerpc)
 358         case "$host_os" in
 359         linux*)
 360             asm_arch=ppc
 361             ;;
 362         esac
 363         ;;
 364     sparc*)
 365         case "$host_os" in
 366         linux*)
 367             asm_arch=sparc
 368             ;;
 369         esac
 370         ;;
 371     esac
 372
 373     case "$asm_arch" in
 374     x86)
 375         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 376         MESA_ASM_SOURCES='$(X86_SOURCES)'
 377         GLAPI_ASM_SOURCES='$(X86_API)'
 378         AC_MSG_RESULT([yes, x86])
 379         ;;
 380     x86_64)
 381         ASM_FLAGS="-DUSE_X86_64_ASM"
 382         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 383         GLAPI_ASM_SOURCES='$(X86-64_API)'
 384         AC_MSG_RESULT([yes, x86_64])
 385         ;;
 386     ppc)
 387         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 388         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 389         AC_MSG_RESULT([yes, ppc])
 390         ;;
 391     sparc)
 392         ASM_FLAGS="-DUSE_SPARC_ASM"
 393         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 394         GLAPI_ASM_SOURCES='$(SPARC_API)'
 395         AC_MSG_RESULT([yes, sparc])
 396         ;;
 397     *)
 398         AC_MSG_RESULT([no, platform not supported])
 399         ;;
 400     esac
 401 fi
 402 AC_SUBST([ASM_FLAGS])
 403 AC_SUBST([MESA_ASM_SOURCES])
 404 AC_SUBST([GLAPI_ASM_SOURCES])
 405
 406 dnl PIC code macro
 407 MESA_PIC_FLAGS
 408
 409 dnl Check to see if dlopen is in default libraries (like Solaris, which
 410 dnl has it in libc), or if libdl is needed to get it.
 411 AC_CHECK_FUNC([dlopen], [],
 412     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 413
 414 dnl See if posix_memalign is available
 415 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 416
 417 dnl SELinux awareness.
 418 AC_ARG_ENABLE([selinux],
 419     [AS_HELP_STRING([--enable-selinux],
 420         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 421     [MESA_SELINUX="$enableval"],
 422     [MESA_SELINUX=no])
 423 if test "x$enable_selinux" = "xyes"; then
 424     AC_CHECK_HEADER([selinux/selinux.h],[],
 425                     [AC_MSG_ERROR([SELinux headers not found])])
 426     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 427                  [AC_MSG_ERROR([SELinux library not found])])
 428     SELINUX_LIBS="-lselinux"
 429     DEFINES="$DEFINES -DMESA_SELINUX"
 430 fi
 431
 432 dnl
 433 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 434 dnl More later: fbdev, ...
 435 dnl
 436 default_driver="xlib"
 437
 438 case "$host_os" in
 439 linux*)
 440     case "$host_cpu" in
 441     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 442     esac
 443     ;;
 444 *freebsd* | dragonfly*)
 445     case "$host_cpu" in
 446     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 447     esac
 448     ;;
 449 esac
 450
 451 AC_ARG_WITH([driver],
 452     [AS_HELP_STRING([--with-driver=DRIVER],
 453         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 454     [mesa_driver="$withval"],
 455     [mesa_driver="$default_driver"])
 456 dnl Check for valid option
 457 case "x$mesa_driver" in
 458 xxlib|xdri|xosmesa)
 459     ;;
 460 *)
 461     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 462     ;;
 463 esac
 464
 465 PKG_CHECK_MODULES([TALLOC], [talloc])
 466
 467 dnl
 468 dnl Driver specific build directories
 469 dnl
 470
 471 dnl this variable will be prepended to SRC_DIRS and is not exported
 472 CORE_DIRS="mapi/glapi glsl mesa"
 473
 474 SRC_DIRS=""
 475 GLU_DIRS="sgi"
 476 GALLIUM_DIRS="auxiliary drivers state_trackers"
 477 GALLIUM_TARGET_DIRS=""
 478 GALLIUM_WINSYS_DIRS="sw"
 479 GALLIUM_DRIVERS_DIRS="softpipe failover trace rbug identity"
 480 GALLIUM_STATE_TRACKERS_DIRS=""
 481
 482 case "$mesa_driver" in
 483 xlib)
 484     DRIVER_DIRS="x11"
 485     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 486     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 487     ;;
 488 dri)
 489     SRC_DIRS="$SRC_DIRS glx"
 490     DRIVER_DIRS="dri"
 491     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 492     ;;
 493 osmesa)
 494     DRIVER_DIRS="osmesa"
 495     ;;
 496 esac
 497 AC_SUBST([SRC_DIRS])
 498 AC_SUBST([GLU_DIRS])
 499 AC_SUBST([DRIVER_DIRS])
 500 AC_SUBST([GALLIUM_DIRS])
 501 AC_SUBST([GALLIUM_TARGET_DIRS])
 502 AC_SUBST([GALLIUM_WINSYS_DIRS])
 503 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 504 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 505 AC_SUBST([MESA_LLVM])
 506
 507 dnl
 508 dnl Find out if X is available. The variable have_x is set if libX11 is
 509 dnl found to mimic AC_PATH_XTRA.
 510 dnl
 511 if test -n "$PKG_CONFIG"; then
 512     AC_MSG_CHECKING([pkg-config files for X11 are available])
 513     PKG_CHECK_EXISTS([x11],[
 514         x11_pkgconfig=yes
 515         have_x=yes
 516         ],[
 517         x11_pkgconfig=no
 518     ])
 519     AC_MSG_RESULT([$x11_pkgconfig])
 520 else
 521     x11_pkgconfig=no
 522 fi
 523 dnl Use the autoconf macro if no pkg-config files
 524 if test "$x11_pkgconfig" = yes; then
 525     PKG_CHECK_MODULES([X11], [x11])
 526 else
 527     AC_PATH_XTRA
 528     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 529     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 530     AC_SUBST([X11_CFLAGS])
 531     AC_SUBST([X11_LIBS])
 532 fi
 533
 534 dnl Try to tell the user that the --x-* options are only used when
 535 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 536 m4_divert_once([HELP_BEGIN],
 537 [These options are only used when the X libraries cannot be found by the
 538 pkg-config utility.])
 539
 540 dnl We need X for xlib and dri, so bomb now if it's not found
 541 case "$mesa_driver" in
 542 xlib|dri)
 543     if test "$no_x" = yes; then
 544         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 545     fi
 546     ;;
 547 esac
 548
 549 dnl XCB - this is only used for GLX right now
 550 AC_ARG_ENABLE([xcb],
 551     [AS_HELP_STRING([--enable-xcb],
 552         [use XCB for GLX @<:@default=disabled@:>@])],
 553     [enable_xcb="$enableval"],
 554     [enable_xcb=no])
 555 if test "x$enable_xcb" = xyes; then
 556     DEFINES="$DEFINES -DUSE_XCB"
 557 else
 558     enable_xcb=no
 559 fi
 560
 561 dnl
 562 dnl libGL configuration per driver
 563 dnl
 564 case "$mesa_driver" in
 565 xlib)
 566     if test "$x11_pkgconfig" = yes; then
 567         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 568         GL_PC_REQ_PRIV="x11 xext"
 569         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 570         GL_LIB_DEPS="$XLIBGL_LIBS"
 571     else
 572         # should check these...
 573         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 574         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 575         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 576         GL_PC_CFLAGS="$X11_INCLUDES"
 577     fi
 578     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 579     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 580
 581     # if static, move the external libraries to the programs
 582     # and empty the libraries for libGL
 583     if test "$enable_static" = yes; then
 584         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 585         GL_LIB_DEPS=""
 586     fi
 587     ;;
 588 dri)
 589     # DRI must be shared, I think
 590     if test "$enable_static" = yes; then
 591         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 592     fi
 593
 594     # Check for libdrm
 595     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 596     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 597     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 598     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 599     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 600
 601     # find the DRI deps for libGL
 602     if test "$x11_pkgconfig" = yes; then
 603         # add xcb modules if necessary
 604         dri_modules="x11 xext xxf86vm xdamage xfixes"
 605         if test "$enable_xcb" = yes; then
 606             dri_modules="$dri_modules x11-xcb xcb-glx"
 607         fi
 608
 609         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 610         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 611         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 612         GL_LIB_DEPS="$DRIGL_LIBS"
 613     else
 614         # should check these...
 615         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 616         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 617         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 618         GL_PC_CFLAGS="$X11_INCLUDES"
 619
 620         # XCB can only be used from pkg-config
 621         if test "$enable_xcb" = yes; then
 622             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 623             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 624             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 625             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 626         fi
 627     fi
 628
 629     # need DRM libs, -lpthread, etc.
 630     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 631     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 632     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 633     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 634     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 635     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 636     ;;
 637 osmesa)
 638     # No libGL for osmesa
 639     GL_LIB_DEPS=""
 640     ;;
 641 esac
 642 AC_SUBST([GL_LIB_DEPS])
 643 AC_SUBST([GL_PC_REQ_PRIV])
 644 AC_SUBST([GL_PC_LIB_PRIV])
 645 AC_SUBST([GL_PC_CFLAGS])
 646 AC_SUBST([DRI_PC_REQ_PRIV])
 647 AC_SUBST([GLESv1_LIB_DEPS])
 648 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 649 AC_SUBST([GLESv2_LIB_DEPS])
 650 AC_SUBST([GLESv2_PC_LIB_PRIV])
 651
 652
 653 dnl
 654 dnl More X11 setup
 655 dnl
 656 if test "$mesa_driver" = xlib; then
 657     DEFINES="$DEFINES -DUSE_XSHM"
 658 fi
 659
 660 dnl
 661 dnl More DRI setup
 662 dnl
 663 AC_ARG_ENABLE([glx-tls],
 664     [AS_HELP_STRING([--enable-glx-tls],
 665         [enable TLS support in GLX @<:@default=disabled@:>@])],
 666     [GLX_USE_TLS="$enableval"],
 667     [GLX_USE_TLS=no])
 668 dnl Directory for DRI drivers
 669 AC_ARG_WITH([dri-driverdir],
 670     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 671         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 672     [DRI_DRIVER_INSTALL_DIR="$withval"],
 673     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 674 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 675 dnl Extra search path for DRI drivers
 676 AC_ARG_WITH([dri-searchpath],
 677     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 678         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 679     [DRI_DRIVER_SEARCH_DIR="$withval"],
 680     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 681 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 682 dnl Direct rendering or just indirect rendering
 683 AC_ARG_ENABLE([driglx-direct],
 684     [AS_HELP_STRING([--disable-driglx-direct],
 685         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 686     [driglx_direct="$enableval"],
 687     [driglx_direct="yes"])
 688 dnl Which drivers to build - default is chosen by platform
 689 AC_ARG_WITH([dri-drivers],
 690     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 691         [comma delimited DRI drivers list, e.g.
 692         "swrast,i965,radeon" @<:@default=auto@:>@])],
 693     [with_dri_drivers="$withval"],
 694     [with_dri_drivers=yes])
 695 if test "x$with_dri_drivers" = x; then
 696     with_dri_drivers=no
 697 fi
 698
 699 dnl Determine which APIs to support
 700 AC_ARG_ENABLE([opengl],
 701     [AS_HELP_STRING([--disable-opengl],
 702         [disable support for standard OpenGL API @<:@default=no@:>@])],
 703     [enable_opengl="$enableval"],
 704     [enable_opengl=yes])
 705 AC_ARG_ENABLE([gles1],
 706     [AS_HELP_STRING([--enable-gles1],
 707         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 708     [enable_gles1="$enableval"],
 709     [enable_gles1=no])
 710 AC_ARG_ENABLE([gles2],
 711     [AS_HELP_STRING([--enable-gles2],
 712         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 713     [enable_gles2="$enableval"],
 714     [enable_gles2=no])
 715 AC_ARG_ENABLE([gles-overlay],
 716     [AS_HELP_STRING([--enable-gles-overlay],
 717         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 718     [enable_gles_overlay="$enableval"],
 719     [enable_gles_overlay=no])
 720
 721 API_DEFINES=""
 722 GLES_OVERLAY=0
 723 if test "x$enable_opengl" = xno; then
 724     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 725 else
 726     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 727 fi
 728 if test "x$enable_gles1" = xyes; then
 729     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 730 fi
 731 if test "x$enable_gles2" = xyes; then
 732     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 733 fi
 734 if test "x$enable_gles_overlay" = xyes -o \
 735     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 736     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 737     if test "x$enable_gles_overlay" = xyes; then
 738         GLES_OVERLAY=1
 739     fi
 740 fi
 741 AC_SUBST([API_DEFINES])
 742 AC_SUBST([GLES_OVERLAY])
 743
 744 dnl If $with_dri_drivers is yes, directories will be added through
 745 dnl platform checks
 746 DRI_DIRS=""
 747 case "$with_dri_drivers" in
 748 no) ;;
 749 yes)
 750     DRI_DIRS="yes"
 751     ;;
 752 *)
 753     # verify the requested driver directories exist
 754     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 755     for driver in $dri_drivers; do
 756         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 757             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 758     done
 759     DRI_DIRS="$dri_drivers"
 760     ;;
 761 esac
 762
 763 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 764 if test "$mesa_driver" = dri; then
 765     # Use TLS in GLX?
 766     if test "x$GLX_USE_TLS" = xyes; then
 767         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 768     fi
 769
 770     # Platform specific settings and drivers to build
 771     case "$host_os" in
 772     linux*)
 773         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 774         if test "x$driglx_direct" = xyes; then
 775             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 776         fi
 777         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 778
 779         case "$host_cpu" in
 780         x86_64)
 781             # sis is missing because they have not be converted to use
 782             # the new interface.  i810 are missing because there is no
 783             # x86-64 system where they could *ever* be used.
 784             if test "x$DRI_DIRS" = "xyes"; then
 785                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 786                     savage tdfx unichrome swrast"
 787             fi
 788             ;;
 789         powerpc*)
 790             # Build only the drivers for cards that exist on PowerPC.
 791             # At some point MGA will be added, but not yet.
 792             if test "x$DRI_DIRS" = "xyes"; then
 793                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 794             fi
 795             ;;
 796         sparc*)
 797             # Build only the drivers for cards that exist on sparc`
 798             if test "x$DRI_DIRS" = "xyes"; then
 799                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 800             fi
 801             ;;
 802         esac
 803         ;;
 804     freebsd* | dragonfly*)
 805         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 806         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 807         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 808         if test "x$driglx_direct" = xyes; then
 809             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 810         fi
 811         if test "x$GXX" = xyes; then
 812             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 813         fi
 814
 815         if test "x$DRI_DIRS" = "xyes"; then
 816             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 817                 unichrome savage sis swrast"
 818         fi
 819         ;;
 820     gnu*)
 821         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 822         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 823         ;;
 824     solaris*)
 825         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 826         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 827         if test "x$driglx_direct" = xyes; then
 828             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 829         fi
 830         ;;
 831     esac
 832
 833     # default drivers
 834     if test "x$DRI_DIRS" = "xyes"; then
 835         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 836             savage sis tdfx unichrome swrast"
 837     fi
 838
 839     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 840
 841     # Check for expat
 842     EXPAT_INCLUDES=""
 843     EXPAT_LIB=-lexpat
 844     AC_ARG_WITH([expat],
 845         [AS_HELP_STRING([--with-expat=DIR],
 846             [expat install directory])],[
 847         EXPAT_INCLUDES="-I$withval/include"
 848         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 849         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 850         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 851         ])
 852     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 853     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 854         [AC_MSG_ERROR([Expat required for DRI.])])
 855
 856     # put all the necessary libs together
 857     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 858 fi
 859 AC_SUBST([DRI_DIRS])
 860 AC_SUBST([EXPAT_INCLUDES])
 861 AC_SUBST([DRI_LIB_DEPS])
 862
 863 case $DRI_DIRS in
 864 *i915*|*i965*)
 865     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 866     ;;
 867 esac
 868
 869 case $DRI_DIRS in
 870 *radeon*|*r200*|*r300*|*r600*)
 871     PKG_CHECK_MODULES([LIBDRM_RADEON],
 872                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 873                       HAVE_LIBDRM_RADEON=yes,
 874                       HAVE_LIBDRM_RADEON=no)
 875
 876     if test "$HAVE_LIBDRM_RADEON" = yes; then
 877         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 878         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 879     fi
 880     ;;
 881 esac
 882 AC_SUBST([RADEON_CFLAGS])
 883 AC_SUBST([RADEON_LDFLAGS])
 884
 885
 886 dnl
 887 dnl OSMesa configuration
 888 dnl
 889 if test "$mesa_driver" = xlib; then
 890     default_gl_osmesa=yes
 891 else
 892     default_gl_osmesa=no
 893 fi
 894 AC_ARG_ENABLE([gl-osmesa],
 895     [AS_HELP_STRING([--enable-gl-osmesa],
 896         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 897     [gl_osmesa="$enableval"],
 898     [gl_osmesa="$default_gl_osmesa"])
 899 if test "x$gl_osmesa" = xyes; then
 900     if test "$mesa_driver" = osmesa; then
 901         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 902     else
 903         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 904     fi
 905 fi
 906
 907 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 908 AC_ARG_WITH([osmesa-bits],
 909     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 910         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 911     [osmesa_bits="$withval"],
 912     [osmesa_bits=8])
 913 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 914     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 915     osmesa_bits=8
 916 fi
 917 case "x$osmesa_bits" in
 918 x8)
 919     OSMESA_LIB=OSMesa
 920     ;;
 921 x16|x32)
 922     OSMESA_LIB="OSMesa$osmesa_bits"
 923     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 924     ;;
 925 *)
 926     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 927     ;;
 928 esac
 929 AC_SUBST([OSMESA_LIB])
 930
 931 case "$DRIVER_DIRS" in
 932 *osmesa*)
 933     # only link libraries with osmesa if shared
 934     if test "$enable_static" = no; then
 935         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 936     else
 937         OSMESA_LIB_DEPS=""
 938     fi
 939     OSMESA_MESA_DEPS=""
 940     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 941     ;;
 942 esac
 943 AC_SUBST([OSMESA_LIB_DEPS])
 944 AC_SUBST([OSMESA_MESA_DEPS])
 945 AC_SUBST([OSMESA_PC_REQ])
 946 AC_SUBST([OSMESA_PC_LIB_PRIV])
 947
 948 dnl
 949 dnl EGL configuration
 950 dnl
 951 AC_ARG_ENABLE([egl],
 952     [AS_HELP_STRING([--disable-egl],
 953         [disable EGL library @<:@default=enabled@:>@])],
 954     [enable_egl="$enableval"],
 955     [enable_egl=yes])
 956 if test "x$enable_egl" = xyes; then
 957     SRC_DIRS="$SRC_DIRS egl"
 958     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
 959     EGL_DRIVERS_DIRS=""
 960     if test "$enable_static" != yes; then
 961         # build egl_glx when libGL is built
 962         if test "$mesa_driver" != osmesa; then
 963             EGL_DRIVERS_DIRS="glx"
 964         fi
 965
 966         # build egl_dri2 when xcb-dri2 is available
 967         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
 968                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
 969         if test "$have_xcb_dri2" = yes; then
 970             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
 971         fi
 972     fi
 973 fi
 974 AC_SUBST([EGL_LIB_DEPS])
 975 AC_SUBST([EGL_DRIVERS_DIRS])
 976
 977 dnl
 978 dnl GLU configuration
 979 dnl
 980 AC_ARG_ENABLE([glu],
 981     [AS_HELP_STRING([--disable-glu],
 982         [enable OpenGL Utility library @<:@default=enabled@:>@])],
 983     [enable_glu="$enableval"],
 984     [enable_glu=yes])
 985 if test "x$enable_glu" = xyes; then
 986     SRC_DIRS="$SRC_DIRS glu"
 987
 988     case "$mesa_driver" in
 989     osmesa)
 990         # Link libGLU to libOSMesa instead of libGL
 991         GLU_LIB_DEPS=""
 992         GLU_PC_REQ="osmesa"
 993         if test "$enable_static" = no; then
 994             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
 995         else
 996             GLU_MESA_DEPS=""
 997         fi
 998         ;;
 999     *)
1000         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1001         GLU_PC_REQ="gl"
1002         GLU_PC_LIB_PRIV="-lm"
1003         if test "$enable_static" = no; then
1004             GLU_LIB_DEPS="-lm"
1005             GLU_MESA_DEPS='-l$(GL_LIB)'
1006         else
1007             GLU_LIB_DEPS=""
1008             GLU_MESA_DEPS=""
1009             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1010         fi
1011         ;;
1012     esac
1013 fi
1014 if test "$enable_static" = no; then
1015     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1016 fi
1017 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1018 AC_SUBST([GLU_LIB_DEPS])
1019 AC_SUBST([GLU_MESA_DEPS])
1020 AC_SUBST([GLU_PC_REQ])
1021 AC_SUBST([GLU_PC_REQ_PRIV])
1022 AC_SUBST([GLU_PC_LIB_PRIV])
1023 AC_SUBST([GLU_PC_CFLAGS])
1024
1025 dnl
1026 dnl GLw configuration
1027 dnl
1028 AC_ARG_ENABLE([glw],
1029     [AS_HELP_STRING([--disable-glw],
1030         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1031     [enable_glw="$enableval"],
1032     [enable_glw=yes])
1033 dnl Don't build GLw on osmesa
1034 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1035     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1036     enable_glw=no
1037 fi
1038 AC_ARG_ENABLE([motif],
1039     [AS_HELP_STRING([--enable-motif],
1040         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1041     [enable_motif="$enableval"],
1042     [enable_motif=no])
1043
1044 if test "x$enable_glw" = xyes; then
1045     SRC_DIRS="$SRC_DIRS glw"
1046     if test "$x11_pkgconfig" = yes; then
1047         PKG_CHECK_MODULES([GLW],[x11 xt])
1048         GLW_PC_REQ_PRIV="x11 xt"
1049         GLW_LIB_DEPS="$GLW_LIBS"
1050     else
1051         # should check these...
1052         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1053         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1054         GLW_PC_CFLAGS="$X11_INCLUDES"
1055     fi
1056
1057     GLW_SOURCES="GLwDrawA.c"
1058     MOTIF_CFLAGS=
1059     if test "x$enable_motif" = xyes; then
1060         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1061         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1062         if test "x$MOTIF_CONFIG" != xno; then
1063             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1064             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1065         else
1066             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1067                 [AC_MSG_ERROR([Can't locate Motif headers])])
1068             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1069                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1070         fi
1071         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1072         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1073         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1074         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1075     fi
1076
1077     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1078     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1079     if test "$enable_static" = no; then
1080         GLW_MESA_DEPS='-l$(GL_LIB)'
1081         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1082     else
1083         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1084         GLW_LIB_DEPS=""
1085         GLW_MESA_DEPS=""
1086     fi
1087 fi
1088 AC_SUBST([GLW_LIB_DEPS])
1089 AC_SUBST([GLW_MESA_DEPS])
1090 AC_SUBST([GLW_SOURCES])
1091 AC_SUBST([MOTIF_CFLAGS])
1092 AC_SUBST([GLW_PC_REQ_PRIV])
1093 AC_SUBST([GLW_PC_LIB_PRIV])
1094 AC_SUBST([GLW_PC_CFLAGS])
1095
1096 dnl
1097 dnl GLUT configuration
1098 dnl
1099 if test -f "$srcdir/include/GL/glut.h"; then
1100     default_glut=yes
1101 else
1102     default_glut=no
1103 fi
1104 AC_ARG_ENABLE([glut],
1105     [AS_HELP_STRING([--disable-glut],
1106         [enable GLUT library @<:@default=enabled if source available@:>@])],
1107     [enable_glut="$enableval"],
1108     [enable_glut="$default_glut"])
1109
1110 dnl Can't build glut if GLU not available
1111 if test "x$enable_glu$enable_glut" = xnoyes; then
1112     AC_MSG_WARN([Disabling glut since GLU is disabled])
1113     enable_glut=no
1114 fi
1115 dnl Don't build glut on osmesa
1116 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1117     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1118     enable_glut=no
1119 fi
1120
1121 if test "x$enable_glut" = xyes; then
1122     SRC_DIRS="$SRC_DIRS glut/glx"
1123     GLUT_CFLAGS=""
1124     if test "x$GCC" = xyes; then
1125         GLUT_CFLAGS="-fexceptions"
1126     fi
1127     if test "$x11_pkgconfig" = yes; then
1128         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1129         GLUT_PC_REQ_PRIV="x11 xmu xi"
1130         GLUT_LIB_DEPS="$GLUT_LIBS"
1131     else
1132         # should check these...
1133         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1134         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1135         GLUT_PC_CFLAGS="$X11_INCLUDES"
1136     fi
1137     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1138     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1139
1140     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1141     if test "$enable_static" = no; then
1142         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1143     else
1144         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1145         GLUT_LIB_DEPS=""
1146         GLUT_MESA_DEPS=""
1147     fi
1148 fi
1149 AC_SUBST([GLUT_LIB_DEPS])
1150 AC_SUBST([GLUT_MESA_DEPS])
1151 AC_SUBST([GLUT_CFLAGS])
1152 AC_SUBST([GLUT_PC_REQ_PRIV])
1153 AC_SUBST([GLUT_PC_LIB_PRIV])
1154 AC_SUBST([GLUT_PC_CFLAGS])
1155
1156 dnl
1157 dnl Program library dependencies
1158 dnl    Only libm is added here if necessary as the libraries should
1159 dnl    be pulled in by the linker
1160 dnl
1161 if test "x$APP_LIB_DEPS" = x; then
1162     case "$host_os" in
1163     solaris*)
1164         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1165         ;;
1166     cygwin*)
1167         APP_LIB_DEPS="-lX11"
1168         ;;
1169     *)
1170         APP_LIB_DEPS="-lm"
1171         ;;
1172     esac
1173 fi
1174 AC_SUBST([APP_LIB_DEPS])
1175 AC_SUBST([PROGRAM_DIRS])
1176
1177 dnl
1178 dnl Gallium configuration
1179 dnl
1180 AC_ARG_ENABLE([gallium],
1181     [AS_HELP_STRING([--disable-gallium],
1182         [build gallium @<:@default=enabled@:>@])],
1183     [enable_gallium="$enableval"],
1184     [enable_gallium=yes])
1185 if test "x$enable_gallium" = xyes; then
1186     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1187     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1188                 [HAS_UDIS86="no"])
1189     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1190 fi
1191
1192 AC_SUBST([LLVM_CFLAGS])
1193 AC_SUBST([LLVM_LIBS])
1194 AC_SUBST([LLVM_LDFLAGS])
1195 AC_SUBST([LLVM_VERSION])
1196
1197 VG_LIB_DEPS=""
1198 EGL_CLIENT_APIS='$(GL_LIB)'
1199 if test "x$enable_gles_overlay" = xyes; then
1200     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1201 fi
1202
1203 dnl
1204 dnl Gallium state trackers configuration
1205 dnl
1206 AC_ARG_WITH([state-trackers],
1207     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1208         [comma delimited state_trackers list, e.g.
1209         "egl,glx" @<:@default=auto@:>@])],
1210     [with_state_trackers="$withval"],
1211     [with_state_trackers=yes])
1212
1213 case "$with_state_trackers" in
1214 no)
1215     GALLIUM_STATE_TRACKERS_DIRS=""
1216     ;;
1217 yes)
1218     # look at what else is built
1219     case "$mesa_driver" in
1220     xlib)
1221         GALLIUM_STATE_TRACKERS_DIRS=glx
1222         ;;
1223     dri)
1224         GALLIUM_STATE_TRACKERS_DIRS="dri"
1225         HAVE_ST_DRI="yes"
1226         if test "x$enable_egl" = xyes; then
1227             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1228             HAVE_ST_EGL="yes"
1229         fi
1230         # Have only tested st/xorg on 1.6.0 servers
1231         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1232             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1233             HAVE_ST_XORG="no")
1234         ;;
1235     esac
1236     ;;
1237 *)
1238     # verify the requested state tracker exist
1239     state_trackers=""
1240     _state_trackers=`IFS=', '; echo $with_state_trackers`
1241     for tracker in $_state_trackers; do
1242         case "$tracker" in
1243         dri)
1244             if test "x$mesa_driver" != xdri; then
1245                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1246             fi
1247             HAVE_ST_DRI="yes"
1248             ;;
1249         egl)
1250             if test "x$enable_egl" != xyes; then
1251                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1252             fi
1253             HAVE_ST_EGL="yes"
1254             ;;
1255         xorg)
1256             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1257             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1258             HAVE_ST_XORG="yes"
1259             ;;
1260         es)
1261             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1262
1263             if test "x$enable_gles_overlay" != xyes; then
1264                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1265                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1266                 fi
1267                 GLES_OVERLAY=1
1268                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1269             fi
1270             tracker=""
1271             ;;
1272         vega)
1273             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1274             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1275             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1276             ;;
1277         esac
1278
1279         if test -n "$tracker"; then
1280             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1281                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1282             if test -n "$state_trackers"; then
1283                 state_trackers="$state_trackers $tracker"
1284             else
1285                 state_trackers="$tracker"
1286             fi
1287         fi
1288     done
1289     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1290     ;;
1291 esac
1292
1293 AC_SUBST([VG_LIB_DEPS])
1294 AC_SUBST([EGL_CLIENT_APIS])
1295
1296 if test "x$HAVE_ST_EGL" = xyes; then
1297         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-apis"
1298 fi
1299
1300 if test "x$HAVE_ST_XORG" = xyes; then
1301     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1302         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1303         HAVE_XEXTPROTO_71="no")
1304 fi
1305
1306 AC_ARG_WITH([egl-platforms],
1307     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1308         [comma delimited native platforms libEGL supports, e.g.
1309         "x11,kms" @<:@default=auto@:>@])],
1310     [with_egl_platforms="$withval"],
1311     [with_egl_platforms=yes])
1312 AC_ARG_WITH([egl-displays],
1313     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1314         [DEPRECATED.  Use --with-egl-platforms instead])],
1315     [with_egl_platforms="$withval"])
1316
1317 EGL_PLATFORMS=""
1318 case "$with_egl_platforms" in
1319 yes)
1320     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1321         EGL_PLATFORMS="x11"
1322     fi
1323     ;;
1324 *)
1325     if test "x$enable_egl" != xyes; then
1326         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1327     fi
1328     # verify the requested driver directories exist
1329     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1330     for plat in $egl_platforms; do
1331         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1332             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1333         if test "$plat" = "fbdev"; then
1334                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1335         fi
1336     done
1337     EGL_PLATFORMS="$egl_platforms"
1338     ;;
1339 esac
1340 AC_SUBST([EGL_PLATFORMS])
1341
1342 AC_ARG_WITH([egl-driver-dir],
1343     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1344                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1345     [EGL_DRIVER_INSTALL_DIR="$withval"],
1346     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1347 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1348
1349 AC_ARG_WITH([xorg-driver-dir],
1350     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1351                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1352     [XORG_DRIVER_INSTALL_DIR="$withval"],
1353     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1354 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1355
1356 AC_ARG_WITH([max-width],
1357     [AS_HELP_STRING([--with-max-width=N],
1358                     [Maximum framebuffer width (4096)])],
1359     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1360      AS_IF([test "${withval}" -gt "4096"],
1361            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1362 )
1363 AC_ARG_WITH([max-height],
1364     [AS_HELP_STRING([--with-max-height=N],
1365                     [Maximum framebuffer height (4096)])],
1366     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1367      AS_IF([test "${withval}" -gt "4096"],
1368            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1369 )
1370
1371 dnl
1372 dnl Gallium LLVM
1373 dnl
1374 AC_ARG_ENABLE([gallium-llvm],
1375     [AS_HELP_STRING([--enable-gallium-llvm],
1376         [build gallium LLVM support @<:@default=disabled@:>@])],
1377     [enable_gallium_llvm="$enableval"],
1378     [enable_gallium_llvm=auto])
1379 if test "x$enable_gallium_llvm" = xyes; then
1380     if test "x$LLVM_CONFIG" != xno; then
1381         LLVM_VERSION=`$LLVM_CONFIG --version`
1382         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1383         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1384
1385         if test "x$HAS_UDIS86" != xno; then
1386             LLVM_LIBS="$LLVM_LIBS -ludis86"
1387             DEFINES="$DEFINES -DHAVE_UDIS86"
1388         fi
1389         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1390         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1391         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1392         MESA_LLVM=1
1393     else
1394         MESA_LLVM=0
1395     fi
1396 else
1397     MESA_LLVM=0
1398 fi
1399
1400 dnl
1401 dnl Gallium helper functions
1402 dnl
1403 gallium_check_st() {
1404     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1405          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1406     fi
1407     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1408          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1409     fi
1410     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1411          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1412     fi
1413     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1414          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1415     fi
1416 }
1417
1418
1419 dnl
1420 dnl Gallium SVGA configuration
1421 dnl
1422 AC_ARG_ENABLE([gallium-svga],
1423     [AS_HELP_STRING([--enable-gallium-svga],
1424         [build gallium SVGA @<:@default=disabled@:>@])],
1425     [enable_gallium_svga="$enableval"],
1426     [enable_gallium_svga=auto])
1427 if test "x$enable_gallium_svga" = xyes; then
1428     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1429     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1430 elif test "x$enable_gallium_svga" = xauto; then
1431     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1432 fi
1433
1434 dnl
1435 dnl Gallium Intel configuration
1436 dnl
1437 AC_ARG_ENABLE([gallium-intel],
1438     [AS_HELP_STRING([--enable-gallium-intel],
1439         [build gallium intel @<:@default=disabled@:>@])],
1440     [enable_gallium_intel="$enableval"],
1441     [enable_gallium_intel=auto])
1442 if test "x$enable_gallium_intel" = xyes; then
1443     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1444     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1445     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1446 elif test "x$enable_gallium_intel" = xauto; then
1447     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1448     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1449 fi
1450
1451 dnl
1452 dnl Gallium Radeon configuration
1453 dnl
1454 AC_ARG_ENABLE([gallium-radeon],
1455     [AS_HELP_STRING([--enable-gallium-radeon],
1456         [build gallium radeon @<:@default=disabled@:>@])],
1457     [enable_gallium_radeon="$enableval"],
1458     [enable_gallium_radeon=auto])
1459 if test "x$enable_gallium_radeon" = xyes; then
1460     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1461     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1462 elif test "x$enable_gallium_radeon" = xauto; then
1463     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1464 fi
1465
1466 dnl
1467 dnl Gallium Radeon r600g configuration
1468 dnl
1469 AC_ARG_ENABLE([gallium-r600],
1470     [AS_HELP_STRING([--enable-gallium-r600],
1471         [build gallium radeon @<:@default=disabled@:>@])],
1472     [enable_gallium_r600="$enableval"],
1473     [enable_gallium_r600=auto])
1474 if test "x$enable_gallium_r600" = xyes; then
1475     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1476     gallium_check_st "r600/drm" "dri-r600"
1477 fi
1478
1479 dnl
1480 dnl Gallium Nouveau configuration
1481 dnl
1482 AC_ARG_ENABLE([gallium-nouveau],
1483     [AS_HELP_STRING([--enable-gallium-nouveau],
1484         [build gallium nouveau @<:@default=disabled@:>@])],
1485     [enable_gallium_nouveau="$enableval"],
1486     [enable_gallium_nouveau=no])
1487 if test "x$enable_gallium_nouveau" = xyes; then
1488     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1489     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1490 fi
1491
1492 dnl
1493 dnl Gallium swrast configuration
1494 dnl
1495 AC_ARG_ENABLE([gallium-swrast],
1496     [AS_HELP_STRING([--enable-gallium-swrast],
1497         [build gallium swrast @<:@default=auto@:>@])],
1498     [enable_gallium_swrast="$enableval"],
1499     [enable_gallium_swrast=auto])
1500 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1501     if test "x$HAVE_ST_DRI" = xyes; then
1502         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1503     fi
1504     if test "x$HAVE_ST_EGL" = xyes; then
1505         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1506     fi
1507 fi
1508
1509 dnl prepend CORE_DIRS to SRC_DIRS
1510 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1511
1512 dnl Restore LDFLAGS and CPPFLAGS
1513 LDFLAGS="$_SAVE_LDFLAGS"
1514 CPPFLAGS="$_SAVE_CPPFLAGS"
1515
1516 dnl Substitute the config
1517 AC_CONFIG_FILES([configs/autoconf])
1518
1519 dnl Replace the configs/current symlink
1520 AC_CONFIG_COMMANDS([configs],[
1521 if test -f configs/current || test -L configs/current; then
1522     rm -f configs/current
1523 fi
1524 ln -s autoconf configs/current
1525 ])
1526
1527 AC_OUTPUT
1528
1529 dnl
1530 dnl Output some configuration info for the user
1531 dnl
1532 echo ""
1533 echo "        prefix:          $prefix"
1534 echo "        exec_prefix:     $exec_prefix"
1535 echo "        libdir:          $libdir"
1536 echo "        includedir:      $includedir"
1537
1538 dnl Driver info
1539 echo ""
1540 echo "        Driver:          $mesa_driver"
1541 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1542     echo "        OSMesa:          lib$OSMESA_LIB"
1543 else
1544     echo "        OSMesa:          no"
1545 fi
1546 if test "$mesa_driver" = dri; then
1547     # cleanup the drivers var
1548     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1549 if test "x$DRI_DIRS" = x; then
1550     echo "        DRI drivers:     no"
1551 else
1552     echo "        DRI drivers:     $dri_dirs"
1553 fi
1554     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1555 fi
1556 echo "        Use XCB:         $enable_xcb"
1557
1558 echo ""
1559 if test "x$MESA_LLVM" = x1; then
1560     echo "        llvm:            yes"
1561     echo "        llvm-config:     $LLVM_CONFIG"
1562     echo "        llvm-version:    $LLVM_VERSION"
1563 else
1564     echo "        llvm:            no"
1565 fi
1566
1567 echo ""
1568 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1569     echo "        Gallium:         yes"
1570     echo "        Gallium dirs:    $GALLIUM_DIRS"
1571     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1572     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1573     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1574     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1575     if test "x$HAVE_ST_EGL" = xyes; then
1576         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1577     fi
1578 else
1579     echo "        Gallium:         no"
1580 fi
1581
1582 dnl Libraries
1583 echo ""
1584 echo "        Shared libs:     $enable_shared"
1585 echo "        Static libs:     $enable_static"
1586 if test "$enable_egl" = yes; then
1587     echo "        EGL:             $EGL_DRIVERS_DIRS"
1588     echo "        EGL platforms:   $EGL_PLATFORMS"
1589 else
1590     echo "        EGL:             no"
1591 fi
1592 echo "        GLU:             $enable_glu"
1593 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1594 echo "        glut:            $enable_glut"
1595
1596 dnl Compiler options
1597 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1598 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1599     $SED 's/^ *//;s/  */ /;s/ *$//'`
1600 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1601     $SED 's/^ *//;s/  */ /;s/ *$//'`
1602 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1603 echo ""
1604 echo "        CFLAGS:          $cflags"
1605 echo "        CXXFLAGS:        $cxxflags"
1606 echo "        Macros:          $defines"
1607
1608 echo ""
1609 echo "        Run '${MAKE-make}' to build Mesa"
1610 echo ""