configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.38
  31 LIBDRM_RADEON_REQUIRED=2.4.56
  32 LIBDRM_INTEL_REQUIRED=2.4.52
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.57
  36 DRI2PROTO_REQUIRED=2.6
  37 DRI3PROTO_REQUIRED=1.0
  38 PRESENTPROTO_REQUIRED=1.0
  39 LIBUDEV_REQUIRED=151
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  42 VDPAU_REQUIRED=0.4.1
  43 WAYLAND_REQUIRED=1.2.0
  44 XCB_REQUIRED=1.9.3
  45 XCBDRI2_REQUIRED=1.8
  46 XCBGLX_REQUIRED=1.8.1
  47 XSHMFENCE_REQUIRED=1.1
  48 XVMC_REQUIRED=1.0.6
  49
  50 dnl Check for progs
  51 AC_PROG_CPP
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54 AM_PROG_CC_C_O
  55 AM_PROG_AS
  56 AX_CHECK_GNU_MAKE
  57 AC_CHECK_PROGS([PYTHON2], [python2 python])
  58 AC_PROG_SED
  59 AC_PROG_MKDIR_P
  60
  61 AC_SYS_LARGEFILE
  62
  63 LT_PREREQ([2.2])
  64 LT_INIT([disable-static])
  65
  66 AX_PROG_BISON([],
  67               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  68                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  69 AX_PROG_FLEX([],
  70              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  71                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  72
  73 AC_CHECK_PROG(INDENT, indent, indent, cat)
  74 if test "x$INDENT" != "xcat"; then
  75     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  76 fi
  77
  78 AC_PROG_INSTALL
  79
  80 dnl We need a POSIX shell for parts of the build. Assume we have one
  81 dnl in most cases.
  82 case "$host_os" in
  83 solaris*)
  84     # Solaris /bin/sh is too old/non-POSIX compliant
  85     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  86     SHELL="$POSIX_SHELL"
  87     ;;
  88 esac
  89
  90 dnl clang is mostly GCC-compatible, but its version is much lower,
  91 dnl so we have to check for it.
  92 AC_MSG_CHECKING([if compiling with clang])
  93
  94 AC_COMPILE_IFELSE(
  95 [AC_LANG_PROGRAM([], [[
  96 #ifndef __clang__
  97        not clang
  98 #endif
  99 ]])],
 100 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 101
 102 AC_MSG_RESULT([$acv_mesa_CLANG])
 103
 104 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 105 dnl versions are explictly not supported.
 106 GEN_ASM_OFFSETS=no
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124
 125     if test "x$cross_compiling" = xyes; then
 126         GEN_ASM_OFFSETS=yes
 127     fi
 128 fi
 129
 130 dnl Check for compiler builtins
 131 AX_GCC_BUILTIN([__builtin_bswap32])
 132 AX_GCC_BUILTIN([__builtin_bswap64])
 133 AX_GCC_BUILTIN([__builtin_clz])
 134 AX_GCC_BUILTIN([__builtin_clzll])
 135 AX_GCC_BUILTIN([__builtin_ctz])
 136 AX_GCC_BUILTIN([__builtin_expect])
 137 AX_GCC_BUILTIN([__builtin_ffs])
 138 AX_GCC_BUILTIN([__builtin_ffsll])
 139 AX_GCC_BUILTIN([__builtin_popcount])
 140 AX_GCC_BUILTIN([__builtin_popcountll])
 141 AX_GCC_BUILTIN([__builtin_unreachable])
 142
 143 AX_GCC_FUNC_ATTRIBUTE([flatten])
 144 AX_GCC_FUNC_ATTRIBUTE([format])
 145 AX_GCC_FUNC_ATTRIBUTE([malloc])
 146 AX_GCC_FUNC_ATTRIBUTE([packed])
 147
 148 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 149
 150 dnl Make sure the pkg-config macros are defined
 151 m4_ifndef([PKG_PROG_PKG_CONFIG],
 152     [m4_fatal([Could not locate the pkg-config autoconf macros.
 153   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 154   are in a different location, try setting the environment variable
 155   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 156 PKG_PROG_PKG_CONFIG()
 157
 158 dnl LIB_DIR - library basename
 159 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 160 AC_SUBST([LIB_DIR])
 161
 162 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 163 _SAVE_LDFLAGS="$LDFLAGS"
 164 _SAVE_CPPFLAGS="$CPPFLAGS"
 165
 166 dnl Compiler macros
 167 DEFINES="-DUSE_EXTERNAL_DXTN_LIB=1"
 168 AC_SUBST([DEFINES])
 169 case "$host_os" in
 170 linux*|*-gnu*|gnu*)
 171     DEFINES="$DEFINES -D_GNU_SOURCE"
 172     ;;
 173 solaris*)
 174     DEFINES="$DEFINES -DSVR4"
 175     ;;
 176 cygwin*)
 177     DEFINES="$DEFINES -D_XOPEN_SOURCE=700"
 178     ;;
 179 esac
 180
 181 dnl Add flags for gcc and g++
 182 if test "x$GCC" = xyes; then
 183     CFLAGS="$CFLAGS -Wall -std=c99"
 184
 185     # Enable -Werror=implicit-function-declaration and
 186     # -Werror=missing-prototypes, if available, or otherwise, just
 187     # -Wmissing-prototypes.  This is particularly useful to avoid
 188     # generating a loadable driver module that has undefined symbols.
 189     save_CFLAGS="$CFLAGS"
 190     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 191     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 192     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 193     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 194                    AC_MSG_RESULT([yes]),
 195                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 196                     AC_MSG_RESULT([no])]);
 197
 198     # Enable -fvisibility=hidden if using a gcc that supports it
 199     save_CFLAGS="$CFLAGS"
 200     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 201     VISIBILITY_CFLAGS="-fvisibility=hidden"
 202     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 204                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 205
 206     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 207     CFLAGS=$save_CFLAGS
 208
 209     # Work around aliasing bugs - developers should comment this out
 210     CFLAGS="$CFLAGS -fno-strict-aliasing"
 211
 212     # gcc's builtin memcmp is slower than glibc's
 213     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 214     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 215 fi
 216 if test "x$GXX" = xyes; then
 217     CXXFLAGS="$CXXFLAGS -Wall"
 218
 219     # Enable -fvisibility=hidden if using a gcc that supports it
 220     save_CXXFLAGS="$CXXFLAGS"
 221     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 222     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 223     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 224     AC_LANG_PUSH([C++])
 225     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 226                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 227     AC_LANG_POP([C++])
 228
 229     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 230     CXXFLAGS=$save_CXXFLAGS
 231
 232     # Work around aliasing bugs - developers should comment this out
 233     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 234
 235     # gcc's builtin memcmp is slower than glibc's
 236     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Optional flags, check for compiler support
 254 dnl
 255 AX_CHECK_COMPILE_FLAG([-msse4.1], [SSE41_SUPPORTED=1], [SSE41_SUPPORTED=0])
 256 if test "x$SSE41_SUPPORTED" = x1; then
 257     DEFINES="$DEFINES -DUSE_SSE41"
 258 fi
 259 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 260
 261 dnl Can't have static and shared libraries, default to static if user
 262 dnl explicitly requested. If both disabled, set to static since shared
 263 dnl was explicitly requested.
 264 case "x$enable_static$enable_shared" in
 265 xyesyes)
 266     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 267     enable_shared=no
 268     ;;
 269 xnono)
 270     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 271     enable_shared=yes
 272     ;;
 273 esac
 274
 275 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 276
 277 dnl
 278 dnl other compiler options
 279 dnl
 280 AC_ARG_ENABLE([debug],
 281     [AS_HELP_STRING([--enable-debug],
 282         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 283     [enable_debug="$enableval"],
 284     [enable_debug=no]
 285 )
 286 if test "x$enable_debug" = xyes; then
 287     DEFINES="$DEFINES -DDEBUG"
 288     if test "x$GCC" = xyes; then
 289         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 290             CFLAGS="$CFLAGS -g"
 291         fi
 292         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 293             CFLAGS="$CFLAGS -O0"
 294         fi
 295     fi
 296     if test "x$GXX" = xyes; then
 297         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 298             CXXFLAGS="$CXXFLAGS -g"
 299         fi
 300         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 301             CXXFLAGS="$CXXFLAGS -O0"
 302         fi
 303     fi
 304 fi
 305
 306 dnl
 307 dnl Check if linker supports -Bsymbolic
 308 dnl
 309 save_LDFLAGS=$LDFLAGS
 310 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 311 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 312 AC_LINK_IFELSE(
 313     [AC_LANG_SOURCE([int main() { return 0;}])],
 314     [AC_MSG_RESULT([yes])
 315         BSYMBOLIC="-Wl,-Bsymbolic";],
 316     [AC_MSG_RESULT([no])
 317         BSYMBOLIC="";])
 318 LDFLAGS=$save_LDFLAGS
 319
 320 AC_SUBST([BSYMBOLIC])
 321
 322 dnl
 323 dnl Check if linker supports garbage collection
 324 dnl
 325 save_LDFLAGS=$LDFLAGS
 326 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 327 AC_MSG_CHECKING([whether ld supports --gc-sections])
 328 AC_LINK_IFELSE(
 329     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 330     [AC_MSG_RESULT([yes])
 331         GC_SECTIONS="-Wl,--gc-sections";],
 332     [AC_MSG_RESULT([no])
 333         GC_SECTIONS="";])
 334 LDFLAGS=$save_LDFLAGS
 335
 336 AC_SUBST([GC_SECTIONS])
 337
 338 dnl
 339 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 340 dnl so when these flags are passed to ld via libtool the checks will fail
 341 dnl
 342 case "$host_os" in
 343 openbsd* | darwin* )
 344     LD_NO_UNDEFINED="" ;;
 345 *)
 346     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 347 esac
 348
 349 AC_SUBST([LD_NO_UNDEFINED])
 350
 351 dnl
 352 dnl Check if linker supports version scripts
 353 dnl
 354 AC_MSG_CHECKING([if the linker supports version-scripts])
 355 save_LDFLAGS=$LDFLAGS
 356 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 357 cat > conftest.map <<EOF
 358 VERSION_1 {
 359      global:
 360          main;
 361
 362      local:
 363          *;
 364 };
 365 EOF
 366 AC_LINK_IFELSE(
 367     [AC_LANG_SOURCE([int main() { return 0;}])],
 368     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 369     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 370 LDFLAGS=$save_LDFLAGS
 371 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 372
 373 dnl
 374 dnl Check if linker supports dynamic list files
 375 dnl
 376 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 377 save_LDFLAGS=$LDFLAGS
 378 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 379 cat > conftest.dyn <<EOF
 380 {
 381         radeon_drm_winsys_create;
 382 };
 383 EOF
 384 AC_LINK_IFELSE(
 385     [AC_LANG_SOURCE([int main() { return 0;}])],
 386     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 387     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 388 LDFLAGS=$save_LDFLAGS
 389 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 390
 391 dnl
 392 dnl compatibility symlinks
 393 dnl
 394 case "$host_os" in
 395 linux* )
 396     HAVE_COMPAT_SYMLINKS=yes ;;
 397 * )
 398     HAVE_COMPAT_SYMLINKS=no ;;
 399 esac
 400
 401 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 402
 403 dnl
 404 dnl library names
 405 dnl
 406 case "$host_os" in
 407 darwin* )
 408     LIB_EXT='dylib' ;;
 409 cygwin* )
 410     LIB_EXT='dll' ;;
 411 aix* )
 412     LIB_EXT='a' ;;
 413 * )
 414     LIB_EXT='so' ;;
 415 esac
 416
 417 AC_SUBST([LIB_EXT])
 418
 419 AC_ARG_WITH([gl-lib-name],
 420   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 421     [specify GL library name @<:@default=GL@:>@])],
 422   [GL_LIB=$withval],
 423   [GL_LIB=GL])
 424 AC_ARG_WITH([osmesa-lib-name],
 425   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 426     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 427   [OSMESA_LIB=$withval],
 428   [OSMESA_LIB=OSMesa])
 429 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 430 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 431
 432 dnl
 433 dnl Mangled Mesa support
 434 dnl
 435 AC_ARG_ENABLE([mangling],
 436   [AS_HELP_STRING([--enable-mangling],
 437     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 438   [enable_mangling="${enableval}"],
 439   [enable_mangling=no]
 440 )
 441 if test "x${enable_mangling}" = "xyes" ; then
 442   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 443   GL_LIB="Mangled${GL_LIB}"
 444   OSMESA_LIB="Mangled${OSMESA_LIB}"
 445 fi
 446 AC_SUBST([GL_LIB])
 447 AC_SUBST([OSMESA_LIB])
 448
 449 dnl
 450 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 451 dnl
 452 AC_ARG_ENABLE([texture-float],
 453     [AS_HELP_STRING([--enable-texture-float],
 454         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 455     [enable_texture_float="$enableval"],
 456     [enable_texture_float=no]
 457 )
 458 if test "x$enable_texture_float" = xyes; then
 459     AC_MSG_WARN([Floating-point textures enabled.])
 460     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 461     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 462 fi
 463
 464 dnl
 465 dnl Arch/platform-specific settings
 466 dnl
 467 AC_ARG_ENABLE([asm],
 468     [AS_HELP_STRING([--disable-asm],
 469         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 470     [enable_asm="$enableval"],
 471     [enable_asm=yes]
 472 )
 473 asm_arch=""
 474 AC_MSG_CHECKING([whether to enable assembly])
 475 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 476 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 477 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 478     case "$host_cpu" in
 479     i?86 | x86_64 | amd64)
 480         enable_asm=no
 481         AC_MSG_RESULT([no, cross compiling])
 482         ;;
 483     esac
 484 fi
 485 # check for supported arches
 486 if test "x$enable_asm" = xyes; then
 487     case "$host_cpu" in
 488     i?86)
 489         case "$host_os" in
 490         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 491             asm_arch=x86
 492             ;;
 493         esac
 494         ;;
 495     x86_64|amd64)
 496         case "$host_os" in
 497         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 498             asm_arch=x86_64
 499             ;;
 500         esac
 501         ;;
 502     sparc*)
 503         case "$host_os" in
 504         linux*)
 505             asm_arch=sparc
 506             ;;
 507         esac
 508         ;;
 509     esac
 510
 511     case "$asm_arch" in
 512     x86)
 513         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 514         AC_MSG_RESULT([yes, x86])
 515         ;;
 516     x86_64|amd64)
 517         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 518         AC_MSG_RESULT([yes, x86_64])
 519         ;;
 520     sparc)
 521         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 522         AC_MSG_RESULT([yes, sparc])
 523         ;;
 524     *)
 525         AC_MSG_RESULT([no, platform not supported])
 526         ;;
 527     esac
 528 fi
 529
 530 dnl Check to see if dlopen is in default libraries (like Solaris, which
 531 dnl has it in libc), or if libdl is needed to get it.
 532 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 533     [AC_CHECK_LIB([dl], [dlopen],
 534        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 535 AC_SUBST([DLOPEN_LIBS])
 536
 537 dnl Check if that library also has dladdr
 538 save_LIBS="$LIBS"
 539 LIBS="$LIBS $DLOPEN_LIBS"
 540 AC_CHECK_FUNCS([dladdr])
 541 LIBS="$save_LIBS"
 542
 543 case "$host_os" in
 544 darwin*|mingw*)
 545     ;;
 546 *)
 547     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 548                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 549                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 550     AC_SUBST([CLOCK_LIB])
 551     ;;
 552 esac
 553
 554 dnl See if posix_memalign is available
 555 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 556
 557 dnl Check for pthreads
 558 case "$host_os" in
 559 mingw*)
 560     ;;
 561 *)
 562     AX_PTHREAD
 563     ;;
 564 esac
 565 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 566 dnl to -pthread, which causes problems if we need -lpthread to appear in
 567 dnl pkgconfig files.
 568 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 569
 570 dnl SELinux awareness.
 571 AC_ARG_ENABLE([selinux],
 572     [AS_HELP_STRING([--enable-selinux],
 573         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 574     [MESA_SELINUX="$enableval"],
 575     [MESA_SELINUX=no])
 576 if test "x$enable_selinux" = "xyes"; then
 577     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 578         [AC_CHECK_HEADER([selinux/selinux.h],[],
 579                          [AC_MSG_ERROR([SELinux headers not found])])
 580          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 581                       [AC_MSG_ERROR([SELinux library not found])])
 582          SELINUX_LIBS="-lselinux"])
 583     DEFINES="$DEFINES -DMESA_SELINUX"
 584 fi
 585 AC_SUBST([SELINUX_CFLAGS])
 586 AC_SUBST([SELINUX_LIBS])
 587
 588 dnl Options for APIs
 589 AC_ARG_ENABLE([opengl],
 590     [AS_HELP_STRING([--disable-opengl],
 591         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 592     [enable_opengl="$enableval"],
 593     [enable_opengl=yes])
 594 AC_ARG_ENABLE([gles1],
 595     [AS_HELP_STRING([--enable-gles1],
 596         [enable support for OpenGL ES 1.x API @<:@default=disabled@:>@])],
 597     [enable_gles1="$enableval"],
 598     [enable_gles1=no])
 599 AC_ARG_ENABLE([gles2],
 600     [AS_HELP_STRING([--enable-gles2],
 601         [enable support for OpenGL ES 2.x API @<:@default=disabled@:>@])],
 602     [enable_gles2="$enableval"],
 603     [enable_gles2=no])
 604 AC_ARG_ENABLE([openvg],
 605     [AS_HELP_STRING([--enable-openvg],
 606         [enable support for OpenVG API @<:@default=disabled@:>@])],
 607     [enable_openvg="$enableval"],
 608     [enable_openvg=no])
 609
 610 AC_ARG_ENABLE([dri],
 611     [AS_HELP_STRING([--enable-dri],
 612         [enable DRI modules @<:@default=enabled@:>@])],
 613     [enable_dri="$enableval"],
 614     [enable_dri=yes])
 615
 616 case "$host_os" in
 617 linux*)
 618     dri3_default=yes
 619     ;;
 620 *)
 621     dri3_default=no
 622     ;;
 623 esac
 624 AC_ARG_ENABLE([dri3],
 625     [AS_HELP_STRING([--enable-dri3],
 626         [enable DRI3 @<:@default=auto@:>@])],
 627     [enable_dri3="$enableval"],
 628     [enable_dri3="$dri3_default"])
 629 AC_ARG_ENABLE([glx],
 630     [AS_HELP_STRING([--enable-glx],
 631         [enable GLX library @<:@default=enabled@:>@])],
 632     [enable_glx="$enableval"],
 633     [enable_glx=yes])
 634 AC_ARG_ENABLE([osmesa],
 635     [AS_HELP_STRING([--enable-osmesa],
 636         [enable OSMesa library @<:@default=disabled@:>@])],
 637     [enable_osmesa="$enableval"],
 638     [enable_osmesa=no])
 639 AC_ARG_ENABLE([gallium-osmesa],
 640     [AS_HELP_STRING([--enable-gallium-osmesa],
 641         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 642     [enable_gallium_osmesa="$enableval"],
 643     [enable_gallium_osmesa=no])
 644 AC_ARG_ENABLE([egl],
 645     [AS_HELP_STRING([--disable-egl],
 646         [disable EGL library @<:@default=enabled@:>@])],
 647     [enable_egl="$enableval"],
 648     [enable_egl=yes])
 649
 650 AC_ARG_ENABLE([xa],
 651     [AS_HELP_STRING([--enable-xa],
 652         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 653     [enable_xa="$enableval"],
 654     [enable_xa=no])
 655 AC_ARG_ENABLE([gbm],
 656    [AS_HELP_STRING([--enable-gbm],
 657          [enable gbm library @<:@default=auto@:>@])],
 658    [enable_gbm="$enableval"],
 659    [enable_gbm=auto])
 660
 661 AC_ARG_ENABLE([xvmc],
 662    [AS_HELP_STRING([--enable-xvmc],
 663          [enable xvmc library @<:@default=auto@:>@])],
 664    [enable_xvmc="$enableval"],
 665    [enable_xvmc=auto])
 666 AC_ARG_ENABLE([vdpau],
 667    [AS_HELP_STRING([--enable-vdpau],
 668          [enable vdpau library @<:@default=auto@:>@])],
 669    [enable_vdpau="$enableval"],
 670    [enable_vdpau=auto])
 671 AC_ARG_ENABLE([omx],
 672    [AS_HELP_STRING([--enable-omx],
 673          [enable OpenMAX library @<:@default=disabled@:>@])],
 674    [enable_omx="$enableval"],
 675    [enable_omx=no])
 676 AC_ARG_ENABLE([va],
 677    [AS_HELP_STRING([--enable-va],
 678          [enable va library @<:@default=auto@:>@])],
 679    [enable_va="$enableval"],
 680    [enable_va=auto])
 681 AC_ARG_ENABLE([opencl],
 682    [AS_HELP_STRING([--enable-opencl],
 683          [enable OpenCL library @<:@default=disabled@:>@])],
 684    [enable_opencl="$enableval"],
 685    [enable_opencl=no])
 686 AC_ARG_ENABLE([opencl_icd],
 687    [AS_HELP_STRING([--enable-opencl-icd],
 688           [Build an OpenCL ICD library to be loaded by an ICD implementation
 689            @<:@default=disabled@:>@])],
 690     [enable_opencl_icd="$enableval"],
 691     [enable_opencl_icd=no])
 692 AC_ARG_ENABLE([xlib-glx],
 693     [AS_HELP_STRING([--enable-xlib-glx],
 694         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 695     [enable_xlib_glx="$enableval"],
 696     [enable_xlib_glx=no])
 697 AC_ARG_ENABLE([gallium-egl],
 698     [AS_HELP_STRING([--enable-gallium-egl],
 699         [enable optional EGL state tracker (not required
 700          for EGL support in Gallium with OpenGL and OpenGL ES)
 701          @<:@default=disabled@:>@])],
 702     [enable_gallium_egl="$enableval"],
 703     [enable_gallium_egl=no])
 704 AC_ARG_ENABLE([gallium-gbm],
 705     [AS_HELP_STRING([--enable-gallium-gbm],
 706         [enable optional gbm state tracker (not required for
 707          gbm support in Gallium)
 708          @<:@default=auto@:>@])],
 709     [enable_gallium_gbm="$enableval"],
 710     [enable_gallium_gbm=auto])
 711
 712 AC_ARG_ENABLE([r600-llvm-compiler],
 713     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 714         [Enable experimental LLVM backend for graphics shaders @<:@default=disabled@:>@])],
 715     [enable_r600_llvm="$enableval"],
 716     [enable_r600_llvm=no])
 717
 718 AC_ARG_ENABLE([gallium-tests],
 719     [AS_HELP_STRING([--enable-gallium-tests],
 720         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
 721     [enable_gallium_tests="$enableval"],
 722     [enable_gallium_tests=no])
 723
 724 # Option for Gallium drivers
 725
 726 # Keep this in sync with the --with-gallium-drivers help string default value
 727 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 728
 729 AC_ARG_WITH([gallium-drivers],
 730     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 731         [comma delimited Gallium drivers list, e.g.
 732         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4"
 733         @<:@default=r300,r600,svga,swrast@:>@])],
 734     [with_gallium_drivers="$withval"],
 735     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 736
 737 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 738 # here so that the script doesn't choke on an unknown driver name later.
 739 case "$with_gallium_drivers" in
 740     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 741     no) with_gallium_drivers='' ;;
 742 esac
 743
 744 if test "x$enable_opengl" = xno -a \
 745         "x$enable_gles1" = xno -a \
 746         "x$enable_gles2" = xno -a \
 747         "x$enable_openvg" = xno -a \
 748         "x$enable_xa" = xno -a \
 749         "x$enable_xvmc" = xno -a \
 750         "x$enable_vdpau" = xno -a \
 751         "x$enable_omx" = xno -a \
 752         "x$enable_va" = xno -a \
 753         "x$enable_opencl" = xno; then
 754     AC_MSG_ERROR([at least one API should be enabled])
 755 fi
 756
 757 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 758 if test "x$enable_opengl" = xno -a \
 759         "x$enable_gles1" = xyes; then
 760     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 761 fi
 762
 763 if test "x$enable_opengl" = xno -a \
 764         "x$enable_gles2" = xyes; then
 765     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 766 fi
 767
 768 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 769 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 770 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 771 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 772                                         "x$enable_gles1" = xyes -o \
 773                                         "x$enable_gles2" = xyes)
 774
 775 if test "x$enable_glx" = xno; then
 776     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 777     enable_xlib_glx=no
 778 fi
 779
 780 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 781     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 782 fi
 783
 784 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 785     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 786 fi
 787
 788 # Disable GLX if OpenGL is not enabled
 789 if test "x$enable_glx$enable_opengl" = xyesno; then
 790     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 791     enable_glx=no
 792 fi
 793
 794 # Disable GLX if DRI and Xlib-GLX are not enabled
 795 if test "x$enable_glx" = xyes -a \
 796         "x$enable_dri" = xno -a \
 797         "x$enable_xlib_glx" = xno; then
 798     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 799     enable_glx=no
 800 fi
 801
 802 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 803                                   "x$enable_dri" = xyes)
 804
 805 # Select which platform-dependent DRI code gets built
 806 case "$host_os" in
 807 darwin*)
 808     dri_platform='apple' ;;
 809 gnu*|mingw*|cygwin*)
 810     dri_platform='none' ;;
 811 *)
 812     dri_platform='drm' ;;
 813 esac
 814
 815 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
 816 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
 817 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm )
 818 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm )
 819 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
 820
 821 AC_ARG_ENABLE([shared-glapi],
 822     [AS_HELP_STRING([--enable-shared-glapi],
 823         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
 824     [enable_shared_glapi="$enableval"],
 825     [enable_shared_glapi=yes])
 826
 827 case "x$enable_opengl$enable_gles1$enable_gles2" in
 828 x*yes*yes*)
 829     if test "x$enable_shared_glapi" = xno; then
 830         AC_MSG_ERROR([shared GLAPI required when building two or more of
 831                       the following APIs - opengl, gles1 gles2])
 832     fi
 833     ;;
 834 esac
 835
 836 # Building Xlib-GLX requires shared glapi to be disabled.
 837 if test "x$enable_xlib_glx" = xyes; then
 838     AC_MSG_NOTICE([Shared GLAPI should not used with Xlib-GLX, disabling])
 839     enable_shared_glapi=no
 840 fi
 841
 842 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 843
 844 # Build the pipe-drivers as separate libraries/modules.
 845 # Do not touch this unless you know what you are doing.
 846 # XXX: Expose via configure option ?
 847 enable_shared_pipe_drivers=no
 848
 849 dnl
 850 dnl Driver specific build directories
 851 dnl
 852
 853 case "x$enable_glx$enable_xlib_glx" in
 854 xyesyes)
 855     NEED_WINSYS_XLIB="yes"
 856     ;;
 857 esac
 858
 859 if test "x$enable_dri" = xyes; then
 860     enable_gallium_loader="$enable_shared_pipe_drivers"
 861 fi
 862
 863 if test "x$enable_gallium_osmesa" = xyes; then
 864     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
 865         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
 866     fi
 867     if test "x$enable_osmesa" = xyes; then
 868         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 869     fi
 870 fi
 871
 872 AC_SUBST([MESA_LLVM])
 873
 874 # Check for libdrm
 875 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 876                   [have_libdrm=yes], [have_libdrm=no])
 877 if test "x$have_libdrm" = xyes; then
 878         DEFINES="$DEFINES -DHAVE_LIBDRM"
 879 fi
 880
 881 case "$host_os" in
 882 linux*)
 883     need_pci_id=yes ;;
 884 *)
 885     need_pci_id=no ;;
 886 esac
 887
 888 PKG_CHECK_MODULES([LIBUDEV], [libudev >= $LIBUDEV_REQUIRED],
 889                   have_libudev=yes, have_libudev=no)
 890
 891 AC_ARG_ENABLE([sysfs],
 892     [AS_HELP_STRING([--enable-sysfs],
 893         [enable /sys PCI identification @<:@default=disabled@:>@])],
 894     [have_sysfs="$enableval"],
 895     [have_sysfs=no]
 896 )
 897
 898 if test "x$enable_dri" = xyes; then
 899     if test "$enable_static" = yes; then
 900         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 901     fi
 902
 903     # not a hard requirement as swrast does not depend on it
 904     if test "x$have_libdrm" = xyes; then
 905         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 906     fi
 907 fi
 908
 909 AC_ARG_ENABLE([driglx-direct],
 910     [AS_HELP_STRING([--disable-driglx-direct],
 911         [disable direct rendering in GLX and EGL for DRI \
 912             @<:@default=auto@:>@])],
 913     [driglx_direct="$enableval"],
 914     [driglx_direct="yes"])
 915
 916 dnl
 917 dnl libGL configuration per driver
 918 dnl
 919 case "x$enable_glx$enable_xlib_glx" in
 920 xyesyes)
 921     # Xlib-based GLX
 922     dri_modules="x11 xext xcb"
 923     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
 924     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 925     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 926     GL_LIB_DEPS="$XLIBGL_LIBS"
 927     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 928     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 929     ;;
 930 xyesno)
 931     # DRI-based GLX
 932     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 933
 934     # find the DRI deps for libGL
 935     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
 936
 937     if test x"$driglx_direct" = xyes; then
 938         if test x"$dri_platform" = xdrm ; then
 939             DEFINES="$DEFINES -DGLX_USE_DRM"
 940             if test "x$have_libdrm" != xyes; then
 941                AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 942             fi
 943
 944             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 945             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 946             if test x"$enable_dri3" = xyes; then
 947                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
 948                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
 949             fi
 950
 951             if test x"$enable_dri" = xyes; then
 952                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
 953             fi
 954
 955             if test x"$enable_dri3" = xyes; then
 956                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
 957                dri_modules="$dri_modules xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
 958             fi
 959         fi
 960         if test x"$dri_platform" = xapple ; then
 961             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
 962         fi
 963     fi
 964
 965     # add xf86vidmode if available
 966     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 967     if test "$HAVE_XF86VIDMODE" = yes ; then
 968         dri_modules="$dri_modules xxf86vm"
 969     fi
 970
 971     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 972     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 973     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 974     GL_LIB_DEPS="$DRIGL_LIBS"
 975
 976     # need DRM libs, $PTHREAD_LIBS, etc.
 977     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 978     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 979     ;;
 980 esac
 981
 982 have_pci_id=no
 983 if test "$have_libudev" = yes; then
 984     DEFINES="$DEFINES -DHAVE_LIBUDEV"
 985     have_pci_id=yes
 986 fi
 987
 988 if test "$have_sysfs" = yes; then
 989     DEFINES="$DEFINES -DHAVE_SYSFS"
 990     have_pci_id=yes
 991 fi
 992
 993 # This is outside the case (above) so that it is invoked even for non-GLX
 994 # builds.
 995 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 996
 997 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 998 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 999 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1000 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1001
1002 AC_SUBST([X11_INCLUDES])
1003 AC_SUBST([GL_LIB_DEPS])
1004 AC_SUBST([GL_PC_REQ_PRIV])
1005 AC_SUBST([GL_PC_LIB_PRIV])
1006 AC_SUBST([GL_PC_CFLAGS])
1007 AC_SUBST([DRI_PC_REQ_PRIV])
1008 AC_SUBST([GLESv1_CM_LIB_DEPS])
1009 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1010 AC_SUBST([GLESv2_LIB_DEPS])
1011 AC_SUBST([GLESv2_PC_LIB_PRIV])
1012
1013 AC_SUBST([HAVE_XF86VIDMODE])
1014
1015 dnl
1016 dnl More GLX setup
1017 dnl
1018 case "x$enable_glx$enable_xlib_glx" in
1019 xyesyes)
1020     DEFINES="$DEFINES -DUSE_XSHM"
1021     ;;
1022 xyesno)
1023     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1024     if test "x$driglx_direct" = xyes; then
1025         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1026     fi
1027     ;;
1028 esac
1029
1030 dnl
1031 dnl TLS detection
1032 dnl
1033
1034 AC_ARG_ENABLE([glx-tls],
1035     [AS_HELP_STRING([--enable-glx-tls],
1036         [enable TLS support in GLX @<:@default=disabled@:>@])],
1037     [GLX_USE_TLS="$enableval"],
1038     [GLX_USE_TLS=no])
1039 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1040
1041 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1042       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1043
1044 dnl
1045 dnl More DRI setup
1046 dnl
1047 dnl Directory for DRI drivers
1048 AC_ARG_WITH([dri-driverdir],
1049     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1050         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1051     [DRI_DRIVER_INSTALL_DIR="$withval"],
1052     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1053 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1054 dnl Extra search path for DRI drivers
1055 AC_ARG_WITH([dri-searchpath],
1056     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1057         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1058     [DRI_DRIVER_SEARCH_DIR="$withval"],
1059     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1060 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1061 dnl Which drivers to build - default is chosen by platform
1062 AC_ARG_WITH([dri-drivers],
1063     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1064         [comma delimited classic DRI drivers list, e.g.
1065         "swrast,i965,radeon" @<:@default=auto@:>@])],
1066     [with_dri_drivers="$withval"],
1067     [with_dri_drivers=auto])
1068
1069 if test "x$with_dri_drivers" = xauto; then
1070     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1071         with_dri_drivers="yes"
1072     else
1073         with_dri_drivers="no"
1074     fi
1075 fi
1076 if test "x$with_dri_drivers" = xno; then
1077     with_dri_drivers=''
1078 fi
1079
1080 dnl If $with_dri_drivers is yes, drivers will be added through
1081 dnl platform checks. Set DEFINES and LIB_DEPS
1082 if test "x$enable_dri" = xyes; then
1083     # Platform specific settings and drivers to build
1084     case "$host_os" in
1085     linux*)
1086         DEFINES="$DEFINES -DHAVE_ALIAS"
1087         if test "x$enable_dri3" = xyes; then
1088             DEFINES="$DEFINES -DHAVE_DRI3"
1089         fi
1090
1091         if test "x$have_pci_id" != xyes; then
1092             AC_MSG_ERROR([libudev-dev or sysfs required for building DRI])
1093         fi
1094
1095         case "$host_cpu" in
1096         powerpc* | sparc*)
1097             # Build only the drivers for cards that exist on PowerPC/sparc
1098             if test "x$with_dri_drivers" = "xyes"; then
1099                 with_dri_drivers="r200 radeon swrast"
1100             fi
1101             ;;
1102         esac
1103         ;;
1104     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1105         DEFINES="$DEFINES -DHAVE_ALIAS"
1106         ;;
1107     gnu*)
1108         DEFINES="$DEFINES -DHAVE_ALIAS"
1109         ;;
1110     cygwin*)
1111         if test "x$with_dri_drivers" = "xyes"; then
1112             with_dri_drivers="swrast"
1113         fi
1114         ;;
1115     darwin*)
1116         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED"
1117         if test "x$with_dri_drivers" = "xyes"; then
1118             with_dri_drivers="swrast"
1119         fi
1120         ;;
1121     esac
1122
1123     # default drivers
1124     if test "x$with_dri_drivers" = "xyes"; then
1125         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1126     fi
1127
1128     # Check for expat
1129     PKG_CHECK_EXISTS([expat], [have_expat=yes], [have_expat=no])
1130     if test "x$have_expat" = "xyes"; then
1131        PKG_CHECK_MODULES([EXPAT], [expat], [],
1132                          AC_MSG_ERROR([Expat required for DRI.]))
1133     else
1134        # expat version 2.0 and earlier do not provide expat.pc
1135        EXPAT_LIBS=-lexpat
1136     fi
1137
1138     DRICOMMON_NEED_LIBDRM=no
1139     # If we are building any DRI driver other than swrast.
1140     if test -n "$with_dri_drivers"; then
1141         if test "x$with_dri_drivers" != xswrast; then
1142             # ... libdrm is required
1143             if test "x$have_libdrm" != xyes; then
1144                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1145             fi
1146             DRICOMMON_NEED_LIBDRM=yes
1147         fi
1148     fi
1149
1150     # If we're building any gallium DRI driver other than swrast
1151     if test -n "$with_gallium_drivers" -a "x$DRICOMMON_NEED_LIBDRM" = xno; then
1152         if test "x$with_gallium_drivers" != xswrast; then
1153             # ... build a libdrm aware dricommon
1154             DRICOMMON_NEED_LIBDRM=yes
1155         fi
1156     fi
1157
1158     # put all the necessary libs together
1159     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1160 fi
1161
1162 AC_SUBST([DRI_LIB_DEPS])
1163
1164 DRI_DIRS=''
1165 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1166 if test -n "$with_dri_drivers"; then
1167     if test "x$enable_opengl" != xyes; then
1168         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1169     fi
1170
1171     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1172     for driver in $dri_drivers; do
1173         DRI_DIRS="$DRI_DIRS $driver"
1174         case "x$driver" in
1175         xi915)
1176             HAVE_I915_DRI=yes;
1177             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1178             ;;
1179         xi965)
1180             HAVE_I965_DRI=yes;
1181             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1182             ;;
1183         xnouveau)
1184             HAVE_NOUVEAU_DRI=yes;
1185             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1186             ;;
1187         xradeon)
1188             HAVE_RADEON_DRI=yes;
1189             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1190             ;;
1191         xr200)
1192             HAVE_R200_DRI=yes;
1193             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1194             ;;
1195         xswrast)
1196             HAVE_SWRAST_DRI=yes;
1197             ;;
1198         *)
1199             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1200             ;;
1201         esac
1202     done
1203     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1204 fi
1205
1206 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1207 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1208                                   "x$enable_osmesa" = xyes -o \
1209                                   -n "$DRI_DIRS")
1210
1211 dnl
1212 dnl OSMesa configuration
1213 dnl
1214
1215 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1216 AC_ARG_WITH([osmesa-bits],
1217     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1218         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1219     [osmesa_bits="$withval"],
1220     [osmesa_bits=8])
1221 if test "x$osmesa_bits" != x8; then
1222     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1223         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1224         osmesa_bits=8
1225     fi
1226 fi
1227 case "x$osmesa_bits" in
1228 x8)
1229     OSMESA_LIB="${OSMESA_LIB}"
1230     ;;
1231 x16|x32)
1232     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1233     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1234     ;;
1235 *)
1236     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1237     ;;
1238 esac
1239
1240 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1241     # only link libraries with osmesa if shared
1242     if test "$enable_static" = no; then
1243         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1244     else
1245         OSMESA_LIB_DEPS=""
1246     fi
1247     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1248 fi
1249
1250 AC_SUBST([OSMESA_LIB_DEPS])
1251 AC_SUBST([OSMESA_PC_REQ])
1252 AC_SUBST([OSMESA_PC_LIB_PRIV])
1253
1254 dnl
1255 dnl gbm configuration
1256 dnl
1257 if test "x$enable_gbm" = xauto; then
1258     case "$with_egl_platforms" in
1259         *drm*)
1260             enable_gbm=yes ;;
1261          *)
1262             enable_gbm=no ;;
1263     esac
1264 fi
1265 if test "x$enable_gbm" = xyes; then
1266     if test "x$need_pci_id$have_pci_id" = xyesno; then
1267         AC_MSG_ERROR([gbm requires udev >= $LIBUDEV_REQUIRED or sysfs])
1268     fi
1269
1270     if test "x$enable_dri" = xyes; then
1271         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1272         if test "x$enable_shared_glapi" = xno; then
1273             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1274         fi
1275     else
1276         # Strictly speaking libgbm does not require --enable-dri, although
1277         # both of its backends do. Thus one can build libgbm without any
1278         # backends if --disable-dri is set.
1279         # To avoid unnecessary complexity of checking if at least one backend
1280         # is available when building, just mandate --enable-dri.
1281         AC_MSG_ERROR([gbm requires --enable-dri])
1282     fi
1283 fi
1284 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1285 if test "x$need_pci_id$have_libudev" = xyesyes; then
1286     GBM_PC_REQ_PRIV="libudev >= $LIBUDEV_REQUIRED"
1287 else
1288     GBM_PC_REQ_PRIV=""
1289 fi
1290 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1291 AC_SUBST([GBM_PC_REQ_PRIV])
1292 AC_SUBST([GBM_PC_LIB_PRIV])
1293
1294 dnl
1295 dnl EGL configuration
1296 dnl
1297 EGL_CLIENT_APIS=""
1298
1299 if test "x$enable_egl" = xyes; then
1300     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1301
1302     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1303
1304     if test "$enable_static" != yes; then
1305         if test "x$enable_dri" = xyes; then
1306             HAVE_EGL_DRIVER_DRI2=1
1307         fi
1308
1309     fi
1310 fi
1311 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1312 AC_SUBST([EGL_LIB_DEPS])
1313
1314 dnl
1315 dnl EGL Gallium configuration
1316 dnl
1317 if test "x$enable_gallium_egl" = xyes; then
1318     if test -z "$with_gallium_drivers"; then
1319         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1320     fi
1321     if test "x$enable_egl" = xno; then
1322         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1323     fi
1324     if test "x$have_libdrm" != xyes; then
1325         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1326     fi
1327 # XXX: Uncomment once converted to use static/shared pipe-drivers
1328 #    enable_gallium_loader=$enable_shared_pipe_drivers
1329 fi
1330 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1331
1332 dnl
1333 dnl gbm Gallium configuration
1334 dnl
1335 if test "x$enable_gallium_gbm" = xauto; then
1336     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1337         yesyesyes*drm*)
1338             enable_gallium_gbm=yes ;;
1339          *)
1340             enable_gallium_gbm=no ;;
1341     esac
1342 fi
1343 if test "x$enable_gallium_gbm" = xyes; then
1344     if test -z "$with_gallium_drivers"; then
1345         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1346     fi
1347     if test "x$enable_gbm" = xno; then
1348         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1349     fi
1350
1351     if test "x$enable_gallium_egl" != xyes; then
1352         AC_MSG_ERROR([gbm_gallium is only used by egl_gallium])
1353     fi
1354
1355     enable_gallium_loader=$enable_shared_pipe_drivers
1356 fi
1357 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1358
1359 dnl
1360 dnl XA configuration
1361 dnl
1362 if test "x$enable_xa" = xyes; then
1363     if test "x$with_gallium_drivers" = xswrast; then
1364        AC_MSG_ERROR([
1365           Building xa requires at least one non swrast gallium driver.
1366           If you are looking to use libxatracker.so with the VMware driver,
1367           make sure to include svga in the gallium drivers list, apart from
1368           enabling XA.
1369           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1370     fi
1371     enable_gallium_loader=$enable_shared_pipe_drivers
1372 fi
1373 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1374
1375 dnl
1376 dnl OpenVG configuration
1377 dnl
1378 VG_LIB_DEPS=""
1379
1380 if test "x$enable_openvg" = xyes; then
1381     if test "x$enable_egl" = xno; then
1382         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1383     fi
1384     if test -z "$with_gallium_drivers"; then
1385         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1386     fi
1387     if test "x$enable_gallium_egl" = xno; then
1388         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1389     fi
1390
1391     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1392     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1393     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1394     AC_SUBST([VG_PC_LIB_PRIV])
1395 fi
1396 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1397
1398 dnl
1399 dnl Gallium G3DVL configuration
1400 dnl
1401 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1402     if test "x$enable_xvmc" = xauto; then
1403         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1404     fi
1405
1406     if test "x$enable_vdpau" = xauto; then
1407         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1408     fi
1409
1410     if test "x$enable_omx" = xauto; then
1411         PKG_CHECK_EXISTS([libomxil-bellagio], [enable_omx=yes], [enable_omx=no])
1412     fi
1413
1414     if test "x$enable_va" = xauto; then
1415         PKG_CHECK_EXISTS([libva], [enable_va=yes], [enable_va=no])
1416     fi
1417 fi
1418
1419 if test "x$enable_xvmc" = xyes; then
1420     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1421     enable_gallium_loader=$enable_shared_pipe_drivers
1422 fi
1423 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1424
1425 if test "x$enable_vdpau" = xyes; then
1426     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1427                       [VDPAU_LIBS="`$PKG_CONFIG --libs x11-xcb xcb xcb-dri2`"])
1428     enable_gallium_loader=$enable_shared_pipe_drivers
1429 fi
1430 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1431
1432 if test "x$enable_omx" = xyes; then
1433     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1434     enable_gallium_loader=$enable_shared_pipe_drivers
1435 fi
1436 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1437
1438 if test "x$enable_va" = xyes; then
1439     PKG_CHECK_MODULES([VA], [libva >= 0.35.0 x11-xcb xcb-dri2 >= $XCBDRI2_REQUIRED],
1440                       [VA_LIBS="`$PKG_CONFIG --libs x11-xcb xcb-dri2`"])
1441     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1442     enable_gallium_loader=$enable_shared_pipe_drivers
1443 fi
1444 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1445
1446 dnl
1447 dnl OpenCL configuration
1448 dnl
1449
1450 AC_ARG_WITH([libclc-path],
1451    [AS_HELP_STRING([--with-libclc-path],
1452          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1453    [LIBCLC_PATH="$withval"],
1454    [LIBCLC_PATH=''])
1455
1456 if test -n "$LIBCLC_PATH"; then
1457    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1458                   Please review the updated build instructions for clover:
1459                   http://dri.freedesktop.org/wiki/GalliumCompute])
1460 fi
1461
1462
1463 AC_ARG_WITH([clang-libdir],
1464    [AS_HELP_STRING([--with-clang-libdir],
1465          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1466    [CLANG_LIBDIR="$withval"],
1467    [CLANG_LIBDIR=''])
1468
1469 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1470
1471 if test "x$enable_opencl" = xyes; then
1472     if test -z "$with_gallium_drivers"; then
1473         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1474     fi
1475
1476     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1477         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1478     fi
1479
1480     if test "x$have_libclc" = xno; then
1481         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1482                     Make sure the directory containing libclc.pc is specified in your
1483                     PKG_CONFIG_PATH environment variable.
1484                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1485     else
1486         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1487         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1488         AC_SUBST([LIBCLC_INCLUDEDIR])
1489         AC_SUBST([LIBCLC_LIBEXECDIR])
1490     fi
1491
1492     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1493     enable_gallium_loader=yes
1494
1495     if test "x$enable_opencl_icd" = xyes; then
1496         OPENCL_LIBNAME="MesaOpenCL"
1497     else
1498         OPENCL_LIBNAME="OpenCL"
1499     fi
1500 fi
1501 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1502 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1503 AC_SUBST([OPENCL_LIBNAME])
1504
1505 dnl
1506 dnl Gallium configuration
1507 dnl
1508 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1509
1510 AC_SUBST([LLVM_BINDIR])
1511 AC_SUBST([LLVM_CFLAGS])
1512 AC_SUBST([LLVM_CPPFLAGS])
1513 AC_SUBST([LLVM_CXXFLAGS])
1514 AC_SUBST([LLVM_LIBDIR])
1515 AC_SUBST([LLVM_LIBS])
1516 AC_SUBST([LLVM_LDFLAGS])
1517 AC_SUBST([LLVM_INCLUDEDIR])
1518 AC_SUBST([LLVM_VERSION])
1519 AC_SUBST([CLANG_RESOURCE_DIR])
1520
1521 case "x$enable_opengl$enable_gles1$enable_gles2" in
1522 x*yes*)
1523     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1524     ;;
1525 esac
1526
1527 AC_SUBST([VG_LIB_DEPS])
1528 AC_SUBST([EGL_CLIENT_APIS])
1529
1530 dnl
1531 dnl EGL Platforms configuration
1532 dnl
1533 AC_ARG_WITH([egl-platforms],
1534     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1535         [comma delimited native platforms libEGL supports, e.g.
1536         "x11,drm" @<:@default=auto@:>@])],
1537     [with_egl_platforms="$withval"],
1538     [if test "x$enable_egl" = xyes; then
1539         with_egl_platforms="x11"
1540     else
1541         with_egl_platforms=""
1542     fi])
1543
1544 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1545     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1546 fi
1547
1548 # Do per-EGL platform setups and checks
1549 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1550 for plat in $egl_platforms; do
1551         case "$plat" in
1552         wayland)
1553                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
1554
1555                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1556                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1557                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1558                 ;;
1559
1560         x11)
1561                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
1562                 ;;
1563
1564         drm)
1565                 test "x$enable_gbm" = "xno" &&
1566                         AC_MSG_ERROR([EGL platform drm needs gbm])
1567                 test "x$have_libdrm" != xyes &&
1568                         AC_MSG_ERROR([EGL platform drm requires libdrm >= $LIBDRM_REQUIRED])
1569                 ;;
1570
1571         android|fbdev|gdi|null)
1572                 ;;
1573
1574         *)
1575                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1576                 ;;
1577         esac
1578
1579         case "$plat$need_pci_id$have_pci_id" in
1580                 waylandyesno|drmyesno)
1581                     AC_MSG_ERROR([cannot build $plat platform without udev >= $LIBUDEV_REQUIRED or sysfs]) ;;
1582         esac
1583 done
1584
1585 # libEGL wants to default to the first platform specified in
1586 # ./configure.  parse that here.
1587 if test "x$egl_platforms" != "x"; then
1588     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1589     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1590 else
1591     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1592 fi
1593
1594 if echo "$egl_platforms" | grep -q 'x11'; then
1595     NEED_WINSYS_XLIB=yes
1596 fi
1597 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
1598 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
1599 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
1600 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep -q 'fbdev')
1601 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep -q 'null')
1602
1603 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1604
1605 AC_SUBST([EGL_NATIVE_PLATFORM])
1606 AC_SUBST([EGL_CFLAGS])
1607
1608 # If we don't have the X11 platform, set this define so we don't try to include
1609 # the X11 headers.
1610 if ! echo "$egl_platforms" | grep -q 'x11'; then
1611     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1612     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1613 fi
1614
1615 AC_ARG_WITH([max-width],
1616     [AS_HELP_STRING([--with-max-width=N],
1617                     [Maximum framebuffer width (4096)])],
1618     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1619      AS_IF([test "${withval}" -gt "4096"],
1620            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1621 )
1622 AC_ARG_WITH([max-height],
1623     [AS_HELP_STRING([--with-max-height=N],
1624                     [Maximum framebuffer height (4096)])],
1625     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1626      AS_IF([test "${withval}" -gt "4096"],
1627            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1628 )
1629
1630 dnl
1631 dnl Gallium LLVM
1632 dnl
1633 AC_ARG_ENABLE([gallium-llvm],
1634     [AS_HELP_STRING([--enable-gallium-llvm],
1635         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1636     [enable_gallium_llvm="$enableval"],
1637     [enable_gallium_llvm=auto])
1638
1639 AC_ARG_ENABLE([llvm-shared-libs],
1640     [AS_HELP_STRING([--enable-llvm-shared-libs],
1641         [link with LLVM shared libraries @<:@default=enabled@:>@])],
1642     [enable_llvm_shared_libs="$enableval"],
1643     [enable_llvm_shared_libs=yes])
1644
1645 AC_ARG_WITH([llvm-prefix],
1646     [AS_HELP_STRING([--with-llvm-prefix],
1647         [Prefix for LLVM installations in non-standard locations])],
1648     [llvm_prefix="$withval"],
1649     [llvm_prefix=''])
1650
1651
1652 # Call this inside ` ` to get the return value.
1653 # $1 is the llvm-config command with arguments.
1654 strip_unwanted_llvm_flags() {
1655     # Use \> (marks the end of the word)
1656     echo `$1` | sed \
1657         -e 's/-DNDEBUG\>//g' \
1658         -e 's/-D_GNU_SOURCE\>//g' \
1659         -e 's/-pedantic\>//g' \
1660         -e 's/-Wcovered-switch-default\>//g' \
1661         -e 's/-O.\>//g' \
1662         -e 's/-g\>//g' \
1663         -e 's/-Wall\>//g' \
1664         -e 's/-Wcast-qual\>//g' \
1665         -e 's/-Woverloaded-virtual\>//g' \
1666         -e 's/-fcolor-diagnostics\>//g' \
1667         -e 's/-fdata-sections\>//g' \
1668         -e 's/-ffunction-sections\>//g' \
1669         -e 's/-fno-exceptions\>//g' \
1670         -e 's/-fomit-frame-pointer\>//g' \
1671         -e 's/-fvisibility-inlines-hidden\>//g' \
1672         -e 's/-fPIC\>//g' \
1673         -e 's/-fstack-protector-strong\>//g'
1674 }
1675
1676
1677 if test -z "$with_gallium_drivers"; then
1678     enable_gallium_llvm=no
1679 fi
1680 if test "x$enable_gallium_llvm" = xauto; then
1681     case "$host_cpu" in
1682     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1683     esac
1684 fi
1685 if test "x$enable_gallium_llvm" = xyes; then
1686     if test -n "$llvm_prefix"; then
1687         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1688     else
1689         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
1690     fi
1691
1692     if test "x$LLVM_CONFIG" != xno; then
1693         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
1694         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1695         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1696         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1697         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1698         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1699         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1700         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1701
1702         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1703             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1704         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1705             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1706
1707         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
1708         if test -z "$LLVM_VERSION_PATCH"; then
1709             LLVM_VERSION_PATCH=0
1710         fi
1711
1712         if test -n "${LLVM_VERSION_MAJOR}"; then
1713             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1714         else
1715             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1716         fi
1717
1718         LLVM_REQUIRED_VERSION_MAJOR="3"
1719         LLVM_REQUIRED_VERSION_MINOR="1"
1720         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1721             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
1722         fi
1723
1724         LLVM_COMPONENTS="engine bitwriter"
1725         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1726             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1727         fi
1728
1729         if test "x$enable_opencl" = xyes; then
1730             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1731             # LLVM 3.3 >= 177971 requires IRReader
1732             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1733                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1734             fi
1735             # LLVM 3.4 requires Option
1736             if $LLVM_CONFIG --components | grep -qw 'option'; then
1737                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1738             fi
1739             # Current OpenCL/Clover and LLVM 3.5 require ObjCARCOpts and ProfileData
1740             if $LLVM_CONFIG --components | grep -qw 'objcarcopts'; then
1741                 LLVM_COMPONENTS="${LLVM_COMPONENTS} objcarcopts"
1742             fi
1743             if $LLVM_CONFIG --components | grep -qw 'profiledata'; then
1744                 LLVM_COMPONENTS="${LLVM_COMPONENTS} profiledata"
1745             fi
1746         fi
1747         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DLLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
1748         MESA_LLVM=1
1749
1750         dnl Check for Clang internal headers
1751         if test "x$enable_opencl" = xyes; then
1752             if test -z "$CLANG_LIBDIR"; then
1753                 CLANG_LIBDIR=${LLVM_LIBDIR}
1754             fi
1755             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1756             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1757                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1758         fi
1759     else
1760         MESA_LLVM=0
1761         LLVM_VERSION_INT=0
1762     fi
1763 else
1764     MESA_LLVM=0
1765     LLVM_VERSION_INT=0
1766
1767     if test "x$enable_opencl" = xyes; then
1768         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
1769     fi
1770 fi
1771
1772 dnl Directory for XVMC libs
1773 AC_ARG_WITH([xvmc-libdir],
1774     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1775         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1776     [XVMC_LIB_INSTALL_DIR="$withval"],
1777     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1778 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1779
1780 dnl
1781 dnl Gallium Tests
1782 dnl
1783 if test "x$enable_gallium_tests" = xyes; then
1784     # XXX: Use $enable_shared_pipe_drivers once converted to use static/shared pipe-drivers
1785     enable_gallium_loader=yes
1786 fi
1787 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1788
1789 dnl Directory for VDPAU libs
1790 AC_ARG_WITH([vdpau-libdir],
1791     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1792         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1793     [VDPAU_LIB_INSTALL_DIR="$withval"],
1794     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1795 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1796
1797 dnl Directory for OMX libs
1798
1799 AC_ARG_WITH([omx-libdir],
1800     [AS_HELP_STRING([--with-omx-libdir=DIR],
1801         [directory for the OMX libraries])],
1802     [OMX_LIB_INSTALL_DIR="$withval"],
1803     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
1804 AC_SUBST([OMX_LIB_INSTALL_DIR])
1805
1806 dnl Directory for VA libs
1807
1808 AC_ARG_WITH([va-libdir],
1809     [AS_HELP_STRING([--with-va-libdir=DIR],
1810         [directory for the VA libraries @<:@default=`pkg-config libva --variable=driverdir`@:>@])],
1811     [VA_LIB_INSTALL_DIR="$withval"],
1812     [VA_LIB_INSTALL_DIR=`pkg-config libva --variable=driverdir`])
1813 AC_SUBST([VA_LIB_INSTALL_DIR])
1814
1815 dnl
1816 dnl Gallium helper functions
1817 dnl
1818 gallium_require_drm() {
1819     if test "x$have_libdrm" != xyes; then
1820        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1821     fi
1822 }
1823
1824 gallium_require_llvm() {
1825     if test "x$MESA_LLVM" = x0; then
1826         case "$host" in *gnux32) return;; esac
1827         case "$host_cpu" in
1828         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1829         esac
1830     fi
1831 }
1832
1833 gallium_require_drm_loader() {
1834     if test "x$enable_gallium_loader" = xyes; then
1835         if test "x$need_pci_id$have_pci_id" = xyesno; then
1836             AC_MSG_ERROR([Gallium drm loader requires libudev >= $LIBUDEV_REQUIRED or sysfs])
1837         fi
1838         enable_gallium_drm_loader=yes
1839     fi
1840     if test "x$enable_va" = xyes && test "x$7" != x; then
1841          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1842     fi
1843 }
1844
1845 require_egl_drm() {
1846     case "$with_egl_platforms" in
1847         *drm*)
1848             ;;
1849          *)
1850             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
1851             ;;
1852     esac
1853     if test "x$enable_gbm" != xyes; then
1854             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
1855     fi
1856 }
1857
1858 radeon_llvm_check() {
1859     if test "x$enable_gallium_llvm" != "xyes"; then
1860         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
1861     fi
1862     LLVM_REQUIRED_VERSION_MAJOR="3"
1863     LLVM_REQUIRED_VERSION_MINOR="4"
1864     LLVM_REQUIRED_VERSION_PATCH="2"
1865     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}${LLVM_REQUIRED_VERSION_PATCH}"; then
1866         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR.$LLVM_REQUIRED_VERSION_PATCH or newer is required for $1])
1867     fi
1868     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1869         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1870                       sources with the --enable-experimental-targets=R600
1871                       configure flag])
1872     fi
1873     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1874     NEED_RADEON_LLVM=yes
1875     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1876                                  [AC_MSG_ERROR([$1 requires libelf when using LLVM])])
1877 }
1878
1879 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1880 if test -n "$with_gallium_drivers"; then
1881     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1882     for driver in $gallium_drivers; do
1883         case "x$driver" in
1884         xsvga)
1885             HAVE_GALLIUM_SVGA=yes
1886             gallium_require_drm "svga"
1887             gallium_require_drm_loader
1888             ;;
1889         xi915)
1890             HAVE_GALLIUM_I915=yes
1891             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1892             gallium_require_drm "Gallium i915"
1893             gallium_require_drm_loader
1894             ;;
1895         xilo)
1896             HAVE_GALLIUM_ILO=yes
1897             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1898             gallium_require_drm "Gallium i965/ilo"
1899             gallium_require_drm_loader
1900             ;;
1901         xr300)
1902             HAVE_GALLIUM_R300=yes
1903             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1904             gallium_require_drm "Gallium R300"
1905             gallium_require_drm_loader
1906             gallium_require_llvm "Gallium R300"
1907             ;;
1908         xr600)
1909             HAVE_GALLIUM_R600=yes
1910             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1911             gallium_require_drm "Gallium R600"
1912             gallium_require_drm_loader
1913             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1914                 radeon_llvm_check "r600g"
1915                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1916             fi
1917             if test "x$enable_r600_llvm" = xyes; then
1918                 USE_R600_LLVM_COMPILER=yes;
1919             fi
1920             if test "x$enable_opencl" = xyes; then
1921                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1922             fi
1923             ;;
1924         xradeonsi)
1925             HAVE_GALLIUM_RADEONSI=yes
1926             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1927             gallium_require_drm "radeonsi"
1928             gallium_require_drm_loader
1929             radeon_llvm_check "radeonsi"
1930             require_egl_drm "radeonsi"
1931             ;;
1932         xnouveau)
1933             HAVE_GALLIUM_NOUVEAU=yes
1934             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1935             gallium_require_drm "nouveau"
1936             gallium_require_drm_loader
1937             ;;
1938         xfreedreno)
1939             HAVE_GALLIUM_FREEDRENO=yes
1940             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1941             gallium_require_drm "freedreno"
1942             gallium_require_drm_loader
1943             ;;
1944         xswrast)
1945             HAVE_GALLIUM_SOFTPIPE=yes
1946             if test "x$MESA_LLVM" = x1; then
1947                 HAVE_GALLIUM_LLVMPIPE=yes
1948             fi
1949             ;;
1950         xvc4)
1951             HAVE_GALLIUM_VC4=yes
1952             gallium_require_drm "vc4"
1953             gallium_require_drm_loader
1954
1955             case "$host_cpu" in
1956                 i?86 | x86_64 | amd64)
1957                 USE_VC4_SIMULATOR=yes
1958                 ;;
1959             esac
1960             ;;
1961         *)
1962             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1963             ;;
1964         esac
1965     done
1966 fi
1967
1968 dnl Set LLVM_LIBS - This is done after the driver configuration so
1969 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1970 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1971 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1972 dnl this was causing the same libraries to be appear multiple times
1973 dnl in LLVM_LIBS.
1974
1975 if test "x$MESA_LLVM" != x0; then
1976
1977     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1978
1979     if test "x$enable_llvm_shared_libs" = xyes; then
1980         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1981         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1982         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1983
1984         if test "x$llvm_have_one_so" = xyes; then
1985             dnl LLVM was built using auto*, so there is only one shared object.
1986             LLVM_LIBS="-l$LLVM_SO_NAME"
1987         else
1988             dnl If LLVM was built with CMake, there will be one shared object per
1989             dnl component.
1990             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1991                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1992         Please make sure you have built llvm with the --enable-shared option
1993         and that your llvm libraries are installed in $LLVM_LIBDIR
1994         If you have installed your llvm libraries to a different directory you
1995         can use the --with-llvm-prefix= configure flag to specify this directory.
1996         NOTE: Mesa is attempting to use llvm shared libraries by default.
1997         If you do not want to build with llvm shared libraries and instead want to
1998         use llvm static libraries then add --disable-llvm-shared-libs to your configure
1999         invocation and rebuild.])])
2000
2001            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2002            dnl install uses a shared object for each compoenent and we have
2003            dnl already added all of these objects to LLVM_LIBS.
2004         fi
2005     else
2006         AC_MSG_WARN([Building mesa with staticly linked LLVM may cause compilation issues])
2007     fi
2008 fi
2009
2010 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2011 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2012 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2013 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2014 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2015 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2016 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2017                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2018 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2019 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2020 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2021 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2022 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2023
2024 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2025
2026 # NOTE: anything using xcb or other client side libs ends up in separate
2027 #       _CLIENT variables.  The pipe loader is built in two variants,
2028 #       one that is standalone and does not link any x client libs (for
2029 #       use by XA tracker in particular, but could be used in any case
2030 #       where communication with xserver is not desired).
2031 if test "x$enable_gallium_loader" = xyes; then
2032     if test "x$NEED_WINSYS_XLIB" = xyes; then
2033         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2034     fi
2035
2036     if test "x$enable_dri" = xyes; then
2037         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2038     fi
2039
2040     if test "x$enable_gallium_drm_loader" = xyes; then
2041         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2042         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
2043                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
2044         if test "x$pipe_loader_have_xcb" = xyes; then
2045             GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES -DHAVE_PIPE_LOADER_XCB"
2046             GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
2047         fi
2048     fi
2049
2050     GALLIUM_PIPE_LOADER_CLIENT_DEFINES="$GALLIUM_PIPE_LOADER_CLIENT_DEFINES $GALLIUM_PIPE_LOADER_DEFINES"
2051     GALLIUM_PIPE_LOADER_CLIENT_LIBS="$GALLIUM_PIPE_LOADER_CLIENT_LIBS $GALLIUM_PIPE_LOADER_LIBS"
2052
2053     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2054     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2055     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_DEFINES])
2056     AC_SUBST([GALLIUM_PIPE_LOADER_CLIENT_LIBS])
2057 fi
2058
2059 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2060 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2061 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2062 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2063 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2064 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2065
2066 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2067                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2068                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2069 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
2070 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2071 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2072 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2073 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2074 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2075 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2076 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2077 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2078     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2079 fi
2080
2081 AC_SUBST([ELF_LIB])
2082
2083 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
2084 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2085 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
2086 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2087 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2088
2089 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2090 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2091 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2092
2093 AC_SUBST([VDPAU_MAJOR], 1)
2094 AC_SUBST([VDPAU_MINOR], 0)
2095
2096 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2097 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2098 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2099 AC_SUBST([VA_MINOR], $VA_MINOR)
2100
2101 AC_SUBST([XVMC_MAJOR], 1)
2102 AC_SUBST([XVMC_MINOR], 0)
2103
2104 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2105 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2106 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2107 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2108
2109 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2110 AC_SUBST([XA_MINOR], $XA_MINOR)
2111 AC_SUBST([XA_TINY], $XA_TINY)
2112 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2113
2114 dnl Restore LDFLAGS and CPPFLAGS
2115 LDFLAGS="$_SAVE_LDFLAGS"
2116 CPPFLAGS="$_SAVE_CPPFLAGS"
2117
2118 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2119 if test "x$acv_mesa_CLANG" = xyes; then
2120     CFLAGS="$CFLAGS -Qunused-arguments"
2121     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2122 fi
2123
2124 dnl Add user CFLAGS and CXXFLAGS
2125 CFLAGS="$CFLAGS $USER_CFLAGS"
2126 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2127
2128 dnl Substitute the config
2129 AC_CONFIG_FILES([Makefile
2130                 src/Makefile
2131                 src/egl/drivers/dri2/Makefile
2132                 src/egl/main/Makefile
2133                 src/egl/main/egl.pc
2134                 src/egl/wayland/Makefile
2135                 src/egl/wayland/wayland-drm/Makefile
2136                 src/egl/wayland/wayland-egl/Makefile
2137                 src/egl/wayland/wayland-egl/wayland-egl.pc
2138                 src/gallium/Makefile
2139                 src/gallium/auxiliary/Makefile
2140                 src/gallium/auxiliary/pipe-loader/Makefile
2141                 src/gallium/drivers/freedreno/Makefile
2142                 src/gallium/drivers/galahad/Makefile
2143                 src/gallium/drivers/i915/Makefile
2144                 src/gallium/drivers/identity/Makefile
2145                 src/gallium/drivers/ilo/Makefile
2146                 src/gallium/drivers/llvmpipe/Makefile
2147                 src/gallium/drivers/noop/Makefile
2148                 src/gallium/drivers/nouveau/Makefile
2149                 src/gallium/drivers/r300/Makefile
2150                 src/gallium/drivers/r600/Makefile
2151                 src/gallium/drivers/radeon/Makefile
2152                 src/gallium/drivers/radeonsi/Makefile
2153                 src/gallium/drivers/rbug/Makefile
2154                 src/gallium/drivers/softpipe/Makefile
2155                 src/gallium/drivers/svga/Makefile
2156                 src/gallium/drivers/trace/Makefile
2157                 src/gallium/drivers/vc4/Makefile
2158                 src/gallium/drivers/vc4/kernel/Makefile
2159                 src/gallium/state_trackers/clover/Makefile
2160                 src/gallium/state_trackers/dri/Makefile
2161                 src/gallium/state_trackers/egl/Makefile
2162                 src/gallium/state_trackers/gbm/Makefile
2163                 src/gallium/state_trackers/glx/xlib/Makefile
2164                 src/gallium/state_trackers/omx/Makefile
2165                 src/gallium/state_trackers/osmesa/Makefile
2166                 src/gallium/state_trackers/va/Makefile
2167                 src/gallium/state_trackers/vdpau/Makefile
2168                 src/gallium/state_trackers/vega/Makefile
2169                 src/gallium/state_trackers/xa/Makefile
2170                 src/gallium/state_trackers/xvmc/Makefile
2171                 src/gallium/targets/dri/Makefile
2172                 src/gallium/targets/egl-static/Makefile
2173                 src/gallium/targets/gbm/Makefile
2174                 src/gallium/targets/libgl-xlib/Makefile
2175                 src/gallium/targets/omx/Makefile
2176                 src/gallium/targets/opencl/Makefile
2177                 src/gallium/targets/osmesa/Makefile
2178                 src/gallium/targets/osmesa/osmesa.pc
2179                 src/gallium/targets/pipe-loader/Makefile
2180                 src/gallium/targets/va/Makefile
2181                 src/gallium/targets/vdpau/Makefile
2182                 src/gallium/targets/xa/Makefile
2183                 src/gallium/targets/xa/xatracker.pc
2184                 src/gallium/targets/xvmc/Makefile
2185                 src/gallium/tests/trivial/Makefile
2186                 src/gallium/tests/unit/Makefile
2187                 src/gallium/winsys/freedreno/drm/Makefile
2188                 src/gallium/winsys/i915/drm/Makefile
2189                 src/gallium/winsys/intel/drm/Makefile
2190                 src/gallium/winsys/nouveau/drm/Makefile
2191                 src/gallium/winsys/radeon/drm/Makefile
2192                 src/gallium/winsys/svga/drm/Makefile
2193                 src/gallium/winsys/sw/dri/Makefile
2194                 src/gallium/winsys/sw/fbdev/Makefile
2195                 src/gallium/winsys/sw/kms-dri/Makefile
2196                 src/gallium/winsys/sw/null/Makefile
2197                 src/gallium/winsys/sw/wayland/Makefile
2198                 src/gallium/winsys/sw/wrapper/Makefile
2199                 src/gallium/winsys/sw/xlib/Makefile
2200                 src/gallium/winsys/vc4/drm/Makefile
2201                 src/gbm/Makefile
2202                 src/gbm/main/gbm.pc
2203                 src/glsl/Makefile
2204                 src/glx/Makefile
2205                 src/glx/apple/Makefile
2206                 src/glx/tests/Makefile
2207                 src/gtest/Makefile
2208                 src/loader/Makefile
2209                 src/mapi/Makefile
2210                 src/mapi/es1api/glesv1_cm.pc
2211                 src/mapi/es2api/glesv2.pc
2212                 src/mapi/glapi/gen/Makefile
2213                 src/mapi/vgapi/Makefile
2214                 src/mapi/vgapi/vg.pc
2215                 src/mesa/Makefile
2216                 src/mesa/gl.pc
2217                 src/mesa/drivers/dri/dri.pc
2218                 src/mesa/drivers/dri/common/Makefile
2219                 src/mesa/drivers/dri/common/xmlpool/Makefile
2220                 src/mesa/drivers/dri/i915/Makefile
2221                 src/mesa/drivers/dri/i965/Makefile
2222                 src/mesa/drivers/dri/Makefile
2223                 src/mesa/drivers/dri/nouveau/Makefile
2224                 src/mesa/drivers/dri/r200/Makefile
2225                 src/mesa/drivers/dri/radeon/Makefile
2226                 src/mesa/drivers/dri/swrast/Makefile
2227                 src/mesa/drivers/osmesa/Makefile
2228                 src/mesa/drivers/osmesa/osmesa.pc
2229                 src/mesa/drivers/x11/Makefile
2230                 src/mesa/main/tests/Makefile
2231                 src/util/Makefile
2232                 src/util/tests/hash_table/Makefile])
2233
2234 AC_OUTPUT
2235
2236 dnl
2237 dnl Output some configuration info for the user
2238 dnl
2239 echo ""
2240 echo "        prefix:          $prefix"
2241 echo "        exec_prefix:     $exec_prefix"
2242 echo "        libdir:          $libdir"
2243 echo "        includedir:      $includedir"
2244
2245 dnl API info
2246 echo ""
2247 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2248 echo "        OpenVG:          $enable_openvg"
2249
2250 dnl Driver info
2251 echo ""
2252 case "x$enable_osmesa$enable_gallium_osmesa" in
2253 xnoyes)
2254         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2255         ;;
2256 xyesno)
2257         echo "        OSMesa:          lib$OSMESA_LIB"
2258         ;;
2259 xnono)
2260         echo "        OSMesa:          no"
2261         ;;
2262 esac
2263
2264 echo ""
2265 if test "x$enable_dri" != xno; then
2266         echo "        DRI platform:    $dri_platform"
2267         if test -z "$DRI_DIRS"; then
2268             echo "        DRI drivers:     no"
2269         else
2270             echo "        DRI drivers:     $DRI_DIRS"
2271         fi
2272         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2273 fi
2274
2275 case "x$enable_glx$enable_xlib_glx" in
2276 xyesyes)
2277     echo "        GLX:             Xlib-based"
2278     ;;
2279 xyesno)
2280     echo "        GLX:             DRI-based"
2281     ;;
2282 *)
2283     echo "        GLX:             $enable_glx"
2284     ;;
2285 esac
2286
2287 dnl EGL
2288 echo ""
2289 echo "        EGL:             $enable_egl"
2290 if test "$enable_egl" = yes; then
2291     echo "        EGL platforms:   $egl_platforms"
2292
2293     egl_drivers=""
2294     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2295         egl_drivers="$egl_drivers builtin:egl_dri2"
2296     fi
2297
2298     if test "x$enable_gallium_egl" = xyes; then
2299         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2300         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2301     else
2302         echo "        EGL drivers:    $egl_drivers"
2303     fi
2304 fi
2305
2306 echo ""
2307 if test "x$MESA_LLVM" = x1; then
2308     echo "        llvm:            yes"
2309     echo "        llvm-config:     $LLVM_CONFIG"
2310     echo "        llvm-version:    $LLVM_VERSION"
2311 else
2312     echo "        llvm:            no"
2313 fi
2314
2315 echo ""
2316 if test -n "$with_gallium_drivers"; then
2317     echo "        Gallium:         yes"
2318 else
2319     echo "        Gallium:         no"
2320 fi
2321
2322
2323 dnl Libraries
2324 echo ""
2325 echo "        Shared libs:     $enable_shared"
2326 echo "        Static libs:     $enable_static"
2327 echo "        Shared-glapi:    $enable_shared_glapi"
2328
2329 dnl Compiler options
2330 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2331 cflags=`echo $CFLAGS | \
2332     $SED 's/^ *//;s/  */ /;s/ *$//'`
2333 cxxflags=`echo $CXXFLAGS | \
2334     $SED 's/^ *//;s/  */ /;s/ *$//'`
2335 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2336 echo ""
2337 echo "        CFLAGS:          $cflags"
2338 echo "        CXXFLAGS:        $cxxflags"
2339 echo "        Macros:          $defines"
2340 echo ""
2341 if test "x$MESA_LLVM" = x1; then
2342     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2343     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2344     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2345     echo ""
2346 fi
2347 echo "        PYTHON2:         $PYTHON2"
2348
2349 echo ""
2350 echo "        Run '${MAKE-make}' to build Mesa"
2351 echo ""