configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  10 AC_INIT([Mesa], [MESA_VERSION],
  11     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  12 AC_CONFIG_AUX_DIR([bin])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AC_CANONICAL_SYSTEM
  15 AM_INIT_AUTOMAKE([foreign])
  16
  17 # Support silent build rules, requires at least automake-1.11. Disable
  18 # by either passing --disable-silent-rules to configure or passing V=1
  19 # to make
  20 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  21     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  22
  23 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  24
  25 dnl Set internal versions
  26 OSMESA_VERSION=8
  27 AC_SUBST([OSMESA_VERSION])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.46
  32 LIBDRM_INTEL_REQUIRED=2.4.38
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  35 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  36 DRI2PROTO_REQUIRED=2.6
  37 GLPROTO_REQUIRED=1.4.14
  38
  39 dnl Check for progs
  40 AC_PROG_CPP
  41 AC_PROG_CC
  42 AC_PROG_CXX
  43 AM_PROG_CC_C_O
  44 AM_PROG_AS
  45 AC_CHECK_PROGS([MAKE], [gmake make])
  46 AC_CHECK_PROGS([PYTHON2], [python2 python])
  47 AX_PYTHON_MODULE([libxml2], [needed])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50
  51 LT_PREREQ([2.2])
  52 LT_INIT([disable-static])
  53
  54 AX_PROG_BISON([],
  55               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  56                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  57 AX_PROG_FLEX([],
  58              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  59                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  60
  61 AC_PATH_PROG([PERL], [perl])
  62
  63 AC_CHECK_PROG(INDENT, indent, indent, cat)
  64 if test "x$INDENT" != "xcat"; then
  65     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  66 fi
  67
  68 AC_PROG_INSTALL
  69
  70 dnl We need a POSIX shell for parts of the build. Assume we have one
  71 dnl in most cases.
  72 case "$host_os" in
  73 solaris*)
  74     # Solaris /bin/sh is too old/non-POSIX compliant
  75     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  76     SHELL="$POSIX_SHELL"
  77     ;;
  78 esac
  79
  80 dnl clang is mostly GCC-compatible, but its version is much lower,
  81 dnl so we have to check for it.
  82 AC_MSG_CHECKING([if compiling with clang])
  83
  84 AC_COMPILE_IFELSE(
  85 [AC_LANG_PROGRAM([], [[
  86 #ifndef __clang__
  87        not clang
  88 #endif
  89 ]])],
  90 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  91
  92 AC_MSG_RESULT([$acv_mesa_CLANG])
  93
  94 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  95 dnl versions are explictly not supported.
  96 GEN_ASM_OFFSETS=no
  97 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
  98     AC_MSG_CHECKING([whether gcc version is sufficient])
  99     major=0
 100     minor=0
 101
 102     GCC_VERSION=`$CC -dumpversion`
 103     if test $? -eq 0; then
 104         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 105         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 106     fi
 107
 108     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 109         AC_MSG_RESULT([no])
 110         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 111     else
 112         AC_MSG_RESULT([yes])
 113     fi
 114
 115     if test "x$cross_compiling" = xyes; then
 116         GEN_ASM_OFFSETS=yes
 117     fi
 118 fi
 119 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 120
 121 dnl Make sure the pkg-config macros are defined
 122 m4_ifndef([PKG_PROG_PKG_CONFIG],
 123     [m4_fatal([Could not locate the pkg-config autoconf macros.
 124   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 125   are in a different location, try setting the environment variable
 126   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 127 PKG_PROG_PKG_CONFIG()
 128
 129 dnl LIB_DIR - library basename
 130 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 131 AC_SUBST([LIB_DIR])
 132
 133 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 134 _SAVE_LDFLAGS="$LDFLAGS"
 135 _SAVE_CPPFLAGS="$CPPFLAGS"
 136
 137 dnl Compiler macros
 138 DEFINES=""
 139 AC_SUBST([DEFINES])
 140 case "$host_os" in
 141 linux*|*-gnu*|gnu*)
 142     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 143     ;;
 144 solaris*)
 145     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 146     ;;
 147 cygwin*)
 148     DEFINES="$DEFINES -DHAVE_PTHREAD"
 149     ;;
 150 esac
 151
 152 dnl Add flags for gcc and g++
 153 if test "x$GCC" = xyes; then
 154     case "$host_os" in
 155     cygwin*)
 156         CFLAGS="$CFLAGS -Wall -std=gnu99"
 157         ;;
 158     *)
 159         CFLAGS="$CFLAGS -Wall -std=c99"
 160         ;;
 161     esac
 162
 163     # Enable -Werror=implicit-function-declaration and
 164     # -Werror=missing-prototypes, if available, or otherwise, just
 165     # -Wmissing-prototypes.  This is particularly useful to avoid
 166     # generating a loadable driver module that has undefined symbols.
 167     save_CFLAGS="$CFLAGS"
 168     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 169     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 170     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 171     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 172                    AC_MSG_RESULT([yes]),
 173                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 174                     AC_MSG_RESULT([no])]);
 175
 176     # Enable -fvisibility=hidden if using a gcc that supports it
 177     save_CFLAGS="$CFLAGS"
 178     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 179     VISIBILITY_CFLAGS="-fvisibility=hidden"
 180     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 181     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 182                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 183
 184     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 185     CFLAGS=$save_CFLAGS
 186
 187     # Work around aliasing bugs - developers should comment this out
 188     CFLAGS="$CFLAGS -fno-strict-aliasing"
 189
 190     # gcc's builtin memcmp is slower than glibc's
 191     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 192     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 193 fi
 194 if test "x$GXX" = xyes; then
 195     CXXFLAGS="$CXXFLAGS -Wall"
 196
 197     # Enable -fvisibility=hidden if using a gcc that supports it
 198     save_CXXFLAGS="$CXXFLAGS"
 199     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 200     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 201     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 202     AC_LANG_PUSH([C++])
 203     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 204                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 205     AC_LANG_POP([C++])
 206
 207     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 208     CXXFLAGS=$save_CXXFLAGS
 209
 210     # Work around aliasing bugs - developers should comment this out
 211     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 212
 213     # gcc's builtin memcmp is slower than glibc's
 214     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 215     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 216 fi
 217
 218 dnl even if the compiler appears to support it, using visibility attributes isn't
 219 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 220 case "$host_os" in
 221 cygwin*)
 222     VISIBILITY_CFLAGS=""
 223     VISIBILITY_CXXFLAGS=""
 224     ;;
 225 esac
 226
 227 AC_SUBST([VISIBILITY_CFLAGS])
 228 AC_SUBST([VISIBILITY_CXXFLAGS])
 229
 230 dnl
 231 dnl Hacks to enable 32 or 64 bit build
 232 dnl
 233 AC_ARG_ENABLE([32-bit],
 234     [AS_HELP_STRING([--enable-32-bit],
 235         [build 32-bit libraries @<:@default=auto@:>@])],
 236     [enable_32bit="$enableval"],
 237     [enable_32bit=auto]
 238 )
 239 if test "x$enable_32bit" = xyes; then
 240     if test "x$GCC" = xyes; then
 241         CFLAGS="$CFLAGS -m32"
 242         CCASFLAGS="$CCASFLAGS -m32"
 243     fi
 244     if test "x$GXX" = xyes; then
 245         CXXFLAGS="$CXXFLAGS -m32"
 246     fi
 247 fi
 248 AC_ARG_ENABLE([64-bit],
 249     [AS_HELP_STRING([--enable-64-bit],
 250         [build 64-bit libraries @<:@default=auto@:>@])],
 251     [enable_64bit="$enableval"],
 252     [enable_64bit=auto]
 253 )
 254 if test "x$enable_64bit" = xyes; then
 255     if test "x$GCC" = xyes; then
 256         CFLAGS="$CFLAGS -m64"
 257     fi
 258     if test "x$GXX" = xyes; then
 259         CXXFLAGS="$CXXFLAGS -m64"
 260     fi
 261 fi
 262
 263 dnl Can't have static and shared libraries, default to static if user
 264 dnl explicitly requested. If both disabled, set to static since shared
 265 dnl was explicitly requested.
 266 case "x$enable_static$enable_shared" in
 267 xyesyes )
 268     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 269     enable_shared=no
 270     ;;
 271 xnono )
 272     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 273     enable_static=yes
 274     ;;
 275 esac
 276
 277 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 278
 279 dnl
 280 dnl other compiler options
 281 dnl
 282 AC_ARG_ENABLE([debug],
 283     [AS_HELP_STRING([--enable-debug],
 284         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 285     [enable_debug="$enableval"],
 286     [enable_debug=no]
 287 )
 288 if test "x$enable_debug" = xyes; then
 289     DEFINES="$DEFINES -DDEBUG"
 290     if test "x$GCC" = xyes; then
 291         CFLAGS="$CFLAGS -g -O0"
 292     fi
 293     if test "x$GXX" = xyes; then
 294         CXXFLAGS="$CXXFLAGS -g -O0"
 295     fi
 296 fi
 297
 298 dnl
 299 dnl library names
 300 dnl
 301 LIB_PREFIX_GLOB='lib'
 302 LIB_VERSION_SEPARATOR='.'
 303 if test "$enable_static" = yes; then
 304     LIB_EXTENSION='a'
 305 else
 306     case "$host_os" in
 307     darwin* )
 308         LIB_EXTENSION='dylib' ;;
 309     cygwin* )
 310         dnl prefix can be 'cyg' or 'lib'
 311         LIB_PREFIX_GLOB='???'
 312         LIB_VERSION_SEPARATOR='-'
 313         LIB_EXTENSION='dll' ;;
 314     aix* )
 315         LIB_EXTENSION='a' ;;
 316     * )
 317         LIB_EXTENSION='so' ;;
 318     esac
 319 fi
 320 AC_ARG_WITH([gl-lib-name],
 321   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 322     [specify GL library name @<:@default=GL@:>@])],
 323   [GL_LIB=$withval],
 324   [GL_LIB=GL])
 325 AC_ARG_WITH([osmesa-lib-name],
 326   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 327     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 328   [OSMESA_LIB=$withval],
 329   [OSMESA_LIB=OSMesa])
 330 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 331 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 332
 333 dnl
 334 dnl Mangled Mesa support
 335 dnl
 336 AC_ARG_ENABLE([mangling],
 337   [AS_HELP_STRING([--enable-mangling],
 338     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 339   [enable_mangling="${enableval}"],
 340   [enable_mangling=no]
 341 )
 342 if test "x${enable_mangling}" = "xyes" ; then
 343   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 344   GL_LIB="Mangled${GL_LIB}"
 345   OSMESA_LIB="Mangled${OSMESA_LIB}"
 346 fi
 347 AC_SUBST([GL_LIB])
 348 AC_SUBST([OSMESA_LIB])
 349
 350 dnl
 351 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 352 dnl
 353 AC_ARG_ENABLE([texture-float],
 354     [AS_HELP_STRING([--enable-texture-float],
 355         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 356     [enable_texture_float="$enableval"],
 357     [enable_texture_float=no]
 358 )
 359 if test "x$enable_texture_float" = xyes; then
 360     AC_MSG_WARN([Floating-point textures enabled.])
 361     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 362     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 363 fi
 364
 365 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 366 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 367 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 368 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 369 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 370 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 371 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 372
 373 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 374 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 375 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 376 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 377 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 378 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 379 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 380
 381 AC_SUBST([GL_LIB_NAME])
 382 AC_SUBST([OSMESA_LIB_NAME])
 383 AC_SUBST([EGL_LIB_NAME])
 384 AC_SUBST([GLESv1_CM_LIB_NAME])
 385 AC_SUBST([GLESv2_LIB_NAME])
 386 AC_SUBST([VG_LIB_NAME])
 387 AC_SUBST([GLAPI_LIB_NAME])
 388
 389 AC_SUBST([GL_LIB_GLOB])
 390 AC_SUBST([EGL_LIB_GLOB])
 391 AC_SUBST([GLESv1_CM_LIB_GLOB])
 392 AC_SUBST([GLESv2_LIB_GLOB])
 393 AC_SUBST([VG_LIB_GLOB])
 394 AC_SUBST([GLAPI_LIB_GLOB])
 395
 396 dnl
 397 dnl Arch/platform-specific settings
 398 dnl
 399 AC_ARG_ENABLE([asm],
 400     [AS_HELP_STRING([--disable-asm],
 401         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 402     [enable_asm="$enableval"],
 403     [enable_asm=yes]
 404 )
 405 asm_arch=""
 406 AC_MSG_CHECKING([whether to enable assembly])
 407 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 408 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 409 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 410     case "$host_cpu" in
 411     i?86 | x86_64 | amd64)
 412         enable_asm=no
 413         AC_MSG_RESULT([no, cross compiling])
 414         ;;
 415     esac
 416 fi
 417 # check for supported arches
 418 if test "x$enable_asm" = xyes; then
 419     case "$host_cpu" in
 420     i?86)
 421         case "$host_os" in
 422         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 423             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 424             ;;
 425         gnu*)
 426             asm_arch=x86
 427             ;;
 428         esac
 429         ;;
 430     x86_64|amd64)
 431         case "$host_os" in
 432         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 433             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 434             ;;
 435         esac
 436         ;;
 437     sparc*)
 438         case "$host_os" in
 439         linux*)
 440             asm_arch=sparc
 441             ;;
 442         esac
 443         ;;
 444     esac
 445
 446     case "$asm_arch" in
 447     x86)
 448         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 449         AC_MSG_RESULT([yes, x86])
 450         ;;
 451     x86_64|amd64)
 452         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 453         AC_MSG_RESULT([yes, x86_64])
 454         ;;
 455     sparc)
 456         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 457         AC_MSG_RESULT([yes, sparc])
 458         ;;
 459     *)
 460         AC_MSG_RESULT([no, platform not supported])
 461         ;;
 462     esac
 463 fi
 464
 465 dnl Check to see if dlopen is in default libraries (like Solaris, which
 466 dnl has it in libc), or if libdl is needed to get it.
 467 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 468     [AC_CHECK_LIB([dl], [dlopen],
 469        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 470 AC_SUBST([DLOPEN_LIBS])
 471
 472 case "$host_os" in
 473 darwin*|mingw*)
 474     ;;
 475 *)
 476     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 477                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 478                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 479     AC_SUBST([CLOCK_LIB])
 480     ;;
 481 esac
 482
 483 dnl See if posix_memalign is available
 484 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 485
 486 dnl Check for pthreads
 487 AX_PTHREAD
 488 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 489 dnl to -pthread, which causes problems if we need -lpthread to appear in
 490 dnl pkgconfig files.
 491 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 492
 493 dnl SELinux awareness.
 494 AC_ARG_ENABLE([selinux],
 495     [AS_HELP_STRING([--enable-selinux],
 496         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 497     [MESA_SELINUX="$enableval"],
 498     [MESA_SELINUX=no])
 499 if test "x$enable_selinux" = "xyes"; then
 500     AC_CHECK_HEADER([selinux/selinux.h],[],
 501                     [AC_MSG_ERROR([SELinux headers not found])])
 502     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 503                  [AC_MSG_ERROR([SELinux library not found])])
 504     SELINUX_LIBS="-lselinux"
 505     DEFINES="$DEFINES -DMESA_SELINUX"
 506 fi
 507 AC_SUBST([SELINUX_LIBS])
 508
 509 dnl Options for APIs
 510 AC_ARG_ENABLE([opengl],
 511     [AS_HELP_STRING([--disable-opengl],
 512         [disable support for standard OpenGL API @<:@default=no@:>@])],
 513     [enable_opengl="$enableval"],
 514     [enable_opengl=yes])
 515 AC_ARG_ENABLE([gles1],
 516     [AS_HELP_STRING([--enable-gles1],
 517         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 518     [enable_gles1="$enableval"],
 519     [enable_gles1=no])
 520 AC_ARG_ENABLE([gles2],
 521     [AS_HELP_STRING([--enable-gles2],
 522         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 523     [enable_gles2="$enableval"],
 524     [enable_gles2=no])
 525 AC_ARG_ENABLE([openvg],
 526     [AS_HELP_STRING([--enable-openvg],
 527         [enable support for OpenVG API @<:@default=no@:>@])],
 528     [enable_openvg="$enableval"],
 529     [enable_openvg=no])
 530
 531 AC_ARG_ENABLE([dri],
 532     [AS_HELP_STRING([--enable-dri],
 533         [enable DRI modules @<:@default=enabled@:>@])],
 534     [enable_dri="$enableval"],
 535     [enable_dri=yes])
 536 AC_ARG_ENABLE([glx],
 537     [AS_HELP_STRING([--enable-glx],
 538         [enable GLX library @<:@default=enabled@:>@])],
 539     [enable_glx="$enableval"],
 540     [enable_glx=yes])
 541 AC_ARG_ENABLE([osmesa],
 542     [AS_HELP_STRING([--enable-osmesa],
 543         [enable OSMesa library @<:@default=disabled@:>@])],
 544     [enable_osmesa="$enableval"],
 545     [enable_osmesa=no])
 546 AC_ARG_ENABLE([gallium-osmesa],
 547     [AS_HELP_STRING([--enable-gallium-osmesa],
 548         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 549     [enable_gallium_osmesa="$enableval"],
 550     [enable_gallium_osmesa=no])
 551 AC_ARG_ENABLE([egl],
 552     [AS_HELP_STRING([--disable-egl],
 553         [disable EGL library @<:@default=enabled@:>@])],
 554     [enable_egl="$enableval"],
 555     [enable_egl=yes])
 556
 557 AC_ARG_ENABLE([xa],
 558     [AS_HELP_STRING([--enable-xa],
 559         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 560     [enable_xa="$enableval"],
 561     [enable_xa=no])
 562 AC_ARG_ENABLE([gbm],
 563    [AS_HELP_STRING([--enable-gbm],
 564          [enable gbm library @<:@default=auto@:>@])],
 565    [enable_gbm="$enableval"],
 566    [enable_gbm=auto])
 567
 568 AC_ARG_ENABLE([xvmc],
 569    [AS_HELP_STRING([--enable-xvmc],
 570          [enable xvmc library @<:@default=auto@:>@])],
 571    [enable_xvmc="$enableval"],
 572    [enable_xvmc=auto])
 573 AC_ARG_ENABLE([vdpau],
 574    [AS_HELP_STRING([--enable-vdpau],
 575          [enable vdpau library @<:@default=auto@:>@])],
 576    [enable_vdpau="$enableval"],
 577    [enable_vdpau=auto])
 578 AC_ARG_ENABLE([opencl],
 579    [AS_HELP_STRING([--enable-opencl],
 580          [enable OpenCL library NOTE: Enabling this option will also enable
 581           --with-llvm-shared-libs
 582           @<:@default=no@:>@])],
 583    [],
 584    [enable_opencl=no])
 585 AC_ARG_ENABLE([opencl_icd],
 586    [AS_HELP_STRING([--enable-opencl-icd],
 587           [Build an OpenCL ICD library to be loaded by an ICD implementation
 588            @<:@default=no@:>@])],
 589     [enable_opencl_icd="$enableval"],
 590     [enable_opencl_icd=no])
 591 AC_ARG_ENABLE([xlib-glx],
 592     [AS_HELP_STRING([--enable-xlib-glx],
 593         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 594     [enable_xlib_glx="$enableval"],
 595     [enable_xlib_glx=no])
 596 AC_ARG_ENABLE([gallium-egl],
 597     [AS_HELP_STRING([--enable-gallium-egl],
 598         [enable optional EGL state tracker (not required
 599          for EGL support in Gallium with OpenGL and OpenGL ES)
 600          @<:@default=disable@:>@])],
 601     [enable_gallium_egl="$enableval"],
 602     [enable_gallium_egl=no])
 603 AC_ARG_ENABLE([gallium-gbm],
 604     [AS_HELP_STRING([--enable-gallium-gbm],
 605         [enable optional gbm state tracker (not required for
 606          gbm support in Gallium)
 607          @<:@default=auto@:>@])],
 608     [enable_gallium_gbm="$enableval"],
 609     [enable_gallium_gbm=auto])
 610
 611 AC_ARG_ENABLE([r600-llvm-compiler],
 612     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 613         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 614     [enable_r600_llvm="$enableval"],
 615     [enable_r600_llvm=no])
 616
 617 AC_ARG_ENABLE([gallium-tests],
 618     [AS_HELP_STRING([--enable-gallium-tests],
 619         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 620     [enable_gallium_tests="$enableval"],
 621     [enable_gallium_tests=no])
 622
 623 # Option for Gallium drivers
 624
 625 # Keep this in sync with the --with-gallium-drivers help string default value
 626 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 627
 628 AC_ARG_WITH([gallium-drivers],
 629     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 630         [comma delimited Gallium drivers list, e.g.
 631         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 632         @<:@default=r300,r600,svga,swrast@:>@])],
 633     [with_gallium_drivers="$withval"],
 634     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 635
 636 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 637 # here so that the script doesn't choke on an unknown driver name later.
 638 case "$with_gallium_drivers" in
 639     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 640     no) with_gallium_drivers='' ;;
 641 esac
 642
 643 if test "x$enable_opengl" = xno -a \
 644         "x$enable_gles1" = xno -a \
 645         "x$enable_gles2" = xno -a \
 646         "x$enable_openvg" = xno -a \
 647         "x$enable_xa" = xno -a \
 648         "x$enable_xvmc" = xno -a \
 649         "x$enable_vdpau" = xno -a \
 650         "x$enable_opencl" = xno; then
 651     AC_MSG_ERROR([at least one API should be enabled])
 652 fi
 653
 654 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 655 if test "x$enable_opengl" = xno -a \
 656         "x$enable_gles1" = xyes; then
 657     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 658 fi
 659
 660 if test "x$enable_opengl" = xno -a \
 661         "x$enable_gles2" = xyes; then
 662     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 663 fi
 664
 665 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 666 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 667 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 668 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 669                                         "x$enable_gles1" = xyes -o \
 670                                         "x$enable_gles2" = xyes)
 671
 672 if test "x$enable_glx" = xno; then
 673     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 674     enable_xlib_glx=no
 675 fi
 676
 677 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 678     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 679 fi
 680
 681 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 682     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 683 fi
 684
 685 # Disable GLX if OpenGL is not enabled
 686 if test "x$enable_glx$enable_opengl" = xyesno; then
 687     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 688     enable_glx=no
 689 fi
 690
 691 # Disable GLX if DRI and Xlib-GLX are not enabled
 692 if test "x$enable_glx" = xyes -a \
 693         "x$enable_dri" = xno -a \
 694         "x$enable_xlib_glx" = xno; then
 695     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 696     enable_glx=no
 697 fi
 698
 699 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 700                                   "x$enable_dri" = xyes)
 701 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 702
 703 AC_ARG_ENABLE([shared-glapi],
 704     [AS_HELP_STRING([--enable-shared-glapi],
 705         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 706     [enable_shared_glapi="$enableval"],
 707     [enable_shared_glapi="$enable_dri"])
 708
 709 # Shared GLAPI is only useful for DRI
 710 if test "x$enable_dri" = xno; then
 711     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 712     enable_shared_glapi=no
 713 fi
 714
 715 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 716
 717 dnl
 718 dnl Driver specific build directories
 719 dnl
 720 GALLIUM_TARGET_DIRS=""
 721 GALLIUM_WINSYS_DIRS="sw"
 722 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 723 GALLIUM_STATE_TRACKERS_DIRS=""
 724
 725 case "x$enable_glx$enable_xlib_glx" in
 726 xyesyes)
 727     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 728     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 729     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 730     NEED_WINSYS_XLIB="yes"
 731     ;;
 732 esac
 733
 734 if test "x$enable_dri" = xyes; then
 735     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 736     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 737 fi
 738
 739 if test "x$enable_gallium_osmesa" = xyes; then
 740     if test -z "$with_gallium_drivers"; then
 741         AC_MSG_ERROR([Cannot enable gallium_osmesa without Gallium])
 742     fi
 743     if test "x$enable_osmesa" = xyes; then
 744         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
 745     fi
 746     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 747     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 748 fi
 749
 750 AC_SUBST([MESA_LLVM])
 751
 752 # Check for libdrm
 753 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 754                   [have_libdrm=yes], [have_libdrm=no])
 755
 756 if test "x$enable_dri" = xyes; then
 757     # DRI must be shared, I think
 758     if test "$enable_static" = yes; then
 759         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 760     fi
 761
 762     # not a hard requirement as swrast does not depend on it
 763     if test "x$have_libdrm" = xyes; then
 764         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 765     fi
 766 fi
 767
 768 dnl Direct rendering or just indirect rendering
 769 case "$host_os" in
 770 gnu*)
 771     dnl Disable by default on GNU/Hurd
 772     driglx_direct_default="no"
 773     ;;
 774 cygwin*)
 775     dnl Disable by default on cygwin
 776     driglx_direct_default="no"
 777     ;;
 778 *)
 779     driglx_direct_default="yes"
 780     ;;
 781 esac
 782 AC_ARG_ENABLE([driglx-direct],
 783     [AS_HELP_STRING([--disable-driglx-direct],
 784         [disable direct rendering in GLX and EGL for DRI \
 785             @<:@default=auto@:>@])],
 786     [driglx_direct="$enableval"],
 787     [driglx_direct="$driglx_direct_default"])
 788
 789 dnl
 790 dnl libGL configuration per driver
 791 dnl
 792 case "x$enable_glx$enable_xlib_glx" in
 793 xyesyes)
 794     # Xlib-based GLX
 795     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 796     GL_PC_REQ_PRIV="x11 xext"
 797     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 798     GL_LIB_DEPS="$XLIBGL_LIBS"
 799     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 800     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 801     ;;
 802 xyesno)
 803     # DRI-based GLX
 804     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 805     if test x"$driglx_direct" = xyes; then
 806         if test "x$have_libdrm" != xyes; then
 807             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 808         fi
 809         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 810         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 811     fi
 812
 813     # find the DRI deps for libGL
 814     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 815
 816     # add xf86vidmode if available
 817     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 818     if test "$HAVE_XF86VIDMODE" = yes ; then
 819         dri_modules="$dri_modules xxf86vm"
 820     fi
 821
 822     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 823     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 824     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 825     GL_LIB_DEPS="$DRIGL_LIBS"
 826
 827     # need DRM libs, $PTHREAD_LIBS, etc.
 828     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 829     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 830     ;;
 831 esac
 832
 833 # This is outside the case (above) so that it is invoked even for non-GLX
 834 # builds.
 835 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 836
 837 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 838 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 839 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 840 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 841
 842 AC_SUBST([X11_INCLUDES])
 843 AC_SUBST([GL_LIB_DEPS])
 844 AC_SUBST([GL_PC_REQ_PRIV])
 845 AC_SUBST([GL_PC_LIB_PRIV])
 846 AC_SUBST([GL_PC_CFLAGS])
 847 AC_SUBST([DRI_PC_REQ_PRIV])
 848 AC_SUBST([GLESv1_CM_LIB_DEPS])
 849 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 850 AC_SUBST([GLESv2_LIB_DEPS])
 851 AC_SUBST([GLESv2_PC_LIB_PRIV])
 852
 853 AC_SUBST([HAVE_XF86VIDMODE])
 854
 855 dnl
 856 dnl More GLX setup
 857 dnl
 858 case "x$enable_glx$enable_xlib_glx" in
 859 xyesyes)
 860     DEFINES="$DEFINES -DUSE_XSHM"
 861     ;;
 862 xyesno)
 863     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 864     if test "x$driglx_direct" = xyes; then
 865         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 866     fi
 867     ;;
 868 esac
 869
 870 dnl
 871 dnl TLS detection
 872 dnl
 873
 874 AC_ARG_ENABLE([glx-tls],
 875     [AS_HELP_STRING([--enable-glx-tls],
 876         [enable TLS support in GLX @<:@default=disabled@:>@])],
 877     [GLX_USE_TLS="$enableval"],
 878     [GLX_USE_TLS=no])
 879 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 880
 881 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 882       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 883
 884 dnl
 885 dnl More DRI setup
 886 dnl
 887 dnl Directory for DRI drivers
 888 AC_ARG_WITH([dri-driverdir],
 889     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 890         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 891     [DRI_DRIVER_INSTALL_DIR="$withval"],
 892     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 893 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 894 dnl Extra search path for DRI drivers
 895 AC_ARG_WITH([dri-searchpath],
 896     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 897         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 898     [DRI_DRIVER_SEARCH_DIR="$withval"],
 899     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 900 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 901 dnl Which drivers to build - default is chosen by platform
 902 AC_ARG_WITH([dri-drivers],
 903     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 904         [comma delimited DRI drivers list, e.g.
 905         "swrast,i965,radeon" @<:@default=auto@:>@])],
 906     [with_dri_drivers="$withval"],
 907     [with_dri_drivers=yes])
 908 if test "x$with_dri_drivers" = x; then
 909     with_dri_drivers=no
 910 fi
 911
 912 dnl If $with_dri_drivers is yes, directories will be added through
 913 dnl platform checks
 914 DRI_DIRS=""
 915 case "$with_dri_drivers" in
 916 no) ;;
 917 yes)
 918     # classic DRI drivers
 919     if test "x$enable_opengl" = xyes; then
 920         DRI_DIRS="yes"
 921     fi
 922     ;;
 923 *)
 924     # verify the requested driver directories exist
 925     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 926     for driver in $dri_drivers; do
 927         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 928             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 929     done
 930     DRI_DIRS="$dri_drivers"
 931     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 932         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 933     fi
 934     ;;
 935 esac
 936
 937 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 938 if test "x$enable_dri" = xyes; then
 939     # Platform specific settings and drivers to build
 940     case "$host_os" in
 941     linux*)
 942         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 943         DEFINES="$DEFINES -DHAVE_ALIAS"
 944
 945         case "$host_cpu" in
 946         x86_64|amd64)
 947             if test "x$DRI_DIRS" = "xyes"; then
 948                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 949             fi
 950             ;;
 951         powerpc*)
 952             # Build only the drivers for cards that exist on PowerPC.
 953             if test "x$DRI_DIRS" = "xyes"; then
 954                 DRI_DIRS="r200 radeon swrast"
 955             fi
 956             ;;
 957         sparc*)
 958             # Build only the drivers for cards that exist on sparc
 959             if test "x$DRI_DIRS" = "xyes"; then
 960                 DRI_DIRS="r200 radeon swrast"
 961             fi
 962             ;;
 963         esac
 964         ;;
 965     *freebsd* | dragonfly* | *netbsd* | openbsd*)
 966         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 967         DEFINES="$DEFINES -DHAVE_ALIAS"
 968
 969         if test "x$DRI_DIRS" = "xyes"; then
 970             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 971         fi
 972         ;;
 973     gnu*)
 974         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 975         DEFINES="$DEFINES -DHAVE_ALIAS"
 976         ;;
 977     solaris*)
 978         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 979         ;;
 980     cygwin*)
 981         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 982         if test "x$DRI_DIRS" = "xyes"; then
 983             DRI_DIRS="swrast"
 984         fi
 985         ;;
 986     esac
 987
 988     # default drivers
 989     if test "x$DRI_DIRS" = "xyes"; then
 990         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 991     fi
 992
 993     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 994
 995     # Check for expat
 996     PKG_CHECK_EXISTS([EXPAT], [have_expat=yes], [have_expat=no])
 997     if test "x$have_expat" = "xyes"; then
 998        PKG_CHECK_MODULES([EXPAT], [expat], [],
 999                          AC_MSG_ERROR([Expat required for DRI.]))
1000     else
1001        # expat version 2.0 and earlier do not provide expat.pc
1002        EXPAT_LIBS=-lexpat
1003     fi
1004
1005     # If we are building any DRI driver other than swrast.
1006     if test -n "$DRI_DIRS"; then
1007         if test x"$DRI_DIRS" != xswrast; then
1008             # ... libdrm is required
1009             if test "x$have_libdrm" != xyes; then
1010                 AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1011             fi
1012             DRICOMMON_NEED_LIBDRM=yes
1013         else
1014             DRICOMMON_NEED_LIBDRM=no
1015         fi
1016     fi
1017
1018     # put all the necessary libs together
1019     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1020     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1021
1022     DRI_DRIVER_LDFLAGS="-module -avoid-version -shared -Wl,-Bsymbolic"
1023 fi
1024
1025 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1026 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
1027                                   "x$enable_osmesa" = xyes -o \
1028                                   -n "$DRI_DIRS")
1029 AC_SUBST([DRI_LIB_DEPS])
1030 AC_SUBST([DRI_DRIVER_LDFLAGS])
1031 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1032
1033 case $DRI_DIRS in
1034 *i915*|*i965*)
1035     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1036
1037     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1038         case $d in
1039         i915)
1040             HAVE_I915_DRI=yes;
1041             ;;
1042         i965)
1043             HAVE_I965_DRI=yes;
1044             ;;
1045         esac
1046     done
1047
1048     ;;
1049 esac
1050
1051 case $DRI_DIRS in
1052 *nouveau*)
1053     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1054     HAVE_NOUVEAU_DRI=yes;
1055     ;;
1056 esac
1057
1058 case $DRI_DIRS in
1059 *radeon*|*r200*)
1060     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1061
1062     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1063         case $d in
1064         radeon)
1065             HAVE_RADEON_DRI=yes;
1066             ;;
1067         r200)
1068             HAVE_R200_DRI=yes;
1069             ;;
1070         esac
1071     done
1072
1073     ;;
1074 esac
1075
1076 case $DRI_DIRS in
1077 *swrast*)
1078     HAVE_SWRAST_DRI=yes;
1079     ;;
1080 esac
1081
1082 dnl
1083 dnl OSMesa configuration
1084 dnl
1085
1086 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1087 AC_ARG_WITH([osmesa-bits],
1088     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1089         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1090     [osmesa_bits="$withval"],
1091     [osmesa_bits=8])
1092 if test "x$osmesa_bits" != x8; then
1093     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1094         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1095         osmesa_bits=8
1096     fi
1097 fi
1098 case "x$osmesa_bits" in
1099 x8)
1100     OSMESA_LIB="${OSMESA_LIB}"
1101     ;;
1102 x16|x32)
1103     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1104     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1105     ;;
1106 *)
1107     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1108     ;;
1109 esac
1110
1111 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1112     # only link libraries with osmesa if shared
1113     if test "$enable_static" = no; then
1114         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1115     else
1116         OSMESA_LIB_DEPS=""
1117     fi
1118     OSMESA_MESA_DEPS=""
1119     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1120 fi
1121
1122 AC_SUBST([OSMESA_LIB_DEPS])
1123 AC_SUBST([OSMESA_MESA_DEPS])
1124 AC_SUBST([OSMESA_PC_REQ])
1125 AC_SUBST([OSMESA_PC_LIB_PRIV])
1126
1127 dnl
1128 dnl gbm configuration
1129 dnl
1130 if test "x$enable_gbm" = xauto; then
1131     case "$with_egl_platforms" in
1132         *drm*)
1133             enable_gbm=yes ;;
1134          *)
1135             enable_gbm=no ;;
1136     esac
1137 fi
1138 if test "x$enable_gbm" = xyes; then
1139     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1140                       AC_MSG_ERROR([gbm needs udev]))
1141
1142     if test "x$enable_dri" = xyes; then
1143         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1144         if test "x$enable_shared_glapi" = xno; then
1145             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1146         fi
1147     fi
1148 fi
1149 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1150 GBM_PC_REQ_PRIV="libudev"
1151 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1152 AC_SUBST([GBM_PC_REQ_PRIV])
1153 AC_SUBST([GBM_PC_LIB_PRIV])
1154
1155 dnl
1156 dnl EGL configuration
1157 dnl
1158 EGL_CLIENT_APIS=""
1159
1160 if test "x$enable_egl" = xyes; then
1161     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1162
1163     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1164
1165     if test "$enable_static" != yes; then
1166         # build egl_glx when libGL is built
1167         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1168                           [have_libudev=yes],[have_libudev=no])
1169         if test "$have_libudev" = yes; then
1170             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1171         fi
1172
1173         if test "x$enable_dri" = xyes; then
1174             HAVE_EGL_DRIVER_DRI2=1
1175         fi
1176
1177     fi
1178 fi
1179 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1180 AC_SUBST([EGL_LIB_DEPS])
1181
1182 dnl
1183 dnl EGL Gallium configuration
1184 dnl
1185 if test "x$enable_gallium_egl" = xyes; then
1186     if test "x$with_gallium_drivers" = x; then
1187         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1188     fi
1189     if test "x$enable_egl" = xno; then
1190         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1191     fi
1192     if test "x$have_libdrm" != xyes; then
1193         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1194     fi
1195
1196     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1197     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1198 fi
1199 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1200
1201 dnl
1202 dnl gbm Gallium configuration
1203 dnl
1204 if test "x$enable_gallium_gbm" = xauto; then
1205     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1206         yesyesyes*drm*)
1207             enable_gallium_gbm=yes ;;
1208          *)
1209             enable_gallium_gbm=no ;;
1210     esac
1211 fi
1212 if test "x$enable_gallium_gbm" = xyes; then
1213     if test "x$with_gallium_drivers" = x; then
1214         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1215     fi
1216     if test "x$enable_gbm" = xno; then
1217         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1218     fi
1219     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1220     if test "x$enable_dri" = xno; then
1221         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1222     fi
1223
1224     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1225     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1226     enable_gallium_loader=yes
1227 fi
1228 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1229
1230 dnl
1231 dnl XA configuration
1232 dnl
1233 if test "x$enable_xa" = xyes; then
1234     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1235 fi
1236 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1237
1238 dnl
1239 dnl OpenVG configuration
1240 dnl
1241 VG_LIB_DEPS=""
1242
1243 if test "x$enable_openvg" = xyes; then
1244     if test "x$enable_egl" = xno; then
1245         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1246     fi
1247     if test "x$with_gallium_drivers" = x; then
1248         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1249     fi
1250     if test "x$enable_gallium_egl" = xno; then
1251         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1252     fi
1253
1254     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1255     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1256     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1257     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1258     AC_SUBST([VG_PC_LIB_PRIV])
1259 fi
1260 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1261
1262 dnl
1263 dnl Gallium G3DVL configuration
1264 dnl
1265 if test -n "$with_gallium_drivers"; then
1266     if test "x$enable_xvmc" = xauto; then
1267         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1268     fi
1269
1270     if test "x$enable_vdpau" = xauto; then
1271         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1272     fi
1273 fi
1274
1275 if test "x$enable_xvmc" = xyes; then
1276     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1277     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1278 fi
1279 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1280
1281 if test "x$enable_vdpau" = xyes; then
1282     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1283     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1284 fi
1285 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1286
1287 dnl
1288 dnl OpenCL configuration
1289 dnl
1290
1291 AC_ARG_WITH([libclc-path],
1292    [AS_HELP_STRING([--with-libclc-path],
1293          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1294    [LIBCLC_PATH="$withval"],
1295    [LIBCLC_PATH=""])
1296
1297 if test "x$LIBCLC_PATH" != x; then
1298    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1299                   Please review the updated build instructions for clover:
1300                   http://dri.freedesktop.org/wiki/GalliumCompute])
1301 fi
1302
1303
1304 AC_ARG_WITH([clang-libdir],
1305    [AS_HELP_STRING([--with-clang-libdir],
1306          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1307    [CLANG_LIBDIR="$withval"],
1308    [CLANG_LIBDIR=""])
1309
1310 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1311
1312 if test "x$enable_opencl" = xyes; then
1313     if test "x$with_gallium_drivers" = x; then
1314         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1315     fi
1316
1317     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1318         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1319     fi
1320
1321     if test "x$have_libclc" = xno; then
1322         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1323                     Make sure the directory containing libclc.pc is specified in your
1324                     PKG_CONFIG_PATH environment variable.
1325                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1326     else
1327         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1328         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1329         AC_SUBST([LIBCLC_INCLUDEDIR])
1330         AC_SUBST([LIBCLC_LIBEXECDIR])
1331     fi
1332
1333     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1334     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1335     enable_gallium_loader=yes
1336
1337     if test "x$enable_opencl_icd" = xyes; then
1338         OPENCL_LIBNAME="MesaOpenCL"
1339     else
1340         OPENCL_LIBNAME="OpenCL"
1341     fi
1342 fi
1343 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1344 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1345 AC_SUBST([OPENCL_LIBNAME])
1346
1347 dnl
1348 dnl Gallium configuration
1349 dnl
1350 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1351
1352 AC_SUBST([LLVM_BINDIR])
1353 AC_SUBST([LLVM_CFLAGS])
1354 AC_SUBST([LLVM_CPPFLAGS])
1355 AC_SUBST([LLVM_CXXFLAGS])
1356 AC_SUBST([LLVM_LIBDIR])
1357 AC_SUBST([LLVM_LIBS])
1358 AC_SUBST([LLVM_LDFLAGS])
1359 AC_SUBST([LLVM_INCLUDEDIR])
1360 AC_SUBST([LLVM_VERSION])
1361 AC_SUBST([CLANG_RESOURCE_DIR])
1362
1363 case "x$enable_opengl$enable_gles1$enable_gles2" in
1364 x*yes*)
1365     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1366     ;;
1367 esac
1368
1369 AC_SUBST([VG_LIB_DEPS])
1370 AC_SUBST([EGL_CLIENT_APIS])
1371
1372 dnl
1373 dnl EGL Platforms configuration
1374 dnl
1375 AC_ARG_WITH([egl-platforms],
1376     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1377         [comma delimited native platforms libEGL supports, e.g.
1378         "x11,drm" @<:@default=auto@:>@])],
1379     [with_egl_platforms="$withval"],
1380     [if test "x$enable_egl" = xyes; then
1381         with_egl_platforms="x11"
1382     else
1383         with_egl_platforms=""
1384     fi])
1385
1386 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1387     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1388 fi
1389
1390 # Do per-EGL platform setups and checks
1391 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1392 for plat in $egl_platforms; do
1393         case "$plat" in
1394         wayland)
1395                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.2.0 wayland-server >= 1.2.0])
1396                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1397
1398                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1399                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1400                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1401                 ;;
1402
1403         x11)
1404                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1405
1406                 if test "x$enable_glx" = xyes; then
1407                         HAVE_EGL_DRIVER_GLX=1
1408                 fi
1409                 ;;
1410
1411         drm)
1412                 test "x$enable_gbm" = "xno" &&
1413                         AC_MSG_ERROR([EGL platform drm needs gbm])
1414                 ;;
1415
1416         android|fbdev|gdi|null)
1417                 ;;
1418
1419         *)
1420                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1421                 ;;
1422         esac
1423
1424         case "$plat$have_libudev" in
1425                 waylandno|drmno)
1426                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1427         esac
1428 done
1429
1430 # libEGL wants to default to the first platform specified in
1431 # ./configure.  parse that here.
1432 if test "x$egl_platforms" != "x"; then
1433     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1434     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1435 else
1436     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1437 fi
1438
1439 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1440     NEED_WINSYS_XLIB=yes
1441 fi
1442 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1443 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1444 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1445 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1446 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1447
1448 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1449 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1450
1451 AC_SUBST([EGL_NATIVE_PLATFORM])
1452 AC_SUBST([EGL_CFLAGS])
1453
1454 # If we don't have the X11 platform, set this define so we don't try to include
1455 # the X11 headers.
1456 if ! echo "$egl_platforms" | grep -q 'x11'; then
1457     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
1458     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
1459 fi
1460
1461 AC_ARG_WITH([egl-driver-dir],
1462     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1463                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1464     [EGL_DRIVER_INSTALL_DIR="$withval"],
1465     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1466 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1467
1468 AC_ARG_WITH([max-width],
1469     [AS_HELP_STRING([--with-max-width=N],
1470                     [Maximum framebuffer width (4096)])],
1471     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1472      AS_IF([test "${withval}" -gt "4096"],
1473            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1474 )
1475 AC_ARG_WITH([max-height],
1476     [AS_HELP_STRING([--with-max-height=N],
1477                     [Maximum framebuffer height (4096)])],
1478     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1479      AS_IF([test "${withval}" -gt "4096"],
1480            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1481 )
1482
1483 dnl
1484 dnl Gallium LLVM
1485 dnl
1486 AC_ARG_ENABLE([gallium-llvm],
1487     [AS_HELP_STRING([--enable-gallium-llvm],
1488         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1489     [enable_gallium_llvm="$enableval"],
1490     [enable_gallium_llvm=auto])
1491
1492 AC_ARG_WITH([llvm-shared-libs],
1493     [AS_HELP_STRING([--with-llvm-shared-libs],
1494         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1495     [],
1496     [with_llvm_shared_libs=no])
1497 AS_IF([test x$enable_opencl = xyes],
1498     [
1499         if test "x$with_llvm_shared_libs" != xyes; then
1500             AC_MSG_ERROR([OpenCL requires LLVM shared libraries])
1501         fi
1502     ])
1503
1504 AC_ARG_WITH([llvm-prefix],
1505     [AS_HELP_STRING([--with-llvm-prefix],
1506         [Prefix for LLVM installations in non-standard locations])],
1507     [llvm_prefix="$withval"],
1508     [llvm_prefix=""])
1509
1510
1511 # Call this inside ` ` to get the return value.
1512 # $1 is the llvm-config command with arguments.
1513 strip_unwanted_llvm_flags() {
1514     # Use \> (marks the end of the word)
1515     echo `$1` | sed \
1516         -e 's/-DNDEBUG\>//g' \
1517         -e 's/-pedantic\>//g' \
1518         -e 's/-Wcovered-switch-default\>//g' \
1519         -e 's/-O.\>//g' \
1520         -e 's/-g\>//g' \
1521         -e 's/-Wall\>//g' \
1522         -e 's/-fomit-frame-pointer\>//g'
1523 }
1524
1525
1526 if test "x$with_gallium_drivers" = x; then
1527     enable_gallium_llvm=no
1528 fi
1529 if test "x$enable_gallium_llvm" = xauto; then
1530     case "$host_cpu" in
1531     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
1532     esac
1533 fi
1534 if test "x$enable_gallium_llvm" = xyes; then
1535     if test "x$llvm_prefix" != x; then
1536         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1537     else
1538         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1539     fi
1540
1541     if test "x$LLVM_CONFIG" != xno; then
1542         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1543         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1544         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1545         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1546         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1547         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1548         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1549         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1550
1551         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
1552             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1553         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
1554             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
1555
1556         if test "x${LLVM_VERSION_MAJOR}" != x; then
1557             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
1558         else
1559             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1560         fi
1561
1562         LLVM_COMPONENTS="engine bitwriter"
1563         if $LLVM_CONFIG --components | grep -qw 'mcjit'; then
1564             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1565         fi
1566
1567         if test "x$enable_opencl" = xyes; then
1568             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1569             # LLVM 3.3 >= 177971 requires IRReader
1570             if $LLVM_CONFIG --components | grep -qw 'irreader'; then
1571                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1572             fi
1573             # LLVM 3.4 requires Option
1574             if $LLVM_CONFIG --components | grep -qw 'option'; then
1575                 LLVM_COMPONENTS="${LLVM_COMPONENTS} option"
1576             fi
1577         fi
1578         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1579         MESA_LLVM=1
1580
1581         dnl Check for Clang internal headers
1582         if test "x$enable_opencl" = xyes; then
1583             if test "x$CLANG_LIBDIR" = x; then
1584                 CLANG_LIBDIR=${LLVM_LIBDIR}
1585             fi
1586             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1587             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
1588                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
1589         fi
1590     else
1591         MESA_LLVM=0
1592         LLVM_VERSION_INT=0
1593     fi
1594 else
1595     MESA_LLVM=0
1596     LLVM_VERSION_INT=0
1597 fi
1598
1599 dnl Directory for XVMC libs
1600 AC_ARG_WITH([xvmc-libdir],
1601     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1602         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1603     [XVMC_LIB_INSTALL_DIR="$withval"],
1604     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1605 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1606
1607 dnl
1608 dnl Gallium Tests
1609 dnl
1610 if test "x$enable_gallium_tests" = xyes; then
1611     enable_gallium_loader=yes
1612 fi
1613 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1614
1615 if test "x$enable_gallium_loader" = xyes; then
1616     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1617 fi
1618 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1619
1620 dnl Directory for VDPAU libs
1621 AC_ARG_WITH([vdpau-libdir],
1622     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1623         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1624     [VDPAU_LIB_INSTALL_DIR="$withval"],
1625     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1626 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1627
1628 dnl Directory for OpenCL libs
1629 AC_ARG_WITH([opencl-libdir],
1630     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1631         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1632     [OPENCL_LIB_INSTALL_DIR="$withval"],
1633     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1634 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1635
1636 dnl
1637 dnl Gallium helper functions
1638 dnl
1639 gallium_check_st() {
1640     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1641          if test "x$have_libdrm" != xyes; then
1642             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1643          fi
1644          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1645     fi
1646     if test "x$enable_dri" = xyes && test "x$2" != x; then
1647          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1648     fi
1649     if test "x$enable_xa" = xyes && test "x$3" != x; then
1650          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1651     fi
1652     if test "x$enable_xvmc" = xyes && test "x$4" != x; then
1653          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1654     fi
1655     if test "x$enable_vdpau" = xyes && test "x$5" != x; then
1656          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1657     fi
1658 }
1659
1660 gallium_require_llvm() {
1661     if test "x$MESA_LLVM" = x0; then
1662         case "$host_cpu" in
1663         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1664         esac
1665     fi
1666 }
1667
1668 gallium_require_drm_loader() {
1669     if test "x$enable_gallium_loader" = xyes; then
1670         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1671                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1672         if test "x$have_libdrm" != xyes; then
1673             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1674         fi
1675         enable_gallium_drm_loader=yes
1676     fi
1677 }
1678
1679 radeon_llvm_check() {
1680     LLVM_REQUIRED_VERSION_MAJOR="3"
1681     LLVM_REQUIRED_VERSION_MINOR="3"
1682     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1683         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1684     fi
1685     if test true && $LLVM_CONFIG --targets-built | grep -qvw 'R600' ; then
1686         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1687                       sources with the --enable-experimental-targets=R600
1688                       configure flag])
1689     fi
1690     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader ipo"
1691     NEED_RADEON_LLVM=yes
1692     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1693                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1694 }
1695
1696 dnl Gallium drivers
1697 if test "x$enable_dri" = xyes -o "x$enable_xa" = xyes -o \
1698         "x$enable_xvmc" = xyes -o "x$enable_vdpau" = xyes; then
1699     NEED_NONNULL_WINSYS=yes
1700 fi
1701 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1702
1703 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1704 if test "x$with_gallium_drivers" != x; then
1705     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1706     for driver in $gallium_drivers; do
1707         case "x$driver" in
1708         xsvga)
1709             HAVE_GALLIUM_SVGA=yes
1710             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1711             gallium_check_st "svga/drm" "dri-vmwgfx" "xa-vmwgfx"
1712             ;;
1713         xi915)
1714             HAVE_GALLIUM_I915=yes
1715             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1716             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1717             if test "x$MESA_LLVM" = x1; then
1718                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1719             fi
1720             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1721             gallium_check_st "i915/drm" "dri-i915"
1722             DRICOMMON_NEED_LIBDRM=yes
1723             ;;
1724         xilo)
1725             HAVE_GALLIUM_ILO=yes
1726             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1727             gallium_require_drm_loader
1728             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1729             gallium_check_st "intel/drm" "dri-ilo"
1730             DRICOMMON_NEED_LIBDRM=yes
1731             ;;
1732         xr300)
1733             HAVE_GALLIUM_R300=yes
1734             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1735             gallium_require_llvm "Gallium R300"
1736             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1737             gallium_check_st "radeon/drm" "r300/dri" "" "" ""
1738             DRICOMMON_NEED_LIBDRM=yes
1739             ;;
1740         xr600)
1741             HAVE_GALLIUM_R600=yes
1742             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1743             gallium_require_drm_loader
1744             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1745             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1746                 radeon_llvm_check
1747                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1748             fi
1749             if test "x$enable_r600_llvm" = xyes; then
1750                 USE_R600_LLVM_COMPILER=yes;
1751             fi
1752             if test "x$enable_opencl" = xyes; then
1753                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1754             fi
1755             gallium_check_st "radeon/drm" "r600/dri" "" "r600/xvmc" "r600/vdpau"
1756             DRICOMMON_NEED_LIBDRM=yes
1757             ;;
1758         xradeonsi)
1759             HAVE_GALLIUM_RADEONSI=yes
1760             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1761             gallium_require_drm_loader
1762             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1763             radeon_llvm_check
1764             gallium_check_st "radeon/drm" "radeonsi/dri" "" "" "radeonsi/vdpau"
1765             DRICOMMON_NEED_LIBDRM=yes
1766             ;;
1767         xnouveau)
1768             HAVE_GALLIUM_NOUVEAU=yes
1769             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1770             gallium_require_drm_loader
1771             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau"
1772             gallium_check_st "nouveau/drm" "dri-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1773             DRICOMMON_NEED_LIBDRM=yes
1774             ;;
1775         xfreedreno)
1776             HAVE_GALLIUM_FREEDRENO=yes
1777             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1778             gallium_require_drm_loader
1779             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1780             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" ""
1781             DRICOMMON_NEED_LIBDRM=yes
1782             ;;
1783         xswrast)
1784             HAVE_GALLIUM_SOFTPIPE=yes
1785             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1786             if test "x$MESA_LLVM" = x1; then
1787                 HAVE_GALLIUM_LLVMPIPE=yes
1788                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1789             fi
1790
1791             if test "x$enable_dri" = xyes; then
1792                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1793             fi
1794             ;;
1795         *)
1796             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1797             ;;
1798         esac
1799     done
1800 fi
1801
1802 dnl Set LLVM_LIBS - This is done after the driver configuration so
1803 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1804 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1805 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1806 dnl this was causing the same libraries to be appear multiple times
1807 dnl in LLVM_LIBS.
1808
1809 if test "x$MESA_LLVM" != x0; then
1810
1811     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1812
1813     if test "x$with_llvm_shared_libs" = xyes; then
1814         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1815         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1816         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.so"], [llvm_have_one_so=yes])
1817
1818         if test "x$llvm_have_one_so" = xyes; then
1819             dnl LLVM was built using auto*, so there is only one shared object.
1820             LLVM_LIBS="-l$LLVM_SO_NAME"
1821         else
1822             dnl If LLVM was built with CMake, there will be one shared object per
1823             dnl component.
1824             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.so"],
1825                     [AC_MSG_ERROR([Could not find llvm shared libraries:
1826         Please make sure you have built llvm with the --enable-shared option
1827         and that your llvm libraries are installed in $LLVM_LIBDIR
1828         If you have installed your llvm libraries to a different directory you
1829         can use the --with-llvm-prefix= configure flag to specify this directory.
1830         NOTE: Mesa is attempting to use llvm shared libraries because you have
1831         passed one of the following options to configure:
1832                 --with-llvm-shared-libs
1833                 --enable-opencl
1834         If you do not want to build with llvm shared libraries and instead want to
1835         use llvm static libraries then remove these options from your configure
1836         invocation and reconfigure.])])
1837
1838            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1839            dnl install uses a shared object for each compoenent and we have
1840            dnl already added all of these objects to LLVM_LIBS.
1841         fi
1842     fi
1843 fi
1844
1845 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1846 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1847 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1848 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1849 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1850 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1851 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1852 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1853 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1854 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1855
1856 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1857                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1858                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1859 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1860                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes \
1861                                                   && test "x$MESA_LLVM" = x1)
1862
1863 if test "x$enable_gallium_loader" = xyes; then
1864     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1865
1866     if test "x$enable_gallium_drm_loader" = xyes; then
1867         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1868         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1869                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1870         if test "x$pipe_loader_have_xcb" = xyes; then
1871             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1872             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1873         fi
1874     fi
1875
1876     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1877     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1878 fi
1879
1880 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1881 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1882 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1883 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1884 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1885 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1886
1887 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1888                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1889                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1890                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1891 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1892                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1893 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1894 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1895 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1896 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1897 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1898 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1899 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1900
1901 AC_SUBST([ELF_LIB])
1902
1903 AM_CONDITIONAL(DRICOMMON_NEED_LIBDRM, test "x$DRICOMMON_NEED_LIBDRM" = xyes)
1904 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1905 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1906 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
1907
1908 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
1909 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
1910 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
1911
1912 AC_SUBST([VDPAU_MAJOR], 1)
1913 AC_SUBST([VDPAU_MINOR], 0)
1914
1915 AC_SUBST([XVMC_MAJOR], 1)
1916 AC_SUBST([XVMC_MINOR], 0)
1917
1918 AC_SUBST([XA_MAJOR], 2)
1919 AC_SUBST([XA_MINOR], 0)
1920 AC_SUBST([XA_TINY], 0)
1921 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1922
1923 dnl Restore LDFLAGS and CPPFLAGS
1924 LDFLAGS="$_SAVE_LDFLAGS"
1925 CPPFLAGS="$_SAVE_CPPFLAGS"
1926
1927 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
1928 if test "x$acv_mesa_CLANG" = xyes; then
1929     CFLAGS="$CFLAGS -Qunused-arguments"
1930     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
1931 fi
1932
1933 dnl Add user CFLAGS and CXXFLAGS
1934 CFLAGS="$CFLAGS $USER_CFLAGS"
1935 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1936
1937 dnl Substitute the config
1938 AC_CONFIG_FILES([Makefile
1939                 src/Makefile
1940                 src/egl/Makefile
1941                 src/egl/drivers/Makefile
1942                 src/egl/drivers/dri2/Makefile
1943                 src/egl/drivers/glx/Makefile
1944                 src/egl/main/Makefile
1945                 src/egl/main/egl.pc
1946                 src/egl/wayland/Makefile
1947                 src/egl/wayland/wayland-drm/Makefile
1948                 src/egl/wayland/wayland-egl/Makefile
1949                 src/egl/wayland/wayland-egl/wayland-egl.pc
1950                 src/gallium/auxiliary/Makefile
1951                 src/gallium/auxiliary/pipe-loader/Makefile
1952                 src/gallium/drivers/Makefile
1953                 src/gallium/drivers/freedreno/Makefile
1954                 src/gallium/drivers/freedreno/a2xx/Makefile
1955                 src/gallium/drivers/freedreno/a3xx/Makefile
1956                 src/gallium/drivers/galahad/Makefile
1957                 src/gallium/drivers/i915/Makefile
1958                 src/gallium/drivers/identity/Makefile
1959                 src/gallium/drivers/ilo/Makefile
1960                 src/gallium/drivers/llvmpipe/Makefile
1961                 src/gallium/drivers/noop/Makefile
1962                 src/gallium/drivers/nouveau/Makefile
1963                 src/gallium/drivers/r300/Makefile
1964                 src/gallium/drivers/r600/Makefile
1965                 src/gallium/drivers/radeon/Makefile
1966                 src/gallium/drivers/radeonsi/Makefile
1967                 src/gallium/drivers/rbug/Makefile
1968                 src/gallium/drivers/softpipe/Makefile
1969                 src/gallium/drivers/svga/Makefile
1970                 src/gallium/drivers/trace/Makefile
1971                 src/gallium/state_trackers/Makefile
1972                 src/gallium/state_trackers/clover/Makefile
1973                 src/gallium/state_trackers/dri/Makefile
1974                 src/gallium/state_trackers/dri/drm/Makefile
1975                 src/gallium/state_trackers/dri/sw/Makefile
1976                 src/gallium/state_trackers/egl/Makefile
1977                 src/gallium/state_trackers/gbm/Makefile
1978                 src/gallium/state_trackers/glx/xlib/Makefile
1979                 src/gallium/state_trackers/osmesa/Makefile
1980                 src/gallium/state_trackers/vdpau/Makefile
1981                 src/gallium/state_trackers/vega/Makefile
1982                 src/gallium/state_trackers/xa/Makefile
1983                 src/gallium/state_trackers/xvmc/Makefile
1984                 src/gallium/targets/Makefile
1985                 src/gallium/targets/dri-freedreno/Makefile
1986                 src/gallium/targets/dri-i915/Makefile
1987                 src/gallium/targets/dri-ilo/Makefile
1988                 src/gallium/targets/dri-nouveau/Makefile
1989                 src/gallium/targets/dri-swrast/Makefile
1990                 src/gallium/targets/dri-vmwgfx/Makefile
1991                 src/gallium/targets/egl-static/Makefile
1992                 src/gallium/targets/gbm/Makefile
1993                 src/gallium/targets/opencl/Makefile
1994                 src/gallium/targets/osmesa/Makefile
1995                 src/gallium/targets/osmesa/osmesa.pc
1996                 src/gallium/targets/pipe-loader/Makefile
1997                 src/gallium/targets/radeonsi/dri/Makefile
1998                 src/gallium/targets/radeonsi/vdpau/Makefile
1999                 src/gallium/targets/r300/dri/Makefile
2000                 src/gallium/targets/r600/dri/Makefile
2001                 src/gallium/targets/r600/vdpau/Makefile
2002                 src/gallium/targets/r600/xvmc/Makefile
2003                 src/gallium/targets/libgl-xlib/Makefile
2004                 src/gallium/targets/vdpau-nouveau/Makefile
2005                 src/gallium/targets/xa-vmwgfx/Makefile
2006                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2007                 src/gallium/targets/xvmc-nouveau/Makefile
2008                 src/gallium/tests/trivial/Makefile
2009                 src/gallium/tests/unit/Makefile
2010                 src/gallium/winsys/Makefile
2011                 src/gallium/winsys/freedreno/drm/Makefile
2012                 src/gallium/winsys/i915/drm/Makefile
2013                 src/gallium/winsys/i915/sw/Makefile
2014                 src/gallium/winsys/intel/drm/Makefile
2015                 src/gallium/winsys/nouveau/drm/Makefile
2016                 src/gallium/winsys/radeon/drm/Makefile
2017                 src/gallium/winsys/svga/drm/Makefile
2018                 src/gallium/winsys/sw/dri/Makefile
2019                 src/gallium/winsys/sw/fbdev/Makefile
2020                 src/gallium/winsys/sw/null/Makefile
2021                 src/gallium/winsys/sw/wayland/Makefile
2022                 src/gallium/winsys/sw/wrapper/Makefile
2023                 src/gallium/winsys/sw/xlib/Makefile
2024                 src/gbm/Makefile
2025                 src/gbm/main/gbm.pc
2026                 src/glsl/Makefile
2027                 src/glx/Makefile
2028                 src/glx/tests/Makefile
2029                 src/gtest/Makefile
2030                 src/mapi/Makefile
2031                 src/mapi/es1api/Makefile
2032                 src/mapi/es1api/glesv1_cm.pc
2033                 src/mapi/es2api/Makefile
2034                 src/mapi/es2api/glesv2.pc
2035                 src/mapi/glapi/Makefile
2036                 src/mapi/glapi/gen/Makefile
2037                 src/mapi/glapi/tests/Makefile
2038                 src/mapi/shared-glapi/Makefile
2039                 src/mapi/shared-glapi/tests/Makefile
2040                 src/mapi/vgapi/Makefile
2041                 src/mapi/vgapi/vg.pc
2042                 src/mesa/Makefile
2043                 src/mesa/gl.pc
2044                 src/mesa/drivers/dri/dri.pc
2045                 src/mesa/drivers/dri/common/Makefile
2046                 src/mesa/drivers/dri/common/xmlpool/Makefile
2047                 src/mesa/drivers/dri/i915/Makefile
2048                 src/mesa/drivers/dri/i965/Makefile
2049                 src/mesa/drivers/dri/Makefile
2050                 src/mesa/drivers/dri/nouveau/Makefile
2051                 src/mesa/drivers/dri/r200/Makefile
2052                 src/mesa/drivers/dri/radeon/Makefile
2053                 src/mesa/drivers/dri/swrast/Makefile
2054                 src/mesa/drivers/osmesa/Makefile
2055                 src/mesa/drivers/osmesa/osmesa.pc
2056                 src/mesa/drivers/x11/Makefile
2057                 src/mesa/main/tests/Makefile
2058                 src/mesa/main/tests/hash_table/Makefile])
2059
2060 dnl Sort the dirs alphabetically
2061 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2062 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2063 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2064 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2065
2066 AC_OUTPUT
2067
2068 dnl
2069 dnl Output some configuration info for the user
2070 dnl
2071 echo ""
2072 echo "        prefix:          $prefix"
2073 echo "        exec_prefix:     $exec_prefix"
2074 echo "        libdir:          $libdir"
2075 echo "        includedir:      $includedir"
2076
2077 dnl API info
2078 echo ""
2079 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2080 echo "        OpenVG:          $enable_openvg"
2081
2082 dnl Driver info
2083 echo ""
2084 case "x$enable_osmesa$enable_gallium_osmesa" in
2085 xnoyes)
2086         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2087         ;;
2088 xyesno)
2089         echo "        OSMesa:          lib$OSMESA_LIB"
2090         ;;
2091 xnono)
2092         echo "        OSMesa:          no"
2093         ;;
2094 esac
2095
2096 if test "x$enable_dri" != xno; then
2097         # cleanup the drivers var
2098         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2099         if test "x$DRI_DIRS" = x; then
2100             echo "        DRI drivers:     no"
2101         else
2102             echo "        DRI drivers:     $dri_dirs"
2103         fi
2104         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2105 fi
2106
2107 case "x$enable_glx$enable_xlib_glx" in
2108 xyesyes)
2109     echo "        GLX:             Xlib-based"
2110     ;;
2111 xyesno)
2112     echo "        GLX:             DRI-based"
2113     ;;
2114 *)
2115     echo "        GLX:             $enable_glx"
2116     ;;
2117 esac
2118
2119 dnl EGL
2120 echo ""
2121 echo "        EGL:             $enable_egl"
2122 if test "$enable_egl" = yes; then
2123     echo "        EGL platforms:   $egl_platforms"
2124
2125     egl_drivers=""
2126     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2127         egl_drivers="$egl_drivers builtin:egl_glx"
2128     fi
2129     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2130         egl_drivers="$egl_drivers builtin:egl_dri2"
2131     fi
2132
2133     if test "x$enable_gallium_egl" = xyes; then
2134         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2135         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2136     else
2137         echo "        EGL drivers:    $egl_drivers"
2138     fi
2139 fi
2140
2141 echo ""
2142 if test "x$MESA_LLVM" = x1; then
2143     echo "        llvm:            yes"
2144     echo "        llvm-config:     $LLVM_CONFIG"
2145     echo "        llvm-version:    $LLVM_VERSION"
2146 else
2147     echo "        llvm:            no"
2148 fi
2149
2150 echo ""
2151 if test -n "$with_gallium_drivers"; then
2152     echo "        Gallium:         yes"
2153     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2154     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2155     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2156     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2157 else
2158     echo "        Gallium:         no"
2159 fi
2160
2161
2162 dnl Libraries
2163 echo ""
2164 echo "        Shared libs:     $enable_shared"
2165 echo "        Static libs:     $enable_static"
2166 echo "        Shared-glapi:    $enable_shared_glapi"
2167
2168 dnl Compiler options
2169 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2170 cflags=`echo $CFLAGS | \
2171     $SED 's/^ *//;s/  */ /;s/ *$//'`
2172 cxxflags=`echo $CXXFLAGS | \
2173     $SED 's/^ *//;s/  */ /;s/ *$//'`
2174 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2175 echo ""
2176 echo "        CFLAGS:          $cflags"
2177 echo "        CXXFLAGS:        $cxxflags"
2178 echo "        Macros:          $defines"
2179 echo ""
2180 if test "x$MESA_LLVM" = x1; then
2181     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2182     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2183     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2184     echo ""
2185 fi
2186 echo "        PYTHON2:         $PYTHON2"
2187
2188 echo ""
2189 echo "        Run '${MAKE-make}' to build Mesa"
2190 echo ""